configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.68
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 LIBUDEV_REQUIRED=151
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.2.0
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.8.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112
 113 AX_PROG_BISON([],
 114               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 115                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 116 AX_PROG_FLEX([],
 117              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 118                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 119
 120 AC_CHECK_PROG(INDENT, indent, indent, cat)
 121 if test "x$INDENT" != "xcat"; then
 122     # Only GNU indent is supported
 123     INDENT_VERSION=`indent --version | grep GNU`
 124     if test $? -eq 0; then
 125        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 126     else
 127        INDENT="cat"
 128     fi
 129 fi
 130
 131 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 132
 133 if test -z "$PYTHON2"; then
 134     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 135         AC_MSG_ERROR([Python not found - unable to generate sources])
 136     fi
 137 else
 138     if test "x$acv_mako_found" = xno; then
 139         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 140             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 141         fi
 142     fi
 143 fi
 144
 145 AC_PROG_INSTALL
 146
 147 dnl We need a POSIX shell for parts of the build. Assume we have one
 148 dnl in most cases.
 149 case "$host_os" in
 150 solaris*)
 151     # Solaris /bin/sh is too old/non-POSIX compliant
 152     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 153     SHELL="$POSIX_SHELL"
 154     ;;
 155 esac
 156
 157 dnl clang is mostly GCC-compatible, but its version is much lower,
 158 dnl so we have to check for it.
 159 AC_MSG_CHECKING([if compiling with clang])
 160
 161 AC_COMPILE_IFELSE(
 162 [AC_LANG_PROGRAM([], [[
 163 #ifndef __clang__
 164        not clang
 165 #endif
 166 ]])],
 167 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 168
 169 AC_MSG_RESULT([$acv_mesa_CLANG])
 170
 171 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 172 dnl versions are explictly not supported.
 173 GEN_ASM_OFFSETS=no
 174 USE_GNU99=no
 175 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 176     AC_MSG_CHECKING([whether gcc version is sufficient])
 177     major=0
 178     minor=0
 179
 180     GCC_VERSION=`$CC -dumpversion`
 181     if test $? -eq 0; then
 182         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 183         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 184     fi
 185
 186     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 187         AC_MSG_RESULT([no])
 188         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 189     else
 190         AC_MSG_RESULT([yes])
 191     fi
 192
 193     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 194         USE_GNU99=yes
 195     fi
 196     if test "x$cross_compiling" = xyes; then
 197         GEN_ASM_OFFSETS=yes
 198     fi
 199 fi
 200
 201 dnl We don't support building Mesa with Sun C compiler
 202 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 203 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 204 if test "x$SUNCC" = xyes; then
 205     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 206 fi
 207
 208 dnl Check for compiler builtins
 209 AX_GCC_BUILTIN([__builtin_bswap32])
 210 AX_GCC_BUILTIN([__builtin_bswap64])
 211 AX_GCC_BUILTIN([__builtin_clz])
 212 AX_GCC_BUILTIN([__builtin_clzll])
 213 AX_GCC_BUILTIN([__builtin_ctz])
 214 AX_GCC_BUILTIN([__builtin_expect])
 215 AX_GCC_BUILTIN([__builtin_ffs])
 216 AX_GCC_BUILTIN([__builtin_ffsll])
 217 AX_GCC_BUILTIN([__builtin_popcount])
 218 AX_GCC_BUILTIN([__builtin_popcountll])
 219 AX_GCC_BUILTIN([__builtin_unreachable])
 220
 221 AX_GCC_FUNC_ATTRIBUTE([const])
 222 AX_GCC_FUNC_ATTRIBUTE([flatten])
 223 AX_GCC_FUNC_ATTRIBUTE([format])
 224 AX_GCC_FUNC_ATTRIBUTE([malloc])
 225 AX_GCC_FUNC_ATTRIBUTE([packed])
 226 AX_GCC_FUNC_ATTRIBUTE([pure])
 227 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 228 AX_GCC_FUNC_ATTRIBUTE([unused])
 229 AX_GCC_FUNC_ATTRIBUTE([visibility])
 230 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 231 AX_GCC_FUNC_ATTRIBUTE([weak])
 232
 233 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 234
 235 dnl Make sure the pkg-config macros are defined
 236 m4_ifndef([PKG_PROG_PKG_CONFIG],
 237     [m4_fatal([Could not locate the pkg-config autoconf macros.
 238   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 239   are in a different location, try setting the environment variable
 240   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 241 PKG_PROG_PKG_CONFIG()
 242
 243 dnl LIB_DIR - library basename
 244 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 245 AC_SUBST([LIB_DIR])
 246
 247 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 248 _SAVE_LDFLAGS="$LDFLAGS"
 249 _SAVE_CPPFLAGS="$CPPFLAGS"
 250
 251 dnl Compiler macros
 252 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 253 AC_SUBST([DEFINES])
 254 android=no
 255 case "$host_os" in
 256 *-android)
 257     android=yes
 258     ;;
 259 linux*|*-gnu*|gnu*|cygwin*)
 260     DEFINES="$DEFINES -D_GNU_SOURCE"
 261     ;;
 262 solaris*)
 263     DEFINES="$DEFINES -DSVR4"
 264     ;;
 265 esac
 266
 267 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 268
 269 dnl Add flags for gcc and g++
 270 if test "x$GCC" = xyes; then
 271     CFLAGS="$CFLAGS -Wall"
 272
 273     if test "x$USE_GNU99" = xyes; then
 274         CFLAGS="$CFLAGS -std=gnu99"
 275     else
 276         CFLAGS="$CFLAGS -std=c99"
 277     fi
 278
 279     # Enable -Werror=implicit-function-declaration and
 280     # -Werror=missing-prototypes, if available, or otherwise, just
 281     # -Wmissing-prototypes.  This is particularly useful to avoid
 282     # generating a loadable driver module that has undefined symbols.
 283     save_CFLAGS="$CFLAGS"
 284     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 285     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 286     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 287     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 288                    AC_MSG_RESULT([yes]),
 289                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 290                     AC_MSG_RESULT([no])]);
 291
 292     # Enable -fvisibility=hidden if using a gcc that supports it
 293     save_CFLAGS="$CFLAGS"
 294     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 295     VISIBILITY_CFLAGS="-fvisibility=hidden"
 296     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 297     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 298                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 299
 300     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 301     CFLAGS=$save_CFLAGS
 302
 303     # We don't want floating-point math functions to set errno or trap
 304     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 305
 306     # Flags to help ensure that certain portions of the code -- and only those
 307     # portions -- can be built with MSVC:
 308     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 309     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 310     #   supports most of C99)
 311     # - the rest has no compiler compiler restrictions
 312     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 313     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 314
 315     # Enable -Werror=vla if compiler supports it
 316     save_CFLAGS="$CFLAGS"
 317     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 318     CFLAGS="$CFLAGS -Werror=vla"
 319     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 320                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 321                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 322                     AC_MSG_RESULT([yes])],
 323                     AC_MSG_RESULT([no]));
 324     CFLAGS="$save_CFLAGS"
 325 fi
 326 if test "x$GXX" = xyes; then
 327     CXXFLAGS="$CXXFLAGS -Wall"
 328
 329     # Enable -fvisibility=hidden if using a gcc that supports it
 330     save_CXXFLAGS="$CXXFLAGS"
 331     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 332     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 333     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 334     AC_LANG_PUSH([C++])
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 336                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 337     AC_LANG_POP([C++])
 338
 339     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 340     CXXFLAGS=$save_CXXFLAGS
 341
 342     # We don't want floating-point math functions to set errno or trap
 343     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 344 fi
 345
 346 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 347 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 348
 349 dnl even if the compiler appears to support it, using visibility attributes isn't
 350 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 351 case "$host_os" in
 352 cygwin*)
 353     VISIBILITY_CFLAGS=""
 354     VISIBILITY_CXXFLAGS=""
 355     ;;
 356 esac
 357
 358 AC_SUBST([VISIBILITY_CFLAGS])
 359 AC_SUBST([VISIBILITY_CXXFLAGS])
 360
 361 dnl
 362 dnl Optional flags, check for compiler support
 363 dnl
 364 SSE41_CFLAGS="-msse4.1"
 365 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 366 dnl stack, but on x86-32 such alignment is not guaranteed.
 367 case "$target_cpu" in
 368 i?86)
 369     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 370     ;;
 371 esac
 372 save_CFLAGS="$CFLAGS"
 373 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 374 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 375 #include <smmintrin.h>
 376 int param;
 377 int main () {
 378     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 379     c = _mm_max_epu32(a, b);
 380     return _mm_cvtsi128_si32(c);
 381 }]])], SSE41_SUPPORTED=1)
 382 CFLAGS="$save_CFLAGS"
 383 if test "x$SSE41_SUPPORTED" = x1; then
 384     DEFINES="$DEFINES -DUSE_SSE41"
 385 fi
 386 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 387 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 388
 389 dnl Check for Endianness
 390 AC_C_BIGENDIAN(
 391    little_endian=no,
 392    little_endian=yes,
 393    little_endian=no,
 394    little_endian=no
 395 )
 396
 397 dnl Check for POWER8 Architecture
 398 PWR8_CFLAGS="-mpower8-vector"
 399 have_pwr8_intrinsics=no
 400 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 401 save_CFLAGS=$CFLAGS
 402 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 403 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 404 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 405 #error "Need GCC >= 4.8 for sane POWER8 support"
 406 #endif
 407 #include <altivec.h>
 408 int main () {
 409     vector unsigned char r;
 410     vector unsigned int v = vec_splat_u32 (1);
 411     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 412     return 0;
 413 }]])], have_pwr8_intrinsics=yes)
 414 CFLAGS=$save_CFLAGS
 415
 416 AC_ARG_ENABLE(pwr8,
 417    [AC_HELP_STRING([--disable-pwr8-inst],
 418                    [disable POWER8-specific instructions])],
 419    [enable_pwr8=$enableval], [enable_pwr8=auto])
 420
 421 if test "x$enable_pwr8" = xno ; then
 422    have_pwr8_intrinsics=disabled
 423 fi
 424
 425 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 426    DEFINES="$DEFINES -D_ARCH_PWR8"
 427    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 428    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 429 else
 430    PWR8_CFLAGS=
 431 fi
 432
 433 AC_MSG_RESULT($have_pwr8_intrinsics)
 434 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 435    AC_MSG_ERROR([POWER8 compiler support not detected])
 436 fi
 437
 438 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 439    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 440 fi
 441
 442 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 443
 444 dnl Can't have static and shared libraries, default to static if user
 445 dnl explicitly requested. If both disabled, set to static since shared
 446 dnl was explicitly requested.
 447 case "x$enable_static$enable_shared" in
 448 xyesyes)
 449     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 450     enable_shared=no
 451     ;;
 452 xnono)
 453     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 454     enable_shared=yes
 455     ;;
 456 esac
 457
 458 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 459
 460 dnl
 461 dnl other compiler options
 462 dnl
 463 AC_ARG_ENABLE([debug],
 464     [AS_HELP_STRING([--enable-debug],
 465         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 466     [enable_debug="$enableval"],
 467     [enable_debug=no]
 468 )
 469
 470 AC_ARG_ENABLE([profile],
 471     [AS_HELP_STRING([--enable-profile],
 472         [enable profiling of code @<:@default=disabled@:>@])],
 473     [enable_profile="$enableval"],
 474     [enable_profile=no]
 475 )
 476
 477 if test "x$enable_profile" = xyes; then
 478     DEFINES="$DEFINES -DPROFILE"
 479     if test "x$GCC" = xyes; then
 480         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 481     fi
 482     if test "x$GXX" = xyes; then
 483         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 484     fi
 485 fi
 486
 487 if test "x$enable_debug" = xyes; then
 488     DEFINES="$DEFINES -DDEBUG"
 489     if test "x$enable_profile" = xyes; then
 490         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 491     fi
 492     if test "x$GCC" = xyes; then
 493         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 494             CFLAGS="$CFLAGS -g"
 495         fi
 496         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 497             CFLAGS="$CFLAGS -O0"
 498         fi
 499     fi
 500     if test "x$GXX" = xyes; then
 501         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 502             CXXFLAGS="$CXXFLAGS -g"
 503         fi
 504         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 505             CXXFLAGS="$CXXFLAGS -O0"
 506         fi
 507     fi
 508 else
 509    DEFINES="$DEFINES -DNDEBUG"
 510 fi
 511
 512 DEFAULT_GL_LIB_NAME=GL
 513
 514 dnl
 515 dnl Check if linker supports -Bsymbolic
 516 dnl
 517 save_LDFLAGS=$LDFLAGS
 518 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 519 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 520 AC_LINK_IFELSE(
 521     [AC_LANG_SOURCE([int main() { return 0;}])],
 522     [AC_MSG_RESULT([yes])
 523         BSYMBOLIC="-Wl,-Bsymbolic";],
 524     [AC_MSG_RESULT([no])
 525         BSYMBOLIC="";])
 526 LDFLAGS=$save_LDFLAGS
 527
 528 AC_SUBST([BSYMBOLIC])
 529
 530 dnl
 531 dnl Check if linker supports garbage collection
 532 dnl
 533 save_LDFLAGS=$LDFLAGS
 534 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 535 AC_MSG_CHECKING([whether ld supports --gc-sections])
 536 AC_LINK_IFELSE(
 537     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 538     [AC_MSG_RESULT([yes])
 539         GC_SECTIONS="-Wl,--gc-sections";],
 540     [AC_MSG_RESULT([no])
 541         GC_SECTIONS="";])
 542 LDFLAGS=$save_LDFLAGS
 543
 544 AC_SUBST([GC_SECTIONS])
 545
 546 dnl
 547 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 548 dnl so when these flags are passed to ld via libtool the checks will fail
 549 dnl
 550 case "$host_os" in
 551 openbsd* | darwin* )
 552     LD_NO_UNDEFINED="" ;;
 553 *)
 554     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 555 esac
 556
 557 AC_SUBST([LD_NO_UNDEFINED])
 558
 559 dnl
 560 dnl Check if linker supports version scripts
 561 dnl
 562 AC_MSG_CHECKING([if the linker supports version-scripts])
 563 save_LDFLAGS=$LDFLAGS
 564 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 565 cat > conftest.map <<EOF
 566 VERSION_1 {
 567      global:
 568          main;
 569
 570      local:
 571          *;
 572 };
 573 EOF
 574 AC_LINK_IFELSE(
 575     [AC_LANG_SOURCE([int main() { return 0;}])],
 576     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 577     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 578 LDFLAGS=$save_LDFLAGS
 579 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 580
 581 dnl
 582 dnl Check if linker supports dynamic list files
 583 dnl
 584 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 585 save_LDFLAGS=$LDFLAGS
 586 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 587 cat > conftest.dyn <<EOF
 588 {
 589         radeon_drm_winsys_create;
 590 };
 591 EOF
 592 AC_LINK_IFELSE(
 593     [AC_LANG_SOURCE([int main() { return 0;}])],
 594     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 595     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 596 LDFLAGS=$save_LDFLAGS
 597 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 598
 599 dnl
 600 dnl compatibility symlinks
 601 dnl
 602 case "$host_os" in
 603 linux* )
 604     HAVE_COMPAT_SYMLINKS=yes ;;
 605 * )
 606     HAVE_COMPAT_SYMLINKS=no ;;
 607 esac
 608
 609 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 610
 611 DEFAULT_GL_LIB_NAME=GL
 612
 613 dnl
 614 dnl Libglvnd configuration
 615 dnl
 616 AC_ARG_ENABLE([libglvnd],
 617     [AS_HELP_STRING([--enable-libglvnd],
 618         [Build for libglvnd @<:@default=disabled@:>@])],
 619     [enable_libglvnd="$enableval"],
 620     [enable_libglvnd=no])
 621 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 622 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 623 if test "x$enable_libglvnd" = xyes ; then
 624     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 625     DEFAULT_GL_LIB_NAME=GLX_mesa
 626 fi
 627
 628 dnl
 629 dnl library names
 630 dnl
 631 dnl Unfortunately we need to do a few things that libtool can't help us with,
 632 dnl so we need some knowledge of shared library filenames:
 633 dnl
 634 dnl LIB_EXT is the extension used when creating symlinks for alternate
 635 dnl filenames for a shared library which will be dynamically loaded
 636 dnl
 637 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 638 dnl the file for a shared library we wish to link with
 639 dnl
 640 case "$host_os" in
 641 darwin* )
 642     LIB_EXT='dylib'
 643     IMP_LIB_EXT=$LIB_EXT
 644     ;;
 645 cygwin* )
 646     LIB_EXT='dll'
 647     IMP_LIB_EXT='dll.a'
 648     ;;
 649 aix* )
 650     LIB_EXT='a'
 651     IMP_LIB_EXT=$LIB_EXT
 652     ;;
 653 * )
 654     LIB_EXT='so'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 esac
 658
 659 AC_SUBST([LIB_EXT])
 660
 661 AC_ARG_WITH([gl-lib-name],
 662   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 663     [specify GL library name @<:@default=GL@:>@])],
 664   [GL_LIB=$withval],
 665   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 666 AC_ARG_WITH([osmesa-lib-name],
 667   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 668     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 669   [OSMESA_LIB=$withval],
 670   [OSMESA_LIB=OSMesa])
 671 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 672 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 673
 674 dnl
 675 dnl Mangled Mesa support
 676 dnl
 677 AC_ARG_ENABLE([mangling],
 678   [AS_HELP_STRING([--enable-mangling],
 679     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 680   [enable_mangling="${enableval}"],
 681   [enable_mangling=no]
 682 )
 683 if test "x${enable_mangling}" = "xyes" ; then
 684   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 685   GL_LIB="Mangled${GL_LIB}"
 686   OSMESA_LIB="Mangled${OSMESA_LIB}"
 687 fi
 688 AC_SUBST([GL_LIB])
 689 AC_SUBST([OSMESA_LIB])
 690
 691 dnl
 692 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 693 dnl
 694 AC_ARG_ENABLE([texture-float],
 695     [AS_HELP_STRING([--enable-texture-float],
 696         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 697     [enable_texture_float="$enableval"],
 698     [enable_texture_float=no]
 699 )
 700 if test "x$enable_texture_float" = xyes; then
 701     AC_MSG_WARN([Floating-point textures enabled.])
 702     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 703     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 704 fi
 705
 706 dnl
 707 dnl Arch/platform-specific settings
 708 dnl
 709 AC_ARG_ENABLE([asm],
 710     [AS_HELP_STRING([--disable-asm],
 711         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 712     [enable_asm="$enableval"],
 713     [enable_asm=yes]
 714 )
 715 asm_arch=""
 716 AC_MSG_CHECKING([whether to enable assembly])
 717 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 718 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 719 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 720     case "$host_cpu" in
 721     i?86 | x86_64 | amd64)
 722         if test "x$host_cpu" != "x$target_cpu"; then
 723             enable_asm=no
 724             AC_MSG_RESULT([no, cross compiling])
 725         fi
 726         ;;
 727     esac
 728 fi
 729 # check for supported arches
 730 if test "x$enable_asm" = xyes; then
 731     case "$host_cpu" in
 732     i?86)
 733         case "$host_os" in
 734         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 735             asm_arch=x86
 736             ;;
 737         esac
 738         ;;
 739     x86_64|amd64)
 740         case "$host_os" in
 741         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 742             asm_arch=x86_64
 743             ;;
 744         esac
 745         ;;
 746     sparc*)
 747         case "$host_os" in
 748         linux*)
 749             asm_arch=sparc
 750             ;;
 751         esac
 752         ;;
 753     esac
 754
 755     case "$asm_arch" in
 756     x86)
 757         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 758         AC_MSG_RESULT([yes, x86])
 759         ;;
 760     x86_64|amd64)
 761         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 762         AC_MSG_RESULT([yes, x86_64])
 763         ;;
 764     sparc)
 765         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 766         AC_MSG_RESULT([yes, sparc])
 767         ;;
 768     *)
 769         AC_MSG_RESULT([no, platform not supported])
 770         ;;
 771     esac
 772 fi
 773
 774 AC_HEADER_MAJOR
 775 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 776 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 777 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 778 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 779
 780 dnl Check to see if dlopen is in default libraries (like Solaris, which
 781 dnl has it in libc), or if libdl is needed to get it.
 782 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 783     [AC_CHECK_LIB([dl], [dlopen],
 784        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 785 AC_SUBST([DLOPEN_LIBS])
 786
 787 dnl Check if that library also has dladdr
 788 save_LIBS="$LIBS"
 789 LIBS="$LIBS $DLOPEN_LIBS"
 790 AC_CHECK_FUNCS([dladdr])
 791 LIBS="$save_LIBS"
 792
 793 case "$host_os" in
 794 darwin*)
 795     ;;
 796 *)
 797     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 798                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 799                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 800     AC_SUBST([CLOCK_LIB])
 801     ;;
 802 esac
 803
 804 dnl See if posix_memalign is available
 805 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 806
 807 dnl Check for pthreads
 808 AX_PTHREAD
 809 if test "x$ax_pthread_ok" = xno; then
 810     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 811 fi
 812 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 813 dnl to -pthread, which causes problems if we need -lpthread to appear in
 814 dnl pkgconfig files.
 815 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 816
 817 dnl pthread-stubs is mandatory on targets where it exists
 818 case "$host_os" in
 819 cygwin* )
 820     pthread_stubs_possible="no"
 821     ;;
 822 * )
 823     pthread_stubs_possible="yes"
 824     ;;
 825 esac
 826
 827 if test "x$pthread_stubs_possible" = xyes; then
 828     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 829     AC_SUBST(PTHREADSTUBS_CFLAGS)
 830     AC_SUBST(PTHREADSTUBS_LIBS)
 831 fi
 832
 833 dnl SELinux awareness.
 834 AC_ARG_ENABLE([selinux],
 835     [AS_HELP_STRING([--enable-selinux],
 836         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 837     [MESA_SELINUX="$enableval"],
 838     [MESA_SELINUX=no])
 839 if test "x$enable_selinux" = "xyes"; then
 840     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 841         [AC_CHECK_HEADER([selinux/selinux.h],[],
 842                          [AC_MSG_ERROR([SELinux headers not found])])
 843          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 844                       [AC_MSG_ERROR([SELinux library not found])])
 845          SELINUX_LIBS="-lselinux"])
 846     DEFINES="$DEFINES -DMESA_SELINUX"
 847 fi
 848 AC_SUBST([SELINUX_CFLAGS])
 849 AC_SUBST([SELINUX_LIBS])
 850
 851 dnl Options for APIs
 852 AC_ARG_ENABLE([opengl],
 853     [AS_HELP_STRING([--disable-opengl],
 854         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 855     [enable_opengl="$enableval"],
 856     [enable_opengl=yes])
 857 AC_ARG_ENABLE([gles1],
 858     [AS_HELP_STRING([--disable-gles1],
 859         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 860     [enable_gles1="$enableval"],
 861     [enable_gles1=yes])
 862 AC_ARG_ENABLE([gles2],
 863     [AS_HELP_STRING([--disable-gles2],
 864         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 865     [enable_gles2="$enableval"],
 866     [enable_gles2=yes])
 867
 868 AC_ARG_ENABLE([dri],
 869     [AS_HELP_STRING([--enable-dri],
 870         [enable DRI modules @<:@default=enabled@:>@])],
 871     [enable_dri="$enableval"],
 872     [enable_dri=yes])
 873
 874 case "$host_os" in
 875 linux*)
 876     dri3_default=yes
 877     ;;
 878 *)
 879     dri3_default=no
 880     ;;
 881 esac
 882
 883 if test "x$enable_dri" = xno; then
 884     dri3_default=no
 885 fi
 886
 887 AC_ARG_ENABLE([dri3],
 888     [AS_HELP_STRING([--enable-dri3],
 889         [enable DRI3 @<:@default=auto@:>@])],
 890     [enable_dri3="$enableval"],
 891     [enable_dri3="$dri3_default"])
 892 AC_ARG_ENABLE([glx],
 893     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 894         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 895     [enable_glx="$enableval"],
 896     [enable_glx=yes])
 897 AC_ARG_ENABLE([osmesa],
 898     [AS_HELP_STRING([--enable-osmesa],
 899         [enable OSMesa library @<:@default=disabled@:>@])],
 900     [enable_osmesa="$enableval"],
 901     [enable_osmesa=no])
 902 AC_ARG_ENABLE([gallium-osmesa],
 903     [AS_HELP_STRING([--enable-gallium-osmesa],
 904         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 905     [enable_gallium_osmesa="$enableval"],
 906     [enable_gallium_osmesa=no])
 907 AC_ARG_ENABLE([egl],
 908     [AS_HELP_STRING([--disable-egl],
 909         [disable EGL library @<:@default=enabled@:>@])],
 910     [enable_egl="$enableval"],
 911     [enable_egl=yes])
 912
 913 AC_ARG_ENABLE([xa],
 914     [AS_HELP_STRING([--enable-xa],
 915         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 916     [enable_xa="$enableval"],
 917     [enable_xa=no])
 918 AC_ARG_ENABLE([gbm],
 919    [AS_HELP_STRING([--enable-gbm],
 920          [enable gbm library @<:@default=auto@:>@])],
 921    [enable_gbm="$enableval"],
 922    [enable_gbm=auto])
 923 AC_ARG_ENABLE([nine],
 924     [AS_HELP_STRING([--enable-nine],
 925         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 926     [enable_nine="$enableval"],
 927     [enable_nine=no])
 928
 929 AC_ARG_ENABLE([xvmc],
 930    [AS_HELP_STRING([--enable-xvmc],
 931          [enable xvmc library @<:@default=auto@:>@])],
 932    [enable_xvmc="$enableval"],
 933    [enable_xvmc=auto])
 934 AC_ARG_ENABLE([vdpau],
 935    [AS_HELP_STRING([--enable-vdpau],
 936          [enable vdpau library @<:@default=auto@:>@])],
 937    [enable_vdpau="$enableval"],
 938    [enable_vdpau=auto])
 939 AC_ARG_ENABLE([omx],
 940    [AS_HELP_STRING([--enable-omx],
 941          [enable OpenMAX library @<:@default=disabled@:>@])],
 942    [enable_omx="$enableval"],
 943    [enable_omx=no])
 944 AC_ARG_ENABLE([va],
 945    [AS_HELP_STRING([--enable-va],
 946          [enable va library @<:@default=auto@:>@])],
 947    [enable_va="$enableval"],
 948    [enable_va=auto])
 949 AC_ARG_ENABLE([opencl],
 950    [AS_HELP_STRING([--enable-opencl],
 951          [enable OpenCL library @<:@default=disabled@:>@])],
 952    [enable_opencl="$enableval"],
 953    [enable_opencl=no])
 954 AC_ARG_ENABLE([opencl_icd],
 955    [AS_HELP_STRING([--enable-opencl-icd],
 956           [Build an OpenCL ICD library to be loaded by an ICD implementation
 957            @<:@default=disabled@:>@])],
 958     [enable_opencl_icd="$enableval"],
 959     [enable_opencl_icd=no])
 960
 961 AC_ARG_ENABLE([gallium-tests],
 962     [AS_HELP_STRING([--enable-gallium-tests],
 963         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 964     [enable_gallium_tests="$enableval"],
 965     [enable_gallium_tests=no])
 966
 967 # Option for Gallium drivers
 968
 969 # Keep this in sync with the --with-gallium-drivers help string default value
 970 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 971
 972 AC_ARG_WITH([gallium-drivers],
 973     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 974         [comma delimited Gallium drivers list, e.g.
 975         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 976         @<:@default=r300,r600,svga,swrast@:>@])],
 977     [with_gallium_drivers="$withval"],
 978     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 979
 980 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 981 # here so that the script doesn't choke on an unknown driver name later.
 982 case "$with_gallium_drivers" in
 983     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 984     no) with_gallium_drivers='' ;;
 985 esac
 986
 987 if test "x$enable_opengl" = xno -a \
 988         "x$enable_gles1" = xno -a \
 989         "x$enable_gles2" = xno -a \
 990         "x$enable_nine" = xno -a \
 991         "x$enable_xa" = xno -a \
 992         "x$enable_xvmc" = xno -a \
 993         "x$enable_vdpau" = xno -a \
 994         "x$enable_omx" = xno -a \
 995         "x$enable_va" = xno -a \
 996         "x$enable_opencl" = xno; then
 997     AC_MSG_ERROR([at least one API should be enabled])
 998 fi
 999
1000 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1001 if test "x$enable_opengl" = xno -a \
1002         "x$enable_gles1" = xyes; then
1003     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1004 fi
1005
1006 if test "x$enable_opengl" = xno -a \
1007         "x$enable_gles2" = xyes; then
1008     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1009 fi
1010
1011 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1012 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1013 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1014 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1015                                         "x$enable_gles1" = xyes -o \
1016                                         "x$enable_gles2" = xyes)
1017
1018 # Validate GLX options
1019 if test "x$enable_glx" = xyes; then
1020     if test "x$enable_dri" = xyes; then
1021         enable_glx=dri
1022     elif test -n "$with_gallium_drivers"; then
1023         enable_glx=gallium-xlib
1024     else
1025         enable_glx=xlib
1026     fi
1027 fi
1028 case "x$enable_glx" in
1029 xdri | xxlib | xgallium-xlib)
1030     # GLX requires OpenGL
1031     if test "x$enable_opengl" = xno; then
1032         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1033     fi
1034
1035     # Check individual dependencies
1036     case "x$enable_glx" in
1037     xdri)
1038         if test "x$enable_dri" = xno; then
1039             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1040         fi
1041         ;;
1042     xxlib)
1043         if test "x$enable_dri" = xyes; then
1044             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1045         fi
1046         ;;
1047     xgallium-xlib )
1048         if test "x$enable_dri" = xyes; then
1049             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1050         fi
1051         if test -z "$with_gallium_drivers"; then
1052             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1053         fi
1054         ;;
1055     esac
1056     ;;
1057 xno)
1058     ;;
1059 *)
1060     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1061     ;;
1062 esac
1063
1064 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1065 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1066 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1067 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1068
1069 dnl
1070 dnl Libglvnd configuration
1071 dnl
1072 AC_ARG_ENABLE([libglvnd],
1073     [AS_HELP_STRING([--enable-libglvnd],
1074         [Build for libglvnd @<:@default=disabled@:>@])],
1075     [enable_libglvnd="$enableval"],
1076     [enable_libglvnd=no])
1077 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1078 if test "x$enable_libglvnd" = xyes ; then
1079     dnl XXX: update once we can handle more than libGL/glx.
1080     dnl Namely: we should error out if neither of the glvnd enabled libraries
1081     dnl are built
1082     case "x$enable_glx" in
1083     xno)
1084         AC_MSG_ERROR([cannot build libglvnd without GLX])
1085         ;;
1086     xxlib | xgallium-xlib )
1087         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1088         ;;
1089     xdri)
1090         ;;
1091     esac
1092
1093     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1094     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1095     DEFAULT_GL_LIB_NAME=GLX_mesa
1096 fi
1097
1098 # Check for libdrm
1099 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1100                   [have_libdrm=yes], [have_libdrm=no])
1101 if test "x$have_libdrm" = xyes; then
1102         DEFINES="$DEFINES -DHAVE_LIBDRM"
1103 fi
1104
1105 # Select which platform-dependent DRI code gets built
1106 case "$host_os" in
1107 darwin*)
1108     dri_platform='apple' ;;
1109 cygwin*)
1110     dri_platform='windows' ;;
1111 gnu*)
1112     dri_platform='none' ;;
1113 *)
1114     dri_platform='drm' ;;
1115 esac
1116
1117 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1118     have_drisw_kms='yes'
1119 fi
1120
1121 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1122 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1123 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1124 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1125 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1126 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1127 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1128
1129 AC_ARG_ENABLE([shared-glapi],
1130     [AS_HELP_STRING([--enable-shared-glapi],
1131         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1132     [enable_shared_glapi="$enableval"],
1133     [enable_shared_glapi=yes])
1134
1135 case "x$enable_opengl$enable_gles1$enable_gles2" in
1136 x*yes*yes*)
1137     if test "x$enable_shared_glapi" = xno; then
1138         AC_MSG_ERROR([shared GLAPI required when building two or more of
1139                       the following APIs - opengl, gles1 gles2])
1140     fi
1141     ;;
1142 esac
1143
1144 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1145
1146 # Build the pipe-drivers as separate libraries/modules.
1147 # Do not touch this unless you know what you are doing.
1148 # XXX: Expose via configure option ?
1149 enable_shared_pipe_drivers=no
1150
1151 dnl
1152 dnl Driver specific build directories
1153 dnl
1154
1155 if test "x$enable_gallium_osmesa" = xyes; then
1156     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1157         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1158     fi
1159     if test "x$enable_osmesa" = xyes; then
1160         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1161     fi
1162 fi
1163
1164 AC_SUBST([MESA_LLVM])
1165
1166 # SHA1 hashing
1167 AC_ARG_WITH([sha1],
1168         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1169         [choose SHA1 implementation])])
1170 case "x$with_sha1" in
1171 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1172   ;;
1173 *)
1174         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1175 esac
1176
1177 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1178 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1179         with_sha1=libc
1180 fi
1181 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1182         AC_MSG_ERROR([sha1 in libc requested but not found])
1183 fi
1184 if test "x$with_sha1" = xlibc; then
1185         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1186                 [Use libc SHA1 functions])
1187         SHA1_LIBS=""
1188 fi
1189 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1190 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1191         with_sha1=CommonCrypto
1192 fi
1193 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1194         AC_MSG_ERROR([CommonCrypto requested but not found])
1195 fi
1196 if test "x$with_sha1" = xCommonCrypto; then
1197         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1198                 [Use CommonCrypto SHA1 functions])
1199         SHA1_LIBS=""
1200 fi
1201 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1202 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1203 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1204         with_sha1=CryptoAPI
1205 fi
1206 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1207         AC_MSG_ERROR([CryptoAPI requested but not found])
1208 fi
1209 if test "x$with_sha1" = xCryptoAPI; then
1210         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1211                 [Use CryptoAPI SHA1 functions])
1212         SHA1_LIBS=""
1213 fi
1214 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1215 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1216         with_sha1=libmd
1217 fi
1218 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1219         AC_MSG_ERROR([libmd requested but not found])
1220 fi
1221 if test "x$with_sha1" = xlibmd; then
1222         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1223                   [Use libmd SHA1 functions])
1224         SHA1_LIBS=-lmd
1225 fi
1226 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1227 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1228    with_sha1=libsha1
1229 fi
1230 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1231         AC_MSG_ERROR([libsha1 requested but not found])
1232 fi
1233 if test "x$with_sha1" = xlibsha1; then
1234         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1235                   [Use libsha1 for SHA1])
1236         SHA1_LIBS=-lsha1
1237 fi
1238 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1239 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1240         with_sha1=libnettle
1241 fi
1242 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1243         AC_MSG_ERROR([libnettle requested but not found])
1244 fi
1245 if test "x$with_sha1" = xlibnettle; then
1246         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1247                   [Use libnettle SHA1 functions])
1248         SHA1_LIBS=-lnettle
1249 fi
1250 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1251 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1252         with_sha1=libgcrypt
1253 fi
1254 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1255         AC_MSG_ERROR([libgcrypt requested but not found])
1256 fi
1257 if test "x$with_sha1" = xlibgcrypt; then
1258         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1259                   [Use libgcrypt SHA1 functions])
1260         SHA1_LIBS=-lgcrypt
1261 fi
1262 # We don't need all of the OpenSSL libraries, just libcrypto
1263 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1264 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1265                   [HAVE_OPENSSL_PKC=no])
1266 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1267         if test "x$with_sha1" = x; then
1268                 with_sha1=libcrypto
1269         fi
1270 else
1271         if test "x$with_sha1" = xlibcrypto; then
1272                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1273         fi
1274 fi
1275 if test "x$with_sha1" = xlibcrypto; then
1276         if test "x$HAVE_LIBCRYPTO" = xyes; then
1277                 SHA1_LIBS=-lcrypto
1278         else
1279                 SHA1_LIBS="$OPENSSL_LIBS"
1280                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1281         fi
1282 fi
1283 AC_MSG_CHECKING([for SHA1 implementation])
1284 AC_MSG_RESULT([$with_sha1])
1285 AC_SUBST(SHA1_LIBS)
1286 AC_SUBST(SHA1_CFLAGS)
1287
1288 # Enable a define for SHA1
1289 if test "x$with_sha1" != "x"; then
1290         DEFINES="$DEFINES -DHAVE_SHA1"
1291 fi
1292
1293 # Allow user to configure out the shader-cache feature
1294 AC_ARG_ENABLE([shader-cache],
1295     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1296     [enable_shader_cache="$enableval"],
1297     [if test "x$with_sha1" != "x"; then
1298         enable_shader_cache=yes
1299      else
1300         enable_shader_cache=no
1301      fi])
1302 if test "x$with_sha1" = "x"; then
1303     if test "x$enable_shader_cache" = "xyes"; then
1304         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1305     fi
1306 fi
1307 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1308
1309 case "$host_os" in
1310 linux*)
1311     need_pci_id=yes ;;
1312 *)
1313     need_pci_id=no ;;
1314 esac
1315
1316 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1317                   have_libudev=yes, have_libudev=no)
1318
1319 AC_ARG_ENABLE([sysfs],
1320     [AS_HELP_STRING([--enable-sysfs],
1321         [enable /sys PCI identification @<:@default=disabled@:>@])],
1322     [have_sysfs="$enableval"],
1323     [have_sysfs=no]
1324 )
1325
1326 if test "x$enable_dri" = xyes; then
1327     if test "$enable_static" = yes; then
1328         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1329     fi
1330
1331     # not a hard requirement as swrast does not depend on it
1332     if test "x$have_libdrm" = xyes; then
1333         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1334     fi
1335 fi
1336
1337 AC_ARG_ENABLE([driglx-direct],
1338     [AS_HELP_STRING([--disable-driglx-direct],
1339         [disable direct rendering in GLX and EGL for DRI \
1340             @<:@default=auto@:>@])],
1341     [driglx_direct="$enableval"],
1342     [driglx_direct="yes"])
1343
1344 dnl
1345 dnl libGL configuration per driver
1346 dnl
1347 case "x$enable_glx" in
1348 xxlib | xgallium-xlib)
1349     # Xlib-based GLX
1350     dri_modules="x11 xext xcb"
1351     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1352     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1353     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1354     GL_LIB_DEPS="$XLIBGL_LIBS"
1355     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1356     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1357     ;;
1358 xdri)
1359     # DRI-based GLX
1360     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1361
1362     # find the DRI deps for libGL
1363     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1364
1365     if test x"$driglx_direct" = xyes; then
1366         if test x"$dri_platform" = xdrm ; then
1367             DEFINES="$DEFINES -DGLX_USE_DRM"
1368             if test "x$have_libdrm" != xyes; then
1369                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1370             fi
1371
1372             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1373             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1374             if test x"$enable_dri3" = xyes; then
1375                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1376                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1377             fi
1378
1379             if test x"$enable_dri" = xyes; then
1380                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1381             fi
1382
1383             if test x"$enable_dri3" = xyes; then
1384                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1385                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1386                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1387             fi
1388         fi
1389         if test x"$dri_platform" = xapple ; then
1390             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1391         fi
1392         if test x"$dri_platform" = xwindows ; then
1393             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1394         fi
1395     fi
1396
1397     # add xf86vidmode if available
1398     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1399     if test "$HAVE_XF86VIDMODE" = yes ; then
1400         dri_modules="$dri_modules xxf86vm"
1401     fi
1402
1403     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1404     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1405     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1406     GL_LIB_DEPS="$DRIGL_LIBS"
1407
1408     # need DRM libs, $PTHREAD_LIBS, etc.
1409     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1410     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1411     ;;
1412 esac
1413
1414 have_pci_id=no
1415 if test "$have_libudev" = yes; then
1416     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1417     have_pci_id=yes
1418 fi
1419
1420 if test "$have_sysfs" = yes; then
1421     DEFINES="$DEFINES -DHAVE_SYSFS"
1422     have_pci_id=yes
1423 fi
1424
1425 # This is outside the case (above) so that it is invoked even for non-GLX
1426 # builds.
1427 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1428
1429 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1430 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1431 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1432 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1433
1434 AC_SUBST([X11_INCLUDES])
1435 AC_SUBST([GL_LIB_DEPS])
1436 AC_SUBST([GL_PC_REQ_PRIV])
1437 AC_SUBST([GL_PC_LIB_PRIV])
1438 AC_SUBST([GL_PC_CFLAGS])
1439 AC_SUBST([DRI_PC_REQ_PRIV])
1440 AC_SUBST([GLESv1_CM_LIB_DEPS])
1441 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1442 AC_SUBST([GLESv2_LIB_DEPS])
1443 AC_SUBST([GLESv2_PC_LIB_PRIV])
1444
1445 AC_SUBST([HAVE_XF86VIDMODE])
1446
1447 dnl
1448 dnl More GLX setup
1449 dnl
1450 case "x$enable_glx" in
1451 xxlib | xgallium-xlib)
1452     DEFINES="$DEFINES -DUSE_XSHM"
1453     ;;
1454 xdri)
1455     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1456     if test "x$driglx_direct" = xyes; then
1457         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1458     fi
1459     ;;
1460 esac
1461
1462 dnl
1463 dnl TLS detection
1464 dnl
1465
1466 AC_ARG_ENABLE([glx-tls],
1467     [AS_HELP_STRING([--enable-glx-tls],
1468         [enable TLS support in GLX @<:@default=disabled@:>@])],
1469     [GLX_USE_TLS="$enableval"],
1470     [GLX_USE_TLS=no])
1471 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1472
1473 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1474       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1475
1476 dnl Read-only text section on x86 hardened platforms
1477 AC_ARG_ENABLE([glx-read-only-text],
1478     [AS_HELP_STRING([--enable-glx-read-only-text],
1479         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1480     [enable_glx_read_only_text="$enableval"],
1481     [enable_glx_read_only_text=no])
1482 if test "x$enable_glx_read_only_text" = xyes; then
1483     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1484 fi
1485
1486 dnl
1487 dnl More DRI setup
1488 dnl
1489 dnl Directory for DRI drivers
1490 AC_ARG_WITH([dri-driverdir],
1491     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1492         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1493     [DRI_DRIVER_INSTALL_DIR="$withval"],
1494     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1495 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1496 dnl Extra search path for DRI drivers
1497 AC_ARG_WITH([dri-searchpath],
1498     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1499         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1500     [DRI_DRIVER_SEARCH_DIR="$withval"],
1501     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1502 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1503 dnl Which drivers to build - default is chosen by platform
1504 AC_ARG_WITH([dri-drivers],
1505     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1506         [comma delimited classic DRI drivers list, e.g.
1507         "swrast,i965,radeon" @<:@default=auto@:>@])],
1508     [with_dri_drivers="$withval"],
1509     [with_dri_drivers=auto])
1510
1511 if test "x$with_dri_drivers" = xauto; then
1512     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1513         with_dri_drivers="yes"
1514     else
1515         with_dri_drivers="no"
1516     fi
1517 fi
1518 if test "x$with_dri_drivers" = xno; then
1519     with_dri_drivers=''
1520 fi
1521
1522 dnl If $with_dri_drivers is yes, drivers will be added through
1523 dnl platform checks. Set DEFINES and LIB_DEPS
1524 if test "x$enable_dri" = xyes; then
1525     # Platform specific settings and drivers to build
1526     case "$host_os" in
1527     linux*)
1528         DEFINES="$DEFINES -DHAVE_ALIAS"
1529         if test "x$enable_dri3" = xyes; then
1530             DEFINES="$DEFINES -DHAVE_DRI3"
1531         fi
1532
1533         if test "x$have_pci_id" != xyes; then
1534             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1535         fi
1536
1537         case "$host_cpu" in
1538         powerpc* | sparc*)
1539             # Build only the drivers for cards that exist on PowerPC/sparc
1540             if test "x$with_dri_drivers" = "xyes"; then
1541                 with_dri_drivers="r200 radeon swrast"
1542             fi
1543             ;;
1544         esac
1545         ;;
1546     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1547         DEFINES="$DEFINES -DHAVE_ALIAS"
1548         ;;
1549     gnu*)
1550         DEFINES="$DEFINES -DHAVE_ALIAS"
1551         ;;
1552     cygwin*)
1553         if test "x$with_dri_drivers" = "xyes"; then
1554             with_dri_drivers="swrast"
1555         fi
1556         ;;
1557     darwin*)
1558         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1559         if test "x$with_dri_drivers" = "xyes"; then
1560             with_dri_drivers="swrast"
1561         fi
1562         ;;
1563     esac
1564
1565     # default drivers
1566     if test "x$with_dri_drivers" = "xyes"; then
1567         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1568     fi
1569
1570     # Check for expat
1571     PKG_CHECK_MODULES([EXPAT], [expat], [],
1572         # expat version 2.0 and earlier do not provide expat.pc
1573         [AC_CHECK_HEADER([expat.h],[],
1574                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1575          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1576                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1577          EXPAT_LIBS="-lexpat"])
1578
1579     # put all the necessary libs together
1580     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1581 fi
1582
1583 AC_SUBST([DRI_LIB_DEPS])
1584
1585 DRI_DIRS=''
1586 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1587 if test -n "$with_dri_drivers"; then
1588     if test "x$enable_opengl" != xyes; then
1589         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1590     fi
1591
1592     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1593     for driver in $dri_drivers; do
1594         DRI_DIRS="$DRI_DIRS $driver"
1595         case "x$driver" in
1596         xi915)
1597             HAVE_I915_DRI=yes;
1598             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1599             ;;
1600         xi965)
1601             HAVE_I965_DRI=yes;
1602             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1603             ;;
1604         xnouveau)
1605             HAVE_NOUVEAU_DRI=yes;
1606             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1607             ;;
1608         xradeon)
1609             HAVE_RADEON_DRI=yes;
1610             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1611             ;;
1612         xr200)
1613             HAVE_R200_DRI=yes;
1614             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1615             ;;
1616         xswrast)
1617             HAVE_SWRAST_DRI=yes;
1618             ;;
1619         *)
1620             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1621             ;;
1622         esac
1623     done
1624     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1625 fi
1626
1627
1628 #
1629 # Vulkan driver configuration
1630 #
1631
1632 AC_ARG_WITH([vulkan-drivers],
1633     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1634         [comma delimited Vulkan drivers list, e.g.
1635         "intel"
1636         @<:@default=no@:>@])],
1637     [with_vulkan_drivers="$withval"],
1638     [with_vulkan_drivers="no"])
1639
1640 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1641 # here so that the script doesn't choke on an unknown driver name later.
1642 case "x$with_vulkan_drivers" in
1643     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1644     xno) with_vulkan_drivers='' ;;
1645 esac
1646
1647 AC_ARG_WITH([vulkan-icddir],
1648     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1649         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1650     [VULKAN_ICD_INSTALL_DIR="$withval"],
1651     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1652 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1653
1654 AC_ARG_ENABLE([vulkan-icd-full-driver-path],
1655    [AS_HELP_STRING([--disable-vulkan-icd-full-driver-path],
1656                    [create Vulkan ICD files with just a .so name and no path])],
1657    [vulkan_icd_driver_path="$enableval"],
1658    [vulkan_icd_driver_path="yes"])
1659 AM_CONDITIONAL(VULKAN_ICD_DRIVER_PATH, test "x$vulkan_icd_driver_path" = xyes)
1660
1661 if test -n "$with_vulkan_drivers"; then
1662     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1663     for driver in $VULKAN_DRIVERS; do
1664         case "x$driver" in
1665         xintel)
1666             if test "x$HAVE_I965_DRI" != xyes; then
1667                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1668             fi
1669             if test "x$with_sha1" == "x"; then
1670                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1671             fi
1672             HAVE_INTEL_VULKAN=yes;
1673
1674             ;;
1675         *)
1676             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1677             ;;
1678         esac
1679     done
1680     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1681 fi
1682
1683
1684 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1685 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1686                                   "x$enable_osmesa" = xyes -o \
1687                                   -n "$DRI_DIRS")
1688
1689 dnl
1690 dnl OSMesa configuration
1691 dnl
1692
1693 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1694 AC_ARG_WITH([osmesa-bits],
1695     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1696         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1697     [osmesa_bits="$withval"],
1698     [osmesa_bits=8])
1699 if test "x$osmesa_bits" != x8; then
1700     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1701         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1702         osmesa_bits=8
1703     fi
1704 fi
1705 case "x$osmesa_bits" in
1706 x8)
1707     OSMESA_LIB="${OSMESA_LIB}"
1708     ;;
1709 x16|x32)
1710     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1711     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1712     ;;
1713 *)
1714     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1715     ;;
1716 esac
1717
1718 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1719     # only link libraries with osmesa if shared
1720     if test "$enable_static" = no; then
1721         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1722     else
1723         OSMESA_LIB_DEPS=""
1724     fi
1725     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1726 fi
1727
1728 AC_SUBST([OSMESA_LIB_DEPS])
1729 AC_SUBST([OSMESA_PC_REQ])
1730 AC_SUBST([OSMESA_PC_LIB_PRIV])
1731
1732 dnl
1733 dnl gbm configuration
1734 dnl
1735 if test "x$enable_gbm" = xauto; then
1736     case "$with_egl_platforms" in
1737         *drm*)
1738             enable_gbm=yes ;;
1739          *)
1740             enable_gbm=no ;;
1741     esac
1742 fi
1743 if test "x$enable_gbm" = xyes; then
1744     if test "x$need_pci_id$have_pci_id" = xyesno; then
1745         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1746     fi
1747
1748     if test "x$enable_dri" = xyes; then
1749         if test "x$enable_shared_glapi" = xno; then
1750             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1751         fi
1752     else
1753         # Strictly speaking libgbm does not require --enable-dri, although
1754         # both of its backends do. Thus one can build libgbm without any
1755         # backends if --disable-dri is set.
1756         # To avoid unnecessary complexity of checking if at least one backend
1757         # is available when building, just mandate --enable-dri.
1758         AC_MSG_ERROR([gbm requires --enable-dri])
1759     fi
1760 fi
1761 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1762 if test "x$need_pci_id$have_libudev" = xyesyes; then
1763     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1764 else
1765     GBM_PC_REQ_PRIV=""
1766 fi
1767 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1768 AC_SUBST([GBM_PC_REQ_PRIV])
1769 AC_SUBST([GBM_PC_LIB_PRIV])
1770
1771 dnl
1772 dnl EGL configuration
1773 dnl
1774 EGL_CLIENT_APIS=""
1775
1776 if test "x$enable_egl" = xyes; then
1777     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1778
1779     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1780
1781     if test "$enable_static" != yes; then
1782         if test "x$enable_dri" = xyes; then
1783             HAVE_EGL_DRIVER_DRI2=1
1784             if test "x$enable_shared_glapi" = xno; then
1785                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1786             fi
1787             if test "x$enable_dri3" = xyes; then
1788                 HAVE_EGL_DRIVER_DRI3=1
1789                 if test "x$enable_shared_glapi" = xno; then
1790                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1791                 fi
1792             fi
1793         else
1794             # Avoid building an "empty" libEGL. Drop/update this
1795             # when other backends (haiku?) come along.
1796             AC_MSG_ERROR([egl requires --enable-dri])
1797         fi
1798
1799     fi
1800 fi
1801 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1802 AC_SUBST([EGL_LIB_DEPS])
1803
1804 gallium_st="mesa"
1805
1806 dnl
1807 dnl XA configuration
1808 dnl
1809 if test "x$enable_xa" = xyes; then
1810     if test "x$with_gallium_drivers" = xswrast; then
1811        AC_MSG_ERROR([
1812           Building xa requires at least one non swrast gallium driver.
1813           If you are looking to use libxatracker.so with the VMware driver,
1814           make sure to include svga in the gallium drivers list, apart from
1815           enabling XA.
1816           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1817     fi
1818     gallium_st="$gallium_st xa"
1819 fi
1820 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1821
1822 dnl
1823 dnl Gallium G3DVL configuration
1824 dnl
1825 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1826     if test "x$enable_xvmc" = xauto; then
1827         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1828     fi
1829
1830     if test "x$enable_vdpau" = xauto; then
1831         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1832     fi
1833
1834     if test "x$enable_omx" = xauto; then
1835         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1836     fi
1837
1838     if test "x$enable_va" = xauto; then
1839         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1840     fi
1841 fi
1842
1843 if test "x$enable_dri" = xyes -o \
1844         "x$enable_xvmc" = xyes -o \
1845         "x$enable_vdpau" = xyes -o \
1846         "x$enable_omx" = xyes -o \
1847         "x$enable_va" = xyes; then
1848     need_gallium_vl=yes
1849 fi
1850 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1851
1852 if test "x$enable_xvmc" = xyes -o \
1853         "x$enable_vdpau" = xyes -o \
1854         "x$enable_omx" = xyes -o \
1855         "x$enable_va" = xyes; then
1856     if test x"$enable_dri3" = xyes; then
1857         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1858                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1859     else
1860         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1861     fi
1862     need_gallium_vl_winsys=yes
1863 fi
1864 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1865
1866 if test "x$enable_xvmc" = xyes; then
1867     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1868     gallium_st="$gallium_st xvmc"
1869 fi
1870 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1871
1872 if test "x$enable_vdpau" = xyes; then
1873     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1874     gallium_st="$gallium_st vdpau"
1875     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1876 fi
1877 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1878
1879 if test "x$enable_omx" = xyes; then
1880     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1881     gallium_st="$gallium_st omx"
1882 fi
1883 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1884
1885 if test "x$enable_va" = xyes; then
1886     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1887     gallium_st="$gallium_st va"
1888 fi
1889 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1890
1891 dnl
1892 dnl Nine Direct3D9 configuration
1893 dnl
1894 if test "x$enable_nine" = xyes; then
1895     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1896         AC_MSG_ERROR([nine requires the gallium swrast driver])
1897     fi
1898     if test "x$with_gallium_drivers" = xswrast; then
1899         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1900     fi
1901     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1902         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1903     fi
1904
1905     if test "x$enable_dri3" = xno; then
1906         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1907     fi
1908
1909     gallium_st="$gallium_st nine"
1910 fi
1911 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1912
1913 dnl
1914 dnl OpenCL configuration
1915 dnl
1916
1917 AC_ARG_WITH([clang-libdir],
1918    [AS_HELP_STRING([--with-clang-libdir],
1919          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1920    [CLANG_LIBDIR="$withval"],
1921    [CLANG_LIBDIR=''])
1922
1923 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1924 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1925
1926 if test "x$have_libelf" = xno; then
1927    LIBELF_LIBS=''
1928    LIBELF_CFLAGS=''
1929    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1930    AC_SUBST([LIBELF_LIBS])
1931    AC_SUBST([LIBELF_CFLAGS])
1932 fi
1933
1934 if test "x$enable_opencl" = xyes; then
1935     if test -z "$with_gallium_drivers"; then
1936         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1937     fi
1938
1939     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1940         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1941     fi
1942
1943     if test "x$have_libclc" = xno; then
1944         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1945                     Make sure the directory containing libclc.pc is specified in your
1946                     PKG_CONFIG_PATH environment variable.
1947                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1948     else
1949         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1950         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1951         AC_SUBST([LIBCLC_INCLUDEDIR])
1952         AC_SUBST([LIBCLC_LIBEXECDIR])
1953     fi
1954
1955     gallium_st="$gallium_st clover"
1956
1957     if test "x$enable_opencl_icd" = xyes; then
1958         OPENCL_LIBNAME="MesaOpenCL"
1959     else
1960         OPENCL_LIBNAME="OpenCL"
1961     fi
1962
1963     if test "x$have_libelf" != xyes; then
1964        AC_MSG_ERROR([Clover requires libelf])
1965     fi
1966 fi
1967 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1968 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1969 AC_SUBST([OPENCL_LIBNAME])
1970
1971 dnl
1972 dnl Gallium configuration
1973 dnl
1974 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1975
1976 AC_SUBST([LLVM_BINDIR])
1977 AC_SUBST([LLVM_CFLAGS])
1978 AC_SUBST([LLVM_CPPFLAGS])
1979 AC_SUBST([LLVM_CXXFLAGS])
1980 AC_SUBST([LLVM_LIBDIR])
1981 AC_SUBST([LLVM_LIBS])
1982 AC_SUBST([LLVM_LDFLAGS])
1983 AC_SUBST([LLVM_INCLUDEDIR])
1984 AC_SUBST([LLVM_VERSION])
1985 AC_SUBST([CLANG_RESOURCE_DIR])
1986
1987 case "x$enable_opengl$enable_gles1$enable_gles2" in
1988 x*yes*)
1989     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1990     ;;
1991 esac
1992
1993 AC_SUBST([VG_LIB_DEPS])
1994 AC_SUBST([EGL_CLIENT_APIS])
1995
1996 dnl
1997 dnl EGL Platforms configuration
1998 dnl
1999 AC_ARG_WITH([egl-platforms],
2000     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2001         [comma delimited native platforms libEGL supports, e.g.
2002         "x11,drm" @<:@default=auto@:>@])],
2003     [with_egl_platforms="$withval"],
2004     [if test "x$enable_egl" = xyes; then
2005         with_egl_platforms="x11"
2006     else
2007         with_egl_platforms=""
2008     fi])
2009
2010 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2011     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2012 fi
2013
2014 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2015         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2016         WAYLAND_SCANNER='')
2017 if test "x$WAYLAND_SCANNER" = x; then
2018     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2019 fi
2020
2021 # Do per-EGL platform setups and checks
2022 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2023 for plat in $egl_platforms; do
2024         case "$plat" in
2025         wayland)
2026                 test "x$have_libdrm" != xyes &&
2027                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
2028
2029                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2030
2031                 if test "x$WAYLAND_SCANNER" = x; then
2032                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2033                 fi
2034                 ;;
2035
2036         x11)
2037                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2038                 ;;
2039
2040         drm)
2041                 test "x$enable_gbm" = "xno" &&
2042                         AC_MSG_ERROR([EGL platform drm needs gbm])
2043                 test "x$have_libdrm" != xyes &&
2044                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
2045                 ;;
2046
2047         surfaceless)
2048                 test "x$have_libdrm" != xyes &&
2049                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
2050                 ;;
2051
2052         android)
2053                 ;;
2054
2055         *)
2056                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2057                 ;;
2058         esac
2059
2060         case "$plat$need_pci_id$have_pci_id" in
2061                 waylandyesno|drmyesno)
2062                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
2063         esac
2064 done
2065
2066 # libEGL wants to default to the first platform specified in
2067 # ./configure.  parse that here.
2068 if test "x$egl_platforms" != "x"; then
2069     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2070     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2071 else
2072     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2073 fi
2074
2075 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2076 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2077 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2078 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2079 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2080
2081 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2082
2083 AC_SUBST([EGL_NATIVE_PLATFORM])
2084 AC_SUBST([EGL_CFLAGS])
2085
2086 # If we don't have the X11 platform, set this define so we don't try to include
2087 # the X11 headers.
2088 if ! echo "$egl_platforms" | grep -q 'x11'; then
2089     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2090     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2091 fi
2092
2093 dnl
2094 dnl Gallium LLVM
2095 dnl
2096 AC_ARG_ENABLE([gallium-llvm],
2097     [AS_HELP_STRING([--enable-gallium-llvm],
2098         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2099     [enable_gallium_llvm="$enableval"],
2100     [enable_gallium_llvm=auto])
2101
2102 AC_ARG_ENABLE([llvm-shared-libs],
2103     [AS_HELP_STRING([--enable-llvm-shared-libs],
2104         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2105     [enable_llvm_shared_libs="$enableval"],
2106     [enable_llvm_shared_libs=yes])
2107
2108 AC_ARG_WITH([llvm-prefix],
2109     [AS_HELP_STRING([--with-llvm-prefix],
2110         [Prefix for LLVM installations in non-standard locations])],
2111     [llvm_prefix="$withval"],
2112     [llvm_prefix=''])
2113
2114
2115 # Call this inside ` ` to get the return value.
2116 # $1 is the llvm-config command with arguments.
2117 strip_unwanted_llvm_flags() {
2118     # Use \> (marks the end of the word)
2119     echo `$1` | sed \
2120         -e 's/-march=\S*//g' \
2121         -e 's/-mtune=\S*//g' \
2122         -e 's/-mcpu=\S*//g' \
2123         -e 's/-DNDEBUG\>//g' \
2124         -e 's/-D_GNU_SOURCE\>//g' \
2125         -e 's/-pedantic\>//g' \
2126         -e 's/-Wcovered-switch-default\>//g' \
2127         -e 's/-O.\>//g' \
2128         -e 's/-g\>//g' \
2129         -e 's/-Wall\>//g' \
2130         -e 's/-Wcast-qual\>//g' \
2131         -e 's/-Woverloaded-virtual\>//g' \
2132         -e 's/-fcolor-diagnostics\>//g' \
2133         -e 's/-fdata-sections\>//g' \
2134         -e 's/-ffunction-sections\>//g' \
2135         -e 's/-fno-exceptions\>//g' \
2136         -e 's/-fomit-frame-pointer\>//g' \
2137         -e 's/-fvisibility-inlines-hidden\>//g' \
2138         -e 's/-fPIC\>//g' \
2139         -e 's/-fstack-protector-strong\>//g'
2140 }
2141
2142 llvm_check_version_for() {
2143     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2144         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2145     fi
2146 }
2147
2148
2149
2150 if test -z "$with_gallium_drivers"; then
2151     enable_gallium_llvm=no
2152 fi
2153 if test "x$enable_gallium_llvm" = xauto; then
2154     case "$host_cpu" in
2155     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2156     esac
2157 fi
2158 if test "x$enable_gallium_llvm" = xyes; then
2159     if test -n "$llvm_prefix"; then
2160         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2161     else
2162         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2163     fi
2164
2165     if test "x$LLVM_CONFIG" != xno; then
2166         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2167         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2168         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2169         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2170         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2171         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2172         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2173         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2174
2175         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2176             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2177         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2178             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2179
2180         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2181         if test -z "$LLVM_VERSION_PATCH"; then
2182             LLVM_VERSION_PATCH=0
2183         fi
2184
2185         if test -n "${LLVM_VERSION_MAJOR}"; then
2186             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2187         else
2188             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2189         fi
2190
2191         LLVM_REQUIRED_VERSION_MAJOR="3"
2192         LLVM_REQUIRED_VERSION_MINOR="3"
2193         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2194             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2195         fi
2196
2197         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2198
2199         if test "x$enable_opencl" = xyes; then
2200             llvm_check_version_for "3" "6" "0" "opencl"
2201
2202             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2203             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2204         fi
2205         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2206         MESA_LLVM=1
2207
2208         dnl Check for Clang internal headers
2209         if test "x$enable_opencl" = xyes; then
2210             if test -z "$CLANG_LIBDIR"; then
2211                 CLANG_LIBDIR=${LLVM_LIBDIR}
2212             fi
2213             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2214             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2215                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2216         fi
2217     else
2218         MESA_LLVM=0
2219         LLVM_VERSION_INT=0
2220     fi
2221 else
2222     MESA_LLVM=0
2223     LLVM_VERSION_INT=0
2224
2225     if test "x$enable_opencl" = xyes; then
2226         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2227     fi
2228 fi
2229
2230 dnl Directory for XVMC libs
2231 AC_ARG_WITH([xvmc-libdir],
2232     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2233         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2234     [XVMC_LIB_INSTALL_DIR="$withval"],
2235     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2236 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2237
2238 dnl
2239 dnl Gallium Tests
2240 dnl
2241 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2242
2243 dnl Directory for VDPAU libs
2244 AC_ARG_WITH([vdpau-libdir],
2245     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2246         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2247     [VDPAU_LIB_INSTALL_DIR="$withval"],
2248     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2249 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2250
2251 dnl Directory for OMX libs
2252
2253 AC_ARG_WITH([omx-libdir],
2254     [AS_HELP_STRING([--with-omx-libdir=DIR],
2255         [directory for the OMX libraries])],
2256     [OMX_LIB_INSTALL_DIR="$withval"],
2257     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2258 AC_SUBST([OMX_LIB_INSTALL_DIR])
2259
2260 dnl Directory for VA libs
2261
2262 AC_ARG_WITH([va-libdir],
2263     [AS_HELP_STRING([--with-va-libdir=DIR],
2264         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2265     [VA_LIB_INSTALL_DIR="$withval"],
2266     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2267 AC_SUBST([VA_LIB_INSTALL_DIR])
2268
2269 AC_ARG_WITH([d3d-libdir],
2270     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2271         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2272     [D3D_DRIVER_INSTALL_DIR="$withval"],
2273     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2274 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2275
2276 dnl
2277 dnl Gallium helper functions
2278 dnl
2279 gallium_require_drm() {
2280     if test "x$have_libdrm" != xyes; then
2281        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2282     fi
2283 }
2284
2285 gallium_require_llvm() {
2286     if test "x$MESA_LLVM" = x0; then
2287         case "$host" in *gnux32) return;; esac
2288         case "$host_cpu" in
2289         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2290         esac
2291     fi
2292 }
2293
2294 gallium_require_drm_loader() {
2295     if test "x$need_pci_id$have_pci_id" = xyesno; then
2296         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2297     fi
2298 }
2299
2300 dnl This is for Glamor. Skip this if OpenGL is disabled.
2301 require_egl_drm() {
2302     if test "x$enable_opengl" = xno; then
2303         return 0
2304     fi
2305
2306     case "$with_egl_platforms" in
2307         *drm*)
2308             ;;
2309          *)
2310             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2311             ;;
2312     esac
2313     if test "x$enable_gbm" != xyes; then
2314             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2315     fi
2316 }
2317
2318 radeon_llvm_check() {
2319     if test ${LLVM_VERSION_INT} -lt 307; then
2320         amdgpu_llvm_target_name='r600'
2321     else
2322         amdgpu_llvm_target_name='amdgpu'
2323     fi
2324     if test "x$enable_gallium_llvm" != "xyes"; then
2325         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2326     fi
2327     llvm_check_version_for "3" "6" "0" $1
2328     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2329         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2330     fi
2331     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2332     NEED_RADEON_LLVM=yes
2333     if test "x$have_libelf" != xyes; then
2334        AC_MSG_ERROR([$1 requires libelf when using llvm])
2335     fi
2336 }
2337
2338 swr_llvm_check() {
2339     gallium_require_llvm $1
2340     if test ${LLVM_VERSION_INT} -lt 306; then
2341         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2342     fi
2343     if test "x$enable_gallium_llvm" != "xyes"; then
2344         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2345     fi
2346 }
2347
2348 swr_require_cxx_feature_flags() {
2349     feature_name="$1"
2350     preprocessor_test="$2"
2351     option_list="$3"
2352     output_var="$4"
2353
2354     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2355     AC_LANG_PUSH([C++])
2356     save_CXXFLAGS="$CXXFLAGS"
2357     save_IFS="$IFS"
2358     IFS=","
2359     found=0
2360     for opts in $option_list
2361     do
2362         unset IFS
2363         CXXFLAGS="$opts $save_CXXFLAGS"
2364         AC_COMPILE_IFELSE(
2365             [AC_LANG_PROGRAM(
2366                 [   #if !($preprocessor_test)
2367                     #error
2368                     #endif
2369                 ])],
2370             [found=1; break],
2371             [])
2372         IFS=","
2373     done
2374     IFS="$save_IFS"
2375     CXXFLAGS="$save_CXXFLAGS"
2376     AC_LANG_POP([C++])
2377     if test $found -eq 1; then
2378         AC_MSG_RESULT([$opts])
2379         eval "$output_var=\$opts"
2380         return 0
2381     fi
2382     AC_MSG_RESULT([no])
2383     AC_MSG_ERROR([swr requires $feature_name support])
2384     return 1
2385 }
2386
2387 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2388 if test -n "$with_gallium_drivers"; then
2389     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2390     for driver in $gallium_drivers; do
2391         case "x$driver" in
2392         xsvga)
2393             HAVE_GALLIUM_SVGA=yes
2394             gallium_require_drm "svga"
2395             gallium_require_drm_loader
2396             ;;
2397         xi915)
2398             HAVE_GALLIUM_I915=yes
2399             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2400             gallium_require_drm "Gallium i915"
2401             gallium_require_drm_loader
2402             ;;
2403         xilo)
2404             HAVE_GALLIUM_ILO=yes
2405             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2406             gallium_require_drm "Gallium i965/ilo"
2407             gallium_require_drm_loader
2408             ;;
2409         xr300)
2410             HAVE_GALLIUM_R300=yes
2411             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2412             gallium_require_drm "Gallium R300"
2413             gallium_require_drm_loader
2414             gallium_require_llvm "Gallium R300"
2415             ;;
2416         xr600)
2417             HAVE_GALLIUM_R600=yes
2418             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2419             gallium_require_drm "Gallium R600"
2420             gallium_require_drm_loader
2421             if test "x$enable_opencl" = xyes; then
2422                 radeon_llvm_check "r600g"
2423                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2424             fi
2425             ;;
2426         xradeonsi)
2427             HAVE_GALLIUM_RADEONSI=yes
2428             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2429             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2430             gallium_require_drm "radeonsi"
2431             gallium_require_drm_loader
2432             radeon_llvm_check "radeonsi"
2433             require_egl_drm "radeonsi"
2434             ;;
2435         xnouveau)
2436             HAVE_GALLIUM_NOUVEAU=yes
2437             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2438             gallium_require_drm "nouveau"
2439             gallium_require_drm_loader
2440             ;;
2441         xfreedreno)
2442             HAVE_GALLIUM_FREEDRENO=yes
2443             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2444             gallium_require_drm "freedreno"
2445             gallium_require_drm_loader
2446             ;;
2447         xswrast)
2448             HAVE_GALLIUM_SOFTPIPE=yes
2449             if test "x$MESA_LLVM" = x1; then
2450                 HAVE_GALLIUM_LLVMPIPE=yes
2451             fi
2452             ;;
2453         xswr)
2454             swr_llvm_check "swr"
2455
2456             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2457                 ",-std=c++11" \
2458                 SWR_CXX11_CXXFLAGS
2459             AC_SUBST([SWR_CXX11_CXXFLAGS])
2460
2461             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2462                 ",-mavx,-march=core-avx" \
2463                 SWR_AVX_CXXFLAGS
2464             AC_SUBST([SWR_AVX_CXXFLAGS])
2465
2466             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2467                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2468                 SWR_AVX2_CXXFLAGS
2469             AC_SUBST([SWR_AVX2_CXXFLAGS])
2470
2471             HAVE_GALLIUM_SWR=yes
2472             ;;
2473         xvc4)
2474             HAVE_GALLIUM_VC4=yes
2475             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2476             gallium_require_drm "vc4"
2477             gallium_require_drm_loader
2478
2479             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2480                               [USE_VC4_SIMULATOR=yes;
2481                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2482                               [USE_VC4_SIMULATOR=no])
2483             ;;
2484         xvirgl)
2485             HAVE_GALLIUM_VIRGL=yes
2486             gallium_require_drm "virgl"
2487             gallium_require_drm_loader
2488             require_egl_drm "virgl"
2489             ;;
2490         *)
2491             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2492             ;;
2493         esac
2494     done
2495 fi
2496
2497 dnl Set LLVM_LIBS - This is done after the driver configuration so
2498 dnl that drivers can add additional components to LLVM_COMPONENTS.
2499 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2500 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2501 dnl this was causing the same libraries to be appear multiple times
2502 dnl in LLVM_LIBS.
2503
2504 if test "x$MESA_LLVM" != x0; then
2505
2506     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2507        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2508     fi
2509     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2510
2511     dnl llvm-config may not give the right answer when llvm is a built as a
2512     dnl single shared library, so we must work the library name out for
2513     dnl ourselves.
2514     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2515     if test "x$enable_llvm_shared_libs" = xyes; then
2516         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2517         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2518         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2519
2520         if test "x$llvm_have_one_so" = xyes; then
2521             dnl LLVM was built using auto*, so there is only one shared object.
2522             LLVM_LIBS="-l$LLVM_SO_NAME"
2523         else
2524             dnl If LLVM was built with CMake, there will be one shared object per
2525             dnl component.
2526             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2527                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2528         Please make sure you have built llvm with the --enable-shared option
2529         and that your llvm libraries are installed in $LLVM_LIBDIR
2530         If you have installed your llvm libraries to a different directory you
2531         can use the --with-llvm-prefix= configure flag to specify this directory.
2532         NOTE: Mesa is attempting to use llvm shared libraries by default.
2533         If you do not want to build with llvm shared libraries and instead want to
2534         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2535         invocation and rebuild.])])
2536
2537            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2538            dnl install uses a shared object for each component and we have
2539            dnl already added all of these objects to LLVM_LIBS.
2540         fi
2541     else
2542         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2543         dnl We need to link to llvm system libs when using static libs
2544         dnl However, only llvm 3.5+ provides --system-libs
2545         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2546             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2547         fi
2548     fi
2549 fi
2550
2551 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2557 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2558                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2560 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2563 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2564 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2565                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2566                                          "x$HAVE_GALLIUM_SWR" = xyes)
2567 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2568 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2569
2570 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2571
2572 if test "x$enable_dri" = xyes; then
2573     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2574 fi
2575
2576 if test "x$have_drisw_kms" = xyes; then
2577     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2578 fi
2579 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2580
2581 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2582 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2583 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2584 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2585 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2586 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2587
2588 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2589
2590 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2591                                         "x$HAVE_I965_DRI" = xyes)
2592
2593 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2594                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2595                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2596 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2597 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2598 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2599 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2600 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2601 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2602     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2603 fi
2604
2605 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2606 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2608
2609 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2610 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2611 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2612
2613 AC_SUBST([NINE_MAJOR], 1)
2614 AC_SUBST([NINE_MINOR], 0)
2615 AC_SUBST([NINE_TINY], 0)
2616 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2617
2618 AC_SUBST([VDPAU_MAJOR], 1)
2619 AC_SUBST([VDPAU_MINOR], 0)
2620
2621 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2622 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2623 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2624 AC_SUBST([VA_MINOR], $VA_MINOR)
2625
2626 AC_SUBST([XVMC_MAJOR], 1)
2627 AC_SUBST([XVMC_MINOR], 0)
2628
2629 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2630 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2631 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2632 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2633
2634 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2635 AC_SUBST([XA_MINOR], $XA_MINOR)
2636 AC_SUBST([XA_TINY], $XA_TINY)
2637 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2638
2639 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2640
2641 AC_ARG_ENABLE(valgrind,
2642               [AS_HELP_STRING([--enable-valgrind],
2643                              [Build mesa with valgrind support (default: auto)])],
2644                              [VALGRIND=$enableval], [VALGRIND=auto])
2645 if test "x$VALGRIND" != xno; then
2646         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2647 fi
2648 AC_MSG_CHECKING([whether to enable Valgrind support])
2649 if test "x$VALGRIND" = xauto; then
2650         VALGRIND="$have_valgrind"
2651 fi
2652
2653 if test "x$VALGRIND" = "xyes"; then
2654         if ! test "x$have_valgrind" = xyes; then
2655                 AC_MSG_ERROR([Valgrind support required but not present])
2656         fi
2657         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2658 fi
2659
2660 AC_MSG_RESULT([$VALGRIND])
2661
2662 dnl Restore LDFLAGS and CPPFLAGS
2663 LDFLAGS="$_SAVE_LDFLAGS"
2664 CPPFLAGS="$_SAVE_CPPFLAGS"
2665
2666 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2667 if test "x$acv_mesa_CLANG" = xyes; then
2668     CFLAGS="$CFLAGS -Qunused-arguments"
2669     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2670 fi
2671
2672 dnl Add user CFLAGS and CXXFLAGS
2673 CFLAGS="$CFLAGS $USER_CFLAGS"
2674 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2675
2676 dnl Substitute the config
2677 AC_CONFIG_FILES([Makefile
2678                 src/Makefile
2679                 src/amd/Makefile
2680                 src/compiler/Makefile
2681                 src/egl/Makefile
2682                 src/egl/main/egl.pc
2683                 src/egl/wayland/wayland-drm/Makefile
2684                 src/egl/wayland/wayland-egl/Makefile
2685                 src/egl/wayland/wayland-egl/wayland-egl.pc
2686                 src/gallium/Makefile
2687                 src/gallium/auxiliary/Makefile
2688                 src/gallium/auxiliary/pipe-loader/Makefile
2689                 src/gallium/drivers/freedreno/Makefile
2690                 src/gallium/drivers/ddebug/Makefile
2691                 src/gallium/drivers/i915/Makefile
2692                 src/gallium/drivers/ilo/Makefile
2693                 src/gallium/drivers/llvmpipe/Makefile
2694                 src/gallium/drivers/noop/Makefile
2695                 src/gallium/drivers/nouveau/Makefile
2696                 src/gallium/drivers/r300/Makefile
2697                 src/gallium/drivers/r600/Makefile
2698                 src/gallium/drivers/radeon/Makefile
2699                 src/gallium/drivers/radeonsi/Makefile
2700                 src/gallium/drivers/rbug/Makefile
2701                 src/gallium/drivers/softpipe/Makefile
2702                 src/gallium/drivers/svga/Makefile
2703                 src/gallium/drivers/swr/Makefile
2704                 src/gallium/drivers/trace/Makefile
2705                 src/gallium/drivers/vc4/Makefile
2706                 src/gallium/drivers/virgl/Makefile
2707                 src/gallium/state_trackers/clover/Makefile
2708                 src/gallium/state_trackers/dri/Makefile
2709                 src/gallium/state_trackers/glx/xlib/Makefile
2710                 src/gallium/state_trackers/nine/Makefile
2711                 src/gallium/state_trackers/omx/Makefile
2712                 src/gallium/state_trackers/osmesa/Makefile
2713                 src/gallium/state_trackers/va/Makefile
2714                 src/gallium/state_trackers/vdpau/Makefile
2715                 src/gallium/state_trackers/xa/Makefile
2716                 src/gallium/state_trackers/xvmc/Makefile
2717                 src/gallium/targets/d3dadapter9/Makefile
2718                 src/gallium/targets/d3dadapter9/d3d.pc
2719                 src/gallium/targets/dri/Makefile
2720                 src/gallium/targets/libgl-xlib/Makefile
2721                 src/gallium/targets/omx/Makefile
2722                 src/gallium/targets/opencl/Makefile
2723                 src/gallium/targets/opencl/mesa.icd
2724                 src/gallium/targets/osmesa/Makefile
2725                 src/gallium/targets/osmesa/osmesa.pc
2726                 src/gallium/targets/pipe-loader/Makefile
2727                 src/gallium/targets/va/Makefile
2728                 src/gallium/targets/vdpau/Makefile
2729                 src/gallium/targets/xa/Makefile
2730                 src/gallium/targets/xa/xatracker.pc
2731                 src/gallium/targets/xvmc/Makefile
2732                 src/gallium/tests/trivial/Makefile
2733                 src/gallium/tests/unit/Makefile
2734                 src/gallium/winsys/freedreno/drm/Makefile
2735                 src/gallium/winsys/i915/drm/Makefile
2736                 src/gallium/winsys/intel/drm/Makefile
2737                 src/gallium/winsys/nouveau/drm/Makefile
2738                 src/gallium/winsys/radeon/drm/Makefile
2739                 src/gallium/winsys/amdgpu/drm/Makefile
2740                 src/gallium/winsys/svga/drm/Makefile
2741                 src/gallium/winsys/sw/dri/Makefile
2742                 src/gallium/winsys/sw/kms-dri/Makefile
2743                 src/gallium/winsys/sw/null/Makefile
2744                 src/gallium/winsys/sw/wrapper/Makefile
2745                 src/gallium/winsys/sw/xlib/Makefile
2746                 src/gallium/winsys/vc4/drm/Makefile
2747                 src/gallium/winsys/virgl/drm/Makefile
2748                 src/gallium/winsys/virgl/vtest/Makefile
2749                 src/gbm/Makefile
2750                 src/gbm/main/gbm.pc
2751                 src/glx/Makefile
2752                 src/glx/apple/Makefile
2753                 src/glx/tests/Makefile
2754                 src/glx/windows/Makefile
2755                 src/glx/windows/windowsdriproto.pc
2756                 src/gtest/Makefile
2757                 src/intel/Makefile
2758                 src/intel/tools/Makefile
2759                 src/intel/vulkan/Makefile
2760                 src/loader/Makefile
2761                 src/mapi/Makefile
2762                 src/mapi/es1api/glesv1_cm.pc
2763                 src/mapi/es2api/glesv2.pc
2764                 src/mapi/glapi/gen/Makefile
2765                 src/mesa/Makefile
2766                 src/mesa/gl.pc
2767                 src/mesa/drivers/dri/dri.pc
2768                 src/mesa/drivers/dri/common/Makefile
2769                 src/mesa/drivers/dri/common/xmlpool/Makefile
2770                 src/mesa/drivers/dri/i915/Makefile
2771                 src/mesa/drivers/dri/i965/Makefile
2772                 src/mesa/drivers/dri/Makefile
2773                 src/mesa/drivers/dri/nouveau/Makefile
2774                 src/mesa/drivers/dri/r200/Makefile
2775                 src/mesa/drivers/dri/radeon/Makefile
2776                 src/mesa/drivers/dri/swrast/Makefile
2777                 src/mesa/drivers/osmesa/Makefile
2778                 src/mesa/drivers/osmesa/osmesa.pc
2779                 src/mesa/drivers/x11/Makefile
2780                 src/mesa/main/tests/Makefile
2781                 src/util/Makefile
2782                 src/util/tests/hash_table/Makefile])
2783
2784 AC_OUTPUT
2785
2786 # Fix up dependencies in *.Plo files, where we changed the extension of a
2787 # source file
2788 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2789
2790
2791 dnl
2792 dnl Output some configuration info for the user
2793 dnl
2794 echo ""
2795 echo "        prefix:          $prefix"
2796 echo "        exec_prefix:     $exec_prefix"
2797 echo "        libdir:          $libdir"
2798 echo "        includedir:      $includedir"
2799
2800 dnl API info
2801 echo ""
2802 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2803
2804 dnl Driver info
2805 echo ""
2806 case "x$enable_osmesa$enable_gallium_osmesa" in
2807 xnoyes)
2808         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2809         ;;
2810 xyesno)
2811         echo "        OSMesa:          lib$OSMESA_LIB"
2812         ;;
2813 xnono)
2814         echo "        OSMesa:          no"
2815         ;;
2816 esac
2817
2818 echo ""
2819 if test "x$enable_dri" != xno; then
2820         echo "        DRI platform:    $dri_platform"
2821         if test -z "$DRI_DIRS"; then
2822             echo "        DRI drivers:     no"
2823         else
2824             echo "        DRI drivers:     $DRI_DIRS"
2825         fi
2826         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2827 fi
2828
2829 case "x$enable_glx" in
2830 xdri)
2831     echo "        GLX:             DRI-based"
2832     ;;
2833 xxlib)
2834     echo "        GLX:             Xlib-based"
2835     ;;
2836 xgallium-xlib)
2837     echo "        GLX:             Xlib-based (Gallium)"
2838     ;;
2839 *)
2840     echo "        GLX:             $enable_glx"
2841     ;;
2842 esac
2843
2844 dnl EGL
2845 echo ""
2846 echo "        EGL:             $enable_egl"
2847 if test "$enable_egl" = yes; then
2848     echo "        EGL platforms:   $egl_platforms"
2849
2850     egl_drivers=""
2851     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2852         egl_drivers="$egl_drivers builtin:egl_dri2"
2853     fi
2854     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2855         egl_drivers="$egl_drivers builtin:egl_dri3"
2856     fi
2857
2858     echo "        EGL drivers:    $egl_drivers"
2859 fi
2860
2861 # Vulkan
2862 echo ""
2863 if test "x$VULKAN_DRIVERS" != x; then
2864     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2865     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2866 else
2867     echo "        Vulkan drivers:  no"
2868 fi
2869
2870 echo ""
2871 if test "x$MESA_LLVM" = x1; then
2872     echo "        llvm:            yes"
2873     echo "        llvm-config:     $LLVM_CONFIG"
2874     echo "        llvm-version:    $LLVM_VERSION"
2875 else
2876     echo "        llvm:            no"
2877 fi
2878
2879 echo ""
2880 if test -n "$with_gallium_drivers"; then
2881     echo "        Gallium drivers: $gallium_drivers"
2882     echo "        Gallium st:      $gallium_st"
2883 else
2884     echo "        Gallium:         no"
2885 fi
2886
2887 dnl Shader cache
2888 echo ""
2889 echo "        Shader cache:    $enable_shader_cache"
2890 if test "x$enable_shader_cache" = "xyes"; then
2891     echo "        With SHA1 from:  $with_sha1"
2892 fi
2893
2894 dnl Libraries
2895 echo ""
2896 echo "        Shared libs:     $enable_shared"
2897 echo "        Static libs:     $enable_static"
2898 echo "        Shared-glapi:    $enable_shared_glapi"
2899
2900 dnl Compiler options
2901 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2902 cflags=`echo $CFLAGS | \
2903     $SED 's/^ *//;s/  */ /;s/ *$//'`
2904 cxxflags=`echo $CXXFLAGS | \
2905     $SED 's/^ *//;s/  */ /;s/ *$//'`
2906 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2907 echo ""
2908 echo "        CFLAGS:          $cflags"
2909 echo "        CXXFLAGS:        $cxxflags"
2910 echo "        Macros:          $defines"
2911 echo ""
2912 if test "x$MESA_LLVM" = x1; then
2913     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2914     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2915     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2916     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2917     echo ""
2918 fi
2919 echo "        PYTHON2:         $PYTHON2"
2920
2921 echo ""
2922 echo "        Run '${MAKE-make}' to build Mesa"
2923 echo ""