configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.90
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.91
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 WAYLAND_PROTOCOLS_REQUIRED=1.8
  93 XCB_REQUIRED=1.9.3
  94 XCBDRI2_REQUIRED=1.8
  95 XCBDRI3_REQUIRED=1.13
  96 XCBGLX_REQUIRED=1.8.1
  97 XCBPRESENT_REQUIRED=1.13
  98 XDAMAGE_REQUIRED=1.1
  99 XSHMFENCE_REQUIRED=1.1
 100 XVMC_REQUIRED=1.0.6
 101 PYTHON_MAKO_REQUIRED=0.8.0
 102 LIBSENSORS_REQUIRED=4.0.0
 103 ZLIB_REQUIRED=1.2.3
 104
 105 dnl LLVM versions
 106 LLVM_REQUIRED_GALLIUM=3.3.0
 107 LLVM_REQUIRED_OPENCL=3.9.0
 108 LLVM_REQUIRED_R600=3.9.0
 109 LLVM_REQUIRED_RADEONSI=4.0.0
 110 LLVM_REQUIRED_RADV=4.0.0
 111 LLVM_REQUIRED_SWR=4.0.0
 112
 113 dnl Check for progs
 114 AC_PROG_CPP
 115 AC_PROG_CC
 116 AC_PROG_CXX
 117 dnl add this here, so the help for this environmnet variable is close to
 118 dnl other CC/CXX flags related help
 119 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 120                               enabled by default and different  from -std=c++11)])
 121 AM_PROG_CC_C_O
 122 AC_PROG_NM
 123 AM_PROG_AS
 124 AX_CHECK_GNU_MAKE
 125 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 126 AC_PROG_SED
 127 AC_PROG_MKDIR_P
 128
 129 AC_SYS_LARGEFILE
 130
 131
 132 LT_PREREQ([2.2])
 133 LT_INIT([disable-static])
 134
 135 AC_CHECK_PROG(RM, rm, [rm -f])
 136
 137 AX_PROG_BISON([],
 138               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 139                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 140 AX_PROG_FLEX([],
 141              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 142                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 143
 144 AC_CHECK_PROG(INDENT, indent, indent, cat)
 145 if test "x$INDENT" != "xcat"; then
 146     # Only GNU indent is supported
 147     INDENT_VERSION=`indent --version | grep GNU`
 148     if test $? -eq 0; then
 149        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 150     else
 151        INDENT="cat"
 152     fi
 153 fi
 154
 155 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 156
 157 if test -z "$PYTHON2"; then
 158     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 159         AC_MSG_ERROR([Python not found - unable to generate sources])
 160     fi
 161 else
 162     if test "x$acv_mako_found" = xno; then
 163         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 164             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 165         fi
 166     fi
 167 fi
 168
 169 AC_PROG_INSTALL
 170
 171 dnl We need a POSIX shell for parts of the build. Assume we have one
 172 dnl in most cases.
 173 case "$host_os" in
 174 solaris*)
 175     # Solaris /bin/sh is too old/non-POSIX compliant
 176     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 177     SHELL="$POSIX_SHELL"
 178     ;;
 179 esac
 180
 181 dnl clang is mostly GCC-compatible, but its version is much lower,
 182 dnl so we have to check for it.
 183 AC_MSG_CHECKING([if compiling with clang])
 184
 185 AC_COMPILE_IFELSE(
 186 [AC_LANG_PROGRAM([], [[
 187 #ifndef __clang__
 188        not clang
 189 #endif
 190 ]])],
 191 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 192
 193 AC_MSG_RESULT([$acv_mesa_CLANG])
 194
 195 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 196 dnl versions are explictly not supported.
 197 GEN_ASM_OFFSETS=no
 198 USE_GNU99=no
 199 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 200     AC_MSG_CHECKING([whether gcc version is sufficient])
 201     major=0
 202     minor=0
 203
 204     GCC_VERSION=`$CC -dumpversion`
 205     if test $? -eq 0; then
 206         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 207         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 208     fi
 209
 210     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 211         AC_MSG_RESULT([no])
 212         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 213     else
 214         AC_MSG_RESULT([yes])
 215     fi
 216
 217     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 218         USE_GNU99=yes
 219     fi
 220     if test "x$cross_compiling" = xyes; then
 221         GEN_ASM_OFFSETS=yes
 222     fi
 223 fi
 224
 225 dnl We don't support building Mesa with Sun C compiler
 226 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 227 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 228 if test "x$SUNCC" = xyes; then
 229     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 230 fi
 231
 232 dnl Check for compiler builtins
 233 AX_GCC_BUILTIN([__builtin_bswap32])
 234 AX_GCC_BUILTIN([__builtin_bswap64])
 235 AX_GCC_BUILTIN([__builtin_clz])
 236 AX_GCC_BUILTIN([__builtin_clzll])
 237 AX_GCC_BUILTIN([__builtin_ctz])
 238 AX_GCC_BUILTIN([__builtin_expect])
 239 AX_GCC_BUILTIN([__builtin_ffs])
 240 AX_GCC_BUILTIN([__builtin_ffsll])
 241 AX_GCC_BUILTIN([__builtin_popcount])
 242 AX_GCC_BUILTIN([__builtin_popcountll])
 243 AX_GCC_BUILTIN([__builtin_unreachable])
 244
 245 AX_GCC_FUNC_ATTRIBUTE([const])
 246 AX_GCC_FUNC_ATTRIBUTE([flatten])
 247 AX_GCC_FUNC_ATTRIBUTE([format])
 248 AX_GCC_FUNC_ATTRIBUTE([malloc])
 249 AX_GCC_FUNC_ATTRIBUTE([packed])
 250 AX_GCC_FUNC_ATTRIBUTE([pure])
 251 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 252 AX_GCC_FUNC_ATTRIBUTE([unused])
 253 AX_GCC_FUNC_ATTRIBUTE([visibility])
 254 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 255 AX_GCC_FUNC_ATTRIBUTE([weak])
 256 AX_GCC_FUNC_ATTRIBUTE([alias])
 257 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 258
 259 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 260
 261 dnl Make sure the pkg-config macros are defined
 262 m4_ifndef([PKG_PROG_PKG_CONFIG],
 263     [m4_fatal([Could not locate the pkg-config autoconf macros.
 264   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 265   are in a different location, try setting the environment variable
 266   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 267 PKG_PROG_PKG_CONFIG()
 268
 269 dnl LIB_DIR - library basename
 270 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 271 AC_SUBST([LIB_DIR])
 272
 273 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 274 _SAVE_LDFLAGS="$LDFLAGS"
 275 _SAVE_CPPFLAGS="$CPPFLAGS"
 276
 277 dnl Compiler macros
 278 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 279 AC_SUBST([DEFINES])
 280 android=no
 281 case "$host_os" in
 282 *-android*)
 283     android=yes
 284     ;;
 285 linux*|*-gnu*|gnu*|cygwin*)
 286     DEFINES="$DEFINES -D_GNU_SOURCE"
 287     ;;
 288 solaris*)
 289     DEFINES="$DEFINES -DSVR4"
 290     ;;
 291 esac
 292
 293 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 294
 295 dnl
 296 dnl Check compiler flags
 297 dnl
 298 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 299 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 300 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 301 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 302 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 303 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 304 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 305
 306 dnl
 307 dnl Check C++ compiler flags
 308 dnl
 309 AC_LANG_PUSH([C++])
 310 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 311 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 312 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 313 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 314 AC_LANG_POP([C++])
 315
 316 # Flags to help ensure that certain portions of the code -- and only those
 317 # portions -- can be built with MSVC:
 318 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 319 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 320 #   supports most of C99)
 321 # - the rest has no compiler compiler restrictions
 322 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 323 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 324 AC_LANG_PUSH([C++])
 325 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 326 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 327 AC_LANG_POP([C++])
 328
 329 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 330 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 331
 332 if test "x$GCC" = xyes; then
 333     if test "x$USE_GNU99" = xyes; then
 334         CFLAGS="$CFLAGS -std=gnu99"
 335     else
 336         CFLAGS="$CFLAGS -std=c99"
 337     fi
 338 fi
 339
 340 dnl
 341 dnl Check whether C++11 is supported, if the environment variable
 342 dnl CXX11_CXXFLAGS is set it takes precedence.
 343 dnl
 344
 345 AC_LANG_PUSH([C++])
 346
 347 check_cxx11_available() {
 348     output_support=$1
 349     AC_COMPILE_IFELSE(
 350         [AC_LANG_PROGRAM([
 351              #if !(__cplusplus >= 201103L)
 352              #error
 353              #endif
 354              #include <tuple>
 355         ])
 356     ], [
 357          AC_MSG_RESULT(yes)
 358          cxx11_support=yes
 359     ], AC_MSG_RESULT(no))
 360     eval "$output_support=\$cxx11_support"
 361 }
 362
 363 HAVE_CXX11=no
 364 save_CXXFLAGS="$CXXFLAGS"
 365
 366 dnl If the user provides a flag to enable c++11, then we test only this
 367 if test "x$CXX11_CXXFLAGS" != "x"; then
 368    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 369    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 370    check_cxx11_available HAVE_CXX11
 371 else
 372    dnl test whether c++11 is enabled by default
 373    AC_MSG_CHECKING(whether c++11 is enabled by default)
 374    check_cxx11_available HAVE_CXX11
 375
 376    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 377    if test "x$HAVE_CXX11" != "xyes"; then
 378        CXX11_CXXFLAGS=-std=c++11
 379        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 380        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 381        check_cxx11_available HAVE_CXX11
 382    fi
 383 fi
 384
 385 CXXFLAGS="$save_CXXFLAGS"
 386 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 387 AC_SUBST(CXX11_CXXFLAGS)
 388 AC_LANG_POP([C++])
 389
 390 dnl even if the compiler appears to support it, using visibility attributes isn't
 391 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 392 case "$host_os" in
 393 cygwin*)
 394     VISIBILITY_CFLAGS=""
 395     VISIBILITY_CXXFLAGS=""
 396     ;;
 397 esac
 398
 399 AC_SUBST([VISIBILITY_CFLAGS])
 400 AC_SUBST([VISIBILITY_CXXFLAGS])
 401
 402 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 403 dnl option is not supported. Hence, check for -Wfoo instead.
 404 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 405 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 406 AC_SUBST([WNO_OVERRIDE_INIT])
 407
 408 dnl
 409 dnl Optional flags, check for compiler support
 410 dnl
 411 SSE41_CFLAGS="-msse4.1"
 412 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 413 dnl stack, but on x86-32 such alignment is not guaranteed.
 414 case "$target_cpu" in
 415 i?86)
 416     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 417     ;;
 418 esac
 419 save_CFLAGS="$CFLAGS"
 420 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 421 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 422 #include <smmintrin.h>
 423 int param;
 424 int main () {
 425     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 426     c = _mm_max_epu32(a, b);
 427     return _mm_cvtsi128_si32(c);
 428 }]])], SSE41_SUPPORTED=1)
 429 CFLAGS="$save_CFLAGS"
 430 if test "x$SSE41_SUPPORTED" = x1; then
 431     DEFINES="$DEFINES -DUSE_SSE41"
 432 fi
 433 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 434 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 435
 436 dnl Check for new-style atomic builtins
 437 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 438 int main() {
 439     int n;
 440     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 441 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 442 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 443     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 444     dnl On some platforms, new-style atomics need a helper library
 445     AC_MSG_CHECKING(whether -latomic is needed)
 446     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 447     #include <stdint.h>
 448     uint64_t v;
 449     int main() {
 450         return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
 451     }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
 452     AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
 453     if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
 454         LIBATOMIC_LIBS="-latomic"
 455     fi
 456 fi
 457 AC_SUBST([LIBATOMIC_LIBS])
 458
 459 dnl Check if host supports 64-bit atomics
 460 dnl note that lack of support usually results in link (not compile) error
 461 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 462 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 463 #include <stdint.h>
 464 uint64_t v;
 465 int main() {
 466     return __sync_add_and_fetch(&v, (uint64_t)1);
 467 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 468 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 469     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 470 fi
 471 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 472
 473 dnl Check for Endianness
 474 AC_C_BIGENDIAN(
 475    little_endian=no,
 476    little_endian=yes,
 477    little_endian=no,
 478    little_endian=no
 479 )
 480
 481 dnl Check for POWER8 Architecture
 482 PWR8_CFLAGS="-mpower8-vector"
 483 have_pwr8_intrinsics=no
 484 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 485 save_CFLAGS=$CFLAGS
 486 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 487 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 488 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 489 #error "Need GCC >= 4.8 for sane POWER8 support"
 490 #endif
 491 #include <altivec.h>
 492 int main () {
 493     vector unsigned char r;
 494     vector unsigned int v = vec_splat_u32 (1);
 495     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 496     return 0;
 497 }]])], have_pwr8_intrinsics=yes)
 498 CFLAGS=$save_CFLAGS
 499
 500 AC_ARG_ENABLE(pwr8,
 501    [AS_HELP_STRING([--disable-pwr8],
 502                    [disable POWER8-specific instructions])],
 503    [enable_pwr8=$enableval], [enable_pwr8=auto])
 504
 505 if test "x$enable_pwr8" = xno ; then
 506    have_pwr8_intrinsics=disabled
 507 fi
 508
 509 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 510    DEFINES="$DEFINES -D_ARCH_PWR8"
 511    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 512    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 513 else
 514    PWR8_CFLAGS=
 515 fi
 516
 517 AC_MSG_RESULT($have_pwr8_intrinsics)
 518 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 519    AC_MSG_ERROR([POWER8 compiler support not detected])
 520 fi
 521
 522 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 523    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 524 fi
 525
 526 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 527
 528 dnl Can't have static and shared libraries, default to static if user
 529 dnl explicitly requested. If both disabled, set to static since shared
 530 dnl was explicitly requested.
 531 case "x$enable_static$enable_shared" in
 532 xyesyes)
 533     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 534     ;;
 535 xnono)
 536     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 537     ;;
 538 esac
 539
 540 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 541
 542 dnl
 543 dnl other compiler options
 544 dnl
 545 AC_ARG_ENABLE([debug],
 546     [AS_HELP_STRING([--enable-debug],
 547         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 548     [enable_debug="$enableval"],
 549     [enable_debug=no]
 550 )
 551
 552 AC_ARG_ENABLE([profile],
 553     [AS_HELP_STRING([--enable-profile],
 554         [enable profiling of code @<:@default=disabled@:>@])],
 555     [enable_profile="$enableval"],
 556     [enable_profile=no]
 557 )
 558
 559 AC_ARG_ENABLE([sanitize],
 560     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 561         [enable code sanitizer @<:@default=disabled@:>@])],
 562     [enable_sanitize="$enableval"],
 563     [enable_sanitize=no])
 564
 565 if test "x$enable_profile" = xyes; then
 566     DEFINES="$DEFINES -DPROFILE"
 567     if test "x$GCC" = xyes; then
 568         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 569     fi
 570     if test "x$GXX" = xyes; then
 571         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 572     fi
 573 fi
 574
 575 if test "x$enable_debug" = xyes; then
 576     DEFINES="$DEFINES -DDEBUG"
 577     if test "x$enable_profile" = xyes; then
 578         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 579     fi
 580     if test "x$GCC" = xyes; then
 581         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 582             CFLAGS="$CFLAGS -g"
 583         fi
 584         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 585             CFLAGS="$CFLAGS -O0"
 586         fi
 587     fi
 588     if test "x$GXX" = xyes; then
 589         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 590             CXXFLAGS="$CXXFLAGS -g"
 591         fi
 592         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 593             CXXFLAGS="$CXXFLAGS -O0"
 594         fi
 595     fi
 596 else
 597    DEFINES="$DEFINES -DNDEBUG"
 598 fi
 599
 600 if test "x$enable_sanitize" != xno; then
 601     if test "x$enable_profile" = xyes; then
 602         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 603     fi
 604
 605     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 606     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 607     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 608
 609     AC_LINK_IFELSE(
 610         [AC_LANG_SOURCE([int main(){return 0;}])],
 611         [],
 612         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 613 fi
 614
 615 dnl
 616 dnl Check if linker supports -Bsymbolic
 617 dnl
 618 save_LDFLAGS=$LDFLAGS
 619 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 620 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 621 AC_LINK_IFELSE(
 622     [AC_LANG_SOURCE([int main() { return 0;}])],
 623     [AC_MSG_RESULT([yes])
 624         BSYMBOLIC="-Wl,-Bsymbolic";],
 625     [AC_MSG_RESULT([no])
 626         BSYMBOLIC="";])
 627 LDFLAGS=$save_LDFLAGS
 628
 629 AC_SUBST([BSYMBOLIC])
 630
 631 dnl
 632 dnl Check if linker supports garbage collection
 633 dnl
 634 save_LDFLAGS=$LDFLAGS
 635 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 636 AC_MSG_CHECKING([whether ld supports --gc-sections])
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 639     [AC_MSG_RESULT([yes])
 640         GC_SECTIONS="-Wl,--gc-sections";],
 641     [AC_MSG_RESULT([no])
 642         GC_SECTIONS="";])
 643 LDFLAGS=$save_LDFLAGS
 644
 645 AC_SUBST([GC_SECTIONS])
 646
 647 dnl
 648 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 649 dnl so when these flags are passed to ld via libtool the checks will fail
 650 dnl
 651 case "$host_os" in
 652 openbsd* | darwin* )
 653     LD_NO_UNDEFINED="" ;;
 654 *)
 655     if test "x$enable_sanitize" = xno; then
 656         LD_NO_UNDEFINED="-Wl,--no-undefined"
 657     else
 658         LD_NO_UNDEFINED=""
 659     fi
 660     ;;
 661 esac
 662
 663 AC_SUBST([LD_NO_UNDEFINED])
 664
 665 dnl
 666 dnl Check if linker supports version scripts
 667 dnl
 668 AC_MSG_CHECKING([if the linker supports version-scripts])
 669 save_LDFLAGS=$LDFLAGS
 670 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 671 AC_LINK_IFELSE(
 672     [AC_LANG_SOURCE([int main() { return 0;}])],
 673     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 674     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 675 LDFLAGS=$save_LDFLAGS
 676 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 677
 678 dnl
 679 dnl Check if linker supports dynamic list files
 680 dnl
 681 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 682 save_LDFLAGS=$LDFLAGS
 683 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 684 AC_LINK_IFELSE(
 685     [AC_LANG_SOURCE([int main() { return 0;}])],
 686     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 687     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 688 LDFLAGS=$save_LDFLAGS
 689 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 690
 691 dnl
 692 dnl OSX linker does not support build-id
 693 dnl
 694 case "$host_os" in
 695 darwin*)
 696     LD_BUILD_ID=""
 697     ;;
 698 *)
 699     LD_BUILD_ID="-Wl,--build-id=sha1"
 700     ;;
 701 esac
 702 AC_SUBST([LD_BUILD_ID])
 703
 704 dnl
 705 dnl compatibility symlinks
 706 dnl
 707 case "$host_os" in
 708 linux* )
 709     HAVE_COMPAT_SYMLINKS=yes ;;
 710 * )
 711     HAVE_COMPAT_SYMLINKS=no ;;
 712 esac
 713
 714 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 715
 716 dnl
 717 dnl library names
 718 dnl
 719 dnl Unfortunately we need to do a few things that libtool can't help us with,
 720 dnl so we need some knowledge of shared library filenames:
 721 dnl
 722 dnl LIB_EXT is the extension used when creating symlinks for alternate
 723 dnl filenames for a shared library which will be dynamically loaded
 724 dnl
 725 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 726 dnl the file for a shared library we wish to link with
 727 dnl
 728 case "$host_os" in
 729 darwin* )
 730     LIB_EXT='dylib'
 731     IMP_LIB_EXT=$LIB_EXT
 732     ;;
 733 cygwin* )
 734     LIB_EXT='dll'
 735     IMP_LIB_EXT='dll.a'
 736     ;;
 737 aix* )
 738     LIB_EXT='a'
 739     IMP_LIB_EXT=$LIB_EXT
 740     ;;
 741 * )
 742     LIB_EXT='so'
 743     IMP_LIB_EXT=$LIB_EXT
 744     ;;
 745 esac
 746
 747 AC_SUBST([LIB_EXT])
 748
 749 dnl
 750 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 751 dnl
 752 AC_ARG_ENABLE([texture-float],
 753     [AS_HELP_STRING([--enable-texture-float],
 754         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 755     [enable_texture_float="$enableval"],
 756     [enable_texture_float=no]
 757 )
 758 if test "x$enable_texture_float" = xyes; then
 759     AC_MSG_WARN([Floating-point textures enabled.])
 760     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 761     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 762 fi
 763
 764 dnl
 765 dnl Arch/platform-specific settings
 766 dnl
 767 AC_ARG_ENABLE([asm],
 768     [AS_HELP_STRING([--disable-asm],
 769         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 770     [enable_asm="$enableval"],
 771     [enable_asm=yes]
 772 )
 773 asm_arch=""
 774 AC_MSG_CHECKING([whether to enable assembly])
 775 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 776 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 777 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 778     case "$host_cpu" in
 779     i?86 | x86_64 | amd64)
 780         if test "x$host_cpu" != "x$target_cpu"; then
 781             enable_asm=no
 782             AC_MSG_RESULT([no, cross compiling])
 783         fi
 784         ;;
 785     esac
 786 fi
 787 # check for supported arches
 788 if test "x$enable_asm" = xyes; then
 789     case "$host_cpu" in
 790     i?86)
 791         case "$host_os" in
 792         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 793             asm_arch=x86
 794             ;;
 795         esac
 796         ;;
 797     x86_64|amd64)
 798         case "$host_os" in
 799         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 800             asm_arch=x86_64
 801             ;;
 802         esac
 803         ;;
 804     sparc*)
 805         case "$host_os" in
 806         linux*)
 807             asm_arch=sparc
 808             ;;
 809         esac
 810         ;;
 811     powerpc64le)
 812         case "$host_os" in
 813         linux*)
 814             asm_arch=ppc64le
 815             ;;
 816         esac
 817         ;;
 818     aarch64)
 819         case "$host_os" in
 820         linux*)
 821             asm_arch=aarch64
 822             ;;
 823         esac
 824         ;;
 825     arm)
 826         case "$host_os" in
 827         linux*)
 828             asm_arch=arm
 829             ;;
 830         esac
 831         ;;
 832     esac
 833
 834     case "$asm_arch" in
 835     x86)
 836         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 837         AC_MSG_RESULT([yes, x86])
 838         ;;
 839     x86_64|amd64)
 840         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 841         AC_MSG_RESULT([yes, x86_64])
 842         ;;
 843     sparc)
 844         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 845         AC_MSG_RESULT([yes, sparc])
 846         ;;
 847     ppc64le)
 848         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 849         AC_MSG_RESULT([yes, ppc64le])
 850         ;;
 851     aarch64)
 852         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 853         AC_MSG_RESULT([yes, aarch64])
 854         ;;
 855     arm)
 856         DEFINES="$DEFINES -DUSE_ARM_ASM"
 857         AC_MSG_RESULT([yes, arm])
 858         ;;
 859     *)
 860         AC_MSG_RESULT([no, platform not supported])
 861         ;;
 862     esac
 863 fi
 864
 865 AC_HEADER_MAJOR
 866 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 867 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 868 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 869 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 870 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 871 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 872
 873 AC_MSG_CHECKING([whether strtod has locale support])
 874 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 875     #define _GNU_SOURCE
 876     #include <stdlib.h>
 877     #include <locale.h>
 878     #ifdef HAVE_XLOCALE_H
 879     #include <xlocale.h>
 880     #endif
 881     int main() {
 882        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 883        const char *s = "1.0";
 884        char *end;
 885        double d = strtod_l(s, end, loc);
 886        float f = strtof_l(s, end, loc);
 887        freelocale(loc);
 888        return 0;
 889     }]])],
 890   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 891    AC_MSG_RESULT([yes]),
 892    AC_MSG_RESULT([no]))
 893
 894 dnl Check to see if dlopen is in default libraries (like Solaris, which
 895 dnl has it in libc), or if libdl is needed to get it.
 896 AC_CHECK_FUNC([dlopen], [],
 897     [AC_CHECK_LIB([dl], [dlopen],
 898        [DLOPEN_LIBS="-ldl"])])
 899 AC_SUBST([DLOPEN_LIBS])
 900
 901 dnl Check if that library also has dladdr
 902 save_LIBS="$LIBS"
 903 LIBS="$LIBS $DLOPEN_LIBS"
 904 AC_CHECK_FUNCS([dladdr])
 905 LIBS="$save_LIBS"
 906
 907 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 908
 909 case "$host_os" in
 910 darwin*)
 911     ;;
 912 *)
 913     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 914                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 915                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 916     AC_SUBST([CLOCK_LIB])
 917     ;;
 918 esac
 919
 920 dnl See if posix_memalign is available
 921 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 922
 923 dnl Check for zlib
 924 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 925 DEFINES="$DEFINES -DHAVE_ZLIB"
 926
 927 dnl Check for pthreads
 928 AX_PTHREAD
 929 if test "x$ax_pthread_ok" = xno; then
 930     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 931 fi
 932 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 933 dnl to -pthread, which causes problems if we need -lpthread to appear in
 934 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 935 dnl is not valid for that platform.
 936 if test "x$android" = xno; then
 937     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 938 fi
 939 dnl According to the manual when using pthreads, one should add -pthread to
 940 dnl both compile and link-time arguments.
 941 dnl In practise that should be sufficient for all platforms, since any
 942 dnl platforms build with GCC and Clang support the flag.
 943 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 944
 945 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 946 dnl project. Even then there's a notable issue as described in the project README
 947 case "$host_os" in
 948 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 949     pthread_stubs_possible="no"
 950     ;;
 951 * )
 952     pthread_stubs_possible="yes"
 953     ;;
 954 esac
 955
 956 if test "x$pthread_stubs_possible" = xyes; then
 957     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 958 fi
 959
 960 dnl Check for futex for fast inline simple_mtx_t.
 961 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 962
 963 dnl SELinux awareness.
 964 AC_ARG_ENABLE([selinux],
 965     [AS_HELP_STRING([--enable-selinux],
 966         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 967     [MESA_SELINUX="$enableval"],
 968     [MESA_SELINUX=no])
 969 if test "x$enable_selinux" = "xyes"; then
 970     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 971         [AC_CHECK_HEADER([selinux/selinux.h],[],
 972                          [AC_MSG_ERROR([SELinux headers not found])])
 973          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 974                       [AC_MSG_ERROR([SELinux library not found])])
 975          SELINUX_LIBS="-lselinux"])
 976     DEFINES="$DEFINES -DMESA_SELINUX"
 977 fi
 978 AC_SUBST([SELINUX_CFLAGS])
 979 AC_SUBST([SELINUX_LIBS])
 980
 981 dnl
 982 dnl LLVM
 983 dnl
 984 AC_ARG_ENABLE([llvm-shared-libs],
 985     [AS_HELP_STRING([--enable-llvm-shared-libs],
 986         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 987     [enable_llvm_shared_libs="$enableval"],
 988     [enable_llvm_shared_libs=yes])
 989
 990 AC_ARG_WITH([llvm-prefix],
 991     [AS_HELP_STRING([--with-llvm-prefix],
 992         [Prefix for LLVM installations in non-standard locations])],
 993     [llvm_prefix="$withval"],
 994     [llvm_prefix=''])
 995
 996 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 997 if test "x$have_libelf" = xno; then
 998    LIBELF_LIBS=''
 999    LIBELF_CFLAGS=''
1000    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1001    AC_SUBST([LIBELF_LIBS])
1002    AC_SUBST([LIBELF_CFLAGS])
1003 fi
1004
1005 if test -z "$LLVM_CONFIG"; then
1006     if test -n "$llvm_prefix"; then
1007         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1008     else
1009         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1010     fi
1011 fi
1012
1013 llvm_add_component() {
1014     new_llvm_component=$1
1015     driver_name=$2
1016
1017     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1018         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1019     else
1020         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1021     fi
1022 }
1023
1024 llvm_add_optional_component() {
1025     new_llvm_component=$1
1026     driver_name=$2
1027
1028     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1029         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1030     fi
1031 }
1032
1033 llvm_add_default_components() {
1034     driver_name=$1
1035
1036     # Required default components
1037     llvm_add_component "bitwriter" $driver_name
1038     llvm_add_component "engine" $driver_name
1039     llvm_add_component "mcdisassembler" $driver_name
1040     llvm_add_component "mcjit" $driver_name
1041
1042     # Optional default components
1043     llvm_add_optional_component "inteljitevents" $driver_name
1044 }
1045
1046 llvm_add_target() {
1047     new_llvm_target=$1
1048     driver_name=$2
1049
1050     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1051         llvm_add_component $new_llvm_target $driver_name
1052     else
1053         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1054     fi
1055 }
1056
1057 # Call this inside ` ` to get the return value.
1058 # $1 is the llvm-config command with arguments.
1059 strip_unwanted_llvm_flags() {
1060     echo " `$1` " | sed -E \
1061         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1062         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1063         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1064         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1065         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1066         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1067         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1068         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1069         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1070         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1071         -e 's/^[[[:space:]]]//' \
1072         -e 's/[[[:space:]]]$//'
1073 }
1074
1075 llvm_set_environment_variables() {
1076     if test "x$LLVM_CONFIG" != xno; then
1077         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1078         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1079         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1080         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1081
1082         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1083         save_CFLAGS="$CFLAGS"
1084         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1085
1086         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1087             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1088         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1089             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1090         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1091             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1092
1093         CFLAGS="$save_CFLAGS"
1094
1095         # Only needed for LLVM < 3.6.0
1096         if test -z "$LLVM_VERSION_PATCH"; then
1097             LLVM_VERSION_PATCH=0
1098         fi
1099
1100         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1101
1102         FOUND_LLVM=yes
1103     else
1104         FOUND_LLVM=no
1105         LLVM_VERSION_INT=0
1106     fi
1107 }
1108
1109 require_llvm() {
1110     if test "x$enable_llvm" != "xyes"; then
1111         AC_MSG_ERROR([--enable-llvm is required when building $1])
1112     fi
1113 }
1114
1115 llvm_require_version() {
1116     require_llvm $2
1117
1118     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1119     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1120     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1121
1122     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1123         # major > required major
1124         #  --> OK
1125         return
1126     fi
1127
1128     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1129         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1130             # major = required major and
1131             # minor > required minor
1132             #  --> OK
1133             return
1134         else
1135             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1136                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1137                     # major = required major and
1138                     # minor = required minor and
1139                     # patch >= required patch
1140                     #  --> OK
1141                     return
1142                 fi
1143             fi
1144         fi
1145     fi
1146
1147     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1148 }
1149
1150 radeon_llvm_check() {
1151     if test ${LLVM_VERSION_INT} -lt 307; then
1152         amdgpu_llvm_target_name='r600'
1153     else
1154         amdgpu_llvm_target_name='amdgpu'
1155     fi
1156
1157     llvm_require_version $*
1158
1159     llvm_add_target $amdgpu_llvm_target_name $2
1160
1161     llvm_add_default_components $2
1162     llvm_add_component "bitreader" $2
1163     llvm_add_component "ipo" $2
1164
1165     if test "x$have_libelf" != xyes; then
1166        AC_MSG_ERROR([$2 requires libelf when using llvm])
1167     fi
1168 }
1169
1170 llvm_set_environment_variables
1171
1172 AC_SUBST([LLVM_CFLAGS])
1173 AC_SUBST([LLVM_CXXFLAGS])
1174 AC_SUBST([LLVM_LIBS])
1175 AC_SUBST([LLVM_LDFLAGS])
1176 AC_SUBST([LLVM_INCLUDEDIR])
1177
1178 dnl
1179 dnl libunwind
1180 dnl
1181 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1182 AC_ARG_ENABLE([libunwind],
1183     [AS_HELP_STRING([--enable-libunwind],
1184             [Use libunwind for backtracing (default: auto)])],
1185         [LIBUNWIND="$enableval"],
1186         [LIBUNWIND="$HAVE_LIBUNWIND"])
1187
1188 if test "x$LIBUNWIND" = "xyes"; then
1189     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1190     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1191 fi
1192
1193
1194 dnl Options for APIs
1195 AC_ARG_ENABLE([opengl],
1196     [AS_HELP_STRING([--disable-opengl],
1197         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1198     [enable_opengl="$enableval"],
1199     [enable_opengl=yes])
1200 AC_ARG_ENABLE([gles1],
1201     [AS_HELP_STRING([--disable-gles1],
1202         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1203     [enable_gles1="$enableval"],
1204     [enable_gles1=yes])
1205 AC_ARG_ENABLE([gles2],
1206     [AS_HELP_STRING([--disable-gles2],
1207         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1208     [enable_gles2="$enableval"],
1209     [enable_gles2=yes])
1210
1211 AC_ARG_ENABLE([dri],
1212     [AS_HELP_STRING([--enable-dri],
1213         [enable DRI modules @<:@default=enabled@:>@])],
1214     [enable_dri="$enableval"],
1215     [enable_dri=yes])
1216
1217 AC_ARG_ENABLE([gallium-extra-hud],
1218     [AS_HELP_STRING([--enable-gallium-extra-hud],
1219         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1220     [enable_gallium_extra_hud="$enableval"],
1221     [enable_gallium_extra_hud=no])
1222 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1223 if test "x$enable_gallium_extra_hud" = xyes ; then
1224     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1225 fi
1226
1227 #TODO: no pkgconfig .pc available for libsensors.
1228 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1229 AC_ARG_ENABLE([lmsensors],
1230     [AS_HELP_STRING([--enable-lmsensors],
1231         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1232     [enable_lmsensors="$enableval"],
1233     [enable_lmsensors=no])
1234 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1235 if test "x$enable_lmsensors" = xyes ; then
1236     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1237     LIBSENSORS_LIBS="-lsensors"
1238 else
1239     LIBSENSORS_LIBS=""
1240 fi
1241 AC_SUBST(LIBSENSORS_LIBS)
1242
1243 case "$host_os" in
1244 linux*)
1245     dri3_default=yes
1246     ;;
1247 *)
1248     dri3_default=no
1249     ;;
1250 esac
1251
1252 if test "x$enable_dri" = xno; then
1253     dri3_default=no
1254 fi
1255
1256 AC_ARG_ENABLE([dri3],
1257     [AS_HELP_STRING([--enable-dri3],
1258         [enable DRI3 @<:@default=auto@:>@])],
1259     [enable_dri3="$enableval"],
1260     [enable_dri3="$dri3_default"])
1261 AC_ARG_ENABLE([glx],
1262     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1263         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1264     [enable_glx="$enableval"],
1265     [enable_glx=yes])
1266 AC_ARG_ENABLE([osmesa],
1267     [AS_HELP_STRING([--enable-osmesa],
1268         [enable OSMesa library @<:@default=disabled@:>@])],
1269     [enable_osmesa="$enableval"],
1270     [enable_osmesa=no])
1271 AC_ARG_ENABLE([gallium-osmesa],
1272     [AS_HELP_STRING([--enable-gallium-osmesa],
1273         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1274     [enable_gallium_osmesa="$enableval"],
1275     [enable_gallium_osmesa=no])
1276 AC_ARG_ENABLE([egl],
1277     [AS_HELP_STRING([--disable-egl],
1278         [disable EGL library @<:@default=enabled@:>@])],
1279     [enable_egl="$enableval"],
1280     [enable_egl=yes])
1281
1282 AC_ARG_ENABLE([xa],
1283     [AS_HELP_STRING([--enable-xa],
1284         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1285     [enable_xa="$enableval"],
1286     [enable_xa=no])
1287 AC_ARG_ENABLE([gbm],
1288    [AS_HELP_STRING([--enable-gbm],
1289          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1290    [enable_gbm="$enableval"],
1291    [case "$host_os" in
1292        cygwin* | darwin*)
1293           enable_gbm=no
1294           ;;
1295        *)
1296           enable_gbm=yes
1297           ;;
1298     esac])
1299 AC_ARG_ENABLE([nine],
1300     [AS_HELP_STRING([--enable-nine],
1301         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1302     [enable_nine="$enableval"],
1303     [enable_nine=no])
1304
1305 AC_ARG_ENABLE([xvmc],
1306    [AS_HELP_STRING([--enable-xvmc],
1307          [enable xvmc library @<:@default=auto@:>@])],
1308    [enable_xvmc="$enableval"],
1309    [enable_xvmc=auto])
1310 AC_ARG_ENABLE([vdpau],
1311    [AS_HELP_STRING([--enable-vdpau],
1312          [enable vdpau library @<:@default=auto@:>@])],
1313    [enable_vdpau="$enableval"],
1314    [enable_vdpau=auto])
1315 AC_ARG_ENABLE([omx],
1316    [AS_HELP_STRING([--enable-omx],
1317          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1318    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1319    [])
1320 AC_ARG_ENABLE([omx-bellagio],
1321    [AS_HELP_STRING([--enable-omx-bellagio],
1322          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1323    [enable_omx_bellagio="$enableval"],
1324    [enable_omx_bellagio=no])
1325 AC_ARG_ENABLE([omx-tizonia],
1326    [AS_HELP_STRING([--enable-omx-tizonia],
1327          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1328    [enable_omx_tizonia="$enableval"],
1329    [enable_omx_tizonia=no])
1330 AC_ARG_ENABLE([va],
1331    [AS_HELP_STRING([--enable-va],
1332          [enable va library @<:@default=auto@:>@])],
1333    [enable_va="$enableval"],
1334    [enable_va=auto])
1335 AC_ARG_ENABLE([opencl],
1336    [AS_HELP_STRING([--enable-opencl],
1337          [enable OpenCL library @<:@default=disabled@:>@])],
1338    [enable_opencl="$enableval"],
1339    [enable_opencl=no])
1340 AC_ARG_ENABLE([opencl_icd],
1341    [AS_HELP_STRING([--enable-opencl-icd],
1342           [Build an OpenCL ICD library to be loaded by an ICD implementation
1343            @<:@default=enabled@:>@])],
1344     [enable_opencl_icd="$enableval"],
1345     [enable_opencl_icd=yes])
1346
1347 AC_ARG_ENABLE([gallium-tests],
1348     [AS_HELP_STRING([--enable-gallium-tests],
1349         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1350     [enable_gallium_tests="$enableval"],
1351     [enable_gallium_tests=no])
1352
1353 # Option for Gallium drivers
1354
1355 # Keep this in sync with the --with-gallium-drivers help string default value
1356 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1357
1358 AC_ARG_WITH([gallium-drivers],
1359     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1360         [comma delimited Gallium drivers list, e.g.
1361         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,vc4,vc5,virgl,etnaviv,imx"
1362         @<:@default=r300,r600,svga,swrast@:>@])],
1363     [with_gallium_drivers="$withval"],
1364     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1365
1366 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1367 # here so that the script doesn't choke on an unknown driver name later.
1368 case "$with_gallium_drivers" in
1369     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1370     no) with_gallium_drivers='' ;;
1371 esac
1372
1373 if test "x$enable_opengl" = xno -a \
1374         "x$enable_gles1" = xno -a \
1375         "x$enable_gles2" = xno -a \
1376         "x$enable_nine" = xno -a \
1377         "x$enable_xa" = xno -a \
1378         "x$enable_xvmc" = xno -a \
1379         "x$enable_vdpau" = xno -a \
1380         "x$enable_omx_bellagio" = xno -a \
1381         "x$enable_omx_tizonia" = xno -a \
1382         "x$enable_va" = xno -a \
1383         "x$enable_opencl" = xno; then
1384     AC_MSG_ERROR([at least one API should be enabled])
1385 fi
1386
1387 if test "x$enable_omx_bellagio" = xyes -a \
1388         "x$enable_omx_tizonia" = xyes; then
1389    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1390 fi
1391
1392 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1393 if test "x$enable_opengl" = xno -a \
1394         "x$enable_gles1" = xyes; then
1395     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1396 fi
1397
1398 if test "x$enable_opengl" = xno -a \
1399         "x$enable_gles2" = xyes; then
1400     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1401 fi
1402
1403 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1404 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1405 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1406 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1407                                         "x$enable_gles1" = xyes -o \
1408                                         "x$enable_gles2" = xyes)
1409 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1410                                       "x$enable_gles1" = xyes -o \
1411                                       "x$enable_gles2" = xyes)
1412
1413 # Validate GLX options
1414 if test "x$enable_glx" = xyes; then
1415     if test "x$enable_dri" = xyes; then
1416         enable_glx=dri
1417     elif test -n "$with_gallium_drivers"; then
1418         enable_glx=gallium-xlib
1419     else
1420         enable_glx=xlib
1421     fi
1422 fi
1423 case "x$enable_glx" in
1424 xdri | xxlib | xgallium-xlib)
1425     # GLX requires OpenGL
1426     if test "x$enable_opengl" = xno; then
1427         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1428     fi
1429
1430     # Check individual dependencies
1431     case "x$enable_glx" in
1432     xdri)
1433         if test "x$enable_dri" = xno; then
1434             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1435         fi
1436         ;;
1437     xxlib)
1438         if test "x$enable_dri" = xyes; then
1439             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1440         fi
1441         ;;
1442     xgallium-xlib )
1443         if test "x$enable_dri" = xyes; then
1444             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1445         fi
1446         if test -z "$with_gallium_drivers"; then
1447             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1448         fi
1449         ;;
1450     esac
1451     ;;
1452 xno)
1453     ;;
1454 *)
1455     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1456     ;;
1457 esac
1458
1459 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1460 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1461 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1462 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1463
1464 DEFAULT_GL_LIB_NAME=GL
1465
1466 dnl
1467 dnl Libglvnd configuration
1468 dnl
1469 AC_ARG_ENABLE([libglvnd],
1470     [AS_HELP_STRING([--enable-libglvnd],
1471         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1472     [enable_libglvnd="$enableval"],
1473     [enable_libglvnd=no])
1474 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1475
1476 if test "x$enable_libglvnd" = xyes ; then
1477     case "x$enable_glx" in
1478     xxlib | xgallium-xlib )
1479         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1480         ;;
1481     esac
1482
1483     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1484     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1485     AC_SUBST([LIBGLVND_DATADIR])
1486
1487     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1488     DEFAULT_GL_LIB_NAME=GLX_mesa
1489
1490     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1491         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1492     fi
1493 fi
1494
1495 AC_ARG_WITH([gl-lib-name],
1496   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1497     [specify GL library name @<:@default=GL@:>@])],
1498   [GL_LIB=$withval],
1499   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1500 AC_ARG_WITH([osmesa-lib-name],
1501   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1502     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1503   [OSMESA_LIB=$withval],
1504   [OSMESA_LIB=OSMesa])
1505 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1506 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1507
1508 dnl
1509 dnl Mangled Mesa support
1510 dnl
1511 AC_ARG_ENABLE([mangling],
1512   [AS_HELP_STRING([--enable-mangling],
1513     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1514   [enable_mangling="${enableval}"],
1515   [enable_mangling=no]
1516 )
1517 if test "x${enable_mangling}" = "xyes" ; then
1518   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1519   GL_LIB="Mangled${GL_LIB}"
1520   OSMESA_LIB="Mangled${OSMESA_LIB}"
1521 fi
1522 AC_SUBST([GL_LIB])
1523 AC_SUBST([OSMESA_LIB])
1524
1525 # Check for libdrm
1526 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1527                   [have_libdrm=yes], [have_libdrm=no])
1528 if test "x$have_libdrm" = xyes; then
1529     DEFINES="$DEFINES -DHAVE_LIBDRM"
1530 fi
1531
1532 require_libdrm() {
1533     if test "x$have_libdrm" != xyes; then
1534        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1535     fi
1536 }
1537
1538
1539 # Select which platform-dependent DRI code gets built
1540 case "$host_os" in
1541 darwin*)
1542     dri_platform='apple' ;;
1543 cygwin*)
1544     dri_platform='windows' ;;
1545 gnu*)
1546     dri_platform='none' ;;
1547 *)
1548     dri_platform='drm' ;;
1549 esac
1550
1551 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1552     have_drisw_kms='yes'
1553 fi
1554
1555 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1556 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1557 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1558 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1559 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1560 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1561 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1562 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1563 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1564
1565 AC_ARG_ENABLE([shared-glapi],
1566     [AS_HELP_STRING([--enable-shared-glapi],
1567         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1568     [enable_shared_glapi="$enableval"],
1569     [enable_shared_glapi=yes])
1570
1571 case "x$enable_opengl$enable_gles1$enable_gles2" in
1572 x*yes*yes*)
1573     if test "x$enable_shared_glapi" = xno; then
1574         AC_MSG_ERROR([shared GLAPI required when building two or more of
1575                       the following APIs - opengl, gles1 gles2])
1576     fi
1577     ;;
1578 esac
1579
1580 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1581
1582 # Build the pipe-drivers as separate libraries/modules.
1583 # Do not touch this unless you know what you are doing.
1584 # XXX: Expose via configure option ?
1585 enable_shared_pipe_drivers=no
1586
1587 dnl
1588 dnl Driver specific build directories
1589 dnl
1590
1591 if test "x$enable_gallium_osmesa" = xyes; then
1592     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1593         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1594     fi
1595     if test "x$enable_osmesa" = xyes; then
1596         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1597     fi
1598 fi
1599
1600 require_dri_shared_libs_and_glapi() {
1601     if test "x$enable_static" = xyes; then
1602         AC_MSG_ERROR([$1 cannot be build as static library])
1603     fi
1604
1605     if test "x$enable_dri" != xyes; then
1606         # There is only a single backend which won't be build/used otherwise.
1607         # XXX: Revisit this as the egl/haiku is a thing.
1608         AC_MSG_ERROR([$1 requires --enable-dri])
1609     fi
1610
1611     if test "x$enable_shared_glapi" != xyes; then
1612         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1613     fi
1614 }
1615
1616 if test "x$enable_dri" = xyes; then
1617     require_dri_shared_libs_and_glapi "DRI"
1618
1619     # not a hard requirement as swrast does not depend on it
1620     if test "x$have_libdrm" = xyes; then
1621         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1622     fi
1623 fi
1624
1625 AC_ARG_ENABLE([driglx-direct],
1626     [AS_HELP_STRING([--disable-driglx-direct],
1627         [disable direct rendering in GLX and EGL for DRI \
1628             @<:@default=enabled@:>@])],
1629     [driglx_direct="$enableval"],
1630     [driglx_direct="yes"])
1631
1632 dnl
1633 dnl libGL configuration per driver
1634 dnl
1635 if test "x$enable_glx" != xno; then
1636     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1637 fi
1638 case "x$enable_glx" in
1639 xxlib | xgallium-xlib)
1640     # Xlib-based GLX
1641     dri_modules="x11 xext xcb"
1642     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1643     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1644     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1645     GL_LIB_DEPS="$XLIBGL_LIBS"
1646     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1647     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1648     ;;
1649 xdri)
1650     # DRI-based GLX
1651
1652     # find the DRI deps for libGL
1653     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1654
1655     if test x"$driglx_direct" = xyes; then
1656         if test x"$dri_platform" = xdrm ; then
1657             DEFINES="$DEFINES -DGLX_USE_DRM"
1658             require_libdrm "Direct rendering"
1659
1660             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1661             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1662
1663             if test x"$enable_dri" = xyes; then
1664                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1665             fi
1666         fi
1667         if test x"$dri_platform" = xapple ; then
1668             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1669         fi
1670         if test x"$dri_platform" = xwindows ; then
1671             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1672         fi
1673     fi
1674
1675     # add xf86vidmode if available
1676     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1677     if test "$HAVE_XF86VIDMODE" = yes ; then
1678         dri_modules="$dri_modules xxf86vm"
1679     fi
1680
1681     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1682     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1683     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1684     GL_LIB_DEPS="$DRIGL_LIBS"
1685
1686     # need DRM libs, $PTHREAD_LIBS, etc.
1687     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1688     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1689     ;;
1690 esac
1691
1692 # This is outside the case (above) so that it is invoked even for non-GLX
1693 # builds.
1694 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1695
1696 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1697 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1698 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1699 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1700
1701 AC_SUBST([X11_INCLUDES])
1702 AC_SUBST([GL_LIB_DEPS])
1703 AC_SUBST([GL_PC_REQ_PRIV])
1704 AC_SUBST([GL_PC_LIB_PRIV])
1705 AC_SUBST([GL_PC_CFLAGS])
1706 AC_SUBST([DRI_PC_REQ_PRIV])
1707 AC_SUBST([GLESv1_CM_LIB_DEPS])
1708 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1709 AC_SUBST([GLESv2_LIB_DEPS])
1710 AC_SUBST([GLESv2_PC_LIB_PRIV])
1711
1712 AC_SUBST([HAVE_XF86VIDMODE])
1713
1714 dnl
1715 dnl More GLX setup
1716 dnl
1717 case "x$enable_glx" in
1718 xxlib | xgallium-xlib)
1719     DEFINES="$DEFINES -DUSE_XSHM"
1720     ;;
1721 xdri)
1722     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1723     if test "x$driglx_direct" = xyes; then
1724         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1725     fi
1726     ;;
1727 esac
1728
1729 dnl
1730 dnl TLS detection
1731 dnl
1732
1733 AC_ARG_ENABLE([glx-tls],
1734     [AS_HELP_STRING([--enable-glx-tls],
1735         [enable TLS support in GLX @<:@default=enabled@:>@])],
1736     [GLX_USE_TLS="$enableval"],
1737     [GLX_USE_TLS=yes])
1738 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1739
1740 if test "x$GLX_USE_TLS" = xyes; then
1741     DEFINES="$DEFINES -DGLX_USE_TLS"
1742 fi
1743
1744 dnl Read-only text section on x86 hardened platforms
1745 AC_ARG_ENABLE([glx-read-only-text],
1746     [AS_HELP_STRING([--enable-glx-read-only-text],
1747         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1748     [enable_glx_read_only_text="$enableval"],
1749     [enable_glx_read_only_text=no])
1750 if test "x$enable_glx_read_only_text" = xyes; then
1751     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1752 fi
1753
1754 dnl
1755 dnl DEPRECATED: EGL Platforms configuration
1756 dnl
1757 AC_ARG_WITH([egl-platforms],
1758     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1759         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1760     [with_egl_platforms="$withval"],
1761     [with_egl_platforms=auto])
1762
1763 if test "x$with_egl_platforms" = xauto; then
1764     with_egl_platforms="x11,surfaceless"
1765     if test "x$enable_gbm" = xyes; then
1766         with_egl_platforms="$with_egl_platforms,drm"
1767     fi
1768 else
1769     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1770 fi
1771
1772 dnl
1773 dnl Platforms configuration
1774 dnl
1775 AC_ARG_WITH([platforms],
1776     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1777         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1778         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1779     [with_platforms="$withval"],
1780     [with_platforms=auto])
1781
1782 # Reuse the autodetection rather than duplicating it.
1783 if test "x$with_platforms" = xauto; then
1784     with_platforms=$with_egl_platforms
1785 fi
1786
1787 # Do per platform setups and checks
1788 platforms=`IFS=', '; echo $with_platforms`
1789 for plat in $platforms; do
1790     case "$plat" in
1791     wayland)
1792
1793         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1794         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1795         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1796         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1797
1798         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1799                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1800                           WAYLAND_SCANNER='')
1801         if test "x$WAYLAND_SCANNER" = x; then
1802             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1803         fi
1804
1805         if test "x$WAYLAND_SCANNER" = "x:"; then
1806                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1807         fi
1808         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1809         ;;
1810
1811     x11)
1812         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1813         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1814         ;;
1815
1816     drm)
1817         test "x$enable_gbm" = "xno" &&
1818                 AC_MSG_ERROR([EGL platform drm needs gbm])
1819         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1820         ;;
1821
1822     surfaceless)
1823         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1824         ;;
1825
1826     android)
1827         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1828         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1829         ;;
1830
1831     *)
1832         AC_MSG_ERROR([platform '$plat' does not exist])
1833         ;;
1834     esac
1835
1836     case "$plat" in
1837     wayland|drm|surfaceless)
1838         require_libdrm "Platform $plat"
1839         ;;
1840     esac
1841 done
1842 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1843
1844 if test "x$enable_glx" != xno; then
1845     if ! echo "$platforms" | grep -q 'x11'; then
1846         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1847     fi
1848 fi
1849
1850 if test x"$enable_dri3" = xyes; then
1851     DEFINES="$DEFINES -DHAVE_DRI3"
1852
1853     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 >= $XCBDRI3_REQUIRED xcb-xfixes xcb-present >= $XCBPRESENT_REQUIRED xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1854     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1855 fi
1856
1857 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1858 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1859 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1860 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1861 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1862
1863 dnl
1864 dnl More DRI setup
1865 dnl
1866 dnl Directory for DRI drivers
1867 AC_ARG_WITH([dri-driverdir],
1868     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1869         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1870     [DRI_DRIVER_INSTALL_DIR="$withval"],
1871     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1872 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1873 dnl Extra search path for DRI drivers
1874 AC_ARG_WITH([dri-searchpath],
1875     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1876         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1877     [DRI_DRIVER_SEARCH_DIR="$withval"],
1878     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1879 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1880 dnl Which drivers to build - default is chosen by platform
1881 AC_ARG_WITH([dri-drivers],
1882     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1883         [comma delimited classic DRI drivers list, e.g.
1884         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1885     [with_dri_drivers="$withval"],
1886     [with_dri_drivers=auto])
1887
1888 if test "x$with_dri_drivers" = xauto; then
1889     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1890         with_dri_drivers="yes"
1891     else
1892         with_dri_drivers="no"
1893     fi
1894 fi
1895 if test "x$with_dri_drivers" = xno; then
1896     with_dri_drivers=''
1897 fi
1898
1899 # Check for expat
1900 PKG_CHECK_MODULES([EXPAT], [expat],,
1901     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1902 )
1903
1904 dnl If $with_dri_drivers is yes, drivers will be added through
1905 dnl platform checks. Set DEFINES and LIB_DEPS
1906 if test "x$enable_dri" = xyes; then
1907     # Platform specific settings and drivers to build
1908     case "$host_os" in
1909     linux*)
1910         case "$host_cpu" in
1911         powerpc* | sparc*)
1912             # Build only the drivers for cards that exist on PowerPC/sparc
1913             if test "x$with_dri_drivers" = "xyes"; then
1914                 with_dri_drivers="r200 radeon swrast"
1915             fi
1916             ;;
1917         esac
1918         ;;
1919     cygwin*)
1920         if test "x$with_dri_drivers" = "xyes"; then
1921             with_dri_drivers="swrast"
1922         fi
1923         ;;
1924     darwin*)
1925         DEFINES="$DEFINES -DBUILDING_MESA"
1926         if test "x$with_dri_drivers" = "xyes"; then
1927             with_dri_drivers="swrast"
1928         fi
1929         ;;
1930     esac
1931
1932     # default drivers
1933     if test "x$with_dri_drivers" = "xyes"; then
1934         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1935     fi
1936
1937     # put all the necessary libs together
1938     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1939 fi
1940
1941 AC_SUBST([DRI_LIB_DEPS])
1942
1943 DRI_DIRS=''
1944 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1945 if test -n "$with_dri_drivers"; then
1946     if test "x$enable_opengl" != xyes; then
1947         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1948     fi
1949
1950     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1951     for driver in $dri_drivers; do
1952         DRI_DIRS="$DRI_DIRS $driver"
1953         case "x$driver" in
1954         xi915)
1955             require_libdrm "i915"
1956             HAVE_I915_DRI=yes
1957             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1958             ;;
1959         xi965)
1960             require_libdrm "i965"
1961             HAVE_I965_DRI=yes
1962             ;;
1963         xnouveau)
1964             require_libdrm "nouveau"
1965             HAVE_NOUVEAU_DRI=yes
1966             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1967             ;;
1968         xradeon)
1969             require_libdrm "radeon"
1970             HAVE_RADEON_DRI=yes;
1971             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1972             ;;
1973         xr200)
1974             require_libdrm "r200"
1975             HAVE_R200_DRI=yes
1976             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1977             ;;
1978         xswrast)
1979             HAVE_SWRAST_DRI=yes
1980             ;;
1981         *)
1982             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1983             ;;
1984         esac
1985     done
1986     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1987 fi
1988
1989
1990 dnl
1991 dnl Gallium LLVM
1992 dnl Deprecated: kept for backwards compatibility
1993 dnl
1994 AC_ARG_ENABLE([gallium-llvm],
1995     [AS_HELP_STRING([--enable-gallium-llvm],
1996         [DEPRECATED: use --enable-llvm instead])],
1997     [enable_gallium_llvm="$enableval"],
1998     [enable_gallium_llvm=auto])
1999
2000 if test "x$enable_gallium_llvm" != xauto; then
2001    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2002    enable_llvm=$enable_gallium_llvm
2003 fi
2004
2005 dnl
2006 dnl LLVM
2007 dnl
2008 AC_ARG_ENABLE([llvm],
2009     [AS_HELP_STRING([--enable-llvm],
2010         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2011     [enable_llvm="$enableval"],
2012     [enable_llvm=auto])
2013
2014 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2015     if test "x$FOUND_LLVM" = xyes; then
2016         case "$host_cpu" in
2017         i*86|x86_64|amd64) enable_llvm=yes;;
2018         *) enable_llvm=no;;
2019         esac
2020     else
2021         enable_llvm=no
2022     fi
2023 fi
2024
2025 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2026     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2027 fi
2028
2029 #
2030 # Vulkan driver configuration
2031 #
2032
2033 AC_ARG_WITH([vulkan-drivers],
2034     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2035         [comma delimited Vulkan drivers list, e.g.
2036         "intel,radeon"
2037         @<:@default=no@:>@])],
2038     [with_vulkan_drivers="$withval"],
2039     [with_vulkan_drivers="no"])
2040
2041 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2042 # here so that the script doesn't choke on an unknown driver name later.
2043 case "x$with_vulkan_drivers" in
2044     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2045     xno) with_vulkan_drivers='' ;;
2046 esac
2047
2048 AC_ARG_WITH([vulkan-icddir],
2049     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2050         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2051     [VULKAN_ICD_INSTALL_DIR="$withval"],
2052     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2053 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2054
2055 require_x11_dri3() {
2056     if echo "$platforms" | grep -q 'x11'; then
2057         if test "x$enable_dri3" != xyes; then
2058             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2059         fi
2060     fi
2061 }
2062
2063 if test -n "$with_vulkan_drivers"; then
2064     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2065         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2066     fi
2067
2068     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2069     for driver in $VULKAN_DRIVERS; do
2070         case "x$driver" in
2071         xintel)
2072             require_libdrm "ANV"
2073             require_x11_dri3 "ANV"
2074             HAVE_INTEL_VULKAN=yes
2075             ;;
2076         xradeon)
2077             require_libdrm "radv"
2078             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2079             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2080             require_x11_dri3 "radv"
2081             HAVE_RADEON_VULKAN=yes
2082             ;;
2083         *)
2084             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2085             ;;
2086         esac
2087     done
2088     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2089 fi
2090
2091
2092 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2093 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2094 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2095                                   "x$enable_osmesa" = xyes -o \
2096                                   -n "$DRI_DIRS")
2097
2098 dnl
2099 dnl OSMesa configuration
2100 dnl
2101
2102 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2103 AC_ARG_WITH([osmesa-bits],
2104     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2105         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2106     [osmesa_bits="$withval"],
2107     [osmesa_bits=8])
2108 if test "x$osmesa_bits" != x8; then
2109     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2110         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2111         osmesa_bits=8
2112     fi
2113 fi
2114 case "x$osmesa_bits" in
2115 x8)
2116     OSMESA_LIB="${OSMESA_LIB}"
2117     ;;
2118 x16|x32)
2119     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2120     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2121     ;;
2122 *)
2123     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2124     ;;
2125 esac
2126
2127 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2128     # only link libraries with osmesa if shared
2129     if test "$enable_static" = no; then
2130         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2131     else
2132         OSMESA_LIB_DEPS=""
2133     fi
2134     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2135 fi
2136
2137 AC_SUBST([OSMESA_LIB_DEPS])
2138 AC_SUBST([OSMESA_PC_REQ])
2139 AC_SUBST([OSMESA_PC_LIB_PRIV])
2140
2141 dnl
2142 dnl gbm configuration
2143 dnl
2144 if test "x$enable_gbm" = xyes; then
2145     require_dri_shared_libs_and_glapi "gbm"
2146 fi
2147 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2148 # FINISHME: GBM has a number of dependencies which we should add below
2149 GBM_PC_REQ_PRIV=""
2150 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2151 AC_SUBST([GBM_PC_REQ_PRIV])
2152 AC_SUBST([GBM_PC_LIB_PRIV])
2153
2154 dnl
2155 dnl EGL configuration
2156 dnl
2157
2158 if test "x$enable_egl" = xyes; then
2159     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2160
2161     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2162
2163     require_dri_shared_libs_and_glapi "egl"
2164 fi
2165 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2166 AC_SUBST([EGL_LIB_DEPS])
2167
2168 gallium_st="mesa"
2169
2170 dnl
2171 dnl XA configuration
2172 dnl
2173 if test "x$enable_xa" = xyes; then
2174     if test "x$with_gallium_drivers" = xswrast; then
2175        AC_MSG_ERROR([
2176           Building xa requires at least one non swrast gallium driver.
2177           If you are looking to use libxatracker.so with the VMware driver,
2178           make sure to include svga in the gallium drivers list, apart from
2179           enabling XA.
2180           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2181     fi
2182     gallium_st="$gallium_st xa"
2183 fi
2184 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2185
2186 if echo $platforms | grep -q "x11"; then
2187     have_xvmc_platform=yes
2188 else
2189     have_xvmc_platform=no
2190 fi
2191
2192 if echo $platforms | grep -q "x11"; then
2193     have_vdpau_platform=yes
2194 else
2195     have_vdpau_platform=no
2196 fi
2197
2198 if echo $platforms | grep -q "x11\|drm"; then
2199     have_omx_platform=yes
2200 else
2201     have_omx_platform=no
2202 fi
2203
2204 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2205     have_va_platform=yes
2206 else
2207     have_va_platform=no
2208 fi
2209
2210 dnl
2211 dnl Gallium G3DVL configuration
2212 dnl
2213 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2214     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2215         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2216     fi
2217
2218     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2219         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2220     fi
2221
2222     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2223         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2224     fi
2225
2226     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2227        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2228     fi
2229
2230     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2231         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2232     fi
2233 fi
2234
2235 if test "x$enable_dri" = xyes -o \
2236         "x$enable_xvmc" = xyes -o \
2237         "x$enable_vdpau" = xyes -o \
2238         "x$enable_omx_bellagio" = xyes -o \
2239         "x$enable_omx_tizonia" = xyes -o \
2240         "x$enable_va" = xyes; then
2241     need_gallium_vl=yes
2242 fi
2243 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2244
2245 if test "x$enable_xvmc" = xyes -o \
2246         "x$enable_vdpau" = xyes -o \
2247         "x$enable_omx_bellagio" = xyes -o \
2248         "x$enable_omx_tizonia" = xyes -o \
2249         "x$enable_va" = xyes; then
2250     if echo $platforms | grep -q "x11"; then
2251         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2252     fi
2253     need_gallium_vl_winsys=yes
2254 fi
2255 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2256
2257 if test "x$enable_xvmc" = xyes; then
2258     if test "x$have_xvmc_platform" != xyes; then
2259         AC_MSG_ERROR([XVMC requires the x11 platforms])
2260     fi
2261     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2262     gallium_st="$gallium_st xvmc"
2263 fi
2264 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2265
2266 if test "x$enable_vdpau" = xyes; then
2267     if test "x$have_vdpau_platform" != xyes; then
2268         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2269     fi
2270     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2271     gallium_st="$gallium_st vdpau"
2272     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2273 fi
2274 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2275
2276 if test "x$enable_omx_bellagio" = xyes; then
2277     if test "x$have_omx_platform" != xyes; then
2278         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2279     fi
2280     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2281     gallium_st="$gallium_st omx_bellagio"
2282     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2283 fi
2284 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2285
2286 if test "x$enable_omx_tizonia" = xyes; then
2287     if test "x$have_omx_platform" != xyes; then
2288         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2289     fi
2290     PKG_CHECK_MODULES([OMX_TIZONIA],
2291                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2292                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2293                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2294     gallium_st="$gallium_st omx_tizonia"
2295     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2296 fi
2297 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2298
2299 if test "x$enable_va" = xyes; then
2300     if test "x$have_va_platform" != xyes; then
2301         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2302     fi
2303     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2304     gallium_st="$gallium_st va"
2305 fi
2306 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2307
2308 dnl
2309 dnl Nine Direct3D9 configuration
2310 dnl
2311 if test "x$enable_nine" = xyes; then
2312     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2313         AC_MSG_ERROR([nine requires the gallium swrast driver])
2314     fi
2315     if test "x$with_gallium_drivers" = xswrast; then
2316         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2317     fi
2318     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2319         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2320     fi
2321
2322     if test "x$enable_dri3" = xno; then
2323         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2324     fi
2325
2326     gallium_st="$gallium_st nine"
2327 fi
2328 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2329
2330 dnl
2331 dnl OpenCL configuration
2332 dnl
2333
2334 AC_ARG_WITH([clang-libdir],
2335    [AS_HELP_STRING([--with-clang-libdir],
2336          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2337    [CLANG_LIBDIR="$withval"],
2338    [CLANG_LIBDIR=''])
2339
2340 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2341
2342 if test "x$enable_opencl" = xyes; then
2343     if test -z "$with_gallium_drivers"; then
2344         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2345     fi
2346
2347     if test "x$HAVE_CXX11" != "xyes"; then
2348        AC_MSG_ERROR([clover requires c++11 support])
2349     fi
2350
2351     if test "x$have_libclc" = xno; then
2352         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2353                     Make sure the directory containing libclc.pc is specified in your
2354                     PKG_CONFIG_PATH environment variable.
2355                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2356     else
2357         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2358         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2359         AC_SUBST([LIBCLC_INCLUDEDIR])
2360         AC_SUBST([LIBCLC_LIBEXECDIR])
2361     fi
2362
2363     gallium_st="$gallium_st clover"
2364
2365     if test "x$enable_opencl_icd" = xyes; then
2366         OPENCL_LIBNAME="MesaOpenCL"
2367     else
2368         OPENCL_LIBNAME="OpenCL"
2369     fi
2370
2371     if test "x$have_libelf" != xyes; then
2372        AC_MSG_ERROR([Clover requires libelf])
2373     fi
2374
2375     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2376         altivec_enabled=no
2377         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2378         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2379         #error "AltiVec not enabled"
2380         #endif
2381         ])], altivec_enabled=yes)
2382
2383         if test "$altivec_enabled" = yes; then
2384             CLOVER_STD_OVERRIDE="-std=gnu++11"
2385         fi
2386         AC_SUBST([CLOVER_STD_OVERRIDE])
2387     fi
2388
2389     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2390
2391     llvm_add_default_components "opencl"
2392     llvm_add_component "all-targets" "opencl"
2393     llvm_add_component "coverage" "opencl"
2394     llvm_add_component "linker" "opencl"
2395     llvm_add_component "instrumentation" "opencl"
2396     llvm_add_component "ipo" "opencl"
2397     llvm_add_component "irreader" "opencl"
2398     llvm_add_component "lto" "opencl"
2399     llvm_add_component "option" "opencl"
2400     llvm_add_component "objcarcopts" "opencl"
2401     llvm_add_component "profiledata" "opencl"
2402     llvm_add_optional_component "coroutines" "opencl"
2403
2404     dnl Check for Clang internal headers
2405     if test -z "$CLANG_LIBDIR"; then
2406         CLANG_LIBDIR=${LLVM_LIBDIR}
2407     fi
2408     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2409     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2410         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2411 fi
2412 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2413 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2414 AC_SUBST([OPENCL_LIBNAME])
2415 AC_SUBST([CLANG_RESOURCE_DIR])
2416
2417 dnl
2418 dnl Gallium configuration
2419 dnl
2420 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2421
2422 # libEGL wants to default to the first platform specified in
2423 # ./configure.  parse that here.
2424 if test "x$platforms" != "x"; then
2425     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2426     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2427 else
2428     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2429 fi
2430
2431 AC_SUBST([EGL_NATIVE_PLATFORM])
2432 AC_SUBST([EGL_CFLAGS])
2433
2434 # If we don't have the X11 platform, set this define so we don't try to include
2435 # the X11 headers.
2436 if ! echo "$platforms" | grep -q 'x11'; then
2437     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2438     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2439 fi
2440
2441 dnl Directory for XVMC libs
2442 AC_ARG_WITH([xvmc-libdir],
2443     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2444         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2445     [XVMC_LIB_INSTALL_DIR="$withval"],
2446     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2447 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2448
2449 dnl
2450 dnl Gallium Tests
2451 dnl
2452 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2453
2454 dnl Directory for VDPAU libs
2455 AC_ARG_WITH([vdpau-libdir],
2456     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2457         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2458     [VDPAU_LIB_INSTALL_DIR="$withval"],
2459     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2460 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2461
2462 dnl Directory for OMX_BELLAGIO libs
2463
2464 AC_ARG_WITH([omx-bellagio-libdir],
2465     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2466         [directory for the OMX_BELLAGIO libraries])],
2467     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2468     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2469                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2470 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2471
2472 dnl Directory for OMX_TIZONIA libs
2473
2474 AC_ARG_WITH([omx-tizonia-libdir],
2475     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2476         [directory for the OMX_TIZONIA libraries])],
2477     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2478     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2479 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2480
2481 dnl Directory for VA libs
2482
2483 AC_ARG_WITH([va-libdir],
2484     [AS_HELP_STRING([--with-va-libdir=DIR],
2485         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2486     [VA_LIB_INSTALL_DIR="$withval"],
2487     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2488 AC_SUBST([VA_LIB_INSTALL_DIR])
2489
2490 AC_ARG_WITH([d3d-libdir],
2491     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2492         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2493     [D3D_DRIVER_INSTALL_DIR="$withval"],
2494     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2495 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2496
2497 dnl Architectures to build SWR library for
2498
2499 AC_ARG_WITH([swr-archs],
2500     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2501         [comma delimited swr architectures list, e.g.
2502         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2503     [with_swr_archs="$withval"],
2504     [with_swr_archs="avx,avx2"])
2505
2506 dnl
2507 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2508 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2509 dnl architectures.
2510 dnl
2511 r300_require_llvm() {
2512     case "$host" in *gnux32) return;; esac
2513     case "$host_cpu" in
2514     i*86|x86_64|amd64) require_llvm $1
2515         ;;
2516     esac
2517 }
2518
2519 dnl
2520 dnl DRM is needed by X, Wayland, and offscreen rendering.
2521 dnl Surfaceless is an alternative for the last one.
2522 dnl
2523 require_basic_egl() {
2524     case "$with_platforms" in
2525         *drm*|*surfaceless*|*android*)
2526             ;;
2527         *)
2528             AC_MSG_ERROR([$1 requires one of these:
2529                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2530                   2) --with-platforms=surfaceless (offscreen only)
2531                   3) --with-platforms=android (Android only)
2532                   Recommended options: drm,x11])
2533             ;;
2534     esac
2535 }
2536
2537 swr_require_cxx_feature_flags() {
2538     feature_name="$1"
2539     preprocessor_test="$2"
2540     option_list="$3"
2541     output_var="$4"
2542
2543     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2544     AC_LANG_PUSH([C++])
2545     save_CXXFLAGS="$CXXFLAGS"
2546     save_IFS="$IFS"
2547     IFS=","
2548     found=0
2549     for opts in $option_list
2550     do
2551         unset IFS
2552         CXXFLAGS="$opts $save_CXXFLAGS"
2553         AC_COMPILE_IFELSE(
2554             [AC_LANG_PROGRAM(
2555                 [   #if !($preprocessor_test)
2556                     #error
2557                     #endif
2558                 ])],
2559             [found=1; break],
2560             [])
2561         IFS=","
2562     done
2563     IFS="$save_IFS"
2564     CXXFLAGS="$save_CXXFLAGS"
2565     AC_LANG_POP([C++])
2566     if test $found -eq 1; then
2567         AC_MSG_RESULT([$opts])
2568         eval "$output_var=\$opts"
2569         return 0
2570     fi
2571     AC_MSG_RESULT([no])
2572     AC_MSG_ERROR([swr requires $feature_name support])
2573     return 1
2574 }
2575
2576 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2577 if test -n "$with_gallium_drivers"; then
2578     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2579     for driver in $gallium_drivers; do
2580         case "x$driver" in
2581         xsvga)
2582             HAVE_GALLIUM_SVGA=yes
2583             require_libdrm "svga"
2584             ;;
2585         xi915)
2586             HAVE_GALLIUM_I915=yes
2587             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2588             require_libdrm "Gallium i915"
2589             ;;
2590         xr300)
2591             HAVE_GALLIUM_R300=yes
2592             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2593             require_libdrm "r300"
2594             r300_require_llvm "r300"
2595             ;;
2596         xr600)
2597             HAVE_GALLIUM_R600=yes
2598             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2599             require_libdrm "r600"
2600             if test "x$enable_llvm" = xyes; then
2601                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2602
2603                 llvm_add_component "asmparser" "r600"
2604                 llvm_add_component "bitreader" "r600"
2605             fi
2606             ;;
2607         xradeonsi)
2608             HAVE_GALLIUM_RADEONSI=yes
2609             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2610             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2611             require_libdrm "radeonsi"
2612             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2613             if test "x$enable_egl" = xyes; then
2614                 require_basic_egl "radeonsi"
2615             fi
2616             ;;
2617         xnouveau)
2618             HAVE_GALLIUM_NOUVEAU=yes
2619             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2620             require_libdrm "nouveau"
2621             ;;
2622         xfreedreno)
2623             HAVE_GALLIUM_FREEDRENO=yes
2624             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2625             require_libdrm "freedreno"
2626             ;;
2627         xetnaviv)
2628             HAVE_GALLIUM_ETNAVIV=yes
2629             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2630             require_libdrm "etnaviv"
2631             ;;
2632        ximx)
2633             HAVE_GALLIUM_IMX=yes
2634             ;;
2635         xtegra)
2636             HAVE_GALLIUM_TEGRA=yes
2637             require_libdrm "tegra"
2638             ;;
2639         xswrast)
2640             HAVE_GALLIUM_SOFTPIPE=yes
2641             if test "x$enable_llvm" = xyes; then
2642                 HAVE_GALLIUM_LLVMPIPE=yes
2643             fi
2644             ;;
2645         xswr)
2646             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2647
2648             if test "x$HAVE_CXX11" != "xyes"; then
2649                 AC_MSG_ERROR([swr requires c++11 support])
2650             fi
2651
2652             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2653                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2654                 SWR_AVX_CXXFLAGS
2655             AC_SUBST([SWR_AVX_CXXFLAGS])
2656
2657             swr_archs=`IFS=', '; echo $with_swr_archs`
2658             for arch in $swr_archs; do
2659                 case "x$arch" in
2660                 xavx)
2661                     HAVE_SWR_AVX=yes
2662                     ;;
2663                 xavx2)
2664                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2665                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2666                         SWR_AVX2_CXXFLAGS
2667                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2668                     HAVE_SWR_AVX2=yes
2669                     ;;
2670                 xknl)
2671                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2672                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2673                         SWR_KNL_CXXFLAGS
2674                     AC_SUBST([SWR_KNL_CXXFLAGS])
2675                     HAVE_SWR_KNL=yes
2676                     ;;
2677                 xskx)
2678                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2679                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2680                         SWR_SKX_CXXFLAGS
2681                     AC_SUBST([SWR_SKX_CXXFLAGS])
2682                     HAVE_SWR_SKX=yes
2683                     ;;
2684                 *)
2685                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2686                     ;;
2687                 esac
2688             done
2689
2690             if test "x$HAVE_SWR_AVX" != xyes -a \
2691                     "x$HAVE_SWR_AVX2" != xyes -a \
2692                     "x$HAVE_SWR_KNL" != xyes -a \
2693                     "x$HAVE_SWR_SKX" != xyes; then
2694                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2695             fi
2696
2697             # test if more than one swr arch configured
2698             if test `echo $swr_archs | wc -w` -eq 1; then
2699                 HAVE_SWR_BUILTIN=yes
2700             fi
2701
2702             HAVE_GALLIUM_SWR=yes
2703             ;;
2704         xvc4)
2705             HAVE_GALLIUM_VC4=yes
2706             require_libdrm "vc4"
2707
2708             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2709                               [USE_VC4_SIMULATOR=yes;
2710                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2711                               [USE_VC4_SIMULATOR=no])
2712             ;;
2713         xvc5)
2714             HAVE_GALLIUM_VC5=yes
2715
2716             PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2717                               [USE_VC5_SIMULATOR=yes;
2718                                DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2719                               [AC_MSG_ERROR([vc5 requires the simulator])])
2720             ;;
2721         xpl111)
2722             HAVE_GALLIUM_PL111=yes
2723             ;;
2724         xvirgl)
2725             HAVE_GALLIUM_VIRGL=yes
2726             require_libdrm "virgl"
2727             if test "x$enable_egl" = xyes; then
2728                 require_basic_egl "virgl"
2729             fi
2730             ;;
2731         *)
2732             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2733             ;;
2734         esac
2735     done
2736 fi
2737
2738 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2739 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x4.0.0 -a \
2740                                               "x$LLVM_VERSION" != x4.0.1)
2741
2742 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2743     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2744     llvm_add_default_components "gallium"
2745 fi
2746
2747 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2748 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2749 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2750 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2751 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2752
2753 dnl We need to validate some needed dependencies for renderonly drivers.
2754
2755 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2756     AC_MSG_ERROR([Building with imx requires etnaviv])
2757 fi
2758
2759 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2760     AC_MSG_ERROR([Building with pl111 requires vc4])
2761 fi
2762
2763 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2764     AC_MSG_ERROR([Building with tegra requires nouveau])
2765 fi
2766
2767 detect_old_buggy_llvm() {
2768     dnl llvm-config may not give the right answer when llvm is a built as a
2769     dnl single shared library, so we must work the library name out for
2770     dnl ourselves.
2771     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2772     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2773     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2774     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2775
2776     if test "x$llvm_have_one_so" = xyes; then
2777         dnl LLVM was built using auto*, so there is only one shared object.
2778         LLVM_LIBS="-l$LLVM_SO_NAME"
2779     else
2780         dnl If LLVM was built with CMake, there will be one shared object per
2781         dnl component.
2782         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2783                [AC_MSG_ERROR([Could not find llvm shared libraries:
2784                 Please make sure you have built llvm with the --enable-shared option
2785                 and that your llvm libraries are installed in $LLVM_LIBDIR
2786                 If you have installed your llvm libraries to a different directory you
2787                 can use the --with-llvm-prefix= configure flag to specify this directory.
2788                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2789                 If you do not want to build with llvm shared libraries and instead want to
2790                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2791                 invocation and rebuild.])])
2792
2793         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2794         dnl install uses a shared object for each component and we have
2795         dnl already added all of these objects to LLVM_LIBS.
2796     fi
2797 }
2798
2799 dnl
2800 dnl Set defines and buildtime variables only when using LLVM.
2801 dnl
2802 if test "x$enable_llvm" = xyes; then
2803     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2804
2805     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2806     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2807     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2808
2809     dnl Set LLVM_LIBS - This is done after the driver configuration so
2810     dnl that drivers can add additional components to LLVM_COMPONENTS.
2811     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2812     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2813     dnl this was causing the same libraries to be appear multiple times
2814     dnl in LLVM_LIBS.
2815
2816     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2817         if test "x$enable_llvm_shared_libs" = xyes; then
2818             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2819         else
2820             dnl Invoking llvm-config with both -libs and --system-libs produces the
2821             dnl two separate lines - each for the set of libraries.
2822                 dnl Call the program twice, effectively folding them into a single line.
2823             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2824             dnl We need to link to llvm system libs when using static libs
2825             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2826         fi
2827     else
2828         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2829         if test "x$enable_llvm_shared_libs" = xyes; then
2830             detect_old_buggy_llvm
2831         else
2832             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2833             dnl We need to link to llvm system libs when using static libs
2834             dnl However, only llvm 3.5+ provides --system-libs
2835             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2836                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2837             fi
2838         fi
2839     fi
2840
2841     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2842     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2843     dnl the LLVM library propagated in the Libs.private of the respective .pc
2844     dnl file which ensures complete dependency information when statically
2845     dnl linking.
2846     if test "x$enable_glx" == xgallium-xlib; then
2847         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2848     fi
2849     if test "x$enable_gallium_osmesa" = xyes; then
2850         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2851     fi
2852 fi
2853
2854 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2855 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2856 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2857 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2858 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2859 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2860 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2861 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2862 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2863 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2864 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2865 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2866 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2867 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2868 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2869 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2870                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2871                                          "x$HAVE_GALLIUM_SWR" = xyes)
2872 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2873 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2874 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2875
2876 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2877
2878 if test "x$enable_dri" = xyes; then
2879     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2880 fi
2881
2882 if test "x$have_drisw_kms" = xyes; then
2883     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2884 fi
2885 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2886
2887 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2888 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2889 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2890 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2891 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2892 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2893
2894 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2895 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2896
2897 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2898                                       "x$HAVE_RADEON_VULKAN" = xyes)
2899
2900 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2901                                       "x$HAVE_GALLIUM_VC5" = xyes)
2902
2903 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2904                                         "x$HAVE_I965_DRI" = xyes)
2905
2906 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2907                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2908                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2909 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2910 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2911 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2912 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2913 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2914
2915 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2916 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2917 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2918 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2919                                         "x$enable_gallium_osmesa" = xyes)
2920
2921 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2922 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2923 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2924 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2925 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2926 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2927
2928 AC_SUBST([NINE_MAJOR], 1)
2929 AC_SUBST([NINE_MINOR], 0)
2930 AC_SUBST([NINE_PATCH], 0)
2931 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
2932
2933 AC_SUBST([VDPAU_MAJOR], 1)
2934 AC_SUBST([VDPAU_MINOR], 0)
2935
2936 if test "x$enable_va" = xyes; then
2937     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2938     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2939 fi
2940 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2941 AC_SUBST([VA_MINOR], $VA_MINOR)
2942
2943 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2944
2945 AC_SUBST([XVMC_MAJOR], 1)
2946 AC_SUBST([XVMC_MINOR], 0)
2947
2948 AC_SUBST([XA_MAJOR], 2)
2949 AC_SUBST([XA_MINOR], 3)
2950 AC_SUBST([XA_PATCH], 0)
2951 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
2952
2953 AC_ARG_ENABLE(valgrind,
2954               [AS_HELP_STRING([--enable-valgrind],
2955                              [Build mesa with valgrind support (default: auto)])],
2956                              [VALGRIND=$enableval], [VALGRIND=auto])
2957 if test "x$VALGRIND" != xno; then
2958     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2959 fi
2960 AC_MSG_CHECKING([whether to enable Valgrind support])
2961 if test "x$VALGRIND" = xauto; then
2962     VALGRIND="$have_valgrind"
2963 fi
2964
2965 if test "x$VALGRIND" = "xyes"; then
2966     if ! test "x$have_valgrind" = xyes; then
2967         AC_MSG_ERROR([Valgrind support required but not present])
2968     fi
2969     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2970 fi
2971
2972 AC_MSG_RESULT([$VALGRIND])
2973
2974 dnl Restore LDFLAGS and CPPFLAGS
2975 LDFLAGS="$_SAVE_LDFLAGS"
2976 CPPFLAGS="$_SAVE_CPPFLAGS"
2977
2978 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2979 if test "x$acv_mesa_CLANG" = xyes; then
2980     CFLAGS="$CFLAGS -Qunused-arguments"
2981     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2982 fi
2983
2984 dnl Add user CFLAGS and CXXFLAGS
2985 CFLAGS="$CFLAGS $USER_CFLAGS"
2986 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2987
2988 dnl Substitute the config
2989 AC_CONFIG_FILES([Makefile
2990                  src/Makefile
2991                  src/amd/Makefile
2992                  src/amd/vulkan/Makefile
2993                  src/broadcom/Makefile
2994                  src/compiler/Makefile
2995                  src/egl/Makefile
2996                  src/egl/main/egl.pc
2997                  src/egl/wayland/wayland-drm/Makefile
2998                  src/egl/wayland/wayland-egl/Makefile
2999                  src/egl/wayland/wayland-egl/wayland-egl.pc
3000                  src/gallium/Makefile
3001                  src/gallium/auxiliary/Makefile
3002                  src/gallium/auxiliary/pipe-loader/Makefile
3003                  src/gallium/drivers/freedreno/Makefile
3004                  src/gallium/drivers/ddebug/Makefile
3005                  src/gallium/drivers/i915/Makefile
3006                  src/gallium/drivers/llvmpipe/Makefile
3007                  src/gallium/drivers/noop/Makefile
3008                  src/gallium/drivers/nouveau/Makefile
3009                  src/gallium/drivers/pl111/Makefile
3010                  src/gallium/drivers/r300/Makefile
3011                  src/gallium/drivers/r600/Makefile
3012                  src/gallium/drivers/radeon/Makefile
3013                  src/gallium/drivers/radeonsi/Makefile
3014                  src/gallium/drivers/rbug/Makefile
3015                  src/gallium/drivers/softpipe/Makefile
3016                  src/gallium/drivers/svga/Makefile
3017                  src/gallium/drivers/swr/Makefile
3018                  src/gallium/drivers/tegra/Makefile
3019                  src/gallium/drivers/trace/Makefile
3020                  src/gallium/drivers/etnaviv/Makefile
3021                  src/gallium/drivers/imx/Makefile
3022                  src/gallium/drivers/vc4/Makefile
3023                  src/gallium/drivers/vc5/Makefile
3024                  src/gallium/drivers/virgl/Makefile
3025                  src/gallium/state_trackers/clover/Makefile
3026                  src/gallium/state_trackers/dri/Makefile
3027                  src/gallium/state_trackers/glx/xlib/Makefile
3028                  src/gallium/state_trackers/nine/Makefile
3029                  src/gallium/state_trackers/omx/Makefile
3030                  src/gallium/state_trackers/omx/bellagio/Makefile
3031                  src/gallium/state_trackers/omx/tizonia/Makefile
3032                  src/gallium/state_trackers/osmesa/Makefile
3033                  src/gallium/state_trackers/va/Makefile
3034                  src/gallium/state_trackers/vdpau/Makefile
3035                  src/gallium/state_trackers/xa/Makefile
3036                  src/gallium/state_trackers/xa/xa_tracker.h
3037                  src/gallium/state_trackers/xvmc/Makefile
3038                  src/gallium/targets/d3dadapter9/Makefile
3039                  src/gallium/targets/d3dadapter9/d3d.pc
3040                  src/gallium/targets/dri/Makefile
3041                  src/gallium/targets/libgl-xlib/Makefile
3042                  src/gallium/targets/omx/Makefile
3043                  src/gallium/targets/opencl/Makefile
3044                  src/gallium/targets/opencl/mesa.icd
3045                  src/gallium/targets/osmesa/Makefile
3046                  src/gallium/targets/osmesa/osmesa.pc
3047                  src/gallium/targets/pipe-loader/Makefile
3048                  src/gallium/targets/va/Makefile
3049                  src/gallium/targets/vdpau/Makefile
3050                  src/gallium/targets/xa/Makefile
3051                  src/gallium/targets/xa/xatracker.pc
3052                  src/gallium/targets/xvmc/Makefile
3053                  src/gallium/tests/trivial/Makefile
3054                  src/gallium/tests/unit/Makefile
3055                  src/gallium/winsys/etnaviv/drm/Makefile
3056                  src/gallium/winsys/imx/drm/Makefile
3057                  src/gallium/winsys/freedreno/drm/Makefile
3058                  src/gallium/winsys/i915/drm/Makefile
3059                  src/gallium/winsys/nouveau/drm/Makefile
3060                  src/gallium/winsys/pl111/drm/Makefile
3061                  src/gallium/winsys/radeon/drm/Makefile
3062                  src/gallium/winsys/amdgpu/drm/Makefile
3063                  src/gallium/winsys/svga/drm/Makefile
3064                  src/gallium/winsys/sw/dri/Makefile
3065                  src/gallium/winsys/sw/kms-dri/Makefile
3066                  src/gallium/winsys/sw/null/Makefile
3067                  src/gallium/winsys/sw/wrapper/Makefile
3068                  src/gallium/winsys/sw/xlib/Makefile
3069                  src/gallium/winsys/tegra/drm/Makefile
3070                  src/gallium/winsys/vc4/drm/Makefile
3071                  src/gallium/winsys/vc5/drm/Makefile
3072                  src/gallium/winsys/virgl/drm/Makefile
3073                  src/gallium/winsys/virgl/vtest/Makefile
3074                  src/gbm/Makefile
3075                  src/gbm/main/gbm.pc
3076                  src/glx/Makefile
3077                  src/glx/apple/Makefile
3078                  src/glx/tests/Makefile
3079                  src/glx/windows/Makefile
3080                  src/glx/windows/windowsdriproto.pc
3081                  src/gtest/Makefile
3082                  src/intel/Makefile
3083                  src/loader/Makefile
3084                  src/mapi/Makefile
3085                  src/mapi/es1api/glesv1_cm.pc
3086                  src/mapi/es2api/glesv2.pc
3087                  src/mapi/glapi/gen/Makefile
3088                  src/mesa/Makefile
3089                  src/mesa/gl.pc
3090                  src/mesa/drivers/dri/dri.pc
3091                  src/mesa/drivers/dri/common/Makefile
3092                  src/mesa/drivers/dri/i915/Makefile
3093                  src/mesa/drivers/dri/i965/Makefile
3094                  src/mesa/drivers/dri/Makefile
3095                  src/mesa/drivers/dri/nouveau/Makefile
3096                  src/mesa/drivers/dri/r200/Makefile
3097                  src/mesa/drivers/dri/radeon/Makefile
3098                  src/mesa/drivers/dri/swrast/Makefile
3099                  src/mesa/drivers/osmesa/Makefile
3100                  src/mesa/drivers/osmesa/osmesa.pc
3101                  src/mesa/drivers/x11/Makefile
3102                  src/mesa/main/tests/Makefile
3103                  src/mesa/state_tracker/tests/Makefile
3104                  src/util/Makefile
3105                  src/util/tests/hash_table/Makefile
3106                  src/util/tests/string_buffer/Makefile
3107                  src/util/xmlpool/Makefile
3108                  src/vulkan/Makefile])
3109
3110 AC_OUTPUT
3111
3112 # Fix up dependencies in *.Plo files, where we changed the extension of a
3113 # source file
3114 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3115
3116 rm -f src/compiler/spirv/spirv_info.lo
3117 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3118
3119 dnl
3120 dnl Output some configuration info for the user
3121 dnl
3122 echo ""
3123 echo "        prefix:          $prefix"
3124 echo "        exec_prefix:     $exec_prefix"
3125 echo "        libdir:          $libdir"
3126 echo "        includedir:      $includedir"
3127
3128 dnl API info
3129 echo ""
3130 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3131
3132 dnl Driver info
3133 echo ""
3134 case "x$enable_osmesa$enable_gallium_osmesa" in
3135 xnoyes)
3136         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3137         ;;
3138 xyesno)
3139         echo "        OSMesa:          lib$OSMESA_LIB"
3140         ;;
3141 xnono)
3142         echo "        OSMesa:          no"
3143         ;;
3144 esac
3145
3146 echo ""
3147 if test "x$enable_dri" != xno; then
3148         echo "        DRI platform:    $dri_platform"
3149         if test -z "$DRI_DIRS"; then
3150             echo "        DRI drivers:     no"
3151         else
3152             echo "        DRI drivers:     $DRI_DIRS"
3153         fi
3154         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3155 fi
3156
3157 case "x$enable_glx" in
3158 xdri)
3159     echo "        GLX:             DRI-based"
3160     ;;
3161 xxlib)
3162     echo "        GLX:             Xlib-based"
3163     ;;
3164 xgallium-xlib)
3165     echo "        GLX:             Xlib-based (Gallium)"
3166     ;;
3167 *)
3168     echo "        GLX:             $enable_glx"
3169     ;;
3170 esac
3171
3172 dnl EGL
3173 echo ""
3174 echo "        EGL:             $enable_egl"
3175 if test "$enable_egl" = yes; then
3176
3177     egl_drivers=""
3178     if test "x$enable_dri" != "xno"; then
3179         egl_drivers="$egl_drivers builtin:egl_dri2"
3180     fi
3181     if test "x$enable_dri3" != "xno"; then
3182         egl_drivers="$egl_drivers builtin:egl_dri3"
3183     fi
3184
3185     echo "        EGL drivers:    $egl_drivers"
3186 fi
3187 if test "x$enable_gbm" = xyes; then
3188     echo "        GBM:             yes"
3189 else
3190     echo "        GBM:             no"
3191 fi
3192
3193     echo "        EGL/Vulkan/VL platforms:   $platforms"
3194
3195 # Vulkan
3196 echo ""
3197 if test "x$VULKAN_DRIVERS" != x; then
3198     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3199     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3200 else
3201     echo "        Vulkan drivers:  no"
3202 fi
3203
3204 echo ""
3205 if test "x$enable_llvm" = xyes; then
3206     echo "        llvm:            yes"
3207     echo "        llvm-config:     $LLVM_CONFIG"
3208     echo "        llvm-version:    $LLVM_VERSION"
3209 else
3210     echo "        llvm:            no"
3211 fi
3212
3213 echo ""
3214 if test -n "$with_gallium_drivers"; then
3215     echo "        Gallium drivers: $gallium_drivers"
3216     echo "        Gallium st:      $gallium_st"
3217 else
3218     echo "        Gallium:         no"
3219 fi
3220
3221 echo ""
3222 if test "x$enable_gallium_extra_hud" != xyes; then
3223     echo "        HUD extra stats: no"
3224 else
3225     echo "        HUD extra stats: yes"
3226 fi
3227
3228 if test "x$enable_lmsensors" != xyes; then
3229     echo "        HUD lmsensors:   no"
3230 else
3231     echo "        HUD lmsensors:   yes"
3232 fi
3233
3234 echo ""
3235 if test "x$HAVE_GALLIUM_SWR" != x; then
3236     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3237         echo "        SWR archs:       $swr_archs (builtin)"
3238     else
3239         echo "        SWR archs:       $swr_archs"
3240     fi
3241 fi
3242
3243 dnl Libraries
3244 echo ""
3245 echo "        Shared libs:     $enable_shared"
3246 echo "        Static libs:     $enable_static"
3247 echo "        Shared-glapi:    $enable_shared_glapi"
3248
3249 dnl Compiler options
3250 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3251 cflags=`echo $CFLAGS | \
3252     $SED 's/^ *//;s/  */ /;s/ *$//'`
3253 cxxflags=`echo $CXXFLAGS | \
3254     $SED 's/^ *//;s/  */ /;s/ *$//'`
3255 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3256 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3257 echo ""
3258 echo "        CFLAGS:          $cflags"
3259 echo "        CXXFLAGS:        $cxxflags"
3260 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3261 echo "        LDFLAGS:         $ldflags"
3262 echo "        Macros:          $defines"
3263 echo ""
3264 if test "x$enable_llvm" = xyes; then
3265     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3266     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3267     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3268     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3269     echo ""
3270 fi
3271 echo "        PYTHON2:         $PYTHON2"
3272
3273 echo ""
3274 echo "        Run '${MAKE-make}' to build Mesa"
3275 echo ""