configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.81
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840 dnl According to the manual when using pthreads, one should add -pthread to
 841 dnl both compile and link-time arguments.
 842 dnl In practise that should be sufficient for all platforms, since any
 843 dnl platforms build with GCC and Clang support the flag.
 844 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 845
 846 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 847 dnl project. Even then there's a notable issue as described in the project README
 848 case "$host_os" in
 849 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 850     pthread_stubs_possible="no"
 851     ;;
 852 * )
 853     pthread_stubs_possible="yes"
 854     ;;
 855 esac
 856
 857 if test "x$pthread_stubs_possible" = xyes; then
 858     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 859 fi
 860
 861 dnl SELinux awareness.
 862 AC_ARG_ENABLE([selinux],
 863     [AS_HELP_STRING([--enable-selinux],
 864         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 865     [MESA_SELINUX="$enableval"],
 866     [MESA_SELINUX=no])
 867 if test "x$enable_selinux" = "xyes"; then
 868     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 869         [AC_CHECK_HEADER([selinux/selinux.h],[],
 870                          [AC_MSG_ERROR([SELinux headers not found])])
 871          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 872                       [AC_MSG_ERROR([SELinux library not found])])
 873          SELINUX_LIBS="-lselinux"])
 874     DEFINES="$DEFINES -DMESA_SELINUX"
 875 fi
 876 AC_SUBST([SELINUX_CFLAGS])
 877 AC_SUBST([SELINUX_LIBS])
 878
 879 dnl
 880 dnl LLVM
 881 dnl
 882 AC_ARG_ENABLE([llvm-shared-libs],
 883     [AS_HELP_STRING([--enable-llvm-shared-libs],
 884         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 885     [enable_llvm_shared_libs="$enableval"],
 886     [enable_llvm_shared_libs=yes])
 887
 888 AC_ARG_WITH([llvm-prefix],
 889     [AS_HELP_STRING([--with-llvm-prefix],
 890         [Prefix for LLVM installations in non-standard locations])],
 891     [llvm_prefix="$withval"],
 892     [llvm_prefix=''])
 893
 894 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 895 if test "x$have_libelf" = xno; then
 896    LIBELF_LIBS=''
 897    LIBELF_CFLAGS=''
 898    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 899    AC_SUBST([LIBELF_LIBS])
 900    AC_SUBST([LIBELF_CFLAGS])
 901 fi
 902
 903 if test -z "$LLVM_CONFIG"; then
 904     if test -n "$llvm_prefix"; then
 905         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 906     else
 907         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 908     fi
 909 fi
 910
 911 llvm_add_component() {
 912     new_llvm_component=$1
 913     driver_name=$2
 914
 915     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 916         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 917     else
 918         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 919     fi
 920 }
 921
 922 llvm_add_default_components() {
 923     driver_name=$1
 924
 925     # Required default components
 926     llvm_add_component "bitwriter" $driver_name
 927     llvm_add_component "engine" $driver_name
 928     llvm_add_component "mcdisassembler" $driver_name
 929     llvm_add_component "mcjit" $driver_name
 930
 931     # Optional default components
 932     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 933         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 934     fi
 935 }
 936
 937 llvm_add_target() {
 938     new_llvm_target=$1
 939     driver_name=$2
 940
 941     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 942         llvm_add_component $new_llvm_target $driver_name
 943     else
 944         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 945     fi
 946 }
 947
 948 # Call this inside ` ` to get the return value.
 949 # $1 is the llvm-config command with arguments.
 950 strip_unwanted_llvm_flags() {
 951     echo " `$1` " | sed -E \
 952         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 953         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 954         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 955         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 956         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 957         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 958         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 959         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 960         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 961         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 962         -e 's/^[[[:space:]]]//' \
 963         -e 's/[[[:space:]]]$//'
 964 }
 965
 966 llvm_set_environment_variables() {
 967     if test "x$LLVM_CONFIG" != xno; then
 968         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 969         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 970         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 971         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 972
 973         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 974         save_CFLAGS="$CFLAGS"
 975         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 976
 977         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 978             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 979         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 980             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 981         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 982             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 983
 984         CFLAGS="$save_CFLAGS"
 985
 986         # Only needed for LLVM < 3.6.0
 987         if test -z "$LLVM_VERSION_PATCH"; then
 988             LLVM_VERSION_PATCH=0
 989         fi
 990
 991         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 992
 993         FOUND_LLVM=yes
 994     else
 995         FOUND_LLVM=no
 996         LLVM_VERSION_INT=0
 997     fi
 998 }
 999
1000 require_llvm() {
1001     if test "x$enable_llvm" != "xyes"; then
1002         AC_MSG_ERROR([--enable-llvm is required when building $1])
1003     fi
1004 }
1005
1006 llvm_require_version() {
1007     require_llvm $2
1008
1009     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1010     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1011     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1012
1013     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1014         # major > required major
1015         #  --> OK
1016         return
1017     fi
1018
1019     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1020         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1021             # major = required major and
1022             # minor > required minor
1023             #  --> OK
1024             return
1025         else
1026             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1027                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1028                     # major = required major and
1029                     # minor = required minor and
1030                     # patch >= required patch
1031                     #  --> OK
1032                     return
1033                 fi
1034             fi
1035         fi
1036     fi
1037
1038     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1039 }
1040
1041 radeon_llvm_check() {
1042     if test ${LLVM_VERSION_INT} -lt 307; then
1043         amdgpu_llvm_target_name='r600'
1044     else
1045         amdgpu_llvm_target_name='amdgpu'
1046     fi
1047
1048     llvm_require_version $*
1049
1050     llvm_add_target $amdgpu_llvm_target_name $2
1051
1052     llvm_add_default_components $2
1053     llvm_add_component "bitreader" $2
1054     llvm_add_component "ipo" $2
1055
1056     if test "x$have_libelf" != xyes; then
1057        AC_MSG_ERROR([$2 requires libelf when using llvm])
1058     fi
1059 }
1060
1061 llvm_set_environment_variables
1062
1063 AC_SUBST([LLVM_CFLAGS])
1064 AC_SUBST([LLVM_CXXFLAGS])
1065 AC_SUBST([LLVM_LIBS])
1066 AC_SUBST([LLVM_LDFLAGS])
1067 AC_SUBST([LLVM_INCLUDEDIR])
1068
1069 dnl
1070 dnl libunwind
1071 dnl
1072 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1073 AC_ARG_ENABLE([libunwind],
1074     [AS_HELP_STRING([--enable-libunwind],
1075             [Use libunwind for backtracing (default: auto)])],
1076         [LIBUNWIND="$enableval"],
1077         [LIBUNWIND="$HAVE_LIBUNWIND"])
1078
1079 if test "x$LIBUNWIND" = "xyes"; then
1080     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1081     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1082 fi
1083
1084
1085 dnl Options for APIs
1086 AC_ARG_ENABLE([opengl],
1087     [AS_HELP_STRING([--disable-opengl],
1088         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1089     [enable_opengl="$enableval"],
1090     [enable_opengl=yes])
1091 AC_ARG_ENABLE([gles1],
1092     [AS_HELP_STRING([--disable-gles1],
1093         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1094     [enable_gles1="$enableval"],
1095     [enable_gles1=yes])
1096 AC_ARG_ENABLE([gles2],
1097     [AS_HELP_STRING([--disable-gles2],
1098         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1099     [enable_gles2="$enableval"],
1100     [enable_gles2=yes])
1101
1102 AC_ARG_ENABLE([dri],
1103     [AS_HELP_STRING([--enable-dri],
1104         [enable DRI modules @<:@default=enabled@:>@])],
1105     [enable_dri="$enableval"],
1106     [enable_dri=yes])
1107
1108 AC_ARG_ENABLE([gallium-extra-hud],
1109     [AS_HELP_STRING([--enable-gallium-extra-hud],
1110         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1111     [enable_gallium_extra_hud="$enableval"],
1112     [enable_gallium_extra_hud=no])
1113 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1114 if test "x$enable_gallium_extra_hud" = xyes ; then
1115     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1116 fi
1117
1118 #TODO: no pkgconfig .pc available for libsensors.
1119 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1120 AC_ARG_ENABLE([lmsensors],
1121     [AS_HELP_STRING([--enable-lmsensors],
1122         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1123     [enable_lmsensors="$enableval"],
1124     [enable_lmsensors=no])
1125 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1126 if test "x$enable_lmsensors" = xyes ; then
1127     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1128     LIBSENSORS_LIBS="-lsensors"
1129 else
1130     LIBSENSORS_LIBS=""
1131 fi
1132 AC_SUBST(LIBSENSORS_LIBS)
1133
1134 case "$host_os" in
1135 linux*)
1136     dri3_default=yes
1137     ;;
1138 *)
1139     dri3_default=no
1140     ;;
1141 esac
1142
1143 if test "x$enable_dri" = xno; then
1144     dri3_default=no
1145 fi
1146
1147 AC_ARG_ENABLE([dri3],
1148     [AS_HELP_STRING([--enable-dri3],
1149         [enable DRI3 @<:@default=auto@:>@])],
1150     [enable_dri3="$enableval"],
1151     [enable_dri3="$dri3_default"])
1152 AC_ARG_ENABLE([glx],
1153     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1154         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1155     [enable_glx="$enableval"],
1156     [enable_glx=yes])
1157 AC_ARG_ENABLE([osmesa],
1158     [AS_HELP_STRING([--enable-osmesa],
1159         [enable OSMesa library @<:@default=disabled@:>@])],
1160     [enable_osmesa="$enableval"],
1161     [enable_osmesa=no])
1162 AC_ARG_ENABLE([gallium-osmesa],
1163     [AS_HELP_STRING([--enable-gallium-osmesa],
1164         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1165     [enable_gallium_osmesa="$enableval"],
1166     [enable_gallium_osmesa=no])
1167 AC_ARG_ENABLE([egl],
1168     [AS_HELP_STRING([--disable-egl],
1169         [disable EGL library @<:@default=enabled@:>@])],
1170     [enable_egl="$enableval"],
1171     [enable_egl=yes])
1172
1173 AC_ARG_ENABLE([xa],
1174     [AS_HELP_STRING([--enable-xa],
1175         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1176     [enable_xa="$enableval"],
1177     [enable_xa=no])
1178 AC_ARG_ENABLE([gbm],
1179    [AS_HELP_STRING([--enable-gbm],
1180          [enable gbm library @<:@default=yes except cygwin@:>@])],
1181    [enable_gbm="$enableval"],
1182    [case "$host_os" in
1183        cygwin*)
1184           enable_gbm=no
1185           ;;
1186        *)
1187           enable_gbm=yes
1188           ;;
1189     esac])
1190 AC_ARG_ENABLE([nine],
1191     [AS_HELP_STRING([--enable-nine],
1192         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1193     [enable_nine="$enableval"],
1194     [enable_nine=no])
1195
1196 AC_ARG_ENABLE([xvmc],
1197    [AS_HELP_STRING([--enable-xvmc],
1198          [enable xvmc library @<:@default=auto@:>@])],
1199    [enable_xvmc="$enableval"],
1200    [enable_xvmc=auto])
1201 AC_ARG_ENABLE([vdpau],
1202    [AS_HELP_STRING([--enable-vdpau],
1203          [enable vdpau library @<:@default=auto@:>@])],
1204    [enable_vdpau="$enableval"],
1205    [enable_vdpau=auto])
1206 AC_ARG_ENABLE([omx],
1207    [AS_HELP_STRING([--enable-omx],
1208          [enable OpenMAX library @<:@default=disabled@:>@])],
1209    [enable_omx="$enableval"],
1210    [enable_omx=no])
1211 AC_ARG_ENABLE([va],
1212    [AS_HELP_STRING([--enable-va],
1213          [enable va library @<:@default=auto@:>@])],
1214    [enable_va="$enableval"],
1215    [enable_va=auto])
1216 AC_ARG_ENABLE([opencl],
1217    [AS_HELP_STRING([--enable-opencl],
1218          [enable OpenCL library @<:@default=disabled@:>@])],
1219    [enable_opencl="$enableval"],
1220    [enable_opencl=no])
1221 AC_ARG_ENABLE([opencl_icd],
1222    [AS_HELP_STRING([--enable-opencl-icd],
1223           [Build an OpenCL ICD library to be loaded by an ICD implementation
1224            @<:@default=disabled@:>@])],
1225     [enable_opencl_icd="$enableval"],
1226     [enable_opencl_icd=no])
1227
1228 AC_ARG_ENABLE([gallium-tests],
1229     [AS_HELP_STRING([--enable-gallium-tests],
1230         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1231     [enable_gallium_tests="$enableval"],
1232     [enable_gallium_tests=no])
1233
1234 # Option for Gallium drivers
1235
1236 # Keep this in sync with the --with-gallium-drivers help string default value
1237 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1238
1239 AC_ARG_WITH([gallium-drivers],
1240     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1241         [comma delimited Gallium drivers list, e.g.
1242         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1243         @<:@default=r300,r600,svga,swrast@:>@])],
1244     [with_gallium_drivers="$withval"],
1245     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1246
1247 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1248 # here so that the script doesn't choke on an unknown driver name later.
1249 case "$with_gallium_drivers" in
1250     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1251     no) with_gallium_drivers='' ;;
1252 esac
1253
1254 if test "x$enable_opengl" = xno -a \
1255         "x$enable_gles1" = xno -a \
1256         "x$enable_gles2" = xno -a \
1257         "x$enable_nine" = xno -a \
1258         "x$enable_xa" = xno -a \
1259         "x$enable_xvmc" = xno -a \
1260         "x$enable_vdpau" = xno -a \
1261         "x$enable_omx" = xno -a \
1262         "x$enable_va" = xno -a \
1263         "x$enable_opencl" = xno; then
1264     AC_MSG_ERROR([at least one API should be enabled])
1265 fi
1266
1267 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1268 if test "x$enable_opengl" = xno -a \
1269         "x$enable_gles1" = xyes; then
1270     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1271 fi
1272
1273 if test "x$enable_opengl" = xno -a \
1274         "x$enable_gles2" = xyes; then
1275     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1276 fi
1277
1278 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1279 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1280 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1281 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1282                                         "x$enable_gles1" = xyes -o \
1283                                         "x$enable_gles2" = xyes)
1284
1285 # Validate GLX options
1286 if test "x$enable_glx" = xyes; then
1287     if test "x$enable_dri" = xyes; then
1288         enable_glx=dri
1289     elif test -n "$with_gallium_drivers"; then
1290         enable_glx=gallium-xlib
1291     else
1292         enable_glx=xlib
1293     fi
1294 fi
1295 case "x$enable_glx" in
1296 xdri | xxlib | xgallium-xlib)
1297     # GLX requires OpenGL
1298     if test "x$enable_opengl" = xno; then
1299         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1300     fi
1301
1302     # Check individual dependencies
1303     case "x$enable_glx" in
1304     xdri)
1305         if test "x$enable_dri" = xno; then
1306             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1307         fi
1308         ;;
1309     xxlib)
1310         if test "x$enable_dri" = xyes; then
1311             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1312         fi
1313         ;;
1314     xgallium-xlib )
1315         if test "x$enable_dri" = xyes; then
1316             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1317         fi
1318         if test -z "$with_gallium_drivers"; then
1319             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1320         fi
1321         ;;
1322     esac
1323     ;;
1324 xno)
1325     ;;
1326 *)
1327     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1328     ;;
1329 esac
1330
1331 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1332 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1333 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1334 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1335
1336 DEFAULT_GL_LIB_NAME=GL
1337
1338 dnl
1339 dnl Libglvnd configuration
1340 dnl
1341 AC_ARG_ENABLE([libglvnd],
1342     [AS_HELP_STRING([--enable-libglvnd],
1343         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1344     [enable_libglvnd="$enableval"],
1345     [enable_libglvnd=no])
1346 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1347
1348 if test "x$enable_libglvnd" = xyes ; then
1349     dnl XXX: update once we can handle more than libGL/glx.
1350     dnl Namely: we should error out if neither of the glvnd enabled libraries
1351     dnl are built
1352     case "x$enable_glx" in
1353     xno)
1354         AC_MSG_ERROR([cannot build libglvnd without GLX])
1355         ;;
1356     xxlib | xgallium-xlib )
1357         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1358         ;;
1359     xdri)
1360         ;;
1361     esac
1362
1363     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1364     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1365     AC_SUBST([LIBGLVND_DATADIR])
1366
1367     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1368     DEFAULT_GL_LIB_NAME=GLX_mesa
1369 fi
1370
1371 AC_ARG_WITH([gl-lib-name],
1372   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1373     [specify GL library name @<:@default=GL@:>@])],
1374   [GL_LIB=$withval],
1375   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1376 AC_ARG_WITH([osmesa-lib-name],
1377   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1378     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1379   [OSMESA_LIB=$withval],
1380   [OSMESA_LIB=OSMesa])
1381 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1382 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1383
1384 dnl
1385 dnl Mangled Mesa support
1386 dnl
1387 AC_ARG_ENABLE([mangling],
1388   [AS_HELP_STRING([--enable-mangling],
1389     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1390   [enable_mangling="${enableval}"],
1391   [enable_mangling=no]
1392 )
1393 if test "x${enable_mangling}" = "xyes" ; then
1394   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1395   GL_LIB="Mangled${GL_LIB}"
1396   OSMESA_LIB="Mangled${OSMESA_LIB}"
1397 fi
1398 AC_SUBST([GL_LIB])
1399 AC_SUBST([OSMESA_LIB])
1400
1401 # Check for libdrm
1402 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1403                   [have_libdrm=yes], [have_libdrm=no])
1404 if test "x$have_libdrm" = xyes; then
1405         DEFINES="$DEFINES -DHAVE_LIBDRM"
1406 fi
1407
1408 require_libdrm() {
1409     if test "x$have_libdrm" != xyes; then
1410        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1411     fi
1412 }
1413
1414
1415 # Select which platform-dependent DRI code gets built
1416 case "$host_os" in
1417 darwin*)
1418     dri_platform='apple' ;;
1419 cygwin*)
1420     dri_platform='windows' ;;
1421 gnu*)
1422     dri_platform='none' ;;
1423 *)
1424     dri_platform='drm' ;;
1425 esac
1426
1427 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1428     have_drisw_kms='yes'
1429 fi
1430
1431 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1432 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1433 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1434 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1435 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1436 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1437 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1438 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1439 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1440
1441 AC_ARG_ENABLE([shared-glapi],
1442     [AS_HELP_STRING([--enable-shared-glapi],
1443         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1444     [enable_shared_glapi="$enableval"],
1445     [enable_shared_glapi=yes])
1446
1447 case "x$enable_opengl$enable_gles1$enable_gles2" in
1448 x*yes*yes*)
1449     if test "x$enable_shared_glapi" = xno; then
1450         AC_MSG_ERROR([shared GLAPI required when building two or more of
1451                       the following APIs - opengl, gles1 gles2])
1452     fi
1453     ;;
1454 esac
1455
1456 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1457
1458 # Build the pipe-drivers as separate libraries/modules.
1459 # Do not touch this unless you know what you are doing.
1460 # XXX: Expose via configure option ?
1461 enable_shared_pipe_drivers=no
1462
1463 dnl
1464 dnl Driver specific build directories
1465 dnl
1466
1467 if test "x$enable_gallium_osmesa" = xyes; then
1468     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1469         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1470     fi
1471     if test "x$enable_osmesa" = xyes; then
1472         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1473     fi
1474 fi
1475
1476 require_dri_shared_libs_and_glapi() {
1477     if test "x$enable_static" = xyes; then
1478         AC_MSG_ERROR([$1 cannot be build as static library])
1479     fi
1480
1481     if test "x$enable_dri" != xyes; then
1482         # There is only a single backend which won't be build/used otherwise.
1483         # XXX: Revisit this as the egl/haiku is a thing.
1484         AC_MSG_ERROR([$1 requires --enable-dri])
1485     fi
1486
1487     if test "x$enable_shared_glapi" != xyes; then
1488         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1489     fi
1490 }
1491
1492 if test "x$enable_dri" = xyes; then
1493     require_dri_shared_libs_and_glapi "DRI"
1494
1495     # not a hard requirement as swrast does not depend on it
1496     if test "x$have_libdrm" = xyes; then
1497         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1498     fi
1499 fi
1500
1501 AC_ARG_ENABLE([driglx-direct],
1502     [AS_HELP_STRING([--disable-driglx-direct],
1503         [disable direct rendering in GLX and EGL for DRI \
1504             @<:@default=auto@:>@])],
1505     [driglx_direct="$enableval"],
1506     [driglx_direct="yes"])
1507
1508 dnl
1509 dnl libGL configuration per driver
1510 dnl
1511 if test "x$enable_glx" != xno; then
1512     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1513 fi
1514 case "x$enable_glx" in
1515 xxlib | xgallium-xlib)
1516     # Xlib-based GLX
1517     dri_modules="x11 xext xcb"
1518     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1519     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1520     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1521     GL_LIB_DEPS="$XLIBGL_LIBS"
1522     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1523     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1524     ;;
1525 xdri)
1526     # DRI-based GLX
1527
1528     # find the DRI deps for libGL
1529     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1530
1531     if test x"$driglx_direct" = xyes; then
1532         if test x"$dri_platform" = xdrm ; then
1533             DEFINES="$DEFINES -DGLX_USE_DRM"
1534             require_libdrm "Direct rendering"
1535
1536             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1537             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1538
1539             if test x"$enable_dri" = xyes; then
1540                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1541             fi
1542         fi
1543         if test x"$dri_platform" = xapple ; then
1544             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1545         fi
1546         if test x"$dri_platform" = xwindows ; then
1547             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1548         fi
1549     fi
1550
1551     # add xf86vidmode if available
1552     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1553     if test "$HAVE_XF86VIDMODE" = yes ; then
1554         dri_modules="$dri_modules xxf86vm"
1555     fi
1556
1557     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1558     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1559     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1560     GL_LIB_DEPS="$DRIGL_LIBS"
1561
1562     # need DRM libs, $PTHREAD_LIBS, etc.
1563     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1564     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1565     ;;
1566 esac
1567
1568 # This is outside the case (above) so that it is invoked even for non-GLX
1569 # builds.
1570 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1571
1572 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1573 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1574 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1576
1577 AC_SUBST([X11_INCLUDES])
1578 AC_SUBST([GL_LIB_DEPS])
1579 AC_SUBST([GL_PC_REQ_PRIV])
1580 AC_SUBST([GL_PC_LIB_PRIV])
1581 AC_SUBST([GL_PC_CFLAGS])
1582 AC_SUBST([DRI_PC_REQ_PRIV])
1583 AC_SUBST([GLESv1_CM_LIB_DEPS])
1584 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1585 AC_SUBST([GLESv2_LIB_DEPS])
1586 AC_SUBST([GLESv2_PC_LIB_PRIV])
1587
1588 AC_SUBST([HAVE_XF86VIDMODE])
1589
1590 dnl
1591 dnl More GLX setup
1592 dnl
1593 case "x$enable_glx" in
1594 xxlib | xgallium-xlib)
1595     DEFINES="$DEFINES -DUSE_XSHM"
1596     ;;
1597 xdri)
1598     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1599     if test "x$driglx_direct" = xyes; then
1600         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1601     fi
1602     ;;
1603 esac
1604
1605 dnl
1606 dnl TLS detection
1607 dnl
1608
1609 AC_ARG_ENABLE([glx-tls],
1610     [AS_HELP_STRING([--enable-glx-tls],
1611         [enable TLS support in GLX @<:@default=enabled@:>@])],
1612     [GLX_USE_TLS="$enableval"],
1613     [GLX_USE_TLS=yes])
1614 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1615
1616 if test "x$GLX_USE_TLS" = xyes; then
1617     DEFINES="$DEFINES -DGLX_USE_TLS"
1618 fi
1619
1620 dnl Read-only text section on x86 hardened platforms
1621 AC_ARG_ENABLE([glx-read-only-text],
1622     [AS_HELP_STRING([--enable-glx-read-only-text],
1623         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1624     [enable_glx_read_only_text="$enableval"],
1625     [enable_glx_read_only_text=no])
1626 if test "x$enable_glx_read_only_text" = xyes; then
1627     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1628 fi
1629
1630 dnl
1631 dnl DEPRECATED: EGL Platforms configuration
1632 dnl
1633 AC_ARG_WITH([egl-platforms],
1634     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1635         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1636     [with_egl_platforms="$withval"],
1637     [with_egl_platforms=auto])
1638
1639 if test "x$with_egl_platforms" = xauto; then
1640     with_egl_platforms="x11,surfaceless"
1641     if test "x$enable_gbm" = xyes; then
1642         with_egl_platforms="$with_egl_platforms,drm"
1643     fi
1644 else
1645     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1646 fi
1647
1648 dnl
1649 dnl Platforms configuration
1650 dnl
1651 AC_ARG_WITH([platforms],
1652     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1653         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1654         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1655     [with_platforms="$withval"],
1656     [with_platforms=auto])
1657
1658 # Reuse the autodetection rather than duplicating it.
1659 if test "x$with_platforms" = xauto; then
1660     with_platforms=$with_egl_platforms
1661 fi
1662
1663 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1664         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1665         WAYLAND_SCANNER='')
1666 if test "x$WAYLAND_SCANNER" = x; then
1667     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1668 fi
1669
1670 # Do per platform setups and checks
1671 platforms=`IFS=', '; echo $with_platforms`
1672 for plat in $platforms; do
1673         case "$plat" in
1674         wayland)
1675
1676                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1677
1678                 if test "x$WAYLAND_SCANNER" = "x:"; then
1679                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1680                 fi
1681                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1682                 ;;
1683
1684         x11)
1685                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1686                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1687                 ;;
1688
1689         drm)
1690                 test "x$enable_gbm" = "xno" &&
1691                         AC_MSG_ERROR([EGL platform drm needs gbm])
1692                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1693                 ;;
1694
1695         surfaceless)
1696                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1697                 ;;
1698
1699         android)
1700                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1701                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1702                 ;;
1703
1704         *)
1705                 AC_MSG_ERROR([platform '$plat' does not exist])
1706                 ;;
1707         esac
1708
1709         case "$plat" in
1710         wayland|drm|surfaceless)
1711                 require_libdrm "Platform $plat"
1712                 ;;
1713         esac
1714 done
1715
1716 if test "x$enable_glx" != xno; then
1717     if ! echo "$platforms" | grep -q 'x11'; then
1718         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1719     fi
1720 fi
1721
1722 if test x"$enable_dri3" = xyes; then
1723     DEFINES="$DEFINES -DHAVE_DRI3"
1724
1725     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1726     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1727 fi
1728
1729 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1730 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1731 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1732 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1733 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1734
1735 dnl
1736 dnl More DRI setup
1737 dnl
1738 dnl Directory for DRI drivers
1739 AC_ARG_WITH([dri-driverdir],
1740     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1741         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1742     [DRI_DRIVER_INSTALL_DIR="$withval"],
1743     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1744 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1745 dnl Extra search path for DRI drivers
1746 AC_ARG_WITH([dri-searchpath],
1747     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1748         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1749     [DRI_DRIVER_SEARCH_DIR="$withval"],
1750     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1751 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1752 dnl Which drivers to build - default is chosen by platform
1753 AC_ARG_WITH([dri-drivers],
1754     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1755         [comma delimited classic DRI drivers list, e.g.
1756         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1757     [with_dri_drivers="$withval"],
1758     [with_dri_drivers=auto])
1759
1760 if test "x$with_dri_drivers" = xauto; then
1761     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1762         with_dri_drivers="yes"
1763     else
1764         with_dri_drivers="no"
1765     fi
1766 fi
1767 if test "x$with_dri_drivers" = xno; then
1768     with_dri_drivers=''
1769 fi
1770
1771 dnl If $with_dri_drivers is yes, drivers will be added through
1772 dnl platform checks. Set DEFINES and LIB_DEPS
1773 if test "x$enable_dri" = xyes; then
1774     # Platform specific settings and drivers to build
1775     case "$host_os" in
1776     linux*)
1777         case "$host_cpu" in
1778         powerpc* | sparc*)
1779             # Build only the drivers for cards that exist on PowerPC/sparc
1780             if test "x$with_dri_drivers" = "xyes"; then
1781                 with_dri_drivers="r200 radeon swrast"
1782             fi
1783             ;;
1784         esac
1785         ;;
1786     cygwin*)
1787         if test "x$with_dri_drivers" = "xyes"; then
1788             with_dri_drivers="swrast"
1789         fi
1790         ;;
1791     darwin*)
1792         DEFINES="$DEFINES -DBUILDING_MESA"
1793         if test "x$with_dri_drivers" = "xyes"; then
1794             with_dri_drivers="swrast"
1795         fi
1796         ;;
1797     esac
1798
1799     # default drivers
1800     if test "x$with_dri_drivers" = "xyes"; then
1801         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1802     fi
1803
1804     # Check for expat
1805     PKG_CHECK_MODULES([EXPAT], [expat], [],
1806         # expat version 2.0 and earlier do not provide expat.pc
1807         [AC_CHECK_HEADER([expat.h],[],
1808                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1809          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1810                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1811          EXPAT_LIBS="-lexpat"])
1812
1813     # put all the necessary libs together
1814     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1815 fi
1816
1817 AC_SUBST([DRI_LIB_DEPS])
1818
1819 DRI_DIRS=''
1820 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1821 if test -n "$with_dri_drivers"; then
1822     if test "x$enable_opengl" != xyes; then
1823         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1824     fi
1825
1826     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1827     for driver in $dri_drivers; do
1828         DRI_DIRS="$DRI_DIRS $driver"
1829         case "x$driver" in
1830         xi915)
1831             require_libdrm "i915"
1832             HAVE_I915_DRI=yes
1833             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1834             ;;
1835         xi965)
1836             require_libdrm "i965"
1837             HAVE_I965_DRI=yes
1838             ;;
1839         xnouveau)
1840             require_libdrm "nouveau"
1841             HAVE_NOUVEAU_DRI=yes
1842             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1843             ;;
1844         xradeon)
1845             require_libdrm "radeon"
1846             HAVE_RADEON_DRI=yes;
1847             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1848             ;;
1849         xr200)
1850             require_libdrm "r200"
1851             HAVE_R200_DRI=yes
1852             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1853             ;;
1854         xswrast)
1855             HAVE_SWRAST_DRI=yes
1856             ;;
1857         *)
1858             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1859             ;;
1860         esac
1861     done
1862     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1863 fi
1864
1865
1866 dnl
1867 dnl Gallium LLVM
1868 dnl Deprecated: kept for backwards compatibility
1869 dnl
1870 AC_ARG_ENABLE([gallium-llvm],
1871     [AS_HELP_STRING([--enable-gallium-llvm],
1872         [DEPRECATED: use --enable-llvm instead])],
1873     [enable_gallium_llvm="$enableval"],
1874     [enable_gallium_llvm=auto])
1875
1876 if test "x$enable_gallium_llvm" != xauto; then
1877    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1878    enable_llvm=$enable_gallium_llvm
1879 fi
1880
1881 dnl
1882 dnl LLVM
1883 dnl
1884 AC_ARG_ENABLE([llvm],
1885     [AS_HELP_STRING([--enable-llvm],
1886         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1887     [enable_llvm="$enableval"],
1888     [enable_llvm=auto])
1889
1890 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1891     if test "x$FOUND_LLVM" = xyes; then
1892         case "$host_cpu" in
1893         i*86|x86_64|amd64) enable_llvm=yes;;
1894         *) enable_llvm=no;;
1895         esac
1896     else
1897         enable_llvm=no
1898     fi
1899 fi
1900
1901 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1902     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1903 fi
1904
1905 #
1906 # Vulkan driver configuration
1907 #
1908
1909 AC_ARG_WITH([vulkan-drivers],
1910     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1911         [comma delimited Vulkan drivers list, e.g.
1912         "intel,radeon"
1913         @<:@default=no@:>@])],
1914     [with_vulkan_drivers="$withval"],
1915     [with_vulkan_drivers="no"])
1916
1917 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1918 # here so that the script doesn't choke on an unknown driver name later.
1919 case "x$with_vulkan_drivers" in
1920     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1921     xno) with_vulkan_drivers='' ;;
1922 esac
1923
1924 AC_ARG_WITH([vulkan-icddir],
1925     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1926         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1927     [VULKAN_ICD_INSTALL_DIR="$withval"],
1928     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1929 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1930
1931 require_x11_dri3() {
1932     if echo "$platforms" | grep -q 'x11'; then
1933         if test "x$enable_dri3" != xyes; then
1934             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1935         fi
1936     fi
1937 }
1938
1939 if test -n "$with_vulkan_drivers"; then
1940     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1941         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1942     fi
1943
1944     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1945     for driver in $VULKAN_DRIVERS; do
1946         case "x$driver" in
1947         xintel)
1948             require_libdrm "ANV"
1949             require_x11_dri3 "ANV"
1950             HAVE_INTEL_VULKAN=yes
1951             ;;
1952         xradeon)
1953             require_libdrm "radv"
1954             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1955             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1956             require_x11_dri3 "radv"
1957             HAVE_RADEON_VULKAN=yes
1958             ;;
1959         *)
1960             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1961             ;;
1962         esac
1963     done
1964     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1965 fi
1966
1967
1968 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1969 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1970 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1971                                   "x$enable_osmesa" = xyes -o \
1972                                   -n "$DRI_DIRS")
1973
1974 dnl
1975 dnl OSMesa configuration
1976 dnl
1977
1978 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1979 AC_ARG_WITH([osmesa-bits],
1980     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1981         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1982     [osmesa_bits="$withval"],
1983     [osmesa_bits=8])
1984 if test "x$osmesa_bits" != x8; then
1985     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1986         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1987         osmesa_bits=8
1988     fi
1989 fi
1990 case "x$osmesa_bits" in
1991 x8)
1992     OSMESA_LIB="${OSMESA_LIB}"
1993     ;;
1994 x16|x32)
1995     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1996     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1997     ;;
1998 *)
1999     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2000     ;;
2001 esac
2002
2003 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2004     # only link libraries with osmesa if shared
2005     if test "$enable_static" = no; then
2006         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2007     else
2008         OSMESA_LIB_DEPS=""
2009     fi
2010     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2011 fi
2012
2013 AC_SUBST([OSMESA_LIB_DEPS])
2014 AC_SUBST([OSMESA_PC_REQ])
2015 AC_SUBST([OSMESA_PC_LIB_PRIV])
2016
2017 dnl
2018 dnl gbm configuration
2019 dnl
2020 if test "x$enable_gbm" = xyes; then
2021     require_dri_shared_libs_and_glapi "gbm"
2022 fi
2023 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2024 # FINISHME: GBM has a number of dependencies which we should add below
2025 GBM_PC_REQ_PRIV=""
2026 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2027 AC_SUBST([GBM_PC_REQ_PRIV])
2028 AC_SUBST([GBM_PC_LIB_PRIV])
2029
2030 dnl
2031 dnl EGL configuration
2032 dnl
2033
2034 if test "x$enable_egl" = xyes; then
2035     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2036
2037     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2038
2039     require_dri_shared_libs_and_glapi "egl"
2040 fi
2041 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2042 AC_SUBST([EGL_LIB_DEPS])
2043
2044 gallium_st="mesa"
2045
2046 dnl
2047 dnl XA configuration
2048 dnl
2049 if test "x$enable_xa" = xyes; then
2050     if test "x$with_gallium_drivers" = xswrast; then
2051        AC_MSG_ERROR([
2052           Building xa requires at least one non swrast gallium driver.
2053           If you are looking to use libxatracker.so with the VMware driver,
2054           make sure to include svga in the gallium drivers list, apart from
2055           enabling XA.
2056           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2057     fi
2058     gallium_st="$gallium_st xa"
2059 fi
2060 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2061
2062 if echo $platforms | grep -q "x11"; then
2063     have_xvmc_platform=yes
2064 else
2065     have_xvmc_platform=no
2066 fi
2067
2068 if echo $platforms | grep -q "x11"; then
2069     have_vdpau_platform=yes
2070 else
2071     have_vdpau_platform=no
2072 fi
2073
2074 if echo $platforms | grep -q "x11\|drm"; then
2075     have_omx_platform=yes
2076 else
2077     have_omx_platform=no
2078 fi
2079
2080 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2081     have_va_platform=yes
2082 else
2083     have_va_platform=no
2084 fi
2085
2086 dnl
2087 dnl Gallium G3DVL configuration
2088 dnl
2089 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2090     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2091         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2092     fi
2093
2094     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2095         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2096     fi
2097
2098     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2099         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2100     fi
2101
2102     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2103         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2104     fi
2105 fi
2106
2107 if test "x$enable_dri" = xyes -o \
2108         "x$enable_xvmc" = xyes -o \
2109         "x$enable_vdpau" = xyes -o \
2110         "x$enable_omx" = xyes -o \
2111         "x$enable_va" = xyes; then
2112     need_gallium_vl=yes
2113 fi
2114 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2115
2116 if test "x$enable_xvmc" = xyes -o \
2117         "x$enable_vdpau" = xyes -o \
2118         "x$enable_omx" = xyes -o \
2119         "x$enable_va" = xyes; then
2120     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2121     need_gallium_vl_winsys=yes
2122 fi
2123 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2124
2125 if test "x$enable_xvmc" = xyes; then
2126     if test "x$have_xvmc_platform" != xyes; then
2127         AC_MSG_ERROR([XVMC requires the x11 platforms])
2128     fi
2129     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2130     gallium_st="$gallium_st xvmc"
2131 fi
2132 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2133
2134 if test "x$enable_vdpau" = xyes; then
2135     if test "x$have_vdpau_platform" != xyes; then
2136         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2137     fi
2138     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2139     gallium_st="$gallium_st vdpau"
2140     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2141 fi
2142 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2143
2144 if test "x$enable_omx" = xyes; then
2145     if test "x$have_omx_platform" != xyes; then
2146         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2147     fi
2148     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2149     gallium_st="$gallium_st omx"
2150 fi
2151 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2152
2153 if test "x$enable_va" = xyes; then
2154     if test "x$have_va_platform" != xyes; then
2155         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2156     fi
2157     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2158     gallium_st="$gallium_st va"
2159 fi
2160 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2161
2162 dnl
2163 dnl Nine Direct3D9 configuration
2164 dnl
2165 if test "x$enable_nine" = xyes; then
2166     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2167         AC_MSG_ERROR([nine requires the gallium swrast driver])
2168     fi
2169     if test "x$with_gallium_drivers" = xswrast; then
2170         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2171     fi
2172     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2173         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2174     fi
2175
2176     if test "x$enable_dri3" = xno; then
2177         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2178     fi
2179
2180     gallium_st="$gallium_st nine"
2181 fi
2182 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2183
2184 dnl
2185 dnl OpenCL configuration
2186 dnl
2187
2188 AC_ARG_WITH([clang-libdir],
2189    [AS_HELP_STRING([--with-clang-libdir],
2190          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2191    [CLANG_LIBDIR="$withval"],
2192    [CLANG_LIBDIR=''])
2193
2194 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2195
2196 if test "x$enable_opencl" = xyes; then
2197     if test -z "$with_gallium_drivers"; then
2198         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2199     fi
2200
2201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2202         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2203     fi
2204
2205     if test "x$have_libclc" = xno; then
2206         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2207                     Make sure the directory containing libclc.pc is specified in your
2208                     PKG_CONFIG_PATH environment variable.
2209                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2210     else
2211         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2212         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2213         AC_SUBST([LIBCLC_INCLUDEDIR])
2214         AC_SUBST([LIBCLC_LIBEXECDIR])
2215     fi
2216
2217     gallium_st="$gallium_st clover"
2218
2219     if test "x$enable_opencl_icd" = xyes; then
2220         OPENCL_LIBNAME="MesaOpenCL"
2221     else
2222         OPENCL_LIBNAME="OpenCL"
2223     fi
2224
2225     if test "x$have_libelf" != xyes; then
2226        AC_MSG_ERROR([Clover requires libelf])
2227     fi
2228
2229     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2230         altivec_enabled=no
2231         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2232         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2233         #error "AltiVec not enabled"
2234         #endif
2235         ])], altivec_enabled=yes)
2236
2237         if test "$altivec_enabled" = yes; then
2238             CLOVER_STD_OVERRIDE="-std=gnu++11"
2239         fi
2240         AC_SUBST([CLOVER_STD_OVERRIDE])
2241     fi
2242
2243     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2244
2245     llvm_add_default_components "opencl"
2246     llvm_add_component "all-targets" "opencl"
2247     llvm_add_component "linker" "opencl"
2248     llvm_add_component "instrumentation" "opencl"
2249     llvm_add_component "ipo" "opencl"
2250     llvm_add_component "irreader" "opencl"
2251     llvm_add_component "option" "opencl"
2252     llvm_add_component "objcarcopts" "opencl"
2253     llvm_add_component "profiledata" "opencl"
2254
2255     dnl Check for Clang internal headers
2256     if test -z "$CLANG_LIBDIR"; then
2257         CLANG_LIBDIR=${LLVM_LIBDIR}
2258     fi
2259     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2260     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2261         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2262 fi
2263 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2264 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2265 AC_SUBST([OPENCL_LIBNAME])
2266 AC_SUBST([CLANG_RESOURCE_DIR])
2267
2268 dnl
2269 dnl Gallium configuration
2270 dnl
2271 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2272
2273 # libEGL wants to default to the first platform specified in
2274 # ./configure.  parse that here.
2275 if test "x$platforms" != "x"; then
2276     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2277     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2278 else
2279     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2280 fi
2281
2282 AC_SUBST([EGL_NATIVE_PLATFORM])
2283 AC_SUBST([EGL_CFLAGS])
2284
2285 # If we don't have the X11 platform, set this define so we don't try to include
2286 # the X11 headers.
2287 if ! echo "$platforms" | grep -q 'x11'; then
2288     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2289     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2290 fi
2291
2292 dnl Directory for XVMC libs
2293 AC_ARG_WITH([xvmc-libdir],
2294     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2295         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2296     [XVMC_LIB_INSTALL_DIR="$withval"],
2297     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2298 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2299
2300 dnl
2301 dnl Gallium Tests
2302 dnl
2303 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2304
2305 dnl Directory for VDPAU libs
2306 AC_ARG_WITH([vdpau-libdir],
2307     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2308         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2309     [VDPAU_LIB_INSTALL_DIR="$withval"],
2310     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2311 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2312
2313 dnl Directory for OMX libs
2314
2315 AC_ARG_WITH([omx-libdir],
2316     [AS_HELP_STRING([--with-omx-libdir=DIR],
2317         [directory for the OMX libraries])],
2318     [OMX_LIB_INSTALL_DIR="$withval"],
2319     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2320                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2321 AC_SUBST([OMX_LIB_INSTALL_DIR])
2322
2323 dnl Directory for VA libs
2324
2325 AC_ARG_WITH([va-libdir],
2326     [AS_HELP_STRING([--with-va-libdir=DIR],
2327         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2328     [VA_LIB_INSTALL_DIR="$withval"],
2329     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2330 AC_SUBST([VA_LIB_INSTALL_DIR])
2331
2332 AC_ARG_WITH([d3d-libdir],
2333     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2334         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2335     [D3D_DRIVER_INSTALL_DIR="$withval"],
2336     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2337 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2338
2339 dnl
2340 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2341 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2342 dnl architectures.
2343 dnl
2344 r300_require_llvm() {
2345     case "$host" in *gnux32) return;; esac
2346     case "$host_cpu" in
2347     i*86|x86_64|amd64) require_llvm $1
2348         ;;
2349     esac
2350 }
2351
2352 dnl
2353 dnl DRM is needed by X, Wayland, and offscreen rendering.
2354 dnl Surfaceless is an alternative for the last one.
2355 dnl
2356 require_basic_egl() {
2357     case "$with_platforms" in
2358         *drm*|*surfaceless*)
2359             ;;
2360         *)
2361             AC_MSG_ERROR([$1 requires one of these:
2362                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2363                   2) --with-platforms=surfaceless (offscreen only)
2364                   Recommended options: drm,x11])
2365             ;;
2366     esac
2367 }
2368
2369 swr_require_cxx_feature_flags() {
2370     feature_name="$1"
2371     preprocessor_test="$2"
2372     option_list="$3"
2373     output_var="$4"
2374
2375     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2376     AC_LANG_PUSH([C++])
2377     save_CXXFLAGS="$CXXFLAGS"
2378     save_IFS="$IFS"
2379     IFS=","
2380     found=0
2381     for opts in $option_list
2382     do
2383         unset IFS
2384         CXXFLAGS="$opts $save_CXXFLAGS"
2385         AC_COMPILE_IFELSE(
2386             [AC_LANG_PROGRAM(
2387                 [   #if !($preprocessor_test)
2388                     #error
2389                     #endif
2390                 ])],
2391             [found=1; break],
2392             [])
2393         IFS=","
2394     done
2395     IFS="$save_IFS"
2396     CXXFLAGS="$save_CXXFLAGS"
2397     AC_LANG_POP([C++])
2398     if test $found -eq 1; then
2399         AC_MSG_RESULT([$opts])
2400         eval "$output_var=\$opts"
2401         return 0
2402     fi
2403     AC_MSG_RESULT([no])
2404     AC_MSG_ERROR([swr requires $feature_name support])
2405     return 1
2406 }
2407
2408 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2409 if test -n "$with_gallium_drivers"; then
2410     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2411     for driver in $gallium_drivers; do
2412         case "x$driver" in
2413         xsvga)
2414             HAVE_GALLIUM_SVGA=yes
2415             require_libdrm "svga"
2416             ;;
2417         xi915)
2418             HAVE_GALLIUM_I915=yes
2419             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2420             require_libdrm "Gallium i915"
2421             ;;
2422         xr300)
2423             HAVE_GALLIUM_R300=yes
2424             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2425             require_libdrm "r300"
2426             r300_require_llvm "r300"
2427             ;;
2428         xr600)
2429             HAVE_GALLIUM_R600=yes
2430             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2431             require_libdrm "r600"
2432             if test "x$enable_llvm" = xyes; then
2433                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2434
2435                 llvm_add_component "asmparser" "r600"
2436                 llvm_add_component "bitreader" "r600"
2437             fi
2438             ;;
2439         xradeonsi)
2440             HAVE_GALLIUM_RADEONSI=yes
2441             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2442             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2443             require_libdrm "radeonsi"
2444             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2445             if test "x$enable_egl" = xyes; then
2446                 require_basic_egl "radeonsi"
2447             fi
2448             ;;
2449         xnouveau)
2450             HAVE_GALLIUM_NOUVEAU=yes
2451             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2452             require_libdrm "nouveau"
2453             ;;
2454         xfreedreno)
2455             HAVE_GALLIUM_FREEDRENO=yes
2456             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2457             require_libdrm "freedreno"
2458             ;;
2459         xetnaviv)
2460             HAVE_GALLIUM_ETNAVIV=yes
2461             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2462             require_libdrm "etnaviv"
2463             ;;
2464        ximx)
2465             HAVE_GALLIUM_IMX=yes
2466             ;;
2467         xswrast)
2468             HAVE_GALLIUM_SOFTPIPE=yes
2469             if test "x$enable_llvm" = xyes; then
2470                 HAVE_GALLIUM_LLVMPIPE=yes
2471             fi
2472             ;;
2473         xswr)
2474             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2475
2476             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2477                 ",-std=c++11" \
2478                 SWR_CXX11_CXXFLAGS
2479             AC_SUBST([SWR_CXX11_CXXFLAGS])
2480
2481             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2482                 ",-mavx,-march=core-avx" \
2483                 SWR_AVX_CXXFLAGS
2484             AC_SUBST([SWR_AVX_CXXFLAGS])
2485
2486             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2487                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2488                 SWR_AVX2_CXXFLAGS
2489             AC_SUBST([SWR_AVX2_CXXFLAGS])
2490
2491             HAVE_GALLIUM_SWR=yes
2492             ;;
2493         xvc4)
2494             HAVE_GALLIUM_VC4=yes
2495             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2496             require_libdrm "vc4"
2497
2498             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2499                               [USE_VC4_SIMULATOR=yes;
2500                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2501                               [USE_VC4_SIMULATOR=no])
2502             ;;
2503         xpl111)
2504             HAVE_GALLIUM_PL111=yes
2505             ;;
2506         xvirgl)
2507             HAVE_GALLIUM_VIRGL=yes
2508             require_libdrm "virgl"
2509             if test "x$enable_egl" = xyes; then
2510                 require_basic_egl "virgl"
2511             fi
2512             ;;
2513         *)
2514             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2515             ;;
2516         esac
2517     done
2518 fi
2519
2520 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2521 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2522                                               "x$LLVM_VERSION" != x3.9.1)
2523
2524 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2525     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2526     llvm_add_default_components "gallium"
2527 fi
2528
2529 dnl We need to validate some needed dependencies for renderonly drivers.
2530
2531 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2532     AC_MSG_ERROR([Building with imx requires etnaviv])
2533 fi
2534
2535 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2536     AC_MSG_ERROR([Building with pl111 requires vc4])
2537 fi
2538
2539 dnl
2540 dnl Set defines and buildtime variables only when using LLVM.
2541 dnl
2542 if test "x$enable_llvm" = xyes; then
2543     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2544
2545     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2546     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2547     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2548
2549     dnl Set LLVM_LIBS - This is done after the driver configuration so
2550     dnl that drivers can add additional components to LLVM_COMPONENTS.
2551     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2552     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2553     dnl this was causing the same libraries to be appear multiple times
2554     dnl in LLVM_LIBS.
2555
2556     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2557        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2558     fi
2559     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2560
2561     dnl llvm-config may not give the right answer when llvm is a built as a
2562     dnl single shared library, so we must work the library name out for
2563     dnl ourselves.
2564     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2565     if test "x$enable_llvm_shared_libs" = xyes; then
2566         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2567         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2568         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2569
2570         if test "x$llvm_have_one_so" = xyes; then
2571             dnl LLVM was built using auto*, so there is only one shared object.
2572             LLVM_LIBS="-l$LLVM_SO_NAME"
2573         else
2574             dnl If LLVM was built with CMake, there will be one shared object per
2575             dnl component.
2576             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2577                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2578         Please make sure you have built llvm with the --enable-shared option
2579         and that your llvm libraries are installed in $LLVM_LIBDIR
2580         If you have installed your llvm libraries to a different directory you
2581         can use the --with-llvm-prefix= configure flag to specify this directory.
2582         NOTE: Mesa is attempting to use llvm shared libraries by default.
2583         If you do not want to build with llvm shared libraries and instead want to
2584         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2585         invocation and rebuild.])])
2586
2587            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2588            dnl install uses a shared object for each component and we have
2589            dnl already added all of these objects to LLVM_LIBS.
2590         fi
2591     else
2592         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2593         dnl We need to link to llvm system libs when using static libs
2594         dnl However, only llvm 3.5+ provides --system-libs
2595         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2596             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2597         fi
2598     fi
2599 fi
2600
2601 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2602 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2603 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2604 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2605 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2606 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2608                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2609 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2610 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2612 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2613 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2614 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2617                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2618                                          "x$HAVE_GALLIUM_SWR" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2621
2622 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2623
2624 if test "x$enable_dri" = xyes; then
2625     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2626 fi
2627
2628 if test "x$have_drisw_kms" = xyes; then
2629     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2630 fi
2631 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2632
2633 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2634 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2635 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2636 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2637 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2638 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2639
2640 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2641 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2642
2643 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2644                                       "x$HAVE_RADEON_VULKAN" = xyes)
2645
2646 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2647                                         "x$HAVE_I965_DRI" = xyes)
2648
2649 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2650                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2651                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2652 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2653 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2654 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2655 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2656
2657 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2658 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2659 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2660 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2661                                         "x$enable_gallium_osmesa" = xyes)
2662
2663 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2664 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2665 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2666
2667 AC_SUBST([NINE_MAJOR], 1)
2668 AC_SUBST([NINE_MINOR], 0)
2669 AC_SUBST([NINE_TINY], 0)
2670 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2671
2672 AC_SUBST([VDPAU_MAJOR], 1)
2673 AC_SUBST([VDPAU_MINOR], 0)
2674
2675 if test "x$enable_va" = xyes; then
2676     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2677     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2678 fi
2679 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2680 AC_SUBST([VA_MINOR], $VA_MINOR)
2681
2682 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2683
2684 AC_SUBST([XVMC_MAJOR], 1)
2685 AC_SUBST([XVMC_MINOR], 0)
2686
2687 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2688 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2689 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2690 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2691
2692 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2693 AC_SUBST([XA_MINOR], $XA_MINOR)
2694 AC_SUBST([XA_TINY], $XA_TINY)
2695 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2696
2697 AC_ARG_ENABLE(valgrind,
2698               [AS_HELP_STRING([--enable-valgrind],
2699                              [Build mesa with valgrind support (default: auto)])],
2700                              [VALGRIND=$enableval], [VALGRIND=auto])
2701 if test "x$VALGRIND" != xno; then
2702         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2703 fi
2704 AC_MSG_CHECKING([whether to enable Valgrind support])
2705 if test "x$VALGRIND" = xauto; then
2706         VALGRIND="$have_valgrind"
2707 fi
2708
2709 if test "x$VALGRIND" = "xyes"; then
2710         if ! test "x$have_valgrind" = xyes; then
2711                 AC_MSG_ERROR([Valgrind support required but not present])
2712         fi
2713         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2714 fi
2715
2716 AC_MSG_RESULT([$VALGRIND])
2717
2718 dnl Restore LDFLAGS and CPPFLAGS
2719 LDFLAGS="$_SAVE_LDFLAGS"
2720 CPPFLAGS="$_SAVE_CPPFLAGS"
2721
2722 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2723 if test "x$acv_mesa_CLANG" = xyes; then
2724     CFLAGS="$CFLAGS -Qunused-arguments"
2725     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2726 fi
2727
2728 dnl Add user CFLAGS and CXXFLAGS
2729 CFLAGS="$CFLAGS $USER_CFLAGS"
2730 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2731
2732 dnl Substitute the config
2733 AC_CONFIG_FILES([Makefile
2734                 src/Makefile
2735                 src/amd/Makefile
2736                 src/amd/vulkan/Makefile
2737                 src/compiler/Makefile
2738                 src/egl/Makefile
2739                 src/egl/main/egl.pc
2740                 src/egl/wayland/wayland-drm/Makefile
2741                 src/egl/wayland/wayland-egl/Makefile
2742                 src/egl/wayland/wayland-egl/wayland-egl.pc
2743                 src/gallium/Makefile
2744                 src/gallium/auxiliary/Makefile
2745                 src/gallium/auxiliary/pipe-loader/Makefile
2746                 src/gallium/drivers/freedreno/Makefile
2747                 src/gallium/drivers/ddebug/Makefile
2748                 src/gallium/drivers/i915/Makefile
2749                 src/gallium/drivers/llvmpipe/Makefile
2750                 src/gallium/drivers/noop/Makefile
2751                 src/gallium/drivers/nouveau/Makefile
2752                 src/gallium/drivers/pl111/Makefile
2753                 src/gallium/drivers/r300/Makefile
2754                 src/gallium/drivers/r600/Makefile
2755                 src/gallium/drivers/radeon/Makefile
2756                 src/gallium/drivers/radeonsi/Makefile
2757                 src/gallium/drivers/rbug/Makefile
2758                 src/gallium/drivers/softpipe/Makefile
2759                 src/gallium/drivers/svga/Makefile
2760                 src/gallium/drivers/swr/Makefile
2761                 src/gallium/drivers/trace/Makefile
2762                 src/gallium/drivers/etnaviv/Makefile
2763                 src/gallium/drivers/imx/Makefile
2764                 src/gallium/drivers/vc4/Makefile
2765                 src/gallium/drivers/virgl/Makefile
2766                 src/gallium/state_trackers/clover/Makefile
2767                 src/gallium/state_trackers/dri/Makefile
2768                 src/gallium/state_trackers/glx/xlib/Makefile
2769                 src/gallium/state_trackers/nine/Makefile
2770                 src/gallium/state_trackers/omx/Makefile
2771                 src/gallium/state_trackers/osmesa/Makefile
2772                 src/gallium/state_trackers/va/Makefile
2773                 src/gallium/state_trackers/vdpau/Makefile
2774                 src/gallium/state_trackers/xa/Makefile
2775                 src/gallium/state_trackers/xvmc/Makefile
2776                 src/gallium/targets/d3dadapter9/Makefile
2777                 src/gallium/targets/d3dadapter9/d3d.pc
2778                 src/gallium/targets/dri/Makefile
2779                 src/gallium/targets/libgl-xlib/Makefile
2780                 src/gallium/targets/omx/Makefile
2781                 src/gallium/targets/opencl/Makefile
2782                 src/gallium/targets/opencl/mesa.icd
2783                 src/gallium/targets/osmesa/Makefile
2784                 src/gallium/targets/osmesa/osmesa.pc
2785                 src/gallium/targets/pipe-loader/Makefile
2786                 src/gallium/targets/va/Makefile
2787                 src/gallium/targets/vdpau/Makefile
2788                 src/gallium/targets/xa/Makefile
2789                 src/gallium/targets/xa/xatracker.pc
2790                 src/gallium/targets/xvmc/Makefile
2791                 src/gallium/tests/trivial/Makefile
2792                 src/gallium/tests/unit/Makefile
2793                 src/gallium/winsys/etnaviv/drm/Makefile
2794                 src/gallium/winsys/imx/drm/Makefile
2795                 src/gallium/winsys/freedreno/drm/Makefile
2796                 src/gallium/winsys/i915/drm/Makefile
2797                 src/gallium/winsys/nouveau/drm/Makefile
2798                 src/gallium/winsys/pl111/drm/Makefile
2799                 src/gallium/winsys/radeon/drm/Makefile
2800                 src/gallium/winsys/amdgpu/drm/Makefile
2801                 src/gallium/winsys/svga/drm/Makefile
2802                 src/gallium/winsys/sw/dri/Makefile
2803                 src/gallium/winsys/sw/kms-dri/Makefile
2804                 src/gallium/winsys/sw/null/Makefile
2805                 src/gallium/winsys/sw/wrapper/Makefile
2806                 src/gallium/winsys/sw/xlib/Makefile
2807                 src/gallium/winsys/vc4/drm/Makefile
2808                 src/gallium/winsys/virgl/drm/Makefile
2809                 src/gallium/winsys/virgl/vtest/Makefile
2810                 src/gbm/Makefile
2811                 src/gbm/main/gbm.pc
2812                 src/glx/Makefile
2813                 src/glx/apple/Makefile
2814                 src/glx/tests/Makefile
2815                 src/glx/windows/Makefile
2816                 src/glx/windows/windowsdriproto.pc
2817                 src/gtest/Makefile
2818                 src/intel/Makefile
2819                 src/loader/Makefile
2820                 src/mapi/Makefile
2821                 src/mapi/es1api/glesv1_cm.pc
2822                 src/mapi/es2api/glesv2.pc
2823                 src/mapi/glapi/gen/Makefile
2824                 src/mesa/Makefile
2825                 src/mesa/gl.pc
2826                 src/mesa/drivers/dri/dri.pc
2827                 src/mesa/drivers/dri/common/Makefile
2828                 src/mesa/drivers/dri/common/xmlpool/Makefile
2829                 src/mesa/drivers/dri/i915/Makefile
2830                 src/mesa/drivers/dri/i965/Makefile
2831                 src/mesa/drivers/dri/Makefile
2832                 src/mesa/drivers/dri/nouveau/Makefile
2833                 src/mesa/drivers/dri/r200/Makefile
2834                 src/mesa/drivers/dri/radeon/Makefile
2835                 src/mesa/drivers/dri/swrast/Makefile
2836                 src/mesa/drivers/osmesa/Makefile
2837                 src/mesa/drivers/osmesa/osmesa.pc
2838                 src/mesa/drivers/x11/Makefile
2839                 src/mesa/main/tests/Makefile
2840                 src/util/Makefile
2841                 src/util/tests/hash_table/Makefile
2842                 src/vulkan/Makefile])
2843
2844 AC_OUTPUT
2845
2846 # Fix up dependencies in *.Plo files, where we changed the extension of a
2847 # source file
2848 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2849
2850
2851 dnl
2852 dnl Output some configuration info for the user
2853 dnl
2854 echo ""
2855 echo "        prefix:          $prefix"
2856 echo "        exec_prefix:     $exec_prefix"
2857 echo "        libdir:          $libdir"
2858 echo "        includedir:      $includedir"
2859
2860 dnl API info
2861 echo ""
2862 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2863
2864 dnl Driver info
2865 echo ""
2866 case "x$enable_osmesa$enable_gallium_osmesa" in
2867 xnoyes)
2868         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2869         ;;
2870 xyesno)
2871         echo "        OSMesa:          lib$OSMESA_LIB"
2872         ;;
2873 xnono)
2874         echo "        OSMesa:          no"
2875         ;;
2876 esac
2877
2878 echo ""
2879 if test "x$enable_dri" != xno; then
2880         echo "        DRI platform:    $dri_platform"
2881         if test -z "$DRI_DIRS"; then
2882             echo "        DRI drivers:     no"
2883         else
2884             echo "        DRI drivers:     $DRI_DIRS"
2885         fi
2886         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2887 fi
2888
2889 case "x$enable_glx" in
2890 xdri)
2891     echo "        GLX:             DRI-based"
2892     ;;
2893 xxlib)
2894     echo "        GLX:             Xlib-based"
2895     ;;
2896 xgallium-xlib)
2897     echo "        GLX:             Xlib-based (Gallium)"
2898     ;;
2899 *)
2900     echo "        GLX:             $enable_glx"
2901     ;;
2902 esac
2903
2904 dnl EGL
2905 echo ""
2906 echo "        EGL:             $enable_egl"
2907 if test "$enable_egl" = yes; then
2908
2909     egl_drivers=""
2910     if test "x$enable_dri" != "xno"; then
2911         egl_drivers="$egl_drivers builtin:egl_dri2"
2912     fi
2913     if test "x$enable_dri3" != "xno"; then
2914         egl_drivers="$egl_drivers builtin:egl_dri3"
2915     fi
2916
2917     echo "        EGL drivers:    $egl_drivers"
2918 fi
2919 if test "x$enable_gbm" = xyes; then
2920     echo "        GBM:             yes"
2921 else
2922     echo "        GBM:             no"
2923 fi
2924
2925     echo "        EGL/Vulkan/VL platforms:   $platforms"
2926
2927 # Vulkan
2928 echo ""
2929 if test "x$VULKAN_DRIVERS" != x; then
2930     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2931     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2932 else
2933     echo "        Vulkan drivers:  no"
2934 fi
2935
2936 echo ""
2937 if test "x$enable_llvm" = xyes; then
2938     echo "        llvm:            yes"
2939     echo "        llvm-config:     $LLVM_CONFIG"
2940     echo "        llvm-version:    $LLVM_VERSION"
2941 else
2942     echo "        llvm:            no"
2943 fi
2944
2945 echo ""
2946 if test -n "$with_gallium_drivers"; then
2947     echo "        Gallium drivers: $gallium_drivers"
2948     echo "        Gallium st:      $gallium_st"
2949 else
2950     echo "        Gallium:         no"
2951 fi
2952
2953 echo ""
2954 if test "x$enable_gallium_extra_hud" != xyes; then
2955     echo "        HUD extra stats: no"
2956 else
2957     echo "        HUD extra stats: yes"
2958 fi
2959
2960 if test "x$enable_lmsensors" != xyes; then
2961     echo "        HUD lmsensors:   no"
2962 else
2963     echo "        HUD lmsensors:   yes"
2964 fi
2965
2966 dnl Libraries
2967 echo ""
2968 echo "        Shared libs:     $enable_shared"
2969 echo "        Static libs:     $enable_static"
2970 echo "        Shared-glapi:    $enable_shared_glapi"
2971
2972 dnl Compiler options
2973 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2974 cflags=`echo $CFLAGS | \
2975     $SED 's/^ *//;s/  */ /;s/ *$//'`
2976 cxxflags=`echo $CXXFLAGS | \
2977     $SED 's/^ *//;s/  */ /;s/ *$//'`
2978 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2979 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2980 echo ""
2981 echo "        CFLAGS:          $cflags"
2982 echo "        CXXFLAGS:        $cxxflags"
2983 echo "        LDFLAGS:         $ldflags"
2984 echo "        Macros:          $defines"
2985 echo ""
2986 if test "x$enable_llvm" = xyes; then
2987     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2988     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2989     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2990     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2991     echo ""
2992 fi
2993 echo "        PYTHON2:         $PYTHON2"
2994
2995 echo ""
2996 echo "        Run '${MAKE-make}' to build Mesa"
2997 echo ""