configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 AC_ARG_ENABLE(autotools,
  56    [AS_HELP_STRING([--enable-autotools],
  57                    [Enable the use of this autotools based build configuration])],
  58    [enable_autotools=$enableval], [enable_autotools=no])
  59
  60 if test "x$enable_autotools" != "xyes" ; then
  61     AC_MSG_ERROR([the autotools build system has been deprecated in favour of
  62     meson and will be removed eventually. For instructions on how to use meson
  63     see https://www.mesa3d.org/meson.html.
  64     If you still want to use the autotools build, then add --enable-autotools
  65     to the configure command line.])
  66 fi
  67
  68 # Support silent build rules, requires at least automake-1.11. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  72     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  73
  74 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  75
  76 dnl Set internal versions
  77 OSMESA_VERSION=8
  78 AC_SUBST([OSMESA_VERSION])
  79 OPENCL_VERSION=1
  80 AC_SUBST([OPENCL_VERSION])
  81
  82 # The idea is that libdrm is distributed as one cohesive package, even
  83 # though it is composed of multiple libraries. However some drivers
  84 # may have different version requirements than others. This list
  85 # codifies which drivers need which version of libdrm. Any libdrm
  86 # version dependencies in non-driver-specific code should be reflected
  87 # in the first entry.
  88 LIBDRM_REQUIRED=2.4.75
  89 LIBDRM_RADEON_REQUIRED=2.4.71
  90 LIBDRM_AMDGPU_REQUIRED=2.4.97
  91 LIBDRM_INTEL_REQUIRED=2.4.75
  92 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  93 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  94 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  95 LIBDRM_VC4_REQUIRED=2.4.89
  96
  97 dnl Versions for external dependencies
  98 DRI2PROTO_REQUIRED=2.8
  99 GLPROTO_REQUIRED=1.4.14
 100 LIBOMXIL_BELLAGIO_REQUIRED=0.0
 101 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
 102 LIBVA_REQUIRED=0.39.0
 103 VDPAU_REQUIRED=1.1
 104 WAYLAND_REQUIRED=1.11
 105 WAYLAND_EGL_BACKEND_REQUIRED=3
 106 WAYLAND_PROTOCOLS_REQUIRED=1.8
 107 XCB_REQUIRED=1.9.3
 108 XCBDRI2_REQUIRED=1.8
 109 XCBDRI3_MODIFIERS_REQUIRED=1.13
 110 XCBGLX_REQUIRED=1.8.1
 111 XCBPRESENT_MODIFIERS_REQUIRED=1.13
 112 XDAMAGE_REQUIRED=1.1
 113 XSHMFENCE_REQUIRED=1.1
 114 XVMC_REQUIRED=1.0.6
 115 PYTHON_MAKO_REQUIRED=0.8.0
 116 LIBSENSORS_REQUIRED=4.0.0
 117 ZLIB_REQUIRED=1.2.3
 118
 119 dnl LLVM versions
 120 LLVM_REQUIRED_GALLIUM=3.3.0
 121 LLVM_REQUIRED_OPENCL=3.9.0
 122 LLVM_REQUIRED_R600=3.9.0
 123 LLVM_REQUIRED_RADEONSI=7.0.0
 124 LLVM_REQUIRED_RADV=7.0.0
 125 LLVM_REQUIRED_SWR=6.0.0
 126
 127 dnl Check for progs
 128 AC_PROG_CPP
 129 AC_PROG_CC
 130 AC_PROG_CXX
 131 dnl add this here, so the help for this environmnet variable is close to
 132 dnl other CC/CXX flags related help
 133 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 134                               enabled by default and different  from -std=c++11)])
 135 AM_PROG_CC_C_O
 136 AC_PROG_GREP
 137 AC_PROG_NM
 138 AM_PROG_AS
 139 AX_CHECK_GNU_MAKE
 140 AM_PATH_PYTHON([2.7],, [AM_PATH_PYTHON([3.4],, [:])])
 141
 142 AC_PROG_SED
 143 AC_PROG_MKDIR_P
 144
 145 AC_SYS_LARGEFILE
 146
 147
 148 LT_PREREQ([2.2])
 149 LT_INIT([disable-static])
 150
 151 AC_CHECK_PROG(RM, rm, [rm -f])
 152
 153 AX_PROG_BISON([],
 154               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 155                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 156 AX_PROG_FLEX([],
 157              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 158                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 159
 160 AC_CHECK_PROG(INDENT, indent, indent, cat)
 161 if test "x$INDENT" != "xcat"; then
 162     # Only GNU indent is supported
 163     INDENT_VERSION=`indent --version | grep GNU`
 164     if test $? -eq 0; then
 165        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 166     else
 167        INDENT="cat"
 168     fi
 169 fi
 170
 171 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 172
 173 if test "$PYTHON" = ":"; then
 174     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 175         AC_MSG_ERROR([Python not found - unable to generate sources])
 176     fi
 177 else
 178     if test "x$acv_mako_found" = xno; then
 179         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 180             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 181         fi
 182     fi
 183 fi
 184
 185 AC_PROG_INSTALL
 186
 187 dnl We need a POSIX shell for parts of the build. Assume we have one
 188 dnl in most cases.
 189 case "$host_os" in
 190 solaris*)
 191     # Solaris /bin/sh is too old/non-POSIX compliant
 192     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 193     SHELL="$POSIX_SHELL"
 194     ;;
 195 esac
 196
 197 dnl clang is mostly GCC-compatible, but its version is much lower,
 198 dnl so we have to check for it.
 199 AC_MSG_CHECKING([if compiling with clang])
 200
 201 AC_COMPILE_IFELSE(
 202 [AC_LANG_PROGRAM([], [[
 203 #ifndef __clang__
 204        not clang
 205 #endif
 206 ]])],
 207 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 208
 209 AC_MSG_RESULT([$acv_mesa_CLANG])
 210
 211 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 212 dnl versions are explictly not supported.
 213 GEN_ASM_OFFSETS=no
 214 USE_GNU99=no
 215 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 216     AC_MSG_CHECKING([whether gcc version is sufficient])
 217     major=0
 218     minor=0
 219
 220     GCC_VERSION=`$CC -dumpversion`
 221     if test $? -eq 0; then
 222         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 223         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 224     fi
 225
 226     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 227         AC_MSG_RESULT([no])
 228         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 229     else
 230         AC_MSG_RESULT([yes])
 231     fi
 232
 233     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 234         USE_GNU99=yes
 235     fi
 236     if test "x$cross_compiling" = xyes; then
 237         GEN_ASM_OFFSETS=yes
 238     fi
 239 fi
 240
 241 dnl We don't support building Mesa with Sun C compiler
 242 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 243 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 244 if test "x$SUNCC" = xyes; then
 245     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 246 fi
 247
 248 dnl Check for compiler builtins
 249 AX_GCC_BUILTIN([__builtin_bswap32])
 250 AX_GCC_BUILTIN([__builtin_bswap64])
 251 AX_GCC_BUILTIN([__builtin_clz])
 252 AX_GCC_BUILTIN([__builtin_clzll])
 253 AX_GCC_BUILTIN([__builtin_ctz])
 254 AX_GCC_BUILTIN([__builtin_expect])
 255 AX_GCC_BUILTIN([__builtin_ffs])
 256 AX_GCC_BUILTIN([__builtin_ffsll])
 257 AX_GCC_BUILTIN([__builtin_popcount])
 258 AX_GCC_BUILTIN([__builtin_popcountll])
 259 AX_GCC_BUILTIN([__builtin_unreachable])
 260
 261 AX_GCC_FUNC_ATTRIBUTE([const])
 262 AX_GCC_FUNC_ATTRIBUTE([flatten])
 263 AX_GCC_FUNC_ATTRIBUTE([format])
 264 AX_GCC_FUNC_ATTRIBUTE([malloc])
 265 AX_GCC_FUNC_ATTRIBUTE([packed])
 266 AX_GCC_FUNC_ATTRIBUTE([pure])
 267 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 268 AX_GCC_FUNC_ATTRIBUTE([unused])
 269 AX_GCC_FUNC_ATTRIBUTE([visibility])
 270 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 271 AX_GCC_FUNC_ATTRIBUTE([weak])
 272 AX_GCC_FUNC_ATTRIBUTE([alias])
 273 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 274
 275 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 276
 277 dnl Make sure the pkg-config macros are defined
 278 m4_ifndef([PKG_PROG_PKG_CONFIG],
 279     [m4_fatal([Could not locate the pkg-config autoconf macros.
 280   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 281   are in a different location, try setting the environment variable
 282   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 283 PKG_PROG_PKG_CONFIG()
 284
 285 dnl LIB_DIR - library basename
 286 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 287 AC_SUBST([LIB_DIR])
 288
 289 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 290 _SAVE_LDFLAGS="$LDFLAGS"
 291 _SAVE_CPPFLAGS="$CPPFLAGS"
 292
 293 dnl Compiler macros
 294 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 295 AC_SUBST([DEFINES])
 296 android=no
 297 case "$host_os" in
 298 *-android*)
 299     android=yes
 300     ;;
 301 linux*|*-gnu*|gnu*|cygwin*)
 302     DEFINES="$DEFINES -D_GNU_SOURCE"
 303     ;;
 304 solaris*)
 305     DEFINES="$DEFINES -DSVR4"
 306     ;;
 307 esac
 308
 309 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 310
 311 # Toggle Werror since at some point clang started treating unknown -W
 312 # flags as warnings, succeeding with the build, yet issuing an annoying
 313 # warning.
 314 save_CFLAGS="$CFLAGS"
 315 export CFLAGS="$CFLAGS -Werror"
 316
 317 dnl
 318 dnl Check compiler flags
 319 dnl
 320 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 321 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 322 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 323 AX_CHECK_COMPILE_FLAG([-Werror=incompatible-pointer-types],    [CFLAGS="$CFLAGS -Werror=incompatible-pointer-types"])
 324 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 325 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
 326 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
 327 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CFLAGS="$CFLAGS -Wno-format-truncation"])
 328 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 329
 330 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 331 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 332
 333 CFLAGS="$save_CFLAGS"
 334
 335 # Toggle Werror since at some point clang started treating unknown -W
 336 # flags as warnings, succeeding with the build, yet issuing an annoying
 337 # warning.
 338 dnl
 339 dnl Check C++ compiler flags
 340 dnl
 341 AC_LANG_PUSH([C++])
 342 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 343 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 344 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 345 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 346 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
 347 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CXXFLAGS="$CXXFLAGS -Wno-format-truncation"])
 348 AC_LANG_POP([C++])
 349
 350 # Flags to help ensure that certain portions of the code -- and only those
 351 # portions -- can be built with MSVC:
 352 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 353 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 354 #   supports most of C99)
 355 # - the rest has no compiler compiler restrictions
 356 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 357 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 358 AC_LANG_PUSH([C++])
 359 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 360 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 361 AC_LANG_POP([C++])
 362
 363 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 364 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 365
 366 if test "x$GCC" = xyes; then
 367     if test "x$USE_GNU99" = xyes; then
 368         CFLAGS="$CFLAGS -std=gnu99"
 369     else
 370         CFLAGS="$CFLAGS -std=c99"
 371     fi
 372 fi
 373
 374 dnl
 375 dnl Check whether C++11 is supported, if the environment variable
 376 dnl CXX11_CXXFLAGS is set it takes precedence.
 377 dnl
 378
 379 AC_LANG_PUSH([C++])
 380
 381 check_cxx11_available() {
 382     output_support=$1
 383     AC_COMPILE_IFELSE(
 384         [AC_LANG_PROGRAM([
 385              #if !(__cplusplus >= 201103L)
 386              #error
 387              #endif
 388              #include <tuple>
 389         ])
 390     ], [
 391          AC_MSG_RESULT(yes)
 392          cxx11_support=yes
 393     ], AC_MSG_RESULT(no))
 394     eval "$output_support=\$cxx11_support"
 395 }
 396
 397 HAVE_CXX11=no
 398 save_CXXFLAGS="$CXXFLAGS"
 399
 400 dnl If the user provides a flag to enable c++11, then we test only this
 401 if test "x$CXX11_CXXFLAGS" != "x"; then
 402    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 403    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 404    check_cxx11_available HAVE_CXX11
 405 else
 406    dnl test whether c++11 is enabled by default
 407    AC_MSG_CHECKING(whether c++11 is enabled by default)
 408    check_cxx11_available HAVE_CXX11
 409
 410    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 411    if test "x$HAVE_CXX11" != "xyes"; then
 412        CXX11_CXXFLAGS=-std=c++11
 413        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 414        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 415        check_cxx11_available HAVE_CXX11
 416    fi
 417 fi
 418
 419 CXXFLAGS="$save_CXXFLAGS"
 420 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 421 AC_SUBST(CXX11_CXXFLAGS)
 422 AC_LANG_POP([C++])
 423
 424 dnl even if the compiler appears to support it, using visibility attributes isn't
 425 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 426 case "$host_os" in
 427 cygwin*)
 428     VISIBILITY_CFLAGS=""
 429     VISIBILITY_CXXFLAGS=""
 430     ;;
 431 esac
 432
 433 AC_SUBST([VISIBILITY_CFLAGS])
 434 AC_SUBST([VISIBILITY_CXXFLAGS])
 435
 436 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 437 dnl option is not supported. Hence, check for -Wfoo instead.
 438 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 439 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 440 AC_SUBST([WNO_OVERRIDE_INIT])
 441
 442 dnl
 443 dnl Optional flags, check for compiler support
 444 dnl
 445 SSE41_CFLAGS="-msse4.1"
 446 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 447 dnl stack, but on x86-32 such alignment is not guaranteed.
 448 case "$target_cpu" in
 449 i?86)
 450     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 451     ;;
 452 esac
 453 save_CFLAGS="$CFLAGS"
 454 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 455 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 456 #include <smmintrin.h>
 457 int param;
 458 int main () {
 459     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 460     c = _mm_max_epu32(a, b);
 461     return _mm_cvtsi128_si32(c);
 462 }]])], SSE41_SUPPORTED=1)
 463 CFLAGS="$save_CFLAGS"
 464 if test "x$SSE41_SUPPORTED" = x1; then
 465     DEFINES="$DEFINES -DUSE_SSE41"
 466 fi
 467 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 468 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 469
 470 dnl Check for new-style atomic builtins. We first check without linking to
 471 dnl -latomic.
 472 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 473 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 474 #include <stdint.h>
 475 int main() {
 476     struct {
 477         uint64_t *v;
 478     } x;
 479     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 480            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 481 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 482
 483 dnl If that didn't work, we try linking with -latomic, which is needed on some
 484 dnl platforms.
 485 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 486    save_LDFLAGS=$LDFLAGS
 487    LDFLAGS="$LDFLAGS -latomic"
 488    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 489    #include <stdint.h>
 490    int main() {
 491         struct {
 492             uint64_t *v;
 493         } x;
 494         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 495                (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 496    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 497           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 498    LDFLAGS=$save_LDFLAGS
 499 fi
 500 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 501
 502 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 503     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 504 fi
 505 AC_SUBST([LIBATOMIC_LIBS])
 506
 507 dnl Check if host supports 64-bit atomics
 508 dnl note that lack of support usually results in link (not compile) error
 509 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 510 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 511 #include <stdint.h>
 512 uint64_t v;
 513 int main() {
 514     return __sync_add_and_fetch(&v, (uint64_t)1);
 515 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 516 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 517     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 518 fi
 519 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 520
 521 dnl Check for Endianness
 522 AC_C_BIGENDIAN(
 523    little_endian=no,
 524    little_endian=yes,
 525    little_endian=no,
 526    little_endian=no
 527 )
 528
 529 dnl Check for POWER8 Architecture
 530 PWR8_CFLAGS="-mpower8-vector"
 531 have_pwr8_intrinsics=no
 532 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 533 save_CFLAGS=$CFLAGS
 534 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 535 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 536 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 537 #error "Need GCC >= 4.8 for sane POWER8 support"
 538 #endif
 539 #include <altivec.h>
 540 int main () {
 541     vector unsigned char r;
 542     vector unsigned int v = vec_splat_u32 (1);
 543     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 544     return 0;
 545 }]])], have_pwr8_intrinsics=yes)
 546 CFLAGS=$save_CFLAGS
 547
 548 AC_ARG_ENABLE(pwr8,
 549    [AS_HELP_STRING([--disable-pwr8],
 550                    [disable POWER8-specific instructions])],
 551    [enable_pwr8=$enableval], [enable_pwr8=auto])
 552
 553 if test "x$enable_pwr8" = xno ; then
 554    have_pwr8_intrinsics=disabled
 555 fi
 556
 557 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 558    DEFINES="$DEFINES -D_ARCH_PWR8"
 559    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 560    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 561 else
 562    PWR8_CFLAGS=
 563 fi
 564
 565 AC_MSG_RESULT($have_pwr8_intrinsics)
 566 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 567    AC_MSG_ERROR([POWER8 compiler support not detected])
 568 fi
 569
 570 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 571    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 572 fi
 573
 574 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 575
 576 dnl Can't have static and shared libraries, default to static if user
 577 dnl explicitly requested. If both disabled, set to static since shared
 578 dnl was explicitly requested.
 579 case "x$enable_static$enable_shared" in
 580 xyesyes)
 581     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 582     ;;
 583 xnono)
 584     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 585     ;;
 586 esac
 587
 588 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 589
 590 dnl
 591 dnl other compiler options
 592 dnl
 593 AC_ARG_ENABLE([debug],
 594     [AS_HELP_STRING([--enable-debug],
 595         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 596     [enable_debug="$enableval"],
 597     [enable_debug=no]
 598 )
 599
 600 AC_ARG_ENABLE([profile],
 601     [AS_HELP_STRING([--enable-profile],
 602         [enable profiling of code @<:@default=disabled@:>@])],
 603     [enable_profile="$enableval"],
 604     [enable_profile=no]
 605 )
 606
 607 AC_ARG_ENABLE([sanitize],
 608     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 609         [enable code sanitizer @<:@default=disabled@:>@])],
 610     [enable_sanitize="$enableval"],
 611     [enable_sanitize=no])
 612
 613 if test "x$enable_profile" = xyes; then
 614     DEFINES="$DEFINES -DPROFILE"
 615     if test "x$GCC" = xyes; then
 616         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 617     fi
 618     if test "x$GXX" = xyes; then
 619         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 620     fi
 621 fi
 622
 623 if test "x$enable_debug" = xyes; then
 624     DEFINES="$DEFINES -DDEBUG"
 625     if test "x$enable_profile" = xyes; then
 626         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 627     fi
 628     if test "x$GCC" = xyes; then
 629         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 630             CFLAGS="$CFLAGS -g"
 631         fi
 632         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 633             CFLAGS="$CFLAGS -O0"
 634         fi
 635     fi
 636     if test "x$GXX" = xyes; then
 637         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 638             CXXFLAGS="$CXXFLAGS -g"
 639         fi
 640         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 641             CXXFLAGS="$CXXFLAGS -O0"
 642         fi
 643     fi
 644 else
 645    DEFINES="$DEFINES -DNDEBUG"
 646 fi
 647
 648 if test "x$enable_sanitize" != xno; then
 649     if test "x$enable_profile" = xyes; then
 650         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 651     fi
 652
 653     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 654     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 655     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 656
 657     AC_LINK_IFELSE(
 658         [AC_LANG_SOURCE([int main(){return 0;}])],
 659         [],
 660         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 661 fi
 662
 663 dnl
 664 dnl Check if linker supports -Bsymbolic
 665 dnl
 666 save_LDFLAGS=$LDFLAGS
 667 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 668 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 669 AC_LINK_IFELSE(
 670     [AC_LANG_SOURCE([int main() { return 0;}])],
 671     [AC_MSG_RESULT([yes])
 672         BSYMBOLIC="-Wl,-Bsymbolic";],
 673     [AC_MSG_RESULT([no])
 674         BSYMBOLIC="";])
 675 LDFLAGS=$save_LDFLAGS
 676
 677 AC_SUBST([BSYMBOLIC])
 678
 679 dnl
 680 dnl Check if linker supports garbage collection
 681 dnl
 682 save_LDFLAGS=$LDFLAGS
 683 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 684 AC_MSG_CHECKING([whether ld supports --gc-sections])
 685 AC_LINK_IFELSE(
 686     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 687     [AC_MSG_RESULT([yes])
 688         GC_SECTIONS="-Wl,--gc-sections";],
 689     [AC_MSG_RESULT([no])
 690         GC_SECTIONS="";])
 691 LDFLAGS=$save_LDFLAGS
 692
 693 AC_SUBST([GC_SECTIONS])
 694
 695 dnl
 696 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 697 dnl so when these flags are passed to ld via libtool the checks will fail
 698 dnl
 699 case "$host_os" in
 700 openbsd* | darwin* )
 701     LD_NO_UNDEFINED="" ;;
 702 *)
 703     if test "x$enable_sanitize" = xno; then
 704         LD_NO_UNDEFINED="-Wl,--no-undefined"
 705     else
 706         LD_NO_UNDEFINED=""
 707     fi
 708     ;;
 709 esac
 710
 711 AC_SUBST([LD_NO_UNDEFINED])
 712
 713 dnl
 714 dnl Check if linker supports version scripts
 715 dnl
 716 AC_MSG_CHECKING([if the linker supports version-scripts])
 717 save_LDFLAGS=$LDFLAGS
 718 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 719 AC_LINK_IFELSE(
 720     [AC_LANG_SOURCE([int main() { return 0;}])],
 721     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 722     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 723 LDFLAGS=$save_LDFLAGS
 724 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 725
 726 dnl
 727 dnl Check if linker supports dynamic list files
 728 dnl
 729 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 730 save_LDFLAGS=$LDFLAGS
 731 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 732 AC_LINK_IFELSE(
 733     [AC_LANG_SOURCE([int main() { return 0;}])],
 734     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 735     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 736 LDFLAGS=$save_LDFLAGS
 737 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 738
 739 dnl
 740 dnl OSX linker does not support build-id
 741 dnl
 742 case "$host_os" in
 743 darwin*)
 744     LD_BUILD_ID=""
 745     ;;
 746 *)
 747     LD_BUILD_ID="-Wl,--build-id=sha1"
 748     ;;
 749 esac
 750 AC_SUBST([LD_BUILD_ID])
 751
 752 dnl
 753 dnl compatibility symlinks
 754 dnl
 755 case "$host_os" in
 756 linux* )
 757     HAVE_COMPAT_SYMLINKS=yes ;;
 758 * )
 759     HAVE_COMPAT_SYMLINKS=no ;;
 760 esac
 761
 762 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 763
 764 dnl
 765 dnl library names
 766 dnl
 767 dnl Unfortunately we need to do a few things that libtool can't help us with,
 768 dnl so we need some knowledge of shared library filenames:
 769 dnl
 770 dnl LIB_EXT is the extension used when creating symlinks for alternate
 771 dnl filenames for a shared library which will be dynamically loaded
 772 dnl
 773 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 774 dnl the file for a shared library we wish to link with
 775 dnl
 776 case "$host_os" in
 777 darwin* )
 778     LIB_EXT='dylib'
 779     IMP_LIB_EXT=$LIB_EXT
 780     ;;
 781 cygwin* )
 782     LIB_EXT='dll'
 783     IMP_LIB_EXT='dll.a'
 784     ;;
 785 aix* )
 786     LIB_EXT='a'
 787     IMP_LIB_EXT=$LIB_EXT
 788     ;;
 789 * )
 790     LIB_EXT='so'
 791     IMP_LIB_EXT=$LIB_EXT
 792     ;;
 793 esac
 794
 795 AC_SUBST([LIB_EXT])
 796
 797 dnl
 798 dnl Arch/platform-specific settings
 799 dnl
 800 AC_ARG_ENABLE([asm],
 801     [AS_HELP_STRING([--disable-asm],
 802         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 803     [enable_asm="$enableval"],
 804     [enable_asm=yes]
 805 )
 806 asm_arch=""
 807 AC_MSG_CHECKING([whether to enable assembly])
 808 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 809 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 810 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 811     case "$host_cpu" in
 812     i?86 | x86_64 | amd64)
 813         if test "x$host_cpu" != "x$target_cpu"; then
 814             enable_asm=no
 815             AC_MSG_RESULT([no, cross compiling])
 816         fi
 817         ;;
 818     esac
 819 fi
 820 # check for supported arches
 821 if test "x$enable_asm" = xyes; then
 822     case "$host_cpu" in
 823     i?86)
 824         case "$host_os" in
 825         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 826             asm_arch=x86
 827             ;;
 828         esac
 829         ;;
 830     x86_64|amd64)
 831         case "$host_os" in
 832         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 833             asm_arch=x86_64
 834             ;;
 835         esac
 836         ;;
 837     sparc*)
 838         case "$host_os" in
 839         linux*)
 840             asm_arch=sparc
 841             ;;
 842         esac
 843         ;;
 844     powerpc64le)
 845         case "$host_os" in
 846         linux*)
 847             asm_arch=ppc64le
 848             ;;
 849         esac
 850         ;;
 851     aarch64)
 852         case "$host_os" in
 853         linux*)
 854             asm_arch=aarch64
 855             ;;
 856         esac
 857         ;;
 858     arm)
 859         case "$host_os" in
 860         linux*)
 861             asm_arch=arm
 862             ;;
 863         esac
 864         ;;
 865     esac
 866
 867     case "$asm_arch" in
 868     x86)
 869         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 870         AC_MSG_RESULT([yes, x86])
 871         ;;
 872     x86_64|amd64)
 873         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 874         AC_MSG_RESULT([yes, x86_64])
 875         ;;
 876     sparc)
 877         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 878         AC_MSG_RESULT([yes, sparc])
 879         ;;
 880     ppc64le)
 881         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 882         AC_MSG_RESULT([yes, ppc64le])
 883         ;;
 884     aarch64)
 885         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 886         AC_MSG_RESULT([yes, aarch64])
 887         ;;
 888     arm)
 889         DEFINES="$DEFINES -DUSE_ARM_ASM"
 890         AC_MSG_RESULT([yes, arm])
 891         ;;
 892     *)
 893         AC_MSG_RESULT([no, platform not supported])
 894         ;;
 895     esac
 896 fi
 897
 898 AC_HEADER_MAJOR
 899 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 900 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 901 AC_CHECK_HEADERS([endian.h])
 902 AC_CHECK_HEADER([dlfcn.h], [DEFINES="$DEFINES -DHAVE_DLFCN_H"])
 903 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 904 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 905 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 906 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 907
 908 AC_MSG_CHECKING([whether strtod has locale support])
 909 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 910     #define _GNU_SOURCE
 911     #include <stdlib.h>
 912     #include <locale.h>
 913     #ifdef HAVE_XLOCALE_H
 914     #include <xlocale.h>
 915     #endif
 916     int main() {
 917        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 918        const char *s = "1.0";
 919        char *end;
 920        double d = strtod_l(s, end, loc);
 921        float f = strtof_l(s, end, loc);
 922        freelocale(loc);
 923        return 0;
 924     }]])],
 925   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 926    AC_MSG_RESULT([yes]),
 927    AC_MSG_RESULT([no]))
 928
 929 dnl Check to see if dlopen is in default libraries (like Solaris, which
 930 dnl has it in libc), or if libdl is needed to get it.
 931 AC_CHECK_FUNC([dlopen], [],
 932     [AC_CHECK_LIB([dl], [dlopen],
 933        [DLOPEN_LIBS="-ldl"])])
 934 AC_SUBST([DLOPEN_LIBS])
 935
 936 dnl Check if that library also has dladdr
 937 save_LIBS="$LIBS"
 938 LIBS="$LIBS $DLOPEN_LIBS"
 939 AC_CHECK_FUNCS([dladdr])
 940 LIBS="$save_LIBS"
 941
 942 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 943
 944 case "$host_os" in
 945 darwin*)
 946     ;;
 947 *)
 948     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 949                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 950                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 951     AC_SUBST([CLOCK_LIB])
 952     ;;
 953 esac
 954
 955 dnl See if posix_memalign is available
 956 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 957
 958 dnl Check for zlib
 959 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 960 DEFINES="$DEFINES -DHAVE_ZLIB"
 961
 962 dnl Check for pthreads
 963 AX_PTHREAD
 964 if test "x$ax_pthread_ok" = xno; then
 965     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 966 fi
 967 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 968 dnl to -pthread, which causes problems if we need -lpthread to appear in
 969 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 970 dnl is not valid for that platform.
 971 if test "x$android" = xno; then
 972     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 973 fi
 974 dnl According to the manual when using pthreads, one should add -pthread to
 975 dnl both compile and link-time arguments.
 976 dnl In practise that should be sufficient for all platforms, since any
 977 dnl platforms build with GCC and Clang support the flag.
 978 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 979
 980 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 981 dnl project. Even then there's a notable issue as described in the project README
 982 case "$host_os" in
 983 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 984     pthread_stubs_possible="no"
 985     ;;
 986 * )
 987     pthread_stubs_possible="yes"
 988     ;;
 989 esac
 990
 991 if test "x$pthread_stubs_possible" = xyes; then
 992     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 993 fi
 994
 995 save_LIBS="$LIBS"
 996 LIBS="$PTHREAD_LIBS"
 997 AC_MSG_CHECKING(whether pthread_setaffinity_np is supported)
 998 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 999     #define _GNU_SOURCE
