gdbserver: modernize configure.ac

Run autoupdate on gdbserver/configure.ac and then tweak it to use easier
to read indentation.  This removes a few warnings when running
`autoreconf -vf -Wall`.

  * Replace AC_INIT with AC_INIT and no arguments plus AC_CONFIG_SRCDIR.
  * Replace AC_GNU_SOURCE with AC_USE_SYSTEM_EXTENSIONS.
  * Replace AC_TRY_COMPILE with AC_COMPILE_IFELSE.
  * Replace AC_TRY_LINK with AC_LINK_IFELSE.

autoupdate gets it right, except this one here:

    --- a/gdbserver/configure.ac
    +++ b/gdbserver/configure.ac
    @@ -304,7 +304,7 @@ if test "$srv_linux_thread_db" = "yes"; then
         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[found="-Wl,--dynamic-list"
                     RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],[RDYNAMIC="-rdynamic"
                     LDFLAGS="$old_LDFLAGS $RDYNAMIC"
    -                AC_TRY_LINK([], [],
    +                _au_m4_changequote([,])AC_TRY_LINK([], [],
                                 [found="-rdynamic"],
                                 [found="no"
                                  RDYNAMIC=""])])

... which I had to convert manually.

The changes in the generated configure file only contain insignificant
whitespace changes, so that gives confidence that the conversion is
correct.

gdbserver/ChangeLog:

	* configure.ac: Modernize.
	* configure: Re-generate.

Change-Id: Ia769aaec2aafac595504f477da955e91dffa4d8f

diff --git a/gdbserver/ChangeLog b/gdbserver/ChangeLog
index f9b2b5ee84ba82d8bfcd82b54afb247faf2bd5dd..2ee4af03989270f6f6ba512039fbe711629a87d3 100644 (file)
--- a/gdbserver/ChangeLog
+++ b/gdbserver/ChangeLog
@@ -1,3 +1,8 @@
+2020-10-31  Simon Marchi  <simon.marchi@polymtl.ca>
+
+       * configure.ac: Modernize.
+       * configure: Re-generate.
+
 2020-10-31  Simon Marchi  <simon.marchi@polymtl.ca>
 
        * configure.ac: Use AC_CANONICAL_{BUILD,HOST,TARGET} instead of

diff --git a/gdbserver/configure b/gdbserver/configure
index 4b7ef288d06516e63b2998bb2f3fccb2d312fc6f..c91ce71c943e6da5a2d287167a2e0fb989d6034b 100755 (executable)
--- a/gdbserver/configure
+++ b/gdbserver/configure
@@ -2713,6 +2713,7 @@ ac_compiler_gnu=$ac_cv_c_compiler_gnu
 
 
 
+
 ac_config_headers="$ac_config_headers config.h:config.in"
 
 
@@ -4245,7 +4246,6 @@ $as_echo "$ac_cv_safe_to_define___extensions__" >&6; }
   $as_echo "#define _TANDEM_SOURCE 1" >>confdefs.h
 
 
-
 # Check whether --enable-largefile was given.
 if test "${enable_largefile+set}" = set; then :
   enableval=$enable_largefile;
@@ -9653,6 +9653,7 @@ int
 main ()
 {
 
+
   ;
   return 0;
 }
@@ -9660,11 +9661,14 @@ _ACEOF
 if ac_fn_c_try_compile "$LINENO"; then :
   { $as_echo "$as_me:${as_lineno-$LINENO}: result: yes" >&5
 $as_echo "yes" >&6; };
+
 $as_echo "#define HAVE_UST 1" >>confdefs.h
 
 else
   { $as_echo "$as_me:${as_lineno-$LINENO}: result: no" >&5
-$as_echo "no" >&6; }; ustlibs= ; ustinc=
+$as_echo "no" >&6; }
+     ustlibs= ; ustinc=
+
 fi
 rm -f core conftest.err conftest.$ac_objext conftest.$ac_ext
   CFLAGS="$saved_CFLAGS"
@@ -10314,8 +10318,10 @@ if ac_fn_c_try_compile "$LINENO"; then :
   gdbsrv_cv_have_ptrace_getregs=yes
 else
   gdbsrv_cv_have_ptrace_getregs=no
+
 fi
 rm -f core conftest.err conftest.$ac_objext conftest.$ac_ext
