configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.79
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.8
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 842 dnl project. Even then there's a notable issue as described in the project README
 843 case "$host_os" in
 844 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 845     pthread_stubs_possible="no"
 846     ;;
 847 * )
 848     pthread_stubs_possible="yes"
 849     ;;
 850 esac
 851
 852 if test "x$pthread_stubs_possible" = xyes; then
 853     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 854     AC_SUBST(PTHREADSTUBS_CFLAGS)
 855     AC_SUBST(PTHREADSTUBS_LIBS)
 856 fi
 857
 858 dnl SELinux awareness.
 859 AC_ARG_ENABLE([selinux],
 860     [AS_HELP_STRING([--enable-selinux],
 861         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 862     [MESA_SELINUX="$enableval"],
 863     [MESA_SELINUX=no])
 864 if test "x$enable_selinux" = "xyes"; then
 865     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 866         [AC_CHECK_HEADER([selinux/selinux.h],[],
 867                          [AC_MSG_ERROR([SELinux headers not found])])
 868          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 869                       [AC_MSG_ERROR([SELinux library not found])])
 870          SELINUX_LIBS="-lselinux"])
 871     DEFINES="$DEFINES -DMESA_SELINUX"
 872 fi
 873 AC_SUBST([SELINUX_CFLAGS])
 874 AC_SUBST([SELINUX_LIBS])
 875
 876 dnl
 877 dnl LLVM
 878 dnl
 879 AC_ARG_ENABLE([llvm-shared-libs],
 880     [AS_HELP_STRING([--enable-llvm-shared-libs],
 881         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 882     [enable_llvm_shared_libs="$enableval"],
 883     [enable_llvm_shared_libs=yes])
 884
 885 AC_ARG_WITH([llvm-prefix],
 886     [AS_HELP_STRING([--with-llvm-prefix],
 887         [Prefix for LLVM installations in non-standard locations])],
 888     [llvm_prefix="$withval"],
 889     [llvm_prefix=''])
 890
 891 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 892 if test "x$have_libelf" = xno; then
 893    LIBELF_LIBS=''
 894    LIBELF_CFLAGS=''
 895    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 896    AC_SUBST([LIBELF_LIBS])
 897    AC_SUBST([LIBELF_CFLAGS])
 898 fi
 899
 900 if test -z "$LLVM_CONFIG"; then
 901     if test -n "$llvm_prefix"; then
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 903     else
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 905     fi
 906 fi
 907
 908 llvm_add_component() {
 909     new_llvm_component=$1
 910     driver_name=$2
 911
 912     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 913         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 914     else
 915         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 916     fi
 917 }
 918
 919 llvm_add_default_components() {
 920     driver_name=$1
 921
 922     # Required default components
 923     llvm_add_component "bitwriter" $driver_name
 924     llvm_add_component "engine" $driver_name
 925     llvm_add_component "mcdisassembler" $driver_name
 926     llvm_add_component "mcjit" $driver_name
 927
 928     # Optional default components
 929     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 930         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 931     fi
 932 }
 933
 934 llvm_add_target() {
 935     new_llvm_target=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 939         llvm_add_component $new_llvm_target $driver_name
 940     else
 941         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 # Call this inside ` ` to get the return value.
 946 # $1 is the llvm-config command with arguments.
 947 strip_unwanted_llvm_flags() {
 948     echo " `$1` " | sed -E \
 949         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 950         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 951         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 952         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 954         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 956         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 957         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 958         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 959         -e 's/^[[[:space:]]]//' \
 960         -e 's/[[[:space:]]]$//'
 961 }
 962
 963 llvm_set_environment_variables() {
 964     if test "x$LLVM_CONFIG" != xno; then
 965         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 966         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 967         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 968         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 969
 970         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 971         save_CFLAGS="$CFLAGS"
 972         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 973
 974         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 975             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 976         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980
 981         CFLAGS="$save_CFLAGS"
 982
 983         # Only needed for LLVM < 3.6.0
 984         if test -z "$LLVM_VERSION_PATCH"; then
 985             LLVM_VERSION_PATCH=0
 986         fi
 987
 988         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 989
 990         FOUND_LLVM=yes
 991     else
 992         FOUND_LLVM=no
 993         LLVM_VERSION_INT=0
 994     fi
 995 }
 996
 997 require_llvm() {
 998     if test "x$enable_llvm" != "xyes"; then
 999         AC_MSG_ERROR([--enable-llvm is required when building $1])
1000     fi
1001 }
1002
1003 llvm_require_version() {
1004     require_llvm $2
1005
1006     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1007     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1008     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1009
1010     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1011         # major > required major
1012         #  --> OK
1013         return
1014     fi
1015
1016     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1017         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1018             # major = required major and
1019             # minor > required minor
1020             #  --> OK
1021             return
1022         else
1023             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1024                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1025                     # major = required major and
1026                     # minor = required minor and
1027                     # patch >= required patch
1028                     #  --> OK
1029                     return
1030                 fi
1031             fi
1032         fi
1033     fi
1034
1035     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1036 }
1037
1038 radeon_llvm_check() {
1039     if test ${LLVM_VERSION_INT} -lt 307; then
1040         amdgpu_llvm_target_name='r600'
1041     else
1042         amdgpu_llvm_target_name='amdgpu'
1043     fi
1044
1045     llvm_require_version $*
1046
1047     llvm_add_target $amdgpu_llvm_target_name $2
1048
1049     llvm_add_default_components $2
1050     llvm_add_component "bitreader" $2
1051     llvm_add_component "ipo" $2
1052
1053     if test "x$have_libelf" != xyes; then
1054        AC_MSG_ERROR([$2 requires libelf when using llvm])
1055     fi
1056 }
1057
1058 llvm_set_environment_variables
1059
1060 AC_SUBST([LLVM_CFLAGS])
1061 AC_SUBST([LLVM_CXXFLAGS])
1062 AC_SUBST([LLVM_LIBS])
1063 AC_SUBST([LLVM_LDFLAGS])
1064 AC_SUBST([LLVM_INCLUDEDIR])
1065
1066 dnl
1067 dnl libunwind
1068 dnl
1069 AC_ARG_ENABLE([libunwind],
1070     [AS_HELP_STRING([--enable-libunwind],
1071             [Use libunwind for backtracing (default: auto)])],
1072         [LIBUNWIND="$enableval"],
1073         [LIBUNWIND="auto"])
1074
1075 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1076 if test "x$LIBUNWIND" = "xauto"; then
1077     LIBUNWIND="$HAVE_LIBUNWIND"
1078 fi
1079
1080 if test "x$LIBUNWIND" = "xyes"; then
1081     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1082     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1083 fi
1084
1085
1086 dnl Options for APIs
1087 AC_ARG_ENABLE([opengl],
1088     [AS_HELP_STRING([--disable-opengl],
1089         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1090     [enable_opengl="$enableval"],
1091     [enable_opengl=yes])
1092 AC_ARG_ENABLE([gles1],
1093     [AS_HELP_STRING([--disable-gles1],
1094         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1095     [enable_gles1="$enableval"],
1096     [enable_gles1=yes])
1097 AC_ARG_ENABLE([gles2],
1098     [AS_HELP_STRING([--disable-gles2],
1099         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1100     [enable_gles2="$enableval"],
1101     [enable_gles2=yes])
1102
1103 AC_ARG_ENABLE([dri],
1104     [AS_HELP_STRING([--enable-dri],
1105         [enable DRI modules @<:@default=enabled@:>@])],
1106     [enable_dri="$enableval"],
1107     [enable_dri=yes])
1108
1109 AC_ARG_ENABLE([gallium-extra-hud],
1110     [AS_HELP_STRING([--enable-gallium-extra-hud],
1111         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1112     [enable_gallium_extra_hud="$enableval"],
1113     [enable_gallium_extra_hud=no])
1114 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1115 if test "x$enable_gallium_extra_hud" = xyes ; then
1116     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1117 fi
1118
1119 #TODO: no pkgconfig .pc available for libsensors.
1120 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1121 AC_ARG_ENABLE([lmsensors],
1122     [AS_HELP_STRING([--enable-lmsensors],
1123         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1124     [enable_lmsensors="$enableval"],
1125     [enable_lmsensors=no])
1126 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1127 if test "x$enable_lmsensors" = xyes ; then
1128     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1129     LIBSENSORS_LIBS="-lsensors"
1130 else
1131     LIBSENSORS_LIBS=""
1132 fi
1133 AC_SUBST(LIBSENSORS_LIBS)
1134
1135 case "$host_os" in
1136 linux*)
1137     dri3_default=yes
1138     ;;
1139 *)
1140     dri3_default=no
1141     ;;
1142 esac
1143
1144 if test "x$enable_dri" = xno; then
1145     dri3_default=no
1146 fi
1147
1148 AC_ARG_ENABLE([dri3],
1149     [AS_HELP_STRING([--enable-dri3],
1150         [enable DRI3 @<:@default=auto@:>@])],
1151     [enable_dri3="$enableval"],
1152     [enable_dri3="$dri3_default"])
1153 AC_ARG_ENABLE([glx],
1154     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1155         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1156     [enable_glx="$enableval"],
1157     [enable_glx=yes])
1158 AC_ARG_ENABLE([osmesa],
1159     [AS_HELP_STRING([--enable-osmesa],
1160         [enable OSMesa library @<:@default=disabled@:>@])],
1161     [enable_osmesa="$enableval"],
1162     [enable_osmesa=no])
1163 AC_ARG_ENABLE([gallium-osmesa],
1164     [AS_HELP_STRING([--enable-gallium-osmesa],
1165         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1166     [enable_gallium_osmesa="$enableval"],
1167     [enable_gallium_osmesa=no])
1168 AC_ARG_ENABLE([egl],
1169     [AS_HELP_STRING([--disable-egl],
1170         [disable EGL library @<:@default=enabled@:>@])],
1171     [enable_egl="$enableval"],
1172     [enable_egl=yes])
1173
1174 AC_ARG_ENABLE([xa],
1175     [AS_HELP_STRING([--enable-xa],
1176         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1177     [enable_xa="$enableval"],
1178     [enable_xa=no])
1179 AC_ARG_ENABLE([gbm],
1180    [AS_HELP_STRING([--enable-gbm],
1181          [enable gbm library @<:@default=yes except cygwin@:>@])],
1182    [enable_gbm="$enableval"],
1183    [case "$host_os" in
1184        cygwin*)
1185           enable_gbm=no
1186           ;;
1187        *)
1188           enable_gbm=yes
1189           ;;
1190     esac])
1191 AC_ARG_ENABLE([nine],
1192     [AS_HELP_STRING([--enable-nine],
1193         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1194     [enable_nine="$enableval"],
1195     [enable_nine=no])
1196
1197 AC_ARG_ENABLE([xvmc],
1198    [AS_HELP_STRING([--enable-xvmc],
1199          [enable xvmc library @<:@default=auto@:>@])],
1200    [enable_xvmc="$enableval"],
1201    [enable_xvmc=auto])
1202 AC_ARG_ENABLE([vdpau],
1203    [AS_HELP_STRING([--enable-vdpau],
1204          [enable vdpau library @<:@default=auto@:>@])],
1205    [enable_vdpau="$enableval"],
1206    [enable_vdpau=auto])
1207 AC_ARG_ENABLE([omx],
1208    [AS_HELP_STRING([--enable-omx],
1209          [enable OpenMAX library @<:@default=disabled@:>@])],
1210    [enable_omx="$enableval"],
1211    [enable_omx=no])
1212 AC_ARG_ENABLE([va],
1213    [AS_HELP_STRING([--enable-va],
1214          [enable va library @<:@default=auto@:>@])],
1215    [enable_va="$enableval"],
1216    [enable_va=auto])
1217 AC_ARG_ENABLE([opencl],
1218    [AS_HELP_STRING([--enable-opencl],
1219          [enable OpenCL library @<:@default=disabled@:>@])],
1220    [enable_opencl="$enableval"],
1221    [enable_opencl=no])
1222 AC_ARG_ENABLE([opencl_icd],
1223    [AS_HELP_STRING([--enable-opencl-icd],
1224           [Build an OpenCL ICD library to be loaded by an ICD implementation
1225            @<:@default=disabled@:>@])],
1226     [enable_opencl_icd="$enableval"],
1227     [enable_opencl_icd=no])
1228
1229 AC_ARG_ENABLE([gallium-tests],
1230     [AS_HELP_STRING([--enable-gallium-tests],
1231         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1232     [enable_gallium_tests="$enableval"],
1233     [enable_gallium_tests=no])
1234
1235 # Option for Gallium drivers
1236
1237 # Keep this in sync with the --with-gallium-drivers help string default value
1238 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1239
1240 AC_ARG_WITH([gallium-drivers],
1241     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1242         [comma delimited Gallium drivers list, e.g.
1243         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1244         @<:@default=r300,r600,svga,swrast@:>@])],
1245     [with_gallium_drivers="$withval"],
1246     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1247
1248 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1249 # here so that the script doesn't choke on an unknown driver name later.
1250 case "$with_gallium_drivers" in
1251     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1252     no) with_gallium_drivers='' ;;
1253 esac
1254
1255 if test "x$enable_opengl" = xno -a \
1256         "x$enable_gles1" = xno -a \
1257         "x$enable_gles2" = xno -a \
1258         "x$enable_nine" = xno -a \
1259         "x$enable_xa" = xno -a \
1260         "x$enable_xvmc" = xno -a \
1261         "x$enable_vdpau" = xno -a \
1262         "x$enable_omx" = xno -a \
1263         "x$enable_va" = xno -a \
1264         "x$enable_opencl" = xno; then
1265     AC_MSG_ERROR([at least one API should be enabled])
1266 fi
1267
1268 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1269 if test "x$enable_opengl" = xno -a \
1270         "x$enable_gles1" = xyes; then
1271     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1272 fi
1273
1274 if test "x$enable_opengl" = xno -a \
1275         "x$enable_gles2" = xyes; then
1276     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1277 fi
1278
1279 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1280 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1282 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1283                                         "x$enable_gles1" = xyes -o \
1284                                         "x$enable_gles2" = xyes)
1285
1286 # Validate GLX options
1287 if test "x$enable_glx" = xyes; then
1288     if test "x$enable_dri" = xyes; then
1289         enable_glx=dri
1290     elif test -n "$with_gallium_drivers"; then
1291         enable_glx=gallium-xlib
1292     else
1293         enable_glx=xlib
1294     fi
1295 fi
1296 case "x$enable_glx" in
1297 xdri | xxlib | xgallium-xlib)
1298     # GLX requires OpenGL
1299     if test "x$enable_opengl" = xno; then
1300         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1301     fi
1302
1303     # Check individual dependencies
1304     case "x$enable_glx" in
1305     xdri)
1306         if test "x$enable_dri" = xno; then
1307             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1308         fi
1309         ;;
1310     xxlib)
1311         if test "x$enable_dri" = xyes; then
1312             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1313         fi
1314         ;;
1315     xgallium-xlib )
1316         if test "x$enable_dri" = xyes; then
1317             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1318         fi
1319         if test -z "$with_gallium_drivers"; then
1320             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1321         fi
1322         ;;
1323     esac
1324     ;;
1325 xno)
1326     ;;
1327 *)
1328     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1329     ;;
1330 esac
1331
1332 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1333 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1334 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1335 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1336
1337 DEFAULT_GL_LIB_NAME=GL
1338
1339 dnl
1340 dnl Libglvnd configuration
1341 dnl
1342 AC_ARG_ENABLE([libglvnd],
1343     [AS_HELP_STRING([--enable-libglvnd],
1344         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1345     [enable_libglvnd="$enableval"],
1346     [enable_libglvnd=no])
1347 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1348
1349 if test "x$enable_libglvnd" = xyes ; then
1350     dnl XXX: update once we can handle more than libGL/glx.
1351     dnl Namely: we should error out if neither of the glvnd enabled libraries
1352     dnl are built
1353     case "x$enable_glx" in
1354     xno)
1355         AC_MSG_ERROR([cannot build libglvnd without GLX])
1356         ;;
1357     xxlib | xgallium-xlib )
1358         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1359         ;;
1360     xdri)
1361         ;;
1362     esac
1363
1364     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1365     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1366     AC_SUBST([LIBGLVND_DATADIR])
1367
1368     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1369     DEFAULT_GL_LIB_NAME=GLX_mesa
1370 fi
1371
1372 AC_ARG_WITH([gl-lib-name],
1373   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1374     [specify GL library name @<:@default=GL@:>@])],
1375   [GL_LIB=$withval],
1376   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1377 AC_ARG_WITH([osmesa-lib-name],
1378   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1379     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1380   [OSMESA_LIB=$withval],
1381   [OSMESA_LIB=OSMesa])
1382 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1383 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1384
1385 dnl
1386 dnl Mangled Mesa support
1387 dnl
1388 AC_ARG_ENABLE([mangling],
1389   [AS_HELP_STRING([--enable-mangling],
1390     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1391   [enable_mangling="${enableval}"],
1392   [enable_mangling=no]
1393 )
1394 if test "x${enable_mangling}" = "xyes" ; then
1395   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1396   GL_LIB="Mangled${GL_LIB}"
1397   OSMESA_LIB="Mangled${OSMESA_LIB}"
1398 fi
1399 AC_SUBST([GL_LIB])
1400 AC_SUBST([OSMESA_LIB])
1401
1402 # Check for libdrm
1403 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1404                   [have_libdrm=yes], [have_libdrm=no])
1405 if test "x$have_libdrm" = xyes; then
1406         DEFINES="$DEFINES -DHAVE_LIBDRM"
1407 fi
1408
1409 require_libdrm() {
1410     if test "x$have_libdrm" != xyes; then
1411        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1412     fi
1413 }
1414
1415
1416 # Select which platform-dependent DRI code gets built
1417 case "$host_os" in
1418 darwin*)
1419     dri_platform='apple' ;;
1420 cygwin*)
1421     dri_platform='windows' ;;
1422 gnu*)
1423     dri_platform='none' ;;
1424 *)
1425     dri_platform='drm' ;;
1426 esac
1427
1428 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1429     have_drisw_kms='yes'
1430 fi
1431
1432 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1433 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1434 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1435 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1436 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1437 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1438 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1439 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1440 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1441
1442 AC_ARG_ENABLE([shared-glapi],
1443     [AS_HELP_STRING([--enable-shared-glapi],
1444         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1445     [enable_shared_glapi="$enableval"],
1446     [enable_shared_glapi=yes])
1447
1448 case "x$enable_opengl$enable_gles1$enable_gles2" in
1449 x*yes*yes*)
1450     if test "x$enable_shared_glapi" = xno; then
1451         AC_MSG_ERROR([shared GLAPI required when building two or more of
1452                       the following APIs - opengl, gles1 gles2])
1453     fi
1454     ;;
1455 esac
1456
1457 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1458
1459 # Build the pipe-drivers as separate libraries/modules.
1460 # Do not touch this unless you know what you are doing.
1461 # XXX: Expose via configure option ?
1462 enable_shared_pipe_drivers=no
1463
1464 dnl
1465 dnl Driver specific build directories
1466 dnl
1467
1468 if test "x$enable_gallium_osmesa" = xyes; then
1469     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1470         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1471     fi
1472     if test "x$enable_osmesa" = xyes; then
1473         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1474     fi
1475 fi
1476
1477 require_dri_shared_libs_and_glapi() {
1478     if test "x$enable_static" = xyes; then
1479         AC_MSG_ERROR([$1 cannot be build as static library])
1480     fi
1481
1482     if test "x$enable_dri" != xyes; then
1483         # There is only a single backend which won't be build/used otherwise.
1484         # XXX: Revisit this as the egl/haiku is a thing.
1485         AC_MSG_ERROR([$1 requires --enable-dri])
1486     fi
1487
1488     if test "x$enable_shared_glapi" != xyes; then
1489         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1490     fi
1491 }
1492
1493 if test "x$enable_dri" = xyes; then
1494     require_dri_shared_libs_and_glapi "DRI"
1495
1496     # not a hard requirement as swrast does not depend on it
1497     if test "x$have_libdrm" = xyes; then
1498         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1499     fi
1500 fi
1501
1502 AC_ARG_ENABLE([driglx-direct],
1503     [AS_HELP_STRING([--disable-driglx-direct],
1504         [disable direct rendering in GLX and EGL for DRI \
1505             @<:@default=auto@:>@])],
1506     [driglx_direct="$enableval"],
1507     [driglx_direct="yes"])
1508
1509 dnl
1510 dnl libGL configuration per driver
1511 dnl
1512 if test "x$enable_glx" != xno; then
1513     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1514 fi
1515 case "x$enable_glx" in
1516 xxlib | xgallium-xlib)
1517     # Xlib-based GLX
1518     dri_modules="x11 xext xcb"
1519     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1520     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1521     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1522     GL_LIB_DEPS="$XLIBGL_LIBS"
1523     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1524     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1525     ;;
1526 xdri)
1527     # DRI-based GLX
1528
1529     # find the DRI deps for libGL
1530     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1531
1532     if test x"$driglx_direct" = xyes; then
1533         if test x"$dri_platform" = xdrm ; then
1534             DEFINES="$DEFINES -DGLX_USE_DRM"
1535             require_libdrm "Direct rendering"
1536
1537             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1538             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1539             if test x"$enable_dri" = xyes; then
1540                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1541             fi
1542
1543             if test x"$enable_dri3" = xyes; then
1544                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1545                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1546                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1547             fi
1548         fi
1549         if test x"$dri_platform" = xapple ; then
1550             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1551         fi
1552         if test x"$dri_platform" = xwindows ; then
1553             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1554         fi
1555     fi
1556
1557     # add xf86vidmode if available
1558     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1559     if test "$HAVE_XF86VIDMODE" = yes ; then
1560         dri_modules="$dri_modules xxf86vm"
1561     fi
1562
1563     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1564     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1565     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1566     GL_LIB_DEPS="$DRIGL_LIBS"
1567
1568     # need DRM libs, $PTHREAD_LIBS, etc.
1569     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1570     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1571     ;;
1572 esac
1573
1574 # This is outside the case (above) so that it is invoked even for non-GLX
1575 # builds.
1576 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1577
1578 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1579 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1580 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1581 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1582
1583 AC_SUBST([X11_INCLUDES])
1584 AC_SUBST([GL_LIB_DEPS])
1585 AC_SUBST([GL_PC_REQ_PRIV])
1586 AC_SUBST([GL_PC_LIB_PRIV])
1587 AC_SUBST([GL_PC_CFLAGS])
1588 AC_SUBST([DRI_PC_REQ_PRIV])
1589 AC_SUBST([GLESv1_CM_LIB_DEPS])
1590 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1591 AC_SUBST([GLESv2_LIB_DEPS])
1592 AC_SUBST([GLESv2_PC_LIB_PRIV])
1593
1594 AC_SUBST([HAVE_XF86VIDMODE])
1595
1596 dnl
1597 dnl More GLX setup
1598 dnl
1599 case "x$enable_glx" in
1600 xxlib | xgallium-xlib)
1601     DEFINES="$DEFINES -DUSE_XSHM"
1602     ;;
1603 xdri)
1604     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1605     if test "x$driglx_direct" = xyes; then
1606         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1607     fi
1608     ;;
1609 esac
1610
1611 dnl
1612 dnl TLS detection
1613 dnl
1614
1615 AC_ARG_ENABLE([glx-tls],
1616     [AS_HELP_STRING([--enable-glx-tls],
1617         [enable TLS support in GLX @<:@default=enabled@:>@])],
1618     [GLX_USE_TLS="$enableval"],
1619     [GLX_USE_TLS=yes])
1620 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1621
1622 if test "x$GLX_USE_TLS" = xyes; then
1623     DEFINES="$DEFINES -DGLX_USE_TLS"
1624 fi
1625
1626 dnl Read-only text section on x86 hardened platforms
1627 AC_ARG_ENABLE([glx-read-only-text],
1628     [AS_HELP_STRING([--enable-glx-read-only-text],
1629         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1630     [enable_glx_read_only_text="$enableval"],
1631     [enable_glx_read_only_text=no])
1632 if test "x$enable_glx_read_only_text" = xyes; then
1633     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1634 fi
1635
1636 dnl
1637 dnl More DRI setup
1638 dnl
1639 dnl Directory for DRI drivers
1640 AC_ARG_WITH([dri-driverdir],
1641     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1642         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1643     [DRI_DRIVER_INSTALL_DIR="$withval"],
1644     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1645 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1646 dnl Extra search path for DRI drivers
1647 AC_ARG_WITH([dri-searchpath],
1648     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1649         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1650     [DRI_DRIVER_SEARCH_DIR="$withval"],
1651     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1652 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1653 dnl Which drivers to build - default is chosen by platform
1654 AC_ARG_WITH([dri-drivers],
1655     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1656         [comma delimited classic DRI drivers list, e.g.
1657         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1658     [with_dri_drivers="$withval"],
1659     [with_dri_drivers=auto])
1660
1661 if test "x$with_dri_drivers" = xauto; then
1662     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1663         with_dri_drivers="yes"
1664     else
1665         with_dri_drivers="no"
1666     fi
1667 fi
1668 if test "x$with_dri_drivers" = xno; then
1669     with_dri_drivers=''
1670 fi
1671
1672 dnl If $with_dri_drivers is yes, drivers will be added through
1673 dnl platform checks. Set DEFINES and LIB_DEPS
1674 if test "x$enable_dri" = xyes; then
1675     # Platform specific settings and drivers to build
1676     case "$host_os" in
1677     linux*)
1678         if test "x$enable_dri3" = xyes; then
1679             DEFINES="$DEFINES -DHAVE_DRI3"
1680         fi
1681
1682         case "$host_cpu" in
1683         powerpc* | sparc*)
1684             # Build only the drivers for cards that exist on PowerPC/sparc
1685             if test "x$with_dri_drivers" = "xyes"; then
1686                 with_dri_drivers="r200 radeon swrast"
1687             fi
1688             ;;
1689         esac
1690         ;;
1691     cygwin*)
1692         if test "x$with_dri_drivers" = "xyes"; then
1693             with_dri_drivers="swrast"
1694         fi
1695         ;;
1696     darwin*)
1697         DEFINES="$DEFINES -DBUILDING_MESA"
1698         if test "x$with_dri_drivers" = "xyes"; then
1699             with_dri_drivers="swrast"
1700         fi
1701         ;;
1702     esac
1703
1704     # default drivers
1705     if test "x$with_dri_drivers" = "xyes"; then
1706         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1707     fi
1708
1709     # Check for expat
1710     PKG_CHECK_MODULES([EXPAT], [expat], [],
1711         # expat version 2.0 and earlier do not provide expat.pc
1712         [AC_CHECK_HEADER([expat.h],[],
1713                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1714          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1715                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1716          EXPAT_LIBS="-lexpat"])
1717
1718     # put all the necessary libs together
1719     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1720 fi
1721
1722 AC_SUBST([DRI_LIB_DEPS])
1723
1724 DRI_DIRS=''
1725 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1726 if test -n "$with_dri_drivers"; then
1727     if test "x$enable_opengl" != xyes; then
1728         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1729     fi
1730
1731     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1732     for driver in $dri_drivers; do
1733         DRI_DIRS="$DRI_DIRS $driver"
1734         case "x$driver" in
1735         xi915)
1736             require_libdrm "i915"
1737             HAVE_I915_DRI=yes
1738             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1739             ;;
1740         xi965)
1741             require_libdrm "i965"
1742             HAVE_I965_DRI=yes
1743             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1744             ;;
1745         xnouveau)
1746             require_libdrm "nouveau"
1747             HAVE_NOUVEAU_DRI=yes
1748             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1749             ;;
1750         xradeon)
1751             require_libdrm "radeon"
1752             HAVE_RADEON_DRI=yes;
1753             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1754             ;;
1755         xr200)
1756             require_libdrm "r200"
1757             HAVE_R200_DRI=yes
1758             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1759             ;;
1760         xswrast)
1761             HAVE_SWRAST_DRI=yes
1762             ;;
1763         *)
1764             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1765             ;;
1766         esac
1767     done
1768     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1769 fi
1770
1771
1772 dnl
1773 dnl Gallium LLVM
1774 dnl Deprecated: kept for backwards compatibility
1775 dnl
1776 AC_ARG_ENABLE([gallium-llvm],
1777     [AS_HELP_STRING([--enable-gallium-llvm],
1778         [DEPRECATED: use --enable-llvm instead])],
1779     [enable_gallium_llvm="$enableval"],
1780     [enable_gallium_llvm=auto])
1781
1782 if test "x$enable_gallium_llvm" != xauto; then
1783    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1784    enable_llvm=$enable_gallium_llvm
1785 fi
1786
1787 dnl
1788 dnl LLVM
1789 dnl
1790 AC_ARG_ENABLE([llvm],
1791     [AS_HELP_STRING([--enable-llvm],
1792         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1793     [enable_llvm="$enableval"],
1794     [enable_llvm=auto])
1795
1796 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1797     if test "x$FOUND_LLVM" = xyes; then
1798         case "$host_cpu" in
1799         i*86|x86_64|amd64) enable_llvm=yes;;
1800         *) enable_llvm=no;;
1801         esac
1802     else
1803         enable_llvm=no
1804     fi
1805 fi
1806
1807 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1808     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1809 fi
1810
1811 #
1812 # Vulkan driver configuration
1813 #
1814
1815 AC_ARG_WITH([vulkan-drivers],
1816     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1817         [comma delimited Vulkan drivers list, e.g.
1818         "intel,radeon"
1819         @<:@default=no@:>@])],
1820     [with_vulkan_drivers="$withval"],
1821     [with_vulkan_drivers="no"])
1822
1823 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1824 # here so that the script doesn't choke on an unknown driver name later.
1825 case "x$with_vulkan_drivers" in
1826     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1827     xno) with_vulkan_drivers='' ;;
1828 esac
1829
1830 AC_ARG_WITH([vulkan-icddir],
1831     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1832         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1833     [VULKAN_ICD_INSTALL_DIR="$withval"],
1834     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1835 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1836
1837 if test -n "$with_vulkan_drivers"; then
1838     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1839         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1840     fi
1841
1842     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1843     for driver in $VULKAN_DRIVERS; do
1844         case "x$driver" in
1845         xintel)
1846             require_libdrm "ANV"
1847             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1848             HAVE_INTEL_VULKAN=yes
1849             ;;
1850         xradeon)
1851             require_libdrm "radv"
1852             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1853             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1854             HAVE_RADEON_VULKAN=yes
1855             ;;
1856         *)
1857             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1858             ;;
1859         esac
1860     done
1861     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1862 fi
1863
1864
1865 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1866 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1867 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1868                                   "x$enable_osmesa" = xyes -o \
1869                                   -n "$DRI_DIRS")
1870
1871 dnl
1872 dnl OSMesa configuration
1873 dnl
1874
1875 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1876 AC_ARG_WITH([osmesa-bits],
1877     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1878         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1879     [osmesa_bits="$withval"],
1880     [osmesa_bits=8])
1881 if test "x$osmesa_bits" != x8; then
1882     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1883         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1884         osmesa_bits=8
1885     fi
1886 fi
1887 case "x$osmesa_bits" in
1888 x8)
1889     OSMESA_LIB="${OSMESA_LIB}"
1890     ;;
1891 x16|x32)
1892     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1893     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1894     ;;
1895 *)
1896     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1897     ;;
1898 esac
1899
1900 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1901     # only link libraries with osmesa if shared
1902     if test "$enable_static" = no; then
1903         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1904     else
1905         OSMESA_LIB_DEPS=""
1906     fi
1907     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1908 fi
1909
1910 AC_SUBST([OSMESA_LIB_DEPS])
1911 AC_SUBST([OSMESA_PC_REQ])
1912 AC_SUBST([OSMESA_PC_LIB_PRIV])
1913
1914 dnl
1915 dnl gbm configuration
1916 dnl
1917 if test "x$enable_gbm" = xyes; then
1918     require_dri_shared_libs_and_glapi "gbm"
1919 fi
1920 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1921 # FINISHME: GBM has a number of dependencies which we should add below
1922 GBM_PC_REQ_PRIV=""
1923 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1924 AC_SUBST([GBM_PC_REQ_PRIV])
1925 AC_SUBST([GBM_PC_LIB_PRIV])
1926
1927 dnl
1928 dnl EGL configuration
1929 dnl
1930
1931 if test "x$enable_egl" = xyes; then
1932     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1933
1934     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1935
1936     require_dri_shared_libs_and_glapi "egl"
1937 fi
1938 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1939 AC_SUBST([EGL_LIB_DEPS])
1940
1941 gallium_st="mesa"
1942
1943 dnl
1944 dnl XA configuration
1945 dnl
1946 if test "x$enable_xa" = xyes; then
1947     if test "x$with_gallium_drivers" = xswrast; then
1948        AC_MSG_ERROR([
1949           Building xa requires at least one non swrast gallium driver.
1950           If you are looking to use libxatracker.so with the VMware driver,
1951           make sure to include svga in the gallium drivers list, apart from
1952           enabling XA.
1953           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1954     fi
1955     gallium_st="$gallium_st xa"
1956 fi
1957 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1958
1959 dnl
1960 dnl Gallium G3DVL configuration
1961 dnl
1962 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1963     if test "x$enable_xvmc" = xauto; then
1964         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1965     fi
1966
1967     if test "x$enable_vdpau" = xauto; then
1968         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1969     fi
1970
1971     if test "x$enable_omx" = xauto; then
1972         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1973     fi
1974
1975     if test "x$enable_va" = xauto; then
1976         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1977     fi
1978 fi
1979
1980 if test "x$enable_dri" = xyes -o \
1981         "x$enable_xvmc" = xyes -o \
1982         "x$enable_vdpau" = xyes -o \
1983         "x$enable_omx" = xyes -o \
1984         "x$enable_va" = xyes; then
1985     need_gallium_vl=yes
1986 fi
1987 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1988
1989 if test "x$enable_xvmc" = xyes -o \
1990         "x$enable_vdpau" = xyes -o \
1991         "x$enable_omx" = xyes -o \
1992         "x$enable_va" = xyes; then
1993     if test x"$enable_dri3" = xyes; then
1994         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1995                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1996     else
1997         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1998     fi
1999     need_gallium_vl_winsys=yes
2000 fi
2001 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2002
2003 if test "x$enable_xvmc" = xyes; then
2004     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2005     gallium_st="$gallium_st xvmc"
2006 fi
2007 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2008
2009 if test "x$enable_vdpau" = xyes; then
2010     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2011     gallium_st="$gallium_st vdpau"
2012     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2013 fi
2014 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2015
2016 if test "x$enable_omx" = xyes; then
2017     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2018     gallium_st="$gallium_st omx"
2019 fi
2020 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2021
2022 if test "x$enable_va" = xyes; then
2023     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2024     gallium_st="$gallium_st va"
2025 fi
2026 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2027
2028 dnl
2029 dnl Nine Direct3D9 configuration
2030 dnl
2031 if test "x$enable_nine" = xyes; then
2032     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2033         AC_MSG_ERROR([nine requires the gallium swrast driver])
2034     fi
2035     if test "x$with_gallium_drivers" = xswrast; then
2036         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2037     fi
2038     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2039         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2040     fi
2041
2042     if test "x$enable_dri3" = xno; then
2043         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2044     fi
2045
2046     gallium_st="$gallium_st nine"
2047 fi
2048 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2049
2050 dnl
2051 dnl OpenCL configuration
2052 dnl
2053
2054 AC_ARG_WITH([clang-libdir],
2055    [AS_HELP_STRING([--with-clang-libdir],
2056          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2057    [CLANG_LIBDIR="$withval"],
2058    [CLANG_LIBDIR=''])
2059
2060 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2061
2062 if test "x$enable_opencl" = xyes; then
2063     if test -z "$with_gallium_drivers"; then
2064         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2065     fi
2066
2067     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2068         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2069     fi
2070
2071     if test "x$have_libclc" = xno; then
2072         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2073                     Make sure the directory containing libclc.pc is specified in your
2074                     PKG_CONFIG_PATH environment variable.
2075                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2076     else
2077         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2078         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2079         AC_SUBST([LIBCLC_INCLUDEDIR])
2080         AC_SUBST([LIBCLC_LIBEXECDIR])
2081     fi
2082
2083     gallium_st="$gallium_st clover"
2084
2085     if test "x$enable_opencl_icd" = xyes; then
2086         OPENCL_LIBNAME="MesaOpenCL"
2087     else
2088         OPENCL_LIBNAME="OpenCL"
2089     fi
2090
2091     if test "x$have_libelf" != xyes; then
2092        AC_MSG_ERROR([Clover requires libelf])
2093     fi
2094
2095     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2096         altivec_enabled=no
2097         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2098         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2099         #error "AltiVec not enabled"
2100         #endif
2101         ])], altivec_enabled=yes)
2102
2103         if test "$altivec_enabled" = yes; then
2104             CLOVER_STD_OVERRIDE="-std=gnu++11"
2105         fi
2106         AC_SUBST([CLOVER_STD_OVERRIDE])
2107     fi
2108
2109     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2110
2111     llvm_add_default_components "opencl"
2112     llvm_add_component "all-targets" "opencl"
2113     llvm_add_component "linker" "opencl"
2114     llvm_add_component "instrumentation" "opencl"
2115     llvm_add_component "ipo" "opencl"
2116     llvm_add_component "irreader" "opencl"
2117     llvm_add_component "option" "opencl"
2118     llvm_add_component "objcarcopts" "opencl"
2119     llvm_add_component "profiledata" "opencl"
2120
2121     dnl Check for Clang internal headers
2122     if test -z "$CLANG_LIBDIR"; then
2123         CLANG_LIBDIR=${LLVM_LIBDIR}
2124     fi
2125     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2126     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2127         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2128 fi
2129 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2130 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2131 AC_SUBST([OPENCL_LIBNAME])
2132 AC_SUBST([CLANG_RESOURCE_DIR])
2133
2134 dnl
2135 dnl Gallium configuration
2136 dnl
2137 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2138
2139 dnl
2140 dnl DEPRECATED: EGL Platforms configuration
2141 dnl
2142 AC_ARG_WITH([egl-platforms],
2143     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2144         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
2145     [with_egl_platforms="$withval"],
2146     [with_egl_platforms=auto])
2147
2148 if test "x$with_egl_platforms" = xauto; then
2149     if test "x$enable_egl" = xyes; then
2150         if test "x$enable_gbm" = xyes; then
2151            with_egl_platforms="x11,drm"
2152         else
2153            with_egl_platforms="x11"
2154         fi
2155     else
2156         with_egl_platforms=""
2157     fi
2158 else
2159     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
2160 fi
2161
2162 dnl
2163 dnl Platforms configuration
2164 dnl
2165 AC_ARG_WITH([platforms],
2166     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
2167         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
2168         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
2169     [with_platforms="$withval"],
2170     [with_platforms=auto])
2171
2172 # For the time being, we still reuse the EGL named variables/defines.
2173 if test "x$with_platforms" != xauto; then
2174     with_egl_platforms=$with_platforms
2175 fi
2176
2177 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2178         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2179         WAYLAND_SCANNER='')
2180 if test "x$WAYLAND_SCANNER" = x; then
2181     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
2182 fi
2183
2184 # Do per-EGL platform setups and checks
2185 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2186 for plat in $egl_platforms; do
2187         case "$plat" in
2188         wayland)
2189
2190                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2191
2192                 if test "x$WAYLAND_SCANNER" = "x:"; then
2193                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2194                 fi
2195                 ;;
2196
2197         x11)
2198                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2199                 ;;
2200
2201         drm)
2202                 test "x$enable_gbm" = "xno" &&
2203                         AC_MSG_ERROR([EGL platform drm needs gbm])
2204                 ;;
2205
2206         surfaceless)
2207                 ;;
2208
2209         android)
2210                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2211                 ;;
2212
2213         *)
2214                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2215                 ;;
2216         esac
2217
2218         case "$plat" in
2219         wayland|drm|surfaceless)
2220                 require_libdrm "Platform $plat"
2221                 ;;
2222         esac
2223 done
2224
2225 # libEGL wants to default to the first platform specified in
2226 # ./configure.  parse that here.
2227 if test "x$egl_platforms" != "x"; then
2228     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2229     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2230 else
2231     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2232 fi
2233
2234 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2235 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2236 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2237 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2238 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2239
2240 AC_SUBST([EGL_NATIVE_PLATFORM])
2241 AC_SUBST([EGL_CFLAGS])
2242
2243 # If we don't have the X11 platform, set this define so we don't try to include
2244 # the X11 headers.
2245 if ! echo "$egl_platforms" | grep -q 'x11'; then
2246     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2247     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2248 fi
2249
2250 dnl Directory for XVMC libs
2251 AC_ARG_WITH([xvmc-libdir],
2252     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2253         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2254     [XVMC_LIB_INSTALL_DIR="$withval"],
2255     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2256 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2257
2258 dnl
2259 dnl Gallium Tests
2260 dnl
2261 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2262
2263 dnl Directory for VDPAU libs
2264 AC_ARG_WITH([vdpau-libdir],
2265     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2266         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2267     [VDPAU_LIB_INSTALL_DIR="$withval"],
2268     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2269 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2270
2271 dnl Directory for OMX libs
2272
2273 AC_ARG_WITH([omx-libdir],
2274     [AS_HELP_STRING([--with-omx-libdir=DIR],
2275         [directory for the OMX libraries])],
2276     [OMX_LIB_INSTALL_DIR="$withval"],
2277     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2278                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2279 AC_SUBST([OMX_LIB_INSTALL_DIR])
2280
2281 dnl Directory for VA libs
2282
2283 AC_ARG_WITH([va-libdir],
2284     [AS_HELP_STRING([--with-va-libdir=DIR],
2285         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2286     [VA_LIB_INSTALL_DIR="$withval"],
2287     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2288 AC_SUBST([VA_LIB_INSTALL_DIR])
2289
2290 AC_ARG_WITH([d3d-libdir],
2291     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2292         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2293     [D3D_DRIVER_INSTALL_DIR="$withval"],
2294     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2295 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2296
2297 dnl
2298 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2299 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2300 dnl architectures.
2301 dnl
2302 r300_require_llvm() {
2303     case "$host" in *gnux32) return;; esac
2304     case "$host_cpu" in
2305     i*86|x86_64|amd64) require_llvm $1
2306         ;;
2307     esac
2308 }
2309
2310 dnl
2311 dnl DRM is needed by X, Wayland, and offscreen rendering.
2312 dnl Surfaceless is an alternative for the last one.
2313 dnl
2314 require_basic_egl() {
2315     case "$with_egl_platforms" in
2316         *drm*|*surfaceless*)
2317             ;;
2318         *)
2319             AC_MSG_ERROR([$1 requires one of these:
2320                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2321                   2) --with-platforms=surfaceless (offscreen only)
2322                   Recommended options: drm,x11])
2323             ;;
2324     esac
2325 }
2326
2327 swr_require_cxx_feature_flags() {
2328     feature_name="$1"
2329     preprocessor_test="$2"
2330     option_list="$3"
2331     output_var="$4"
2332
2333     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2334     AC_LANG_PUSH([C++])
2335     save_CXXFLAGS="$CXXFLAGS"
2336     save_IFS="$IFS"
2337     IFS=","
2338     found=0
2339     for opts in $option_list
2340     do
2341         unset IFS
2342         CXXFLAGS="$opts $save_CXXFLAGS"
2343         AC_COMPILE_IFELSE(
2344             [AC_LANG_PROGRAM(
2345                 [   #if !($preprocessor_test)
2346                     #error
2347                     #endif
2348                 ])],
2349             [found=1; break],
2350             [])
2351         IFS=","
2352     done
2353     IFS="$save_IFS"
2354     CXXFLAGS="$save_CXXFLAGS"
2355     AC_LANG_POP([C++])
2356     if test $found -eq 1; then
2357         AC_MSG_RESULT([$opts])
2358         eval "$output_var=\$opts"
2359         return 0
2360     fi
2361     AC_MSG_RESULT([no])
2362     AC_MSG_ERROR([swr requires $feature_name support])
2363     return 1
2364 }
2365
2366 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2367 if test -n "$with_gallium_drivers"; then
2368     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2369     for driver in $gallium_drivers; do
2370         case "x$driver" in
2371         xsvga)
2372             HAVE_GALLIUM_SVGA=yes
2373             require_libdrm "svga"
2374             ;;
2375         xi915)
2376             HAVE_GALLIUM_I915=yes
2377             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2378             require_libdrm "Gallium i915"
2379             ;;
2380         xr300)
2381             HAVE_GALLIUM_R300=yes
2382             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2383             require_libdrm "r300"
2384             r300_require_llvm "r300"
2385             ;;
2386         xr600)
2387             HAVE_GALLIUM_R600=yes
2388             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2389             require_libdrm "r600"
2390             if test "x$enable_llvm" = xyes; then
2391                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2392
2393                 llvm_add_component "asmparser" "r600"
2394                 llvm_add_component "bitreader" "r600"
2395             fi
2396             ;;
2397         xradeonsi)
2398             HAVE_GALLIUM_RADEONSI=yes
2399             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2400             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2401             require_libdrm "radeonsi"
2402             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2403             if test "x$enable_egl" = xyes; then
2404                 require_basic_egl "radeonsi"
2405             fi
2406             ;;
2407         xnouveau)
2408             HAVE_GALLIUM_NOUVEAU=yes
2409             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2410             require_libdrm "nouveau"
2411             ;;
2412         xfreedreno)
2413             HAVE_GALLIUM_FREEDRENO=yes
2414             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2415             require_libdrm "freedreno"
2416             ;;
2417         xetnaviv)
2418             HAVE_GALLIUM_ETNAVIV=yes
2419             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2420             require_libdrm "etnaviv"
2421             ;;
2422        ximx)
2423             HAVE_GALLIUM_IMX=yes
2424             ;;
2425         xswrast)
2426             HAVE_GALLIUM_SOFTPIPE=yes
2427             if test "x$enable_llvm" = xyes; then
2428                 HAVE_GALLIUM_LLVMPIPE=yes
2429             fi
2430             ;;
2431         xswr)
2432             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2433
2434             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2435                 "-std=c++14" \
2436                 SWR_CXX14_CXXFLAGS
2437             AC_SUBST([SWR_CXX14_CXXFLAGS])
2438
2439             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2440                 ",-mavx,-march=core-avx" \
2441                 SWR_AVX_CXXFLAGS
2442             AC_SUBST([SWR_AVX_CXXFLAGS])
2443
2444             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2445                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2446                 SWR_AVX2_CXXFLAGS
2447             AC_SUBST([SWR_AVX2_CXXFLAGS])
2448
2449             HAVE_GALLIUM_SWR=yes
2450             ;;
2451         xvc4)
2452             HAVE_GALLIUM_VC4=yes
2453             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2454             require_libdrm "vc4"
2455
2456             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2457                               [USE_VC4_SIMULATOR=yes;
2458                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2459                               [USE_VC4_SIMULATOR=no])
2460             ;;
2461         xvirgl)
2462             HAVE_GALLIUM_VIRGL=yes
2463             require_libdrm "virgl"
2464             if test "x$enable_egl" = xyes; then
2465                 require_basic_egl "virgl"
2466             fi
2467             ;;
2468         *)
2469             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2470             ;;
2471         esac
2472     done
2473 fi
2474
2475 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2476     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2477     llvm_add_default_components "gallium"
2478 fi
2479
2480 dnl We need to validate some needed dependencies for renderonly drivers.
2481
2482 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2483     AC_MSG_ERROR([Building with imx requires etnaviv])
2484 fi
2485
2486 dnl
2487 dnl Set defines and buildtime variables only when using LLVM.
2488 dnl
2489 if test "x$enable_llvm" = xyes; then
2490     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2491
2492     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2493     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2494     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2495
2496     dnl Set LLVM_LIBS - This is done after the driver configuration so
2497     dnl that drivers can add additional components to LLVM_COMPONENTS.
2498     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2499     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2500     dnl this was causing the same libraries to be appear multiple times
2501     dnl in LLVM_LIBS.
2502
2503     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2504        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2505     fi
2506     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2507
2508     dnl llvm-config may not give the right answer when llvm is a built as a
2509     dnl single shared library, so we must work the library name out for
2510     dnl ourselves.
2511     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2512     if test "x$enable_llvm_shared_libs" = xyes; then
2513         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2514         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2515         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2516
2517         if test "x$llvm_have_one_so" = xyes; then
2518             dnl LLVM was built using auto*, so there is only one shared object.
2519             LLVM_LIBS="-l$LLVM_SO_NAME"
2520         else
2521             dnl If LLVM was built with CMake, there will be one shared object per
2522             dnl component.
2523             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2524                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2525         Please make sure you have built llvm with the --enable-shared option
2526         and that your llvm libraries are installed in $LLVM_LIBDIR
2527         If you have installed your llvm libraries to a different directory you
2528         can use the --with-llvm-prefix= configure flag to specify this directory.
2529         NOTE: Mesa is attempting to use llvm shared libraries by default.
2530         If you do not want to build with llvm shared libraries and instead want to
2531         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2532         invocation and rebuild.])])
2533
2534            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2535            dnl install uses a shared object for each component and we have
2536            dnl already added all of these objects to LLVM_LIBS.
2537         fi
2538     else
2539         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2540         dnl We need to link to llvm system libs when using static libs
2541         dnl However, only llvm 3.5+ provides --system-libs
2542         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2543             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2544         fi
2545     fi
2546 fi
2547
2548 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2550 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2554                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2557 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2558 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2560 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2563                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2564                                          "x$HAVE_GALLIUM_SWR" = xyes)
2565 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2566 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2567
2568 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2569
2570 if test "x$enable_dri" = xyes; then
2571     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2572 fi
2573
2574 if test "x$have_drisw_kms" = xyes; then
2575     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2576 fi
2577 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2578
2579 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2580 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2581 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2582 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2583 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2584 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2585
2586 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2587 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2588
2589 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2590                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2591                                       "x$HAVE_RADEON_VULKAN" = xyes)
2592
2593 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2594                                         "x$HAVE_I965_DRI" = xyes)
2595
2596 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2597                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2598                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2599 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2600 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2601 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2602 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2603
2604 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2605 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2606 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2607 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2608                                         "x$enable_gallium_osmesa" = xyes)
2609
2610 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2611 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2612 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2613
2614 AC_SUBST([NINE_MAJOR], 1)
2615 AC_SUBST([NINE_MINOR], 0)
2616 AC_SUBST([NINE_TINY], 0)
2617 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2618
2619 AC_SUBST([VDPAU_MAJOR], 1)
2620 AC_SUBST([VDPAU_MINOR], 0)
2621
2622 if test "x$enable_va" = xyes; then
2623     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2624     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2625 fi
2626 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2627 AC_SUBST([VA_MINOR], $VA_MINOR)
2628
2629 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2630
2631 AC_SUBST([XVMC_MAJOR], 1)
2632 AC_SUBST([XVMC_MINOR], 0)
2633
2634 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2635 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2636 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2637 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2638
2639 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2640 AC_SUBST([XA_MINOR], $XA_MINOR)
2641 AC_SUBST([XA_TINY], $XA_TINY)
2642 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2643
2644 AC_ARG_ENABLE(valgrind,
2645               [AS_HELP_STRING([--enable-valgrind],
2646                              [Build mesa with valgrind support (default: auto)])],
2647                              [VALGRIND=$enableval], [VALGRIND=auto])
2648 if test "x$VALGRIND" != xno; then
2649         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2650 fi
2651 AC_MSG_CHECKING([whether to enable Valgrind support])
2652 if test "x$VALGRIND" = xauto; then
2653         VALGRIND="$have_valgrind"
2654 fi
2655
2656 if test "x$VALGRIND" = "xyes"; then
2657         if ! test "x$have_valgrind" = xyes; then
2658                 AC_MSG_ERROR([Valgrind support required but not present])
2659         fi
2660         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2661 fi
2662
2663 AC_MSG_RESULT([$VALGRIND])
2664
2665 dnl Restore LDFLAGS and CPPFLAGS
2666 LDFLAGS="$_SAVE_LDFLAGS"
2667 CPPFLAGS="$_SAVE_CPPFLAGS"
2668
2669 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2670 if test "x$acv_mesa_CLANG" = xyes; then
2671     CFLAGS="$CFLAGS -Qunused-arguments"
2672     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2673 fi
2674
2675 dnl Add user CFLAGS and CXXFLAGS
2676 CFLAGS="$CFLAGS $USER_CFLAGS"
2677 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2678
2679 dnl Substitute the config
2680 AC_CONFIG_FILES([Makefile
2681                 src/Makefile
2682                 src/amd/Makefile
2683                 src/amd/vulkan/Makefile
2684                 src/compiler/Makefile
2685                 src/egl/Makefile
2686                 src/egl/main/egl.pc
2687                 src/egl/wayland/wayland-drm/Makefile
2688                 src/egl/wayland/wayland-egl/Makefile
2689                 src/egl/wayland/wayland-egl/wayland-egl.pc
2690                 src/gallium/Makefile
2691                 src/gallium/auxiliary/Makefile
2692                 src/gallium/auxiliary/pipe-loader/Makefile
2693                 src/gallium/drivers/freedreno/Makefile
2694                 src/gallium/drivers/ddebug/Makefile
2695                 src/gallium/drivers/i915/Makefile
2696                 src/gallium/drivers/llvmpipe/Makefile
2697                 src/gallium/drivers/noop/Makefile
2698                 src/gallium/drivers/nouveau/Makefile
2699                 src/gallium/drivers/r300/Makefile
2700                 src/gallium/drivers/r600/Makefile
2701                 src/gallium/drivers/radeon/Makefile
2702                 src/gallium/drivers/radeonsi/Makefile
2703                 src/gallium/drivers/rbug/Makefile
2704                 src/gallium/drivers/softpipe/Makefile
2705                 src/gallium/drivers/svga/Makefile
2706                 src/gallium/drivers/swr/Makefile
2707                 src/gallium/drivers/trace/Makefile
2708                 src/gallium/drivers/etnaviv/Makefile
2709                 src/gallium/drivers/imx/Makefile
2710                 src/gallium/drivers/vc4/Makefile
2711                 src/gallium/drivers/virgl/Makefile
2712                 src/gallium/state_trackers/clover/Makefile
2713                 src/gallium/state_trackers/dri/Makefile
2714                 src/gallium/state_trackers/glx/xlib/Makefile
2715                 src/gallium/state_trackers/nine/Makefile
2716                 src/gallium/state_trackers/omx/Makefile
2717                 src/gallium/state_trackers/osmesa/Makefile
2718                 src/gallium/state_trackers/va/Makefile
2719                 src/gallium/state_trackers/vdpau/Makefile
2720                 src/gallium/state_trackers/xa/Makefile
2721                 src/gallium/state_trackers/xvmc/Makefile
2722                 src/gallium/targets/d3dadapter9/Makefile
2723                 src/gallium/targets/d3dadapter9/d3d.pc
2724                 src/gallium/targets/dri/Makefile
2725                 src/gallium/targets/libgl-xlib/Makefile
2726                 src/gallium/targets/omx/Makefile
2727                 src/gallium/targets/opencl/Makefile
2728                 src/gallium/targets/opencl/mesa.icd
2729                 src/gallium/targets/osmesa/Makefile
2730                 src/gallium/targets/osmesa/osmesa.pc
2731                 src/gallium/targets/pipe-loader/Makefile
2732                 src/gallium/targets/va/Makefile
2733                 src/gallium/targets/vdpau/Makefile
2734                 src/gallium/targets/xa/Makefile
2735                 src/gallium/targets/xa/xatracker.pc
2736                 src/gallium/targets/xvmc/Makefile
2737                 src/gallium/tests/trivial/Makefile
2738                 src/gallium/tests/unit/Makefile
2739                 src/gallium/winsys/etnaviv/drm/Makefile
2740                 src/gallium/winsys/imx/drm/Makefile
2741                 src/gallium/winsys/freedreno/drm/Makefile
2742                 src/gallium/winsys/i915/drm/Makefile
2743                 src/gallium/winsys/nouveau/drm/Makefile
2744                 src/gallium/winsys/radeon/drm/Makefile
2745                 src/gallium/winsys/amdgpu/drm/Makefile
2746                 src/gallium/winsys/svga/drm/Makefile
2747                 src/gallium/winsys/sw/dri/Makefile
2748                 src/gallium/winsys/sw/kms-dri/Makefile
2749                 src/gallium/winsys/sw/null/Makefile
2750                 src/gallium/winsys/sw/wrapper/Makefile
2751                 src/gallium/winsys/sw/xlib/Makefile
2752                 src/gallium/winsys/vc4/drm/Makefile
2753                 src/gallium/winsys/virgl/drm/Makefile
2754                 src/gallium/winsys/virgl/vtest/Makefile
2755                 src/gbm/Makefile
2756                 src/gbm/main/gbm.pc
2757                 src/glx/Makefile
2758                 src/glx/apple/Makefile
2759                 src/glx/tests/Makefile
2760                 src/glx/windows/Makefile
2761                 src/glx/windows/windowsdriproto.pc
2762                 src/gtest/Makefile
2763                 src/intel/Makefile
2764                 src/loader/Makefile
2765                 src/mapi/Makefile
2766                 src/mapi/es1api/glesv1_cm.pc
2767                 src/mapi/es2api/glesv2.pc
2768                 src/mapi/glapi/gen/Makefile
2769                 src/mesa/Makefile
2770                 src/mesa/gl.pc
2771                 src/mesa/drivers/dri/dri.pc
2772                 src/mesa/drivers/dri/common/Makefile
2773                 src/mesa/drivers/dri/common/xmlpool/Makefile
2774                 src/mesa/drivers/dri/i915/Makefile
2775                 src/mesa/drivers/dri/i965/Makefile
2776                 src/mesa/drivers/dri/Makefile
2777                 src/mesa/drivers/dri/nouveau/Makefile
2778                 src/mesa/drivers/dri/r200/Makefile
2779                 src/mesa/drivers/dri/radeon/Makefile
2780                 src/mesa/drivers/dri/swrast/Makefile
2781                 src/mesa/drivers/osmesa/Makefile
2782                 src/mesa/drivers/osmesa/osmesa.pc
2783                 src/mesa/drivers/x11/Makefile
2784                 src/mesa/main/tests/Makefile
2785                 src/util/Makefile
2786                 src/util/tests/hash_table/Makefile
2787                 src/vulkan/Makefile])
2788
2789 AC_OUTPUT
2790
2791 # Fix up dependencies in *.Plo files, where we changed the extension of a
2792 # source file
2793 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2794
2795
2796 dnl
2797 dnl Output some configuration info for the user
2798 dnl
2799 echo ""
2800 echo "        prefix:          $prefix"
2801 echo "        exec_prefix:     $exec_prefix"
2802 echo "        libdir:          $libdir"
2803 echo "        includedir:      $includedir"
2804
2805 dnl API info
2806 echo ""
2807 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2808
2809 dnl Driver info
2810 echo ""
2811 case "x$enable_osmesa$enable_gallium_osmesa" in
2812 xnoyes)
2813         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2814         ;;
2815 xyesno)
2816         echo "        OSMesa:          lib$OSMESA_LIB"
2817         ;;
2818 xnono)
2819         echo "        OSMesa:          no"
2820         ;;
2821 esac
2822
2823 echo ""
2824 if test "x$enable_dri" != xno; then
2825         echo "        DRI platform:    $dri_platform"
2826         if test -z "$DRI_DIRS"; then
2827             echo "        DRI drivers:     no"
2828         else
2829             echo "        DRI drivers:     $DRI_DIRS"
2830         fi
2831         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2832 fi
2833
2834 case "x$enable_glx" in
2835 xdri)
2836     echo "        GLX:             DRI-based"
2837     ;;
2838 xxlib)
2839     echo "        GLX:             Xlib-based"
2840     ;;
2841 xgallium-xlib)
2842     echo "        GLX:             Xlib-based (Gallium)"
2843     ;;
2844 *)
2845     echo "        GLX:             $enable_glx"
2846     ;;
2847 esac
2848
2849 dnl EGL
2850 echo ""
2851 echo "        EGL:             $enable_egl"
2852 if test "$enable_egl" = yes; then
2853
2854     egl_drivers=""
2855     if test "x$enable_dri" != "xno"; then
2856         egl_drivers="$egl_drivers builtin:egl_dri2"
2857     fi
2858     if test "x$enable_dri3" != "xno"; then
2859         egl_drivers="$egl_drivers builtin:egl_dri3"
2860     fi
2861
2862     echo "        EGL drivers:    $egl_drivers"
2863 fi
2864 if test "x$enable_gbm" = xyes; then
2865     echo "        GBM:             yes"
2866 else
2867     echo "        GBM:             no"
2868 fi
2869
2870     echo "        EGL/Vulkan/VL platforms:   $egl_platforms"
2871
2872 # Vulkan
2873 echo ""
2874 if test "x$VULKAN_DRIVERS" != x; then
2875     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2876     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2877 else
2878     echo "        Vulkan drivers:  no"
2879 fi
2880
2881 echo ""
2882 if test "x$enable_llvm" = xyes; then
2883     echo "        llvm:            yes"
2884     echo "        llvm-config:     $LLVM_CONFIG"
2885     echo "        llvm-version:    $LLVM_VERSION"
2886 else
2887     echo "        llvm:            no"
2888 fi
2889
2890 echo ""
2891 if test -n "$with_gallium_drivers"; then
2892     echo "        Gallium drivers: $gallium_drivers"
2893     echo "        Gallium st:      $gallium_st"
2894 else
2895     echo "        Gallium:         no"
2896 fi
2897
2898 echo ""
2899 if test "x$enable_gallium_extra_hud" != xyes; then
2900     echo "        HUD extra stats: no"
2901 else
2902     echo "        HUD extra stats: yes"
2903 fi
2904
2905 if test "x$enable_lmsensors" != xyes; then
2906     echo "        HUD lmsensors:   no"
2907 else
2908     echo "        HUD lmsensors:   yes"
2909 fi
2910
2911 dnl Libraries
2912 echo ""
2913 echo "        Shared libs:     $enable_shared"
2914 echo "        Static libs:     $enable_static"
2915 echo "        Shared-glapi:    $enable_shared_glapi"
2916
2917 dnl Compiler options
2918 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2919 cflags=`echo $CFLAGS | \
2920     $SED 's/^ *//;s/  */ /;s/ *$//'`
2921 cxxflags=`echo $CXXFLAGS | \
2922     $SED 's/^ *//;s/  */ /;s/ *$//'`
2923 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2924 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2925 echo ""
2926 echo "        CFLAGS:          $cflags"
2927 echo "        CXXFLAGS:        $cxxflags"
2928 echo "        LDFLAGS:         $ldflags"
2929 echo "        Macros:          $defines"
2930 echo ""
2931 if test "x$enable_llvm" = xyes; then
2932     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2933     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2934     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2935     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2936     echo ""
2937 fi
2938 echo "        PYTHON2:         $PYTHON2"
2939
2940 echo ""
2941 echo "        Run '${MAKE-make}' to build Mesa"
2942 echo ""