configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.95
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  82 LIBDRM_VC4_REQUIRED=2.4.89
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
  89 LIBVA_REQUIRED=0.39.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 WAYLAND_EGL_BACKEND_REQUIRED=3
  93 WAYLAND_PROTOCOLS_REQUIRED=1.8
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBDRI3_MODIFIERS_REQUIRED=1.13
  97 XCBGLX_REQUIRED=1.8.1
  98 XCBPRESENT_MODIFIERS_REQUIRED=1.13
  99 XDAMAGE_REQUIRED=1.1
 100 XSHMFENCE_REQUIRED=1.1
 101 XVMC_REQUIRED=1.0.6
 102 PYTHON_MAKO_REQUIRED=0.8.0
 103 LIBSENSORS_REQUIRED=4.0.0
 104 ZLIB_REQUIRED=1.2.3
 105
 106 dnl LLVM versions
 107 LLVM_REQUIRED_GALLIUM=3.3.0
 108 LLVM_REQUIRED_OPENCL=3.9.0
 109 LLVM_REQUIRED_R600=3.9.0
 110 LLVM_REQUIRED_RADEONSI=6.0.0
 111 LLVM_REQUIRED_RADV=6.0.0
 112 LLVM_REQUIRED_SWR=6.0.0
 113
 114 dnl Check for progs
 115 AC_PROG_CPP
 116 AC_PROG_CC
 117 AC_PROG_CXX
 118 dnl add this here, so the help for this environmnet variable is close to
 119 dnl other CC/CXX flags related help
 120 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 121                               enabled by default and different  from -std=c++11)])
 122 AM_PROG_CC_C_O
 123 AC_PROG_GREP
 124 AC_PROG_NM
 125 AM_PROG_AS
 126 AX_CHECK_GNU_MAKE
 127 AM_PATH_PYTHON([2.7],, [:])
 128 PYTHON2=$PYTHON
 129 AC_SUBST([PYTHON2])
 130
 131 AC_PROG_SED
 132 AC_PROG_MKDIR_P
 133
 134 AC_SYS_LARGEFILE
 135
 136
 137 LT_PREREQ([2.2])
 138 LT_INIT([disable-static])
 139
 140 AC_CHECK_PROG(RM, rm, [rm -f])
 141
 142 AX_PROG_BISON([],
 143               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 144                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 145 AX_PROG_FLEX([],
 146              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 147                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 148
 149 AC_CHECK_PROG(INDENT, indent, indent, cat)
 150 if test "x$INDENT" != "xcat"; then
 151     # Only GNU indent is supported
 152     INDENT_VERSION=`indent --version | grep GNU`
 153     if test $? -eq 0; then
 154        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 155     else
 156        INDENT="cat"
 157     fi
 158 fi
 159
 160 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 161
 162 if test "$PYTHON2" = ":"; then
 163     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 164         AC_MSG_ERROR([Python not found - unable to generate sources])
 165     fi
 166 else
 167     if test "x$acv_mako_found" = xno; then
 168         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 169             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 170         fi
 171     fi
 172 fi
 173
 174 AC_PROG_INSTALL
 175
 176 dnl We need a POSIX shell for parts of the build. Assume we have one
 177 dnl in most cases.
 178 case "$host_os" in
 179 solaris*)
 180     # Solaris /bin/sh is too old/non-POSIX compliant
 181     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 182     SHELL="$POSIX_SHELL"
 183     ;;
 184 esac
 185
 186 dnl clang is mostly GCC-compatible, but its version is much lower,
 187 dnl so we have to check for it.
 188 AC_MSG_CHECKING([if compiling with clang])
 189
 190 AC_COMPILE_IFELSE(
 191 [AC_LANG_PROGRAM([], [[
 192 #ifndef __clang__
 193        not clang
 194 #endif
 195 ]])],
 196 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 197
 198 AC_MSG_RESULT([$acv_mesa_CLANG])
 199
 200 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 201 dnl versions are explictly not supported.
 202 GEN_ASM_OFFSETS=no
 203 USE_GNU99=no
 204 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 205     AC_MSG_CHECKING([whether gcc version is sufficient])
 206     major=0
 207     minor=0
 208
 209     GCC_VERSION=`$CC -dumpversion`
 210     if test $? -eq 0; then
 211         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 212         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 213     fi
 214
 215     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 216         AC_MSG_RESULT([no])
 217         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 218     else
 219         AC_MSG_RESULT([yes])
 220     fi
 221
 222     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 223         USE_GNU99=yes
 224     fi
 225     if test "x$cross_compiling" = xyes; then
 226         GEN_ASM_OFFSETS=yes
 227     fi
 228 fi
 229
 230 dnl We don't support building Mesa with Sun C compiler
 231 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 232 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 233 if test "x$SUNCC" = xyes; then
 234     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 235 fi
 236
 237 dnl Check for compiler builtins
 238 AX_GCC_BUILTIN([__builtin_bswap32])
 239 AX_GCC_BUILTIN([__builtin_bswap64])
 240 AX_GCC_BUILTIN([__builtin_clz])
 241 AX_GCC_BUILTIN([__builtin_clzll])
 242 AX_GCC_BUILTIN([__builtin_ctz])
 243 AX_GCC_BUILTIN([__builtin_expect])
 244 AX_GCC_BUILTIN([__builtin_ffs])
 245 AX_GCC_BUILTIN([__builtin_ffsll])
 246 AX_GCC_BUILTIN([__builtin_popcount])
 247 AX_GCC_BUILTIN([__builtin_popcountll])
 248 AX_GCC_BUILTIN([__builtin_unreachable])
 249
 250 AX_GCC_FUNC_ATTRIBUTE([const])
 251 AX_GCC_FUNC_ATTRIBUTE([flatten])
 252 AX_GCC_FUNC_ATTRIBUTE([format])
 253 AX_GCC_FUNC_ATTRIBUTE([malloc])
 254 AX_GCC_FUNC_ATTRIBUTE([packed])
 255 AX_GCC_FUNC_ATTRIBUTE([pure])
 256 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 257 AX_GCC_FUNC_ATTRIBUTE([unused])
 258 AX_GCC_FUNC_ATTRIBUTE([visibility])
 259 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 260 AX_GCC_FUNC_ATTRIBUTE([weak])
 261 AX_GCC_FUNC_ATTRIBUTE([alias])
 262 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 263
 264 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 265
 266 dnl Make sure the pkg-config macros are defined
 267 m4_ifndef([PKG_PROG_PKG_CONFIG],
 268     [m4_fatal([Could not locate the pkg-config autoconf macros.
 269   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 270   are in a different location, try setting the environment variable
 271   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 272 PKG_PROG_PKG_CONFIG()
 273
 274 dnl LIB_DIR - library basename
 275 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 276 AC_SUBST([LIB_DIR])
 277
 278 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 279 _SAVE_LDFLAGS="$LDFLAGS"
 280 _SAVE_CPPFLAGS="$CPPFLAGS"
 281
 282 dnl Compiler macros
 283 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 284 AC_SUBST([DEFINES])
 285 android=no
 286 case "$host_os" in
 287 *-android*)
 288     android=yes
 289     ;;
 290 linux*|*-gnu*|gnu*|cygwin*)
 291     DEFINES="$DEFINES -D_GNU_SOURCE"
 292     ;;
 293 solaris*)
 294     DEFINES="$DEFINES -DSVR4"
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 299
 300 dnl
 301 dnl Check compiler flags
 302 dnl
 303 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 304 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 305 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 306 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 307 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
 308 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
 309 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CFLAGS="$CFLAGS -Wno-format-truncation"])
 310 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 311
 312 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 313 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 314
 315 dnl
 316 dnl Check C++ compiler flags
 317 dnl
 318 AC_LANG_PUSH([C++])
 319 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 320 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 321 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 322 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 323 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
 324 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CXXFLAGS="$CXXFLAGS -Wno-format-truncation"])
 325 AC_LANG_POP([C++])
 326
 327 # Flags to help ensure that certain portions of the code -- and only those
 328 # portions -- can be built with MSVC:
 329 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 330 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 331 #   supports most of C99)
 332 # - the rest has no compiler compiler restrictions
 333 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 334 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 335 AC_LANG_PUSH([C++])
 336 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 337 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 338 AC_LANG_POP([C++])
 339
 340 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 341 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 342
 343 if test "x$GCC" = xyes; then
 344     if test "x$USE_GNU99" = xyes; then
 345         CFLAGS="$CFLAGS -std=gnu99"
 346     else
 347         CFLAGS="$CFLAGS -std=c99"
 348     fi
 349 fi
 350
 351 dnl
 352 dnl Check whether C++11 is supported, if the environment variable
 353 dnl CXX11_CXXFLAGS is set it takes precedence.
 354 dnl
 355
 356 AC_LANG_PUSH([C++])
 357
 358 check_cxx11_available() {
 359     output_support=$1
 360     AC_COMPILE_IFELSE(
 361         [AC_LANG_PROGRAM([
 362              #if !(__cplusplus >= 201103L)
 363              #error
 364              #endif
 365              #include <tuple>
 366         ])
 367     ], [
 368          AC_MSG_RESULT(yes)
 369          cxx11_support=yes
 370     ], AC_MSG_RESULT(no))
 371     eval "$output_support=\$cxx11_support"
 372 }
 373
 374 HAVE_CXX11=no
 375 save_CXXFLAGS="$CXXFLAGS"
 376
 377 dnl If the user provides a flag to enable c++11, then we test only this
 378 if test "x$CXX11_CXXFLAGS" != "x"; then
 379    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 380    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 381    check_cxx11_available HAVE_CXX11
 382 else
 383    dnl test whether c++11 is enabled by default
 384    AC_MSG_CHECKING(whether c++11 is enabled by default)
 385    check_cxx11_available HAVE_CXX11
 386
 387    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 388    if test "x$HAVE_CXX11" != "xyes"; then
 389        CXX11_CXXFLAGS=-std=c++11
 390        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 391        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 392        check_cxx11_available HAVE_CXX11
 393    fi
 394 fi
 395
 396 CXXFLAGS="$save_CXXFLAGS"
 397 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 398 AC_SUBST(CXX11_CXXFLAGS)
 399 AC_LANG_POP([C++])
 400
 401 dnl even if the compiler appears to support it, using visibility attributes isn't
 402 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 403 case "$host_os" in
 404 cygwin*)
 405     VISIBILITY_CFLAGS=""
 406     VISIBILITY_CXXFLAGS=""
 407     ;;
 408 esac
 409
 410 AC_SUBST([VISIBILITY_CFLAGS])
 411 AC_SUBST([VISIBILITY_CXXFLAGS])
 412
 413 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 414 dnl option is not supported. Hence, check for -Wfoo instead.
 415 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 416 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 417 AC_SUBST([WNO_OVERRIDE_INIT])
 418
 419 dnl
 420 dnl Optional flags, check for compiler support
 421 dnl
 422 SSE41_CFLAGS="-msse4.1"
 423 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 424 dnl stack, but on x86-32 such alignment is not guaranteed.
 425 case "$target_cpu" in
 426 i?86)
 427     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 428     ;;
 429 esac
 430 save_CFLAGS="$CFLAGS"
 431 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 432 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 433 #include <smmintrin.h>
 434 int param;
 435 int main () {
 436     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 437     c = _mm_max_epu32(a, b);
 438     return _mm_cvtsi128_si32(c);
 439 }]])], SSE41_SUPPORTED=1)
 440 CFLAGS="$save_CFLAGS"
 441 if test "x$SSE41_SUPPORTED" = x1; then
 442     DEFINES="$DEFINES -DUSE_SSE41"
 443 fi
 444 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 445 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 446
 447 dnl Check for new-style atomic builtins. We first check without linking to
 448 dnl -latomic.
 449 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 450 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 451 #include <stdint.h>
 452 int main() {
 453     struct {
 454         uint64_t *v;
 455     } x;
 456     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 457            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 458 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 459
 460 dnl If that didn't work, we try linking with -latomic, which is needed on some
 461 dnl platforms.
 462 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 463    save_LDFLAGS=$LDFLAGS
 464    LDFLAGS="$LDFLAGS -latomic"
 465    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 466    #include <stdint.h>
 467    int main() {
 468         struct {
 469             uint64_t *v;
 470         } x;
 471         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 472                (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 473    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 474           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 475    LDFLAGS=$save_LDFLAGS
 476 fi
 477 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 478
 479 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 480     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 481 fi
 482 AC_SUBST([LIBATOMIC_LIBS])
 483
 484 dnl Check if host supports 64-bit atomics
 485 dnl note that lack of support usually results in link (not compile) error
 486 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 487 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 488 #include <stdint.h>
 489 uint64_t v;
 490 int main() {
 491     return __sync_add_and_fetch(&v, (uint64_t)1);
 492 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 493 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 494     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 495 fi
 496 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 497
 498 dnl Check for Endianness
 499 AC_C_BIGENDIAN(
 500    little_endian=no,
 501    little_endian=yes,
 502    little_endian=no,
 503    little_endian=no
 504 )
 505
 506 dnl Check for POWER8 Architecture
 507 PWR8_CFLAGS="-mpower8-vector"
 508 have_pwr8_intrinsics=no
 509 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 510 save_CFLAGS=$CFLAGS
 511 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 512 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 513 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 514 #error "Need GCC >= 4.8 for sane POWER8 support"
 515 #endif
 516 #include <altivec.h>
 517 int main () {
 518     vector unsigned char r;
 519     vector unsigned int v = vec_splat_u32 (1);
 520     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 521     return 0;
 522 }]])], have_pwr8_intrinsics=yes)
 523 CFLAGS=$save_CFLAGS
 524
 525 AC_ARG_ENABLE(pwr8,
 526    [AS_HELP_STRING([--disable-pwr8],
 527                    [disable POWER8-specific instructions])],
 528    [enable_pwr8=$enableval], [enable_pwr8=auto])
 529
 530 if test "x$enable_pwr8" = xno ; then
 531    have_pwr8_intrinsics=disabled
 532 fi
 533
 534 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 535    DEFINES="$DEFINES -D_ARCH_PWR8"
 536    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 537    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 538 else
 539    PWR8_CFLAGS=
 540 fi
 541
 542 AC_MSG_RESULT($have_pwr8_intrinsics)
 543 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 544    AC_MSG_ERROR([POWER8 compiler support not detected])
 545 fi
 546
 547 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 548    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 549 fi
 550
 551 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 552
 553 dnl Can't have static and shared libraries, default to static if user
 554 dnl explicitly requested. If both disabled, set to static since shared
 555 dnl was explicitly requested.
 556 case "x$enable_static$enable_shared" in
 557 xyesyes)
 558     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 559     ;;
 560 xnono)
 561     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 562     ;;
 563 esac
 564
 565 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 566
 567 dnl
 568 dnl other compiler options
 569 dnl
 570 AC_ARG_ENABLE([debug],
 571     [AS_HELP_STRING([--enable-debug],
 572         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 573     [enable_debug="$enableval"],
 574     [enable_debug=no]
 575 )
 576
 577 AC_ARG_ENABLE([profile],
 578     [AS_HELP_STRING([--enable-profile],
 579         [enable profiling of code @<:@default=disabled@:>@])],
 580     [enable_profile="$enableval"],
 581     [enable_profile=no]
 582 )
 583
 584 AC_ARG_ENABLE([sanitize],
 585     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 586         [enable code sanitizer @<:@default=disabled@:>@])],
 587     [enable_sanitize="$enableval"],
 588     [enable_sanitize=no])
 589
 590 if test "x$enable_profile" = xyes; then
 591     DEFINES="$DEFINES -DPROFILE"
 592     if test "x$GCC" = xyes; then
 593         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 594     fi
 595     if test "x$GXX" = xyes; then
 596         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 597     fi
 598 fi
 599
 600 if test "x$enable_debug" = xyes; then
 601     DEFINES="$DEFINES -DDEBUG"
 602     if test "x$enable_profile" = xyes; then
 603         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 604     fi
 605     if test "x$GCC" = xyes; then
 606         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 607             CFLAGS="$CFLAGS -g"
 608         fi
 609         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 610             CFLAGS="$CFLAGS -O0"
 611         fi
 612     fi
 613     if test "x$GXX" = xyes; then
 614         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 615             CXXFLAGS="$CXXFLAGS -g"
 616         fi
 617         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 618             CXXFLAGS="$CXXFLAGS -O0"
 619         fi
 620     fi
 621 else
 622    DEFINES="$DEFINES -DNDEBUG"
 623 fi
 624
 625 if test "x$enable_sanitize" != xno; then
 626     if test "x$enable_profile" = xyes; then
 627         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 628     fi
 629
 630     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 631     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 632     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 633
 634     AC_LINK_IFELSE(
 635         [AC_LANG_SOURCE([int main(){return 0;}])],
 636         [],
 637         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 638 fi
 639
 640 dnl
 641 dnl Check if linker supports -Bsymbolic
 642 dnl
 643 save_LDFLAGS=$LDFLAGS
 644 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 645 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 646 AC_LINK_IFELSE(
 647     [AC_LANG_SOURCE([int main() { return 0;}])],
 648     [AC_MSG_RESULT([yes])
 649         BSYMBOLIC="-Wl,-Bsymbolic";],
 650     [AC_MSG_RESULT([no])
 651         BSYMBOLIC="";])
 652 LDFLAGS=$save_LDFLAGS
 653
 654 AC_SUBST([BSYMBOLIC])
 655
 656 dnl
 657 dnl Check if linker supports garbage collection
 658 dnl
 659 save_LDFLAGS=$LDFLAGS
 660 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 661 AC_MSG_CHECKING([whether ld supports --gc-sections])
 662 AC_LINK_IFELSE(
 663     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 664     [AC_MSG_RESULT([yes])
 665         GC_SECTIONS="-Wl,--gc-sections";],
 666     [AC_MSG_RESULT([no])
 667         GC_SECTIONS="";])
 668 LDFLAGS=$save_LDFLAGS
 669
 670 AC_SUBST([GC_SECTIONS])
 671
 672 dnl
 673 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 674 dnl so when these flags are passed to ld via libtool the checks will fail
 675 dnl
 676 case "$host_os" in
 677 openbsd* | darwin* )
 678     LD_NO_UNDEFINED="" ;;
 679 *)
 680     if test "x$enable_sanitize" = xno; then
 681         LD_NO_UNDEFINED="-Wl,--no-undefined"
 682     else
 683         LD_NO_UNDEFINED=""
 684     fi
 685     ;;
 686 esac
 687
 688 AC_SUBST([LD_NO_UNDEFINED])
 689
 690 dnl
 691 dnl Check if linker supports version scripts
 692 dnl
 693 AC_MSG_CHECKING([if the linker supports version-scripts])
 694 save_LDFLAGS=$LDFLAGS
 695 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 696 AC_LINK_IFELSE(
 697     [AC_LANG_SOURCE([int main() { return 0;}])],
 698     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 699     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 700 LDFLAGS=$save_LDFLAGS
 701 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 702
 703 dnl
 704 dnl Check if linker supports dynamic list files
 705 dnl
 706 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 707 save_LDFLAGS=$LDFLAGS
 708 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 709 AC_LINK_IFELSE(
 710     [AC_LANG_SOURCE([int main() { return 0;}])],
 711     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 712     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 713 LDFLAGS=$save_LDFLAGS
 714 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 715
 716 dnl
 717 dnl OSX linker does not support build-id
 718 dnl
 719 case "$host_os" in
 720 darwin*)
 721     LD_BUILD_ID=""
 722     ;;
 723 *)
 724     LD_BUILD_ID="-Wl,--build-id=sha1"
 725     ;;
 726 esac
 727 AC_SUBST([LD_BUILD_ID])
 728
 729 dnl
 730 dnl compatibility symlinks
 731 dnl
 732 case "$host_os" in
 733 linux* )
 734     HAVE_COMPAT_SYMLINKS=yes ;;
 735 * )
 736     HAVE_COMPAT_SYMLINKS=no ;;
 737 esac
 738
 739 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 740
 741 dnl
 742 dnl library names
 743 dnl
 744 dnl Unfortunately we need to do a few things that libtool can't help us with,
 745 dnl so we need some knowledge of shared library filenames:
 746 dnl
 747 dnl LIB_EXT is the extension used when creating symlinks for alternate
 748 dnl filenames for a shared library which will be dynamically loaded
 749 dnl
 750 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 751 dnl the file for a shared library we wish to link with
 752 dnl
 753 case "$host_os" in
 754 darwin* )
 755     LIB_EXT='dylib'
 756     IMP_LIB_EXT=$LIB_EXT
 757     ;;
 758 cygwin* )
 759     LIB_EXT='dll'
 760     IMP_LIB_EXT='dll.a'
 761     ;;
 762 aix* )
 763     LIB_EXT='a'
 764     IMP_LIB_EXT=$LIB_EXT
 765     ;;
 766 * )
 767     LIB_EXT='so'
 768     IMP_LIB_EXT=$LIB_EXT
 769     ;;
 770 esac
 771
 772 AC_SUBST([LIB_EXT])
 773
 774 dnl
 775 dnl Arch/platform-specific settings
 776 dnl
 777 AC_ARG_ENABLE([asm],
 778     [AS_HELP_STRING([--disable-asm],
 779         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 780     [enable_asm="$enableval"],
 781     [enable_asm=yes]
 782 )
 783 asm_arch=""
 784 AC_MSG_CHECKING([whether to enable assembly])
 785 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 786 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 787 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 788     case "$host_cpu" in
 789     i?86 | x86_64 | amd64)
 790         if test "x$host_cpu" != "x$target_cpu"; then
 791             enable_asm=no
 792             AC_MSG_RESULT([no, cross compiling])
 793         fi
 794         ;;
 795     esac
 796 fi
 797 # check for supported arches
 798 if test "x$enable_asm" = xyes; then
 799     case "$host_cpu" in
 800     i?86)
 801         case "$host_os" in
 802         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 803             asm_arch=x86
 804             ;;
 805         esac
 806         ;;
 807     x86_64|amd64)
 808         case "$host_os" in
 809         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 810             asm_arch=x86_64
 811             ;;
 812         esac
 813         ;;
 814     sparc*)
 815         case "$host_os" in
 816         linux*)
 817             asm_arch=sparc
 818             ;;
 819         esac
 820         ;;
 821     powerpc64le)
 822         case "$host_os" in
 823         linux*)
 824             asm_arch=ppc64le
 825             ;;
 826         esac
 827         ;;
 828     aarch64)
 829         case "$host_os" in
 830         linux*)
 831             asm_arch=aarch64
 832             ;;
 833         esac
 834         ;;
 835     arm)
 836         case "$host_os" in
 837         linux*)
 838             asm_arch=arm
 839             ;;
 840         esac
 841         ;;
 842     esac
 843
 844     case "$asm_arch" in
 845     x86)
 846         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 847         AC_MSG_RESULT([yes, x86])
 848         ;;
 849     x86_64|amd64)
 850         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 851         AC_MSG_RESULT([yes, x86_64])
 852         ;;
 853     sparc)
 854         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 855         AC_MSG_RESULT([yes, sparc])
 856         ;;
 857     ppc64le)
 858         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 859         AC_MSG_RESULT([yes, ppc64le])
 860         ;;
 861     aarch64)
 862         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 863         AC_MSG_RESULT([yes, aarch64])
 864         ;;
 865     arm)
 866         DEFINES="$DEFINES -DUSE_ARM_ASM"
 867         AC_MSG_RESULT([yes, arm])
 868         ;;
 869     *)
 870         AC_MSG_RESULT([no, platform not supported])
 871         ;;
 872     esac
 873 fi
 874
 875 AC_HEADER_MAJOR
 876 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 877 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 878 AC_CHECK_HEADERS([endian.h])
 879 AC_CHECK_HEADER([dlfcn.h], [DEFINES="$DEFINES -DHAVE_DLFCN_H"])
 880 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 881 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 882 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 883 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 884
 885 AC_MSG_CHECKING([whether strtod has locale support])
 886 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 887     #define _GNU_SOURCE
 888     #include <stdlib.h>
 889     #include <locale.h>
 890     #ifdef HAVE_XLOCALE_H
 891     #include <xlocale.h>
 892     #endif
 893     int main() {
 894        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 895        const char *s = "1.0";
 896        char *end;
 897        double d = strtod_l(s, end, loc);
 898        float f = strtof_l(s, end, loc);
 899        freelocale(loc);
 900        return 0;
 901     }]])],
 902   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 903    AC_MSG_RESULT([yes]),
 904    AC_MSG_RESULT([no]))
 905
 906 dnl Check to see if dlopen is in default libraries (like Solaris, which
 907 dnl has it in libc), or if libdl is needed to get it.
 908 AC_CHECK_FUNC([dlopen], [],
 909     [AC_CHECK_LIB([dl], [dlopen],
 910        [DLOPEN_LIBS="-ldl"])])
 911 AC_SUBST([DLOPEN_LIBS])
 912
 913 dnl Check if that library also has dladdr
 914 save_LIBS="$LIBS"
 915 LIBS="$LIBS $DLOPEN_LIBS"
 916 AC_CHECK_FUNCS([dladdr])
 917 LIBS="$save_LIBS"
 918
 919 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 920
 921 case "$host_os" in
 922 darwin*)
 923     ;;
 924 *)
 925     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 926                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 927                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 928     AC_SUBST([CLOCK_LIB])
 929     ;;
 930 esac
 931
 932 dnl See if posix_memalign is available
 933 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 934
 935 dnl Check for zlib
 936 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 937 DEFINES="$DEFINES -DHAVE_ZLIB"
 938
 939 dnl Check for pthreads
 940 AX_PTHREAD
 941 if test "x$ax_pthread_ok" = xno; then
 942     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 943 fi
 944 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 945 dnl to -pthread, which causes problems if we need -lpthread to appear in
 946 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 947 dnl is not valid for that platform.
 948 if test "x$android" = xno; then
 949     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 950 fi
 951 dnl According to the manual when using pthreads, one should add -pthread to
 952 dnl both compile and link-time arguments.
 953 dnl In practise that should be sufficient for all platforms, since any
 954 dnl platforms build with GCC and Clang support the flag.
 955 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 956
 957 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 958 dnl project. Even then there's a notable issue as described in the project README
 959 case "$host_os" in
 960 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 961     pthread_stubs_possible="no"
 962     ;;
 963 * )
 964     pthread_stubs_possible="yes"
 965     ;;
 966 esac
 967
 968 if test "x$pthread_stubs_possible" = xyes; then
 969     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 970 fi
 971
 972 save_LIBS="$LIBS"
 973 LIBS="$PTHREAD_LIBS"
 974 AC_MSG_CHECKING(whether pthread_setaffinity_np is supported)
 975 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 976     #define _GNU_SOURCE
 977     #include <pthread.h>
 978     int main() {
 979        void *a = (void*) &pthread_setaffinity_np;
 980        long b = (long) a;
 981        return (int) b;
 982     }]])],
 983   [DEFINES="$DEFINES -DHAVE_PTHREAD_SETAFFINITY"];
 984    AC_MSG_RESULT([yes]),
 985    AC_MSG_RESULT([no]))
 986 LIBS="$save_LIBS"
 987
 988 dnl Check for futex for fast inline simple_mtx_t.
 989 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 990
 991 dnl SELinux awareness.
 992 AC_ARG_ENABLE([selinux],
 993     [AS_HELP_STRING([--enable-selinux],
 994         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 995     [MESA_SELINUX="$enableval"],
 996     [MESA_SELINUX=no])
 997 if test "x$enable_selinux" = "xyes"; then
 998     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 999         [AC_CHECK_HEADER([selinux/selinux.h],[],
1000                          [AC_MSG_ERROR([SELinux headers not found])])
1001          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
1002                       [AC_MSG_ERROR([SELinux library not found])])
1003          SELINUX_LIBS="-lselinux"])
1004     DEFINES="$DEFINES -DMESA_SELINUX"
1005 fi
1006 AC_SUBST([SELINUX_CFLAGS])
1007 AC_SUBST([SELINUX_LIBS])
1008
1009 dnl
1010 dnl LLVM
1011 dnl
1012 AC_ARG_ENABLE([llvm-shared-libs],
1013     [AS_HELP_STRING([--enable-llvm-shared-libs],
1014         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1015     [enable_llvm_shared_libs="$enableval"],
1016     [enable_llvm_shared_libs=yes])
1017
1018 AC_ARG_WITH([llvm-prefix],
1019     [AS_HELP_STRING([--with-llvm-prefix],
1020         [Prefix for LLVM installations in non-standard locations])],
1021     [llvm_prefix="$withval"],
1022     [llvm_prefix=''])
1023
1024 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1025 if test "x$have_libelf" = xno; then
1026    LIBELF_LIBS=''
1027    LIBELF_CFLAGS=''
1028    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1029    AC_SUBST([LIBELF_LIBS])
1030    AC_SUBST([LIBELF_CFLAGS])
1031 fi
1032
1033 if test -z "$LLVM_CONFIG"; then
1034     if test -n "$llvm_prefix"; then
1035         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1036     else
1037         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1038     fi
1039 fi
1040
1041 llvm_add_component() {
1042     new_llvm_component=$1
1043     driver_name=$2
1044
1045     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1046         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1047     else
1048         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1049     fi
1050 }
1051
1052 llvm_add_optional_component() {
1053     new_llvm_component=$1
1054     driver_name=$2
1055
1056     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1057         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1058     fi
1059 }
1060
1061 llvm_add_default_components() {
1062     driver_name=$1
1063
1064     # Required default components
1065     llvm_add_component "bitwriter" $driver_name
1066     llvm_add_component "engine" $driver_name
1067     llvm_add_component "mcdisassembler" $driver_name
1068     llvm_add_component "mcjit" $driver_name
1069
1070     # Optional default components
1071     llvm_add_optional_component "inteljitevents" $driver_name
1072 }
1073
1074 llvm_add_target() {
1075     new_llvm_target=$1
1076     driver_name=$2
1077
1078     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1079         llvm_add_component $new_llvm_target $driver_name
1080     else
1081         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1082     fi
1083 }
1084
1085 # Call this inside ` ` to get the return value.
1086 # $1 is the llvm-config command with arguments.
1087 strip_unwanted_llvm_flags() {
1088     echo " `$1` " | sed -E \
1089         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1090         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1091         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1092         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1093         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1094         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1095         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1096         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1097         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1098         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1099         -e 's/^[[[:space:]]]//' \
1100         -e 's/[[[:space:]]]$//'
1101 }
1102
1103 llvm_set_environment_variables() {
1104     if test "x$LLVM_CONFIG" != xno; then
1105         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1106         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1107         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1108         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1109
1110         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1111         save_CFLAGS="$CFLAGS"
1112         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1113
1114         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1115             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1116         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1117             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1118         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1119             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1120
1121         CFLAGS="$save_CFLAGS"
1122
1123         # Only needed for LLVM < 3.6.0
1124         if test -z "$LLVM_VERSION_PATCH"; then
1125             LLVM_VERSION_PATCH=0
1126         fi
1127
1128         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1129
1130         FOUND_LLVM=yes
1131     else
1132         FOUND_LLVM=no
1133         LLVM_VERSION_INT=0
1134     fi
1135 }
1136
1137 require_llvm() {
1138     if test "x$enable_llvm" != "xyes"; then
1139         AC_MSG_ERROR([--enable-llvm is required when building $1])
1140     fi
1141 }
1142
1143 llvm_require_version() {
1144     require_llvm $2
1145
1146     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1147     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1148     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1149
1150     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1151         # major > required major
1152         #  --> OK
1153         return
1154     fi
1155
1156     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1157         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1158             # major = required major and
1159             # minor > required minor
1160             #  --> OK
1161             return
1162         else
1163             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1164                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1165                     # major = required major and
1166                     # minor = required minor and
1167                     # patch >= required patch
1168                     #  --> OK
1169                     return
1170                 fi
1171             fi
1172         fi
1173     fi
1174
1175     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1176 }
1177
1178 radeon_llvm_check() {
1179     if test ${LLVM_VERSION_INT} -lt 307; then
1180         amdgpu_llvm_target_name='r600'
1181     else
1182         amdgpu_llvm_target_name='amdgpu'
1183     fi
1184
1185     llvm_require_version $*
1186
1187     llvm_add_target $amdgpu_llvm_target_name $2
1188
1189     llvm_add_default_components $2
1190     llvm_add_component "bitreader" $2
1191     llvm_add_component "ipo" $2
1192
1193     if test "x$have_libelf" != xyes; then
1194        AC_MSG_ERROR([$2 requires libelf when using llvm])
1195     fi
1196 }
1197
1198 llvm_set_environment_variables
1199
1200 AC_SUBST([LLVM_CFLAGS])
1201 AC_SUBST([LLVM_CXXFLAGS])
1202 AC_SUBST([LLVM_LIBS])
1203 AC_SUBST([LLVM_LDFLAGS])
1204 AC_SUBST([LLVM_INCLUDEDIR])
1205
1206 dnl
1207 dnl libunwind
1208 dnl
1209 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1210 AC_ARG_ENABLE([libunwind],
1211     [AS_HELP_STRING([--enable-libunwind],
1212             [Use libunwind for backtracing (default: auto)])],
1213         [LIBUNWIND="$enableval"],
1214         [LIBUNWIND="$HAVE_LIBUNWIND"])
1215
1216 if test "x$LIBUNWIND" = "xyes"; then
1217     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1218     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1219 fi
1220
1221
1222 dnl Options for APIs
1223 AC_ARG_ENABLE([opengl],
1224     [AS_HELP_STRING([--disable-opengl],
1225         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1226     [enable_opengl="$enableval"],
1227     [enable_opengl=yes])
1228 AC_ARG_ENABLE([gles1],
1229     [AS_HELP_STRING([--disable-gles1],
1230         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1231     [enable_gles1="$enableval"],
1232     [enable_gles1=yes])
1233 AC_ARG_ENABLE([gles2],
1234     [AS_HELP_STRING([--disable-gles2],
1235         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1236     [enable_gles2="$enableval"],
1237     [enable_gles2=yes])
1238
1239 AC_ARG_ENABLE([dri],
1240     [AS_HELP_STRING([--enable-dri],
1241         [enable DRI modules @<:@default=enabled@:>@])],
1242     [enable_dri="$enableval"],
1243     [enable_dri=yes])
1244
1245 AC_ARG_ENABLE([gallium-extra-hud],
1246     [AS_HELP_STRING([--enable-gallium-extra-hud],
1247         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1248     [enable_gallium_extra_hud="$enableval"],
1249     [enable_gallium_extra_hud=no])
1250 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1251 if test "x$enable_gallium_extra_hud" = xyes ; then
1252     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1253 fi
1254
1255 #TODO: no pkgconfig .pc available for libsensors.
1256 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1257 AC_ARG_ENABLE([lmsensors],
1258     [AS_HELP_STRING([--enable-lmsensors],
1259         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1260     [enable_lmsensors="$enableval"],
1261     [enable_lmsensors=no])
1262 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1263 if test "x$enable_lmsensors" = xyes ; then
1264     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1265     LIBSENSORS_LIBS="-lsensors"
1266 else
1267     LIBSENSORS_LIBS=""
1268 fi
1269 AC_SUBST(LIBSENSORS_LIBS)
1270
1271 case "$host_os" in
1272 linux*)
1273     dri3_default=yes
1274     ;;
1275 *)
1276     dri3_default=no
1277     ;;
1278 esac
1279
1280 if test "x$enable_dri" = xno; then
1281     dri3_default=no
1282 fi
1283
1284 AC_ARG_ENABLE([dri3],
1285     [AS_HELP_STRING([--enable-dri3],
1286         [enable DRI3 @<:@default=auto@:>@])],
1287     [enable_dri3="$enableval"],
1288     [enable_dri3="$dri3_default"])
1289 AC_ARG_ENABLE([glx],
1290     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1291         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1292     [enable_glx="$enableval"],
1293     [enable_glx=yes])
1294 AC_ARG_ENABLE([osmesa],
1295     [AS_HELP_STRING([--enable-osmesa],
1296         [enable OSMesa library @<:@default=disabled@:>@])],
1297     [enable_osmesa="$enableval"],
1298     [enable_osmesa=no])
1299 AC_ARG_ENABLE([gallium-osmesa],
1300     [AS_HELP_STRING([--enable-gallium-osmesa],
1301         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1302     [enable_gallium_osmesa="$enableval"],
1303     [enable_gallium_osmesa=no])
1304 AC_ARG_ENABLE([egl],
1305     [AS_HELP_STRING([--disable-egl],
1306         [disable EGL library @<:@default=enabled@:>@])],
1307     [enable_egl="$enableval"],
1308     [enable_egl=yes])
1309
1310 AC_ARG_ENABLE([xa],
1311     [AS_HELP_STRING([--enable-xa],
1312         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1313     [enable_xa="$enableval"],
1314     [enable_xa=no])
1315 AC_ARG_ENABLE([gbm],
1316    [AS_HELP_STRING([--enable-gbm],
1317          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1318    [enable_gbm="$enableval"],
1319    [case "$host_os" in
1320        cygwin* | darwin*)
1321           enable_gbm=no
1322           ;;
1323        *)
1324           enable_gbm=yes
1325           ;;
1326     esac])
1327 AC_ARG_ENABLE([nine],
1328     [AS_HELP_STRING([--enable-nine],
1329         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1330     [enable_nine="$enableval"],
1331     [enable_nine=no])
1332
1333 AC_ARG_ENABLE([xvmc],
1334    [AS_HELP_STRING([--enable-xvmc],
1335          [enable xvmc library @<:@default=auto@:>@])],
1336    [enable_xvmc="$enableval"],
1337    [enable_xvmc=auto])
1338 AC_ARG_ENABLE([vdpau],
1339    [AS_HELP_STRING([--enable-vdpau],
1340          [enable vdpau library @<:@default=auto@:>@])],
1341    [enable_vdpau="$enableval"],
1342    [enable_vdpau=auto])
1343 AC_ARG_ENABLE([omx],
1344    [AS_HELP_STRING([--enable-omx],
1345          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1346    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1347    [])
1348 AC_ARG_ENABLE([omx-bellagio],
1349    [AS_HELP_STRING([--enable-omx-bellagio],
1350          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1351    [enable_omx_bellagio="$enableval"],
1352    [enable_omx_bellagio=no])
1353 AC_ARG_ENABLE([omx-tizonia],
1354    [AS_HELP_STRING([--enable-omx-tizonia],
1355          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1356    [enable_omx_tizonia="$enableval"],
1357    [enable_omx_tizonia=no])
1358 AC_ARG_ENABLE([va],
1359    [AS_HELP_STRING([--enable-va],
1360          [enable va library @<:@default=auto@:>@])],
1361    [enable_va="$enableval"],
1362    [enable_va=auto])
1363 AC_ARG_ENABLE([opencl],
1364    [AS_HELP_STRING([--enable-opencl],
1365          [enable OpenCL library @<:@default=disabled@:>@])],
1366    [enable_opencl="$enableval"],
1367    [enable_opencl=no])
1368 AC_ARG_ENABLE([opencl_icd],
1369    [AS_HELP_STRING([--enable-opencl-icd],
1370           [Build an OpenCL ICD library to be loaded by an ICD implementation
1371            @<:@default=enabled@:>@])],
1372     [enable_opencl_icd="$enableval"],
1373     [enable_opencl_icd=yes])
1374
1375 AC_ARG_ENABLE([gallium-tests],
1376     [AS_HELP_STRING([--enable-gallium-tests],
1377         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1378     [enable_gallium_tests="$enableval"],
1379     [enable_gallium_tests=no])
1380
1381 # Option for Gallium drivers
1382
1383 # Keep this in sync with the --with-gallium-drivers help string default value
1384 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1385
1386 AC_ARG_WITH([gallium-drivers],
1387     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1388         [comma delimited Gallium drivers list, e.g.
1389         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1390         @<:@default=r300,r600,svga,swrast@:>@])],
1391     [with_gallium_drivers="$withval"],
1392     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1393
1394 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1395 # here so that the script doesn't choke on an unknown driver name later.
1396 case "$with_gallium_drivers" in
1397     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1398     no) with_gallium_drivers='' ;;
1399 esac
1400
1401 if test "x$enable_opengl" = xno -a \
1402         "x$enable_gles1" = xno -a \
1403         "x$enable_gles2" = xno -a \
1404         "x$enable_nine" = xno -a \
1405         "x$enable_xa" = xno -a \
1406         "x$enable_xvmc" = xno -a \
1407         "x$enable_vdpau" = xno -a \
1408         "x$enable_omx_bellagio" = xno -a \
1409         "x$enable_omx_tizonia" = xno -a \
1410         "x$enable_va" = xno -a \
1411         "x$enable_opencl" = xno; then
1412     AC_MSG_ERROR([at least one API should be enabled])
1413 fi
1414
1415 if test "x$enable_omx_bellagio" = xyes -a \
1416         "x$enable_omx_tizonia" = xyes; then
1417    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1418 fi
1419
1420 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1421 if test "x$enable_opengl" = xno -a \
1422         "x$enable_gles1" = xyes; then
1423     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1424 fi
1425
1426 if test "x$enable_opengl" = xno -a \
1427         "x$enable_gles2" = xyes; then
1428     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1429 fi
1430
1431 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1432 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1433 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1434 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1435                                         "x$enable_gles1" = xyes -o \
1436                                         "x$enable_gles2" = xyes)
1437 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1438                                       "x$enable_opengl" = xyes -o \
1439                                       "x$enable_gles1" = xyes -o \
1440                                       "x$enable_gles2" = xyes)
1441
1442 # Validate GLX options
1443 if test "x$enable_glx" = xyes; then
1444     if test "x$enable_dri" = xyes; then
1445         enable_glx=dri
1446     elif test -n "$with_gallium_drivers"; then
1447         enable_glx=gallium-xlib
1448     else
1449         enable_glx=xlib
1450     fi
1451 fi
1452 case "x$enable_glx" in
1453 xdri | xxlib | xgallium-xlib)
1454     # GLX requires OpenGL
1455     if test "x$enable_opengl" = xno; then
1456         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1457     fi
1458
1459     # Check individual dependencies
1460     case "x$enable_glx" in
1461     xdri)
1462         if test "x$enable_dri" = xno; then
1463             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1464         fi
1465         ;;
1466     xxlib)
1467         if test "x$enable_dri" = xyes; then
1468             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1469         fi
1470         ;;
1471     xgallium-xlib )
1472         if test "x$enable_dri" = xyes; then
1473             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1474         fi
1475         if test -z "$with_gallium_drivers"; then
1476             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1477         fi
1478         ;;
1479     esac
1480     ;;
1481 xno)
1482     ;;
1483 *)
1484     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1485     ;;
1486 esac
1487
1488 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1489 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1490 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1491 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1492
1493 DEFAULT_GL_LIB_NAME=GL
1494
1495 dnl
1496 dnl Libglvnd configuration
1497 dnl
1498 AC_ARG_ENABLE([libglvnd],
1499     [AS_HELP_STRING([--enable-libglvnd],
1500         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1501     [enable_libglvnd="$enableval"],
1502     [enable_libglvnd=no])
1503 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1504
1505 if test "x$enable_libglvnd" = xyes ; then
1506     case "x$enable_glx" in
1507     xxlib | xgallium-xlib )
1508         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1509         ;;
1510     esac
1511
1512     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1513     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1514     AC_SUBST([LIBGLVND_DATADIR])
1515
1516     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1517     DEFAULT_GL_LIB_NAME=GLX_mesa
1518
1519     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1520         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1521     fi
1522 fi
1523
1524 AC_ARG_WITH([gl-lib-name],
1525   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1526     [specify GL library name @<:@default=GL@:>@])],
1527   [AC_MSG_ERROR([--with-gl-lib-name is no longer supported. Rename the library manually if needed.])],
1528   [])
1529 AC_ARG_WITH([osmesa-lib-name],
1530   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1531     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1532   [AC_MSG_ERROR([--with-osmesa-lib-name is no longer supported. Rename the library manually if needed.])],
1533   [])
1534 GL_LIB="$DEFAULT_GL_LIB_NAME"
1535 OSMESA_LIB=OSMesa
1536
1537 dnl
1538 dnl Mangled Mesa support
1539 dnl
1540 AC_ARG_ENABLE([mangling],
1541   [AS_HELP_STRING([--enable-mangling],
1542     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1543   [enable_mangling="${enableval}"],
1544   [enable_mangling=no]
1545 )
1546 if test "x${enable_mangling}" = "xyes" ; then
1547   if test "x$enable_libglvnd" = xyes; then
1548     AC_MSG_ERROR([Conflicting options --enable-mangling and --enable-libglvnd.])
1549   fi
1550   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1551   GL_LIB="Mangled${GL_LIB}"
1552   OSMESA_LIB="Mangled${OSMESA_LIB}"
1553 fi
1554 AC_SUBST([GL_LIB])
1555 AC_SUBST([OSMESA_LIB])
1556
1557 dnl HACK when building glx + glvnd we ship gl.pc, despite that glvnd should do it
1558 dnl Thus we need to use GL as a DSO name.
1559 if test "x$enable_libglvnd" = xyes -a "x$enable_glx" != xno; then
1560   GL_PKGCONF_LIB="GL"
1561 else
1562   GL_PKGCONF_LIB="$GL_LIB"
1563 fi
1564 AC_SUBST([GL_PKGCONF_LIB])
1565
1566 # Check for libdrm
1567 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1568                   [have_libdrm=yes], [have_libdrm=no])
1569 if test "x$have_libdrm" = xyes; then
1570     DEFINES="$DEFINES -DHAVE_LIBDRM"
1571 fi
1572
1573 require_libdrm() {
1574     if test "x$have_libdrm" != xyes; then
1575        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1576     fi
1577 }
1578
1579
1580 # Select which platform-dependent DRI code gets built
1581 case "$host_os" in
1582 darwin*)
1583     dri_platform='apple' ;;
1584 cygwin*)
1585     dri_platform='windows' ;;
1586 gnu*)
1587     dri_platform='none' ;;
1588 *)
1589     dri_platform='drm' ;;
1590 esac
1591
1592 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1593     have_drisw_kms='yes'
1594 fi
1595
1596 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1597 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1598 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1599 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1600 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1601 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1602 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1603 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1604 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1605 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1606
1607 AC_ARG_ENABLE([shared-glapi],
1608     [AS_HELP_STRING([--enable-shared-glapi],
1609         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1610     [enable_shared_glapi="$enableval"],
1611     [enable_shared_glapi=yes])
1612
1613 case "x$enable_opengl$enable_gles1$enable_gles2" in
1614 x*yes*yes*)
1615     if test "x$enable_shared_glapi" = xno; then
1616         AC_MSG_ERROR([shared GLAPI required when building two or more of
1617                       the following APIs - opengl, gles1 gles2])
1618     fi
1619     ;;
1620 esac
1621
1622 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1623
1624 # Build the pipe-drivers as separate libraries/modules.
1625 # Do not touch this unless you know what you are doing.
1626 # XXX: Expose via configure option ?
1627 enable_shared_pipe_drivers=no
1628
1629 dnl
1630 dnl Driver specific build directories
1631 dnl
1632
1633 if test "x$enable_gallium_osmesa" = xyes; then
1634     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1635         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1636     fi
1637     if test "x$enable_osmesa" = xyes; then
1638         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1639     fi
1640 fi
1641
1642 require_dri_shared_libs_and_glapi() {
1643     if test "x$enable_static" = xyes; then
1644         AC_MSG_ERROR([$1 cannot be build as static library])
1645     fi
1646
1647     if test "x$enable_dri" != xyes; then
1648         # There is only a single backend which won't be build/used otherwise.
1649         # XXX: Revisit this as the egl/haiku is a thing.
1650         AC_MSG_ERROR([$1 requires --enable-dri])
1651     fi
1652
1653     if test "x$enable_shared_glapi" != xyes; then
1654         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1655     fi
1656 }
1657
1658 if test "x$enable_dri" = xyes; then
1659     require_dri_shared_libs_and_glapi "DRI"
1660
1661     # not a hard requirement as swrast does not depend on it
1662     if test "x$have_libdrm" = xyes; then
1663         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1664     fi
1665 fi
1666
1667 AC_ARG_ENABLE([driglx-direct],
1668     [AS_HELP_STRING([--disable-driglx-direct],
1669         [disable direct rendering in GLX and EGL for DRI \
1670             @<:@default=enabled@:>@])],
1671     [driglx_direct="$enableval"],
1672     [driglx_direct="yes"])
1673
1674 dnl
1675 dnl libGL configuration per driver
1676 dnl
1677 if test "x$enable_glx" != xno; then
1678     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1679 fi
1680 case "x$enable_glx" in
1681 xxlib | xgallium-xlib)
1682     # Xlib-based GLX
1683     dri_modules="x11 xext xcb"
1684     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1685     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1686     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1687     GL_LIB_DEPS="$XLIBGL_LIBS"
1688     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1689     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1690     ;;
1691 xdri)
1692     # DRI-based GLX
1693
1694     require_dri_shared_libs_and_glapi "GLX"
1695
1696     # find the DRI deps for libGL
1697     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1698
1699     if test x"$driglx_direct" = xyes; then
1700         if test x"$dri_platform" = xdrm ; then
1701             DEFINES="$DEFINES -DGLX_USE_DRM"
1702             require_libdrm "Direct rendering"
1703
1704             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1705             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1706
1707             if test x"$enable_dri" = xyes; then
1708                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1709             fi
1710         fi
1711         if test x"$dri_platform" = xapple ; then
1712             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1713         fi
1714         if test x"$dri_platform" = xwindows ; then
1715             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1716         fi
1717     fi
1718
1719     # add xf86vidmode if available
1720     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1721     if test "$HAVE_XF86VIDMODE" = yes ; then
1722         dri_modules="$dri_modules xxf86vm"
1723     fi
1724
1725     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1726     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1727     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1728     GL_LIB_DEPS="$DRIGL_LIBS"
1729
1730     # need DRM libs, $PTHREAD_LIBS, etc.
1731     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1732     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1733     ;;
1734 esac
1735
1736 # This is outside the case (above) so that it is invoked even for non-GLX
1737 # builds.
1738 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1739
1740 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1741 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1742 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1743 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1744
1745 AC_SUBST([X11_INCLUDES])
1746 AC_SUBST([GL_LIB_DEPS])
1747 AC_SUBST([GL_PC_REQ_PRIV])
1748 AC_SUBST([GL_PC_LIB_PRIV])
1749 AC_SUBST([GL_PC_CFLAGS])
1750 AC_SUBST([DRI_PC_REQ_PRIV])
1751 AC_SUBST([GLESv1_CM_LIB_DEPS])
1752 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1753 AC_SUBST([GLESv2_LIB_DEPS])
1754 AC_SUBST([GLESv2_PC_LIB_PRIV])
1755
1756 AC_SUBST([HAVE_XF86VIDMODE])
1757
1758 dnl
1759 dnl More GLX setup
1760 dnl
1761 case "x$enable_glx" in
1762 xxlib | xgallium-xlib)
1763     DEFINES="$DEFINES -DUSE_XSHM"
1764     ;;
1765 xdri)
1766     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1767     if test "x$driglx_direct" = xyes; then
1768         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1769     fi
1770     ;;
1771 esac
1772
1773 dnl
1774 dnl TLS detection
1775 dnl
1776
1777 AC_ARG_ENABLE([glx-tls],
1778     [AS_HELP_STRING([--enable-glx-tls],
1779         [enable TLS support in GLX @<:@default=enabled@:>@])],
1780     [GLX_USE_TLS="$enableval"],
1781     [GLX_USE_TLS=yes])
1782 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1783
1784 if test "x$GLX_USE_TLS" = xyes; then
1785     DEFINES="$DEFINES -DGLX_USE_TLS"
1786 fi
1787
1788 dnl Read-only text section on x86 hardened platforms
1789 AC_ARG_ENABLE([glx-read-only-text],
1790     [AS_HELP_STRING([--enable-glx-read-only-text],
1791         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1792     [enable_glx_read_only_text="$enableval"],
1793     [enable_glx_read_only_text=no])
1794 if test "x$enable_glx_read_only_text" = xyes; then
1795     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1796 fi
1797
1798 dnl
1799 dnl DEPRECATED: EGL Platforms configuration
1800 dnl
1801 AC_ARG_WITH([egl-platforms],
1802     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1803         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1804     [with_egl_platforms="$withval"],
1805     [with_egl_platforms=auto])
1806
1807 if test "x$with_egl_platforms" = xauto; then
1808     with_egl_platforms="x11,surfaceless"
1809     if test "x$enable_gbm" = xyes; then
1810         with_egl_platforms="$with_egl_platforms,drm"
1811     fi
1812 else
1813     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1814 fi
1815
1816 dnl
1817 dnl Platforms configuration
1818 dnl
1819 AC_ARG_WITH([platforms],
1820     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1821         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1822         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1823     [with_platforms="$withval"],
1824     [with_platforms=auto])
1825
1826 # Reuse the autodetection rather than duplicating it.
1827 if test "x$with_platforms" = xauto; then
1828     with_platforms=$with_egl_platforms
1829 fi
1830
1831 # Do per platform setups and checks
1832 platforms=`IFS=', '; echo $with_platforms`
1833 for plat in $platforms; do
1834     case "$plat" in
1835     wayland)
1836
1837         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1838         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1839         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1840         if test "x$enable_egl" = xyes; then
1841           PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1842         fi
1843         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1844
1845         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1846                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1847                           WAYLAND_SCANNER='')
1848         PKG_CHECK_EXISTS([wayland-scanner >= 1.15],
1849                           AC_SUBST(SCANNER_ARG, 'private-code'),
1850                           AC_SUBST(SCANNER_ARG, 'code'))
1851
1852         if test "x$WAYLAND_SCANNER" = x; then
1853             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1854         fi
1855
1856         if test "x$WAYLAND_SCANNER" = "x:"; then
1857                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1858         fi
1859         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1860         ;;
1861
1862     x11)
1863         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1864         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1865         ;;
1866
1867     drm)
1868         test "x$enable_gbm" = "xno" &&
1869                 AC_MSG_ERROR([EGL platform drm needs gbm])
1870         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1871         ;;
1872
1873     surfaceless)
1874         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1875         ;;
1876
1877     android)
1878         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1879         if test -n "$with_gallium_drivers"; then
1880             PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1881         fi
1882         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1883         ;;
1884
1885     *)
1886         AC_MSG_ERROR([platform '$plat' does not exist])
1887         ;;
1888     esac
1889
1890     case "$plat" in
1891     wayland|drm|surfaceless)
1892         require_libdrm "Platform $plat"
1893         ;;
1894     esac
1895 done
1896 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1897
1898 if test "x$enable_glx" != xno; then
1899     if ! echo "$platforms" | grep -q 'x11'; then
1900         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1901     fi
1902 fi
1903
1904 if test x"$enable_dri3" = xyes; then
1905     DEFINES="$DEFINES -DHAVE_DRI3"
1906
1907     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1908     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1909     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1910     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1911
1912     if test "x$have_dri3_modifiers" == xyes; then
1913         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1914     fi
1915 fi
1916
1917
1918 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1919     have_xlease=yes
1920 else
1921     have_xlease=no
1922 fi
1923
1924 if test x"$have_xlease" = xyes; then
1925     randr_modules="x11-xcb xcb-randr"
1926     PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1927     xlib_randr_modules="xrandr"
1928     PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1929 fi
1930
1931 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1932 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1933 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1934 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1935 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1936
1937 AC_ARG_ENABLE(xlib-lease,
1938     [AS_HELP_STRING([--enable-xlib-lease]
1939                     [enable VK_acquire_xlib_display using X leases])],
1940     [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1941 case "x$enable_xlib_lease" in
1942 xyes)
1943     ;;
1944 xno)
1945     ;;
1946 *)
1947     if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1948         enable_xlib_lease=yes
1949     else
1950         enable_xlib_lease=no
1951     fi
1952 esac
1953
1954 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1955
1956 dnl
1957 dnl More DRI setup
1958 dnl
1959 dnl Directory for DRI drivers
1960 AC_ARG_WITH([dri-driverdir],
1961     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1962         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1963     [DRI_DRIVER_INSTALL_DIR="$withval"],
1964     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1965 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1966 dnl Extra search path for DRI drivers
1967 AC_ARG_WITH([dri-searchpath],
1968     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1969         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1970     [DRI_DRIVER_SEARCH_DIR="$withval"],
1971     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1972 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1973 dnl Which drivers to build - default is chosen by platform
1974 AC_ARG_WITH([dri-drivers],
1975     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1976         [comma delimited classic DRI drivers list, e.g.
1977         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1978     [with_dri_drivers="$withval"],
1979     [with_dri_drivers=auto])
1980
1981 if test "x$with_dri_drivers" = xauto; then
1982     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1983         with_dri_drivers="yes"
1984     else
1985         with_dri_drivers="no"
1986     fi
1987 fi
1988 if test "x$with_dri_drivers" = xno; then
1989     with_dri_drivers=''
1990 fi
1991
1992 # Check for expat
1993 PKG_CHECK_MODULES([EXPAT], [expat],,
1994     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1995 )
1996
1997 dnl If $with_dri_drivers is yes, drivers will be added through
1998 dnl platform checks. Set DEFINES and LIB_DEPS
1999 if test "x$enable_dri" = xyes; then
2000     # Platform specific settings and drivers to build
2001     case "$host_os" in
2002     linux*)
2003         case "$host_cpu" in
2004         powerpc* | sparc*)
2005             # Build only the drivers for cards that exist on PowerPC/sparc
2006             if test "x$with_dri_drivers" = "xyes"; then
2007                 with_dri_drivers="r200 radeon swrast"
2008             fi
2009             ;;
2010         esac
2011         ;;
2012     cygwin*)
2013         if test "x$with_dri_drivers" = "xyes"; then
2014             with_dri_drivers="swrast"
2015         fi
2016         ;;
2017     darwin*)
2018         DEFINES="$DEFINES -DBUILDING_MESA"
2019         if test "x$with_dri_drivers" = "xyes"; then
2020             with_dri_drivers="swrast"
2021         fi
2022         ;;
2023     esac
2024
2025     # default drivers
2026     if test "x$with_dri_drivers" = "xyes"; then
2027         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
2028     fi
2029
2030     # put all the necessary libs together
2031     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
2032 fi
2033
2034 AC_SUBST([DRI_LIB_DEPS])
2035
2036 DRI_DIRS=''
2037 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
2038 if test -n "$with_dri_drivers"; then
2039     if test "x$enable_opengl" != xyes; then
2040         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2041     fi
2042
2043     dri_drivers=`IFS=', '; echo $with_dri_drivers`
2044     for driver in $dri_drivers; do
2045         DRI_DIRS="$DRI_DIRS $driver"
2046         case "x$driver" in
2047         xi915)
2048             require_libdrm "i915"
2049             HAVE_I915_DRI=yes
2050             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2051             ;;
2052         xi965)
2053             require_libdrm "i965"
2054             HAVE_I965_DRI=yes
2055             ;;
2056         xnouveau)
2057             require_libdrm "nouveau"
2058             HAVE_NOUVEAU_DRI=yes
2059             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2060             ;;
2061         xradeon)
2062             require_libdrm "radeon"
2063             HAVE_RADEON_DRI=yes;
2064             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2065             ;;
2066         xr200)
2067             require_libdrm "r200"
2068             HAVE_R200_DRI=yes
2069             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2070             ;;
2071         xswrast)
2072             HAVE_SWRAST_DRI=yes
2073             ;;
2074         *)
2075             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2076             ;;
2077         esac
2078     done
2079     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2080 fi
2081
2082
2083 dnl
2084 dnl Gallium LLVM
2085 dnl Deprecated: kept for backwards compatibility
2086 dnl
2087 AC_ARG_ENABLE([gallium-llvm],
2088     [AS_HELP_STRING([--enable-gallium-llvm],
2089         [DEPRECATED: use --enable-llvm instead])],
2090     [enable_gallium_llvm="$enableval"],
2091     [enable_gallium_llvm=auto])
2092
2093 if test "x$enable_gallium_llvm" != xauto; then
2094    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2095    enable_llvm=$enable_gallium_llvm
2096 fi
2097
2098 dnl
2099 dnl LLVM
2100 dnl
2101 AC_ARG_ENABLE([llvm],
2102     [AS_HELP_STRING([--enable-llvm],
2103         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2104     [enable_llvm="$enableval"],
2105     [enable_llvm=auto])
2106
2107 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2108     if test "x$FOUND_LLVM" = xyes; then
2109         case "$host_cpu" in
2110         i*86|x86_64|amd64) enable_llvm=yes;;
2111         *) enable_llvm=no;;
2112         esac
2113     else
2114         enable_llvm=no
2115     fi
2116 fi
2117
2118 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2119     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2120 fi
2121
2122 #
2123 # Vulkan driver configuration
2124 #
2125
2126 AC_ARG_WITH([vulkan-drivers],
2127     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2128         [comma delimited Vulkan drivers list, e.g.
2129         "intel,radeon"
2130         @<:@default=no@:>@])],
2131     [with_vulkan_drivers="$withval"],
2132     [with_vulkan_drivers="no"])
2133
2134 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2135 # here so that the script doesn't choke on an unknown driver name later.
2136 case "x$with_vulkan_drivers" in
2137     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2138     xno) with_vulkan_drivers='' ;;
2139 esac
2140
2141 AC_ARG_WITH([vulkan-icddir],
2142     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2143         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2144     [VULKAN_ICD_INSTALL_DIR="$withval"],
2145     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2146 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2147
2148 require_x11_dri3() {
2149     if echo "$platforms" | grep -q 'x11'; then
2150         if test "x$enable_dri3" != xyes; then
2151             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2152         fi
2153     fi
2154 }
2155
2156 if test -n "$with_vulkan_drivers"; then
2157     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2158         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2159     fi
2160
2161     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2162     for driver in $VULKAN_DRIVERS; do
2163         case "x$driver" in
2164         xintel)
2165             require_libdrm "ANV"
2166             require_x11_dri3 "ANV"
2167             HAVE_INTEL_VULKAN=yes
2168             ;;
2169         xradeon)
2170             require_libdrm "radv"
2171             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2172             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2173             require_x11_dri3 "radv"
2174             if test "x$acv_mako_found" = xno; then
2175                 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2176             fi
2177             HAVE_RADEON_VULKAN=yes
2178             ;;
2179         *)
2180             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2181             ;;
2182         esac
2183     done
2184     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2185 fi
2186
2187
2188 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2189 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2190 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2191                                   "x$enable_osmesa" = xyes -o \
2192                                   -n "$DRI_DIRS")
2193
2194 dnl
2195 dnl OSMesa configuration
2196 dnl
2197
2198 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2199 AC_ARG_WITH([osmesa-bits],
2200     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2201         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2202     [osmesa_bits="$withval"],
2203     [osmesa_bits=8])
2204 if test "x$osmesa_bits" != x8; then
2205     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2206         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2207         osmesa_bits=8
2208     fi
2209 fi
2210 case "x$osmesa_bits" in
2211 x8)
2212     OSMESA_LIB="${OSMESA_LIB}"
2213     ;;
2214 x16|x32)
2215     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2216     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2217     ;;
2218 *)
2219     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2220     ;;
2221 esac
2222
2223 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2224     # only link libraries with osmesa if shared
2225     if test "$enable_static" = no; then
2226         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2227     else
2228         OSMESA_LIB_DEPS=""
2229     fi
2230     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2231 fi
2232
2233 AC_SUBST([OSMESA_LIB_DEPS])
2234 AC_SUBST([OSMESA_PC_REQ])
2235 AC_SUBST([OSMESA_PC_LIB_PRIV])
2236
2237 dnl
2238 dnl gbm configuration
2239 dnl
2240 if test "x$enable_gbm" = xyes; then
2241     require_dri_shared_libs_and_glapi "gbm"
2242 fi
2243 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2244 # FINISHME: GBM has a number of dependencies which we should add below
2245 GBM_PC_REQ_PRIV=""
2246 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2247 AC_SUBST([GBM_PC_REQ_PRIV])
2248 AC_SUBST([GBM_PC_LIB_PRIV])
2249
2250 dnl
2251 dnl EGL configuration
2252 dnl
2253
2254 if test "x$enable_egl" = xyes; then
2255     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2256
2257     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2258
2259     require_dri_shared_libs_and_glapi "egl"
2260 fi
2261 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2262 AC_SUBST([EGL_LIB_DEPS])
2263
2264 gallium_st="mesa"
2265
2266 dnl
2267 dnl XA configuration
2268 dnl
2269 if test "x$enable_xa" = xyes; then
2270     if test "x$with_gallium_drivers" = xswrast; then
2271        AC_MSG_ERROR([
2272           Building xa requires at least one non swrast gallium driver.
2273           If you are looking to use libxatracker.so with the VMware driver,
2274           make sure to include svga in the gallium drivers list, apart from
2275           enabling XA.
2276           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2277     fi
2278     gallium_st="$gallium_st xa"
2279 fi
2280 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2281
2282 if echo $platforms | grep -q "x11"; then
2283     have_xvmc_platform=yes
2284 else
2285     have_xvmc_platform=no
2286 fi
2287
2288 if echo $platforms | grep -q "x11"; then
2289     have_vdpau_platform=yes
2290 else
2291     have_vdpau_platform=no
2292 fi
2293
2294 if echo $platforms | egrep -q "x11|drm"; then
2295     have_omx_platform=yes
2296 else
2297     have_omx_platform=no
2298 fi
2299
2300 if echo $platforms | egrep -q "x11|drm|wayland"; then
2301     have_va_platform=yes
2302 else
2303     have_va_platform=no
2304 fi
2305
2306 dnl
2307 dnl Gallium G3DVL configuration
2308 dnl
2309 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2310     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2311         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2312     fi
2313
2314     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2315         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2316     fi
2317
2318     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2319         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2320     fi
2321
2322     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2323        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2324     fi
2325
2326     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2327         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2328     fi
2329 fi
2330
2331 if test "x$enable_dri" = xyes -o \
2332         "x$enable_xvmc" = xyes -o \
2333         "x$enable_vdpau" = xyes -o \
2334         "x$enable_omx_bellagio" = xyes -o \
2335         "x$enable_omx_tizonia" = xyes -o \
2336         "x$enable_va" = xyes; then
2337     need_gallium_vl=yes
2338 fi
2339 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2340
2341 if test "x$enable_xvmc" = xyes -o \
2342         "x$enable_vdpau" = xyes -o \
2343         "x$enable_omx_bellagio" = xyes -o \
2344         "x$enable_omx_tizonia" = xyes -o \
2345         "x$enable_va" = xyes; then
2346     if echo $platforms | grep -q "x11"; then
2347         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2348     fi
2349     need_gallium_vl_winsys=yes
2350 fi
2351 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2352
2353 if test "x$enable_xvmc" = xyes; then
2354     if test "x$have_xvmc_platform" != xyes; then
2355         AC_MSG_ERROR([XVMC requires the x11 platforms])
2356     fi
2357     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2358     gallium_st="$gallium_st xvmc"
2359 fi
2360 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2361
2362 if test "x$enable_vdpau" = xyes; then
2363     if test "x$have_vdpau_platform" != xyes; then
2364         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2365     fi
2366     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2367     gallium_st="$gallium_st vdpau"
2368     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2369 fi
2370 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2371
2372 if test "x$enable_omx_bellagio" = xyes; then
2373     if test "x$have_omx_platform" != xyes; then
2374         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2375     fi
2376     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2377     gallium_st="$gallium_st omx_bellagio"
2378     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2379 else
2380     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2381 fi
2382 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2383
2384 if test "x$enable_omx_tizonia" = xyes; then
2385     if test "x$have_omx_platform" != xyes; then
2386         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2387     fi
2388     PKG_CHECK_MODULES([OMX_TIZONIA],
2389                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2390                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2391                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2392     gallium_st="$gallium_st omx_tizonia"
2393     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2394 else
2395     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2396 fi
2397 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2398
2399 if test "x$enable_va" = xyes; then
2400     if test "x$have_va_platform" != xyes; then
2401         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2402     fi
2403     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2404     gallium_st="$gallium_st va"
2405 fi
2406 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2407
2408 dnl
2409 dnl Nine Direct3D9 configuration
2410 dnl
2411 if test "x$enable_nine" = xyes; then
2412     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2413         AC_MSG_ERROR([nine requires the gallium swrast driver])
2414     fi
2415     if test "x$with_gallium_drivers" = xswrast; then
2416         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2417     fi
2418     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2419         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2420     fi
2421
2422     if test "x$enable_dri3" = xno; then
2423         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2424     fi
2425
2426     gallium_st="$gallium_st nine"
2427 fi
2428 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2429
2430 dnl
2431 dnl OpenCL configuration
2432 dnl
2433
2434 AC_ARG_WITH([clang-libdir],
2435    [AS_HELP_STRING([--with-clang-libdir],
2436          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2437    [CLANG_LIBDIR="$withval"],
2438    [CLANG_LIBDIR=''])
2439
2440 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2441
2442 if test "x$enable_opencl" = xyes; then
2443     if test -z "$with_gallium_drivers"; then
2444         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2445     fi
2446
2447     if test "x$HAVE_CXX11" != "xyes"; then
2448        AC_MSG_ERROR([clover requires c++11 support])
2449     fi
2450
2451     if test "x$have_libclc" = xno; then
2452         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2453                     Make sure the directory containing libclc.pc is specified in your
2454                     PKG_CONFIG_PATH environment variable.
2455                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2456     else
2457         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2458         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2459         AC_SUBST([LIBCLC_INCLUDEDIR])
2460         AC_SUBST([LIBCLC_LIBEXECDIR])
2461     fi
2462
2463     gallium_st="$gallium_st clover"
2464
2465     if test "x$enable_opencl_icd" = xyes; then
2466         OPENCL_LIBNAME="MesaOpenCL"
2467     else
2468         OPENCL_LIBNAME="OpenCL"
2469     fi
2470
2471     if test "x$have_libelf" != xyes; then
2472        AC_MSG_ERROR([Clover requires libelf])
2473     fi
2474
2475     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2476         altivec_enabled=no
2477         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2478         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2479         #error "AltiVec not enabled"
2480         #endif
2481         ])], altivec_enabled=yes)
2482
2483         if test "$altivec_enabled" = yes; then
2484             CLOVER_STD_OVERRIDE="-std=gnu++11"
2485         fi
2486         AC_SUBST([CLOVER_STD_OVERRIDE])
2487     fi
2488
2489     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2490
2491     llvm_add_default_components "opencl"
2492     llvm_add_component "all-targets" "opencl"
2493     llvm_add_component "coverage" "opencl"
2494     llvm_add_component "linker" "opencl"
2495     llvm_add_component "instrumentation" "opencl"
2496     llvm_add_component "ipo" "opencl"
2497     llvm_add_component "irreader" "opencl"
2498     llvm_add_component "lto" "opencl"
2499     llvm_add_component "option" "opencl"
2500     llvm_add_component "objcarcopts" "opencl"
2501     llvm_add_component "profiledata" "opencl"
2502     llvm_add_optional_component "coroutines" "opencl"
2503
2504     dnl Check for Clang internal headers
2505     if test -z "$CLANG_LIBDIR"; then
2506         CLANG_LIBDIR=${LLVM_LIBDIR}
2507     fi
2508     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2509     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2510         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2511 fi
2512 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2513 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2514 AC_SUBST([OPENCL_LIBNAME])
2515 AC_SUBST([CLANG_RESOURCE_DIR])
2516
2517 dnl
2518 dnl Gallium configuration
2519 dnl
2520 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2521
2522 # libEGL wants to default to the first platform specified in
2523 # ./configure.  parse that here.
2524 if test "x$platforms" != "x"; then
2525     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2526     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2527 else
2528     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2529 fi
2530
2531 AC_SUBST([EGL_NATIVE_PLATFORM])
2532 AC_SUBST([EGL_CFLAGS])
2533
2534 # If we don't have the X11 platform, set this define so we don't try to include
2535 # the X11 headers.
2536 if ! echo "$platforms" | grep -q 'x11'; then
2537     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2538     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2539 fi
2540
2541 dnl Directory for XVMC libs
2542 AC_ARG_WITH([xvmc-libdir],
2543     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2544         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2545     [XVMC_LIB_INSTALL_DIR="$withval"],
2546     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2547 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2548
2549 dnl
2550 dnl Gallium Tests
2551 dnl
2552 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2553
2554 dnl Directory for VDPAU libs
2555 AC_ARG_WITH([vdpau-libdir],
2556     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2557         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2558     [VDPAU_LIB_INSTALL_DIR="$withval"],
2559     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2560 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2561
2562 dnl Directory for OMX_BELLAGIO libs
2563
2564 AC_ARG_WITH([omx-bellagio-libdir],
2565     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2566         [directory for the OMX_BELLAGIO libraries])],
2567     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2568     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2569                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2570 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2571
2572 dnl Directory for OMX_TIZONIA libs
2573
2574 AC_ARG_WITH([omx-tizonia-libdir],
2575     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2576         [directory for the OMX_TIZONIA libraries])],
2577     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2578     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2579 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2580
2581 dnl Directory for VA libs
2582
2583 AC_ARG_WITH([va-libdir],
2584     [AS_HELP_STRING([--with-va-libdir=DIR],
2585         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2586     [VA_LIB_INSTALL_DIR="$withval"],
2587     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2588 AC_SUBST([VA_LIB_INSTALL_DIR])
2589
2590 AC_ARG_WITH([d3d-libdir],
2591     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2592         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2593     [D3D_DRIVER_INSTALL_DIR="$withval"],
2594     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2595 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2596
2597 dnl Architectures to build SWR library for
2598
2599 AC_ARG_WITH([swr-archs],
2600     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2601         [comma delimited swr architectures list, e.g.
2602         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2603     [with_swr_archs="$withval"],
2604     [with_swr_archs="avx,avx2"])
2605
2606 dnl
2607 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2608 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2609 dnl architectures.
2610 dnl
2611 r300_require_llvm() {
2612     case "$host" in *gnux32) return;; esac
2613     case "$host_cpu" in
2614     i*86|x86_64|amd64) require_llvm $1
2615         ;;
2616     esac
2617 }
2618
2619 dnl
2620 dnl DRM is needed by X, Wayland, and offscreen rendering.
2621 dnl Surfaceless is an alternative for the last one.
2622 dnl
2623 require_basic_egl() {
2624     case "$with_platforms" in
2625         *drm*|*surfaceless*|*android*)
2626             ;;
2627         *)
2628             AC_MSG_ERROR([$1 requires one of these:
2629                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2630                   2) --with-platforms=surfaceless (offscreen only)
2631                   3) --with-platforms=android (Android only)
2632                   Recommended options: drm,x11])
2633             ;;
2634     esac
2635 }
2636
2637 swr_require_cxx_feature_flags() {
2638     feature_name="$1"
2639     preprocessor_test="$2"
2640     option_list="$3"
2641     output_var="$4"
2642
2643     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2644     AC_LANG_PUSH([C++])
2645     save_CXXFLAGS="$CXXFLAGS"
2646     save_IFS="$IFS"
2647     IFS=","
2648     found=0
2649     for opts in $option_list
2650     do
2651         unset IFS
2652         CXXFLAGS="$opts $save_CXXFLAGS"
2653         AC_COMPILE_IFELSE(
2654             [AC_LANG_PROGRAM(
2655                 [   #if !($preprocessor_test)
2656                     #error
2657                     #endif
2658                 ])],
2659             [found=1; break],
2660             [])
2661         IFS=","
2662     done
2663     IFS="$save_IFS"
2664     CXXFLAGS="$save_CXXFLAGS"
2665     AC_LANG_POP([C++])
2666     if test $found -eq 1; then
2667         AC_MSG_RESULT([$opts])
2668         eval "$output_var=\$opts"
2669         return 0
2670     fi
2671     AC_MSG_RESULT([no])
2672     AC_MSG_ERROR([swr requires $feature_name support])
2673     return 1
2674 }
2675
2676 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2677 if test -n "$with_gallium_drivers"; then
2678     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2679     for driver in $gallium_drivers; do
2680         case "x$driver" in
2681         xsvga)
2682             HAVE_GALLIUM_SVGA=yes
2683             require_libdrm "svga"
2684             ;;
2685         xi915)
2686             HAVE_GALLIUM_I915=yes
2687             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2688             require_libdrm "Gallium i915"
2689             ;;
2690         xr300)
2691             HAVE_GALLIUM_R300=yes
2692             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2693             require_libdrm "r300"
2694             r300_require_llvm "r300"
2695             ;;
2696         xr600)
2697             HAVE_GALLIUM_R600=yes
2698             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2699             require_libdrm "r600"
2700             if test "x$enable_llvm" = xyes; then
2701                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2702
2703                 llvm_add_component "asmparser" "r600"
2704                 llvm_add_component "bitreader" "r600"
2705             fi
2706             ;;
2707         xradeonsi)
2708             HAVE_GALLIUM_RADEONSI=yes
2709             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2710             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2711             require_libdrm "radeonsi"
2712             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2713             if test "x$enable_egl" = xyes; then
2714                 require_basic_egl "radeonsi"
2715             fi
2716             ;;
2717         xnouveau)
2718             HAVE_GALLIUM_NOUVEAU=yes
2719             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2720             require_libdrm "nouveau"
2721             ;;
2722         xfreedreno)
2723             HAVE_GALLIUM_FREEDRENO=yes
2724             require_libdrm "freedreno"
2725             ;;
2726         xetnaviv)
2727             HAVE_GALLIUM_ETNAVIV=yes
2728             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2729             require_libdrm "etnaviv"
2730             ;;
2731        ximx)
2732             HAVE_GALLIUM_IMX=yes
2733             ;;
2734         xtegra)
2735             HAVE_GALLIUM_TEGRA=yes
2736             require_libdrm "tegra"
2737             ;;
2738         xswrast)
2739             HAVE_GALLIUM_SOFTPIPE=yes
2740             if test "x$enable_llvm" = xyes; then
2741                 HAVE_GALLIUM_LLVMPIPE=yes
2742             fi
2743             ;;
2744         xswr)
2745             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2746
2747             if test "x$HAVE_CXX11" != "xyes"; then
2748                 AC_MSG_ERROR([swr requires c++11 support])
2749             fi
2750
2751             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2752                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2753                 SWR_AVX_CXXFLAGS
2754             AC_SUBST([SWR_AVX_CXXFLAGS])
2755
2756             swr_archs=`IFS=', '; echo $with_swr_archs`
2757             for arch in $swr_archs; do
2758                 case "x$arch" in
2759                 xavx)
2760                     HAVE_SWR_AVX=yes
2761                     ;;
2762                 xavx2)
2763                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2764                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2765                         SWR_AVX2_CXXFLAGS
2766                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2767                     HAVE_SWR_AVX2=yes
2768                     ;;
2769                 xknl)
2770                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2771                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2772                         SWR_KNL_CXXFLAGS
2773                     AC_SUBST([SWR_KNL_CXXFLAGS])
2774                     HAVE_SWR_KNL=yes
2775                     ;;
2776                 xskx)
2777                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2778                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2779                         SWR_SKX_CXXFLAGS
2780                     AC_SUBST([SWR_SKX_CXXFLAGS])
2781                     HAVE_SWR_SKX=yes
2782                     ;;
2783                 *)
2784                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2785                     ;;
2786                 esac
2787             done
2788
2789             if test "x$HAVE_SWR_AVX" != xyes -a \
2790                     "x$HAVE_SWR_AVX2" != xyes -a \
2791                     "x$HAVE_SWR_KNL" != xyes -a \
2792                     "x$HAVE_SWR_SKX" != xyes; then
2793                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2794             fi
2795
2796             # test if more than one swr arch configured
2797             if test `echo $swr_archs | wc -w` -eq 1; then
2798                 HAVE_SWR_BUILTIN=yes
2799             fi
2800
2801             HAVE_GALLIUM_SWR=yes
2802             ;;
2803         xvc4)
2804             HAVE_GALLIUM_VC4=yes
2805             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2806
2807             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2808                               [USE_VC4_SIMULATOR=yes;
2809                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2810                               [USE_VC4_SIMULATOR=no])
2811             ;;
2812         xv3d)
2813             HAVE_GALLIUM_V3D=yes
2814
2815             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2816                               [USE_V3D_SIMULATOR=yes;
2817                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2818                               [USE_V3D_SIMULATOR=no])
2819             ;;
2820         xpl111)
2821             HAVE_GALLIUM_PL111=yes
2822             ;;
2823         xvirgl)
2824             HAVE_GALLIUM_VIRGL=yes
2825             require_libdrm "virgl"
2826             if test "x$enable_egl" = xyes; then
2827                 require_basic_egl "virgl"
2828             fi
2829             ;;
2830         *)
2831             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2832             ;;
2833         esac
2834     done
2835 fi
2836
2837 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2838 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x6.0.0 -a \
2839                                               "x$LLVM_VERSION" != x6.0.1)
2840
2841 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2842     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2843     llvm_add_default_components "gallium"
2844 fi
2845
2846 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2847 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2848 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2849 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2850 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2851
2852 dnl We need to validate some needed dependencies for renderonly drivers.
2853
2854 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2855     AC_MSG_ERROR([Building with imx requires etnaviv])
2856 fi
2857
2858 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2859     AC_MSG_ERROR([Building with pl111 requires vc4])
2860 fi
2861
2862 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2863     AC_MSG_ERROR([Building with tegra requires nouveau])
2864 fi
2865
2866 detect_old_buggy_llvm() {
2867     dnl llvm-config may not give the right answer when llvm is a built as a
2868     dnl single shared library, so we must work the library name out for
2869     dnl ourselves.
2870     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2871     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2872     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2873     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2874
2875     if test "x$llvm_have_one_so" = xyes; then
2876         dnl LLVM was built using auto*, so there is only one shared object.
2877         LLVM_LIBS="-l$LLVM_SO_NAME"
2878     else
2879         dnl If LLVM was built with CMake, there will be one shared object per
2880         dnl component.
2881         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2882                [AC_MSG_ERROR([Could not find llvm shared libraries:
2883                 Please make sure you have built llvm with the --enable-shared option
2884                 and that your llvm libraries are installed in $LLVM_LIBDIR
2885                 If you have installed your llvm libraries to a different directory you
2886                 can use the --with-llvm-prefix= configure flag to specify this directory.
2887                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2888                 If you do not want to build with llvm shared libraries and instead want to
2889                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2890                 invocation and rebuild.])])
2891
2892         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2893         dnl install uses a shared object for each component and we have
2894         dnl already added all of these objects to LLVM_LIBS.
2895     fi
2896 }
2897
2898 dnl
2899 dnl Set defines and buildtime variables only when using LLVM.
2900 dnl
2901 if test "x$enable_llvm" = xyes; then
2902     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2903
2904     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2905     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2906     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2907
2908     dnl Set LLVM_LIBS - This is done after the driver configuration so
2909     dnl that drivers can add additional components to LLVM_COMPONENTS.
2910     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2911     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2912     dnl this was causing the same libraries to be appear multiple times
2913     dnl in LLVM_LIBS.
2914
2915     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2916         if test "x$enable_llvm_shared_libs" = xyes; then
2917             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2918         else
2919             dnl Invoking llvm-config with both -libs and --system-libs produces the
2920             dnl two separate lines - each for the set of libraries.
2921                 dnl Call the program twice, effectively folding them into a single line.
2922             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2923             dnl We need to link to llvm system libs when using static libs
2924             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2925         fi
2926     else
2927         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2928         if test "x$enable_llvm_shared_libs" = xyes; then
2929             detect_old_buggy_llvm
2930         else
2931             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2932             dnl We need to link to llvm system libs when using static libs
2933             dnl However, only llvm 3.5+ provides --system-libs
2934             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2935                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2936             fi
2937         fi
2938     fi
2939
2940     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2941     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2942     dnl the LLVM library propagated in the Libs.private of the respective .pc
2943     dnl file which ensures complete dependency information when statically
2944     dnl linking.
2945     if test "x$enable_glx" == xgallium-xlib; then
2946         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2947     fi
2948     if test "x$enable_gallium_osmesa" = xyes; then
2949         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2950     fi
2951 fi
2952
2953 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2954 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2955 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2956 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2957 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2958 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2959 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2960 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2961 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2962 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2963 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2964 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2965 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2966 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2967 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2968                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2969                                          "x$HAVE_GALLIUM_SWR" = xyes)
2970 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2971 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2972 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2973
2974 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2975
2976 if test "x$enable_dri" = xyes; then
2977     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2978 fi
2979
2980 if test "x$have_drisw_kms" = xyes; then
2981     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2982 fi
2983 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2984
2985 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2986 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2987 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2988 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2989 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2990 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2991
2992 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2993 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2994
2995 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2996                                       "x$HAVE_RADEON_VULKAN" = xyes)
2997
2998 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2999                                       "x$HAVE_GALLIUM_V3D" = xyes)
3000
3001 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
3002                                         "x$HAVE_I965_DRI" = xyes)
3003
3004 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
3005                                             "x$HAVE_GALLIUM_R600" = xyes -o \
3006                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
3007 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
3008 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
3009 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
3010 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
3011 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
3012
3013 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
3014 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
3015 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
3016 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
3017                                         "x$enable_gallium_osmesa" = xyes)
3018
3019 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
3020 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
3021 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
3022 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
3023 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
3024 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
3025
3026 AC_SUBST([NINE_MAJOR], 1)
3027 AC_SUBST([NINE_MINOR], 0)
3028 AC_SUBST([NINE_PATCH], 0)
3029 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
3030
3031 AC_SUBST([VDPAU_MAJOR], 1)
3032 AC_SUBST([VDPAU_MINOR], 0)
3033
3034 if test "x$enable_va" = xyes; then
3035     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
3036     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
3037 fi
3038 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3039 AC_SUBST([VA_MINOR], $VA_MINOR)
3040
3041 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3042
3043 AC_SUBST([XVMC_MAJOR], 1)
3044 AC_SUBST([XVMC_MINOR], 0)
3045
3046 AC_SUBST([XA_MAJOR], 2)
3047 AC_SUBST([XA_MINOR], 4)
3048 AC_SUBST([XA_PATCH], 0)
3049 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3050
3051 AC_ARG_ENABLE(valgrind,
3052               [AS_HELP_STRING([--enable-valgrind],
3053                              [Build mesa with valgrind support (default: auto)])],
3054                              [VALGRIND=$enableval], [VALGRIND=auto])
3055 if test "x$VALGRIND" != xno; then
3056     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3057 fi
3058 AC_MSG_CHECKING([whether to enable Valgrind support])
3059 if test "x$VALGRIND" = xauto; then
3060     VALGRIND="$have_valgrind"
3061 fi
3062
3063 if test "x$VALGRIND" = "xyes"; then
3064     if ! test "x$have_valgrind" = xyes; then
3065         AC_MSG_ERROR([Valgrind support required but not present])
3066     fi
3067     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3068 fi
3069
3070 AC_MSG_RESULT([$VALGRIND])
3071
3072 dnl Restore LDFLAGS and CPPFLAGS
3073 LDFLAGS="$_SAVE_LDFLAGS"
3074 CPPFLAGS="$_SAVE_CPPFLAGS"
3075
3076 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3077 if test "x$acv_mesa_CLANG" = xyes; then
3078     CFLAGS="$CFLAGS -Qunused-arguments"
3079     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3080 fi
3081
3082 dnl Add user CFLAGS and CXXFLAGS
3083 CFLAGS="$CFLAGS $USER_CFLAGS"
3084 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3085
3086 dnl Substitute the config
3087 AC_CONFIG_FILES([Makefile
3088                  src/Makefile
3089                  src/amd/Makefile
3090                  src/amd/vulkan/Makefile
3091                  src/broadcom/Makefile
3092                  src/compiler/Makefile
3093                  src/egl/Makefile
3094                  src/egl/main/egl.pc
3095                  src/egl/wayland/wayland-drm/Makefile
3096                  src/gallium/Makefile
3097                  src/gallium/auxiliary/Makefile
3098                  src/gallium/auxiliary/pipe-loader/Makefile
3099                  src/gallium/drivers/freedreno/Makefile
3100                  src/gallium/drivers/i915/Makefile
3101                  src/gallium/drivers/llvmpipe/Makefile
3102                  src/gallium/drivers/nouveau/Makefile
3103                  src/gallium/drivers/pl111/Makefile
3104                  src/gallium/drivers/r300/Makefile
3105                  src/gallium/drivers/r600/Makefile
3106                  src/gallium/drivers/radeonsi/Makefile
3107                  src/gallium/drivers/softpipe/Makefile
3108                  src/gallium/drivers/svga/Makefile
3109                  src/gallium/drivers/swr/Makefile
3110                  src/gallium/drivers/tegra/Makefile
3111                  src/gallium/drivers/etnaviv/Makefile
3112                  src/gallium/drivers/imx/Makefile
3113                  src/gallium/drivers/v3d/Makefile
3114                  src/gallium/drivers/vc4/Makefile
3115                  src/gallium/drivers/virgl/Makefile
3116                  src/gallium/state_trackers/clover/Makefile
3117                  src/gallium/state_trackers/dri/Makefile
3118                  src/gallium/state_trackers/glx/xlib/Makefile
3119                  src/gallium/state_trackers/nine/Makefile
3120                  src/gallium/state_trackers/omx/Makefile
3121                  src/gallium/state_trackers/omx/bellagio/Makefile
3122                  src/gallium/state_trackers/omx/tizonia/Makefile
3123                  src/gallium/state_trackers/osmesa/Makefile
3124                  src/gallium/state_trackers/va/Makefile
3125                  src/gallium/state_trackers/vdpau/Makefile
3126                  src/gallium/state_trackers/xa/Makefile
3127                  src/gallium/state_trackers/xa/xa_tracker.h
3128                  src/gallium/state_trackers/xvmc/Makefile
3129                  src/gallium/targets/d3dadapter9/Makefile
3130                  src/gallium/targets/d3dadapter9/d3d.pc
3131                  src/gallium/targets/dri/Makefile
3132                  src/gallium/targets/libgl-xlib/Makefile
3133                  src/gallium/targets/omx/Makefile
3134                  src/gallium/targets/opencl/Makefile
3135                  src/gallium/targets/opencl/mesa.icd
3136                  src/gallium/targets/osmesa/Makefile
3137                  src/gallium/targets/osmesa/osmesa.pc
3138                  src/gallium/targets/pipe-loader/Makefile
3139                  src/gallium/targets/va/Makefile
3140                  src/gallium/targets/vdpau/Makefile
3141                  src/gallium/targets/xa/Makefile
3142                  src/gallium/targets/xa/xatracker.pc
3143                  src/gallium/targets/xvmc/Makefile
3144                  src/gallium/tests/trivial/Makefile
3145                  src/gallium/tests/unit/Makefile
3146                  src/gallium/winsys/etnaviv/drm/Makefile
3147                  src/gallium/winsys/imx/drm/Makefile
3148                  src/gallium/winsys/freedreno/drm/Makefile
3149                  src/gallium/winsys/i915/drm/Makefile
3150                  src/gallium/winsys/nouveau/drm/Makefile
3151                  src/gallium/winsys/pl111/drm/Makefile
3152                  src/gallium/winsys/radeon/drm/Makefile
3153                  src/gallium/winsys/amdgpu/drm/Makefile
3154                  src/gallium/winsys/svga/drm/Makefile
3155                  src/gallium/winsys/sw/dri/Makefile
3156                  src/gallium/winsys/sw/kms-dri/Makefile
3157                  src/gallium/winsys/sw/null/Makefile
3158                  src/gallium/winsys/sw/wrapper/Makefile
3159                  src/gallium/winsys/sw/xlib/Makefile
3160                  src/gallium/winsys/tegra/drm/Makefile
3161                  src/gallium/winsys/v3d/drm/Makefile
3162                  src/gallium/winsys/vc4/drm/Makefile
3163                  src/gallium/winsys/virgl/drm/Makefile
3164                  src/gallium/winsys/virgl/vtest/Makefile
3165                  src/gbm/Makefile
3166                  src/gbm/main/gbm.pc
3167                  src/glx/Makefile
3168                  src/glx/apple/Makefile
3169                  src/glx/tests/Makefile
3170                  src/glx/windows/Makefile
3171                  src/glx/windows/windowsdriproto.pc
3172                  src/gtest/Makefile
3173                  src/intel/Makefile
3174                  src/loader/Makefile
3175                  src/mapi/Makefile
3176                  src/mapi/es1api/glesv1_cm.pc
3177                  src/mapi/es2api/glesv2.pc
3178                  src/mapi/glapi/gen/Makefile
3179                  src/mesa/Makefile
3180                  src/mesa/gl.pc
3181                  src/mesa/drivers/dri/dri.pc
3182                  src/mesa/drivers/dri/common/Makefile
3183                  src/mesa/drivers/dri/i915/Makefile
3184                  src/mesa/drivers/dri/i965/Makefile
3185                  src/mesa/drivers/dri/Makefile
3186                  src/mesa/drivers/dri/nouveau/Makefile
3187                  src/mesa/drivers/dri/r200/Makefile
3188                  src/mesa/drivers/dri/radeon/Makefile
3189                  src/mesa/drivers/dri/swrast/Makefile
3190                  src/mesa/drivers/osmesa/Makefile
3191                  src/mesa/drivers/osmesa/osmesa.pc
3192                  src/mesa/drivers/x11/Makefile
3193                  src/mesa/main/tests/Makefile
3194                  src/mesa/state_tracker/tests/Makefile
3195                  src/util/Makefile
3196                  src/util/tests/fast_idiv_by_const/Makefile
3197                  src/util/tests/hash_table/Makefile
3198                  src/util/tests/set/Makefile
3199                  src/util/tests/string_buffer/Makefile
3200                  src/util/tests/vma/Makefile
3201                  src/util/xmlpool/Makefile
3202                  src/vulkan/Makefile])
3203
3204 AC_OUTPUT
3205
3206 # Fix up dependencies in *.Plo files, where we changed the extension of a
3207 # source file
3208 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3209
3210 rm -f src/compiler/spirv/spirv_info.lo
3211 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3212
3213 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3214 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3215
3216 dnl
3217 dnl Output some configuration info for the user
3218 dnl
3219 echo ""
3220 echo "        prefix:          $prefix"
3221 echo "        exec_prefix:     $exec_prefix"
3222 echo "        libdir:          $libdir"
3223 echo "        includedir:      $includedir"
3224
3225 dnl API info
3226 echo ""
3227 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3228
3229 dnl Driver info
3230 echo ""
3231 case "x$enable_osmesa$enable_gallium_osmesa" in
3232 xnoyes)
3233         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3234         ;;
3235 xyesno)
3236         echo "        OSMesa:          lib$OSMESA_LIB"
3237         ;;
3238 xnono)
3239         echo "        OSMesa:          no"
3240         ;;
3241 esac
3242
3243 echo ""
3244 if test "x$enable_dri" != xno; then
3245         echo "        DRI platform:    $dri_platform"
3246         if test -z "$DRI_DIRS"; then
3247             echo "        DRI drivers:     no"
3248         else
3249             echo "        DRI drivers:     $DRI_DIRS"
3250         fi
3251         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3252 fi
3253
3254 case "x$enable_glx" in
3255 xdri)
3256     echo "        GLX:             DRI-based"
3257     ;;
3258 xxlib)
3259     echo "        GLX:             Xlib-based"
3260     ;;
3261 xgallium-xlib)
3262     echo "        GLX:             Xlib-based (Gallium)"
3263     ;;
3264 *)
3265     echo "        GLX:             $enable_glx"
3266     ;;
3267 esac
3268
3269 dnl EGL
3270 echo ""
3271 echo "        EGL:             $enable_egl"
3272 if test "$enable_egl" = yes; then
3273
3274     egl_drivers=""
3275     if test "x$enable_dri" != "xno"; then
3276         egl_drivers="$egl_drivers builtin:egl_dri2"
3277     fi
3278     if test "x$enable_dri3" != "xno"; then
3279         egl_drivers="$egl_drivers builtin:egl_dri3"
3280     fi
3281
3282     echo "        EGL drivers:    $egl_drivers"
3283 fi
3284 if test "x$enable_gbm" = xyes; then
3285     echo "        GBM:             yes"
3286 else
3287     echo "        GBM:             no"
3288 fi
3289
3290     echo "        EGL/Vulkan/VL platforms:   $platforms"
3291
3292 # Vulkan
3293 echo ""
3294 if test "x$VULKAN_DRIVERS" != x; then
3295     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3296     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3297 else
3298     echo "        Vulkan drivers:  no"
3299 fi
3300
3301 echo ""
3302 if test "x$enable_llvm" = xyes; then
3303     echo "        llvm:            yes"
3304     echo "        llvm-config:     $LLVM_CONFIG"
3305     echo "        llvm-version:    $LLVM_VERSION"
3306 else
3307     echo "        llvm:            no"
3308 fi
3309
3310 echo ""
3311 if test -n "$with_gallium_drivers"; then
3312     echo "        Gallium drivers: $gallium_drivers"
3313     echo "        Gallium st:      $gallium_st"
3314 else
3315     echo "        Gallium:         no"
3316 fi
3317
3318 echo ""
3319 if test "x$enable_gallium_extra_hud" != xyes; then
3320     echo "        HUD extra stats: no"
3321 else
3322     echo "        HUD extra stats: yes"
3323 fi
3324
3325 if test "x$enable_lmsensors" != xyes; then
3326     echo "        HUD lmsensors:   no"
3327 else
3328     echo "        HUD lmsensors:   yes"
3329 fi
3330
3331 echo ""
3332 if test "x$HAVE_GALLIUM_SWR" != x; then
3333     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3334         echo "        SWR archs:       $swr_archs (builtin)"
3335     else
3336         echo "        SWR archs:       $swr_archs"
3337     fi
3338 fi
3339
3340 dnl Libraries
3341 echo ""
3342 echo "        Shared libs:     $enable_shared"
3343 echo "        Static libs:     $enable_static"
3344 echo "        Shared-glapi:    $enable_shared_glapi"
3345
3346 dnl Compiler options
3347 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3348 cflags=`echo $CFLAGS | \
3349     $SED 's/^ *//;s/  */ /;s/ *$//'`
3350 cxxflags=`echo $CXXFLAGS | \
3351     $SED 's/^ *//;s/  */ /;s/ *$//'`
3352 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3353 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3354 echo ""
3355 echo "        CFLAGS:          $cflags"
3356 echo "        CXXFLAGS:        $cxxflags"
3357 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3358 echo "        LDFLAGS:         $ldflags"
3359 echo "        Macros:          $defines"
3360 echo ""
3361 if test "x$enable_llvm" = xyes; then
3362     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3363     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3364     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3365     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3366     echo ""
3367 fi
3368 echo "        PYTHON2:         $PYTHON2"
3369
3370 echo ""
3371 echo "        Run '${MAKE-make}' to build Mesa"
3372 echo ""