configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AC_CHECK_PROG(RM, rm, [rm -f])
 111
 112 AX_PROG_BISON([],
 113               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 114                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 115 AX_PROG_FLEX([],
 116              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 117                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 118
 119 AC_CHECK_PROG(INDENT, indent, indent, cat)
 120 if test "x$INDENT" != "xcat"; then
 121     # Only GNU indent is supported
 122     INDENT_VERSION=`indent --version | grep GNU`
 123     if test $? -eq 0; then
 124        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 125     else
 126        INDENT="cat"
 127     fi
 128 fi
 129
 130 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 131
 132 if test -z "$PYTHON2"; then
 133     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 134         AC_MSG_ERROR([Python not found - unable to generate sources])
 135     fi
 136 else
 137     if test "x$acv_mako_found" = xno; then
 138         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 139             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 140         fi
 141     fi
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 dnl We need a POSIX shell for parts of the build. Assume we have one
 147 dnl in most cases.
 148 case "$host_os" in
 149 solaris*)
 150     # Solaris /bin/sh is too old/non-POSIX compliant
 151     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 152     SHELL="$POSIX_SHELL"
 153     ;;
 154 esac
 155
 156 dnl clang is mostly GCC-compatible, but its version is much lower,
 157 dnl so we have to check for it.
 158 AC_MSG_CHECKING([if compiling with clang])
 159
 160 AC_COMPILE_IFELSE(
 161 [AC_LANG_PROGRAM([], [[
 162 #ifndef __clang__
 163        not clang
 164 #endif
 165 ]])],
 166 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 167
 168 AC_MSG_RESULT([$acv_mesa_CLANG])
 169
 170 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 171 dnl versions are explictly not supported.
 172 GEN_ASM_OFFSETS=no
 173 USE_GNU99=no
 174 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 175     AC_MSG_CHECKING([whether gcc version is sufficient])
 176     major=0
 177     minor=0
 178
 179     GCC_VERSION=`$CC -dumpversion`
 180     if test $? -eq 0; then
 181         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 182         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 183     fi
 184
 185     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 186         AC_MSG_RESULT([no])
 187         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 188     else
 189         AC_MSG_RESULT([yes])
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 193         USE_GNU99=yes
 194     fi
 195     if test "x$cross_compiling" = xyes; then
 196         GEN_ASM_OFFSETS=yes
 197     fi
 198 fi
 199
 200 dnl We don't support building Mesa with Sun C compiler
 201 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 202 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 203 if test "x$SUNCC" = xyes; then
 204     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 205 fi
 206
 207 dnl Check for compiler builtins
 208 AX_GCC_BUILTIN([__builtin_bswap32])
 209 AX_GCC_BUILTIN([__builtin_bswap64])
 210 AX_GCC_BUILTIN([__builtin_clz])
 211 AX_GCC_BUILTIN([__builtin_clzll])
 212 AX_GCC_BUILTIN([__builtin_ctz])
 213 AX_GCC_BUILTIN([__builtin_expect])
 214 AX_GCC_BUILTIN([__builtin_ffs])
 215 AX_GCC_BUILTIN([__builtin_ffsll])
 216 AX_GCC_BUILTIN([__builtin_popcount])
 217 AX_GCC_BUILTIN([__builtin_popcountll])
 218 AX_GCC_BUILTIN([__builtin_unreachable])
 219
 220 AX_GCC_FUNC_ATTRIBUTE([const])
 221 AX_GCC_FUNC_ATTRIBUTE([flatten])
 222 AX_GCC_FUNC_ATTRIBUTE([format])
 223 AX_GCC_FUNC_ATTRIBUTE([malloc])
 224 AX_GCC_FUNC_ATTRIBUTE([packed])
 225 AX_GCC_FUNC_ATTRIBUTE([pure])
 226 AX_GCC_FUNC_ATTRIBUTE([unused])
 227 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 228
 229 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 230
 231 dnl Make sure the pkg-config macros are defined
 232 m4_ifndef([PKG_PROG_PKG_CONFIG],
 233     [m4_fatal([Could not locate the pkg-config autoconf macros.
 234   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 235   are in a different location, try setting the environment variable
 236   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 237 PKG_PROG_PKG_CONFIG()
 238
 239 dnl LIB_DIR - library basename
 240 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 241 AC_SUBST([LIB_DIR])
 242
 243 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 244 _SAVE_LDFLAGS="$LDFLAGS"
 245 _SAVE_CPPFLAGS="$CPPFLAGS"
 246
 247 dnl Compiler macros
 248 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 249 AC_SUBST([DEFINES])
 250 case "$host_os" in
 251 linux*|*-gnu*|gnu*)
 252     DEFINES="$DEFINES -D_GNU_SOURCE"
 253     ;;
 254 solaris*)
 255     DEFINES="$DEFINES -DSVR4"
 256     ;;
 257 cygwin*)
 258     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 259     ;;
 260 esac
 261
 262 dnl Add flags for gcc and g++
 263 if test "x$GCC" = xyes; then
 264     CFLAGS="$CFLAGS -Wall"
 265
 266     if test "x$USE_GNU99" = xyes; then
 267         CFLAGS="$CFLAGS -std=gnu99"
 268     else
 269         CFLAGS="$CFLAGS -std=c99"
 270     fi
 271
 272     # Enable -Werror=implicit-function-declaration and
 273     # -Werror=missing-prototypes, if available, or otherwise, just
 274     # -Wmissing-prototypes.  This is particularly useful to avoid
 275     # generating a loadable driver module that has undefined symbols.
 276     save_CFLAGS="$CFLAGS"
 277     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 278     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 279     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 280     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 281                    AC_MSG_RESULT([yes]),
 282                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 283                     AC_MSG_RESULT([no])]);
 284
 285     # Enable -fvisibility=hidden if using a gcc that supports it
 286     save_CFLAGS="$CFLAGS"
 287     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 288     VISIBILITY_CFLAGS="-fvisibility=hidden"
 289     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 290     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 291                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 292
 293     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 294     CFLAGS=$save_CFLAGS
 295
 296     # Work around aliasing bugs - developers should comment this out
 297     CFLAGS="$CFLAGS -fno-strict-aliasing"
 298
 299     # We don't want floating-point math functions to set errno or trap
 300     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 301
 302     # gcc's builtin memcmp is slower than glibc's
 303     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 304     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 305
 306     # Flags to help ensure that certain portions of the code -- and only those
 307     # portions -- can be built with MSVC:
 308     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 309     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326
 327     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 328     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 329 fi
 330 if test "x$GXX" = xyes; then
 331     CXXFLAGS="$CXXFLAGS -Wall"
 332
 333     # Enable -fvisibility=hidden if using a gcc that supports it
 334     save_CXXFLAGS="$CXXFLAGS"
 335     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 336     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 337     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 338     AC_LANG_PUSH([C++])
 339     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 340                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 341     AC_LANG_POP([C++])
 342
 343     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 344     CXXFLAGS=$save_CXXFLAGS
 345
 346     # Work around aliasing bugs - developers should comment this out
 347     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 348
 349     # gcc's builtin memcmp is slower than glibc's
 350     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 351     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 352 fi
 353
 354 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 355 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 356 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 357 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 358
 359 dnl even if the compiler appears to support it, using visibility attributes isn't
 360 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 361 case "$host_os" in
 362 cygwin*)
 363     VISIBILITY_CFLAGS=""
 364     VISIBILITY_CXXFLAGS=""
 365     ;;
 366 esac
 367
 368 AC_SUBST([VISIBILITY_CFLAGS])
 369 AC_SUBST([VISIBILITY_CXXFLAGS])
 370
 371 dnl
 372 dnl Optional flags, check for compiler support
 373 dnl
 374 SSE41_CFLAGS="-msse4.1"
 375 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 376 dnl stack, but on x86-32 such alignment is not guaranteed.
 377 case "$target_cpu" in
 378 i?86)
 379     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 380     ;;
 381 esac
 382 save_CFLAGS="$CFLAGS"
 383 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 384 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 385 #include <smmintrin.h>
 386 int param;
 387 int main () {
 388     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 389     c = _mm_max_epu32(a, b);
 390     return _mm_cvtsi128_si32(c);
 391 }]])], SSE41_SUPPORTED=1)
 392 CFLAGS="$save_CFLAGS"
 393 if test "x$SSE41_SUPPORTED" = x1; then
 394     DEFINES="$DEFINES -DUSE_SSE41"
 395 fi
 396 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 397 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 398
 399 dnl Check for Endianness
 400 AC_C_BIGENDIAN(
 401    little_endian=no,
 402    little_endian=yes,
 403    little_endian=no,
 404    little_endian=no
 405 )
 406
 407 dnl Check for POWER8 Architecture
 408 PWR8_CFLAGS="-mpower8-vector"
 409 have_pwr8_intrinsics=no
 410 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 411 save_CFLAGS=$CFLAGS
 412 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 413 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 414 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 415 #error "Need GCC >= 4.8 for sane POWER8 support"
 416 #endif
 417 #include <altivec.h>
 418 int main () {
 419     vector unsigned char r;
 420     vector unsigned int v = vec_splat_u32 (1);
 421     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 422     return 0;
 423 }]])], have_pwr8_intrinsics=yes)
 424 CFLAGS=$save_CFLAGS
 425
 426 AC_ARG_ENABLE(pwr8,
 427    [AC_HELP_STRING([--disable-pwr8-inst],
 428                    [disable POWER8-specific instructions])],
 429    [enable_pwr8=$enableval], [enable_pwr8=auto])
 430
 431 if test "x$enable_pwr8" = xno ; then
 432    have_pwr8_intrinsics=disabled
 433 fi
 434
 435 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 436    DEFINES="$DEFINES -D_ARCH_PWR8"
 437    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 438    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 439 else
 440    PWR8_CFLAGS=
 441 fi
 442
 443 AC_MSG_RESULT($have_pwr8_intrinsics)
 444 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 445    AC_MSG_ERROR([POWER8 compiler support not detected])
 446 fi
 447
 448 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 449    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 450 fi
 451
 452 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 453
 454 dnl Can't have static and shared libraries, default to static if user
 455 dnl explicitly requested. If both disabled, set to static since shared
 456 dnl was explicitly requested.
 457 case "x$enable_static$enable_shared" in
 458 xyesyes)
 459     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 460     enable_shared=no
 461     ;;
 462 xnono)
 463     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 464     enable_shared=yes
 465     ;;
 466 esac
 467
 468 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 469
 470 dnl
 471 dnl other compiler options
 472 dnl
 473 AC_ARG_ENABLE([debug],
 474     [AS_HELP_STRING([--enable-debug],
 475         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 476     [enable_debug="$enableval"],
 477     [enable_debug=no]
 478 )
 479
 480 AC_ARG_ENABLE([profile],
 481     [AS_HELP_STRING([--enable-profile],
 482         [enable profiling of code @<:@default=disabled@:>@])],
 483     [enable_profile="$enableval"],
 484     [enable_profile=no]
 485 )
 486
 487 if test "x$enable_profile" = xyes; then
 488     DEFINES="$DEFINES -DPROFILE"
 489     if test "x$GCC" = xyes; then
 490         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 491     fi
 492     if test "x$GXX" = xyes; then
 493         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 494     fi
 495 fi
 496
 497 if test "x$enable_debug" = xyes; then
 498     DEFINES="$DEFINES -DDEBUG"
 499     if test "x$enable_profile" = xyes; then
 500         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 501     fi
 502     if test "x$GCC" = xyes; then
 503         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 504             CFLAGS="$CFLAGS -g"
 505         fi
 506         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 507             CFLAGS="$CFLAGS -O0"
 508         fi
 509     fi
 510     if test "x$GXX" = xyes; then
 511         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 512             CXXFLAGS="$CXXFLAGS -g"
 513         fi
 514         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 515             CXXFLAGS="$CXXFLAGS -O0"
 516         fi
 517     fi
 518 else
 519    DEFINES="$DEFINES -DNDEBUG"
 520 fi
 521
 522 dnl
 523 dnl Check if linker supports -Bsymbolic
 524 dnl
 525 save_LDFLAGS=$LDFLAGS
 526 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 527 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 528 AC_LINK_IFELSE(
 529     [AC_LANG_SOURCE([int main() { return 0;}])],
 530     [AC_MSG_RESULT([yes])
 531         BSYMBOLIC="-Wl,-Bsymbolic";],
 532     [AC_MSG_RESULT([no])
 533         BSYMBOLIC="";])
 534 LDFLAGS=$save_LDFLAGS
 535
 536 AC_SUBST([BSYMBOLIC])
 537
 538 dnl
 539 dnl Check if linker supports garbage collection
 540 dnl
 541 save_LDFLAGS=$LDFLAGS
 542 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 543 AC_MSG_CHECKING([whether ld supports --gc-sections])
 544 AC_LINK_IFELSE(
 545     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 546     [AC_MSG_RESULT([yes])
 547         GC_SECTIONS="-Wl,--gc-sections";],
 548     [AC_MSG_RESULT([no])
 549         GC_SECTIONS="";])
 550 LDFLAGS=$save_LDFLAGS
 551
 552 AC_SUBST([GC_SECTIONS])
 553
 554 dnl
 555 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 556 dnl so when these flags are passed to ld via libtool the checks will fail
 557 dnl
 558 case "$host_os" in
 559 openbsd* | darwin* )
 560     LD_NO_UNDEFINED="" ;;
 561 *)
 562     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 563 esac
 564
 565 AC_SUBST([LD_NO_UNDEFINED])
 566
 567 dnl
 568 dnl Check if linker supports version scripts
 569 dnl
 570 AC_MSG_CHECKING([if the linker supports version-scripts])
 571 save_LDFLAGS=$LDFLAGS
 572 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 573 cat > conftest.map <<EOF
 574 VERSION_1 {
 575      global:
 576          main;
 577
 578      local:
 579          *;
 580 };
 581 EOF
 582 AC_LINK_IFELSE(
 583     [AC_LANG_SOURCE([int main() { return 0;}])],
 584     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 585     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 586 LDFLAGS=$save_LDFLAGS
 587 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 588
 589 dnl
 590 dnl Check if linker supports dynamic list files
 591 dnl
 592 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 593 save_LDFLAGS=$LDFLAGS
 594 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 595 cat > conftest.dyn <<EOF
 596 {
 597         radeon_drm_winsys_create;
 598 };
 599 EOF
 600 AC_LINK_IFELSE(
 601     [AC_LANG_SOURCE([int main() { return 0;}])],
 602     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 603     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 604 LDFLAGS=$save_LDFLAGS
 605 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 606
 607 dnl
 608 dnl compatibility symlinks
 609 dnl
 610 case "$host_os" in
 611 linux* )
 612     HAVE_COMPAT_SYMLINKS=yes ;;
 613 * )
 614     HAVE_COMPAT_SYMLINKS=no ;;
 615 esac
 616
 617 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 618
 619 dnl
 620 dnl library names
 621 dnl
 622 dnl Unfortunately we need to do a few things that libtool can't help us with,
 623 dnl so we need some knowledge of shared library filenames:
 624 dnl
 625 dnl LIB_EXT is the extension used when creating symlinks for alternate
 626 dnl filenames for a shared library which will be dynamically loaded
 627 dnl
 628 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 629 dnl the file for a shared library we wish to link with
 630 dnl
 631 case "$host_os" in
 632 darwin* )
 633     LIB_EXT='dylib'
 634     IMP_LIB_EXT=$LIB_EXT
 635     ;;
 636 cygwin* )
 637     LIB_EXT='dll'
 638     IMP_LIB_EXT='dll.a'
 639     ;;
 640 aix* )
 641     LIB_EXT='a'
 642     IMP_LIB_EXT=$LIB_EXT
 643     ;;
 644 * )
 645     LIB_EXT='so'
 646     IMP_LIB_EXT=$LIB_EXT
 647     ;;
 648 esac
 649
 650 AC_SUBST([LIB_EXT])
 651
 652 AC_ARG_WITH([gl-lib-name],
 653   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 654     [specify GL library name @<:@default=GL@:>@])],
 655   [GL_LIB=$withval],
 656   [GL_LIB=GL])
 657 AC_ARG_WITH([osmesa-lib-name],
 658   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 659     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 660   [OSMESA_LIB=$withval],
 661   [OSMESA_LIB=OSMesa])
 662 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 663 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 664
 665 dnl
 666 dnl Mangled Mesa support
 667 dnl
 668 AC_ARG_ENABLE([mangling],
 669   [AS_HELP_STRING([--enable-mangling],
 670     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 671   [enable_mangling="${enableval}"],
 672   [enable_mangling=no]
 673 )
 674 if test "x${enable_mangling}" = "xyes" ; then
 675   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 676   GL_LIB="Mangled${GL_LIB}"
 677   OSMESA_LIB="Mangled${OSMESA_LIB}"
 678 fi
 679 AC_SUBST([GL_LIB])
 680 AC_SUBST([OSMESA_LIB])
 681
 682 dnl
 683 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 684 dnl
 685 AC_ARG_ENABLE([texture-float],
 686     [AS_HELP_STRING([--enable-texture-float],
 687         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 688     [enable_texture_float="$enableval"],
 689     [enable_texture_float=no]
 690 )
 691 if test "x$enable_texture_float" = xyes; then
 692     AC_MSG_WARN([Floating-point textures enabled.])
 693     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 694     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 695 fi
 696
 697 dnl
 698 dnl Arch/platform-specific settings
 699 dnl
 700 AC_ARG_ENABLE([asm],
 701     [AS_HELP_STRING([--disable-asm],
 702         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 703     [enable_asm="$enableval"],
 704     [enable_asm=yes]
 705 )
 706 asm_arch=""
 707 AC_MSG_CHECKING([whether to enable assembly])
 708 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 709 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 710 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 711     case "$host_cpu" in
 712     i?86 | x86_64 | amd64)
 713         enable_asm=no
 714         AC_MSG_RESULT([no, cross compiling])
 715         ;;
 716     esac
 717 fi
 718 # check for supported arches
 719 if test "x$enable_asm" = xyes; then
 720     case "$host_cpu" in
 721     i?86)
 722         case "$host_os" in
 723         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 724             asm_arch=x86
 725             ;;
 726         esac
 727         ;;
 728     x86_64|amd64)
 729         case "$host_os" in
 730         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 731             asm_arch=x86_64
 732             ;;
 733         esac
 734         ;;
 735     sparc*)
 736         case "$host_os" in
 737         linux*)
 738             asm_arch=sparc
 739             ;;
 740         esac
 741         ;;
 742     esac
 743
 744     case "$asm_arch" in
 745     x86)
 746         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 747         AC_MSG_RESULT([yes, x86])
 748         ;;
 749     x86_64|amd64)
 750         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 751         AC_MSG_RESULT([yes, x86_64])
 752         ;;
 753     sparc)
 754         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 755         AC_MSG_RESULT([yes, sparc])
 756         ;;
 757     *)
 758         AC_MSG_RESULT([no, platform not supported])
 759         ;;
 760     esac
 761 fi
 762
 763 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 764 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 765 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 766 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 767
 768 dnl Check to see if dlopen is in default libraries (like Solaris, which
 769 dnl has it in libc), or if libdl is needed to get it.
 770 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 771     [AC_CHECK_LIB([dl], [dlopen],
 772        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 773 AC_SUBST([DLOPEN_LIBS])
 774
 775 dnl Check if that library also has dladdr
 776 save_LIBS="$LIBS"
 777 LIBS="$LIBS $DLOPEN_LIBS"
 778 AC_CHECK_FUNCS([dladdr])
 779 LIBS="$save_LIBS"
 780
 781 case "$host_os" in
 782 darwin*)
 783     ;;
 784 *)
 785     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 786                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 787                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 788     AC_SUBST([CLOCK_LIB])
 789     ;;
 790 esac
 791
 792 dnl See if posix_memalign is available
 793 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 794
 795 dnl Check for pthreads
 796 AX_PTHREAD
 797 if test "x$ax_pthread_ok" = xno; then
 798     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 799 fi
 800 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 801 dnl to -pthread, which causes problems if we need -lpthread to appear in
 802 dnl pkgconfig files.
 803 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 804
 805 dnl SELinux awareness.
 806 AC_ARG_ENABLE([selinux],
 807     [AS_HELP_STRING([--enable-selinux],
 808         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 809     [MESA_SELINUX="$enableval"],
 810     [MESA_SELINUX=no])
 811 if test "x$enable_selinux" = "xyes"; then
 812     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 813         [AC_CHECK_HEADER([selinux/selinux.h],[],
 814                          [AC_MSG_ERROR([SELinux headers not found])])
 815          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 816                       [AC_MSG_ERROR([SELinux library not found])])
 817          SELINUX_LIBS="-lselinux"])
 818     DEFINES="$DEFINES -DMESA_SELINUX"
 819 fi
 820 AC_SUBST([SELINUX_CFLAGS])
 821 AC_SUBST([SELINUX_LIBS])
 822
 823 dnl Options for APIs
 824 AC_ARG_ENABLE([opengl],
 825     [AS_HELP_STRING([--disable-opengl],
 826         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 827     [enable_opengl="$enableval"],
 828     [enable_opengl=yes])
 829 AC_ARG_ENABLE([gles1],
 830     [AS_HELP_STRING([--disable-gles1],
 831         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 832     [enable_gles1="$enableval"],
 833     [enable_gles1=yes])
 834 AC_ARG_ENABLE([gles2],
 835     [AS_HELP_STRING([--disable-gles2],
 836         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 837     [enable_gles2="$enableval"],
 838     [enable_gles2=yes])
 839
 840 AC_ARG_ENABLE([dri],
 841     [AS_HELP_STRING([--enable-dri],
 842         [enable DRI modules @<:@default=enabled@:>@])],
 843     [enable_dri="$enableval"],
 844     [enable_dri=yes])
 845
 846 case "$host_os" in
 847 linux*)
 848     dri3_default=yes
 849     ;;
 850 *)
 851     dri3_default=no
 852     ;;
 853 esac
 854
 855 if test "x$enable_dri" = xno; then
 856     dri3_default=no
 857 fi
 858
 859 AC_ARG_ENABLE([dri3],
 860     [AS_HELP_STRING([--enable-dri3],
 861         [enable DRI3 @<:@default=auto@:>@])],
 862     [enable_dri3="$enableval"],
 863     [enable_dri3="$dri3_default"])
 864 AC_ARG_ENABLE([glx],
 865     [AS_HELP_STRING([--enable-glx],
 866         [enable GLX library @<:@default=enabled@:>@])],
 867     [enable_glx="$enableval"],
 868     [enable_glx=yes])
 869 AC_ARG_ENABLE([osmesa],
 870     [AS_HELP_STRING([--enable-osmesa],
 871         [enable OSMesa library @<:@default=disabled@:>@])],
 872     [enable_osmesa="$enableval"],
 873     [enable_osmesa=no])
 874 AC_ARG_ENABLE([gallium-osmesa],
 875     [AS_HELP_STRING([--enable-gallium-osmesa],
 876         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 877     [enable_gallium_osmesa="$enableval"],
 878     [enable_gallium_osmesa=no])
 879 AC_ARG_ENABLE([egl],
 880     [AS_HELP_STRING([--disable-egl],
 881         [disable EGL library @<:@default=enabled@:>@])],
 882     [enable_egl="$enableval"],
 883     [enable_egl=yes])
 884
 885 AC_ARG_ENABLE([xa],
 886     [AS_HELP_STRING([--enable-xa],
 887         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 888     [enable_xa="$enableval"],
 889     [enable_xa=no])
 890 AC_ARG_ENABLE([gbm],
 891    [AS_HELP_STRING([--enable-gbm],
 892          [enable gbm library @<:@default=auto@:>@])],
 893    [enable_gbm="$enableval"],
 894    [enable_gbm=auto])
 895 AC_ARG_ENABLE([nine],
 896     [AS_HELP_STRING([--enable-nine],
 897         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 898     [enable_nine="$enableval"],
 899     [enable_nine=no])
 900
 901 AC_ARG_ENABLE([xvmc],
 902    [AS_HELP_STRING([--enable-xvmc],
 903          [enable xvmc library @<:@default=auto@:>@])],
 904    [enable_xvmc="$enableval"],
 905    [enable_xvmc=auto])
 906 AC_ARG_ENABLE([vdpau],
 907    [AS_HELP_STRING([--enable-vdpau],
 908          [enable vdpau library @<:@default=auto@:>@])],
 909    [enable_vdpau="$enableval"],
 910    [enable_vdpau=auto])
 911 AC_ARG_ENABLE([omx],
 912    [AS_HELP_STRING([--enable-omx],
 913          [enable OpenMAX library @<:@default=disabled@:>@])],
 914    [enable_omx="$enableval"],
 915    [enable_omx=no])
 916 AC_ARG_ENABLE([va],
 917    [AS_HELP_STRING([--enable-va],
 918          [enable va library @<:@default=auto@:>@])],
 919    [enable_va="$enableval"],
 920    [enable_va=auto])
 921 AC_ARG_ENABLE([opencl],
 922    [AS_HELP_STRING([--enable-opencl],
 923          [enable OpenCL library @<:@default=disabled@:>@])],
 924    [enable_opencl="$enableval"],
 925    [enable_opencl=no])
 926 AC_ARG_ENABLE([opencl_icd],
 927    [AS_HELP_STRING([--enable-opencl-icd],
 928           [Build an OpenCL ICD library to be loaded by an ICD implementation
 929            @<:@default=disabled@:>@])],
 930     [enable_opencl_icd="$enableval"],
 931     [enable_opencl_icd=no])
 932 AC_ARG_ENABLE([xlib-glx],
 933     [AS_HELP_STRING([--enable-xlib-glx],
 934         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 935     [enable_xlib_glx="$enableval"],
 936     [enable_xlib_glx=no])
 937
 938 AC_ARG_ENABLE([r600-llvm-compiler],
 939     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 940         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 941     [enable_r600_llvm="$enableval"],
 942     [enable_r600_llvm=no])
 943
 944 AC_ARG_ENABLE([gallium-tests],
 945     [AS_HELP_STRING([--enable-gallium-tests],
 946         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 947     [enable_gallium_tests="$enableval"],
 948     [enable_gallium_tests=no])
 949
 950 # Option for Gallium drivers
 951
 952 # Keep this in sync with the --with-gallium-drivers help string default value
 953 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 954
 955 AC_ARG_WITH([gallium-drivers],
 956     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 957         [comma delimited Gallium drivers list, e.g.
 958         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 959         @<:@default=r300,r600,svga,swrast@:>@])],
 960     [with_gallium_drivers="$withval"],
 961     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 962
 963 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 964 # here so that the script doesn't choke on an unknown driver name later.
 965 case "$with_gallium_drivers" in
 966     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 967     no) with_gallium_drivers='' ;;
 968 esac
 969
 970 if test "x$enable_opengl" = xno -a \
 971         "x$enable_gles1" = xno -a \
 972         "x$enable_gles2" = xno -a \
 973         "x$enable_nine" = xno -a \
 974         "x$enable_xa" = xno -a \
 975         "x$enable_xvmc" = xno -a \
 976         "x$enable_vdpau" = xno -a \
 977         "x$enable_omx" = xno -a \
 978         "x$enable_va" = xno -a \
 979         "x$enable_opencl" = xno; then
 980     AC_MSG_ERROR([at least one API should be enabled])
 981 fi
 982
 983 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 984 if test "x$enable_opengl" = xno -a \
 985         "x$enable_gles1" = xyes; then
 986     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 987 fi
 988
 989 if test "x$enable_opengl" = xno -a \
 990         "x$enable_gles2" = xyes; then
 991     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 992 fi
 993
 994 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 995 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 996 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 997 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 998                                         "x$enable_gles1" = xyes -o \
 999                                         "x$enable_gles2" = xyes)
1000
1001 if test "x$enable_glx" = xno; then
1002     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
1003     enable_xlib_glx=no
1004 fi
1005
1006 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
1007     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
1008 fi
1009
1010 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
1011     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
1012 fi
1013
1014 # Disable GLX if OpenGL is not enabled
1015 if test "x$enable_glx$enable_opengl" = xyesno; then
1016     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
1017     enable_glx=no
1018 fi
1019
1020 # Disable GLX if DRI and Xlib-GLX are not enabled
1021 if test "x$enable_glx" = xyes -a \
1022         "x$enable_dri" = xno -a \
1023         "x$enable_xlib_glx" = xno; then
1024     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
1025     enable_glx=no
1026 fi
1027
1028 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
1029                                   "x$enable_dri" = xyes)
1030
1031 # Check for libdrm
1032 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1033                   [have_libdrm=yes], [have_libdrm=no])
1034 if test "x$have_libdrm" = xyes; then
1035         DEFINES="$DEFINES -DHAVE_LIBDRM"
1036 fi
1037
1038 # Select which platform-dependent DRI code gets built
1039 case "$host_os" in
1040 darwin*)
1041     dri_platform='apple' ;;
1042 gnu*|cygwin*)
1043     dri_platform='none' ;;
1044 *)
1045     dri_platform='drm' ;;
1046 esac
1047
1048 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1049     have_drisw_kms='yes'
1050 fi
1051
1052 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1053 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1054 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1055 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1056 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1057 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1058
1059 AC_ARG_ENABLE([shared-glapi],
1060     [AS_HELP_STRING([--enable-shared-glapi],
1061         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1062     [enable_shared_glapi="$enableval"],
1063     [enable_shared_glapi=yes])
1064
1065 case "x$enable_opengl$enable_gles1$enable_gles2" in
1066 x*yes*yes*)
1067     if test "x$enable_shared_glapi" = xno; then
1068         AC_MSG_ERROR([shared GLAPI required when building two or more of
1069                       the following APIs - opengl, gles1 gles2])
1070     fi
1071     ;;
1072 esac
1073
1074 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1075
1076 # Build the pipe-drivers as separate libraries/modules.
1077 # Do not touch this unless you know what you are doing.
1078 # XXX: Expose via configure option ?
1079 enable_shared_pipe_drivers=no
1080
1081 dnl
1082 dnl Driver specific build directories
1083 dnl
1084
1085 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
1086     NEED_WINSYS_XLIB="yes"
1087 fi
1088
1089 if test "x$enable_gallium_osmesa" = xyes; then
1090     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1091         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1092     fi
1093     if test "x$enable_osmesa" = xyes; then
1094         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1095     fi
1096 fi
1097
1098 AC_SUBST([MESA_LLVM])
1099
1100 # SHA1 hashing
1101 AC_ARG_WITH([sha1],
1102         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1103         [choose SHA1 implementation])])
1104 case "x$with_sha1" in
1105 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1106   ;;
1107 *)
1108         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1109 esac
1110
1111 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1112 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1113         with_sha1=libc
1114 fi
1115 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1116         AC_MSG_ERROR([sha1 in libc requested but not found])
1117 fi
1118 if test "x$with_sha1" = xlibc; then
1119         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1120                 [Use libc SHA1 functions])
1121         SHA1_LIBS=""
1122 fi
1123 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1124 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1125         with_sha1=CommonCrypto
1126 fi
1127 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1128         AC_MSG_ERROR([CommonCrypto requested but not found])
1129 fi
1130 if test "x$with_sha1" = xCommonCrypto; then
1131         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1132                 [Use CommonCrypto SHA1 functions])
1133         SHA1_LIBS=""
1134 fi
1135 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1136 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1137 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1138         with_sha1=CryptoAPI
1139 fi
1140 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1141         AC_MSG_ERROR([CryptoAPI requested but not found])
1142 fi
1143 if test "x$with_sha1" = xCryptoAPI; then
1144         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1145                 [Use CryptoAPI SHA1 functions])
1146         SHA1_LIBS=""
1147 fi
1148 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1149 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1150         with_sha1=libmd
1151 fi
1152 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1153         AC_MSG_ERROR([libmd requested but not found])
1154 fi
1155 if test "x$with_sha1" = xlibmd; then
1156         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1157                   [Use libmd SHA1 functions])
1158         SHA1_LIBS=-lmd
1159 fi
1160 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1161 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1162    with_sha1=libsha1
1163 fi
1164 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1165         AC_MSG_ERROR([libsha1 requested but not found])
1166 fi
1167 if test "x$with_sha1" = xlibsha1; then
1168         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1169                   [Use libsha1 for SHA1])
1170         SHA1_LIBS=-lsha1
1171 fi
1172 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1173 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1174         with_sha1=libnettle
1175 fi
1176 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1177         AC_MSG_ERROR([libnettle requested but not found])
1178 fi
1179 if test "x$with_sha1" = xlibnettle; then
1180         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1181                   [Use libnettle SHA1 functions])
1182         SHA1_LIBS=-lnettle
1183 fi
1184 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1185 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1186         with_sha1=libgcrypt
1187 fi
1188 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1189         AC_MSG_ERROR([libgcrypt requested but not found])
1190 fi
1191 if test "x$with_sha1" = xlibgcrypt; then
1192         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1193                   [Use libgcrypt SHA1 functions])
1194         SHA1_LIBS=-lgcrypt
1195 fi
1196 # We don't need all of the OpenSSL libraries, just libcrypto
1197 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1198 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1199                   [HAVE_OPENSSL_PKC=no])
1200 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1201         if test "x$with_sha1" = x; then
1202                 with_sha1=libcrypto
1203         fi
1204 else
1205         if test "x$with_sha1" = xlibcrypto; then
1206                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1207         fi
1208 fi
1209 if test "x$with_sha1" = xlibcrypto; then
1210         if test "x$HAVE_LIBCRYPTO" = xyes; then
1211                 SHA1_LIBS=-lcrypto
1212         else
1213                 SHA1_LIBS="$OPENSSL_LIBS"
1214                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1215         fi
1216 fi
1217 AC_MSG_CHECKING([for SHA1 implementation])
1218 AC_MSG_RESULT([$with_sha1])
1219 AC_SUBST(SHA1_LIBS)
1220 AC_SUBST(SHA1_CFLAGS)
1221
1222 # Enable a define for SHA1
1223 if test "x$with_sha1" != "x"; then
1224         DEFINES="$DEFINES -DHAVE_SHA1"
1225 fi
1226
1227 # Allow user to configure out the shader-cache feature
1228 AC_ARG_ENABLE([shader-cache],
1229     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1230     [enable_shader_cache="$enableval"],
1231     [if test "x$with_sha1" != "x"; then
1232         enable_shader_cache=yes
1233      else
1234         enable_shader_cache=no
1235      fi])
1236 if test "x$with_sha1" = "x"; then
1237     if test "x$enable_shader_cache" = "xyes"; then
1238         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1239     fi
1240 fi
1241 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1242
1243 case "$host_os" in
1244 linux*)
1245     need_pci_id=yes ;;
1246 *)
1247     need_pci_id=no ;;
1248 esac
1249
1250 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1251                   have_libudev=yes, have_libudev=no)
1252
1253 AC_ARG_ENABLE([sysfs],
1254     [AS_HELP_STRING([--enable-sysfs],
1255         [enable /sys PCI identification @<:@default=disabled@:>@])],
1256     [have_sysfs="$enableval"],
1257     [have_sysfs=no]
1258 )
1259
1260 if test "x$enable_dri" = xyes; then
1261     if test "$enable_static" = yes; then
1262         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1263     fi
1264
1265     # not a hard requirement as swrast does not depend on it
1266     if test "x$have_libdrm" = xyes; then
1267         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1268     fi
1269 fi
1270
1271 AC_ARG_ENABLE([driglx-direct],
1272     [AS_HELP_STRING([--disable-driglx-direct],
1273         [disable direct rendering in GLX and EGL for DRI \
1274             @<:@default=auto@:>@])],
1275     [driglx_direct="$enableval"],
1276     [driglx_direct="yes"])
1277
1278 dnl
1279 dnl libGL configuration per driver
1280 dnl
1281 case "x$enable_glx$enable_xlib_glx" in
1282 xyesyes)
1283     # Xlib-based GLX
1284     dri_modules="x11 xext xcb"
1285     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1286     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1287     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1288     GL_LIB_DEPS="$XLIBGL_LIBS"
1289     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1290     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1291     ;;
1292 xyesno)
1293     # DRI-based GLX
1294     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1295
1296     # find the DRI deps for libGL
1297     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1298
1299     if test x"$driglx_direct" = xyes; then
1300         if test x"$dri_platform" = xdrm ; then
1301             DEFINES="$DEFINES -DGLX_USE_DRM"
1302             if test "x$have_libdrm" != xyes; then
1303                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1304             fi
1305
1306             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1307             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1308             if test x"$enable_dri3" = xyes; then
1309                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1310                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1311             fi
1312
1313             if test x"$enable_dri" = xyes; then
1314                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1315             fi
1316
1317             if test x"$enable_dri3" = xyes; then
1318                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1319                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1320                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1321             fi
1322         fi
1323         if test x"$dri_platform" = xapple ; then
1324             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1325         fi
1326     fi
1327
1328     # add xf86vidmode if available
1329     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1330     if test "$HAVE_XF86VIDMODE" = yes ; then
1331         dri_modules="$dri_modules xxf86vm"
1332     fi
1333
1334     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1335     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1336     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1337     GL_LIB_DEPS="$DRIGL_LIBS"
1338
1339     # need DRM libs, $PTHREAD_LIBS, etc.
1340     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1341     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1342     ;;
1343 esac
1344
1345 have_pci_id=no
1346 if test "$have_libudev" = yes; then
1347     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1348     have_pci_id=yes
1349 fi
1350
1351 if test "$have_sysfs" = yes; then
1352     DEFINES="$DEFINES -DHAVE_SYSFS"
1353     have_pci_id=yes
1354 fi
1355
1356 # This is outside the case (above) so that it is invoked even for non-GLX
1357 # builds.
1358 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1359
1360 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1361 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1362 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1363 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1364
1365 AC_SUBST([X11_INCLUDES])
1366 AC_SUBST([GL_LIB_DEPS])
1367 AC_SUBST([GL_PC_REQ_PRIV])
1368 AC_SUBST([GL_PC_LIB_PRIV])
1369 AC_SUBST([GL_PC_CFLAGS])
1370 AC_SUBST([DRI_PC_REQ_PRIV])
1371 AC_SUBST([GLESv1_CM_LIB_DEPS])
1372 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1373 AC_SUBST([GLESv2_LIB_DEPS])
1374 AC_SUBST([GLESv2_PC_LIB_PRIV])
1375
1376 AC_SUBST([HAVE_XF86VIDMODE])
1377
1378 dnl
1379 dnl More GLX setup
1380 dnl
1381 case "x$enable_glx$enable_xlib_glx" in
1382 xyesyes)
1383     DEFINES="$DEFINES -DUSE_XSHM"
1384     ;;
1385 xyesno)
1386     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1387     if test "x$driglx_direct" = xyes; then
1388         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1389     fi
1390     ;;
1391 esac
1392
1393 dnl
1394 dnl TLS detection
1395 dnl
1396
1397 AC_ARG_ENABLE([glx-tls],
1398     [AS_HELP_STRING([--enable-glx-tls],
1399         [enable TLS support in GLX @<:@default=disabled@:>@])],
1400     [GLX_USE_TLS="$enableval"],
1401     [GLX_USE_TLS=no])
1402 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1403
1404 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1405       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1406
1407 dnl Read-only text section on x86 hardened platforms
1408 AC_ARG_ENABLE([glx-read-only-text],
1409     [AS_HELP_STRING([--enable-glx-read-only-text],
1410         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1411     [enable_glx_read_only_text="$enableval"],
1412     [enable_glx_read_only_text=no])
1413 if test "x$enable_glx_read_only_text" = xyes; then
1414     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1415 fi
1416
1417 dnl
1418 dnl More DRI setup
1419 dnl
1420 dnl Directory for DRI drivers
1421 AC_ARG_WITH([dri-driverdir],
1422     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1423         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1424     [DRI_DRIVER_INSTALL_DIR="$withval"],
1425     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1426 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1427 dnl Extra search path for DRI drivers
1428 AC_ARG_WITH([dri-searchpath],
1429     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1430         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1431     [DRI_DRIVER_SEARCH_DIR="$withval"],
1432     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1433 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1434 dnl Which drivers to build - default is chosen by platform
1435 AC_ARG_WITH([dri-drivers],
1436     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1437         [comma delimited classic DRI drivers list, e.g.
1438         "swrast,i965,radeon" @<:@default=auto@:>@])],
1439     [with_dri_drivers="$withval"],
1440     [with_dri_drivers=auto])
1441
1442 if test "x$with_dri_drivers" = xauto; then
1443     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1444         with_dri_drivers="yes"
1445     else
1446         with_dri_drivers="no"
1447     fi
1448 fi
1449 if test "x$with_dri_drivers" = xno; then
1450     with_dri_drivers=''
1451 fi
1452
1453 dnl If $with_dri_drivers is yes, drivers will be added through
1454 dnl platform checks. Set DEFINES and LIB_DEPS
1455 if test "x$enable_dri" = xyes; then
1456     # Platform specific settings and drivers to build
1457     case "$host_os" in
1458     linux*)
1459         DEFINES="$DEFINES -DHAVE_ALIAS"
1460         if test "x$enable_dri3" = xyes; then
1461             DEFINES="$DEFINES -DHAVE_DRI3"
1462         fi
1463
1464         if test "x$have_pci_id" != xyes; then
1465             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1466         fi
1467
1468         case "$host_cpu" in
1469         powerpc* | sparc*)
1470             # Build only the drivers for cards that exist on PowerPC/sparc
1471             if test "x$with_dri_drivers" = "xyes"; then
1472                 with_dri_drivers="r200 radeon swrast"
1473             fi
1474             ;;
1475         esac
1476         ;;
1477     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1478         DEFINES="$DEFINES -DHAVE_ALIAS"
1479         ;;
1480     gnu*)
1481         DEFINES="$DEFINES -DHAVE_ALIAS"
1482         ;;
1483     cygwin*)
1484         if test "x$with_dri_drivers" = "xyes"; then
1485             with_dri_drivers="swrast"
1486         fi
1487         ;;
1488     darwin*)
1489         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1490         if test "x$with_dri_drivers" = "xyes"; then
1491             with_dri_drivers="swrast"
1492         fi
1493         ;;
1494     esac
1495
1496     # default drivers
1497     if test "x$with_dri_drivers" = "xyes"; then
1498         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1499     fi
1500
1501     # Check for expat
1502     PKG_CHECK_MODULES([EXPAT], [expat], [],
1503         # expat version 2.0 and earlier do not provide expat.pc
1504         [AC_CHECK_HEADER([expat.h],[],
1505                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1506          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1507                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1508          EXPAT_LIBS="-lexpat"])
1509
1510     # put all the necessary libs together
1511     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1512 fi
1513
1514 AC_SUBST([DRI_LIB_DEPS])
1515
1516 DRI_DIRS=''
1517 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1518 if test -n "$with_dri_drivers"; then
1519     if test "x$enable_opengl" != xyes; then
1520         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1521     fi
1522
1523     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1524     for driver in $dri_drivers; do
1525         DRI_DIRS="$DRI_DIRS $driver"
1526         case "x$driver" in
1527         xi915)
1528             HAVE_I915_DRI=yes;
1529             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1530             ;;
1531         xi965)
1532             HAVE_I965_DRI=yes;
1533             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1534             ;;
1535         xnouveau)
1536             HAVE_NOUVEAU_DRI=yes;
1537             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1538             ;;
1539         xradeon)
1540             HAVE_RADEON_DRI=yes;
1541             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1542             ;;
1543         xr200)
1544             HAVE_R200_DRI=yes;
1545             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1546             ;;
1547         xswrast)
1548             HAVE_SWRAST_DRI=yes;
1549             ;;
1550         *)
1551             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1552             ;;
1553         esac
1554     done
1555     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1556 fi
1557
1558 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1559 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1560                                   "x$enable_osmesa" = xyes -o \
1561                                   -n "$DRI_DIRS")
1562
1563 dnl
1564 dnl OSMesa configuration
1565 dnl
1566
1567 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1568 AC_ARG_WITH([osmesa-bits],
1569     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1570         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1571     [osmesa_bits="$withval"],
1572     [osmesa_bits=8])
1573 if test "x$osmesa_bits" != x8; then
1574     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1575         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1576         osmesa_bits=8
1577     fi
1578 fi
1579 case "x$osmesa_bits" in
1580 x8)
1581     OSMESA_LIB="${OSMESA_LIB}"
1582     ;;
1583 x16|x32)
1584     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1585     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1586     ;;
1587 *)
1588     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1589     ;;
1590 esac
1591
1592 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1593     # only link libraries with osmesa if shared
1594     if test "$enable_static" = no; then
1595         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1596     else
1597         OSMESA_LIB_DEPS=""
1598     fi
1599     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1600 fi
1601
1602 AC_SUBST([OSMESA_LIB_DEPS])
1603 AC_SUBST([OSMESA_PC_REQ])
1604 AC_SUBST([OSMESA_PC_LIB_PRIV])
1605
1606 dnl
1607 dnl gbm configuration
1608 dnl
1609 if test "x$enable_gbm" = xauto; then
1610     case "$with_egl_platforms" in
1611         *drm*)
1612             enable_gbm=yes ;;
1613          *)
1614             enable_gbm=no ;;
1615     esac
1616 fi
1617 if test "x$enable_gbm" = xyes; then
1618     if test "x$need_pci_id$have_pci_id" = xyesno; then
1619         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1620     fi
1621
1622     if test "x$enable_dri" = xyes; then
1623         if test "x$enable_shared_glapi" = xno; then
1624             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1625         fi
1626     else
1627         # Strictly speaking libgbm does not require --enable-dri, although
1628         # both of its backends do. Thus one can build libgbm without any
1629         # backends if --disable-dri is set.
1630         # To avoid unnecessary complexity of checking if at least one backend
1631         # is available when building, just mandate --enable-dri.
1632         AC_MSG_ERROR([gbm requires --enable-dri])
1633     fi
1634 fi
1635 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1636 if test "x$need_pci_id$have_libudev" = xyesyes; then
1637     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1638 else
1639     GBM_PC_REQ_PRIV=""
1640 fi
1641 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1642 AC_SUBST([GBM_PC_REQ_PRIV])
1643 AC_SUBST([GBM_PC_LIB_PRIV])
1644
1645 dnl
1646 dnl EGL configuration
1647 dnl
1648 EGL_CLIENT_APIS=""
1649
1650 if test "x$enable_egl" = xyes; then
1651     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1652
1653     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1654
1655     if test "$enable_static" != yes; then
1656         if test "x$enable_dri" = xyes; then
1657             HAVE_EGL_DRIVER_DRI2=1
1658             if test "x$enable_shared_glapi" = xno; then
1659                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1660             fi
1661             if test "x$enable_dri3" = xyes; then
1662                 HAVE_EGL_DRIVER_DRI3=1
1663                 if test "x$enable_shared_glapi" = xno; then
1664                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1665                 fi
1666             fi
1667         else
1668             # Avoid building an "empty" libEGL. Drop/update this
1669             # when other backends (haiku?) come along.
1670             AC_MSG_ERROR([egl requires --enable-dri])
1671         fi
1672
1673     fi
1674 fi
1675 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1676 AC_SUBST([EGL_LIB_DEPS])
1677
1678 gallium_st="mesa"
1679
1680 dnl
1681 dnl XA configuration
1682 dnl
1683 if test "x$enable_xa" = xyes; then
1684     if test "x$with_gallium_drivers" = xswrast; then
1685        AC_MSG_ERROR([
1686           Building xa requires at least one non swrast gallium driver.
1687           If you are looking to use libxatracker.so with the VMware driver,
1688           make sure to include svga in the gallium drivers list, apart from
1689           enabling XA.
1690           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1691     fi
1692     gallium_st="$gallium_st xa"
1693 fi
1694 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1695
1696 dnl
1697 dnl Gallium G3DVL configuration
1698 dnl
1699 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1700     if test "x$enable_xvmc" = xauto; then
1701         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1702     fi
1703
1704     if test "x$enable_vdpau" = xauto; then
1705         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1706     fi
1707
1708     if test "x$enable_omx" = xauto; then
1709         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1710     fi
1711
1712     if test "x$enable_va" = xauto; then
1713         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1714     fi
1715 fi
1716
1717 if test "x$enable_dri" = xyes -o \
1718         "x$enable_xvmc" = xyes -o \
1719         "x$enable_vdpau" = xyes -o \
1720         "x$enable_omx" = xyes -o \
1721         "x$enable_va" = xyes; then
1722     need_gallium_vl=yes
1723 fi
1724 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1725
1726 if test "x$enable_xvmc" = xyes -o \
1727         "x$enable_vdpau" = xyes -o \
1728         "x$enable_omx" = xyes -o \
1729         "x$enable_va" = xyes; then
1730     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1731     need_gallium_vl_winsys=yes
1732 fi
1733 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1734
1735 if test "x$enable_xvmc" = xyes; then
1736     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1737     gallium_st="$gallium_st xvmc"
1738 fi
1739 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1740
1741 if test "x$enable_vdpau" = xyes; then
1742     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1743     gallium_st="$gallium_st vdpau"
1744 fi
1745 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1746
1747 if test "x$enable_omx" = xyes; then
1748     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1749     gallium_st="$gallium_st omx"
1750 fi
1751 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1752
1753 if test "x$enable_va" = xyes; then
1754     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1755     gallium_st="$gallium_st va"
1756 fi
1757 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1758
1759 dnl
1760 dnl Nine Direct3D9 configuration
1761 dnl
1762 if test "x$enable_nine" = xyes; then
1763     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1764         AC_MSG_ERROR([nine requires the gallium swrast driver])
1765     fi
1766     if test "x$with_gallium_drivers" = xswrast; then
1767         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1768     fi
1769     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1770         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1771     fi
1772
1773     if test "x$enable_dri3" = xno; then
1774         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1775     fi
1776
1777     gallium_st="$gallium_st nine"
1778 fi
1779 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1780
1781 dnl
1782 dnl OpenCL configuration
1783 dnl
1784
1785 AC_ARG_WITH([clang-libdir],
1786    [AS_HELP_STRING([--with-clang-libdir],
1787          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1788    [CLANG_LIBDIR="$withval"],
1789    [CLANG_LIBDIR=''])
1790
1791 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1792 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1793
1794 if test "x$have_libelf" = xno; then
1795    LIBELF_LIBS=''
1796    LIBELF_CFLAGS=''
1797    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1798    AC_SUBST([LIBELF_LIBS])
1799    AC_SUBST([LIBELF_CFLAGS])
1800 fi
1801
1802 if test "x$enable_opencl" = xyes; then
1803     if test -z "$with_gallium_drivers"; then
1804         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1805     fi
1806
1807     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1808         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1809     fi
1810
1811     if test "x$have_libclc" = xno; then
1812         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1813                     Make sure the directory containing libclc.pc is specified in your
1814                     PKG_CONFIG_PATH environment variable.
1815                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1816     else
1817         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1818         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1819         AC_SUBST([LIBCLC_INCLUDEDIR])
1820         AC_SUBST([LIBCLC_LIBEXECDIR])
1821     fi
1822
1823     gallium_st="$gallium_st clover"
1824
1825     if test "x$enable_opencl_icd" = xyes; then
1826         OPENCL_LIBNAME="MesaOpenCL"
1827     else
1828         OPENCL_LIBNAME="OpenCL"
1829     fi
1830
1831     if test "x$have_libelf" != xyes; then
1832        AC_MSG_ERROR([Clover requires libelf])
1833     fi
1834 fi
1835 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1836 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1837 AC_SUBST([OPENCL_LIBNAME])
1838
1839 dnl
1840 dnl Gallium configuration
1841 dnl
1842 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1843
1844 AC_SUBST([LLVM_BINDIR])
1845 AC_SUBST([LLVM_CFLAGS])
1846 AC_SUBST([LLVM_CPPFLAGS])
1847 AC_SUBST([LLVM_CXXFLAGS])
1848 AC_SUBST([LLVM_LIBDIR])
1849 AC_SUBST([LLVM_LIBS])
1850 AC_SUBST([LLVM_LDFLAGS])
1851 AC_SUBST([LLVM_INCLUDEDIR])
1852 AC_SUBST([LLVM_VERSION])
1853 AC_SUBST([CLANG_RESOURCE_DIR])
1854
1855 case "x$enable_opengl$enable_gles1$enable_gles2" in
1856 x*yes*)
1857     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1858     ;;
1859 esac
1860
1861 AC_SUBST([VG_LIB_DEPS])
1862 AC_SUBST([EGL_CLIENT_APIS])
1863
1864 dnl
1865 dnl EGL Platforms configuration
1866 dnl
1867 AC_ARG_WITH([egl-platforms],
1868     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1869         [comma delimited native platforms libEGL supports, e.g.
1870         "x11,drm" @<:@default=auto@:>@])],
1871     [with_egl_platforms="$withval"],
1872     [if test "x$enable_egl" = xyes; then
1873         with_egl_platforms="x11"
1874     else
1875         with_egl_platforms=""
1876     fi])
1877
1878 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1879     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1880 fi
1881
1882 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1883         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1884         WAYLAND_SCANNER='')
1885 if test "x$WAYLAND_SCANNER" = x; then
1886     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1887 fi
1888
1889 # Do per-EGL platform setups and checks
1890 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1891 for plat in $egl_platforms; do
1892         case "$plat" in
1893         wayland)
1894                 test "x$have_libdrm" != xyes &&
1895                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1896
1897                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1898
1899                 if test "x$WAYLAND_SCANNER" = x; then
1900                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1901                 fi
1902                 ;;
1903
1904         x11)
1905                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1906                 ;;
1907
1908         drm)
1909                 test "x$enable_gbm" = "xno" &&
1910                         AC_MSG_ERROR([EGL platform drm needs gbm])
1911                 test "x$have_libdrm" != xyes &&
1912                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1913                 ;;
1914
1915         surfaceless)
1916                 test "x$have_libdrm" != xyes &&
1917                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1918                 ;;
1919
1920         *)
1921                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1922                 ;;
1923         esac
1924
1925         case "$plat$need_pci_id$have_pci_id" in
1926                 waylandyesno|drmyesno)
1927                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1928         esac
1929 done
1930
1931 # libEGL wants to default to the first platform specified in
1932 # ./configure.  parse that here.
1933 if test "x$egl_platforms" != "x"; then
1934     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1935     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1936 else
1937     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1938 fi
1939
1940 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1941 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1942 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1943 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1944 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1945
1946 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1947
1948 AC_SUBST([EGL_NATIVE_PLATFORM])
1949 AC_SUBST([EGL_CFLAGS])
1950
1951 # If we don't have the X11 platform, set this define so we don't try to include
1952 # the X11 headers.
1953 if ! echo "$egl_platforms" | grep -q 'x11'; then
1954     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1955     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1956 fi
1957
1958 dnl
1959 dnl Gallium LLVM
1960 dnl
1961 AC_ARG_ENABLE([gallium-llvm],
1962     [AS_HELP_STRING([--enable-gallium-llvm],
1963         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1964     [enable_gallium_llvm="$enableval"],
1965     [enable_gallium_llvm=auto])
1966
1967 AC_ARG_ENABLE([llvm-shared-libs],
1968     [AS_HELP_STRING([--enable-llvm-shared-libs],
1969         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1970     [enable_llvm_shared_libs="$enableval"],
1971     [enable_llvm_shared_libs=yes])
1972
1973 AC_ARG_WITH([llvm-prefix],
1974     [AS_HELP_STRING([--with-llvm-prefix],
1975         [Prefix for LLVM installations in non-standard locations])],
1976     [llvm_prefix="$withval"],
1977     [llvm_prefix=''])
1978
1979
1980 # Call this inside ` ` to get the return value.
1981 # $1 is the llvm-config command with arguments.
1982 strip_unwanted_llvm_flags() {
1983     # Use \> (marks the end of the word)
1984     echo `$1` | sed \
1985         -e 's/-DNDEBUG\>//g' \
1986         -e 's/-D_GNU_SOURCE\>//g' \
1987         -e 's/-pedantic\>//g' \
1988         -e 's/-Wcovered-switch-default\>//g' \
1989         -e 's/-O.\>//g' \
1990         -e 's/-g\>//g' \
1991         -e 's/-Wall\>//g' \
1992         -e 's/-Wcast-qual\>//g' \
1993         -e 's/-Woverloaded-virtual\>//g' \
1994         -e 's/-fcolor-diagnostics\>//g' \
1995         -e 's/-fdata-sections\>//g' \
1996         -e 's/-ffunction-sections\>//g' \
1997         -e 's/-fno-exceptions\>//g' \
1998         -e 's/-fomit-frame-pointer\>//g' \
1999         -e 's/-fvisibility-inlines-hidden\>//g' \
2000         -e 's/-fPIC\>//g' \
2001         -e 's/-fstack-protector-strong\>//g'
2002 }
2003
2004 llvm_check_version_for() {
2005     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2006         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2007     fi
2008 }
2009
2010
2011
2012 if test -z "$with_gallium_drivers"; then
2013     enable_gallium_llvm=no
2014 fi
2015 if test "x$enable_gallium_llvm" = xauto; then
2016     case "$host_cpu" in
2017     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2018     esac
2019 fi
2020 if test "x$enable_gallium_llvm" = xyes; then
2021     if test -n "$llvm_prefix"; then
2022         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2023     else
2024         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2025     fi
2026
2027     if test "x$LLVM_CONFIG" != xno; then
2028         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2029         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2030         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2031         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2032         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2033         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2034         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2035         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2036
2037         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2038             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2039         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2040             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2041
2042         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2043         if test -z "$LLVM_VERSION_PATCH"; then
2044             LLVM_VERSION_PATCH=0
2045         fi
2046
2047         if test -n "${LLVM_VERSION_MAJOR}"; then
2048             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2049         else
2050             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2051         fi
2052
2053         LLVM_REQUIRED_VERSION_MAJOR="3"
2054         LLVM_REQUIRED_VERSION_MINOR="3"
2055         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2056             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2057         fi
2058
2059         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2060
2061         if test "x$enable_opencl" = xyes; then
2062             llvm_check_version_for "3" "5" "0" "opencl"
2063
2064             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2065             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2066         fi
2067         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2068         MESA_LLVM=1
2069
2070         dnl Check for Clang internal headers
2071         if test "x$enable_opencl" = xyes; then
2072             if test -z "$CLANG_LIBDIR"; then
2073                 CLANG_LIBDIR=${LLVM_LIBDIR}
2074             fi
2075             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2076             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2077                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2078         fi
2079     else
2080         MESA_LLVM=0
2081         LLVM_VERSION_INT=0
2082     fi
2083 else
2084     MESA_LLVM=0
2085     LLVM_VERSION_INT=0
2086
2087     if test "x$enable_opencl" = xyes; then
2088         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2089     fi
2090 fi
2091
2092 dnl Directory for XVMC libs
2093 AC_ARG_WITH([xvmc-libdir],
2094     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2095         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2096     [XVMC_LIB_INSTALL_DIR="$withval"],
2097     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2098 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2099
2100 dnl
2101 dnl Gallium Tests
2102 dnl
2103 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2104
2105 dnl Directory for VDPAU libs
2106 AC_ARG_WITH([vdpau-libdir],
2107     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2108         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2109     [VDPAU_LIB_INSTALL_DIR="$withval"],
2110     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2111 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2112
2113 dnl Directory for OMX libs
2114
2115 AC_ARG_WITH([omx-libdir],
2116     [AS_HELP_STRING([--with-omx-libdir=DIR],
2117         [directory for the OMX libraries])],
2118     [OMX_LIB_INSTALL_DIR="$withval"],
2119     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2120 AC_SUBST([OMX_LIB_INSTALL_DIR])
2121
2122 dnl Directory for VA libs
2123
2124 AC_ARG_WITH([va-libdir],
2125     [AS_HELP_STRING([--with-va-libdir=DIR],
2126         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2127     [VA_LIB_INSTALL_DIR="$withval"],
2128     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2129 AC_SUBST([VA_LIB_INSTALL_DIR])
2130
2131 AC_ARG_WITH([d3d-libdir],
2132     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2133         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2134     [D3D_DRIVER_INSTALL_DIR="$withval"],
2135     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2136 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2137
2138 dnl
2139 dnl Gallium helper functions
2140 dnl
2141 gallium_require_drm() {
2142     if test "x$have_libdrm" != xyes; then
2143        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2144     fi
2145 }
2146
2147 gallium_require_llvm() {
2148     if test "x$MESA_LLVM" = x0; then
2149         case "$host" in *gnux32) return;; esac
2150         case "$host_cpu" in
2151         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2152         esac
2153     fi
2154 }
2155
2156 gallium_require_drm_loader() {
2157     if test "x$need_pci_id$have_pci_id" = xyesno; then
2158         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2159     fi
2160 }
2161
2162 require_egl_drm() {
2163     case "$with_egl_platforms" in
2164         *drm*)
2165             ;;
2166          *)
2167             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2168             ;;
2169     esac
2170     if test "x$enable_gbm" != xyes; then
2171             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2172     fi
2173 }
2174
2175 radeon_llvm_check() {
2176     if test ${LLVM_VERSION_INT} -lt 307; then
2177         amdgpu_llvm_target_name='r600'
2178     else
2179         amdgpu_llvm_target_name='amdgpu'
2180     fi
2181     if test "x$enable_gallium_llvm" != "xyes"; then
2182         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2183     fi
2184     llvm_check_version_for "3" "5" "0" $1
2185     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2186         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2187     fi
2188     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2189     NEED_RADEON_LLVM=yes
2190     if test "x$have_libelf" != xyes; then
2191        AC_MSG_ERROR([$1 requires libelf when using llvm])
2192     fi
2193 }
2194
2195 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2196 if test -n "$with_gallium_drivers"; then
2197     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2198     for driver in $gallium_drivers; do
2199         case "x$driver" in
2200         xsvga)
2201             HAVE_GALLIUM_SVGA=yes
2202             gallium_require_drm "svga"
2203             gallium_require_drm_loader
2204             ;;
2205         xi915)
2206             HAVE_GALLIUM_I915=yes
2207             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2208             gallium_require_drm "Gallium i915"
2209             gallium_require_drm_loader
2210             ;;
2211         xilo)
2212             HAVE_GALLIUM_ILO=yes
2213             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2214             gallium_require_drm "Gallium i965/ilo"
2215             gallium_require_drm_loader
2216             ;;
2217         xr300)
2218             HAVE_GALLIUM_R300=yes
2219             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2220             gallium_require_drm "Gallium R300"
2221             gallium_require_drm_loader
2222             gallium_require_llvm "Gallium R300"
2223             ;;
2224         xr600)
2225             HAVE_GALLIUM_R600=yes
2226             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2227             gallium_require_drm "Gallium R600"
2228             gallium_require_drm_loader
2229             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2230                 radeon_llvm_check "r600g"
2231                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2232             fi
2233             if test "x$enable_r600_llvm" = xyes; then
2234                 USE_R600_LLVM_COMPILER=yes;
2235             fi
2236             if test "x$enable_opencl" = xyes; then
2237                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2238             fi
2239             ;;
2240         xradeonsi)
2241             HAVE_GALLIUM_RADEONSI=yes
2242             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2243             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2244             gallium_require_drm "radeonsi"
2245             gallium_require_drm_loader
2246             radeon_llvm_check "radeonsi"
2247             require_egl_drm "radeonsi"
2248             ;;
2249         xnouveau)
2250             HAVE_GALLIUM_NOUVEAU=yes
2251             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2252             gallium_require_drm "nouveau"
2253             gallium_require_drm_loader
2254             ;;
2255         xfreedreno)
2256             HAVE_GALLIUM_FREEDRENO=yes
2257             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2258             gallium_require_drm "freedreno"
2259             gallium_require_drm_loader
2260             ;;
2261         xswrast)
2262             HAVE_GALLIUM_SOFTPIPE=yes
2263             if test "x$MESA_LLVM" = x1; then
2264                 HAVE_GALLIUM_LLVMPIPE=yes
2265             fi
2266             ;;
2267         xvc4)
2268             HAVE_GALLIUM_VC4=yes
2269             gallium_require_drm "vc4"
2270             gallium_require_drm_loader
2271
2272             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2273                               [USE_VC4_SIMULATOR=yes;
2274                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2275                               [USE_VC4_SIMULATOR=no])
2276             ;;
2277         xvirgl)
2278             HAVE_GALLIUM_VIRGL=yes
2279             gallium_require_drm "virgl"
2280             gallium_require_drm_loader
2281             require_egl_drm "virgl"
2282             ;;
2283         *)
2284             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2285             ;;
2286         esac
2287     done
2288 fi
2289
2290 dnl Set LLVM_LIBS - This is done after the driver configuration so
2291 dnl that drivers can add additional components to LLVM_COMPONENTS.
2292 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2293 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2294 dnl this was causing the same libraries to be appear multiple times
2295 dnl in LLVM_LIBS.
2296
2297 if test "x$MESA_LLVM" != x0; then
2298
2299     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2300
2301     dnl llvm-config may not give the right answer when llvm is a built as a
2302     dnl single shared library, so we must work the library name out for
2303     dnl ourselves.
2304     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2305     if test "x$enable_llvm_shared_libs" = xyes; then
2306         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2307         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2308         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2309
2310         if test "x$llvm_have_one_so" = xyes; then
2311             dnl LLVM was built using auto*, so there is only one shared object.
2312             LLVM_LIBS="-l$LLVM_SO_NAME"
2313         else
2314             dnl If LLVM was built with CMake, there will be one shared object per
2315             dnl component.
2316             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2317                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2318         Please make sure you have built llvm with the --enable-shared option
2319         and that your llvm libraries are installed in $LLVM_LIBDIR
2320         If you have installed your llvm libraries to a different directory you
2321         can use the --with-llvm-prefix= configure flag to specify this directory.
2322         NOTE: Mesa is attempting to use llvm shared libraries by default.
2323         If you do not want to build with llvm shared libraries and instead want to
2324         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2325         invocation and rebuild.])])
2326
2327            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2328            dnl install uses a shared object for each component and we have
2329            dnl already added all of these objects to LLVM_LIBS.
2330         fi
2331     else
2332         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2333         dnl We need to link to llvm system libs when using static libs
2334         dnl However, only llvm 3.5+ provides --system-libs
2335         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2336             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2337         fi
2338     fi
2339 fi
2340
2341 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2342 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2343 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2344 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2345 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2346 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2347 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2348                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2349 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2350 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2351 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2352 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2353 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2354 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2355
2356 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2357
2358 if test "x$enable_dri" = xyes; then
2359     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2360 fi
2361
2362 if test "x$have_drisw_kms" = xyes; then
2363     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2364 fi
2365 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2366
2367 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2368 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2369 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2370 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2371 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2372 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2373
2374 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2375                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2376                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2377 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2378 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2379 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2380 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2381 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2382 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2383 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2384     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2385 fi
2386
2387 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2388 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2389 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2390 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2391
2392 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2393 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2394 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2395
2396 AC_SUBST([NINE_MAJOR], 1)
2397 AC_SUBST([NINE_MINOR], 0)
2398 AC_SUBST([NINE_TINY], 0)
2399 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2400
2401 AC_SUBST([VDPAU_MAJOR], 1)
2402 AC_SUBST([VDPAU_MINOR], 0)
2403
2404 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2405 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2406 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2407 AC_SUBST([VA_MINOR], $VA_MINOR)
2408
2409 AC_SUBST([XVMC_MAJOR], 1)
2410 AC_SUBST([XVMC_MINOR], 0)
2411
2412 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2413 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2414 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2415 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2416
2417 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2418 AC_SUBST([XA_MINOR], $XA_MINOR)
2419 AC_SUBST([XA_TINY], $XA_TINY)
2420 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2421
2422 dnl Restore LDFLAGS and CPPFLAGS
2423 LDFLAGS="$_SAVE_LDFLAGS"
2424 CPPFLAGS="$_SAVE_CPPFLAGS"
2425
2426 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2427 if test "x$acv_mesa_CLANG" = xyes; then
2428     CFLAGS="$CFLAGS -Qunused-arguments"
2429     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2430 fi
2431
2432 dnl Add user CFLAGS and CXXFLAGS
2433 CFLAGS="$CFLAGS $USER_CFLAGS"
2434 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2435
2436 dnl Substitute the config
2437 AC_CONFIG_FILES([Makefile
2438                 src/Makefile
2439                 src/compiler/Makefile
2440                 src/egl/Makefile
2441                 src/egl/main/egl.pc
2442                 src/egl/wayland/wayland-drm/Makefile
2443                 src/egl/wayland/wayland-egl/Makefile
2444                 src/egl/wayland/wayland-egl/wayland-egl.pc
2445                 src/gallium/Makefile
2446                 src/gallium/auxiliary/Makefile
2447                 src/gallium/auxiliary/pipe-loader/Makefile
2448                 src/gallium/drivers/freedreno/Makefile
2449                 src/gallium/drivers/ddebug/Makefile
2450                 src/gallium/drivers/i915/Makefile
2451                 src/gallium/drivers/ilo/Makefile
2452                 src/gallium/drivers/llvmpipe/Makefile
2453                 src/gallium/drivers/noop/Makefile
2454                 src/gallium/drivers/nouveau/Makefile
2455                 src/gallium/drivers/r300/Makefile
2456                 src/gallium/drivers/r600/Makefile
2457                 src/gallium/drivers/radeon/Makefile
2458                 src/gallium/drivers/radeonsi/Makefile
2459                 src/gallium/drivers/rbug/Makefile
2460                 src/gallium/drivers/softpipe/Makefile
2461                 src/gallium/drivers/svga/Makefile
2462                 src/gallium/drivers/trace/Makefile
2463                 src/gallium/drivers/vc4/Makefile
2464                 src/gallium/drivers/virgl/Makefile
2465                 src/gallium/state_trackers/clover/Makefile
2466                 src/gallium/state_trackers/dri/Makefile
2467                 src/gallium/state_trackers/glx/xlib/Makefile
2468                 src/gallium/state_trackers/nine/Makefile
2469                 src/gallium/state_trackers/omx/Makefile
2470                 src/gallium/state_trackers/osmesa/Makefile
2471                 src/gallium/state_trackers/va/Makefile
2472                 src/gallium/state_trackers/vdpau/Makefile
2473                 src/gallium/state_trackers/xa/Makefile
2474                 src/gallium/state_trackers/xvmc/Makefile
2475                 src/gallium/targets/d3dadapter9/Makefile
2476                 src/gallium/targets/d3dadapter9/d3d.pc
2477                 src/gallium/targets/dri/Makefile
2478                 src/gallium/targets/libgl-xlib/Makefile
2479                 src/gallium/targets/omx/Makefile
2480                 src/gallium/targets/opencl/Makefile
2481                 src/gallium/targets/opencl/mesa.icd
2482                 src/gallium/targets/osmesa/Makefile
2483                 src/gallium/targets/osmesa/osmesa.pc
2484                 src/gallium/targets/pipe-loader/Makefile
2485                 src/gallium/targets/va/Makefile
2486                 src/gallium/targets/vdpau/Makefile
2487                 src/gallium/targets/xa/Makefile
2488                 src/gallium/targets/xa/xatracker.pc
2489                 src/gallium/targets/xvmc/Makefile
2490                 src/gallium/tests/trivial/Makefile
2491                 src/gallium/tests/unit/Makefile
2492                 src/gallium/winsys/freedreno/drm/Makefile
2493                 src/gallium/winsys/i915/drm/Makefile
2494                 src/gallium/winsys/intel/drm/Makefile
2495                 src/gallium/winsys/nouveau/drm/Makefile
2496                 src/gallium/winsys/radeon/drm/Makefile
2497                 src/gallium/winsys/amdgpu/drm/Makefile
2498                 src/gallium/winsys/svga/drm/Makefile
2499                 src/gallium/winsys/sw/dri/Makefile
2500                 src/gallium/winsys/sw/kms-dri/Makefile
2501                 src/gallium/winsys/sw/null/Makefile
2502                 src/gallium/winsys/sw/wrapper/Makefile
2503                 src/gallium/winsys/sw/xlib/Makefile
2504                 src/gallium/winsys/vc4/drm/Makefile
2505                 src/gallium/winsys/virgl/drm/Makefile
2506                 src/gallium/winsys/virgl/vtest/Makefile
2507                 src/gbm/Makefile
2508                 src/gbm/main/gbm.pc
2509                 src/glsl/Makefile
2510                 src/glx/Makefile
2511                 src/glx/apple/Makefile
2512                 src/glx/tests/Makefile
2513                 src/gtest/Makefile
2514                 src/loader/Makefile
2515                 src/mapi/Makefile
2516                 src/mapi/es1api/glesv1_cm.pc
2517                 src/mapi/es2api/glesv2.pc
2518                 src/mapi/glapi/gen/Makefile
2519                 src/mesa/Makefile
2520                 src/mesa/gl.pc
2521                 src/mesa/drivers/dri/dri.pc
2522                 src/mesa/drivers/dri/common/Makefile
2523                 src/mesa/drivers/dri/common/xmlpool/Makefile
2524                 src/mesa/drivers/dri/i915/Makefile
2525                 src/mesa/drivers/dri/i965/Makefile
2526                 src/mesa/drivers/dri/Makefile
2527                 src/mesa/drivers/dri/nouveau/Makefile
2528                 src/mesa/drivers/dri/r200/Makefile
2529                 src/mesa/drivers/dri/radeon/Makefile
2530                 src/mesa/drivers/dri/swrast/Makefile
2531                 src/mesa/drivers/osmesa/Makefile
2532                 src/mesa/drivers/osmesa/osmesa.pc
2533                 src/mesa/drivers/x11/Makefile
2534                 src/mesa/main/tests/Makefile
2535                 src/util/Makefile
2536                 src/util/tests/hash_table/Makefile])
2537
2538 AC_OUTPUT
2539
2540 dnl
2541 dnl Output some configuration info for the user
2542 dnl
2543 echo ""
2544 echo "        prefix:          $prefix"
2545 echo "        exec_prefix:     $exec_prefix"
2546 echo "        libdir:          $libdir"
2547 echo "        includedir:      $includedir"
2548
2549 dnl API info
2550 echo ""
2551 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2552
2553 dnl Driver info
2554 echo ""
2555 case "x$enable_osmesa$enable_gallium_osmesa" in
2556 xnoyes)
2557         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2558         ;;
2559 xyesno)
2560         echo "        OSMesa:          lib$OSMESA_LIB"
2561         ;;
2562 xnono)
2563         echo "        OSMesa:          no"
2564         ;;
2565 esac
2566
2567 echo ""
2568 if test "x$enable_dri" != xno; then
2569         echo "        DRI platform:    $dri_platform"
2570         if test -z "$DRI_DIRS"; then
2571             echo "        DRI drivers:     no"
2572         else
2573             echo "        DRI drivers:     $DRI_DIRS"
2574         fi
2575         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2576 fi
2577
2578 case "x$enable_glx$enable_xlib_glx" in
2579 xyesyes)
2580     echo "        GLX:             Xlib-based"
2581     ;;
2582 xyesno)
2583     echo "        GLX:             DRI-based"
2584     ;;
2585 *)
2586     echo "        GLX:             $enable_glx"
2587     ;;
2588 esac
2589
2590 dnl EGL
2591 echo ""
2592 echo "        EGL:             $enable_egl"
2593 if test "$enable_egl" = yes; then
2594     echo "        EGL platforms:   $egl_platforms"
2595
2596     egl_drivers=""
2597     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2598         egl_drivers="$egl_drivers builtin:egl_dri2"
2599     fi
2600     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2601         egl_drivers="$egl_drivers builtin:egl_dri3"
2602     fi
2603
2604     echo "        EGL drivers:    $egl_drivers"
2605 fi
2606
2607 echo ""
2608 if test "x$MESA_LLVM" = x1; then
2609     echo "        llvm:            yes"
2610     echo "        llvm-config:     $LLVM_CONFIG"
2611     echo "        llvm-version:    $LLVM_VERSION"
2612 else
2613     echo "        llvm:            no"
2614 fi
2615
2616 echo ""
2617 if test -n "$with_gallium_drivers"; then
2618     echo "        Gallium drivers: $gallium_drivers"
2619     echo "        Gallium st:      $gallium_st"
2620 else
2621     echo "        Gallium:         no"
2622 fi
2623
2624 dnl Shader cache
2625 echo ""
2626 echo "        Shader cache:    $enable_shader_cache"
2627 if test "x$enable_shader_cache" = "xyes"; then
2628     echo "        With SHA1 from:  $with_sha1"
2629 fi
2630
2631 dnl Libraries
2632 echo ""
2633 echo "        Shared libs:     $enable_shared"
2634 echo "        Static libs:     $enable_static"
2635 echo "        Shared-glapi:    $enable_shared_glapi"
2636
2637 dnl Compiler options
2638 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2639 cflags=`echo $CFLAGS | \
2640     $SED 's/^ *//;s/  */ /;s/ *$//'`
2641 cxxflags=`echo $CXXFLAGS | \
2642     $SED 's/^ *//;s/  */ /;s/ *$//'`
2643 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2644 echo ""
2645 echo "        CFLAGS:          $cflags"
2646 echo "        CXXFLAGS:        $cxxflags"
2647 echo "        Macros:          $defines"
2648 echo ""
2649 if test "x$MESA_LLVM" = x1; then
2650     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2651     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2652     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2653     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2654     echo ""
2655 fi
2656 echo "        PYTHON2:         $PYTHON2"
2657
2658 echo ""
2659 echo "        Run '${MAKE-make}' to build Mesa"
2660 echo ""