configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AC_CHECK_PROG(RM, rm, [rm -f])
 111
 112 AX_PROG_BISON([],
 113               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 114                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 115 AX_PROG_FLEX([],
 116              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 117                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 118
 119 AC_CHECK_PROG(INDENT, indent, indent, cat)
 120 if test "x$INDENT" != "xcat"; then
 121     # Only GNU indent is supported
 122     INDENT_VERSION=`indent --version | grep GNU`
 123     if test $? -eq 0; then
 124        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 125     else
 126        INDENT="cat"
 127     fi
 128 fi
 129
 130 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 131
 132 if test -z "$PYTHON2"; then
 133     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 134         AC_MSG_ERROR([Python not found - unable to generate sources])
 135     fi
 136 else
 137     if test "x$acv_mako_found" = xno; then
 138         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 139             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 140         fi
 141     fi
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 dnl We need a POSIX shell for parts of the build. Assume we have one
 147 dnl in most cases.
 148 case "$host_os" in
 149 solaris*)
 150     # Solaris /bin/sh is too old/non-POSIX compliant
 151     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 152     SHELL="$POSIX_SHELL"
 153     ;;
 154 esac
 155
 156 dnl clang is mostly GCC-compatible, but its version is much lower,
 157 dnl so we have to check for it.
 158 AC_MSG_CHECKING([if compiling with clang])
 159
 160 AC_COMPILE_IFELSE(
 161 [AC_LANG_PROGRAM([], [[
 162 #ifndef __clang__
 163        not clang
 164 #endif
 165 ]])],
 166 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 167
 168 AC_MSG_RESULT([$acv_mesa_CLANG])
 169
 170 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 171 dnl versions are explictly not supported.
 172 GEN_ASM_OFFSETS=no
 173 USE_GNU99=no
 174 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 175     AC_MSG_CHECKING([whether gcc version is sufficient])
 176     major=0
 177     minor=0
 178
 179     GCC_VERSION=`$CC -dumpversion`
 180     if test $? -eq 0; then
 181         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 182         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 183     fi
 184
 185     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 186         AC_MSG_RESULT([no])
 187         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 188     else
 189         AC_MSG_RESULT([yes])
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 193         USE_GNU99=yes
 194     fi
 195     if test "x$cross_compiling" = xyes; then
 196         GEN_ASM_OFFSETS=yes
 197     fi
 198 fi
 199
 200 dnl Check for compiler builtins
 201 AX_GCC_BUILTIN([__builtin_bswap32])
 202 AX_GCC_BUILTIN([__builtin_bswap64])
 203 AX_GCC_BUILTIN([__builtin_clz])
 204 AX_GCC_BUILTIN([__builtin_clzll])
 205 AX_GCC_BUILTIN([__builtin_ctz])
 206 AX_GCC_BUILTIN([__builtin_expect])
 207 AX_GCC_BUILTIN([__builtin_ffs])
 208 AX_GCC_BUILTIN([__builtin_ffsll])
 209 AX_GCC_BUILTIN([__builtin_popcount])
 210 AX_GCC_BUILTIN([__builtin_popcountll])
 211 AX_GCC_BUILTIN([__builtin_unreachable])
 212
 213 AX_GCC_FUNC_ATTRIBUTE([const])
 214 AX_GCC_FUNC_ATTRIBUTE([flatten])
 215 AX_GCC_FUNC_ATTRIBUTE([format])
 216 AX_GCC_FUNC_ATTRIBUTE([malloc])
 217 AX_GCC_FUNC_ATTRIBUTE([packed])
 218 AX_GCC_FUNC_ATTRIBUTE([pure])
 219 AX_GCC_FUNC_ATTRIBUTE([unused])
 220 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 221
 222 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 223
 224 dnl Make sure the pkg-config macros are defined
 225 m4_ifndef([PKG_PROG_PKG_CONFIG],
 226     [m4_fatal([Could not locate the pkg-config autoconf macros.
 227   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 228   are in a different location, try setting the environment variable
 229   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 230 PKG_PROG_PKG_CONFIG()
 231
 232 dnl LIB_DIR - library basename
 233 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 234 AC_SUBST([LIB_DIR])
 235
 236 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 237 _SAVE_LDFLAGS="$LDFLAGS"
 238 _SAVE_CPPFLAGS="$CPPFLAGS"
 239
 240 dnl Compiler macros
 241 DEFINES="-D__STDC_LIMIT_MACROS"
 242 AC_SUBST([DEFINES])
 243 case "$host_os" in
 244 linux*|*-gnu*|gnu*)
 245     DEFINES="$DEFINES -D_GNU_SOURCE"
 246     ;;
 247 solaris*)
 248     DEFINES="$DEFINES -DSVR4"
 249     ;;
 250 cygwin*)
 251     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 252     ;;
 253 esac
 254
 255 dnl Add flags for gcc and g++
 256 if test "x$GCC" = xyes; then
 257     CFLAGS="$CFLAGS -Wall"
 258
 259     if test "x$USE_GNU99" = xyes; then
 260         CFLAGS="$CFLAGS -std=gnu99"
 261     else
 262         CFLAGS="$CFLAGS -std=c99"
 263     fi
 264
 265     # Enable -Werror=implicit-function-declaration and
 266     # -Werror=missing-prototypes, if available, or otherwise, just
 267     # -Wmissing-prototypes.  This is particularly useful to avoid
 268     # generating a loadable driver module that has undefined symbols.
 269     save_CFLAGS="$CFLAGS"
 270     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 271     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 272     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 273     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 274                    AC_MSG_RESULT([yes]),
 275                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 276                     AC_MSG_RESULT([no])]);
 277
 278     # Enable -fvisibility=hidden if using a gcc that supports it
 279     save_CFLAGS="$CFLAGS"
 280     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 281     VISIBILITY_CFLAGS="-fvisibility=hidden"
 282     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 283     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 284                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 285
 286     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 287     CFLAGS=$save_CFLAGS
 288
 289     # Work around aliasing bugs - developers should comment this out
 290     CFLAGS="$CFLAGS -fno-strict-aliasing"
 291
 292     # We don't want floating-point math functions to set errno or trap
 293     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 294
 295     # gcc's builtin memcmp is slower than glibc's
 296     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 297     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 298
 299     # Flags to help ensure that certain portions of the code -- and only those
 300     # portions -- can be built with MSVC:
 301     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 302     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 303     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 304     #   supports most of C99)
 305     # - the rest has no compiler compiler restrictions
 306     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 307     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 308
 309     # Enable -Werror=vla if compiler supports it
 310     save_CFLAGS="$CFLAGS"
 311     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 312     CFLAGS="$CFLAGS -Werror=vla"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 314                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 315                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 316                     AC_MSG_RESULT([yes])],
 317                     AC_MSG_RESULT([no]));
 318     CFLAGS="$save_CFLAGS"
 319
 320     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 321     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 322 fi
 323 if test "x$GXX" = xyes; then
 324     CXXFLAGS="$CXXFLAGS -Wall"
 325
 326     # Enable -fvisibility=hidden if using a gcc that supports it
 327     save_CXXFLAGS="$CXXFLAGS"
 328     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 329     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 330     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 331     AC_LANG_PUSH([C++])
 332     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 333                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 334     AC_LANG_POP([C++])
 335
 336     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 337     CXXFLAGS=$save_CXXFLAGS
 338
 339     # Work around aliasing bugs - developers should comment this out
 340     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 341
 342     # gcc's builtin memcmp is slower than glibc's
 343     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 344     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 350 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 351
 352 dnl even if the compiler appears to support it, using visibility attributes isn't
 353 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 354 case "$host_os" in
 355 cygwin*)
 356     VISIBILITY_CFLAGS=""
 357     VISIBILITY_CXXFLAGS=""
 358     ;;
 359 esac
 360
 361 AC_SUBST([VISIBILITY_CFLAGS])
 362 AC_SUBST([VISIBILITY_CXXFLAGS])
 363
 364 dnl
 365 dnl Optional flags, check for compiler support
 366 dnl
 367 SSE41_CFLAGS="-msse4.1"
 368 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 369 dnl stack, but on x86-32 such alignment is not guaranteed.
 370 case "$target_cpu" in
 371 i?86)
 372     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 373     ;;
 374 esac
 375 save_CFLAGS="$CFLAGS"
 376 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 377 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 378 #include <smmintrin.h>
 379 int main () {
 380     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 381     c = _mm_max_epu32(a, b);
 382     return 0;
 383 }]])], SSE41_SUPPORTED=1)
 384 CFLAGS="$save_CFLAGS"
 385 if test "x$SSE41_SUPPORTED" = x1; then
 386     DEFINES="$DEFINES -DUSE_SSE41"
 387 fi
 388 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 389 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 390
 391 dnl Can't have static and shared libraries, default to static if user
 392 dnl explicitly requested. If both disabled, set to static since shared
 393 dnl was explicitly requested.
 394 case "x$enable_static$enable_shared" in
 395 xyesyes)
 396     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 397     enable_shared=no
 398     ;;
 399 xnono)
 400     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 401     enable_shared=yes
 402     ;;
 403 esac
 404
 405 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 406
 407 dnl
 408 dnl other compiler options
 409 dnl
 410 AC_ARG_ENABLE([debug],
 411     [AS_HELP_STRING([--enable-debug],
 412         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 413     [enable_debug="$enableval"],
 414     [enable_debug=no]
 415 )
 416 if test "x$enable_debug" = xyes; then
 417     DEFINES="$DEFINES -DDEBUG"
 418     if test "x$GCC" = xyes; then
 419         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 420             CFLAGS="$CFLAGS -g"
 421         fi
 422         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 423             CFLAGS="$CFLAGS -O0"
 424         fi
 425     fi
 426     if test "x$GXX" = xyes; then
 427         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 428             CXXFLAGS="$CXXFLAGS -g"
 429         fi
 430         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 431             CXXFLAGS="$CXXFLAGS -O0"
 432         fi
 433     fi
 434 else
 435    DEFINES="$DEFINES -DNDEBUG"
 436 fi
 437
 438 dnl
 439 dnl Check if linker supports -Bsymbolic
 440 dnl
 441 save_LDFLAGS=$LDFLAGS
 442 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 443 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 444 AC_LINK_IFELSE(
 445     [AC_LANG_SOURCE([int main() { return 0;}])],
 446     [AC_MSG_RESULT([yes])
 447         BSYMBOLIC="-Wl,-Bsymbolic";],
 448     [AC_MSG_RESULT([no])
 449         BSYMBOLIC="";])
 450 LDFLAGS=$save_LDFLAGS
 451
 452 AC_SUBST([BSYMBOLIC])
 453
 454 dnl
 455 dnl Check if linker supports garbage collection
 456 dnl
 457 save_LDFLAGS=$LDFLAGS
 458 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 459 AC_MSG_CHECKING([whether ld supports --gc-sections])
 460 AC_LINK_IFELSE(
 461     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 462     [AC_MSG_RESULT([yes])
 463         GC_SECTIONS="-Wl,--gc-sections";],
 464     [AC_MSG_RESULT([no])
 465         GC_SECTIONS="";])
 466 LDFLAGS=$save_LDFLAGS
 467
 468 AC_SUBST([GC_SECTIONS])
 469
 470 dnl
 471 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 472 dnl so when these flags are passed to ld via libtool the checks will fail
 473 dnl
 474 case "$host_os" in
 475 openbsd* | darwin* )
 476     LD_NO_UNDEFINED="" ;;
 477 *)
 478     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 479 esac
 480
 481 AC_SUBST([LD_NO_UNDEFINED])
 482
 483 dnl
 484 dnl Check if linker supports version scripts
 485 dnl
 486 AC_MSG_CHECKING([if the linker supports version-scripts])
 487 save_LDFLAGS=$LDFLAGS
 488 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 489 cat > conftest.map <<EOF
 490 VERSION_1 {
 491      global:
 492          main;
 493
 494      local:
 495          *;
 496 };
 497 EOF
 498 AC_LINK_IFELSE(
 499     [AC_LANG_SOURCE([int main() { return 0;}])],
 500     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 501     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 502 LDFLAGS=$save_LDFLAGS
 503 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 504
 505 dnl
 506 dnl Check if linker supports dynamic list files
 507 dnl
 508 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 509 save_LDFLAGS=$LDFLAGS
 510 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 511 cat > conftest.dyn <<EOF
 512 {
 513         radeon_drm_winsys_create;
 514 };
 515 EOF
 516 AC_LINK_IFELSE(
 517     [AC_LANG_SOURCE([int main() { return 0;}])],
 518     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 519     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 520 LDFLAGS=$save_LDFLAGS
 521 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 522
 523 dnl
 524 dnl compatibility symlinks
 525 dnl
 526 case "$host_os" in
 527 linux* )
 528     HAVE_COMPAT_SYMLINKS=yes ;;
 529 * )
 530     HAVE_COMPAT_SYMLINKS=no ;;
 531 esac
 532
 533 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 534
 535 dnl
 536 dnl library names
 537 dnl
 538 dnl Unfortunately we need to do a few things that libtool can't help us with,
 539 dnl so we need some knowledge of shared library filenames:
 540 dnl
 541 dnl LIB_EXT is the extension used when creating symlinks for alternate
 542 dnl filenames for a shared library which will be dynamically loaded
 543 dnl
 544 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 545 dnl the file for a shared library we wish to link with
 546 dnl
 547 case "$host_os" in
 548 darwin* )
 549     LIB_EXT='dylib'
 550     IMP_LIB_EXT=$LIB_EXT
 551     ;;
 552 cygwin* )
 553     LIB_EXT='dll'
 554     IMP_LIB_EXT='dll.a'
 555     ;;
 556 aix* )
 557     LIB_EXT='a'
 558     IMP_LIB_EXT=$LIB_EXT
 559     ;;
 560 * )
 561     LIB_EXT='so'
 562     IMP_LIB_EXT=$LIB_EXT
 563     ;;
 564 esac
 565
 566 AC_SUBST([LIB_EXT])
 567
 568 AC_ARG_WITH([gl-lib-name],
 569   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 570     [specify GL library name @<:@default=GL@:>@])],
 571   [GL_LIB=$withval],
 572   [GL_LIB=GL])
 573 AC_ARG_WITH([osmesa-lib-name],
 574   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 575     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 576   [OSMESA_LIB=$withval],
 577   [OSMESA_LIB=OSMesa])
 578 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 579 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 580
 581 dnl
 582 dnl Mangled Mesa support
 583 dnl
 584 AC_ARG_ENABLE([mangling],
 585   [AS_HELP_STRING([--enable-mangling],
 586     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 587   [enable_mangling="${enableval}"],
 588   [enable_mangling=no]
 589 )
 590 if test "x${enable_mangling}" = "xyes" ; then
 591   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 592   GL_LIB="Mangled${GL_LIB}"
 593   OSMESA_LIB="Mangled${OSMESA_LIB}"
 594 fi
 595 AC_SUBST([GL_LIB])
 596 AC_SUBST([OSMESA_LIB])
 597
 598 dnl
 599 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 600 dnl
 601 AC_ARG_ENABLE([texture-float],
 602     [AS_HELP_STRING([--enable-texture-float],
 603         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 604     [enable_texture_float="$enableval"],
 605     [enable_texture_float=no]
 606 )
 607 if test "x$enable_texture_float" = xyes; then
 608     AC_MSG_WARN([Floating-point textures enabled.])
 609     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 610     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 611 fi
 612
 613 dnl
 614 dnl Arch/platform-specific settings
 615 dnl
 616 AC_ARG_ENABLE([asm],
 617     [AS_HELP_STRING([--disable-asm],
 618         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 619     [enable_asm="$enableval"],
 620     [enable_asm=yes]
 621 )
 622 asm_arch=""
 623 AC_MSG_CHECKING([whether to enable assembly])
 624 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 625 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 626 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 627     case "$host_cpu" in
 628     i?86 | x86_64 | amd64)
 629         enable_asm=no
 630         AC_MSG_RESULT([no, cross compiling])
 631         ;;
 632     esac
 633 fi
 634 # check for supported arches
 635 if test "x$enable_asm" = xyes; then
 636     case "$host_cpu" in
 637     i?86)
 638         case "$host_os" in
 639         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 640             asm_arch=x86
 641             ;;
 642         esac
 643         ;;
 644     x86_64|amd64)
 645         case "$host_os" in
 646         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 647             asm_arch=x86_64
 648             ;;
 649         esac
 650         ;;
 651     sparc*)
 652         case "$host_os" in
 653         linux*)
 654             asm_arch=sparc
 655             ;;
 656         esac
 657         ;;
 658     esac
 659
 660     case "$asm_arch" in
 661     x86)
 662         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 663         AC_MSG_RESULT([yes, x86])
 664         ;;
 665     x86_64|amd64)
 666         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 667         AC_MSG_RESULT([yes, x86_64])
 668         ;;
 669     sparc)
 670         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 671         AC_MSG_RESULT([yes, sparc])
 672         ;;
 673     *)
 674         AC_MSG_RESULT([no, platform not supported])
 675         ;;
 676     esac
 677 fi
 678
 679 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 680 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 681 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 682 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 683
 684 dnl Check to see if dlopen is in default libraries (like Solaris, which
 685 dnl has it in libc), or if libdl is needed to get it.
 686 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 687     [AC_CHECK_LIB([dl], [dlopen],
 688        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 689 AC_SUBST([DLOPEN_LIBS])
 690
 691 dnl Check if that library also has dladdr
 692 save_LIBS="$LIBS"
 693 LIBS="$LIBS $DLOPEN_LIBS"
 694 AC_CHECK_FUNCS([dladdr])
 695 LIBS="$save_LIBS"
 696
 697 case "$host_os" in
 698 darwin*)
 699     ;;
 700 *)
 701     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 702                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 703                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 704     AC_SUBST([CLOCK_LIB])
 705     ;;
 706 esac
 707
 708 dnl See if posix_memalign is available
 709 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 710
 711 dnl Check for pthreads
 712 AX_PTHREAD
 713 if test "x$ax_pthread_ok" = xno; then
 714     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 715 fi
 716 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 717 dnl to -pthread, which causes problems if we need -lpthread to appear in
 718 dnl pkgconfig files.
 719 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 720
 721 dnl SELinux awareness.
 722 AC_ARG_ENABLE([selinux],
 723     [AS_HELP_STRING([--enable-selinux],
 724         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 725     [MESA_SELINUX="$enableval"],
 726     [MESA_SELINUX=no])
 727 if test "x$enable_selinux" = "xyes"; then
 728     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 729         [AC_CHECK_HEADER([selinux/selinux.h],[],
 730                          [AC_MSG_ERROR([SELinux headers not found])])
 731          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 732                       [AC_MSG_ERROR([SELinux library not found])])
 733          SELINUX_LIBS="-lselinux"])
 734     DEFINES="$DEFINES -DMESA_SELINUX"
 735 fi
 736 AC_SUBST([SELINUX_CFLAGS])
 737 AC_SUBST([SELINUX_LIBS])
 738
 739 dnl Options for APIs
 740 AC_ARG_ENABLE([opengl],
 741     [AS_HELP_STRING([--disable-opengl],
 742         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 743     [enable_opengl="$enableval"],
 744     [enable_opengl=yes])
 745 AC_ARG_ENABLE([gles1],
 746     [AS_HELP_STRING([--disable-gles1],
 747         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 748     [enable_gles1="$enableval"],
 749     [enable_gles1=yes])
 750 AC_ARG_ENABLE([gles2],
 751     [AS_HELP_STRING([--disable-gles2],
 752         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 753     [enable_gles2="$enableval"],
 754     [enable_gles2=yes])
 755
 756 AC_ARG_ENABLE([dri],
 757     [AS_HELP_STRING([--enable-dri],
 758         [enable DRI modules @<:@default=enabled@:>@])],
 759     [enable_dri="$enableval"],
 760     [enable_dri=yes])
 761
 762 case "$host_os" in
 763 linux*)
 764     dri3_default=yes
 765     ;;
 766 *)
 767     dri3_default=no
 768     ;;
 769 esac
 770 AC_ARG_ENABLE([dri3],
 771     [AS_HELP_STRING([--enable-dri3],
 772         [enable DRI3 @<:@default=auto@:>@])],
 773     [enable_dri3="$enableval"],
 774     [enable_dri3="$dri3_default"])
 775 AC_ARG_ENABLE([glx],
 776     [AS_HELP_STRING([--enable-glx],
 777         [enable GLX library @<:@default=enabled@:>@])],
 778     [enable_glx="$enableval"],
 779     [enable_glx=yes])
 780 AC_ARG_ENABLE([osmesa],
 781     [AS_HELP_STRING([--enable-osmesa],
 782         [enable OSMesa library @<:@default=disabled@:>@])],
 783     [enable_osmesa="$enableval"],
 784     [enable_osmesa=no])
 785 AC_ARG_ENABLE([gallium-osmesa],
 786     [AS_HELP_STRING([--enable-gallium-osmesa],
 787         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 788     [enable_gallium_osmesa="$enableval"],
 789     [enable_gallium_osmesa=no])
 790 AC_ARG_ENABLE([egl],
 791     [AS_HELP_STRING([--disable-egl],
 792         [disable EGL library @<:@default=enabled@:>@])],
 793     [enable_egl="$enableval"],
 794     [enable_egl=yes])
 795
 796 AC_ARG_ENABLE([xa],
 797     [AS_HELP_STRING([--enable-xa],
 798         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 799     [enable_xa="$enableval"],
 800     [enable_xa=no])
 801 AC_ARG_ENABLE([gbm],
 802    [AS_HELP_STRING([--enable-gbm],
 803          [enable gbm library @<:@default=auto@:>@])],
 804    [enable_gbm="$enableval"],
 805    [enable_gbm=auto])
 806 AC_ARG_ENABLE([nine],
 807     [AS_HELP_STRING([--enable-nine],
 808         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 809     [enable_nine="$enableval"],
 810     [enable_nine=no])
 811
 812 AC_ARG_ENABLE([xvmc],
 813    [AS_HELP_STRING([--enable-xvmc],
 814          [enable xvmc library @<:@default=auto@:>@])],
 815    [enable_xvmc="$enableval"],
 816    [enable_xvmc=auto])
 817 AC_ARG_ENABLE([vdpau],
 818    [AS_HELP_STRING([--enable-vdpau],
 819          [enable vdpau library @<:@default=auto@:>@])],
 820    [enable_vdpau="$enableval"],
 821    [enable_vdpau=auto])
 822 AC_ARG_ENABLE([omx],
 823    [AS_HELP_STRING([--enable-omx],
 824          [enable OpenMAX library @<:@default=disabled@:>@])],
 825    [enable_omx="$enableval"],
 826    [enable_omx=no])
 827 AC_ARG_ENABLE([va],
 828    [AS_HELP_STRING([--enable-va],
 829          [enable va library @<:@default=auto@:>@])],
 830    [enable_va="$enableval"],
 831    [enable_va=auto])
 832 AC_ARG_ENABLE([opencl],
 833    [AS_HELP_STRING([--enable-opencl],
 834          [enable OpenCL library @<:@default=disabled@:>@])],
 835    [enable_opencl="$enableval"],
 836    [enable_opencl=no])
 837 AC_ARG_ENABLE([opencl_icd],
 838    [AS_HELP_STRING([--enable-opencl-icd],
 839           [Build an OpenCL ICD library to be loaded by an ICD implementation
 840            @<:@default=disabled@:>@])],
 841     [enable_opencl_icd="$enableval"],
 842     [enable_opencl_icd=no])
 843 AC_ARG_ENABLE([xlib-glx],
 844     [AS_HELP_STRING([--enable-xlib-glx],
 845         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 846     [enable_xlib_glx="$enableval"],
 847     [enable_xlib_glx=no])
 848
 849 AC_ARG_ENABLE([r600-llvm-compiler],
 850     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 851         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 852     [enable_r600_llvm="$enableval"],
 853     [enable_r600_llvm=no])
 854
 855 AC_ARG_ENABLE([gallium-tests],
 856     [AS_HELP_STRING([--enable-gallium-tests],
 857         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 858     [enable_gallium_tests="$enableval"],
 859     [enable_gallium_tests=no])
 860
 861 # Option for Gallium drivers
 862
 863 # Keep this in sync with the --with-gallium-drivers help string default value
 864 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 865
 866 AC_ARG_WITH([gallium-drivers],
 867     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 868         [comma delimited Gallium drivers list, e.g.
 869         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 870         @<:@default=r300,r600,svga,swrast@:>@])],
 871     [with_gallium_drivers="$withval"],
 872     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 873
 874 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 875 # here so that the script doesn't choke on an unknown driver name later.
 876 case "$with_gallium_drivers" in
 877     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 878     no) with_gallium_drivers='' ;;
 879 esac
 880
 881 if test "x$enable_opengl" = xno -a \
 882         "x$enable_gles1" = xno -a \
 883         "x$enable_gles2" = xno -a \
 884         "x$enable_nine" = xno -a \
 885         "x$enable_xa" = xno -a \
 886         "x$enable_xvmc" = xno -a \
 887         "x$enable_vdpau" = xno -a \
 888         "x$enable_omx" = xno -a \
 889         "x$enable_va" = xno -a \
 890         "x$enable_opencl" = xno; then
 891     AC_MSG_ERROR([at least one API should be enabled])
 892 fi
 893
 894 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 895 if test "x$enable_opengl" = xno -a \
 896         "x$enable_gles1" = xyes; then
 897     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 898 fi
 899
 900 if test "x$enable_opengl" = xno -a \
 901         "x$enable_gles2" = xyes; then
 902     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 903 fi
 904
 905 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 906 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 907 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 908 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 909                                         "x$enable_gles1" = xyes -o \
 910                                         "x$enable_gles2" = xyes)
 911
 912 if test "x$enable_glx" = xno; then
 913     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 914     enable_xlib_glx=no
 915 fi
 916
 917 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 918     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 919 fi
 920
 921 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 922     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 923 fi
 924
 925 # Disable GLX if OpenGL is not enabled
 926 if test "x$enable_glx$enable_opengl" = xyesno; then
 927     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 928     enable_glx=no
 929 fi
 930
 931 # Disable GLX if DRI and Xlib-GLX are not enabled
 932 if test "x$enable_glx" = xyes -a \
 933         "x$enable_dri" = xno -a \
 934         "x$enable_xlib_glx" = xno; then
 935     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 936     enable_glx=no
 937 fi
 938
 939 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 940                                   "x$enable_dri" = xyes)
 941
 942 # Check for libdrm
 943 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 944                   [have_libdrm=yes], [have_libdrm=no])
 945 if test "x$have_libdrm" = xyes; then
 946         DEFINES="$DEFINES -DHAVE_LIBDRM"
 947 fi
 948
 949 # Select which platform-dependent DRI code gets built
 950 case "$host_os" in
 951 darwin*)
 952     dri_platform='apple' ;;
 953 gnu*|cygwin*)
 954     dri_platform='none' ;;
 955 *)
 956     dri_platform='drm' ;;
 957 esac
 958
 959 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 960 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 961 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 962 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 963 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 964
 965 AC_ARG_ENABLE([shared-glapi],
 966     [AS_HELP_STRING([--enable-shared-glapi],
 967         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 968     [enable_shared_glapi="$enableval"],
 969     [enable_shared_glapi=yes])
 970
 971 case "x$enable_opengl$enable_gles1$enable_gles2" in
 972 x*yes*yes*)
 973     if test "x$enable_shared_glapi" = xno; then
 974         AC_MSG_ERROR([shared GLAPI required when building two or more of
 975                       the following APIs - opengl, gles1 gles2])
 976     fi
 977     ;;
 978 esac
 979
 980 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 981
 982 # Build the pipe-drivers as separate libraries/modules.
 983 # Do not touch this unless you know what you are doing.
 984 # XXX: Expose via configure option ?
 985 enable_shared_pipe_drivers=no
 986
 987 dnl
 988 dnl Driver specific build directories
 989 dnl
 990
 991 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 992     NEED_WINSYS_XLIB="yes"
 993 fi
 994
 995 if test "x$enable_dri" = xyes; then
 996     enable_gallium_loader="$enable_shared_pipe_drivers"
 997 fi
 998
 999 if test "x$enable_gallium_osmesa" = xyes; then
1000     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1001         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1002     fi
1003     if test "x$enable_osmesa" = xyes; then
1004         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1005     fi
1006 fi
1007
1008 AC_SUBST([MESA_LLVM])
1009
1010 # SHA1 hashing
1011 AC_ARG_WITH([sha1],
1012         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1013         [choose SHA1 implementation])])
1014 case "x$with_sha1" in
1015 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1016   ;;
1017 *)
1018         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1019 esac
1020
1021 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1022 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1023         with_sha1=libc
1024 fi
1025 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1026         AC_MSG_ERROR([sha1 in libc requested but not found])
1027 fi
1028 if test "x$with_sha1" = xlibc; then
1029         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1030                 [Use libc SHA1 functions])
1031         SHA1_LIBS=""
1032 fi
1033 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1034 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1035         with_sha1=CommonCrypto
1036 fi
1037 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1038         AC_MSG_ERROR([CommonCrypto requested but not found])
1039 fi
1040 if test "x$with_sha1" = xCommonCrypto; then
1041         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1042                 [Use CommonCrypto SHA1 functions])
1043         SHA1_LIBS=""
1044 fi
1045 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1046 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1047 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1048         with_sha1=CryptoAPI
1049 fi
1050 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1051         AC_MSG_ERROR([CryptoAPI requested but not found])
1052 fi
1053 if test "x$with_sha1" = xCryptoAPI; then
1054         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1055                 [Use CryptoAPI SHA1 functions])
1056         SHA1_LIBS=""
1057 fi
1058 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1059 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1060         with_sha1=libmd
1061 fi
1062 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1063         AC_MSG_ERROR([libmd requested but not found])
1064 fi
1065 if test "x$with_sha1" = xlibmd; then
1066         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1067                   [Use libmd SHA1 functions])
1068         SHA1_LIBS=-lmd
1069 fi
1070 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1071 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1072    with_sha1=libsha1
1073 fi
1074 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1075         AC_MSG_ERROR([libsha1 requested but not found])
1076 fi
1077 if test "x$with_sha1" = xlibsha1; then
1078         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1079                   [Use libsha1 for SHA1])
1080         SHA1_LIBS=-lsha1
1081 fi
1082 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1083 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1084         with_sha1=libnettle
1085 fi
1086 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1087         AC_MSG_ERROR([libnettle requested but not found])
1088 fi
1089 if test "x$with_sha1" = xlibnettle; then
1090         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1091                   [Use libnettle SHA1 functions])
1092         SHA1_LIBS=-lnettle
1093 fi
1094 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1095 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1096         with_sha1=libgcrypt
1097 fi
1098 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1099         AC_MSG_ERROR([libgcrypt requested but not found])
1100 fi
1101 if test "x$with_sha1" = xlibgcrypt; then
1102         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1103                   [Use libgcrypt SHA1 functions])
1104         SHA1_LIBS=-lgcrypt
1105 fi
1106 # We don't need all of the OpenSSL libraries, just libcrypto
1107 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1108 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1109                   [HAVE_OPENSSL_PKC=no])
1110 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1111         if test "x$with_sha1" = x; then
1112                 with_sha1=libcrypto
1113         fi
1114 else
1115         if test "x$with_sha1" = xlibcrypto; then
1116                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1117         fi
1118 fi
1119 if test "x$with_sha1" = xlibcrypto; then
1120         if test "x$HAVE_LIBCRYPTO" = xyes; then
1121                 SHA1_LIBS=-lcrypto
1122         else
1123                 SHA1_LIBS="$OPENSSL_LIBS"
1124                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1125         fi
1126 fi
1127 AC_MSG_CHECKING([for SHA1 implementation])
1128 AC_MSG_RESULT([$with_sha1])
1129 AC_SUBST(SHA1_LIBS)
1130 AC_SUBST(SHA1_CFLAGS)
1131
1132 # Enable a define for SHA1
1133 if test "x$with_sha1" != "x"; then
1134         DEFINES="$DEFINES -DHAVE_SHA1"
1135 fi
1136
1137 # Allow user to configure out the shader-cache feature
1138 AC_ARG_ENABLE([shader-cache],
1139     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1140     [enable_shader_cache="$enableval"],
1141     [if test "x$with_sha1" != "x"; then
1142         enable_shader_cache=yes
1143      else
1144         enable_shader_cache=no
1145      fi])
1146 if test "x$with_sha1" = "x"; then
1147     if test "x$enable_shader_cache" = "xyes"; then
1148         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1149     fi
1150 fi
1151 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1152
1153 case "$host_os" in
1154 linux*)
1155     need_pci_id=yes ;;
1156 *)
1157     need_pci_id=no ;;
1158 esac
1159
1160 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1161                   have_libudev=yes, have_libudev=no)
1162
1163 AC_ARG_ENABLE([sysfs],
1164     [AS_HELP_STRING([--enable-sysfs],
1165         [enable /sys PCI identification @<:@default=disabled@:>@])],
1166     [have_sysfs="$enableval"],
1167     [have_sysfs=no]
1168 )
1169
1170 if test "x$enable_dri" = xyes; then
1171     if test "$enable_static" = yes; then
1172         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1173     fi
1174
1175     # not a hard requirement as swrast does not depend on it
1176     if test "x$have_libdrm" = xyes; then
1177         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1178     fi
1179 fi
1180
1181 AC_ARG_ENABLE([driglx-direct],
1182     [AS_HELP_STRING([--disable-driglx-direct],
1183         [disable direct rendering in GLX and EGL for DRI \
1184             @<:@default=auto@:>@])],
1185     [driglx_direct="$enableval"],
1186     [driglx_direct="yes"])
1187
1188 dnl
1189 dnl libGL configuration per driver
1190 dnl
1191 case "x$enable_glx$enable_xlib_glx" in
1192 xyesyes)
1193     # Xlib-based GLX
1194     dri_modules="x11 xext xcb"
1195     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1196     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1197     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1198     GL_LIB_DEPS="$XLIBGL_LIBS"
1199     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1200     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1201     ;;
1202 xyesno)
1203     # DRI-based GLX
1204     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1205
1206     # find the DRI deps for libGL
1207     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1208
1209     if test x"$driglx_direct" = xyes; then
1210         if test x"$dri_platform" = xdrm ; then
1211             DEFINES="$DEFINES -DGLX_USE_DRM"
1212             if test "x$have_libdrm" != xyes; then
1213                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1214             fi
1215
1216             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1217             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1218             if test x"$enable_dri3" = xyes; then
1219                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1220                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1221             fi
1222
1223             if test x"$enable_dri" = xyes; then
1224                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1225             fi
1226
1227             if test x"$enable_dri3" = xyes; then
1228                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1229                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1230                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1231             fi
1232         fi
1233         if test x"$dri_platform" = xapple ; then
1234             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1235         fi
1236     fi
1237
1238     # add xf86vidmode if available
1239     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1240     if test "$HAVE_XF86VIDMODE" = yes ; then
1241         dri_modules="$dri_modules xxf86vm"
1242     fi
1243
1244     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1245     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1246     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1247     GL_LIB_DEPS="$DRIGL_LIBS"
1248
1249     # need DRM libs, $PTHREAD_LIBS, etc.
1250     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1251     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1252     ;;
1253 esac
1254
1255 have_pci_id=no
1256 if test "$have_libudev" = yes; then
1257     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1258     have_pci_id=yes
1259 fi
1260
1261 if test "$have_sysfs" = yes; then
1262     DEFINES="$DEFINES -DHAVE_SYSFS"
1263     have_pci_id=yes
1264 fi
1265
1266 # This is outside the case (above) so that it is invoked even for non-GLX
1267 # builds.
1268 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1269
1270 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1271 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1272 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1273 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1274
1275 AC_SUBST([X11_INCLUDES])
1276 AC_SUBST([GL_LIB_DEPS])
1277 AC_SUBST([GL_PC_REQ_PRIV])
1278 AC_SUBST([GL_PC_LIB_PRIV])
1279 AC_SUBST([GL_PC_CFLAGS])
1280 AC_SUBST([DRI_PC_REQ_PRIV])
1281 AC_SUBST([GLESv1_CM_LIB_DEPS])
1282 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1283 AC_SUBST([GLESv2_LIB_DEPS])
1284 AC_SUBST([GLESv2_PC_LIB_PRIV])
1285
1286 AC_SUBST([HAVE_XF86VIDMODE])
1287
1288 dnl
1289 dnl More GLX setup
1290 dnl
1291 case "x$enable_glx$enable_xlib_glx" in
1292 xyesyes)
1293     DEFINES="$DEFINES -DUSE_XSHM"
1294     ;;
1295 xyesno)
1296     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1297     if test "x$driglx_direct" = xyes; then
1298         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1299     fi
1300     ;;
1301 esac
1302
1303 dnl
1304 dnl TLS detection
1305 dnl
1306
1307 AC_ARG_ENABLE([glx-tls],
1308     [AS_HELP_STRING([--enable-glx-tls],
1309         [enable TLS support in GLX @<:@default=disabled@:>@])],
1310     [GLX_USE_TLS="$enableval"],
1311     [GLX_USE_TLS=no])
1312 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1313
1314 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1315       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1316
1317 dnl Read-only text section on x86 hardened platforms
1318 AC_ARG_ENABLE([glx-read-only-text],
1319     [AS_HELP_STRING([--enable-glx-read-only-text],
1320         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1321     [enable_glx_read_only_text="$enableval"],
1322     [enable_glx_read_only_text=no])
1323 if test "x$enable_glx_read_only_text" = xyes; then
1324     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1325 fi
1326
1327 dnl
1328 dnl More DRI setup
1329 dnl
1330 dnl Directory for DRI drivers
1331 AC_ARG_WITH([dri-driverdir],
1332     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1333         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1334     [DRI_DRIVER_INSTALL_DIR="$withval"],
1335     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1336 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1337 dnl Extra search path for DRI drivers
1338 AC_ARG_WITH([dri-searchpath],
1339     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1340         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1341     [DRI_DRIVER_SEARCH_DIR="$withval"],
1342     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1343 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1344 dnl Which drivers to build - default is chosen by platform
1345 AC_ARG_WITH([dri-drivers],
1346     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1347         [comma delimited classic DRI drivers list, e.g.
1348         "swrast,i965,radeon" @<:@default=auto@:>@])],
1349     [with_dri_drivers="$withval"],
1350     [with_dri_drivers=auto])
1351
1352 if test "x$with_dri_drivers" = xauto; then
1353     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1354         with_dri_drivers="yes"
1355     else
1356         with_dri_drivers="no"
1357     fi
1358 fi
1359 if test "x$with_dri_drivers" = xno; then
1360     with_dri_drivers=''
1361 fi
1362
1363 dnl If $with_dri_drivers is yes, drivers will be added through
1364 dnl platform checks. Set DEFINES and LIB_DEPS
1365 if test "x$enable_dri" = xyes; then
1366     # Platform specific settings and drivers to build
1367     case "$host_os" in
1368     linux*)
1369         DEFINES="$DEFINES -DHAVE_ALIAS"
1370         if test "x$enable_dri3" = xyes; then
1371             DEFINES="$DEFINES -DHAVE_DRI3"
1372         fi
1373
1374         if test "x$have_pci_id" != xyes; then
1375             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1376         fi
1377
1378         case "$host_cpu" in
1379         powerpc* | sparc*)
1380             # Build only the drivers for cards that exist on PowerPC/sparc
1381             if test "x$with_dri_drivers" = "xyes"; then
1382                 with_dri_drivers="r200 radeon swrast"
1383             fi
1384             ;;
1385         esac
1386         ;;
1387     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1388         DEFINES="$DEFINES -DHAVE_ALIAS"
1389         ;;
1390     gnu*)
1391         DEFINES="$DEFINES -DHAVE_ALIAS"
1392         ;;
1393     cygwin*)
1394         if test "x$with_dri_drivers" = "xyes"; then
1395             with_dri_drivers="swrast"
1396         fi
1397         ;;
1398     darwin*)
1399         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1400         if test "x$with_dri_drivers" = "xyes"; then
1401             with_dri_drivers="swrast"
1402         fi
1403         ;;
1404     esac
1405
1406     # default drivers
1407     if test "x$with_dri_drivers" = "xyes"; then
1408         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1409     fi
1410
1411     # Check for expat
1412     PKG_CHECK_MODULES([EXPAT], [expat], [],
1413         # expat version 2.0 and earlier do not provide expat.pc
1414         [AC_CHECK_HEADER([expat.h],[],
1415                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1416          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1417                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1418          EXPAT_LIBS="-lexpat"])
1419
1420     # put all the necessary libs together
1421     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1422 fi
1423
1424 AC_SUBST([DRI_LIB_DEPS])
1425
1426 DRI_DIRS=''
1427 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1428 if test -n "$with_dri_drivers"; then
1429     if test "x$enable_opengl" != xyes; then
1430         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1431     fi
1432
1433     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1434     for driver in $dri_drivers; do
1435         DRI_DIRS="$DRI_DIRS $driver"
1436         case "x$driver" in
1437         xi915)
1438             HAVE_I915_DRI=yes;
1439             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1440             ;;
1441         xi965)
1442             HAVE_I965_DRI=yes;
1443             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1444             ;;
1445         xnouveau)
1446             HAVE_NOUVEAU_DRI=yes;
1447             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1448             ;;
1449         xradeon)
1450             HAVE_RADEON_DRI=yes;
1451             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1452             ;;
1453         xr200)
1454             HAVE_R200_DRI=yes;
1455             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1456             ;;
1457         xswrast)
1458             HAVE_SWRAST_DRI=yes;
1459             ;;
1460         *)
1461             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1462             ;;
1463         esac
1464     done
1465     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1466 fi
1467
1468 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1469 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1470                                   "x$enable_osmesa" = xyes -o \
1471                                   -n "$DRI_DIRS")
1472
1473 dnl
1474 dnl OSMesa configuration
1475 dnl
1476
1477 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1478 AC_ARG_WITH([osmesa-bits],
1479     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1480         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1481     [osmesa_bits="$withval"],
1482     [osmesa_bits=8])
1483 if test "x$osmesa_bits" != x8; then
1484     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1485         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1486         osmesa_bits=8
1487     fi
1488 fi
1489 case "x$osmesa_bits" in
1490 x8)
1491     OSMESA_LIB="${OSMESA_LIB}"
1492     ;;
1493 x16|x32)
1494     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1495     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1496     ;;
1497 *)
1498     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1499     ;;
1500 esac
1501
1502 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1503     # only link libraries with osmesa if shared
1504     if test "$enable_static" = no; then
1505         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1506     else
1507         OSMESA_LIB_DEPS=""
1508     fi
1509     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1510 fi
1511
1512 AC_SUBST([OSMESA_LIB_DEPS])
1513 AC_SUBST([OSMESA_PC_REQ])
1514 AC_SUBST([OSMESA_PC_LIB_PRIV])
1515
1516 dnl
1517 dnl gbm configuration
1518 dnl
1519 if test "x$enable_gbm" = xauto; then
1520     case "$with_egl_platforms" in
1521         *drm*)
1522             enable_gbm=yes ;;
1523          *)
1524             enable_gbm=no ;;
1525     esac
1526 fi
1527 if test "x$enable_gbm" = xyes; then
1528     if test "x$need_pci_id$have_pci_id" = xyesno; then
1529         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1530     fi
1531
1532     if test "x$enable_dri" = xyes; then
1533         if test "x$enable_shared_glapi" = xno; then
1534             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1535         fi
1536     else
1537         # Strictly speaking libgbm does not require --enable-dri, although
1538         # both of its backends do. Thus one can build libgbm without any
1539         # backends if --disable-dri is set.
1540         # To avoid unnecessary complexity of checking if at least one backend
1541         # is available when building, just mandate --enable-dri.
1542         AC_MSG_ERROR([gbm requires --enable-dri])
1543     fi
1544 fi
1545 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1546 if test "x$need_pci_id$have_libudev" = xyesyes; then
1547     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1548 else
1549     GBM_PC_REQ_PRIV=""
1550 fi
1551 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1552 AC_SUBST([GBM_PC_REQ_PRIV])
1553 AC_SUBST([GBM_PC_LIB_PRIV])
1554
1555 dnl
1556 dnl EGL configuration
1557 dnl
1558 EGL_CLIENT_APIS=""
1559
1560 if test "x$enable_egl" = xyes; then
1561     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1562
1563     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1564
1565     if test "$enable_static" != yes; then
1566         if test "x$enable_dri" = xyes; then
1567             HAVE_EGL_DRIVER_DRI2=1
1568             if test "x$enable_shared_glapi" = xno; then
1569                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1570             fi
1571         else
1572             # Avoid building an "empty" libEGL. Drop/update this
1573             # when other backends (haiku?) come along.
1574             AC_MSG_ERROR([egl requires --enable-dri])
1575         fi
1576
1577     fi
1578 fi
1579 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1580 AC_SUBST([EGL_LIB_DEPS])
1581
1582 gallium_st="mesa"
1583
1584 dnl
1585 dnl XA configuration
1586 dnl
1587 if test "x$enable_xa" = xyes; then
1588     if test "x$with_gallium_drivers" = xswrast; then
1589        AC_MSG_ERROR([
1590           Building xa requires at least one non swrast gallium driver.
1591           If you are looking to use libxatracker.so with the VMware driver,
1592           make sure to include svga in the gallium drivers list, apart from
1593           enabling XA.
1594           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1595     fi
1596     enable_gallium_loader=$enable_shared_pipe_drivers
1597     gallium_st="$gallium_st xa"
1598 fi
1599 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1600
1601 dnl
1602 dnl Gallium G3DVL configuration
1603 dnl
1604 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1605     if test "x$enable_xvmc" = xauto; then
1606         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1607     fi
1608
1609     if test "x$enable_vdpau" = xauto; then
1610         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1611     fi
1612
1613     if test "x$enable_omx" = xauto; then
1614         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1615     fi
1616
1617     if test "x$enable_va" = xauto; then
1618         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1619     fi
1620 fi
1621
1622 if test "x$enable_dri" = xyes -o \
1623         "x$enable_xvmc" = xyes -o \
1624         "x$enable_vdpau" = xyes -o \
1625         "x$enable_omx" = xyes -o \
1626         "x$enable_va" = xyes; then
1627     need_gallium_vl=yes
1628 fi
1629 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1630
1631 if test "x$enable_xvmc" = xyes -o \
1632         "x$enable_vdpau" = xyes -o \
1633         "x$enable_omx" = xyes -o \
1634         "x$enable_va" = xyes; then
1635     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1636     need_gallium_vl_winsys=yes
1637 fi
1638 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1639
1640 if test "x$enable_xvmc" = xyes; then
1641     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1642     enable_gallium_loader=$enable_shared_pipe_drivers
1643     gallium_st="$gallium_st xvmc"
1644 fi
1645 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1646
1647 if test "x$enable_vdpau" = xyes; then
1648     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1649     enable_gallium_loader=$enable_shared_pipe_drivers
1650     gallium_st="$gallium_st vdpau"
1651 fi
1652 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1653
1654 if test "x$enable_omx" = xyes; then
1655     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1656     enable_gallium_loader=$enable_shared_pipe_drivers
1657     gallium_st="$gallium_st omx"
1658 fi
1659 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1660
1661 if test "x$enable_va" = xyes; then
1662     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1663     enable_gallium_loader=$enable_shared_pipe_drivers
1664     gallium_st="$gallium_st va"
1665 fi
1666 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1667
1668 dnl
1669 dnl Nine Direct3D9 configuration
1670 dnl
1671 if test "x$enable_nine" = xyes; then
1672     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1673         AC_MSG_ERROR([nine requires the gallium swrast driver])
1674     fi
1675     if test "x$with_gallium_drivers" = xswrast; then
1676         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1677     fi
1678     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1679         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1680     fi
1681
1682     if test "x$enable_dri3" = xno; then
1683         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1684     fi
1685
1686     enable_gallium_loader=$enable_shared_pipe_drivers
1687     gallium_st="$gallium_st nine"
1688 fi
1689 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1690
1691 dnl
1692 dnl OpenCL configuration
1693 dnl
1694
1695 AC_ARG_WITH([clang-libdir],
1696    [AS_HELP_STRING([--with-clang-libdir],
1697          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1698    [CLANG_LIBDIR="$withval"],
1699    [CLANG_LIBDIR=''])
1700
1701 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1702 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1703
1704 if test "x$enable_opencl" = xyes; then
1705     if test -z "$with_gallium_drivers"; then
1706         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1707     fi
1708
1709     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1710         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1711     fi
1712
1713     if test "x$have_libclc" = xno; then
1714         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1715                     Make sure the directory containing libclc.pc is specified in your
1716                     PKG_CONFIG_PATH environment variable.
1717                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1718     else
1719         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1720         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1721         AC_SUBST([LIBCLC_INCLUDEDIR])
1722         AC_SUBST([LIBCLC_LIBEXECDIR])
1723     fi
1724
1725     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1726     enable_gallium_loader=yes
1727     gallium_st="$gallium_st clover"
1728
1729     if test "x$enable_opencl_icd" = xyes; then
1730         OPENCL_LIBNAME="MesaOpenCL"
1731     else
1732         OPENCL_LIBNAME="OpenCL"
1733     fi
1734
1735     if test "x$have_libelf" != xyes; then
1736        AC_MSG_ERROR([Clover requires libelf])
1737     fi
1738 fi
1739 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1740 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1741 AC_SUBST([OPENCL_LIBNAME])
1742
1743 dnl
1744 dnl Gallium configuration
1745 dnl
1746 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1747
1748 AC_SUBST([LLVM_BINDIR])
1749 AC_SUBST([LLVM_CFLAGS])
1750 AC_SUBST([LLVM_CPPFLAGS])
1751 AC_SUBST([LLVM_CXXFLAGS])
1752 AC_SUBST([LLVM_LIBDIR])
1753 AC_SUBST([LLVM_LIBS])
1754 AC_SUBST([LLVM_LDFLAGS])
1755 AC_SUBST([LLVM_INCLUDEDIR])
1756 AC_SUBST([LLVM_VERSION])
1757 AC_SUBST([CLANG_RESOURCE_DIR])
1758
1759 case "x$enable_opengl$enable_gles1$enable_gles2" in
1760 x*yes*)
1761     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1762     ;;
1763 esac
1764
1765 AC_SUBST([VG_LIB_DEPS])
1766 AC_SUBST([EGL_CLIENT_APIS])
1767
1768 dnl
1769 dnl EGL Platforms configuration
1770 dnl
1771 AC_ARG_WITH([egl-platforms],
1772     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1773         [comma delimited native platforms libEGL supports, e.g.
1774         "x11,drm" @<:@default=auto@:>@])],
1775     [with_egl_platforms="$withval"],
1776     [if test "x$enable_egl" = xyes; then
1777         with_egl_platforms="x11"
1778     else
1779         with_egl_platforms=""
1780     fi])
1781
1782 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1783     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1784 fi
1785
1786 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1787         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1788         WAYLAND_SCANNER='')
1789 if test "x$WAYLAND_SCANNER" = x; then
1790     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1791 fi
1792
1793 # Do per-EGL platform setups and checks
1794 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1795 for plat in $egl_platforms; do
1796         case "$plat" in
1797         wayland)
1798                 test "x$have_libdrm" != xyes &&
1799                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1800
1801                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1802
1803                 if test "x$WAYLAND_SCANNER" = x; then
1804                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1805                 fi
1806                 ;;
1807
1808         x11)
1809                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1810                 ;;
1811
1812         drm)
1813                 test "x$enable_gbm" = "xno" &&
1814                         AC_MSG_ERROR([EGL platform drm needs gbm])
1815                 test "x$have_libdrm" != xyes &&
1816                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1817                 ;;
1818
1819         surfaceless)
1820                 test "x$have_libdrm" != xyes &&
1821                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1822                 ;;
1823
1824         *)
1825                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1826                 ;;
1827         esac
1828
1829         case "$plat$need_pci_id$have_pci_id" in
1830                 waylandyesno|drmyesno)
1831                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1832         esac
1833 done
1834
1835 # libEGL wants to default to the first platform specified in
1836 # ./configure.  parse that here.
1837 if test "x$egl_platforms" != "x"; then
1838     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1839     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1840 else
1841     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1842 fi
1843
1844 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1845 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1846 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1847 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1848 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1849
1850 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1851
1852 AC_SUBST([EGL_NATIVE_PLATFORM])
1853 AC_SUBST([EGL_CFLAGS])
1854
1855 # If we don't have the X11 platform, set this define so we don't try to include
1856 # the X11 headers.
1857 if ! echo "$egl_platforms" | grep -q 'x11'; then
1858     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1859     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1860 fi
1861
1862 dnl
1863 dnl Gallium LLVM
1864 dnl
1865 AC_ARG_ENABLE([gallium-llvm],
1866     [AS_HELP_STRING([--enable-gallium-llvm],
1867         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1868     [enable_gallium_llvm="$enableval"],
1869     [enable_gallium_llvm=auto])
1870
1871 AC_ARG_ENABLE([llvm-shared-libs],
1872     [AS_HELP_STRING([--enable-llvm-shared-libs],
1873         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1874     [enable_llvm_shared_libs="$enableval"],
1875     [enable_llvm_shared_libs=yes])
1876
1877 AC_ARG_WITH([llvm-prefix],
1878     [AS_HELP_STRING([--with-llvm-prefix],
1879         [Prefix for LLVM installations in non-standard locations])],
1880     [llvm_prefix="$withval"],
1881     [llvm_prefix=''])
1882
1883
1884 # Call this inside ` ` to get the return value.
1885 # $1 is the llvm-config command with arguments.
1886 strip_unwanted_llvm_flags() {
1887     # Use \> (marks the end of the word)
1888     echo `$1` | sed \
1889         -e 's/-DNDEBUG\>//g' \
1890         -e 's/-D_GNU_SOURCE\>//g' \
1891         -e 's/-pedantic\>//g' \
1892         -e 's/-Wcovered-switch-default\>//g' \
1893         -e 's/-O.\>//g' \
1894         -e 's/-g\>//g' \
1895         -e 's/-Wall\>//g' \
1896         -e 's/-Wcast-qual\>//g' \
1897         -e 's/-Woverloaded-virtual\>//g' \
1898         -e 's/-fcolor-diagnostics\>//g' \
1899         -e 's/-fdata-sections\>//g' \
1900         -e 's/-ffunction-sections\>//g' \
1901         -e 's/-fno-exceptions\>//g' \
1902         -e 's/-fomit-frame-pointer\>//g' \
1903         -e 's/-fvisibility-inlines-hidden\>//g' \
1904         -e 's/-fPIC\>//g' \
1905         -e 's/-fstack-protector-strong\>//g'
1906 }
1907
1908 llvm_check_version_for() {
1909     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1910         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1911     fi
1912 }
1913
1914
1915
1916 if test -z "$with_gallium_drivers"; then
1917     enable_gallium_llvm=no
1918 fi
1919 if test "x$enable_gallium_llvm" = xauto; then
1920     case "$host_cpu" in
1921     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1922     esac
1923 fi
1924 if test "x$enable_gallium_llvm" = xyes; then
1925     if test -n "$llvm_prefix"; then
1926         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1927     else
1928         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1929     fi
1930
1931     if test "x$LLVM_CONFIG" != xno; then
1932         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1933         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1934         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1935         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1936         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1937         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1938         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1939         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1940
1941         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1942             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1943         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1944             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1945
1946         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1947         if test -z "$LLVM_VERSION_PATCH"; then
1948             LLVM_VERSION_PATCH=0
1949         fi
1950
1951         if test -n "${LLVM_VERSION_MAJOR}"; then
1952             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1953         else
1954             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1955         fi
1956
1957         LLVM_REQUIRED_VERSION_MAJOR="3"
1958         LLVM_REQUIRED_VERSION_MINOR="3"
1959         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1960             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1961         fi
1962
1963         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1964
1965         if test "x$enable_opencl" = xyes; then
1966             llvm_check_version_for "3" "5" "0" "opencl"
1967
1968             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1969             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1970         fi
1971         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1972         MESA_LLVM=1
1973
1974         dnl Check for Clang internal headers
1975         if test "x$enable_opencl" = xyes; then
1976             if test -z "$CLANG_LIBDIR"; then
1977                 CLANG_LIBDIR=${LLVM_LIBDIR}
1978             fi
1979             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1980             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1981                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1982         fi
1983     else
1984         MESA_LLVM=0
1985         LLVM_VERSION_INT=0
1986     fi
1987 else
1988     MESA_LLVM=0
1989     LLVM_VERSION_INT=0
1990
1991     if test "x$enable_opencl" = xyes; then
1992         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1993     fi
1994 fi
1995
1996 dnl Directory for XVMC libs
1997 AC_ARG_WITH([xvmc-libdir],
1998     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1999         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2000     [XVMC_LIB_INSTALL_DIR="$withval"],
2001     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2002 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2003
2004 dnl
2005 dnl Gallium Tests
2006 dnl
2007 if test "x$enable_gallium_tests" = xyes; then
2008     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
2009     enable_gallium_loader=yes
2010 fi
2011 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2012
2013 dnl Directory for VDPAU libs
2014 AC_ARG_WITH([vdpau-libdir],
2015     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2016         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2017     [VDPAU_LIB_INSTALL_DIR="$withval"],
2018     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2019 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2020
2021 dnl Directory for OMX libs
2022
2023 AC_ARG_WITH([omx-libdir],
2024     [AS_HELP_STRING([--with-omx-libdir=DIR],
2025         [directory for the OMX libraries])],
2026     [OMX_LIB_INSTALL_DIR="$withval"],
2027     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2028 AC_SUBST([OMX_LIB_INSTALL_DIR])
2029
2030 dnl Directory for VA libs
2031
2032 AC_ARG_WITH([va-libdir],
2033     [AS_HELP_STRING([--with-va-libdir=DIR],
2034         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2035     [VA_LIB_INSTALL_DIR="$withval"],
2036     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2037 AC_SUBST([VA_LIB_INSTALL_DIR])
2038
2039 AC_ARG_WITH([d3d-libdir],
2040     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2041         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2042     [D3D_DRIVER_INSTALL_DIR="$withval"],
2043     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2044 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2045
2046 dnl
2047 dnl Gallium helper functions
2048 dnl
2049 gallium_require_drm() {
2050     if test "x$have_libdrm" != xyes; then
2051        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2052     fi
2053 }
2054
2055 gallium_require_llvm() {
2056     if test "x$MESA_LLVM" = x0; then
2057         case "$host" in *gnux32) return;; esac
2058         case "$host_cpu" in
2059         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2060         esac
2061     fi
2062 }
2063
2064 gallium_require_drm_loader() {
2065     if test "x$enable_gallium_loader" = xyes; then
2066         if test "x$need_pci_id$have_pci_id" = xyesno; then
2067             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2068         fi
2069         enable_gallium_drm_loader=yes
2070     fi
2071     if test "x$enable_va" = xyes && test "x$7" != x; then
2072          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2073     fi
2074 }
2075
2076 require_egl_drm() {
2077     case "$with_egl_platforms" in
2078         *drm*)
2079             ;;
2080          *)
2081             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2082             ;;
2083     esac
2084     if test "x$enable_gbm" != xyes; then
2085             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2086     fi
2087 }
2088
2089 radeon_llvm_check() {
2090     if test ${LLVM_VERSION_INT} -lt 307; then
2091         amdgpu_llvm_target_name='r600'
2092     else
2093         amdgpu_llvm_target_name='amdgpu'
2094     fi
2095     if test "x$enable_gallium_llvm" != "xyes"; then
2096         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2097     fi
2098     llvm_check_version_for "3" "5" "0" $1
2099     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2100         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2101     fi
2102     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2103     NEED_RADEON_LLVM=yes
2104     if test "x$have_libelf" != xyes; then
2105        AC_MSG_ERROR([$1 requires libelf when using llvm])
2106     fi
2107 }
2108
2109 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2110 if test -n "$with_gallium_drivers"; then
2111     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2112     for driver in $gallium_drivers; do
2113         case "x$driver" in
2114         xsvga)
2115             HAVE_GALLIUM_SVGA=yes
2116             gallium_require_drm "svga"
2117             gallium_require_drm_loader
2118             ;;
2119         xi915)
2120             HAVE_GALLIUM_I915=yes
2121             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2122             gallium_require_drm "Gallium i915"
2123             gallium_require_drm_loader
2124             ;;
2125         xilo)
2126             HAVE_GALLIUM_ILO=yes
2127             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2128             gallium_require_drm "Gallium i965/ilo"
2129             gallium_require_drm_loader
2130             ;;
2131         xr300)
2132             HAVE_GALLIUM_R300=yes
2133             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2134             gallium_require_drm "Gallium R300"
2135             gallium_require_drm_loader
2136             gallium_require_llvm "Gallium R300"
2137             ;;
2138         xr600)
2139             HAVE_GALLIUM_R600=yes
2140             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2141             gallium_require_drm "Gallium R600"
2142             gallium_require_drm_loader
2143             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2144                 radeon_llvm_check "r600g"
2145                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2146             fi
2147             if test "x$enable_r600_llvm" = xyes; then
2148                 USE_R600_LLVM_COMPILER=yes;
2149             fi
2150             if test "x$enable_opencl" = xyes; then
2151                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2152             fi
2153             ;;
2154         xradeonsi)
2155             HAVE_GALLIUM_RADEONSI=yes
2156             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2157             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2158             gallium_require_drm "radeonsi"
2159             gallium_require_drm_loader
2160             radeon_llvm_check "radeonsi"
2161             require_egl_drm "radeonsi"
2162             ;;
2163         xnouveau)
2164             HAVE_GALLIUM_NOUVEAU=yes
2165             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2166             gallium_require_drm "nouveau"
2167             gallium_require_drm_loader
2168             ;;
2169         xfreedreno)
2170             HAVE_GALLIUM_FREEDRENO=yes
2171             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2172             gallium_require_drm "freedreno"
2173             gallium_require_drm_loader
2174             ;;
2175         xswrast)
2176             HAVE_GALLIUM_SOFTPIPE=yes
2177             if test "x$MESA_LLVM" = x1; then
2178                 HAVE_GALLIUM_LLVMPIPE=yes
2179             fi
2180             ;;
2181         xvc4)
2182             HAVE_GALLIUM_VC4=yes
2183             gallium_require_drm "vc4"
2184             gallium_require_drm_loader
2185
2186             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2187                               [USE_VC4_SIMULATOR=yes], [USE_VC4_SIMULATOR=no])
2188             ;;
2189         xvirgl)
2190             HAVE_GALLIUM_VIRGL=yes
2191             gallium_require_drm "virgl"
2192             gallium_require_drm_loader
2193             require_egl_drm "virgl"
2194             ;;
2195         *)
2196             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2197             ;;
2198         esac
2199     done
2200 fi
2201
2202 dnl Set LLVM_LIBS - This is done after the driver configuration so
2203 dnl that drivers can add additional components to LLVM_COMPONENTS.
2204 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2205 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2206 dnl this was causing the same libraries to be appear multiple times
2207 dnl in LLVM_LIBS.
2208
2209 if test "x$MESA_LLVM" != x0; then
2210
2211     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2212
2213     dnl llvm-config may not give the right answer when llvm is a built as a
2214     dnl single shared library, so we must work the library name out for
2215     dnl ourselves.
2216     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2217     if test "x$enable_llvm_shared_libs" = xyes; then
2218         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2219         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2220         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2221
2222         if test "x$llvm_have_one_so" = xyes; then
2223             dnl LLVM was built using auto*, so there is only one shared object.
2224             LLVM_LIBS="-l$LLVM_SO_NAME"
2225         else
2226             dnl If LLVM was built with CMake, there will be one shared object per
2227             dnl component.
2228             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2229                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2230         Please make sure you have built llvm with the --enable-shared option
2231         and that your llvm libraries are installed in $LLVM_LIBDIR
2232         If you have installed your llvm libraries to a different directory you
2233         can use the --with-llvm-prefix= configure flag to specify this directory.
2234         NOTE: Mesa is attempting to use llvm shared libraries by default.
2235         If you do not want to build with llvm shared libraries and instead want to
2236         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2237         invocation and rebuild.])])
2238
2239            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2240            dnl install uses a shared object for each component and we have
2241            dnl already added all of these objects to LLVM_LIBS.
2242         fi
2243     else
2244         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2245         dnl We need to link to llvm system libs when using static libs
2246         dnl However, only llvm 3.5+ provides --system-libs
2247         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2248             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2249         fi
2250     fi
2251 fi
2252
2253 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2254 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2255 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2256 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2257 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2258 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2259 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2260                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2261 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2262 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2263 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2264 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2265 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2266 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2267
2268 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2269
2270 # NOTE: anything using xcb or other client side libs ends up in separate
2271 #       _CLIENT variables.  The pipe loader is built in two variants,
2272 #       one that is standalone and does not link any x client libs (for
2273 #       use by XA tracker in particular, but could be used in any case
2274 #       where communication with xserver is not desired).
2275 if test "x$enable_gallium_loader" = xyes; then
2276     if test "x$enable_dri" = xyes; then
2277         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2278     fi
2279
2280     if test "x$enable_gallium_drm_loader" = xyes; then
2281         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2282     fi
2283
2284     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2285 fi
2286
2287 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2288 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2289 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2290 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2291 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2292 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2293
2294 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2295                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2296                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2297 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2298 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2299 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2300 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2301 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2302 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2303 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2304 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2305 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2306     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2307 fi
2308
2309 AC_SUBST([ELF_LIB])
2310
2311 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2312 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2313 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2314 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2315
2316 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2317 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2318 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2319
2320 AC_SUBST([NINE_MAJOR], 1)
2321 AC_SUBST([NINE_MINOR], 0)
2322 AC_SUBST([NINE_TINY], 0)
2323 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2324
2325 AC_SUBST([VDPAU_MAJOR], 1)
2326 AC_SUBST([VDPAU_MINOR], 0)
2327
2328 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2329 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2330 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2331 AC_SUBST([VA_MINOR], $VA_MINOR)
2332
2333 AC_SUBST([XVMC_MAJOR], 1)
2334 AC_SUBST([XVMC_MINOR], 0)
2335
2336 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2337 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2338 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2339 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2340
2341 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2342 AC_SUBST([XA_MINOR], $XA_MINOR)
2343 AC_SUBST([XA_TINY], $XA_TINY)
2344 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2345
2346 dnl Restore LDFLAGS and CPPFLAGS
2347 LDFLAGS="$_SAVE_LDFLAGS"
2348 CPPFLAGS="$_SAVE_CPPFLAGS"
2349
2350 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2351 if test "x$acv_mesa_CLANG" = xyes; then
2352     CFLAGS="$CFLAGS -Qunused-arguments"
2353     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2354 fi
2355
2356 dnl Add user CFLAGS and CXXFLAGS
2357 CFLAGS="$CFLAGS $USER_CFLAGS"
2358 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2359
2360 dnl Substitute the config
2361 AC_CONFIG_FILES([Makefile
2362                 src/Makefile
2363                 src/egl/Makefile
2364                 src/egl/main/egl.pc
2365                 src/egl/wayland/wayland-drm/Makefile
2366                 src/egl/wayland/wayland-egl/Makefile
2367                 src/egl/wayland/wayland-egl/wayland-egl.pc
2368                 src/gallium/Makefile
2369                 src/gallium/auxiliary/Makefile
2370                 src/gallium/auxiliary/pipe-loader/Makefile
2371                 src/gallium/drivers/freedreno/Makefile
2372                 src/gallium/drivers/ddebug/Makefile
2373                 src/gallium/drivers/i915/Makefile
2374                 src/gallium/drivers/ilo/Makefile
2375                 src/gallium/drivers/llvmpipe/Makefile
2376                 src/gallium/drivers/noop/Makefile
2377                 src/gallium/drivers/nouveau/Makefile
2378                 src/gallium/drivers/r300/Makefile
2379                 src/gallium/drivers/r600/Makefile
2380                 src/gallium/drivers/radeon/Makefile
2381                 src/gallium/drivers/radeonsi/Makefile
2382                 src/gallium/drivers/rbug/Makefile
2383                 src/gallium/drivers/softpipe/Makefile
2384                 src/gallium/drivers/svga/Makefile
2385                 src/gallium/drivers/trace/Makefile
2386                 src/gallium/drivers/vc4/Makefile
2387                 src/gallium/drivers/virgl/Makefile
2388                 src/gallium/state_trackers/clover/Makefile
2389                 src/gallium/state_trackers/dri/Makefile
2390                 src/gallium/state_trackers/glx/xlib/Makefile
2391                 src/gallium/state_trackers/nine/Makefile
2392                 src/gallium/state_trackers/omx/Makefile
2393                 src/gallium/state_trackers/osmesa/Makefile
2394                 src/gallium/state_trackers/va/Makefile
2395                 src/gallium/state_trackers/vdpau/Makefile
2396                 src/gallium/state_trackers/xa/Makefile
2397                 src/gallium/state_trackers/xvmc/Makefile
2398                 src/gallium/targets/d3dadapter9/Makefile
2399                 src/gallium/targets/d3dadapter9/d3d.pc
2400                 src/gallium/targets/dri/Makefile
2401                 src/gallium/targets/libgl-xlib/Makefile
2402                 src/gallium/targets/omx/Makefile
2403                 src/gallium/targets/opencl/Makefile
2404                 src/gallium/targets/opencl/mesa.icd
2405                 src/gallium/targets/osmesa/Makefile
2406                 src/gallium/targets/osmesa/osmesa.pc
2407                 src/gallium/targets/pipe-loader/Makefile
2408                 src/gallium/targets/va/Makefile
2409                 src/gallium/targets/vdpau/Makefile
2410                 src/gallium/targets/xa/Makefile
2411                 src/gallium/targets/xa/xatracker.pc
2412                 src/gallium/targets/xvmc/Makefile
2413                 src/gallium/tests/trivial/Makefile
2414                 src/gallium/tests/unit/Makefile
2415                 src/gallium/winsys/freedreno/drm/Makefile
2416                 src/gallium/winsys/i915/drm/Makefile
2417                 src/gallium/winsys/intel/drm/Makefile
2418                 src/gallium/winsys/nouveau/drm/Makefile
2419                 src/gallium/winsys/radeon/drm/Makefile
2420                 src/gallium/winsys/amdgpu/drm/Makefile
2421                 src/gallium/winsys/svga/drm/Makefile
2422                 src/gallium/winsys/sw/dri/Makefile
2423                 src/gallium/winsys/sw/kms-dri/Makefile
2424                 src/gallium/winsys/sw/null/Makefile
2425                 src/gallium/winsys/sw/wrapper/Makefile
2426                 src/gallium/winsys/sw/xlib/Makefile
2427                 src/gallium/winsys/vc4/drm/Makefile
2428                 src/gallium/winsys/virgl/drm/Makefile
2429                 src/gallium/winsys/virgl/vtest/Makefile
2430                 src/gbm/Makefile
2431                 src/gbm/main/gbm.pc
2432                 src/glsl/Makefile
2433                 src/glx/Makefile
2434                 src/glx/apple/Makefile
2435                 src/glx/tests/Makefile
2436                 src/gtest/Makefile
2437                 src/loader/Makefile
2438                 src/mapi/Makefile
2439                 src/mapi/es1api/glesv1_cm.pc
2440                 src/mapi/es2api/glesv2.pc
2441                 src/mapi/glapi/gen/Makefile
2442                 src/mesa/Makefile
2443                 src/mesa/gl.pc
2444                 src/mesa/drivers/dri/dri.pc
2445                 src/mesa/drivers/dri/common/Makefile
2446                 src/mesa/drivers/dri/common/xmlpool/Makefile
2447                 src/mesa/drivers/dri/i915/Makefile
2448                 src/mesa/drivers/dri/i965/Makefile
2449                 src/mesa/drivers/dri/Makefile
2450                 src/mesa/drivers/dri/nouveau/Makefile
2451                 src/mesa/drivers/dri/r200/Makefile
2452                 src/mesa/drivers/dri/radeon/Makefile
2453                 src/mesa/drivers/dri/swrast/Makefile
2454                 src/mesa/drivers/osmesa/Makefile
2455                 src/mesa/drivers/osmesa/osmesa.pc
2456                 src/mesa/drivers/x11/Makefile
2457                 src/mesa/main/tests/Makefile
2458                 src/util/Makefile
2459                 src/util/tests/hash_table/Makefile])
2460
2461 AC_OUTPUT
2462
2463 dnl
2464 dnl Output some configuration info for the user
2465 dnl
2466 echo ""
2467 echo "        prefix:          $prefix"
2468 echo "        exec_prefix:     $exec_prefix"
2469 echo "        libdir:          $libdir"
2470 echo "        includedir:      $includedir"
2471
2472 dnl API info
2473 echo ""
2474 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2475
2476 dnl Driver info
2477 echo ""
2478 case "x$enable_osmesa$enable_gallium_osmesa" in
2479 xnoyes)
2480         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2481         ;;
2482 xyesno)
2483         echo "        OSMesa:          lib$OSMESA_LIB"
2484         ;;
2485 xnono)
2486         echo "        OSMesa:          no"
2487         ;;
2488 esac
2489
2490 echo ""
2491 if test "x$enable_dri" != xno; then
2492         echo "        DRI platform:    $dri_platform"
2493         if test -z "$DRI_DIRS"; then
2494             echo "        DRI drivers:     no"
2495         else
2496             echo "        DRI drivers:     $DRI_DIRS"
2497         fi
2498         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2499 fi
2500
2501 case "x$enable_glx$enable_xlib_glx" in
2502 xyesyes)
2503     echo "        GLX:             Xlib-based"
2504     ;;
2505 xyesno)
2506     echo "        GLX:             DRI-based"
2507     ;;
2508 *)
2509     echo "        GLX:             $enable_glx"
2510     ;;
2511 esac
2512
2513 dnl EGL
2514 echo ""
2515 echo "        EGL:             $enable_egl"
2516 if test "$enable_egl" = yes; then
2517     echo "        EGL platforms:   $egl_platforms"
2518
2519     egl_drivers=""
2520     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2521         egl_drivers="$egl_drivers builtin:egl_dri2"
2522     fi
2523
2524     echo "        EGL drivers:    $egl_drivers"
2525 fi
2526
2527 echo ""
2528 if test "x$MESA_LLVM" = x1; then
2529     echo "        llvm:            yes"
2530     echo "        llvm-config:     $LLVM_CONFIG"
2531     echo "        llvm-version:    $LLVM_VERSION"
2532 else
2533     echo "        llvm:            no"
2534 fi
2535
2536 echo ""
2537 if test -n "$with_gallium_drivers"; then
2538     echo "        Gallium drivers: $gallium_drivers"
2539     echo "        Gallium st:      $gallium_st"
2540 else
2541     echo "        Gallium:         no"
2542 fi
2543
2544 dnl Shader cache
2545 echo ""
2546 echo "        Shader cache:    $enable_shader_cache"
2547 if test "x$enable_shader_cache" = "xyes"; then
2548     echo "        With SHA1 from:  $with_sha1"
2549 fi
2550
2551 dnl Libraries
2552 echo ""
2553 echo "        Shared libs:     $enable_shared"
2554 echo "        Static libs:     $enable_static"
2555 echo "        Shared-glapi:    $enable_shared_glapi"
2556
2557 dnl Compiler options
2558 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2559 cflags=`echo $CFLAGS | \
2560     $SED 's/^ *//;s/  */ /;s/ *$//'`
2561 cxxflags=`echo $CXXFLAGS | \
2562     $SED 's/^ *//;s/  */ /;s/ *$//'`
2563 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2564 echo ""
2565 echo "        CFLAGS:          $cflags"
2566 echo "        CXXFLAGS:        $cxxflags"
2567 echo "        Macros:          $defines"
2568 echo ""
2569 if test "x$MESA_LLVM" = x1; then
2570     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2571     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2572     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2573     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2574     echo ""
2575 fi
2576 echo "        PYTHON2:         $PYTHON2"
2577
2578 echo ""
2579 echo "        Run '${MAKE-make}' to build Mesa"
2580 echo ""