configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.81
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 XCB_REQUIRED=1.9.3
  92 XCBDRI2_REQUIRED=1.8
  93 XCBGLX_REQUIRED=1.8.1
  94 XDAMAGE_REQUIRED=1.1
  95 XSHMFENCE_REQUIRED=1.1
  96 XVMC_REQUIRED=1.0.6
  97 PYTHON_MAKO_REQUIRED=0.8.0
  98 LIBSENSORS_REQUIRED=4.0.0
  99 ZLIB_REQUIRED=1.2.3
 100
 101 dnl LLVM versions
 102 LLVM_REQUIRED_GALLIUM=3.3.0
 103 LLVM_REQUIRED_OPENCL=3.6.0
 104 LLVM_REQUIRED_R600=3.9.0
 105 LLVM_REQUIRED_RADEONSI=3.9.0
 106 LLVM_REQUIRED_RADV=3.9.0
 107 LLVM_REQUIRED_SWR=3.9.0
 108
 109 dnl Check for progs
 110 AC_PROG_CPP
 111 AC_PROG_CC
 112 AC_PROG_CXX
 113 AM_PROG_CC_C_O
 114 AM_PROG_AS
 115 AX_CHECK_GNU_MAKE
 116 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 117 AC_PROG_SED
 118 AC_PROG_MKDIR_P
 119
 120 AC_SYS_LARGEFILE
 121
 122 LT_PREREQ([2.2])
 123 LT_INIT([disable-static])
 124
 125 AC_CHECK_PROG(RM, rm, [rm -f])
 126
 127 AX_PROG_BISON([],
 128               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 129                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 130 AX_PROG_FLEX([],
 131              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 132                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 133
 134 AC_CHECK_PROG(INDENT, indent, indent, cat)
 135 if test "x$INDENT" != "xcat"; then
 136     # Only GNU indent is supported
 137     INDENT_VERSION=`indent --version | grep GNU`
 138     if test $? -eq 0; then
 139        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 140     else
 141        INDENT="cat"
 142     fi
 143 fi
 144
 145 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 146
 147 if test -z "$PYTHON2"; then
 148     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 149         AC_MSG_ERROR([Python not found - unable to generate sources])
 150     fi
 151 else
 152     if test "x$acv_mako_found" = xno; then
 153         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 154             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 155         fi
 156     fi
 157 fi
 158
 159 AC_PROG_INSTALL
 160
 161 dnl We need a POSIX shell for parts of the build. Assume we have one
 162 dnl in most cases.
 163 case "$host_os" in
 164 solaris*)
 165     # Solaris /bin/sh is too old/non-POSIX compliant
 166     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 167     SHELL="$POSIX_SHELL"
 168     ;;
 169 esac
 170
 171 dnl clang is mostly GCC-compatible, but its version is much lower,
 172 dnl so we have to check for it.
 173 AC_MSG_CHECKING([if compiling with clang])
 174
 175 AC_COMPILE_IFELSE(
 176 [AC_LANG_PROGRAM([], [[
 177 #ifndef __clang__
 178        not clang
 179 #endif
 180 ]])],
 181 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 182
 183 AC_MSG_RESULT([$acv_mesa_CLANG])
 184
 185 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 186 dnl versions are explictly not supported.
 187 GEN_ASM_OFFSETS=no
 188 USE_GNU99=no
 189 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 190     AC_MSG_CHECKING([whether gcc version is sufficient])
 191     major=0
 192     minor=0
 193
 194     GCC_VERSION=`$CC -dumpversion`
 195     if test $? -eq 0; then
 196         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 197         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 198     fi
 199
 200     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 201         AC_MSG_RESULT([no])
 202         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 203     else
 204         AC_MSG_RESULT([yes])
 205     fi
 206
 207     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 208         USE_GNU99=yes
 209     fi
 210     if test "x$cross_compiling" = xyes; then
 211         GEN_ASM_OFFSETS=yes
 212     fi
 213 fi
 214
 215 dnl We don't support building Mesa with Sun C compiler
 216 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 217 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 218 if test "x$SUNCC" = xyes; then
 219     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 220 fi
 221
 222 dnl Check for compiler builtins
 223 AX_GCC_BUILTIN([__builtin_bswap32])
 224 AX_GCC_BUILTIN([__builtin_bswap64])
 225 AX_GCC_BUILTIN([__builtin_clz])
 226 AX_GCC_BUILTIN([__builtin_clzll])
 227 AX_GCC_BUILTIN([__builtin_ctz])
 228 AX_GCC_BUILTIN([__builtin_expect])
 229 AX_GCC_BUILTIN([__builtin_ffs])
 230 AX_GCC_BUILTIN([__builtin_ffsll])
 231 AX_GCC_BUILTIN([__builtin_popcount])
 232 AX_GCC_BUILTIN([__builtin_popcountll])
 233 AX_GCC_BUILTIN([__builtin_unreachable])
 234
 235 AX_GCC_FUNC_ATTRIBUTE([const])
 236 AX_GCC_FUNC_ATTRIBUTE([flatten])
 237 AX_GCC_FUNC_ATTRIBUTE([format])
 238 AX_GCC_FUNC_ATTRIBUTE([malloc])
 239 AX_GCC_FUNC_ATTRIBUTE([packed])
 240 AX_GCC_FUNC_ATTRIBUTE([pure])
 241 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 242 AX_GCC_FUNC_ATTRIBUTE([unused])
 243 AX_GCC_FUNC_ATTRIBUTE([visibility])
 244 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 245 AX_GCC_FUNC_ATTRIBUTE([weak])
 246 AX_GCC_FUNC_ATTRIBUTE([alias])
 247
 248 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 249
 250 dnl Make sure the pkg-config macros are defined
 251 m4_ifndef([PKG_PROG_PKG_CONFIG],
 252     [m4_fatal([Could not locate the pkg-config autoconf macros.
 253   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 254   are in a different location, try setting the environment variable
 255   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 256 PKG_PROG_PKG_CONFIG()
 257
 258 dnl LIB_DIR - library basename
 259 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 260 AC_SUBST([LIB_DIR])
 261
 262 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 263 _SAVE_LDFLAGS="$LDFLAGS"
 264 _SAVE_CPPFLAGS="$CPPFLAGS"
 265
 266 dnl Compiler macros
 267 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 268 AC_SUBST([DEFINES])
 269 android=no
 270 case "$host_os" in
 271 *-android*)
 272     android=yes
 273     ;;
 274 linux*|*-gnu*|gnu*|cygwin*)
 275     DEFINES="$DEFINES -D_GNU_SOURCE"
 276     ;;
 277 solaris*)
 278     DEFINES="$DEFINES -DSVR4"
 279     ;;
 280 esac
 281
 282 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 283
 284 dnl Add flags for gcc and g++
 285 if test "x$GCC" = xyes; then
 286     CFLAGS="$CFLAGS -Wall"
 287
 288     if test "x$USE_GNU99" = xyes; then
 289         CFLAGS="$CFLAGS -std=gnu99"
 290     else
 291         CFLAGS="$CFLAGS -std=c99"
 292     fi
 293
 294     # Enable -Werror=implicit-function-declaration and
 295     # -Werror=missing-prototypes, if available, or otherwise, just
 296     # -Wmissing-prototypes.  This is particularly useful to avoid
 297     # generating a loadable driver module that has undefined symbols.
 298     save_CFLAGS="$CFLAGS"
 299     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 300     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 301     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 302     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 303                    AC_MSG_RESULT([yes]),
 304                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 305                     AC_MSG_RESULT([no])])
 306
 307     # Enable -fvisibility=hidden if using a gcc that supports it
 308     save_CFLAGS="$CFLAGS"
 309     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 310     VISIBILITY_CFLAGS="-fvisibility=hidden"
 311     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 312     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 313                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 314
 315     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 316     CFLAGS=$save_CFLAGS
 317
 318     # We don't want floating-point math functions to set errno or trap
 319     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 320
 321     # Flags to help ensure that certain portions of the code -- and only those
 322     # portions -- can be built with MSVC:
 323     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 324     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 325     #   supports most of C99)
 326     # - the rest has no compiler compiler restrictions
 327     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 328     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 329
 330     # Enable -Werror=vla if compiler supports it
 331     save_CFLAGS="$CFLAGS"
 332     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 333     CFLAGS="$CFLAGS -Werror=vla"
 334     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 335                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 336                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 337                     AC_MSG_RESULT([yes])],
 338                     AC_MSG_RESULT([no]))
 339     CFLAGS="$save_CFLAGS"
 340 fi
 341 if test "x$GXX" = xyes; then
 342     CXXFLAGS="$CXXFLAGS -Wall"
 343
 344     # Enable -fvisibility=hidden if using a gcc that supports it
 345     save_CXXFLAGS="$CXXFLAGS"
 346     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 347     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 348     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 349     AC_LANG_PUSH([C++])
 350     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 351                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 352     AC_LANG_POP([C++])
 353
 354     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 355     CXXFLAGS=$save_CXXFLAGS
 356
 357     # We don't want floating-point math functions to set errno or trap
 358     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 359 fi
 360
 361 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 362 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 363
 364 dnl even if the compiler appears to support it, using visibility attributes isn't
 365 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 366 case "$host_os" in
 367 cygwin*)
 368     VISIBILITY_CFLAGS=""
 369     VISIBILITY_CXXFLAGS=""
 370     ;;
 371 esac
 372
 373 AC_SUBST([VISIBILITY_CFLAGS])
 374 AC_SUBST([VISIBILITY_CXXFLAGS])
 375
 376 dnl
 377 dnl Optional flags, check for compiler support
 378 dnl
 379 SSE41_CFLAGS="-msse4.1"
 380 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 381 dnl stack, but on x86-32 such alignment is not guaranteed.
 382 case "$target_cpu" in
 383 i?86)
 384     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 385     ;;
 386 esac
 387 save_CFLAGS="$CFLAGS"
 388 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 389 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 390 #include <smmintrin.h>
 391 int param;
 392 int main () {
 393     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 394     c = _mm_max_epu32(a, b);
 395     return _mm_cvtsi128_si32(c);
 396 }]])], SSE41_SUPPORTED=1)
 397 CFLAGS="$save_CFLAGS"
 398 if test "x$SSE41_SUPPORTED" = x1; then
 399     DEFINES="$DEFINES -DUSE_SSE41"
 400 fi
 401 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 402 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 403
 404 dnl Check for new-style atomic builtins
 405 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 406 int main() {
 407     int n;
 408     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 409 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 410 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 411     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 412 fi
 413 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 414
 415 dnl Check if host supports 64-bit atomics
 416 dnl note that lack of support usually results in link (not compile) error
 417 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 418 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 419 #include <stdint.h>
 420 uint64_t v;
 421 int main() {
 422     return __sync_add_and_fetch(&v, (uint64_t)1);
 423 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 424 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 425     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 426 fi
 427 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 428
 429 dnl Check for Endianness
 430 AC_C_BIGENDIAN(
 431    little_endian=no,
 432    little_endian=yes,
 433    little_endian=no,
 434    little_endian=no
 435 )
 436
 437 dnl Check for POWER8 Architecture
 438 PWR8_CFLAGS="-mpower8-vector"
 439 have_pwr8_intrinsics=no
 440 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 441 save_CFLAGS=$CFLAGS
 442 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 443 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 444 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 445 #error "Need GCC >= 4.8 for sane POWER8 support"
 446 #endif
 447 #include <altivec.h>
 448 int main () {
 449     vector unsigned char r;
 450     vector unsigned int v = vec_splat_u32 (1);
 451     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 452     return 0;
 453 }]])], have_pwr8_intrinsics=yes)
 454 CFLAGS=$save_CFLAGS
 455
 456 AC_ARG_ENABLE(pwr8,
 457    [AS_HELP_STRING([--disable-pwr8],
 458                    [disable POWER8-specific instructions])],
 459    [enable_pwr8=$enableval], [enable_pwr8=auto])
 460
 461 if test "x$enable_pwr8" = xno ; then
 462    have_pwr8_intrinsics=disabled
 463 fi
 464
 465 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 466    DEFINES="$DEFINES -D_ARCH_PWR8"
 467    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 468    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 469 else
 470    PWR8_CFLAGS=
 471 fi
 472
 473 AC_MSG_RESULT($have_pwr8_intrinsics)
 474 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 475    AC_MSG_ERROR([POWER8 compiler support not detected])
 476 fi
 477
 478 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 479    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 480 fi
 481
 482 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 483
 484 dnl Can't have static and shared libraries, default to static if user
 485 dnl explicitly requested. If both disabled, set to static since shared
 486 dnl was explicitly requested.
 487 case "x$enable_static$enable_shared" in
 488 xyesyes)
 489     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 490     ;;
 491 xnono)
 492     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 493     ;;
 494 esac
 495
 496 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 497
 498 dnl
 499 dnl other compiler options
 500 dnl
 501 AC_ARG_ENABLE([debug],
 502     [AS_HELP_STRING([--enable-debug],
 503         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 504     [enable_debug="$enableval"],
 505     [enable_debug=no]
 506 )
 507
 508 AC_ARG_ENABLE([profile],
 509     [AS_HELP_STRING([--enable-profile],
 510         [enable profiling of code @<:@default=disabled@:>@])],
 511     [enable_profile="$enableval"],
 512     [enable_profile=no]
 513 )
 514
 515 AC_ARG_ENABLE([sanitize],
 516     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 517         [enable code sanitizer @<:@default=disabled@:>@])],
 518     [enable_sanitize="$enableval"],
 519     [enable_sanitize=no])
 520
 521 if test "x$enable_profile" = xyes; then
 522     DEFINES="$DEFINES -DPROFILE"
 523     if test "x$GCC" = xyes; then
 524         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 525     fi
 526     if test "x$GXX" = xyes; then
 527         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 528     fi
 529 fi
 530
 531 if test "x$enable_debug" = xyes; then
 532     DEFINES="$DEFINES -DDEBUG"
 533     if test "x$enable_profile" = xyes; then
 534         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 535     fi
 536     if test "x$GCC" = xyes; then
 537         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 538             CFLAGS="$CFLAGS -g"
 539         fi
 540         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 541             CFLAGS="$CFLAGS -O0"
 542         fi
 543     fi
 544     if test "x$GXX" = xyes; then
 545         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 546             CXXFLAGS="$CXXFLAGS -g"
 547         fi
 548         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 549             CXXFLAGS="$CXXFLAGS -O0"
 550         fi
 551     fi
 552 else
 553    DEFINES="$DEFINES -DNDEBUG"
 554 fi
 555
 556 if test "x$enable_sanitize" != xno; then
 557     if test "x$enable_profile" = xyes; then
 558         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 559     fi
 560
 561     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 562     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 563     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 564
 565     AC_LINK_IFELSE(
 566         [AC_LANG_SOURCE([int main(){return 0;}])],
 567         [],
 568         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 569 fi
 570
 571 dnl
 572 dnl Check if linker supports -Bsymbolic
 573 dnl
 574 save_LDFLAGS=$LDFLAGS
 575 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 576 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 577 AC_LINK_IFELSE(
 578     [AC_LANG_SOURCE([int main() { return 0;}])],
 579     [AC_MSG_RESULT([yes])
 580         BSYMBOLIC="-Wl,-Bsymbolic";],
 581     [AC_MSG_RESULT([no])
 582         BSYMBOLIC="";])
 583 LDFLAGS=$save_LDFLAGS
 584
 585 AC_SUBST([BSYMBOLIC])
 586
 587 dnl
 588 dnl Check if linker supports garbage collection
 589 dnl
 590 save_LDFLAGS=$LDFLAGS
 591 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 592 AC_MSG_CHECKING([whether ld supports --gc-sections])
 593 AC_LINK_IFELSE(
 594     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 595     [AC_MSG_RESULT([yes])
 596         GC_SECTIONS="-Wl,--gc-sections";],
 597     [AC_MSG_RESULT([no])
 598         GC_SECTIONS="";])
 599 LDFLAGS=$save_LDFLAGS
 600
 601 AC_SUBST([GC_SECTIONS])
 602
 603 dnl
 604 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 605 dnl so when these flags are passed to ld via libtool the checks will fail
 606 dnl
 607 case "$host_os" in
 608 openbsd* | darwin* )
 609     LD_NO_UNDEFINED="" ;;
 610 *)
 611     if test "x$enable_sanitize" = xno; then
 612         LD_NO_UNDEFINED="-Wl,--no-undefined"
 613     else
 614         LD_NO_UNDEFINED=""
 615     fi
 616     ;;
 617 esac
 618
 619 AC_SUBST([LD_NO_UNDEFINED])
 620
 621 dnl
 622 dnl Check if linker supports version scripts
 623 dnl
 624 AC_MSG_CHECKING([if the linker supports version-scripts])
 625 save_LDFLAGS=$LDFLAGS
 626 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 627 cat > conftest.map <<EOF
 628 VERSION_1 {
 629      global:
 630          main;
 631
 632      local:
 633          *;
 634 };
 635 EOF
 636 AC_LINK_IFELSE(
 637     [AC_LANG_SOURCE([int main() { return 0;}])],
 638     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 639     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 640 LDFLAGS=$save_LDFLAGS
 641 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 642
 643 dnl
 644 dnl Check if linker supports dynamic list files
 645 dnl
 646 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 647 save_LDFLAGS=$LDFLAGS
 648 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 649 cat > conftest.dyn <<EOF
 650 {
 651         radeon_drm_winsys_create;
 652 };
 653 EOF
 654 AC_LINK_IFELSE(
 655     [AC_LANG_SOURCE([int main() { return 0;}])],
 656     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 657     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 658 LDFLAGS=$save_LDFLAGS
 659 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 660
 661 dnl
 662 dnl compatibility symlinks
 663 dnl
 664 case "$host_os" in
 665 linux* )
 666     HAVE_COMPAT_SYMLINKS=yes ;;
 667 * )
 668     HAVE_COMPAT_SYMLINKS=no ;;
 669 esac
 670
 671 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 672
 673 dnl
 674 dnl library names
 675 dnl
 676 dnl Unfortunately we need to do a few things that libtool can't help us with,
 677 dnl so we need some knowledge of shared library filenames:
 678 dnl
 679 dnl LIB_EXT is the extension used when creating symlinks for alternate
 680 dnl filenames for a shared library which will be dynamically loaded
 681 dnl
 682 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 683 dnl the file for a shared library we wish to link with
 684 dnl
 685 case "$host_os" in
 686 darwin* )
 687     LIB_EXT='dylib'
 688     IMP_LIB_EXT=$LIB_EXT
 689     ;;
 690 cygwin* )
 691     LIB_EXT='dll'
 692     IMP_LIB_EXT='dll.a'
 693     ;;
 694 aix* )
 695     LIB_EXT='a'
 696     IMP_LIB_EXT=$LIB_EXT
 697     ;;
 698 * )
 699     LIB_EXT='so'
 700     IMP_LIB_EXT=$LIB_EXT
 701     ;;
 702 esac
 703
 704 AC_SUBST([LIB_EXT])
 705
 706 dnl
 707 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 708 dnl
 709 AC_ARG_ENABLE([texture-float],
 710     [AS_HELP_STRING([--enable-texture-float],
 711         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 712     [enable_texture_float="$enableval"],
 713     [enable_texture_float=no]
 714 )
 715 if test "x$enable_texture_float" = xyes; then
 716     AC_MSG_WARN([Floating-point textures enabled.])
 717     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 718     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 719 fi
 720
 721 dnl
 722 dnl Arch/platform-specific settings
 723 dnl
 724 AC_ARG_ENABLE([asm],
 725     [AS_HELP_STRING([--disable-asm],
 726         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 727     [enable_asm="$enableval"],
 728     [enable_asm=yes]
 729 )
 730 asm_arch=""
 731 AC_MSG_CHECKING([whether to enable assembly])
 732 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 733 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 734 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 735     case "$host_cpu" in
 736     i?86 | x86_64 | amd64)
 737         if test "x$host_cpu" != "x$target_cpu"; then
 738             enable_asm=no
 739             AC_MSG_RESULT([no, cross compiling])
 740         fi
 741         ;;
 742     esac
 743 fi
 744 # check for supported arches
 745 if test "x$enable_asm" = xyes; then
 746     case "$host_cpu" in
 747     i?86)
 748         case "$host_os" in
 749         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 750             asm_arch=x86
 751             ;;
 752         esac
 753         ;;
 754     x86_64|amd64)
 755         case "$host_os" in
 756         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 757             asm_arch=x86_64
 758             ;;
 759         esac
 760         ;;
 761     sparc*)
 762         case "$host_os" in
 763         linux*)
 764             asm_arch=sparc
 765             ;;
 766         esac
 767         ;;
 768     powerpc64le)
 769         case "$host_os" in
 770         linux*)
 771             asm_arch=ppc64le
 772             ;;
 773         esac
 774         ;;
 775     esac
 776
 777     case "$asm_arch" in
 778     x86)
 779         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 780         AC_MSG_RESULT([yes, x86])
 781         ;;
 782     x86_64|amd64)
 783         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 784         AC_MSG_RESULT([yes, x86_64])
 785         ;;
 786     sparc)
 787         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 788         AC_MSG_RESULT([yes, sparc])
 789         ;;
 790     ppc64le)
 791         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 792         AC_MSG_RESULT([yes, ppc64le])
 793         ;;
 794     *)
 795         AC_MSG_RESULT([no, platform not supported])
 796         ;;
 797     esac
 798 fi
 799
 800 AC_HEADER_MAJOR
 801 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 802 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 803 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 804 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 805
 806 dnl Check to see if dlopen is in default libraries (like Solaris, which
 807 dnl has it in libc), or if libdl is needed to get it.
 808 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 809     [AC_CHECK_LIB([dl], [dlopen],
 810        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 811 AC_SUBST([DLOPEN_LIBS])
 812
 813 dnl Check if that library also has dladdr
 814 save_LIBS="$LIBS"
 815 LIBS="$LIBS $DLOPEN_LIBS"
 816 AC_CHECK_FUNCS([dladdr])
 817 LIBS="$save_LIBS"
 818
 819 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 820
 821 case "$host_os" in
 822 darwin*)
 823     ;;
 824 *)
 825     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 826                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 827                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 828     AC_SUBST([CLOCK_LIB])
 829     ;;
 830 esac
 831
 832 dnl See if posix_memalign is available
 833 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 834
 835 dnl Check for zlib
 836 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 837
 838 dnl Check for pthreads
 839 AX_PTHREAD
 840 if test "x$ax_pthread_ok" = xno; then
 841     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 842 fi
 843 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 844 dnl to -pthread, which causes problems if we need -lpthread to appear in
 845 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 846 dnl is not valid for that platform.
 847 if test "x$android" = xno; then
 848     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 849 fi
 850 dnl According to the manual when using pthreads, one should add -pthread to
 851 dnl both compile and link-time arguments.
 852 dnl In practise that should be sufficient for all platforms, since any
 853 dnl platforms build with GCC and Clang support the flag.
 854 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 855
 856 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 857 dnl project. Even then there's a notable issue as described in the project README
 858 case "$host_os" in
 859 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 860     pthread_stubs_possible="no"
 861     ;;
 862 * )
 863     pthread_stubs_possible="yes"
 864     ;;
 865 esac
 866
 867 if test "x$pthread_stubs_possible" = xyes; then
 868     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 869 fi
 870
 871 dnl SELinux awareness.
 872 AC_ARG_ENABLE([selinux],
 873     [AS_HELP_STRING([--enable-selinux],
 874         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 875     [MESA_SELINUX="$enableval"],
 876     [MESA_SELINUX=no])
 877 if test "x$enable_selinux" = "xyes"; then
 878     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 879         [AC_CHECK_HEADER([selinux/selinux.h],[],
 880                          [AC_MSG_ERROR([SELinux headers not found])])
 881          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 882                       [AC_MSG_ERROR([SELinux library not found])])
 883          SELINUX_LIBS="-lselinux"])
 884     DEFINES="$DEFINES -DMESA_SELINUX"
 885 fi
 886 AC_SUBST([SELINUX_CFLAGS])
 887 AC_SUBST([SELINUX_LIBS])
 888
 889 dnl
 890 dnl LLVM
 891 dnl
 892 AC_ARG_ENABLE([llvm-shared-libs],
 893     [AS_HELP_STRING([--enable-llvm-shared-libs],
 894         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 895     [enable_llvm_shared_libs="$enableval"],
 896     [enable_llvm_shared_libs=yes])
 897
 898 AC_ARG_WITH([llvm-prefix],
 899     [AS_HELP_STRING([--with-llvm-prefix],
 900         [Prefix for LLVM installations in non-standard locations])],
 901     [llvm_prefix="$withval"],
 902     [llvm_prefix=''])
 903
 904 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 905 if test "x$have_libelf" = xno; then
 906    LIBELF_LIBS=''
 907    LIBELF_CFLAGS=''
 908    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 909    AC_SUBST([LIBELF_LIBS])
 910    AC_SUBST([LIBELF_CFLAGS])
 911 fi
 912
 913 if test -z "$LLVM_CONFIG"; then
 914     if test -n "$llvm_prefix"; then
 915         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 916     else
 917         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 918     fi
 919 fi
 920
 921 llvm_add_component() {
 922     new_llvm_component=$1
 923     driver_name=$2
 924
 925     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 926         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 927     else
 928         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 929     fi
 930 }
 931
 932 llvm_add_default_components() {
 933     driver_name=$1
 934
 935     # Required default components
 936     llvm_add_component "bitwriter" $driver_name
 937     llvm_add_component "engine" $driver_name
 938     llvm_add_component "mcdisassembler" $driver_name
 939     llvm_add_component "mcjit" $driver_name
 940
 941     # Optional default components
 942     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 943         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 944     fi
 945 }
 946
 947 llvm_add_target() {
 948     new_llvm_target=$1
 949     driver_name=$2
 950
 951     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 952         llvm_add_component $new_llvm_target $driver_name
 953     else
 954         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 955     fi
 956 }
 957
 958 # Call this inside ` ` to get the return value.
 959 # $1 is the llvm-config command with arguments.
 960 strip_unwanted_llvm_flags() {
 961     echo " `$1` " | sed -E \
 962         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 963         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 964         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 965         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 966         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 967         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 968         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 969         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 970         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 971         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 972         -e 's/^[[[:space:]]]//' \
 973         -e 's/[[[:space:]]]$//'
 974 }
 975
 976 llvm_set_environment_variables() {
 977     if test "x$LLVM_CONFIG" != xno; then
 978         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 979         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 980         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 981         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 982
 983         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 984         save_CFLAGS="$CFLAGS"
 985         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 986
 987         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 988             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 989         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 990             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 991         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 992             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 993
 994         CFLAGS="$save_CFLAGS"
 995
 996         # Only needed for LLVM < 3.6.0
 997         if test -z "$LLVM_VERSION_PATCH"; then
 998             LLVM_VERSION_PATCH=0
 999         fi
1000
1001         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1002
1003         FOUND_LLVM=yes
1004     else
1005         FOUND_LLVM=no
1006         LLVM_VERSION_INT=0
1007     fi
1008 }
1009
1010 require_llvm() {
1011     if test "x$enable_llvm" != "xyes"; then
1012         AC_MSG_ERROR([--enable-llvm is required when building $1])
1013     fi
1014 }
1015
1016 llvm_require_version() {
1017     require_llvm $2
1018
1019     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1020     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1021     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1022
1023     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1024         # major > required major
1025         #  --> OK
1026         return
1027     fi
1028
1029     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1030         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1031             # major = required major and
1032             # minor > required minor
1033             #  --> OK
1034             return
1035         else
1036             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1037                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1038                     # major = required major and
1039                     # minor = required minor and
1040                     # patch >= required patch
1041                     #  --> OK
1042                     return
1043                 fi
1044             fi
1045         fi
1046     fi
1047
1048     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1049 }
1050
1051 radeon_llvm_check() {
1052     if test ${LLVM_VERSION_INT} -lt 307; then
1053         amdgpu_llvm_target_name='r600'
1054     else
1055         amdgpu_llvm_target_name='amdgpu'
1056     fi
1057
1058     llvm_require_version $*
1059
1060     llvm_add_target $amdgpu_llvm_target_name $2
1061
1062     llvm_add_default_components $2
1063     llvm_add_component "bitreader" $2
1064     llvm_add_component "ipo" $2
1065
1066     if test "x$have_libelf" != xyes; then
1067        AC_MSG_ERROR([$2 requires libelf when using llvm])
1068     fi
1069 }
1070
1071 llvm_set_environment_variables
1072
1073 AC_SUBST([LLVM_CFLAGS])
1074 AC_SUBST([LLVM_CXXFLAGS])
1075 AC_SUBST([LLVM_LIBS])
1076 AC_SUBST([LLVM_LDFLAGS])
1077 AC_SUBST([LLVM_INCLUDEDIR])
1078
1079 dnl
1080 dnl libunwind
1081 dnl
1082 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1083 AC_ARG_ENABLE([libunwind],
1084     [AS_HELP_STRING([--enable-libunwind],
1085             [Use libunwind for backtracing (default: auto)])],
1086         [LIBUNWIND="$enableval"],
1087         [LIBUNWIND="$HAVE_LIBUNWIND"])
1088
1089 if test "x$LIBUNWIND" = "xyes"; then
1090     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1091     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1092 fi
1093
1094
1095 dnl Options for APIs
1096 AC_ARG_ENABLE([opengl],
1097     [AS_HELP_STRING([--disable-opengl],
1098         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1099     [enable_opengl="$enableval"],
1100     [enable_opengl=yes])
1101 AC_ARG_ENABLE([gles1],
1102     [AS_HELP_STRING([--disable-gles1],
1103         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1104     [enable_gles1="$enableval"],
1105     [enable_gles1=yes])
1106 AC_ARG_ENABLE([gles2],
1107     [AS_HELP_STRING([--disable-gles2],
1108         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1109     [enable_gles2="$enableval"],
1110     [enable_gles2=yes])
1111
1112 AC_ARG_ENABLE([dri],
1113     [AS_HELP_STRING([--enable-dri],
1114         [enable DRI modules @<:@default=enabled@:>@])],
1115     [enable_dri="$enableval"],
1116     [enable_dri=yes])
1117
1118 AC_ARG_ENABLE([gallium-extra-hud],
1119     [AS_HELP_STRING([--enable-gallium-extra-hud],
1120         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1121     [enable_gallium_extra_hud="$enableval"],
1122     [enable_gallium_extra_hud=no])
1123 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1124 if test "x$enable_gallium_extra_hud" = xyes ; then
1125     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1126 fi
1127
1128 #TODO: no pkgconfig .pc available for libsensors.
1129 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1130 AC_ARG_ENABLE([lmsensors],
1131     [AS_HELP_STRING([--enable-lmsensors],
1132         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1133     [enable_lmsensors="$enableval"],
1134     [enable_lmsensors=no])
1135 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1136 if test "x$enable_lmsensors" = xyes ; then
1137     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1138     LIBSENSORS_LIBS="-lsensors"
1139 else
1140     LIBSENSORS_LIBS=""
1141 fi
1142 AC_SUBST(LIBSENSORS_LIBS)
1143
1144 case "$host_os" in
1145 linux*)
1146     dri3_default=yes
1147     ;;
1148 *)
1149     dri3_default=no
1150     ;;
1151 esac
1152
1153 if test "x$enable_dri" = xno; then
1154     dri3_default=no
1155 fi
1156
1157 AC_ARG_ENABLE([dri3],
1158     [AS_HELP_STRING([--enable-dri3],
1159         [enable DRI3 @<:@default=auto@:>@])],
1160     [enable_dri3="$enableval"],
1161     [enable_dri3="$dri3_default"])
1162 AC_ARG_ENABLE([glx],
1163     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1164         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1165     [enable_glx="$enableval"],
1166     [enable_glx=yes])
1167 AC_ARG_ENABLE([osmesa],
1168     [AS_HELP_STRING([--enable-osmesa],
1169         [enable OSMesa library @<:@default=disabled@:>@])],
1170     [enable_osmesa="$enableval"],
1171     [enable_osmesa=no])
1172 AC_ARG_ENABLE([gallium-osmesa],
1173     [AS_HELP_STRING([--enable-gallium-osmesa],
1174         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1175     [enable_gallium_osmesa="$enableval"],
1176     [enable_gallium_osmesa=no])
1177 AC_ARG_ENABLE([egl],
1178     [AS_HELP_STRING([--disable-egl],
1179         [disable EGL library @<:@default=enabled@:>@])],
1180     [enable_egl="$enableval"],
1181     [enable_egl=yes])
1182
1183 AC_ARG_ENABLE([xa],
1184     [AS_HELP_STRING([--enable-xa],
1185         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1186     [enable_xa="$enableval"],
1187     [enable_xa=no])
1188 AC_ARG_ENABLE([gbm],
1189    [AS_HELP_STRING([--enable-gbm],
1190          [enable gbm library @<:@default=yes except cygwin@:>@])],
1191    [enable_gbm="$enableval"],
1192    [case "$host_os" in
1193        cygwin*)
1194           enable_gbm=no
1195           ;;
1196        *)
1197           enable_gbm=yes
1198           ;;
1199     esac])
1200 AC_ARG_ENABLE([nine],
1201     [AS_HELP_STRING([--enable-nine],
1202         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1203     [enable_nine="$enableval"],
1204     [enable_nine=no])
1205
1206 AC_ARG_ENABLE([xvmc],
1207    [AS_HELP_STRING([--enable-xvmc],
1208          [enable xvmc library @<:@default=auto@:>@])],
1209    [enable_xvmc="$enableval"],
1210    [enable_xvmc=auto])
1211 AC_ARG_ENABLE([vdpau],
1212    [AS_HELP_STRING([--enable-vdpau],
1213          [enable vdpau library @<:@default=auto@:>@])],
1214    [enable_vdpau="$enableval"],
1215    [enable_vdpau=auto])
1216 AC_ARG_ENABLE([omx],
1217    [AS_HELP_STRING([--enable-omx],
1218          [enable OpenMAX library @<:@default=disabled@:>@])],
1219    [enable_omx="$enableval"],
1220    [enable_omx=no])
1221 AC_ARG_ENABLE([va],
1222    [AS_HELP_STRING([--enable-va],
1223          [enable va library @<:@default=auto@:>@])],
1224    [enable_va="$enableval"],
1225    [enable_va=auto])
1226 AC_ARG_ENABLE([opencl],
1227    [AS_HELP_STRING([--enable-opencl],
1228          [enable OpenCL library @<:@default=disabled@:>@])],
1229    [enable_opencl="$enableval"],
1230    [enable_opencl=no])
1231 AC_ARG_ENABLE([opencl_icd],
1232    [AS_HELP_STRING([--enable-opencl-icd],
1233           [Build an OpenCL ICD library to be loaded by an ICD implementation
1234            @<:@default=disabled@:>@])],
1235     [enable_opencl_icd="$enableval"],
1236     [enable_opencl_icd=no])
1237
1238 AC_ARG_ENABLE([gallium-tests],
1239     [AS_HELP_STRING([--enable-gallium-tests],
1240         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1241     [enable_gallium_tests="$enableval"],
1242     [enable_gallium_tests=no])
1243
1244 # Option for Gallium drivers
1245
1246 # Keep this in sync with the --with-gallium-drivers help string default value
1247 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1248
1249 AC_ARG_WITH([gallium-drivers],
1250     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1251         [comma delimited Gallium drivers list, e.g.
1252         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1253         @<:@default=r300,r600,svga,swrast@:>@])],
1254     [with_gallium_drivers="$withval"],
1255     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1256
1257 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1258 # here so that the script doesn't choke on an unknown driver name later.
1259 case "$with_gallium_drivers" in
1260     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1261     no) with_gallium_drivers='' ;;
1262 esac
1263
1264 if test "x$enable_opengl" = xno -a \
1265         "x$enable_gles1" = xno -a \
1266         "x$enable_gles2" = xno -a \
1267         "x$enable_nine" = xno -a \
1268         "x$enable_xa" = xno -a \
1269         "x$enable_xvmc" = xno -a \
1270         "x$enable_vdpau" = xno -a \
1271         "x$enable_omx" = xno -a \
1272         "x$enable_va" = xno -a \
1273         "x$enable_opencl" = xno; then
1274     AC_MSG_ERROR([at least one API should be enabled])
1275 fi
1276
1277 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1278 if test "x$enable_opengl" = xno -a \
1279         "x$enable_gles1" = xyes; then
1280     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1281 fi
1282
1283 if test "x$enable_opengl" = xno -a \
1284         "x$enable_gles2" = xyes; then
1285     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1286 fi
1287
1288 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1289 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1290 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1291 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1292                                         "x$enable_gles1" = xyes -o \
1293                                         "x$enable_gles2" = xyes)
1294
1295 # Validate GLX options
1296 if test "x$enable_glx" = xyes; then
1297     if test "x$enable_dri" = xyes; then
1298         enable_glx=dri
1299     elif test -n "$with_gallium_drivers"; then
1300         enable_glx=gallium-xlib
1301     else
1302         enable_glx=xlib
1303     fi
1304 fi
1305 case "x$enable_glx" in
1306 xdri | xxlib | xgallium-xlib)
1307     # GLX requires OpenGL
1308     if test "x$enable_opengl" = xno; then
1309         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1310     fi
1311
1312     # Check individual dependencies
1313     case "x$enable_glx" in
1314     xdri)
1315         if test "x$enable_dri" = xno; then
1316             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1317         fi
1318         ;;
1319     xxlib)
1320         if test "x$enable_dri" = xyes; then
1321             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1322         fi
1323         ;;
1324     xgallium-xlib )
1325         if test "x$enable_dri" = xyes; then
1326             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1327         fi
1328         if test -z "$with_gallium_drivers"; then
1329             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1330         fi
1331         ;;
1332     esac
1333     ;;
1334 xno)
1335     ;;
1336 *)
1337     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1338     ;;
1339 esac
1340
1341 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1342 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1343 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1344 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1345
1346 DEFAULT_GL_LIB_NAME=GL
1347
1348 dnl
1349 dnl Libglvnd configuration
1350 dnl
1351 AC_ARG_ENABLE([libglvnd],
1352     [AS_HELP_STRING([--enable-libglvnd],
1353         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1354     [enable_libglvnd="$enableval"],
1355     [enable_libglvnd=no])
1356 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1357
1358 if test "x$enable_libglvnd" = xyes ; then
1359     dnl XXX: update once we can handle more than libGL/glx.
1360     dnl Namely: we should error out if neither of the glvnd enabled libraries
1361     dnl are built
1362     case "x$enable_glx" in
1363     xno)
1364         AC_MSG_ERROR([cannot build libglvnd without GLX])
1365         ;;
1366     xxlib | xgallium-xlib )
1367         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1368         ;;
1369     xdri)
1370         ;;
1371     esac
1372
1373     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1374     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1375     AC_SUBST([LIBGLVND_DATADIR])
1376
1377     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1378     DEFAULT_GL_LIB_NAME=GLX_mesa
1379 fi
1380
1381 AC_ARG_WITH([gl-lib-name],
1382   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1383     [specify GL library name @<:@default=GL@:>@])],
1384   [GL_LIB=$withval],
1385   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1386 AC_ARG_WITH([osmesa-lib-name],
1387   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1388     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1389   [OSMESA_LIB=$withval],
1390   [OSMESA_LIB=OSMesa])
1391 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1392 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1393
1394 dnl
1395 dnl Mangled Mesa support
1396 dnl
1397 AC_ARG_ENABLE([mangling],
1398   [AS_HELP_STRING([--enable-mangling],
1399     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1400   [enable_mangling="${enableval}"],
1401   [enable_mangling=no]
1402 )
1403 if test "x${enable_mangling}" = "xyes" ; then
1404   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1405   GL_LIB="Mangled${GL_LIB}"
1406   OSMESA_LIB="Mangled${OSMESA_LIB}"
1407 fi
1408 AC_SUBST([GL_LIB])
1409 AC_SUBST([OSMESA_LIB])
1410
1411 # Check for libdrm
1412 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1413                   [have_libdrm=yes], [have_libdrm=no])
1414 if test "x$have_libdrm" = xyes; then
1415         DEFINES="$DEFINES -DHAVE_LIBDRM"
1416 fi
1417
1418 require_libdrm() {
1419     if test "x$have_libdrm" != xyes; then
1420        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1421     fi
1422 }
1423
1424
1425 # Select which platform-dependent DRI code gets built
1426 case "$host_os" in
1427 darwin*)
1428     dri_platform='apple' ;;
1429 cygwin*)
1430     dri_platform='windows' ;;
1431 gnu*)
1432     dri_platform='none' ;;
1433 *)
1434     dri_platform='drm' ;;
1435 esac
1436
1437 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1438     have_drisw_kms='yes'
1439 fi
1440
1441 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1442 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1443 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1444 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1445 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1446 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1447 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1448 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1449 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1450
1451 AC_ARG_ENABLE([shared-glapi],
1452     [AS_HELP_STRING([--enable-shared-glapi],
1453         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1454     [enable_shared_glapi="$enableval"],
1455     [enable_shared_glapi=yes])
1456
1457 case "x$enable_opengl$enable_gles1$enable_gles2" in
1458 x*yes*yes*)
1459     if test "x$enable_shared_glapi" = xno; then
1460         AC_MSG_ERROR([shared GLAPI required when building two or more of
1461                       the following APIs - opengl, gles1 gles2])
1462     fi
1463     ;;
1464 esac
1465
1466 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1467
1468 # Build the pipe-drivers as separate libraries/modules.
1469 # Do not touch this unless you know what you are doing.
1470 # XXX: Expose via configure option ?
1471 enable_shared_pipe_drivers=no
1472
1473 dnl
1474 dnl Driver specific build directories
1475 dnl
1476
1477 if test "x$enable_gallium_osmesa" = xyes; then
1478     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1479         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1480     fi
1481     if test "x$enable_osmesa" = xyes; then
1482         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1483     fi
1484 fi
1485
1486 require_dri_shared_libs_and_glapi() {
1487     if test "x$enable_static" = xyes; then
1488         AC_MSG_ERROR([$1 cannot be build as static library])
1489     fi
1490
1491     if test "x$enable_dri" != xyes; then
1492         # There is only a single backend which won't be build/used otherwise.
1493         # XXX: Revisit this as the egl/haiku is a thing.
1494         AC_MSG_ERROR([$1 requires --enable-dri])
1495     fi
1496
1497     if test "x$enable_shared_glapi" != xyes; then
1498         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1499     fi
1500 }
1501
1502 if test "x$enable_dri" = xyes; then
1503     require_dri_shared_libs_and_glapi "DRI"
1504
1505     # not a hard requirement as swrast does not depend on it
1506     if test "x$have_libdrm" = xyes; then
1507         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1508     fi
1509 fi
1510
1511 AC_ARG_ENABLE([driglx-direct],
1512     [AS_HELP_STRING([--disable-driglx-direct],
1513         [disable direct rendering in GLX and EGL for DRI \
1514             @<:@default=auto@:>@])],
1515     [driglx_direct="$enableval"],
1516     [driglx_direct="yes"])
1517
1518 dnl
1519 dnl libGL configuration per driver
1520 dnl
1521 if test "x$enable_glx" != xno; then
1522     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1523 fi
1524 case "x$enable_glx" in
1525 xxlib | xgallium-xlib)
1526     # Xlib-based GLX
1527     dri_modules="x11 xext xcb"
1528     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1529     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1530     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1531     GL_LIB_DEPS="$XLIBGL_LIBS"
1532     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1533     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1534     ;;
1535 xdri)
1536     # DRI-based GLX
1537
1538     # find the DRI deps for libGL
1539     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1540
1541     if test x"$driglx_direct" = xyes; then
1542         if test x"$dri_platform" = xdrm ; then
1543             DEFINES="$DEFINES -DGLX_USE_DRM"
1544             require_libdrm "Direct rendering"
1545
1546             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1547             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1548
1549             if test x"$enable_dri" = xyes; then
1550                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1551             fi
1552         fi
1553         if test x"$dri_platform" = xapple ; then
1554             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1555         fi
1556         if test x"$dri_platform" = xwindows ; then
1557             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1558         fi
1559     fi
1560
1561     # add xf86vidmode if available
1562     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1563     if test "$HAVE_XF86VIDMODE" = yes ; then
1564         dri_modules="$dri_modules xxf86vm"
1565     fi
1566
1567     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1568     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1569     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1570     GL_LIB_DEPS="$DRIGL_LIBS"
1571
1572     # need DRM libs, $PTHREAD_LIBS, etc.
1573     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1574     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575     ;;
1576 esac
1577
1578 # This is outside the case (above) so that it is invoked even for non-GLX
1579 # builds.
1580 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1581
1582 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1583 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1584 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1585 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1586
1587 AC_SUBST([X11_INCLUDES])
1588 AC_SUBST([GL_LIB_DEPS])
1589 AC_SUBST([GL_PC_REQ_PRIV])
1590 AC_SUBST([GL_PC_LIB_PRIV])
1591 AC_SUBST([GL_PC_CFLAGS])
1592 AC_SUBST([DRI_PC_REQ_PRIV])
1593 AC_SUBST([GLESv1_CM_LIB_DEPS])
1594 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1595 AC_SUBST([GLESv2_LIB_DEPS])
1596 AC_SUBST([GLESv2_PC_LIB_PRIV])
1597
1598 AC_SUBST([HAVE_XF86VIDMODE])
1599
1600 dnl
1601 dnl More GLX setup
1602 dnl
1603 case "x$enable_glx" in
1604 xxlib | xgallium-xlib)
1605     DEFINES="$DEFINES -DUSE_XSHM"
1606     ;;
1607 xdri)
1608     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1609     if test "x$driglx_direct" = xyes; then
1610         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1611     fi
1612     ;;
1613 esac
1614
1615 dnl
1616 dnl TLS detection
1617 dnl
1618
1619 AC_ARG_ENABLE([glx-tls],
1620     [AS_HELP_STRING([--enable-glx-tls],
1621         [enable TLS support in GLX @<:@default=enabled@:>@])],
1622     [GLX_USE_TLS="$enableval"],
1623     [GLX_USE_TLS=yes])
1624 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1625
1626 if test "x$GLX_USE_TLS" = xyes; then
1627     DEFINES="$DEFINES -DGLX_USE_TLS"
1628 fi
1629
1630 dnl Read-only text section on x86 hardened platforms
1631 AC_ARG_ENABLE([glx-read-only-text],
1632     [AS_HELP_STRING([--enable-glx-read-only-text],
1633         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1634     [enable_glx_read_only_text="$enableval"],
1635     [enable_glx_read_only_text=no])
1636 if test "x$enable_glx_read_only_text" = xyes; then
1637     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1638 fi
1639
1640 dnl
1641 dnl DEPRECATED: EGL Platforms configuration
1642 dnl
1643 AC_ARG_WITH([egl-platforms],
1644     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1645         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1646     [with_egl_platforms="$withval"],
1647     [with_egl_platforms=auto])
1648
1649 if test "x$with_egl_platforms" = xauto; then
1650     with_egl_platforms="x11,surfaceless"
1651     if test "x$enable_gbm" = xyes; then
1652         with_egl_platforms="$with_egl_platforms,drm"
1653     fi
1654 else
1655     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1656 fi
1657
1658 dnl
1659 dnl Platforms configuration
1660 dnl
1661 AC_ARG_WITH([platforms],
1662     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1663         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1664         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1665     [with_platforms="$withval"],
1666     [with_platforms=auto])
1667
1668 # Reuse the autodetection rather than duplicating it.
1669 if test "x$with_platforms" = xauto; then
1670     with_platforms=$with_egl_platforms
1671 fi
1672
1673 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1674         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1675         WAYLAND_SCANNER='')
1676 if test "x$WAYLAND_SCANNER" = x; then
1677     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1678 fi
1679
1680 # Do per platform setups and checks
1681 platforms=`IFS=', '; echo $with_platforms`
1682 for plat in $platforms; do
1683         case "$plat" in
1684         wayland)
1685
1686                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1687
1688                 if test "x$WAYLAND_SCANNER" = "x:"; then
1689                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1690                 fi
1691                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1692                 ;;
1693
1694         x11)
1695                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1696                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1697                 ;;
1698
1699         drm)
1700                 test "x$enable_gbm" = "xno" &&
1701                         AC_MSG_ERROR([EGL platform drm needs gbm])
1702                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1703                 ;;
1704
1705         surfaceless)
1706                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1707                 ;;
1708
1709         android)
1710                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1711                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1712                 ;;
1713
1714         *)
1715                 AC_MSG_ERROR([platform '$plat' does not exist])
1716                 ;;
1717         esac
1718
1719         case "$plat" in
1720         wayland|drm|surfaceless)
1721                 require_libdrm "Platform $plat"
1722                 ;;
1723         esac
1724 done
1725
1726 if test "x$enable_glx" != xno; then
1727     if ! echo "$platforms" | grep -q 'x11'; then
1728         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1729     fi
1730 fi
1731
1732 if test x"$enable_dri3" = xyes; then
1733     DEFINES="$DEFINES -DHAVE_DRI3"
1734
1735     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1736     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1737 fi
1738
1739 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1740 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1741 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1742 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1743 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1744
1745 dnl
1746 dnl More DRI setup
1747 dnl
1748 dnl Directory for DRI drivers
1749 AC_ARG_WITH([dri-driverdir],
1750     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1751         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1752     [DRI_DRIVER_INSTALL_DIR="$withval"],
1753     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1754 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1755 dnl Extra search path for DRI drivers
1756 AC_ARG_WITH([dri-searchpath],
1757     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1758         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1759     [DRI_DRIVER_SEARCH_DIR="$withval"],
1760     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1761 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1762 dnl Which drivers to build - default is chosen by platform
1763 AC_ARG_WITH([dri-drivers],
1764     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1765         [comma delimited classic DRI drivers list, e.g.
1766         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1767     [with_dri_drivers="$withval"],
1768     [with_dri_drivers=auto])
1769
1770 if test "x$with_dri_drivers" = xauto; then
1771     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1772         with_dri_drivers="yes"
1773     else
1774         with_dri_drivers="no"
1775     fi
1776 fi
1777 if test "x$with_dri_drivers" = xno; then
1778     with_dri_drivers=''
1779 fi
1780
1781 dnl If $with_dri_drivers is yes, drivers will be added through
1782 dnl platform checks. Set DEFINES and LIB_DEPS
1783 if test "x$enable_dri" = xyes; then
1784     # Platform specific settings and drivers to build
1785     case "$host_os" in
1786     linux*)
1787         case "$host_cpu" in
1788         powerpc* | sparc*)
1789             # Build only the drivers for cards that exist on PowerPC/sparc
1790             if test "x$with_dri_drivers" = "xyes"; then
1791                 with_dri_drivers="r200 radeon swrast"
1792             fi
1793             ;;
1794         esac
1795         ;;
1796     cygwin*)
1797         if test "x$with_dri_drivers" = "xyes"; then
1798             with_dri_drivers="swrast"
1799         fi
1800         ;;
1801     darwin*)
1802         DEFINES="$DEFINES -DBUILDING_MESA"
1803         if test "x$with_dri_drivers" = "xyes"; then
1804             with_dri_drivers="swrast"
1805         fi
1806         ;;
1807     esac
1808
1809     # default drivers
1810     if test "x$with_dri_drivers" = "xyes"; then
1811         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1812     fi
1813
1814     # Check for expat
1815     PKG_CHECK_MODULES([EXPAT], [expat], [],
1816         # expat version 2.0 and earlier do not provide expat.pc
1817         [AC_CHECK_HEADER([expat.h],[],
1818                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1819          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1820                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1821          EXPAT_LIBS="-lexpat"])
1822
1823     # put all the necessary libs together
1824     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1825 fi
1826
1827 AC_SUBST([DRI_LIB_DEPS])
1828
1829 DRI_DIRS=''
1830 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1831 if test -n "$with_dri_drivers"; then
1832     if test "x$enable_opengl" != xyes; then
1833         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1834     fi
1835
1836     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1837     for driver in $dri_drivers; do
1838         DRI_DIRS="$DRI_DIRS $driver"
1839         case "x$driver" in
1840         xi915)
1841             require_libdrm "i915"
1842             HAVE_I915_DRI=yes
1843             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1844             ;;
1845         xi965)
1846             require_libdrm "i965"
1847             HAVE_I965_DRI=yes
1848             ;;
1849         xnouveau)
1850             require_libdrm "nouveau"
1851             HAVE_NOUVEAU_DRI=yes
1852             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1853             ;;
1854         xradeon)
1855             require_libdrm "radeon"
1856             HAVE_RADEON_DRI=yes;
1857             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1858             ;;
1859         xr200)
1860             require_libdrm "r200"
1861             HAVE_R200_DRI=yes
1862             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1863             ;;
1864         xswrast)
1865             HAVE_SWRAST_DRI=yes
1866             ;;
1867         *)
1868             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1869             ;;
1870         esac
1871     done
1872     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1873 fi
1874
1875
1876 dnl
1877 dnl Gallium LLVM
1878 dnl Deprecated: kept for backwards compatibility
1879 dnl
1880 AC_ARG_ENABLE([gallium-llvm],
1881     [AS_HELP_STRING([--enable-gallium-llvm],
1882         [DEPRECATED: use --enable-llvm instead])],
1883     [enable_gallium_llvm="$enableval"],
1884     [enable_gallium_llvm=auto])
1885
1886 if test "x$enable_gallium_llvm" != xauto; then
1887    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1888    enable_llvm=$enable_gallium_llvm
1889 fi
1890
1891 dnl
1892 dnl LLVM
1893 dnl
1894 AC_ARG_ENABLE([llvm],
1895     [AS_HELP_STRING([--enable-llvm],
1896         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1897     [enable_llvm="$enableval"],
1898     [enable_llvm=auto])
1899
1900 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1901     if test "x$FOUND_LLVM" = xyes; then
1902         case "$host_cpu" in
1903         i*86|x86_64|amd64) enable_llvm=yes;;
1904         *) enable_llvm=no;;
1905         esac
1906     else
1907         enable_llvm=no
1908     fi
1909 fi
1910
1911 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1912     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1913 fi
1914
1915 #
1916 # Vulkan driver configuration
1917 #
1918
1919 AC_ARG_WITH([vulkan-drivers],
1920     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1921         [comma delimited Vulkan drivers list, e.g.
1922         "intel,radeon"
1923         @<:@default=no@:>@])],
1924     [with_vulkan_drivers="$withval"],
1925     [with_vulkan_drivers="no"])
1926
1927 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1928 # here so that the script doesn't choke on an unknown driver name later.
1929 case "x$with_vulkan_drivers" in
1930     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1931     xno) with_vulkan_drivers='' ;;
1932 esac
1933
1934 AC_ARG_WITH([vulkan-icddir],
1935     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1936         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1937     [VULKAN_ICD_INSTALL_DIR="$withval"],
1938     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1939 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1940
1941 require_x11_dri3() {
1942     if echo "$platforms" | grep -q 'x11'; then
1943         if test "x$enable_dri3" != xyes; then
1944             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1945         fi
1946     fi
1947 }
1948
1949 if test -n "$with_vulkan_drivers"; then
1950     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1951         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1952     fi
1953
1954     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1955     for driver in $VULKAN_DRIVERS; do
1956         case "x$driver" in
1957         xintel)
1958             require_libdrm "ANV"
1959             require_x11_dri3 "ANV"
1960             HAVE_INTEL_VULKAN=yes
1961             ;;
1962         xradeon)
1963             require_libdrm "radv"
1964             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1965             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1966             require_x11_dri3 "radv"
1967             HAVE_RADEON_VULKAN=yes
1968             ;;
1969         *)
1970             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1971             ;;
1972         esac
1973     done
1974     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1975 fi
1976
1977
1978 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1979 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1980 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1981                                   "x$enable_osmesa" = xyes -o \
1982                                   -n "$DRI_DIRS")
1983
1984 dnl
1985 dnl OSMesa configuration
1986 dnl
1987
1988 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1989 AC_ARG_WITH([osmesa-bits],
1990     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1991         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1992     [osmesa_bits="$withval"],
1993     [osmesa_bits=8])
1994 if test "x$osmesa_bits" != x8; then
1995     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1996         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1997         osmesa_bits=8
1998     fi
1999 fi
2000 case "x$osmesa_bits" in
2001 x8)
2002     OSMESA_LIB="${OSMESA_LIB}"
2003     ;;
2004 x16|x32)
2005     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2006     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2007     ;;
2008 *)
2009     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2010     ;;
2011 esac
2012
2013 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2014     # only link libraries with osmesa if shared
2015     if test "$enable_static" = no; then
2016         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2017     else
2018         OSMESA_LIB_DEPS=""
2019     fi
2020     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2021 fi
2022
2023 AC_SUBST([OSMESA_LIB_DEPS])
2024 AC_SUBST([OSMESA_PC_REQ])
2025 AC_SUBST([OSMESA_PC_LIB_PRIV])
2026
2027 dnl
2028 dnl gbm configuration
2029 dnl
2030 if test "x$enable_gbm" = xyes; then
2031     require_dri_shared_libs_and_glapi "gbm"
2032 fi
2033 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2034 # FINISHME: GBM has a number of dependencies which we should add below
2035 GBM_PC_REQ_PRIV=""
2036 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2037 AC_SUBST([GBM_PC_REQ_PRIV])
2038 AC_SUBST([GBM_PC_LIB_PRIV])
2039
2040 dnl
2041 dnl EGL configuration
2042 dnl
2043
2044 if test "x$enable_egl" = xyes; then
2045     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2046
2047     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2048
2049     require_dri_shared_libs_and_glapi "egl"
2050 fi
2051 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2052 AC_SUBST([EGL_LIB_DEPS])
2053
2054 gallium_st="mesa"
2055
2056 dnl
2057 dnl XA configuration
2058 dnl
2059 if test "x$enable_xa" = xyes; then
2060     if test "x$with_gallium_drivers" = xswrast; then
2061        AC_MSG_ERROR([
2062           Building xa requires at least one non swrast gallium driver.
2063           If you are looking to use libxatracker.so with the VMware driver,
2064           make sure to include svga in the gallium drivers list, apart from
2065           enabling XA.
2066           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2067     fi
2068     gallium_st="$gallium_st xa"
2069 fi
2070 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2071
2072 if echo $platforms | grep -q "x11"; then
2073     have_xvmc_platform=yes
2074 else
2075     have_xvmc_platform=no
2076 fi
2077
2078 if echo $platforms | grep -q "x11"; then
2079     have_vdpau_platform=yes
2080 else
2081     have_vdpau_platform=no
2082 fi
2083
2084 if echo $platforms | grep -q "x11\|drm"; then
2085     have_omx_platform=yes
2086 else
2087     have_omx_platform=no
2088 fi
2089
2090 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2091     have_va_platform=yes
2092 else
2093     have_va_platform=no
2094 fi
2095
2096 dnl
2097 dnl Gallium G3DVL configuration
2098 dnl
2099 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2100     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2101         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2102     fi
2103
2104     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2105         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2106     fi
2107
2108     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2109         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2110     fi
2111
2112     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2113         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2114     fi
2115 fi
2116
2117 if test "x$enable_dri" = xyes -o \
2118         "x$enable_xvmc" = xyes -o \
2119         "x$enable_vdpau" = xyes -o \
2120         "x$enable_omx" = xyes -o \
2121         "x$enable_va" = xyes; then
2122     need_gallium_vl=yes
2123 fi
2124 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2125
2126 if test "x$enable_xvmc" = xyes -o \
2127         "x$enable_vdpau" = xyes -o \
2128         "x$enable_omx" = xyes -o \
2129         "x$enable_va" = xyes; then
2130     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2131     need_gallium_vl_winsys=yes
2132 fi
2133 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2134
2135 if test "x$enable_xvmc" = xyes; then
2136     if test "x$have_xvmc_platform" != xyes; then
2137         AC_MSG_ERROR([XVMC requires the x11 platforms])
2138     fi
2139     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2140     gallium_st="$gallium_st xvmc"
2141 fi
2142 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2143
2144 if test "x$enable_vdpau" = xyes; then
2145     if test "x$have_vdpau_platform" != xyes; then
2146         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2147     fi
2148     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2149     gallium_st="$gallium_st vdpau"
2150     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2151 fi
2152 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2153
2154 if test "x$enable_omx" = xyes; then
2155     if test "x$have_omx_platform" != xyes; then
2156         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2157     fi
2158     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2159     gallium_st="$gallium_st omx"
2160 fi
2161 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2162
2163 if test "x$enable_va" = xyes; then
2164     if test "x$have_va_platform" != xyes; then
2165         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2166     fi
2167     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2168     gallium_st="$gallium_st va"
2169 fi
2170 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2171
2172 dnl
2173 dnl Nine Direct3D9 configuration
2174 dnl
2175 if test "x$enable_nine" = xyes; then
2176     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2177         AC_MSG_ERROR([nine requires the gallium swrast driver])
2178     fi
2179     if test "x$with_gallium_drivers" = xswrast; then
2180         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2181     fi
2182     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2183         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2184     fi
2185
2186     if test "x$enable_dri3" = xno; then
2187         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2188     fi
2189
2190     gallium_st="$gallium_st nine"
2191 fi
2192 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2193
2194 dnl
2195 dnl OpenCL configuration
2196 dnl
2197
2198 AC_ARG_WITH([clang-libdir],
2199    [AS_HELP_STRING([--with-clang-libdir],
2200          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2201    [CLANG_LIBDIR="$withval"],
2202    [CLANG_LIBDIR=''])
2203
2204 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2205
2206 if test "x$enable_opencl" = xyes; then
2207     if test -z "$with_gallium_drivers"; then
2208         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2209     fi
2210
2211     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2212         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2213     fi
2214
2215     if test "x$have_libclc" = xno; then
2216         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2217                     Make sure the directory containing libclc.pc is specified in your
2218                     PKG_CONFIG_PATH environment variable.
2219                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2220     else
2221         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2222         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2223         AC_SUBST([LIBCLC_INCLUDEDIR])
2224         AC_SUBST([LIBCLC_LIBEXECDIR])
2225     fi
2226
2227     gallium_st="$gallium_st clover"
2228
2229     if test "x$enable_opencl_icd" = xyes; then
2230         OPENCL_LIBNAME="MesaOpenCL"
2231     else
2232         OPENCL_LIBNAME="OpenCL"
2233     fi
2234
2235     if test "x$have_libelf" != xyes; then
2236        AC_MSG_ERROR([Clover requires libelf])
2237     fi
2238
2239     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2240         altivec_enabled=no
2241         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2242         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2243         #error "AltiVec not enabled"
2244         #endif
2245         ])], altivec_enabled=yes)
2246
2247         if test "$altivec_enabled" = yes; then
2248             CLOVER_STD_OVERRIDE="-std=gnu++11"
2249         fi
2250         AC_SUBST([CLOVER_STD_OVERRIDE])
2251     fi
2252
2253     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2254
2255     llvm_add_default_components "opencl"
2256     llvm_add_component "all-targets" "opencl"
2257     llvm_add_component "linker" "opencl"
2258     llvm_add_component "instrumentation" "opencl"
2259     llvm_add_component "ipo" "opencl"
2260     llvm_add_component "irreader" "opencl"
2261     llvm_add_component "option" "opencl"
2262     llvm_add_component "objcarcopts" "opencl"
2263     llvm_add_component "profiledata" "opencl"
2264
2265     dnl Check for Clang internal headers
2266     if test -z "$CLANG_LIBDIR"; then
2267         CLANG_LIBDIR=${LLVM_LIBDIR}
2268     fi
2269     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2270     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2271         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2272 fi
2273 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2274 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2275 AC_SUBST([OPENCL_LIBNAME])
2276 AC_SUBST([CLANG_RESOURCE_DIR])
2277
2278 dnl
2279 dnl Gallium configuration
2280 dnl
2281 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2282
2283 # libEGL wants to default to the first platform specified in
2284 # ./configure.  parse that here.
2285 if test "x$platforms" != "x"; then
2286     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2287     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2288 else
2289     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2290 fi
2291
2292 AC_SUBST([EGL_NATIVE_PLATFORM])
2293 AC_SUBST([EGL_CFLAGS])
2294
2295 # If we don't have the X11 platform, set this define so we don't try to include
2296 # the X11 headers.
2297 if ! echo "$platforms" | grep -q 'x11'; then
2298     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2299     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2300 fi
2301
2302 dnl Directory for XVMC libs
2303 AC_ARG_WITH([xvmc-libdir],
2304     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2305         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2306     [XVMC_LIB_INSTALL_DIR="$withval"],
2307     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2308 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2309
2310 dnl
2311 dnl Gallium Tests
2312 dnl
2313 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2314
2315 dnl Directory for VDPAU libs
2316 AC_ARG_WITH([vdpau-libdir],
2317     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2318         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2319     [VDPAU_LIB_INSTALL_DIR="$withval"],
2320     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2321 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2322
2323 dnl Directory for OMX libs
2324
2325 AC_ARG_WITH([omx-libdir],
2326     [AS_HELP_STRING([--with-omx-libdir=DIR],
2327         [directory for the OMX libraries])],
2328     [OMX_LIB_INSTALL_DIR="$withval"],
2329     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2330                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2331 AC_SUBST([OMX_LIB_INSTALL_DIR])
2332
2333 dnl Directory for VA libs
2334
2335 AC_ARG_WITH([va-libdir],
2336     [AS_HELP_STRING([--with-va-libdir=DIR],
2337         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2338     [VA_LIB_INSTALL_DIR="$withval"],
2339     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2340 AC_SUBST([VA_LIB_INSTALL_DIR])
2341
2342 AC_ARG_WITH([d3d-libdir],
2343     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2344         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2345     [D3D_DRIVER_INSTALL_DIR="$withval"],
2346     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2347 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2348
2349 dnl
2350 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2351 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2352 dnl architectures.
2353 dnl
2354 r300_require_llvm() {
2355     case "$host" in *gnux32) return;; esac
2356     case "$host_cpu" in
2357     i*86|x86_64|amd64) require_llvm $1
2358         ;;
2359     esac
2360 }
2361
2362 dnl
2363 dnl DRM is needed by X, Wayland, and offscreen rendering.
2364 dnl Surfaceless is an alternative for the last one.
2365 dnl
2366 require_basic_egl() {
2367     case "$with_platforms" in
2368         *drm*|*surfaceless*)
2369             ;;
2370         *)
2371             AC_MSG_ERROR([$1 requires one of these:
2372                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2373                   2) --with-platforms=surfaceless (offscreen only)
2374                   Recommended options: drm,x11])
2375             ;;
2376     esac
2377 }
2378
2379 swr_require_cxx_feature_flags() {
2380     feature_name="$1"
2381     preprocessor_test="$2"
2382     option_list="$3"
2383     output_var="$4"
2384
2385     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2386     AC_LANG_PUSH([C++])
2387     save_CXXFLAGS="$CXXFLAGS"
2388     save_IFS="$IFS"
2389     IFS=","
2390     found=0
2391     for opts in $option_list
2392     do
2393         unset IFS
2394         CXXFLAGS="$opts $save_CXXFLAGS"
2395         AC_COMPILE_IFELSE(
2396             [AC_LANG_PROGRAM(
2397                 [   #if !($preprocessor_test)
2398                     #error
2399                     #endif
2400                 ])],
2401             [found=1; break],
2402             [])
2403         IFS=","
2404     done
2405     IFS="$save_IFS"
2406     CXXFLAGS="$save_CXXFLAGS"
2407     AC_LANG_POP([C++])
2408     if test $found -eq 1; then
2409         AC_MSG_RESULT([$opts])
2410         eval "$output_var=\$opts"
2411         return 0
2412     fi
2413     AC_MSG_RESULT([no])
2414     AC_MSG_ERROR([swr requires $feature_name support])
2415     return 1
2416 }
2417
2418 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2419 if test -n "$with_gallium_drivers"; then
2420     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2421     for driver in $gallium_drivers; do
2422         case "x$driver" in
2423         xsvga)
2424             HAVE_GALLIUM_SVGA=yes
2425             require_libdrm "svga"
2426             ;;
2427         xi915)
2428             HAVE_GALLIUM_I915=yes
2429             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2430             require_libdrm "Gallium i915"
2431             ;;
2432         xr300)
2433             HAVE_GALLIUM_R300=yes
2434             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2435             require_libdrm "r300"
2436             r300_require_llvm "r300"
2437             ;;
2438         xr600)
2439             HAVE_GALLIUM_R600=yes
2440             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2441             require_libdrm "r600"
2442             if test "x$enable_llvm" = xyes; then
2443                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2444
2445                 llvm_add_component "asmparser" "r600"
2446                 llvm_add_component "bitreader" "r600"
2447             fi
2448             ;;
2449         xradeonsi)
2450             HAVE_GALLIUM_RADEONSI=yes
2451             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2452             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2453             require_libdrm "radeonsi"
2454             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2455             if test "x$enable_egl" = xyes; then
2456                 require_basic_egl "radeonsi"
2457             fi
2458             ;;
2459         xnouveau)
2460             HAVE_GALLIUM_NOUVEAU=yes
2461             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2462             require_libdrm "nouveau"
2463             ;;
2464         xfreedreno)
2465             HAVE_GALLIUM_FREEDRENO=yes
2466             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2467             require_libdrm "freedreno"
2468             ;;
2469         xetnaviv)
2470             HAVE_GALLIUM_ETNAVIV=yes
2471             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2472             require_libdrm "etnaviv"
2473             ;;
2474        ximx)
2475             HAVE_GALLIUM_IMX=yes
2476             ;;
2477         xswrast)
2478             HAVE_GALLIUM_SOFTPIPE=yes
2479             if test "x$enable_llvm" = xyes; then
2480                 HAVE_GALLIUM_LLVMPIPE=yes
2481             fi
2482             ;;
2483         xswr)
2484             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2485
2486             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2487                 ",-std=c++11" \
2488                 SWR_CXX11_CXXFLAGS
2489             AC_SUBST([SWR_CXX11_CXXFLAGS])
2490
2491             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2492                 ",-mavx,-march=core-avx" \
2493                 SWR_AVX_CXXFLAGS
2494             AC_SUBST([SWR_AVX_CXXFLAGS])
2495
2496             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2497                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2498                 SWR_AVX2_CXXFLAGS
2499             AC_SUBST([SWR_AVX2_CXXFLAGS])
2500
2501             HAVE_GALLIUM_SWR=yes
2502             ;;
2503         xvc4)
2504             HAVE_GALLIUM_VC4=yes
2505             require_libdrm "vc4"
2506
2507             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2508                               [USE_VC4_SIMULATOR=yes;
2509                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2510                               [USE_VC4_SIMULATOR=no])
2511             ;;
2512         xpl111)
2513             HAVE_GALLIUM_PL111=yes
2514             ;;
2515         xvirgl)
2516             HAVE_GALLIUM_VIRGL=yes
2517             require_libdrm "virgl"
2518             if test "x$enable_egl" = xyes; then
2519                 require_basic_egl "virgl"
2520             fi
2521             ;;
2522         *)
2523             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2524             ;;
2525         esac
2526     done
2527 fi
2528
2529 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2530 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2531                                               "x$LLVM_VERSION" != x3.9.1)
2532
2533 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2534     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2535     llvm_add_default_components "gallium"
2536 fi
2537
2538 dnl We need to validate some needed dependencies for renderonly drivers.
2539
2540 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2541     AC_MSG_ERROR([Building with imx requires etnaviv])
2542 fi
2543
2544 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2545     AC_MSG_ERROR([Building with pl111 requires vc4])
2546 fi
2547
2548 dnl
2549 dnl Set defines and buildtime variables only when using LLVM.
2550 dnl
2551 if test "x$enable_llvm" = xyes; then
2552     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2553
2554     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2555     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2556     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2557
2558     dnl Set LLVM_LIBS - This is done after the driver configuration so
2559     dnl that drivers can add additional components to LLVM_COMPONENTS.
2560     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2561     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2562     dnl this was causing the same libraries to be appear multiple times
2563     dnl in LLVM_LIBS.
2564
2565     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2566        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2567     fi
2568     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2569
2570     dnl llvm-config may not give the right answer when llvm is a built as a
2571     dnl single shared library, so we must work the library name out for
2572     dnl ourselves.
2573     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2574     if test "x$enable_llvm_shared_libs" = xyes; then
2575         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2576         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2577         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2578
2579         if test "x$llvm_have_one_so" = xyes; then
2580             dnl LLVM was built using auto*, so there is only one shared object.
2581             LLVM_LIBS="-l$LLVM_SO_NAME"
2582         else
2583             dnl If LLVM was built with CMake, there will be one shared object per
2584             dnl component.
2585             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2586                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2587         Please make sure you have built llvm with the --enable-shared option
2588         and that your llvm libraries are installed in $LLVM_LIBDIR
2589         If you have installed your llvm libraries to a different directory you
2590         can use the --with-llvm-prefix= configure flag to specify this directory.
2591         NOTE: Mesa is attempting to use llvm shared libraries by default.
2592         If you do not want to build with llvm shared libraries and instead want to
2593         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2594         invocation and rebuild.])])
2595
2596            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2597            dnl install uses a shared object for each component and we have
2598            dnl already added all of these objects to LLVM_LIBS.
2599         fi
2600     else
2601         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2602         dnl We need to link to llvm system libs when using static libs
2603         dnl However, only llvm 3.5+ provides --system-libs
2604         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2605             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2606         fi
2607     fi
2608 fi
2609
2610 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2612 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2613 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2614 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2617                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2625 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2626                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2627                                          "x$HAVE_GALLIUM_SWR" = xyes)
2628 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2629 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2630
2631 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2632
2633 if test "x$enable_dri" = xyes; then
2634     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2635 fi
2636
2637 if test "x$have_drisw_kms" = xyes; then
2638     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2639 fi
2640 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2641
2642 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2643 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2644 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2645 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2646 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2647 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2648
2649 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2650 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2651
2652 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2653                                       "x$HAVE_RADEON_VULKAN" = xyes)
2654
2655 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2656                                         "x$HAVE_I965_DRI" = xyes)
2657
2658 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2659                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2660                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2661 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2662 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2663 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2664 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2665
2666 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2667 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2668 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2669 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2670                                         "x$enable_gallium_osmesa" = xyes)
2671
2672 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2673 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2674 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2675 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2676
2677 AC_SUBST([NINE_MAJOR], 1)
2678 AC_SUBST([NINE_MINOR], 0)
2679 AC_SUBST([NINE_TINY], 0)
2680 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2681
2682 AC_SUBST([VDPAU_MAJOR], 1)
2683 AC_SUBST([VDPAU_MINOR], 0)
2684
2685 if test "x$enable_va" = xyes; then
2686     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2687     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2688 fi
2689 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2690 AC_SUBST([VA_MINOR], $VA_MINOR)
2691
2692 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2693
2694 AC_SUBST([XVMC_MAJOR], 1)
2695 AC_SUBST([XVMC_MINOR], 0)
2696
2697 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2698 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2699 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2700 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2701
2702 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2703 AC_SUBST([XA_MINOR], $XA_MINOR)
2704 AC_SUBST([XA_TINY], $XA_TINY)
2705 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2706
2707 AC_ARG_ENABLE(valgrind,
2708               [AS_HELP_STRING([--enable-valgrind],
2709                              [Build mesa with valgrind support (default: auto)])],
2710                              [VALGRIND=$enableval], [VALGRIND=auto])
2711 if test "x$VALGRIND" != xno; then
2712         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2713 fi
2714 AC_MSG_CHECKING([whether to enable Valgrind support])
2715 if test "x$VALGRIND" = xauto; then
2716         VALGRIND="$have_valgrind"
2717 fi
2718
2719 if test "x$VALGRIND" = "xyes"; then
2720         if ! test "x$have_valgrind" = xyes; then
2721                 AC_MSG_ERROR([Valgrind support required but not present])
2722         fi
2723         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2724 fi
2725
2726 AC_MSG_RESULT([$VALGRIND])
2727
2728 dnl Restore LDFLAGS and CPPFLAGS
2729 LDFLAGS="$_SAVE_LDFLAGS"
2730 CPPFLAGS="$_SAVE_CPPFLAGS"
2731
2732 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2733 if test "x$acv_mesa_CLANG" = xyes; then
2734     CFLAGS="$CFLAGS -Qunused-arguments"
2735     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2736 fi
2737
2738 dnl Add user CFLAGS and CXXFLAGS
2739 CFLAGS="$CFLAGS $USER_CFLAGS"
2740 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2741
2742 dnl Substitute the config
2743 AC_CONFIG_FILES([Makefile
2744                 src/Makefile
2745                 src/amd/Makefile
2746                 src/amd/vulkan/Makefile
2747                 src/broadcom/Makefile
2748                 src/compiler/Makefile
2749                 src/egl/Makefile
2750                 src/egl/main/egl.pc
2751                 src/egl/wayland/wayland-drm/Makefile
2752                 src/egl/wayland/wayland-egl/Makefile
2753                 src/egl/wayland/wayland-egl/wayland-egl.pc
2754                 src/gallium/Makefile
2755                 src/gallium/auxiliary/Makefile
2756                 src/gallium/auxiliary/pipe-loader/Makefile
2757                 src/gallium/drivers/freedreno/Makefile
2758                 src/gallium/drivers/ddebug/Makefile
2759                 src/gallium/drivers/i915/Makefile
2760                 src/gallium/drivers/llvmpipe/Makefile
2761                 src/gallium/drivers/noop/Makefile
2762                 src/gallium/drivers/nouveau/Makefile
2763                 src/gallium/drivers/pl111/Makefile
2764                 src/gallium/drivers/r300/Makefile
2765                 src/gallium/drivers/r600/Makefile
2766                 src/gallium/drivers/radeon/Makefile
2767                 src/gallium/drivers/radeonsi/Makefile
2768                 src/gallium/drivers/rbug/Makefile
2769                 src/gallium/drivers/softpipe/Makefile
2770                 src/gallium/drivers/svga/Makefile
2771                 src/gallium/drivers/swr/Makefile
2772                 src/gallium/drivers/trace/Makefile
2773                 src/gallium/drivers/etnaviv/Makefile
2774                 src/gallium/drivers/imx/Makefile
2775                 src/gallium/drivers/vc4/Makefile
2776                 src/gallium/drivers/virgl/Makefile
2777                 src/gallium/state_trackers/clover/Makefile
2778                 src/gallium/state_trackers/dri/Makefile
2779                 src/gallium/state_trackers/glx/xlib/Makefile
2780                 src/gallium/state_trackers/nine/Makefile
2781                 src/gallium/state_trackers/omx/Makefile
2782                 src/gallium/state_trackers/osmesa/Makefile
2783                 src/gallium/state_trackers/va/Makefile
2784                 src/gallium/state_trackers/vdpau/Makefile
2785                 src/gallium/state_trackers/xa/Makefile
2786                 src/gallium/state_trackers/xvmc/Makefile
2787                 src/gallium/targets/d3dadapter9/Makefile
2788                 src/gallium/targets/d3dadapter9/d3d.pc
2789                 src/gallium/targets/dri/Makefile
2790                 src/gallium/targets/libgl-xlib/Makefile
2791                 src/gallium/targets/omx/Makefile
2792                 src/gallium/targets/opencl/Makefile
2793                 src/gallium/targets/opencl/mesa.icd
2794                 src/gallium/targets/osmesa/Makefile
2795                 src/gallium/targets/osmesa/osmesa.pc
2796                 src/gallium/targets/pipe-loader/Makefile
2797                 src/gallium/targets/va/Makefile
2798                 src/gallium/targets/vdpau/Makefile
2799                 src/gallium/targets/xa/Makefile
2800                 src/gallium/targets/xa/xatracker.pc
2801                 src/gallium/targets/xvmc/Makefile
2802                 src/gallium/tests/trivial/Makefile
2803                 src/gallium/tests/unit/Makefile
2804                 src/gallium/winsys/etnaviv/drm/Makefile
2805                 src/gallium/winsys/imx/drm/Makefile
2806                 src/gallium/winsys/freedreno/drm/Makefile
2807                 src/gallium/winsys/i915/drm/Makefile
2808                 src/gallium/winsys/nouveau/drm/Makefile
2809                 src/gallium/winsys/pl111/drm/Makefile
2810                 src/gallium/winsys/radeon/drm/Makefile
2811                 src/gallium/winsys/amdgpu/drm/Makefile
2812                 src/gallium/winsys/svga/drm/Makefile
2813                 src/gallium/winsys/sw/dri/Makefile
2814                 src/gallium/winsys/sw/kms-dri/Makefile
2815                 src/gallium/winsys/sw/null/Makefile
2816                 src/gallium/winsys/sw/wrapper/Makefile
2817                 src/gallium/winsys/sw/xlib/Makefile
2818                 src/gallium/winsys/vc4/drm/Makefile
2819                 src/gallium/winsys/virgl/drm/Makefile
2820                 src/gallium/winsys/virgl/vtest/Makefile
2821                 src/gbm/Makefile
2822                 src/gbm/main/gbm.pc
2823                 src/glx/Makefile
2824                 src/glx/apple/Makefile
2825                 src/glx/tests/Makefile
2826                 src/glx/windows/Makefile
2827                 src/glx/windows/windowsdriproto.pc
2828                 src/gtest/Makefile
2829                 src/intel/Makefile
2830                 src/loader/Makefile
2831                 src/mapi/Makefile
2832                 src/mapi/es1api/glesv1_cm.pc
2833                 src/mapi/es2api/glesv2.pc
2834                 src/mapi/glapi/gen/Makefile
2835                 src/mesa/Makefile
2836                 src/mesa/gl.pc
2837                 src/mesa/drivers/dri/dri.pc
2838                 src/mesa/drivers/dri/common/Makefile
2839                 src/mesa/drivers/dri/common/xmlpool/Makefile
2840                 src/mesa/drivers/dri/i915/Makefile
2841                 src/mesa/drivers/dri/i965/Makefile
2842                 src/mesa/drivers/dri/Makefile
2843                 src/mesa/drivers/dri/nouveau/Makefile
2844                 src/mesa/drivers/dri/r200/Makefile
2845                 src/mesa/drivers/dri/radeon/Makefile
2846                 src/mesa/drivers/dri/swrast/Makefile
2847                 src/mesa/drivers/osmesa/Makefile
2848                 src/mesa/drivers/osmesa/osmesa.pc
2849                 src/mesa/drivers/x11/Makefile
2850                 src/mesa/main/tests/Makefile
2851                 src/util/Makefile
2852                 src/util/tests/hash_table/Makefile
2853                 src/vulkan/Makefile])
2854
2855 AC_OUTPUT
2856
2857 # Fix up dependencies in *.Plo files, where we changed the extension of a
2858 # source file
2859 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2860
2861
2862 dnl
2863 dnl Output some configuration info for the user
2864 dnl
2865 echo ""
2866 echo "        prefix:          $prefix"
2867 echo "        exec_prefix:     $exec_prefix"
2868 echo "        libdir:          $libdir"
2869 echo "        includedir:      $includedir"
2870
2871 dnl API info
2872 echo ""
2873 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2874
2875 dnl Driver info
2876 echo ""
2877 case "x$enable_osmesa$enable_gallium_osmesa" in
2878 xnoyes)
2879         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2880         ;;
2881 xyesno)
2882         echo "        OSMesa:          lib$OSMESA_LIB"
2883         ;;
2884 xnono)
2885         echo "        OSMesa:          no"
2886         ;;
2887 esac
2888
2889 echo ""
2890 if test "x$enable_dri" != xno; then
2891         echo "        DRI platform:    $dri_platform"
2892         if test -z "$DRI_DIRS"; then
2893             echo "        DRI drivers:     no"
2894         else
2895             echo "        DRI drivers:     $DRI_DIRS"
2896         fi
2897         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2898 fi
2899
2900 case "x$enable_glx" in
2901 xdri)
2902     echo "        GLX:             DRI-based"
2903     ;;
2904 xxlib)
2905     echo "        GLX:             Xlib-based"
2906     ;;
2907 xgallium-xlib)
2908     echo "        GLX:             Xlib-based (Gallium)"
2909     ;;
2910 *)
2911     echo "        GLX:             $enable_glx"
2912     ;;
2913 esac
2914
2915 dnl EGL
2916 echo ""
2917 echo "        EGL:             $enable_egl"
2918 if test "$enable_egl" = yes; then
2919
2920     egl_drivers=""
2921     if test "x$enable_dri" != "xno"; then
2922         egl_drivers="$egl_drivers builtin:egl_dri2"
2923     fi
2924     if test "x$enable_dri3" != "xno"; then
2925         egl_drivers="$egl_drivers builtin:egl_dri3"
2926     fi
2927
2928     echo "        EGL drivers:    $egl_drivers"
2929 fi
2930 if test "x$enable_gbm" = xyes; then
2931     echo "        GBM:             yes"
2932 else
2933     echo "        GBM:             no"
2934 fi
2935
2936     echo "        EGL/Vulkan/VL platforms:   $platforms"
2937
2938 # Vulkan
2939 echo ""
2940 if test "x$VULKAN_DRIVERS" != x; then
2941     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2942     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2943 else
2944     echo "        Vulkan drivers:  no"
2945 fi
2946
2947 echo ""
2948 if test "x$enable_llvm" = xyes; then
2949     echo "        llvm:            yes"
2950     echo "        llvm-config:     $LLVM_CONFIG"
2951     echo "        llvm-version:    $LLVM_VERSION"
2952 else
2953     echo "        llvm:            no"
2954 fi
2955
2956 echo ""
2957 if test -n "$with_gallium_drivers"; then
2958     echo "        Gallium drivers: $gallium_drivers"
2959     echo "        Gallium st:      $gallium_st"
2960 else
2961     echo "        Gallium:         no"
2962 fi
2963
2964 echo ""
2965 if test "x$enable_gallium_extra_hud" != xyes; then
2966     echo "        HUD extra stats: no"
2967 else
2968     echo "        HUD extra stats: yes"
2969 fi
2970
2971 if test "x$enable_lmsensors" != xyes; then
2972     echo "        HUD lmsensors:   no"
2973 else
2974     echo "        HUD lmsensors:   yes"
2975 fi
2976
2977 dnl Libraries
2978 echo ""
2979 echo "        Shared libs:     $enable_shared"
2980 echo "        Static libs:     $enable_static"
2981 echo "        Shared-glapi:    $enable_shared_glapi"
2982
2983 dnl Compiler options
2984 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2985 cflags=`echo $CFLAGS | \
2986     $SED 's/^ *//;s/  */ /;s/ *$//'`
2987 cxxflags=`echo $CXXFLAGS | \
2988     $SED 's/^ *//;s/  */ /;s/ *$//'`
2989 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2990 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2991 echo ""
2992 echo "        CFLAGS:          $cflags"
2993 echo "        CXXFLAGS:        $cxxflags"
2994 echo "        LDFLAGS:         $ldflags"
2995 echo "        Macros:          $defines"
2996 echo ""
2997 if test "x$enable_llvm" = xyes; then
2998     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2999     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3000     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3001     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3002     echo ""
3003 fi
3004 echo "        PYTHON2:         $PYTHON2"
3005
3006 echo ""
3007 echo "        Run '${MAKE-make}' to build Mesa"
3008 echo ""