zlib/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_INIT([zlib], [1.1.4])
   4 AC_CONFIG_SRCDIR([zlib.h])
   5
   6 if test -n "${with_target_subdir}"; then
   7   AM_ENABLE_MULTILIB(, ..)
   8 fi
   9
  10 AC_CANONICAL_SYSTEM
  11
  12 # This works around an automake problem.
  13 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  14 AC_SUBST(mkinstalldirs)
  15
  16 AM_INIT_AUTOMAKE
  17
  18 AM_MAINTAINER_MODE
  19
  20 dnl We use these options to decide which functions to include.
  21 AC_ARG_WITH(target-subdir,
  22 [  --with-target-subdir=SUBDIR
  23                           configuring in a subdirectory])
  24
  25 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  26    COMPPATH=.
  27 else
  28    COMPPATH=..
  29 fi
  30 AC_SUBST(COMPPATH)
  31
  32 AC_ARG_WITH(cross-host,
  33 [  --with-cross-host=HOST  configuring with a cross compiler])
  34
  35 dnl Default to --enable-multilib
  36 AC_ARG_ENABLE(multilib,
  37 [  --enable-multilib       build many library versions (default)],
  38 [case "${enableval}" in
  39   yes) multilib=yes ;;
  40   no)  multilib=no ;;
  41   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  42  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  43
  44 AC_ARG_WITH(system-zlib,
  45 [  --with-system-zlib      use installed libz])
  46
  47 # Make sure we don't test executables when making cross-tools.
  48 GCC_NO_EXECUTABLES
  49
  50 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  51 # We must force CC to /not/ be precious variables; otherwise
  52 # the wrong, non-multilib-adjusted value will be used in multilibs.
  53 # As a side effect, we have to subst CFLAGS ourselves.
  54
  55 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  56 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  57 AC_PROG_CC
  58 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  59
  60 AC_SUBST(CFLAGS)
  61
  62 # Add CET specific flags if CET is enabled
  63 GCC_CET_FLAGS(CET_FLAGS)
  64 AC_SUBST(CET_FLAGS)
  65
  66 AC_PROG_LIBTOOL
  67
  68 # Find CPP now so that any conditional tests below won't do it and
  69 # thereby make the resulting definitions conditional.
  70 AC_PROG_CPP
  71
  72 if test -n "$with_cross_host"; then
  73    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  74    # may not work correctly, because the compiler may not be able to
  75    # link executables.
  76
  77    # We assume newlib.  This lets us hard-code the functions we know
  78    # we'll have.
  79    AC_DEFINE(HAVE_MEMCPY)
  80    AC_DEFINE(HAVE_STRERROR)
  81 else
  82    AC_FUNC_MMAP
  83    AC_CHECK_FUNCS(memcpy strerror)
  84 fi
  85
  86 AC_CHECK_HEADERS(unistd.h)
  87
  88 GCC_WITH_TOOLEXECLIBDIR
  89
  90 if test -n "$with_cross_host" &&
  91    test x"$with_cross_host" != x"no"; then
  92   toolexecdir='$(exec_prefix)/$(target_alias)'
  93   case ${with_toolexeclibdir} in
  94     no)
  95       toolexeclibdir='$(toolexecdir)/lib'
  96       ;;
  97     *)
  98       toolexeclibdir=${with_toolexeclibdir}
  99       ;;
 100   esac
 101 else
 102   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 103   toolexeclibdir='$(libdir)'
 104 fi
 105 if test "$GCC" = yes && $CC -print-multi-os-directory > /dev/null 2>&1; then
 106   multiosdir=/`$CC -print-multi-os-directory`
 107   case $multiosdir in
 108     /.) multiosdir= ;; # Avoid trailing /.
 109   esac
 110 else
 111   multiosdir=
 112 fi
 113 toolexeclibdir=${toolexeclibdir}${multiosdir}
 114 AC_SUBST(toolexecdir)
 115 AC_SUBST(toolexeclibdir)
 116
 117 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
 118
 119 if test "${multilib}" = "yes"; then
 120   multilib_arg="--enable-multilib"
 121 else
 122   multilib_arg=
 123 fi
 124
 125 AC_ARG_ENABLE(host-shared,
 126 [AS_HELP_STRING([--enable-host-shared],
 127                 [build host code as shared libraries])],
 128 [PICFLAG=-fPIC], [PICFLAG=])
 129 AC_SUBST(PICFLAG)
 130
 131 AC_CONFIG_FILES([Makefile])
 132 AC_OUTPUT