33f1c42c8bed48c7d86672fd87b9e1c037b9968b
[mesa.git] / configure.ac
1 dnl Copyright © 2011-2014 Intel Corporation
2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
3 dnl Copyright © 2007-2010 Dan Nicholson
4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
5 dnl Copyright © 2010-2014 Christian König
6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
7 dnl Copyright © 2009-2012 Jakob Bornecrantz
8 dnl Copyright © 2009-2014 Jon TURNEY
9 dnl Copyright © 2011-2012 Benjamin Franzke
10 dnl Copyright © 2008-2014 David Airlie
11 dnl Copyright © 2009-2013 Brian Paul
12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
13 dnl
14 dnl Permission is hereby granted, free of charge, to any person obtaining a
15 dnl copy of this software and associated documentation files (the "Software"),
16 dnl to deal in the Software without restriction, including without limitation
17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
18 dnl and/or sell copies of the Software, and to permit persons to whom the
19 dnl Software is furnished to do so, subject to the following conditions:
20 dnl
21 dnl The above copyright notice and this permission notice (including the next
22 dnl paragraph) shall be included in all copies or substantial portions of the
23 dnl Software.
24 dnl
25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
31 dnl DEALINGS IN THE SOFTWARE.
32 dnl
33 dnl Process this file with autoconf to create configure.
34
35 AC_PREREQ([2.60])
36
37 dnl Tell the user about autoconf.html in the --help output
38 m4_divert_once([HELP_END], [
39 See docs/autoconf.html for more details on the options for Mesa.])
40
41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
42 AC_INIT([Mesa], [MESA_VERSION],
43 [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
44 AC_CONFIG_AUX_DIR([bin])
45 AC_CONFIG_MACRO_DIR([m4])
46 AC_CANONICAL_SYSTEM
47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
48
49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
50 case "$host_os" in
51 mingw*)
52 AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
53 ;;
54 esac
55
56 # Support silent build rules, requires at least automake-1.11. Disable
57 # by either passing --disable-silent-rules to configure or passing V=1
58 # to make
59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
60 [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
61
62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
63
64 dnl Set internal versions
65 OSMESA_VERSION=8
66 AC_SUBST([OSMESA_VERSION])
67 OPENCL_VERSION=1
68 AC_SUBST([OPENCL_VERSION])
69
70 dnl Versions for external dependencies
71 LIBDRM_REQUIRED=2.4.66
72 LIBDRM_RADEON_REQUIRED=2.4.56
73 LIBDRM_AMDGPU_REQUIRED=2.4.63
74 LIBDRM_INTEL_REQUIRED=2.4.61
75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
78 LIBDRM_VC4_REQUIRED=2.4.69
79 LIBDRM_ETNAVIV_REQUIRED=2.4.74
80 DRI2PROTO_REQUIRED=2.6
81 DRI3PROTO_REQUIRED=1.0
82 PRESENTPROTO_REQUIRED=1.0
83 GLPROTO_REQUIRED=1.4.14
84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
85 LIBVA_REQUIRED=0.38.0
86 VDPAU_REQUIRED=1.1
87 WAYLAND_REQUIRED=1.11
88 XCB_REQUIRED=1.9.3
89 XCBDRI2_REQUIRED=1.8
90 XCBGLX_REQUIRED=1.8.1
91 XSHMFENCE_REQUIRED=1.1
92 XVMC_REQUIRED=1.0.6
93 PYTHON_MAKO_REQUIRED=0.8.0
94 LIBSENSORS_REQUIRED=4.0.0
95
96 dnl LLVM versions
97 LLVM_REQUIRED_GALLIUM=3.3.0
98 LLVM_REQUIRED_OPENCL=3.6.0
99 LLVM_REQUIRED_R600=3.6.0
100 LLVM_REQUIRED_RADEONSI=3.6.0
101 LLVM_REQUIRED_RADV=3.9.0
102 LLVM_REQUIRED_SWR=3.6.0
103
104 dnl Check for progs
105 AC_PROG_CPP
106 AC_PROG_CC
107 AC_PROG_CXX
108 AM_PROG_CC_C_O
109 AM_PROG_AS
110 AX_CHECK_GNU_MAKE
111 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
112 AC_PROG_SED
113 AC_PROG_MKDIR_P
114
115 AC_SYS_LARGEFILE
116
117 LT_PREREQ([2.2])
118 LT_INIT([disable-static])
119
120 AC_CHECK_PROG(RM, rm, [rm -f])
121 AC_CHECK_PROG(XXD, xxd, [xxd])
122
123 AX_PROG_BISON([],
124 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
125 [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
126 AX_PROG_FLEX([],
127 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
128 [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
129
130 AC_CHECK_PROG(INDENT, indent, indent, cat)
131 if test "x$INDENT" != "xcat"; then
132 # Only GNU indent is supported
133 INDENT_VERSION=`indent --version | grep GNU`
134 if test $? -eq 0; then
135 AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
136 else
137 INDENT="cat"
138 fi
139 fi
140
141 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
142
143 if test -z "$PYTHON2"; then
144 if test ! -f "$srcdir/src/util/format_srgb.c"; then
145 AC_MSG_ERROR([Python not found - unable to generate sources])
146 fi
147 else
148 if test "x$acv_mako_found" = xno; then
149 if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
150 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
151 fi
152 fi
153 fi
154
155 AC_PROG_INSTALL
156
157 dnl We need a POSIX shell for parts of the build. Assume we have one
158 dnl in most cases.
159 case "$host_os" in
160 solaris*)
161 # Solaris /bin/sh is too old/non-POSIX compliant
162 AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
163 SHELL="$POSIX_SHELL"
164 ;;
165 esac
166
167 dnl clang is mostly GCC-compatible, but its version is much lower,
168 dnl so we have to check for it.
169 AC_MSG_CHECKING([if compiling with clang])
170
171 AC_COMPILE_IFELSE(
172 [AC_LANG_PROGRAM([], [[
173 #ifndef __clang__
174 not clang
175 #endif
176 ]])],
177 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
178
179 AC_MSG_RESULT([$acv_mesa_CLANG])
180
181 dnl If we're using GCC, make sure that it is at least version 4.2.0. Older
182 dnl versions are explictly not supported.
183 GEN_ASM_OFFSETS=no
184 USE_GNU99=no
185 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
186 AC_MSG_CHECKING([whether gcc version is sufficient])
187 major=0
188 minor=0
189
190 GCC_VERSION=`$CC -dumpversion`
191 if test $? -eq 0; then
192 GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
193 GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
194 fi
195
196 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
197 AC_MSG_RESULT([no])
198 AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
199 else
200 AC_MSG_RESULT([yes])
201 fi
202
203 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
204 USE_GNU99=yes
205 fi
206 if test "x$cross_compiling" = xyes; then
207 GEN_ASM_OFFSETS=yes
208 fi
209 fi
210
211 dnl We don't support building Mesa with Sun C compiler
212 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
213 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
214 if test "x$SUNCC" = xyes; then
215 AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
216 fi
217
218 dnl Check for compiler builtins
219 AX_GCC_BUILTIN([__builtin_bswap32])
220 AX_GCC_BUILTIN([__builtin_bswap64])
221 AX_GCC_BUILTIN([__builtin_clz])
222 AX_GCC_BUILTIN([__builtin_clzll])
223 AX_GCC_BUILTIN([__builtin_ctz])
224 AX_GCC_BUILTIN([__builtin_expect])
225 AX_GCC_BUILTIN([__builtin_ffs])
226 AX_GCC_BUILTIN([__builtin_ffsll])
227 AX_GCC_BUILTIN([__builtin_popcount])
228 AX_GCC_BUILTIN([__builtin_popcountll])
229 AX_GCC_BUILTIN([__builtin_unreachable])
230
231 AX_GCC_FUNC_ATTRIBUTE([const])
232 AX_GCC_FUNC_ATTRIBUTE([flatten])
233 AX_GCC_FUNC_ATTRIBUTE([format])
234 AX_GCC_FUNC_ATTRIBUTE([malloc])
235 AX_GCC_FUNC_ATTRIBUTE([packed])
236 AX_GCC_FUNC_ATTRIBUTE([pure])
237 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
238 AX_GCC_FUNC_ATTRIBUTE([unused])
239 AX_GCC_FUNC_ATTRIBUTE([visibility])
240 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
241 AX_GCC_FUNC_ATTRIBUTE([weak])
242 AX_GCC_FUNC_ATTRIBUTE([alias])
243
244 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
245
246 dnl Make sure the pkg-config macros are defined
247 m4_ifndef([PKG_PROG_PKG_CONFIG],
248 [m4_fatal([Could not locate the pkg-config autoconf macros.
249 These are usually located in /usr/share/aclocal/pkg.m4. If your macros
250 are in a different location, try setting the environment variable
251 ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
252 PKG_PROG_PKG_CONFIG()
253
254 dnl LIB_DIR - library basename
255 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
256 AC_SUBST([LIB_DIR])
257
258 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
259 _SAVE_LDFLAGS="$LDFLAGS"
260 _SAVE_CPPFLAGS="$CPPFLAGS"
261
262 dnl Compiler macros
263 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
264 AC_SUBST([DEFINES])
265 android=no
266 case "$host_os" in
267 *-android)
268 android=yes
269 ;;
270 linux*|*-gnu*|gnu*|cygwin*)
271 DEFINES="$DEFINES -D_GNU_SOURCE"
272 ;;
273 solaris*)
274 DEFINES="$DEFINES -DSVR4"
275 ;;
276 esac
277
278 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
279
280 dnl Add flags for gcc and g++
281 if test "x$GCC" = xyes; then
282 CFLAGS="$CFLAGS -Wall"
283
284 if test "x$USE_GNU99" = xyes; then
285 CFLAGS="$CFLAGS -std=gnu99"
286 else
287 CFLAGS="$CFLAGS -std=c99"
288 fi
289
290 # Enable -Werror=implicit-function-declaration and
291 # -Werror=missing-prototypes, if available, or otherwise, just
292 # -Wmissing-prototypes. This is particularly useful to avoid
293 # generating a loadable driver module that has undefined symbols.
294 save_CFLAGS="$CFLAGS"
295 AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
296 CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
297 CFLAGS="$CFLAGS -Werror=missing-prototypes"
298 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
299 AC_MSG_RESULT([yes]),
300 [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
301 AC_MSG_RESULT([no])]);
302
303 # Enable -fvisibility=hidden if using a gcc that supports it
304 save_CFLAGS="$CFLAGS"
305 AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
306 VISIBILITY_CFLAGS="-fvisibility=hidden"
307 CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
308 AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
309 [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
310
311 # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
312 CFLAGS=$save_CFLAGS
313
314 # We don't want floating-point math functions to set errno or trap
315 CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
316
317 # Flags to help ensure that certain portions of the code -- and only those
318 # portions -- can be built with MSVC:
319 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
320 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
321 # supports most of C99)
322 # - the rest has no compiler compiler restrictions
323 MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
324 MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
325
326 # Enable -Werror=vla if compiler supports it
327 save_CFLAGS="$CFLAGS"
328 AC_MSG_CHECKING([whether $CC supports -Werror=vla])
329 CFLAGS="$CFLAGS -Werror=vla"
330 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
331 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
332 MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
333 AC_MSG_RESULT([yes])],
334 AC_MSG_RESULT([no]));
335 CFLAGS="$save_CFLAGS"
336 fi
337 if test "x$GXX" = xyes; then
338 CXXFLAGS="$CXXFLAGS -Wall"
339
340 # Enable -fvisibility=hidden if using a gcc that supports it
341 save_CXXFLAGS="$CXXFLAGS"
342 AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
343 VISIBILITY_CXXFLAGS="-fvisibility=hidden"
344 CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
345 AC_LANG_PUSH([C++])
346 AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
347 [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
348 AC_LANG_POP([C++])
349
350 # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
351 CXXFLAGS=$save_CXXFLAGS
352
353 # We don't want floating-point math functions to set errno or trap
354 CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
355 fi
356
357 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
358 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
359
360 dnl even if the compiler appears to support it, using visibility attributes isn't
361 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
362 case "$host_os" in
363 cygwin*)
364 VISIBILITY_CFLAGS=""
365 VISIBILITY_CXXFLAGS=""
366 ;;
367 esac
368
369 AC_SUBST([VISIBILITY_CFLAGS])
370 AC_SUBST([VISIBILITY_CXXFLAGS])
371
372 dnl
373 dnl Optional flags, check for compiler support
374 dnl
375 SSE41_CFLAGS="-msse4.1"
376 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
377 dnl stack, but on x86-32 such alignment is not guaranteed.
378 case "$target_cpu" in
379 i?86)
380 SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
381 ;;
382 esac
383 save_CFLAGS="$CFLAGS"
384 CFLAGS="$SSE41_CFLAGS $CFLAGS"
385 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
386 #include <smmintrin.h>
387 int param;
388 int main () {
389 __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
390 c = _mm_max_epu32(a, b);
391 return _mm_cvtsi128_si32(c);
392 }]])], SSE41_SUPPORTED=1)
393 CFLAGS="$save_CFLAGS"
394 if test "x$SSE41_SUPPORTED" = x1; then
395 DEFINES="$DEFINES -DUSE_SSE41"
396 fi
397 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
398 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
399
400 dnl Check for new-style atomic builtins
401 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
402 int main() {
403 int n;
404 return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
405 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
406 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
407 DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
408 fi
409 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
410
411 dnl Check for Endianness
412 AC_C_BIGENDIAN(
413 little_endian=no,
414 little_endian=yes,
415 little_endian=no,
416 little_endian=no
417 )
418
419 dnl Check for POWER8 Architecture
420 PWR8_CFLAGS="-mpower8-vector"
421 have_pwr8_intrinsics=no
422 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
423 save_CFLAGS=$CFLAGS
424 CFLAGS="$PWR8_CFLAGS $CFLAGS"
425 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
426 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
427 #error "Need GCC >= 4.8 for sane POWER8 support"
428 #endif
429 #include <altivec.h>
430 int main () {
431 vector unsigned char r;
432 vector unsigned int v = vec_splat_u32 (1);
433 r = __builtin_vec_vgbbd ((vector unsigned char) v);
434 return 0;
435 }]])], have_pwr8_intrinsics=yes)
436 CFLAGS=$save_CFLAGS
437
438 AC_ARG_ENABLE(pwr8,
439 [AC_HELP_STRING([--disable-pwr8-inst],
440 [disable POWER8-specific instructions])],
441 [enable_pwr8=$enableval], [enable_pwr8=auto])
442
443 if test "x$enable_pwr8" = xno ; then
444 have_pwr8_intrinsics=disabled
445 fi
446
447 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
448 DEFINES="$DEFINES -D_ARCH_PWR8"
449 CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
450 CFLAGS="$CFLAGS $PWR8_CFLAGS"
451 else
452 PWR8_CFLAGS=
453 fi
454
455 AC_MSG_RESULT($have_pwr8_intrinsics)
456 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
457 AC_MSG_ERROR([POWER8 compiler support not detected])
458 fi
459
460 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
461 AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
462 fi
463
464 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
465
466 dnl Can't have static and shared libraries, default to static if user
467 dnl explicitly requested. If both disabled, set to static since shared
468 dnl was explicitly requested.
469 case "x$enable_static$enable_shared" in
470 xyesyes)
471 AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
472 ;;
473 xnono)
474 AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
475 ;;
476 esac
477
478 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
479
480 dnl
481 dnl other compiler options
482 dnl
483 AC_ARG_ENABLE([debug],
484 [AS_HELP_STRING([--enable-debug],
485 [use debug compiler flags and macros @<:@default=disabled@:>@])],
486 [enable_debug="$enableval"],
487 [enable_debug=no]
488 )
489
490 AC_ARG_ENABLE([profile],
491 [AS_HELP_STRING([--enable-profile],
492 [enable profiling of code @<:@default=disabled@:>@])],
493 [enable_profile="$enableval"],
494 [enable_profile=no]
495 )
496
497 if test "x$enable_profile" = xyes; then
498 DEFINES="$DEFINES -DPROFILE"
499 if test "x$GCC" = xyes; then
500 CFLAGS="$CFLAGS -fno-omit-frame-pointer"
501 fi
502 if test "x$GXX" = xyes; then
503 CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
504 fi
505 fi
506
507 if test "x$enable_debug" = xyes; then
508 DEFINES="$DEFINES -DDEBUG"
509 if test "x$enable_profile" = xyes; then
510 AC_MSG_WARN([Debug and Profile are enabled at the same time])
511 fi
512 if test "x$GCC" = xyes; then
513 if ! echo "$CFLAGS" | grep -q -e '-g'; then
514 CFLAGS="$CFLAGS -g"
515 fi
516 if ! echo "$CFLAGS" | grep -q -e '-O'; then
517 CFLAGS="$CFLAGS -O0"
518 fi
519 fi
520 if test "x$GXX" = xyes; then
521 if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
522 CXXFLAGS="$CXXFLAGS -g"
523 fi
524 if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
525 CXXFLAGS="$CXXFLAGS -O0"
526 fi
527 fi
528 else
529 DEFINES="$DEFINES -DNDEBUG"
530 fi
531
532 DEFAULT_GL_LIB_NAME=GL
533
534 dnl
535 dnl Check if linker supports -Bsymbolic
536 dnl
537 save_LDFLAGS=$LDFLAGS
538 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
539 AC_MSG_CHECKING([if ld supports -Bsymbolic])
540 AC_LINK_IFELSE(
541 [AC_LANG_SOURCE([int main() { return 0;}])],
542 [AC_MSG_RESULT([yes])
543 BSYMBOLIC="-Wl,-Bsymbolic";],
544 [AC_MSG_RESULT([no])
545 BSYMBOLIC="";])
546 LDFLAGS=$save_LDFLAGS
547
548 AC_SUBST([BSYMBOLIC])
549
550 dnl
551 dnl Check if linker supports garbage collection
552 dnl
553 save_LDFLAGS=$LDFLAGS
554 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
555 AC_MSG_CHECKING([whether ld supports --gc-sections])
556 AC_LINK_IFELSE(
557 [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
558 [AC_MSG_RESULT([yes])
559 GC_SECTIONS="-Wl,--gc-sections";],
560 [AC_MSG_RESULT([no])
561 GC_SECTIONS="";])
562 LDFLAGS=$save_LDFLAGS
563
564 AC_SUBST([GC_SECTIONS])
565
566 dnl
567 dnl OpenBSD does not have DT_NEEDED entries for libc by design
568 dnl so when these flags are passed to ld via libtool the checks will fail
569 dnl
570 case "$host_os" in
571 openbsd* | darwin* )
572 LD_NO_UNDEFINED="" ;;
573 *)
574 LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
575 esac
576
577 AC_SUBST([LD_NO_UNDEFINED])
578
579 dnl
580 dnl Check if linker supports version scripts
581 dnl
582 AC_MSG_CHECKING([if the linker supports version-scripts])
583 save_LDFLAGS=$LDFLAGS
584 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
585 cat > conftest.map <<EOF
586 VERSION_1 {
587 global:
588 main;
589
590 local:
591 *;
592 };
593 EOF
594 AC_LINK_IFELSE(
595 [AC_LANG_SOURCE([int main() { return 0;}])],
596 [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
597 [have_ld_version_script=no; AC_MSG_RESULT(no)])
598 LDFLAGS=$save_LDFLAGS
599 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
600
601 dnl
602 dnl Check if linker supports dynamic list files
603 dnl
604 AC_MSG_CHECKING([if the linker supports --dynamic-list])
605 save_LDFLAGS=$LDFLAGS
606 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
607 cat > conftest.dyn <<EOF
608 {
609 radeon_drm_winsys_create;
610 };
611 EOF
612 AC_LINK_IFELSE(
613 [AC_LANG_SOURCE([int main() { return 0;}])],
614 [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
615 [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
616 LDFLAGS=$save_LDFLAGS
617 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
618
619 dnl
620 dnl compatibility symlinks
621 dnl
622 case "$host_os" in
623 linux* )
624 HAVE_COMPAT_SYMLINKS=yes ;;
625 * )
626 HAVE_COMPAT_SYMLINKS=no ;;
627 esac
628
629 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
630
631 DEFAULT_GL_LIB_NAME=GL
632
633 dnl
634 dnl Libglvnd configuration
635 dnl
636 AC_ARG_ENABLE([libglvnd],
637 [AS_HELP_STRING([--enable-libglvnd],
638 [Build for libglvnd @<:@default=disabled@:>@])],
639 [enable_libglvnd="$enableval"],
640 [enable_libglvnd=no])
641 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
642 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
643 if test "x$enable_libglvnd" = xyes ; then
644 DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
645 DEFAULT_GL_LIB_NAME=GLX_mesa
646 fi
647
648 dnl
649 dnl library names
650 dnl
651 dnl Unfortunately we need to do a few things that libtool can't help us with,
652 dnl so we need some knowledge of shared library filenames:
653 dnl
654 dnl LIB_EXT is the extension used when creating symlinks for alternate
655 dnl filenames for a shared library which will be dynamically loaded
656 dnl
657 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
658 dnl the file for a shared library we wish to link with
659 dnl
660 case "$host_os" in
661 darwin* )
662 LIB_EXT='dylib'
663 IMP_LIB_EXT=$LIB_EXT
664 ;;
665 cygwin* )
666 LIB_EXT='dll'
667 IMP_LIB_EXT='dll.a'
668 ;;
669 aix* )
670 LIB_EXT='a'
671 IMP_LIB_EXT=$LIB_EXT
672 ;;
673 * )
674 LIB_EXT='so'
675 IMP_LIB_EXT=$LIB_EXT
676 ;;
677 esac
678
679 AC_SUBST([LIB_EXT])
680
681 AC_ARG_WITH([gl-lib-name],
682 [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
683 [specify GL library name @<:@default=GL@:>@])],
684 [GL_LIB=$withval],
685 [GL_LIB="$DEFAULT_GL_LIB_NAME"])
686 AC_ARG_WITH([osmesa-lib-name],
687 [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
688 [specify OSMesa library name @<:@default=OSMesa@:>@])],
689 [OSMESA_LIB=$withval],
690 [OSMESA_LIB=OSMesa])
691 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
692 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
693
694 dnl
695 dnl Mangled Mesa support
696 dnl
697 AC_ARG_ENABLE([mangling],
698 [AS_HELP_STRING([--enable-mangling],
699 [enable mangled symbols and library name @<:@default=disabled@:>@])],
700 [enable_mangling="${enableval}"],
701 [enable_mangling=no]
702 )
703 if test "x${enable_mangling}" = "xyes" ; then
704 DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
705 GL_LIB="Mangled${GL_LIB}"
706 OSMESA_LIB="Mangled${OSMESA_LIB}"
707 fi
708 AC_SUBST([GL_LIB])
709 AC_SUBST([OSMESA_LIB])
710
711 dnl
712 dnl potentially-infringing-but-nobody-knows-for-sure stuff
713 dnl
714 AC_ARG_ENABLE([texture-float],
715 [AS_HELP_STRING([--enable-texture-float],
716 [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
717 [enable_texture_float="$enableval"],
718 [enable_texture_float=no]
719 )
720 if test "x$enable_texture_float" = xyes; then
721 AC_MSG_WARN([Floating-point textures enabled.])
722 AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
723 DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
724 fi
725
726 dnl
727 dnl Arch/platform-specific settings
728 dnl
729 AC_ARG_ENABLE([asm],
730 [AS_HELP_STRING([--disable-asm],
731 [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
732 [enable_asm="$enableval"],
733 [enable_asm=yes]
734 )
735 asm_arch=""
736 AC_MSG_CHECKING([whether to enable assembly])
737 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
738 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
739 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
740 case "$host_cpu" in
741 i?86 | x86_64 | amd64)
742 if test "x$host_cpu" != "x$target_cpu"; then
743 enable_asm=no
744 AC_MSG_RESULT([no, cross compiling])
745 fi
746 ;;
747 esac
748 fi
749 # check for supported arches
750 if test "x$enable_asm" = xyes; then
751 case "$host_cpu" in
752 i?86)
753 case "$host_os" in
754 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
755 asm_arch=x86
756 ;;
757 esac
758 ;;
759 x86_64|amd64)
760 case "$host_os" in
761 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
762 asm_arch=x86_64
763 ;;
764 esac
765 ;;
766 sparc*)
767 case "$host_os" in
768 linux*)
769 asm_arch=sparc
770 ;;
771 esac
772 ;;
773 esac
774
775 case "$asm_arch" in
776 x86)
777 DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
778 AC_MSG_RESULT([yes, x86])
779 ;;
780 x86_64|amd64)
781 DEFINES="$DEFINES -DUSE_X86_64_ASM"
782 AC_MSG_RESULT([yes, x86_64])
783 ;;
784 sparc)
785 DEFINES="$DEFINES -DUSE_SPARC_ASM"
786 AC_MSG_RESULT([yes, sparc])
787 ;;
788 *)
789 AC_MSG_RESULT([no, platform not supported])
790 ;;
791 esac
792 fi
793
794 AC_HEADER_MAJOR
795 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
796 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
797 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
798 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
799
800 dnl Check to see if dlopen is in default libraries (like Solaris, which
801 dnl has it in libc), or if libdl is needed to get it.
802 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
803 [AC_CHECK_LIB([dl], [dlopen],
804 [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
805 AC_SUBST([DLOPEN_LIBS])
806
807 dnl Check if that library also has dladdr
808 save_LIBS="$LIBS"
809 LIBS="$LIBS $DLOPEN_LIBS"
810 AC_CHECK_FUNCS([dladdr])
811 LIBS="$save_LIBS"
812
813 case "$host_os" in
814 darwin*)
815 ;;
816 *)
817 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
818 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
819 [AC_MSG_ERROR([Could not find clock_gettime])])])
820 AC_SUBST([CLOCK_LIB])
821 ;;
822 esac
823
824 dnl See if posix_memalign is available
825 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
826
827 dnl Check for pthreads
828 AX_PTHREAD
829 if test "x$ax_pthread_ok" = xno; then
830 AC_MSG_ERROR([Building mesa on this platform requires pthreads])
831 fi
832 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
833 dnl to -pthread, which causes problems if we need -lpthread to appear in
834 dnl pkgconfig files. Since Android doesn't have a pthread lib, this check
835 dnl is not valid for that platform.
836 if test "x$android" = xno; then
837 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
838 fi
839
840 dnl pthread-stubs is mandatory on targets where it exists
841 case "$host_os" in
842 cygwin* )
843 pthread_stubs_possible="no"
844 ;;
845 * )
846 pthread_stubs_possible="yes"
847 ;;
848 esac
849
850 if test "x$pthread_stubs_possible" = xyes; then
851 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
852 AC_SUBST(PTHREADSTUBS_CFLAGS)
853 AC_SUBST(PTHREADSTUBS_LIBS)
854 fi
855
856 dnl SELinux awareness.
857 AC_ARG_ENABLE([selinux],
858 [AS_HELP_STRING([--enable-selinux],
859 [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
860 [MESA_SELINUX="$enableval"],
861 [MESA_SELINUX=no])
862 if test "x$enable_selinux" = "xyes"; then
863 PKG_CHECK_MODULES([SELINUX], [libselinux], [],
864 [AC_CHECK_HEADER([selinux/selinux.h],[],
865 [AC_MSG_ERROR([SELinux headers not found])])
866 AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
867 [AC_MSG_ERROR([SELinux library not found])])
868 SELINUX_LIBS="-lselinux"])
869 DEFINES="$DEFINES -DMESA_SELINUX"
870 fi
871 AC_SUBST([SELINUX_CFLAGS])
872 AC_SUBST([SELINUX_LIBS])
873
874 dnl
875 dnl LLVM
876 dnl
877 AC_ARG_ENABLE([llvm-shared-libs],
878 [AS_HELP_STRING([--enable-llvm-shared-libs],
879 [link with LLVM shared libraries @<:@default=enabled@:>@])],
880 [enable_llvm_shared_libs="$enableval"],
881 [enable_llvm_shared_libs=yes])
882
883 AC_ARG_WITH([llvm-prefix],
884 [AS_HELP_STRING([--with-llvm-prefix],
885 [Prefix for LLVM installations in non-standard locations])],
886 [llvm_prefix="$withval"],
887 [llvm_prefix=''])
888
889 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
890 if test "x$have_libelf" = xno; then
891 LIBELF_LIBS=''
892 LIBELF_CFLAGS=''
893 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
894 AC_SUBST([LIBELF_LIBS])
895 AC_SUBST([LIBELF_CFLAGS])
896 fi
897
898 if test -z "$LLVM_CONFIG"; then
899 if test -n "$llvm_prefix"; then
900 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
901 else
902 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
903 fi
904 fi
905
906 llvm_add_component() {
907 new_llvm_component=$1
908 driver_name=$2
909
910 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
911 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
912 else
913 AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
914 fi
915 }
916
917 llvm_add_default_components() {
918 driver_name=$1
919
920 # Required default components
921 llvm_add_component "bitwriter" $driver_name
922 llvm_add_component "engine" $driver_name
923 llvm_add_component "mcdisassembler" $driver_name
924 llvm_add_component "mcjit" $driver_name
925
926 # Optional default components
927 if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
928 LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
929 fi
930 }
931
932 llvm_add_target() {
933 new_llvm_target=$1
934 driver_name=$2
935
936 if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
937 llvm_add_component $new_llvm_target $driver_name
938 else
939 AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
940 fi
941 }
942
943 # Call this inside ` ` to get the return value.
944 # $1 is the llvm-config command with arguments.
945 strip_unwanted_llvm_flags() {
946 # Use \> (marks the end of the word)
947 echo `$1` | sed \
948 -e 's/-march=\S*//g' \
949 -e 's/-mtune=\S*//g' \
950 -e 's/-mcpu=\S*//g' \
951 -e 's/-DNDEBUG\>//g' \
952 -e 's/-D_GNU_SOURCE\>//g' \
953 -e 's/-pedantic\>//g' \
954 -e 's/-Wcovered-switch-default\>//g' \
955 -e 's/-O.\>//g' \
956 -e 's/-g\>//g' \
957 -e 's/-Wall\>//g' \
958 -e 's/-Wcast-qual\>//g' \
959 -e 's/-Woverloaded-virtual\>//g' \
960 -e 's/-fcolor-diagnostics\>//g' \
961 -e 's/-fdata-sections\>//g' \
962 -e 's/-ffunction-sections\>//g' \
963 -e 's/-fno-exceptions\>//g' \
964 -e 's/-fomit-frame-pointer\>//g' \
965 -e 's/-fvisibility-inlines-hidden\>//g' \
966 -e 's/-fPIC\>//g' \
967 -e 's/-fstack-protector-strong\>//g'
968 }
969
970 llvm_set_environment_variables() {
971 if test "x$LLVM_CONFIG" != xno; then
972 LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
973 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
974 LLVM_BINDIR=`$LLVM_CONFIG --bindir`
975 LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
976 LLVM_CFLAGS=$LLVM_CPPFLAGS # CPPFLAGS seem to be sufficient
977 LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
978 LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
979 LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
980
981 # We need to respect LLVM_CFLAGS when compiling LLVM headers.
982 save_CFLAGS="$CFLAGS"
983 CFLAGS="$CFLAGS $LLVM_CFLAGS"
984
985 AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
986 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
987 AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
988 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
989 AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
990 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
991
992 CFLAGS="$save_CFLAGS"
993
994 # Only needed for LLVM < 3.6.0
995 if test -z "$LLVM_VERSION_PATCH"; then
996 LLVM_VERSION_PATCH=0
997 fi
998
999 if test "$LLVM_VERSION_MINOR" -lt 10; then
1000 LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1001 else
1002 LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
1003 fi
1004
1005 DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1006 MESA_LLVM=1
1007 else
1008 MESA_LLVM=0
1009 LLVM_VERSION_INT=0
1010 fi
1011 }
1012
1013 llvm_check_version_for() {
1014 if test "x$MESA_LLVM" = x0; then
1015 AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1016 return
1017 fi
1018
1019 llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1020 llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1021 llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1022
1023 if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1024 # major > required major
1025 # --> OK
1026 return
1027 fi
1028
1029 if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1030 if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1031 # major = required major and
1032 # minor > required minor
1033 # --> OK
1034 return
1035 else
1036 if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1037 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1038 # major = required major and
1039 # minor = required minor and
1040 # patch >= required patch
1041 # --> OK
1042 return
1043 fi
1044 fi
1045 fi
1046 fi
1047
1048 AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1049 }
1050
1051 radeon_llvm_check() {
1052 if test ${LLVM_VERSION_INT} -lt 307; then
1053 amdgpu_llvm_target_name='r600'
1054 else
1055 amdgpu_llvm_target_name='amdgpu'
1056 fi
1057
1058 llvm_check_version_for $*
1059
1060 llvm_add_target $amdgpu_llvm_target_name $2
1061
1062 llvm_add_default_components $2
1063 llvm_add_component "bitreader" $2
1064 llvm_add_component "ipo" $2
1065
1066 NEED_RADEON_LLVM=yes
1067 if test "x$have_libelf" != xyes; then
1068 AC_MSG_ERROR([$1 requires libelf when using llvm])
1069 fi
1070 }
1071
1072 llvm_set_environment_variables
1073
1074 AC_SUBST([MESA_LLVM])
1075 AC_SUBST([LLVM_BINDIR])
1076 AC_SUBST([LLVM_CFLAGS])
1077 AC_SUBST([LLVM_CPPFLAGS])
1078 AC_SUBST([LLVM_CXXFLAGS])
1079 AC_SUBST([LLVM_LIBDIR])
1080 AC_SUBST([LLVM_LIBS])
1081 AC_SUBST([LLVM_LDFLAGS])
1082 AC_SUBST([LLVM_INCLUDEDIR])
1083 AC_SUBST([LLVM_VERSION])
1084
1085 dnl Options for APIs
1086 AC_ARG_ENABLE([opengl],
1087 [AS_HELP_STRING([--disable-opengl],
1088 [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1089 [enable_opengl="$enableval"],
1090 [enable_opengl=yes])
1091 AC_ARG_ENABLE([gles1],
1092 [AS_HELP_STRING([--disable-gles1],
1093 [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1094 [enable_gles1="$enableval"],
1095 [enable_gles1=yes])
1096 AC_ARG_ENABLE([gles2],
1097 [AS_HELP_STRING([--disable-gles2],
1098 [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1099 [enable_gles2="$enableval"],
1100 [enable_gles2=yes])
1101
1102 AC_ARG_ENABLE([dri],
1103 [AS_HELP_STRING([--enable-dri],
1104 [enable DRI modules @<:@default=enabled@:>@])],
1105 [enable_dri="$enableval"],
1106 [enable_dri=yes])
1107
1108 AC_ARG_ENABLE([gallium-extra-hud],
1109 [AS_HELP_STRING([--enable-gallium-extra-hud],
1110 [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1111 [enable_gallium_extra_hud="$enableval"],
1112 [enable_gallium_extra_hud=no])
1113 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1114 if test "x$enable_gallium_extra_hud" = xyes ; then
1115 DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1116 fi
1117
1118 #TODO: no pkgconfig .pc available for libsensors.
1119 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1120 AC_ARG_ENABLE([lmsensors],
1121 [AS_HELP_STRING([--enable-lmsensors],
1122 [enable HUD lmsensor support @<:@default=disabled@:>@])],
1123 [enable_lmsensors="$enableval"],
1124 [enable_lmsensors=no])
1125 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1126 if test "x$enable_lmsensors" = xyes ; then
1127 DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1128 LIBSENSORS_LIBS="-lsensors"
1129 else
1130 LIBSENSORS_LIBS=""
1131 fi
1132 AC_SUBST(LIBSENSORS_LIBS)
1133
1134 case "$host_os" in
1135 linux*)
1136 dri3_default=yes
1137 ;;
1138 *)
1139 dri3_default=no
1140 ;;
1141 esac
1142
1143 if test "x$enable_dri" = xno; then
1144 dri3_default=no
1145 fi
1146
1147 AC_ARG_ENABLE([dri3],
1148 [AS_HELP_STRING([--enable-dri3],
1149 [enable DRI3 @<:@default=auto@:>@])],
1150 [enable_dri3="$enableval"],
1151 [enable_dri3="$dri3_default"])
1152 AC_ARG_ENABLE([glx],
1153 [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1154 [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1155 [enable_glx="$enableval"],
1156 [enable_glx=yes])
1157 AC_ARG_ENABLE([osmesa],
1158 [AS_HELP_STRING([--enable-osmesa],
1159 [enable OSMesa library @<:@default=disabled@:>@])],
1160 [enable_osmesa="$enableval"],
1161 [enable_osmesa=no])
1162 AC_ARG_ENABLE([gallium-osmesa],
1163 [AS_HELP_STRING([--enable-gallium-osmesa],
1164 [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1165 [enable_gallium_osmesa="$enableval"],
1166 [enable_gallium_osmesa=no])
1167 AC_ARG_ENABLE([egl],
1168 [AS_HELP_STRING([--disable-egl],
1169 [disable EGL library @<:@default=enabled@:>@])],
1170 [enable_egl="$enableval"],
1171 [enable_egl=yes])
1172
1173 AC_ARG_ENABLE([xa],
1174 [AS_HELP_STRING([--enable-xa],
1175 [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1176 [enable_xa="$enableval"],
1177 [enable_xa=no])
1178 AC_ARG_ENABLE([gbm],
1179 [AS_HELP_STRING([--enable-gbm],
1180 [enable gbm library @<:@default=yes except cygwin@:>@])],
1181 [enable_gbm="$enableval"],
1182 [case "$host_os" in
1183 cygwin*)
1184 enable_gbm=no
1185 ;;
1186 *)
1187 enable_gbm=yes
1188 ;;
1189 esac])
1190 AC_ARG_ENABLE([nine],
1191 [AS_HELP_STRING([--enable-nine],
1192 [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1193 [enable_nine="$enableval"],
1194 [enable_nine=no])
1195
1196 AC_ARG_ENABLE([xvmc],
1197 [AS_HELP_STRING([--enable-xvmc],
1198 [enable xvmc library @<:@default=auto@:>@])],
1199 [enable_xvmc="$enableval"],
1200 [enable_xvmc=auto])
1201 AC_ARG_ENABLE([vdpau],
1202 [AS_HELP_STRING([--enable-vdpau],
1203 [enable vdpau library @<:@default=auto@:>@])],
1204 [enable_vdpau="$enableval"],
1205 [enable_vdpau=auto])
1206 AC_ARG_ENABLE([omx],
1207 [AS_HELP_STRING([--enable-omx],
1208 [enable OpenMAX library @<:@default=disabled@:>@])],
1209 [enable_omx="$enableval"],
1210 [enable_omx=no])
1211 AC_ARG_ENABLE([va],
1212 [AS_HELP_STRING([--enable-va],
1213 [enable va library @<:@default=auto@:>@])],
1214 [enable_va="$enableval"],
1215 [enable_va=auto])
1216 AC_ARG_ENABLE([opencl],
1217 [AS_HELP_STRING([--enable-opencl],
1218 [enable OpenCL library @<:@default=disabled@:>@])],
1219 [enable_opencl="$enableval"],
1220 [enable_opencl=no])
1221 AC_ARG_ENABLE([opencl_icd],
1222 [AS_HELP_STRING([--enable-opencl-icd],
1223 [Build an OpenCL ICD library to be loaded by an ICD implementation
1224 @<:@default=disabled@:>@])],
1225 [enable_opencl_icd="$enableval"],
1226 [enable_opencl_icd=no])
1227
1228 AC_ARG_ENABLE([gallium-tests],
1229 [AS_HELP_STRING([--enable-gallium-tests],
1230 [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1231 [enable_gallium_tests="$enableval"],
1232 [enable_gallium_tests=no])
1233
1234 # Option for Gallium drivers
1235
1236 # Keep this in sync with the --with-gallium-drivers help string default value
1237 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1238
1239 AC_ARG_WITH([gallium-drivers],
1240 [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1241 [comma delimited Gallium drivers list, e.g.
1242 "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl,etnaviv,imx"
1243 @<:@default=r300,r600,svga,swrast@:>@])],
1244 [with_gallium_drivers="$withval"],
1245 [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1246
1247 # Doing '--without-gallium-drivers' will set this variable to 'no'. Clear it
1248 # here so that the script doesn't choke on an unknown driver name later.
1249 case "$with_gallium_drivers" in
1250 yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1251 no) with_gallium_drivers='' ;;
1252 esac
1253
1254 if test "x$enable_opengl" = xno -a \
1255 "x$enable_gles1" = xno -a \
1256 "x$enable_gles2" = xno -a \
1257 "x$enable_nine" = xno -a \
1258 "x$enable_xa" = xno -a \
1259 "x$enable_xvmc" = xno -a \
1260 "x$enable_vdpau" = xno -a \
1261 "x$enable_omx" = xno -a \
1262 "x$enable_va" = xno -a \
1263 "x$enable_opencl" = xno; then
1264 AC_MSG_ERROR([at least one API should be enabled])
1265 fi
1266
1267 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1268 if test "x$enable_opengl" = xno -a \
1269 "x$enable_gles1" = xyes; then
1270 AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1271 fi
1272
1273 if test "x$enable_opengl" = xno -a \
1274 "x$enable_gles2" = xyes; then
1275 AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1276 fi
1277
1278 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1279 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1280 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1281 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1282 "x$enable_gles1" = xyes -o \
1283 "x$enable_gles2" = xyes)
1284
1285 # Validate GLX options
1286 if test "x$enable_glx" = xyes; then
1287 if test "x$enable_dri" = xyes; then
1288 enable_glx=dri
1289 elif test -n "$with_gallium_drivers"; then
1290 enable_glx=gallium-xlib
1291 else
1292 enable_glx=xlib
1293 fi
1294 fi
1295 case "x$enable_glx" in
1296 xdri | xxlib | xgallium-xlib)
1297 # GLX requires OpenGL
1298 if test "x$enable_opengl" = xno; then
1299 AC_MSG_ERROR([GLX cannot be built without OpenGL])
1300 fi
1301
1302 # Check individual dependencies
1303 case "x$enable_glx" in
1304 xdri)
1305 if test "x$enable_dri" = xno; then
1306 AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1307 fi
1308 ;;
1309 xxlib)
1310 if test "x$enable_dri" = xyes; then
1311 AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1312 fi
1313 ;;
1314 xgallium-xlib )
1315 if test "x$enable_dri" = xyes; then
1316 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1317 fi
1318 if test -z "$with_gallium_drivers"; then
1319 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1320 fi
1321 ;;
1322 esac
1323 ;;
1324 xno)
1325 ;;
1326 *)
1327 AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1328 ;;
1329 esac
1330
1331 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1332 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1333 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1334 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1335
1336 dnl
1337 dnl Libglvnd configuration
1338 dnl
1339 AC_ARG_ENABLE([libglvnd],
1340 [AS_HELP_STRING([--enable-libglvnd],
1341 [Build for libglvnd @<:@default=disabled@:>@])],
1342 [enable_libglvnd="$enableval"],
1343 [enable_libglvnd=no])
1344 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1345 if test "x$enable_libglvnd" = xyes ; then
1346 dnl XXX: update once we can handle more than libGL/glx.
1347 dnl Namely: we should error out if neither of the glvnd enabled libraries
1348 dnl are built
1349 case "x$enable_glx" in
1350 xno)
1351 AC_MSG_ERROR([cannot build libglvnd without GLX])
1352 ;;
1353 xxlib | xgallium-xlib )
1354 AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1355 ;;
1356 xdri)
1357 ;;
1358 esac
1359
1360 PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1361 DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1362 DEFAULT_GL_LIB_NAME=GLX_mesa
1363 fi
1364
1365 # Check for libdrm
1366 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1367 [have_libdrm=yes], [have_libdrm=no])
1368 if test "x$have_libdrm" = xyes; then
1369 DEFINES="$DEFINES -DHAVE_LIBDRM"
1370 fi
1371
1372 require_libdrm() {
1373 if test "x$have_libdrm" != xyes; then
1374 AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1375 fi
1376 }
1377
1378
1379 # Select which platform-dependent DRI code gets built
1380 case "$host_os" in
1381 darwin*)
1382 dri_platform='apple' ;;
1383 cygwin*)
1384 dri_platform='windows' ;;
1385 gnu*)
1386 dri_platform='none' ;;
1387 *)
1388 dri_platform='drm' ;;
1389 esac
1390
1391 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1392 have_drisw_kms='yes'
1393 fi
1394
1395 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1396 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1397 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1398 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1399 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1400 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1401 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1402 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1403 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1404
1405 AC_ARG_ENABLE([shared-glapi],
1406 [AS_HELP_STRING([--enable-shared-glapi],
1407 [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1408 [enable_shared_glapi="$enableval"],
1409 [enable_shared_glapi=yes])
1410
1411 case "x$enable_opengl$enable_gles1$enable_gles2" in
1412 x*yes*yes*)
1413 if test "x$enable_shared_glapi" = xno; then
1414 AC_MSG_ERROR([shared GLAPI required when building two or more of
1415 the following APIs - opengl, gles1 gles2])
1416 fi
1417 ;;
1418 esac
1419
1420 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1421
1422 # Build the pipe-drivers as separate libraries/modules.
1423 # Do not touch this unless you know what you are doing.
1424 # XXX: Expose via configure option ?
1425 enable_shared_pipe_drivers=no
1426
1427 dnl
1428 dnl Driver specific build directories
1429 dnl
1430
1431 if test "x$enable_gallium_osmesa" = xyes; then
1432 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1433 AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1434 fi
1435 if test "x$enable_osmesa" = xyes; then
1436 AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1437 fi
1438 fi
1439
1440 # SHA1 hashing
1441 AC_ARG_WITH([sha1],
1442 [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1443 [choose SHA1 implementation])])
1444 case "x$with_sha1" in
1445 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1446 ;;
1447 *)
1448 AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1449 esac
1450
1451 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1452 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1453 with_sha1=libc
1454 fi
1455 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1456 AC_MSG_ERROR([sha1 in libc requested but not found])
1457 fi
1458 if test "x$with_sha1" = xlibc; then
1459 AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1460 [Use libc SHA1 functions])
1461 SHA1_LIBS=""
1462 fi
1463 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1464 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1465 with_sha1=CommonCrypto
1466 fi
1467 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1468 AC_MSG_ERROR([CommonCrypto requested but not found])
1469 fi
1470 if test "x$with_sha1" = xCommonCrypto; then
1471 AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1472 [Use CommonCrypto SHA1 functions])
1473 SHA1_LIBS=""
1474 fi
1475 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1476 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1477 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1478 with_sha1=CryptoAPI
1479 fi
1480 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1481 AC_MSG_ERROR([CryptoAPI requested but not found])
1482 fi
1483 if test "x$with_sha1" = xCryptoAPI; then
1484 AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1485 [Use CryptoAPI SHA1 functions])
1486 SHA1_LIBS=""
1487 fi
1488 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1489 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1490 with_sha1=libmd
1491 fi
1492 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1493 AC_MSG_ERROR([libmd requested but not found])
1494 fi
1495 if test "x$with_sha1" = xlibmd; then
1496 AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1497 [Use libmd SHA1 functions])
1498 SHA1_LIBS=-lmd
1499 fi
1500 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1501 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1502 with_sha1=libsha1
1503 fi
1504 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1505 AC_MSG_ERROR([libsha1 requested but not found])
1506 fi
1507 if test "x$with_sha1" = xlibsha1; then
1508 AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1509 [Use libsha1 for SHA1])
1510 SHA1_LIBS=-lsha1
1511 fi
1512 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1513 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1514 with_sha1=libnettle
1515 fi
1516 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1517 AC_MSG_ERROR([libnettle requested but not found])
1518 fi
1519 if test "x$with_sha1" = xlibnettle; then
1520 AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1521 [Use libnettle SHA1 functions])
1522 SHA1_LIBS=-lnettle
1523 fi
1524 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1525 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1526 with_sha1=libgcrypt
1527 fi
1528 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1529 AC_MSG_ERROR([libgcrypt requested but not found])
1530 fi
1531 if test "x$with_sha1" = xlibgcrypt; then
1532 AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1533 [Use libgcrypt SHA1 functions])
1534 SHA1_LIBS=-lgcrypt
1535 fi
1536 # We don't need all of the OpenSSL libraries, just libcrypto
1537 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1538 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1539 [HAVE_OPENSSL_PKC=no])
1540 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1541 if test "x$with_sha1" = x; then
1542 with_sha1=libcrypto
1543 fi
1544 else
1545 if test "x$with_sha1" = xlibcrypto; then
1546 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1547 fi
1548 fi
1549 if test "x$with_sha1" = xlibcrypto; then
1550 if test "x$HAVE_LIBCRYPTO" = xyes; then
1551 SHA1_LIBS=-lcrypto
1552 else
1553 SHA1_LIBS="$OPENSSL_LIBS"
1554 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1555 fi
1556 fi
1557 AC_MSG_CHECKING([for SHA1 implementation])
1558 AC_MSG_RESULT([$with_sha1])
1559 AC_SUBST(SHA1_LIBS)
1560 AC_SUBST(SHA1_CFLAGS)
1561
1562 # Enable a define for SHA1
1563 if test "x$with_sha1" != "x"; then
1564 DEFINES="$DEFINES -DHAVE_SHA1"
1565 fi
1566
1567 # Allow user to configure out the shader-cache feature
1568 AC_ARG_ENABLE([shader-cache],
1569 AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1570 [enable_shader_cache="$enableval"],
1571 [if test "x$with_sha1" != "x"; then
1572 enable_shader_cache=yes
1573 else
1574 enable_shader_cache=no
1575 fi])
1576 if test "x$with_sha1" = "x"; then
1577 if test "x$enable_shader_cache" = "xyes"; then
1578 AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1579 fi
1580 fi
1581 if test "x$enable_shader_cache" = "xyes"; then
1582 AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1583 fi
1584
1585 if test "x$enable_dri" = xyes; then
1586 require_dri_shared_libs_and_glapi "DRI"
1587
1588 # not a hard requirement as swrast does not depend on it
1589 if test "x$have_libdrm" = xyes; then
1590 DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1591 fi
1592 fi
1593
1594 AC_ARG_ENABLE([driglx-direct],
1595 [AS_HELP_STRING([--disable-driglx-direct],
1596 [disable direct rendering in GLX and EGL for DRI \
1597 @<:@default=auto@:>@])],
1598 [driglx_direct="$enableval"],
1599 [driglx_direct="yes"])
1600
1601 dnl
1602 dnl libGL configuration per driver
1603 dnl
1604 if test "x$enable_glx" != xno; then
1605 PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1606 fi
1607 case "x$enable_glx" in
1608 xxlib | xgallium-xlib)
1609 # Xlib-based GLX
1610 dri_modules="x11 xext xcb"
1611 PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1612 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1613 X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1614 GL_LIB_DEPS="$XLIBGL_LIBS"
1615 GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1616 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1617 ;;
1618 xdri)
1619 # DRI-based GLX
1620
1621 # find the DRI deps for libGL
1622 dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1623
1624 if test x"$driglx_direct" = xyes; then
1625 if test x"$dri_platform" = xdrm ; then
1626 DEFINES="$DEFINES -DGLX_USE_DRM"
1627 require_libdrm "Direct rendering"
1628
1629 PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1630 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1631 if test x"$enable_dri3" = xyes; then
1632 PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1633 PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1634 fi
1635
1636 if test x"$enable_dri" = xyes; then
1637 dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1638 fi
1639
1640 if test x"$enable_dri3" = xyes; then
1641 PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1642 dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1643 PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1644 fi
1645 fi
1646 if test x"$dri_platform" = xapple ; then
1647 DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1648 fi
1649 if test x"$dri_platform" = xwindows ; then
1650 DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1651 fi
1652 fi
1653
1654 # add xf86vidmode if available
1655 PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1656 if test "$HAVE_XF86VIDMODE" = yes ; then
1657 dri_modules="$dri_modules xxf86vm"
1658 fi
1659
1660 PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1661 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1662 X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1663 GL_LIB_DEPS="$DRIGL_LIBS"
1664
1665 # need DRM libs, $PTHREAD_LIBS, etc.
1666 GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1667 GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1668 ;;
1669 esac
1670
1671 # This is outside the case (above) so that it is invoked even for non-GLX
1672 # builds.
1673 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1674
1675 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1676 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1677 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1678 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1679
1680 AC_SUBST([X11_INCLUDES])
1681 AC_SUBST([GL_LIB_DEPS])
1682 AC_SUBST([GL_PC_REQ_PRIV])
1683 AC_SUBST([GL_PC_LIB_PRIV])
1684 AC_SUBST([GL_PC_CFLAGS])
1685 AC_SUBST([DRI_PC_REQ_PRIV])
1686 AC_SUBST([GLESv1_CM_LIB_DEPS])
1687 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1688 AC_SUBST([GLESv2_LIB_DEPS])
1689 AC_SUBST([GLESv2_PC_LIB_PRIV])
1690
1691 AC_SUBST([HAVE_XF86VIDMODE])
1692
1693 dnl
1694 dnl More GLX setup
1695 dnl
1696 case "x$enable_glx" in
1697 xxlib | xgallium-xlib)
1698 DEFINES="$DEFINES -DUSE_XSHM"
1699 ;;
1700 xdri)
1701 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1702 if test "x$driglx_direct" = xyes; then
1703 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1704 fi
1705 ;;
1706 esac
1707
1708 dnl
1709 dnl TLS detection
1710 dnl
1711
1712 AC_ARG_ENABLE([glx-tls],
1713 [AS_HELP_STRING([--enable-glx-tls],
1714 [enable TLS support in GLX @<:@default=enabled@:>@])],
1715 [GLX_USE_TLS="$enableval"],
1716 [GLX_USE_TLS=yes])
1717 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1718
1719 if test "x$GLX_USE_TLS" = xyes; then
1720 DEFINES="$DEFINES -DGLX_USE_TLS"
1721 fi
1722
1723 dnl Read-only text section on x86 hardened platforms
1724 AC_ARG_ENABLE([glx-read-only-text],
1725 [AS_HELP_STRING([--enable-glx-read-only-text],
1726 [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1727 [enable_glx_read_only_text="$enableval"],
1728 [enable_glx_read_only_text=no])
1729 if test "x$enable_glx_read_only_text" = xyes; then
1730 DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1731 fi
1732
1733 dnl
1734 dnl More DRI setup
1735 dnl
1736 dnl Directory for DRI drivers
1737 AC_ARG_WITH([dri-driverdir],
1738 [AS_HELP_STRING([--with-dri-driverdir=DIR],
1739 [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1740 [DRI_DRIVER_INSTALL_DIR="$withval"],
1741 [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1742 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1743 dnl Extra search path for DRI drivers
1744 AC_ARG_WITH([dri-searchpath],
1745 [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1746 [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1747 [DRI_DRIVER_SEARCH_DIR="$withval"],
1748 [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1749 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1750 dnl Which drivers to build - default is chosen by platform
1751 AC_ARG_WITH([dri-drivers],
1752 [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1753 [comma delimited classic DRI drivers list, e.g.
1754 "swrast,i965,radeon" @<:@default=auto@:>@])],
1755 [with_dri_drivers="$withval"],
1756 [with_dri_drivers=auto])
1757
1758 if test "x$with_dri_drivers" = xauto; then
1759 if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1760 with_dri_drivers="yes"
1761 else
1762 with_dri_drivers="no"
1763 fi
1764 fi
1765 if test "x$with_dri_drivers" = xno; then
1766 with_dri_drivers=''
1767 fi
1768
1769 dnl If $with_dri_drivers is yes, drivers will be added through
1770 dnl platform checks. Set DEFINES and LIB_DEPS
1771 if test "x$enable_dri" = xyes; then
1772 # Platform specific settings and drivers to build
1773 case "$host_os" in
1774 linux*)
1775 if test "x$enable_dri3" = xyes; then
1776 DEFINES="$DEFINES -DHAVE_DRI3"
1777 fi
1778
1779 case "$host_cpu" in
1780 powerpc* | sparc*)
1781 # Build only the drivers for cards that exist on PowerPC/sparc
1782 if test "x$with_dri_drivers" = "xyes"; then
1783 with_dri_drivers="r200 radeon swrast"
1784 fi
1785 ;;
1786 esac
1787 ;;
1788 cygwin*)
1789 if test "x$with_dri_drivers" = "xyes"; then
1790 with_dri_drivers="swrast"
1791 fi
1792 ;;
1793 darwin*)
1794 DEFINES="$DEFINES -DBUILDING_MESA"
1795 if test "x$with_dri_drivers" = "xyes"; then
1796 with_dri_drivers="swrast"
1797 fi
1798 ;;
1799 esac
1800
1801 # default drivers
1802 if test "x$with_dri_drivers" = "xyes"; then
1803 with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1804 fi
1805
1806 # Check for expat
1807 PKG_CHECK_MODULES([EXPAT], [expat], [],
1808 # expat version 2.0 and earlier do not provide expat.pc
1809 [AC_CHECK_HEADER([expat.h],[],
1810 [AC_MSG_ERROR([Expat headers required for DRI not found])])
1811 AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1812 [AC_MSG_ERROR([Expat library required for DRI not found])])
1813 EXPAT_LIBS="-lexpat"])
1814
1815 # put all the necessary libs together
1816 DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1817 fi
1818
1819 AC_SUBST([DRI_LIB_DEPS])
1820
1821 DRI_DIRS=''
1822 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1823 if test -n "$with_dri_drivers"; then
1824 if test "x$enable_opengl" != xyes; then
1825 AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1826 fi
1827
1828 dri_drivers=`IFS=', '; echo $with_dri_drivers`
1829 for driver in $dri_drivers; do
1830 DRI_DIRS="$DRI_DIRS $driver"
1831 case "x$driver" in
1832 xi915)
1833 HAVE_I915_DRI=yes;
1834 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1835 ;;
1836 xi965)
1837 HAVE_I965_DRI=yes;
1838 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1839 ;;
1840 xnouveau)
1841 HAVE_NOUVEAU_DRI=yes;
1842 PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1843 ;;
1844 xradeon)
1845 HAVE_RADEON_DRI=yes;
1846 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1847 ;;
1848 xr200)
1849 HAVE_R200_DRI=yes;
1850 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1851 ;;
1852 xswrast)
1853 HAVE_SWRAST_DRI=yes;
1854 ;;
1855 *)
1856 AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1857 ;;
1858 esac
1859 done
1860 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1861 fi
1862
1863
1864 #
1865 # Vulkan driver configuration
1866 #
1867
1868 AC_ARG_WITH([vulkan-drivers],
1869 [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1870 [comma delimited Vulkan drivers list, e.g.
1871 "intel"
1872 @<:@default=no@:>@])],
1873 [with_vulkan_drivers="$withval"],
1874 [with_vulkan_drivers="no"])
1875
1876 # Doing '--without-vulkan-drivers' will set this variable to 'no'. Clear it
1877 # here so that the script doesn't choke on an unknown driver name later.
1878 case "x$with_vulkan_drivers" in
1879 xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1880 xno) with_vulkan_drivers='' ;;
1881 esac
1882
1883 AC_ARG_WITH([vulkan-icddir],
1884 [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1885 [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1886 [VULKAN_ICD_INSTALL_DIR="$withval"],
1887 [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1888 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1889
1890 if test -n "$with_vulkan_drivers"; then
1891 VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1892 for driver in $VULKAN_DRIVERS; do
1893 case "x$driver" in
1894 xintel)
1895 if test "x$HAVE_I965_DRI" != xyes; then
1896 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1897 fi
1898 if test "x$with_sha1" == "x"; then
1899 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1900 fi
1901 HAVE_INTEL_VULKAN=yes;
1902
1903 ;;
1904 xradeon)
1905 PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1906 radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1907 HAVE_RADEON_VULKAN=yes;
1908 if test "x$with_sha1" == "x"; then
1909 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1910 fi
1911 ;;
1912 *)
1913 AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1914 ;;
1915 esac
1916 done
1917 VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1918 fi
1919
1920
1921 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1922 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1923 "x$enable_osmesa" = xyes -o \
1924 -n "$DRI_DIRS")
1925
1926 dnl
1927 dnl OSMesa configuration
1928 dnl
1929
1930 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1931 AC_ARG_WITH([osmesa-bits],
1932 [AS_HELP_STRING([--with-osmesa-bits=BITS],
1933 [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1934 [osmesa_bits="$withval"],
1935 [osmesa_bits=8])
1936 if test "x$osmesa_bits" != x8; then
1937 if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1938 AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1939 osmesa_bits=8
1940 fi
1941 fi
1942 case "x$osmesa_bits" in
1943 x8)
1944 OSMESA_LIB="${OSMESA_LIB}"
1945 ;;
1946 x16|x32)
1947 OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1948 DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1949 ;;
1950 *)
1951 AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1952 ;;
1953 esac
1954
1955 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1956 # only link libraries with osmesa if shared
1957 if test "$enable_static" = no; then
1958 OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1959 else
1960 OSMESA_LIB_DEPS=""
1961 fi
1962 OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1963 fi
1964
1965 AC_SUBST([OSMESA_LIB_DEPS])
1966 AC_SUBST([OSMESA_PC_REQ])
1967 AC_SUBST([OSMESA_PC_LIB_PRIV])
1968
1969 require_dri_shared_libs_and_glapi() {
1970 if test "x$enable_static" = xyes; then
1971 AC_MSG_ERROR([$1 cannot be build as static library])
1972 fi
1973
1974 if test "x$enable_dri" != xyes; then
1975 # There is only a single backend which won't be build/used otherwise.
1976 # XXX: Revisit this as the egl/haiku is a thing.
1977 AC_MSG_ERROR([$1 requires --enable-dri])
1978 fi
1979
1980 if test "x$enable_shared_glapi" != xyes; then
1981 AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1982 fi
1983 }
1984
1985 dnl
1986 dnl gbm configuration
1987 dnl
1988 if test "x$enable_gbm" = xyes; then
1989 require_dri_shared_libs_and_glapi "gbm"
1990 fi
1991 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1992 # FINISHME: GBM has a number of dependencies which we should add below
1993 GBM_PC_REQ_PRIV=""
1994 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1995 AC_SUBST([GBM_PC_REQ_PRIV])
1996 AC_SUBST([GBM_PC_LIB_PRIV])
1997
1998 dnl
1999 dnl EGL configuration
2000 dnl
2001
2002 if test "x$enable_egl" = xyes; then
2003 EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2004
2005 AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2006
2007 require_dri_shared_libs_and_glapi "egl"
2008 fi
2009 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2010 AC_SUBST([EGL_LIB_DEPS])
2011
2012 gallium_st="mesa"
2013
2014 dnl
2015 dnl XA configuration
2016 dnl
2017 if test "x$enable_xa" = xyes; then
2018 if test "x$with_gallium_drivers" = xswrast; then
2019 AC_MSG_ERROR([
2020 Building xa requires at least one non swrast gallium driver.
2021 If you are looking to use libxatracker.so with the VMware driver,
2022 make sure to include svga in the gallium drivers list, apart from
2023 enabling XA.
2024 Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2025 fi
2026 gallium_st="$gallium_st xa"
2027 fi
2028 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2029
2030 dnl
2031 dnl Gallium G3DVL configuration
2032 dnl
2033 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2034 if test "x$enable_xvmc" = xauto; then
2035 PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2036 fi
2037
2038 if test "x$enable_vdpau" = xauto; then
2039 PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2040 fi
2041
2042 if test "x$enable_omx" = xauto; then
2043 PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2044 fi
2045
2046 if test "x$enable_va" = xauto; then
2047 PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2048 fi
2049 fi
2050
2051 if test "x$enable_dri" = xyes -o \
2052 "x$enable_xvmc" = xyes -o \
2053 "x$enable_vdpau" = xyes -o \
2054 "x$enable_omx" = xyes -o \
2055 "x$enable_va" = xyes; then
2056 need_gallium_vl=yes
2057 fi
2058 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2059
2060 if test "x$enable_xvmc" = xyes -o \
2061 "x$enable_vdpau" = xyes -o \
2062 "x$enable_omx" = xyes -o \
2063 "x$enable_va" = xyes; then
2064 if test x"$enable_dri3" = xyes; then
2065 PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2066 xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2067 else
2068 PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2069 fi
2070 need_gallium_vl_winsys=yes
2071 fi
2072 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2073
2074 if test "x$enable_xvmc" = xyes; then
2075 PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2076 gallium_st="$gallium_st xvmc"
2077 fi
2078 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2079
2080 if test "x$enable_vdpau" = xyes; then
2081 PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2082 gallium_st="$gallium_st vdpau"
2083 DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2084 fi
2085 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2086
2087 if test "x$enable_omx" = xyes; then
2088 PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2089 gallium_st="$gallium_st omx"
2090 fi
2091 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2092
2093 if test "x$enable_va" = xyes; then
2094 PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2095 gallium_st="$gallium_st va"
2096 fi
2097 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2098
2099 dnl
2100 dnl Nine Direct3D9 configuration
2101 dnl
2102 if test "x$enable_nine" = xyes; then
2103 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2104 AC_MSG_ERROR([nine requires the gallium swrast driver])
2105 fi
2106 if test "x$with_gallium_drivers" = xswrast; then
2107 AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2108 fi
2109 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2110 AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2111 fi
2112
2113 if test "x$enable_dri3" = xno; then
2114 AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2115 fi
2116
2117 gallium_st="$gallium_st nine"
2118 fi
2119 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2120
2121 dnl
2122 dnl OpenCL configuration
2123 dnl
2124
2125 AC_ARG_WITH([clang-libdir],
2126 [AS_HELP_STRING([--with-clang-libdir],
2127 [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2128 [CLANG_LIBDIR="$withval"],
2129 [CLANG_LIBDIR=''])
2130
2131 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2132
2133 if test "x$enable_opencl" = xyes; then
2134 if test -z "$with_gallium_drivers"; then
2135 AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2136 fi
2137
2138 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2139 AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2140 fi
2141
2142 if test "x$have_libclc" = xno; then
2143 AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2144 Make sure the directory containing libclc.pc is specified in your
2145 PKG_CONFIG_PATH environment variable.
2146 By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2147 else
2148 LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2149 LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2150 AC_SUBST([LIBCLC_INCLUDEDIR])
2151 AC_SUBST([LIBCLC_LIBEXECDIR])
2152 fi
2153
2154 gallium_st="$gallium_st clover"
2155
2156 if test "x$enable_opencl_icd" = xyes; then
2157 OPENCL_LIBNAME="MesaOpenCL"
2158 else
2159 OPENCL_LIBNAME="OpenCL"
2160 fi
2161
2162 if test "x$have_libelf" != xyes; then
2163 AC_MSG_ERROR([Clover requires libelf])
2164 fi
2165
2166 llvm_check_version_for $LLVM_REQUIRED_OPENCL "opencl"
2167
2168 llvm_add_default_components "opencl"
2169 llvm_add_component "all-targets" "opencl"
2170 llvm_add_component "linker" "opencl"
2171 llvm_add_component "instrumentation" "opencl"
2172 llvm_add_component "ipo" "opencl"
2173 llvm_add_component "irreader" "opencl"
2174 llvm_add_component "option" "opencl"
2175 llvm_add_component "objcarcopts" "opencl"
2176 llvm_add_component "profiledata" "opencl"
2177
2178 dnl Check for Clang internal headers
2179 if test -z "$CLANG_LIBDIR"; then
2180 CLANG_LIBDIR=${LLVM_LIBDIR}
2181 fi
2182 CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2183 AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2184 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2185 fi
2186 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2187 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2188 AC_SUBST([OPENCL_LIBNAME])
2189 AC_SUBST([CLANG_RESOURCE_DIR])
2190
2191 dnl
2192 dnl Gallium configuration
2193 dnl
2194 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2195
2196 dnl
2197 dnl EGL Platforms configuration
2198 dnl
2199 AC_ARG_WITH([egl-platforms],
2200 [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2201 [comma delimited native platforms libEGL supports, e.g.
2202 "x11,drm" @<:@default=auto@:>@])],
2203 [with_egl_platforms="$withval"],
2204 [if test "x$enable_egl" = xyes; then
2205 if test "x$enable_gbm" = xyes; then
2206 with_egl_platforms="x11,drm"
2207 else
2208 with_egl_platforms="x11"
2209 fi
2210 else
2211 with_egl_platforms=""
2212 fi])
2213
2214 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2215 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2216 fi
2217
2218 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2219 WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2220 WAYLAND_SCANNER='')
2221 if test "x$WAYLAND_SCANNER" = x; then
2222 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2223 fi
2224
2225 # Do per-EGL platform setups and checks
2226 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2227 for plat in $egl_platforms; do
2228 case "$plat" in
2229 wayland)
2230
2231 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2232
2233 if test "x$WAYLAND_SCANNER" = x; then
2234 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2235 fi
2236 ;;
2237
2238 x11)
2239 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2240 ;;
2241
2242 drm)
2243 test "x$enable_gbm" = "xno" &&
2244 AC_MSG_ERROR([EGL platform drm needs gbm])
2245 ;;
2246
2247 surfaceless)
2248 ;;
2249
2250 android)
2251 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2252 ;;
2253
2254 *)
2255 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2256 ;;
2257 esac
2258
2259 case "$plat" in
2260 wayland|drm|surfaceless)
2261 require_libdrm "Platform $plat"
2262 ;;
2263 esac
2264 done
2265
2266 # libEGL wants to default to the first platform specified in
2267 # ./configure. parse that here.
2268 if test "x$egl_platforms" != "x"; then
2269 FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2270 EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2271 else
2272 EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2273 fi
2274
2275 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2276 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2277 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2278 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2279 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2280
2281 AC_SUBST([EGL_NATIVE_PLATFORM])
2282 AC_SUBST([EGL_CFLAGS])
2283
2284 # If we don't have the X11 platform, set this define so we don't try to include
2285 # the X11 headers.
2286 if ! echo "$egl_platforms" | grep -q 'x11'; then
2287 DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2288 GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2289 fi
2290
2291 dnl
2292 dnl Gallium LLVM
2293 dnl
2294 AC_ARG_ENABLE([gallium-llvm],
2295 [AS_HELP_STRING([--enable-gallium-llvm],
2296 [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2297 [enable_gallium_llvm="$enableval"],
2298 [enable_gallium_llvm=auto])
2299
2300 if test -z "$with_gallium_drivers"; then
2301 enable_gallium_llvm=no
2302 fi
2303 if test "x$enable_gallium_llvm" = xauto; then
2304 case "$host_cpu" in
2305 i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2306 esac
2307 fi
2308
2309 dnl Directory for XVMC libs
2310 AC_ARG_WITH([xvmc-libdir],
2311 [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2312 [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2313 [XVMC_LIB_INSTALL_DIR="$withval"],
2314 [XVMC_LIB_INSTALL_DIR='${libdir}'])
2315 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2316
2317 dnl
2318 dnl Gallium Tests
2319 dnl
2320 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2321
2322 dnl Directory for VDPAU libs
2323 AC_ARG_WITH([vdpau-libdir],
2324 [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2325 [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2326 [VDPAU_LIB_INSTALL_DIR="$withval"],
2327 [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2328 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2329
2330 dnl Directory for OMX libs
2331
2332 AC_ARG_WITH([omx-libdir],
2333 [AS_HELP_STRING([--with-omx-libdir=DIR],
2334 [directory for the OMX libraries])],
2335 [OMX_LIB_INSTALL_DIR="$withval"],
2336 [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2337 AC_SUBST([OMX_LIB_INSTALL_DIR])
2338
2339 dnl Directory for VA libs
2340
2341 AC_ARG_WITH([va-libdir],
2342 [AS_HELP_STRING([--with-va-libdir=DIR],
2343 [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2344 [VA_LIB_INSTALL_DIR="$withval"],
2345 [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2346 AC_SUBST([VA_LIB_INSTALL_DIR])
2347
2348 AC_ARG_WITH([d3d-libdir],
2349 [AS_HELP_STRING([--with-d3d-libdir=DIR],
2350 [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2351 [D3D_DRIVER_INSTALL_DIR="$withval"],
2352 [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2353 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2354
2355 dnl
2356 dnl Gallium helper functions
2357 dnl
2358 gallium_require_llvm() {
2359 if test "x$enable_gallium_llvm" = "xyes"; then
2360 llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2361 else
2362 AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2363 fi
2364 }
2365
2366 dnl
2367 dnl DRM is needed by X, Wayland, and offscreen rendering.
2368 dnl Surfaceless is an alternative for the last one.
2369 dnl
2370 require_basic_egl() {
2371 case "$with_egl_platforms" in
2372 *drm*|*surfaceless*)
2373 ;;
2374 *)
2375 AC_MSG_ERROR([$1 requires one of these:
2376 1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2377 2) --with-egl-platforms=surfaceless (offscreen only)
2378 Recommended options: drm,x11])
2379 ;;
2380 esac
2381 }
2382
2383 radeon_gallium_llvm_check() {
2384 if test "x$enable_gallium_llvm" != "xyes"; then
2385 AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2386 fi
2387 radeon_llvm_check $*
2388 }
2389
2390 swr_require_cxx_feature_flags() {
2391 feature_name="$1"
2392 preprocessor_test="$2"
2393 option_list="$3"
2394 output_var="$4"
2395
2396 AC_MSG_CHECKING([whether $CXX supports $feature_name])
2397 AC_LANG_PUSH([C++])
2398 save_CXXFLAGS="$CXXFLAGS"
2399 save_IFS="$IFS"
2400 IFS=","
2401 found=0
2402 for opts in $option_list
2403 do
2404 unset IFS
2405 CXXFLAGS="$opts $save_CXXFLAGS"
2406 AC_COMPILE_IFELSE(
2407 [AC_LANG_PROGRAM(
2408 [ #if !($preprocessor_test)
2409 #error
2410 #endif
2411 ])],
2412 [found=1; break],
2413 [])
2414 IFS=","
2415 done
2416 IFS="$save_IFS"
2417 CXXFLAGS="$save_CXXFLAGS"
2418 AC_LANG_POP([C++])
2419 if test $found -eq 1; then
2420 AC_MSG_RESULT([$opts])
2421 eval "$output_var=\$opts"
2422 return 0
2423 fi
2424 AC_MSG_RESULT([no])
2425 AC_MSG_ERROR([swr requires $feature_name support])
2426 return 1
2427 }
2428
2429 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2430 if test -n "$with_gallium_drivers"; then
2431 gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2432 for driver in $gallium_drivers; do
2433 case "x$driver" in
2434 xsvga)
2435 HAVE_GALLIUM_SVGA=yes
2436 require_libdrm "svga"
2437 ;;
2438 xi915)
2439 HAVE_GALLIUM_I915=yes
2440 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2441 require_libdrm "Gallium i915"
2442 ;;
2443 xilo)
2444 HAVE_GALLIUM_ILO=yes
2445 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2446 require_libdrm "Gallium i965/ilo"
2447 ;;
2448 xr300)
2449 HAVE_GALLIUM_R300=yes
2450 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2451 require_libdrm "r300"
2452 gallium_require_llvm "r300"
2453 ;;
2454 xr600)
2455 HAVE_GALLIUM_R600=yes
2456 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2457 require_libdrm "r600"
2458 if test "x$enable_opencl" = xyes; then
2459 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2460
2461 llvm_add_component "asmparser" "r600"
2462 llvm_add_component "bitreader" "r600"
2463 fi
2464 ;;
2465 xradeonsi)
2466 HAVE_GALLIUM_RADEONSI=yes
2467 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2468 PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2469 require_libdrm "radeonsi"
2470 radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2471 require_basic_egl "radeonsi"
2472 ;;
2473 xnouveau)
2474 HAVE_GALLIUM_NOUVEAU=yes
2475 PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2476 require_libdrm "nouveau"
2477 ;;
2478 xfreedreno)
2479 HAVE_GALLIUM_FREEDRENO=yes
2480 PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2481 require_libdrm "freedreno"
2482 ;;
2483 xetnaviv)
2484 HAVE_GALLIUM_ETNAVIV=yes
2485 PKG_CHECK_MODULES([ETNAVIV], [libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2486 require_libdrm "etnaviv"
2487 ;;
2488 ximx)
2489 HAVE_GALLIUM_IMX=yes
2490 ;;
2491 xswrast)
2492 HAVE_GALLIUM_SOFTPIPE=yes
2493 if test "x$MESA_LLVM" = x1 && test "x$enable_gallium_llvm" == "xyes"; then
2494 HAVE_GALLIUM_LLVMPIPE=yes
2495 fi
2496 ;;
2497 xswr)
2498 llvm_check_version_for $LLVM_REQUIRED_SWR "swr"
2499 gallium_require_llvm "swr"
2500
2501 swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2502 ",-std=c++11" \
2503 SWR_CXX11_CXXFLAGS
2504 AC_SUBST([SWR_CXX11_CXXFLAGS])
2505
2506 swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2507 ",-mavx,-march=core-avx" \
2508 SWR_AVX_CXXFLAGS
2509 AC_SUBST([SWR_AVX_CXXFLAGS])
2510
2511 swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2512 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2513 SWR_AVX2_CXXFLAGS
2514 AC_SUBST([SWR_AVX2_CXXFLAGS])
2515
2516 HAVE_GALLIUM_SWR=yes
2517 ;;
2518 xvc4)
2519 HAVE_GALLIUM_VC4=yes
2520 PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2521 require_libdrm "vc4"
2522
2523 PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2524 [USE_VC4_SIMULATOR=yes;
2525 DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2526 [USE_VC4_SIMULATOR=no])
2527 ;;
2528 xvirgl)
2529 HAVE_GALLIUM_VIRGL=yes
2530 require_libdrm "virgl"
2531 require_basic_egl "virgl"
2532 ;;
2533 *)
2534 AC_MSG_ERROR([Unknown Gallium driver: $driver])
2535 ;;
2536 esac
2537 done
2538 fi
2539
2540 if test "x$enable_gallium_llvm" == "xyes"; then
2541 llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2542 llvm_add_default_components "gallium"
2543 fi
2544
2545 dnl We need to validate some needed dependencies for renderonly drivers.
2546
2547 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" == xyes ; then
2548 AC_ERROR([Building with imx requires etnaviv])
2549 fi
2550
2551 dnl Set LLVM_LIBS - This is done after the driver configuration so
2552 dnl that drivers can add additional components to LLVM_COMPONENTS.
2553 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2554 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2555 dnl this was causing the same libraries to be appear multiple times
2556 dnl in LLVM_LIBS.
2557
2558 if test "x$MESA_LLVM" != x0; then
2559
2560 if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2561 AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2562 fi
2563 LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2564
2565 dnl llvm-config may not give the right answer when llvm is a built as a
2566 dnl single shared library, so we must work the library name out for
2567 dnl ourselves.
2568 dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2569 if test "x$enable_llvm_shared_libs" = xyes; then
2570 dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2571 LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2572 AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2573
2574 if test "x$llvm_have_one_so" = xyes; then
2575 dnl LLVM was built using auto*, so there is only one shared object.
2576 LLVM_LIBS="-l$LLVM_SO_NAME"
2577 else
2578 dnl If LLVM was built with CMake, there will be one shared object per
2579 dnl component.
2580 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2581 [AC_MSG_ERROR([Could not find llvm shared libraries:
2582 Please make sure you have built llvm with the --enable-shared option
2583 and that your llvm libraries are installed in $LLVM_LIBDIR
2584 If you have installed your llvm libraries to a different directory you
2585 can use the --with-llvm-prefix= configure flag to specify this directory.
2586 NOTE: Mesa is attempting to use llvm shared libraries by default.
2587 If you do not want to build with llvm shared libraries and instead want to
2588 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2589 invocation and rebuild.])])
2590
2591 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2592 dnl install uses a shared object for each component and we have
2593 dnl already added all of these objects to LLVM_LIBS.
2594 fi
2595 else
2596 AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2597 dnl We need to link to llvm system libs when using static libs
2598 dnl However, only llvm 3.5+ provides --system-libs
2599 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2600 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2601 fi
2602 fi
2603 fi
2604
2605 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2606 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2608 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2609 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2610 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2612 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2613 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2614 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2617 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2621 "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2622 "x$HAVE_GALLIUM_SWR" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2625
2626 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2627
2628 if test "x$enable_dri" = xyes; then
2629 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2630 fi
2631
2632 if test "x$have_drisw_kms" = xyes; then
2633 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2634 fi
2635 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2636
2637 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2638 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2639 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2640 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2641 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2642 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2643
2644 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2645 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2646
2647 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2648 "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2649 "x$HAVE_RADEON_VULKAN" = xyes)
2650
2651 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2652 "x$HAVE_I965_DRI" = xyes)
2653
2654 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2655 "x$HAVE_GALLIUM_R600" = xyes -o \
2656 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2657 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2658 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2659 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2660 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$MESA_LLVM" = x1 -a \
2661 "x$enable_gallium_llvm" = xyes)
2662 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2663 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2664 AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2665 fi
2666
2667 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2668 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2669 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2670 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2671 "x$enable_gallium_osmesa" = xyes)
2672
2673 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2674 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2675 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2676
2677 AC_SUBST([NINE_MAJOR], 1)
2678 AC_SUBST([NINE_MINOR], 0)
2679 AC_SUBST([NINE_TINY], 0)
2680 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2681
2682 AC_SUBST([VDPAU_MAJOR], 1)
2683 AC_SUBST([VDPAU_MINOR], 0)
2684
2685 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2686 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2687 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2688 AC_SUBST([VA_MINOR], $VA_MINOR)
2689
2690 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2691
2692 AC_SUBST([XVMC_MAJOR], 1)
2693 AC_SUBST([XVMC_MINOR], 0)
2694
2695 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2696 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2697 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2698 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2699
2700 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2701 AC_SUBST([XA_MINOR], $XA_MINOR)
2702 AC_SUBST([XA_TINY], $XA_TINY)
2703 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2704
2705 AC_ARG_ENABLE(valgrind,
2706 [AS_HELP_STRING([--enable-valgrind],
2707 [Build mesa with valgrind support (default: auto)])],
2708 [VALGRIND=$enableval], [VALGRIND=auto])
2709 if test "x$VALGRIND" != xno; then
2710 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2711 fi
2712 AC_MSG_CHECKING([whether to enable Valgrind support])
2713 if test "x$VALGRIND" = xauto; then
2714 VALGRIND="$have_valgrind"
2715 fi
2716
2717 if test "x$VALGRIND" = "xyes"; then
2718 if ! test "x$have_valgrind" = xyes; then
2719 AC_MSG_ERROR([Valgrind support required but not present])
2720 fi
2721 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2722 fi
2723
2724 AC_MSG_RESULT([$VALGRIND])
2725
2726 dnl Restore LDFLAGS and CPPFLAGS
2727 LDFLAGS="$_SAVE_LDFLAGS"
2728 CPPFLAGS="$_SAVE_CPPFLAGS"
2729
2730 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2731 if test "x$acv_mesa_CLANG" = xyes; then
2732 CFLAGS="$CFLAGS -Qunused-arguments"
2733 CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2734 fi
2735
2736 dnl Add user CFLAGS and CXXFLAGS
2737 CFLAGS="$CFLAGS $USER_CFLAGS"
2738 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2739
2740 dnl Substitute the config
2741 AC_CONFIG_FILES([Makefile
2742 src/Makefile
2743 src/amd/Makefile
2744 src/amd/vulkan/Makefile
2745 src/compiler/Makefile
2746 src/egl/Makefile
2747 src/egl/main/egl.pc
2748 src/egl/wayland/wayland-drm/Makefile
2749 src/egl/wayland/wayland-egl/Makefile
2750 src/egl/wayland/wayland-egl/wayland-egl.pc
2751 src/gallium/Makefile
2752 src/gallium/auxiliary/Makefile
2753 src/gallium/auxiliary/pipe-loader/Makefile
2754 src/gallium/drivers/freedreno/Makefile
2755 src/gallium/drivers/ddebug/Makefile
2756 src/gallium/drivers/i915/Makefile
2757 src/gallium/drivers/ilo/Makefile
2758 src/gallium/drivers/llvmpipe/Makefile
2759 src/gallium/drivers/noop/Makefile
2760 src/gallium/drivers/nouveau/Makefile
2761 src/gallium/drivers/r300/Makefile
2762 src/gallium/drivers/r600/Makefile
2763 src/gallium/drivers/radeon/Makefile
2764 src/gallium/drivers/radeonsi/Makefile
2765 src/gallium/drivers/rbug/Makefile
2766 src/gallium/drivers/softpipe/Makefile
2767 src/gallium/drivers/svga/Makefile
2768 src/gallium/drivers/swr/Makefile
2769 src/gallium/drivers/trace/Makefile
2770 src/gallium/drivers/etnaviv/Makefile
2771 src/gallium/drivers/imx/Makefile
2772 src/gallium/drivers/vc4/Makefile
2773 src/gallium/drivers/virgl/Makefile
2774 src/gallium/state_trackers/clover/Makefile
2775 src/gallium/state_trackers/dri/Makefile
2776 src/gallium/state_trackers/glx/xlib/Makefile
2777 src/gallium/state_trackers/nine/Makefile
2778 src/gallium/state_trackers/omx/Makefile
2779 src/gallium/state_trackers/osmesa/Makefile
2780 src/gallium/state_trackers/va/Makefile
2781 src/gallium/state_trackers/vdpau/Makefile
2782 src/gallium/state_trackers/xa/Makefile
2783 src/gallium/state_trackers/xvmc/Makefile
2784 src/gallium/targets/d3dadapter9/Makefile
2785 src/gallium/targets/d3dadapter9/d3d.pc
2786 src/gallium/targets/dri/Makefile
2787 src/gallium/targets/libgl-xlib/Makefile
2788 src/gallium/targets/omx/Makefile
2789 src/gallium/targets/opencl/Makefile
2790 src/gallium/targets/opencl/mesa.icd
2791 src/gallium/targets/osmesa/Makefile
2792 src/gallium/targets/osmesa/osmesa.pc
2793 src/gallium/targets/pipe-loader/Makefile
2794 src/gallium/targets/va/Makefile
2795 src/gallium/targets/vdpau/Makefile
2796 src/gallium/targets/xa/Makefile
2797 src/gallium/targets/xa/xatracker.pc
2798 src/gallium/targets/xvmc/Makefile
2799 src/gallium/tests/trivial/Makefile
2800 src/gallium/tests/unit/Makefile
2801 src/gallium/winsys/etnaviv/drm/Makefile
2802 src/gallium/winsys/imx/drm/Makefile
2803 src/gallium/winsys/freedreno/drm/Makefile
2804 src/gallium/winsys/i915/drm/Makefile
2805 src/gallium/winsys/intel/drm/Makefile
2806 src/gallium/winsys/nouveau/drm/Makefile
2807 src/gallium/winsys/radeon/drm/Makefile
2808 src/gallium/winsys/amdgpu/drm/Makefile
2809 src/gallium/winsys/svga/drm/Makefile
2810 src/gallium/winsys/sw/dri/Makefile
2811 src/gallium/winsys/sw/kms-dri/Makefile
2812 src/gallium/winsys/sw/null/Makefile
2813 src/gallium/winsys/sw/wrapper/Makefile
2814 src/gallium/winsys/sw/xlib/Makefile
2815 src/gallium/winsys/vc4/drm/Makefile
2816 src/gallium/winsys/virgl/drm/Makefile
2817 src/gallium/winsys/virgl/vtest/Makefile
2818 src/gbm/Makefile
2819 src/gbm/main/gbm.pc
2820 src/glx/Makefile
2821 src/glx/apple/Makefile
2822 src/glx/tests/Makefile
2823 src/glx/windows/Makefile
2824 src/glx/windows/windowsdriproto.pc
2825 src/gtest/Makefile
2826 src/intel/Makefile
2827 src/intel/tools/Makefile
2828 src/intel/vulkan/Makefile
2829 src/loader/Makefile
2830 src/mapi/Makefile
2831 src/mapi/es1api/glesv1_cm.pc
2832 src/mapi/es2api/glesv2.pc
2833 src/mapi/glapi/gen/Makefile
2834 src/mesa/Makefile
2835 src/mesa/gl.pc
2836 src/mesa/drivers/dri/dri.pc
2837 src/mesa/drivers/dri/common/Makefile
2838 src/mesa/drivers/dri/common/xmlpool/Makefile
2839 src/mesa/drivers/dri/i915/Makefile
2840 src/mesa/drivers/dri/i965/Makefile
2841 src/mesa/drivers/dri/Makefile
2842 src/mesa/drivers/dri/nouveau/Makefile
2843 src/mesa/drivers/dri/r200/Makefile
2844 src/mesa/drivers/dri/radeon/Makefile
2845 src/mesa/drivers/dri/swrast/Makefile
2846 src/mesa/drivers/osmesa/Makefile
2847 src/mesa/drivers/osmesa/osmesa.pc
2848 src/mesa/drivers/x11/Makefile
2849 src/mesa/main/tests/Makefile
2850 src/util/Makefile
2851 src/util/tests/hash_table/Makefile
2852 src/vulkan/wsi/Makefile])
2853
2854 AC_OUTPUT
2855
2856 # Fix up dependencies in *.Plo files, where we changed the extension of a
2857 # source file
2858 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2859
2860
2861 dnl
2862 dnl Output some configuration info for the user
2863 dnl
2864 echo ""
2865 echo " prefix: $prefix"
2866 echo " exec_prefix: $exec_prefix"
2867 echo " libdir: $libdir"
2868 echo " includedir: $includedir"
2869
2870 dnl API info
2871 echo ""
2872 echo " OpenGL: $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2873
2874 dnl Driver info
2875 echo ""
2876 case "x$enable_osmesa$enable_gallium_osmesa" in
2877 xnoyes)
2878 echo " OSMesa: lib$OSMESA_LIB (Gallium)"
2879 ;;
2880 xyesno)
2881 echo " OSMesa: lib$OSMESA_LIB"
2882 ;;
2883 xnono)
2884 echo " OSMesa: no"
2885 ;;
2886 esac
2887
2888 echo ""
2889 if test "x$enable_dri" != xno; then
2890 echo " DRI platform: $dri_platform"
2891 if test -z "$DRI_DIRS"; then
2892 echo " DRI drivers: no"
2893 else
2894 echo " DRI drivers: $DRI_DIRS"
2895 fi
2896 echo " DRI driver dir: $DRI_DRIVER_INSTALL_DIR"
2897 fi
2898
2899 case "x$enable_glx" in
2900 xdri)
2901 echo " GLX: DRI-based"
2902 ;;
2903 xxlib)
2904 echo " GLX: Xlib-based"
2905 ;;
2906 xgallium-xlib)
2907 echo " GLX: Xlib-based (Gallium)"
2908 ;;
2909 *)
2910 echo " GLX: $enable_glx"
2911 ;;
2912 esac
2913
2914 dnl EGL
2915 echo ""
2916 echo " EGL: $enable_egl"
2917 if test "$enable_egl" = yes; then
2918 echo " EGL platforms: $egl_platforms"
2919
2920 egl_drivers=""
2921 if test "x$enable_dri" != "xno"; then
2922 egl_drivers="$egl_drivers builtin:egl_dri2"
2923 fi
2924 if test "x$enable_dri3" != "xno"; then
2925 egl_drivers="$egl_drivers builtin:egl_dri3"
2926 fi
2927
2928 echo " EGL drivers: $egl_drivers"
2929 fi
2930 if test "x$enable_gbm" = xyes; then
2931 echo " GBM: yes"
2932 else
2933 echo " GBM: no"
2934 fi
2935
2936 # Vulkan
2937 echo ""
2938 if test "x$VULKAN_DRIVERS" != x; then
2939 echo " Vulkan drivers: $VULKAN_DRIVERS"
2940 echo " Vulkan ICD dir: $VULKAN_ICD_INSTALL_DIR"
2941 else
2942 echo " Vulkan drivers: no"
2943 fi
2944
2945 echo ""
2946 if test "x$MESA_LLVM" = x1; then
2947 echo " llvm: yes"
2948 echo " llvm-config: $LLVM_CONFIG"
2949 echo " llvm-version: $LLVM_VERSION"
2950 else
2951 echo " llvm: no"
2952 fi
2953
2954 echo ""
2955 if test -n "$with_gallium_drivers"; then
2956 echo " Gallium drivers: $gallium_drivers"
2957 echo " Gallium st: $gallium_st"
2958 else
2959 echo " Gallium: no"
2960 fi
2961
2962 echo ""
2963 if test "x$enable_gallium_extra_hud" != xyes; then
2964 echo " HUD extra stats: no"
2965 else
2966 echo " HUD extra stats: yes"
2967 fi
2968
2969 if test "x$enable_lmsensors" != xyes; then
2970 echo " HUD lmsensors: no"
2971 else
2972 echo " HUD lmsensors: yes"
2973 fi
2974
2975 dnl Shader cache
2976 echo ""
2977 echo " Shader cache: $enable_shader_cache"
2978 if test "x$enable_shader_cache" = "xyes"; then
2979 echo " With SHA1 from: $with_sha1"
2980 fi
2981
2982 dnl Libraries
2983 echo ""
2984 echo " Shared libs: $enable_shared"
2985 echo " Static libs: $enable_static"
2986 echo " Shared-glapi: $enable_shared_glapi"
2987
2988 dnl Compiler options
2989 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2990 cflags=`echo $CFLAGS | \
2991 $SED 's/^ *//;s/ */ /;s/ *$//'`
2992 cxxflags=`echo $CXXFLAGS | \
2993 $SED 's/^ *//;s/ */ /;s/ *$//'`
2994 defines=`echo $DEFINES | $SED 's/^ *//;s/ */ /;s/ *$//'`
2995 echo ""
2996 echo " CFLAGS: $cflags"
2997 echo " CXXFLAGS: $cxxflags"
2998 echo " Macros: $defines"
2999 echo ""
3000 if test "x$MESA_LLVM" = x1; then
3001 echo " LLVM_CFLAGS: $LLVM_CFLAGS"
3002 echo " LLVM_CXXFLAGS: $LLVM_CXXFLAGS"
3003 echo " LLVM_CPPFLAGS: $LLVM_CPPFLAGS"
3004 echo " LLVM_LDFLAGS: $LLVM_LDFLAGS"
3005 echo ""
3006 fi
3007 echo " PYTHON2: $PYTHON2"
3008
3009 echo ""
3010 echo " Run '${MAKE-make}' to build Mesa"
3011 echo ""