configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319
 320 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330
 331 AC_SUBST([GL_LIB_NAME])
 332 AC_SUBST([GLU_LIB_NAME])
 333 AC_SUBST([GLUT_LIB_NAME])
 334 AC_SUBST([GLW_LIB_NAME])
 335 AC_SUBST([OSMESA_LIB_NAME])
 336 AC_SUBST([EGL_LIB_NAME])
 337 AC_SUBST([GLESv1_CM_LIB_NAME])
 338 AC_SUBST([GLESv2_LIB_NAME])
 339 AC_SUBST([VG_LIB_NAME])
 340
 341 AC_SUBST([GL_LIB_GLOB])
 342 AC_SUBST([GLU_LIB_GLOB])
 343 AC_SUBST([GLUT_LIB_GLOB])
 344 AC_SUBST([GLW_LIB_GLOB])
 345 AC_SUBST([OSMESA_LIB_GLOB])
 346 AC_SUBST([EGL_LIB_GLOB])
 347 AC_SUBST([GLESv1_CM_LIB_GLOB])
 348 AC_SUBST([GLESv2_LIB_GLOB])
 349 AC_SUBST([VG_LIB_GLOB])
 350
 351 dnl
 352 dnl Arch/platform-specific settings
 353 dnl
 354 AC_ARG_ENABLE([asm],
 355     [AS_HELP_STRING([--disable-asm],
 356         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 357     [enable_asm="$enableval"],
 358     [enable_asm=yes]
 359 )
 360 asm_arch=""
 361 ASM_FLAGS=""
 362 MESA_ASM_SOURCES=""
 363 GLAPI_ASM_SOURCES=""
 364 AC_MSG_CHECKING([whether to enable assembly])
 365 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 366 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 367 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 368     case "$host_cpu" in
 369     i?86 | x86_64)
 370         enable_asm=no
 371         AC_MSG_RESULT([no, cross compiling])
 372         ;;
 373     esac
 374 fi
 375 # check for supported arches
 376 if test "x$enable_asm" = xyes; then
 377     case "$host_cpu" in
 378     i?86)
 379         case "$host_os" in
 380         linux* | *freebsd* | dragonfly* | *netbsd*)
 381             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 382             ;;
 383         esac
 384         ;;
 385     x86_64)
 386         case "$host_os" in
 387         linux* | *freebsd* | dragonfly* | *netbsd*)
 388             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 389             ;;
 390         esac
 391         ;;
 392     powerpc)
 393         case "$host_os" in
 394         linux*)
 395             asm_arch=ppc
 396             ;;
 397         esac
 398         ;;
 399     sparc*)
 400         case "$host_os" in
 401         linux*)
 402             asm_arch=sparc
 403             ;;
 404         esac
 405         ;;
 406     esac
 407
 408     case "$asm_arch" in
 409     x86)
 410         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 411         MESA_ASM_SOURCES='$(X86_SOURCES)'
 412         GLAPI_ASM_SOURCES='$(X86_API)'
 413         AC_MSG_RESULT([yes, x86])
 414         ;;
 415     x86_64)
 416         ASM_FLAGS="-DUSE_X86_64_ASM"
 417         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 418         GLAPI_ASM_SOURCES='$(X86-64_API)'
 419         AC_MSG_RESULT([yes, x86_64])
 420         ;;
 421     ppc)
 422         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 423         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 424         AC_MSG_RESULT([yes, ppc])
 425         ;;
 426     sparc)
 427         ASM_FLAGS="-DUSE_SPARC_ASM"
 428         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 429         GLAPI_ASM_SOURCES='$(SPARC_API)'
 430         AC_MSG_RESULT([yes, sparc])
 431         ;;
 432     *)
 433         AC_MSG_RESULT([no, platform not supported])
 434         ;;
 435     esac
 436 fi
 437 AC_SUBST([ASM_FLAGS])
 438 AC_SUBST([MESA_ASM_SOURCES])
 439 AC_SUBST([GLAPI_ASM_SOURCES])
 440
 441 dnl PIC code macro
 442 MESA_PIC_FLAGS
 443
 444 dnl Check to see if dlopen is in default libraries (like Solaris, which
 445 dnl has it in libc), or if libdl is needed to get it.
 446 AC_CHECK_FUNC([dlopen], [],
 447     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 448 AC_SUBST([DLOPEN_LIBS])
 449
 450 dnl See if posix_memalign is available
 451 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 452
 453 dnl SELinux awareness.
 454 AC_ARG_ENABLE([selinux],
 455     [AS_HELP_STRING([--enable-selinux],
 456         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 457     [MESA_SELINUX="$enableval"],
 458     [MESA_SELINUX=no])
 459 if test "x$enable_selinux" = "xyes"; then
 460     AC_CHECK_HEADER([selinux/selinux.h],[],
 461                     [AC_MSG_ERROR([SELinux headers not found])])
 462     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 463                  [AC_MSG_ERROR([SELinux library not found])])
 464     SELINUX_LIBS="-lselinux"
 465     DEFINES="$DEFINES -DMESA_SELINUX"
 466 fi
 467
 468 dnl Determine which APIs to support
 469 AC_ARG_ENABLE([opengl],
 470     [AS_HELP_STRING([--disable-opengl],
 471         [disable support for standard OpenGL API @<:@default=no@:>@])],
 472     [enable_opengl="$enableval"],
 473     [enable_opengl=yes])
 474 AC_ARG_ENABLE([gles1],
 475     [AS_HELP_STRING([--enable-gles1],
 476         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 477     [enable_gles1="$enableval"],
 478     [enable_gles1=no])
 479 AC_ARG_ENABLE([gles2],
 480     [AS_HELP_STRING([--enable-gles2],
 481         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 482     [enable_gles2="$enableval"],
 483     [enable_gles2=no])
 484 AC_ARG_ENABLE([gles-overlay],
 485     [AS_HELP_STRING([--enable-gles-overlay],
 486         [DEPRECATED.  Same as --enable-gles1 and --enable-gles2])],
 487     [enable_gles1="$enableval"; enable_gles2="$enableval"],
 488     [])
 489
 490 AC_ARG_ENABLE([openvg],
 491     [AS_HELP_STRING([--enable-openvg],
 492         [enable support for OpenVG API @<:@default=no@:>@])],
 493     [enable_openvg="$enableval"],
 494     [enable_openvg=no])
 495
 496 dnl smooth the transition; should be removed eventually
 497 if test "x$enable_openvg" = xno; then
 498     case "x$with_state_trackers" in
 499     x*vega*)
 500         AC_MSG_WARN([vega state tracker is enabled without --enable-openvg])
 501         enable_openvg=yes
 502         ;;
 503     esac
 504 fi
 505
 506 if test "x$enable_opengl" = xno -a \
 507         "x$enable_gles1" = xno -a \
 508         "x$enable_gles2" = xno -a \
 509         "x$enable_openvg" = xno; then
 510     AC_MSG_ERROR([at least one API should be enabled])
 511 fi
 512
 513 API_DEFINES=""
 514 if test "x$enable_opengl" = xno; then
 515     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 516 else
 517     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 518 fi
 519 if test "x$enable_gles1" = xyes; then
 520     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 521 fi
 522 if test "x$enable_gles2" = xyes; then
 523     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 524 fi
 525 AC_SUBST([API_DEFINES])
 526
 527 dnl
 528 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 529 dnl More later: fbdev, ...
 530 dnl
 531 default_driver="xlib"
 532
 533 case "$host_os" in
 534 linux*)
 535     case "$host_cpu" in
 536     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 537     esac
 538     ;;
 539 *freebsd* | dragonfly* | *netbsd*)
 540     case "$host_cpu" in
 541     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 542     esac
 543     ;;
 544 esac
 545
 546 if test "x$enable_opengl" = xno; then
 547     default_driver="no"
 548 fi
 549
 550 AC_ARG_WITH([driver],
 551     [AS_HELP_STRING([--with-driver=DRIVER],
 552         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 553     [mesa_driver="$withval"],
 554     [mesa_driver="$default_driver"])
 555 dnl Check for valid option
 556 case "x$mesa_driver" in
 557 xxlib|xdri|xosmesa)
 558     if test "x$enable_opengl" = xno; then
 559         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 560     fi
 561     ;;
 562 xno)
 563     ;;
 564 *)
 565     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 566     ;;
 567 esac
 568
 569 PKG_CHECK_MODULES([TALLOC], [talloc])
 570 AC_SUBST([TALLOC_LIBS])
 571 AC_SUBST([TALLOC_CFLAGS])
 572
 573 dnl
 574 dnl Driver specific build directories
 575 dnl
 576
 577 dnl this variable will be prepended to SRC_DIRS and is not exported
 578 CORE_DIRS=""
 579
 580 SRC_DIRS=""
 581 GLU_DIRS="sgi"
 582 GALLIUM_DIRS="auxiliary drivers state_trackers"
 583 GALLIUM_TARGET_DIRS=""
 584 GALLIUM_WINSYS_DIRS="sw"
 585 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug noop identity"
 586 GALLIUM_STATE_TRACKERS_DIRS=""
 587
 588 # build glapi if OpenGL is enabled
 589 if test "x$enable_opengl" = xyes; then
 590     CORE_DIRS="$CORE_DIRS mapi/glapi"
 591 fi
 592
 593 # build es1api if OpenGL ES 1.x is enabled
 594 if test "x$enable_gles1" = xyes; then
 595     CORE_DIRS="$CORE_DIRS mapi/es1api"
 596 fi
 597
 598 # build es2api if OpenGL ES 2.x is enabled
 599 if test "x$enable_gles2" = xyes; then
 600     CORE_DIRS="$CORE_DIRS mapi/es2api"
 601 fi
 602
 603 # build vgapi if OpenVG is enabled
 604 if test "x$enable_openvg" = xyes; then
 605     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 606 fi
 607
 608 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 609 case "x$enable_opengl$enable_gles1$enable_gles2" in
 610 x*yes*)
 611     CORE_DIRS="$CORE_DIRS glsl mesa"
 612     ;;
 613 esac
 614
 615 case "$mesa_driver" in
 616 xlib)
 617     DRIVER_DIRS="x11"
 618     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 619     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 620     ;;
 621 dri)
 622     SRC_DIRS="$SRC_DIRS glx"
 623     DRIVER_DIRS="dri"
 624     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 625     ;;
 626 osmesa)
 627     DRIVER_DIRS="osmesa"
 628     ;;
 629 no)
 630     DRIVER_DRIS=""
 631     ;;
 632 esac
 633 AC_SUBST([SRC_DIRS])
 634 AC_SUBST([GLU_DIRS])
 635 AC_SUBST([DRIVER_DIRS])
 636 AC_SUBST([GALLIUM_DIRS])
 637 AC_SUBST([GALLIUM_TARGET_DIRS])
 638 AC_SUBST([GALLIUM_WINSYS_DIRS])
 639 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 640 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 641 AC_SUBST([MESA_LLVM])
 642
 643 dnl
 644 dnl Find out if X is available. The variable have_x is set if libX11 is
 645 dnl found to mimic AC_PATH_XTRA.
 646 dnl
 647 if test -n "$PKG_CONFIG"; then
 648     AC_MSG_CHECKING([pkg-config files for X11 are available])
 649     PKG_CHECK_EXISTS([x11],[
 650         x11_pkgconfig=yes
 651         have_x=yes
 652         ],[
 653         x11_pkgconfig=no
 654     ])
 655     AC_MSG_RESULT([$x11_pkgconfig])
 656 else
 657     x11_pkgconfig=no
 658 fi
 659 dnl Use the autoconf macro if no pkg-config files
 660 if test "$x11_pkgconfig" = yes; then
 661     PKG_CHECK_MODULES([X11], [x11])
 662 else
 663     AC_PATH_XTRA
 664     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 665     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 666     AC_SUBST([X11_CFLAGS])
 667     AC_SUBST([X11_LIBS])
 668 fi
 669
 670 dnl Try to tell the user that the --x-* options are only used when
 671 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 672 m4_divert_once([HELP_BEGIN],
 673 [These options are only used when the X libraries cannot be found by the
 674 pkg-config utility.])
 675
 676 dnl We need X for xlib and dri, so bomb now if it's not found
 677 case "$mesa_driver" in
 678 xlib|dri)
 679     if test "$no_x" = yes; then
 680         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 681     fi
 682     ;;
 683 esac
 684
 685 dnl XCB - this is only used for GLX right now
 686 AC_ARG_ENABLE([xcb],
 687     [AS_HELP_STRING([--enable-xcb],
 688         [use XCB for GLX @<:@default=disabled@:>@])],
 689     [enable_xcb="$enableval"],
 690     [enable_xcb=no])
 691 if test "x$enable_xcb" = xyes; then
 692     DEFINES="$DEFINES -DUSE_XCB"
 693 else
 694     enable_xcb=no
 695 fi
 696
 697 dnl
 698 dnl libGL configuration per driver
 699 dnl
 700 case "$mesa_driver" in
 701 xlib)
 702     if test "$x11_pkgconfig" = yes; then
 703         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 704         GL_PC_REQ_PRIV="x11 xext"
 705         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 706         GL_LIB_DEPS="$XLIBGL_LIBS"
 707     else
 708         # should check these...
 709         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 710         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 711         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 712         GL_PC_CFLAGS="$X11_INCLUDES"
 713     fi
 714     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 715     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 716
 717     # if static, move the external libraries to the programs
 718     # and empty the libraries for libGL
 719     if test "$enable_static" = yes; then
 720         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 721         GL_LIB_DEPS=""
 722     fi
 723     ;;
 724 dri|no) # these checks are still desired when there is no mesa_driver
 725     # DRI must be shared, I think
 726     if test "$enable_static" = yes; then
 727         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 728     fi
 729
 730     # Check for libdrm
 731     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 732     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 733     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 734     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 735     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 736
 737     # find the DRI deps for libGL
 738     if test "$x11_pkgconfig" = yes; then
 739         dri_modules="x11 xext xdamage xfixes"
 740
 741         # add xf86vidmode if available
 742         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 743         if test "$HAVE_XF86VIDMODE" = yes ; then
 744             dri_modules="$dri_modules xxf86vm"
 745         fi
 746
 747         # add xcb modules if necessary
 748         if test "$enable_xcb" = yes; then
 749             dri_modules="$dri_modules x11-xcb xcb-glx"
 750         fi
 751
 752         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 753         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 754         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 755         GL_LIB_DEPS="$DRIGL_LIBS"
 756     else
 757         # should check these...
 758         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 759         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 760         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 761         GL_PC_CFLAGS="$X11_INCLUDES"
 762
 763         # XCB can only be used from pkg-config
 764         if test "$enable_xcb" = yes; then
 765             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 766             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 767             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 768             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 769         fi
 770     fi
 771
 772     # need DRM libs, -lpthread, etc.
 773     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 774     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 775     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 776     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 777     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 778     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 779     ;;
 780 osmesa)
 781     # No libGL for osmesa
 782     GL_LIB_DEPS=""
 783     ;;
 784 esac
 785 AC_SUBST([GL_LIB_DEPS])
 786 AC_SUBST([GL_PC_REQ_PRIV])
 787 AC_SUBST([GL_PC_LIB_PRIV])
 788 AC_SUBST([GL_PC_CFLAGS])
 789 AC_SUBST([DRI_PC_REQ_PRIV])
 790 AC_SUBST([GLESv1_CM_LIB_DEPS])
 791 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 792 AC_SUBST([GLESv2_LIB_DEPS])
 793 AC_SUBST([GLESv2_PC_LIB_PRIV])
 794
 795
 796 AC_SUBST([HAVE_XF86VIDMODE])
 797
 798 PKG_CHECK_MODULES([LIBDRM_RADEON],
 799                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 800                   HAVE_LIBDRM_RADEON=yes,
 801                   HAVE_LIBDRM_RADEON=no)
 802
 803 dnl
 804 dnl More X11 setup
 805 dnl
 806 if test "$mesa_driver" = xlib; then
 807     DEFINES="$DEFINES -DUSE_XSHM"
 808 fi
 809
 810 dnl
 811 dnl More DRI setup
 812 dnl
 813 AC_ARG_ENABLE([glx-tls],
 814     [AS_HELP_STRING([--enable-glx-tls],
 815         [enable TLS support in GLX @<:@default=disabled@:>@])],
 816     [GLX_USE_TLS="$enableval"],
 817     [GLX_USE_TLS=no])
 818 dnl Directory for DRI drivers
 819 AC_ARG_WITH([dri-driverdir],
 820     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 821         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 822     [DRI_DRIVER_INSTALL_DIR="$withval"],
 823     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 824 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 825 dnl Extra search path for DRI drivers
 826 AC_ARG_WITH([dri-searchpath],
 827     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 828         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 829     [DRI_DRIVER_SEARCH_DIR="$withval"],
 830     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 831 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 832 dnl Direct rendering or just indirect rendering
 833 AC_ARG_ENABLE([driglx-direct],
 834     [AS_HELP_STRING([--disable-driglx-direct],
 835         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 836     [driglx_direct="$enableval"],
 837     [driglx_direct="yes"])
 838 dnl Which drivers to build - default is chosen by platform
 839 AC_ARG_WITH([dri-drivers],
 840     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 841         [comma delimited DRI drivers list, e.g.
 842         "swrast,i965,radeon" @<:@default=auto@:>@])],
 843     [with_dri_drivers="$withval"],
 844     [with_dri_drivers=yes])
 845 if test "x$with_dri_drivers" = x; then
 846     with_dri_drivers=no
 847 fi
 848
 849 dnl If $with_dri_drivers is yes, directories will be added through
 850 dnl platform checks
 851 DRI_DIRS=""
 852 case "$with_dri_drivers" in
 853 no) ;;
 854 yes)
 855     DRI_DIRS="yes"
 856     ;;
 857 *)
 858     # verify the requested driver directories exist
 859     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 860     for driver in $dri_drivers; do
 861         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 862             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 863     done
 864     DRI_DIRS="$dri_drivers"
 865     ;;
 866 esac
 867
 868 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 869 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 870     # Use TLS in GLX?
 871     if test "x$GLX_USE_TLS" = xyes; then
 872         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 873     fi
 874
 875     # Platform specific settings and drivers to build
 876     case "$host_os" in
 877     linux*)
 878         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 879         if test "x$driglx_direct" = xyes; then
 880             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 881         fi
 882         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 883
 884         case "$host_cpu" in
 885         x86_64)
 886             # sis is missing because they have not be converted to use
 887             # the new interface.  i810 are missing because there is no
 888             # x86-64 system where they could *ever* be used.
 889             if test "x$DRI_DIRS" = "xyes"; then
 890                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 891                     savage tdfx unichrome swrast"
 892             fi
 893             ;;
 894         powerpc*)
 895             # Build only the drivers for cards that exist on PowerPC.
 896             # At some point MGA will be added, but not yet.
 897             if test "x$DRI_DIRS" = "xyes"; then
 898                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 899             fi
 900             ;;
 901         sparc*)
 902             # Build only the drivers for cards that exist on sparc`
 903             if test "x$DRI_DIRS" = "xyes"; then
 904                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 905             fi
 906             ;;
 907         esac
 908         ;;
 909     freebsd* | dragonfly* | *netbsd*)
 910         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 911         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 912         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 913         if test "x$driglx_direct" = xyes; then
 914             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 915         fi
 916
 917         if test "x$DRI_DIRS" = "xyes"; then
 918             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 919                 unichrome savage sis swrast"
 920         fi
 921         ;;
 922     gnu*)
 923         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 924         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 925         ;;
 926     solaris*)
 927         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 928         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 929         if test "x$driglx_direct" = xyes; then
 930             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 931         fi
 932         ;;
 933     esac
 934
 935     # default drivers
 936     if test "x$DRI_DIRS" = "xyes"; then
 937         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 938             savage sis tdfx unichrome swrast"
 939     fi
 940
 941     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 942
 943     # Check for expat
 944     if test "$mesa_driver" = dri; then
 945         EXPAT_INCLUDES=""
 946         EXPAT_LIB=-lexpat
 947         AC_ARG_WITH([expat],
 948             [AS_HELP_STRING([--with-expat=DIR],
 949                 [expat install directory])],[
 950             EXPAT_INCLUDES="-I$withval/include"
 951             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 952             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 953             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 954             ])
 955         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 956         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 957             [AC_MSG_ERROR([Expat required for DRI.])])
 958     fi
 959
 960     # put all the necessary libs together
 961     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 962 fi
 963 AC_SUBST([DRI_DIRS])
 964 AC_SUBST([EXPAT_INCLUDES])
 965 AC_SUBST([DRI_LIB_DEPS])
 966
 967 case $DRI_DIRS in
 968 *i915*|*i965*)
 969     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.23])
 970     ;;
 971 esac
 972
 973 case $DRI_DIRS in
 974 *radeon*|*r200*|*r300*|*r600*)
 975     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
 976         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 977         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 978     fi
 979     ;;
 980 esac
 981 AC_SUBST([RADEON_CFLAGS])
 982 AC_SUBST([RADEON_LDFLAGS])
 983
 984
 985 dnl
 986 dnl OSMesa configuration
 987 dnl
 988 if test "$mesa_driver" = xlib; then
 989     default_gl_osmesa=yes
 990 else
 991     default_gl_osmesa=no
 992 fi
 993 AC_ARG_ENABLE([gl-osmesa],
 994     [AS_HELP_STRING([--enable-gl-osmesa],
 995         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 996     [gl_osmesa="$enableval"],
 997     [gl_osmesa="$default_gl_osmesa"])
 998 if test "x$gl_osmesa" = xyes; then
 999     if test "x$enable_opengl" = xno; then
1000         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
1001     fi
1002     if test "$mesa_driver" = osmesa; then
1003         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1004     else
1005         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1006     fi
1007 fi
1008
1009 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1010 AC_ARG_WITH([osmesa-bits],
1011     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1012         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1013     [osmesa_bits="$withval"],
1014     [osmesa_bits=8])
1015 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1016     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1017     osmesa_bits=8
1018 fi
1019 case "x$osmesa_bits" in
1020 x8)
1021     OSMESA_LIB=OSMesa
1022     ;;
1023 x16|x32)
1024     OSMESA_LIB="OSMesa$osmesa_bits"
1025     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1026     ;;
1027 *)
1028     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1029     ;;
1030 esac
1031 AC_SUBST([OSMESA_LIB])
1032
1033 case "$DRIVER_DIRS" in
1034 *osmesa*)
1035     # only link libraries with osmesa if shared
1036     if test "$enable_static" = no; then
1037         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1038     else
1039         OSMESA_LIB_DEPS=""
1040     fi
1041     OSMESA_MESA_DEPS=""
1042     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1043     ;;
1044 esac
1045 AC_SUBST([OSMESA_LIB_DEPS])
1046 AC_SUBST([OSMESA_MESA_DEPS])
1047 AC_SUBST([OSMESA_PC_REQ])
1048 AC_SUBST([OSMESA_PC_LIB_PRIV])
1049
1050 dnl
1051 dnl EGL configuration
1052 dnl
1053 AC_ARG_ENABLE([egl],
1054     [AS_HELP_STRING([--disable-egl],
1055         [disable EGL library @<:@default=enabled@:>@])],
1056     [enable_egl="$enableval"],
1057     [enable_egl=yes])
1058 if test "x$enable_egl" = xno; then
1059     if test "x$mesa_driver" = xno; then
1060         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1061     fi
1062     if test "x$enable_openvg" = xyes; then
1063         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1064     fi
1065 fi
1066 if test "x$enable_egl" = xyes; then
1067     SRC_DIRS="$SRC_DIRS egl"
1068     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1069     EGL_DRIVERS_DIRS=""
1070     if test "$enable_static" != yes; then
1071         # build egl_glx when libGL is built
1072         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1073             EGL_DRIVERS_DIRS="glx"
1074         fi
1075
1076         if test "$mesa_driver" = dri; then
1077             # build egl_dri2 when xcb-dri2 is available
1078             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1079                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1080             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1081                           [have_libudev=yes],[have_libudev=no])
1082
1083             if test "$have_xcb_dri2" = yes; then
1084                 EGL_DRIVER_DRI2=dri2
1085                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1086                 if test "$have_libudev" = yes; then
1087                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1088                 fi
1089             fi
1090         fi
1091
1092         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1093     fi
1094 fi
1095 AC_SUBST([EGL_LIB_DEPS])
1096 AC_SUBST([EGL_DRIVERS_DIRS])
1097
1098 dnl
1099 dnl GLU configuration
1100 dnl
1101 AC_ARG_ENABLE([glu],
1102     [AS_HELP_STRING([--disable-glu],
1103         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1104     [enable_glu="$enableval"],
1105     [enable_glu=yes])
1106
1107 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1108     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1109     enable_glu=no
1110 fi
1111
1112 if test "x$enable_glu" = xyes; then
1113     SRC_DIRS="$SRC_DIRS glu"
1114
1115     case "$mesa_driver" in
1116     osmesa)
1117         # Link libGLU to libOSMesa instead of libGL
1118         GLU_LIB_DEPS=""
1119         GLU_PC_REQ="osmesa"
1120         if test "$enable_static" = no; then
1121             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1122         else
1123             GLU_MESA_DEPS=""
1124         fi
1125         ;;
1126     *)
1127         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1128         GLU_PC_REQ="gl"
1129         GLU_PC_LIB_PRIV="-lm"
1130         if test "$enable_static" = no; then
1131             GLU_LIB_DEPS="-lm"
1132             GLU_MESA_DEPS='-l$(GL_LIB)'
1133         else
1134             GLU_LIB_DEPS=""
1135             GLU_MESA_DEPS=""
1136             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1137         fi
1138         ;;
1139     esac
1140 fi
1141 if test "$enable_static" = no; then
1142     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1143 fi
1144 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1145 AC_SUBST([GLU_LIB_DEPS])
1146 AC_SUBST([GLU_MESA_DEPS])
1147 AC_SUBST([GLU_PC_REQ])
1148 AC_SUBST([GLU_PC_REQ_PRIV])
1149 AC_SUBST([GLU_PC_LIB_PRIV])
1150 AC_SUBST([GLU_PC_CFLAGS])
1151
1152 dnl
1153 dnl GLw configuration
1154 dnl
1155 AC_ARG_ENABLE([glw],
1156     [AS_HELP_STRING([--disable-glw],
1157         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1158     [enable_glw="$enableval"],
1159     [enable_glw=yes])
1160 dnl Don't build GLw on osmesa
1161 if test "x$enable_glw" = xyes; then
1162     case "$mesa_driver" in
1163     osmesa|no)
1164         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1165         enable_glw=no
1166         ;;
1167     esac
1168 fi
1169 AC_ARG_ENABLE([motif],
1170     [AS_HELP_STRING([--enable-motif],
1171         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1172     [enable_motif="$enableval"],
1173     [enable_motif=no])
1174
1175 if test "x$enable_glw" = xyes; then
1176     SRC_DIRS="$SRC_DIRS glw"
1177     if test "$x11_pkgconfig" = yes; then
1178         PKG_CHECK_MODULES([GLW],[x11 xt])
1179         GLW_PC_REQ_PRIV="x11 xt"
1180         GLW_LIB_DEPS="$GLW_LIBS"
1181     else
1182         # should check these...
1183         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1184         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1185         GLW_PC_CFLAGS="$X11_INCLUDES"
1186     fi
1187
1188     GLW_SOURCES="GLwDrawA.c"
1189     MOTIF_CFLAGS=
1190     if test "x$enable_motif" = xyes; then
1191         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1192         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1193         if test "x$MOTIF_CONFIG" != xno; then
1194             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1195             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1196         else
1197             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1198                 [AC_MSG_ERROR([Can't locate Motif headers])])
1199             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1200                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1201         fi
1202         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1203         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1204         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1205         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1206     fi
1207
1208     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1209     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1210     if test "$enable_static" = no; then
1211         GLW_MESA_DEPS='-l$(GL_LIB)'
1212         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1213     else
1214         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1215         GLW_LIB_DEPS=""
1216         GLW_MESA_DEPS=""
1217     fi
1218 fi
1219 AC_SUBST([GLW_LIB_DEPS])
1220 AC_SUBST([GLW_MESA_DEPS])
1221 AC_SUBST([GLW_SOURCES])
1222 AC_SUBST([MOTIF_CFLAGS])
1223 AC_SUBST([GLW_PC_REQ_PRIV])
1224 AC_SUBST([GLW_PC_LIB_PRIV])
1225 AC_SUBST([GLW_PC_CFLAGS])
1226
1227 dnl
1228 dnl GLUT configuration
1229 dnl
1230 if test -f "$srcdir/include/GL/glut.h"; then
1231     default_glut=yes
1232 else
1233     default_glut=no
1234 fi
1235 AC_ARG_ENABLE([glut],
1236     [AS_HELP_STRING([--disable-glut],
1237         [enable GLUT library @<:@default=enabled if source available@:>@])],
1238     [enable_glut="$enableval"],
1239     [enable_glut="$default_glut"])
1240
1241 dnl Don't build glut on osmesa
1242 if test "x$enable_glut" = xyes; then
1243     case "$mesa_driver" in
1244     osmesa|no)
1245         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1246         enable_glut=no
1247         ;;
1248     esac
1249 fi
1250 dnl Can't build glut if GLU not available
1251 if test "x$enable_glu$enable_glut" = xnoyes; then
1252     AC_MSG_WARN([Disabling glut since GLU is disabled])
1253     enable_glut=no
1254 fi
1255
1256 if test "x$enable_glut" = xyes; then
1257     SRC_DIRS="$SRC_DIRS glut/glx"
1258     if test "$x11_pkgconfig" = yes; then
1259         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1260         GLUT_PC_REQ_PRIV="x11 xmu xi"
1261         GLUT_LIB_DEPS="$GLUT_LIBS"
1262     else
1263         # should check these...
1264         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1265         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1266         GLUT_PC_CFLAGS="$X11_INCLUDES"
1267     fi
1268     if test "x$GCC" = xyes; then
1269         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1270     fi
1271     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1272     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1273
1274     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1275     if test "$enable_static" = no; then
1276         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1277     else
1278         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1279         GLUT_LIB_DEPS=""
1280         GLUT_MESA_DEPS=""
1281     fi
1282 fi
1283 AC_SUBST([GLUT_LIB_DEPS])
1284 AC_SUBST([GLUT_MESA_DEPS])
1285 AC_SUBST([GLUT_CFLAGS])
1286 AC_SUBST([GLUT_PC_REQ_PRIV])
1287 AC_SUBST([GLUT_PC_LIB_PRIV])
1288 AC_SUBST([GLUT_PC_CFLAGS])
1289
1290 dnl
1291 dnl Program library dependencies
1292 dnl    Only libm is added here if necessary as the libraries should
1293 dnl    be pulled in by the linker
1294 dnl
1295 if test "x$APP_LIB_DEPS" = x; then
1296     case "$host_os" in
1297     solaris*)
1298         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1299         ;;
1300     cygwin*)
1301         APP_LIB_DEPS="-lX11"
1302         ;;
1303     *)
1304         APP_LIB_DEPS="-lm"
1305         ;;
1306     esac
1307 fi
1308 AC_SUBST([APP_LIB_DEPS])
1309 AC_SUBST([PROGRAM_DIRS])
1310
1311 dnl
1312 dnl Gallium configuration
1313 dnl
1314 AC_ARG_ENABLE([gallium],
1315     [AS_HELP_STRING([--disable-gallium],
1316         [build gallium @<:@default=enabled@:>@])],
1317     [enable_gallium="$enableval"],
1318     [enable_gallium=yes])
1319 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1320     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1321 fi
1322 if test "x$enable_gallium" = xyes; then
1323     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1324     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1325                 [HAS_UDIS86="no"])
1326     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1327 fi
1328
1329 AC_SUBST([LLVM_CFLAGS])
1330 AC_SUBST([LLVM_LIBS])
1331 AC_SUBST([LLVM_LDFLAGS])
1332 AC_SUBST([LLVM_VERSION])
1333
1334 dnl
1335 dnl Gallium state trackers configuration
1336 dnl
1337
1338 AC_ARG_ENABLE([gallium-egl],
1339     [AS_HELP_STRING([--enable-gallium-egl],
1340         [enable gallium EGL state tracker @<:@default=auto@:>@])],
1341     [enable_gallium_egl="$enableval"],
1342     [enable_gallium_egl=auto])
1343 if test "x$enable_gallium_egl" = xauto; then
1344     case "$mesa_driver" in
1345     dri|no)
1346         enable_gallium_egl=$enable_egl
1347         ;;
1348     *)
1349         enable_gallium_egl=$enable_openvg
1350         ;;
1351     esac
1352 fi
1353 case "x$enable_egl$enable_gallium_egl" in
1354 xnoyes)
1355     AC_MSG_ERROR([cannot build Gallium EGL state tracker without EGL])
1356 esac
1357
1358 AC_ARG_WITH([state-trackers],
1359     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1360         [comma delimited state_trackers list, e.g.
1361         "egl,glx" @<:@default=auto@:>@])],
1362     [with_state_trackers="$withval"],
1363     [with_state_trackers=yes])
1364
1365 case "$with_state_trackers" in
1366 no)
1367     GALLIUM_STATE_TRACKERS_DIRS=""
1368     ;;
1369 yes)
1370     # look at what else is built
1371     case "$mesa_driver" in
1372     xlib)
1373         GALLIUM_STATE_TRACKERS_DIRS=glx
1374         ;;
1375     dri)
1376         GALLIUM_STATE_TRACKERS_DIRS="dri"
1377         HAVE_ST_DRI="yes"
1378         # Have only tested st/xorg on 1.6.0 servers
1379         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1380             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1381             HAVE_ST_XORG="no")
1382         ;;
1383     esac
1384
1385     if test "x$enable_egl" = xyes; then
1386         if test "$enable_openvg" = yes; then
1387             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1388             st_egl="yes"
1389         fi
1390
1391         if test "$enable_gallium_egl" = yes; then
1392             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1393             HAVE_ST_EGL="yes"
1394         fi
1395     fi
1396     ;;
1397 *)
1398     # verify the requested state tracker exist
1399     state_trackers=""
1400     _state_trackers=`IFS=', '; echo $with_state_trackers`
1401     for tracker in $_state_trackers; do
1402         case "$tracker" in
1403         dri)
1404             if test "x$mesa_driver" != xdri; then
1405                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1406             fi
1407             HAVE_ST_DRI="yes"
1408             ;;
1409         egl)
1410             if test "x$enable_egl" != xyes; then
1411                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1412             fi
1413             HAVE_ST_EGL="yes"
1414             ;;
1415         xorg)
1416             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1417             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1418             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1419             HAVE_ST_XORG="yes"
1420             ;;
1421         vega)
1422             if test "x$enable_openvg" != xyes; then
1423                 AC_MSG_ERROR([cannot build vega state tracker without --enable-openvg])
1424             fi
1425             ;;
1426         esac
1427
1428         if test -n "$tracker"; then
1429             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1430                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1431             if test -n "$state_trackers"; then
1432                 state_trackers="$state_trackers $tracker"
1433             else
1434                 state_trackers="$tracker"
1435             fi
1436         fi
1437     done
1438     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1439     ;;
1440 esac
1441
1442
1443 EGL_CLIENT_APIS=""
1444 VG_LIB_DEPS=""
1445
1446 case "x$enable_opengl$enable_gles1$enable_gles2" in
1447 x*yes*)
1448     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1449     ;;
1450 esac
1451 if test "x$enable_openvg" = xyes; then
1452     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1453     VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1454 fi
1455
1456 AC_SUBST([VG_LIB_DEPS])
1457 AC_SUBST([EGL_CLIENT_APIS])
1458
1459 if test "x$HAVE_ST_EGL" = xyes; then
1460         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1461 fi
1462
1463 if test "x$HAVE_ST_XORG" = xyes; then
1464     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1465         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1466         HAVE_XEXTPROTO_71="no")
1467 fi
1468
1469 AC_ARG_WITH([egl-platforms],
1470     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1471         [comma delimited native platforms libEGL supports, e.g.
1472         "x11,drm" @<:@default=auto@:>@])],
1473     [with_egl_platforms="$withval"],
1474     [with_egl_platforms=yes])
1475 AC_ARG_WITH([egl-displays],
1476     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1477         [DEPRECATED.  Use --with-egl-platforms instead])],
1478     [with_egl_platforms="$withval"])
1479
1480 EGL_PLATFORMS=""
1481 case "$with_egl_platforms" in
1482 yes)
1483     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1484         EGL_PLATFORMS="x11"
1485         if test "$mesa_driver" = dri; then
1486             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1487         fi
1488     fi
1489     ;;
1490 *)
1491     if test "x$enable_egl" != xyes; then
1492         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1493     fi
1494     # verify the requested driver directories exist
1495     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1496     for plat in $egl_platforms; do
1497         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1498             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1499         if test "$plat" = "fbdev"; then
1500                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1501         fi
1502     done
1503     EGL_PLATFORMS="$egl_platforms"
1504     ;;
1505 esac
1506 AC_SUBST([EGL_PLATFORMS])
1507
1508 AC_ARG_WITH([egl-driver-dir],
1509     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1510                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1511     [EGL_DRIVER_INSTALL_DIR="$withval"],
1512     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1513 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1514
1515 AC_ARG_WITH([xorg-driver-dir],
1516     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1517                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1518     [XORG_DRIVER_INSTALL_DIR="$withval"],
1519     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1520 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1521
1522 AC_ARG_WITH([max-width],
1523     [AS_HELP_STRING([--with-max-width=N],
1524                     [Maximum framebuffer width (4096)])],
1525     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1526      AS_IF([test "${withval}" -gt "4096"],
1527            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1528 )
1529 AC_ARG_WITH([max-height],
1530     [AS_HELP_STRING([--with-max-height=N],
1531                     [Maximum framebuffer height (4096)])],
1532     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1533      AS_IF([test "${withval}" -gt "4096"],
1534            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1535 )
1536
1537 dnl
1538 dnl Gallium LLVM
1539 dnl
1540 AC_ARG_ENABLE([gallium-llvm],
1541     [AS_HELP_STRING([--enable-gallium-llvm],
1542         [build gallium LLVM support @<:@default=disabled@:>@])],
1543     [enable_gallium_llvm="$enableval"],
1544     [enable_gallium_llvm=auto])
1545 if test "x$enable_gallium_llvm" = xyes; then
1546     if test "x$LLVM_CONFIG" != xno; then
1547         LLVM_VERSION=`$LLVM_CONFIG --version`
1548         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags`
1549         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1550
1551         if test "x$HAS_UDIS86" != xno; then
1552             LLVM_LIBS="$LLVM_LIBS -ludis86"
1553             DEFINES="$DEFINES -DHAVE_UDIS86"
1554         fi
1555         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1556         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1557         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1558         MESA_LLVM=1
1559     else
1560         MESA_LLVM=0
1561     fi
1562 else
1563     MESA_LLVM=0
1564 fi
1565
1566 dnl
1567 dnl Gallium helper functions
1568 dnl
1569 gallium_check_st() {
1570     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1571          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1572     fi
1573     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1574          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1575     fi
1576     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1577          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1578     fi
1579 }
1580
1581
1582 dnl
1583 dnl Gallium SVGA configuration
1584 dnl
1585 AC_ARG_ENABLE([gallium-svga],
1586     [AS_HELP_STRING([--enable-gallium-svga],
1587         [build gallium SVGA @<:@default=disabled@:>@])],
1588     [enable_gallium_svga="$enableval"],
1589     [enable_gallium_svga=auto])
1590 if test "x$enable_gallium_svga" = xyes; then
1591     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1592     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1593 elif test "x$enable_gallium_svga" = xauto; then
1594     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1595 fi
1596
1597 dnl
1598 dnl Gallium i915 configuration
1599 dnl
1600 AC_ARG_ENABLE([gallium-i915],
1601     [AS_HELP_STRING([--enable-gallium-i915],
1602         [build gallium i915 @<:@default=disabled@:>@])],
1603     [enable_gallium_i915="$enableval"],
1604     [enable_gallium_i915=auto])
1605 if test "x$enable_gallium_i915" = xyes; then
1606     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1607     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1608     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1609 elif test "x$enable_gallium_i915" = xauto; then
1610     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1611     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1612 fi
1613
1614 dnl
1615 dnl Gallium i965 configuration
1616 dnl
1617 AC_ARG_ENABLE([gallium-i965],
1618     [AS_HELP_STRING([--enable-gallium-i965],
1619         [build gallium i965 @<:@default=disabled@:>@])],
1620     [enable_gallium_i965="$enableval"],
1621     [enable_gallium_i965=auto])
1622 if test "x$enable_gallium_i965" = xyes; then
1623     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1624     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1625 elif test "x$enable_gallium_i965" = xauto; then
1626     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1627 fi
1628
1629 dnl
1630 dnl Gallium Radeon r300g configuration
1631 dnl
1632 AC_ARG_ENABLE([gallium-radeon],
1633     [AS_HELP_STRING([--enable-gallium-radeon],
1634         [build gallium radeon @<:@default=disabled@:>@])],
1635     [enable_gallium_radeon="$enableval"],
1636     [enable_gallium_radeon=auto])
1637 if test "x$enable_gallium_radeon" = xauto; then
1638     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1639         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1640         gallium_check_st "radeon/drm" "dri-r300"
1641     else
1642         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1643     fi
1644 fi
1645 if test "x$enable_gallium_radeon" = xyes; then
1646     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1647         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1648         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1649     else
1650         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1651     fi
1652 fi
1653
1654 dnl
1655 dnl Gallium Radeon r600g configuration
1656 dnl
1657 AC_ARG_ENABLE([gallium-r600],
1658     [AS_HELP_STRING([--enable-gallium-r600],
1659         [build gallium radeon @<:@default=disabled@:>@])],
1660     [enable_gallium_r600="$enableval"],
1661     [enable_gallium_r600=auto])
1662 if test "x$enable_gallium_r600" = xyes; then
1663     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1664         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1665         gallium_check_st "r600/drm" "dri-r600"
1666     else
1667         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1668     fi
1669 fi
1670
1671 dnl
1672 dnl Gallium Nouveau configuration
1673 dnl
1674 AC_ARG_ENABLE([gallium-nouveau],
1675     [AS_HELP_STRING([--enable-gallium-nouveau],
1676         [build gallium nouveau @<:@default=disabled@:>@])],
1677     [enable_gallium_nouveau="$enableval"],
1678     [enable_gallium_nouveau=no])
1679 if test "x$enable_gallium_nouveau" = xyes; then
1680     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1681     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1682 fi
1683
1684 dnl
1685 dnl Gallium swrast configuration
1686 dnl
1687 AC_ARG_ENABLE([gallium-swrast],
1688     [AS_HELP_STRING([--enable-gallium-swrast],
1689         [build gallium swrast @<:@default=auto@:>@])],
1690     [enable_gallium_swrast="$enableval"],
1691     [enable_gallium_swrast=auto])
1692 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1693     if test "x$HAVE_ST_DRI" = xyes; then
1694         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1695     fi
1696 fi
1697
1698 dnl
1699 dnl Gallium noop configuration
1700 dnl
1701 AC_ARG_ENABLE([gallium-noop],
1702     [AS_HELP_STRING([--enable-gallium-noop],
1703         [build gallium radeon @<:@default=disabled@:>@])],
1704     [enable_gallium_noop="$enableval"],
1705     [enable_gallium_noop=auto])
1706 if test "x$enable_gallium_noop" = xyes; then
1707     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS noop"
1708     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-noop"
1709 fi
1710
1711 dnl prepend CORE_DIRS to SRC_DIRS
1712 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1713
1714 dnl Restore LDFLAGS and CPPFLAGS
1715 LDFLAGS="$_SAVE_LDFLAGS"
1716 CPPFLAGS="$_SAVE_CPPFLAGS"
1717
1718 dnl Substitute the config
1719 AC_CONFIG_FILES([configs/autoconf])
1720
1721 dnl Replace the configs/current symlink
1722 AC_CONFIG_COMMANDS([configs],[
1723 if test -f configs/current || test -L configs/current; then
1724     rm -f configs/current
1725 fi
1726 ln -s autoconf configs/current
1727 ])
1728
1729 AC_OUTPUT
1730
1731 dnl
1732 dnl Output some configuration info for the user
1733 dnl
1734 echo ""
1735 echo "        prefix:          $prefix"
1736 echo "        exec_prefix:     $exec_prefix"
1737 echo "        libdir:          $libdir"
1738 echo "        includedir:      $includedir"
1739
1740 dnl API info
1741 echo ""
1742 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1743 echo "        OpenVG:          $enable_openvg"
1744
1745 dnl Driver info
1746 echo ""
1747 echo "        Driver:          $mesa_driver"
1748 if test "$mesa_driver" != no; then
1749     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1750         echo "        OSMesa:          lib$OSMESA_LIB"
1751     else
1752         echo "        OSMesa:          no"
1753     fi
1754     if test "$mesa_driver" = dri; then
1755         # cleanup the drivers var
1756         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1757         if test "x$DRI_DIRS" = x; then
1758             echo "        DRI drivers:     no"
1759         else
1760             echo "        DRI drivers:     $dri_dirs"
1761         fi
1762         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1763         echo "        Use XCB:         $enable_xcb"
1764     fi
1765 fi
1766 echo ""
1767 echo "        GLU:             $enable_glu"
1768 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1769 echo "        glut:            $enable_glut"
1770
1771 dnl EGL
1772 echo ""
1773 echo "        EGL:             $enable_egl"
1774 if test "$enable_egl" = yes; then
1775     echo "        EGL platforms:   $EGL_PLATFORMS"
1776
1777     egl_drivers=""
1778     for d in $EGL_DRIVERS_DIRS; do
1779         egl_drivers="$egl_drivers builtin:egl_$d"
1780     done
1781
1782     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1783         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
1784         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
1785     else
1786         echo "        EGL drivers:    $egl_drivers"
1787     fi
1788 fi
1789
1790 echo ""
1791 if test "x$MESA_LLVM" = x1; then
1792     echo "        llvm:            yes"
1793     echo "        llvm-config:     $LLVM_CONFIG"
1794     echo "        llvm-version:    $LLVM_VERSION"
1795 else
1796     echo "        llvm:            no"
1797 fi
1798
1799 echo ""
1800 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1801     echo "        Gallium:         yes"
1802     echo "        Gallium dirs:    $GALLIUM_DIRS"
1803     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1804     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1805     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1806     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1807 else
1808     echo "        Gallium:         no"
1809 fi
1810
1811 dnl Libraries
1812 echo ""
1813 echo "        Shared libs:     $enable_shared"
1814 echo "        Static libs:     $enable_static"
1815
1816 dnl Compiler options
1817 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1818 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1819     $SED 's/^ *//;s/  */ /;s/ *$//'`
1820 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1821     $SED 's/^ *//;s/  */ /;s/ *$//'`
1822 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1823 echo ""
1824 echo "        CFLAGS:          $cflags"
1825 echo "        CXXFLAGS:        $cxxflags"
1826 echo "        Macros:          $defines"
1827 echo ""
1828 echo "        PYTHON2:         $PYTHON2"
1829
1830 echo ""
1831 echo "        Run '${MAKE-make}' to build Mesa"
1832 echo ""