+# For gthread support. Depends on GLIBCXX_ENABLE_SYMVERS.
+GLIBCXX_CHECK_GTHREADS
+
+# For Filesystem TS.
+AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
+GLIBCXX_ENABLE_FILESYSTEM_TS
+GLIBCXX_CHECK_FILESYSTEM_DEPS
+
+# For Transactional Memory TS
+GLIBCXX_CHECK_SIZE_T_MANGLING
+
+# Define documentation rules conditionally.
+
+# See if makeinfo has been installed and is modern enough
+# that we can use it.
+ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
+ [GNU texinfo.* \([0-9][0-9.]*\)],
+ [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
+AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
+
+# Check for doxygen
+AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
+AC_CHECK_PROG([DOT], dot, yes, no)
+
+# Check for docbook
+AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
+AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
+GLIBCXX_CONFIGURE_DOCBOOK
+
+# Check for xml/html dependencies.
+AM_CONDITIONAL(BUILD_XML,
+ test $ac_cv_prog_DOXYGEN = "yes" &&
+ test $ac_cv_prog_DOT = "yes" &&
+ test $ac_cv_prog_XSLTPROC = "yes" &&
+ test $ac_cv_prog_XMLLINT = "yes" &&
+ test $glibcxx_stylesheets = "yes")
+
+AM_CONDITIONAL(BUILD_HTML,
+ test $ac_cv_prog_DOXYGEN = "yes" &&
+ test $ac_cv_prog_DOT = "yes" &&
+ test $ac_cv_prog_XSLTPROC = "yes" &&
+ test $ac_cv_prog_XMLLINT = "yes" &&
+ test $glibcxx_stylesheets = "yes")
+
+# Check for man dependencies.
+AM_CONDITIONAL(BUILD_MAN,
+ test $ac_cv_prog_DOXYGEN = "yes" &&
+ test $ac_cv_prog_DOT = "yes")
+
+# Check for pdf dependencies.
+AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
+AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
+AM_CONDITIONAL(BUILD_PDF,
+ test $ac_cv_prog_DBLATEX = "yes" &&
+ test $ac_cv_prog_PDFLATEX = "yes")
+
+