configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.81
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.8
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 842 dnl project. Even then there's a notable issue as described in the project README
 843 case "$host_os" in
 844 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 845     pthread_stubs_possible="no"
 846     ;;
 847 * )
 848     pthread_stubs_possible="yes"
 849     ;;
 850 esac
 851
 852 if test "x$pthread_stubs_possible" = xyes; then
 853     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 854     AC_SUBST(PTHREADSTUBS_CFLAGS)
 855     AC_SUBST(PTHREADSTUBS_LIBS)
 856 fi
 857
 858 dnl SELinux awareness.
 859 AC_ARG_ENABLE([selinux],
 860     [AS_HELP_STRING([--enable-selinux],
 861         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 862     [MESA_SELINUX="$enableval"],
 863     [MESA_SELINUX=no])
 864 if test "x$enable_selinux" = "xyes"; then
 865     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 866         [AC_CHECK_HEADER([selinux/selinux.h],[],
 867                          [AC_MSG_ERROR([SELinux headers not found])])
 868          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 869                       [AC_MSG_ERROR([SELinux library not found])])
 870          SELINUX_LIBS="-lselinux"])
 871     DEFINES="$DEFINES -DMESA_SELINUX"
 872 fi
 873 AC_SUBST([SELINUX_CFLAGS])
 874 AC_SUBST([SELINUX_LIBS])
 875
 876 dnl
 877 dnl LLVM
 878 dnl
 879 AC_ARG_ENABLE([llvm-shared-libs],
 880     [AS_HELP_STRING([--enable-llvm-shared-libs],
 881         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 882     [enable_llvm_shared_libs="$enableval"],
 883     [enable_llvm_shared_libs=yes])
 884
 885 AC_ARG_WITH([llvm-prefix],
 886     [AS_HELP_STRING([--with-llvm-prefix],
 887         [Prefix for LLVM installations in non-standard locations])],
 888     [llvm_prefix="$withval"],
 889     [llvm_prefix=''])
 890
 891 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 892 if test "x$have_libelf" = xno; then
 893    LIBELF_LIBS=''
 894    LIBELF_CFLAGS=''
 895    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 896    AC_SUBST([LIBELF_LIBS])
 897    AC_SUBST([LIBELF_CFLAGS])
 898 fi
 899
 900 if test -z "$LLVM_CONFIG"; then
 901     if test -n "$llvm_prefix"; then
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 903     else
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 905     fi
 906 fi
 907
 908 llvm_add_component() {
 909     new_llvm_component=$1
 910     driver_name=$2
 911
 912     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 913         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 914     else
 915         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 916     fi
 917 }
 918
 919 llvm_add_default_components() {
 920     driver_name=$1
 921
 922     # Required default components
 923     llvm_add_component "bitwriter" $driver_name
 924     llvm_add_component "engine" $driver_name
 925     llvm_add_component "mcdisassembler" $driver_name
 926     llvm_add_component "mcjit" $driver_name
 927
 928     # Optional default components
 929     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 930         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 931     fi
 932 }
 933
 934 llvm_add_target() {
 935     new_llvm_target=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 939         llvm_add_component $new_llvm_target $driver_name
 940     else
 941         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 # Call this inside ` ` to get the return value.
 946 # $1 is the llvm-config command with arguments.
 947 strip_unwanted_llvm_flags() {
 948     echo " `$1` " | sed -E \
 949         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 950         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 951         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 952         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 954         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 956         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 957         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 958         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 959         -e 's/^[[[:space:]]]//' \
 960         -e 's/[[[:space:]]]$//'
 961 }
 962
 963 llvm_set_environment_variables() {
 964     if test "x$LLVM_CONFIG" != xno; then
 965         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 966         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 967         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 968         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 969
 970         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 971         save_CFLAGS="$CFLAGS"
 972         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 973
 974         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 975             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 976         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980
 981         CFLAGS="$save_CFLAGS"
 982
 983         # Only needed for LLVM < 3.6.0
 984         if test -z "$LLVM_VERSION_PATCH"; then
 985             LLVM_VERSION_PATCH=0
 986         fi
 987
 988         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 989
 990         FOUND_LLVM=yes
 991     else
 992         FOUND_LLVM=no
 993         LLVM_VERSION_INT=0
 994     fi
 995 }
 996
 997 require_llvm() {
 998     if test "x$enable_llvm" != "xyes"; then
 999         AC_MSG_ERROR([--enable-llvm is required when building $1])
1000     fi
1001 }
1002
1003 llvm_require_version() {
1004     require_llvm $2
1005
1006     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1007     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1008     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1009
1010     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1011         # major > required major
1012         #  --> OK
1013         return
1014     fi
1015
1016     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1017         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1018             # major = required major and
1019             # minor > required minor
1020             #  --> OK
1021             return
1022         else
1023             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1024                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1025                     # major = required major and
1026                     # minor = required minor and
1027                     # patch >= required patch
1028                     #  --> OK
1029                     return
1030                 fi
1031             fi
1032         fi
1033     fi
1034
1035     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1036 }
1037
1038 radeon_llvm_check() {
1039     if test ${LLVM_VERSION_INT} -lt 307; then
1040         amdgpu_llvm_target_name='r600'
1041     else
1042         amdgpu_llvm_target_name='amdgpu'
1043     fi
1044
1045     llvm_require_version $*
1046
1047     llvm_add_target $amdgpu_llvm_target_name $2
1048
1049     llvm_add_default_components $2
1050     llvm_add_component "bitreader" $2
1051     llvm_add_component "ipo" $2
1052
1053     if test "x$have_libelf" != xyes; then
1054        AC_MSG_ERROR([$2 requires libelf when using llvm])
1055     fi
1056 }
1057
1058 llvm_set_environment_variables
1059
1060 AC_SUBST([LLVM_CFLAGS])
1061 AC_SUBST([LLVM_CXXFLAGS])
1062 AC_SUBST([LLVM_LIBS])
1063 AC_SUBST([LLVM_LDFLAGS])
1064 AC_SUBST([LLVM_INCLUDEDIR])
1065
1066 dnl
1067 dnl libunwind
1068 dnl
1069 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1070 AC_ARG_ENABLE([libunwind],
1071     [AS_HELP_STRING([--enable-libunwind],
1072             [Use libunwind for backtracing (default: auto)])],
1073         [LIBUNWIND="$enableval"],
1074         [LIBUNWIND="$HAVE_LIBUNWIND"])
1075
1076 if test "x$LIBUNWIND" = "xyes"; then
1077     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1078     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1079 fi
1080
1081
1082 dnl Options for APIs
1083 AC_ARG_ENABLE([opengl],
1084     [AS_HELP_STRING([--disable-opengl],
1085         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1086     [enable_opengl="$enableval"],
1087     [enable_opengl=yes])
1088 AC_ARG_ENABLE([gles1],
1089     [AS_HELP_STRING([--disable-gles1],
1090         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1091     [enable_gles1="$enableval"],
1092     [enable_gles1=yes])
1093 AC_ARG_ENABLE([gles2],
1094     [AS_HELP_STRING([--disable-gles2],
1095         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1096     [enable_gles2="$enableval"],
1097     [enable_gles2=yes])
1098
1099 AC_ARG_ENABLE([dri],
1100     [AS_HELP_STRING([--enable-dri],
1101         [enable DRI modules @<:@default=enabled@:>@])],
1102     [enable_dri="$enableval"],
1103     [enable_dri=yes])
1104
1105 AC_ARG_ENABLE([gallium-extra-hud],
1106     [AS_HELP_STRING([--enable-gallium-extra-hud],
1107         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1108     [enable_gallium_extra_hud="$enableval"],
1109     [enable_gallium_extra_hud=no])
1110 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1111 if test "x$enable_gallium_extra_hud" = xyes ; then
1112     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1113 fi
1114
1115 #TODO: no pkgconfig .pc available for libsensors.
1116 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1117 AC_ARG_ENABLE([lmsensors],
1118     [AS_HELP_STRING([--enable-lmsensors],
1119         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1120     [enable_lmsensors="$enableval"],
1121     [enable_lmsensors=no])
1122 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1123 if test "x$enable_lmsensors" = xyes ; then
1124     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1125     LIBSENSORS_LIBS="-lsensors"
1126 else
1127     LIBSENSORS_LIBS=""
1128 fi
1129 AC_SUBST(LIBSENSORS_LIBS)
1130
1131 case "$host_os" in
1132 linux*)
1133     dri3_default=yes
1134     ;;
1135 *)
1136     dri3_default=no
1137     ;;
1138 esac
1139
1140 if test "x$enable_dri" = xno; then
1141     dri3_default=no
1142 fi
1143
1144 AC_ARG_ENABLE([dri3],
1145     [AS_HELP_STRING([--enable-dri3],
1146         [enable DRI3 @<:@default=auto@:>@])],
1147     [enable_dri3="$enableval"],
1148     [enable_dri3="$dri3_default"])
1149 AC_ARG_ENABLE([glx],
1150     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1151         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1152     [enable_glx="$enableval"],
1153     [enable_glx=yes])
1154 AC_ARG_ENABLE([osmesa],
1155     [AS_HELP_STRING([--enable-osmesa],
1156         [enable OSMesa library @<:@default=disabled@:>@])],
1157     [enable_osmesa="$enableval"],
1158     [enable_osmesa=no])
1159 AC_ARG_ENABLE([gallium-osmesa],
1160     [AS_HELP_STRING([--enable-gallium-osmesa],
1161         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1162     [enable_gallium_osmesa="$enableval"],
1163     [enable_gallium_osmesa=no])
1164 AC_ARG_ENABLE([egl],
1165     [AS_HELP_STRING([--disable-egl],
1166         [disable EGL library @<:@default=enabled@:>@])],
1167     [enable_egl="$enableval"],
1168     [enable_egl=yes])
1169
1170 AC_ARG_ENABLE([xa],
1171     [AS_HELP_STRING([--enable-xa],
1172         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1173     [enable_xa="$enableval"],
1174     [enable_xa=no])
1175 AC_ARG_ENABLE([gbm],
1176    [AS_HELP_STRING([--enable-gbm],
1177          [enable gbm library @<:@default=yes except cygwin@:>@])],
1178    [enable_gbm="$enableval"],
1179    [case "$host_os" in
1180        cygwin*)
1181           enable_gbm=no
1182           ;;
1183        *)
1184           enable_gbm=yes
1185           ;;
1186     esac])
1187 AC_ARG_ENABLE([nine],
1188     [AS_HELP_STRING([--enable-nine],
1189         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1190     [enable_nine="$enableval"],
1191     [enable_nine=no])
1192
1193 AC_ARG_ENABLE([xvmc],
1194    [AS_HELP_STRING([--enable-xvmc],
1195          [enable xvmc library @<:@default=auto@:>@])],
1196    [enable_xvmc="$enableval"],
1197    [enable_xvmc=auto])
1198 AC_ARG_ENABLE([vdpau],
1199    [AS_HELP_STRING([--enable-vdpau],
1200          [enable vdpau library @<:@default=auto@:>@])],
1201    [enable_vdpau="$enableval"],
1202    [enable_vdpau=auto])
1203 AC_ARG_ENABLE([omx],
1204    [AS_HELP_STRING([--enable-omx],
1205          [enable OpenMAX library @<:@default=disabled@:>@])],
1206    [enable_omx="$enableval"],
1207    [enable_omx=no])
1208 AC_ARG_ENABLE([va],
1209    [AS_HELP_STRING([--enable-va],
1210          [enable va library @<:@default=auto@:>@])],
1211    [enable_va="$enableval"],
1212    [enable_va=auto])
1213 AC_ARG_ENABLE([opencl],
1214    [AS_HELP_STRING([--enable-opencl],
1215          [enable OpenCL library @<:@default=disabled@:>@])],
1216    [enable_opencl="$enableval"],
1217    [enable_opencl=no])
1218 AC_ARG_ENABLE([opencl_icd],
1219    [AS_HELP_STRING([--enable-opencl-icd],
1220           [Build an OpenCL ICD library to be loaded by an ICD implementation
1221            @<:@default=disabled@:>@])],
1222     [enable_opencl_icd="$enableval"],
1223     [enable_opencl_icd=no])
1224
1225 AC_ARG_ENABLE([gallium-tests],
1226     [AS_HELP_STRING([--enable-gallium-tests],
1227         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1228     [enable_gallium_tests="$enableval"],
1229     [enable_gallium_tests=no])
1230
1231 # Option for Gallium drivers
1232
1233 # Keep this in sync with the --with-gallium-drivers help string default value
1234 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1235
1236 AC_ARG_WITH([gallium-drivers],
1237     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1238         [comma delimited Gallium drivers list, e.g.
1239         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1240         @<:@default=r300,r600,svga,swrast@:>@])],
1241     [with_gallium_drivers="$withval"],
1242     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1243
1244 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1245 # here so that the script doesn't choke on an unknown driver name later.
1246 case "$with_gallium_drivers" in
1247     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1248     no) with_gallium_drivers='' ;;
1249 esac
1250
1251 if test "x$enable_opengl" = xno -a \
1252         "x$enable_gles1" = xno -a \
1253         "x$enable_gles2" = xno -a \
1254         "x$enable_nine" = xno -a \
1255         "x$enable_xa" = xno -a \
1256         "x$enable_xvmc" = xno -a \
1257         "x$enable_vdpau" = xno -a \
1258         "x$enable_omx" = xno -a \
1259         "x$enable_va" = xno -a \
1260         "x$enable_opencl" = xno; then
1261     AC_MSG_ERROR([at least one API should be enabled])
1262 fi
1263
1264 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1265 if test "x$enable_opengl" = xno -a \
1266         "x$enable_gles1" = xyes; then
1267     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1268 fi
1269
1270 if test "x$enable_opengl" = xno -a \
1271         "x$enable_gles2" = xyes; then
1272     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1273 fi
1274
1275 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1276 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1277 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1278 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1279                                         "x$enable_gles1" = xyes -o \
1280                                         "x$enable_gles2" = xyes)
1281
1282 # Validate GLX options
1283 if test "x$enable_glx" = xyes; then
1284     if test "x$enable_dri" = xyes; then
1285         enable_glx=dri
1286     elif test -n "$with_gallium_drivers"; then
1287         enable_glx=gallium-xlib
1288     else
1289         enable_glx=xlib
1290     fi
1291 fi
1292 case "x$enable_glx" in
1293 xdri | xxlib | xgallium-xlib)
1294     # GLX requires OpenGL
1295     if test "x$enable_opengl" = xno; then
1296         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1297     fi
1298
1299     # Check individual dependencies
1300     case "x$enable_glx" in
1301     xdri)
1302         if test "x$enable_dri" = xno; then
1303             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1304         fi
1305         ;;
1306     xxlib)
1307         if test "x$enable_dri" = xyes; then
1308             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1309         fi
1310         ;;
1311     xgallium-xlib )
1312         if test "x$enable_dri" = xyes; then
1313             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1314         fi
1315         if test -z "$with_gallium_drivers"; then
1316             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1317         fi
1318         ;;
1319     esac
1320     ;;
1321 xno)
1322     ;;
1323 *)
1324     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1325     ;;
1326 esac
1327
1328 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1329 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1330 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1331 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1332
1333 DEFAULT_GL_LIB_NAME=GL
1334
1335 dnl
1336 dnl Libglvnd configuration
1337 dnl
1338 AC_ARG_ENABLE([libglvnd],
1339     [AS_HELP_STRING([--enable-libglvnd],
1340         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1341     [enable_libglvnd="$enableval"],
1342     [enable_libglvnd=no])
1343 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1344
1345 if test "x$enable_libglvnd" = xyes ; then
1346     dnl XXX: update once we can handle more than libGL/glx.
1347     dnl Namely: we should error out if neither of the glvnd enabled libraries
1348     dnl are built
1349     case "x$enable_glx" in
1350     xno)
1351         AC_MSG_ERROR([cannot build libglvnd without GLX])
1352         ;;
1353     xxlib | xgallium-xlib )
1354         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1355         ;;
1356     xdri)
1357         ;;
1358     esac
1359
1360     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1361     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1362     AC_SUBST([LIBGLVND_DATADIR])
1363
1364     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1365     DEFAULT_GL_LIB_NAME=GLX_mesa
1366 fi
1367
1368 AC_ARG_WITH([gl-lib-name],
1369   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1370     [specify GL library name @<:@default=GL@:>@])],
1371   [GL_LIB=$withval],
1372   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1373 AC_ARG_WITH([osmesa-lib-name],
1374   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1375     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1376   [OSMESA_LIB=$withval],
1377   [OSMESA_LIB=OSMesa])
1378 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1379 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1380
1381 dnl
1382 dnl Mangled Mesa support
1383 dnl
1384 AC_ARG_ENABLE([mangling],
1385   [AS_HELP_STRING([--enable-mangling],
1386     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1387   [enable_mangling="${enableval}"],
1388   [enable_mangling=no]
1389 )
1390 if test "x${enable_mangling}" = "xyes" ; then
1391   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1392   GL_LIB="Mangled${GL_LIB}"
1393   OSMESA_LIB="Mangled${OSMESA_LIB}"
1394 fi
1395 AC_SUBST([GL_LIB])
1396 AC_SUBST([OSMESA_LIB])
1397
1398 # Check for libdrm
1399 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1400                   [have_libdrm=yes], [have_libdrm=no])
1401 if test "x$have_libdrm" = xyes; then
1402         DEFINES="$DEFINES -DHAVE_LIBDRM"
1403 fi
1404
1405 require_libdrm() {
1406     if test "x$have_libdrm" != xyes; then
1407        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1408     fi
1409 }
1410
1411
1412 # Select which platform-dependent DRI code gets built
1413 case "$host_os" in
1414 darwin*)
1415     dri_platform='apple' ;;
1416 cygwin*)
1417     dri_platform='windows' ;;
1418 gnu*)
1419     dri_platform='none' ;;
1420 *)
1421     dri_platform='drm' ;;
1422 esac
1423
1424 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1425     have_drisw_kms='yes'
1426 fi
1427
1428 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1429 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1430 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1431 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1432 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1433 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1434 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1435 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1436 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1437
1438 AC_ARG_ENABLE([shared-glapi],
1439     [AS_HELP_STRING([--enable-shared-glapi],
1440         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1441     [enable_shared_glapi="$enableval"],
1442     [enable_shared_glapi=yes])
1443
1444 case "x$enable_opengl$enable_gles1$enable_gles2" in
1445 x*yes*yes*)
1446     if test "x$enable_shared_glapi" = xno; then
1447         AC_MSG_ERROR([shared GLAPI required when building two or more of
1448                       the following APIs - opengl, gles1 gles2])
1449     fi
1450     ;;
1451 esac
1452
1453 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1454
1455 # Build the pipe-drivers as separate libraries/modules.
1456 # Do not touch this unless you know what you are doing.
1457 # XXX: Expose via configure option ?
1458 enable_shared_pipe_drivers=no
1459
1460 dnl
1461 dnl Driver specific build directories
1462 dnl
1463
1464 if test "x$enable_gallium_osmesa" = xyes; then
1465     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1466         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1467     fi
1468     if test "x$enable_osmesa" = xyes; then
1469         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1470     fi
1471 fi
1472
1473 require_dri_shared_libs_and_glapi() {
1474     if test "x$enable_static" = xyes; then
1475         AC_MSG_ERROR([$1 cannot be build as static library])
1476     fi
1477
1478     if test "x$enable_dri" != xyes; then
1479         # There is only a single backend which won't be build/used otherwise.
1480         # XXX: Revisit this as the egl/haiku is a thing.
1481         AC_MSG_ERROR([$1 requires --enable-dri])
1482     fi
1483
1484     if test "x$enable_shared_glapi" != xyes; then
1485         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1486     fi
1487 }
1488
1489 if test "x$enable_dri" = xyes; then
1490     require_dri_shared_libs_and_glapi "DRI"
1491
1492     # not a hard requirement as swrast does not depend on it
1493     if test "x$have_libdrm" = xyes; then
1494         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1495     fi
1496 fi
1497
1498 AC_ARG_ENABLE([driglx-direct],
1499     [AS_HELP_STRING([--disable-driglx-direct],
1500         [disable direct rendering in GLX and EGL for DRI \
1501             @<:@default=auto@:>@])],
1502     [driglx_direct="$enableval"],
1503     [driglx_direct="yes"])
1504
1505 dnl
1506 dnl libGL configuration per driver
1507 dnl
1508 if test "x$enable_glx" != xno; then
1509     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1510 fi
1511 case "x$enable_glx" in
1512 xxlib | xgallium-xlib)
1513     # Xlib-based GLX
1514     dri_modules="x11 xext xcb"
1515     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1516     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1517     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1518     GL_LIB_DEPS="$XLIBGL_LIBS"
1519     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1520     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1521     ;;
1522 xdri)
1523     # DRI-based GLX
1524
1525     # find the DRI deps for libGL
1526     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1527
1528     if test x"$driglx_direct" = xyes; then
1529         if test x"$dri_platform" = xdrm ; then
1530             DEFINES="$DEFINES -DGLX_USE_DRM"
1531             require_libdrm "Direct rendering"
1532
1533             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1534             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1535
1536             if test x"$enable_dri" = xyes; then
1537                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1538             fi
1539         fi
1540         if test x"$dri_platform" = xapple ; then
1541             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1542         fi
1543         if test x"$dri_platform" = xwindows ; then
1544             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1545         fi
1546     fi
1547
1548     # add xf86vidmode if available
1549     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1550     if test "$HAVE_XF86VIDMODE" = yes ; then
1551         dri_modules="$dri_modules xxf86vm"
1552     fi
1553
1554     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1555     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1556     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1557     GL_LIB_DEPS="$DRIGL_LIBS"
1558
1559     # need DRM libs, $PTHREAD_LIBS, etc.
1560     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1561     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1562     ;;
1563 esac
1564
1565 # This is outside the case (above) so that it is invoked even for non-GLX
1566 # builds.
1567 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1568
1569 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1570 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1571 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1572 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1573
1574 AC_SUBST([X11_INCLUDES])
1575 AC_SUBST([GL_LIB_DEPS])
1576 AC_SUBST([GL_PC_REQ_PRIV])
1577 AC_SUBST([GL_PC_LIB_PRIV])
1578 AC_SUBST([GL_PC_CFLAGS])
1579 AC_SUBST([DRI_PC_REQ_PRIV])
1580 AC_SUBST([GLESv1_CM_LIB_DEPS])
1581 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1582 AC_SUBST([GLESv2_LIB_DEPS])
1583 AC_SUBST([GLESv2_PC_LIB_PRIV])
1584
1585 AC_SUBST([HAVE_XF86VIDMODE])
1586
1587 dnl
1588 dnl More GLX setup
1589 dnl
1590 case "x$enable_glx" in
1591 xxlib | xgallium-xlib)
1592     DEFINES="$DEFINES -DUSE_XSHM"
1593     ;;
1594 xdri)
1595     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1596     if test "x$driglx_direct" = xyes; then
1597         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1598     fi
1599     ;;
1600 esac
1601
1602 dnl
1603 dnl TLS detection
1604 dnl
1605
1606 AC_ARG_ENABLE([glx-tls],
1607     [AS_HELP_STRING([--enable-glx-tls],
1608         [enable TLS support in GLX @<:@default=enabled@:>@])],
1609     [GLX_USE_TLS="$enableval"],
1610     [GLX_USE_TLS=yes])
1611 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1612
1613 if test "x$GLX_USE_TLS" = xyes; then
1614     DEFINES="$DEFINES -DGLX_USE_TLS"
1615 fi
1616
1617 dnl Read-only text section on x86 hardened platforms
1618 AC_ARG_ENABLE([glx-read-only-text],
1619     [AS_HELP_STRING([--enable-glx-read-only-text],
1620         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1621     [enable_glx_read_only_text="$enableval"],
1622     [enable_glx_read_only_text=no])
1623 if test "x$enable_glx_read_only_text" = xyes; then
1624     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1625 fi
1626
1627 dnl
1628 dnl DEPRECATED: EGL Platforms configuration
1629 dnl
1630 AC_ARG_WITH([egl-platforms],
1631     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1632         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1633     [with_egl_platforms="$withval"],
1634     [with_egl_platforms=auto])
1635
1636 if test "x$with_egl_platforms" = xauto; then
1637     with_egl_platforms="x11,surfaceless"
1638     if test "x$enable_gbm" = xyes; then
1639         with_egl_platforms="$with_egl_platforms,drm"
1640     fi
1641 else
1642     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1643 fi
1644
1645 dnl
1646 dnl Platforms configuration
1647 dnl
1648 AC_ARG_WITH([platforms],
1649     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1650         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1651         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1652     [with_platforms="$withval"],
1653     [with_platforms=auto])
1654
1655 # Reuse the autodetection rather than duplicating it.
1656 if test "x$with_platforms" = xauto; then
1657     with_platforms=$with_egl_platforms
1658 fi
1659
1660 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1661         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1662         WAYLAND_SCANNER='')
1663 if test "x$WAYLAND_SCANNER" = x; then
1664     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1665 fi
1666
1667 # Do per platform setups and checks
1668 platforms=`IFS=', '; echo $with_platforms`
1669 for plat in $platforms; do
1670         case "$plat" in
1671         wayland)
1672
1673                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1674
1675                 if test "x$WAYLAND_SCANNER" = "x:"; then
1676                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1677                 fi
1678                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1679                 ;;
1680
1681         x11)
1682                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1683                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1684                 ;;
1685
1686         drm)
1687                 test "x$enable_gbm" = "xno" &&
1688                         AC_MSG_ERROR([EGL platform drm needs gbm])
1689                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1690                 ;;
1691
1692         surfaceless)
1693                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1694                 ;;
1695
1696         android)
1697                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1698                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1699                 ;;
1700
1701         *)
1702                 AC_MSG_ERROR([platform '$plat' does not exist])
1703                 ;;
1704         esac
1705
1706         case "$plat" in
1707         wayland|drm|surfaceless)
1708                 require_libdrm "Platform $plat"
1709                 ;;
1710         esac
1711 done
1712
1713 if test "x$enable_glx" != xno; then
1714     if ! echo "$platforms" | grep -q 'x11'; then
1715         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1716     fi
1717 fi
1718
1719 if test x"$enable_dri3" = xyes; then
1720     DEFINES="$DEFINES -DHAVE_DRI3"
1721
1722     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1723     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1724 fi
1725
1726 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1727 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1728 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1729 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1730 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1731
1732 dnl
1733 dnl More DRI setup
1734 dnl
1735 dnl Directory for DRI drivers
1736 AC_ARG_WITH([dri-driverdir],
1737     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1738         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1739     [DRI_DRIVER_INSTALL_DIR="$withval"],
1740     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1741 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1742 dnl Extra search path for DRI drivers
1743 AC_ARG_WITH([dri-searchpath],
1744     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1745         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1746     [DRI_DRIVER_SEARCH_DIR="$withval"],
1747     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1748 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1749 dnl Which drivers to build - default is chosen by platform
1750 AC_ARG_WITH([dri-drivers],
1751     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1752         [comma delimited classic DRI drivers list, e.g.
1753         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1754     [with_dri_drivers="$withval"],
1755     [with_dri_drivers=auto])
1756
1757 if test "x$with_dri_drivers" = xauto; then
1758     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1759         with_dri_drivers="yes"
1760     else
1761         with_dri_drivers="no"
1762     fi
1763 fi
1764 if test "x$with_dri_drivers" = xno; then
1765     with_dri_drivers=''
1766 fi
1767
1768 dnl If $with_dri_drivers is yes, drivers will be added through
1769 dnl platform checks. Set DEFINES and LIB_DEPS
1770 if test "x$enable_dri" = xyes; then
1771     # Platform specific settings and drivers to build
1772     case "$host_os" in
1773     linux*)
1774         case "$host_cpu" in
1775         powerpc* | sparc*)
1776             # Build only the drivers for cards that exist on PowerPC/sparc
1777             if test "x$with_dri_drivers" = "xyes"; then
1778                 with_dri_drivers="r200 radeon swrast"
1779             fi
1780             ;;
1781         esac
1782         ;;
1783     cygwin*)
1784         if test "x$with_dri_drivers" = "xyes"; then
1785             with_dri_drivers="swrast"
1786         fi
1787         ;;
1788     darwin*)
1789         DEFINES="$DEFINES -DBUILDING_MESA"
1790         if test "x$with_dri_drivers" = "xyes"; then
1791             with_dri_drivers="swrast"
1792         fi
1793         ;;
1794     esac
1795
1796     # default drivers
1797     if test "x$with_dri_drivers" = "xyes"; then
1798         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1799     fi
1800
1801     # Check for expat
1802     PKG_CHECK_MODULES([EXPAT], [expat], [],
1803         # expat version 2.0 and earlier do not provide expat.pc
1804         [AC_CHECK_HEADER([expat.h],[],
1805                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1806          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1807                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1808          EXPAT_LIBS="-lexpat"])
1809
1810     # put all the necessary libs together
1811     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1812 fi
1813
1814 AC_SUBST([DRI_LIB_DEPS])
1815
1816 DRI_DIRS=''
1817 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1818 if test -n "$with_dri_drivers"; then
1819     if test "x$enable_opengl" != xyes; then
1820         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1821     fi
1822
1823     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1824     for driver in $dri_drivers; do
1825         DRI_DIRS="$DRI_DIRS $driver"
1826         case "x$driver" in
1827         xi915)
1828             require_libdrm "i915"
1829             HAVE_I915_DRI=yes
1830             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1831             ;;
1832         xi965)
1833             require_libdrm "i965"
1834             HAVE_I965_DRI=yes
1835             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1836             ;;
1837         xnouveau)
1838             require_libdrm "nouveau"
1839             HAVE_NOUVEAU_DRI=yes
1840             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1841             ;;
1842         xradeon)
1843             require_libdrm "radeon"
1844             HAVE_RADEON_DRI=yes;
1845             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1846             ;;
1847         xr200)
1848             require_libdrm "r200"
1849             HAVE_R200_DRI=yes
1850             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1851             ;;
1852         xswrast)
1853             HAVE_SWRAST_DRI=yes
1854             ;;
1855         *)
1856             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1857             ;;
1858         esac
1859     done
1860     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1861 fi
1862
1863
1864 dnl
1865 dnl Gallium LLVM
1866 dnl Deprecated: kept for backwards compatibility
1867 dnl
1868 AC_ARG_ENABLE([gallium-llvm],
1869     [AS_HELP_STRING([--enable-gallium-llvm],
1870         [DEPRECATED: use --enable-llvm instead])],
1871     [enable_gallium_llvm="$enableval"],
1872     [enable_gallium_llvm=auto])
1873
1874 if test "x$enable_gallium_llvm" != xauto; then
1875    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1876    enable_llvm=$enable_gallium_llvm
1877 fi
1878
1879 dnl
1880 dnl LLVM
1881 dnl
1882 AC_ARG_ENABLE([llvm],
1883     [AS_HELP_STRING([--enable-llvm],
1884         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1885     [enable_llvm="$enableval"],
1886     [enable_llvm=auto])
1887
1888 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1889     if test "x$FOUND_LLVM" = xyes; then
1890         case "$host_cpu" in
1891         i*86|x86_64|amd64) enable_llvm=yes;;
1892         *) enable_llvm=no;;
1893         esac
1894     else
1895         enable_llvm=no
1896     fi
1897 fi
1898
1899 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1900     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1901 fi
1902
1903 #
1904 # Vulkan driver configuration
1905 #
1906
1907 AC_ARG_WITH([vulkan-drivers],
1908     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1909         [comma delimited Vulkan drivers list, e.g.
1910         "intel,radeon"
1911         @<:@default=no@:>@])],
1912     [with_vulkan_drivers="$withval"],
1913     [with_vulkan_drivers="no"])
1914
1915 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1916 # here so that the script doesn't choke on an unknown driver name later.
1917 case "x$with_vulkan_drivers" in
1918     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1919     xno) with_vulkan_drivers='' ;;
1920 esac
1921
1922 AC_ARG_WITH([vulkan-icddir],
1923     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1924         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1925     [VULKAN_ICD_INSTALL_DIR="$withval"],
1926     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1927 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1928
1929 require_x11_dri3() {
1930     if echo "$platforms" | grep -q 'x11'; then
1931         if test "x$enable_dri3" != xyes; then
1932             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1933         fi
1934     fi
1935 }
1936
1937 if test -n "$with_vulkan_drivers"; then
1938     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1939         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1940     fi
1941
1942     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1943     for driver in $VULKAN_DRIVERS; do
1944         case "x$driver" in
1945         xintel)
1946             require_libdrm "ANV"
1947             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1948             require_x11_dri3 "ANV"
1949             HAVE_INTEL_VULKAN=yes
1950             ;;
1951         xradeon)
1952             require_libdrm "radv"
1953             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1954             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1955             require_x11_dri3 "radv"
1956             HAVE_RADEON_VULKAN=yes
1957             ;;
1958         *)
1959             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1960             ;;
1961         esac
1962     done
1963     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1964 fi
1965
1966
1967 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1968 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1969 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1970                                   "x$enable_osmesa" = xyes -o \
1971                                   -n "$DRI_DIRS")
1972
1973 dnl
1974 dnl OSMesa configuration
1975 dnl
1976
1977 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1978 AC_ARG_WITH([osmesa-bits],
1979     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1980         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1981     [osmesa_bits="$withval"],
1982     [osmesa_bits=8])
1983 if test "x$osmesa_bits" != x8; then
1984     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1985         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1986         osmesa_bits=8
1987     fi
1988 fi
1989 case "x$osmesa_bits" in
1990 x8)
1991     OSMESA_LIB="${OSMESA_LIB}"
1992     ;;
1993 x16|x32)
1994     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1995     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1996     ;;
1997 *)
1998     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1999     ;;
2000 esac
2001
2002 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2003     # only link libraries with osmesa if shared
2004     if test "$enable_static" = no; then
2005         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2006     else
2007         OSMESA_LIB_DEPS=""
2008     fi
2009     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2010 fi
2011
2012 AC_SUBST([OSMESA_LIB_DEPS])
2013 AC_SUBST([OSMESA_PC_REQ])
2014 AC_SUBST([OSMESA_PC_LIB_PRIV])
2015
2016 dnl
2017 dnl gbm configuration
2018 dnl
2019 if test "x$enable_gbm" = xyes; then
2020     require_dri_shared_libs_and_glapi "gbm"
2021 fi
2022 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2023 # FINISHME: GBM has a number of dependencies which we should add below
2024 GBM_PC_REQ_PRIV=""
2025 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2026 AC_SUBST([GBM_PC_REQ_PRIV])
2027 AC_SUBST([GBM_PC_LIB_PRIV])
2028
2029 dnl
2030 dnl EGL configuration
2031 dnl
2032
2033 if test "x$enable_egl" = xyes; then
2034     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2035
2036     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2037
2038     require_dri_shared_libs_and_glapi "egl"
2039 fi
2040 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2041 AC_SUBST([EGL_LIB_DEPS])
2042
2043 gallium_st="mesa"
2044
2045 dnl
2046 dnl XA configuration
2047 dnl
2048 if test "x$enable_xa" = xyes; then
2049     if test "x$with_gallium_drivers" = xswrast; then
2050        AC_MSG_ERROR([
2051           Building xa requires at least one non swrast gallium driver.
2052           If you are looking to use libxatracker.so with the VMware driver,
2053           make sure to include svga in the gallium drivers list, apart from
2054           enabling XA.
2055           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2056     fi
2057     gallium_st="$gallium_st xa"
2058 fi
2059 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2060
2061 if echo $platforms | grep -q "x11"; then
2062     have_xvmc_platform=yes
2063 else
2064     have_xvmc_platform=no
2065 fi
2066
2067 if echo $platforms | grep -q "x11"; then
2068     have_vdpau_platform=yes
2069 else
2070     have_vdpau_platform=no
2071 fi
2072
2073 if echo $platforms | grep -q "x11\|drm"; then
2074     have_omx_platform=yes
2075 else
2076     have_omx_platform=no
2077 fi
2078
2079 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2080     have_va_platform=yes
2081 else
2082     have_va_platform=no
2083 fi
2084
2085 dnl
2086 dnl Gallium G3DVL configuration
2087 dnl
2088 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2089     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2090         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2091     fi
2092
2093     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2094         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2095     fi
2096
2097     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2098         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2099     fi
2100
2101     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2102         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2103     fi
2104 fi
2105
2106 if test "x$enable_dri" = xyes -o \
2107         "x$enable_xvmc" = xyes -o \
2108         "x$enable_vdpau" = xyes -o \
2109         "x$enable_omx" = xyes -o \
2110         "x$enable_va" = xyes; then
2111     need_gallium_vl=yes
2112 fi
2113 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2114
2115 if test "x$enable_xvmc" = xyes -o \
2116         "x$enable_vdpau" = xyes -o \
2117         "x$enable_omx" = xyes -o \
2118         "x$enable_va" = xyes; then
2119     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2120     need_gallium_vl_winsys=yes
2121 fi
2122 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2123
2124 if test "x$enable_xvmc" = xyes; then
2125     if test "x$have_xvmc_platform" != xyes; then
2126         AC_MSG_ERROR([XVMC requires the x11 platforms])
2127     fi
2128     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2129     gallium_st="$gallium_st xvmc"
2130 fi
2131 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2132
2133 if test "x$enable_vdpau" = xyes; then
2134     if test "x$have_vdpau_platform" != xyes; then
2135         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2136     fi
2137     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2138     gallium_st="$gallium_st vdpau"
2139     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2140 fi
2141 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2142
2143 if test "x$enable_omx" = xyes; then
2144     if test "x$have_omx_platform" != xyes; then
2145         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2146     fi
2147     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2148     gallium_st="$gallium_st omx"
2149 fi
2150 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2151
2152 if test "x$enable_va" = xyes; then
2153     if test "x$have_va_platform" != xyes; then
2154         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2155     fi
2156     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2157     gallium_st="$gallium_st va"
2158 fi
2159 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2160
2161 dnl
2162 dnl Nine Direct3D9 configuration
2163 dnl
2164 if test "x$enable_nine" = xyes; then
2165     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2166         AC_MSG_ERROR([nine requires the gallium swrast driver])
2167     fi
2168     if test "x$with_gallium_drivers" = xswrast; then
2169         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2170     fi
2171     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2172         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2173     fi
2174
2175     if test "x$enable_dri3" = xno; then
2176         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2177     fi
2178
2179     gallium_st="$gallium_st nine"
2180 fi
2181 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2182
2183 dnl
2184 dnl OpenCL configuration
2185 dnl
2186
2187 AC_ARG_WITH([clang-libdir],
2188    [AS_HELP_STRING([--with-clang-libdir],
2189          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2190    [CLANG_LIBDIR="$withval"],
2191    [CLANG_LIBDIR=''])
2192
2193 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2194
2195 if test "x$enable_opencl" = xyes; then
2196     if test -z "$with_gallium_drivers"; then
2197         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2198     fi
2199
2200     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2201         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2202     fi
2203
2204     if test "x$have_libclc" = xno; then
2205         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2206                     Make sure the directory containing libclc.pc is specified in your
2207                     PKG_CONFIG_PATH environment variable.
2208                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2209     else
2210         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2211         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2212         AC_SUBST([LIBCLC_INCLUDEDIR])
2213         AC_SUBST([LIBCLC_LIBEXECDIR])
2214     fi
2215
2216     gallium_st="$gallium_st clover"
2217
2218     if test "x$enable_opencl_icd" = xyes; then
2219         OPENCL_LIBNAME="MesaOpenCL"
2220     else
2221         OPENCL_LIBNAME="OpenCL"
2222     fi
2223
2224     if test "x$have_libelf" != xyes; then
2225        AC_MSG_ERROR([Clover requires libelf])
2226     fi
2227
2228     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2229         altivec_enabled=no
2230         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2231         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2232         #error "AltiVec not enabled"
2233         #endif
2234         ])], altivec_enabled=yes)
2235
2236         if test "$altivec_enabled" = yes; then
2237             CLOVER_STD_OVERRIDE="-std=gnu++11"
2238         fi
2239         AC_SUBST([CLOVER_STD_OVERRIDE])
2240     fi
2241
2242     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2243
2244     llvm_add_default_components "opencl"
2245     llvm_add_component "all-targets" "opencl"
2246     llvm_add_component "linker" "opencl"
2247     llvm_add_component "instrumentation" "opencl"
2248     llvm_add_component "ipo" "opencl"
2249     llvm_add_component "irreader" "opencl"
2250     llvm_add_component "option" "opencl"
2251     llvm_add_component "objcarcopts" "opencl"
2252     llvm_add_component "profiledata" "opencl"
2253
2254     dnl Check for Clang internal headers
2255     if test -z "$CLANG_LIBDIR"; then
2256         CLANG_LIBDIR=${LLVM_LIBDIR}
2257     fi
2258     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2259     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2260         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2261 fi
2262 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2263 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2264 AC_SUBST([OPENCL_LIBNAME])
2265 AC_SUBST([CLANG_RESOURCE_DIR])
2266
2267 dnl
2268 dnl Gallium configuration
2269 dnl
2270 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2271
2272 # libEGL wants to default to the first platform specified in
2273 # ./configure.  parse that here.
2274 if test "x$platforms" != "x"; then
2275     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2276     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2277 else
2278     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2279 fi
2280
2281 AC_SUBST([EGL_NATIVE_PLATFORM])
2282 AC_SUBST([EGL_CFLAGS])
2283
2284 # If we don't have the X11 platform, set this define so we don't try to include
2285 # the X11 headers.
2286 if ! echo "$platforms" | grep -q 'x11'; then
2287     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2288     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2289 fi
2290
2291 dnl Directory for XVMC libs
2292 AC_ARG_WITH([xvmc-libdir],
2293     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2294         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2295     [XVMC_LIB_INSTALL_DIR="$withval"],
2296     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2297 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2298
2299 dnl
2300 dnl Gallium Tests
2301 dnl
2302 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2303
2304 dnl Directory for VDPAU libs
2305 AC_ARG_WITH([vdpau-libdir],
2306     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2307         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2308     [VDPAU_LIB_INSTALL_DIR="$withval"],
2309     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2310 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2311
2312 dnl Directory for OMX libs
2313
2314 AC_ARG_WITH([omx-libdir],
2315     [AS_HELP_STRING([--with-omx-libdir=DIR],
2316         [directory for the OMX libraries])],
2317     [OMX_LIB_INSTALL_DIR="$withval"],
2318     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2319                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2320 AC_SUBST([OMX_LIB_INSTALL_DIR])
2321
2322 dnl Directory for VA libs
2323
2324 AC_ARG_WITH([va-libdir],
2325     [AS_HELP_STRING([--with-va-libdir=DIR],
2326         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2327     [VA_LIB_INSTALL_DIR="$withval"],
2328     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2329 AC_SUBST([VA_LIB_INSTALL_DIR])
2330
2331 AC_ARG_WITH([d3d-libdir],
2332     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2333         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2334     [D3D_DRIVER_INSTALL_DIR="$withval"],
2335     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2336 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2337
2338 dnl
2339 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2340 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2341 dnl architectures.
2342 dnl
2343 r300_require_llvm() {
2344     case "$host" in *gnux32) return;; esac
2345     case "$host_cpu" in
2346     i*86|x86_64|amd64) require_llvm $1
2347         ;;
2348     esac
2349 }
2350
2351 dnl
2352 dnl DRM is needed by X, Wayland, and offscreen rendering.
2353 dnl Surfaceless is an alternative for the last one.
2354 dnl
2355 require_basic_egl() {
2356     case "$with_platforms" in
2357         *drm*|*surfaceless*)
2358             ;;
2359         *)
2360             AC_MSG_ERROR([$1 requires one of these:
2361                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2362                   2) --with-platforms=surfaceless (offscreen only)
2363                   Recommended options: drm,x11])
2364             ;;
2365     esac
2366 }
2367
2368 swr_require_cxx_feature_flags() {
2369     feature_name="$1"
2370     preprocessor_test="$2"
2371     option_list="$3"
2372     output_var="$4"
2373
2374     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2375     AC_LANG_PUSH([C++])
2376     save_CXXFLAGS="$CXXFLAGS"
2377     save_IFS="$IFS"
2378     IFS=","
2379     found=0
2380     for opts in $option_list
2381     do
2382         unset IFS
2383         CXXFLAGS="$opts $save_CXXFLAGS"
2384         AC_COMPILE_IFELSE(
2385             [AC_LANG_PROGRAM(
2386                 [   #if !($preprocessor_test)
2387                     #error
2388                     #endif
2389                 ])],
2390             [found=1; break],
2391             [])
2392         IFS=","
2393     done
2394     IFS="$save_IFS"
2395     CXXFLAGS="$save_CXXFLAGS"
2396     AC_LANG_POP([C++])
2397     if test $found -eq 1; then
2398         AC_MSG_RESULT([$opts])
2399         eval "$output_var=\$opts"
2400         return 0
2401     fi
2402     AC_MSG_RESULT([no])
2403     AC_MSG_ERROR([swr requires $feature_name support])
2404     return 1
2405 }
2406
2407 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2408 if test -n "$with_gallium_drivers"; then
2409     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2410     for driver in $gallium_drivers; do
2411         case "x$driver" in
2412         xsvga)
2413             HAVE_GALLIUM_SVGA=yes
2414             require_libdrm "svga"
2415             ;;
2416         xi915)
2417             HAVE_GALLIUM_I915=yes
2418             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2419             require_libdrm "Gallium i915"
2420             ;;
2421         xr300)
2422             HAVE_GALLIUM_R300=yes
2423             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2424             require_libdrm "r300"
2425             r300_require_llvm "r300"
2426             ;;
2427         xr600)
2428             HAVE_GALLIUM_R600=yes
2429             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2430             require_libdrm "r600"
2431             if test "x$enable_llvm" = xyes; then
2432                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2433
2434                 llvm_add_component "asmparser" "r600"
2435                 llvm_add_component "bitreader" "r600"
2436             fi
2437             ;;
2438         xradeonsi)
2439             HAVE_GALLIUM_RADEONSI=yes
2440             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2441             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2442             require_libdrm "radeonsi"
2443             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2444             if test "x$enable_egl" = xyes; then
2445                 require_basic_egl "radeonsi"
2446             fi
2447             ;;
2448         xnouveau)
2449             HAVE_GALLIUM_NOUVEAU=yes
2450             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2451             require_libdrm "nouveau"
2452             ;;
2453         xfreedreno)
2454             HAVE_GALLIUM_FREEDRENO=yes
2455             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2456             require_libdrm "freedreno"
2457             ;;
2458         xetnaviv)
2459             HAVE_GALLIUM_ETNAVIV=yes
2460             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2461             require_libdrm "etnaviv"
2462             ;;
2463        ximx)
2464             HAVE_GALLIUM_IMX=yes
2465             ;;
2466         xswrast)
2467             HAVE_GALLIUM_SOFTPIPE=yes
2468             if test "x$enable_llvm" = xyes; then
2469                 HAVE_GALLIUM_LLVMPIPE=yes
2470             fi
2471             ;;
2472         xswr)
2473             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2474
2475             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2476                 "-std=c++14" \
2477                 SWR_CXX14_CXXFLAGS
2478             AC_SUBST([SWR_CXX14_CXXFLAGS])
2479
2480             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2481                 ",-mavx,-march=core-avx" \
2482                 SWR_AVX_CXXFLAGS
2483             AC_SUBST([SWR_AVX_CXXFLAGS])
2484
2485             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2486                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2487                 SWR_AVX2_CXXFLAGS
2488             AC_SUBST([SWR_AVX2_CXXFLAGS])
2489
2490             HAVE_GALLIUM_SWR=yes
2491             ;;
2492         xvc4)
2493             HAVE_GALLIUM_VC4=yes
2494             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2495             require_libdrm "vc4"
2496
2497             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2498                               [USE_VC4_SIMULATOR=yes;
2499                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2500                               [USE_VC4_SIMULATOR=no])
2501             ;;
2502         xvirgl)
2503             HAVE_GALLIUM_VIRGL=yes
2504             require_libdrm "virgl"
2505             if test "x$enable_egl" = xyes; then
2506                 require_basic_egl "virgl"
2507             fi
2508             ;;
2509         *)
2510             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2511             ;;
2512         esac
2513     done
2514 fi
2515
2516 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2517 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2518                                               "x$LLVM_VERSION" != x3.9.1)
2519
2520 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2521     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2522     llvm_add_default_components "gallium"
2523 fi
2524
2525 dnl We need to validate some needed dependencies for renderonly drivers.
2526
2527 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2528     AC_MSG_ERROR([Building with imx requires etnaviv])
2529 fi
2530
2531 dnl
2532 dnl Set defines and buildtime variables only when using LLVM.
2533 dnl
2534 if test "x$enable_llvm" = xyes; then
2535     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2536
2537     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2538     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2539     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2540
2541     dnl Set LLVM_LIBS - This is done after the driver configuration so
2542     dnl that drivers can add additional components to LLVM_COMPONENTS.
2543     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2544     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2545     dnl this was causing the same libraries to be appear multiple times
2546     dnl in LLVM_LIBS.
2547
2548     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2549        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2550     fi
2551     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2552
2553     dnl llvm-config may not give the right answer when llvm is a built as a
2554     dnl single shared library, so we must work the library name out for
2555     dnl ourselves.
2556     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2557     if test "x$enable_llvm_shared_libs" = xyes; then
2558         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2559         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2560         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2561
2562         if test "x$llvm_have_one_so" = xyes; then
2563             dnl LLVM was built using auto*, so there is only one shared object.
2564             LLVM_LIBS="-l$LLVM_SO_NAME"
2565         else
2566             dnl If LLVM was built with CMake, there will be one shared object per
2567             dnl component.
2568             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2569                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2570         Please make sure you have built llvm with the --enable-shared option
2571         and that your llvm libraries are installed in $LLVM_LIBDIR
2572         If you have installed your llvm libraries to a different directory you
2573         can use the --with-llvm-prefix= configure flag to specify this directory.
2574         NOTE: Mesa is attempting to use llvm shared libraries by default.
2575         If you do not want to build with llvm shared libraries and instead want to
2576         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2577         invocation and rebuild.])])
2578
2579            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2580            dnl install uses a shared object for each component and we have
2581            dnl already added all of these objects to LLVM_LIBS.
2582         fi
2583     else
2584         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2585         dnl We need to link to llvm system libs when using static libs
2586         dnl However, only llvm 3.5+ provides --system-libs
2587         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2588             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2589         fi
2590     fi
2591 fi
2592
2593 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2594 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2595 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2596 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2597 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2598 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2599                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2600 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2601 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2602 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2603 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2604 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2605 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2606 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2608                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2609                                          "x$HAVE_GALLIUM_SWR" = xyes)
2610 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2612
2613 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2614
2615 if test "x$enable_dri" = xyes; then
2616     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2617 fi
2618
2619 if test "x$have_drisw_kms" = xyes; then
2620     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2621 fi
2622 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2623
2624 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2625 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2626 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2627 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2628 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2629 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2630
2631 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2632 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2633
2634 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2635                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2636                                       "x$HAVE_RADEON_VULKAN" = xyes)
2637
2638 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2639                                         "x$HAVE_I965_DRI" = xyes)
2640
2641 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2642                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2643                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2644 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2645 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2646 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2647 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2648
2649 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2650 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2651 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2652 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2653                                         "x$enable_gallium_osmesa" = xyes)
2654
2655 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2656 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2657 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2658
2659 AC_SUBST([NINE_MAJOR], 1)
2660 AC_SUBST([NINE_MINOR], 0)
2661 AC_SUBST([NINE_TINY], 0)
2662 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2663
2664 AC_SUBST([VDPAU_MAJOR], 1)
2665 AC_SUBST([VDPAU_MINOR], 0)
2666
2667 if test "x$enable_va" = xyes; then
2668     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2669     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2670 fi
2671 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2672 AC_SUBST([VA_MINOR], $VA_MINOR)
2673
2674 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2675
2676 AC_SUBST([XVMC_MAJOR], 1)
2677 AC_SUBST([XVMC_MINOR], 0)
2678
2679 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2680 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2681 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2682 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2683
2684 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2685 AC_SUBST([XA_MINOR], $XA_MINOR)
2686 AC_SUBST([XA_TINY], $XA_TINY)
2687 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2688
2689 AC_ARG_ENABLE(valgrind,
2690               [AS_HELP_STRING([--enable-valgrind],
2691                              [Build mesa with valgrind support (default: auto)])],
2692                              [VALGRIND=$enableval], [VALGRIND=auto])
2693 if test "x$VALGRIND" != xno; then
2694         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2695 fi
2696 AC_MSG_CHECKING([whether to enable Valgrind support])
2697 if test "x$VALGRIND" = xauto; then
2698         VALGRIND="$have_valgrind"
2699 fi
2700
2701 if test "x$VALGRIND" = "xyes"; then
2702         if ! test "x$have_valgrind" = xyes; then
2703                 AC_MSG_ERROR([Valgrind support required but not present])
2704         fi
2705         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2706 fi
2707
2708 AC_MSG_RESULT([$VALGRIND])
2709
2710 dnl Restore LDFLAGS and CPPFLAGS
2711 LDFLAGS="$_SAVE_LDFLAGS"
2712 CPPFLAGS="$_SAVE_CPPFLAGS"
2713
2714 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2715 if test "x$acv_mesa_CLANG" = xyes; then
2716     CFLAGS="$CFLAGS -Qunused-arguments"
2717     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2718 fi
2719
2720 dnl Add user CFLAGS and CXXFLAGS
2721 CFLAGS="$CFLAGS $USER_CFLAGS"
2722 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2723
2724 dnl Substitute the config
2725 AC_CONFIG_FILES([Makefile
2726                 src/Makefile
2727                 src/amd/Makefile
2728                 src/amd/vulkan/Makefile
2729                 src/compiler/Makefile
2730                 src/egl/Makefile
2731                 src/egl/main/egl.pc
2732                 src/egl/wayland/wayland-drm/Makefile
2733                 src/egl/wayland/wayland-egl/Makefile
2734                 src/egl/wayland/wayland-egl/wayland-egl.pc
2735                 src/gallium/Makefile
2736                 src/gallium/auxiliary/Makefile
2737                 src/gallium/auxiliary/pipe-loader/Makefile
2738                 src/gallium/drivers/freedreno/Makefile
2739                 src/gallium/drivers/ddebug/Makefile
2740                 src/gallium/drivers/i915/Makefile
2741                 src/gallium/drivers/llvmpipe/Makefile
2742                 src/gallium/drivers/noop/Makefile
2743                 src/gallium/drivers/nouveau/Makefile
2744                 src/gallium/drivers/r300/Makefile
2745                 src/gallium/drivers/r600/Makefile
2746                 src/gallium/drivers/radeon/Makefile
2747                 src/gallium/drivers/radeonsi/Makefile
2748                 src/gallium/drivers/rbug/Makefile
2749                 src/gallium/drivers/softpipe/Makefile
2750                 src/gallium/drivers/svga/Makefile
2751                 src/gallium/drivers/swr/Makefile
2752                 src/gallium/drivers/trace/Makefile
2753                 src/gallium/drivers/etnaviv/Makefile
2754                 src/gallium/drivers/imx/Makefile
2755                 src/gallium/drivers/vc4/Makefile
2756                 src/gallium/drivers/virgl/Makefile
2757                 src/gallium/state_trackers/clover/Makefile
2758                 src/gallium/state_trackers/dri/Makefile
2759                 src/gallium/state_trackers/glx/xlib/Makefile
2760                 src/gallium/state_trackers/nine/Makefile
2761                 src/gallium/state_trackers/omx/Makefile
2762                 src/gallium/state_trackers/osmesa/Makefile
2763                 src/gallium/state_trackers/va/Makefile
2764                 src/gallium/state_trackers/vdpau/Makefile
2765                 src/gallium/state_trackers/xa/Makefile
2766                 src/gallium/state_trackers/xvmc/Makefile
2767                 src/gallium/targets/d3dadapter9/Makefile
2768                 src/gallium/targets/d3dadapter9/d3d.pc
2769                 src/gallium/targets/dri/Makefile
2770                 src/gallium/targets/libgl-xlib/Makefile
2771                 src/gallium/targets/omx/Makefile
2772                 src/gallium/targets/opencl/Makefile
2773                 src/gallium/targets/opencl/mesa.icd
2774                 src/gallium/targets/osmesa/Makefile
2775                 src/gallium/targets/osmesa/osmesa.pc
2776                 src/gallium/targets/pipe-loader/Makefile
2777                 src/gallium/targets/va/Makefile
2778                 src/gallium/targets/vdpau/Makefile
2779                 src/gallium/targets/xa/Makefile
2780                 src/gallium/targets/xa/xatracker.pc
2781                 src/gallium/targets/xvmc/Makefile
2782                 src/gallium/tests/trivial/Makefile
2783                 src/gallium/tests/unit/Makefile
2784                 src/gallium/winsys/etnaviv/drm/Makefile
2785                 src/gallium/winsys/imx/drm/Makefile
2786                 src/gallium/winsys/freedreno/drm/Makefile
2787                 src/gallium/winsys/i915/drm/Makefile
2788                 src/gallium/winsys/nouveau/drm/Makefile
2789                 src/gallium/winsys/radeon/drm/Makefile
2790                 src/gallium/winsys/amdgpu/drm/Makefile
2791                 src/gallium/winsys/svga/drm/Makefile
2792                 src/gallium/winsys/sw/dri/Makefile
2793                 src/gallium/winsys/sw/kms-dri/Makefile
2794                 src/gallium/winsys/sw/null/Makefile
2795                 src/gallium/winsys/sw/wrapper/Makefile
2796                 src/gallium/winsys/sw/xlib/Makefile
2797                 src/gallium/winsys/vc4/drm/Makefile
2798                 src/gallium/winsys/virgl/drm/Makefile
2799                 src/gallium/winsys/virgl/vtest/Makefile
2800                 src/gbm/Makefile
2801                 src/gbm/main/gbm.pc
2802                 src/glx/Makefile
2803                 src/glx/apple/Makefile
2804                 src/glx/tests/Makefile
2805                 src/glx/windows/Makefile
2806                 src/glx/windows/windowsdriproto.pc
2807                 src/gtest/Makefile
2808                 src/intel/Makefile
2809                 src/loader/Makefile
2810                 src/mapi/Makefile
2811                 src/mapi/es1api/glesv1_cm.pc
2812                 src/mapi/es2api/glesv2.pc
2813                 src/mapi/glapi/gen/Makefile
2814                 src/mesa/Makefile
2815                 src/mesa/gl.pc
2816                 src/mesa/drivers/dri/dri.pc
2817                 src/mesa/drivers/dri/common/Makefile
2818                 src/mesa/drivers/dri/common/xmlpool/Makefile
2819                 src/mesa/drivers/dri/i915/Makefile
2820                 src/mesa/drivers/dri/i965/Makefile
2821                 src/mesa/drivers/dri/Makefile
2822                 src/mesa/drivers/dri/nouveau/Makefile
2823                 src/mesa/drivers/dri/r200/Makefile
2824                 src/mesa/drivers/dri/radeon/Makefile
2825                 src/mesa/drivers/dri/swrast/Makefile
2826                 src/mesa/drivers/osmesa/Makefile
2827                 src/mesa/drivers/osmesa/osmesa.pc
2828                 src/mesa/drivers/x11/Makefile
2829                 src/mesa/main/tests/Makefile
2830                 src/util/Makefile
2831                 src/util/tests/hash_table/Makefile
2832                 src/vulkan/Makefile])
2833
2834 AC_OUTPUT
2835
2836 # Fix up dependencies in *.Plo files, where we changed the extension of a
2837 # source file
2838 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2839
2840
2841 dnl
2842 dnl Output some configuration info for the user
2843 dnl
2844 echo ""
2845 echo "        prefix:          $prefix"
2846 echo "        exec_prefix:     $exec_prefix"
2847 echo "        libdir:          $libdir"
2848 echo "        includedir:      $includedir"
2849
2850 dnl API info
2851 echo ""
2852 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2853
2854 dnl Driver info
2855 echo ""
2856 case "x$enable_osmesa$enable_gallium_osmesa" in
2857 xnoyes)
2858         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2859         ;;
2860 xyesno)
2861         echo "        OSMesa:          lib$OSMESA_LIB"
2862         ;;
2863 xnono)
2864         echo "        OSMesa:          no"
2865         ;;
2866 esac
2867
2868 echo ""
2869 if test "x$enable_dri" != xno; then
2870         echo "        DRI platform:    $dri_platform"
2871         if test -z "$DRI_DIRS"; then
2872             echo "        DRI drivers:     no"
2873         else
2874             echo "        DRI drivers:     $DRI_DIRS"
2875         fi
2876         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2877 fi
2878
2879 case "x$enable_glx" in
2880 xdri)
2881     echo "        GLX:             DRI-based"
2882     ;;
2883 xxlib)
2884     echo "        GLX:             Xlib-based"
2885     ;;
2886 xgallium-xlib)
2887     echo "        GLX:             Xlib-based (Gallium)"
2888     ;;
2889 *)
2890     echo "        GLX:             $enable_glx"
2891     ;;
2892 esac
2893
2894 dnl EGL
2895 echo ""
2896 echo "        EGL:             $enable_egl"
2897 if test "$enable_egl" = yes; then
2898
2899     egl_drivers=""
2900     if test "x$enable_dri" != "xno"; then
2901         egl_drivers="$egl_drivers builtin:egl_dri2"
2902     fi
2903     if test "x$enable_dri3" != "xno"; then
2904         egl_drivers="$egl_drivers builtin:egl_dri3"
2905     fi
2906
2907     echo "        EGL drivers:    $egl_drivers"
2908 fi
2909 if test "x$enable_gbm" = xyes; then
2910     echo "        GBM:             yes"
2911 else
2912     echo "        GBM:             no"
2913 fi
2914
2915     echo "        EGL/Vulkan/VL platforms:   $platforms"
2916
2917 # Vulkan
2918 echo ""
2919 if test "x$VULKAN_DRIVERS" != x; then
2920     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2921     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2922 else
2923     echo "        Vulkan drivers:  no"
2924 fi
2925
2926 echo ""
2927 if test "x$enable_llvm" = xyes; then
2928     echo "        llvm:            yes"
2929     echo "        llvm-config:     $LLVM_CONFIG"
2930     echo "        llvm-version:    $LLVM_VERSION"
2931 else
2932     echo "        llvm:            no"
2933 fi
2934
2935 echo ""
2936 if test -n "$with_gallium_drivers"; then
2937     echo "        Gallium drivers: $gallium_drivers"
2938     echo "        Gallium st:      $gallium_st"
2939 else
2940     echo "        Gallium:         no"
2941 fi
2942
2943 echo ""
2944 if test "x$enable_gallium_extra_hud" != xyes; then
2945     echo "        HUD extra stats: no"
2946 else
2947     echo "        HUD extra stats: yes"
2948 fi
2949
2950 if test "x$enable_lmsensors" != xyes; then
2951     echo "        HUD lmsensors:   no"
2952 else
2953     echo "        HUD lmsensors:   yes"
2954 fi
2955
2956 dnl Libraries
2957 echo ""
2958 echo "        Shared libs:     $enable_shared"
2959 echo "        Static libs:     $enable_static"
2960 echo "        Shared-glapi:    $enable_shared_glapi"
2961
2962 dnl Compiler options
2963 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2964 cflags=`echo $CFLAGS | \
2965     $SED 's/^ *//;s/  */ /;s/ *$//'`
2966 cxxflags=`echo $CXXFLAGS | \
2967     $SED 's/^ *//;s/  */ /;s/ *$//'`
2968 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2969 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2970 echo ""
2971 echo "        CFLAGS:          $cflags"
2972 echo "        CXXFLAGS:        $cxxflags"
2973 echo "        LDFLAGS:         $ldflags"
2974 echo "        Macros:          $defines"
2975 echo ""
2976 if test "x$enable_llvm" = xyes; then
2977     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2978     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2979     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2980     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2981     echo ""
2982 fi
2983 echo "        PYTHON2:         $PYTHON2"
2984
2985 echo ""
2986 echo "        Run '${MAKE-make}' to build Mesa"
2987 echo ""