projects / mesa.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
egl/x11: Support DRI3 v1.1
[mesa.git] / configure.ac
1 dnl Copyright © 2011-2014 Intel Corporation
2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
3 dnl Copyright © 2007-2010 Dan Nicholson
4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
5 dnl Copyright © 2010-2014 Christian König
6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
7 dnl Copyright © 2009-2012 Jakob Bornecrantz
8 dnl Copyright © 2009-2014 Jon TURNEY
9 dnl Copyright © 2011-2012 Benjamin Franzke
10 dnl Copyright © 2008-2014 David Airlie
11 dnl Copyright © 2009-2013 Brian Paul
12 dnl
13 dnl Permission is hereby granted, free of charge, to any person obtaining a
14 dnl copy of this software and associated documentation files (the "Software"),
15 dnl to deal in the Software without restriction, including without limitation
16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
17 dnl and/or sell copies of the Software, and to permit persons to whom the
18 dnl Software is furnished to do so, subject to the following conditions:
19 dnl
20 dnl The above copyright notice and this permission notice (including the next
21 dnl paragraph) shall be included in all copies or substantial portions of the
22 dnl Software.
23 dnl
24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
30 dnl DEALINGS IN THE SOFTWARE.
31 dnl
32 dnl Process this file with autoconf to create configure.
33
34 AC_PREREQ([2.60])
35
36 dnl Tell the user about autoconf.html in the --help output
37 m4_divert_once([HELP_END], [
38 See docs/autoconf.html for more details on the options for Mesa.])
39
40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
41 AC_INIT([Mesa], [MESA_VERSION],
42 [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
43 AC_CONFIG_AUX_DIR([bin])
44 AC_CONFIG_MACRO_DIR([m4])
45 AC_CANONICAL_SYSTEM
46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
47
48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
49 case "$host_os" in
50 mingw*)
51 AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
52 ;;
53 esac
54
55 # Support silent build rules, requires at least automake-1.11. Disable
56 # by either passing --disable-silent-rules to configure or passing V=1
57 # to make
58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
59 [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
60
61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
62
63 dnl Set internal versions
64 OSMESA_VERSION=8
65 AC_SUBST([OSMESA_VERSION])
66 OPENCL_VERSION=1
67 AC_SUBST([OPENCL_VERSION])
68
69 # The idea is that libdrm is distributed as one cohesive package, even
70 # though it is composed of multiple libraries. However some drivers
71 # may have different version requirements than others. This list
72 # codifies which drivers need which version of libdrm. Any libdrm
73 # version dependencies in non-driver-specific code should be reflected
74 # in the first entry.
75 LIBDRM_REQUIRED=2.4.75
76 LIBDRM_RADEON_REQUIRED=2.4.71
77 LIBDRM_AMDGPU_REQUIRED=2.4.90
78 LIBDRM_INTEL_REQUIRED=2.4.75
79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
81 LIBDRM_FREEDRENO_REQUIRED=2.4.91
82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
83
84 dnl Versions for external dependencies
85 DRI2PROTO_REQUIRED=2.8
86 GLPROTO_REQUIRED=1.4.14
87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
88 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
89 LIBVA_REQUIRED=0.38.0
90 VDPAU_REQUIRED=1.1
91 WAYLAND_REQUIRED=1.11
92 WAYLAND_PROTOCOLS_REQUIRED=1.8
93 XCB_REQUIRED=1.9.3
94 XCBDRI2_REQUIRED=1.8
95 XCBDRI3_REQUIRED=1.13
96 XCBGLX_REQUIRED=1.8.1
97 XCBPRESENT_REQUIRED=1.13
98 XDAMAGE_REQUIRED=1.1
99 XSHMFENCE_REQUIRED=1.1
100 XVMC_REQUIRED=1.0.6
101 PYTHON_MAKO_REQUIRED=0.8.0
102 LIBSENSORS_REQUIRED=4.0.0
103 ZLIB_REQUIRED=1.2.3
104
105 dnl LLVM versions
106 LLVM_REQUIRED_GALLIUM=3.3.0
107 LLVM_REQUIRED_OPENCL=3.9.0
108 LLVM_REQUIRED_R600=3.9.0
109 LLVM_REQUIRED_RADEONSI=4.0.0
110 LLVM_REQUIRED_RADV=4.0.0
111 LLVM_REQUIRED_SWR=4.0.0
112
113 dnl Check for progs
114 AC_PROG_CPP
115 AC_PROG_CC
116 AC_PROG_CXX
117 dnl add this here, so the help for this environmnet variable is close to
118 dnl other CC/CXX flags related help
119 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
120 enabled by default and different from -std=c++11)])
121 AM_PROG_CC_C_O
122 AC_PROG_NM
123 AM_PROG_AS
124 AX_CHECK_GNU_MAKE
125 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
126 AC_PROG_SED
127 AC_PROG_MKDIR_P
128
129 AC_SYS_LARGEFILE
130
131
132 LT_PREREQ([2.2])
133 LT_INIT([disable-static])
134
135 AC_CHECK_PROG(RM, rm, [rm -f])
136
137 AX_PROG_BISON([],
138 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
139 [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
140 AX_PROG_FLEX([],
141 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
142 [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
143
144 AC_CHECK_PROG(INDENT, indent, indent, cat)
145 if test "x$INDENT" != "xcat"; then
146 # Only GNU indent is supported
147 INDENT_VERSION=`indent --version | grep GNU`
148 if test $? -eq 0; then
149 AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
150 else
151 INDENT="cat"
152 fi
153 fi
154
155 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
156
157 if test -z "$PYTHON2"; then
158 if test ! -f "$srcdir/src/util/format_srgb.c"; then
159 AC_MSG_ERROR([Python not found - unable to generate sources])
160 fi
161 else
162 if test "x$acv_mako_found" = xno; then
163 if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
164 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
165 fi
166 fi
167 fi
168
169 AC_PROG_INSTALL
170
171 dnl We need a POSIX shell for parts of the build. Assume we have one
172 dnl in most cases.
173 case "$host_os" in
174 solaris*)
175 # Solaris /bin/sh is too old/non-POSIX compliant
176 AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
177 SHELL="$POSIX_SHELL"
178 ;;
179 esac
180
181 dnl clang is mostly GCC-compatible, but its version is much lower,
182 dnl so we have to check for it.
183 AC_MSG_CHECKING([if compiling with clang])
184
185 AC_COMPILE_IFELSE(
186 [AC_LANG_PROGRAM([], [[
187 #ifndef __clang__
188 not clang
189 #endif
190 ]])],
191 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
192
193 AC_MSG_RESULT([$acv_mesa_CLANG])
194
195 dnl If we're using GCC, make sure that it is at least version 4.2.0. Older
196 dnl versions are explictly not supported.
197 GEN_ASM_OFFSETS=no
198 USE_GNU99=no
199 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
200 AC_MSG_CHECKING([whether gcc version is sufficient])
201 major=0
202 minor=0
203
204 GCC_VERSION=`$CC -dumpversion`
205 if test $? -eq 0; then
206 GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
207 GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
208 fi
209
210 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
211 AC_MSG_RESULT([no])
212 AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
213 else
214 AC_MSG_RESULT([yes])
215 fi
216
217 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
218 USE_GNU99=yes
219 fi
220 if test "x$cross_compiling" = xyes; then
221 GEN_ASM_OFFSETS=yes
222 fi
223 fi
224
225 dnl We don't support building Mesa with Sun C compiler
226 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
227 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
228 if test "x$SUNCC" = xyes; then
229 AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
230 fi
231
232 dnl Check for compiler builtins
233 AX_GCC_BUILTIN([__builtin_bswap32])
234 AX_GCC_BUILTIN([__builtin_bswap64])
235 AX_GCC_BUILTIN([__builtin_clz])
236 AX_GCC_BUILTIN([__builtin_clzll])
237 AX_GCC_BUILTIN([__builtin_ctz])
238 AX_GCC_BUILTIN([__builtin_expect])
239 AX_GCC_BUILTIN([__builtin_ffs])
240 AX_GCC_BUILTIN([__builtin_ffsll])
241 AX_GCC_BUILTIN([__builtin_popcount])
242 AX_GCC_BUILTIN([__builtin_popcountll])
243 AX_GCC_BUILTIN([__builtin_unreachable])
244
245 AX_GCC_FUNC_ATTRIBUTE([const])
246 AX_GCC_FUNC_ATTRIBUTE([flatten])
247 AX_GCC_FUNC_ATTRIBUTE([format])
248 AX_GCC_FUNC_ATTRIBUTE([malloc])
249 AX_GCC_FUNC_ATTRIBUTE([packed])
250 AX_GCC_FUNC_ATTRIBUTE([pure])
251 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
252 AX_GCC_FUNC_ATTRIBUTE([unused])
253 AX_GCC_FUNC_ATTRIBUTE([visibility])
254 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
255 AX_GCC_FUNC_ATTRIBUTE([weak])
256 AX_GCC_FUNC_ATTRIBUTE([alias])
257 AX_GCC_FUNC_ATTRIBUTE([noreturn])
258
259 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
260
261 dnl Make sure the pkg-config macros are defined
262 m4_ifndef([PKG_PROG_PKG_CONFIG],
263 [m4_fatal([Could not locate the pkg-config autoconf macros.
264 These are usually located in /usr/share/aclocal/pkg.m4. If your macros
265 are in a different location, try setting the environment variable
266 ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
267 PKG_PROG_PKG_CONFIG()
268
269 dnl LIB_DIR - library basename
270 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
271 AC_SUBST([LIB_DIR])
272
273 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
274 _SAVE_LDFLAGS="$LDFLAGS"
275 _SAVE_CPPFLAGS="$CPPFLAGS"
276
277 dnl Compiler macros
278 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
279 AC_SUBST([DEFINES])
280 android=no
281 case "$host_os" in
282 *-android*)
283 android=yes
284 ;;
285 linux*|*-gnu*|gnu*|cygwin*)
286 DEFINES="$DEFINES -D_GNU_SOURCE"
287 ;;
288 solaris*)
289 DEFINES="$DEFINES -DSVR4"
290 ;;
291 esac
292
293 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
294
295 dnl
296 dnl Check compiler flags
297 dnl
298 AX_CHECK_COMPILE_FLAG([-Wall], [CFLAGS="$CFLAGS -Wall"])
299 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
300 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes], [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
301 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes], [CFLAGS="$CFLAGS -Wmissing-prototypes"])
302 AX_CHECK_COMPILE_FLAG([-fno-math-errno], [CFLAGS="$CFLAGS -fno-math-errno"])
303 AX_CHECK_COMPILE_FLAG([-fno-trapping-math], [CFLAGS="$CFLAGS -fno-trapping-math"])
304 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
305
306 dnl
307 dnl Check C++ compiler flags
308 dnl
309 AC_LANG_PUSH([C++])
310 AX_CHECK_COMPILE_FLAG([-Wall], [CXXFLAGS="$CXXFLAGS -Wall"])
311 AX_CHECK_COMPILE_FLAG([-fno-math-errno], [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
312 AX_CHECK_COMPILE_FLAG([-fno-trapping-math], [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
313 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
314 AC_LANG_POP([C++])
315
316 # Flags to help ensure that certain portions of the code -- and only those
317 # portions -- can be built with MSVC:
318 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
319 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
320 # supports most of C99)
321 # - the rest has no compiler compiler restrictions
322 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith], [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
323 AX_CHECK_COMPILE_FLAG([-Werror=vla], [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
324 AC_LANG_PUSH([C++])
325 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith], [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
326 AX_CHECK_COMPILE_FLAG([-Werror=vla], [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
327 AC_LANG_POP([C++])
328
329 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
330 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
331
332 if test "x$GCC" = xyes; then
333 if test "x$USE_GNU99" = xyes; then
334 CFLAGS="$CFLAGS -std=gnu99"
335 else
336 CFLAGS="$CFLAGS -std=c99"
337 fi
338 fi
339
340 dnl
341 dnl Check whether C++11 is supported, if the environment variable
342 dnl CXX11_CXXFLAGS is set it takes precedence.
343 dnl
344
345 AC_LANG_PUSH([C++])
346
347 check_cxx11_available() {
348 output_support=$1
349 AC_COMPILE_IFELSE(
350 [AC_LANG_PROGRAM([
351 #if !(__cplusplus >= 201103L)
352 #error
353 #endif
354 #include <tuple>
355 ])
356 ], [
357 AC_MSG_RESULT(yes)
358 cxx11_support=yes
359 ], AC_MSG_RESULT(no))
360 eval "$output_support=\$cxx11_support"
361 }
362
363 HAVE_CXX11=no
364 save_CXXFLAGS="$CXXFLAGS"
365
366 dnl If the user provides a flag to enable c++11, then we test only this
367 if test "x$CXX11_CXXFLAGS" != "x"; then
368 CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
369 AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
370 check_cxx11_available HAVE_CXX11
371 else
372 dnl test whether c++11 is enabled by default
373 AC_MSG_CHECKING(whether c++11 is enabled by default)
374 check_cxx11_available HAVE_CXX11
375
376 dnl C++11 not enabled by default, test whether -std=c++11 does the job
377 if test "x$HAVE_CXX11" != "xyes"; then
378 CXX11_CXXFLAGS=-std=c++11
379 CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
380 AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
381 check_cxx11_available HAVE_CXX11
382 fi
383 fi
384
385 CXXFLAGS="$save_CXXFLAGS"
386 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
387 AC_SUBST(CXX11_CXXFLAGS)
388 AC_LANG_POP([C++])
389
390 dnl even if the compiler appears to support it, using visibility attributes isn't
391 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
392 case "$host_os" in
393 cygwin*)
394 VISIBILITY_CFLAGS=""
395 VISIBILITY_CXXFLAGS=""
396 ;;
397 esac
398
399 AC_SUBST([VISIBILITY_CFLAGS])
400 AC_SUBST([VISIBILITY_CXXFLAGS])
401
402 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
403 dnl option is not supported. Hence, check for -Wfoo instead.
404 AX_CHECK_COMPILE_FLAG([-Woverride-init], [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"]) # gcc
405 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides], [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
406 AC_SUBST([WNO_OVERRIDE_INIT])
407
408 dnl
409 dnl Optional flags, check for compiler support
410 dnl
411 SSE41_CFLAGS="-msse4.1"
412 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
413 dnl stack, but on x86-32 such alignment is not guaranteed.
414 case "$target_cpu" in
415 i?86)
416 SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
417 ;;
418 esac
419 save_CFLAGS="$CFLAGS"
420 CFLAGS="$SSE41_CFLAGS $CFLAGS"
421 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
422 #include <smmintrin.h>
423 int param;
424 int main () {
425 __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
426 c = _mm_max_epu32(a, b);
427 return _mm_cvtsi128_si32(c);
428 }]])], SSE41_SUPPORTED=1)
429 CFLAGS="$save_CFLAGS"
430 if test "x$SSE41_SUPPORTED" = x1; then
431 DEFINES="$DEFINES -DUSE_SSE41"
432 fi
433 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
434 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
435
436 dnl Check for new-style atomic builtins
437 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
438 int main() {
439 int n;
440 return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
441 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
442 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
443 DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
444 dnl On some platforms, new-style atomics need a helper library
445 AC_MSG_CHECKING(whether -latomic is needed)
446 AC_LINK_IFELSE([AC_LANG_SOURCE([[
447 #include <stdint.h>
448 uint64_t v;
449 int main() {
450 return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
451 }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
452 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
453 if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
454 LIBATOMIC_LIBS="-latomic"
455 fi
456 fi
457 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
458 AC_SUBST([LIBATOMIC_LIBS])
459
460 dnl Check if host supports 64-bit atomics
461 dnl note that lack of support usually results in link (not compile) error
462 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
463 AC_LINK_IFELSE([AC_LANG_SOURCE([[
464 #include <stdint.h>
465 uint64_t v;
466 int main() {
467 return __sync_add_and_fetch(&v, (uint64_t)1);
468 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
469 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
470 DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
471 fi
472 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
473
474 dnl Check for Endianness
475 AC_C_BIGENDIAN(
476 little_endian=no,
477 little_endian=yes,
478 little_endian=no,
479 little_endian=no
480 )
481
482 dnl Check for POWER8 Architecture
483 PWR8_CFLAGS="-mpower8-vector"
484 have_pwr8_intrinsics=no
485 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
486 save_CFLAGS=$CFLAGS
487 CFLAGS="$PWR8_CFLAGS $CFLAGS"
488 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
489 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
490 #error "Need GCC >= 4.8 for sane POWER8 support"
491 #endif
492 #include <altivec.h>
493 int main () {
494 vector unsigned char r;
495 vector unsigned int v = vec_splat_u32 (1);
496 r = __builtin_vec_vgbbd ((vector unsigned char) v);
497 return 0;
498 }]])], have_pwr8_intrinsics=yes)
499 CFLAGS=$save_CFLAGS
500
501 AC_ARG_ENABLE(pwr8,
502 [AS_HELP_STRING([--disable-pwr8],
503 [disable POWER8-specific instructions])],
504 [enable_pwr8=$enableval], [enable_pwr8=auto])
505
506 if test "x$enable_pwr8" = xno ; then
507 have_pwr8_intrinsics=disabled
508 fi
509
510 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
511 DEFINES="$DEFINES -D_ARCH_PWR8"
512 CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
513 CFLAGS="$CFLAGS $PWR8_CFLAGS"
514 else
515 PWR8_CFLAGS=
516 fi
517
518 AC_MSG_RESULT($have_pwr8_intrinsics)
519 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
520 AC_MSG_ERROR([POWER8 compiler support not detected])
521 fi
522
523 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
524 AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
525 fi
526
527 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
528
529 dnl Can't have static and shared libraries, default to static if user
530 dnl explicitly requested. If both disabled, set to static since shared
531 dnl was explicitly requested.
532 case "x$enable_static$enable_shared" in
533 xyesyes)
534 AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
535 ;;
536 xnono)
537 AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
538 ;;
539 esac
540
541 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
542
543 dnl
544 dnl other compiler options
545 dnl
546 AC_ARG_ENABLE([debug],
547 [AS_HELP_STRING([--enable-debug],
548 [use debug compiler flags and macros @<:@default=disabled@:>@])],
549 [enable_debug="$enableval"],
550 [enable_debug=no]
551 )
552
553 AC_ARG_ENABLE([profile],
554 [AS_HELP_STRING([--enable-profile],
555 [enable profiling of code @<:@default=disabled@:>@])],
556 [enable_profile="$enableval"],
557 [enable_profile=no]
558 )
559
560 AC_ARG_ENABLE([sanitize],
561 [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
562 [enable code sanitizer @<:@default=disabled@:>@])],
563 [enable_sanitize="$enableval"],
564 [enable_sanitize=no])
565
566 if test "x$enable_profile" = xyes; then
567 DEFINES="$DEFINES -DPROFILE"
568 if test "x$GCC" = xyes; then
569 CFLAGS="$CFLAGS -fno-omit-frame-pointer"
570 fi
571 if test "x$GXX" = xyes; then
572 CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
573 fi
574 fi
575
576 if test "x$enable_debug" = xyes; then
577 DEFINES="$DEFINES -DDEBUG"
578 if test "x$enable_profile" = xyes; then
579 AC_MSG_WARN([Debug and Profile are enabled at the same time])
580 fi
581 if test "x$GCC" = xyes; then
582 if ! echo "$CFLAGS" | grep -q -e '-g'; then
583 CFLAGS="$CFLAGS -g"
584 fi
585 if ! echo "$CFLAGS" | grep -q -e '-O'; then
586 CFLAGS="$CFLAGS -O0"
587 fi
588 fi
589 if test "x$GXX" = xyes; then
590 if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
591 CXXFLAGS="$CXXFLAGS -g"
592 fi
593 if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
594 CXXFLAGS="$CXXFLAGS -O0"
595 fi
596 fi
597 else
598 DEFINES="$DEFINES -DNDEBUG"
599 fi
600
601 if test "x$enable_sanitize" != xno; then
602 if test "x$enable_profile" = xyes; then
603 AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
604 fi
605
606 CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
607 CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
608 LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
609
610 AC_LINK_IFELSE(
611 [AC_LANG_SOURCE([int main(){return 0;}])],
612 [],
613 [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
614 fi
615
616 dnl
617 dnl Check if linker supports -Bsymbolic
618 dnl
619 save_LDFLAGS=$LDFLAGS
620 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
621 AC_MSG_CHECKING([if ld supports -Bsymbolic])
622 AC_LINK_IFELSE(
623 [AC_LANG_SOURCE([int main() { return 0;}])],
624 [AC_MSG_RESULT([yes])
625 BSYMBOLIC="-Wl,-Bsymbolic";],
626 [AC_MSG_RESULT([no])
627 BSYMBOLIC="";])
628 LDFLAGS=$save_LDFLAGS
629
630 AC_SUBST([BSYMBOLIC])
631
632 dnl
633 dnl Check if linker supports garbage collection
634 dnl
635 save_LDFLAGS=$LDFLAGS
636 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
637 AC_MSG_CHECKING([whether ld supports --gc-sections])
638 AC_LINK_IFELSE(
639 [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
640 [AC_MSG_RESULT([yes])
641 GC_SECTIONS="-Wl,--gc-sections";],
642 [AC_MSG_RESULT([no])
643 GC_SECTIONS="";])
644 LDFLAGS=$save_LDFLAGS
645
646 AC_SUBST([GC_SECTIONS])
647
648 dnl
649 dnl OpenBSD does not have DT_NEEDED entries for libc by design
650 dnl so when these flags are passed to ld via libtool the checks will fail
651 dnl
652 case "$host_os" in
653 openbsd* | darwin* )
654 LD_NO_UNDEFINED="" ;;
655 *)
656 if test "x$enable_sanitize" = xno; then
657 LD_NO_UNDEFINED="-Wl,--no-undefined"
658 else
659 LD_NO_UNDEFINED=""
660 fi
661 ;;
662 esac
663
664 AC_SUBST([LD_NO_UNDEFINED])
665
666 dnl
667 dnl Check if linker supports version scripts
668 dnl
669 AC_MSG_CHECKING([if the linker supports version-scripts])
670 save_LDFLAGS=$LDFLAGS
671 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
672 AC_LINK_IFELSE(
673 [AC_LANG_SOURCE([int main() { return 0;}])],
674 [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
675 [have_ld_version_script=no; AC_MSG_RESULT(no)])
676 LDFLAGS=$save_LDFLAGS
677 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
678
679 dnl
680 dnl Check if linker supports dynamic list files
681 dnl
682 AC_MSG_CHECKING([if the linker supports --dynamic-list])
683 save_LDFLAGS=$LDFLAGS
684 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
685 AC_LINK_IFELSE(
686 [AC_LANG_SOURCE([int main() { return 0;}])],
687 [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
688 [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
689 LDFLAGS=$save_LDFLAGS
690 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
691
692 dnl
693 dnl OSX linker does not support build-id
694 dnl
695 case "$host_os" in
696 darwin*)
697 LD_BUILD_ID=""
698 ;;
699 *)
700 LD_BUILD_ID="-Wl,--build-id=sha1"
701 ;;
702 esac
703 AC_SUBST([LD_BUILD_ID])
704
705 dnl
706 dnl compatibility symlinks
707 dnl
708 case "$host_os" in
709 linux* )
710 HAVE_COMPAT_SYMLINKS=yes ;;
711 * )
712 HAVE_COMPAT_SYMLINKS=no ;;
713 esac
714
715 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
716
717 dnl
718 dnl library names
719 dnl
720 dnl Unfortunately we need to do a few things that libtool can't help us with,
721 dnl so we need some knowledge of shared library filenames:
722 dnl
723 dnl LIB_EXT is the extension used when creating symlinks for alternate
724 dnl filenames for a shared library which will be dynamically loaded
725 dnl
726 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
727 dnl the file for a shared library we wish to link with
728 dnl
729 case "$host_os" in
730 darwin* )
731 LIB_EXT='dylib'
732 IMP_LIB_EXT=$LIB_EXT
733 ;;
734 cygwin* )
735 LIB_EXT='dll'
736 IMP_LIB_EXT='dll.a'
737 ;;
738 aix* )
739 LIB_EXT='a'
740 IMP_LIB_EXT=$LIB_EXT
741 ;;
742 * )
743 LIB_EXT='so'
744 IMP_LIB_EXT=$LIB_EXT
745 ;;
746 esac
747
748 AC_SUBST([LIB_EXT])
749
750 dnl
751 dnl potentially-infringing-but-nobody-knows-for-sure stuff
752 dnl
753 AC_ARG_ENABLE([texture-float],
754 [AS_HELP_STRING([--enable-texture-float],
755 [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
756 [enable_texture_float="$enableval"],
757 [enable_texture_float=no]
758 )
759 if test "x$enable_texture_float" = xyes; then
760 AC_MSG_WARN([Floating-point textures enabled.])
761 AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
762 DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
763 fi
764
765 dnl
766 dnl Arch/platform-specific settings
767 dnl
768 AC_ARG_ENABLE([asm],
769 [AS_HELP_STRING([--disable-asm],
770 [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
771 [enable_asm="$enableval"],
772 [enable_asm=yes]
773 )
774 asm_arch=""
775 AC_MSG_CHECKING([whether to enable assembly])
776 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
777 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
778 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
779 case "$host_cpu" in
780 i?86 | x86_64 | amd64)
781 if test "x$host_cpu" != "x$target_cpu"; then
782 enable_asm=no
783 AC_MSG_RESULT([no, cross compiling])
784 fi
785 ;;
786 esac
787 fi
788 # check for supported arches
789 if test "x$enable_asm" = xyes; then
790 case "$host_cpu" in
791 i?86)
792 case "$host_os" in
793 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
794 asm_arch=x86
795 ;;
796 esac
797 ;;
798 x86_64|amd64)
799 case "$host_os" in
800 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
801 asm_arch=x86_64
802 ;;
803 esac
804 ;;
805 sparc*)
806 case "$host_os" in
807 linux*)
808 asm_arch=sparc
809 ;;
810 esac
811 ;;
812 powerpc64le)
813 case "$host_os" in
814 linux*)
815 asm_arch=ppc64le
816 ;;
817 esac
818 ;;
819 aarch64)
820 case "$host_os" in
821 linux*)
822 asm_arch=aarch64
823 ;;
824 esac
825 ;;
826 arm)
827 case "$host_os" in
828 linux*)
829 asm_arch=arm
830 ;;
831 esac
832 ;;
833 esac
834
835 case "$asm_arch" in
836 x86)
837 DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
838 AC_MSG_RESULT([yes, x86])
839 ;;
840 x86_64|amd64)
841 DEFINES="$DEFINES -DUSE_X86_64_ASM"
842 AC_MSG_RESULT([yes, x86_64])
843 ;;
844 sparc)
845 DEFINES="$DEFINES -DUSE_SPARC_ASM"
846 AC_MSG_RESULT([yes, sparc])
847 ;;
848 ppc64le)
849 DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
850 AC_MSG_RESULT([yes, ppc64le])
851 ;;
852 aarch64)
853 DEFINES="$DEFINES -DUSE_AARCH64_ASM"
854 AC_MSG_RESULT([yes, aarch64])
855 ;;
856 arm)
857 DEFINES="$DEFINES -DUSE_ARM_ASM"
858 AC_MSG_RESULT([yes, arm])
859 ;;
860 *)
861 AC_MSG_RESULT([no, platform not supported])
862 ;;
863 esac
864 fi
865
866 AC_HEADER_MAJOR
867 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
868 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
869 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
870 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
871 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
872 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
873
874 AC_MSG_CHECKING([whether strtod has locale support])
875 AC_LINK_IFELSE([AC_LANG_SOURCE([[
876 #define _GNU_SOURCE
877 #include <stdlib.h>
878 #include <locale.h>
879 #ifdef HAVE_XLOCALE_H
880 #include <xlocale.h>
881 #endif
882 int main() {
883 locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
884 const char *s = "1.0";
885 char *end;
886 double d = strtod_l(s, end, loc);
887 float f = strtof_l(s, end, loc);
888 freelocale(loc);
889 return 0;
890 }]])],
891 [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
892 AC_MSG_RESULT([yes]),
893 AC_MSG_RESULT([no]))
894
895 dnl Check to see if dlopen is in default libraries (like Solaris, which
896 dnl has it in libc), or if libdl is needed to get it.
897 AC_CHECK_FUNC([dlopen], [],
898 [AC_CHECK_LIB([dl], [dlopen],
899 [DLOPEN_LIBS="-ldl"])])
900 AC_SUBST([DLOPEN_LIBS])
901
902 dnl Check if that library also has dladdr
903 save_LIBS="$LIBS"
904 LIBS="$LIBS $DLOPEN_LIBS"
905 AC_CHECK_FUNCS([dladdr])
906 LIBS="$save_LIBS"
907
908 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
909
910 case "$host_os" in
911 darwin*)
912 ;;
913 *)
914 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
915 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
916 [AC_MSG_ERROR([Could not find clock_gettime])])])
917 AC_SUBST([CLOCK_LIB])
918 ;;
919 esac
920
921 dnl See if posix_memalign is available
922 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
923
924 dnl Check for zlib
925 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
926 DEFINES="$DEFINES -DHAVE_ZLIB"
927
928 dnl Check for pthreads
929 AX_PTHREAD
930 if test "x$ax_pthread_ok" = xno; then
931 AC_MSG_ERROR([Building mesa on this platform requires pthreads])
932 fi
933 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
934 dnl to -pthread, which causes problems if we need -lpthread to appear in
935 dnl pkgconfig files. Since Android doesn't have a pthread lib, this check
936 dnl is not valid for that platform.
937 if test "x$android" = xno; then
938 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
939 fi
940 dnl According to the manual when using pthreads, one should add -pthread to
941 dnl both compile and link-time arguments.
942 dnl In practise that should be sufficient for all platforms, since any
943 dnl platforms build with GCC and Clang support the flag.
944 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
945
946 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
947 dnl project. Even then there's a notable issue as described in the project README
948 case "$host_os" in
949 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
950 pthread_stubs_possible="no"
951 ;;
952 * )
953 pthread_stubs_possible="yes"
954 ;;
955 esac
956
957 if test "x$pthread_stubs_possible" = xyes; then
958 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
959 fi
960
961 dnl Check for futex for fast inline simple_mtx_t.
962 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
963
964 dnl SELinux awareness.
965 AC_ARG_ENABLE([selinux],
966 [AS_HELP_STRING([--enable-selinux],
967 [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
968 [MESA_SELINUX="$enableval"],
969 [MESA_SELINUX=no])
970 if test "x$enable_selinux" = "xyes"; then
971 PKG_CHECK_MODULES([SELINUX], [libselinux], [],
972 [AC_CHECK_HEADER([selinux/selinux.h],[],
973 [AC_MSG_ERROR([SELinux headers not found])])
974 AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
975 [AC_MSG_ERROR([SELinux library not found])])
976 SELINUX_LIBS="-lselinux"])
977 DEFINES="$DEFINES -DMESA_SELINUX"
978 fi
979 AC_SUBST([SELINUX_CFLAGS])
980 AC_SUBST([SELINUX_LIBS])
981
982 dnl
983 dnl LLVM
984 dnl
985 AC_ARG_ENABLE([llvm-shared-libs],
986 [AS_HELP_STRING([--enable-llvm-shared-libs],
987 [link with LLVM shared libraries @<:@default=enabled@:>@])],
988 [enable_llvm_shared_libs="$enableval"],
989 [enable_llvm_shared_libs=yes])
990
991 AC_ARG_WITH([llvm-prefix],
992 [AS_HELP_STRING([--with-llvm-prefix],
993 [Prefix for LLVM installations in non-standard locations])],
994 [llvm_prefix="$withval"],
995 [llvm_prefix=''])
996
997 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
998 if test "x$have_libelf" = xno; then
999 LIBELF_LIBS=''
1000 LIBELF_CFLAGS=''
1001 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1002 AC_SUBST([LIBELF_LIBS])
1003 AC_SUBST([LIBELF_CFLAGS])
1004 fi
1005
1006 if test -z "$LLVM_CONFIG"; then
1007 if test -n "$llvm_prefix"; then
1008 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1009 else
1010 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1011 fi
1012 fi
1013
1014 llvm_add_component() {
1015 new_llvm_component=$1
1016 driver_name=$2
1017
1018 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1019 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1020 else
1021 AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1022 fi
1023 }
1024
1025 llvm_add_optional_component() {
1026 new_llvm_component=$1
1027 driver_name=$2
1028
1029 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1030 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1031 fi
1032 }
1033
1034 llvm_add_default_components() {
1035 driver_name=$1
1036
1037 # Required default components
1038 llvm_add_component "bitwriter" $driver_name
1039 llvm_add_component "engine" $driver_name
1040 llvm_add_component "mcdisassembler" $driver_name
1041 llvm_add_component "mcjit" $driver_name
1042
1043 # Optional default components
1044 llvm_add_optional_component "inteljitevents" $driver_name
1045 }
1046
1047 llvm_add_target() {
1048 new_llvm_target=$1
1049 driver_name=$2
1050
1051 if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1052 llvm_add_component $new_llvm_target $driver_name
1053 else
1054 AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1055 fi
1056 }
1057
1058 # Call this inside ` ` to get the return value.
1059 # $1 is the llvm-config command with arguments.
1060 strip_unwanted_llvm_flags() {
1061 echo " `$1` " | sed -E \
1062 -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1063 -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1064 -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1065 -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1066 -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1067 -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1068 -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1069 -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1070 -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1071 -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1072 -e 's/^[[[:space:]]]//' \
1073 -e 's/[[[:space:]]]$//'
1074 }
1075
1076 llvm_set_environment_variables() {
1077 if test "x$LLVM_CONFIG" != xno; then
1078 LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1079 LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1080 LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1081 LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1082
1083 # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1084 save_CFLAGS="$CFLAGS"
1085 CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1086
1087 AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1088 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1089 AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1090 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1091 AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1092 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1093
1094 CFLAGS="$save_CFLAGS"
1095
1096 # Only needed for LLVM < 3.6.0
1097 if test -z "$LLVM_VERSION_PATCH"; then
1098 LLVM_VERSION_PATCH=0
1099 fi
1100
1101 LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1102
1103 FOUND_LLVM=yes
1104 else
1105 FOUND_LLVM=no
1106 LLVM_VERSION_INT=0
1107 fi
1108 }
1109
1110 require_llvm() {
1111 if test "x$enable_llvm" != "xyes"; then
1112 AC_MSG_ERROR([--enable-llvm is required when building $1])
1113 fi
1114 }
1115
1116 llvm_require_version() {
1117 require_llvm $2
1118
1119 llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1120 llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1121 llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1122
1123 if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1124 # major > required major
1125 # --> OK
1126 return
1127 fi
1128
1129 if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1130 if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1131 # major = required major and
1132 # minor > required minor
1133 # --> OK
1134 return
1135 else
1136 if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1137 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1138 # major = required major and
1139 # minor = required minor and
1140 # patch >= required patch
1141 # --> OK
1142 return
1143 fi
1144 fi
1145 fi
1146 fi
1147
1148 AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1149 }
1150
1151 radeon_llvm_check() {
1152 if test ${LLVM_VERSION_INT} -lt 307; then
1153 amdgpu_llvm_target_name='r600'
1154 else
1155 amdgpu_llvm_target_name='amdgpu'
1156 fi
1157
1158 llvm_require_version $*
1159
1160 llvm_add_target $amdgpu_llvm_target_name $2
1161
1162 llvm_add_default_components $2
1163 llvm_add_component "bitreader" $2
1164 llvm_add_component "ipo" $2
1165
1166 if test "x$have_libelf" != xyes; then
1167 AC_MSG_ERROR([$2 requires libelf when using llvm])
1168 fi
1169 }
1170
1171 llvm_set_environment_variables
1172
1173 AC_SUBST([LLVM_CFLAGS])
1174 AC_SUBST([LLVM_CXXFLAGS])
1175 AC_SUBST([LLVM_LIBS])
1176 AC_SUBST([LLVM_LDFLAGS])
1177 AC_SUBST([LLVM_INCLUDEDIR])
1178
1179 dnl
1180 dnl libunwind
1181 dnl
1182 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1183 AC_ARG_ENABLE([libunwind],
1184 [AS_HELP_STRING([--enable-libunwind],
1185 [Use libunwind for backtracing (default: auto)])],
1186 [LIBUNWIND="$enableval"],
1187 [LIBUNWIND="$HAVE_LIBUNWIND"])
1188
1189 if test "x$LIBUNWIND" = "xyes"; then
1190 PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1191 AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1192 fi
1193
1194
1195 dnl Options for APIs
1196 AC_ARG_ENABLE([opengl],
1197 [AS_HELP_STRING([--disable-opengl],
1198 [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1199 [enable_opengl="$enableval"],
1200 [enable_opengl=yes])
1201 AC_ARG_ENABLE([gles1],
1202 [AS_HELP_STRING([--disable-gles1],
1203 [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1204 [enable_gles1="$enableval"],
1205 [enable_gles1=yes])
1206 AC_ARG_ENABLE([gles2],
1207 [AS_HELP_STRING([--disable-gles2],
1208 [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1209 [enable_gles2="$enableval"],
1210 [enable_gles2=yes])
1211
1212 AC_ARG_ENABLE([dri],
1213 [AS_HELP_STRING([--enable-dri],
1214 [enable DRI modules @<:@default=enabled@:>@])],
1215 [enable_dri="$enableval"],
1216 [enable_dri=yes])
1217
1218 AC_ARG_ENABLE([gallium-extra-hud],
1219 [AS_HELP_STRING([--enable-gallium-extra-hud],
1220 [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1221 [enable_gallium_extra_hud="$enableval"],
1222 [enable_gallium_extra_hud=no])
1223 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1224 if test "x$enable_gallium_extra_hud" = xyes ; then
1225 DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1226 fi
1227
1228 #TODO: no pkgconfig .pc available for libsensors.
1229 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1230 AC_ARG_ENABLE([lmsensors],
1231 [AS_HELP_STRING([--enable-lmsensors],
1232 [enable HUD lmsensor support @<:@default=disabled@:>@])],
1233 [enable_lmsensors="$enableval"],
1234 [enable_lmsensors=no])
1235 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1236 if test "x$enable_lmsensors" = xyes ; then
1237 DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1238 LIBSENSORS_LIBS="-lsensors"
1239 else
1240 LIBSENSORS_LIBS=""
1241 fi
1242 AC_SUBST(LIBSENSORS_LIBS)
1243
1244 case "$host_os" in
1245 linux*)
1246 dri3_default=yes
1247 ;;
1248 *)
1249 dri3_default=no
1250 ;;
1251 esac
1252
1253 if test "x$enable_dri" = xno; then
1254 dri3_default=no
1255 fi
1256
1257 AC_ARG_ENABLE([dri3],
1258 [AS_HELP_STRING([--enable-dri3],
1259 [enable DRI3 @<:@default=auto@:>@])],
1260 [enable_dri3="$enableval"],
1261 [enable_dri3="$dri3_default"])
1262 AC_ARG_ENABLE([glx],
1263 [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1264 [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1265 [enable_glx="$enableval"],
1266 [enable_glx=yes])
1267 AC_ARG_ENABLE([osmesa],
1268 [AS_HELP_STRING([--enable-osmesa],
1269 [enable OSMesa library @<:@default=disabled@:>@])],
1270 [enable_osmesa="$enableval"],
1271 [enable_osmesa=no])
1272 AC_ARG_ENABLE([gallium-osmesa],
1273 [AS_HELP_STRING([--enable-gallium-osmesa],
1274 [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1275 [enable_gallium_osmesa="$enableval"],
1276 [enable_gallium_osmesa=no])
1277 AC_ARG_ENABLE([egl],
1278 [AS_HELP_STRING([--disable-egl],
1279 [disable EGL library @<:@default=enabled@:>@])],
1280 [enable_egl="$enableval"],
1281 [enable_egl=yes])
1282
1283 AC_ARG_ENABLE([xa],
1284 [AS_HELP_STRING([--enable-xa],
1285 [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1286 [enable_xa="$enableval"],
1287 [enable_xa=no])
1288 AC_ARG_ENABLE([gbm],
1289 [AS_HELP_STRING([--enable-gbm],
1290 [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1291 [enable_gbm="$enableval"],
1292 [case "$host_os" in
1293 cygwin* | darwin*)
1294 enable_gbm=no
1295 ;;
1296 *)
1297 enable_gbm=yes
1298 ;;
1299 esac])
1300 AC_ARG_ENABLE([nine],
1301 [AS_HELP_STRING([--enable-nine],
1302 [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1303 [enable_nine="$enableval"],
1304 [enable_nine=no])
1305
1306 AC_ARG_ENABLE([xvmc],
1307 [AS_HELP_STRING([--enable-xvmc],
1308 [enable xvmc library @<:@default=auto@:>@])],
1309 [enable_xvmc="$enableval"],
1310 [enable_xvmc=auto])
1311 AC_ARG_ENABLE([vdpau],
1312 [AS_HELP_STRING([--enable-vdpau],
1313 [enable vdpau library @<:@default=auto@:>@])],
1314 [enable_vdpau="$enableval"],
1315 [enable_vdpau=auto])
1316 AC_ARG_ENABLE([omx],
1317 [AS_HELP_STRING([--enable-omx],
1318 [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1319 [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1320 [])
1321 AC_ARG_ENABLE([omx-bellagio],
1322 [AS_HELP_STRING([--enable-omx-bellagio],
1323 [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1324 [enable_omx_bellagio="$enableval"],
1325 [enable_omx_bellagio=no])
1326 AC_ARG_ENABLE([omx-tizonia],
1327 [AS_HELP_STRING([--enable-omx-tizonia],
1328 [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1329 [enable_omx_tizonia="$enableval"],
1330 [enable_omx_tizonia=no])
1331 AC_ARG_ENABLE([va],
1332 [AS_HELP_STRING([--enable-va],
1333 [enable va library @<:@default=auto@:>@])],
1334 [enable_va="$enableval"],
1335 [enable_va=auto])
1336 AC_ARG_ENABLE([opencl],
1337 [AS_HELP_STRING([--enable-opencl],
1338 [enable OpenCL library @<:@default=disabled@:>@])],
1339 [enable_opencl="$enableval"],
1340 [enable_opencl=no])
1341 AC_ARG_ENABLE([opencl_icd],
1342 [AS_HELP_STRING([--enable-opencl-icd],
1343 [Build an OpenCL ICD library to be loaded by an ICD implementation
1344 @<:@default=enabled@:>@])],
1345 [enable_opencl_icd="$enableval"],
1346 [enable_opencl_icd=yes])
1347
1348 AC_ARG_ENABLE([gallium-tests],
1349 [AS_HELP_STRING([--enable-gallium-tests],
1350 [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1351 [enable_gallium_tests="$enableval"],
1352 [enable_gallium_tests=no])
1353
1354 # Option for Gallium drivers
1355
1356 # Keep this in sync with the --with-gallium-drivers help string default value
1357 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1358
1359 AC_ARG_WITH([gallium-drivers],
1360 [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1361 [comma delimited Gallium drivers list, e.g.
1362 "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,vc4,vc5,virgl,etnaviv,imx"
1363 @<:@default=r300,r600,svga,swrast@:>@])],
1364 [with_gallium_drivers="$withval"],
1365 [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1366
1367 # Doing '--without-gallium-drivers' will set this variable to 'no'. Clear it
1368 # here so that the script doesn't choke on an unknown driver name later.
1369 case "$with_gallium_drivers" in
1370 yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1371 no) with_gallium_drivers='' ;;
1372 esac
1373
1374 if test "x$enable_opengl" = xno -a \
1375 "x$enable_gles1" = xno -a \
1376 "x$enable_gles2" = xno -a \
1377 "x$enable_nine" = xno -a \
1378 "x$enable_xa" = xno -a \
1379 "x$enable_xvmc" = xno -a \
1380 "x$enable_vdpau" = xno -a \
1381 "x$enable_omx_bellagio" = xno -a \
1382 "x$enable_omx_tizonia" = xno -a \
1383 "x$enable_va" = xno -a \
1384 "x$enable_opencl" = xno; then
1385 AC_MSG_ERROR([at least one API should be enabled])
1386 fi
1387
1388 if test "x$enable_omx_bellagio" = xyes -a \
1389 "x$enable_omx_tizonia" = xyes; then
1390 AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1391 fi
1392
1393 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1394 if test "x$enable_opengl" = xno -a \
1395 "x$enable_gles1" = xyes; then
1396 AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1397 fi
1398
1399 if test "x$enable_opengl" = xno -a \
1400 "x$enable_gles2" = xyes; then
1401 AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1402 fi
1403
1404 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1405 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1406 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1407 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1408 "x$enable_gles1" = xyes -o \
1409 "x$enable_gles2" = xyes)
1410 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1411 "x$enable_gles1" = xyes -o \
1412 "x$enable_gles2" = xyes)
1413
1414 # Validate GLX options
1415 if test "x$enable_glx" = xyes; then
1416 if test "x$enable_dri" = xyes; then
1417 enable_glx=dri
1418 elif test -n "$with_gallium_drivers"; then
1419 enable_glx=gallium-xlib
1420 else
1421 enable_glx=xlib
1422 fi
1423 fi
1424 case "x$enable_glx" in
1425 xdri | xxlib | xgallium-xlib)
1426 # GLX requires OpenGL
1427 if test "x$enable_opengl" = xno; then
1428 AC_MSG_ERROR([GLX cannot be built without OpenGL])
1429 fi
1430
1431 # Check individual dependencies
1432 case "x$enable_glx" in
1433 xdri)
1434 if test "x$enable_dri" = xno; then
1435 AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1436 fi
1437 ;;
1438 xxlib)
1439 if test "x$enable_dri" = xyes; then
1440 AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1441 fi
1442 ;;
1443 xgallium-xlib )
1444 if test "x$enable_dri" = xyes; then
1445 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1446 fi
1447 if test -z "$with_gallium_drivers"; then
1448 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1449 fi
1450 ;;
1451 esac
1452 ;;
1453 xno)
1454 ;;
1455 *)
1456 AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1457 ;;
1458 esac
1459
1460 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1461 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1462 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1463 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1464
1465 DEFAULT_GL_LIB_NAME=GL
1466
1467 dnl
1468 dnl Libglvnd configuration
1469 dnl
1470 AC_ARG_ENABLE([libglvnd],
1471 [AS_HELP_STRING([--enable-libglvnd],
1472 [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1473 [enable_libglvnd="$enableval"],
1474 [enable_libglvnd=no])
1475 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1476
1477 if test "x$enable_libglvnd" = xyes ; then
1478 case "x$enable_glx" in
1479 xxlib | xgallium-xlib )
1480 AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1481 ;;
1482 esac
1483
1484 PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1485 LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1486 AC_SUBST([LIBGLVND_DATADIR])
1487
1488 DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1489 DEFAULT_GL_LIB_NAME=GLX_mesa
1490
1491 if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1492 AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1493 fi
1494 fi
1495
1496 AC_ARG_WITH([gl-lib-name],
1497 [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1498 [specify GL library name @<:@default=GL@:>@])],
1499 [GL_LIB=$withval],
1500 [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1501 AC_ARG_WITH([osmesa-lib-name],
1502 [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1503 [specify OSMesa library name @<:@default=OSMesa@:>@])],
1504 [OSMESA_LIB=$withval],
1505 [OSMESA_LIB=OSMesa])
1506 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1507 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1508
1509 dnl
1510 dnl Mangled Mesa support
1511 dnl
1512 AC_ARG_ENABLE([mangling],
1513 [AS_HELP_STRING([--enable-mangling],
1514 [enable mangled symbols and library name @<:@default=disabled@:>@])],
1515 [enable_mangling="${enableval}"],
1516 [enable_mangling=no]
1517 )
1518 if test "x${enable_mangling}" = "xyes" ; then
1519 DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1520 GL_LIB="Mangled${GL_LIB}"
1521 OSMESA_LIB="Mangled${OSMESA_LIB}"
1522 fi
1523 AC_SUBST([GL_LIB])
1524 AC_SUBST([OSMESA_LIB])
1525
1526 # Check for libdrm
1527 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1528 [have_libdrm=yes], [have_libdrm=no])
1529 if test "x$have_libdrm" = xyes; then
1530 DEFINES="$DEFINES -DHAVE_LIBDRM"
1531 fi
1532
1533 require_libdrm() {
1534 if test "x$have_libdrm" != xyes; then
1535 AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1536 fi
1537 }
1538
1539
1540 # Select which platform-dependent DRI code gets built
1541 case "$host_os" in
1542 darwin*)
1543 dri_platform='apple' ;;
1544 cygwin*)
1545 dri_platform='windows' ;;
1546 gnu*)
1547 dri_platform='none' ;;
1548 *)
1549 dri_platform='drm' ;;
1550 esac
1551
1552 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1553 have_drisw_kms='yes'
1554 fi
1555
1556 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1557 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1558 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1559 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1560 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1561 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1562 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1563 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1564 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1565
1566 AC_ARG_ENABLE([shared-glapi],
1567 [AS_HELP_STRING([--enable-shared-glapi],
1568 [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1569 [enable_shared_glapi="$enableval"],
1570 [enable_shared_glapi=yes])
1571
1572 case "x$enable_opengl$enable_gles1$enable_gles2" in
1573 x*yes*yes*)
1574 if test "x$enable_shared_glapi" = xno; then
1575 AC_MSG_ERROR([shared GLAPI required when building two or more of
1576 the following APIs - opengl, gles1 gles2])
1577 fi
1578 ;;
1579 esac
1580
1581 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1582
1583 # Build the pipe-drivers as separate libraries/modules.
1584 # Do not touch this unless you know what you are doing.
1585 # XXX: Expose via configure option ?
1586 enable_shared_pipe_drivers=no
1587
1588 dnl
1589 dnl Driver specific build directories
1590 dnl
1591
1592 if test "x$enable_gallium_osmesa" = xyes; then
1593 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1594 AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1595 fi
1596 if test "x$enable_osmesa" = xyes; then
1597 AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1598 fi
1599 fi
1600
1601 require_dri_shared_libs_and_glapi() {
1602 if test "x$enable_static" = xyes; then
1603 AC_MSG_ERROR([$1 cannot be build as static library])
1604 fi
1605
1606 if test "x$enable_dri" != xyes; then
1607 # There is only a single backend which won't be build/used otherwise.
1608 # XXX: Revisit this as the egl/haiku is a thing.
1609 AC_MSG_ERROR([$1 requires --enable-dri])
1610 fi
1611
1612 if test "x$enable_shared_glapi" != xyes; then
1613 AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1614 fi
1615 }
1616
1617 if test "x$enable_dri" = xyes; then
1618 require_dri_shared_libs_and_glapi "DRI"
1619
1620 # not a hard requirement as swrast does not depend on it
1621 if test "x$have_libdrm" = xyes; then
1622 DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1623 fi
1624 fi
1625
1626 AC_ARG_ENABLE([driglx-direct],
1627 [AS_HELP_STRING([--disable-driglx-direct],
1628 [disable direct rendering in GLX and EGL for DRI \
1629 @<:@default=enabled@:>@])],
1630 [driglx_direct="$enableval"],
1631 [driglx_direct="yes"])
1632
1633 dnl
1634 dnl libGL configuration per driver
1635 dnl
1636 if test "x$enable_glx" != xno; then
1637 PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1638 fi
1639 case "x$enable_glx" in
1640 xxlib | xgallium-xlib)
1641 # Xlib-based GLX
1642 dri_modules="x11 xext xcb"
1643 PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1644 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1645 X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1646 GL_LIB_DEPS="$XLIBGL_LIBS"
1647 GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1648 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1649 ;;
1650 xdri)
1651 # DRI-based GLX
1652
1653 # find the DRI deps for libGL
1654 dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1655
1656 if test x"$driglx_direct" = xyes; then
1657 if test x"$dri_platform" = xdrm ; then
1658 DEFINES="$DEFINES -DGLX_USE_DRM"
1659 require_libdrm "Direct rendering"
1660
1661 PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1662 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1663
1664 if test x"$enable_dri" = xyes; then
1665 dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1666 fi
1667 fi
1668 if test x"$dri_platform" = xapple ; then
1669 DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1670 fi
1671 if test x"$dri_platform" = xwindows ; then
1672 DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1673 fi
1674 fi
1675
1676 # add xf86vidmode if available
1677 PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1678 if test "$HAVE_XF86VIDMODE" = yes ; then
1679 dri_modules="$dri_modules xxf86vm"
1680 fi
1681
1682 PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1683 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1684 X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1685 GL_LIB_DEPS="$DRIGL_LIBS"
1686
1687 # need DRM libs, $PTHREAD_LIBS, etc.
1688 GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1689 GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1690 ;;
1691 esac
1692
1693 # This is outside the case (above) so that it is invoked even for non-GLX
1694 # builds.
1695 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1696
1697 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1698 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1699 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1700 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1701
1702 AC_SUBST([X11_INCLUDES])
1703 AC_SUBST([GL_LIB_DEPS])
1704 AC_SUBST([GL_PC_REQ_PRIV])
1705 AC_SUBST([GL_PC_LIB_PRIV])
1706 AC_SUBST([GL_PC_CFLAGS])
1707 AC_SUBST([DRI_PC_REQ_PRIV])
1708 AC_SUBST([GLESv1_CM_LIB_DEPS])
1709 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1710 AC_SUBST([GLESv2_LIB_DEPS])
1711 AC_SUBST([GLESv2_PC_LIB_PRIV])
1712
1713 AC_SUBST([HAVE_XF86VIDMODE])
1714
1715 dnl
1716 dnl More GLX setup
1717 dnl
1718 case "x$enable_glx" in
1719 xxlib | xgallium-xlib)
1720 DEFINES="$DEFINES -DUSE_XSHM"
1721 ;;
1722 xdri)
1723 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1724 if test "x$driglx_direct" = xyes; then
1725 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1726 fi
1727 ;;
1728 esac
1729
1730 dnl
1731 dnl TLS detection
1732 dnl
1733
1734 AC_ARG_ENABLE([glx-tls],
1735 [AS_HELP_STRING([--enable-glx-tls],
1736 [enable TLS support in GLX @<:@default=enabled@:>@])],
1737 [GLX_USE_TLS="$enableval"],
1738 [GLX_USE_TLS=yes])
1739 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1740
1741 if test "x$GLX_USE_TLS" = xyes; then
1742 DEFINES="$DEFINES -DGLX_USE_TLS"
1743 fi
1744
1745 dnl Read-only text section on x86 hardened platforms
1746 AC_ARG_ENABLE([glx-read-only-text],
1747 [AS_HELP_STRING([--enable-glx-read-only-text],
1748 [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1749 [enable_glx_read_only_text="$enableval"],
1750 [enable_glx_read_only_text=no])
1751 if test "x$enable_glx_read_only_text" = xyes; then
1752 DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1753 fi
1754
1755 dnl
1756 dnl DEPRECATED: EGL Platforms configuration
1757 dnl
1758 AC_ARG_WITH([egl-platforms],
1759 [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1760 [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1761 [with_egl_platforms="$withval"],
1762 [with_egl_platforms=auto])
1763
1764 if test "x$with_egl_platforms" = xauto; then
1765 with_egl_platforms="x11,surfaceless"
1766 if test "x$enable_gbm" = xyes; then
1767 with_egl_platforms="$with_egl_platforms,drm"
1768 fi
1769 else
1770 AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1771 fi
1772
1773 dnl
1774 dnl Platforms configuration
1775 dnl
1776 AC_ARG_WITH([platforms],
1777 [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1778 [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1779 "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1780 [with_platforms="$withval"],
1781 [with_platforms=auto])
1782
1783 # Reuse the autodetection rather than duplicating it.
1784 if test "x$with_platforms" = xauto; then
1785 with_platforms=$with_egl_platforms
1786 fi
1787
1788 # Do per platform setups and checks
1789 platforms=`IFS=', '; echo $with_platforms`
1790 for plat in $platforms; do
1791 case "$plat" in
1792 wayland)
1793
1794 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1795 PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1796 PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1797 WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1798
1799 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1800 WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1801 WAYLAND_SCANNER='')
1802 if test "x$WAYLAND_SCANNER" = x; then
1803 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1804 fi
1805
1806 if test "x$WAYLAND_SCANNER" = "x:"; then
1807 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1808 fi
1809 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1810 ;;
1811
1812 x11)
1813 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1814 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1815 ;;
1816
1817 drm)
1818 test "x$enable_gbm" = "xno" &&
1819 AC_MSG_ERROR([EGL platform drm needs gbm])
1820 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1821 ;;
1822
1823 surfaceless)
1824 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1825 ;;
1826
1827 android)
1828 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1829 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1830 ;;
1831
1832 *)
1833 AC_MSG_ERROR([platform '$plat' does not exist])
1834 ;;
1835 esac
1836
1837 case "$plat" in
1838 wayland|drm|surfaceless)
1839 require_libdrm "Platform $plat"
1840 ;;
1841 esac
1842 done
1843 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1844
1845 if test "x$enable_glx" != xno; then
1846 if ! echo "$platforms" | grep -q 'x11'; then
1847 AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1848 fi
1849 fi
1850
1851 if test x"$enable_dri3" = xyes; then
1852 DEFINES="$DEFINES -DHAVE_DRI3"
1853
1854 dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 >= $XCBDRI3_REQUIRED xcb-xfixes xcb-present >= $XCBPRESENT_REQUIRED xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1855 PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1856 fi
1857
1858 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1859 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1860 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1861 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1862 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1863
1864 dnl
1865 dnl More DRI setup
1866 dnl
1867 dnl Directory for DRI drivers
1868 AC_ARG_WITH([dri-driverdir],
1869 [AS_HELP_STRING([--with-dri-driverdir=DIR],
1870 [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1871 [DRI_DRIVER_INSTALL_DIR="$withval"],
1872 [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1873 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1874 dnl Extra search path for DRI drivers
1875 AC_ARG_WITH([dri-searchpath],
1876 [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1877 [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1878 [DRI_DRIVER_SEARCH_DIR="$withval"],
1879 [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1880 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1881 dnl Which drivers to build - default is chosen by platform
1882 AC_ARG_WITH([dri-drivers],
1883 [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1884 [comma delimited classic DRI drivers list, e.g.
1885 "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1886 [with_dri_drivers="$withval"],
1887 [with_dri_drivers=auto])
1888
1889 if test "x$with_dri_drivers" = xauto; then
1890 if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1891 with_dri_drivers="yes"
1892 else
1893 with_dri_drivers="no"
1894 fi
1895 fi
1896 if test "x$with_dri_drivers" = xno; then
1897 with_dri_drivers=''
1898 fi
1899
1900 # Check for expat
1901 PKG_CHECK_MODULES([EXPAT], [expat],,
1902 [PKG_CHECK_MODULES([EXPAT], [expat21])]
1903 )
1904
1905 dnl If $with_dri_drivers is yes, drivers will be added through
1906 dnl platform checks. Set DEFINES and LIB_DEPS
1907 if test "x$enable_dri" = xyes; then
1908 # Platform specific settings and drivers to build
1909 case "$host_os" in
1910 linux*)
1911 case "$host_cpu" in
1912 powerpc* | sparc*)
1913 # Build only the drivers for cards that exist on PowerPC/sparc
1914 if test "x$with_dri_drivers" = "xyes"; then
1915 with_dri_drivers="r200 radeon swrast"
1916 fi
1917 ;;
1918 esac
1919 ;;
1920 cygwin*)
1921 if test "x$with_dri_drivers" = "xyes"; then
1922 with_dri_drivers="swrast"
1923 fi
1924 ;;
1925 darwin*)
1926 DEFINES="$DEFINES -DBUILDING_MESA"
1927 if test "x$with_dri_drivers" = "xyes"; then
1928 with_dri_drivers="swrast"
1929 fi
1930 ;;
1931 esac
1932
1933 # default drivers
1934 if test "x$with_dri_drivers" = "xyes"; then
1935 with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1936 fi
1937
1938 # put all the necessary libs together
1939 DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1940 fi
1941
1942 AC_SUBST([DRI_LIB_DEPS])
1943
1944 DRI_DIRS=''
1945 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1946 if test -n "$with_dri_drivers"; then
1947 if test "x$enable_opengl" != xyes; then
1948 AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1949 fi
1950
1951 dri_drivers=`IFS=', '; echo $with_dri_drivers`
1952 for driver in $dri_drivers; do
1953 DRI_DIRS="$DRI_DIRS $driver"
1954 case "x$driver" in
1955 xi915)
1956 require_libdrm "i915"
1957 HAVE_I915_DRI=yes
1958 PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1959 ;;
1960 xi965)
1961 require_libdrm "i965"
1962 HAVE_I965_DRI=yes
1963 ;;
1964 xnouveau)
1965 require_libdrm "nouveau"
1966 HAVE_NOUVEAU_DRI=yes
1967 PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1968 ;;
1969 xradeon)
1970 require_libdrm "radeon"
1971 HAVE_RADEON_DRI=yes;
1972 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1973 ;;
1974 xr200)
1975 require_libdrm "r200"
1976 HAVE_R200_DRI=yes
1977 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1978 ;;
1979 xswrast)
1980 HAVE_SWRAST_DRI=yes
1981 ;;
1982 *)
1983 AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1984 ;;
1985 esac
1986 done
1987 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1988 fi
1989
1990
1991 dnl
1992 dnl Gallium LLVM
1993 dnl Deprecated: kept for backwards compatibility
1994 dnl
1995 AC_ARG_ENABLE([gallium-llvm],
1996 [AS_HELP_STRING([--enable-gallium-llvm],
1997 [DEPRECATED: use --enable-llvm instead])],
1998 [enable_gallium_llvm="$enableval"],
1999 [enable_gallium_llvm=auto])
2000
2001 if test "x$enable_gallium_llvm" != xauto; then
2002 AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2003 enable_llvm=$enable_gallium_llvm
2004 fi
2005
2006 dnl
2007 dnl LLVM
2008 dnl
2009 AC_ARG_ENABLE([llvm],
2010 [AS_HELP_STRING([--enable-llvm],
2011 [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2012 [enable_llvm="$enableval"],
2013 [enable_llvm=auto])
2014
2015 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2016 if test "x$FOUND_LLVM" = xyes; then
2017 case "$host_cpu" in
2018 i*86|x86_64|amd64) enable_llvm=yes;;
2019 *) enable_llvm=no;;
2020 esac
2021 else
2022 enable_llvm=no
2023 fi
2024 fi
2025
2026 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2027 AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2028 fi
2029
2030 #
2031 # Vulkan driver configuration
2032 #
2033
2034 AC_ARG_WITH([vulkan-drivers],
2035 [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2036 [comma delimited Vulkan drivers list, e.g.
2037 "intel,radeon"
2038 @<:@default=no@:>@])],
2039 [with_vulkan_drivers="$withval"],
2040 [with_vulkan_drivers="no"])
2041
2042 # Doing '--without-vulkan-drivers' will set this variable to 'no'. Clear it
2043 # here so that the script doesn't choke on an unknown driver name later.
2044 case "x$with_vulkan_drivers" in
2045 xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2046 xno) with_vulkan_drivers='' ;;
2047 esac
2048
2049 AC_ARG_WITH([vulkan-icddir],
2050 [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2051 [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2052 [VULKAN_ICD_INSTALL_DIR="$withval"],
2053 [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2054 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2055
2056 require_x11_dri3() {
2057 if echo "$platforms" | grep -q 'x11'; then
2058 if test "x$enable_dri3" != xyes; then
2059 AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2060 fi
2061 fi
2062 }
2063
2064 if test -n "$with_vulkan_drivers"; then
2065 if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2066 AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2067 fi
2068
2069 VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2070 for driver in $VULKAN_DRIVERS; do
2071 case "x$driver" in
2072 xintel)
2073 require_libdrm "ANV"
2074 require_x11_dri3 "ANV"
2075 HAVE_INTEL_VULKAN=yes
2076 ;;
2077 xradeon)
2078 require_libdrm "radv"
2079 PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2080 radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2081 require_x11_dri3 "radv"
2082 HAVE_RADEON_VULKAN=yes
2083 ;;
2084 *)
2085 AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2086 ;;
2087 esac
2088 done
2089 VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2090 fi
2091
2092
2093 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2094 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2095 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2096 "x$enable_osmesa" = xyes -o \
2097 -n "$DRI_DIRS")
2098
2099 dnl
2100 dnl OSMesa configuration
2101 dnl
2102
2103 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2104 AC_ARG_WITH([osmesa-bits],
2105 [AS_HELP_STRING([--with-osmesa-bits=BITS],
2106 [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2107 [osmesa_bits="$withval"],
2108 [osmesa_bits=8])
2109 if test "x$osmesa_bits" != x8; then
2110 if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2111 AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2112 osmesa_bits=8
2113 fi
2114 fi
2115 case "x$osmesa_bits" in
2116 x8)
2117 OSMESA_LIB="${OSMESA_LIB}"
2118 ;;
2119 x16|x32)
2120 OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2121 DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2122 ;;
2123 *)
2124 AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2125 ;;
2126 esac
2127
2128 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2129 # only link libraries with osmesa if shared
2130 if test "$enable_static" = no; then
2131 OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2132 else
2133 OSMESA_LIB_DEPS=""
2134 fi
2135 OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2136 fi
2137
2138 AC_SUBST([OSMESA_LIB_DEPS])
2139 AC_SUBST([OSMESA_PC_REQ])
2140 AC_SUBST([OSMESA_PC_LIB_PRIV])
2141
2142 dnl
2143 dnl gbm configuration
2144 dnl
2145 if test "x$enable_gbm" = xyes; then
2146 require_dri_shared_libs_and_glapi "gbm"
2147 fi
2148 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2149 # FINISHME: GBM has a number of dependencies which we should add below
2150 GBM_PC_REQ_PRIV=""
2151 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2152 AC_SUBST([GBM_PC_REQ_PRIV])
2153 AC_SUBST([GBM_PC_LIB_PRIV])
2154
2155 dnl
2156 dnl EGL configuration
2157 dnl
2158
2159 if test "x$enable_egl" = xyes; then
2160 EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2161
2162 AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2163
2164 require_dri_shared_libs_and_glapi "egl"
2165 fi
2166 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2167 AC_SUBST([EGL_LIB_DEPS])
2168
2169 gallium_st="mesa"
2170
2171 dnl
2172 dnl XA configuration
2173 dnl
2174 if test "x$enable_xa" = xyes; then
2175 if test "x$with_gallium_drivers" = xswrast; then
2176 AC_MSG_ERROR([
2177 Building xa requires at least one non swrast gallium driver.
2178 If you are looking to use libxatracker.so with the VMware driver,
2179 make sure to include svga in the gallium drivers list, apart from
2180 enabling XA.
2181 Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2182 fi
2183 gallium_st="$gallium_st xa"
2184 fi
2185 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2186
2187 if echo $platforms | grep -q "x11"; then
2188 have_xvmc_platform=yes
2189 else
2190 have_xvmc_platform=no
2191 fi
2192
2193 if echo $platforms | grep -q "x11"; then
2194 have_vdpau_platform=yes
2195 else
2196 have_vdpau_platform=no
2197 fi
2198
2199 if echo $platforms | grep -q "x11\|drm"; then
2200 have_omx_platform=yes
2201 else
2202 have_omx_platform=no
2203 fi
2204
2205 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2206 have_va_platform=yes
2207 else
2208 have_va_platform=no
2209 fi
2210
2211 dnl
2212 dnl Gallium G3DVL configuration
2213 dnl
2214 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2215 if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2216 PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2217 fi
2218
2219 if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2220 PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2221 fi
2222
2223 if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2224 PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2225 fi
2226
2227 if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2228 PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2229 fi
2230
2231 if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2232 PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2233 fi
2234 fi
2235
2236 if test "x$enable_dri" = xyes -o \
2237 "x$enable_xvmc" = xyes -o \
2238 "x$enable_vdpau" = xyes -o \
2239 "x$enable_omx_bellagio" = xyes -o \
2240 "x$enable_omx_tizonia" = xyes -o \
2241 "x$enable_va" = xyes; then
2242 need_gallium_vl=yes
2243 fi
2244 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2245
2246 if test "x$enable_xvmc" = xyes -o \
2247 "x$enable_vdpau" = xyes -o \
2248 "x$enable_omx_bellagio" = xyes -o \
2249 "x$enable_omx_tizonia" = xyes -o \
2250 "x$enable_va" = xyes; then
2251 if echo $platforms | grep -q "x11"; then
2252 PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2253 fi
2254 need_gallium_vl_winsys=yes
2255 fi
2256 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2257
2258 if test "x$enable_xvmc" = xyes; then
2259 if test "x$have_xvmc_platform" != xyes; then
2260 AC_MSG_ERROR([XVMC requires the x11 platforms])
2261 fi
2262 PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2263 gallium_st="$gallium_st xvmc"
2264 fi
2265 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2266
2267 if test "x$enable_vdpau" = xyes; then
2268 if test "x$have_vdpau_platform" != xyes; then
2269 AC_MSG_ERROR([VDPAU requires the x11 platforms])
2270 fi
2271 PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2272 gallium_st="$gallium_st vdpau"
2273 DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2274 fi
2275 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2276
2277 if test "x$enable_omx_bellagio" = xyes; then
2278 if test "x$have_omx_platform" != xyes; then
2279 AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2280 fi
2281 PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2282 gallium_st="$gallium_st omx_bellagio"
2283 AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2284 fi
2285 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2286
2287 if test "x$enable_omx_tizonia" = xyes; then
2288 if test "x$have_omx_platform" != xyes; then
2289 AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2290 fi
2291 PKG_CHECK_MODULES([OMX_TIZONIA],
2292 [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2293 tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2294 libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2295 gallium_st="$gallium_st omx_tizonia"
2296 AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2297 fi
2298 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2299
2300 if test "x$enable_va" = xyes; then
2301 if test "x$have_va_platform" != xyes; then
2302 AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2303 fi
2304 PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2305 gallium_st="$gallium_st va"
2306 fi
2307 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2308
2309 dnl
2310 dnl Nine Direct3D9 configuration
2311 dnl
2312 if test "x$enable_nine" = xyes; then
2313 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2314 AC_MSG_ERROR([nine requires the gallium swrast driver])
2315 fi
2316 if test "x$with_gallium_drivers" = xswrast; then
2317 AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2318 fi
2319 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2320 AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2321 fi
2322
2323 if test "x$enable_dri3" = xno; then
2324 AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2325 fi
2326
2327 gallium_st="$gallium_st nine"
2328 fi
2329 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2330
2331 dnl
2332 dnl OpenCL configuration
2333 dnl
2334
2335 AC_ARG_WITH([clang-libdir],
2336 [AS_HELP_STRING([--with-clang-libdir],
2337 [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2338 [CLANG_LIBDIR="$withval"],
2339 [CLANG_LIBDIR=''])
2340
2341 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2342
2343 if test "x$enable_opencl" = xyes; then
2344 if test -z "$with_gallium_drivers"; then
2345 AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2346 fi
2347
2348 if test "x$HAVE_CXX11" != "xyes"; then
2349 AC_MSG_ERROR([clover requires c++11 support])
2350 fi
2351
2352 if test "x$have_libclc" = xno; then
2353 AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2354 Make sure the directory containing libclc.pc is specified in your
2355 PKG_CONFIG_PATH environment variable.
2356 By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2357 else
2358 LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2359 LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2360 AC_SUBST([LIBCLC_INCLUDEDIR])
2361 AC_SUBST([LIBCLC_LIBEXECDIR])
2362 fi
2363
2364 gallium_st="$gallium_st clover"
2365
2366 if test "x$enable_opencl_icd" = xyes; then
2367 OPENCL_LIBNAME="MesaOpenCL"
2368 else
2369 OPENCL_LIBNAME="OpenCL"
2370 fi
2371
2372 if test "x$have_libelf" != xyes; then
2373 AC_MSG_ERROR([Clover requires libelf])
2374 fi
2375
2376 if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2377 altivec_enabled=no
2378 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2379 #if !defined(__VEC__) || !defined(__ALTIVEC__)
2380 #error "AltiVec not enabled"
2381 #endif
2382 ])], altivec_enabled=yes)
2383
2384 if test "$altivec_enabled" = yes; then
2385 CLOVER_STD_OVERRIDE="-std=gnu++11"
2386 fi
2387 AC_SUBST([CLOVER_STD_OVERRIDE])
2388 fi
2389
2390 llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2391
2392 llvm_add_default_components "opencl"
2393 llvm_add_component "all-targets" "opencl"
2394 llvm_add_component "coverage" "opencl"
2395 llvm_add_component "linker" "opencl"
2396 llvm_add_component "instrumentation" "opencl"
2397 llvm_add_component "ipo" "opencl"
2398 llvm_add_component "irreader" "opencl"
2399 llvm_add_component "lto" "opencl"
2400 llvm_add_component "option" "opencl"
2401 llvm_add_component "objcarcopts" "opencl"
2402 llvm_add_component "profiledata" "opencl"
2403 llvm_add_optional_component "coroutines" "opencl"
2404
2405 dnl Check for Clang internal headers
2406 if test -z "$CLANG_LIBDIR"; then
2407 CLANG_LIBDIR=${LLVM_LIBDIR}
2408 fi
2409 CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2410 AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2411 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2412 fi
2413 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2414 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2415 AC_SUBST([OPENCL_LIBNAME])
2416 AC_SUBST([CLANG_RESOURCE_DIR])
2417
2418 dnl
2419 dnl Gallium configuration
2420 dnl
2421 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2422
2423 # libEGL wants to default to the first platform specified in
2424 # ./configure. parse that here.
2425 if test "x$platforms" != "x"; then
2426 FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2427 EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2428 else
2429 EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2430 fi
2431
2432 AC_SUBST([EGL_NATIVE_PLATFORM])
2433 AC_SUBST([EGL_CFLAGS])
2434
2435 # If we don't have the X11 platform, set this define so we don't try to include
2436 # the X11 headers.
2437 if ! echo "$platforms" | grep -q 'x11'; then
2438 DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2439 GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2440 fi
2441
2442 dnl Directory for XVMC libs
2443 AC_ARG_WITH([xvmc-libdir],
2444 [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2445 [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2446 [XVMC_LIB_INSTALL_DIR="$withval"],
2447 [XVMC_LIB_INSTALL_DIR='${libdir}'])
2448 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2449
2450 dnl
2451 dnl Gallium Tests
2452 dnl
2453 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2454
2455 dnl Directory for VDPAU libs
2456 AC_ARG_WITH([vdpau-libdir],
2457 [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2458 [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2459 [VDPAU_LIB_INSTALL_DIR="$withval"],
2460 [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2461 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2462
2463 dnl Directory for OMX_BELLAGIO libs
2464
2465 AC_ARG_WITH([omx-bellagio-libdir],
2466 [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2467 [directory for the OMX_BELLAGIO libraries])],
2468 [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2469 [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2470 $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2471 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2472
2473 dnl Directory for OMX_TIZONIA libs
2474
2475 AC_ARG_WITH([omx-tizonia-libdir],
2476 [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2477 [directory for the OMX_TIZONIA libraries])],
2478 [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2479 [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2480 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2481
2482 dnl Directory for VA libs
2483
2484 AC_ARG_WITH([va-libdir],
2485 [AS_HELP_STRING([--with-va-libdir=DIR],
2486 [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2487 [VA_LIB_INSTALL_DIR="$withval"],
2488 [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2489 AC_SUBST([VA_LIB_INSTALL_DIR])
2490
2491 AC_ARG_WITH([d3d-libdir],
2492 [AS_HELP_STRING([--with-d3d-libdir=DIR],
2493 [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2494 [D3D_DRIVER_INSTALL_DIR="$withval"],
2495 [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2496 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2497
2498 dnl Architectures to build SWR library for
2499
2500 AC_ARG_WITH([swr-archs],
2501 [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2502 [comma delimited swr architectures list, e.g.
2503 "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2504 [with_swr_archs="$withval"],
2505 [with_swr_archs="avx,avx2"])
2506
2507 dnl
2508 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2509 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2510 dnl architectures.
2511 dnl
2512 r300_require_llvm() {
2513 case "$host" in *gnux32) return;; esac
2514 case "$host_cpu" in
2515 i*86|x86_64|amd64) require_llvm $1
2516 ;;
2517 esac
2518 }
2519
2520 dnl
2521 dnl DRM is needed by X, Wayland, and offscreen rendering.
2522 dnl Surfaceless is an alternative for the last one.
2523 dnl
2524 require_basic_egl() {
2525 case "$with_platforms" in
2526 *drm*|*surfaceless*|*android*)
2527 ;;
2528 *)
2529 AC_MSG_ERROR([$1 requires one of these:
2530 1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2531 2) --with-platforms=surfaceless (offscreen only)
2532 3) --with-platforms=android (Android only)
2533 Recommended options: drm,x11])
2534 ;;
2535 esac
2536 }
2537
2538 swr_require_cxx_feature_flags() {
2539 feature_name="$1"
2540 preprocessor_test="$2"
2541 option_list="$3"
2542 output_var="$4"
2543
2544 AC_MSG_CHECKING([whether $CXX supports $feature_name])
2545 AC_LANG_PUSH([C++])
2546 save_CXXFLAGS="$CXXFLAGS"
2547 save_IFS="$IFS"
2548 IFS=","
2549 found=0
2550 for opts in $option_list
2551 do
2552 unset IFS
2553 CXXFLAGS="$opts $save_CXXFLAGS"
2554 AC_COMPILE_IFELSE(
2555 [AC_LANG_PROGRAM(
2556 [ #if !($preprocessor_test)
2557 #error
2558 #endif
2559 ])],
2560 [found=1; break],
2561 [])
2562 IFS=","
2563 done
2564 IFS="$save_IFS"
2565 CXXFLAGS="$save_CXXFLAGS"
2566 AC_LANG_POP([C++])
2567 if test $found -eq 1; then
2568 AC_MSG_RESULT([$opts])
2569 eval "$output_var=\$opts"
2570 return 0
2571 fi
2572 AC_MSG_RESULT([no])
2573 AC_MSG_ERROR([swr requires $feature_name support])
2574 return 1
2575 }
2576
2577 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2578 if test -n "$with_gallium_drivers"; then
2579 gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2580 for driver in $gallium_drivers; do
2581 case "x$driver" in
2582 xsvga)
2583 HAVE_GALLIUM_SVGA=yes
2584 require_libdrm "svga"
2585 ;;
2586 xi915)
2587 HAVE_GALLIUM_I915=yes
2588 PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2589 require_libdrm "Gallium i915"
2590 ;;
2591 xr300)
2592 HAVE_GALLIUM_R300=yes
2593 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2594 require_libdrm "r300"
2595 r300_require_llvm "r300"
2596 ;;
2597 xr600)
2598 HAVE_GALLIUM_R600=yes
2599 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2600 require_libdrm "r600"
2601 if test "x$enable_llvm" = xyes; then
2602 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2603
2604 llvm_add_component "asmparser" "r600"
2605 llvm_add_component "bitreader" "r600"
2606 fi
2607 ;;
2608 xradeonsi)
2609 HAVE_GALLIUM_RADEONSI=yes
2610 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2611 PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2612 require_libdrm "radeonsi"
2613 radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2614 if test "x$enable_egl" = xyes; then
2615 require_basic_egl "radeonsi"
2616 fi
2617 ;;
2618 xnouveau)
2619 HAVE_GALLIUM_NOUVEAU=yes
2620 PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2621 require_libdrm "nouveau"
2622 ;;
2623 xfreedreno)
2624 HAVE_GALLIUM_FREEDRENO=yes
2625 PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2626 require_libdrm "freedreno"
2627 ;;
2628 xetnaviv)
2629 HAVE_GALLIUM_ETNAVIV=yes
2630 PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2631 require_libdrm "etnaviv"
2632 ;;
2633 ximx)
2634 HAVE_GALLIUM_IMX=yes
2635 ;;
2636 xtegra)
2637 HAVE_GALLIUM_TEGRA=yes
2638 require_libdrm "tegra"
2639 ;;
2640 xswrast)
2641 HAVE_GALLIUM_SOFTPIPE=yes
2642 if test "x$enable_llvm" = xyes; then
2643 HAVE_GALLIUM_LLVMPIPE=yes
2644 fi
2645 ;;
2646 xswr)
2647 llvm_require_version $LLVM_REQUIRED_SWR "swr"
2648
2649 if test "x$HAVE_CXX11" != "xyes"; then
2650 AC_MSG_ERROR([swr requires c++11 support])
2651 fi
2652
2653 swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2654 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2655 SWR_AVX_CXXFLAGS
2656 AC_SUBST([SWR_AVX_CXXFLAGS])
2657
2658 swr_archs=`IFS=', '; echo $with_swr_archs`
2659 for arch in $swr_archs; do
2660 case "x$arch" in
2661 xavx)
2662 HAVE_SWR_AVX=yes
2663 ;;
2664 xavx2)
2665 swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2666 ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2667 SWR_AVX2_CXXFLAGS
2668 AC_SUBST([SWR_AVX2_CXXFLAGS])
2669 HAVE_SWR_AVX2=yes
2670 ;;
2671 xknl)
2672 swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2673 ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2674 SWR_KNL_CXXFLAGS
2675 AC_SUBST([SWR_KNL_CXXFLAGS])
2676 HAVE_SWR_KNL=yes
2677 ;;
2678 xskx)
2679 swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2680 ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2681 SWR_SKX_CXXFLAGS
2682 AC_SUBST([SWR_SKX_CXXFLAGS])
2683 HAVE_SWR_SKX=yes
2684 ;;
2685 *)
2686 AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2687 ;;
2688 esac
2689 done
2690
2691 if test "x$HAVE_SWR_AVX" != xyes -a \
2692 "x$HAVE_SWR_AVX2" != xyes -a \
2693 "x$HAVE_SWR_KNL" != xyes -a \
2694 "x$HAVE_SWR_SKX" != xyes; then
2695 AC_MSG_ERROR([swr enabled but no swr architectures selected])
2696 fi
2697
2698 # test if more than one swr arch configured
2699 if test `echo $swr_archs | wc -w` -eq 1; then
2700 HAVE_SWR_BUILTIN=yes
2701 fi
2702
2703 HAVE_GALLIUM_SWR=yes
2704 ;;
2705 xvc4)
2706 HAVE_GALLIUM_VC4=yes
2707 require_libdrm "vc4"
2708
2709 PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2710 [USE_VC4_SIMULATOR=yes;
2711 DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2712 [USE_VC4_SIMULATOR=no])
2713 ;;
2714 xvc5)
2715 HAVE_GALLIUM_VC5=yes
2716
2717 PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2718 [USE_VC5_SIMULATOR=yes;
2719 DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2720 [AC_MSG_ERROR([vc5 requires the simulator])])
2721 ;;
2722 xpl111)
2723 HAVE_GALLIUM_PL111=yes
2724 ;;
2725 xvirgl)
2726 HAVE_GALLIUM_VIRGL=yes
2727 require_libdrm "virgl"
2728 if test "x$enable_egl" = xyes; then
2729 require_basic_egl "virgl"
2730 fi
2731 ;;
2732 *)
2733 AC_MSG_ERROR([Unknown Gallium driver: $driver])
2734 ;;
2735 esac
2736 done
2737 fi
2738
2739 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2740 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x4.0.0 -a \
2741 "x$LLVM_VERSION" != x4.0.1)
2742
2743 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2744 llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2745 llvm_add_default_components "gallium"
2746 fi
2747
2748 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2749 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2750 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2751 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2752 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2753
2754 dnl We need to validate some needed dependencies for renderonly drivers.
2755
2756 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes ; then
2757 AC_MSG_ERROR([Building with imx requires etnaviv])
2758 fi
2759
2760 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes ; then
2761 AC_MSG_ERROR([Building with pl111 requires vc4])
2762 fi
2763
2764 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2765 AC_MSG_ERROR([Building with tegra requires nouveau])
2766 fi
2767
2768 detect_old_buggy_llvm() {
2769 dnl llvm-config may not give the right answer when llvm is a built as a
2770 dnl single shared library, so we must work the library name out for
2771 dnl ourselves.
2772 dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2773 dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2774 LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2775 AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2776
2777 if test "x$llvm_have_one_so" = xyes; then
2778 dnl LLVM was built using auto*, so there is only one shared object.
2779 LLVM_LIBS="-l$LLVM_SO_NAME"
2780 else
2781 dnl If LLVM was built with CMake, there will be one shared object per
2782 dnl component.
2783 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2784 [AC_MSG_ERROR([Could not find llvm shared libraries:
2785 Please make sure you have built llvm with the --enable-shared option
2786 and that your llvm libraries are installed in $LLVM_LIBDIR
2787 If you have installed your llvm libraries to a different directory you
2788 can use the --with-llvm-prefix= configure flag to specify this directory.
2789 NOTE: Mesa is attempting to use llvm shared libraries by default.
2790 If you do not want to build with llvm shared libraries and instead want to
2791 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2792 invocation and rebuild.])])
2793
2794 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2795 dnl install uses a shared object for each component and we have
2796 dnl already added all of these objects to LLVM_LIBS.
2797 fi
2798 }
2799
2800 dnl
2801 dnl Set defines and buildtime variables only when using LLVM.
2802 dnl
2803 if test "x$enable_llvm" = xyes; then
2804 DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2805
2806 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2807 LLVM_CFLAGS=$LLVM_CPPFLAGS # CPPFLAGS seem to be sufficient
2808 LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2809
2810 dnl Set LLVM_LIBS - This is done after the driver configuration so
2811 dnl that drivers can add additional components to LLVM_COMPONENTS.
2812 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2813 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2814 dnl this was causing the same libraries to be appear multiple times
2815 dnl in LLVM_LIBS.
2816
2817 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2818 if test "x$enable_llvm_shared_libs" = xyes; then
2819 LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2820 else
2821 dnl Invoking llvm-config with both -libs and --system-libs produces the
2822 dnl two separate lines - each for the set of libraries.
2823 dnl Call the program twice, effectively folding them into a single line.
2824 LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2825 dnl We need to link to llvm system libs when using static libs
2826 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2827 fi
2828 else
2829 LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2830 if test "x$enable_llvm_shared_libs" = xyes; then
2831 detect_old_buggy_llvm
2832 else
2833 AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2834 dnl We need to link to llvm system libs when using static libs
2835 dnl However, only llvm 3.5+ provides --system-libs
2836 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2837 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2838 fi
2839 fi
2840 fi
2841
2842 dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2843 dnl swr/llvmpipe driver into the final binary. Adding LLVM_LIBS results in
2844 dnl the LLVM library propagated in the Libs.private of the respective .pc
2845 dnl file which ensures complete dependency information when statically
2846 dnl linking.
2847 if test "x$enable_glx" == xgallium-xlib; then
2848 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2849 fi
2850 if test "x$enable_gallium_osmesa" = xyes; then
2851 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2852 fi
2853 fi
2854
2855 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2856 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2857 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2858 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2859 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2860 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2861 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2862 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2863 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2864 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2865 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2866 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2867 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2868 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2869 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2870 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2871 "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2872 "x$HAVE_GALLIUM_SWR" = xyes)
2873 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2874 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2875 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2876
2877 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2878
2879 if test "x$enable_dri" = xyes; then
2880 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2881 fi
2882
2883 if test "x$have_drisw_kms" = xyes; then
2884 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2885 fi
2886 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2887
2888 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2889 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2890 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2891 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2892 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2893 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2894
2895 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2896 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2897
2898 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2899 "x$HAVE_RADEON_VULKAN" = xyes)
2900
2901 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2902 "x$HAVE_GALLIUM_VC5" = xyes)
2903
2904 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2905 "x$HAVE_I965_DRI" = xyes)
2906
2907 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2908 "x$HAVE_GALLIUM_R600" = xyes -o \
2909 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2910 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2911 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2912 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2913 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2914 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2915
2916 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2917 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2918 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2919 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2920 "x$enable_gallium_osmesa" = xyes)
2921
2922 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2923 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2924 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2925 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2926 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2927 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2928
2929 AC_SUBST([NINE_MAJOR], 1)
2930 AC_SUBST([NINE_MINOR], 0)
2931 AC_SUBST([NINE_PATCH], 0)
2932 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
2933
2934 AC_SUBST([VDPAU_MAJOR], 1)
2935 AC_SUBST([VDPAU_MINOR], 0)
2936
2937 if test "x$enable_va" = xyes; then
2938 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2939 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2940 fi
2941 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2942 AC_SUBST([VA_MINOR], $VA_MINOR)
2943
2944 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2945
2946 AC_SUBST([XVMC_MAJOR], 1)
2947 AC_SUBST([XVMC_MINOR], 0)
2948
2949 AC_SUBST([XA_MAJOR], 2)
2950 AC_SUBST([XA_MINOR], 3)
2951 AC_SUBST([XA_PATCH], 0)
2952 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
2953
2954 AC_ARG_ENABLE(valgrind,
2955 [AS_HELP_STRING([--enable-valgrind],
2956 [Build mesa with valgrind support (default: auto)])],
2957 [VALGRIND=$enableval], [VALGRIND=auto])
2958 if test "x$VALGRIND" != xno; then
2959 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2960 fi
2961 AC_MSG_CHECKING([whether to enable Valgrind support])
2962 if test "x$VALGRIND" = xauto; then
2963 VALGRIND="$have_valgrind"
2964 fi
2965
2966 if test "x$VALGRIND" = "xyes"; then
2967 if ! test "x$have_valgrind" = xyes; then
2968 AC_MSG_ERROR([Valgrind support required but not present])
2969 fi
2970 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2971 fi
2972
2973 AC_MSG_RESULT([$VALGRIND])
2974
2975 dnl Restore LDFLAGS and CPPFLAGS
2976 LDFLAGS="$_SAVE_LDFLAGS"
2977 CPPFLAGS="$_SAVE_CPPFLAGS"
2978
2979 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2980 if test "x$acv_mesa_CLANG" = xyes; then
2981 CFLAGS="$CFLAGS -Qunused-arguments"
2982 CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2983 fi
2984
2985 dnl Add user CFLAGS and CXXFLAGS
2986 CFLAGS="$CFLAGS $USER_CFLAGS"
2987 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2988
2989 dnl Substitute the config
2990 AC_CONFIG_FILES([Makefile
2991 src/Makefile
2992 src/amd/Makefile
2993 src/amd/vulkan/Makefile
2994 src/broadcom/Makefile
2995 src/compiler/Makefile
2996 src/egl/Makefile
2997 src/egl/main/egl.pc
2998 src/egl/wayland/wayland-drm/Makefile
2999 src/egl/wayland/wayland-egl/Makefile
3000 src/egl/wayland/wayland-egl/wayland-egl.pc
3001 src/gallium/Makefile
3002 src/gallium/auxiliary/Makefile
3003 src/gallium/auxiliary/pipe-loader/Makefile
3004 src/gallium/drivers/freedreno/Makefile
3005 src/gallium/drivers/ddebug/Makefile
3006 src/gallium/drivers/i915/Makefile
3007 src/gallium/drivers/llvmpipe/Makefile
3008 src/gallium/drivers/noop/Makefile
3009 src/gallium/drivers/nouveau/Makefile
3010 src/gallium/drivers/pl111/Makefile
3011 src/gallium/drivers/r300/Makefile
3012 src/gallium/drivers/r600/Makefile
3013 src/gallium/drivers/radeon/Makefile
3014 src/gallium/drivers/radeonsi/Makefile
3015 src/gallium/drivers/rbug/Makefile
3016 src/gallium/drivers/softpipe/Makefile
3017 src/gallium/drivers/svga/Makefile
3018 src/gallium/drivers/swr/Makefile
3019 src/gallium/drivers/tegra/Makefile
3020 src/gallium/drivers/trace/Makefile
3021 src/gallium/drivers/etnaviv/Makefile
3022 src/gallium/drivers/imx/Makefile
3023 src/gallium/drivers/vc4/Makefile
3024 src/gallium/drivers/vc5/Makefile
3025 src/gallium/drivers/virgl/Makefile
3026 src/gallium/state_trackers/clover/Makefile
3027 src/gallium/state_trackers/dri/Makefile
3028 src/gallium/state_trackers/glx/xlib/Makefile
3029 src/gallium/state_trackers/nine/Makefile
3030 src/gallium/state_trackers/omx/Makefile
3031 src/gallium/state_trackers/omx/bellagio/Makefile
3032 src/gallium/state_trackers/omx/tizonia/Makefile
3033 src/gallium/state_trackers/osmesa/Makefile
3034 src/gallium/state_trackers/va/Makefile
3035 src/gallium/state_trackers/vdpau/Makefile
3036 src/gallium/state_trackers/xa/Makefile
3037 src/gallium/state_trackers/xa/xa_tracker.h
3038 src/gallium/state_trackers/xvmc/Makefile
3039 src/gallium/targets/d3dadapter9/Makefile
3040 src/gallium/targets/d3dadapter9/d3d.pc
3041 src/gallium/targets/dri/Makefile
3042 src/gallium/targets/libgl-xlib/Makefile
3043 src/gallium/targets/omx/Makefile
3044 src/gallium/targets/opencl/Makefile
3045 src/gallium/targets/opencl/mesa.icd
3046 src/gallium/targets/osmesa/Makefile
3047 src/gallium/targets/osmesa/osmesa.pc
3048 src/gallium/targets/pipe-loader/Makefile
3049 src/gallium/targets/va/Makefile
3050 src/gallium/targets/vdpau/Makefile
3051 src/gallium/targets/xa/Makefile
3052 src/gallium/targets/xa/xatracker.pc
3053 src/gallium/targets/xvmc/Makefile
3054 src/gallium/tests/trivial/Makefile
3055 src/gallium/tests/unit/Makefile
3056 src/gallium/winsys/etnaviv/drm/Makefile
3057 src/gallium/winsys/imx/drm/Makefile
3058 src/gallium/winsys/freedreno/drm/Makefile
3059 src/gallium/winsys/i915/drm/Makefile
3060 src/gallium/winsys/nouveau/drm/Makefile
3061 src/gallium/winsys/pl111/drm/Makefile
3062 src/gallium/winsys/radeon/drm/Makefile
3063 src/gallium/winsys/amdgpu/drm/Makefile
3064 src/gallium/winsys/svga/drm/Makefile
3065 src/gallium/winsys/sw/dri/Makefile
3066 src/gallium/winsys/sw/kms-dri/Makefile
3067 src/gallium/winsys/sw/null/Makefile
3068 src/gallium/winsys/sw/wrapper/Makefile
3069 src/gallium/winsys/sw/xlib/Makefile
3070 src/gallium/winsys/tegra/drm/Makefile
3071 src/gallium/winsys/vc4/drm/Makefile
3072 src/gallium/winsys/vc5/drm/Makefile
3073 src/gallium/winsys/virgl/drm/Makefile
3074 src/gallium/winsys/virgl/vtest/Makefile
3075 src/gbm/Makefile
3076 src/gbm/main/gbm.pc
3077 src/glx/Makefile
3078 src/glx/apple/Makefile
3079 src/glx/tests/Makefile
3080 src/glx/windows/Makefile
3081 src/glx/windows/windowsdriproto.pc
3082 src/gtest/Makefile
3083 src/intel/Makefile
3084 src/loader/Makefile
3085 src/mapi/Makefile
3086 src/mapi/es1api/glesv1_cm.pc
3087 src/mapi/es2api/glesv2.pc
3088 src/mapi/glapi/gen/Makefile
3089 src/mesa/Makefile
3090 src/mesa/gl.pc
3091 src/mesa/drivers/dri/dri.pc
3092 src/mesa/drivers/dri/common/Makefile
3093 src/mesa/drivers/dri/i915/Makefile
3094 src/mesa/drivers/dri/i965/Makefile
3095 src/mesa/drivers/dri/Makefile
3096 src/mesa/drivers/dri/nouveau/Makefile
3097 src/mesa/drivers/dri/r200/Makefile
3098 src/mesa/drivers/dri/radeon/Makefile
3099 src/mesa/drivers/dri/swrast/Makefile
3100 src/mesa/drivers/osmesa/Makefile
3101 src/mesa/drivers/osmesa/osmesa.pc
3102 src/mesa/drivers/x11/Makefile
3103 src/mesa/main/tests/Makefile
3104 src/mesa/state_tracker/tests/Makefile
3105 src/util/Makefile
3106 src/util/tests/hash_table/Makefile
3107 src/util/tests/string_buffer/Makefile
3108 src/util/xmlpool/Makefile
3109 src/vulkan/Makefile])
3110
3111 AC_OUTPUT
3112
3113 # Fix up dependencies in *.Plo files, where we changed the extension of a
3114 # source file
3115 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3116
3117 rm -f src/compiler/spirv/spirv_info.lo
3118 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3119
3120 dnl
3121 dnl Output some configuration info for the user
3122 dnl
3123 echo ""
3124 echo " prefix: $prefix"
3125 echo " exec_prefix: $exec_prefix"
3126 echo " libdir: $libdir"
3127 echo " includedir: $includedir"
3128
3129 dnl API info
3130 echo ""
3131 echo " OpenGL: $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3132
3133 dnl Driver info
3134 echo ""
3135 case "x$enable_osmesa$enable_gallium_osmesa" in
3136 xnoyes)
3137 echo " OSMesa: lib$OSMESA_LIB (Gallium)"
3138 ;;
3139 xyesno)
3140 echo " OSMesa: lib$OSMESA_LIB"
3141 ;;
3142 xnono)
3143 echo " OSMesa: no"
3144 ;;
3145 esac
3146
3147 echo ""
3148 if test "x$enable_dri" != xno; then
3149 echo " DRI platform: $dri_platform"
3150 if test -z "$DRI_DIRS"; then
3151 echo " DRI drivers: no"
3152 else
3153 echo " DRI drivers: $DRI_DIRS"
3154 fi
3155 echo " DRI driver dir: $DRI_DRIVER_INSTALL_DIR"
3156 fi
3157
3158 case "x$enable_glx" in
3159 xdri)
3160 echo " GLX: DRI-based"
3161 ;;
3162 xxlib)
3163 echo " GLX: Xlib-based"
3164 ;;
3165 xgallium-xlib)
3166 echo " GLX: Xlib-based (Gallium)"
3167 ;;
3168 *)
3169 echo " GLX: $enable_glx"
3170 ;;
3171 esac
3172
3173 dnl EGL
3174 echo ""
3175 echo " EGL: $enable_egl"
3176 if test "$enable_egl" = yes; then
3177
3178 egl_drivers=""
3179 if test "x$enable_dri" != "xno"; then
3180 egl_drivers="$egl_drivers builtin:egl_dri2"
3181 fi
3182 if test "x$enable_dri3" != "xno"; then
3183 egl_drivers="$egl_drivers builtin:egl_dri3"
3184 fi
3185
3186 echo " EGL drivers: $egl_drivers"
3187 fi
3188 if test "x$enable_gbm" = xyes; then
3189 echo " GBM: yes"
3190 else
3191 echo " GBM: no"
3192 fi
3193
3194 echo " EGL/Vulkan/VL platforms: $platforms"
3195
3196 # Vulkan
3197 echo ""
3198 if test "x$VULKAN_DRIVERS" != x; then
3199 echo " Vulkan drivers: $VULKAN_DRIVERS"
3200 echo " Vulkan ICD dir: $VULKAN_ICD_INSTALL_DIR"
3201 else
3202 echo " Vulkan drivers: no"
3203 fi
3204
3205 echo ""
3206 if test "x$enable_llvm" = xyes; then
3207 echo " llvm: yes"
3208 echo " llvm-config: $LLVM_CONFIG"
3209 echo " llvm-version: $LLVM_VERSION"
3210 else
3211 echo " llvm: no"
3212 fi
3213
3214 echo ""
3215 if test -n "$with_gallium_drivers"; then
3216 echo " Gallium drivers: $gallium_drivers"
3217 echo " Gallium st: $gallium_st"
3218 else
3219 echo " Gallium: no"
3220 fi
3221
3222 echo ""
3223 if test "x$enable_gallium_extra_hud" != xyes; then
3224 echo " HUD extra stats: no"
3225 else
3226 echo " HUD extra stats: yes"
3227 fi
3228
3229 if test "x$enable_lmsensors" != xyes; then
3230 echo " HUD lmsensors: no"
3231 else
3232 echo " HUD lmsensors: yes"
3233 fi
3234
3235 echo ""
3236 if test "x$HAVE_GALLIUM_SWR" != x; then
3237 if test "x$HAVE_SWR_BUILTIN" = xyes; then
3238 echo " SWR archs: $swr_archs (builtin)"
3239 else
3240 echo " SWR archs: $swr_archs"
3241 fi
3242 fi
3243
3244 dnl Libraries
3245 echo ""
3246 echo " Shared libs: $enable_shared"
3247 echo " Static libs: $enable_static"
3248 echo " Shared-glapi: $enable_shared_glapi"
3249
3250 dnl Compiler options
3251 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3252 cflags=`echo $CFLAGS | \
3253 $SED 's/^ *//;s/ */ /;s/ *$//'`
3254 cxxflags=`echo $CXXFLAGS | \
3255 $SED 's/^ *//;s/ */ /;s/ *$//'`
3256 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/ */ /;s/ *$//'`
3257 defines=`echo $DEFINES | $SED 's/^ *//;s/ */ /;s/ *$//'`
3258 echo ""
3259 echo " CFLAGS: $cflags"
3260 echo " CXXFLAGS: $cxxflags"
3261 echo " CXX11_CXXFLAGS: $CXX11_CXXFLAGS"
3262 echo " LDFLAGS: $ldflags"
3263 echo " Macros: $defines"
3264 echo ""
3265 if test "x$enable_llvm" = xyes; then
3266 echo " LLVM_CFLAGS: $LLVM_CFLAGS"
3267 echo " LLVM_CXXFLAGS: $LLVM_CXXFLAGS"
3268 echo " LLVM_CPPFLAGS: $LLVM_CPPFLAGS"
3269 echo " LLVM_LDFLAGS: $LLVM_LDFLAGS"
3270 echo ""
3271 fi
3272 echo " PYTHON2: $PYTHON2"
3273
3274 echo ""
3275 echo " Run '${MAKE-make}' to build Mesa"
3276 echo ""