1000     #include <pthread.h>
1001     int main() {
1002        void *a = (void*) &pthread_setaffinity_np;
1003        long b = (long) a;
1004        return (int) b;
1005     }]])],
1006   [DEFINES="$DEFINES -DHAVE_PTHREAD_SETAFFINITY"];
1007    AC_MSG_RESULT([yes]),
1008    AC_MSG_RESULT([no]))
1009 LIBS="$save_LIBS"
1010
1011 dnl Check for futex for fast inline simple_mtx_t.
1012 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
1013
1014 dnl SELinux awareness.
1015 AC_ARG_ENABLE([selinux],
1016     [AS_HELP_STRING([--enable-selinux],
1017         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
1018     [MESA_SELINUX="$enableval"],
1019     [MESA_SELINUX=no])
1020 if test "x$enable_selinux" = "xyes"; then
1021     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
1022         [AC_CHECK_HEADER([selinux/selinux.h],[],
1023                          [AC_MSG_ERROR([SELinux headers not found])])
1024          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
1025                       [AC_MSG_ERROR([SELinux library not found])])
1026          SELINUX_LIBS="-lselinux"])
1027     DEFINES="$DEFINES -DMESA_SELINUX"
1028 fi
1029 AC_SUBST([SELINUX_CFLAGS])
1030 AC_SUBST([SELINUX_LIBS])
1031
1032 dnl
1033 dnl LLVM
1034 dnl
1035 AC_ARG_ENABLE([llvm-shared-libs],
1036     [AS_HELP_STRING([--enable-llvm-shared-libs],
1037         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1038     [enable_llvm_shared_libs="$enableval"],
1039     [enable_llvm_shared_libs=yes])
1040
1041 AC_ARG_WITH([llvm-prefix],
1042     [AS_HELP_STRING([--with-llvm-prefix],
1043         [Prefix for LLVM installations in non-standard locations])],
1044     [llvm_prefix="$withval"],
1045     [llvm_prefix=''])
1046
1047 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1048 if test "x$have_libelf" = xno; then
1049    LIBELF_LIBS=''
1050    LIBELF_CFLAGS=''
1051    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1052    AC_SUBST([LIBELF_LIBS])
1053    AC_SUBST([LIBELF_CFLAGS])
1054 fi
1055
1056 if test -z "$LLVM_CONFIG"; then
1057     if test -n "$llvm_prefix"; then
1058         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1059     else
1060         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1061     fi
1062 fi
1063
1064 llvm_add_component() {
1065     new_llvm_component=$1
1066     driver_name=$2
1067
1068     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1069         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1070     else
1071         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1072     fi
1073 }
1074
1075 llvm_add_optional_component() {
1076     new_llvm_component=$1
1077     driver_name=$2
1078
1079     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1080         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1081     fi
1082 }
1083
1084 llvm_add_default_components() {
1085     driver_name=$1
1086
1087     # Required default components
1088     llvm_add_component "bitwriter" $driver_name
1089     llvm_add_component "engine" $driver_name
1090     llvm_add_component "mcdisassembler" $driver_name
1091     llvm_add_component "mcjit" $driver_name
1092
1093     # Optional default components
1094     llvm_add_optional_component "inteljitevents" $driver_name
1095 }
1096
1097 llvm_add_target() {
1098     new_llvm_target=$1
1099     driver_name=$2
1100
1101     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1102         llvm_add_component $new_llvm_target $driver_name
1103     else
1104         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1105     fi
1106 }
1107
1108 # Call this inside ` ` to get the return value.
1109 # $1 is the llvm-config command with arguments.
1110 strip_unwanted_llvm_flags() {
1111     echo " `$1` " | sed -E \
1112         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1113         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1114         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1115         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1116         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1117         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1118         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1119         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1120         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1121         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1122         -e 's/^[[[:space:]]]//' \
1123         -e 's/[[[:space:]]]$//'
1124 }
1125
1126 llvm_set_environment_variables() {
1127     if test "x$LLVM_CONFIG" != xno; then
1128         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1129         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1130         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1131         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1132
1133         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1134         save_CFLAGS="$CFLAGS"
1135         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1136
1137         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1138             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1139         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1140             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1141         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1142             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1143
1144         CFLAGS="$save_CFLAGS"
1145
1146         # Only needed for LLVM < 3.6.0
1147         if test -z "$LLVM_VERSION_PATCH"; then
1148             LLVM_VERSION_PATCH=0
1149         fi
1150
1151         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1152
1153         FOUND_LLVM=yes
1154     else
1155         FOUND_LLVM=no
1156         LLVM_VERSION_INT=0
1157     fi
1158 }
1159
1160 require_llvm() {
1161     if test "x$enable_llvm" != "xyes"; then
1162         AC_MSG_ERROR([--enable-llvm is required when building $1])
1163     fi
1164 }
1165
1166 llvm_require_version() {
1167     require_llvm $2
1168
1169     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1170     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1171     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1172
1173     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1174         # major > required major
1175         #  --> OK
1176         return
1177     fi
1178
1179     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1180         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1181             # major = required major and
1182             # minor > required minor
1183             #  --> OK
1184             return
1185         else
1186             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1187                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1188                     # major = required major and
1189                     # minor = required minor and
1190                     # patch >= required patch
1191                     #  --> OK
1192                     return
1193                 fi
1194             fi
1195         fi
1196     fi
1197
1198     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1199 }
1200
1201 radeon_llvm_check() {
1202     if test ${LLVM_VERSION_INT} -lt 307; then
1203         amdgpu_llvm_target_name='r600'
1204     else
1205         amdgpu_llvm_target_name='amdgpu'
1206     fi
1207
1208     llvm_require_version $*
1209
1210     llvm_add_target $amdgpu_llvm_target_name $2
1211
1212     llvm_add_default_components $2
1213     llvm_add_component "bitreader" $2
1214     llvm_add_component "ipo" $2
1215
1216     if test "x$have_libelf" != xyes; then
1217        AC_MSG_ERROR([$2 requires libelf when using llvm])
1218     fi
1219 }
1220
1221 llvm_set_environment_variables
1222
1223 AC_SUBST([LLVM_CFLAGS])
1224 AC_SUBST([LLVM_CXXFLAGS])
1225 AC_SUBST([LLVM_LIBS])
1226 AC_SUBST([LLVM_LDFLAGS])
1227 AC_SUBST([LLVM_INCLUDEDIR])
1228
1229 dnl
1230 dnl libunwind
1231 dnl
1232 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1233 AC_ARG_ENABLE([libunwind],
1234     [AS_HELP_STRING([--enable-libunwind],
1235             [Use libunwind for backtracing (default: auto)])],
1236         [LIBUNWIND="$enableval"],
1237         [LIBUNWIND="$HAVE_LIBUNWIND"])
1238
1239 if test "x$LIBUNWIND" = "xyes"; then
1240     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1241     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1242 fi
1243
1244
1245 dnl Options for APIs
1246 AC_ARG_ENABLE([opengl],
1247     [AS_HELP_STRING([--disable-opengl],
1248         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1249     [enable_opengl="$enableval"],
1250     [enable_opengl=yes])
1251 AC_ARG_ENABLE([gles1],
1252     [AS_HELP_STRING([--disable-gles1],
1253         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1254     [enable_gles1="$enableval"],
1255     [enable_gles1=yes])
1256 AC_ARG_ENABLE([gles2],
1257     [AS_HELP_STRING([--disable-gles2],
1258         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1259     [enable_gles2="$enableval"],
1260     [enable_gles2=yes])
1261
1262 AC_ARG_ENABLE([dri],
1263     [AS_HELP_STRING([--enable-dri],
1264         [enable DRI modules @<:@default=enabled@:>@])],
1265     [enable_dri="$enableval"],
1266     [enable_dri=yes])
1267
1268 AC_ARG_ENABLE([gallium-extra-hud],
1269     [AS_HELP_STRING([--enable-gallium-extra-hud],
1270         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1271     [enable_gallium_extra_hud="$enableval"],
1272     [enable_gallium_extra_hud=no])
1273 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1274 if test "x$enable_gallium_extra_hud" = xyes ; then
1275     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1276 fi
1277
1278 #TODO: no pkgconfig .pc available for libsensors.
1279 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1280 AC_ARG_ENABLE([lmsensors],
1281     [AS_HELP_STRING([--enable-lmsensors],
1282         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1283     [enable_lmsensors="$enableval"],
1284     [enable_lmsensors=no])
1285 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1286 if test "x$enable_lmsensors" = xyes ; then
1287     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1288     LIBSENSORS_LIBS="-lsensors"
1289 else
1290     LIBSENSORS_LIBS=""
1291 fi
1292 AC_SUBST(LIBSENSORS_LIBS)
1293
1294 case "$host_os" in
1295 linux*)
1296     dri3_default=yes
1297     ;;
1298 *)
1299     dri3_default=no
1300     ;;
1301 esac
1302
1303 if test "x$enable_dri" = xno; then
1304     dri3_default=no
1305 fi
1306
1307 AC_ARG_ENABLE([dri3],
1308     [AS_HELP_STRING([--enable-dri3],
1309         [enable DRI3 @<:@default=auto@:>@])],
1310     [enable_dri3="$enableval"],
1311     [enable_dri3="$dri3_default"])
1312 AC_ARG_ENABLE([glx],
1313     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1314         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1315     [enable_glx="$enableval"],
1316     [enable_glx=yes])
1317 AC_ARG_ENABLE([osmesa],
1318     [AS_HELP_STRING([--enable-osmesa],
1319         [enable OSMesa library @<:@default=disabled@:>@])],
1320     [enable_osmesa="$enableval"],
1321     [enable_osmesa=no])
1322 AC_ARG_ENABLE([gallium-osmesa],
1323     [AS_HELP_STRING([--enable-gallium-osmesa],
1324         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1325     [enable_gallium_osmesa="$enableval"],
1326     [enable_gallium_osmesa=no])
1327 AC_ARG_ENABLE([egl],
1328     [AS_HELP_STRING([--disable-egl],
1329         [disable EGL library @<:@default=enabled@:>@])],
1330     [enable_egl="$enableval"],
1331     [enable_egl=yes])
1332
1333 AC_ARG_ENABLE([xa],
1334     [AS_HELP_STRING([--enable-xa],
1335         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1336     [enable_xa="$enableval"],
1337     [enable_xa=no])
1338 AC_ARG_ENABLE([gbm],
1339    [AS_HELP_STRING([--enable-gbm],
1340          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1341    [enable_gbm="$enableval"],
1342    [case "$host_os" in
1343        cygwin* | darwin*)
1344           enable_gbm=no
1345           ;;
1346        *)
1347           enable_gbm=yes
1348           ;;
1349     esac])
1350 AC_ARG_ENABLE([nine],
1351     [AS_HELP_STRING([--enable-nine],
1352         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1353     [enable_nine="$enableval"],
1354     [enable_nine=no])
1355
1356 AC_ARG_ENABLE([xvmc],
1357    [AS_HELP_STRING([--enable-xvmc],
1358          [enable xvmc library @<:@default=auto@:>@])],
1359    [enable_xvmc="$enableval"],
1360    [enable_xvmc=auto])
1361 AC_ARG_ENABLE([vdpau],
1362    [AS_HELP_STRING([--enable-vdpau],
1363          [enable vdpau library @<:@default=auto@:>@])],
1364    [enable_vdpau="$enableval"],
1365    [enable_vdpau=auto])
1366 AC_ARG_ENABLE([omx],
1367    [AS_HELP_STRING([--enable-omx],
1368          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1369    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1370    [])
1371 AC_ARG_ENABLE([omx-bellagio],
1372    [AS_HELP_STRING([--enable-omx-bellagio],
1373          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1374    [enable_omx_bellagio="$enableval"],
1375    [enable_omx_bellagio=no])
1376 AC_ARG_ENABLE([omx-tizonia],
1377    [AS_HELP_STRING([--enable-omx-tizonia],
1378          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1379    [enable_omx_tizonia="$enableval"],
1380    [enable_omx_tizonia=no])
1381 AC_ARG_ENABLE([va],
1382    [AS_HELP_STRING([--enable-va],
1383          [enable va library @<:@default=auto@:>@])],
1384    [enable_va="$enableval"],
1385    [enable_va=auto])
1386 AC_ARG_ENABLE([opencl],
1387    [AS_HELP_STRING([--enable-opencl],
1388          [enable OpenCL library @<:@default=disabled@:>@])],
1389    [enable_opencl="$enableval"],
1390    [enable_opencl=no])
1391 AC_ARG_ENABLE([opencl_icd],
1392    [AS_HELP_STRING([--enable-opencl-icd],
1393           [Build an OpenCL ICD library to be loaded by an ICD implementation
1394            @<:@default=enabled@:>@])],
1395     [enable_opencl_icd="$enableval"],
1396     [enable_opencl_icd=yes])
1397
1398 AC_ARG_ENABLE([gallium-tests],
1399     [AS_HELP_STRING([--enable-gallium-tests],
1400         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1401     [enable_gallium_tests="$enableval"],
1402     [enable_gallium_tests=no])
1403
1404 # Option for Gallium drivers
1405
1406 # Keep this in sync with the --with-gallium-drivers help string default value
1407 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1408
1409 AC_ARG_WITH([gallium-drivers],
1410     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1411         [comma delimited Gallium drivers list, e.g.
1412         "i915,nouveau,r300,r600,radeonsi,freedreno,kmsro,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv"
1413         @<:@default=r300,r600,svga,swrast@:>@])],
1414     [with_gallium_drivers="$withval"],
1415     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1416
1417 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1418 # here so that the script doesn't choke on an unknown driver name later.
1419 case "$with_gallium_drivers" in
1420     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1421     no) with_gallium_drivers='' ;;
1422 esac
1423
1424 if test "x$enable_opengl" = xno -a \
1425         "x$enable_gles1" = xno -a \
1426         "x$enable_gles2" = xno -a \
1427         "x$enable_nine" = xno -a \
1428         "x$enable_xa" = xno -a \
1429         "x$enable_xvmc" = xno -a \
1430         "x$enable_vdpau" = xno -a \
1431         "x$enable_omx_bellagio" = xno -a \
1432         "x$enable_omx_tizonia" = xno -a \
1433         "x$enable_va" = xno -a \
1434         "x$enable_opencl" = xno; then
1435     AC_MSG_ERROR([at least one API should be enabled])
1436 fi
1437
1438 if test "x$enable_omx_bellagio" = xyes -a \
1439         "x$enable_omx_tizonia" = xyes; then
1440    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1441 fi
1442
1443 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1444 if test "x$enable_opengl" = xno -a \
1445         "x$enable_gles1" = xyes; then
1446     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1447 fi
1448
1449 if test "x$enable_opengl" = xno -a \
1450         "x$enable_gles2" = xyes; then
1451     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1452 fi
1453
1454 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1455 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1456 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1457 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1458                                         "x$enable_gles1" = xyes -o \
1459                                         "x$enable_gles2" = xyes)
1460 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1461                                       "x$enable_opengl" = xyes -o \
1462                                       "x$enable_gles1" = xyes -o \
1463                                       "x$enable_gles2" = xyes)
1464
1465 # Validate GLX options
1466 if test "x$enable_glx" = xyes; then
1467     if test "x$enable_dri" = xyes; then
1468         enable_glx=dri
1469     elif test -n "$with_gallium_drivers"; then
1470         enable_glx=gallium-xlib
1471     else
1472         enable_glx=xlib
1473     fi
1474 fi
1475 case "x$enable_glx" in
1476 xdri | xxlib | xgallium-xlib)
1477     # GLX requires OpenGL
1478     if test "x$enable_opengl" = xno; then
1479         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1480     fi
1481
1482     # Check individual dependencies
1483     case "x$enable_glx" in
1484     xdri)
1485         if test "x$enable_dri" = xno; then
1486             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1487         fi
1488         ;;
1489     xxlib)
1490         if test "x$enable_dri" = xyes; then
1491             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1492         fi
1493         ;;
1494     xgallium-xlib )
1495         if test "x$enable_dri" = xyes; then
1496             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1497         fi
1498         if test -z "$with_gallium_drivers"; then
1499             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1500         fi
1501         ;;
1502     esac
1503     ;;
1504 xno)
1505     ;;
1506 *)
1507     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1508     ;;
1509 esac
1510
1511 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1512 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1513 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1514 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1515
1516 DEFAULT_GL_LIB_NAME=GL
1517
1518 dnl
1519 dnl Libglvnd configuration
1520 dnl
1521 AC_ARG_ENABLE([libglvnd],
1522     [AS_HELP_STRING([--enable-libglvnd],
1523         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1524     [enable_libglvnd="$enableval"],
1525     [enable_libglvnd=no])
1526 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1527
1528 if test "x$enable_libglvnd" = xyes ; then
1529     case "x$enable_glx" in
1530     xxlib | xgallium-xlib )
1531         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1532         ;;
1533     esac
1534
1535     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1536     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1537     AC_SUBST([LIBGLVND_DATADIR])
1538
1539     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1540     DEFAULT_GL_LIB_NAME=GLX_mesa
1541
1542     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1543         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1544     fi
1545 fi
1546
1547 AC_ARG_WITH([gl-lib-name],
1548   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1549     [specify GL library name @<:@default=GL@:>@])],
1550   [AC_MSG_ERROR([--with-gl-lib-name is no longer supported. Rename the library manually if needed.])],
1551   [])
1552 AC_ARG_WITH([osmesa-lib-name],
1553   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1554     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1555   [AC_MSG_ERROR([--with-osmesa-lib-name is no longer supported. Rename the library manually if needed.])],
1556   [])
1557 GL_LIB="$DEFAULT_GL_LIB_NAME"
1558 OSMESA_LIB=OSMesa
1559
1560 dnl
1561 dnl Mangled Mesa support
1562 dnl
1563 AC_ARG_ENABLE([mangling],
1564   [AS_HELP_STRING([--enable-mangling],
1565     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1566   [enable_mangling="${enableval}"],
1567   [enable_mangling=no]
1568 )
1569 if test "x${enable_mangling}" = "xyes" ; then
1570   if test "x$enable_libglvnd" = xyes; then
1571     AC_MSG_ERROR([Conflicting options --enable-mangling and --enable-libglvnd.])
1572   fi
1573   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1574   GL_LIB="Mangled${GL_LIB}"
1575   OSMESA_LIB="Mangled${OSMESA_LIB}"
1576 fi
1577 AC_SUBST([GL_LIB])
1578 AC_SUBST([OSMESA_LIB])
1579
1580 dnl HACK when building glx + glvnd we ship gl.pc, despite that glvnd should do it
1581 dnl Thus we need to use GL as a DSO name.
1582 if test "x$enable_libglvnd" = xyes -a "x$enable_glx" != xno; then
1583   GL_PKGCONF_LIB="GL"
1584 else
1585   GL_PKGCONF_LIB="$GL_LIB"
1586 fi
1587 AC_SUBST([GL_PKGCONF_LIB])
1588
1589 # Check for libdrm
1590 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1591                   [have_libdrm=yes], [have_libdrm=no])
1592 if test "x$have_libdrm" = xyes; then
1593     DEFINES="$DEFINES -DHAVE_LIBDRM"
1594 fi
1595
1596 require_libdrm() {
1597     if test "x$have_libdrm" != xyes; then
1598        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1599     fi
1600 }
1601
1602
1603 # Select which platform-dependent DRI code gets built
1604 case "$host_os" in
1605 darwin*)
1606     dri_platform='apple' ;;
1607 cygwin*)
1608     dri_platform='windows' ;;
1609 gnu*)
1610     dri_platform='none' ;;
1611 *)
1612     dri_platform='drm' ;;
1613 esac
1614
1615 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1616     have_drisw_kms='yes'
1617 fi
1618
1619 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1620 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1621 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1622 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1623 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1624 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1625 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1626 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1627 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1628 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1629
1630 AC_ARG_ENABLE([shared-glapi],
1631     [AS_HELP_STRING([--enable-shared-glapi],
1632         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1633     [enable_shared_glapi="$enableval"],
1634     [enable_shared_glapi=yes])
1635
1636 case "x$enable_opengl$enable_gles1$enable_gles2" in
1637 x*yes*yes*)
1638     if test "x$enable_shared_glapi" = xno; then
1639         AC_MSG_ERROR([shared GLAPI required when building two or more of
1640                       the following APIs - opengl, gles1 gles2])
1641     fi
1642     ;;
1643 esac
1644
1645 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1646
1647 # Build the pipe-drivers as separate libraries/modules.
1648 # Do not touch this unless you know what you are doing.
1649 # XXX: Expose via configure option ?
1650 enable_shared_pipe_drivers=no
1651
1652 dnl
1653 dnl Driver specific build directories
1654 dnl
1655
1656 if test "x$enable_gallium_osmesa" = xyes; then
1657     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1658         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1659     fi
1660     if test "x$enable_osmesa" = xyes; then
1661         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1662     fi
1663 fi
1664
1665 require_dri_shared_libs_and_glapi() {
1666     if test "x$enable_static" = xyes; then
1667         AC_MSG_ERROR([$1 cannot be build as static library])
1668     fi
1669
1670     if test "x$enable_dri" != xyes; then
1671         # There is only a single backend which won't be build/used otherwise.
1672         # XXX: Revisit this as the egl/haiku is a thing.
1673         AC_MSG_ERROR([$1 requires --enable-dri])
1674     fi
1675
1676     if test "x$enable_shared_glapi" != xyes; then
1677         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1678     fi
1679 }
1680
1681 if test "x$enable_dri" = xyes; then
1682     require_dri_shared_libs_and_glapi "DRI"
1683
1684     # not a hard requirement as swrast does not depend on it
1685     if test "x$have_libdrm" = xyes; then
1686         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1687     fi
1688 fi
1689
1690 AC_ARG_ENABLE([driglx-direct],
1691     [AS_HELP_STRING([--disable-driglx-direct],
1692         [disable direct rendering in GLX and EGL for DRI \
1693             @<:@default=enabled@:>@])],
1694     [driglx_direct="$enableval"],
1695     [driglx_direct="yes"])
1696
1697 dnl
1698 dnl libGL configuration per driver
1699 dnl
1700 if test "x$enable_glx" != xno; then
1701     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1702 fi
1703 case "x$enable_glx" in
1704 xxlib | xgallium-xlib)
1705     # Xlib-based GLX
1706     dri_modules="x11 xext xcb"
1707     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1708     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1709     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1710     GL_LIB_DEPS="$XLIBGL_LIBS"
1711     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1712     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1713     ;;
1714 xdri)
1715     # DRI-based GLX
1716
1717     require_dri_shared_libs_and_glapi "GLX"
1718
1719     # find the DRI deps for libGL
1720     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1721
1722     if test x"$driglx_direct" = xyes; then
1723         if test x"$dri_platform" = xdrm ; then
1724             DEFINES="$DEFINES -DGLX_USE_DRM"
1725             require_libdrm "Direct rendering"
1726
1727             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1728             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1729
1730             if test x"$enable_dri" = xyes; then
1731                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1732             fi
1733
1734             dri_modules="$dri_modules xxf86vm"
1735         fi
1736         if test x"$dri_platform" = xapple ; then
1737             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1738         fi
1739         if test x"$dri_platform" = xwindows ; then
1740             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1741         fi
1742     fi
1743
1744     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1745     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1746     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1747     GL_LIB_DEPS="$DRIGL_LIBS"
1748
1749     # need DRM libs, $PTHREAD_LIBS, etc.
1750     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1751     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1752     ;;
1753 esac
1754
1755 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1756 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1757 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1758 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1759
1760 AC_SUBST([X11_INCLUDES])
1761 AC_SUBST([GL_LIB_DEPS])
1762 AC_SUBST([GL_PC_REQ_PRIV])
1763 AC_SUBST([GL_PC_LIB_PRIV])
1764 AC_SUBST([GL_PC_CFLAGS])
1765 AC_SUBST([DRI_PC_REQ_PRIV])
1766 AC_SUBST([GLESv1_CM_LIB_DEPS])
1767 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1768 AC_SUBST([GLESv2_LIB_DEPS])
1769 AC_SUBST([GLESv2_PC_LIB_PRIV])
1770
1771 dnl
1772 dnl More GLX setup
1773 dnl
1774 case "x$enable_glx" in
1775 xxlib | xgallium-xlib)
1776     DEFINES="$DEFINES -DUSE_XSHM"
1777     ;;
1778 xdri)
1779     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1780     if test "x$driglx_direct" = xyes; then
1781         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1782     fi
1783     ;;
1784 esac
1785
1786 dnl
1787 dnl TLS detection
1788 dnl
1789
1790 AC_ARG_ENABLE([glx-tls],
1791     [AS_HELP_STRING([--enable-glx-tls],
1792         [enable TLS support in GLX @<:@default=enabled@:>@])],
1793     [GLX_USE_TLS="$enableval"],
1794     [GLX_USE_TLS=yes])
1795 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1796
1797 if test "x$GLX_USE_TLS" = xyes; then
1798     DEFINES="$DEFINES -DGLX_USE_TLS"
1799 fi
1800
1801 dnl Read-only text section on x86 hardened platforms
1802 AC_ARG_ENABLE([glx-read-only-text],
1803     [AS_HELP_STRING([--enable-glx-read-only-text],
1804         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1805     [enable_glx_read_only_text="$enableval"],
1806     [enable_glx_read_only_text=no])
1807 if test "x$enable_glx_read_only_text" = xyes; then
1808     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1809 fi
1810
1811 dnl
1812 dnl DEPRECATED: EGL Platforms configuration
1813 dnl
1814 AC_ARG_WITH([egl-platforms],
1815     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1816         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1817     [with_egl_platforms="$withval"],
1818     [with_egl_platforms=auto])
1819
1820 if test "x$with_egl_platforms" = xauto; then
1821     with_egl_platforms="x11,surfaceless"
1822     if test "x$enable_gbm" = xyes; then
1823         with_egl_platforms="$with_egl_platforms,drm"
1824     fi
1825 else
1826     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1827 fi
1828
1829 dnl
1830 dnl Platforms configuration
1831 dnl
1832 AC_ARG_WITH([platforms],
1833     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1834         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1835         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1836     [with_platforms="$withval"],
1837     [with_platforms=auto])
1838
1839 # Reuse the autodetection rather than duplicating it.
1840 if test "x$with_platforms" = xauto; then
1841     with_platforms=$with_egl_platforms
1842 fi
1843
1844 # Do per platform setups and checks
1845 platforms=`IFS=', '; echo $with_platforms`
1846 for plat in $platforms; do
1847     case "$plat" in
1848     wayland)
1849
1850         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1851         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1852         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1853         if test "x$enable_egl" = xyes; then
1854           PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1855         fi
1856         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1857
1858         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1859                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1860                           WAYLAND_SCANNER='')
1861         PKG_CHECK_EXISTS([wayland-scanner >= 1.15],
1862                           AC_SUBST(SCANNER_ARG, 'private-code'),
1863                           AC_SUBST(SCANNER_ARG, 'code'))
1864
1865         if test "x$WAYLAND_SCANNER" = x; then
1866             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1867         fi
1868
1869         if test "x$WAYLAND_SCANNER" = "x:"; then
1870                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1871         fi
1872         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1873         ;;
1874
1875     x11)
1876         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1877         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1878         ;;
1879
1880     drm)
1881         test "x$enable_egl" = "xyes" &&
1882         test "x$enable_gbm" = "xno" &&
1883                 AC_MSG_ERROR([EGL platform drm needs gbm])
1884         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1885         ;;
1886
1887     surfaceless)
1888         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1889         ;;
1890
1891     android)
1892         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1893         if test -n "$with_gallium_drivers"; then
1894             PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1895         fi
1896         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1897         ;;
1898
1899     *)
1900         AC_MSG_ERROR([platform '$plat' does not exist])
1901         ;;
1902     esac
1903
1904     case "$plat" in
1905     wayland|drm|surfaceless)
1906         require_libdrm "Platform $plat"
1907         ;;
1908     esac
1909 done
1910 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1911
1912 if test "x$enable_glx" != xno; then
1913     if ! echo "$platforms" | grep -q 'x11'; then
1914         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1915     fi
1916 fi
1917
1918 if test x"$enable_dri3" = xyes; then
1919     DEFINES="$DEFINES -DHAVE_DRI3"
1920
1921     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1922     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1923     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1924     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1925
1926     if test "x$have_dri3_modifiers" = xyes; then
1927         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1928     fi
1929 fi
1930
1931
1932 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1933     have_xlease=yes
1934 else
1935     have_xlease=no
1936 fi
1937
1938 if test x"$have_xlease" = xyes; then
1939     randr_modules="x11-xcb xcb-randr"
1940     PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1941     xlib_randr_modules="xrandr"
1942     PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1943 fi
1944
1945 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1946 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1947 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1948 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1949 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1950
1951 AC_ARG_ENABLE(xlib-lease,
1952     [AS_HELP_STRING([--enable-xlib-lease]
1953                     [enable VK_acquire_xlib_display using X leases])],
1954     [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1955 case "x$enable_xlib_lease" in
1956 xyes)
1957     ;;
1958 xno)
1959     ;;
1960 *)
1961     if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1962         enable_xlib_lease=yes
1963     else
1964         enable_xlib_lease=no
1965     fi
1966 esac
1967
1968 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1969
1970 dnl
1971 dnl More DRI setup
1972 dnl
1973 dnl Directory for DRI drivers
1974 AC_ARG_WITH([dri-driverdir],
1975     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1976         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1977     [DRI_DRIVER_INSTALL_DIR="$withval"],
1978     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1979 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1980 dnl Extra search path for DRI drivers
1981 AC_ARG_WITH([dri-searchpath],
1982     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1983         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1984     [DRI_DRIVER_SEARCH_DIR="$withval"],
1985     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1986 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1987 dnl Which drivers to build - default is chosen by platform
1988 AC_ARG_WITH([dri-drivers],
1989     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1990         [comma delimited classic DRI drivers list, e.g.
1991         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1992     [with_dri_drivers="$withval"],
1993     [with_dri_drivers=auto])
1994
1995 if test "x$with_dri_drivers" = xauto; then
1996     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1997         with_dri_drivers="yes"
1998     else
1999         with_dri_drivers="no"
2000     fi
2001 fi
2002 if test "x$with_dri_drivers" = xno; then
2003     with_dri_drivers=''
2004 fi
2005
2006 # Check for expat
2007 PKG_CHECK_MODULES([EXPAT], [expat],,
2008     [PKG_CHECK_MODULES([EXPAT], [expat21])]
2009 )
2010
2011 dnl If $with_dri_drivers is yes, drivers will be added through
2012 dnl platform checks. Set DEFINES and LIB_DEPS
2013 if test "x$enable_dri" = xyes; then
2014     # Platform specific settings and drivers to build
2015     case "$host_os" in
2016     linux*)
2017         case "$host_cpu" in
2018         powerpc* | sparc*)
2019             # Build only the drivers for cards that exist on PowerPC/sparc
2020             if test "x$with_dri_drivers" = "xyes"; then
2021                 with_dri_drivers="r200 radeon swrast"
2022             fi
2023             ;;
2024         esac
2025         ;;
2026     cygwin*)
2027         if test "x$with_dri_drivers" = "xyes"; then
2028             with_dri_drivers="swrast"
2029         fi
2030         ;;
2031     darwin*)
2032         DEFINES="$DEFINES -DBUILDING_MESA"
2033         if test "x$with_dri_drivers" = "xyes"; then
2034             with_dri_drivers="swrast"
2035         fi
2036         ;;
2037     esac
2038
2039     # default drivers
2040     if test "x$with_dri_drivers" = "xyes"; then
2041         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
2042     fi
2043
2044     # put all the necessary libs together
2045     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
2046 fi
2047
2048 AC_SUBST([DRI_LIB_DEPS])
2049
2050 DRI_DIRS=''
2051 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
2052 if test -n "$with_dri_drivers"; then
2053     if test "x$enable_opengl" != xyes; then
2054         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2055     fi
2056
2057     dri_drivers=`IFS=', '; echo $with_dri_drivers`
2058     for driver in $dri_drivers; do
2059         DRI_DIRS="$DRI_DIRS $driver"
2060         case "x$driver" in
2061         xi915)
2062             require_libdrm "i915"
2063             HAVE_I915_DRI=yes
2064             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2065             ;;
2066         xi965)
2067             require_libdrm "i965"
2068             HAVE_I965_DRI=yes
2069             ;;
2070         xnouveau)
2071             require_libdrm "nouveau"
2072             HAVE_NOUVEAU_DRI=yes
2073             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2074             ;;
2075         xradeon)
2076             require_libdrm "radeon"
2077             HAVE_RADEON_DRI=yes;
2078             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2079             ;;
2080         xr200)
2081             require_libdrm "r200"
2082             HAVE_R200_DRI=yes
2083             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2084             ;;
2085         xswrast)
2086             HAVE_SWRAST_DRI=yes
2087             ;;
2088         *)
2089             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2090             ;;
2091         esac
2092     done
2093     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2094 fi
2095
2096
2097 dnl
2098 dnl Gallium LLVM
2099 dnl Deprecated: kept for backwards compatibility
2100 dnl
2101 AC_ARG_ENABLE([gallium-llvm],
2102     [AS_HELP_STRING([--enable-gallium-llvm],
2103         [DEPRECATED: use --enable-llvm instead])],
2104     [enable_gallium_llvm="$enableval"],
2105     [enable_gallium_llvm=auto])
2106
2107 if test "x$enable_gallium_llvm" != xauto; then
2108    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2109    enable_llvm=$enable_gallium_llvm
2110 fi
2111
2112 dnl
2113 dnl LLVM
2114 dnl
2115 AC_ARG_ENABLE([llvm],
2116     [AS_HELP_STRING([--enable-llvm],
2117         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2118     [enable_llvm="$enableval"],
2119     [enable_llvm=auto])
2120
2121 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2122     if test "x$FOUND_LLVM" = xyes; then
2123         case "$host_cpu" in
2124         i*86|x86_64|amd64) enable_llvm=yes;;
2125         *) enable_llvm=no;;
2126         esac
2127     else
2128         enable_llvm=no
2129     fi
2130 fi
2131
2132 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2133     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2134 fi
2135
2136 #
2137 # Vulkan driver configuration
2138 #
2139
2140 AC_ARG_WITH([vulkan-drivers],
2141     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2142         [comma delimited Vulkan drivers list, e.g.
2143         "intel,radeon"
2144         @<:@default=no@:>@])],
2145     [with_vulkan_drivers="$withval"],
2146     [with_vulkan_drivers="no"])
2147
2148 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2149 # here so that the script doesn't choke on an unknown driver name later.
2150 case "x$with_vulkan_drivers" in
2151     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2152     xno) with_vulkan_drivers='' ;;
2153 esac
2154
2155 AC_ARG_WITH([vulkan-icddir],
2156     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2157         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2158     [VULKAN_ICD_INSTALL_DIR="$withval"],
2159     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2160 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2161
2162 require_x11_dri3() {
2163     if echo "$platforms" | grep -q 'x11'; then
2164         if test "x$enable_dri3" != xyes; then
2165             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2166         fi
2167     fi
2168 }
2169
2170 if test -n "$with_vulkan_drivers"; then
2171     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2172         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2173     fi
2174
2175     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2176     for driver in $VULKAN_DRIVERS; do
2177         case "x$driver" in
2178         xintel)
2179             require_libdrm "ANV"
2180             require_x11_dri3 "ANV"
2181             HAVE_INTEL_VULKAN=yes
2182             ;;
2183         xradeon)
2184             require_libdrm "radv"
2185             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2186             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2187             require_x11_dri3 "radv"
2188             if test "x$acv_mako_found" = xno; then
2189                 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2190             fi
2191             HAVE_RADEON_VULKAN=yes
2192             ;;
2193         *)
2194             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2195             ;;
2196         esac
2197     done
2198     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2199 fi
2200
2201
2202 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2203 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2204 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2205                                   "x$enable_osmesa" = xyes -o \
2206                                   -n "$DRI_DIRS")
2207
2208 dnl
2209 dnl OSMesa configuration
2210 dnl
2211
2212 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2213 AC_ARG_WITH([osmesa-bits],
2214     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2215         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2216     [osmesa_bits="$withval"],
2217     [osmesa_bits=8])
2218 if test "x$osmesa_bits" != x8; then
2219     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2220         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2221         osmesa_bits=8
2222     fi
2223 fi
2224 case "x$osmesa_bits" in
2225 x8)
2226     OSMESA_LIB="${OSMESA_LIB}"
2227     ;;
2228 x16|x32)
2229     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2230     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2231     ;;
2232 *)
2233     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2234     ;;
2235 esac
2236
2237 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2238     # only link libraries with osmesa if shared
2239     if test "$enable_static" = no; then
2240         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2241     else
2242         OSMESA_LIB_DEPS=""
2243     fi
2244     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2245 fi
2246
2247 AC_SUBST([OSMESA_LIB_DEPS])
2248 AC_SUBST([OSMESA_PC_REQ])
2249 AC_SUBST([OSMESA_PC_LIB_PRIV])
2250
2251 dnl
2252 dnl gbm configuration
2253 dnl
2254 if test "x$enable_gbm" = xyes; then
2255     require_dri_shared_libs_and_glapi "gbm"
2256 fi
2257 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2258 # FINISHME: GBM has a number of dependencies which we should add below
2259 GBM_PC_REQ_PRIV=""
2260 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2261 AC_SUBST([GBM_PC_REQ_PRIV])
2262 AC_SUBST([GBM_PC_LIB_PRIV])
2263
2264 dnl
2265 dnl EGL configuration
2266 dnl
2267
2268 if test "x$enable_egl" = xyes; then
2269     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2270
2271     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2272
2273     require_dri_shared_libs_and_glapi "egl"
2274 fi
2275 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2276 AC_SUBST([EGL_LIB_DEPS])
2277
2278 gallium_st="mesa"
2279
2280 dnl
2281 dnl XA configuration
2282 dnl
2283 if test "x$enable_xa" = xyes; then
2284     if test "x$with_gallium_drivers" = xswrast; then
2285        AC_MSG_ERROR([
2286           Building xa requires at least one non swrast gallium driver.
2287           If you are looking to use libxatracker.so with the VMware driver,
2288           make sure to include svga in the gallium drivers list, apart from
2289           enabling XA.
2290           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2291     fi
2292     gallium_st="$gallium_st xa"
2293 fi
2294 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2295
2296 if echo $platforms | grep -q "x11"; then
2297     have_xvmc_platform=yes
2298 else
2299     have_xvmc_platform=no
2300 fi
2301
2302 if echo $platforms | grep -q "x11"; then
2303     have_vdpau_platform=yes
2304 else
2305     have_vdpau_platform=no
2306 fi
2307
2308 if echo $platforms | egrep -q "x11|drm"; then
2309     have_omx_platform=yes
2310 else
2311     have_omx_platform=no
2312 fi
2313
2314 if echo $platforms | egrep -q "x11|drm|wayland"; then
2315     have_va_platform=yes
2316 else
2317     have_va_platform=no
2318 fi
2319
2320 dnl
2321 dnl Gallium G3DVL configuration
2322 dnl
2323 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2324     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2325         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2326     fi
2327
2328     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2329         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2330     fi
2331
2332     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2333         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2334     fi
2335
2336     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2337        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2338     fi
2339
2340     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2341         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2342     fi
2343 fi
2344
2345 if test "x$enable_dri" = xyes -o \
2346         "x$enable_xvmc" = xyes -o \
2347         "x$enable_vdpau" = xyes -o \
2348         "x$enable_omx_bellagio" = xyes -o \
2349         "x$enable_omx_tizonia" = xyes -o \
2350         "x$enable_va" = xyes; then
2351     need_gallium_vl=yes
2352 fi
2353 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2354
2355 if test "x$enable_xvmc" = xyes -o \
2356         "x$enable_vdpau" = xyes -o \
2357         "x$enable_omx_bellagio" = xyes -o \
2358         "x$enable_omx_tizonia" = xyes -o \
2359         "x$enable_va" = xyes; then
2360     if echo $platforms | grep -q "x11"; then
2361         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2362     fi
2363     need_gallium_vl_winsys=yes
2364 fi
2365 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2366
2367 if test "x$enable_xvmc" = xyes; then
2368     if test "x$have_xvmc_platform" != xyes; then
2369         AC_MSG_ERROR([XVMC requires the x11 platforms])
2370     fi
2371     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2372     gallium_st="$gallium_st xvmc"
2373 fi
2374 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2375
2376 if test "x$enable_vdpau" = xyes; then
2377     if test "x$have_vdpau_platform" != xyes; then
2378         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2379     fi
2380     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2381     gallium_st="$gallium_st vdpau"
2382     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2383 fi
2384 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2385
2386 if test "x$enable_omx_bellagio" = xyes; then
2387     if test "x$have_omx_platform" != xyes; then
2388         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2389     fi
2390     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2391     gallium_st="$gallium_st omx_bellagio"
2392     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2393 else
2394     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2395 fi
2396 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2397
2398 if test "x$enable_omx_tizonia" = xyes; then
2399     if test "x$have_omx_platform" != xyes; then
2400         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2401     fi
2402     PKG_CHECK_MODULES([OMX_TIZONIA],
2403                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2404                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2405                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2406     gallium_st="$gallium_st omx_tizonia"
2407     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2408 else
2409     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2410 fi
2411 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2412
2413 if test "x$enable_va" = xyes; then
2414     if test "x$have_va_platform" != xyes; then
2415         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2416     fi
2417     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2418     gallium_st="$gallium_st va"
2419 fi
2420 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2421
2422 dnl
2423 dnl Nine Direct3D9 configuration
2424 dnl
2425 if test "x$enable_nine" = xyes; then
2426     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2427         AC_MSG_ERROR([nine requires the gallium swrast driver])
2428     fi
2429     if test "x$with_gallium_drivers" = xswrast; then
2430         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2431     fi
2432     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2433         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2434     fi
2435
2436     if test "x$enable_dri3" = xno; then
2437         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2438     fi
2439
2440     gallium_st="$gallium_st nine"
2441 fi
2442 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2443
2444 dnl
2445 dnl OpenCL configuration
2446 dnl
2447
2448 AC_ARG_WITH([clang-libdir],
2449    [AS_HELP_STRING([--with-clang-libdir],
2450          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2451    [CLANG_LIBDIR="$withval"],
2452    [CLANG_LIBDIR=''])
2453
2454 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2455
2456 if test "x$enable_opencl" = xyes; then
2457     if test -z "$with_gallium_drivers"; then
2458         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2459     fi
2460
2461     if test "x$HAVE_CXX11" != "xyes"; then
2462        AC_MSG_ERROR([clover requires c++11 support])
2463     fi
2464
2465     if test "x$have_libclc" = xno; then
2466         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2467                     Make sure the directory containing libclc.pc is specified in your
2468                     PKG_CONFIG_PATH environment variable.
2469                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2470     else
2471         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2472         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2473         AC_SUBST([LIBCLC_INCLUDEDIR])
2474         AC_SUBST([LIBCLC_LIBEXECDIR])
2475     fi
2476
2477     gallium_st="$gallium_st clover"
2478
2479     if test "x$enable_opencl_icd" = xyes; then
2480         OPENCL_LIBNAME="MesaOpenCL"
2481     else
2482         OPENCL_LIBNAME="OpenCL"
2483     fi
2484
2485     if test "x$have_libelf" != xyes; then
2486        AC_MSG_ERROR([Clover requires libelf])
2487     fi
2488
2489     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2490         altivec_enabled=no
2491         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2492         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2493         #error "AltiVec not enabled"
2494         #endif
2495         ])], altivec_enabled=yes)
2496
2497         if test "$altivec_enabled" = yes; then
2498             CLOVER_STD_OVERRIDE="-std=gnu++11"
2499         fi
2500         AC_SUBST([CLOVER_STD_OVERRIDE])
2501     fi
2502
2503     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2504
2505     llvm_add_default_components "opencl"
2506     llvm_add_component "all-targets" "opencl"
2507     llvm_add_component "coverage" "opencl"
2508     llvm_add_component "linker" "opencl"
2509     llvm_add_component "instrumentation" "opencl"
2510     llvm_add_component "ipo" "opencl"
2511     llvm_add_component "irreader" "opencl"
2512     llvm_add_component "lto" "opencl"
2513     llvm_add_component "option" "opencl"
2514     llvm_add_component "objcarcopts" "opencl"
2515     llvm_add_component "profiledata" "opencl"
2516     llvm_add_optional_component "coroutines" "opencl"
2517
2518     dnl Check for Clang internal headers
2519     if test -z "$CLANG_LIBDIR"; then
2520         CLANG_LIBDIR=${LLVM_LIBDIR}
2521     fi
2522     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2523     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2524         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2525 fi
2526 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2527 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2528 AC_SUBST([OPENCL_LIBNAME])
2529 AC_SUBST([CLANG_RESOURCE_DIR])
2530
2531 dnl
2532 dnl Gallium configuration
2533 dnl
2534 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2535
2536 # libEGL wants to default to the first platform specified in
2537 # ./configure.  parse that here.
2538 if test "x$platforms" != "x"; then
2539     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2540     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2541 else
2542     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2543 fi
2544
2545 AC_SUBST([EGL_NATIVE_PLATFORM])
2546 AC_SUBST([EGL_CFLAGS])
2547
2548 # If we don't have the X11 platform, set this define so we don't try to include
2549 # the X11 headers.
2550 if ! echo "$platforms" | grep -q 'x11'; then
2551     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2552     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2553 fi
2554
2555 dnl Directory for XVMC libs
2556 AC_ARG_WITH([xvmc-libdir],
2557     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2558         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2559     [XVMC_LIB_INSTALL_DIR="$withval"],
2560     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2561 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2562
2563 dnl
2564 dnl Gallium Tests
2565 dnl
2566 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2567
2568 dnl Directory for VDPAU libs
2569 AC_ARG_WITH([vdpau-libdir],
2570     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2571         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2572     [VDPAU_LIB_INSTALL_DIR="$withval"],
2573     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2574 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2575
2576 dnl Directory for OMX_BELLAGIO libs
2577
2578 AC_ARG_WITH([omx-bellagio-libdir],
2579     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2580         [directory for the OMX_BELLAGIO libraries])],
2581     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2582     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2583                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2584 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2585
2586 dnl Directory for OMX_TIZONIA libs
2587
2588 AC_ARG_WITH([omx-tizonia-libdir],
2589     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2590         [directory for the OMX_TIZONIA libraries])],
2591     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2592     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2593 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2594
2595 dnl Directory for VA libs
2596
2597 AC_ARG_WITH([va-libdir],
2598     [AS_HELP_STRING([--with-va-libdir=DIR],
2599         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2600     [VA_LIB_INSTALL_DIR="$withval"],
2601     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2602 AC_SUBST([VA_LIB_INSTALL_DIR])
2603
2604 AC_ARG_WITH([d3d-libdir],
2605     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2606         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2607     [D3D_DRIVER_INSTALL_DIR="$withval"],
2608     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2609 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2610
2611 dnl Architectures to build SWR library for
2612
2613 AC_ARG_WITH([swr-archs],
2614     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2615         [comma delimited swr architectures list, e.g.
2616         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2617     [with_swr_archs="$withval"],
2618     [with_swr_archs="avx,avx2"])
2619
2620 dnl
2621 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2622 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2623 dnl architectures.
2624 dnl
2625 r300_require_llvm() {
2626     case "$host" in *gnux32) return;; esac
2627     case "$host_cpu" in
2628     i*86|x86_64|amd64) require_llvm $1
2629         ;;
2630     esac
2631 }
2632
2633 dnl
2634 dnl DRM is needed by X, Wayland, and offscreen rendering.
2635 dnl Surfaceless is an alternative for the last one.
2636 dnl
2637 require_basic_egl() {
2638     case "$with_platforms" in
2639         *drm*|*surfaceless*|*android*)
2640             ;;
2641         *)
2642             AC_MSG_ERROR([$1 requires one of these:
2643                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2644                   2) --with-platforms=surfaceless (offscreen only)
2645                   3) --with-platforms=android (Android only)
2646                   Recommended options: drm,x11])
2647             ;;
2648     esac
2649 }
2650
2651 swr_require_cxx_feature_flags() {
2652     feature_name="$1"
2653     preprocessor_test="$2"
2654     option_list="$3"
2655     output_var="$4"
2656
2657     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2658     AC_LANG_PUSH([C++])
2659     save_CXXFLAGS="$CXXFLAGS"
2660     save_IFS="$IFS"
2661     IFS=","
2662     found=0
2663     for opts in $option_list
2664     do
2665         unset IFS
2666         CXXFLAGS="$opts $save_CXXFLAGS"
2667         AC_COMPILE_IFELSE(
2668             [AC_LANG_PROGRAM(
2669                 [   #if !($preprocessor_test)
2670                     #error
2671                     #endif
2672                 ])],
2673             [found=1; break],
2674             [])
2675         IFS=","
2676     done
2677     IFS="$save_IFS"
2678     CXXFLAGS="$save_CXXFLAGS"
2679     AC_LANG_POP([C++])
2680     if test $found -eq 1; then
2681         AC_MSG_RESULT([$opts])
2682         eval "$output_var=\$opts"
2683         return 0
2684     fi
2685     AC_MSG_RESULT([no])
2686     AC_MSG_ERROR([swr requires $feature_name support])
2687     return 1
2688 }
2689
2690 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2691 if test -n "$with_gallium_drivers"; then
2692     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2693     for driver in $gallium_drivers; do
2694         case "x$driver" in
2695         xsvga)
2696             HAVE_GALLIUM_SVGA=yes
2697             require_libdrm "svga"
2698             ;;
2699         xi915)
2700             HAVE_GALLIUM_I915=yes
2701             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2702             require_libdrm "Gallium i915"
2703             ;;
2704         xr300)
2705             HAVE_GALLIUM_R300=yes
2706             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2707             require_libdrm "r300"
2708             r300_require_llvm "r300"
2709             ;;
2710         xr600)
2711             HAVE_GALLIUM_R600=yes
2712             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2713             require_libdrm "r600"
2714             if test "x$enable_llvm" = xyes; then
2715                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2716
2717                 llvm_add_component "asmparser" "r600"
2718                 llvm_add_component "bitreader" "r600"
2719             fi
2720             ;;
2721         xradeonsi)
2722             HAVE_GALLIUM_RADEONSI=yes
2723             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2724             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2725             require_libdrm "radeonsi"
2726             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2727             if test "x$enable_egl" = xyes; then
2728                 require_basic_egl "radeonsi"
2729             fi
2730             ;;
2731         xnouveau)
2732             HAVE_GALLIUM_NOUVEAU=yes
2733             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2734             require_libdrm "nouveau"
2735             ;;
2736         xfreedreno)
2737             HAVE_GALLIUM_FREEDRENO=yes
2738             require_libdrm "freedreno"
2739             ;;
2740         xetnaviv)
2741             HAVE_GALLIUM_ETNAVIV=yes
2742             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2743             require_libdrm "etnaviv"
2744             ;;
2745         xtegra)
2746             HAVE_GALLIUM_TEGRA=yes
2747             require_libdrm "tegra"
2748             ;;
2749         xswrast)
2750             HAVE_GALLIUM_SOFTPIPE=yes
2751             if test "x$enable_llvm" = xyes; then
2752                 HAVE_GALLIUM_LLVMPIPE=yes
2753             fi
2754             ;;
2755         xswr)
2756             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2757
2758             if test "x$HAVE_CXX11" != "xyes"; then
2759                 AC_MSG_ERROR([swr requires c++11 support])
2760             fi
2761
2762             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2763                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2764                 SWR_AVX_CXXFLAGS
2765             AC_SUBST([SWR_AVX_CXXFLAGS])
2766
2767             swr_archs=`IFS=', '; echo $with_swr_archs`
2768             for arch in $swr_archs; do
2769                 case "x$arch" in
2770                 xavx)
2771                     HAVE_SWR_AVX=yes
2772                     ;;
2773                 xavx2)
2774                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2775                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2776                         SWR_AVX2_CXXFLAGS
2777                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2778                     HAVE_SWR_AVX2=yes
2779                     ;;
2780                 xknl)
2781                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2782                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2783                         SWR_KNL_CXXFLAGS
2784                     AC_SUBST([SWR_KNL_CXXFLAGS])
2785                     HAVE_SWR_KNL=yes
2786                     ;;
2787                 xskx)
2788                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2789                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2790                         SWR_SKX_CXXFLAGS
2791                     AC_SUBST([SWR_SKX_CXXFLAGS])
2792                     HAVE_SWR_SKX=yes
2793                     ;;
2794                 *)
2795                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2796                     ;;
2797                 esac
2798             done
2799
2800             if test "x$HAVE_SWR_AVX" != xyes -a \
2801                     "x$HAVE_SWR_AVX2" != xyes -a \
2802                     "x$HAVE_SWR_KNL" != xyes -a \
2803                     "x$HAVE_SWR_SKX" != xyes; then
2804                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2805             fi
2806
2807             # test if more than one swr arch configured
2808             if test `echo $swr_archs | wc -w` -eq 1; then
2809                 HAVE_SWR_BUILTIN=yes
2810             fi
2811
2812             HAVE_GALLIUM_SWR=yes
2813             ;;
2814         xvc4)
2815             HAVE_GALLIUM_VC4=yes
2816             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2817
2818             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2819                               [USE_VC4_SIMULATOR=yes;
2820                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2821                               [USE_VC4_SIMULATOR=no])
2822             ;;
2823         xv3d)
2824             HAVE_GALLIUM_V3D=yes
2825
2826             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2827                               [USE_V3D_SIMULATOR=yes;
2828                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2829                               [USE_V3D_SIMULATOR=no])
2830             ;;
2831         xkmsro)
2832             HAVE_GALLIUM_KMSRO=yes
2833             ;;
2834         xvirgl)
2835             HAVE_GALLIUM_VIRGL=yes
2836             require_libdrm "virgl"
2837             if test "x$enable_egl" = xyes; then
2838                 require_basic_egl "virgl"
2839             fi
2840             ;;
2841         *)
2842             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2843             ;;
2844         esac
2845     done
2846 fi
2847
2848 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2849 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x6.0.0 -a \
2850                                               "x$LLVM_VERSION" != x6.0.1)
2851
2852 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2853     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2854     llvm_add_default_components "gallium"
2855 fi
2856
2857 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2858 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2859 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2860 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2861 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2862
2863 dnl We need to validate some needed dependencies for renderonly drivers.
2864
2865 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_KMSRO" = xyes  ; then
2866     AC_MSG_ERROR([Building with kmsro requires vc4])
2867 fi
2868
2869 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2870     AC_MSG_ERROR([Building with tegra requires nouveau])
2871 fi
2872
2873 detect_old_buggy_llvm() {
2874     dnl llvm-config may not give the right answer when llvm is a built as a
2875     dnl single shared library, so we must work the library name out for
2876     dnl ourselves.
2877     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2878     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2879     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2880     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2881
2882     if test "x$llvm_have_one_so" = xyes; then
2883         dnl LLVM was built using auto*, so there is only one shared object.
2884         LLVM_LIBS="-l$LLVM_SO_NAME"
2885     else
2886         dnl If LLVM was built with CMake, there will be one shared object per
2887         dnl component.
2888         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2889                [AC_MSG_ERROR([Could not find llvm shared libraries:
2890                 Please make sure you have built llvm with the --enable-shared option
2891                 and that your llvm libraries are installed in $LLVM_LIBDIR
2892                 If you have installed your llvm libraries to a different directory you
2893                 can use the --with-llvm-prefix= configure flag to specify this directory.
2894                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2895                 If you do not want to build with llvm shared libraries and instead want to
2896                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2897                 invocation and rebuild.])])
2898
2899         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2900         dnl install uses a shared object for each component and we have
2901         dnl already added all of these objects to LLVM_LIBS.
2902     fi
2903 }
2904
2905 dnl
2906 dnl Set defines and buildtime variables only when using LLVM.
2907 dnl
2908 if test "x$enable_llvm" = xyes; then
2909     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2910
2911     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2912     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2913     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2914     LLVM_CXXFLAGS="$CXX11_CXXFLAGS $LLVM_CXXFLAGS"
2915
2916     dnl Set LLVM_LIBS - This is done after the driver configuration so
2917     dnl that drivers can add additional components to LLVM_COMPONENTS.
2918     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2919     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2920     dnl this was causing the same libraries to be appear multiple times
2921     dnl in LLVM_LIBS.
2922
2923     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2924         if test "x$enable_llvm_shared_libs" = xyes; then
2925             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2926         else
2927             dnl Invoking llvm-config with both -libs and --system-libs produces the
2928             dnl two separate lines - each for the set of libraries.
2929                 dnl Call the program twice, effectively folding them into a single line.
2930             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2931             dnl We need to link to llvm system libs when using static libs
2932             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2933         fi
2934     else
2935         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2936         if test "x$enable_llvm_shared_libs" = xyes; then
2937             detect_old_buggy_llvm
2938         else
2939             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2940             dnl We need to link to llvm system libs when using static libs
2941             dnl However, only llvm 3.5+ provides --system-libs
2942             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2943                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2944             fi
2945         fi
2946     fi
2947
2948     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2949     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2950     dnl the LLVM library propagated in the Libs.private of the respective .pc
2951     dnl file which ensures complete dependency information when statically
2952     dnl linking.
2953     if test "x$enable_glx" = xgallium-xlib; then
2954         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2955     fi
2956     if test "x$enable_gallium_osmesa" = xyes; then
2957         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2958     fi
2959 fi
2960
2961 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2962 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2963 AM_CONDITIONAL(HAVE_GALLIUM_KMSRO, test "x$HAVE_GALLIUM_KMSRO" = xyes)
2964 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2965 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2966 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2967 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2968 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2969 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2970 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2971 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2972 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2973 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2974 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2975                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2976                                          "x$HAVE_GALLIUM_SWR" = xyes)
2977 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2978 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2979 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2980
2981 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2982
2983 if test "x$enable_dri" = xyes; then
2984     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2985 fi
2986
2987 if test "x$have_drisw_kms" = xyes; then
2988     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2989 fi
2990 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2991
2992 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2993 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2994 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2995 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2996 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2997 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2998
2999 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
3000 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
3001
3002 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
3003                                       "x$HAVE_RADEON_VULKAN" = xyes)
3004
3005 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
3006                                       "x$HAVE_GALLIUM_V3D" = xyes)
3007
3008 AM_CONDITIONAL(HAVE_FREEDRENO_DRIVERS, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
3009 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
3010                                         "x$HAVE_I965_DRI" = xyes)
3011
3012 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
3013                                             "x$HAVE_GALLIUM_R600" = xyes -o \
3014                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
3015 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
3016 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
3017 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
3018 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
3019 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
3020
3021 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
3022 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
3023 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
3024 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
3025                                         "x$enable_gallium_osmesa" = xyes)
3026
3027 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
3028 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
3029 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
3030 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
3031 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
3032 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
3033
3034 AC_SUBST([NINE_MAJOR], 1)
3035 AC_SUBST([NINE_MINOR], 0)
3036 AC_SUBST([NINE_PATCH], 0)
3037 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
3038
3039 AC_SUBST([VDPAU_MAJOR], 1)
3040 AC_SUBST([VDPAU_MINOR], 0)
3041
3042 if test "x$enable_va" = xyes; then
3043     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
3044     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
3045 fi
3046 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3047 AC_SUBST([VA_MINOR], $VA_MINOR)
3048
3049 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3050
3051 AC_SUBST([XVMC_MAJOR], 1)
3052 AC_SUBST([XVMC_MINOR], 0)
3053
3054 AC_SUBST([XA_MAJOR], 2)
3055 AC_SUBST([XA_MINOR], 5)
3056 AC_SUBST([XA_PATCH], 0)
3057 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3058
3059 AC_ARG_ENABLE(valgrind,
3060               [AS_HELP_STRING([--enable-valgrind],
3061                              [Build mesa with valgrind support (default: auto)])],
3062                              [VALGRIND=$enableval], [VALGRIND=auto])
3063 if test "x$VALGRIND" != xno; then
3064     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3065 fi
3066 AC_MSG_CHECKING([whether to enable Valgrind support])
3067 if test "x$VALGRIND" = xauto; then
3068     VALGRIND="$have_valgrind"
3069 fi
3070
3071 if test "x$VALGRIND" = "xyes"; then
3072     if ! test "x$have_valgrind" = xyes; then
3073         AC_MSG_ERROR([Valgrind support required but not present])
3074     fi
3075     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3076 fi
3077
3078 AC_MSG_RESULT([$VALGRIND])
3079
3080 dnl Restore LDFLAGS and CPPFLAGS
3081 LDFLAGS="$_SAVE_LDFLAGS"
3082 CPPFLAGS="$_SAVE_CPPFLAGS"
3083
3084 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3085 if test "x$acv_mesa_CLANG" = xyes; then
3086     CFLAGS="$CFLAGS -Qunused-arguments"
3087     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3088 fi
3089
3090 dnl Add user CFLAGS and CXXFLAGS
3091 CFLAGS="$CFLAGS $USER_CFLAGS"
3092 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3093
3094 dnl Substitute the config
3095 AC_CONFIG_FILES([Makefile
3096                  src/Makefile
3097                  src/amd/Makefile
3098                  src/amd/vulkan/Makefile
3099                  src/broadcom/Makefile
3100                  src/compiler/Makefile
3101                  src/freedreno/Makefile
3102                  src/egl/Makefile
3103                  src/egl/main/egl.pc
3104                  src/egl/wayland/wayland-drm/Makefile
3105                  src/gallium/Makefile
3106                  src/gallium/auxiliary/Makefile
3107                  src/gallium/auxiliary/pipe-loader/Makefile
3108                  src/gallium/drivers/freedreno/Makefile
3109                  src/gallium/drivers/i915/Makefile
3110                  src/gallium/drivers/llvmpipe/Makefile
3111                  src/gallium/drivers/nouveau/Makefile
3112                  src/gallium/drivers/kmsro/Makefile
3113                  src/gallium/drivers/r300/Makefile
3114                  src/gallium/drivers/r600/Makefile
3115                  src/gallium/drivers/radeonsi/Makefile
3116                  src/gallium/drivers/softpipe/Makefile
3117                  src/gallium/drivers/svga/Makefile
3118                  src/gallium/drivers/swr/Makefile
3119                  src/gallium/drivers/tegra/Makefile
3120                  src/gallium/drivers/etnaviv/Makefile
3121                  src/gallium/drivers/v3d/Makefile
3122                  src/gallium/drivers/vc4/Makefile
3123                  src/gallium/drivers/virgl/Makefile
3124                  src/gallium/state_trackers/clover/Makefile
3125                  src/gallium/state_trackers/dri/Makefile
3126                  src/gallium/state_trackers/glx/xlib/Makefile
3127                  src/gallium/state_trackers/nine/Makefile
3128                  src/gallium/state_trackers/omx/Makefile
3129                  src/gallium/state_trackers/omx/bellagio/Makefile
3130                  src/gallium/state_trackers/omx/tizonia/Makefile
3131                  src/gallium/state_trackers/osmesa/Makefile
3132                  src/gallium/state_trackers/va/Makefile
3133                  src/gallium/state_trackers/vdpau/Makefile
3134                  src/gallium/state_trackers/xa/Makefile
3135                  src/gallium/state_trackers/xa/xa_tracker.h
3136                  src/gallium/state_trackers/xvmc/Makefile
3137                  src/gallium/targets/d3dadapter9/Makefile
3138                  src/gallium/targets/d3dadapter9/d3d.pc
3139                  src/gallium/targets/dri/Makefile
3140                  src/gallium/targets/libgl-xlib/Makefile
3141                  src/gallium/targets/omx/Makefile
3142                  src/gallium/targets/opencl/Makefile
3143                  src/gallium/targets/opencl/mesa.icd
3144                  src/gallium/targets/osmesa/Makefile
3145                  src/gallium/targets/osmesa/osmesa.pc
3146                  src/gallium/targets/pipe-loader/Makefile
3147                  src/gallium/targets/va/Makefile
3148                  src/gallium/targets/vdpau/Makefile
3149                  src/gallium/targets/xa/Makefile
3150                  src/gallium/targets/xa/xatracker.pc
3151                  src/gallium/targets/xvmc/Makefile
3152                  src/gallium/tests/trivial/Makefile
3153                  src/gallium/tests/unit/Makefile
3154                  src/gallium/winsys/etnaviv/drm/Makefile
3155                  src/gallium/winsys/freedreno/drm/Makefile
3156                  src/gallium/winsys/i915/drm/Makefile
3157                  src/gallium/winsys/nouveau/drm/Makefile
3158                  src/gallium/winsys/kmsro/drm/Makefile
3159                  src/gallium/winsys/radeon/drm/Makefile
3160                  src/gallium/winsys/amdgpu/drm/Makefile
3161                  src/gallium/winsys/svga/drm/Makefile
3162                  src/gallium/winsys/sw/dri/Makefile
3163                  src/gallium/winsys/sw/kms-dri/Makefile
3164                  src/gallium/winsys/sw/null/Makefile
3165                  src/gallium/winsys/sw/wrapper/Makefile
3166                  src/gallium/winsys/sw/xlib/Makefile
3167                  src/gallium/winsys/tegra/drm/Makefile
3168                  src/gallium/winsys/v3d/drm/Makefile
3169                  src/gallium/winsys/vc4/drm/Makefile
3170                  src/gallium/winsys/virgl/drm/Makefile
3171                  src/gallium/winsys/virgl/vtest/Makefile
3172                  src/gbm/Makefile
3173                  src/gbm/main/gbm.pc
3174                  src/glx/Makefile
3175                  src/glx/apple/Makefile
3176                  src/glx/tests/Makefile
3177                  src/glx/windows/Makefile
3178                  src/glx/windows/windowsdriproto.pc
3179                  src/gtest/Makefile
3180                  src/intel/Makefile
3181                  src/loader/Makefile
3182                  src/mapi/Makefile
3183                  src/mapi/es1api/glesv1_cm.pc
3184                  src/mapi/es2api/glesv2.pc
3185                  src/mapi/glapi/gen/Makefile
3186                  src/mesa/Makefile
3187                  src/mesa/gl.pc
3188                  src/mesa/drivers/dri/dri.pc
3189                  src/mesa/drivers/dri/common/Makefile
3190                  src/mesa/drivers/dri/i915/Makefile
3191                  src/mesa/drivers/dri/i965/Makefile
3192                  src/mesa/drivers/dri/Makefile
3193                  src/mesa/drivers/dri/nouveau/Makefile
3194                  src/mesa/drivers/dri/r200/Makefile
3195                  src/mesa/drivers/dri/radeon/Makefile
3196                  src/mesa/drivers/dri/swrast/Makefile
3197                  src/mesa/drivers/osmesa/Makefile
3198                  src/mesa/drivers/osmesa/osmesa.pc
3199                  src/mesa/drivers/x11/Makefile
3200                  src/mesa/main/tests/Makefile
3201                  src/mesa/state_tracker/tests/Makefile
3202                  src/util/Makefile
3203                  src/util/tests/fast_idiv_by_const/Makefile
3204                  src/util/tests/hash_table/Makefile
3205                  src/util/tests/set/Makefile
3206                  src/util/tests/string_buffer/Makefile
3207                  src/util/tests/vma/Makefile
3208                  src/util/xmlpool/Makefile
3209                  src/vulkan/Makefile])
3210
3211 AC_OUTPUT
3212
3213 # Fix up dependencies in *.Plo files, where we changed the extension of a
3214 # source file
3215 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3216
3217 rm -f src/compiler/spirv/spirv_info.lo
3218 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3219
3220 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3221 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3222
3223 dnl
3224 dnl Output some configuration info for the user
3225 dnl
3226 echo ""
3227 echo "        prefix:          $prefix"
3228 echo "        exec_prefix:     $exec_prefix"
3229 echo "        libdir:          $libdir"
3230 echo "        includedir:      $includedir"
3231
3232 dnl API info
3233 echo ""
3234 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3235
3236 dnl Driver info
3237 echo ""
3238 case "x$enable_osmesa$enable_gallium_osmesa" in
3239 xnoyes)
3240         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3241         ;;
3242 xyesno)
3243         echo "        OSMesa:          lib$OSMESA_LIB"
3244         ;;
3245 xnono)
3246         echo "        OSMesa:          no"
3247         ;;
3248 esac
3249
3250 echo ""
3251 if test "x$enable_dri" != xno; then
3252         echo "        DRI platform:    $dri_platform"
3253         if test -z "$DRI_DIRS"; then
3254             echo "        DRI drivers:     no"
3255         else
3256             echo "        DRI drivers:     $DRI_DIRS"
3257         fi
3258         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3259 fi
3260
3261 case "x$enable_glx" in
3262 xdri)
3263     echo "        GLX:             DRI-based"
3264     ;;
3265 xxlib)
3266     echo "        GLX:             Xlib-based"
3267     ;;
3268 xgallium-xlib)
3269     echo "        GLX:             Xlib-based (Gallium)"
3270     ;;
3271 *)
3272     echo "        GLX:             $enable_glx"
3273     ;;
3274 esac
3275
3276 dnl EGL
3277 echo ""
3278 echo "        EGL:             $enable_egl"
3279 if test "$enable_egl" = yes; then
3280
3281     egl_drivers=""
3282     if test "x$enable_dri" != "xno"; then
3283         egl_drivers="$egl_drivers builtin:egl_dri2"
3284     fi
3285     if test "x$enable_dri3" != "xno"; then
3286         egl_drivers="$egl_drivers builtin:egl_dri3"
3287     fi
3288
3289     echo "        EGL drivers:    $egl_drivers"
3290 fi
3291 if test "x$enable_gbm" = xyes; then
3292     echo "        GBM:             yes"
3293 else
3294     echo "        GBM:             no"
3295 fi
3296
3297     echo "        EGL/Vulkan/VL platforms:   $platforms"
3298
3299 # Vulkan
3300 echo ""
3301 if test "x$VULKAN_DRIVERS" != x; then
3302     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3303     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3304 else
3305     echo "        Vulkan drivers:  no"
3306 fi
3307
3308 echo ""
3309 if test "x$enable_llvm" = xyes; then
3310     echo "        llvm:            yes"
3311     echo "        llvm-config:     $LLVM_CONFIG"
3312     echo "        llvm-version:    $LLVM_VERSION"
3313 else
3314     echo "        llvm:            no"
3315 fi
3316
3317 echo ""
3318 if test -n "$with_gallium_drivers"; then
3319     echo "        Gallium drivers: $gallium_drivers"
3320     echo "        Gallium st:      $gallium_st"
3321 else
3322     echo "        Gallium:         no"
3323 fi
3324
3325 echo ""
3326 if test "x$enable_gallium_extra_hud" != xyes; then
3327     echo "        HUD extra stats: no"
3328 else
3329     echo "        HUD extra stats: yes"
3330 fi
3331
3332 if test "x$enable_lmsensors" != xyes; then
3333     echo "        HUD lmsensors:   no"
3334 else
3335     echo "        HUD lmsensors:   yes"
3336 fi
3337
3338 echo ""
3339 if test "x$HAVE_GALLIUM_SWR" != x; then
3340     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3341         echo "        SWR archs:       $swr_archs (builtin)"
3342     else
3343         echo "        SWR archs:       $swr_archs"
3344     fi
3345 fi
3346
3347 dnl Libraries
3348 echo ""
3349 echo "        Shared libs:     $enable_shared"
3350 echo "        Static libs:     $enable_static"
3351 echo "        Shared-glapi:    $enable_shared_glapi"
3352
3353 dnl Compiler options
3354 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3355 cflags=`echo $CFLAGS | \
3356     $SED 's/^ *//;s/  */ /;s/ *$//'`
3357 cxxflags=`echo $CXXFLAGS | \
3358     $SED 's/^ *//;s/  */ /;s/ *$//'`
3359 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3360 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3361 echo ""
3362 echo "        CFLAGS:          $cflags"
3363 echo "        CXXFLAGS:        $cxxflags"
3364 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3365 echo "        LDFLAGS:         $ldflags"
3366 echo "        Macros:          $defines"
3367 echo ""
3368 if test "x$enable_llvm" = xyes; then
3369     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3370     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3371     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3372     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3373     echo ""
3374 fi
3375 echo "        PYTHON:         $PYTHON"
3376
3377 echo ""
3378 echo "        Run '${MAKE-make}' to build Mesa"
3379 echo ""