configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.81
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     powerpc64le)
 770         case "$host_os" in
 771         linux*)
 772             asm_arch=ppc64le
 773             ;;
 774         esac
 775         ;;
 776     esac
 777
 778     case "$asm_arch" in
 779     x86)
 780         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 781         AC_MSG_RESULT([yes, x86])
 782         ;;
 783     x86_64|amd64)
 784         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 785         AC_MSG_RESULT([yes, x86_64])
 786         ;;
 787     sparc)
 788         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 789         AC_MSG_RESULT([yes, sparc])
 790         ;;
 791     ppc64le)
 792         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 793         AC_MSG_RESULT([yes, ppc64le])
 794         ;;
 795     *)
 796         AC_MSG_RESULT([no, platform not supported])
 797         ;;
 798     esac
 799 fi
 800
 801 AC_HEADER_MAJOR
 802 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 803 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 804 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 805 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 806
 807 dnl Check to see if dlopen is in default libraries (like Solaris, which
 808 dnl has it in libc), or if libdl is needed to get it.
 809 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 810     [AC_CHECK_LIB([dl], [dlopen],
 811        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 812 AC_SUBST([DLOPEN_LIBS])
 813
 814 dnl Check if that library also has dladdr
 815 save_LIBS="$LIBS"
 816 LIBS="$LIBS $DLOPEN_LIBS"
 817 AC_CHECK_FUNCS([dladdr])
 818 LIBS="$save_LIBS"
 819
 820 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 821
 822 case "$host_os" in
 823 darwin*)
 824     ;;
 825 *)
 826     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 827                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 828                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 829     AC_SUBST([CLOCK_LIB])
 830     ;;
 831 esac
 832
 833 dnl See if posix_memalign is available
 834 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 835
 836 dnl Check for zlib
 837 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 838
 839 dnl Check for pthreads
 840 AX_PTHREAD
 841 if test "x$ax_pthread_ok" = xno; then
 842     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 843 fi
 844 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 845 dnl to -pthread, which causes problems if we need -lpthread to appear in
 846 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 847 dnl is not valid for that platform.
 848 if test "x$android" = xno; then
 849     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 850 fi
 851 dnl According to the manual when using pthreads, one should add -pthread to
 852 dnl both compile and link-time arguments.
 853 dnl In practise that should be sufficient for all platforms, since any
 854 dnl platforms build with GCC and Clang support the flag.
 855 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 856
 857 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 858 dnl project. Even then there's a notable issue as described in the project README
 859 case "$host_os" in
 860 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 861     pthread_stubs_possible="no"
 862     ;;
 863 * )
 864     pthread_stubs_possible="yes"
 865     ;;
 866 esac
 867
 868 if test "x$pthread_stubs_possible" = xyes; then
 869     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 870 fi
 871
 872 dnl SELinux awareness.
 873 AC_ARG_ENABLE([selinux],
 874     [AS_HELP_STRING([--enable-selinux],
 875         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 876     [MESA_SELINUX="$enableval"],
 877     [MESA_SELINUX=no])
 878 if test "x$enable_selinux" = "xyes"; then
 879     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 880         [AC_CHECK_HEADER([selinux/selinux.h],[],
 881                          [AC_MSG_ERROR([SELinux headers not found])])
 882          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 883                       [AC_MSG_ERROR([SELinux library not found])])
 884          SELINUX_LIBS="-lselinux"])
 885     DEFINES="$DEFINES -DMESA_SELINUX"
 886 fi
 887 AC_SUBST([SELINUX_CFLAGS])
 888 AC_SUBST([SELINUX_LIBS])
 889
 890 dnl
 891 dnl LLVM
 892 dnl
 893 AC_ARG_ENABLE([llvm-shared-libs],
 894     [AS_HELP_STRING([--enable-llvm-shared-libs],
 895         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 896     [enable_llvm_shared_libs="$enableval"],
 897     [enable_llvm_shared_libs=yes])
 898
 899 AC_ARG_WITH([llvm-prefix],
 900     [AS_HELP_STRING([--with-llvm-prefix],
 901         [Prefix for LLVM installations in non-standard locations])],
 902     [llvm_prefix="$withval"],
 903     [llvm_prefix=''])
 904
 905 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 906 if test "x$have_libelf" = xno; then
 907    LIBELF_LIBS=''
 908    LIBELF_CFLAGS=''
 909    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 910    AC_SUBST([LIBELF_LIBS])
 911    AC_SUBST([LIBELF_CFLAGS])
 912 fi
 913
 914 if test -z "$LLVM_CONFIG"; then
 915     if test -n "$llvm_prefix"; then
 916         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 917     else
 918         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 919     fi
 920 fi
 921
 922 llvm_add_component() {
 923     new_llvm_component=$1
 924     driver_name=$2
 925
 926     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 927         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 928     else
 929         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 930     fi
 931 }
 932
 933 llvm_add_default_components() {
 934     driver_name=$1
 935
 936     # Required default components
 937     llvm_add_component "bitwriter" $driver_name
 938     llvm_add_component "engine" $driver_name
 939     llvm_add_component "mcdisassembler" $driver_name
 940     llvm_add_component "mcjit" $driver_name
 941
 942     # Optional default components
 943     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 944         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 945     fi
 946 }
 947
 948 llvm_add_target() {
 949     new_llvm_target=$1
 950     driver_name=$2
 951
 952     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 953         llvm_add_component $new_llvm_target $driver_name
 954     else
 955         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 956     fi
 957 }
 958
 959 # Call this inside ` ` to get the return value.
 960 # $1 is the llvm-config command with arguments.
 961 strip_unwanted_llvm_flags() {
 962     echo " `$1` " | sed -E \
 963         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 964         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 965         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 966         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 967         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 968         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 969         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 970         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 971         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 972         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 973         -e 's/^[[[:space:]]]//' \
 974         -e 's/[[[:space:]]]$//'
 975 }
 976
 977 llvm_set_environment_variables() {
 978     if test "x$LLVM_CONFIG" != xno; then
 979         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 980         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 981         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 982         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 983
 984         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 985         save_CFLAGS="$CFLAGS"
 986         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 987
 988         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 989             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 990         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 991             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 992         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 993             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 994
 995         CFLAGS="$save_CFLAGS"
 996
 997         # Only needed for LLVM < 3.6.0
 998         if test -z "$LLVM_VERSION_PATCH"; then
 999             LLVM_VERSION_PATCH=0
1000         fi
1001
1002         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1003
1004         FOUND_LLVM=yes
1005     else
1006         FOUND_LLVM=no
1007         LLVM_VERSION_INT=0
1008     fi
1009 }
1010
1011 require_llvm() {
1012     if test "x$enable_llvm" != "xyes"; then
1013         AC_MSG_ERROR([--enable-llvm is required when building $1])
1014     fi
1015 }
1016
1017 llvm_require_version() {
1018     require_llvm $2
1019
1020     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1021     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1022     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1023
1024     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1025         # major > required major
1026         #  --> OK
1027         return
1028     fi
1029
1030     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1031         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1032             # major = required major and
1033             # minor > required minor
1034             #  --> OK
1035             return
1036         else
1037             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1038                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1039                     # major = required major and
1040                     # minor = required minor and
1041                     # patch >= required patch
1042                     #  --> OK
1043                     return
1044                 fi
1045             fi
1046         fi
1047     fi
1048
1049     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1050 }
1051
1052 radeon_llvm_check() {
1053     if test ${LLVM_VERSION_INT} -lt 307; then
1054         amdgpu_llvm_target_name='r600'
1055     else
1056         amdgpu_llvm_target_name='amdgpu'
1057     fi
1058
1059     llvm_require_version $*
1060
1061     llvm_add_target $amdgpu_llvm_target_name $2
1062
1063     llvm_add_default_components $2
1064     llvm_add_component "bitreader" $2
1065     llvm_add_component "ipo" $2
1066
1067     if test "x$have_libelf" != xyes; then
1068        AC_MSG_ERROR([$2 requires libelf when using llvm])
1069     fi
1070 }
1071
1072 llvm_set_environment_variables
1073
1074 AC_SUBST([LLVM_CFLAGS])
1075 AC_SUBST([LLVM_CXXFLAGS])
1076 AC_SUBST([LLVM_LIBS])
1077 AC_SUBST([LLVM_LDFLAGS])
1078 AC_SUBST([LLVM_INCLUDEDIR])
1079
1080 dnl
1081 dnl libunwind
1082 dnl
1083 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1084 AC_ARG_ENABLE([libunwind],
1085     [AS_HELP_STRING([--enable-libunwind],
1086             [Use libunwind for backtracing (default: auto)])],
1087         [LIBUNWIND="$enableval"],
1088         [LIBUNWIND="$HAVE_LIBUNWIND"])
1089
1090 if test "x$LIBUNWIND" = "xyes"; then
1091     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1092     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1093 fi
1094
1095
1096 dnl Options for APIs
1097 AC_ARG_ENABLE([opengl],
1098     [AS_HELP_STRING([--disable-opengl],
1099         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1100     [enable_opengl="$enableval"],
1101     [enable_opengl=yes])
1102 AC_ARG_ENABLE([gles1],
1103     [AS_HELP_STRING([--disable-gles1],
1104         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1105     [enable_gles1="$enableval"],
1106     [enable_gles1=yes])
1107 AC_ARG_ENABLE([gles2],
1108     [AS_HELP_STRING([--disable-gles2],
1109         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1110     [enable_gles2="$enableval"],
1111     [enable_gles2=yes])
1112
1113 AC_ARG_ENABLE([dri],
1114     [AS_HELP_STRING([--enable-dri],
1115         [enable DRI modules @<:@default=enabled@:>@])],
1116     [enable_dri="$enableval"],
1117     [enable_dri=yes])
1118
1119 AC_ARG_ENABLE([gallium-extra-hud],
1120     [AS_HELP_STRING([--enable-gallium-extra-hud],
1121         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1122     [enable_gallium_extra_hud="$enableval"],
1123     [enable_gallium_extra_hud=no])
1124 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1125 if test "x$enable_gallium_extra_hud" = xyes ; then
1126     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1127 fi
1128
1129 #TODO: no pkgconfig .pc available for libsensors.
1130 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1131 AC_ARG_ENABLE([lmsensors],
1132     [AS_HELP_STRING([--enable-lmsensors],
1133         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1134     [enable_lmsensors="$enableval"],
1135     [enable_lmsensors=no])
1136 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1137 if test "x$enable_lmsensors" = xyes ; then
1138     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1139     LIBSENSORS_LIBS="-lsensors"
1140 else
1141     LIBSENSORS_LIBS=""
1142 fi
1143 AC_SUBST(LIBSENSORS_LIBS)
1144
1145 case "$host_os" in
1146 linux*)
1147     dri3_default=yes
1148     ;;
1149 *)
1150     dri3_default=no
1151     ;;
1152 esac
1153
1154 if test "x$enable_dri" = xno; then
1155     dri3_default=no
1156 fi
1157
1158 AC_ARG_ENABLE([dri3],
1159     [AS_HELP_STRING([--enable-dri3],
1160         [enable DRI3 @<:@default=auto@:>@])],
1161     [enable_dri3="$enableval"],
1162     [enable_dri3="$dri3_default"])
1163 AC_ARG_ENABLE([glx],
1164     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1165         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1166     [enable_glx="$enableval"],
1167     [enable_glx=yes])
1168 AC_ARG_ENABLE([osmesa],
1169     [AS_HELP_STRING([--enable-osmesa],
1170         [enable OSMesa library @<:@default=disabled@:>@])],
1171     [enable_osmesa="$enableval"],
1172     [enable_osmesa=no])
1173 AC_ARG_ENABLE([gallium-osmesa],
1174     [AS_HELP_STRING([--enable-gallium-osmesa],
1175         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1176     [enable_gallium_osmesa="$enableval"],
1177     [enable_gallium_osmesa=no])
1178 AC_ARG_ENABLE([egl],
1179     [AS_HELP_STRING([--disable-egl],
1180         [disable EGL library @<:@default=enabled@:>@])],
1181     [enable_egl="$enableval"],
1182     [enable_egl=yes])
1183
1184 AC_ARG_ENABLE([xa],
1185     [AS_HELP_STRING([--enable-xa],
1186         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1187     [enable_xa="$enableval"],
1188     [enable_xa=no])
1189 AC_ARG_ENABLE([gbm],
1190    [AS_HELP_STRING([--enable-gbm],
1191          [enable gbm library @<:@default=yes except cygwin@:>@])],
1192    [enable_gbm="$enableval"],
1193    [case "$host_os" in
1194        cygwin*)
1195           enable_gbm=no
1196           ;;
1197        *)
1198           enable_gbm=yes
1199           ;;
1200     esac])
1201 AC_ARG_ENABLE([nine],
1202     [AS_HELP_STRING([--enable-nine],
1203         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1204     [enable_nine="$enableval"],
1205     [enable_nine=no])
1206
1207 AC_ARG_ENABLE([xvmc],
1208    [AS_HELP_STRING([--enable-xvmc],
1209          [enable xvmc library @<:@default=auto@:>@])],
1210    [enable_xvmc="$enableval"],
1211    [enable_xvmc=auto])
1212 AC_ARG_ENABLE([vdpau],
1213    [AS_HELP_STRING([--enable-vdpau],
1214          [enable vdpau library @<:@default=auto@:>@])],
1215    [enable_vdpau="$enableval"],
1216    [enable_vdpau=auto])
1217 AC_ARG_ENABLE([omx],
1218    [AS_HELP_STRING([--enable-omx],
1219          [enable OpenMAX library @<:@default=disabled@:>@])],
1220    [enable_omx="$enableval"],
1221    [enable_omx=no])
1222 AC_ARG_ENABLE([va],
1223    [AS_HELP_STRING([--enable-va],
1224          [enable va library @<:@default=auto@:>@])],
1225    [enable_va="$enableval"],
1226    [enable_va=auto])
1227 AC_ARG_ENABLE([opencl],
1228    [AS_HELP_STRING([--enable-opencl],
1229          [enable OpenCL library @<:@default=disabled@:>@])],
1230    [enable_opencl="$enableval"],
1231    [enable_opencl=no])
1232 AC_ARG_ENABLE([opencl_icd],
1233    [AS_HELP_STRING([--enable-opencl-icd],
1234           [Build an OpenCL ICD library to be loaded by an ICD implementation
1235            @<:@default=disabled@:>@])],
1236     [enable_opencl_icd="$enableval"],
1237     [enable_opencl_icd=no])
1238
1239 AC_ARG_ENABLE([gallium-tests],
1240     [AS_HELP_STRING([--enable-gallium-tests],
1241         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1242     [enable_gallium_tests="$enableval"],
1243     [enable_gallium_tests=no])
1244
1245 # Option for Gallium drivers
1246
1247 # Keep this in sync with the --with-gallium-drivers help string default value
1248 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1249
1250 AC_ARG_WITH([gallium-drivers],
1251     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1252         [comma delimited Gallium drivers list, e.g.
1253         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1254         @<:@default=r300,r600,svga,swrast@:>@])],
1255     [with_gallium_drivers="$withval"],
1256     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1257
1258 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1259 # here so that the script doesn't choke on an unknown driver name later.
1260 case "$with_gallium_drivers" in
1261     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1262     no) with_gallium_drivers='' ;;
1263 esac
1264
1265 if test "x$enable_opengl" = xno -a \
1266         "x$enable_gles1" = xno -a \
1267         "x$enable_gles2" = xno -a \
1268         "x$enable_nine" = xno -a \
1269         "x$enable_xa" = xno -a \
1270         "x$enable_xvmc" = xno -a \
1271         "x$enable_vdpau" = xno -a \
1272         "x$enable_omx" = xno -a \
1273         "x$enable_va" = xno -a \
1274         "x$enable_opencl" = xno; then
1275     AC_MSG_ERROR([at least one API should be enabled])
1276 fi
1277
1278 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1279 if test "x$enable_opengl" = xno -a \
1280         "x$enable_gles1" = xyes; then
1281     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1282 fi
1283
1284 if test "x$enable_opengl" = xno -a \
1285         "x$enable_gles2" = xyes; then
1286     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1287 fi
1288
1289 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1290 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1291 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1292 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1293                                         "x$enable_gles1" = xyes -o \
1294                                         "x$enable_gles2" = xyes)
1295 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1296                                       "x$enable_gles1" = xyes -o \
1297                                       "x$enable_gles2" = xyes)
1298
1299 # Validate GLX options
1300 if test "x$enable_glx" = xyes; then
1301     if test "x$enable_dri" = xyes; then
1302         enable_glx=dri
1303     elif test -n "$with_gallium_drivers"; then
1304         enable_glx=gallium-xlib
1305     else
1306         enable_glx=xlib
1307     fi
1308 fi
1309 case "x$enable_glx" in
1310 xdri | xxlib | xgallium-xlib)
1311     # GLX requires OpenGL
1312     if test "x$enable_opengl" = xno; then
1313         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1314     fi
1315
1316     # Check individual dependencies
1317     case "x$enable_glx" in
1318     xdri)
1319         if test "x$enable_dri" = xno; then
1320             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1321         fi
1322         ;;
1323     xxlib)
1324         if test "x$enable_dri" = xyes; then
1325             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1326         fi
1327         ;;
1328     xgallium-xlib )
1329         if test "x$enable_dri" = xyes; then
1330             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1331         fi
1332         if test -z "$with_gallium_drivers"; then
1333             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1334         fi
1335         ;;
1336     esac
1337     ;;
1338 xno)
1339     ;;
1340 *)
1341     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1342     ;;
1343 esac
1344
1345 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1346 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1347 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1348 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1349
1350 DEFAULT_GL_LIB_NAME=GL
1351
1352 dnl
1353 dnl Libglvnd configuration
1354 dnl
1355 AC_ARG_ENABLE([libglvnd],
1356     [AS_HELP_STRING([--enable-libglvnd],
1357         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1358     [enable_libglvnd="$enableval"],
1359     [enable_libglvnd=no])
1360 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1361
1362 if test "x$enable_libglvnd" = xyes ; then
1363     dnl XXX: update once we can handle more than libGL/glx.
1364     dnl Namely: we should error out if neither of the glvnd enabled libraries
1365     dnl are built
1366     case "x$enable_glx" in
1367     xno)
1368         AC_MSG_ERROR([cannot build libglvnd without GLX])
1369         ;;
1370     xxlib | xgallium-xlib )
1371         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1372         ;;
1373     xdri)
1374         ;;
1375     esac
1376
1377     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1378     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1379     AC_SUBST([LIBGLVND_DATADIR])
1380
1381     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1382     DEFAULT_GL_LIB_NAME=GLX_mesa
1383 fi
1384
1385 AC_ARG_WITH([gl-lib-name],
1386   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1387     [specify GL library name @<:@default=GL@:>@])],
1388   [GL_LIB=$withval],
1389   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1390 AC_ARG_WITH([osmesa-lib-name],
1391   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1392     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1393   [OSMESA_LIB=$withval],
1394   [OSMESA_LIB=OSMesa])
1395 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1396 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1397
1398 dnl
1399 dnl Mangled Mesa support
1400 dnl
1401 AC_ARG_ENABLE([mangling],
1402   [AS_HELP_STRING([--enable-mangling],
1403     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1404   [enable_mangling="${enableval}"],
1405   [enable_mangling=no]
1406 )
1407 if test "x${enable_mangling}" = "xyes" ; then
1408   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1409   GL_LIB="Mangled${GL_LIB}"
1410   OSMESA_LIB="Mangled${OSMESA_LIB}"
1411 fi
1412 AC_SUBST([GL_LIB])
1413 AC_SUBST([OSMESA_LIB])
1414
1415 # Check for libdrm
1416 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1417                   [have_libdrm=yes], [have_libdrm=no])
1418 if test "x$have_libdrm" = xyes; then
1419         DEFINES="$DEFINES -DHAVE_LIBDRM"
1420 fi
1421
1422 require_libdrm() {
1423     if test "x$have_libdrm" != xyes; then
1424        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1425     fi
1426 }
1427
1428
1429 # Select which platform-dependent DRI code gets built
1430 case "$host_os" in
1431 darwin*)
1432     dri_platform='apple' ;;
1433 cygwin*)
1434     dri_platform='windows' ;;
1435 gnu*)
1436     dri_platform='none' ;;
1437 *)
1438     dri_platform='drm' ;;
1439 esac
1440
1441 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1442     have_drisw_kms='yes'
1443 fi
1444
1445 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1446 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1447 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1448 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1449 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1450 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1451 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1452 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1453 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1454
1455 AC_ARG_ENABLE([shared-glapi],
1456     [AS_HELP_STRING([--enable-shared-glapi],
1457         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1458     [enable_shared_glapi="$enableval"],
1459     [enable_shared_glapi=yes])
1460
1461 case "x$enable_opengl$enable_gles1$enable_gles2" in
1462 x*yes*yes*)
1463     if test "x$enable_shared_glapi" = xno; then
1464         AC_MSG_ERROR([shared GLAPI required when building two or more of
1465                       the following APIs - opengl, gles1 gles2])
1466     fi
1467     ;;
1468 esac
1469
1470 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1471
1472 # Build the pipe-drivers as separate libraries/modules.
1473 # Do not touch this unless you know what you are doing.
1474 # XXX: Expose via configure option ?
1475 enable_shared_pipe_drivers=no
1476
1477 dnl
1478 dnl Driver specific build directories
1479 dnl
1480
1481 if test "x$enable_gallium_osmesa" = xyes; then
1482     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1483         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1484     fi
1485     if test "x$enable_osmesa" = xyes; then
1486         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1487     fi
1488 fi
1489
1490 require_dri_shared_libs_and_glapi() {
1491     if test "x$enable_static" = xyes; then
1492         AC_MSG_ERROR([$1 cannot be build as static library])
1493     fi
1494
1495     if test "x$enable_dri" != xyes; then
1496         # There is only a single backend which won't be build/used otherwise.
1497         # XXX: Revisit this as the egl/haiku is a thing.
1498         AC_MSG_ERROR([$1 requires --enable-dri])
1499     fi
1500
1501     if test "x$enable_shared_glapi" != xyes; then
1502         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1503     fi
1504 }
1505
1506 if test "x$enable_dri" = xyes; then
1507     require_dri_shared_libs_and_glapi "DRI"
1508
1509     # not a hard requirement as swrast does not depend on it
1510     if test "x$have_libdrm" = xyes; then
1511         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1512     fi
1513 fi
1514
1515 AC_ARG_ENABLE([driglx-direct],
1516     [AS_HELP_STRING([--disable-driglx-direct],
1517         [disable direct rendering in GLX and EGL for DRI \
1518             @<:@default=auto@:>@])],
1519     [driglx_direct="$enableval"],
1520     [driglx_direct="yes"])
1521
1522 dnl
1523 dnl libGL configuration per driver
1524 dnl
1525 if test "x$enable_glx" != xno; then
1526     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1527 fi
1528 case "x$enable_glx" in
1529 xxlib | xgallium-xlib)
1530     # Xlib-based GLX
1531     dri_modules="x11 xext xcb"
1532     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1533     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1534     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1535     GL_LIB_DEPS="$XLIBGL_LIBS"
1536     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1537     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1538     ;;
1539 xdri)
1540     # DRI-based GLX
1541
1542     # find the DRI deps for libGL
1543     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1544
1545     if test x"$driglx_direct" = xyes; then
1546         if test x"$dri_platform" = xdrm ; then
1547             DEFINES="$DEFINES -DGLX_USE_DRM"
1548             require_libdrm "Direct rendering"
1549
1550             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1551             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1552
1553             if test x"$enable_dri" = xyes; then
1554                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1555             fi
1556         fi
1557         if test x"$dri_platform" = xapple ; then
1558             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1559         fi
1560         if test x"$dri_platform" = xwindows ; then
1561             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1562         fi
1563     fi
1564
1565     # add xf86vidmode if available
1566     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1567     if test "$HAVE_XF86VIDMODE" = yes ; then
1568         dri_modules="$dri_modules xxf86vm"
1569     fi
1570
1571     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1572     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1573     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1574     GL_LIB_DEPS="$DRIGL_LIBS"
1575
1576     # need DRM libs, $PTHREAD_LIBS, etc.
1577     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1578     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1579     ;;
1580 esac
1581
1582 # This is outside the case (above) so that it is invoked even for non-GLX
1583 # builds.
1584 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1585
1586 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1587 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1588 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1589 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1590
1591 AC_SUBST([X11_INCLUDES])
1592 AC_SUBST([GL_LIB_DEPS])
1593 AC_SUBST([GL_PC_REQ_PRIV])
1594 AC_SUBST([GL_PC_LIB_PRIV])
1595 AC_SUBST([GL_PC_CFLAGS])
1596 AC_SUBST([DRI_PC_REQ_PRIV])
1597 AC_SUBST([GLESv1_CM_LIB_DEPS])
1598 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1599 AC_SUBST([GLESv2_LIB_DEPS])
1600 AC_SUBST([GLESv2_PC_LIB_PRIV])
1601
1602 AC_SUBST([HAVE_XF86VIDMODE])
1603
1604 dnl
1605 dnl More GLX setup
1606 dnl
1607 case "x$enable_glx" in
1608 xxlib | xgallium-xlib)
1609     DEFINES="$DEFINES -DUSE_XSHM"
1610     ;;
1611 xdri)
1612     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1613     if test "x$driglx_direct" = xyes; then
1614         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1615     fi
1616     ;;
1617 esac
1618
1619 dnl
1620 dnl TLS detection
1621 dnl
1622
1623 AC_ARG_ENABLE([glx-tls],
1624     [AS_HELP_STRING([--enable-glx-tls],
1625         [enable TLS support in GLX @<:@default=enabled@:>@])],
1626     [GLX_USE_TLS="$enableval"],
1627     [GLX_USE_TLS=yes])
1628 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1629
1630 if test "x$GLX_USE_TLS" = xyes; then
1631     DEFINES="$DEFINES -DGLX_USE_TLS"
1632 fi
1633
1634 dnl Read-only text section on x86 hardened platforms
1635 AC_ARG_ENABLE([glx-read-only-text],
1636     [AS_HELP_STRING([--enable-glx-read-only-text],
1637         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1638     [enable_glx_read_only_text="$enableval"],
1639     [enable_glx_read_only_text=no])
1640 if test "x$enable_glx_read_only_text" = xyes; then
1641     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1642 fi
1643
1644 dnl
1645 dnl DEPRECATED: EGL Platforms configuration
1646 dnl
1647 AC_ARG_WITH([egl-platforms],
1648     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1649         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1650     [with_egl_platforms="$withval"],
1651     [with_egl_platforms=auto])
1652
1653 if test "x$with_egl_platforms" = xauto; then
1654     with_egl_platforms="x11,surfaceless"
1655     if test "x$enable_gbm" = xyes; then
1656         with_egl_platforms="$with_egl_platforms,drm"
1657     fi
1658 else
1659     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1660 fi
1661
1662 dnl
1663 dnl Platforms configuration
1664 dnl
1665 AC_ARG_WITH([platforms],
1666     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1667         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1668         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1669     [with_platforms="$withval"],
1670     [with_platforms=auto])
1671
1672 # Reuse the autodetection rather than duplicating it.
1673 if test "x$with_platforms" = xauto; then
1674     with_platforms=$with_egl_platforms
1675 fi
1676
1677 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1678         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1679         WAYLAND_SCANNER='')
1680 if test "x$WAYLAND_SCANNER" = x; then
1681     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1682 fi
1683
1684 # Do per platform setups and checks
1685 platforms=`IFS=', '; echo $with_platforms`
1686 for plat in $platforms; do
1687         case "$plat" in
1688         wayland)
1689
1690                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1691                 ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1692                 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1693
1694                 if test "x$WAYLAND_SCANNER" = "x:"; then
1695                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1696                 fi
1697                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1698                 ;;
1699
1700         x11)
1701                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1702                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1703                 ;;
1704
1705         drm)
1706                 test "x$enable_gbm" = "xno" &&
1707                         AC_MSG_ERROR([EGL platform drm needs gbm])
1708                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1709                 ;;
1710
1711         surfaceless)
1712                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1713                 ;;
1714
1715         android)
1716                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1717                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1718                 ;;
1719
1720         *)
1721                 AC_MSG_ERROR([platform '$plat' does not exist])
1722                 ;;
1723         esac
1724
1725         case "$plat" in
1726         wayland|drm|surfaceless)
1727                 require_libdrm "Platform $plat"
1728                 ;;
1729         esac
1730 done
1731
1732 if test "x$enable_glx" != xno; then
1733     if ! echo "$platforms" | grep -q 'x11'; then
1734         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1735     fi
1736 fi
1737
1738 if test x"$enable_dri3" = xyes; then
1739     DEFINES="$DEFINES -DHAVE_DRI3"
1740
1741     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1742     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1743 fi
1744
1745 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1746 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1747 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1748 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1749 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1750
1751 dnl
1752 dnl More DRI setup
1753 dnl
1754 dnl Directory for DRI drivers
1755 AC_ARG_WITH([dri-driverdir],
1756     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1757         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1758     [DRI_DRIVER_INSTALL_DIR="$withval"],
1759     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1760 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1761 dnl Extra search path for DRI drivers
1762 AC_ARG_WITH([dri-searchpath],
1763     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1764         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1765     [DRI_DRIVER_SEARCH_DIR="$withval"],
1766     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1767 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1768 dnl Which drivers to build - default is chosen by platform
1769 AC_ARG_WITH([dri-drivers],
1770     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1771         [comma delimited classic DRI drivers list, e.g.
1772         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1773     [with_dri_drivers="$withval"],
1774     [with_dri_drivers=auto])
1775
1776 if test "x$with_dri_drivers" = xauto; then
1777     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1778         with_dri_drivers="yes"
1779     else
1780         with_dri_drivers="no"
1781     fi
1782 fi
1783 if test "x$with_dri_drivers" = xno; then
1784     with_dri_drivers=''
1785 fi
1786
1787 dnl If $with_dri_drivers is yes, drivers will be added through
1788 dnl platform checks. Set DEFINES and LIB_DEPS
1789 if test "x$enable_dri" = xyes; then
1790     # Platform specific settings and drivers to build
1791     case "$host_os" in
1792     linux*)
1793         case "$host_cpu" in
1794         powerpc* | sparc*)
1795             # Build only the drivers for cards that exist on PowerPC/sparc
1796             if test "x$with_dri_drivers" = "xyes"; then
1797                 with_dri_drivers="r200 radeon swrast"
1798             fi
1799             ;;
1800         esac
1801         ;;
1802     cygwin*)
1803         if test "x$with_dri_drivers" = "xyes"; then
1804             with_dri_drivers="swrast"
1805         fi
1806         ;;
1807     darwin*)
1808         DEFINES="$DEFINES -DBUILDING_MESA"
1809         if test "x$with_dri_drivers" = "xyes"; then
1810             with_dri_drivers="swrast"
1811         fi
1812         ;;
1813     esac
1814
1815     # default drivers
1816     if test "x$with_dri_drivers" = "xyes"; then
1817         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1818     fi
1819
1820     # Check for expat
1821     PKG_CHECK_MODULES([EXPAT], [expat], [],
1822         # expat version 2.0 and earlier do not provide expat.pc
1823         [AC_CHECK_HEADER([expat.h],[],
1824                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1825          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1826                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1827          EXPAT_LIBS="-lexpat"])
1828
1829     # put all the necessary libs together
1830     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1831 fi
1832
1833 AC_SUBST([DRI_LIB_DEPS])
1834
1835 DRI_DIRS=''
1836 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1837 if test -n "$with_dri_drivers"; then
1838     if test "x$enable_opengl" != xyes; then
1839         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1840     fi
1841
1842     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1843     for driver in $dri_drivers; do
1844         DRI_DIRS="$DRI_DIRS $driver"
1845         case "x$driver" in
1846         xi915)
1847             require_libdrm "i915"
1848             HAVE_I915_DRI=yes
1849             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1850             ;;
1851         xi965)
1852             require_libdrm "i965"
1853             HAVE_I965_DRI=yes
1854             ;;
1855         xnouveau)
1856             require_libdrm "nouveau"
1857             HAVE_NOUVEAU_DRI=yes
1858             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1859             ;;
1860         xradeon)
1861             require_libdrm "radeon"
1862             HAVE_RADEON_DRI=yes;
1863             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1864             ;;
1865         xr200)
1866             require_libdrm "r200"
1867             HAVE_R200_DRI=yes
1868             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1869             ;;
1870         xswrast)
1871             HAVE_SWRAST_DRI=yes
1872             ;;
1873         *)
1874             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1875             ;;
1876         esac
1877     done
1878     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1879 fi
1880
1881
1882 dnl
1883 dnl Gallium LLVM
1884 dnl Deprecated: kept for backwards compatibility
1885 dnl
1886 AC_ARG_ENABLE([gallium-llvm],
1887     [AS_HELP_STRING([--enable-gallium-llvm],
1888         [DEPRECATED: use --enable-llvm instead])],
1889     [enable_gallium_llvm="$enableval"],
1890     [enable_gallium_llvm=auto])
1891
1892 if test "x$enable_gallium_llvm" != xauto; then
1893    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1894    enable_llvm=$enable_gallium_llvm
1895 fi
1896
1897 dnl
1898 dnl LLVM
1899 dnl
1900 AC_ARG_ENABLE([llvm],
1901     [AS_HELP_STRING([--enable-llvm],
1902         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1903     [enable_llvm="$enableval"],
1904     [enable_llvm=auto])
1905
1906 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1907     if test "x$FOUND_LLVM" = xyes; then
1908         case "$host_cpu" in
1909         i*86|x86_64|amd64) enable_llvm=yes;;
1910         *) enable_llvm=no;;
1911         esac
1912     else
1913         enable_llvm=no
1914     fi
1915 fi
1916
1917 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1918     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1919 fi
1920
1921 #
1922 # Vulkan driver configuration
1923 #
1924
1925 AC_ARG_WITH([vulkan-drivers],
1926     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1927         [comma delimited Vulkan drivers list, e.g.
1928         "intel,radeon"
1929         @<:@default=no@:>@])],
1930     [with_vulkan_drivers="$withval"],
1931     [with_vulkan_drivers="no"])
1932
1933 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1934 # here so that the script doesn't choke on an unknown driver name later.
1935 case "x$with_vulkan_drivers" in
1936     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1937     xno) with_vulkan_drivers='' ;;
1938 esac
1939
1940 AC_ARG_WITH([vulkan-icddir],
1941     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1942         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1943     [VULKAN_ICD_INSTALL_DIR="$withval"],
1944     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1945 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1946
1947 require_x11_dri3() {
1948     if echo "$platforms" | grep -q 'x11'; then
1949         if test "x$enable_dri3" != xyes; then
1950             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1951         fi
1952     fi
1953 }
1954
1955 if test -n "$with_vulkan_drivers"; then
1956     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1957         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1958     fi
1959
1960     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1961     for driver in $VULKAN_DRIVERS; do
1962         case "x$driver" in
1963         xintel)
1964             require_libdrm "ANV"
1965             require_x11_dri3 "ANV"
1966             HAVE_INTEL_VULKAN=yes
1967             ;;
1968         xradeon)
1969             require_libdrm "radv"
1970             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1971             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1972             require_x11_dri3 "radv"
1973             HAVE_RADEON_VULKAN=yes
1974             ;;
1975         *)
1976             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1977             ;;
1978         esac
1979     done
1980     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1981 fi
1982
1983
1984 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1985 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1986 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1987                                   "x$enable_osmesa" = xyes -o \
1988                                   -n "$DRI_DIRS")
1989
1990 dnl
1991 dnl OSMesa configuration
1992 dnl
1993
1994 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1995 AC_ARG_WITH([osmesa-bits],
1996     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1997         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1998     [osmesa_bits="$withval"],
1999     [osmesa_bits=8])
2000 if test "x$osmesa_bits" != x8; then
2001     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2002         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2003         osmesa_bits=8
2004     fi
2005 fi
2006 case "x$osmesa_bits" in
2007 x8)
2008     OSMESA_LIB="${OSMESA_LIB}"
2009     ;;
2010 x16|x32)
2011     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2012     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2013     ;;
2014 *)
2015     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2016     ;;
2017 esac
2018
2019 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2020     # only link libraries with osmesa if shared
2021     if test "$enable_static" = no; then
2022         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2023     else
2024         OSMESA_LIB_DEPS=""
2025     fi
2026     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2027 fi
2028
2029 AC_SUBST([OSMESA_LIB_DEPS])
2030 AC_SUBST([OSMESA_PC_REQ])
2031 AC_SUBST([OSMESA_PC_LIB_PRIV])
2032
2033 dnl
2034 dnl gbm configuration
2035 dnl
2036 if test "x$enable_gbm" = xyes; then
2037     require_dri_shared_libs_and_glapi "gbm"
2038 fi
2039 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2040 # FINISHME: GBM has a number of dependencies which we should add below
2041 GBM_PC_REQ_PRIV=""
2042 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2043 AC_SUBST([GBM_PC_REQ_PRIV])
2044 AC_SUBST([GBM_PC_LIB_PRIV])
2045
2046 dnl
2047 dnl EGL configuration
2048 dnl
2049
2050 if test "x$enable_egl" = xyes; then
2051     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2052
2053     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2054
2055     require_dri_shared_libs_and_glapi "egl"
2056 fi
2057 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2058 AC_SUBST([EGL_LIB_DEPS])
2059
2060 gallium_st="mesa"
2061
2062 dnl
2063 dnl XA configuration
2064 dnl
2065 if test "x$enable_xa" = xyes; then
2066     if test "x$with_gallium_drivers" = xswrast; then
2067        AC_MSG_ERROR([
2068           Building xa requires at least one non swrast gallium driver.
2069           If you are looking to use libxatracker.so with the VMware driver,
2070           make sure to include svga in the gallium drivers list, apart from
2071           enabling XA.
2072           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2073     fi
2074     gallium_st="$gallium_st xa"
2075 fi
2076 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2077
2078 if echo $platforms | grep -q "x11"; then
2079     have_xvmc_platform=yes
2080 else
2081     have_xvmc_platform=no
2082 fi
2083
2084 if echo $platforms | grep -q "x11"; then
2085     have_vdpau_platform=yes
2086 else
2087     have_vdpau_platform=no
2088 fi
2089
2090 if echo $platforms | grep -q "x11\|drm"; then
2091     have_omx_platform=yes
2092 else
2093     have_omx_platform=no
2094 fi
2095
2096 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2097     have_va_platform=yes
2098 else
2099     have_va_platform=no
2100 fi
2101
2102 dnl
2103 dnl Gallium G3DVL configuration
2104 dnl
2105 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2106     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2107         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2108     fi
2109
2110     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2111         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2112     fi
2113
2114     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2115         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2116     fi
2117
2118     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2119         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2120     fi
2121 fi
2122
2123 if test "x$enable_dri" = xyes -o \
2124         "x$enable_xvmc" = xyes -o \
2125         "x$enable_vdpau" = xyes -o \
2126         "x$enable_omx" = xyes -o \
2127         "x$enable_va" = xyes; then
2128     need_gallium_vl=yes
2129 fi
2130 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2131
2132 if test "x$enable_xvmc" = xyes -o \
2133         "x$enable_vdpau" = xyes -o \
2134         "x$enable_omx" = xyes -o \
2135         "x$enable_va" = xyes; then
2136     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2137     need_gallium_vl_winsys=yes
2138 fi
2139 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2140
2141 if test "x$enable_xvmc" = xyes; then
2142     if test "x$have_xvmc_platform" != xyes; then
2143         AC_MSG_ERROR([XVMC requires the x11 platforms])
2144     fi
2145     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2146     gallium_st="$gallium_st xvmc"
2147 fi
2148 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2149
2150 if test "x$enable_vdpau" = xyes; then
2151     if test "x$have_vdpau_platform" != xyes; then
2152         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2153     fi
2154     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2155     gallium_st="$gallium_st vdpau"
2156     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2157 fi
2158 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2159
2160 if test "x$enable_omx" = xyes; then
2161     if test "x$have_omx_platform" != xyes; then
2162         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2163     fi
2164     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2165     gallium_st="$gallium_st omx"
2166 fi
2167 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2168
2169 if test "x$enable_va" = xyes; then
2170     if test "x$have_va_platform" != xyes; then
2171         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2172     fi
2173     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2174     gallium_st="$gallium_st va"
2175 fi
2176 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2177
2178 dnl
2179 dnl Nine Direct3D9 configuration
2180 dnl
2181 if test "x$enable_nine" = xyes; then
2182     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2183         AC_MSG_ERROR([nine requires the gallium swrast driver])
2184     fi
2185     if test "x$with_gallium_drivers" = xswrast; then
2186         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2187     fi
2188     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2189         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2190     fi
2191
2192     if test "x$enable_dri3" = xno; then
2193         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2194     fi
2195
2196     gallium_st="$gallium_st nine"
2197 fi
2198 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2199
2200 dnl
2201 dnl OpenCL configuration
2202 dnl
2203
2204 AC_ARG_WITH([clang-libdir],
2205    [AS_HELP_STRING([--with-clang-libdir],
2206          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2207    [CLANG_LIBDIR="$withval"],
2208    [CLANG_LIBDIR=''])
2209
2210 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2211
2212 if test "x$enable_opencl" = xyes; then
2213     if test -z "$with_gallium_drivers"; then
2214         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2215     fi
2216
2217     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2218         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2219     fi
2220
2221     if test "x$have_libclc" = xno; then
2222         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2223                     Make sure the directory containing libclc.pc is specified in your
2224                     PKG_CONFIG_PATH environment variable.
2225                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2226     else
2227         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2228         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2229         AC_SUBST([LIBCLC_INCLUDEDIR])
2230         AC_SUBST([LIBCLC_LIBEXECDIR])
2231     fi
2232
2233     gallium_st="$gallium_st clover"
2234
2235     if test "x$enable_opencl_icd" = xyes; then
2236         OPENCL_LIBNAME="MesaOpenCL"
2237     else
2238         OPENCL_LIBNAME="OpenCL"
2239     fi
2240
2241     if test "x$have_libelf" != xyes; then
2242        AC_MSG_ERROR([Clover requires libelf])
2243     fi
2244
2245     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2246         altivec_enabled=no
2247         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2248         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2249         #error "AltiVec not enabled"
2250         #endif
2251         ])], altivec_enabled=yes)
2252
2253         if test "$altivec_enabled" = yes; then
2254             CLOVER_STD_OVERRIDE="-std=gnu++11"
2255         fi
2256         AC_SUBST([CLOVER_STD_OVERRIDE])
2257     fi
2258
2259     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2260
2261     llvm_add_default_components "opencl"
2262     llvm_add_component "all-targets" "opencl"
2263     llvm_add_component "linker" "opencl"
2264     llvm_add_component "instrumentation" "opencl"
2265     llvm_add_component "ipo" "opencl"
2266     llvm_add_component "irreader" "opencl"
2267     llvm_add_component "option" "opencl"
2268     llvm_add_component "objcarcopts" "opencl"
2269     llvm_add_component "profiledata" "opencl"
2270
2271     dnl Check for Clang internal headers
2272     if test -z "$CLANG_LIBDIR"; then
2273         CLANG_LIBDIR=${LLVM_LIBDIR}
2274     fi
2275     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2276     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2277         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2278 fi
2279 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2280 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2281 AC_SUBST([OPENCL_LIBNAME])
2282 AC_SUBST([CLANG_RESOURCE_DIR])
2283
2284 dnl
2285 dnl Gallium configuration
2286 dnl
2287 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2288
2289 # libEGL wants to default to the first platform specified in
2290 # ./configure.  parse that here.
2291 if test "x$platforms" != "x"; then
2292     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2293     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2294 else
2295     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2296 fi
2297
2298 AC_SUBST([EGL_NATIVE_PLATFORM])
2299 AC_SUBST([EGL_CFLAGS])
2300
2301 # If we don't have the X11 platform, set this define so we don't try to include
2302 # the X11 headers.
2303 if ! echo "$platforms" | grep -q 'x11'; then
2304     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2305     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2306 fi
2307
2308 dnl Directory for XVMC libs
2309 AC_ARG_WITH([xvmc-libdir],
2310     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2311         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2312     [XVMC_LIB_INSTALL_DIR="$withval"],
2313     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2314 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2315
2316 dnl
2317 dnl Gallium Tests
2318 dnl
2319 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2320
2321 dnl Directory for VDPAU libs
2322 AC_ARG_WITH([vdpau-libdir],
2323     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2324         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2325     [VDPAU_LIB_INSTALL_DIR="$withval"],
2326     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2327 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2328
2329 dnl Directory for OMX libs
2330
2331 AC_ARG_WITH([omx-libdir],
2332     [AS_HELP_STRING([--with-omx-libdir=DIR],
2333         [directory for the OMX libraries])],
2334     [OMX_LIB_INSTALL_DIR="$withval"],
2335     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2336                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2337 AC_SUBST([OMX_LIB_INSTALL_DIR])
2338
2339 dnl Directory for VA libs
2340
2341 AC_ARG_WITH([va-libdir],
2342     [AS_HELP_STRING([--with-va-libdir=DIR],
2343         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2344     [VA_LIB_INSTALL_DIR="$withval"],
2345     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2346 AC_SUBST([VA_LIB_INSTALL_DIR])
2347
2348 AC_ARG_WITH([d3d-libdir],
2349     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2350         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2351     [D3D_DRIVER_INSTALL_DIR="$withval"],
2352     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2353 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2354
2355 dnl
2356 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2357 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2358 dnl architectures.
2359 dnl
2360 r300_require_llvm() {
2361     case "$host" in *gnux32) return;; esac
2362     case "$host_cpu" in
2363     i*86|x86_64|amd64) require_llvm $1
2364         ;;
2365     esac
2366 }
2367
2368 dnl
2369 dnl DRM is needed by X, Wayland, and offscreen rendering.
2370 dnl Surfaceless is an alternative for the last one.
2371 dnl
2372 require_basic_egl() {
2373     case "$with_platforms" in
2374         *drm*|*surfaceless*)
2375             ;;
2376         *)
2377             AC_MSG_ERROR([$1 requires one of these:
2378                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2379                   2) --with-platforms=surfaceless (offscreen only)
2380                   Recommended options: drm,x11])
2381             ;;
2382     esac
2383 }
2384
2385 swr_require_cxx_feature_flags() {
2386     feature_name="$1"
2387     preprocessor_test="$2"
2388     option_list="$3"
2389     output_var="$4"
2390
2391     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2392     AC_LANG_PUSH([C++])
2393     save_CXXFLAGS="$CXXFLAGS"
2394     save_IFS="$IFS"
2395     IFS=","
2396     found=0
2397     for opts in $option_list
2398     do
2399         unset IFS
2400         CXXFLAGS="$opts $save_CXXFLAGS"
2401         AC_COMPILE_IFELSE(
2402             [AC_LANG_PROGRAM(
2403                 [   #if !($preprocessor_test)
2404                     #error
2405                     #endif
2406                 ])],
2407             [found=1; break],
2408             [])
2409         IFS=","
2410     done
2411     IFS="$save_IFS"
2412     CXXFLAGS="$save_CXXFLAGS"
2413     AC_LANG_POP([C++])
2414     if test $found -eq 1; then
2415         AC_MSG_RESULT([$opts])
2416         eval "$output_var=\$opts"
2417         return 0
2418     fi
2419     AC_MSG_RESULT([no])
2420     AC_MSG_ERROR([swr requires $feature_name support])
2421     return 1
2422 }
2423
2424 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2425 if test -n "$with_gallium_drivers"; then
2426     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2427     for driver in $gallium_drivers; do
2428         case "x$driver" in
2429         xsvga)
2430             HAVE_GALLIUM_SVGA=yes
2431             require_libdrm "svga"
2432             ;;
2433         xi915)
2434             HAVE_GALLIUM_I915=yes
2435             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2436             require_libdrm "Gallium i915"
2437             ;;
2438         xr300)
2439             HAVE_GALLIUM_R300=yes
2440             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2441             require_libdrm "r300"
2442             r300_require_llvm "r300"
2443             ;;
2444         xr600)
2445             HAVE_GALLIUM_R600=yes
2446             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2447             require_libdrm "r600"
2448             if test "x$enable_llvm" = xyes; then
2449                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2450
2451                 llvm_add_component "asmparser" "r600"
2452                 llvm_add_component "bitreader" "r600"
2453             fi
2454             ;;
2455         xradeonsi)
2456             HAVE_GALLIUM_RADEONSI=yes
2457             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2458             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2459             require_libdrm "radeonsi"
2460             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2461             if test "x$enable_egl" = xyes; then
2462                 require_basic_egl "radeonsi"
2463             fi
2464             ;;
2465         xnouveau)
2466             HAVE_GALLIUM_NOUVEAU=yes
2467             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2468             require_libdrm "nouveau"
2469             ;;
2470         xfreedreno)
2471             HAVE_GALLIUM_FREEDRENO=yes
2472             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2473             require_libdrm "freedreno"
2474             ;;
2475         xetnaviv)
2476             HAVE_GALLIUM_ETNAVIV=yes
2477             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2478             require_libdrm "etnaviv"
2479             ;;
2480        ximx)
2481             HAVE_GALLIUM_IMX=yes
2482             ;;
2483         xswrast)
2484             HAVE_GALLIUM_SOFTPIPE=yes
2485             if test "x$enable_llvm" = xyes; then
2486                 HAVE_GALLIUM_LLVMPIPE=yes
2487             fi
2488             ;;
2489         xswr)
2490             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2491
2492             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2493                 ",-std=c++11" \
2494                 SWR_CXX11_CXXFLAGS
2495             AC_SUBST([SWR_CXX11_CXXFLAGS])
2496
2497             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2498                 ",-mavx,-march=core-avx" \
2499                 SWR_AVX_CXXFLAGS
2500             AC_SUBST([SWR_AVX_CXXFLAGS])
2501
2502             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2503                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2504                 SWR_AVX2_CXXFLAGS
2505             AC_SUBST([SWR_AVX2_CXXFLAGS])
2506
2507             HAVE_GALLIUM_SWR=yes
2508             ;;
2509         xvc4)
2510             HAVE_GALLIUM_VC4=yes
2511             require_libdrm "vc4"
2512
2513             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2514                               [USE_VC4_SIMULATOR=yes;
2515                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2516                               [USE_VC4_SIMULATOR=no])
2517             ;;
2518         xpl111)
2519             HAVE_GALLIUM_PL111=yes
2520             ;;
2521         xvirgl)
2522             HAVE_GALLIUM_VIRGL=yes
2523             require_libdrm "virgl"
2524             if test "x$enable_egl" = xyes; then
2525                 require_basic_egl "virgl"
2526             fi
2527             ;;
2528         *)
2529             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2530             ;;
2531         esac
2532     done
2533 fi
2534
2535 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2536 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2537                                               "x$LLVM_VERSION" != x3.9.1)
2538
2539 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2540     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2541     llvm_add_default_components "gallium"
2542 fi
2543
2544 dnl We need to validate some needed dependencies for renderonly drivers.
2545
2546 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2547     AC_MSG_ERROR([Building with imx requires etnaviv])
2548 fi
2549
2550 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2551     AC_MSG_ERROR([Building with pl111 requires vc4])
2552 fi
2553
2554 dnl
2555 dnl Set defines and buildtime variables only when using LLVM.
2556 dnl
2557 if test "x$enable_llvm" = xyes; then
2558     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2559
2560     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2561     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2562     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2563
2564     dnl Set LLVM_LIBS - This is done after the driver configuration so
2565     dnl that drivers can add additional components to LLVM_COMPONENTS.
2566     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2567     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2568     dnl this was causing the same libraries to be appear multiple times
2569     dnl in LLVM_LIBS.
2570
2571     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2572        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2573     fi
2574     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2575
2576     dnl llvm-config may not give the right answer when llvm is a built as a
2577     dnl single shared library, so we must work the library name out for
2578     dnl ourselves.
2579     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2580     if test "x$enable_llvm_shared_libs" = xyes; then
2581         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2582         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2583         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2584
2585         if test "x$llvm_have_one_so" = xyes; then
2586             dnl LLVM was built using auto*, so there is only one shared object.
2587             LLVM_LIBS="-l$LLVM_SO_NAME"
2588         else
2589             dnl If LLVM was built with CMake, there will be one shared object per
2590             dnl component.
2591             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2592                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2593         Please make sure you have built llvm with the --enable-shared option
2594         and that your llvm libraries are installed in $LLVM_LIBDIR
2595         If you have installed your llvm libraries to a different directory you
2596         can use the --with-llvm-prefix= configure flag to specify this directory.
2597         NOTE: Mesa is attempting to use llvm shared libraries by default.
2598         If you do not want to build with llvm shared libraries and instead want to
2599         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2600         invocation and rebuild.])])
2601
2602            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2603            dnl install uses a shared object for each component and we have
2604            dnl already added all of these objects to LLVM_LIBS.
2605         fi
2606     else
2607         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2608         dnl We need to link to llvm system libs when using static libs
2609         dnl However, only llvm 3.5+ provides --system-libs
2610         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2611             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2612         fi
2613     fi
2614 fi
2615
2616 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2617 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2623                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2625 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2627 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2628 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2629 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2630 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2631 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2632                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2633                                          "x$HAVE_GALLIUM_SWR" = xyes)
2634 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2635 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2636
2637 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2638
2639 if test "x$enable_dri" = xyes; then
2640     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2641 fi
2642
2643 if test "x$have_drisw_kms" = xyes; then
2644     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2645 fi
2646 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2647
2648 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2649 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2650 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2651 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2652 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2653 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2654
2655 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2656 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2657
2658 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2659                                       "x$HAVE_RADEON_VULKAN" = xyes)
2660
2661 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2662                                         "x$HAVE_I965_DRI" = xyes)
2663
2664 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2665                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2666                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2667 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2668 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2669 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2670 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2671
2672 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2673 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2674 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2675 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2676                                         "x$enable_gallium_osmesa" = xyes)
2677
2678 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2679 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2680 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2681 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2682
2683 AC_SUBST([NINE_MAJOR], 1)
2684 AC_SUBST([NINE_MINOR], 0)
2685 AC_SUBST([NINE_TINY], 0)
2686 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2687
2688 AC_SUBST([VDPAU_MAJOR], 1)
2689 AC_SUBST([VDPAU_MINOR], 0)
2690
2691 if test "x$enable_va" = xyes; then
2692     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2693     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2694 fi
2695 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2696 AC_SUBST([VA_MINOR], $VA_MINOR)
2697
2698 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2699
2700 AC_SUBST([XVMC_MAJOR], 1)
2701 AC_SUBST([XVMC_MINOR], 0)
2702
2703 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2704 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2705 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2706 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2707
2708 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2709 AC_SUBST([XA_MINOR], $XA_MINOR)
2710 AC_SUBST([XA_TINY], $XA_TINY)
2711 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2712
2713 AC_ARG_ENABLE(valgrind,
2714               [AS_HELP_STRING([--enable-valgrind],
2715                              [Build mesa with valgrind support (default: auto)])],
2716                              [VALGRIND=$enableval], [VALGRIND=auto])
2717 if test "x$VALGRIND" != xno; then
2718         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2719 fi
2720 AC_MSG_CHECKING([whether to enable Valgrind support])
2721 if test "x$VALGRIND" = xauto; then
2722         VALGRIND="$have_valgrind"
2723 fi
2724
2725 if test "x$VALGRIND" = "xyes"; then
2726         if ! test "x$have_valgrind" = xyes; then
2727                 AC_MSG_ERROR([Valgrind support required but not present])
2728         fi
2729         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2730 fi
2731
2732 AC_MSG_RESULT([$VALGRIND])
2733
2734 dnl Restore LDFLAGS and CPPFLAGS
2735 LDFLAGS="$_SAVE_LDFLAGS"
2736 CPPFLAGS="$_SAVE_CPPFLAGS"
2737
2738 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2739 if test "x$acv_mesa_CLANG" = xyes; then
2740     CFLAGS="$CFLAGS -Qunused-arguments"
2741     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2742 fi
2743
2744 dnl Add user CFLAGS and CXXFLAGS
2745 CFLAGS="$CFLAGS $USER_CFLAGS"
2746 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2747
2748 dnl Substitute the config
2749 AC_CONFIG_FILES([Makefile
2750                 src/Makefile
2751                 src/amd/Makefile
2752                 src/amd/vulkan/Makefile
2753                 src/broadcom/Makefile
2754                 src/compiler/Makefile
2755                 src/egl/Makefile
2756                 src/egl/main/egl.pc
2757                 src/egl/wayland/wayland-drm/Makefile
2758                 src/egl/wayland/wayland-egl/Makefile
2759                 src/egl/wayland/wayland-egl/wayland-egl.pc
2760                 src/gallium/Makefile
2761                 src/gallium/auxiliary/Makefile
2762                 src/gallium/auxiliary/pipe-loader/Makefile
2763                 src/gallium/drivers/freedreno/Makefile
2764                 src/gallium/drivers/ddebug/Makefile
2765                 src/gallium/drivers/i915/Makefile
2766                 src/gallium/drivers/llvmpipe/Makefile
2767                 src/gallium/drivers/noop/Makefile
2768                 src/gallium/drivers/nouveau/Makefile
2769                 src/gallium/drivers/pl111/Makefile
2770                 src/gallium/drivers/r300/Makefile
2771                 src/gallium/drivers/r600/Makefile
2772                 src/gallium/drivers/radeon/Makefile
2773                 src/gallium/drivers/radeonsi/Makefile
2774                 src/gallium/drivers/rbug/Makefile
2775                 src/gallium/drivers/softpipe/Makefile
2776                 src/gallium/drivers/svga/Makefile
2777                 src/gallium/drivers/swr/Makefile
2778                 src/gallium/drivers/trace/Makefile
2779                 src/gallium/drivers/etnaviv/Makefile
2780                 src/gallium/drivers/imx/Makefile
2781                 src/gallium/drivers/vc4/Makefile
2782                 src/gallium/drivers/virgl/Makefile
2783                 src/gallium/state_trackers/clover/Makefile
2784                 src/gallium/state_trackers/dri/Makefile
2785                 src/gallium/state_trackers/glx/xlib/Makefile
2786                 src/gallium/state_trackers/nine/Makefile
2787                 src/gallium/state_trackers/omx/Makefile
2788                 src/gallium/state_trackers/osmesa/Makefile
2789                 src/gallium/state_trackers/va/Makefile
2790                 src/gallium/state_trackers/vdpau/Makefile
2791                 src/gallium/state_trackers/xa/Makefile
2792                 src/gallium/state_trackers/xvmc/Makefile
2793                 src/gallium/targets/d3dadapter9/Makefile
2794                 src/gallium/targets/d3dadapter9/d3d.pc
2795                 src/gallium/targets/dri/Makefile
2796                 src/gallium/targets/libgl-xlib/Makefile
2797                 src/gallium/targets/omx/Makefile
2798                 src/gallium/targets/opencl/Makefile
2799                 src/gallium/targets/opencl/mesa.icd
2800                 src/gallium/targets/osmesa/Makefile
2801                 src/gallium/targets/osmesa/osmesa.pc
2802                 src/gallium/targets/pipe-loader/Makefile
2803                 src/gallium/targets/va/Makefile
2804                 src/gallium/targets/vdpau/Makefile
2805                 src/gallium/targets/xa/Makefile
2806                 src/gallium/targets/xa/xatracker.pc
2807                 src/gallium/targets/xvmc/Makefile
2808                 src/gallium/tests/trivial/Makefile
2809                 src/gallium/tests/unit/Makefile
2810                 src/gallium/winsys/etnaviv/drm/Makefile
2811                 src/gallium/winsys/imx/drm/Makefile
2812                 src/gallium/winsys/freedreno/drm/Makefile
2813                 src/gallium/winsys/i915/drm/Makefile
2814                 src/gallium/winsys/nouveau/drm/Makefile
2815                 src/gallium/winsys/pl111/drm/Makefile
2816                 src/gallium/winsys/radeon/drm/Makefile
2817                 src/gallium/winsys/amdgpu/drm/Makefile
2818                 src/gallium/winsys/svga/drm/Makefile
2819                 src/gallium/winsys/sw/dri/Makefile
2820                 src/gallium/winsys/sw/kms-dri/Makefile
2821                 src/gallium/winsys/sw/null/Makefile
2822                 src/gallium/winsys/sw/wrapper/Makefile
2823                 src/gallium/winsys/sw/xlib/Makefile
2824                 src/gallium/winsys/vc4/drm/Makefile
2825                 src/gallium/winsys/virgl/drm/Makefile
2826                 src/gallium/winsys/virgl/vtest/Makefile
2827                 src/gbm/Makefile
2828                 src/gbm/main/gbm.pc
2829                 src/glx/Makefile
2830                 src/glx/apple/Makefile
2831                 src/glx/tests/Makefile
2832                 src/glx/windows/Makefile
2833                 src/glx/windows/windowsdriproto.pc
2834                 src/gtest/Makefile
2835                 src/intel/Makefile
2836                 src/loader/Makefile
2837                 src/mapi/Makefile
2838                 src/mapi/es1api/glesv1_cm.pc
2839                 src/mapi/es2api/glesv2.pc
2840                 src/mapi/glapi/gen/Makefile
2841                 src/mesa/Makefile
2842                 src/mesa/gl.pc
2843                 src/mesa/drivers/dri/dri.pc
2844                 src/mesa/drivers/dri/common/Makefile
2845                 src/mesa/drivers/dri/common/xmlpool/Makefile
2846                 src/mesa/drivers/dri/i915/Makefile
2847                 src/mesa/drivers/dri/i965/Makefile
2848                 src/mesa/drivers/dri/Makefile
2849                 src/mesa/drivers/dri/nouveau/Makefile
2850                 src/mesa/drivers/dri/r200/Makefile
2851                 src/mesa/drivers/dri/radeon/Makefile
2852                 src/mesa/drivers/dri/swrast/Makefile
2853                 src/mesa/drivers/osmesa/Makefile
2854                 src/mesa/drivers/osmesa/osmesa.pc
2855                 src/mesa/drivers/x11/Makefile
2856                 src/mesa/main/tests/Makefile
2857                 src/util/Makefile
2858                 src/util/tests/hash_table/Makefile
2859                 src/vulkan/Makefile])
2860
2861 AC_OUTPUT
2862
2863 # Fix up dependencies in *.Plo files, where we changed the extension of a
2864 # source file
2865 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2866
2867
2868 dnl
2869 dnl Output some configuration info for the user
2870 dnl
2871 echo ""
2872 echo "        prefix:          $prefix"
2873 echo "        exec_prefix:     $exec_prefix"
2874 echo "        libdir:          $libdir"
2875 echo "        includedir:      $includedir"
2876
2877 dnl API info
2878 echo ""
2879 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2880
2881 dnl Driver info
2882 echo ""
2883 case "x$enable_osmesa$enable_gallium_osmesa" in
2884 xnoyes)
2885         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2886         ;;
2887 xyesno)
2888         echo "        OSMesa:          lib$OSMESA_LIB"
2889         ;;
2890 xnono)
2891         echo "        OSMesa:          no"
2892         ;;
2893 esac
2894
2895 echo ""
2896 if test "x$enable_dri" != xno; then
2897         echo "        DRI platform:    $dri_platform"
2898         if test -z "$DRI_DIRS"; then
2899             echo "        DRI drivers:     no"
2900         else
2901             echo "        DRI drivers:     $DRI_DIRS"
2902         fi
2903         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2904 fi
2905
2906 case "x$enable_glx" in
2907 xdri)
2908     echo "        GLX:             DRI-based"
2909     ;;
2910 xxlib)
2911     echo "        GLX:             Xlib-based"
2912     ;;
2913 xgallium-xlib)
2914     echo "        GLX:             Xlib-based (Gallium)"
2915     ;;
2916 *)
2917     echo "        GLX:             $enable_glx"
2918     ;;
2919 esac
2920
2921 dnl EGL
2922 echo ""
2923 echo "        EGL:             $enable_egl"
2924 if test "$enable_egl" = yes; then
2925
2926     egl_drivers=""
2927     if test "x$enable_dri" != "xno"; then
2928         egl_drivers="$egl_drivers builtin:egl_dri2"
2929     fi
2930     if test "x$enable_dri3" != "xno"; then
2931         egl_drivers="$egl_drivers builtin:egl_dri3"
2932     fi
2933
2934     echo "        EGL drivers:    $egl_drivers"
2935 fi
2936 if test "x$enable_gbm" = xyes; then
2937     echo "        GBM:             yes"
2938 else
2939     echo "        GBM:             no"
2940 fi
2941
2942     echo "        EGL/Vulkan/VL platforms:   $platforms"
2943
2944 # Vulkan
2945 echo ""
2946 if test "x$VULKAN_DRIVERS" != x; then
2947     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2948     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2949 else
2950     echo "        Vulkan drivers:  no"
2951 fi
2952
2953 echo ""
2954 if test "x$enable_llvm" = xyes; then
2955     echo "        llvm:            yes"
2956     echo "        llvm-config:     $LLVM_CONFIG"
2957     echo "        llvm-version:    $LLVM_VERSION"
2958 else
2959     echo "        llvm:            no"
2960 fi
2961
2962 echo ""
2963 if test -n "$with_gallium_drivers"; then
2964     echo "        Gallium drivers: $gallium_drivers"
2965     echo "        Gallium st:      $gallium_st"
2966 else
2967     echo "        Gallium:         no"
2968 fi
2969
2970 echo ""
2971 if test "x$enable_gallium_extra_hud" != xyes; then
2972     echo "        HUD extra stats: no"
2973 else
2974     echo "        HUD extra stats: yes"
2975 fi
2976
2977 if test "x$enable_lmsensors" != xyes; then
2978     echo "        HUD lmsensors:   no"
2979 else
2980     echo "        HUD lmsensors:   yes"
2981 fi
2982
2983 dnl Libraries
2984 echo ""
2985 echo "        Shared libs:     $enable_shared"
2986 echo "        Static libs:     $enable_static"
2987 echo "        Shared-glapi:    $enable_shared_glapi"
2988
2989 dnl Compiler options
2990 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2991 cflags=`echo $CFLAGS | \
2992     $SED 's/^ *//;s/  */ /;s/ *$//'`
2993 cxxflags=`echo $CXXFLAGS | \
2994     $SED 's/^ *//;s/  */ /;s/ *$//'`
2995 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2996 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2997 echo ""
2998 echo "        CFLAGS:          $cflags"
2999 echo "        CXXFLAGS:        $cxxflags"
3000 echo "        LDFLAGS:         $ldflags"
3001 echo "        Macros:          $defines"
3002 echo ""
3003 if test "x$enable_llvm" = xyes; then
3004     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3005     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3006     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3007     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3008     echo ""
3009 fi
3010 echo "        PYTHON2:         $PYTHON2"
3011
3012 echo ""
3013 echo "        Run '${MAKE-make}' to build Mesa"
3014 echo ""