+
 fi
 
   { $as_echo "$as_me:${as_lineno-$LINENO}: result: $gdbsrv_cv_have_ptrace_getregs" >&5
@@ -10346,8 +10352,10 @@ if ac_fn_c_try_compile "$LINENO"; then :
   gdbsrv_cv_have_ptrace_getfpxregs=yes
 else
   gdbsrv_cv_have_ptrace_getfpxregs=no
+
 fi
 rm -f core conftest.err conftest.$ac_objext conftest.$ac_ext
+
 fi
 
   { $as_echo "$as_me:${as_lineno-$LINENO}: result: $gdbsrv_cv_have_ptrace_getfpxregs" >&5
@@ -10513,11 +10521,11 @@ main ()
 _ACEOF
 if ac_fn_c_try_link "$LINENO"; then :
   found="-Wl,--dynamic-list"
-                RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
+       RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
 else
   RDYNAMIC="-rdynamic"
-                LDFLAGS="$old_LDFLAGS $RDYNAMIC"
-                cat confdefs.h - <<_ACEOF >conftest.$ac_ext
+       LDFLAGS="$old_LDFLAGS $RDYNAMIC"
+       cat confdefs.h - <<_ACEOF >conftest.$ac_ext
 /* end confdefs.h.  */
 
 int
@@ -10532,10 +10540,12 @@ if ac_fn_c_try_link "$LINENO"; then :
   found="-rdynamic"
 else
   found="no"
-                             RDYNAMIC=""
+         RDYNAMIC=""
+
 fi
 rm -f core conftest.err conftest.$ac_objext \
     conftest$ac_exeext conftest.$ac_ext
+
 fi
 rm -f core conftest.err conftest.$ac_objext \
     conftest$ac_exeext conftest.$ac_ext
@@ -10571,8 +10581,10 @@ if ac_fn_c_try_compile "$LINENO"; then :
   gdbsrv_cv_have_td_version=yes
 else
   gdbsrv_cv_have_td_version=no
+
 fi
 rm -f core conftest.err conftest.$ac_objext conftest.$ac_ext
+
 fi
 { $as_echo "$as_me:${as_lineno-$LINENO}: result: $gdbsrv_cv_have_td_version" >&5
 $as_echo "$gdbsrv_cv_have_td_version" >&6; }
@@ -10619,14 +10631,15 @@ $as_echo_n "checking whether the target supports __sync_*_compare_and_swap... "
 if ${gdbsrv_cv_have_sync_builtins+:} false; then :
   $as_echo_n "(cached) " >&6
 else
-
-cat confdefs.h - <<_ACEOF >conftest.$ac_ext
+  cat confdefs.h - <<_ACEOF >conftest.$ac_ext
 /* end confdefs.h.  */
 
 int
 main ()
 {
-int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);
+int foo, bar;
+        bar = __sync_val_compare_and_swap(&foo, 0, 1);
+
   ;
   return 0;
 }
@@ -10635,9 +10648,11 @@ if ac_fn_c_try_link "$LINENO"; then :
   gdbsrv_cv_have_sync_builtins=yes
 else
   gdbsrv_cv_have_sync_builtins=no
+
 fi
 rm -f core conftest.err conftest.$ac_objext \
     conftest$ac_exeext conftest.$ac_ext
+
 fi
 { $as_echo "$as_me:${as_lineno-$LINENO}: result: $gdbsrv_cv_have_sync_builtins" >&5
 $as_echo "$gdbsrv_cv_have_sync_builtins" >&6; }

diff --git a/gdbserver/configure.ac b/gdbserver/configure.ac
index c4748703dcda005faeaab8d744cd204a221a36f2..dd646cffa1a3c0586894cee9d0a01c817f17c435 100644 (file)
--- a/gdbserver/configure.ac
+++ b/gdbserver/configure.ac
@@ -18,14 +18,15 @@ dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
 
 dnl Process this file with autoconf to produce a configure script.
 
-AC_INIT(server.cc)
+AC_INIT
+AC_CONFIG_SRCDIR([server.cc])
 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
 
 AM_MAINTAINER_MODE
 
 AC_PROG_CC
 AC_PROG_CXX
-AC_GNU_SOURCE
+AC_USE_SYSTEM_EXTENSIONS
 AC_SYS_LARGEFILE
 AM_PROG_INSTALL_STRIP
 
@@ -124,12 +125,19 @@ if test "x$with_ust" != "xno"; then
   saved_CFLAGS="$CFLAGS"
   CFLAGS="$CFLAGS $ustinc"
   AC_MSG_CHECKING([for ust])
-  AC_TRY_COMPILE([
+  AC_COMPILE_IFELSE(
+    [AC_LANG_PROGRAM(
+       [
 #define CONFIG_UST_GDB_INTEGRATION
 #include <ust/ust.h>
-  ],[],
-  [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
-  [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
+       ],
+       []
+     )],
+    [AC_MSG_RESULT([yes]);
+     AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
+    [AC_MSG_RESULT([no])
+     ustlibs= ; ustinc= ]
+  )
   CFLAGS="$saved_CFLAGS"
 fi
 
@@ -249,11 +257,14 @@ if test "${srv_linux_regsets}" = "yes"; then
            [Define if the target supports register sets.])
 
   AC_MSG_CHECKING(for PTRACE_GETREGS)
-  AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
-  [AC_TRY_COMPILE([#include <sys/ptrace.h>],
-                 [PTRACE_GETREGS;],
-                 [gdbsrv_cv_have_ptrace_getregs=yes],
-                 [gdbsrv_cv_have_ptrace_getregs=no])])
+  AC_CACHE_VAL(
+    [gdbsrv_cv_have_ptrace_getregs],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
+       [gdbsrv_cv_have_ptrace_getregs=yes],
+       [gdbsrv_cv_have_ptrace_getregs=no]
+     )]
+  )
   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
@@ -262,11 +273,14 @@ if test "${srv_linux_regsets}" = "yes"; then
   fi
 
   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
-  AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
-  [AC_TRY_COMPILE([#include <sys/ptrace.h>],
-                 [PTRACE_GETFPXREGS;],
-                 [gdbsrv_cv_have_ptrace_getfpxregs=yes],
-                 [gdbsrv_cv_have_ptrace_getfpxregs=no])])
+  AC_CACHE_VAL(
+    [gdbsrv_cv_have_ptrace_getfpxregs],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
+       [gdbsrv_cv_have_ptrace_getfpxregs=yes],
+       [gdbsrv_cv_have_ptrace_getfpxregs=no]
+     )]
+  )
   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
