configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.81
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     powerpc64le)
 770         case "$host_os" in
 771         linux*)
 772             asm_arch=ppc64le
 773             ;;
 774         esac
 775         ;;
 776     esac
 777
 778     case "$asm_arch" in
 779     x86)
 780         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 781         AC_MSG_RESULT([yes, x86])
 782         ;;
 783     x86_64|amd64)
 784         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 785         AC_MSG_RESULT([yes, x86_64])
 786         ;;
 787     sparc)
 788         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 789         AC_MSG_RESULT([yes, sparc])
 790         ;;
 791     ppc64le)
 792         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 793         AC_MSG_RESULT([yes, ppc64le])
 794         ;;
 795     *)
 796         AC_MSG_RESULT([no, platform not supported])
 797         ;;
 798     esac
 799 fi
 800
 801 AC_HEADER_MAJOR
 802 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 803 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 804 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 805 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 806
 807 dnl Check to see if dlopen is in default libraries (like Solaris, which
 808 dnl has it in libc), or if libdl is needed to get it.
 809 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 810     [AC_CHECK_LIB([dl], [dlopen],
 811        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 812 AC_SUBST([DLOPEN_LIBS])
 813
 814 dnl Check if that library also has dladdr
 815 save_LIBS="$LIBS"
 816 LIBS="$LIBS $DLOPEN_LIBS"
 817 AC_CHECK_FUNCS([dladdr])
 818 LIBS="$save_LIBS"
 819
 820 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 821
 822 case "$host_os" in
 823 darwin*)
 824     ;;
 825 *)
 826     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 827                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 828                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 829     AC_SUBST([CLOCK_LIB])
 830     ;;
 831 esac
 832
 833 dnl See if posix_memalign is available
 834 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 835
 836 dnl Check for zlib
 837 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 838
 839 dnl Check for pthreads
 840 AX_PTHREAD
 841 if test "x$ax_pthread_ok" = xno; then
 842     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 843 fi
 844 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 845 dnl to -pthread, which causes problems if we need -lpthread to appear in
 846 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 847 dnl is not valid for that platform.
 848 if test "x$android" = xno; then
 849     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 850 fi
 851 dnl According to the manual when using pthreads, one should add -pthread to
 852 dnl both compile and link-time arguments.
 853 dnl In practise that should be sufficient for all platforms, since any
 854 dnl platforms build with GCC and Clang support the flag.
 855 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 856
 857 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 858 dnl project. Even then there's a notable issue as described in the project README
 859 case "$host_os" in
 860 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 861     pthread_stubs_possible="no"
 862     ;;
 863 * )
 864     pthread_stubs_possible="yes"
 865     ;;
 866 esac
 867
 868 if test "x$pthread_stubs_possible" = xyes; then
 869     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 870 fi
 871
 872 dnl SELinux awareness.
 873 AC_ARG_ENABLE([selinux],
 874     [AS_HELP_STRING([--enable-selinux],
 875         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 876     [MESA_SELINUX="$enableval"],
 877     [MESA_SELINUX=no])
 878 if test "x$enable_selinux" = "xyes"; then
 879     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 880         [AC_CHECK_HEADER([selinux/selinux.h],[],
 881                          [AC_MSG_ERROR([SELinux headers not found])])
 882          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 883                       [AC_MSG_ERROR([SELinux library not found])])
 884          SELINUX_LIBS="-lselinux"])
 885     DEFINES="$DEFINES -DMESA_SELINUX"
 886 fi
 887 AC_SUBST([SELINUX_CFLAGS])
 888 AC_SUBST([SELINUX_LIBS])
 889
 890 dnl
 891 dnl LLVM
 892 dnl
 893 AC_ARG_ENABLE([llvm-shared-libs],
 894     [AS_HELP_STRING([--enable-llvm-shared-libs],
 895         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 896     [enable_llvm_shared_libs="$enableval"],
 897     [enable_llvm_shared_libs=yes])
 898
 899 AC_ARG_WITH([llvm-prefix],
 900     [AS_HELP_STRING([--with-llvm-prefix],
 901         [Prefix for LLVM installations in non-standard locations])],
 902     [llvm_prefix="$withval"],
 903     [llvm_prefix=''])
 904
 905 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 906 if test "x$have_libelf" = xno; then
 907    LIBELF_LIBS=''
 908    LIBELF_CFLAGS=''
 909    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 910    AC_SUBST([LIBELF_LIBS])
 911    AC_SUBST([LIBELF_CFLAGS])
 912 fi
 913
 914 if test -z "$LLVM_CONFIG"; then
 915     if test -n "$llvm_prefix"; then
 916         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 917     else
 918         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 919     fi
 920 fi
 921
 922 llvm_add_component() {
 923     new_llvm_component=$1
 924     driver_name=$2
 925
 926     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 927         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 928     else
 929         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 930     fi
 931 }
 932
 933 llvm_add_default_components() {
 934     driver_name=$1
 935
 936     # Required default components
 937     llvm_add_component "bitwriter" $driver_name
 938     llvm_add_component "engine" $driver_name
 939     llvm_add_component "mcdisassembler" $driver_name
 940     llvm_add_component "mcjit" $driver_name
 941
 942     # Optional default components
 943     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 944         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 945     fi
 946 }
 947
 948 llvm_add_target() {
 949     new_llvm_target=$1
 950     driver_name=$2
 951
 952     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 953         llvm_add_component $new_llvm_target $driver_name
 954     else
 955         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 956     fi
 957 }
 958
 959 # Call this inside ` ` to get the return value.
 960 # $1 is the llvm-config command with arguments.
 961 strip_unwanted_llvm_flags() {
 962     echo " `$1` " | sed -E \
 963         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 964         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 965         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 966         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 967         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 968         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 969         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 970         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 971         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 972         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 973         -e 's/^[[[:space:]]]//' \
 974         -e 's/[[[:space:]]]$//'
 975 }
 976
 977 llvm_set_environment_variables() {
 978     if test "x$LLVM_CONFIG" != xno; then
 979         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 980         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 981         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 982         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 983
 984         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 985         save_CFLAGS="$CFLAGS"
 986         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 987
 988         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 989             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 990         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 991             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 992         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 993             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 994
 995         CFLAGS="$save_CFLAGS"
 996
 997         # Only needed for LLVM < 3.6.0
 998         if test -z "$LLVM_VERSION_PATCH"; then
 999             LLVM_VERSION_PATCH=0
1000         fi
1001
1002         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1003
1004         FOUND_LLVM=yes
1005     else
1006         FOUND_LLVM=no
1007         LLVM_VERSION_INT=0
1008     fi
1009 }
1010
1011 require_llvm() {
1012     if test "x$enable_llvm" != "xyes"; then
1013         AC_MSG_ERROR([--enable-llvm is required when building $1])
1014     fi
1015 }
1016
1017 llvm_require_version() {
1018     require_llvm $2
1019
1020     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1021     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1022     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1023
1024     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1025         # major > required major
1026         #  --> OK
1027         return
1028     fi
1029
1030     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1031         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1032             # major = required major and
1033             # minor > required minor
1034             #  --> OK
1035             return
1036         else
1037             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1038                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1039                     # major = required major and
1040                     # minor = required minor and
1041                     # patch >= required patch
1042                     #  --> OK
1043                     return
1044                 fi
1045             fi
1046         fi
1047     fi
1048
1049     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1050 }
1051
1052 radeon_llvm_check() {
1053     if test ${LLVM_VERSION_INT} -lt 307; then
1054         amdgpu_llvm_target_name='r600'
1055     else
1056         amdgpu_llvm_target_name='amdgpu'
1057     fi
1058
1059     llvm_require_version $*
1060
1061     llvm_add_target $amdgpu_llvm_target_name $2
1062
1063     llvm_add_default_components $2
1064     llvm_add_component "bitreader" $2
1065     llvm_add_component "ipo" $2
1066
1067     if test "x$have_libelf" != xyes; then
1068        AC_MSG_ERROR([$2 requires libelf when using llvm])
1069     fi
1070 }
1071
1072 llvm_set_environment_variables
1073
1074 AC_SUBST([LLVM_CFLAGS])
1075 AC_SUBST([LLVM_CXXFLAGS])
1076 AC_SUBST([LLVM_LIBS])
1077 AC_SUBST([LLVM_LDFLAGS])
1078 AC_SUBST([LLVM_INCLUDEDIR])
1079
1080 dnl
1081 dnl libunwind
1082 dnl
1083 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1084 AC_ARG_ENABLE([libunwind],
1085     [AS_HELP_STRING([--enable-libunwind],
1086             [Use libunwind for backtracing (default: auto)])],
1087         [LIBUNWIND="$enableval"],
1088         [LIBUNWIND="$HAVE_LIBUNWIND"])
1089
1090 if test "x$LIBUNWIND" = "xyes"; then
1091     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1092     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1093 fi
1094
1095
1096 dnl Options for APIs
1097 AC_ARG_ENABLE([opengl],
1098     [AS_HELP_STRING([--disable-opengl],
1099         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1100     [enable_opengl="$enableval"],
1101     [enable_opengl=yes])
1102 AC_ARG_ENABLE([gles1],
1103     [AS_HELP_STRING([--disable-gles1],
1104         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1105     [enable_gles1="$enableval"],
1106     [enable_gles1=yes])
1107 AC_ARG_ENABLE([gles2],
1108     [AS_HELP_STRING([--disable-gles2],
1109         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1110     [enable_gles2="$enableval"],
1111     [enable_gles2=yes])
1112
1113 AC_ARG_ENABLE([dri],
1114     [AS_HELP_STRING([--enable-dri],
1115         [enable DRI modules @<:@default=enabled@:>@])],
1116     [enable_dri="$enableval"],
1117     [enable_dri=yes])
1118
1119 AC_ARG_ENABLE([gallium-extra-hud],
1120     [AS_HELP_STRING([--enable-gallium-extra-hud],
1121         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1122     [enable_gallium_extra_hud="$enableval"],
1123     [enable_gallium_extra_hud=no])
1124 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1125 if test "x$enable_gallium_extra_hud" = xyes ; then
1126     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1127 fi
1128
1129 #TODO: no pkgconfig .pc available for libsensors.
1130 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1131 AC_ARG_ENABLE([lmsensors],
1132     [AS_HELP_STRING([--enable-lmsensors],
1133         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1134     [enable_lmsensors="$enableval"],
1135     [enable_lmsensors=no])
1136 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1137 if test "x$enable_lmsensors" = xyes ; then
1138     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1139     LIBSENSORS_LIBS="-lsensors"
1140 else
1141     LIBSENSORS_LIBS=""
1142 fi
1143 AC_SUBST(LIBSENSORS_LIBS)
1144
1145 case "$host_os" in
1146 linux*)
1147     dri3_default=yes
1148     ;;
1149 *)
1150     dri3_default=no
1151     ;;
1152 esac
1153
1154 if test "x$enable_dri" = xno; then
1155     dri3_default=no
1156 fi
1157
1158 AC_ARG_ENABLE([dri3],
1159     [AS_HELP_STRING([--enable-dri3],
1160         [enable DRI3 @<:@default=auto@:>@])],
1161     [enable_dri3="$enableval"],
1162     [enable_dri3="$dri3_default"])
1163 AC_ARG_ENABLE([glx],
1164     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1165         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1166     [enable_glx="$enableval"],
1167     [enable_glx=yes])
1168 AC_ARG_ENABLE([osmesa],
1169     [AS_HELP_STRING([--enable-osmesa],
1170         [enable OSMesa library @<:@default=disabled@:>@])],
1171     [enable_osmesa="$enableval"],
1172     [enable_osmesa=no])
1173 AC_ARG_ENABLE([gallium-osmesa],
1174     [AS_HELP_STRING([--enable-gallium-osmesa],
1175         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1176     [enable_gallium_osmesa="$enableval"],
1177     [enable_gallium_osmesa=no])
1178 AC_ARG_ENABLE([egl],
1179     [AS_HELP_STRING([--disable-egl],
1180         [disable EGL library @<:@default=enabled@:>@])],
1181     [enable_egl="$enableval"],
1182     [enable_egl=yes])
1183
1184 AC_ARG_ENABLE([xa],
1185     [AS_HELP_STRING([--enable-xa],
1186         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1187     [enable_xa="$enableval"],
1188     [enable_xa=no])
1189 AC_ARG_ENABLE([gbm],
1190    [AS_HELP_STRING([--enable-gbm],
1191          [enable gbm library @<:@default=yes except cygwin@:>@])],
1192    [enable_gbm="$enableval"],
1193    [case "$host_os" in
1194        cygwin*)
1195           enable_gbm=no
1196           ;;
1197        *)
1198           enable_gbm=yes
1199           ;;
1200     esac])
1201 AC_ARG_ENABLE([nine],
1202     [AS_HELP_STRING([--enable-nine],
1203         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1204     [enable_nine="$enableval"],
1205     [enable_nine=no])
1206
1207 AC_ARG_ENABLE([xvmc],
1208    [AS_HELP_STRING([--enable-xvmc],
1209          [enable xvmc library @<:@default=auto@:>@])],
1210    [enable_xvmc="$enableval"],
1211    [enable_xvmc=auto])
1212 AC_ARG_ENABLE([vdpau],
1213    [AS_HELP_STRING([--enable-vdpau],
1214          [enable vdpau library @<:@default=auto@:>@])],
1215    [enable_vdpau="$enableval"],
1216    [enable_vdpau=auto])
1217 AC_ARG_ENABLE([omx],
1218    [AS_HELP_STRING([--enable-omx],
1219          [enable OpenMAX library @<:@default=disabled@:>@])],
1220    [enable_omx="$enableval"],
1221    [enable_omx=no])
1222 AC_ARG_ENABLE([va],
1223    [AS_HELP_STRING([--enable-va],
1224          [enable va library @<:@default=auto@:>@])],
1225    [enable_va="$enableval"],
1226    [enable_va=auto])
1227 AC_ARG_ENABLE([opencl],
1228    [AS_HELP_STRING([--enable-opencl],
1229          [enable OpenCL library @<:@default=disabled@:>@])],
1230    [enable_opencl="$enableval"],
1231    [enable_opencl=no])
1232 AC_ARG_ENABLE([opencl_icd],
1233    [AS_HELP_STRING([--enable-opencl-icd],
1234           [Build an OpenCL ICD library to be loaded by an ICD implementation
1235            @<:@default=disabled@:>@])],
1236     [enable_opencl_icd="$enableval"],
1237     [enable_opencl_icd=no])
1238
1239 AC_ARG_ENABLE([gallium-tests],
1240     [AS_HELP_STRING([--enable-gallium-tests],
1241         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1242     [enable_gallium_tests="$enableval"],
1243     [enable_gallium_tests=no])
1244
1245 # Option for Gallium drivers
1246
1247 # Keep this in sync with the --with-gallium-drivers help string default value
1248 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1249
1250 AC_ARG_WITH([gallium-drivers],
1251     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1252         [comma delimited Gallium drivers list, e.g.
1253         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1254         @<:@default=r300,r600,svga,swrast@:>@])],
1255     [with_gallium_drivers="$withval"],
1256     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1257
1258 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1259 # here so that the script doesn't choke on an unknown driver name later.
1260 case "$with_gallium_drivers" in
1261     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1262     no) with_gallium_drivers='' ;;
1263 esac
1264
1265 if test "x$enable_opengl" = xno -a \
1266         "x$enable_gles1" = xno -a \
1267         "x$enable_gles2" = xno -a \
1268         "x$enable_nine" = xno -a \
1269         "x$enable_xa" = xno -a \
1270         "x$enable_xvmc" = xno -a \
1271         "x$enable_vdpau" = xno -a \
1272         "x$enable_omx" = xno -a \
1273         "x$enable_va" = xno -a \
1274         "x$enable_opencl" = xno; then
1275     AC_MSG_ERROR([at least one API should be enabled])
1276 fi
1277
1278 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1279 if test "x$enable_opengl" = xno -a \
1280         "x$enable_gles1" = xyes; then
1281     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1282 fi
1283
1284 if test "x$enable_opengl" = xno -a \
1285         "x$enable_gles2" = xyes; then
1286     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1287 fi
1288
1289 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1290 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1291 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1292 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1293                                         "x$enable_gles1" = xyes -o \
1294                                         "x$enable_gles2" = xyes)
1295
1296 # Validate GLX options
1297 if test "x$enable_glx" = xyes; then
1298     if test "x$enable_dri" = xyes; then
1299         enable_glx=dri
1300     elif test -n "$with_gallium_drivers"; then
1301         enable_glx=gallium-xlib
1302     else
1303         enable_glx=xlib
1304     fi
1305 fi
1306 case "x$enable_glx" in
1307 xdri | xxlib | xgallium-xlib)
1308     # GLX requires OpenGL
1309     if test "x$enable_opengl" = xno; then
1310         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1311     fi
1312
1313     # Check individual dependencies
1314     case "x$enable_glx" in
1315     xdri)
1316         if test "x$enable_dri" = xno; then
1317             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1318         fi
1319         ;;
1320     xxlib)
1321         if test "x$enable_dri" = xyes; then
1322             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1323         fi
1324         ;;
1325     xgallium-xlib )
1326         if test "x$enable_dri" = xyes; then
1327             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1328         fi
1329         if test -z "$with_gallium_drivers"; then
1330             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1331         fi
1332         ;;
1333     esac
1334     ;;
1335 xno)
1336     ;;
1337 *)
1338     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1339     ;;
1340 esac
1341
1342 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1343 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1344 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1345 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1346
1347 DEFAULT_GL_LIB_NAME=GL
1348
1349 dnl
1350 dnl Libglvnd configuration
1351 dnl
1352 AC_ARG_ENABLE([libglvnd],
1353     [AS_HELP_STRING([--enable-libglvnd],
1354         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1355     [enable_libglvnd="$enableval"],
1356     [enable_libglvnd=no])
1357 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1358
1359 if test "x$enable_libglvnd" = xyes ; then
1360     dnl XXX: update once we can handle more than libGL/glx.
1361     dnl Namely: we should error out if neither of the glvnd enabled libraries
1362     dnl are built
1363     case "x$enable_glx" in
1364     xno)
1365         AC_MSG_ERROR([cannot build libglvnd without GLX])
1366         ;;
1367     xxlib | xgallium-xlib )
1368         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1369         ;;
1370     xdri)
1371         ;;
1372     esac
1373
1374     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1375     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1376     AC_SUBST([LIBGLVND_DATADIR])
1377
1378     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1379     DEFAULT_GL_LIB_NAME=GLX_mesa
1380 fi
1381
1382 AC_ARG_WITH([gl-lib-name],
1383   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1384     [specify GL library name @<:@default=GL@:>@])],
1385   [GL_LIB=$withval],
1386   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1387 AC_ARG_WITH([osmesa-lib-name],
1388   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1389     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1390   [OSMESA_LIB=$withval],
1391   [OSMESA_LIB=OSMesa])
1392 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1393 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1394
1395 dnl
1396 dnl Mangled Mesa support
1397 dnl
1398 AC_ARG_ENABLE([mangling],
1399   [AS_HELP_STRING([--enable-mangling],
1400     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1401   [enable_mangling="${enableval}"],
1402   [enable_mangling=no]
1403 )
1404 if test "x${enable_mangling}" = "xyes" ; then
1405   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1406   GL_LIB="Mangled${GL_LIB}"
1407   OSMESA_LIB="Mangled${OSMESA_LIB}"
1408 fi
1409 AC_SUBST([GL_LIB])
1410 AC_SUBST([OSMESA_LIB])
1411
1412 # Check for libdrm
1413 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1414                   [have_libdrm=yes], [have_libdrm=no])
1415 if test "x$have_libdrm" = xyes; then
1416         DEFINES="$DEFINES -DHAVE_LIBDRM"
1417 fi
1418
1419 require_libdrm() {
1420     if test "x$have_libdrm" != xyes; then
1421        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1422     fi
1423 }
1424
1425
1426 # Select which platform-dependent DRI code gets built
1427 case "$host_os" in
1428 darwin*)
1429     dri_platform='apple' ;;
1430 cygwin*)
1431     dri_platform='windows' ;;
1432 gnu*)
1433     dri_platform='none' ;;
1434 *)
1435     dri_platform='drm' ;;
1436 esac
1437
1438 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1439     have_drisw_kms='yes'
1440 fi
1441
1442 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1443 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1444 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1445 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1446 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1447 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1448 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1449 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1450 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1451
1452 AC_ARG_ENABLE([shared-glapi],
1453     [AS_HELP_STRING([--enable-shared-glapi],
1454         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1455     [enable_shared_glapi="$enableval"],
1456     [enable_shared_glapi=yes])
1457
1458 case "x$enable_opengl$enable_gles1$enable_gles2" in
1459 x*yes*yes*)
1460     if test "x$enable_shared_glapi" = xno; then
1461         AC_MSG_ERROR([shared GLAPI required when building two or more of
1462                       the following APIs - opengl, gles1 gles2])
1463     fi
1464     ;;
1465 esac
1466
1467 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1468
1469 # Build the pipe-drivers as separate libraries/modules.
1470 # Do not touch this unless you know what you are doing.
1471 # XXX: Expose via configure option ?
1472 enable_shared_pipe_drivers=no
1473
1474 dnl
1475 dnl Driver specific build directories
1476 dnl
1477
1478 if test "x$enable_gallium_osmesa" = xyes; then
1479     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1480         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1481     fi
1482     if test "x$enable_osmesa" = xyes; then
1483         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1484     fi
1485 fi
1486
1487 require_dri_shared_libs_and_glapi() {
1488     if test "x$enable_static" = xyes; then
1489         AC_MSG_ERROR([$1 cannot be build as static library])
1490     fi
1491
1492     if test "x$enable_dri" != xyes; then
1493         # There is only a single backend which won't be build/used otherwise.
1494         # XXX: Revisit this as the egl/haiku is a thing.
1495         AC_MSG_ERROR([$1 requires --enable-dri])
1496     fi
1497
1498     if test "x$enable_shared_glapi" != xyes; then
1499         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1500     fi
1501 }
1502
1503 if test "x$enable_dri" = xyes; then
1504     require_dri_shared_libs_and_glapi "DRI"
1505
1506     # not a hard requirement as swrast does not depend on it
1507     if test "x$have_libdrm" = xyes; then
1508         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1509     fi
1510 fi
1511
1512 AC_ARG_ENABLE([driglx-direct],
1513     [AS_HELP_STRING([--disable-driglx-direct],
1514         [disable direct rendering in GLX and EGL for DRI \
1515             @<:@default=auto@:>@])],
1516     [driglx_direct="$enableval"],
1517     [driglx_direct="yes"])
1518
1519 dnl
1520 dnl libGL configuration per driver
1521 dnl
1522 if test "x$enable_glx" != xno; then
1523     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1524 fi
1525 case "x$enable_glx" in
1526 xxlib | xgallium-xlib)
1527     # Xlib-based GLX
1528     dri_modules="x11 xext xcb"
1529     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1530     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1531     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1532     GL_LIB_DEPS="$XLIBGL_LIBS"
1533     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1534     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1535     ;;
1536 xdri)
1537     # DRI-based GLX
1538
1539     # find the DRI deps for libGL
1540     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1541
1542     if test x"$driglx_direct" = xyes; then
1543         if test x"$dri_platform" = xdrm ; then
1544             DEFINES="$DEFINES -DGLX_USE_DRM"
1545             require_libdrm "Direct rendering"
1546
1547             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1548             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1549
1550             if test x"$enable_dri" = xyes; then
1551                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1552             fi
1553         fi
1554         if test x"$dri_platform" = xapple ; then
1555             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1556         fi
1557         if test x"$dri_platform" = xwindows ; then
1558             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1559         fi
1560     fi
1561
1562     # add xf86vidmode if available
1563     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1564     if test "$HAVE_XF86VIDMODE" = yes ; then
1565         dri_modules="$dri_modules xxf86vm"
1566     fi
1567
1568     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1569     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1570     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1571     GL_LIB_DEPS="$DRIGL_LIBS"
1572
1573     # need DRM libs, $PTHREAD_LIBS, etc.
1574     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1576     ;;
1577 esac
1578
1579 # This is outside the case (above) so that it is invoked even for non-GLX
1580 # builds.
1581 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1582
1583 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1584 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1585 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1586 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1587
1588 AC_SUBST([X11_INCLUDES])
1589 AC_SUBST([GL_LIB_DEPS])
1590 AC_SUBST([GL_PC_REQ_PRIV])
1591 AC_SUBST([GL_PC_LIB_PRIV])
1592 AC_SUBST([GL_PC_CFLAGS])
1593 AC_SUBST([DRI_PC_REQ_PRIV])
1594 AC_SUBST([GLESv1_CM_LIB_DEPS])
1595 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1596 AC_SUBST([GLESv2_LIB_DEPS])
1597 AC_SUBST([GLESv2_PC_LIB_PRIV])
1598
1599 AC_SUBST([HAVE_XF86VIDMODE])
1600
1601 dnl
1602 dnl More GLX setup
1603 dnl
1604 case "x$enable_glx" in
1605 xxlib | xgallium-xlib)
1606     DEFINES="$DEFINES -DUSE_XSHM"
1607     ;;
1608 xdri)
1609     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1610     if test "x$driglx_direct" = xyes; then
1611         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1612     fi
1613     ;;
1614 esac
1615
1616 dnl
1617 dnl TLS detection
1618 dnl
1619
1620 AC_ARG_ENABLE([glx-tls],
1621     [AS_HELP_STRING([--enable-glx-tls],
1622         [enable TLS support in GLX @<:@default=enabled@:>@])],
1623     [GLX_USE_TLS="$enableval"],
1624     [GLX_USE_TLS=yes])
1625 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1626
1627 if test "x$GLX_USE_TLS" = xyes; then
1628     DEFINES="$DEFINES -DGLX_USE_TLS"
1629 fi
1630
1631 dnl Read-only text section on x86 hardened platforms
1632 AC_ARG_ENABLE([glx-read-only-text],
1633     [AS_HELP_STRING([--enable-glx-read-only-text],
1634         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1635     [enable_glx_read_only_text="$enableval"],
1636     [enable_glx_read_only_text=no])
1637 if test "x$enable_glx_read_only_text" = xyes; then
1638     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1639 fi
1640
1641 dnl
1642 dnl DEPRECATED: EGL Platforms configuration
1643 dnl
1644 AC_ARG_WITH([egl-platforms],
1645     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1646         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1647     [with_egl_platforms="$withval"],
1648     [with_egl_platforms=auto])
1649
1650 if test "x$with_egl_platforms" = xauto; then
1651     with_egl_platforms="x11,surfaceless"
1652     if test "x$enable_gbm" = xyes; then
1653         with_egl_platforms="$with_egl_platforms,drm"
1654     fi
1655 else
1656     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1657 fi
1658
1659 dnl
1660 dnl Platforms configuration
1661 dnl
1662 AC_ARG_WITH([platforms],
1663     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1664         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1665         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1666     [with_platforms="$withval"],
1667     [with_platforms=auto])
1668
1669 # Reuse the autodetection rather than duplicating it.
1670 if test "x$with_platforms" = xauto; then
1671     with_platforms=$with_egl_platforms
1672 fi
1673
1674 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1675         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1676         WAYLAND_SCANNER='')
1677 if test "x$WAYLAND_SCANNER" = x; then
1678     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1679 fi
1680
1681 # Do per platform setups and checks
1682 platforms=`IFS=', '; echo $with_platforms`
1683 for plat in $platforms; do
1684         case "$plat" in
1685         wayland)
1686
1687                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1688
1689                 if test "x$WAYLAND_SCANNER" = "x:"; then
1690                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1691                 fi
1692                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1693                 ;;
1694
1695         x11)
1696                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1697                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1698                 ;;
1699
1700         drm)
1701                 test "x$enable_gbm" = "xno" &&
1702                         AC_MSG_ERROR([EGL platform drm needs gbm])
1703                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1704                 ;;
1705
1706         surfaceless)
1707                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1708                 ;;
1709
1710         android)
1711                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1712                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1713                 ;;
1714
1715         *)
1716                 AC_MSG_ERROR([platform '$plat' does not exist])
1717                 ;;
1718         esac
1719
1720         case "$plat" in
1721         wayland|drm|surfaceless)
1722                 require_libdrm "Platform $plat"
1723                 ;;
1724         esac
1725 done
1726
1727 if test "x$enable_glx" != xno; then
1728     if ! echo "$platforms" | grep -q 'x11'; then
1729         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1730     fi
1731 fi
1732
1733 if test x"$enable_dri3" = xyes; then
1734     DEFINES="$DEFINES -DHAVE_DRI3"
1735
1736     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1737     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1738 fi
1739
1740 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1741 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1742 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1743 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1744 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1745
1746 dnl
1747 dnl More DRI setup
1748 dnl
1749 dnl Directory for DRI drivers
1750 AC_ARG_WITH([dri-driverdir],
1751     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1752         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1753     [DRI_DRIVER_INSTALL_DIR="$withval"],
1754     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1755 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1756 dnl Extra search path for DRI drivers
1757 AC_ARG_WITH([dri-searchpath],
1758     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1759         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1760     [DRI_DRIVER_SEARCH_DIR="$withval"],
1761     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1762 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1763 dnl Which drivers to build - default is chosen by platform
1764 AC_ARG_WITH([dri-drivers],
1765     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1766         [comma delimited classic DRI drivers list, e.g.
1767         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1768     [with_dri_drivers="$withval"],
1769     [with_dri_drivers=auto])
1770
1771 if test "x$with_dri_drivers" = xauto; then
1772     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1773         with_dri_drivers="yes"
1774     else
1775         with_dri_drivers="no"
1776     fi
1777 fi
1778 if test "x$with_dri_drivers" = xno; then
1779     with_dri_drivers=''
1780 fi
1781
1782 dnl If $with_dri_drivers is yes, drivers will be added through
1783 dnl platform checks. Set DEFINES and LIB_DEPS
1784 if test "x$enable_dri" = xyes; then
1785     # Platform specific settings and drivers to build
1786     case "$host_os" in
1787     linux*)
1788         case "$host_cpu" in
1789         powerpc* | sparc*)
1790             # Build only the drivers for cards that exist on PowerPC/sparc
1791             if test "x$with_dri_drivers" = "xyes"; then
1792                 with_dri_drivers="r200 radeon swrast"
1793             fi
1794             ;;
1795         esac
1796         ;;
1797     cygwin*)
1798         if test "x$with_dri_drivers" = "xyes"; then
1799             with_dri_drivers="swrast"
1800         fi
1801         ;;
1802     darwin*)
1803         DEFINES="$DEFINES -DBUILDING_MESA"
1804         if test "x$with_dri_drivers" = "xyes"; then
1805             with_dri_drivers="swrast"
1806         fi
1807         ;;
1808     esac
1809
1810     # default drivers
1811     if test "x$with_dri_drivers" = "xyes"; then
1812         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1813     fi
1814
1815     # Check for expat
1816     PKG_CHECK_MODULES([EXPAT], [expat], [],
1817         # expat version 2.0 and earlier do not provide expat.pc
1818         [AC_CHECK_HEADER([expat.h],[],
1819                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1820          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1821                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1822          EXPAT_LIBS="-lexpat"])
1823
1824     # put all the necessary libs together
1825     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1826 fi
1827
1828 AC_SUBST([DRI_LIB_DEPS])
1829
1830 DRI_DIRS=''
1831 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1832 if test -n "$with_dri_drivers"; then
1833     if test "x$enable_opengl" != xyes; then
1834         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1835     fi
1836
1837     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1838     for driver in $dri_drivers; do
1839         DRI_DIRS="$DRI_DIRS $driver"
1840         case "x$driver" in
1841         xi915)
1842             require_libdrm "i915"
1843             HAVE_I915_DRI=yes
1844             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1845             ;;
1846         xi965)
1847             require_libdrm "i965"
1848             HAVE_I965_DRI=yes
1849             ;;
1850         xnouveau)
1851             require_libdrm "nouveau"
1852             HAVE_NOUVEAU_DRI=yes
1853             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1854             ;;
1855         xradeon)
1856             require_libdrm "radeon"
1857             HAVE_RADEON_DRI=yes;
1858             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1859             ;;
1860         xr200)
1861             require_libdrm "r200"
1862             HAVE_R200_DRI=yes
1863             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1864             ;;
1865         xswrast)
1866             HAVE_SWRAST_DRI=yes
1867             ;;
1868         *)
1869             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1870             ;;
1871         esac
1872     done
1873     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1874 fi
1875
1876
1877 dnl
1878 dnl Gallium LLVM
1879 dnl Deprecated: kept for backwards compatibility
1880 dnl
1881 AC_ARG_ENABLE([gallium-llvm],
1882     [AS_HELP_STRING([--enable-gallium-llvm],
1883         [DEPRECATED: use --enable-llvm instead])],
1884     [enable_gallium_llvm="$enableval"],
1885     [enable_gallium_llvm=auto])
1886
1887 if test "x$enable_gallium_llvm" != xauto; then
1888    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1889    enable_llvm=$enable_gallium_llvm
1890 fi
1891
1892 dnl
1893 dnl LLVM
1894 dnl
1895 AC_ARG_ENABLE([llvm],
1896     [AS_HELP_STRING([--enable-llvm],
1897         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1898     [enable_llvm="$enableval"],
1899     [enable_llvm=auto])
1900
1901 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1902     if test "x$FOUND_LLVM" = xyes; then
1903         case "$host_cpu" in
1904         i*86|x86_64|amd64) enable_llvm=yes;;
1905         *) enable_llvm=no;;
1906         esac
1907     else
1908         enable_llvm=no
1909     fi
1910 fi
1911
1912 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1913     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1914 fi
1915
1916 #
1917 # Vulkan driver configuration
1918 #
1919
1920 AC_ARG_WITH([vulkan-drivers],
1921     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1922         [comma delimited Vulkan drivers list, e.g.
1923         "intel,radeon"
1924         @<:@default=no@:>@])],
1925     [with_vulkan_drivers="$withval"],
1926     [with_vulkan_drivers="no"])
1927
1928 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1929 # here so that the script doesn't choke on an unknown driver name later.
1930 case "x$with_vulkan_drivers" in
1931     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1932     xno) with_vulkan_drivers='' ;;
1933 esac
1934
1935 AC_ARG_WITH([vulkan-icddir],
1936     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1937         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1938     [VULKAN_ICD_INSTALL_DIR="$withval"],
1939     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1940 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1941
1942 require_x11_dri3() {
1943     if echo "$platforms" | grep -q 'x11'; then
1944         if test "x$enable_dri3" != xyes; then
1945             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1946         fi
1947     fi
1948 }
1949
1950 if test -n "$with_vulkan_drivers"; then
1951     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1952         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1953     fi
1954
1955     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1956     for driver in $VULKAN_DRIVERS; do
1957         case "x$driver" in
1958         xintel)
1959             require_libdrm "ANV"
1960             require_x11_dri3 "ANV"
1961             HAVE_INTEL_VULKAN=yes
1962             ;;
1963         xradeon)
1964             require_libdrm "radv"
1965             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1966             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1967             require_x11_dri3 "radv"
1968             HAVE_RADEON_VULKAN=yes
1969             ;;
1970         *)
1971             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1972             ;;
1973         esac
1974     done
1975     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1976 fi
1977
1978
1979 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1980 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1981 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1982                                   "x$enable_osmesa" = xyes -o \
1983                                   -n "$DRI_DIRS")
1984
1985 dnl
1986 dnl OSMesa configuration
1987 dnl
1988
1989 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1990 AC_ARG_WITH([osmesa-bits],
1991     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1992         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1993     [osmesa_bits="$withval"],
1994     [osmesa_bits=8])
1995 if test "x$osmesa_bits" != x8; then
1996     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1997         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1998         osmesa_bits=8
1999     fi
2000 fi
2001 case "x$osmesa_bits" in
2002 x8)
2003     OSMESA_LIB="${OSMESA_LIB}"
2004     ;;
2005 x16|x32)
2006     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2007     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2008     ;;
2009 *)
2010     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2011     ;;
2012 esac
2013
2014 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2015     # only link libraries with osmesa if shared
2016     if test "$enable_static" = no; then
2017         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2018     else
2019         OSMESA_LIB_DEPS=""
2020     fi
2021     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2022 fi
2023
2024 AC_SUBST([OSMESA_LIB_DEPS])
2025 AC_SUBST([OSMESA_PC_REQ])
2026 AC_SUBST([OSMESA_PC_LIB_PRIV])
2027
2028 dnl
2029 dnl gbm configuration
2030 dnl
2031 if test "x$enable_gbm" = xyes; then
2032     require_dri_shared_libs_and_glapi "gbm"
2033 fi
2034 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2035 # FINISHME: GBM has a number of dependencies which we should add below
2036 GBM_PC_REQ_PRIV=""
2037 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2038 AC_SUBST([GBM_PC_REQ_PRIV])
2039 AC_SUBST([GBM_PC_LIB_PRIV])
2040
2041 dnl
2042 dnl EGL configuration
2043 dnl
2044
2045 if test "x$enable_egl" = xyes; then
2046     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2047
2048     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2049
2050     require_dri_shared_libs_and_glapi "egl"
2051 fi
2052 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2053 AC_SUBST([EGL_LIB_DEPS])
2054
2055 gallium_st="mesa"
2056
2057 dnl
2058 dnl XA configuration
2059 dnl
2060 if test "x$enable_xa" = xyes; then
2061     if test "x$with_gallium_drivers" = xswrast; then
2062        AC_MSG_ERROR([
2063           Building xa requires at least one non swrast gallium driver.
2064           If you are looking to use libxatracker.so with the VMware driver,
2065           make sure to include svga in the gallium drivers list, apart from
2066           enabling XA.
2067           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2068     fi
2069     gallium_st="$gallium_st xa"
2070 fi
2071 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2072
2073 if echo $platforms | grep -q "x11"; then
2074     have_xvmc_platform=yes
2075 else
2076     have_xvmc_platform=no
2077 fi
2078
2079 if echo $platforms | grep -q "x11"; then
2080     have_vdpau_platform=yes
2081 else
2082     have_vdpau_platform=no
2083 fi
2084
2085 if echo $platforms | grep -q "x11\|drm"; then
2086     have_omx_platform=yes
2087 else
2088     have_omx_platform=no
2089 fi
2090
2091 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2092     have_va_platform=yes
2093 else
2094     have_va_platform=no
2095 fi
2096
2097 dnl
2098 dnl Gallium G3DVL configuration
2099 dnl
2100 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2101     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2102         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2103     fi
2104
2105     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2106         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2107     fi
2108
2109     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2110         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2111     fi
2112
2113     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2114         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2115     fi
2116 fi
2117
2118 if test "x$enable_dri" = xyes -o \
2119         "x$enable_xvmc" = xyes -o \
2120         "x$enable_vdpau" = xyes -o \
2121         "x$enable_omx" = xyes -o \
2122         "x$enable_va" = xyes; then
2123     need_gallium_vl=yes
2124 fi
2125 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2126
2127 if test "x$enable_xvmc" = xyes -o \
2128         "x$enable_vdpau" = xyes -o \
2129         "x$enable_omx" = xyes -o \
2130         "x$enable_va" = xyes; then
2131     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2132     need_gallium_vl_winsys=yes
2133 fi
2134 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2135
2136 if test "x$enable_xvmc" = xyes; then
2137     if test "x$have_xvmc_platform" != xyes; then
2138         AC_MSG_ERROR([XVMC requires the x11 platforms])
2139     fi
2140     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2141     gallium_st="$gallium_st xvmc"
2142 fi
2143 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2144
2145 if test "x$enable_vdpau" = xyes; then
2146     if test "x$have_vdpau_platform" != xyes; then
2147         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2148     fi
2149     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2150     gallium_st="$gallium_st vdpau"
2151     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2152 fi
2153 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2154
2155 if test "x$enable_omx" = xyes; then
2156     if test "x$have_omx_platform" != xyes; then
2157         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2158     fi
2159     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2160     gallium_st="$gallium_st omx"
2161 fi
2162 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2163
2164 if test "x$enable_va" = xyes; then
2165     if test "x$have_va_platform" != xyes; then
2166         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2167     fi
2168     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2169     gallium_st="$gallium_st va"
2170 fi
2171 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2172
2173 dnl
2174 dnl Nine Direct3D9 configuration
2175 dnl
2176 if test "x$enable_nine" = xyes; then
2177     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2178         AC_MSG_ERROR([nine requires the gallium swrast driver])
2179     fi
2180     if test "x$with_gallium_drivers" = xswrast; then
2181         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2182     fi
2183     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2184         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2185     fi
2186
2187     if test "x$enable_dri3" = xno; then
2188         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2189     fi
2190
2191     gallium_st="$gallium_st nine"
2192 fi
2193 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2194
2195 dnl
2196 dnl OpenCL configuration
2197 dnl
2198
2199 AC_ARG_WITH([clang-libdir],
2200    [AS_HELP_STRING([--with-clang-libdir],
2201          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2202    [CLANG_LIBDIR="$withval"],
2203    [CLANG_LIBDIR=''])
2204
2205 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2206
2207 if test "x$enable_opencl" = xyes; then
2208     if test -z "$with_gallium_drivers"; then
2209         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2210     fi
2211
2212     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2213         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2214     fi
2215
2216     if test "x$have_libclc" = xno; then
2217         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2218                     Make sure the directory containing libclc.pc is specified in your
2219                     PKG_CONFIG_PATH environment variable.
2220                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2221     else
2222         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2223         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2224         AC_SUBST([LIBCLC_INCLUDEDIR])
2225         AC_SUBST([LIBCLC_LIBEXECDIR])
2226     fi
2227
2228     gallium_st="$gallium_st clover"
2229
2230     if test "x$enable_opencl_icd" = xyes; then
2231         OPENCL_LIBNAME="MesaOpenCL"
2232     else
2233         OPENCL_LIBNAME="OpenCL"
2234     fi
2235
2236     if test "x$have_libelf" != xyes; then
2237        AC_MSG_ERROR([Clover requires libelf])
2238     fi
2239
2240     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2241         altivec_enabled=no
2242         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2243         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2244         #error "AltiVec not enabled"
2245         #endif
2246         ])], altivec_enabled=yes)
2247
2248         if test "$altivec_enabled" = yes; then
2249             CLOVER_STD_OVERRIDE="-std=gnu++11"
2250         fi
2251         AC_SUBST([CLOVER_STD_OVERRIDE])
2252     fi
2253
2254     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2255
2256     llvm_add_default_components "opencl"
2257     llvm_add_component "all-targets" "opencl"
2258     llvm_add_component "linker" "opencl"
2259     llvm_add_component "instrumentation" "opencl"
2260     llvm_add_component "ipo" "opencl"
2261     llvm_add_component "irreader" "opencl"
2262     llvm_add_component "option" "opencl"
2263     llvm_add_component "objcarcopts" "opencl"
2264     llvm_add_component "profiledata" "opencl"
2265
2266     dnl Check for Clang internal headers
2267     if test -z "$CLANG_LIBDIR"; then
2268         CLANG_LIBDIR=${LLVM_LIBDIR}
2269     fi
2270     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2271     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2272         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2273 fi
2274 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2275 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2276 AC_SUBST([OPENCL_LIBNAME])
2277 AC_SUBST([CLANG_RESOURCE_DIR])
2278
2279 dnl
2280 dnl Gallium configuration
2281 dnl
2282 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2283
2284 # libEGL wants to default to the first platform specified in
2285 # ./configure.  parse that here.
2286 if test "x$platforms" != "x"; then
2287     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2288     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2289 else
2290     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2291 fi
2292
2293 AC_SUBST([EGL_NATIVE_PLATFORM])
2294 AC_SUBST([EGL_CFLAGS])
2295
2296 # If we don't have the X11 platform, set this define so we don't try to include
2297 # the X11 headers.
2298 if ! echo "$platforms" | grep -q 'x11'; then
2299     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2300     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2301 fi
2302
2303 dnl Directory for XVMC libs
2304 AC_ARG_WITH([xvmc-libdir],
2305     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2306         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2307     [XVMC_LIB_INSTALL_DIR="$withval"],
2308     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2309 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2310
2311 dnl
2312 dnl Gallium Tests
2313 dnl
2314 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2315
2316 dnl Directory for VDPAU libs
2317 AC_ARG_WITH([vdpau-libdir],
2318     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2319         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2320     [VDPAU_LIB_INSTALL_DIR="$withval"],
2321     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2322 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2323
2324 dnl Directory for OMX libs
2325
2326 AC_ARG_WITH([omx-libdir],
2327     [AS_HELP_STRING([--with-omx-libdir=DIR],
2328         [directory for the OMX libraries])],
2329     [OMX_LIB_INSTALL_DIR="$withval"],
2330     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2331                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2332 AC_SUBST([OMX_LIB_INSTALL_DIR])
2333
2334 dnl Directory for VA libs
2335
2336 AC_ARG_WITH([va-libdir],
2337     [AS_HELP_STRING([--with-va-libdir=DIR],
2338         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2339     [VA_LIB_INSTALL_DIR="$withval"],
2340     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2341 AC_SUBST([VA_LIB_INSTALL_DIR])
2342
2343 AC_ARG_WITH([d3d-libdir],
2344     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2345         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2346     [D3D_DRIVER_INSTALL_DIR="$withval"],
2347     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2348 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2349
2350 dnl
2351 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2352 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2353 dnl architectures.
2354 dnl
2355 r300_require_llvm() {
2356     case "$host" in *gnux32) return;; esac
2357     case "$host_cpu" in
2358     i*86|x86_64|amd64) require_llvm $1
2359         ;;
2360     esac
2361 }
2362
2363 dnl
2364 dnl DRM is needed by X, Wayland, and offscreen rendering.
2365 dnl Surfaceless is an alternative for the last one.
2366 dnl
2367 require_basic_egl() {
2368     case "$with_platforms" in
2369         *drm*|*surfaceless*)
2370             ;;
2371         *)
2372             AC_MSG_ERROR([$1 requires one of these:
2373                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2374                   2) --with-platforms=surfaceless (offscreen only)
2375                   Recommended options: drm,x11])
2376             ;;
2377     esac
2378 }
2379
2380 swr_require_cxx_feature_flags() {
2381     feature_name="$1"
2382     preprocessor_test="$2"
2383     option_list="$3"
2384     output_var="$4"
2385
2386     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2387     AC_LANG_PUSH([C++])
2388     save_CXXFLAGS="$CXXFLAGS"
2389     save_IFS="$IFS"
2390     IFS=","
2391     found=0
2392     for opts in $option_list
2393     do
2394         unset IFS
2395         CXXFLAGS="$opts $save_CXXFLAGS"
2396         AC_COMPILE_IFELSE(
2397             [AC_LANG_PROGRAM(
2398                 [   #if !($preprocessor_test)
2399                     #error
2400                     #endif
2401                 ])],
2402             [found=1; break],
2403             [])
2404         IFS=","
2405     done
2406     IFS="$save_IFS"
2407     CXXFLAGS="$save_CXXFLAGS"
2408     AC_LANG_POP([C++])
2409     if test $found -eq 1; then
2410         AC_MSG_RESULT([$opts])
2411         eval "$output_var=\$opts"
2412         return 0
2413     fi
2414     AC_MSG_RESULT([no])
2415     AC_MSG_ERROR([swr requires $feature_name support])
2416     return 1
2417 }
2418
2419 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2420 if test -n "$with_gallium_drivers"; then
2421     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2422     for driver in $gallium_drivers; do
2423         case "x$driver" in
2424         xsvga)
2425             HAVE_GALLIUM_SVGA=yes
2426             require_libdrm "svga"
2427             ;;
2428         xi915)
2429             HAVE_GALLIUM_I915=yes
2430             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2431             require_libdrm "Gallium i915"
2432             ;;
2433         xr300)
2434             HAVE_GALLIUM_R300=yes
2435             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2436             require_libdrm "r300"
2437             r300_require_llvm "r300"
2438             ;;
2439         xr600)
2440             HAVE_GALLIUM_R600=yes
2441             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2442             require_libdrm "r600"
2443             if test "x$enable_llvm" = xyes; then
2444                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2445
2446                 llvm_add_component "asmparser" "r600"
2447                 llvm_add_component "bitreader" "r600"
2448             fi
2449             ;;
2450         xradeonsi)
2451             HAVE_GALLIUM_RADEONSI=yes
2452             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2453             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2454             require_libdrm "radeonsi"
2455             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2456             if test "x$enable_egl" = xyes; then
2457                 require_basic_egl "radeonsi"
2458             fi
2459             ;;
2460         xnouveau)
2461             HAVE_GALLIUM_NOUVEAU=yes
2462             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2463             require_libdrm "nouveau"
2464             ;;
2465         xfreedreno)
2466             HAVE_GALLIUM_FREEDRENO=yes
2467             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2468             require_libdrm "freedreno"
2469             ;;
2470         xetnaviv)
2471             HAVE_GALLIUM_ETNAVIV=yes
2472             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2473             require_libdrm "etnaviv"
2474             ;;
2475        ximx)
2476             HAVE_GALLIUM_IMX=yes
2477             ;;
2478         xswrast)
2479             HAVE_GALLIUM_SOFTPIPE=yes
2480             if test "x$enable_llvm" = xyes; then
2481                 HAVE_GALLIUM_LLVMPIPE=yes
2482             fi
2483             ;;
2484         xswr)
2485             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2486
2487             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2488                 ",-std=c++11" \
2489                 SWR_CXX11_CXXFLAGS
2490             AC_SUBST([SWR_CXX11_CXXFLAGS])
2491
2492             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2493                 ",-mavx,-march=core-avx" \
2494                 SWR_AVX_CXXFLAGS
2495             AC_SUBST([SWR_AVX_CXXFLAGS])
2496
2497             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2498                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2499                 SWR_AVX2_CXXFLAGS
2500             AC_SUBST([SWR_AVX2_CXXFLAGS])
2501
2502             HAVE_GALLIUM_SWR=yes
2503             ;;
2504         xvc4)
2505             HAVE_GALLIUM_VC4=yes
2506             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2507             require_libdrm "vc4"
2508
2509             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2510                               [USE_VC4_SIMULATOR=yes;
2511                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2512                               [USE_VC4_SIMULATOR=no])
2513             ;;
2514         xpl111)
2515             HAVE_GALLIUM_PL111=yes
2516             ;;
2517         xvirgl)
2518             HAVE_GALLIUM_VIRGL=yes
2519             require_libdrm "virgl"
2520             if test "x$enable_egl" = xyes; then
2521                 require_basic_egl "virgl"
2522             fi
2523             ;;
2524         *)
2525             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2526             ;;
2527         esac
2528     done
2529 fi
2530
2531 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2532 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2533                                               "x$LLVM_VERSION" != x3.9.1)
2534
2535 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2536     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2537     llvm_add_default_components "gallium"
2538 fi
2539
2540 dnl We need to validate some needed dependencies for renderonly drivers.
2541
2542 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2543     AC_MSG_ERROR([Building with imx requires etnaviv])
2544 fi
2545
2546 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2547     AC_MSG_ERROR([Building with pl111 requires vc4])
2548 fi
2549
2550 dnl
2551 dnl Set defines and buildtime variables only when using LLVM.
2552 dnl
2553 if test "x$enable_llvm" = xyes; then
2554     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2555
2556     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2557     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2558     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2559
2560     dnl Set LLVM_LIBS - This is done after the driver configuration so
2561     dnl that drivers can add additional components to LLVM_COMPONENTS.
2562     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2563     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2564     dnl this was causing the same libraries to be appear multiple times
2565     dnl in LLVM_LIBS.
2566
2567     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2568        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2569     fi
2570     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2571
2572     dnl llvm-config may not give the right answer when llvm is a built as a
2573     dnl single shared library, so we must work the library name out for
2574     dnl ourselves.
2575     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2576     if test "x$enable_llvm_shared_libs" = xyes; then
2577         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2578         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2579         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2580
2581         if test "x$llvm_have_one_so" = xyes; then
2582             dnl LLVM was built using auto*, so there is only one shared object.
2583             LLVM_LIBS="-l$LLVM_SO_NAME"
2584         else
2585             dnl If LLVM was built with CMake, there will be one shared object per
2586             dnl component.
2587             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2588                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2589         Please make sure you have built llvm with the --enable-shared option
2590         and that your llvm libraries are installed in $LLVM_LIBDIR
2591         If you have installed your llvm libraries to a different directory you
2592         can use the --with-llvm-prefix= configure flag to specify this directory.
2593         NOTE: Mesa is attempting to use llvm shared libraries by default.
2594         If you do not want to build with llvm shared libraries and instead want to
2595         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2596         invocation and rebuild.])])
2597
2598            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2599            dnl install uses a shared object for each component and we have
2600            dnl already added all of these objects to LLVM_LIBS.
2601         fi
2602     else
2603         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2604         dnl We need to link to llvm system libs when using static libs
2605         dnl However, only llvm 3.5+ provides --system-libs
2606         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2607             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2608         fi
2609     fi
2610 fi
2611
2612 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2613 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2614 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2617 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2619                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2625 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2627 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2628                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2629                                          "x$HAVE_GALLIUM_SWR" = xyes)
2630 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2631 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2632
2633 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2634
2635 if test "x$enable_dri" = xyes; then
2636     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2637 fi
2638
2639 if test "x$have_drisw_kms" = xyes; then
2640     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2641 fi
2642 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2643
2644 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2645 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2646 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2647 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2648 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2649 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2650
2651 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2652 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2653
2654 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2655                                       "x$HAVE_RADEON_VULKAN" = xyes)
2656
2657 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2658                                         "x$HAVE_I965_DRI" = xyes)
2659
2660 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2661                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2662                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2663 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2664 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2665 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2666 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2667
2668 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2669 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2670 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2671 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2672                                         "x$enable_gallium_osmesa" = xyes)
2673
2674 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2675 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2676 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2677 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2678
2679 AC_SUBST([NINE_MAJOR], 1)
2680 AC_SUBST([NINE_MINOR], 0)
2681 AC_SUBST([NINE_TINY], 0)
2682 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2683
2684 AC_SUBST([VDPAU_MAJOR], 1)
2685 AC_SUBST([VDPAU_MINOR], 0)
2686
2687 if test "x$enable_va" = xyes; then
2688     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2689     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2690 fi
2691 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2692 AC_SUBST([VA_MINOR], $VA_MINOR)
2693
2694 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2695
2696 AC_SUBST([XVMC_MAJOR], 1)
2697 AC_SUBST([XVMC_MINOR], 0)
2698
2699 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2700 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2701 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2702 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2703
2704 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2705 AC_SUBST([XA_MINOR], $XA_MINOR)
2706 AC_SUBST([XA_TINY], $XA_TINY)
2707 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2708
2709 AC_ARG_ENABLE(valgrind,
2710               [AS_HELP_STRING([--enable-valgrind],
2711                              [Build mesa with valgrind support (default: auto)])],
2712                              [VALGRIND=$enableval], [VALGRIND=auto])
2713 if test "x$VALGRIND" != xno; then
2714         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2715 fi
2716 AC_MSG_CHECKING([whether to enable Valgrind support])
2717 if test "x$VALGRIND" = xauto; then
2718         VALGRIND="$have_valgrind"
2719 fi
2720
2721 if test "x$VALGRIND" = "xyes"; then
2722         if ! test "x$have_valgrind" = xyes; then
2723                 AC_MSG_ERROR([Valgrind support required but not present])
2724         fi
2725         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2726 fi
2727
2728 AC_MSG_RESULT([$VALGRIND])
2729
2730 dnl Restore LDFLAGS and CPPFLAGS
2731 LDFLAGS="$_SAVE_LDFLAGS"
2732 CPPFLAGS="$_SAVE_CPPFLAGS"
2733
2734 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2735 if test "x$acv_mesa_CLANG" = xyes; then
2736     CFLAGS="$CFLAGS -Qunused-arguments"
2737     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2738 fi
2739
2740 dnl Add user CFLAGS and CXXFLAGS
2741 CFLAGS="$CFLAGS $USER_CFLAGS"
2742 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2743
2744 dnl Substitute the config
2745 AC_CONFIG_FILES([Makefile
2746                 src/Makefile
2747                 src/amd/Makefile
2748                 src/amd/vulkan/Makefile
2749                 src/compiler/Makefile
2750                 src/egl/Makefile
2751                 src/egl/main/egl.pc
2752                 src/egl/wayland/wayland-drm/Makefile
2753                 src/egl/wayland/wayland-egl/Makefile
2754                 src/egl/wayland/wayland-egl/wayland-egl.pc
2755                 src/gallium/Makefile
2756                 src/gallium/auxiliary/Makefile
2757                 src/gallium/auxiliary/pipe-loader/Makefile
2758                 src/gallium/drivers/freedreno/Makefile
2759                 src/gallium/drivers/ddebug/Makefile
2760                 src/gallium/drivers/i915/Makefile
2761                 src/gallium/drivers/llvmpipe/Makefile
2762                 src/gallium/drivers/noop/Makefile
2763                 src/gallium/drivers/nouveau/Makefile
2764                 src/gallium/drivers/pl111/Makefile
2765                 src/gallium/drivers/r300/Makefile
2766                 src/gallium/drivers/r600/Makefile
2767                 src/gallium/drivers/radeon/Makefile
2768                 src/gallium/drivers/radeonsi/Makefile
2769                 src/gallium/drivers/rbug/Makefile
2770                 src/gallium/drivers/softpipe/Makefile
2771                 src/gallium/drivers/svga/Makefile
2772                 src/gallium/drivers/swr/Makefile
2773                 src/gallium/drivers/trace/Makefile
2774                 src/gallium/drivers/etnaviv/Makefile
2775                 src/gallium/drivers/imx/Makefile
2776                 src/gallium/drivers/vc4/Makefile
2777                 src/gallium/drivers/virgl/Makefile
2778                 src/gallium/state_trackers/clover/Makefile
2779                 src/gallium/state_trackers/dri/Makefile
2780                 src/gallium/state_trackers/glx/xlib/Makefile
2781                 src/gallium/state_trackers/nine/Makefile
2782                 src/gallium/state_trackers/omx/Makefile
2783                 src/gallium/state_trackers/osmesa/Makefile
2784                 src/gallium/state_trackers/va/Makefile
2785                 src/gallium/state_trackers/vdpau/Makefile
2786                 src/gallium/state_trackers/xa/Makefile
2787                 src/gallium/state_trackers/xvmc/Makefile
2788                 src/gallium/targets/d3dadapter9/Makefile
2789                 src/gallium/targets/d3dadapter9/d3d.pc
2790                 src/gallium/targets/dri/Makefile
2791                 src/gallium/targets/libgl-xlib/Makefile
2792                 src/gallium/targets/omx/Makefile
2793                 src/gallium/targets/opencl/Makefile
2794                 src/gallium/targets/opencl/mesa.icd
2795                 src/gallium/targets/osmesa/Makefile
2796                 src/gallium/targets/osmesa/osmesa.pc
2797                 src/gallium/targets/pipe-loader/Makefile
2798                 src/gallium/targets/va/Makefile
2799                 src/gallium/targets/vdpau/Makefile
2800                 src/gallium/targets/xa/Makefile
2801                 src/gallium/targets/xa/xatracker.pc
2802                 src/gallium/targets/xvmc/Makefile
2803                 src/gallium/tests/trivial/Makefile
2804                 src/gallium/tests/unit/Makefile
2805                 src/gallium/winsys/etnaviv/drm/Makefile
2806                 src/gallium/winsys/imx/drm/Makefile
2807                 src/gallium/winsys/freedreno/drm/Makefile
2808                 src/gallium/winsys/i915/drm/Makefile
2809                 src/gallium/winsys/nouveau/drm/Makefile
2810                 src/gallium/winsys/pl111/drm/Makefile
2811                 src/gallium/winsys/radeon/drm/Makefile
2812                 src/gallium/winsys/amdgpu/drm/Makefile
2813                 src/gallium/winsys/svga/drm/Makefile
2814                 src/gallium/winsys/sw/dri/Makefile
2815                 src/gallium/winsys/sw/kms-dri/Makefile
2816                 src/gallium/winsys/sw/null/Makefile
2817                 src/gallium/winsys/sw/wrapper/Makefile
2818                 src/gallium/winsys/sw/xlib/Makefile
2819                 src/gallium/winsys/vc4/drm/Makefile
2820                 src/gallium/winsys/virgl/drm/Makefile
2821                 src/gallium/winsys/virgl/vtest/Makefile
2822                 src/gbm/Makefile
2823                 src/gbm/main/gbm.pc
2824                 src/glx/Makefile
2825                 src/glx/apple/Makefile
2826                 src/glx/tests/Makefile
2827                 src/glx/windows/Makefile
2828                 src/glx/windows/windowsdriproto.pc
2829                 src/gtest/Makefile
2830                 src/intel/Makefile
2831                 src/loader/Makefile
2832                 src/mapi/Makefile
2833                 src/mapi/es1api/glesv1_cm.pc
2834                 src/mapi/es2api/glesv2.pc
2835                 src/mapi/glapi/gen/Makefile
2836                 src/mesa/Makefile
2837                 src/mesa/gl.pc
2838                 src/mesa/drivers/dri/dri.pc
2839                 src/mesa/drivers/dri/common/Makefile
2840                 src/mesa/drivers/dri/common/xmlpool/Makefile
2841                 src/mesa/drivers/dri/i915/Makefile
2842                 src/mesa/drivers/dri/i965/Makefile
2843                 src/mesa/drivers/dri/Makefile
2844                 src/mesa/drivers/dri/nouveau/Makefile
2845                 src/mesa/drivers/dri/r200/Makefile
2846                 src/mesa/drivers/dri/radeon/Makefile
2847                 src/mesa/drivers/dri/swrast/Makefile
2848                 src/mesa/drivers/osmesa/Makefile
2849                 src/mesa/drivers/osmesa/osmesa.pc
2850                 src/mesa/drivers/x11/Makefile
2851                 src/mesa/main/tests/Makefile
2852                 src/util/Makefile
2853                 src/util/tests/hash_table/Makefile
2854                 src/vulkan/Makefile])
2855
2856 AC_OUTPUT
2857
2858 # Fix up dependencies in *.Plo files, where we changed the extension of a
2859 # source file
2860 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2861
2862
2863 dnl
2864 dnl Output some configuration info for the user
2865 dnl
2866 echo ""
2867 echo "        prefix:          $prefix"
2868 echo "        exec_prefix:     $exec_prefix"
2869 echo "        libdir:          $libdir"
2870 echo "        includedir:      $includedir"
2871
2872 dnl API info
2873 echo ""
2874 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2875
2876 dnl Driver info
2877 echo ""
2878 case "x$enable_osmesa$enable_gallium_osmesa" in
2879 xnoyes)
2880         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2881         ;;
2882 xyesno)
2883         echo "        OSMesa:          lib$OSMESA_LIB"
2884         ;;
2885 xnono)
2886         echo "        OSMesa:          no"
2887         ;;
2888 esac
2889
2890 echo ""
2891 if test "x$enable_dri" != xno; then
2892         echo "        DRI platform:    $dri_platform"
2893         if test -z "$DRI_DIRS"; then
2894             echo "        DRI drivers:     no"
2895         else
2896             echo "        DRI drivers:     $DRI_DIRS"
2897         fi
2898         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2899 fi
2900
2901 case "x$enable_glx" in
2902 xdri)
2903     echo "        GLX:             DRI-based"
2904     ;;
2905 xxlib)
2906     echo "        GLX:             Xlib-based"
2907     ;;
2908 xgallium-xlib)
2909     echo "        GLX:             Xlib-based (Gallium)"
2910     ;;
2911 *)
2912     echo "        GLX:             $enable_glx"
2913     ;;
2914 esac
2915
2916 dnl EGL
2917 echo ""
2918 echo "        EGL:             $enable_egl"
2919 if test "$enable_egl" = yes; then
2920
2921     egl_drivers=""
2922     if test "x$enable_dri" != "xno"; then
2923         egl_drivers="$egl_drivers builtin:egl_dri2"
2924     fi
2925     if test "x$enable_dri3" != "xno"; then
2926         egl_drivers="$egl_drivers builtin:egl_dri3"
2927     fi
2928
2929     echo "        EGL drivers:    $egl_drivers"
2930 fi
2931 if test "x$enable_gbm" = xyes; then
2932     echo "        GBM:             yes"
2933 else
2934     echo "        GBM:             no"
2935 fi
2936
2937     echo "        EGL/Vulkan/VL platforms:   $platforms"
2938
2939 # Vulkan
2940 echo ""
2941 if test "x$VULKAN_DRIVERS" != x; then
2942     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2943     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2944 else
2945     echo "        Vulkan drivers:  no"
2946 fi
2947
2948 echo ""
2949 if test "x$enable_llvm" = xyes; then
2950     echo "        llvm:            yes"
2951     echo "        llvm-config:     $LLVM_CONFIG"
2952     echo "        llvm-version:    $LLVM_VERSION"
2953 else
2954     echo "        llvm:            no"
2955 fi
2956
2957 echo ""
2958 if test -n "$with_gallium_drivers"; then
2959     echo "        Gallium drivers: $gallium_drivers"
2960     echo "        Gallium st:      $gallium_st"
2961 else
2962     echo "        Gallium:         no"
2963 fi
2964
2965 echo ""
2966 if test "x$enable_gallium_extra_hud" != xyes; then
2967     echo "        HUD extra stats: no"
2968 else
2969     echo "        HUD extra stats: yes"
2970 fi
2971
2972 if test "x$enable_lmsensors" != xyes; then
2973     echo "        HUD lmsensors:   no"
2974 else
2975     echo "        HUD lmsensors:   yes"
2976 fi
2977
2978 dnl Libraries
2979 echo ""
2980 echo "        Shared libs:     $enable_shared"
2981 echo "        Static libs:     $enable_static"
2982 echo "        Shared-glapi:    $enable_shared_glapi"
2983
2984 dnl Compiler options
2985 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2986 cflags=`echo $CFLAGS | \
2987     $SED 's/^ *//;s/  */ /;s/ *$//'`
2988 cxxflags=`echo $CXXFLAGS | \
2989     $SED 's/^ *//;s/  */ /;s/ *$//'`
2990 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2991 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2992 echo ""
2993 echo "        CFLAGS:          $cflags"
2994 echo "        CXXFLAGS:        $cxxflags"
2995 echo "        LDFLAGS:         $ldflags"
2996 echo "        Macros:          $defines"
2997 echo ""
2998 if test "x$enable_llvm" = xyes; then
2999     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3000     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3001     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3002     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3003     echo ""
3004 fi
3005 echo "        PYTHON2:         $PYTHON2"
3006
3007 echo ""
3008 echo "        Run '${MAKE-make}' to build Mesa"
3009 echo ""