configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.61
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([const])
 209 AX_GCC_FUNC_ATTRIBUTE([flatten])
 210 AX_GCC_FUNC_ATTRIBUTE([format])
 211 AX_GCC_FUNC_ATTRIBUTE([malloc])
 212 AX_GCC_FUNC_ATTRIBUTE([packed])
 213 AX_GCC_FUNC_ATTRIBUTE([pure])
 214 AX_GCC_FUNC_ATTRIBUTE([unused])
 215 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 216
 217 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 218
 219 dnl Make sure the pkg-config macros are defined
 220 m4_ifndef([PKG_PROG_PKG_CONFIG],
 221     [m4_fatal([Could not locate the pkg-config autoconf macros.
 222   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 223   are in a different location, try setting the environment variable
 224   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 225 PKG_PROG_PKG_CONFIG()
 226
 227 dnl LIB_DIR - library basename
 228 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 229 AC_SUBST([LIB_DIR])
 230
 231 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 232 _SAVE_LDFLAGS="$LDFLAGS"
 233 _SAVE_CPPFLAGS="$CPPFLAGS"
 234
 235 dnl Compiler macros
 236 DEFINES=""
 237 AC_SUBST([DEFINES])
 238 case "$host_os" in
 239 linux*|*-gnu*|gnu*)
 240     DEFINES="$DEFINES -D_GNU_SOURCE"
 241     ;;
 242 solaris*)
 243     DEFINES="$DEFINES -DSVR4"
 244     ;;
 245 cygwin*)
 246     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 247     ;;
 248 esac
 249
 250 dnl Add flags for gcc and g++
 251 if test "x$GCC" = xyes; then
 252     CFLAGS="$CFLAGS -Wall"
 253
 254     if test "x$USE_GNU99" = xyes; then
 255         CFLAGS="$CFLAGS -std=gnu99"
 256     else
 257         CFLAGS="$CFLAGS -std=c99"
 258     fi
 259
 260     # Enable -Werror=implicit-function-declaration and
 261     # -Werror=missing-prototypes, if available, or otherwise, just
 262     # -Wmissing-prototypes.  This is particularly useful to avoid
 263     # generating a loadable driver module that has undefined symbols.
 264     save_CFLAGS="$CFLAGS"
 265     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 266     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 267     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 268     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 269                    AC_MSG_RESULT([yes]),
 270                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 271                     AC_MSG_RESULT([no])]);
 272
 273     # Enable -fvisibility=hidden if using a gcc that supports it
 274     save_CFLAGS="$CFLAGS"
 275     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 276     VISIBILITY_CFLAGS="-fvisibility=hidden"
 277     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 278     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 279                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 280
 281     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 282     CFLAGS=$save_CFLAGS
 283
 284     # Work around aliasing bugs - developers should comment this out
 285     CFLAGS="$CFLAGS -fno-strict-aliasing"
 286
 287     # gcc's builtin memcmp is slower than glibc's
 288     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 289     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 290
 291     # Flags to help ensure that certain portions of the code -- and only those
 292     # portions -- can be built with MSVC:
 293     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 294     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 295     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 296     #   supports most of C99)
 297     # - the rest has no compiler compiler restrictions
 298     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 299     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 300
 301     # Enable -Werror=vla if compiler supports it
 302     save_CFLAGS="$CFLAGS"
 303     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 304     CFLAGS="$CFLAGS -Werror=vla"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 307                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 308                     AC_MSG_RESULT([yes])],
 309                     AC_MSG_RESULT([no]));
 310     CFLAGS="$save_CFLAGS"
 311
 312     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 313     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 314 fi
 315 if test "x$GXX" = xyes; then
 316     CXXFLAGS="$CXXFLAGS -Wall"
 317
 318     # Enable -fvisibility=hidden if using a gcc that supports it
 319     save_CXXFLAGS="$CXXFLAGS"
 320     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 321     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 322     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 323     AC_LANG_PUSH([C++])
 324     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 325                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 326     AC_LANG_POP([C++])
 327
 328     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 329     CXXFLAGS=$save_CXXFLAGS
 330
 331     # Work around aliasing bugs - developers should comment this out
 332     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 333
 334     # gcc's builtin memcmp is slower than glibc's
 335     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 336     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 337 fi
 338
 339 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 340 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 341 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 342 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 343
 344 dnl even if the compiler appears to support it, using visibility attributes isn't
 345 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 346 case "$host_os" in
 347 cygwin*)
 348     VISIBILITY_CFLAGS=""
 349     VISIBILITY_CXXFLAGS=""
 350     ;;
 351 esac
 352
 353 AC_SUBST([VISIBILITY_CFLAGS])
 354 AC_SUBST([VISIBILITY_CXXFLAGS])
 355
 356 dnl
 357 dnl Optional flags, check for compiler support
 358 dnl
 359 SSE41_CFLAGS="-msse4.1"
 360 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 361 dnl stack, but on x86-32 such alignment is not guaranteed.
 362 case "$target_cpu" in
 363 i?86)
 364     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 365     ;;
 366 esac
 367 save_CFLAGS="$CFLAGS"
 368 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 369 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 370 #include <smmintrin.h>
 371 int main () {
 372     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 373     c = _mm_max_epu32(a, b);
 374     return 0;
 375 }]])], SSE41_SUPPORTED=1)
 376 CFLAGS="$save_CFLAGS"
 377 if test "x$SSE41_SUPPORTED" = x1; then
 378     DEFINES="$DEFINES -DUSE_SSE41"
 379 fi
 380 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 381 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 382
 383 dnl Can't have static and shared libraries, default to static if user
 384 dnl explicitly requested. If both disabled, set to static since shared
 385 dnl was explicitly requested.
 386 case "x$enable_static$enable_shared" in
 387 xyesyes)
 388     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 389     enable_shared=no
 390     ;;
 391 xnono)
 392     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 393     enable_shared=yes
 394     ;;
 395 esac
 396
 397 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 398
 399 dnl
 400 dnl other compiler options
 401 dnl
 402 AC_ARG_ENABLE([debug],
 403     [AS_HELP_STRING([--enable-debug],
 404         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 405     [enable_debug="$enableval"],
 406     [enable_debug=no]
 407 )
 408 if test "x$enable_debug" = xyes; then
 409     DEFINES="$DEFINES -DDEBUG"
 410     if test "x$GCC" = xyes; then
 411         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 412             CFLAGS="$CFLAGS -g"
 413         fi
 414         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 415             CFLAGS="$CFLAGS -O0"
 416         fi
 417     fi
 418     if test "x$GXX" = xyes; then
 419         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 420             CXXFLAGS="$CXXFLAGS -g"
 421         fi
 422         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 423             CXXFLAGS="$CXXFLAGS -O0"
 424         fi
 425     fi
 426 else
 427    DEFINES="$DEFINES -DNDEBUG"
 428 fi
 429
 430 dnl
 431 dnl Check if linker supports -Bsymbolic
 432 dnl
 433 save_LDFLAGS=$LDFLAGS
 434 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 435 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 436 AC_LINK_IFELSE(
 437     [AC_LANG_SOURCE([int main() { return 0;}])],
 438     [AC_MSG_RESULT([yes])
 439         BSYMBOLIC="-Wl,-Bsymbolic";],
 440     [AC_MSG_RESULT([no])
 441         BSYMBOLIC="";])
 442 LDFLAGS=$save_LDFLAGS
 443
 444 AC_SUBST([BSYMBOLIC])
 445
 446 dnl
 447 dnl Check if linker supports garbage collection
 448 dnl
 449 save_LDFLAGS=$LDFLAGS
 450 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 451 AC_MSG_CHECKING([whether ld supports --gc-sections])
 452 AC_LINK_IFELSE(
 453     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 454     [AC_MSG_RESULT([yes])
 455         GC_SECTIONS="-Wl,--gc-sections";],
 456     [AC_MSG_RESULT([no])
 457         GC_SECTIONS="";])
 458 LDFLAGS=$save_LDFLAGS
 459
 460 AC_SUBST([GC_SECTIONS])
 461
 462 dnl
 463 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 464 dnl so when these flags are passed to ld via libtool the checks will fail
 465 dnl
 466 case "$host_os" in
 467 openbsd* | darwin* )
 468     LD_NO_UNDEFINED="" ;;
 469 *)
 470     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 471 esac
 472
 473 AC_SUBST([LD_NO_UNDEFINED])
 474
 475 dnl
 476 dnl Check if linker supports version scripts
 477 dnl
 478 AC_MSG_CHECKING([if the linker supports version-scripts])
 479 save_LDFLAGS=$LDFLAGS
 480 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 481 cat > conftest.map <<EOF
 482 VERSION_1 {
 483      global:
 484          main;
 485
 486      local:
 487          *;
 488 };
 489 EOF
 490 AC_LINK_IFELSE(
 491     [AC_LANG_SOURCE([int main() { return 0;}])],
 492     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 493     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 494 LDFLAGS=$save_LDFLAGS
 495 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 496
 497 dnl
 498 dnl Check if linker supports dynamic list files
 499 dnl
 500 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 501 save_LDFLAGS=$LDFLAGS
 502 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 503 cat > conftest.dyn <<EOF
 504 {
 505         radeon_drm_winsys_create;
 506 };
 507 EOF
 508 AC_LINK_IFELSE(
 509     [AC_LANG_SOURCE([int main() { return 0;}])],
 510     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 511     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 512 LDFLAGS=$save_LDFLAGS
 513 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 514
 515 dnl
 516 dnl compatibility symlinks
 517 dnl
 518 case "$host_os" in
 519 linux* )
 520     HAVE_COMPAT_SYMLINKS=yes ;;
 521 * )
 522     HAVE_COMPAT_SYMLINKS=no ;;
 523 esac
 524
 525 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 526
 527 dnl
 528 dnl library names
 529 dnl
 530 case "$host_os" in
 531 darwin* )
 532     LIB_EXT='dylib' ;;
 533 cygwin* )
 534     LIB_EXT='dll' ;;
 535 aix* )
 536     LIB_EXT='a' ;;
 537 * )
 538     LIB_EXT='so' ;;
 539 esac
 540
 541 AC_SUBST([LIB_EXT])
 542
 543 AC_ARG_WITH([gl-lib-name],
 544   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 545     [specify GL library name @<:@default=GL@:>@])],
 546   [GL_LIB=$withval],
 547   [GL_LIB=GL])
 548 AC_ARG_WITH([osmesa-lib-name],
 549   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 550     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 551   [OSMESA_LIB=$withval],
 552   [OSMESA_LIB=OSMesa])
 553 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 554 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 555
 556 dnl
 557 dnl Mangled Mesa support
 558 dnl
 559 AC_ARG_ENABLE([mangling],
 560   [AS_HELP_STRING([--enable-mangling],
 561     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 562   [enable_mangling="${enableval}"],
 563   [enable_mangling=no]
 564 )
 565 if test "x${enable_mangling}" = "xyes" ; then
 566   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 567   GL_LIB="Mangled${GL_LIB}"
 568   OSMESA_LIB="Mangled${OSMESA_LIB}"
 569 fi
 570 AC_SUBST([GL_LIB])
 571 AC_SUBST([OSMESA_LIB])
 572
 573 dnl
 574 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 575 dnl
 576 AC_ARG_ENABLE([texture-float],
 577     [AS_HELP_STRING([--enable-texture-float],
 578         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 579     [enable_texture_float="$enableval"],
 580     [enable_texture_float=no]
 581 )
 582 if test "x$enable_texture_float" = xyes; then
 583     AC_MSG_WARN([Floating-point textures enabled.])
 584     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 585     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 586 fi
 587
 588 dnl
 589 dnl Arch/platform-specific settings
 590 dnl
 591 AC_ARG_ENABLE([asm],
 592     [AS_HELP_STRING([--disable-asm],
 593         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 594     [enable_asm="$enableval"],
 595     [enable_asm=yes]
 596 )
 597 asm_arch=""
 598 AC_MSG_CHECKING([whether to enable assembly])
 599 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 600 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 601 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 602     case "$host_cpu" in
 603     i?86 | x86_64 | amd64)
 604         enable_asm=no
 605         AC_MSG_RESULT([no, cross compiling])
 606         ;;
 607     esac
 608 fi
 609 # check for supported arches
 610 if test "x$enable_asm" = xyes; then
 611     case "$host_cpu" in
 612     i?86)
 613         case "$host_os" in
 614         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 615             asm_arch=x86
 616             ;;
 617         esac
 618         ;;
 619     x86_64|amd64)
 620         case "$host_os" in
 621         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 622             asm_arch=x86_64
 623             ;;
 624         esac
 625         ;;
 626     sparc*)
 627         case "$host_os" in
 628         linux*)
 629             asm_arch=sparc
 630             ;;
 631         esac
 632         ;;
 633     esac
 634
 635     case "$asm_arch" in
 636     x86)
 637         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 638         AC_MSG_RESULT([yes, x86])
 639         ;;
 640     x86_64|amd64)
 641         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 642         AC_MSG_RESULT([yes, x86_64])
 643         ;;
 644     sparc)
 645         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 646         AC_MSG_RESULT([yes, sparc])
 647         ;;
 648     *)
 649         AC_MSG_RESULT([no, platform not supported])
 650         ;;
 651     esac
 652 fi
 653
 654 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 655 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 656 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 657
 658 dnl Check to see if dlopen is in default libraries (like Solaris, which
 659 dnl has it in libc), or if libdl is needed to get it.
 660 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 661     [AC_CHECK_LIB([dl], [dlopen],
 662        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 663 AC_SUBST([DLOPEN_LIBS])
 664
 665 dnl Check if that library also has dladdr
 666 save_LIBS="$LIBS"
 667 LIBS="$LIBS $DLOPEN_LIBS"
 668 AC_CHECK_FUNCS([dladdr])
 669 LIBS="$save_LIBS"
 670
 671 case "$host_os" in
 672 darwin*)
 673     ;;
 674 *)
 675     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 676                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 677                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 678     AC_SUBST([CLOCK_LIB])
 679     ;;
 680 esac
 681
 682 dnl See if posix_memalign is available
 683 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 684
 685 dnl Check for pthreads
 686 AX_PTHREAD
 687 if test "x$ax_pthread_ok" = xno; then
 688     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 689 fi
 690 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 691 dnl to -pthread, which causes problems if we need -lpthread to appear in
 692 dnl pkgconfig files.
 693 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 694
 695 dnl SELinux awareness.
 696 AC_ARG_ENABLE([selinux],
 697     [AS_HELP_STRING([--enable-selinux],
 698         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 699     [MESA_SELINUX="$enableval"],
 700     [MESA_SELINUX=no])
 701 if test "x$enable_selinux" = "xyes"; then
 702     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 703         [AC_CHECK_HEADER([selinux/selinux.h],[],
 704                          [AC_MSG_ERROR([SELinux headers not found])])
 705          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 706                       [AC_MSG_ERROR([SELinux library not found])])
 707          SELINUX_LIBS="-lselinux"])
 708     DEFINES="$DEFINES -DMESA_SELINUX"
 709 fi
 710 AC_SUBST([SELINUX_CFLAGS])
 711 AC_SUBST([SELINUX_LIBS])
 712
 713 dnl Options for APIs
 714 AC_ARG_ENABLE([opengl],
 715     [AS_HELP_STRING([--disable-opengl],
 716         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 717     [enable_opengl="$enableval"],
 718     [enable_opengl=yes])
 719 AC_ARG_ENABLE([gles1],
 720     [AS_HELP_STRING([--disable-gles1],
 721         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 722     [enable_gles1="$enableval"],
 723     [enable_gles1=yes])
 724 AC_ARG_ENABLE([gles2],
 725     [AS_HELP_STRING([--disable-gles2],
 726         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 727     [enable_gles2="$enableval"],
 728     [enable_gles2=yes])
 729
 730 AC_ARG_ENABLE([dri],
 731     [AS_HELP_STRING([--enable-dri],
 732         [enable DRI modules @<:@default=enabled@:>@])],
 733     [enable_dri="$enableval"],
 734     [enable_dri=yes])
 735
 736 case "$host_os" in
 737 linux*)
 738     dri3_default=yes
 739     ;;
 740 *)
 741     dri3_default=no
 742     ;;
 743 esac
 744 AC_ARG_ENABLE([dri3],
 745     [AS_HELP_STRING([--enable-dri3],
 746         [enable DRI3 @<:@default=auto@:>@])],
 747     [enable_dri3="$enableval"],
 748     [enable_dri3="$dri3_default"])
 749 AC_ARG_ENABLE([glx],
 750     [AS_HELP_STRING([--enable-glx],
 751         [enable GLX library @<:@default=enabled@:>@])],
 752     [enable_glx="$enableval"],
 753     [enable_glx=yes])
 754 AC_ARG_ENABLE([osmesa],
 755     [AS_HELP_STRING([--enable-osmesa],
 756         [enable OSMesa library @<:@default=disabled@:>@])],
 757     [enable_osmesa="$enableval"],
 758     [enable_osmesa=no])
 759 AC_ARG_ENABLE([gallium-osmesa],
 760     [AS_HELP_STRING([--enable-gallium-osmesa],
 761         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 762     [enable_gallium_osmesa="$enableval"],
 763     [enable_gallium_osmesa=no])
 764 AC_ARG_ENABLE([egl],
 765     [AS_HELP_STRING([--disable-egl],
 766         [disable EGL library @<:@default=enabled@:>@])],
 767     [enable_egl="$enableval"],
 768     [enable_egl=yes])
 769
 770 AC_ARG_ENABLE([xa],
 771     [AS_HELP_STRING([--enable-xa],
 772         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 773     [enable_xa="$enableval"],
 774     [enable_xa=no])
 775 AC_ARG_ENABLE([gbm],
 776    [AS_HELP_STRING([--enable-gbm],
 777          [enable gbm library @<:@default=auto@:>@])],
 778    [enable_gbm="$enableval"],
 779    [enable_gbm=auto])
 780 AC_ARG_ENABLE([nine],
 781     [AS_HELP_STRING([--enable-nine],
 782         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 783     [enable_nine="$enableval"],
 784     [enable_nine=no])
 785
 786 AC_ARG_ENABLE([xvmc],
 787    [AS_HELP_STRING([--enable-xvmc],
 788          [enable xvmc library @<:@default=auto@:>@])],
 789    [enable_xvmc="$enableval"],
 790    [enable_xvmc=auto])
 791 AC_ARG_ENABLE([vdpau],
 792    [AS_HELP_STRING([--enable-vdpau],
 793          [enable vdpau library @<:@default=auto@:>@])],
 794    [enable_vdpau="$enableval"],
 795    [enable_vdpau=auto])
 796 AC_ARG_ENABLE([omx],
 797    [AS_HELP_STRING([--enable-omx],
 798          [enable OpenMAX library @<:@default=disabled@:>@])],
 799    [enable_omx="$enableval"],
 800    [enable_omx=no])
 801 AC_ARG_ENABLE([va],
 802    [AS_HELP_STRING([--enable-va],
 803          [enable va library @<:@default=auto@:>@])],
 804    [enable_va="$enableval"],
 805    [enable_va=auto])
 806 AC_ARG_ENABLE([opencl],
 807    [AS_HELP_STRING([--enable-opencl],
 808          [enable OpenCL library @<:@default=disabled@:>@])],
 809    [enable_opencl="$enableval"],
 810    [enable_opencl=no])
 811 AC_ARG_ENABLE([opencl_icd],
 812    [AS_HELP_STRING([--enable-opencl-icd],
 813           [Build an OpenCL ICD library to be loaded by an ICD implementation
 814            @<:@default=disabled@:>@])],
 815     [enable_opencl_icd="$enableval"],
 816     [enable_opencl_icd=no])
 817 AC_ARG_ENABLE([xlib-glx],
 818     [AS_HELP_STRING([--enable-xlib-glx],
 819         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 820     [enable_xlib_glx="$enableval"],
 821     [enable_xlib_glx=no])
 822
 823 AC_ARG_ENABLE([r600-llvm-compiler],
 824     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 825         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 826     [enable_r600_llvm="$enableval"],
 827     [enable_r600_llvm=no])
 828
 829 AC_ARG_ENABLE([gallium-tests],
 830     [AS_HELP_STRING([--enable-gallium-tests],
 831         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 832     [enable_gallium_tests="$enableval"],
 833     [enable_gallium_tests=no])
 834
 835 # Option for Gallium drivers
 836
 837 # Keep this in sync with the --with-gallium-drivers help string default value
 838 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 839
 840 AC_ARG_WITH([gallium-drivers],
 841     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 842         [comma delimited Gallium drivers list, e.g.
 843         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 844         @<:@default=r300,r600,svga,swrast@:>@])],
 845     [with_gallium_drivers="$withval"],
 846     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 847
 848 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 849 # here so that the script doesn't choke on an unknown driver name later.
 850 case "$with_gallium_drivers" in
 851     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 852     no) with_gallium_drivers='' ;;
 853 esac
 854
 855 if test "x$enable_opengl" = xno -a \
 856         "x$enable_gles1" = xno -a \
 857         "x$enable_gles2" = xno -a \
 858         "x$enable_nine" = xno -a \
 859         "x$enable_xa" = xno -a \
 860         "x$enable_xvmc" = xno -a \
 861         "x$enable_vdpau" = xno -a \
 862         "x$enable_omx" = xno -a \
 863         "x$enable_va" = xno -a \
 864         "x$enable_opencl" = xno; then
 865     AC_MSG_ERROR([at least one API should be enabled])
 866 fi
 867
 868 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 869 if test "x$enable_opengl" = xno -a \
 870         "x$enable_gles1" = xyes; then
 871     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 872 fi
 873
 874 if test "x$enable_opengl" = xno -a \
 875         "x$enable_gles2" = xyes; then
 876     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 877 fi
 878
 879 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 880 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 881 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 882 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 883                                         "x$enable_gles1" = xyes -o \
 884                                         "x$enable_gles2" = xyes)
 885
 886 if test "x$enable_glx" = xno; then
 887     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 888     enable_xlib_glx=no
 889 fi
 890
 891 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 892     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 893 fi
 894
 895 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 896     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 897 fi
 898
 899 # Disable GLX if OpenGL is not enabled
 900 if test "x$enable_glx$enable_opengl" = xyesno; then
 901     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 902     enable_glx=no
 903 fi
 904
 905 # Disable GLX if DRI and Xlib-GLX are not enabled
 906 if test "x$enable_glx" = xyes -a \
 907         "x$enable_dri" = xno -a \
 908         "x$enable_xlib_glx" = xno; then
 909     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 910     enable_glx=no
 911 fi
 912
 913 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 914                                   "x$enable_dri" = xyes)
 915
 916 # Check for libdrm
 917 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 918                   [have_libdrm=yes], [have_libdrm=no])
 919 if test "x$have_libdrm" = xyes; then
 920         DEFINES="$DEFINES -DHAVE_LIBDRM"
 921 fi
 922
 923 # Select which platform-dependent DRI code gets built
 924 case "$host_os" in
 925 darwin*)
 926     dri_platform='apple' ;;
 927 gnu*|cygwin*)
 928     dri_platform='none' ;;
 929 *)
 930     dri_platform='drm' ;;
 931 esac
 932
 933 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 934 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 935 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 936 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 937 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 938
 939 AC_ARG_ENABLE([shared-glapi],
 940     [AS_HELP_STRING([--enable-shared-glapi],
 941         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 942     [enable_shared_glapi="$enableval"],
 943     [enable_shared_glapi=yes])
 944
 945 case "x$enable_opengl$enable_gles1$enable_gles2" in
 946 x*yes*yes*)
 947     if test "x$enable_shared_glapi" = xno; then
 948         AC_MSG_ERROR([shared GLAPI required when building two or more of
 949                       the following APIs - opengl, gles1 gles2])
 950     fi
 951     ;;
 952 esac
 953
 954 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 955
 956 # Build the pipe-drivers as separate libraries/modules.
 957 # Do not touch this unless you know what you are doing.
 958 # XXX: Expose via configure option ?
 959 enable_shared_pipe_drivers=no
 960
 961 dnl
 962 dnl Driver specific build directories
 963 dnl
 964
 965 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 966     NEED_WINSYS_XLIB="yes"
 967 fi
 968
 969 if test "x$enable_dri" = xyes; then
 970     enable_gallium_loader="$enable_shared_pipe_drivers"
 971 fi
 972
 973 if test "x$enable_gallium_osmesa" = xyes; then
 974     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 975         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 976     fi
 977     if test "x$enable_osmesa" = xyes; then
 978         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 979     fi
 980 fi
 981
 982 AC_SUBST([MESA_LLVM])
 983
 984 # SHA1 hashing
 985 AC_ARG_WITH([sha1],
 986         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 987         [choose SHA1 implementation])])
 988 case "x$with_sha1" in
 989 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 990   ;;
 991 *)
 992         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 993 esac
 994
 995 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 996 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 997         with_sha1=libc
 998 fi
 999 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1000         AC_MSG_ERROR([sha1 in libc requested but not found])
1001 fi
1002 if test "x$with_sha1" = xlibc; then
1003         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1004                 [Use libc SHA1 functions])
1005         SHA1_LIBS=""
1006 fi
1007 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1008 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1009         with_sha1=CommonCrypto
1010 fi
1011 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1012         AC_MSG_ERROR([CommonCrypto requested but not found])
1013 fi
1014 if test "x$with_sha1" = xCommonCrypto; then
1015         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1016                 [Use CommonCrypto SHA1 functions])
1017         SHA1_LIBS=""
1018 fi
1019 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1020 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1021 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1022         with_sha1=CryptoAPI
1023 fi
1024 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1025         AC_MSG_ERROR([CryptoAPI requested but not found])
1026 fi
1027 if test "x$with_sha1" = xCryptoAPI; then
1028         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1029                 [Use CryptoAPI SHA1 functions])
1030         SHA1_LIBS=""
1031 fi
1032 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1033 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1034         with_sha1=libmd
1035 fi
1036 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1037         AC_MSG_ERROR([libmd requested but not found])
1038 fi
1039 if test "x$with_sha1" = xlibmd; then
1040         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1041                   [Use libmd SHA1 functions])
1042         SHA1_LIBS=-lmd
1043 fi
1044 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1045 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1046    with_sha1=libsha1
1047 fi
1048 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1049         AC_MSG_ERROR([libsha1 requested but not found])
1050 fi
1051 if test "x$with_sha1" = xlibsha1; then
1052         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1053                   [Use libsha1 for SHA1])
1054         SHA1_LIBS=-lsha1
1055 fi
1056 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1057 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1058         with_sha1=libnettle
1059 fi
1060 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1061         AC_MSG_ERROR([libnettle requested but not found])
1062 fi
1063 if test "x$with_sha1" = xlibnettle; then
1064         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1065                   [Use libnettle SHA1 functions])
1066         SHA1_LIBS=-lnettle
1067 fi
1068 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1069 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1070         with_sha1=libgcrypt
1071 fi
1072 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1073         AC_MSG_ERROR([libgcrypt requested but not found])
1074 fi
1075 if test "x$with_sha1" = xlibgcrypt; then
1076         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1077                   [Use libgcrypt SHA1 functions])
1078         SHA1_LIBS=-lgcrypt
1079 fi
1080 # We don't need all of the OpenSSL libraries, just libcrypto
1081 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1082 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1083                   [HAVE_OPENSSL_PKC=no])
1084 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1085         if test "x$with_sha1" = x; then
1086                 with_sha1=libcrypto
1087         fi
1088 else
1089         if test "x$with_sha1" = xlibcrypto; then
1090                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1091         fi
1092 fi
1093 if test "x$with_sha1" = xlibcrypto; then
1094         if test "x$HAVE_LIBCRYPTO" = xyes; then
1095                 SHA1_LIBS=-lcrypto
1096         else
1097                 SHA1_LIBS="$OPENSSL_LIBS"
1098                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1099         fi
1100 fi
1101 AC_MSG_CHECKING([for SHA1 implementation])
1102 AC_MSG_RESULT([$with_sha1])
1103 AC_SUBST(SHA1_LIBS)
1104 AC_SUBST(SHA1_CFLAGS)
1105
1106 # Allow user to configure out the shader-cache feature
1107 AC_ARG_ENABLE([shader-cache],
1108     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1109     [enable_shader_cache="$enableval"],
1110     [if test "x$with_sha1" != "x"; then
1111         enable_shader_cache=yes
1112      else
1113         enable_shader_cache=no
1114      fi])
1115 if test "x$with_sha1" = "x"; then
1116     if test "x$enable_shader_cache" = "xyes"; then
1117         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1118     fi
1119 fi
1120 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1121
1122 case "$host_os" in
1123 linux*)
1124     need_pci_id=yes ;;
1125 *)
1126     need_pci_id=no ;;
1127 esac
1128
1129 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1130                   have_libudev=yes, have_libudev=no)
1131
1132 AC_ARG_ENABLE([sysfs],
1133     [AS_HELP_STRING([--enable-sysfs],
1134         [enable /sys PCI identification @<:@default=disabled@:>@])],
1135     [have_sysfs="$enableval"],
1136     [have_sysfs=no]
1137 )
1138
1139 if test "x$enable_dri" = xyes; then
1140     if test "$enable_static" = yes; then
1141         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1142     fi
1143
1144     # not a hard requirement as swrast does not depend on it
1145     if test "x$have_libdrm" = xyes; then
1146         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1147     fi
1148 fi
1149
1150 AC_ARG_ENABLE([driglx-direct],
1151     [AS_HELP_STRING([--disable-driglx-direct],
1152         [disable direct rendering in GLX and EGL for DRI \
1153             @<:@default=auto@:>@])],
1154     [driglx_direct="$enableval"],
1155     [driglx_direct="yes"])
1156
1157 dnl
1158 dnl libGL configuration per driver
1159 dnl
1160 case "x$enable_glx$enable_xlib_glx" in
1161 xyesyes)
1162     # Xlib-based GLX
1163     dri_modules="x11 xext xcb"
1164     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1165     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1166     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1167     GL_LIB_DEPS="$XLIBGL_LIBS"
1168     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1169     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1170     ;;
1171 xyesno)
1172     # DRI-based GLX
1173     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1174
1175     # find the DRI deps for libGL
1176     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1177
1178     if test x"$driglx_direct" = xyes; then
1179         if test x"$dri_platform" = xdrm ; then
1180             DEFINES="$DEFINES -DGLX_USE_DRM"
1181             if test "x$have_libdrm" != xyes; then
1182                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1183             fi
1184
1185             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1186             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1187             if test x"$enable_dri3" = xyes; then
1188                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1189                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1190             fi
1191
1192             if test x"$enable_dri" = xyes; then
1193                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1194             fi
1195
1196             if test x"$enable_dri3" = xyes; then
1197                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1198                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1199             fi
1200         fi
1201         if test x"$dri_platform" = xapple ; then
1202             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1203         fi
1204     fi
1205
1206     # add xf86vidmode if available
1207     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1208     if test "$HAVE_XF86VIDMODE" = yes ; then
1209         dri_modules="$dri_modules xxf86vm"
1210     fi
1211
1212     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1213     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1214     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1215     GL_LIB_DEPS="$DRIGL_LIBS"
1216
1217     # need DRM libs, $PTHREAD_LIBS, etc.
1218     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1219     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1220     ;;
1221 esac
1222
1223 have_pci_id=no
1224 if test "$have_libudev" = yes; then
1225     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1226     have_pci_id=yes
1227 fi
1228
1229 if test "$have_sysfs" = yes; then
1230     DEFINES="$DEFINES -DHAVE_SYSFS"
1231     have_pci_id=yes
1232 fi
1233
1234 # This is outside the case (above) so that it is invoked even for non-GLX
1235 # builds.
1236 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1237
1238 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1239 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1240 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1241 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1242
1243 AC_SUBST([X11_INCLUDES])
1244 AC_SUBST([GL_LIB_DEPS])
1245 AC_SUBST([GL_PC_REQ_PRIV])
1246 AC_SUBST([GL_PC_LIB_PRIV])
1247 AC_SUBST([GL_PC_CFLAGS])
1248 AC_SUBST([DRI_PC_REQ_PRIV])
1249 AC_SUBST([GLESv1_CM_LIB_DEPS])
1250 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1251 AC_SUBST([GLESv2_LIB_DEPS])
1252 AC_SUBST([GLESv2_PC_LIB_PRIV])
1253
1254 AC_SUBST([HAVE_XF86VIDMODE])
1255
1256 dnl
1257 dnl More GLX setup
1258 dnl
1259 case "x$enable_glx$enable_xlib_glx" in
1260 xyesyes)
1261     DEFINES="$DEFINES -DUSE_XSHM"
1262     ;;
1263 xyesno)
1264     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1265     if test "x$driglx_direct" = xyes; then
1266         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1267     fi
1268     ;;
1269 esac
1270
1271 dnl
1272 dnl TLS detection
1273 dnl
1274
1275 AC_ARG_ENABLE([glx-tls],
1276     [AS_HELP_STRING([--enable-glx-tls],
1277         [enable TLS support in GLX @<:@default=disabled@:>@])],
1278     [GLX_USE_TLS="$enableval"],
1279     [GLX_USE_TLS=no])
1280 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1281
1282 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1283       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1284
1285 dnl
1286 dnl More DRI setup
1287 dnl
1288 dnl Directory for DRI drivers
1289 AC_ARG_WITH([dri-driverdir],
1290     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1291         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1292     [DRI_DRIVER_INSTALL_DIR="$withval"],
1293     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1294 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1295 dnl Extra search path for DRI drivers
1296 AC_ARG_WITH([dri-searchpath],
1297     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1298         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1299     [DRI_DRIVER_SEARCH_DIR="$withval"],
1300     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1301 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1302 dnl Which drivers to build - default is chosen by platform
1303 AC_ARG_WITH([dri-drivers],
1304     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1305         [comma delimited classic DRI drivers list, e.g.
1306         "swrast,i965,radeon" @<:@default=auto@:>@])],
1307     [with_dri_drivers="$withval"],
1308     [with_dri_drivers=auto])
1309
1310 if test "x$with_dri_drivers" = xauto; then
1311     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1312         with_dri_drivers="yes"
1313     else
1314         with_dri_drivers="no"
1315     fi
1316 fi
1317 if test "x$with_dri_drivers" = xno; then
1318     with_dri_drivers=''
1319 fi
1320
1321 dnl If $with_dri_drivers is yes, drivers will be added through
1322 dnl platform checks. Set DEFINES and LIB_DEPS
1323 if test "x$enable_dri" = xyes; then
1324     # Platform specific settings and drivers to build
1325     case "$host_os" in
1326     linux*)
1327         DEFINES="$DEFINES -DHAVE_ALIAS"
1328         if test "x$enable_dri3" = xyes; then
1329             DEFINES="$DEFINES -DHAVE_DRI3"
1330         fi
1331
1332         if test "x$have_pci_id" != xyes; then
1333             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1334         fi
1335
1336         case "$host_cpu" in
1337         powerpc* | sparc*)
1338             # Build only the drivers for cards that exist on PowerPC/sparc
1339             if test "x$with_dri_drivers" = "xyes"; then
1340                 with_dri_drivers="r200 radeon swrast"
1341             fi
1342             ;;
1343         esac
1344         ;;
1345     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1346         DEFINES="$DEFINES -DHAVE_ALIAS"
1347         ;;
1348     gnu*)
1349         DEFINES="$DEFINES -DHAVE_ALIAS"
1350         ;;
1351     cygwin*)
1352         if test "x$with_dri_drivers" = "xyes"; then
1353             with_dri_drivers="swrast"
1354         fi
1355         ;;
1356     darwin*)
1357         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1358         if test "x$with_dri_drivers" = "xyes"; then
1359             with_dri_drivers="swrast"
1360         fi
1361         ;;
1362     esac
1363
1364     # default drivers
1365     if test "x$with_dri_drivers" = "xyes"; then
1366         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1367     fi
1368
1369     # Check for expat
1370     PKG_CHECK_MODULES([EXPAT], [expat], [],
1371         # expat version 2.0 and earlier do not provide expat.pc
1372         [AC_CHECK_HEADER([expat.h],[],
1373                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1374          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1375                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1376          EXPAT_LIBS="-lexpat"])
1377
1378     # put all the necessary libs together
1379     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1380 fi
1381
1382 AC_SUBST([DRI_LIB_DEPS])
1383
1384 DRI_DIRS=''
1385 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1386 if test -n "$with_dri_drivers"; then
1387     if test "x$enable_opengl" != xyes; then
1388         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1389     fi
1390
1391     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1392     for driver in $dri_drivers; do
1393         DRI_DIRS="$DRI_DIRS $driver"
1394         case "x$driver" in
1395         xi915)
1396             HAVE_I915_DRI=yes;
1397             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1398             ;;
1399         xi965)
1400             HAVE_I965_DRI=yes;
1401             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1402             ;;
1403         xnouveau)
1404             HAVE_NOUVEAU_DRI=yes;
1405             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1406             ;;
1407         xradeon)
1408             HAVE_RADEON_DRI=yes;
1409             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1410             ;;
1411         xr200)
1412             HAVE_R200_DRI=yes;
1413             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1414             ;;
1415         xswrast)
1416             HAVE_SWRAST_DRI=yes;
1417             ;;
1418         *)
1419             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1420             ;;
1421         esac
1422     done
1423     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1424 fi
1425
1426 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1427 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1428                                   "x$enable_osmesa" = xyes -o \
1429                                   -n "$DRI_DIRS")
1430
1431 dnl
1432 dnl OSMesa configuration
1433 dnl
1434
1435 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1436 AC_ARG_WITH([osmesa-bits],
1437     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1438         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1439     [osmesa_bits="$withval"],
1440     [osmesa_bits=8])
1441 if test "x$osmesa_bits" != x8; then
1442     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1443         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1444         osmesa_bits=8
1445     fi
1446 fi
1447 case "x$osmesa_bits" in
1448 x8)
1449     OSMESA_LIB="${OSMESA_LIB}"
1450     ;;
1451 x16|x32)
1452     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1453     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1454     ;;
1455 *)
1456     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1457     ;;
1458 esac
1459
1460 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1461     # only link libraries with osmesa if shared
1462     if test "$enable_static" = no; then
1463         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1464     else
1465         OSMESA_LIB_DEPS=""
1466     fi
1467     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1468 fi
1469
1470 AC_SUBST([OSMESA_LIB_DEPS])
1471 AC_SUBST([OSMESA_PC_REQ])
1472 AC_SUBST([OSMESA_PC_LIB_PRIV])
1473
1474 dnl
1475 dnl gbm configuration
1476 dnl
1477 if test "x$enable_gbm" = xauto; then
1478     case "$with_egl_platforms" in
1479         *drm*)
1480             enable_gbm=yes ;;
1481          *)
1482             enable_gbm=no ;;
1483     esac
1484 fi
1485 if test "x$enable_gbm" = xyes; then
1486     if test "x$need_pci_id$have_pci_id" = xyesno; then
1487         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1488     fi
1489
1490     if test "x$enable_dri" = xyes; then
1491         if test "x$enable_shared_glapi" = xno; then
1492             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1493         fi
1494     else
1495         # Strictly speaking libgbm does not require --enable-dri, although
1496         # both of its backends do. Thus one can build libgbm without any
1497         # backends if --disable-dri is set.
1498         # To avoid unnecessary complexity of checking if at least one backend
1499         # is available when building, just mandate --enable-dri.
1500         AC_MSG_ERROR([gbm requires --enable-dri])
1501     fi
1502 fi
1503 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1504 if test "x$need_pci_id$have_libudev" = xyesyes; then
1505     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1506 else
1507     GBM_PC_REQ_PRIV=""
1508 fi
1509 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1510 AC_SUBST([GBM_PC_REQ_PRIV])
1511 AC_SUBST([GBM_PC_LIB_PRIV])
1512
1513 dnl
1514 dnl EGL configuration
1515 dnl
1516 EGL_CLIENT_APIS=""
1517
1518 if test "x$enable_egl" = xyes; then
1519     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1520
1521     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1522
1523     if test "$enable_static" != yes; then
1524         if test "x$enable_dri" = xyes; then
1525             HAVE_EGL_DRIVER_DRI2=1
1526             if test "x$enable_shared_glapi" = xno; then
1527                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1528             fi
1529         else
1530             # Avoid building an "empty" libEGL. Drop/update this
1531             # when other backends (haiku?) come along.
1532             AC_MSG_ERROR([egl requires --enable-dri])
1533         fi
1534
1535     fi
1536 fi
1537 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1538 AC_SUBST([EGL_LIB_DEPS])
1539
1540 dnl
1541 dnl XA configuration
1542 dnl
1543 if test "x$enable_xa" = xyes; then
1544     if test "x$with_gallium_drivers" = xswrast; then
1545        AC_MSG_ERROR([
1546           Building xa requires at least one non swrast gallium driver.
1547           If you are looking to use libxatracker.so with the VMware driver,
1548           make sure to include svga in the gallium drivers list, apart from
1549           enabling XA.
1550           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1551     fi
1552     enable_gallium_loader=$enable_shared_pipe_drivers
1553 fi
1554 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1555
1556 dnl
1557 dnl Gallium G3DVL configuration
1558 dnl
1559 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1560     if test "x$enable_xvmc" = xauto; then
1561         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1562     fi
1563
1564     if test "x$enable_vdpau" = xauto; then
1565         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1566     fi
1567
1568     if test "x$enable_omx" = xauto; then
1569         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1570     fi
1571
1572     if test "x$enable_va" = xauto; then
1573         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1574     fi
1575 fi
1576
1577 if test "x$enable_dri" = xyes -o \
1578         "x$enable_xvmc" = xyes -o \
1579         "x$enable_vdpau" = xyes -o \
1580         "x$enable_omx" = xyes -o \
1581         "x$enable_va" = xyes; then
1582     need_gallium_vl=yes
1583 fi
1584 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1585
1586 if test "x$enable_xvmc" = xyes -o \
1587         "x$enable_vdpau" = xyes -o \
1588         "x$enable_omx" = xyes -o \
1589         "x$enable_va" = xyes; then
1590     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1591     need_gallium_vl_winsys=yes
1592 fi
1593 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1594
1595 if test "x$enable_xvmc" = xyes; then
1596     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1597     enable_gallium_loader=$enable_shared_pipe_drivers
1598 fi
1599 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1600
1601 if test "x$enable_vdpau" = xyes; then
1602     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1603     enable_gallium_loader=$enable_shared_pipe_drivers
1604 fi
1605 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1606
1607 if test "x$enable_omx" = xyes; then
1608     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1609     enable_gallium_loader=$enable_shared_pipe_drivers
1610 fi
1611 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1612
1613 if test "x$enable_va" = xyes; then
1614     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1615     enable_gallium_loader=$enable_shared_pipe_drivers
1616 fi
1617 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1618
1619 dnl
1620 dnl Nine Direct3D9 configuration
1621 dnl
1622 if test "x$enable_nine" = xyes; then
1623     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1624         AC_MSG_ERROR([nine requires the gallium swrast driver])
1625     fi
1626     if test "x$with_gallium_drivers" = xswrast; then
1627         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1628     fi
1629     if test "x$enable_dri3" = xno; then
1630         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1631     fi
1632
1633     enable_gallium_loader=$enable_shared_pipe_drivers
1634 fi
1635 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1636
1637 dnl
1638 dnl OpenCL configuration
1639 dnl
1640
1641 AC_ARG_WITH([clang-libdir],
1642    [AS_HELP_STRING([--with-clang-libdir],
1643          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1644    [CLANG_LIBDIR="$withval"],
1645    [CLANG_LIBDIR=''])
1646
1647 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1648 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1649
1650 if test "x$enable_opencl" = xyes; then
1651     if test -z "$with_gallium_drivers"; then
1652         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1653     fi
1654
1655     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1656         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1657     fi
1658
1659     if test "x$have_libclc" = xno; then
1660         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1661                     Make sure the directory containing libclc.pc is specified in your
1662                     PKG_CONFIG_PATH environment variable.
1663                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1664     else
1665         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1666         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1667         AC_SUBST([LIBCLC_INCLUDEDIR])
1668         AC_SUBST([LIBCLC_LIBEXECDIR])
1669     fi
1670
1671     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1672     enable_gallium_loader=yes
1673
1674     if test "x$enable_opencl_icd" = xyes; then
1675         OPENCL_LIBNAME="MesaOpenCL"
1676     else
1677         OPENCL_LIBNAME="OpenCL"
1678     fi
1679
1680     if test "x$have_libelf" != xyes; then
1681        AC_MSG_ERROR([Clover requires libelf])
1682     fi
1683 fi
1684 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1685 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1686 AC_SUBST([OPENCL_LIBNAME])
1687
1688 dnl
1689 dnl Gallium configuration
1690 dnl
1691 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1692
1693 AC_SUBST([LLVM_BINDIR])
1694 AC_SUBST([LLVM_CFLAGS])
1695 AC_SUBST([LLVM_CPPFLAGS])
1696 AC_SUBST([LLVM_CXXFLAGS])
1697 AC_SUBST([LLVM_LIBDIR])
1698 AC_SUBST([LLVM_LIBS])
1699 AC_SUBST([LLVM_LDFLAGS])
1700 AC_SUBST([LLVM_INCLUDEDIR])
1701 AC_SUBST([LLVM_VERSION])
1702 AC_SUBST([CLANG_RESOURCE_DIR])
1703
1704 case "x$enable_opengl$enable_gles1$enable_gles2" in
1705 x*yes*)
1706     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1707     ;;
1708 esac
1709
1710 AC_SUBST([VG_LIB_DEPS])
1711 AC_SUBST([EGL_CLIENT_APIS])
1712
1713 dnl
1714 dnl EGL Platforms configuration
1715 dnl
1716 AC_ARG_WITH([egl-platforms],
1717     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1718         [comma delimited native platforms libEGL supports, e.g.
1719         "x11,drm" @<:@default=auto@:>@])],
1720     [with_egl_platforms="$withval"],
1721     [if test "x$enable_egl" = xyes; then
1722         with_egl_platforms="x11"
1723     else
1724         with_egl_platforms=""
1725     fi])
1726
1727 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1728     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1729 fi
1730
1731 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1732         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1733         WAYLAND_SCANNER='')
1734 if test "x$WAYLAND_SCANNER" = x; then
1735     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1736 fi
1737
1738 # Do per-EGL platform setups and checks
1739 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1740 for plat in $egl_platforms; do
1741         case "$plat" in
1742         wayland)
1743                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1744
1745                 if test "x$WAYLAND_SCANNER" = x; then
1746                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1747                 fi
1748                 ;;
1749
1750         x11)
1751                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1752                 ;;
1753
1754         drm)
1755                 test "x$enable_gbm" = "xno" &&
1756                         AC_MSG_ERROR([EGL platform drm needs gbm])
1757                 test "x$have_libdrm" != xyes &&
1758                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1759                 ;;
1760
1761         surfaceless)
1762                 test "x$have_libdrm" != xyes &&
1763                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1764                 ;;
1765
1766         android|gdi|null)
1767                 ;;
1768
1769         *)
1770                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1771                 ;;
1772         esac
1773
1774         case "$plat$need_pci_id$have_pci_id" in
1775                 waylandyesno|drmyesno)
1776                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1777         esac
1778 done
1779
1780 # libEGL wants to default to the first platform specified in
1781 # ./configure.  parse that here.
1782 if test "x$egl_platforms" != "x"; then
1783     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1784     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1785 else
1786     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1787 fi
1788
1789 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1790 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1791 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1792 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1793 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1794
1795 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1796
1797 AC_SUBST([EGL_NATIVE_PLATFORM])
1798 AC_SUBST([EGL_CFLAGS])
1799
1800 # If we don't have the X11 platform, set this define so we don't try to include
1801 # the X11 headers.
1802 if ! echo "$egl_platforms" | grep -q 'x11'; then
1803     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1804     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1805 fi
1806
1807 dnl
1808 dnl Gallium LLVM
1809 dnl
1810 AC_ARG_ENABLE([gallium-llvm],
1811     [AS_HELP_STRING([--enable-gallium-llvm],
1812         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1813     [enable_gallium_llvm="$enableval"],
1814     [enable_gallium_llvm=auto])
1815
1816 AC_ARG_ENABLE([llvm-shared-libs],
1817     [AS_HELP_STRING([--enable-llvm-shared-libs],
1818         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1819     [enable_llvm_shared_libs="$enableval"],
1820     [enable_llvm_shared_libs=yes])
1821
1822 AC_ARG_WITH([llvm-prefix],
1823     [AS_HELP_STRING([--with-llvm-prefix],
1824         [Prefix for LLVM installations in non-standard locations])],
1825     [llvm_prefix="$withval"],
1826     [llvm_prefix=''])
1827
1828
1829 # Call this inside ` ` to get the return value.
1830 # $1 is the llvm-config command with arguments.
1831 strip_unwanted_llvm_flags() {
1832     # Use \> (marks the end of the word)
1833     echo `$1` | sed \
1834         -e 's/-DNDEBUG\>//g' \
1835         -e 's/-D_GNU_SOURCE\>//g' \
1836         -e 's/-pedantic\>//g' \
1837         -e 's/-Wcovered-switch-default\>//g' \
1838         -e 's/-O.\>//g' \
1839         -e 's/-g\>//g' \
1840         -e 's/-Wall\>//g' \
1841         -e 's/-Wcast-qual\>//g' \
1842         -e 's/-Woverloaded-virtual\>//g' \
1843         -e 's/-fcolor-diagnostics\>//g' \
1844         -e 's/-fdata-sections\>//g' \
1845         -e 's/-ffunction-sections\>//g' \
1846         -e 's/-fno-exceptions\>//g' \
1847         -e 's/-fomit-frame-pointer\>//g' \
1848         -e 's/-fvisibility-inlines-hidden\>//g' \
1849         -e 's/-fPIC\>//g' \
1850         -e 's/-fstack-protector-strong\>//g'
1851 }
1852
1853 llvm_check_version_for() {
1854     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1855         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1856     fi
1857 }
1858
1859
1860
1861 if test -z "$with_gallium_drivers"; then
1862     enable_gallium_llvm=no
1863 fi
1864 if test "x$enable_gallium_llvm" = xauto; then
1865     case "$host_cpu" in
1866     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1867     esac
1868 fi
1869 if test "x$enable_gallium_llvm" = xyes; then
1870     if test -n "$llvm_prefix"; then
1871         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1872     else
1873         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1874     fi
1875
1876     if test "x$LLVM_CONFIG" != xno; then
1877         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1878         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1879         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1880         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1881         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1882         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1883         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1884         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1885
1886         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1887             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1888         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1889             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1890
1891         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1892         if test -z "$LLVM_VERSION_PATCH"; then
1893             LLVM_VERSION_PATCH=0
1894         fi
1895
1896         if test -n "${LLVM_VERSION_MAJOR}"; then
1897             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1898         else
1899             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1900         fi
1901
1902         LLVM_REQUIRED_VERSION_MAJOR="3"
1903         LLVM_REQUIRED_VERSION_MINOR="3"
1904         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1905             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1906         fi
1907
1908         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1909
1910         if test "x$enable_opencl" = xyes; then
1911             llvm_check_version_for "3" "5" "0" "opencl"
1912
1913             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1914             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1915         fi
1916         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1917         MESA_LLVM=1
1918
1919         dnl Check for Clang internal headers
1920         if test "x$enable_opencl" = xyes; then
1921             if test -z "$CLANG_LIBDIR"; then
1922                 CLANG_LIBDIR=${LLVM_LIBDIR}
1923             fi
1924             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1925             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1926                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1927         fi
1928     else
1929         MESA_LLVM=0
1930         LLVM_VERSION_INT=0
1931     fi
1932 else
1933     MESA_LLVM=0
1934     LLVM_VERSION_INT=0
1935
1936     if test "x$enable_opencl" = xyes; then
1937         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1938     fi
1939 fi
1940
1941 dnl Directory for XVMC libs
1942 AC_ARG_WITH([xvmc-libdir],
1943     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1944         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1945     [XVMC_LIB_INSTALL_DIR="$withval"],
1946     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1947 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1948
1949 dnl
1950 dnl Gallium Tests
1951 dnl
1952 if test "x$enable_gallium_tests" = xyes; then
1953     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1954     enable_gallium_loader=yes
1955 fi
1956 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1957
1958 dnl Directory for VDPAU libs
1959 AC_ARG_WITH([vdpau-libdir],
1960     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1961         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1962     [VDPAU_LIB_INSTALL_DIR="$withval"],
1963     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1964 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1965
1966 dnl Directory for OMX libs
1967
1968 AC_ARG_WITH([omx-libdir],
1969     [AS_HELP_STRING([--with-omx-libdir=DIR],
1970         [directory for the OMX libraries])],
1971     [OMX_LIB_INSTALL_DIR="$withval"],
1972     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1973 AC_SUBST([OMX_LIB_INSTALL_DIR])
1974
1975 dnl Directory for VA libs
1976
1977 AC_ARG_WITH([va-libdir],
1978     [AS_HELP_STRING([--with-va-libdir=DIR],
1979         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1980     [VA_LIB_INSTALL_DIR="$withval"],
1981     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1982 AC_SUBST([VA_LIB_INSTALL_DIR])
1983
1984 AC_ARG_WITH([d3d-libdir],
1985     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1986         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1987     [D3D_DRIVER_INSTALL_DIR="$withval"],
1988     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1989 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1990
1991 dnl
1992 dnl Gallium helper functions
1993 dnl
1994 gallium_require_drm() {
1995     if test "x$have_libdrm" != xyes; then
1996        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1997     fi
1998 }
1999
2000 gallium_require_llvm() {
2001     if test "x$MESA_LLVM" = x0; then
2002         case "$host" in *gnux32) return;; esac
2003         case "$host_cpu" in
2004         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2005         esac
2006     fi
2007 }
2008
2009 gallium_require_drm_loader() {
2010     if test "x$enable_gallium_loader" = xyes; then
2011         if test "x$need_pci_id$have_pci_id" = xyesno; then
2012             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2013         fi
2014         enable_gallium_drm_loader=yes
2015     fi
2016     if test "x$enable_va" = xyes && test "x$7" != x; then
2017          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2018     fi
2019 }
2020
2021 require_egl_drm() {
2022     case "$with_egl_platforms" in
2023         *drm*)
2024             ;;
2025          *)
2026             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2027             ;;
2028     esac
2029     if test "x$enable_gbm" != xyes; then
2030             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2031     fi
2032 }
2033
2034 radeon_llvm_check() {
2035     if test ${LLVM_VERSION_INT} -lt 307; then
2036         amdgpu_llvm_target_name='r600'
2037     else
2038         amdgpu_llvm_target_name='amdgpu'
2039     fi
2040     if test "x$enable_gallium_llvm" != "xyes"; then
2041         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2042     fi
2043     llvm_check_version_for "3" "4" "2" $1
2044     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2045         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2046     fi
2047     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2048     NEED_RADEON_LLVM=yes
2049     if test "x$have_libelf" != xyes; then
2050        AC_MSG_ERROR([$1 requires libelf when using llvm])
2051     fi
2052 }
2053
2054 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2055 if test -n "$with_gallium_drivers"; then
2056     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2057     for driver in $gallium_drivers; do
2058         case "x$driver" in
2059         xsvga)
2060             HAVE_GALLIUM_SVGA=yes
2061             gallium_require_drm "svga"
2062             gallium_require_drm_loader
2063             ;;
2064         xi915)
2065             HAVE_GALLIUM_I915=yes
2066             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2067             gallium_require_drm "Gallium i915"
2068             gallium_require_drm_loader
2069             ;;
2070         xilo)
2071             HAVE_GALLIUM_ILO=yes
2072             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2073             gallium_require_drm "Gallium i965/ilo"
2074             gallium_require_drm_loader
2075             ;;
2076         xr300)
2077             HAVE_GALLIUM_R300=yes
2078             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2079             gallium_require_drm "Gallium R300"
2080             gallium_require_drm_loader
2081             gallium_require_llvm "Gallium R300"
2082             ;;
2083         xr600)
2084             HAVE_GALLIUM_R600=yes
2085             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2086             gallium_require_drm "Gallium R600"
2087             gallium_require_drm_loader
2088             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2089                 radeon_llvm_check "r600g"
2090                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2091             fi
2092             if test "x$enable_r600_llvm" = xyes; then
2093                 USE_R600_LLVM_COMPILER=yes;
2094             fi
2095             if test "x$enable_opencl" = xyes; then
2096                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2097             fi
2098             ;;
2099         xradeonsi)
2100             HAVE_GALLIUM_RADEONSI=yes
2101             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2102             gallium_require_drm "radeonsi"
2103             gallium_require_drm_loader
2104             radeon_llvm_check "radeonsi"
2105             require_egl_drm "radeonsi"
2106             ;;
2107         xnouveau)
2108             HAVE_GALLIUM_NOUVEAU=yes
2109             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2110             gallium_require_drm "nouveau"
2111             gallium_require_drm_loader
2112             ;;
2113         xfreedreno)
2114             HAVE_GALLIUM_FREEDRENO=yes
2115             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2116             gallium_require_drm "freedreno"
2117             gallium_require_drm_loader
2118             ;;
2119         xswrast)
2120             HAVE_GALLIUM_SOFTPIPE=yes
2121             if test "x$MESA_LLVM" = x1; then
2122                 HAVE_GALLIUM_LLVMPIPE=yes
2123             fi
2124             ;;
2125         xvc4)
2126             HAVE_GALLIUM_VC4=yes
2127             gallium_require_drm "vc4"
2128             gallium_require_drm_loader
2129
2130             case "$host_cpu" in
2131                 i?86 | x86_64 | amd64)
2132                 USE_VC4_SIMULATOR=yes
2133                 ;;
2134             esac
2135             ;;
2136         *)
2137             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2138             ;;
2139         esac
2140     done
2141 fi
2142
2143 dnl Set LLVM_LIBS - This is done after the driver configuration so
2144 dnl that drivers can add additional components to LLVM_COMPONENTS.
2145 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2146 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2147 dnl this was causing the same libraries to be appear multiple times
2148 dnl in LLVM_LIBS.
2149
2150 if test "x$MESA_LLVM" != x0; then
2151
2152     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2153
2154     if test "x$enable_llvm_shared_libs" = xyes; then
2155         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2156         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2157         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2158
2159         if test "x$llvm_have_one_so" = xyes; then
2160             dnl LLVM was built using auto*, so there is only one shared object.
2161             LLVM_LIBS="-l$LLVM_SO_NAME"
2162         else
2163             dnl If LLVM was built with CMake, there will be one shared object per
2164             dnl component.
2165             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2166                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2167         Please make sure you have built llvm with the --enable-shared option
2168         and that your llvm libraries are installed in $LLVM_LIBDIR
2169         If you have installed your llvm libraries to a different directory you
2170         can use the --with-llvm-prefix= configure flag to specify this directory.
2171         NOTE: Mesa is attempting to use llvm shared libraries by default.
2172         If you do not want to build with llvm shared libraries and instead want to
2173         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2174         invocation and rebuild.])])
2175
2176            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2177            dnl install uses a shared object for each component and we have
2178            dnl already added all of these objects to LLVM_LIBS.
2179         fi
2180     else
2181         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2182         dnl We need to link to llvm system libs when using static libs
2183         dnl However, only llvm 3.5+ provides --system-libs
2184         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2185             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2186         fi
2187     fi
2188 fi
2189
2190 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2191 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2192 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2193 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2194 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2195 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2196 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2197                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2198 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2199 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2200 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2201 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2202 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2203
2204 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2205
2206 # NOTE: anything using xcb or other client side libs ends up in separate
2207 #       _CLIENT variables.  The pipe loader is built in two variants,
2208 #       one that is standalone and does not link any x client libs (for
2209 #       use by XA tracker in particular, but could be used in any case
2210 #       where communication with xserver is not desired).
2211 if test "x$enable_gallium_loader" = xyes; then
2212     if test "x$enable_dri" = xyes; then
2213         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2214     fi
2215
2216     if test "x$enable_gallium_drm_loader" = xyes; then
2217         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2218     fi
2219
2220     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2221 fi
2222
2223 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2224 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2225 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2226 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2227 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2228 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2229
2230 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2231                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2232                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2233 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2234 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2235 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2236 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2237 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2238 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2239 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2240 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2241 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2242     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2243 fi
2244
2245 AC_SUBST([ELF_LIB])
2246
2247 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2248 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2249 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2250 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2251
2252 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2253 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2254 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2255
2256 AC_SUBST([NINE_MAJOR], 1)
2257 AC_SUBST([NINE_MINOR], 0)
2258 AC_SUBST([NINE_TINY], 0)
2259 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2260
2261 AC_SUBST([VDPAU_MAJOR], 1)
2262 AC_SUBST([VDPAU_MINOR], 0)
2263
2264 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2265 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2266 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2267 AC_SUBST([VA_MINOR], $VA_MINOR)
2268
2269 AC_SUBST([XVMC_MAJOR], 1)
2270 AC_SUBST([XVMC_MINOR], 0)
2271
2272 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2273 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2274 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2275 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2276
2277 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2278 AC_SUBST([XA_MINOR], $XA_MINOR)
2279 AC_SUBST([XA_TINY], $XA_TINY)
2280 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2281
2282 dnl Restore LDFLAGS and CPPFLAGS
2283 LDFLAGS="$_SAVE_LDFLAGS"
2284 CPPFLAGS="$_SAVE_CPPFLAGS"
2285
2286 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2287 if test "x$acv_mesa_CLANG" = xyes; then
2288     CFLAGS="$CFLAGS -Qunused-arguments"
2289     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2290 fi
2291
2292 dnl Add user CFLAGS and CXXFLAGS
2293 CFLAGS="$CFLAGS $USER_CFLAGS"
2294 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2295
2296 dnl Substitute the config
2297 AC_CONFIG_FILES([Makefile
2298                 src/Makefile
2299                 src/egl/Makefile
2300                 src/egl/main/egl.pc
2301                 src/egl/wayland/wayland-drm/Makefile
2302                 src/egl/wayland/wayland-egl/Makefile
2303                 src/egl/wayland/wayland-egl/wayland-egl.pc
2304                 src/gallium/Makefile
2305                 src/gallium/auxiliary/Makefile
2306                 src/gallium/auxiliary/pipe-loader/Makefile
2307                 src/gallium/drivers/freedreno/Makefile
2308                 src/gallium/drivers/i915/Makefile
2309                 src/gallium/drivers/ilo/Makefile
2310                 src/gallium/drivers/llvmpipe/Makefile
2311                 src/gallium/drivers/noop/Makefile
2312                 src/gallium/drivers/nouveau/Makefile
2313                 src/gallium/drivers/r300/Makefile
2314                 src/gallium/drivers/r600/Makefile
2315                 src/gallium/drivers/radeon/Makefile
2316                 src/gallium/drivers/radeonsi/Makefile
2317                 src/gallium/drivers/rbug/Makefile
2318                 src/gallium/drivers/softpipe/Makefile
2319                 src/gallium/drivers/svga/Makefile
2320                 src/gallium/drivers/trace/Makefile
2321                 src/gallium/drivers/vc4/Makefile
2322                 src/gallium/state_trackers/clover/Makefile
2323                 src/gallium/state_trackers/dri/Makefile
2324                 src/gallium/state_trackers/glx/xlib/Makefile
2325                 src/gallium/state_trackers/nine/Makefile
2326                 src/gallium/state_trackers/omx/Makefile
2327                 src/gallium/state_trackers/osmesa/Makefile
2328                 src/gallium/state_trackers/va/Makefile
2329                 src/gallium/state_trackers/vdpau/Makefile
2330                 src/gallium/state_trackers/xa/Makefile
2331                 src/gallium/state_trackers/xvmc/Makefile
2332                 src/gallium/targets/d3dadapter9/Makefile
2333                 src/gallium/targets/d3dadapter9/d3d.pc
2334                 src/gallium/targets/dri/Makefile
2335                 src/gallium/targets/libgl-xlib/Makefile
2336                 src/gallium/targets/omx/Makefile
2337                 src/gallium/targets/opencl/Makefile
2338                 src/gallium/targets/osmesa/Makefile
2339                 src/gallium/targets/osmesa/osmesa.pc
2340                 src/gallium/targets/pipe-loader/Makefile
2341                 src/gallium/targets/va/Makefile
2342                 src/gallium/targets/vdpau/Makefile
2343                 src/gallium/targets/xa/Makefile
2344                 src/gallium/targets/xa/xatracker.pc
2345                 src/gallium/targets/xvmc/Makefile
2346                 src/gallium/tests/trivial/Makefile
2347                 src/gallium/tests/unit/Makefile
2348                 src/gallium/winsys/freedreno/drm/Makefile
2349                 src/gallium/winsys/i915/drm/Makefile
2350                 src/gallium/winsys/intel/drm/Makefile
2351                 src/gallium/winsys/nouveau/drm/Makefile
2352                 src/gallium/winsys/radeon/drm/Makefile
2353                 src/gallium/winsys/svga/drm/Makefile
2354                 src/gallium/winsys/sw/dri/Makefile
2355                 src/gallium/winsys/sw/kms-dri/Makefile
2356                 src/gallium/winsys/sw/null/Makefile
2357                 src/gallium/winsys/sw/wrapper/Makefile
2358                 src/gallium/winsys/sw/xlib/Makefile
2359                 src/gallium/winsys/vc4/drm/Makefile
2360                 src/gbm/Makefile
2361                 src/gbm/main/gbm.pc
2362                 src/glsl/Makefile
2363                 src/glx/Makefile
2364                 src/glx/apple/Makefile
2365                 src/glx/tests/Makefile
2366                 src/gtest/Makefile
2367                 src/loader/Makefile
2368                 src/mapi/Makefile
2369                 src/mapi/es1api/glesv1_cm.pc
2370                 src/mapi/es2api/glesv2.pc
2371                 src/mapi/glapi/gen/Makefile
2372                 src/mesa/Makefile
2373                 src/mesa/gl.pc
2374                 src/mesa/drivers/dri/dri.pc
2375                 src/mesa/drivers/dri/common/Makefile
2376                 src/mesa/drivers/dri/common/xmlpool/Makefile
2377                 src/mesa/drivers/dri/i915/Makefile
2378                 src/mesa/drivers/dri/i965/Makefile
2379                 src/mesa/drivers/dri/Makefile
2380                 src/mesa/drivers/dri/nouveau/Makefile
2381                 src/mesa/drivers/dri/r200/Makefile
2382                 src/mesa/drivers/dri/radeon/Makefile
2383                 src/mesa/drivers/dri/swrast/Makefile
2384                 src/mesa/drivers/osmesa/Makefile
2385                 src/mesa/drivers/osmesa/osmesa.pc
2386                 src/mesa/drivers/x11/Makefile
2387                 src/mesa/main/tests/Makefile
2388                 src/util/Makefile
2389                 src/util/tests/hash_table/Makefile])
2390
2391 AC_OUTPUT
2392
2393 dnl
2394 dnl Output some configuration info for the user
2395 dnl
2396 echo ""
2397 echo "        prefix:          $prefix"
2398 echo "        exec_prefix:     $exec_prefix"
2399 echo "        libdir:          $libdir"
2400 echo "        includedir:      $includedir"
2401
2402 dnl API info
2403 echo ""
2404 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2405
2406 dnl Driver info
2407 echo ""
2408 case "x$enable_osmesa$enable_gallium_osmesa" in
2409 xnoyes)
2410         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2411         ;;
2412 xyesno)
2413         echo "        OSMesa:          lib$OSMESA_LIB"
2414         ;;
2415 xnono)
2416         echo "        OSMesa:          no"
2417         ;;
2418 esac
2419
2420 echo ""
2421 if test "x$enable_dri" != xno; then
2422         echo "        DRI platform:    $dri_platform"
2423         if test -z "$DRI_DIRS"; then
2424             echo "        DRI drivers:     no"
2425         else
2426             echo "        DRI drivers:     $DRI_DIRS"
2427         fi
2428         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2429 fi
2430
2431 case "x$enable_glx$enable_xlib_glx" in
2432 xyesyes)
2433     echo "        GLX:             Xlib-based"
2434     ;;
2435 xyesno)
2436     echo "        GLX:             DRI-based"
2437     ;;
2438 *)
2439     echo "        GLX:             $enable_glx"
2440     ;;
2441 esac
2442
2443 dnl EGL
2444 echo ""
2445 echo "        EGL:             $enable_egl"
2446 if test "$enable_egl" = yes; then
2447     echo "        EGL platforms:   $egl_platforms"
2448
2449     egl_drivers=""
2450     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2451         egl_drivers="$egl_drivers builtin:egl_dri2"
2452     fi
2453
2454     echo "        EGL drivers:    $egl_drivers"
2455 fi
2456
2457 echo ""
2458 if test "x$MESA_LLVM" = x1; then
2459     echo "        llvm:            yes"
2460     echo "        llvm-config:     $LLVM_CONFIG"
2461     echo "        llvm-version:    $LLVM_VERSION"
2462 else
2463     echo "        llvm:            no"
2464 fi
2465
2466 echo ""
2467 if test -n "$with_gallium_drivers"; then
2468     echo "        Gallium:         yes"
2469 else
2470     echo "        Gallium:         no"
2471 fi
2472
2473 dnl Shader cache
2474 echo ""
2475 echo "        Shader cache:    $enable_shader_cache"
2476 if test "x$enable_shader_cache" = "xyes"; then
2477     echo "        With SHA1 from:  $with_sha1"
2478 fi
2479
2480 dnl Libraries
2481 echo ""
2482 echo "        Shared libs:     $enable_shared"
2483 echo "        Static libs:     $enable_static"
2484 echo "        Shared-glapi:    $enable_shared_glapi"
2485
2486 dnl Compiler options
2487 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2488 cflags=`echo $CFLAGS | \
2489     $SED 's/^ *//;s/  */ /;s/ *$//'`
2490 cxxflags=`echo $CXXFLAGS | \
2491     $SED 's/^ *//;s/  */ /;s/ *$//'`
2492 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2493 echo ""
2494 echo "        CFLAGS:          $cflags"
2495 echo "        CXXFLAGS:        $cxxflags"
2496 echo "        Macros:          $defines"
2497 echo ""
2498 if test "x$MESA_LLVM" = x1; then
2499     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2500     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2501     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2502     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2503     echo ""
2504 fi
2505 echo "        PYTHON2:         $PYTHON2"
2506
2507 echo ""
2508 echo "        Run '${MAKE-make}' to build Mesa"
2509 echo ""