projects / mesa.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
android: broadcom/genxml: fix collision with intel/genxml header-gen macro
[mesa.git] / configure.ac
1 dnl Copyright © 2011-2014 Intel Corporation
2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
3 dnl Copyright © 2007-2010 Dan Nicholson
4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
5 dnl Copyright © 2010-2014 Christian König
6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
7 dnl Copyright © 2009-2012 Jakob Bornecrantz
8 dnl Copyright © 2009-2014 Jon TURNEY
9 dnl Copyright © 2011-2012 Benjamin Franzke
10 dnl Copyright © 2008-2014 David Airlie
11 dnl Copyright © 2009-2013 Brian Paul
12 dnl
13 dnl Permission is hereby granted, free of charge, to any person obtaining a
14 dnl copy of this software and associated documentation files (the "Software"),
15 dnl to deal in the Software without restriction, including without limitation
16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
17 dnl and/or sell copies of the Software, and to permit persons to whom the
18 dnl Software is furnished to do so, subject to the following conditions:
19 dnl
20 dnl The above copyright notice and this permission notice (including the next
21 dnl paragraph) shall be included in all copies or substantial portions of the
22 dnl Software.
23 dnl
24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
30 dnl DEALINGS IN THE SOFTWARE.
31 dnl
32 dnl Process this file with autoconf to create configure.
33
34 AC_PREREQ([2.60])
35
36 dnl Tell the user about autoconf.html in the --help output
37 m4_divert_once([HELP_END], [
38 See docs/autoconf.html for more details on the options for Mesa.])
39
40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
41 AC_INIT([Mesa], [MESA_VERSION],
42 [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
43 AC_CONFIG_AUX_DIR([bin])
44 AC_CONFIG_MACRO_DIR([m4])
45 AC_CANONICAL_SYSTEM
46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
47
48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
49 case "$host_os" in
50 mingw*)
51 AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
52 ;;
53 esac
54
55 # Support silent build rules, requires at least automake-1.11. Disable
56 # by either passing --disable-silent-rules to configure or passing V=1
57 # to make
58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
59 [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
60
61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
62
63 dnl Set internal versions
64 OSMESA_VERSION=8
65 AC_SUBST([OSMESA_VERSION])
66 OPENCL_VERSION=1
67 AC_SUBST([OPENCL_VERSION])
68
69 # The idea is that libdrm is distributed as one cohesive package, even
70 # though it is composed of multiple libraries. However some drivers
71 # may have different version requirements than others. This list
72 # codifies which drivers need which version of libdrm. Any libdrm
73 # version dependencies in non-driver-specific code should be reflected
74 # in the first entry.
75 LIBDRM_REQUIRED=2.4.75
76 LIBDRM_RADEON_REQUIRED=2.4.71
77 LIBDRM_AMDGPU_REQUIRED=2.4.93
78 LIBDRM_INTEL_REQUIRED=2.4.75
79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
81 LIBDRM_FREEDRENO_REQUIRED=2.4.93
82 LIBDRM_ETNAVIV_REQUIRED=2.4.89
83 LIBDRM_VC4_REQUIRED=2.4.89
84
85 dnl Versions for external dependencies
86 DRI2PROTO_REQUIRED=2.8
87 GLPROTO_REQUIRED=1.4.14
88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
89 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
90 LIBVA_REQUIRED=0.39.0
91 VDPAU_REQUIRED=1.1
92 WAYLAND_REQUIRED=1.11
93 WAYLAND_EGL_BACKEND_REQUIRED=3
94 WAYLAND_PROTOCOLS_REQUIRED=1.8
95 XCB_REQUIRED=1.9.3
96 XCBDRI2_REQUIRED=1.8
97 XCBDRI3_MODIFIERS_REQUIRED=1.13
98 XCBGLX_REQUIRED=1.8.1
99 XCBPRESENT_MODIFIERS_REQUIRED=1.13
100 XDAMAGE_REQUIRED=1.1
101 XSHMFENCE_REQUIRED=1.1
102 XVMC_REQUIRED=1.0.6
103 PYTHON_MAKO_REQUIRED=0.8.0
104 LIBSENSORS_REQUIRED=4.0.0
105 ZLIB_REQUIRED=1.2.3
106
107 dnl LLVM versions
108 LLVM_REQUIRED_GALLIUM=3.3.0
109 LLVM_REQUIRED_OPENCL=3.9.0
110 LLVM_REQUIRED_R600=3.9.0
111 LLVM_REQUIRED_RADEONSI=6.0.0
112 LLVM_REQUIRED_RADV=6.0.0
113 LLVM_REQUIRED_SWR=6.0.0
114
115 dnl Check for progs
116 AC_PROG_CPP
117 AC_PROG_CC
118 AC_PROG_CXX
119 dnl add this here, so the help for this environmnet variable is close to
120 dnl other CC/CXX flags related help
121 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
122 enabled by default and different from -std=c++11)])
123 AM_PROG_CC_C_O
124 AC_PROG_GREP
125 AC_PROG_NM
126 AM_PROG_AS
127 AX_CHECK_GNU_MAKE
128 AM_PATH_PYTHON([2.7],, [:])
129 PYTHON2=$PYTHON
130 AC_SUBST([PYTHON2])
131
132 AC_PROG_SED
133 AC_PROG_MKDIR_P
134
135 AC_SYS_LARGEFILE
136
137
138 LT_PREREQ([2.2])
139 LT_INIT([disable-static])
140
141 AC_CHECK_PROG(RM, rm, [rm -f])
142
143 AX_PROG_BISON([],
144 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
145 [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
146 AX_PROG_FLEX([],
147 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
148 [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
149
150 AC_CHECK_PROG(INDENT, indent, indent, cat)
151 if test "x$INDENT" != "xcat"; then
152 # Only GNU indent is supported
153 INDENT_VERSION=`indent --version | grep GNU`
154 if test $? -eq 0; then
155 AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
156 else
157 INDENT="cat"
158 fi
159 fi
160
161 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
162
163 if test "$PYTHON2" = ":"; then
164 if test ! -f "$srcdir/src/util/format_srgb.c"; then
165 AC_MSG_ERROR([Python not found - unable to generate sources])
166 fi
167 else
168 if test "x$acv_mako_found" = xno; then
169 if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
170 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
171 fi
172 fi
173 fi
174
175 AC_PROG_INSTALL
176
177 dnl We need a POSIX shell for parts of the build. Assume we have one
178 dnl in most cases.
179 case "$host_os" in
180 solaris*)
181 # Solaris /bin/sh is too old/non-POSIX compliant
182 AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
183 SHELL="$POSIX_SHELL"
184 ;;
185 esac
186
187 dnl clang is mostly GCC-compatible, but its version is much lower,
188 dnl so we have to check for it.
189 AC_MSG_CHECKING([if compiling with clang])
190
191 AC_COMPILE_IFELSE(
192 [AC_LANG_PROGRAM([], [[
193 #ifndef __clang__
194 not clang
195 #endif
196 ]])],
197 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
198
199 AC_MSG_RESULT([$acv_mesa_CLANG])
200
201 dnl If we're using GCC, make sure that it is at least version 4.2.0. Older
202 dnl versions are explictly not supported.
203 GEN_ASM_OFFSETS=no
204 USE_GNU99=no
205 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
206 AC_MSG_CHECKING([whether gcc version is sufficient])
207 major=0
208 minor=0
209
210 GCC_VERSION=`$CC -dumpversion`
211 if test $? -eq 0; then
212 GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
213 GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
214 fi
215
216 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
217 AC_MSG_RESULT([no])
218 AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
219 else
220 AC_MSG_RESULT([yes])
221 fi
222
223 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
224 USE_GNU99=yes
225 fi
226 if test "x$cross_compiling" = xyes; then
227 GEN_ASM_OFFSETS=yes
228 fi
229 fi
230
231 dnl We don't support building Mesa with Sun C compiler
232 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
233 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
234 if test "x$SUNCC" = xyes; then
235 AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
236 fi
237
238 dnl Check for compiler builtins
239 AX_GCC_BUILTIN([__builtin_bswap32])
240 AX_GCC_BUILTIN([__builtin_bswap64])
241 AX_GCC_BUILTIN([__builtin_clz])
242 AX_GCC_BUILTIN([__builtin_clzll])
243 AX_GCC_BUILTIN([__builtin_ctz])
244 AX_GCC_BUILTIN([__builtin_expect])
245 AX_GCC_BUILTIN([__builtin_ffs])
246 AX_GCC_BUILTIN([__builtin_ffsll])
247 AX_GCC_BUILTIN([__builtin_popcount])
248 AX_GCC_BUILTIN([__builtin_popcountll])
249 AX_GCC_BUILTIN([__builtin_unreachable])
250
251 AX_GCC_FUNC_ATTRIBUTE([const])
252 AX_GCC_FUNC_ATTRIBUTE([flatten])
253 AX_GCC_FUNC_ATTRIBUTE([format])
254 AX_GCC_FUNC_ATTRIBUTE([malloc])
255 AX_GCC_FUNC_ATTRIBUTE([packed])
256 AX_GCC_FUNC_ATTRIBUTE([pure])
257 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
258 AX_GCC_FUNC_ATTRIBUTE([unused])
259 AX_GCC_FUNC_ATTRIBUTE([visibility])
260 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
261 AX_GCC_FUNC_ATTRIBUTE([weak])
262 AX_GCC_FUNC_ATTRIBUTE([alias])
263 AX_GCC_FUNC_ATTRIBUTE([noreturn])
264
265 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
266
267 dnl Make sure the pkg-config macros are defined
268 m4_ifndef([PKG_PROG_PKG_CONFIG],
269 [m4_fatal([Could not locate the pkg-config autoconf macros.
270 These are usually located in /usr/share/aclocal/pkg.m4. If your macros
271 are in a different location, try setting the environment variable
272 ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
273 PKG_PROG_PKG_CONFIG()
274
275 dnl LIB_DIR - library basename
276 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
277 AC_SUBST([LIB_DIR])
278
279 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
280 _SAVE_LDFLAGS="$LDFLAGS"
281 _SAVE_CPPFLAGS="$CPPFLAGS"
282
283 dnl Compiler macros
284 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
285 AC_SUBST([DEFINES])
286 android=no
287 case "$host_os" in
288 *-android*)
289 android=yes
290 ;;
291 linux*|*-gnu*|gnu*|cygwin*)
292 DEFINES="$DEFINES -D_GNU_SOURCE"
293 ;;
294 solaris*)
295 DEFINES="$DEFINES -DSVR4"
296 ;;
297 esac
298
299 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
300
301 dnl
302 dnl Check compiler flags
303 dnl
304 AX_CHECK_COMPILE_FLAG([-Wall], [CFLAGS="$CFLAGS -Wall"])
305 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
306 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes], [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
307 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes], [CFLAGS="$CFLAGS -Wmissing-prototypes"])
308 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
309 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers], [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
310 AX_CHECK_COMPILE_FLAG([-fno-math-errno], [CFLAGS="$CFLAGS -fno-math-errno"])
311
312 AX_CHECK_COMPILE_FLAG([-fno-trapping-math], [CFLAGS="$CFLAGS -fno-trapping-math"])
313 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
314
315 dnl
316 dnl Check C++ compiler flags
317 dnl
318 AC_LANG_PUSH([C++])
319 AX_CHECK_COMPILE_FLAG([-Wall], [CXXFLAGS="$CXXFLAGS -Wall"])
320 AX_CHECK_COMPILE_FLAG([-fno-math-errno], [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
321 AX_CHECK_COMPILE_FLAG([-fno-trapping-math], [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
322 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
323 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers], [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
324 AC_LANG_POP([C++])
325
326 # Flags to help ensure that certain portions of the code -- and only those
327 # portions -- can be built with MSVC:
328 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
329 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
330 # supports most of C99)
331 # - the rest has no compiler compiler restrictions
332 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith], [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
333 AX_CHECK_COMPILE_FLAG([-Werror=vla], [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
334 AC_LANG_PUSH([C++])
335 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith], [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
336 AX_CHECK_COMPILE_FLAG([-Werror=vla], [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
337 AC_LANG_POP([C++])
338
339 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
340 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
341
342 if test "x$GCC" = xyes; then
343 if test "x$USE_GNU99" = xyes; then
344 CFLAGS="$CFLAGS -std=gnu99"
345 else
346 CFLAGS="$CFLAGS -std=c99"
347 fi
348 fi
349
350 dnl
351 dnl Check whether C++11 is supported, if the environment variable
352 dnl CXX11_CXXFLAGS is set it takes precedence.
353 dnl
354
355 AC_LANG_PUSH([C++])
356
357 check_cxx11_available() {
358 output_support=$1
359 AC_COMPILE_IFELSE(
360 [AC_LANG_PROGRAM([
361 #if !(__cplusplus >= 201103L)
362 #error
363 #endif
364 #include <tuple>
365 ])
366 ], [
367 AC_MSG_RESULT(yes)
368 cxx11_support=yes
369 ], AC_MSG_RESULT(no))
370 eval "$output_support=\$cxx11_support"
371 }
372
373 HAVE_CXX11=no
374 save_CXXFLAGS="$CXXFLAGS"
375
376 dnl If the user provides a flag to enable c++11, then we test only this
377 if test "x$CXX11_CXXFLAGS" != "x"; then
378 CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
379 AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
380 check_cxx11_available HAVE_CXX11
381 else
382 dnl test whether c++11 is enabled by default
383 AC_MSG_CHECKING(whether c++11 is enabled by default)
384 check_cxx11_available HAVE_CXX11
385
386 dnl C++11 not enabled by default, test whether -std=c++11 does the job
387 if test "x$HAVE_CXX11" != "xyes"; then
388 CXX11_CXXFLAGS=-std=c++11
389 CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
390 AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
391 check_cxx11_available HAVE_CXX11
392 fi
393 fi
394
395 CXXFLAGS="$save_CXXFLAGS"
396 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
397 AC_SUBST(CXX11_CXXFLAGS)
398 AC_LANG_POP([C++])
399
400 dnl even if the compiler appears to support it, using visibility attributes isn't
401 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
402 case "$host_os" in
403 cygwin*)
404 VISIBILITY_CFLAGS=""
405 VISIBILITY_CXXFLAGS=""
406 ;;
407 esac
408
409 AC_SUBST([VISIBILITY_CFLAGS])
410 AC_SUBST([VISIBILITY_CXXFLAGS])
411
412 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
413 dnl option is not supported. Hence, check for -Wfoo instead.
414 AX_CHECK_COMPILE_FLAG([-Woverride-init], [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"]) # gcc
415 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides], [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
416 AC_SUBST([WNO_OVERRIDE_INIT])
417
418 dnl
419 dnl Optional flags, check for compiler support
420 dnl
421 SSE41_CFLAGS="-msse4.1"
422 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
423 dnl stack, but on x86-32 such alignment is not guaranteed.
424 case "$target_cpu" in
425 i?86)
426 SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
427 ;;
428 esac
429 save_CFLAGS="$CFLAGS"
430 CFLAGS="$SSE41_CFLAGS $CFLAGS"
431 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
432 #include <smmintrin.h>
433 int param;
434 int main () {
435 __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
436 c = _mm_max_epu32(a, b);
437 return _mm_cvtsi128_si32(c);
438 }]])], SSE41_SUPPORTED=1)
439 CFLAGS="$save_CFLAGS"
440 if test "x$SSE41_SUPPORTED" = x1; then
441 DEFINES="$DEFINES -DUSE_SSE41"
442 fi
443 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
444 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
445
446 dnl Check for new-style atomic builtins. We first check without linking to
447 dnl -latomic.
448 AC_MSG_CHECKING(whether __atomic_load_n is supported)
449 AC_LINK_IFELSE([AC_LANG_SOURCE([[
450 #include <stdint.h>
451 int main() {
452 struct {
453 uint64_t *v;
454 } x;
455 return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
456 (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
457 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
458
459 dnl If that didn't work, we try linking with -latomic, which is needed on some
460 dnl platforms.
461 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
462 save_LDFLAGS=$LDFLAGS
463 LDFLAGS="$LDFLAGS -latomic"
464 AC_LINK_IFELSE([AC_LANG_SOURCE([[
465 #include <stdint.h>
466 int main() {
467 struct {
468 uint64_t *v;
469 } x;
470 return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
471 (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
472 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
473 GCC_ATOMIC_BUILTINS_SUPPORTED=no)
474 LDFLAGS=$save_LDFLAGS
475 fi
476 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
477
478 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
479 DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
480 fi
481 AC_SUBST([LIBATOMIC_LIBS])
482
483 dnl Check if host supports 64-bit atomics
484 dnl note that lack of support usually results in link (not compile) error
485 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
486 AC_LINK_IFELSE([AC_LANG_SOURCE([[
487 #include <stdint.h>
488 uint64_t v;
489 int main() {
490 return __sync_add_and_fetch(&v, (uint64_t)1);
491 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
492 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
493 DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
494 fi
495 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
496
497 dnl Check for Endianness
498 AC_C_BIGENDIAN(
499 little_endian=no,
500 little_endian=yes,
501 little_endian=no,
502 little_endian=no
503 )
504
505 dnl Check for POWER8 Architecture
506 PWR8_CFLAGS="-mpower8-vector"
507 have_pwr8_intrinsics=no
508 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
509 save_CFLAGS=$CFLAGS
510 CFLAGS="$PWR8_CFLAGS $CFLAGS"
511 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
512 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
513 #error "Need GCC >= 4.8 for sane POWER8 support"
514 #endif
515 #include <altivec.h>
516 int main () {
517 vector unsigned char r;
518 vector unsigned int v = vec_splat_u32 (1);
519 r = __builtin_vec_vgbbd ((vector unsigned char) v);
520 return 0;
521 }]])], have_pwr8_intrinsics=yes)
522 CFLAGS=$save_CFLAGS
523
524 AC_ARG_ENABLE(pwr8,
525 [AS_HELP_STRING([--disable-pwr8],
526 [disable POWER8-specific instructions])],
527 [enable_pwr8=$enableval], [enable_pwr8=auto])
528
529 if test "x$enable_pwr8" = xno ; then
530 have_pwr8_intrinsics=disabled
531 fi
532
533 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
534 DEFINES="$DEFINES -D_ARCH_PWR8"
535 CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
536 CFLAGS="$CFLAGS $PWR8_CFLAGS"
537 else
538 PWR8_CFLAGS=
539 fi
540
541 AC_MSG_RESULT($have_pwr8_intrinsics)
542 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
543 AC_MSG_ERROR([POWER8 compiler support not detected])
544 fi
545
546 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
547 AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
548 fi
549
550 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
551
552 dnl Can't have static and shared libraries, default to static if user
553 dnl explicitly requested. If both disabled, set to static since shared
554 dnl was explicitly requested.
555 case "x$enable_static$enable_shared" in
556 xyesyes)
557 AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
558 ;;
559 xnono)
560 AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
561 ;;
562 esac
563
564 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
565
566 dnl
567 dnl other compiler options
568 dnl
569 AC_ARG_ENABLE([debug],
570 [AS_HELP_STRING([--enable-debug],
571 [use debug compiler flags and macros @<:@default=disabled@:>@])],
572 [enable_debug="$enableval"],
573 [enable_debug=no]
574 )
575
576 AC_ARG_ENABLE([profile],
577 [AS_HELP_STRING([--enable-profile],
578 [enable profiling of code @<:@default=disabled@:>@])],
579 [enable_profile="$enableval"],
580 [enable_profile=no]
581 )
582
583 AC_ARG_ENABLE([sanitize],
584 [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
585 [enable code sanitizer @<:@default=disabled@:>@])],
586 [enable_sanitize="$enableval"],
587 [enable_sanitize=no])
588
589 if test "x$enable_profile" = xyes; then
590 DEFINES="$DEFINES -DPROFILE"
591 if test "x$GCC" = xyes; then
592 CFLAGS="$CFLAGS -fno-omit-frame-pointer"
593 fi
594 if test "x$GXX" = xyes; then
595 CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
596 fi
597 fi
598
599 if test "x$enable_debug" = xyes; then
600 DEFINES="$DEFINES -DDEBUG"
601 if test "x$enable_profile" = xyes; then
602 AC_MSG_WARN([Debug and Profile are enabled at the same time])
603 fi
604 if test "x$GCC" = xyes; then
605 if ! echo "$CFLAGS" | grep -q -e '-g'; then
606 CFLAGS="$CFLAGS -g"
607 fi
608 if ! echo "$CFLAGS" | grep -q -e '-O'; then
609 CFLAGS="$CFLAGS -O0"
610 fi
611 fi
612 if test "x$GXX" = xyes; then
613 if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
614 CXXFLAGS="$CXXFLAGS -g"
615 fi
616 if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
617 CXXFLAGS="$CXXFLAGS -O0"
618 fi
619 fi
620 else
621 DEFINES="$DEFINES -DNDEBUG"
622 fi
623
624 if test "x$enable_sanitize" != xno; then
625 if test "x$enable_profile" = xyes; then
626 AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
627 fi
628
629 CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
630 CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
631 LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
632
633 AC_LINK_IFELSE(
634 [AC_LANG_SOURCE([int main(){return 0;}])],
635 [],
636 [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
637 fi
638
639 dnl
640 dnl Check if linker supports -Bsymbolic
641 dnl
642 save_LDFLAGS=$LDFLAGS
643 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
644 AC_MSG_CHECKING([if ld supports -Bsymbolic])
645 AC_LINK_IFELSE(
646 [AC_LANG_SOURCE([int main() { return 0;}])],
647 [AC_MSG_RESULT([yes])
648 BSYMBOLIC="-Wl,-Bsymbolic";],
649 [AC_MSG_RESULT([no])
650 BSYMBOLIC="";])
651 LDFLAGS=$save_LDFLAGS
652
653 AC_SUBST([BSYMBOLIC])
654
655 dnl
656 dnl Check if linker supports garbage collection
657 dnl
658 save_LDFLAGS=$LDFLAGS
659 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
660 AC_MSG_CHECKING([whether ld supports --gc-sections])
661 AC_LINK_IFELSE(
662 [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
663 [AC_MSG_RESULT([yes])
664 GC_SECTIONS="-Wl,--gc-sections";],
665 [AC_MSG_RESULT([no])
666 GC_SECTIONS="";])
667 LDFLAGS=$save_LDFLAGS
668
669 AC_SUBST([GC_SECTIONS])
670
671 dnl
672 dnl OpenBSD does not have DT_NEEDED entries for libc by design
673 dnl so when these flags are passed to ld via libtool the checks will fail
674 dnl
675 case "$host_os" in
676 openbsd* | darwin* )
677 LD_NO_UNDEFINED="" ;;
678 *)
679 if test "x$enable_sanitize" = xno; then
680 LD_NO_UNDEFINED="-Wl,--no-undefined"
681 else
682 LD_NO_UNDEFINED=""
683 fi
684 ;;
685 esac
686
687 AC_SUBST([LD_NO_UNDEFINED])
688
689 dnl
690 dnl Check if linker supports version scripts
691 dnl
692 AC_MSG_CHECKING([if the linker supports version-scripts])
693 save_LDFLAGS=$LDFLAGS
694 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
695 AC_LINK_IFELSE(
696 [AC_LANG_SOURCE([int main() { return 0;}])],
697 [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
698 [have_ld_version_script=no; AC_MSG_RESULT(no)])
699 LDFLAGS=$save_LDFLAGS
700 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
701
702 dnl
703 dnl Check if linker supports dynamic list files
704 dnl
705 AC_MSG_CHECKING([if the linker supports --dynamic-list])
706 save_LDFLAGS=$LDFLAGS
707 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
708 AC_LINK_IFELSE(
709 [AC_LANG_SOURCE([int main() { return 0;}])],
710 [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
711 [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
712 LDFLAGS=$save_LDFLAGS
713 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
714
715 dnl
716 dnl OSX linker does not support build-id
717 dnl
718 case "$host_os" in
719 darwin*)
720 LD_BUILD_ID=""
721 ;;
722 *)
723 LD_BUILD_ID="-Wl,--build-id=sha1"
724 ;;
725 esac
726 AC_SUBST([LD_BUILD_ID])
727
728 dnl
729 dnl compatibility symlinks
730 dnl
731 case "$host_os" in
732 linux* )
733 HAVE_COMPAT_SYMLINKS=yes ;;
734 * )
735 HAVE_COMPAT_SYMLINKS=no ;;
736 esac
737
738 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
739
740 dnl
741 dnl library names
742 dnl
743 dnl Unfortunately we need to do a few things that libtool can't help us with,
744 dnl so we need some knowledge of shared library filenames:
745 dnl
746 dnl LIB_EXT is the extension used when creating symlinks for alternate
747 dnl filenames for a shared library which will be dynamically loaded
748 dnl
749 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
750 dnl the file for a shared library we wish to link with
751 dnl
752 case "$host_os" in
753 darwin* )
754 LIB_EXT='dylib'
755 IMP_LIB_EXT=$LIB_EXT
756 ;;
757 cygwin* )
758 LIB_EXT='dll'
759 IMP_LIB_EXT='dll.a'
760 ;;
761 aix* )
762 LIB_EXT='a'
763 IMP_LIB_EXT=$LIB_EXT
764 ;;
765 * )
766 LIB_EXT='so'
767 IMP_LIB_EXT=$LIB_EXT
768 ;;
769 esac
770
771 AC_SUBST([LIB_EXT])
772
773 dnl
774 dnl Arch/platform-specific settings
775 dnl
776 AC_ARG_ENABLE([asm],
777 [AS_HELP_STRING([--disable-asm],
778 [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
779 [enable_asm="$enableval"],
780 [enable_asm=yes]
781 )
782 asm_arch=""
783 AC_MSG_CHECKING([whether to enable assembly])
784 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
785 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
786 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
787 case "$host_cpu" in
788 i?86 | x86_64 | amd64)
789 if test "x$host_cpu" != "x$target_cpu"; then
790 enable_asm=no
791 AC_MSG_RESULT([no, cross compiling])
792 fi
793 ;;
794 esac
795 fi
796 # check for supported arches
797 if test "x$enable_asm" = xyes; then
798 case "$host_cpu" in
799 i?86)
800 case "$host_os" in
801 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
802 asm_arch=x86
803 ;;
804 esac
805 ;;
806 x86_64|amd64)
807 case "$host_os" in
808 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
809 asm_arch=x86_64
810 ;;
811 esac
812 ;;
813 sparc*)
814 case "$host_os" in
815 linux*)
816 asm_arch=sparc
817 ;;
818 esac
819 ;;
820 powerpc64le)
821 case "$host_os" in
822 linux*)
823 asm_arch=ppc64le
824 ;;
825 esac
826 ;;
827 aarch64)
828 case "$host_os" in
829 linux*)
830 asm_arch=aarch64
831 ;;
832 esac
833 ;;
834 arm)
835 case "$host_os" in
836 linux*)
837 asm_arch=arm
838 ;;
839 esac
840 ;;
841 esac
842
843 case "$asm_arch" in
844 x86)
845 DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
846 AC_MSG_RESULT([yes, x86])
847 ;;
848 x86_64|amd64)
849 DEFINES="$DEFINES -DUSE_X86_64_ASM"
850 AC_MSG_RESULT([yes, x86_64])
851 ;;
852 sparc)
853 DEFINES="$DEFINES -DUSE_SPARC_ASM"
854 AC_MSG_RESULT([yes, sparc])
855 ;;
856 ppc64le)
857 DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
858 AC_MSG_RESULT([yes, ppc64le])
859 ;;
860 aarch64)
861 DEFINES="$DEFINES -DUSE_AARCH64_ASM"
862 AC_MSG_RESULT([yes, aarch64])
863 ;;
864 arm)
865 DEFINES="$DEFINES -DUSE_ARM_ASM"
866 AC_MSG_RESULT([yes, arm])
867 ;;
868 *)
869 AC_MSG_RESULT([no, platform not supported])
870 ;;
871 esac
872 fi
873
874 AC_HEADER_MAJOR
875 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
876 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
877 AC_CHECK_HEADERS([endian.h])
878 AC_CHECK_HEADER([dlfcn.h], [DEFINES="$DEFINES -DHAVE_DLFCN_H"])
879 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
880 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
881 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
882 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
883
884 AC_MSG_CHECKING([whether strtod has locale support])
885 AC_LINK_IFELSE([AC_LANG_SOURCE([[
886 #define _GNU_SOURCE
887 #include <stdlib.h>
888 #include <locale.h>
889 #ifdef HAVE_XLOCALE_H
890 #include <xlocale.h>
891 #endif
892 int main() {
893 locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
894 const char *s = "1.0";
895 char *end;
896 double d = strtod_l(s, end, loc);
897 float f = strtof_l(s, end, loc);
898 freelocale(loc);
899 return 0;
900 }]])],
901 [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
902 AC_MSG_RESULT([yes]),
903 AC_MSG_RESULT([no]))
904
905 dnl Check to see if dlopen is in default libraries (like Solaris, which
906 dnl has it in libc), or if libdl is needed to get it.
907 AC_CHECK_FUNC([dlopen], [],
908 [AC_CHECK_LIB([dl], [dlopen],
909 [DLOPEN_LIBS="-ldl"])])
910 AC_SUBST([DLOPEN_LIBS])
911
912 dnl Check if that library also has dladdr
913 save_LIBS="$LIBS"
914 LIBS="$LIBS $DLOPEN_LIBS"
915 AC_CHECK_FUNCS([dladdr])
916 LIBS="$save_LIBS"
917
918 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
919
920 case "$host_os" in
921 darwin*)
922 ;;
923 *)
924 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
925 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
926 [AC_MSG_ERROR([Could not find clock_gettime])])])
927 AC_SUBST([CLOCK_LIB])
928 ;;
929 esac
930
931 dnl See if posix_memalign is available
932 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
933
934 dnl Check for zlib
935 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
936 DEFINES="$DEFINES -DHAVE_ZLIB"
937
938 dnl Check for pthreads
939 AX_PTHREAD
940 if test "x$ax_pthread_ok" = xno; then
941 AC_MSG_ERROR([Building mesa on this platform requires pthreads])
942 fi
943 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
944 dnl to -pthread, which causes problems if we need -lpthread to appear in
945 dnl pkgconfig files. Since Android doesn't have a pthread lib, this check
946 dnl is not valid for that platform.
947 if test "x$android" = xno; then
948 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
949 fi
950 dnl According to the manual when using pthreads, one should add -pthread to
951 dnl both compile and link-time arguments.
952 dnl In practise that should be sufficient for all platforms, since any
953 dnl platforms build with GCC and Clang support the flag.
954 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
955
956 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
957 dnl project. Even then there's a notable issue as described in the project README
958 case "$host_os" in
959 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
960 pthread_stubs_possible="no"
961 ;;
962 * )
963 pthread_stubs_possible="yes"
964 ;;
965 esac
966
967 if test "x$pthread_stubs_possible" = xyes; then
968 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
969 fi
970
971 dnl Check for futex for fast inline simple_mtx_t.
972 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
973
974 dnl SELinux awareness.
975 AC_ARG_ENABLE([selinux],
976 [AS_HELP_STRING([--enable-selinux],
977 [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
978 [MESA_SELINUX="$enableval"],
979 [MESA_SELINUX=no])
980 if test "x$enable_selinux" = "xyes"; then
981 PKG_CHECK_MODULES([SELINUX], [libselinux], [],
982 [AC_CHECK_HEADER([selinux/selinux.h],[],
983 [AC_MSG_ERROR([SELinux headers not found])])
984 AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
985 [AC_MSG_ERROR([SELinux library not found])])
986 SELINUX_LIBS="-lselinux"])
987 DEFINES="$DEFINES -DMESA_SELINUX"
988 fi
989 AC_SUBST([SELINUX_CFLAGS])
990 AC_SUBST([SELINUX_LIBS])
991
992 dnl
993 dnl LLVM
994 dnl
995 AC_ARG_ENABLE([llvm-shared-libs],
996 [AS_HELP_STRING([--enable-llvm-shared-libs],
997 [link with LLVM shared libraries @<:@default=enabled@:>@])],
998 [enable_llvm_shared_libs="$enableval"],
999 [enable_llvm_shared_libs=yes])
1000
1001 AC_ARG_WITH([llvm-prefix],
1002 [AS_HELP_STRING([--with-llvm-prefix],
1003 [Prefix for LLVM installations in non-standard locations])],
1004 [llvm_prefix="$withval"],
1005 [llvm_prefix=''])
1006
1007 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1008 if test "x$have_libelf" = xno; then
1009 LIBELF_LIBS=''
1010 LIBELF_CFLAGS=''
1011 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1012 AC_SUBST([LIBELF_LIBS])
1013 AC_SUBST([LIBELF_CFLAGS])
1014 fi
1015
1016 if test -z "$LLVM_CONFIG"; then
1017 if test -n "$llvm_prefix"; then
1018 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1019 else
1020 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1021 fi
1022 fi
1023
1024 llvm_add_component() {
1025 new_llvm_component=$1
1026 driver_name=$2
1027
1028 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1029 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1030 else
1031 AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1032 fi
1033 }
1034
1035 llvm_add_optional_component() {
1036 new_llvm_component=$1
1037 driver_name=$2
1038
1039 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1040 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1041 fi
1042 }
1043
1044 llvm_add_default_components() {
1045 driver_name=$1
1046
1047 # Required default components
1048 llvm_add_component "bitwriter" $driver_name
1049 llvm_add_component "engine" $driver_name
1050 llvm_add_component "mcdisassembler" $driver_name
1051 llvm_add_component "mcjit" $driver_name
1052
1053 # Optional default components
1054 llvm_add_optional_component "inteljitevents" $driver_name
1055 }
1056
1057 llvm_add_target() {
1058 new_llvm_target=$1
1059 driver_name=$2
1060
1061 if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1062 llvm_add_component $new_llvm_target $driver_name
1063 else
1064 AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1065 fi
1066 }
1067
1068 # Call this inside ` ` to get the return value.
1069 # $1 is the llvm-config command with arguments.
1070 strip_unwanted_llvm_flags() {
1071 echo " `$1` " | sed -E \
1072 -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1073 -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1074 -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1075 -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1076 -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1077 -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1078 -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1079 -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1080 -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1081 -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1082 -e 's/^[[[:space:]]]//' \
1083 -e 's/[[[:space:]]]$//'
1084 }
1085
1086 llvm_set_environment_variables() {
1087 if test "x$LLVM_CONFIG" != xno; then
1088 LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1089 LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1090 LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1091 LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1092
1093 # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1094 save_CFLAGS="$CFLAGS"
1095 CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1096
1097 AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1098 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1099 AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1100 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1101 AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1102 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1103
1104 CFLAGS="$save_CFLAGS"
1105
1106 # Only needed for LLVM < 3.6.0
1107 if test -z "$LLVM_VERSION_PATCH"; then
1108 LLVM_VERSION_PATCH=0
1109 fi
1110
1111 LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1112
1113 FOUND_LLVM=yes
1114 else
1115 FOUND_LLVM=no
1116 LLVM_VERSION_INT=0
1117 fi
1118 }
1119
1120 require_llvm() {
1121 if test "x$enable_llvm" != "xyes"; then
1122 AC_MSG_ERROR([--enable-llvm is required when building $1])
1123 fi
1124 }
1125
1126 llvm_require_version() {
1127 require_llvm $2
1128
1129 llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1130 llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1131 llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1132
1133 if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1134 # major > required major
1135 # --> OK
1136 return
1137 fi
1138
1139 if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1140 if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1141 # major = required major and
1142 # minor > required minor
1143 # --> OK
1144 return
1145 else
1146 if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1147 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1148 # major = required major and
1149 # minor = required minor and
1150 # patch >= required patch
1151 # --> OK
1152 return
1153 fi
1154 fi
1155 fi
1156 fi
1157
1158 AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1159 }
1160
1161 radeon_llvm_check() {
1162 if test ${LLVM_VERSION_INT} -lt 307; then
1163 amdgpu_llvm_target_name='r600'
1164 else
1165 amdgpu_llvm_target_name='amdgpu'
1166 fi
1167
1168 llvm_require_version $*
1169
1170 llvm_add_target $amdgpu_llvm_target_name $2
1171
1172 llvm_add_default_components $2
1173 llvm_add_component "bitreader" $2
1174 llvm_add_component "ipo" $2
1175
1176 if test "x$have_libelf" != xyes; then
1177 AC_MSG_ERROR([$2 requires libelf when using llvm])
1178 fi
1179 }
1180
1181 llvm_set_environment_variables
1182
1183 AC_SUBST([LLVM_CFLAGS])
1184 AC_SUBST([LLVM_CXXFLAGS])
1185 AC_SUBST([LLVM_LIBS])
1186 AC_SUBST([LLVM_LDFLAGS])
1187 AC_SUBST([LLVM_INCLUDEDIR])
1188
1189 dnl
1190 dnl libunwind
1191 dnl
1192 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1193 AC_ARG_ENABLE([libunwind],
1194 [AS_HELP_STRING([--enable-libunwind],
1195 [Use libunwind for backtracing (default: auto)])],
1196 [LIBUNWIND="$enableval"],
1197 [LIBUNWIND="$HAVE_LIBUNWIND"])
1198
1199 if test "x$LIBUNWIND" = "xyes"; then
1200 PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1201 AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1202 fi
1203
1204
1205 dnl Options for APIs
1206 AC_ARG_ENABLE([opengl],
1207 [AS_HELP_STRING([--disable-opengl],
1208 [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1209 [enable_opengl="$enableval"],
1210 [enable_opengl=yes])
1211 AC_ARG_ENABLE([gles1],
1212 [AS_HELP_STRING([--disable-gles1],
1213 [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1214 [enable_gles1="$enableval"],
1215 [enable_gles1=yes])
1216 AC_ARG_ENABLE([gles2],
1217 [AS_HELP_STRING([--disable-gles2],
1218 [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1219 [enable_gles2="$enableval"],
1220 [enable_gles2=yes])
1221
1222 AC_ARG_ENABLE([dri],
1223 [AS_HELP_STRING([--enable-dri],
1224 [enable DRI modules @<:@default=enabled@:>@])],
1225 [enable_dri="$enableval"],
1226 [enable_dri=yes])
1227
1228 AC_ARG_ENABLE([gallium-extra-hud],
1229 [AS_HELP_STRING([--enable-gallium-extra-hud],
1230 [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1231 [enable_gallium_extra_hud="$enableval"],
1232 [enable_gallium_extra_hud=no])
1233 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1234 if test "x$enable_gallium_extra_hud" = xyes ; then
1235 DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1236 fi
1237
1238 #TODO: no pkgconfig .pc available for libsensors.
1239 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1240 AC_ARG_ENABLE([lmsensors],
1241 [AS_HELP_STRING([--enable-lmsensors],
1242 [enable HUD lmsensor support @<:@default=disabled@:>@])],
1243 [enable_lmsensors="$enableval"],
1244 [enable_lmsensors=no])
1245 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1246 if test "x$enable_lmsensors" = xyes ; then
1247 DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1248 LIBSENSORS_LIBS="-lsensors"
1249 else
1250 LIBSENSORS_LIBS=""
1251 fi
1252 AC_SUBST(LIBSENSORS_LIBS)
1253
1254 case "$host_os" in
1255 linux*)
1256 dri3_default=yes
1257 ;;
1258 *)
1259 dri3_default=no
1260 ;;
1261 esac
1262
1263 if test "x$enable_dri" = xno; then
1264 dri3_default=no
1265 fi
1266
1267 AC_ARG_ENABLE([dri3],
1268 [AS_HELP_STRING([--enable-dri3],
1269 [enable DRI3 @<:@default=auto@:>@])],
1270 [enable_dri3="$enableval"],
1271 [enable_dri3="$dri3_default"])
1272 AC_ARG_ENABLE([glx],
1273 [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1274 [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1275 [enable_glx="$enableval"],
1276 [enable_glx=yes])
1277 AC_ARG_ENABLE([osmesa],
1278 [AS_HELP_STRING([--enable-osmesa],
1279 [enable OSMesa library @<:@default=disabled@:>@])],
1280 [enable_osmesa="$enableval"],
1281 [enable_osmesa=no])
1282 AC_ARG_ENABLE([gallium-osmesa],
1283 [AS_HELP_STRING([--enable-gallium-osmesa],
1284 [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1285 [enable_gallium_osmesa="$enableval"],
1286 [enable_gallium_osmesa=no])
1287 AC_ARG_ENABLE([egl],
1288 [AS_HELP_STRING([--disable-egl],
1289 [disable EGL library @<:@default=enabled@:>@])],
1290 [enable_egl="$enableval"],
1291 [enable_egl=yes])
1292
1293 AC_ARG_ENABLE([xa],
1294 [AS_HELP_STRING([--enable-xa],
1295 [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1296 [enable_xa="$enableval"],
1297 [enable_xa=no])
1298 AC_ARG_ENABLE([gbm],
1299 [AS_HELP_STRING([--enable-gbm],
1300 [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1301 [enable_gbm="$enableval"],
1302 [case "$host_os" in
1303 cygwin* | darwin*)
1304 enable_gbm=no
1305 ;;
1306 *)
1307 enable_gbm=yes
1308 ;;
1309 esac])
1310 AC_ARG_ENABLE([nine],
1311 [AS_HELP_STRING([--enable-nine],
1312 [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1313 [enable_nine="$enableval"],
1314 [enable_nine=no])
1315
1316 AC_ARG_ENABLE([xvmc],
1317 [AS_HELP_STRING([--enable-xvmc],
1318 [enable xvmc library @<:@default=auto@:>@])],
1319 [enable_xvmc="$enableval"],
1320 [enable_xvmc=auto])
1321 AC_ARG_ENABLE([vdpau],
1322 [AS_HELP_STRING([--enable-vdpau],
1323 [enable vdpau library @<:@default=auto@:>@])],
1324 [enable_vdpau="$enableval"],
1325 [enable_vdpau=auto])
1326 AC_ARG_ENABLE([omx],
1327 [AS_HELP_STRING([--enable-omx],
1328 [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1329 [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1330 [])
1331 AC_ARG_ENABLE([omx-bellagio],
1332 [AS_HELP_STRING([--enable-omx-bellagio],
1333 [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1334 [enable_omx_bellagio="$enableval"],
1335 [enable_omx_bellagio=no])
1336 AC_ARG_ENABLE([omx-tizonia],
1337 [AS_HELP_STRING([--enable-omx-tizonia],
1338 [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1339 [enable_omx_tizonia="$enableval"],
1340 [enable_omx_tizonia=no])
1341 AC_ARG_ENABLE([va],
1342 [AS_HELP_STRING([--enable-va],
1343 [enable va library @<:@default=auto@:>@])],
1344 [enable_va="$enableval"],
1345 [enable_va=auto])
1346 AC_ARG_ENABLE([opencl],
1347 [AS_HELP_STRING([--enable-opencl],
1348 [enable OpenCL library @<:@default=disabled@:>@])],
1349 [enable_opencl="$enableval"],
1350 [enable_opencl=no])
1351 AC_ARG_ENABLE([opencl_icd],
1352 [AS_HELP_STRING([--enable-opencl-icd],
1353 [Build an OpenCL ICD library to be loaded by an ICD implementation
1354 @<:@default=enabled@:>@])],
1355 [enable_opencl_icd="$enableval"],
1356 [enable_opencl_icd=yes])
1357
1358 AC_ARG_ENABLE([gallium-tests],
1359 [AS_HELP_STRING([--enable-gallium-tests],
1360 [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1361 [enable_gallium_tests="$enableval"],
1362 [enable_gallium_tests=no])
1363
1364 # Option for Gallium drivers
1365
1366 # Keep this in sync with the --with-gallium-drivers help string default value
1367 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1368
1369 AC_ARG_WITH([gallium-drivers],
1370 [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1371 [comma delimited Gallium drivers list, e.g.
1372 "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1373 @<:@default=r300,r600,svga,swrast@:>@])],
1374 [with_gallium_drivers="$withval"],
1375 [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1376
1377 # Doing '--without-gallium-drivers' will set this variable to 'no'. Clear it
1378 # here so that the script doesn't choke on an unknown driver name later.
1379 case "$with_gallium_drivers" in
1380 yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1381 no) with_gallium_drivers='' ;;
1382 esac
1383
1384 if test "x$enable_opengl" = xno -a \
1385 "x$enable_gles1" = xno -a \
1386 "x$enable_gles2" = xno -a \
1387 "x$enable_nine" = xno -a \
1388 "x$enable_xa" = xno -a \
1389 "x$enable_xvmc" = xno -a \
1390 "x$enable_vdpau" = xno -a \
1391 "x$enable_omx_bellagio" = xno -a \
1392 "x$enable_omx_tizonia" = xno -a \
1393 "x$enable_va" = xno -a \
1394 "x$enable_opencl" = xno; then
1395 AC_MSG_ERROR([at least one API should be enabled])
1396 fi
1397
1398 if test "x$enable_omx_bellagio" = xyes -a \
1399 "x$enable_omx_tizonia" = xyes; then
1400 AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1401 fi
1402
1403 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1404 if test "x$enable_opengl" = xno -a \
1405 "x$enable_gles1" = xyes; then
1406 AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1407 fi
1408
1409 if test "x$enable_opengl" = xno -a \
1410 "x$enable_gles2" = xyes; then
1411 AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1412 fi
1413
1414 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1415 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1416 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1417 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1418 "x$enable_gles1" = xyes -o \
1419 "x$enable_gles2" = xyes)
1420 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1421 "x$enable_opengl" = xyes -o \
1422 "x$enable_gles1" = xyes -o \
1423 "x$enable_gles2" = xyes)
1424
1425 # Validate GLX options
1426 if test "x$enable_glx" = xyes; then
1427 if test "x$enable_dri" = xyes; then
1428 enable_glx=dri
1429 elif test -n "$with_gallium_drivers"; then
1430 enable_glx=gallium-xlib
1431 else
1432 enable_glx=xlib
1433 fi
1434 fi
1435 case "x$enable_glx" in
1436 xdri | xxlib | xgallium-xlib)
1437 # GLX requires OpenGL
1438 if test "x$enable_opengl" = xno; then
1439 AC_MSG_ERROR([GLX cannot be built without OpenGL])
1440 fi
1441
1442 # Check individual dependencies
1443 case "x$enable_glx" in
1444 xdri)
1445 if test "x$enable_dri" = xno; then
1446 AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1447 fi
1448 ;;
1449 xxlib)
1450 if test "x$enable_dri" = xyes; then
1451 AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1452 fi
1453 ;;
1454 xgallium-xlib )
1455 if test "x$enable_dri" = xyes; then
1456 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1457 fi
1458 if test -z "$with_gallium_drivers"; then
1459 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1460 fi
1461 ;;
1462 esac
1463 ;;
1464 xno)
1465 ;;
1466 *)
1467 AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1468 ;;
1469 esac
1470
1471 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1472 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1473 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1474 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1475
1476 DEFAULT_GL_LIB_NAME=GL
1477
1478 dnl
1479 dnl Libglvnd configuration
1480 dnl
1481 AC_ARG_ENABLE([libglvnd],
1482 [AS_HELP_STRING([--enable-libglvnd],
1483 [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1484 [enable_libglvnd="$enableval"],
1485 [enable_libglvnd=no])
1486 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1487
1488 if test "x$enable_libglvnd" = xyes ; then
1489 case "x$enable_glx" in
1490 xxlib | xgallium-xlib )
1491 AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1492 ;;
1493 esac
1494
1495 PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1496 LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1497 AC_SUBST([LIBGLVND_DATADIR])
1498
1499 DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1500 DEFAULT_GL_LIB_NAME=GLX_mesa
1501
1502 if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1503 AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1504 fi
1505 fi
1506
1507 AC_ARG_WITH([gl-lib-name],
1508 [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1509 [specify GL library name @<:@default=GL@:>@])],
1510 [AC_MSG_ERROR([--with-gl-lib-name is no longer supported. Rename the library manually if needed.])],
1511 [])
1512 AC_ARG_WITH([osmesa-lib-name],
1513 [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1514 [specify OSMesa library name @<:@default=OSMesa@:>@])],
1515 [AC_MSG_ERROR([--with-osmesa-lib-name is no longer supported. Rename the library manually if needed.])],
1516 [])
1517 GL_LIB="$DEFAULT_GL_LIB_NAME"
1518 OSMESA_LIB=OSMesa
1519
1520 dnl
1521 dnl Mangled Mesa support
1522 dnl
1523 AC_ARG_ENABLE([mangling],
1524 [AS_HELP_STRING([--enable-mangling],
1525 [enable mangled symbols and library name @<:@default=disabled@:>@])],
1526 [enable_mangling="${enableval}"],
1527 [enable_mangling=no]
1528 )
1529 if test "x${enable_mangling}" = "xyes" ; then
1530 if test "x$enable_libglvnd" = xyes; then
1531 AC_MSG_ERROR([Conflicting options --enable-mangling and --enable-libglvnd.])
1532 fi
1533 DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1534 GL_LIB="Mangled${GL_LIB}"
1535 OSMESA_LIB="Mangled${OSMESA_LIB}"
1536 fi
1537 AC_SUBST([GL_LIB])
1538 AC_SUBST([OSMESA_LIB])
1539
1540 dnl HACK when building glx + glvnd we ship gl.pc, despite that glvnd should do it
1541 dnl Thus we need to use GL as a DSO name.
1542 if test "x$enable_libglvnd" = xyes -a "x$enable_glx" != xno; then
1543 GL_PKGCONF_LIB="GL"
1544 else
1545 GL_PKGCONF_LIB="$GL_LIB"
1546 fi
1547 AC_SUBST([GL_PKGCONF_LIB])
1548
1549 # Check for libdrm
1550 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1551 [have_libdrm=yes], [have_libdrm=no])
1552 if test "x$have_libdrm" = xyes; then
1553 DEFINES="$DEFINES -DHAVE_LIBDRM"
1554 fi
1555
1556 require_libdrm() {
1557 if test "x$have_libdrm" != xyes; then
1558 AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1559 fi
1560 }
1561
1562
1563 # Select which platform-dependent DRI code gets built
1564 case "$host_os" in
1565 darwin*)
1566 dri_platform='apple' ;;
1567 cygwin*)
1568 dri_platform='windows' ;;
1569 gnu*)
1570 dri_platform='none' ;;
1571 *)
1572 dri_platform='drm' ;;
1573 esac
1574
1575 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1576 have_drisw_kms='yes'
1577 fi
1578
1579 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1580 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1581 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1582 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1583 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1584 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1585 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1586 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1587 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1588 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1589
1590 AC_ARG_ENABLE([shared-glapi],
1591 [AS_HELP_STRING([--enable-shared-glapi],
1592 [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1593 [enable_shared_glapi="$enableval"],
1594 [enable_shared_glapi=yes])
1595
1596 case "x$enable_opengl$enable_gles1$enable_gles2" in
1597 x*yes*yes*)
1598 if test "x$enable_shared_glapi" = xno; then
1599 AC_MSG_ERROR([shared GLAPI required when building two or more of
1600 the following APIs - opengl, gles1 gles2])
1601 fi
1602 ;;
1603 esac
1604
1605 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1606
1607 # Build the pipe-drivers as separate libraries/modules.
1608 # Do not touch this unless you know what you are doing.
1609 # XXX: Expose via configure option ?
1610 enable_shared_pipe_drivers=no
1611
1612 dnl
1613 dnl Driver specific build directories
1614 dnl
1615
1616 if test "x$enable_gallium_osmesa" = xyes; then
1617 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1618 AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1619 fi
1620 if test "x$enable_osmesa" = xyes; then
1621 AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1622 fi
1623 fi
1624
1625 require_dri_shared_libs_and_glapi() {
1626 if test "x$enable_static" = xyes; then
1627 AC_MSG_ERROR([$1 cannot be build as static library])
1628 fi
1629
1630 if test "x$enable_dri" != xyes; then
1631 # There is only a single backend which won't be build/used otherwise.
1632 # XXX: Revisit this as the egl/haiku is a thing.
1633 AC_MSG_ERROR([$1 requires --enable-dri])
1634 fi
1635
1636 if test "x$enable_shared_glapi" != xyes; then
1637 AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1638 fi
1639 }
1640
1641 if test "x$enable_dri" = xyes; then
1642 require_dri_shared_libs_and_glapi "DRI"
1643
1644 # not a hard requirement as swrast does not depend on it
1645 if test "x$have_libdrm" = xyes; then
1646 DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1647 fi
1648 fi
1649
1650 AC_ARG_ENABLE([driglx-direct],
1651 [AS_HELP_STRING([--disable-driglx-direct],
1652 [disable direct rendering in GLX and EGL for DRI \
1653 @<:@default=enabled@:>@])],
1654 [driglx_direct="$enableval"],
1655 [driglx_direct="yes"])
1656
1657 dnl
1658 dnl libGL configuration per driver
1659 dnl
1660 if test "x$enable_glx" != xno; then
1661 PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1662 fi
1663 case "x$enable_glx" in
1664 xxlib | xgallium-xlib)
1665 # Xlib-based GLX
1666 dri_modules="x11 xext xcb"
1667 PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1668 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1669 X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1670 GL_LIB_DEPS="$XLIBGL_LIBS"
1671 GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1672 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1673 ;;
1674 xdri)
1675 # DRI-based GLX
1676
1677 require_dri_shared_libs_and_glapi "GLX"
1678
1679 # find the DRI deps for libGL
1680 dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1681
1682 if test x"$driglx_direct" = xyes; then
1683 if test x"$dri_platform" = xdrm ; then
1684 DEFINES="$DEFINES -DGLX_USE_DRM"
1685 require_libdrm "Direct rendering"
1686
1687 PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1688 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1689
1690 if test x"$enable_dri" = xyes; then
1691 dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1692 fi
1693 fi
1694 if test x"$dri_platform" = xapple ; then
1695 DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1696 fi
1697 if test x"$dri_platform" = xwindows ; then
1698 DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1699 fi
1700 fi
1701
1702 # add xf86vidmode if available
1703 PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1704 if test "$HAVE_XF86VIDMODE" = yes ; then
1705 dri_modules="$dri_modules xxf86vm"
1706 fi
1707
1708 PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1709 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1710 X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1711 GL_LIB_DEPS="$DRIGL_LIBS"
1712
1713 # need DRM libs, $PTHREAD_LIBS, etc.
1714 GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1715 GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1716 ;;
1717 esac
1718
1719 # This is outside the case (above) so that it is invoked even for non-GLX
1720 # builds.
1721 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1722
1723 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1724 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1725 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1726 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1727
1728 AC_SUBST([X11_INCLUDES])
1729 AC_SUBST([GL_LIB_DEPS])
1730 AC_SUBST([GL_PC_REQ_PRIV])
1731 AC_SUBST([GL_PC_LIB_PRIV])
1732 AC_SUBST([GL_PC_CFLAGS])
1733 AC_SUBST([DRI_PC_REQ_PRIV])
1734 AC_SUBST([GLESv1_CM_LIB_DEPS])
1735 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1736 AC_SUBST([GLESv2_LIB_DEPS])
1737 AC_SUBST([GLESv2_PC_LIB_PRIV])
1738
1739 AC_SUBST([HAVE_XF86VIDMODE])
1740
1741 dnl
1742 dnl More GLX setup
1743 dnl
1744 case "x$enable_glx" in
1745 xxlib | xgallium-xlib)
1746 DEFINES="$DEFINES -DUSE_XSHM"
1747 ;;
1748 xdri)
1749 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1750 if test "x$driglx_direct" = xyes; then
1751 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1752 fi
1753 ;;
1754 esac
1755
1756 dnl
1757 dnl TLS detection
1758 dnl
1759
1760 AC_ARG_ENABLE([glx-tls],
1761 [AS_HELP_STRING([--enable-glx-tls],
1762 [enable TLS support in GLX @<:@default=enabled@:>@])],
1763 [GLX_USE_TLS="$enableval"],
1764 [GLX_USE_TLS=yes])
1765 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1766
1767 if test "x$GLX_USE_TLS" = xyes; then
1768 DEFINES="$DEFINES -DGLX_USE_TLS"
1769 fi
1770
1771 dnl Read-only text section on x86 hardened platforms
1772 AC_ARG_ENABLE([glx-read-only-text],
1773 [AS_HELP_STRING([--enable-glx-read-only-text],
1774 [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1775 [enable_glx_read_only_text="$enableval"],
1776 [enable_glx_read_only_text=no])
1777 if test "x$enable_glx_read_only_text" = xyes; then
1778 DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1779 fi
1780
1781 dnl
1782 dnl DEPRECATED: EGL Platforms configuration
1783 dnl
1784 AC_ARG_WITH([egl-platforms],
1785 [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1786 [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1787 [with_egl_platforms="$withval"],
1788 [with_egl_platforms=auto])
1789
1790 if test "x$with_egl_platforms" = xauto; then
1791 with_egl_platforms="x11,surfaceless"
1792 if test "x$enable_gbm" = xyes; then
1793 with_egl_platforms="$with_egl_platforms,drm"
1794 fi
1795 else
1796 AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1797 fi
1798
1799 dnl
1800 dnl Platforms configuration
1801 dnl
1802 AC_ARG_WITH([platforms],
1803 [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1804 [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1805 "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1806 [with_platforms="$withval"],
1807 [with_platforms=auto])
1808
1809 # Reuse the autodetection rather than duplicating it.
1810 if test "x$with_platforms" = xauto; then
1811 with_platforms=$with_egl_platforms
1812 fi
1813
1814 # Do per platform setups and checks
1815 platforms=`IFS=', '; echo $with_platforms`
1816 for plat in $platforms; do
1817 case "$plat" in
1818 wayland)
1819
1820 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1821 PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1822 PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1823 if test "x$enable_egl" = xyes; then
1824 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1825 fi
1826 WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1827
1828 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1829 WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1830 WAYLAND_SCANNER='')
1831 PKG_CHECK_EXISTS([wayland-scanner >= 1.15],
1832 AC_SUBST(SCANNER_ARG, 'private-code'),
1833 AC_SUBST(SCANNER_ARG, 'code'))
1834
1835 if test "x$WAYLAND_SCANNER" = x; then
1836 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1837 fi
1838
1839 if test "x$WAYLAND_SCANNER" = "x:"; then
1840 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1841 fi
1842 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1843 ;;
1844
1845 x11)
1846 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1847 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1848 ;;
1849
1850 drm)
1851 test "x$enable_gbm" = "xno" &&
1852 AC_MSG_ERROR([EGL platform drm needs gbm])
1853 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1854 ;;
1855
1856 surfaceless)
1857 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1858 ;;
1859
1860 android)
1861 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1862 if test -n "$with_gallium_drivers"; then
1863 PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1864 fi
1865 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1866 ;;
1867
1868 *)
1869 AC_MSG_ERROR([platform '$plat' does not exist])
1870 ;;
1871 esac
1872
1873 case "$plat" in
1874 wayland|drm|surfaceless)
1875 require_libdrm "Platform $plat"
1876 ;;
1877 esac
1878 done
1879 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1880
1881 if test "x$enable_glx" != xno; then
1882 if ! echo "$platforms" | grep -q 'x11'; then
1883 AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1884 fi
1885 fi
1886
1887 if test x"$enable_dri3" = xyes; then
1888 DEFINES="$DEFINES -DHAVE_DRI3"
1889
1890 dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1891 PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1892 dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1893 PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1894
1895 if test "x$have_dri3_modifiers" == xyes; then
1896 DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1897 fi
1898 fi
1899
1900
1901 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1902 have_xlease=yes
1903 else
1904 have_xlease=no
1905 fi
1906
1907 if test x"$have_xlease" = xyes; then
1908 randr_modules="x11-xcb xcb-randr"
1909 PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1910 xlib_randr_modules="xrandr"
1911 PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1912 fi
1913
1914 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1915 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1916 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1917 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1918 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1919
1920 AC_ARG_ENABLE(xlib-lease,
1921 [AS_HELP_STRING([--enable-xlib-lease]
1922 [enable VK_acquire_xlib_display using X leases])],
1923 [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1924 case "x$enable_xlib_lease" in
1925 xyes)
1926 ;;
1927 xno)
1928 ;;
1929 *)
1930 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1931 enable_xlib_lease=yes
1932 else
1933 enable_xlib_lease=no
1934 fi
1935 esac
1936
1937 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1938
1939 dnl
1940 dnl More DRI setup
1941 dnl
1942 dnl Directory for DRI drivers
1943 AC_ARG_WITH([dri-driverdir],
1944 [AS_HELP_STRING([--with-dri-driverdir=DIR],
1945 [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1946 [DRI_DRIVER_INSTALL_DIR="$withval"],
1947 [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1948 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1949 dnl Extra search path for DRI drivers
1950 AC_ARG_WITH([dri-searchpath],
1951 [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1952 [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1953 [DRI_DRIVER_SEARCH_DIR="$withval"],
1954 [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1955 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1956 dnl Which drivers to build - default is chosen by platform
1957 AC_ARG_WITH([dri-drivers],
1958 [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1959 [comma delimited classic DRI drivers list, e.g.
1960 "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1961 [with_dri_drivers="$withval"],
1962 [with_dri_drivers=auto])
1963
1964 if test "x$with_dri_drivers" = xauto; then
1965 if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1966 with_dri_drivers="yes"
1967 else
1968 with_dri_drivers="no"
1969 fi
1970 fi
1971 if test "x$with_dri_drivers" = xno; then
1972 with_dri_drivers=''
1973 fi
1974
1975 # Check for expat
1976 PKG_CHECK_MODULES([EXPAT], [expat],,
1977 [PKG_CHECK_MODULES([EXPAT], [expat21])]
1978 )
1979
1980 dnl If $with_dri_drivers is yes, drivers will be added through
1981 dnl platform checks. Set DEFINES and LIB_DEPS
1982 if test "x$enable_dri" = xyes; then
1983 # Platform specific settings and drivers to build
1984 case "$host_os" in
1985 linux*)
1986 case "$host_cpu" in
1987 powerpc* | sparc*)
1988 # Build only the drivers for cards that exist on PowerPC/sparc
1989 if test "x$with_dri_drivers" = "xyes"; then
1990 with_dri_drivers="r200 radeon swrast"
1991 fi
1992 ;;
1993 esac
1994 ;;
1995 cygwin*)
1996 if test "x$with_dri_drivers" = "xyes"; then
1997 with_dri_drivers="swrast"
1998 fi
1999 ;;
2000 darwin*)
2001 DEFINES="$DEFINES -DBUILDING_MESA"
2002 if test "x$with_dri_drivers" = "xyes"; then
2003 with_dri_drivers="swrast"
2004 fi
2005 ;;
2006 esac
2007
2008 # default drivers
2009 if test "x$with_dri_drivers" = "xyes"; then
2010 with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
2011 fi
2012
2013 # put all the necessary libs together
2014 DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
2015 fi
2016
2017 AC_SUBST([DRI_LIB_DEPS])
2018
2019 DRI_DIRS=''
2020 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
2021 if test -n "$with_dri_drivers"; then
2022 if test "x$enable_opengl" != xyes; then
2023 AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2024 fi
2025
2026 dri_drivers=`IFS=', '; echo $with_dri_drivers`
2027 for driver in $dri_drivers; do
2028 DRI_DIRS="$DRI_DIRS $driver"
2029 case "x$driver" in
2030 xi915)
2031 require_libdrm "i915"
2032 HAVE_I915_DRI=yes
2033 PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2034 ;;
2035 xi965)
2036 require_libdrm "i965"
2037 HAVE_I965_DRI=yes
2038 ;;
2039 xnouveau)
2040 require_libdrm "nouveau"
2041 HAVE_NOUVEAU_DRI=yes
2042 PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2043 ;;
2044 xradeon)
2045 require_libdrm "radeon"
2046 HAVE_RADEON_DRI=yes;
2047 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2048 ;;
2049 xr200)
2050 require_libdrm "r200"
2051 HAVE_R200_DRI=yes
2052 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2053 ;;
2054 xswrast)
2055 HAVE_SWRAST_DRI=yes
2056 ;;
2057 *)
2058 AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2059 ;;
2060 esac
2061 done
2062 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2063 fi
2064
2065
2066 dnl
2067 dnl Gallium LLVM
2068 dnl Deprecated: kept for backwards compatibility
2069 dnl
2070 AC_ARG_ENABLE([gallium-llvm],
2071 [AS_HELP_STRING([--enable-gallium-llvm],
2072 [DEPRECATED: use --enable-llvm instead])],
2073 [enable_gallium_llvm="$enableval"],
2074 [enable_gallium_llvm=auto])
2075
2076 if test "x$enable_gallium_llvm" != xauto; then
2077 AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2078 enable_llvm=$enable_gallium_llvm
2079 fi
2080
2081 dnl
2082 dnl LLVM
2083 dnl
2084 AC_ARG_ENABLE([llvm],
2085 [AS_HELP_STRING([--enable-llvm],
2086 [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2087 [enable_llvm="$enableval"],
2088 [enable_llvm=auto])
2089
2090 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2091 if test "x$FOUND_LLVM" = xyes; then
2092 case "$host_cpu" in
2093 i*86|x86_64|amd64) enable_llvm=yes;;
2094 *) enable_llvm=no;;
2095 esac
2096 else
2097 enable_llvm=no
2098 fi
2099 fi
2100
2101 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2102 AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2103 fi
2104
2105 #
2106 # Vulkan driver configuration
2107 #
2108
2109 AC_ARG_WITH([vulkan-drivers],
2110 [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2111 [comma delimited Vulkan drivers list, e.g.
2112 "intel,radeon"
2113 @<:@default=no@:>@])],
2114 [with_vulkan_drivers="$withval"],
2115 [with_vulkan_drivers="no"])
2116
2117 # Doing '--without-vulkan-drivers' will set this variable to 'no'. Clear it
2118 # here so that the script doesn't choke on an unknown driver name later.
2119 case "x$with_vulkan_drivers" in
2120 xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2121 xno) with_vulkan_drivers='' ;;
2122 esac
2123
2124 AC_ARG_WITH([vulkan-icddir],
2125 [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2126 [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2127 [VULKAN_ICD_INSTALL_DIR="$withval"],
2128 [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2129 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2130
2131 require_x11_dri3() {
2132 if echo "$platforms" | grep -q 'x11'; then
2133 if test "x$enable_dri3" != xyes; then
2134 AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2135 fi
2136 fi
2137 }
2138
2139 if test -n "$with_vulkan_drivers"; then
2140 if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2141 AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2142 fi
2143
2144 VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2145 for driver in $VULKAN_DRIVERS; do
2146 case "x$driver" in
2147 xintel)
2148 require_libdrm "ANV"
2149 require_x11_dri3 "ANV"
2150 HAVE_INTEL_VULKAN=yes
2151 ;;
2152 xradeon)
2153 require_libdrm "radv"
2154 PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2155 radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2156 require_x11_dri3 "radv"
2157 if test "x$acv_mako_found" = xno; then
2158 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2159 fi
2160 HAVE_RADEON_VULKAN=yes
2161 ;;
2162 *)
2163 AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2164 ;;
2165 esac
2166 done
2167 VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2168 fi
2169
2170
2171 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2172 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2173 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2174 "x$enable_osmesa" = xyes -o \
2175 -n "$DRI_DIRS")
2176
2177 dnl
2178 dnl OSMesa configuration
2179 dnl
2180
2181 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2182 AC_ARG_WITH([osmesa-bits],
2183 [AS_HELP_STRING([--with-osmesa-bits=BITS],
2184 [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2185 [osmesa_bits="$withval"],
2186 [osmesa_bits=8])
2187 if test "x$osmesa_bits" != x8; then
2188 if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2189 AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2190 osmesa_bits=8
2191 fi
2192 fi
2193 case "x$osmesa_bits" in
2194 x8)
2195 OSMESA_LIB="${OSMESA_LIB}"
2196 ;;
2197 x16|x32)
2198 OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2199 DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2200 ;;
2201 *)
2202 AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2203 ;;
2204 esac
2205
2206 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2207 # only link libraries with osmesa if shared
2208 if test "$enable_static" = no; then
2209 OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2210 else
2211 OSMESA_LIB_DEPS=""
2212 fi
2213 OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2214 fi
2215
2216 AC_SUBST([OSMESA_LIB_DEPS])
2217 AC_SUBST([OSMESA_PC_REQ])
2218 AC_SUBST([OSMESA_PC_LIB_PRIV])
2219
2220 dnl
2221 dnl gbm configuration
2222 dnl
2223 if test "x$enable_gbm" = xyes; then
2224 require_dri_shared_libs_and_glapi "gbm"
2225 fi
2226 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2227 # FINISHME: GBM has a number of dependencies which we should add below
2228 GBM_PC_REQ_PRIV=""
2229 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2230 AC_SUBST([GBM_PC_REQ_PRIV])
2231 AC_SUBST([GBM_PC_LIB_PRIV])
2232
2233 dnl
2234 dnl EGL configuration
2235 dnl
2236
2237 if test "x$enable_egl" = xyes; then
2238 EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2239
2240 AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2241
2242 require_dri_shared_libs_and_glapi "egl"
2243 fi
2244 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2245 AC_SUBST([EGL_LIB_DEPS])
2246
2247 gallium_st="mesa"
2248
2249 dnl
2250 dnl XA configuration
2251 dnl
2252 if test "x$enable_xa" = xyes; then
2253 if test "x$with_gallium_drivers" = xswrast; then
2254 AC_MSG_ERROR([
2255 Building xa requires at least one non swrast gallium driver.
2256 If you are looking to use libxatracker.so with the VMware driver,
2257 make sure to include svga in the gallium drivers list, apart from
2258 enabling XA.
2259 Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2260 fi
2261 gallium_st="$gallium_st xa"
2262 fi
2263 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2264
2265 if echo $platforms | grep -q "x11"; then
2266 have_xvmc_platform=yes
2267 else
2268 have_xvmc_platform=no
2269 fi
2270
2271 if echo $platforms | grep -q "x11"; then
2272 have_vdpau_platform=yes
2273 else
2274 have_vdpau_platform=no
2275 fi
2276
2277 if echo $platforms | egrep -q "x11|drm"; then
2278 have_omx_platform=yes
2279 else
2280 have_omx_platform=no
2281 fi
2282
2283 if echo $platforms | egrep -q "x11|drm|wayland"; then
2284 have_va_platform=yes
2285 else
2286 have_va_platform=no
2287 fi
2288
2289 dnl
2290 dnl Gallium G3DVL configuration
2291 dnl
2292 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2293 if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2294 PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2295 fi
2296
2297 if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2298 PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2299 fi
2300
2301 if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2302 PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2303 fi
2304
2305 if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2306 PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2307 fi
2308
2309 if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2310 PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2311 fi
2312 fi
2313
2314 if test "x$enable_dri" = xyes -o \
2315 "x$enable_xvmc" = xyes -o \
2316 "x$enable_vdpau" = xyes -o \
2317 "x$enable_omx_bellagio" = xyes -o \
2318 "x$enable_omx_tizonia" = xyes -o \
2319 "x$enable_va" = xyes; then
2320 need_gallium_vl=yes
2321 fi
2322 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2323
2324 if test "x$enable_xvmc" = xyes -o \
2325 "x$enable_vdpau" = xyes -o \
2326 "x$enable_omx_bellagio" = xyes -o \
2327 "x$enable_omx_tizonia" = xyes -o \
2328 "x$enable_va" = xyes; then
2329 if echo $platforms | grep -q "x11"; then
2330 PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2331 fi
2332 need_gallium_vl_winsys=yes
2333 fi
2334 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2335
2336 if test "x$enable_xvmc" = xyes; then
2337 if test "x$have_xvmc_platform" != xyes; then
2338 AC_MSG_ERROR([XVMC requires the x11 platforms])
2339 fi
2340 PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2341 gallium_st="$gallium_st xvmc"
2342 fi
2343 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2344
2345 if test "x$enable_vdpau" = xyes; then
2346 if test "x$have_vdpau_platform" != xyes; then
2347 AC_MSG_ERROR([VDPAU requires the x11 platforms])
2348 fi
2349 PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2350 gallium_st="$gallium_st vdpau"
2351 DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2352 fi
2353 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2354
2355 if test "x$enable_omx_bellagio" = xyes; then
2356 if test "x$have_omx_platform" != xyes; then
2357 AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2358 fi
2359 PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2360 gallium_st="$gallium_st omx_bellagio"
2361 AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2362 else
2363 AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2364 fi
2365 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2366
2367 if test "x$enable_omx_tizonia" = xyes; then
2368 if test "x$have_omx_platform" != xyes; then
2369 AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2370 fi
2371 PKG_CHECK_MODULES([OMX_TIZONIA],
2372 [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2373 tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2374 libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2375 gallium_st="$gallium_st omx_tizonia"
2376 AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2377 else
2378 AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2379 fi
2380 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2381
2382 if test "x$enable_va" = xyes; then
2383 if test "x$have_va_platform" != xyes; then
2384 AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2385 fi
2386 PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2387 gallium_st="$gallium_st va"
2388 fi
2389 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2390
2391 dnl
2392 dnl Nine Direct3D9 configuration
2393 dnl
2394 if test "x$enable_nine" = xyes; then
2395 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2396 AC_MSG_ERROR([nine requires the gallium swrast driver])
2397 fi
2398 if test "x$with_gallium_drivers" = xswrast; then
2399 AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2400 fi
2401 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2402 AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2403 fi
2404
2405 if test "x$enable_dri3" = xno; then
2406 AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2407 fi
2408
2409 gallium_st="$gallium_st nine"
2410 fi
2411 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2412
2413 dnl
2414 dnl OpenCL configuration
2415 dnl
2416
2417 AC_ARG_WITH([clang-libdir],
2418 [AS_HELP_STRING([--with-clang-libdir],
2419 [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2420 [CLANG_LIBDIR="$withval"],
2421 [CLANG_LIBDIR=''])
2422
2423 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2424
2425 if test "x$enable_opencl" = xyes; then
2426 if test -z "$with_gallium_drivers"; then
2427 AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2428 fi
2429
2430 if test "x$HAVE_CXX11" != "xyes"; then
2431 AC_MSG_ERROR([clover requires c++11 support])
2432 fi
2433
2434 if test "x$have_libclc" = xno; then
2435 AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2436 Make sure the directory containing libclc.pc is specified in your
2437 PKG_CONFIG_PATH environment variable.
2438 By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2439 else
2440 LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2441 LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2442 AC_SUBST([LIBCLC_INCLUDEDIR])
2443 AC_SUBST([LIBCLC_LIBEXECDIR])
2444 fi
2445
2446 gallium_st="$gallium_st clover"
2447
2448 if test "x$enable_opencl_icd" = xyes; then
2449 OPENCL_LIBNAME="MesaOpenCL"
2450 else
2451 OPENCL_LIBNAME="OpenCL"
2452 fi
2453
2454 if test "x$have_libelf" != xyes; then
2455 AC_MSG_ERROR([Clover requires libelf])
2456 fi
2457
2458 if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2459 altivec_enabled=no
2460 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2461 #if !defined(__VEC__) || !defined(__ALTIVEC__)
2462 #error "AltiVec not enabled"
2463 #endif
2464 ])], altivec_enabled=yes)
2465
2466 if test "$altivec_enabled" = yes; then
2467 CLOVER_STD_OVERRIDE="-std=gnu++11"
2468 fi
2469 AC_SUBST([CLOVER_STD_OVERRIDE])
2470 fi
2471
2472 llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2473
2474 llvm_add_default_components "opencl"
2475 llvm_add_component "all-targets" "opencl"
2476 llvm_add_component "coverage" "opencl"
2477 llvm_add_component "linker" "opencl"
2478 llvm_add_component "instrumentation" "opencl"
2479 llvm_add_component "ipo" "opencl"
2480 llvm_add_component "irreader" "opencl"
2481 llvm_add_component "lto" "opencl"
2482 llvm_add_component "option" "opencl"
2483 llvm_add_component "objcarcopts" "opencl"
2484 llvm_add_component "profiledata" "opencl"
2485 llvm_add_optional_component "coroutines" "opencl"
2486
2487 dnl Check for Clang internal headers
2488 if test -z "$CLANG_LIBDIR"; then
2489 CLANG_LIBDIR=${LLVM_LIBDIR}
2490 fi
2491 CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2492 AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2493 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2494 fi
2495 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2496 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2497 AC_SUBST([OPENCL_LIBNAME])
2498 AC_SUBST([CLANG_RESOURCE_DIR])
2499
2500 dnl
2501 dnl Gallium configuration
2502 dnl
2503 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2504
2505 # libEGL wants to default to the first platform specified in
2506 # ./configure. parse that here.
2507 if test "x$platforms" != "x"; then
2508 FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2509 EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2510 else
2511 EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2512 fi
2513
2514 AC_SUBST([EGL_NATIVE_PLATFORM])
2515 AC_SUBST([EGL_CFLAGS])
2516
2517 # If we don't have the X11 platform, set this define so we don't try to include
2518 # the X11 headers.
2519 if ! echo "$platforms" | grep -q 'x11'; then
2520 DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2521 GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2522 fi
2523
2524 dnl Directory for XVMC libs
2525 AC_ARG_WITH([xvmc-libdir],
2526 [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2527 [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2528 [XVMC_LIB_INSTALL_DIR="$withval"],
2529 [XVMC_LIB_INSTALL_DIR='${libdir}'])
2530 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2531
2532 dnl
2533 dnl Gallium Tests
2534 dnl
2535 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2536
2537 dnl Directory for VDPAU libs
2538 AC_ARG_WITH([vdpau-libdir],
2539 [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2540 [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2541 [VDPAU_LIB_INSTALL_DIR="$withval"],
2542 [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2543 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2544
2545 dnl Directory for OMX_BELLAGIO libs
2546
2547 AC_ARG_WITH([omx-bellagio-libdir],
2548 [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2549 [directory for the OMX_BELLAGIO libraries])],
2550 [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2551 [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2552 $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2553 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2554
2555 dnl Directory for OMX_TIZONIA libs
2556
2557 AC_ARG_WITH([omx-tizonia-libdir],
2558 [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2559 [directory for the OMX_TIZONIA libraries])],
2560 [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2561 [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2562 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2563
2564 dnl Directory for VA libs
2565
2566 AC_ARG_WITH([va-libdir],
2567 [AS_HELP_STRING([--with-va-libdir=DIR],
2568 [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2569 [VA_LIB_INSTALL_DIR="$withval"],
2570 [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2571 AC_SUBST([VA_LIB_INSTALL_DIR])
2572
2573 AC_ARG_WITH([d3d-libdir],
2574 [AS_HELP_STRING([--with-d3d-libdir=DIR],
2575 [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2576 [D3D_DRIVER_INSTALL_DIR="$withval"],
2577 [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2578 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2579
2580 dnl Architectures to build SWR library for
2581
2582 AC_ARG_WITH([swr-archs],
2583 [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2584 [comma delimited swr architectures list, e.g.
2585 "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2586 [with_swr_archs="$withval"],
2587 [with_swr_archs="avx,avx2"])
2588
2589 dnl
2590 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2591 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2592 dnl architectures.
2593 dnl
2594 r300_require_llvm() {
2595 case "$host" in *gnux32) return;; esac
2596 case "$host_cpu" in
2597 i*86|x86_64|amd64) require_llvm $1
2598 ;;
2599 esac
2600 }
2601
2602 dnl
2603 dnl DRM is needed by X, Wayland, and offscreen rendering.
2604 dnl Surfaceless is an alternative for the last one.
2605 dnl
2606 require_basic_egl() {
2607 case "$with_platforms" in
2608 *drm*|*surfaceless*|*android*)
2609 ;;
2610 *)
2611 AC_MSG_ERROR([$1 requires one of these:
2612 1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2613 2) --with-platforms=surfaceless (offscreen only)
2614 3) --with-platforms=android (Android only)
2615 Recommended options: drm,x11])
2616 ;;
2617 esac
2618 }
2619
2620 swr_require_cxx_feature_flags() {
2621 feature_name="$1"
2622 preprocessor_test="$2"
2623 option_list="$3"
2624 output_var="$4"
2625
2626 AC_MSG_CHECKING([whether $CXX supports $feature_name])
2627 AC_LANG_PUSH([C++])
2628 save_CXXFLAGS="$CXXFLAGS"
2629 save_IFS="$IFS"
2630 IFS=","
2631 found=0
2632 for opts in $option_list
2633 do
2634 unset IFS
2635 CXXFLAGS="$opts $save_CXXFLAGS"
2636 AC_COMPILE_IFELSE(
2637 [AC_LANG_PROGRAM(
2638 [ #if !($preprocessor_test)
2639 #error
2640 #endif
2641 ])],
2642 [found=1; break],
2643 [])
2644 IFS=","
2645 done
2646 IFS="$save_IFS"
2647 CXXFLAGS="$save_CXXFLAGS"
2648 AC_LANG_POP([C++])
2649 if test $found -eq 1; then
2650 AC_MSG_RESULT([$opts])
2651 eval "$output_var=\$opts"
2652 return 0
2653 fi
2654 AC_MSG_RESULT([no])
2655 AC_MSG_ERROR([swr requires $feature_name support])
2656 return 1
2657 }
2658
2659 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2660 if test -n "$with_gallium_drivers"; then
2661 gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2662 for driver in $gallium_drivers; do
2663 case "x$driver" in
2664 xsvga)
2665 HAVE_GALLIUM_SVGA=yes
2666 require_libdrm "svga"
2667 ;;
2668 xi915)
2669 HAVE_GALLIUM_I915=yes
2670 PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2671 require_libdrm "Gallium i915"
2672 ;;
2673 xr300)
2674 HAVE_GALLIUM_R300=yes
2675 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2676 require_libdrm "r300"
2677 r300_require_llvm "r300"
2678 ;;
2679 xr600)
2680 HAVE_GALLIUM_R600=yes
2681 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2682 require_libdrm "r600"
2683 if test "x$enable_llvm" = xyes; then
2684 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2685
2686 llvm_add_component "asmparser" "r600"
2687 llvm_add_component "bitreader" "r600"
2688 fi
2689 ;;
2690 xradeonsi)
2691 HAVE_GALLIUM_RADEONSI=yes
2692 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2693 PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2694 require_libdrm "radeonsi"
2695 radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2696 if test "x$enable_egl" = xyes; then
2697 require_basic_egl "radeonsi"
2698 fi
2699 ;;
2700 xnouveau)
2701 HAVE_GALLIUM_NOUVEAU=yes
2702 PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2703 require_libdrm "nouveau"
2704 ;;
2705 xfreedreno)
2706 HAVE_GALLIUM_FREEDRENO=yes
2707 PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2708 require_libdrm "freedreno"
2709 ;;
2710 xetnaviv)
2711 HAVE_GALLIUM_ETNAVIV=yes
2712 PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2713 require_libdrm "etnaviv"
2714 ;;
2715 ximx)
2716 HAVE_GALLIUM_IMX=yes
2717 ;;
2718 xtegra)
2719 HAVE_GALLIUM_TEGRA=yes
2720 require_libdrm "tegra"
2721 ;;
2722 xswrast)
2723 HAVE_GALLIUM_SOFTPIPE=yes
2724 if test "x$enable_llvm" = xyes; then
2725 HAVE_GALLIUM_LLVMPIPE=yes
2726 fi
2727 ;;
2728 xswr)
2729 llvm_require_version $LLVM_REQUIRED_SWR "swr"
2730
2731 if test "x$HAVE_CXX11" != "xyes"; then
2732 AC_MSG_ERROR([swr requires c++11 support])
2733 fi
2734
2735 swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2736 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2737 SWR_AVX_CXXFLAGS
2738 AC_SUBST([SWR_AVX_CXXFLAGS])
2739
2740 swr_archs=`IFS=', '; echo $with_swr_archs`
2741 for arch in $swr_archs; do
2742 case "x$arch" in
2743 xavx)
2744 HAVE_SWR_AVX=yes
2745 ;;
2746 xavx2)
2747 swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2748 ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2749 SWR_AVX2_CXXFLAGS
2750 AC_SUBST([SWR_AVX2_CXXFLAGS])
2751 HAVE_SWR_AVX2=yes
2752 ;;
2753 xknl)
2754 swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2755 ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2756 SWR_KNL_CXXFLAGS
2757 AC_SUBST([SWR_KNL_CXXFLAGS])
2758 HAVE_SWR_KNL=yes
2759 ;;
2760 xskx)
2761 swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2762 ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2763 SWR_SKX_CXXFLAGS
2764 AC_SUBST([SWR_SKX_CXXFLAGS])
2765 HAVE_SWR_SKX=yes
2766 ;;
2767 *)
2768 AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2769 ;;
2770 esac
2771 done
2772
2773 if test "x$HAVE_SWR_AVX" != xyes -a \
2774 "x$HAVE_SWR_AVX2" != xyes -a \
2775 "x$HAVE_SWR_KNL" != xyes -a \
2776 "x$HAVE_SWR_SKX" != xyes; then
2777 AC_MSG_ERROR([swr enabled but no swr architectures selected])
2778 fi
2779
2780 # test if more than one swr arch configured
2781 if test `echo $swr_archs | wc -w` -eq 1; then
2782 HAVE_SWR_BUILTIN=yes
2783 fi
2784
2785 HAVE_GALLIUM_SWR=yes
2786 ;;
2787 xvc4)
2788 HAVE_GALLIUM_VC4=yes
2789 PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2790
2791 PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2792 [USE_VC4_SIMULATOR=yes;
2793 DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2794 [USE_VC4_SIMULATOR=no])
2795 ;;
2796 xv3d)
2797 HAVE_GALLIUM_V3D=yes
2798
2799 PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2800 [USE_V3D_SIMULATOR=yes;
2801 DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2802 [USE_V3D_SIMULATOR=no])
2803 ;;
2804 xpl111)
2805 HAVE_GALLIUM_PL111=yes
2806 ;;
2807 xvirgl)
2808 HAVE_GALLIUM_VIRGL=yes
2809 require_libdrm "virgl"
2810 if test "x$enable_egl" = xyes; then
2811 require_basic_egl "virgl"
2812 fi
2813 ;;
2814 *)
2815 AC_MSG_ERROR([Unknown Gallium driver: $driver])
2816 ;;
2817 esac
2818 done
2819 fi
2820
2821 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2822 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x6.0.0 -a \
2823 "x$LLVM_VERSION" != x6.0.1)
2824
2825 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2826 llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2827 llvm_add_default_components "gallium"
2828 fi
2829
2830 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2831 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2832 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2833 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2834 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2835
2836 dnl We need to validate some needed dependencies for renderonly drivers.
2837
2838 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes ; then
2839 AC_MSG_ERROR([Building with imx requires etnaviv])
2840 fi
2841
2842 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes ; then
2843 AC_MSG_ERROR([Building with pl111 requires vc4])
2844 fi
2845
2846 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2847 AC_MSG_ERROR([Building with tegra requires nouveau])
2848 fi
2849
2850 detect_old_buggy_llvm() {
2851 dnl llvm-config may not give the right answer when llvm is a built as a
2852 dnl single shared library, so we must work the library name out for
2853 dnl ourselves.
2854 dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2855 dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2856 LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2857 AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2858
2859 if test "x$llvm_have_one_so" = xyes; then
2860 dnl LLVM was built using auto*, so there is only one shared object.
2861 LLVM_LIBS="-l$LLVM_SO_NAME"
2862 else
2863 dnl If LLVM was built with CMake, there will be one shared object per
2864 dnl component.
2865 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2866 [AC_MSG_ERROR([Could not find llvm shared libraries:
2867 Please make sure you have built llvm with the --enable-shared option
2868 and that your llvm libraries are installed in $LLVM_LIBDIR
2869 If you have installed your llvm libraries to a different directory you
2870 can use the --with-llvm-prefix= configure flag to specify this directory.
2871 NOTE: Mesa is attempting to use llvm shared libraries by default.
2872 If you do not want to build with llvm shared libraries and instead want to
2873 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2874 invocation and rebuild.])])
2875
2876 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2877 dnl install uses a shared object for each component and we have
2878 dnl already added all of these objects to LLVM_LIBS.
2879 fi
2880 }
2881
2882 dnl
2883 dnl Set defines and buildtime variables only when using LLVM.
2884 dnl
2885 if test "x$enable_llvm" = xyes; then
2886 DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2887
2888 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2889 LLVM_CFLAGS=$LLVM_CPPFLAGS # CPPFLAGS seem to be sufficient
2890 LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2891
2892 dnl Set LLVM_LIBS - This is done after the driver configuration so
2893 dnl that drivers can add additional components to LLVM_COMPONENTS.
2894 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2895 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2896 dnl this was causing the same libraries to be appear multiple times
2897 dnl in LLVM_LIBS.
2898
2899 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2900 if test "x$enable_llvm_shared_libs" = xyes; then
2901 LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2902 else
2903 dnl Invoking llvm-config with both -libs and --system-libs produces the
2904 dnl two separate lines - each for the set of libraries.
2905 dnl Call the program twice, effectively folding them into a single line.
2906 LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2907 dnl We need to link to llvm system libs when using static libs
2908 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2909 fi
2910 else
2911 LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2912 if test "x$enable_llvm_shared_libs" = xyes; then
2913 detect_old_buggy_llvm
2914 else
2915 AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2916 dnl We need to link to llvm system libs when using static libs
2917 dnl However, only llvm 3.5+ provides --system-libs
2918 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2919 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2920 fi
2921 fi
2922 fi
2923
2924 dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2925 dnl swr/llvmpipe driver into the final binary. Adding LLVM_LIBS results in
2926 dnl the LLVM library propagated in the Libs.private of the respective .pc
2927 dnl file which ensures complete dependency information when statically
2928 dnl linking.
2929 if test "x$enable_glx" == xgallium-xlib; then
2930 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2931 fi
2932 if test "x$enable_gallium_osmesa" = xyes; then
2933 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2934 fi
2935 fi
2936
2937 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2938 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2939 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2940 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2941 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2942 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2943 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2944 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2945 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2946 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2947 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2948 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2949 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2950 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2951 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2952 "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2953 "x$HAVE_GALLIUM_SWR" = xyes)
2954 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2955 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2956 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2957
2958 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2959
2960 if test "x$enable_dri" = xyes; then
2961 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2962 fi
2963
2964 if test "x$have_drisw_kms" = xyes; then
2965 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2966 fi
2967 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2968
2969 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2970 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2971 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2972 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2973 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2974 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2975
2976 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2977 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2978
2979 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2980 "x$HAVE_RADEON_VULKAN" = xyes)
2981
2982 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2983 "x$HAVE_GALLIUM_V3D" = xyes)
2984
2985 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2986 "x$HAVE_I965_DRI" = xyes)
2987
2988 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2989 "x$HAVE_GALLIUM_R600" = xyes -o \
2990 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2991 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2992 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2993 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2994 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
2995 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2996
2997 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2998 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2999 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
3000 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
3001 "x$enable_gallium_osmesa" = xyes)
3002
3003 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
3004 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
3005 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
3006 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
3007 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
3008 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
3009
3010 AC_SUBST([NINE_MAJOR], 1)
3011 AC_SUBST([NINE_MINOR], 0)
3012 AC_SUBST([NINE_PATCH], 0)
3013 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
3014
3015 AC_SUBST([VDPAU_MAJOR], 1)
3016 AC_SUBST([VDPAU_MINOR], 0)
3017
3018 if test "x$enable_va" = xyes; then
3019 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
3020 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
3021 fi
3022 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3023 AC_SUBST([VA_MINOR], $VA_MINOR)
3024
3025 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3026
3027 AC_SUBST([XVMC_MAJOR], 1)
3028 AC_SUBST([XVMC_MINOR], 0)
3029
3030 AC_SUBST([XA_MAJOR], 2)
3031 AC_SUBST([XA_MINOR], 4)
3032 AC_SUBST([XA_PATCH], 0)
3033 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3034
3035 AC_ARG_ENABLE(valgrind,
3036 [AS_HELP_STRING([--enable-valgrind],
3037 [Build mesa with valgrind support (default: auto)])],
3038 [VALGRIND=$enableval], [VALGRIND=auto])
3039 if test "x$VALGRIND" != xno; then
3040 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3041 fi
3042 AC_MSG_CHECKING([whether to enable Valgrind support])
3043 if test "x$VALGRIND" = xauto; then
3044 VALGRIND="$have_valgrind"
3045 fi
3046
3047 if test "x$VALGRIND" = "xyes"; then
3048 if ! test "x$have_valgrind" = xyes; then
3049 AC_MSG_ERROR([Valgrind support required but not present])
3050 fi
3051 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3052 fi
3053
3054 AC_MSG_RESULT([$VALGRIND])
3055
3056 dnl Restore LDFLAGS and CPPFLAGS
3057 LDFLAGS="$_SAVE_LDFLAGS"
3058 CPPFLAGS="$_SAVE_CPPFLAGS"
3059
3060 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3061 if test "x$acv_mesa_CLANG" = xyes; then
3062 CFLAGS="$CFLAGS -Qunused-arguments"
3063 CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3064 fi
3065
3066 dnl Add user CFLAGS and CXXFLAGS
3067 CFLAGS="$CFLAGS $USER_CFLAGS"
3068 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3069
3070 dnl Substitute the config
3071 AC_CONFIG_FILES([Makefile
3072 src/Makefile
3073 src/amd/Makefile
3074 src/amd/vulkan/Makefile
3075 src/broadcom/Makefile
3076 src/compiler/Makefile
3077 src/egl/Makefile
3078 src/egl/main/egl.pc
3079 src/egl/wayland/wayland-drm/Makefile
3080 src/gallium/Makefile
3081 src/gallium/auxiliary/Makefile
3082 src/gallium/auxiliary/pipe-loader/Makefile
3083 src/gallium/drivers/freedreno/Makefile
3084 src/gallium/drivers/i915/Makefile
3085 src/gallium/drivers/llvmpipe/Makefile
3086 src/gallium/drivers/nouveau/Makefile
3087 src/gallium/drivers/pl111/Makefile
3088 src/gallium/drivers/r300/Makefile
3089 src/gallium/drivers/r600/Makefile
3090 src/gallium/drivers/radeonsi/Makefile
3091 src/gallium/drivers/softpipe/Makefile
3092 src/gallium/drivers/svga/Makefile
3093 src/gallium/drivers/swr/Makefile
3094 src/gallium/drivers/tegra/Makefile
3095 src/gallium/drivers/etnaviv/Makefile
3096 src/gallium/drivers/imx/Makefile
3097 src/gallium/drivers/v3d/Makefile
3098 src/gallium/drivers/vc4/Makefile
3099 src/gallium/drivers/virgl/Makefile
3100 src/gallium/state_trackers/clover/Makefile
3101 src/gallium/state_trackers/dri/Makefile
3102 src/gallium/state_trackers/glx/xlib/Makefile
3103 src/gallium/state_trackers/nine/Makefile
3104 src/gallium/state_trackers/omx/Makefile
3105 src/gallium/state_trackers/omx/bellagio/Makefile
3106 src/gallium/state_trackers/omx/tizonia/Makefile
3107 src/gallium/state_trackers/osmesa/Makefile
3108 src/gallium/state_trackers/va/Makefile
3109 src/gallium/state_trackers/vdpau/Makefile
3110 src/gallium/state_trackers/xa/Makefile
3111 src/gallium/state_trackers/xa/xa_tracker.h
3112 src/gallium/state_trackers/xvmc/Makefile
3113 src/gallium/targets/d3dadapter9/Makefile
3114 src/gallium/targets/d3dadapter9/d3d.pc
3115 src/gallium/targets/dri/Makefile
3116 src/gallium/targets/libgl-xlib/Makefile
3117 src/gallium/targets/omx/Makefile
3118 src/gallium/targets/opencl/Makefile
3119 src/gallium/targets/opencl/mesa.icd
3120 src/gallium/targets/osmesa/Makefile
3121 src/gallium/targets/osmesa/osmesa.pc
3122 src/gallium/targets/pipe-loader/Makefile
3123 src/gallium/targets/va/Makefile
3124 src/gallium/targets/vdpau/Makefile
3125 src/gallium/targets/xa/Makefile
3126 src/gallium/targets/xa/xatracker.pc
3127 src/gallium/targets/xvmc/Makefile
3128 src/gallium/tests/trivial/Makefile
3129 src/gallium/tests/unit/Makefile
3130 src/gallium/winsys/etnaviv/drm/Makefile
3131 src/gallium/winsys/imx/drm/Makefile
3132 src/gallium/winsys/freedreno/drm/Makefile
3133 src/gallium/winsys/i915/drm/Makefile
3134 src/gallium/winsys/nouveau/drm/Makefile
3135 src/gallium/winsys/pl111/drm/Makefile
3136 src/gallium/winsys/radeon/drm/Makefile
3137 src/gallium/winsys/amdgpu/drm/Makefile
3138 src/gallium/winsys/svga/drm/Makefile
3139 src/gallium/winsys/sw/dri/Makefile
3140 src/gallium/winsys/sw/kms-dri/Makefile
3141 src/gallium/winsys/sw/null/Makefile
3142 src/gallium/winsys/sw/wrapper/Makefile
3143 src/gallium/winsys/sw/xlib/Makefile
3144 src/gallium/winsys/tegra/drm/Makefile
3145 src/gallium/winsys/v3d/drm/Makefile
3146 src/gallium/winsys/vc4/drm/Makefile
3147 src/gallium/winsys/virgl/drm/Makefile
3148 src/gallium/winsys/virgl/vtest/Makefile
3149 src/gbm/Makefile
3150 src/gbm/main/gbm.pc
3151 src/glx/Makefile
3152 src/glx/apple/Makefile
3153 src/glx/tests/Makefile
3154 src/glx/windows/Makefile
3155 src/glx/windows/windowsdriproto.pc
3156 src/gtest/Makefile
3157 src/intel/Makefile
3158 src/loader/Makefile
3159 src/mapi/Makefile
3160 src/mapi/es1api/glesv1_cm.pc
3161 src/mapi/es2api/glesv2.pc
3162 src/mapi/glapi/gen/Makefile
3163 src/mesa/Makefile
3164 src/mesa/gl.pc
3165 src/mesa/drivers/dri/dri.pc
3166 src/mesa/drivers/dri/common/Makefile
3167 src/mesa/drivers/dri/i915/Makefile
3168 src/mesa/drivers/dri/i965/Makefile
3169 src/mesa/drivers/dri/Makefile
3170 src/mesa/drivers/dri/nouveau/Makefile
3171 src/mesa/drivers/dri/r200/Makefile
3172 src/mesa/drivers/dri/radeon/Makefile
3173 src/mesa/drivers/dri/swrast/Makefile
3174 src/mesa/drivers/osmesa/Makefile
3175 src/mesa/drivers/osmesa/osmesa.pc
3176 src/mesa/drivers/x11/Makefile
3177 src/mesa/main/tests/Makefile
3178 src/mesa/state_tracker/tests/Makefile
3179 src/util/Makefile
3180 src/util/tests/hash_table/Makefile
3181 src/util/tests/set/Makefile
3182 src/util/tests/string_buffer/Makefile
3183 src/util/tests/vma/Makefile
3184 src/util/xmlpool/Makefile
3185 src/vulkan/Makefile])
3186
3187 AC_OUTPUT
3188
3189 # Fix up dependencies in *.Plo files, where we changed the extension of a
3190 # source file
3191 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3192
3193 rm -f src/compiler/spirv/spirv_info.lo
3194 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3195
3196 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3197 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3198
3199 dnl
3200 dnl Output some configuration info for the user
3201 dnl
3202 echo ""
3203 echo " prefix: $prefix"
3204 echo " exec_prefix: $exec_prefix"
3205 echo " libdir: $libdir"
3206 echo " includedir: $includedir"
3207
3208 dnl API info
3209 echo ""
3210 echo " OpenGL: $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3211
3212 dnl Driver info
3213 echo ""
3214 case "x$enable_osmesa$enable_gallium_osmesa" in
3215 xnoyes)
3216 echo " OSMesa: lib$OSMESA_LIB (Gallium)"
3217 ;;
3218 xyesno)
3219 echo " OSMesa: lib$OSMESA_LIB"
3220 ;;
3221 xnono)
3222 echo " OSMesa: no"
3223 ;;
3224 esac
3225
3226 echo ""
3227 if test "x$enable_dri" != xno; then
3228 echo " DRI platform: $dri_platform"
3229 if test -z "$DRI_DIRS"; then
3230 echo " DRI drivers: no"
3231 else
3232 echo " DRI drivers: $DRI_DIRS"
3233 fi
3234 echo " DRI driver dir: $DRI_DRIVER_INSTALL_DIR"
3235 fi
3236
3237 case "x$enable_glx" in
3238 xdri)
3239 echo " GLX: DRI-based"
3240 ;;
3241 xxlib)
3242 echo " GLX: Xlib-based"
3243 ;;
3244 xgallium-xlib)
3245 echo " GLX: Xlib-based (Gallium)"
3246 ;;
3247 *)
3248 echo " GLX: $enable_glx"
3249 ;;
3250 esac
3251
3252 dnl EGL
3253 echo ""
3254 echo " EGL: $enable_egl"
3255 if test "$enable_egl" = yes; then
3256
3257 egl_drivers=""
3258 if test "x$enable_dri" != "xno"; then
3259 egl_drivers="$egl_drivers builtin:egl_dri2"
3260 fi
3261 if test "x$enable_dri3" != "xno"; then
3262 egl_drivers="$egl_drivers builtin:egl_dri3"
3263 fi
3264
3265 echo " EGL drivers: $egl_drivers"
3266 fi
3267 if test "x$enable_gbm" = xyes; then
3268 echo " GBM: yes"
3269 else
3270 echo " GBM: no"
3271 fi
3272
3273 echo " EGL/Vulkan/VL platforms: $platforms"
3274
3275 # Vulkan
3276 echo ""
3277 if test "x$VULKAN_DRIVERS" != x; then
3278 echo " Vulkan drivers: $VULKAN_DRIVERS"
3279 echo " Vulkan ICD dir: $VULKAN_ICD_INSTALL_DIR"
3280 else
3281 echo " Vulkan drivers: no"
3282 fi
3283
3284 echo ""
3285 if test "x$enable_llvm" = xyes; then
3286 echo " llvm: yes"
3287 echo " llvm-config: $LLVM_CONFIG"
3288 echo " llvm-version: $LLVM_VERSION"
3289 else
3290 echo " llvm: no"
3291 fi
3292
3293 echo ""
3294 if test -n "$with_gallium_drivers"; then
3295 echo " Gallium drivers: $gallium_drivers"
3296 echo " Gallium st: $gallium_st"
3297 else
3298 echo " Gallium: no"
3299 fi
3300
3301 echo ""
3302 if test "x$enable_gallium_extra_hud" != xyes; then
3303 echo " HUD extra stats: no"
3304 else
3305 echo " HUD extra stats: yes"
3306 fi
3307
3308 if test "x$enable_lmsensors" != xyes; then
3309 echo " HUD lmsensors: no"
3310 else
3311 echo " HUD lmsensors: yes"
3312 fi
3313
3314 echo ""
3315 if test "x$HAVE_GALLIUM_SWR" != x; then
3316 if test "x$HAVE_SWR_BUILTIN" = xyes; then
3317 echo " SWR archs: $swr_archs (builtin)"
3318 else
3319 echo " SWR archs: $swr_archs"
3320 fi
3321 fi
3322
3323 dnl Libraries
3324 echo ""
3325 echo " Shared libs: $enable_shared"
3326 echo " Static libs: $enable_static"
3327 echo " Shared-glapi: $enable_shared_glapi"
3328
3329 dnl Compiler options
3330 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3331 cflags=`echo $CFLAGS | \
3332 $SED 's/^ *//;s/ */ /;s/ *$//'`
3333 cxxflags=`echo $CXXFLAGS | \
3334 $SED 's/^ *//;s/ */ /;s/ *$//'`
3335 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/ */ /;s/ *$//'`
3336 defines=`echo $DEFINES | $SED 's/^ *//;s/ */ /;s/ *$//'`
3337 echo ""
3338 echo " CFLAGS: $cflags"
3339 echo " CXXFLAGS: $cxxflags"
3340 echo " CXX11_CXXFLAGS: $CXX11_CXXFLAGS"
3341 echo " LDFLAGS: $ldflags"
3342 echo " Macros: $defines"
3343 echo ""
3344 if test "x$enable_llvm" = xyes; then
3345 echo " LLVM_CFLAGS: $LLVM_CFLAGS"
3346 echo " LLVM_CXXFLAGS: $LLVM_CXXFLAGS"
3347 echo " LLVM_CPPFLAGS: $LLVM_CPPFLAGS"
3348 echo " LLVM_LDFLAGS: $LLVM_LDFLAGS"
3349 echo ""
3350 fi
3351 echo " PYTHON2: $PYTHON2"
3352
3353 echo ""
3354 echo " Run '${MAKE-make}' to build Mesa"
3355 echo ""