@@ -308,15 +322,19 @@ if test "$srv_linux_thread_db" = "yes"; then
     # supported there.
     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
     LDFLAGS="$LDFLAGS $RDYNAMIC"
-    AC_TRY_LINK([], [],
-               [found="-Wl,--dynamic-list"
-                RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
-               [RDYNAMIC="-rdynamic"
-                LDFLAGS="$old_LDFLAGS $RDYNAMIC"
-                AC_TRY_LINK([], [],
-                            [found="-rdynamic"],
-                            [found="no"
-                             RDYNAMIC=""])])
+    AC_LINK_IFELSE(
+      [AC_LANG_PROGRAM([],[])],
+      [found="-Wl,--dynamic-list"
+       RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
+      [RDYNAMIC="-rdynamic"
+       LDFLAGS="$old_LDFLAGS $RDYNAMIC"
+       AC_LINK_IFELSE(
+        [AC_LANG_PROGRAM([], [])],
+        [found="-rdynamic"],
+        [found="no"
+         RDYNAMIC=""]
+       )]
+    )
     AC_SUBST(RDYNAMIC)
     LDFLAGS="$old_LDFLAGS"
     AC_MSG_RESULT($found)
@@ -326,10 +344,15 @@ if test "$srv_linux_thread_db" = "yes"; then
 
   srv_thread_depfiles="thread-db.o proc-service.o"
   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
-  AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
-  [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
-                 [gdbsrv_cv_have_td_version=yes],
-                 [gdbsrv_cv_have_td_version=no])])
+  AC_CACHE_CHECK(
+    [for TD_VERSION],
+    [gdbsrv_cv_have_td_version],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM([#include <thread_db.h>], [TD_VERSION;])],
+       [gdbsrv_cv_have_td_version=yes],
+       [gdbsrv_cv_have_td_version=no]
+     )]
+  )
   if test "$gdbsrv_cv_have_td_version" = yes; then
     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
   fi
@@ -360,11 +383,19 @@ GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_dep
 GDBSERVER_LIBS="$srv_libs"
 
 dnl Check whether the target supports __sync_*_compare_and_swap.
-AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
-               gdbsrv_cv_have_sync_builtins, [
-AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
-               gdbsrv_cv_have_sync_builtins=yes,
-               gdbsrv_cv_have_sync_builtins=no)])
+AC_CACHE_CHECK(
+  [whether the target supports __sync_*_compare_and_swap],
+  [gdbsrv_cv_have_sync_builtins],
+  [AC_LINK_IFELSE(
+     [AC_LANG_PROGRAM(
+       [],
+       [int foo, bar;
+        bar = __sync_val_compare_and_swap(&foo, 0, 1);]
+      )],
+     [gdbsrv_cv_have_sync_builtins=yes],
+     [gdbsrv_cv_have_sync_builtins=no]
+   )]
+)
 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
     [Define to 1 if the target supports __sync_*_compare_and_swap])