configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.82
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     powerpc64le)
 770         case "$host_os" in
 771         linux*)
 772             asm_arch=ppc64le
 773             ;;
 774         esac
 775         ;;
 776     aarch64)
 777         case "$host_os" in
 778         linux*)
 779             asm_arch=aarch64
 780             ;;
 781         esac
 782         ;;
 783     arm)
 784         case "$host_os" in
 785         linux*)
 786             asm_arch=arm
 787             ;;
 788         esac
 789         ;;
 790     esac
 791
 792     case "$asm_arch" in
 793     x86)
 794         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 795         AC_MSG_RESULT([yes, x86])
 796         ;;
 797     x86_64|amd64)
 798         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 799         AC_MSG_RESULT([yes, x86_64])
 800         ;;
 801     sparc)
 802         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 803         AC_MSG_RESULT([yes, sparc])
 804         ;;
 805     ppc64le)
 806         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 807         AC_MSG_RESULT([yes, ppc64le])
 808         ;;
 809     aarch64)
 810         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 811         AC_MSG_RESULT([yes, aarch64])
 812         ;;
 813     arm)
 814         DEFINES="$DEFINES -DUSE_ARM_ASM"
 815         AC_MSG_RESULT([yes, arm])
 816         ;;
 817     *)
 818         AC_MSG_RESULT([no, platform not supported])
 819         ;;
 820     esac
 821 fi
 822
 823 AC_HEADER_MAJOR
 824 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 825 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 826 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 827 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 828
 829 dnl Check to see if dlopen is in default libraries (like Solaris, which
 830 dnl has it in libc), or if libdl is needed to get it.
 831 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 832     [AC_CHECK_LIB([dl], [dlopen],
 833        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 834 AC_SUBST([DLOPEN_LIBS])
 835
 836 dnl Check if that library also has dladdr
 837 save_LIBS="$LIBS"
 838 LIBS="$LIBS $DLOPEN_LIBS"
 839 AC_CHECK_FUNCS([dladdr])
 840 LIBS="$save_LIBS"
 841
 842 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 843
 844 case "$host_os" in
 845 darwin*)
 846     ;;
 847 *)
 848     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 849                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 850                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 851     AC_SUBST([CLOCK_LIB])
 852     ;;
 853 esac
 854
 855 dnl See if posix_memalign is available
 856 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 857
 858 dnl Check for zlib
 859 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 860
 861 dnl Check for pthreads
 862 AX_PTHREAD
 863 if test "x$ax_pthread_ok" = xno; then
 864     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 865 fi
 866 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 867 dnl to -pthread, which causes problems if we need -lpthread to appear in
 868 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 869 dnl is not valid for that platform.
 870 if test "x$android" = xno; then
 871     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 872 fi
 873 dnl According to the manual when using pthreads, one should add -pthread to
 874 dnl both compile and link-time arguments.
 875 dnl In practise that should be sufficient for all platforms, since any
 876 dnl platforms build with GCC and Clang support the flag.
 877 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 878
 879 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 880 dnl project. Even then there's a notable issue as described in the project README
 881 case "$host_os" in
 882 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 883     pthread_stubs_possible="no"
 884     ;;
 885 * )
 886     pthread_stubs_possible="yes"
 887     ;;
 888 esac
 889
 890 if test "x$pthread_stubs_possible" = xyes; then
 891     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 892 fi
 893
 894 dnl SELinux awareness.
 895 AC_ARG_ENABLE([selinux],
 896     [AS_HELP_STRING([--enable-selinux],
 897         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 898     [MESA_SELINUX="$enableval"],
 899     [MESA_SELINUX=no])
 900 if test "x$enable_selinux" = "xyes"; then
 901     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 902         [AC_CHECK_HEADER([selinux/selinux.h],[],
 903                          [AC_MSG_ERROR([SELinux headers not found])])
 904          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 905                       [AC_MSG_ERROR([SELinux library not found])])
 906          SELINUX_LIBS="-lselinux"])
 907     DEFINES="$DEFINES -DMESA_SELINUX"
 908 fi
 909 AC_SUBST([SELINUX_CFLAGS])
 910 AC_SUBST([SELINUX_LIBS])
 911
 912 dnl
 913 dnl LLVM
 914 dnl
 915 AC_ARG_ENABLE([llvm-shared-libs],
 916     [AS_HELP_STRING([--enable-llvm-shared-libs],
 917         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 918     [enable_llvm_shared_libs="$enableval"],
 919     [enable_llvm_shared_libs=yes])
 920
 921 AC_ARG_WITH([llvm-prefix],
 922     [AS_HELP_STRING([--with-llvm-prefix],
 923         [Prefix for LLVM installations in non-standard locations])],
 924     [llvm_prefix="$withval"],
 925     [llvm_prefix=''])
 926
 927 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 928 if test "x$have_libelf" = xno; then
 929    LIBELF_LIBS=''
 930    LIBELF_CFLAGS=''
 931    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 932    AC_SUBST([LIBELF_LIBS])
 933    AC_SUBST([LIBELF_CFLAGS])
 934 fi
 935
 936 if test -z "$LLVM_CONFIG"; then
 937     if test -n "$llvm_prefix"; then
 938         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 939     else
 940         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 941     fi
 942 fi
 943
 944 llvm_add_component() {
 945     new_llvm_component=$1
 946     driver_name=$2
 947
 948     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 949         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 950     else
 951         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 952     fi
 953 }
 954
 955 llvm_add_default_components() {
 956     driver_name=$1
 957
 958     # Required default components
 959     llvm_add_component "bitwriter" $driver_name
 960     llvm_add_component "engine" $driver_name
 961     llvm_add_component "mcdisassembler" $driver_name
 962     llvm_add_component "mcjit" $driver_name
 963
 964     # Optional default components
 965     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 966         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 967     fi
 968 }
 969
 970 llvm_add_target() {
 971     new_llvm_target=$1
 972     driver_name=$2
 973
 974     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 975         llvm_add_component $new_llvm_target $driver_name
 976     else
 977         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 978     fi
 979 }
 980
 981 # Call this inside ` ` to get the return value.
 982 # $1 is the llvm-config command with arguments.
 983 strip_unwanted_llvm_flags() {
 984     echo " `$1` " | sed -E \
 985         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 986         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 987         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 988         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 989         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 990         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 991         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 992         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 993         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 994         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 995         -e 's/^[[[:space:]]]//' \
 996         -e 's/[[[:space:]]]$//'
 997 }
 998
 999 llvm_set_environment_variables() {
1000     if test "x$LLVM_CONFIG" != xno; then
1001         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1002         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1003         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1004         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1005
1006         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1007         save_CFLAGS="$CFLAGS"
1008         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1009
1010         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1011             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1012         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1013             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1014         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1015             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1016
1017         CFLAGS="$save_CFLAGS"
1018
1019         # Only needed for LLVM < 3.6.0
1020         if test -z "$LLVM_VERSION_PATCH"; then
1021             LLVM_VERSION_PATCH=0
1022         fi
1023
1024         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1025
1026         FOUND_LLVM=yes
1027     else
1028         FOUND_LLVM=no
1029         LLVM_VERSION_INT=0
1030     fi
1031 }
1032
1033 require_llvm() {
1034     if test "x$enable_llvm" != "xyes"; then
1035         AC_MSG_ERROR([--enable-llvm is required when building $1])
1036     fi
1037 }
1038
1039 llvm_require_version() {
1040     require_llvm $2
1041
1042     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1043     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1044     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1045
1046     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1047         # major > required major
1048         #  --> OK
1049         return
1050     fi
1051
1052     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1053         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1054             # major = required major and
1055             # minor > required minor
1056             #  --> OK
1057             return
1058         else
1059             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1060                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1061                     # major = required major and
1062                     # minor = required minor and
1063                     # patch >= required patch
1064                     #  --> OK
1065                     return
1066                 fi
1067             fi
1068         fi
1069     fi
1070
1071     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1072 }
1073
1074 radeon_llvm_check() {
1075     if test ${LLVM_VERSION_INT} -lt 307; then
1076         amdgpu_llvm_target_name='r600'
1077     else
1078         amdgpu_llvm_target_name='amdgpu'
1079     fi
1080
1081     llvm_require_version $*
1082
1083     llvm_add_target $amdgpu_llvm_target_name $2
1084
1085     llvm_add_default_components $2
1086     llvm_add_component "bitreader" $2
1087     llvm_add_component "ipo" $2
1088
1089     if test "x$have_libelf" != xyes; then
1090        AC_MSG_ERROR([$2 requires libelf when using llvm])
1091     fi
1092 }
1093
1094 llvm_set_environment_variables
1095
1096 AC_SUBST([LLVM_CFLAGS])
1097 AC_SUBST([LLVM_CXXFLAGS])
1098 AC_SUBST([LLVM_LIBS])
1099 AC_SUBST([LLVM_LDFLAGS])
1100 AC_SUBST([LLVM_INCLUDEDIR])
1101
1102 dnl
1103 dnl libunwind
1104 dnl
1105 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1106 AC_ARG_ENABLE([libunwind],
1107     [AS_HELP_STRING([--enable-libunwind],
1108             [Use libunwind for backtracing (default: auto)])],
1109         [LIBUNWIND="$enableval"],
1110         [LIBUNWIND="$HAVE_LIBUNWIND"])
1111
1112 if test "x$LIBUNWIND" = "xyes"; then
1113     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1114     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1115 fi
1116
1117
1118 dnl Options for APIs
1119 AC_ARG_ENABLE([opengl],
1120     [AS_HELP_STRING([--disable-opengl],
1121         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1122     [enable_opengl="$enableval"],
1123     [enable_opengl=yes])
1124 AC_ARG_ENABLE([gles1],
1125     [AS_HELP_STRING([--disable-gles1],
1126         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1127     [enable_gles1="$enableval"],
1128     [enable_gles1=yes])
1129 AC_ARG_ENABLE([gles2],
1130     [AS_HELP_STRING([--disable-gles2],
1131         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1132     [enable_gles2="$enableval"],
1133     [enable_gles2=yes])
1134
1135 AC_ARG_ENABLE([dri],
1136     [AS_HELP_STRING([--enable-dri],
1137         [enable DRI modules @<:@default=enabled@:>@])],
1138     [enable_dri="$enableval"],
1139     [enable_dri=yes])
1140
1141 AC_ARG_ENABLE([gallium-extra-hud],
1142     [AS_HELP_STRING([--enable-gallium-extra-hud],
1143         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1144     [enable_gallium_extra_hud="$enableval"],
1145     [enable_gallium_extra_hud=no])
1146 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1147 if test "x$enable_gallium_extra_hud" = xyes ; then
1148     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1149 fi
1150
1151 #TODO: no pkgconfig .pc available for libsensors.
1152 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1153 AC_ARG_ENABLE([lmsensors],
1154     [AS_HELP_STRING([--enable-lmsensors],
1155         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1156     [enable_lmsensors="$enableval"],
1157     [enable_lmsensors=no])
1158 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1159 if test "x$enable_lmsensors" = xyes ; then
1160     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1161     LIBSENSORS_LIBS="-lsensors"
1162 else
1163     LIBSENSORS_LIBS=""
1164 fi
1165 AC_SUBST(LIBSENSORS_LIBS)
1166
1167 case "$host_os" in
1168 linux*)
1169     dri3_default=yes
1170     ;;
1171 *)
1172     dri3_default=no
1173     ;;
1174 esac
1175
1176 if test "x$enable_dri" = xno; then
1177     dri3_default=no
1178 fi
1179
1180 AC_ARG_ENABLE([dri3],
1181     [AS_HELP_STRING([--enable-dri3],
1182         [enable DRI3 @<:@default=auto@:>@])],
1183     [enable_dri3="$enableval"],
1184     [enable_dri3="$dri3_default"])
1185 AC_ARG_ENABLE([glx],
1186     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1187         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1188     [enable_glx="$enableval"],
1189     [enable_glx=yes])
1190 AC_ARG_ENABLE([osmesa],
1191     [AS_HELP_STRING([--enable-osmesa],
1192         [enable OSMesa library @<:@default=disabled@:>@])],
1193     [enable_osmesa="$enableval"],
1194     [enable_osmesa=no])
1195 AC_ARG_ENABLE([gallium-osmesa],
1196     [AS_HELP_STRING([--enable-gallium-osmesa],
1197         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1198     [enable_gallium_osmesa="$enableval"],
1199     [enable_gallium_osmesa=no])
1200 AC_ARG_ENABLE([egl],
1201     [AS_HELP_STRING([--disable-egl],
1202         [disable EGL library @<:@default=enabled@:>@])],
1203     [enable_egl="$enableval"],
1204     [enable_egl=yes])
1205
1206 AC_ARG_ENABLE([xa],
1207     [AS_HELP_STRING([--enable-xa],
1208         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1209     [enable_xa="$enableval"],
1210     [enable_xa=no])
1211 AC_ARG_ENABLE([gbm],
1212    [AS_HELP_STRING([--enable-gbm],
1213          [enable gbm library @<:@default=yes except cygwin@:>@])],
1214    [enable_gbm="$enableval"],
1215    [case "$host_os" in
1216        cygwin*)
1217           enable_gbm=no
1218           ;;
1219        *)
1220           enable_gbm=yes
1221           ;;
1222     esac])
1223 AC_ARG_ENABLE([nine],
1224     [AS_HELP_STRING([--enable-nine],
1225         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1226     [enable_nine="$enableval"],
1227     [enable_nine=no])
1228
1229 AC_ARG_ENABLE([xvmc],
1230    [AS_HELP_STRING([--enable-xvmc],
1231          [enable xvmc library @<:@default=auto@:>@])],
1232    [enable_xvmc="$enableval"],
1233    [enable_xvmc=auto])
1234 AC_ARG_ENABLE([vdpau],
1235    [AS_HELP_STRING([--enable-vdpau],
1236          [enable vdpau library @<:@default=auto@:>@])],
1237    [enable_vdpau="$enableval"],
1238    [enable_vdpau=auto])
1239 AC_ARG_ENABLE([omx],
1240    [AS_HELP_STRING([--enable-omx],
1241          [enable OpenMAX library @<:@default=disabled@:>@])],
1242    [enable_omx="$enableval"],
1243    [enable_omx=no])
1244 AC_ARG_ENABLE([va],
1245    [AS_HELP_STRING([--enable-va],
1246          [enable va library @<:@default=auto@:>@])],
1247    [enable_va="$enableval"],
1248    [enable_va=auto])
1249 AC_ARG_ENABLE([opencl],
1250    [AS_HELP_STRING([--enable-opencl],
1251          [enable OpenCL library @<:@default=disabled@:>@])],
1252    [enable_opencl="$enableval"],
1253    [enable_opencl=no])
1254 AC_ARG_ENABLE([opencl_icd],
1255    [AS_HELP_STRING([--enable-opencl-icd],
1256           [Build an OpenCL ICD library to be loaded by an ICD implementation
1257            @<:@default=disabled@:>@])],
1258     [enable_opencl_icd="$enableval"],
1259     [enable_opencl_icd=no])
1260
1261 AC_ARG_ENABLE([gallium-tests],
1262     [AS_HELP_STRING([--enable-gallium-tests],
1263         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1264     [enable_gallium_tests="$enableval"],
1265     [enable_gallium_tests=no])
1266
1267 # Option for Gallium drivers
1268
1269 # Keep this in sync with the --with-gallium-drivers help string default value
1270 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1271
1272 AC_ARG_WITH([gallium-drivers],
1273     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1274         [comma delimited Gallium drivers list, e.g.
1275         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1276         @<:@default=r300,r600,svga,swrast@:>@])],
1277     [with_gallium_drivers="$withval"],
1278     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1279
1280 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1281 # here so that the script doesn't choke on an unknown driver name later.
1282 case "$with_gallium_drivers" in
1283     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1284     no) with_gallium_drivers='' ;;
1285 esac
1286
1287 if test "x$enable_opengl" = xno -a \
1288         "x$enable_gles1" = xno -a \
1289         "x$enable_gles2" = xno -a \
1290         "x$enable_nine" = xno -a \
1291         "x$enable_xa" = xno -a \
1292         "x$enable_xvmc" = xno -a \
1293         "x$enable_vdpau" = xno -a \
1294         "x$enable_omx" = xno -a \
1295         "x$enable_va" = xno -a \
1296         "x$enable_opencl" = xno; then
1297     AC_MSG_ERROR([at least one API should be enabled])
1298 fi
1299
1300 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1301 if test "x$enable_opengl" = xno -a \
1302         "x$enable_gles1" = xyes; then
1303     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1304 fi
1305
1306 if test "x$enable_opengl" = xno -a \
1307         "x$enable_gles2" = xyes; then
1308     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1309 fi
1310
1311 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1312 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1313 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1314 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1315                                         "x$enable_gles1" = xyes -o \
1316                                         "x$enable_gles2" = xyes)
1317 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1318                                       "x$enable_gles1" = xyes -o \
1319                                       "x$enable_gles2" = xyes)
1320
1321 # Validate GLX options
1322 if test "x$enable_glx" = xyes; then
1323     if test "x$enable_dri" = xyes; then
1324         enable_glx=dri
1325     elif test -n "$with_gallium_drivers"; then
1326         enable_glx=gallium-xlib
1327     else
1328         enable_glx=xlib
1329     fi
1330 fi
1331 case "x$enable_glx" in
1332 xdri | xxlib | xgallium-xlib)
1333     # GLX requires OpenGL
1334     if test "x$enable_opengl" = xno; then
1335         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1336     fi
1337
1338     # Check individual dependencies
1339     case "x$enable_glx" in
1340     xdri)
1341         if test "x$enable_dri" = xno; then
1342             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1343         fi
1344         ;;
1345     xxlib)
1346         if test "x$enable_dri" = xyes; then
1347             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1348         fi
1349         ;;
1350     xgallium-xlib )
1351         if test "x$enable_dri" = xyes; then
1352             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1353         fi
1354         if test -z "$with_gallium_drivers"; then
1355             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1356         fi
1357         ;;
1358     esac
1359     ;;
1360 xno)
1361     ;;
1362 *)
1363     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1364     ;;
1365 esac
1366
1367 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1368 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1369 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1370 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1371
1372 DEFAULT_GL_LIB_NAME=GL
1373
1374 dnl
1375 dnl Libglvnd configuration
1376 dnl
1377 AC_ARG_ENABLE([libglvnd],
1378     [AS_HELP_STRING([--enable-libglvnd],
1379         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1380     [enable_libglvnd="$enableval"],
1381     [enable_libglvnd=no])
1382 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1383
1384 if test "x$enable_libglvnd" = xyes ; then
1385     dnl XXX: update once we can handle more than libGL/glx.
1386     dnl Namely: we should error out if neither of the glvnd enabled libraries
1387     dnl are built
1388     case "x$enable_glx" in
1389     xno)
1390         AC_MSG_ERROR([cannot build libglvnd without GLX])
1391         ;;
1392     xxlib | xgallium-xlib )
1393         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1394         ;;
1395     xdri)
1396         ;;
1397     esac
1398
1399     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1400     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1401     AC_SUBST([LIBGLVND_DATADIR])
1402
1403     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1404     DEFAULT_GL_LIB_NAME=GLX_mesa
1405 fi
1406
1407 AC_ARG_WITH([gl-lib-name],
1408   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1409     [specify GL library name @<:@default=GL@:>@])],
1410   [GL_LIB=$withval],
1411   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1412 AC_ARG_WITH([osmesa-lib-name],
1413   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1414     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1415   [OSMESA_LIB=$withval],
1416   [OSMESA_LIB=OSMesa])
1417 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1418 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1419
1420 dnl
1421 dnl Mangled Mesa support
1422 dnl
1423 AC_ARG_ENABLE([mangling],
1424   [AS_HELP_STRING([--enable-mangling],
1425     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1426   [enable_mangling="${enableval}"],
1427   [enable_mangling=no]
1428 )
1429 if test "x${enable_mangling}" = "xyes" ; then
1430   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1431   GL_LIB="Mangled${GL_LIB}"
1432   OSMESA_LIB="Mangled${OSMESA_LIB}"
1433 fi
1434 AC_SUBST([GL_LIB])
1435 AC_SUBST([OSMESA_LIB])
1436
1437 # Check for libdrm
1438 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1439                   [have_libdrm=yes], [have_libdrm=no])
1440 if test "x$have_libdrm" = xyes; then
1441     DEFINES="$DEFINES -DHAVE_LIBDRM"
1442 fi
1443
1444 require_libdrm() {
1445     if test "x$have_libdrm" != xyes; then
1446        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1447     fi
1448 }
1449
1450
1451 # Select which platform-dependent DRI code gets built
1452 case "$host_os" in
1453 darwin*)
1454     dri_platform='apple' ;;
1455 cygwin*)
1456     dri_platform='windows' ;;
1457 gnu*)
1458     dri_platform='none' ;;
1459 *)
1460     dri_platform='drm' ;;
1461 esac
1462
1463 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1464     have_drisw_kms='yes'
1465 fi
1466
1467 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1468 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1469 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1470 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1471 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1472 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1473 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1474 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1475 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1476
1477 AC_ARG_ENABLE([shared-glapi],
1478     [AS_HELP_STRING([--enable-shared-glapi],
1479         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1480     [enable_shared_glapi="$enableval"],
1481     [enable_shared_glapi=yes])
1482
1483 case "x$enable_opengl$enable_gles1$enable_gles2" in
1484 x*yes*yes*)
1485     if test "x$enable_shared_glapi" = xno; then
1486         AC_MSG_ERROR([shared GLAPI required when building two or more of
1487                       the following APIs - opengl, gles1 gles2])
1488     fi
1489     ;;
1490 esac
1491
1492 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1493
1494 # Build the pipe-drivers as separate libraries/modules.
1495 # Do not touch this unless you know what you are doing.
1496 # XXX: Expose via configure option ?
1497 enable_shared_pipe_drivers=no
1498
1499 dnl
1500 dnl Driver specific build directories
1501 dnl
1502
1503 if test "x$enable_gallium_osmesa" = xyes; then
1504     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1505         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1506     fi
1507     if test "x$enable_osmesa" = xyes; then
1508         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1509     fi
1510 fi
1511
1512 require_dri_shared_libs_and_glapi() {
1513     if test "x$enable_static" = xyes; then
1514         AC_MSG_ERROR([$1 cannot be build as static library])
1515     fi
1516
1517     if test "x$enable_dri" != xyes; then
1518         # There is only a single backend which won't be build/used otherwise.
1519         # XXX: Revisit this as the egl/haiku is a thing.
1520         AC_MSG_ERROR([$1 requires --enable-dri])
1521     fi
1522
1523     if test "x$enable_shared_glapi" != xyes; then
1524         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1525     fi
1526 }
1527
1528 if test "x$enable_dri" = xyes; then
1529     require_dri_shared_libs_and_glapi "DRI"
1530
1531     # not a hard requirement as swrast does not depend on it
1532     if test "x$have_libdrm" = xyes; then
1533         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1534     fi
1535 fi
1536
1537 AC_ARG_ENABLE([driglx-direct],
1538     [AS_HELP_STRING([--disable-driglx-direct],
1539         [disable direct rendering in GLX and EGL for DRI \
1540             @<:@default=auto@:>@])],
1541     [driglx_direct="$enableval"],
1542     [driglx_direct="yes"])
1543
1544 dnl
1545 dnl libGL configuration per driver
1546 dnl
1547 if test "x$enable_glx" != xno; then
1548     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1549 fi
1550 case "x$enable_glx" in
1551 xxlib | xgallium-xlib)
1552     # Xlib-based GLX
1553     dri_modules="x11 xext xcb"
1554     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1555     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1556     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1557     GL_LIB_DEPS="$XLIBGL_LIBS"
1558     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1559     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1560     ;;
1561 xdri)
1562     # DRI-based GLX
1563
1564     # find the DRI deps for libGL
1565     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1566
1567     if test x"$driglx_direct" = xyes; then
1568         if test x"$dri_platform" = xdrm ; then
1569             DEFINES="$DEFINES -DGLX_USE_DRM"
1570             require_libdrm "Direct rendering"
1571
1572             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1573             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1574
1575             if test x"$enable_dri" = xyes; then
1576                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1577             fi
1578         fi
1579         if test x"$dri_platform" = xapple ; then
1580             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1581         fi
1582         if test x"$dri_platform" = xwindows ; then
1583             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1584         fi
1585     fi
1586
1587     # add xf86vidmode if available
1588     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1589     if test "$HAVE_XF86VIDMODE" = yes ; then
1590         dri_modules="$dri_modules xxf86vm"
1591     fi
1592
1593     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1594     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1595     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1596     GL_LIB_DEPS="$DRIGL_LIBS"
1597
1598     # need DRM libs, $PTHREAD_LIBS, etc.
1599     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1600     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1601     ;;
1602 esac
1603
1604 # This is outside the case (above) so that it is invoked even for non-GLX
1605 # builds.
1606 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1607
1608 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1609 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1610 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1611 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1612
1613 AC_SUBST([X11_INCLUDES])
1614 AC_SUBST([GL_LIB_DEPS])
1615 AC_SUBST([GL_PC_REQ_PRIV])
1616 AC_SUBST([GL_PC_LIB_PRIV])
1617 AC_SUBST([GL_PC_CFLAGS])
1618 AC_SUBST([DRI_PC_REQ_PRIV])
1619 AC_SUBST([GLESv1_CM_LIB_DEPS])
1620 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1621 AC_SUBST([GLESv2_LIB_DEPS])
1622 AC_SUBST([GLESv2_PC_LIB_PRIV])
1623
1624 AC_SUBST([HAVE_XF86VIDMODE])
1625
1626 dnl
1627 dnl More GLX setup
1628 dnl
1629 case "x$enable_glx" in
1630 xxlib | xgallium-xlib)
1631     DEFINES="$DEFINES -DUSE_XSHM"
1632     ;;
1633 xdri)
1634     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1635     if test "x$driglx_direct" = xyes; then
1636         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1637     fi
1638     ;;
1639 esac
1640
1641 dnl
1642 dnl TLS detection
1643 dnl
1644
1645 AC_ARG_ENABLE([glx-tls],
1646     [AS_HELP_STRING([--enable-glx-tls],
1647         [enable TLS support in GLX @<:@default=enabled@:>@])],
1648     [GLX_USE_TLS="$enableval"],
1649     [GLX_USE_TLS=yes])
1650 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1651
1652 if test "x$GLX_USE_TLS" = xyes; then
1653     DEFINES="$DEFINES -DGLX_USE_TLS"
1654 fi
1655
1656 dnl Read-only text section on x86 hardened platforms
1657 AC_ARG_ENABLE([glx-read-only-text],
1658     [AS_HELP_STRING([--enable-glx-read-only-text],
1659         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1660     [enable_glx_read_only_text="$enableval"],
1661     [enable_glx_read_only_text=no])
1662 if test "x$enable_glx_read_only_text" = xyes; then
1663     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1664 fi
1665
1666 dnl
1667 dnl DEPRECATED: EGL Platforms configuration
1668 dnl
1669 AC_ARG_WITH([egl-platforms],
1670     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1671         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1672     [with_egl_platforms="$withval"],
1673     [with_egl_platforms=auto])
1674
1675 if test "x$with_egl_platforms" = xauto; then
1676     with_egl_platforms="x11,surfaceless"
1677     if test "x$enable_gbm" = xyes; then
1678         with_egl_platforms="$with_egl_platforms,drm"
1679     fi
1680 else
1681     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1682 fi
1683
1684 dnl
1685 dnl Platforms configuration
1686 dnl
1687 AC_ARG_WITH([platforms],
1688     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1689         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1690         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1691     [with_platforms="$withval"],
1692     [with_platforms=auto])
1693
1694 # Reuse the autodetection rather than duplicating it.
1695 if test "x$with_platforms" = xauto; then
1696     with_platforms=$with_egl_platforms
1697 fi
1698
1699 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1700         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1701         WAYLAND_SCANNER='')
1702 if test "x$WAYLAND_SCANNER" = x; then
1703     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1704 fi
1705
1706 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1707 if test "x$have_wayland_protocols" = xyes; then
1708     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1709 fi
1710 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1711
1712 # Do per platform setups and checks
1713 platforms=`IFS=', '; echo $with_platforms`
1714 for plat in $platforms; do
1715     case "$plat" in
1716     wayland)
1717
1718         PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1719
1720         if test "x$WAYLAND_SCANNER" = "x:"; then
1721                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1722         fi
1723         if test "x$have_wayland_protocols" = xno; then
1724                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1725         fi
1726         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1727         ;;
1728
1729     x11)
1730         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1731         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1732         ;;
1733
1734     drm)
1735         test "x$enable_gbm" = "xno" &&
1736                 AC_MSG_ERROR([EGL platform drm needs gbm])
1737         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1738         ;;
1739
1740     surfaceless)
1741         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1742         ;;
1743
1744     android)
1745         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1746         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1747         ;;
1748
1749     *)
1750         AC_MSG_ERROR([platform '$plat' does not exist])
1751         ;;
1752     esac
1753
1754     case "$plat" in
1755     wayland|drm|surfaceless)
1756         require_libdrm "Platform $plat"
1757         ;;
1758     esac
1759 done
1760
1761 if test "x$enable_glx" != xno; then
1762     if ! echo "$platforms" | grep -q 'x11'; then
1763         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1764     fi
1765 fi
1766
1767 if test x"$enable_dri3" = xyes; then
1768     DEFINES="$DEFINES -DHAVE_DRI3"
1769
1770     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1771     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1772 fi
1773
1774 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1775 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1776 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1777 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1778 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1779
1780 dnl
1781 dnl More DRI setup
1782 dnl
1783 dnl Directory for DRI drivers
1784 AC_ARG_WITH([dri-driverdir],
1785     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1786         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1787     [DRI_DRIVER_INSTALL_DIR="$withval"],
1788     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1789 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1790 dnl Extra search path for DRI drivers
1791 AC_ARG_WITH([dri-searchpath],
1792     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1793         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1794     [DRI_DRIVER_SEARCH_DIR="$withval"],
1795     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1796 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1797 dnl Which drivers to build - default is chosen by platform
1798 AC_ARG_WITH([dri-drivers],
1799     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1800         [comma delimited classic DRI drivers list, e.g.
1801         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1802     [with_dri_drivers="$withval"],
1803     [with_dri_drivers=auto])
1804
1805 if test "x$with_dri_drivers" = xauto; then
1806     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1807         with_dri_drivers="yes"
1808     else
1809         with_dri_drivers="no"
1810     fi
1811 fi
1812 if test "x$with_dri_drivers" = xno; then
1813     with_dri_drivers=''
1814 fi
1815
1816 # Check for expat
1817 PKG_CHECK_MODULES([EXPAT], [expat])
1818
1819 dnl If $with_dri_drivers is yes, drivers will be added through
1820 dnl platform checks. Set DEFINES and LIB_DEPS
1821 if test "x$enable_dri" = xyes; then
1822     # Platform specific settings and drivers to build
1823     case "$host_os" in
1824     linux*)
1825         case "$host_cpu" in
1826         powerpc* | sparc*)
1827             # Build only the drivers for cards that exist on PowerPC/sparc
1828             if test "x$with_dri_drivers" = "xyes"; then
1829                 with_dri_drivers="r200 radeon swrast"
1830             fi
1831             ;;
1832         esac
1833         ;;
1834     cygwin*)
1835         if test "x$with_dri_drivers" = "xyes"; then
1836             with_dri_drivers="swrast"
1837         fi
1838         ;;
1839     darwin*)
1840         DEFINES="$DEFINES -DBUILDING_MESA"
1841         if test "x$with_dri_drivers" = "xyes"; then
1842             with_dri_drivers="swrast"
1843         fi
1844         ;;
1845     esac
1846
1847     # default drivers
1848     if test "x$with_dri_drivers" = "xyes"; then
1849         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1850     fi
1851
1852     # put all the necessary libs together
1853     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1854 fi
1855
1856 AC_SUBST([DRI_LIB_DEPS])
1857
1858 DRI_DIRS=''
1859 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1860 if test -n "$with_dri_drivers"; then
1861     if test "x$enable_opengl" != xyes; then
1862         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1863     fi
1864
1865     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1866     for driver in $dri_drivers; do
1867         DRI_DIRS="$DRI_DIRS $driver"
1868         case "x$driver" in
1869         xi915)
1870             require_libdrm "i915"
1871             HAVE_I915_DRI=yes
1872             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1873             ;;
1874         xi965)
1875             require_libdrm "i965"
1876             HAVE_I965_DRI=yes
1877             ;;
1878         xnouveau)
1879             require_libdrm "nouveau"
1880             HAVE_NOUVEAU_DRI=yes
1881             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1882             ;;
1883         xradeon)
1884             require_libdrm "radeon"
1885             HAVE_RADEON_DRI=yes;
1886             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1887             ;;
1888         xr200)
1889             require_libdrm "r200"
1890             HAVE_R200_DRI=yes
1891             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1892             ;;
1893         xswrast)
1894             HAVE_SWRAST_DRI=yes
1895             ;;
1896         *)
1897             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1898             ;;
1899         esac
1900     done
1901     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1902 fi
1903
1904
1905 dnl
1906 dnl Gallium LLVM
1907 dnl Deprecated: kept for backwards compatibility
1908 dnl
1909 AC_ARG_ENABLE([gallium-llvm],
1910     [AS_HELP_STRING([--enable-gallium-llvm],
1911         [DEPRECATED: use --enable-llvm instead])],
1912     [enable_gallium_llvm="$enableval"],
1913     [enable_gallium_llvm=auto])
1914
1915 if test "x$enable_gallium_llvm" != xauto; then
1916    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1917    enable_llvm=$enable_gallium_llvm
1918 fi
1919
1920 dnl
1921 dnl LLVM
1922 dnl
1923 AC_ARG_ENABLE([llvm],
1924     [AS_HELP_STRING([--enable-llvm],
1925         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1926     [enable_llvm="$enableval"],
1927     [enable_llvm=auto])
1928
1929 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1930     if test "x$FOUND_LLVM" = xyes; then
1931         case "$host_cpu" in
1932         i*86|x86_64|amd64) enable_llvm=yes;;
1933         *) enable_llvm=no;;
1934         esac
1935     else
1936         enable_llvm=no
1937     fi
1938 fi
1939
1940 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1941     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1942 fi
1943
1944 #
1945 # Vulkan driver configuration
1946 #
1947
1948 AC_ARG_WITH([vulkan-drivers],
1949     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1950         [comma delimited Vulkan drivers list, e.g.
1951         "intel,radeon"
1952         @<:@default=no@:>@])],
1953     [with_vulkan_drivers="$withval"],
1954     [with_vulkan_drivers="no"])
1955
1956 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1957 # here so that the script doesn't choke on an unknown driver name later.
1958 case "x$with_vulkan_drivers" in
1959     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1960     xno) with_vulkan_drivers='' ;;
1961 esac
1962
1963 AC_ARG_WITH([vulkan-icddir],
1964     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1965         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1966     [VULKAN_ICD_INSTALL_DIR="$withval"],
1967     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1968 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1969
1970 require_x11_dri3() {
1971     if echo "$platforms" | grep -q 'x11'; then
1972         if test "x$enable_dri3" != xyes; then
1973             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1974         fi
1975     fi
1976 }
1977
1978 if test -n "$with_vulkan_drivers"; then
1979     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1980         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1981     fi
1982
1983     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1984     for driver in $VULKAN_DRIVERS; do
1985         case "x$driver" in
1986         xintel)
1987             require_libdrm "ANV"
1988             require_x11_dri3 "ANV"
1989             HAVE_INTEL_VULKAN=yes
1990             ;;
1991         xradeon)
1992             require_libdrm "radv"
1993             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1994             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1995             require_x11_dri3 "radv"
1996             HAVE_RADEON_VULKAN=yes
1997             ;;
1998         *)
1999             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2000             ;;
2001         esac
2002     done
2003     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2004 fi
2005
2006
2007 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2008 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2009 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2010                                   "x$enable_osmesa" = xyes -o \
2011                                   -n "$DRI_DIRS")
2012
2013 dnl
2014 dnl OSMesa configuration
2015 dnl
2016
2017 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2018 AC_ARG_WITH([osmesa-bits],
2019     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2020         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2021     [osmesa_bits="$withval"],
2022     [osmesa_bits=8])
2023 if test "x$osmesa_bits" != x8; then
2024     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2025         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2026         osmesa_bits=8
2027     fi
2028 fi
2029 case "x$osmesa_bits" in
2030 x8)
2031     OSMESA_LIB="${OSMESA_LIB}"
2032     ;;
2033 x16|x32)
2034     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2035     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2036     ;;
2037 *)
2038     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2039     ;;
2040 esac
2041
2042 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2043     # only link libraries with osmesa if shared
2044     if test "$enable_static" = no; then
2045         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2046     else
2047         OSMESA_LIB_DEPS=""
2048     fi
2049     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2050 fi
2051
2052 AC_SUBST([OSMESA_LIB_DEPS])
2053 AC_SUBST([OSMESA_PC_REQ])
2054 AC_SUBST([OSMESA_PC_LIB_PRIV])
2055
2056 dnl
2057 dnl gbm configuration
2058 dnl
2059 if test "x$enable_gbm" = xyes; then
2060     require_dri_shared_libs_and_glapi "gbm"
2061 fi
2062 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2063 # FINISHME: GBM has a number of dependencies which we should add below
2064 GBM_PC_REQ_PRIV=""
2065 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2066 AC_SUBST([GBM_PC_REQ_PRIV])
2067 AC_SUBST([GBM_PC_LIB_PRIV])
2068
2069 dnl
2070 dnl EGL configuration
2071 dnl
2072
2073 if test "x$enable_egl" = xyes; then
2074     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2075
2076     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2077
2078     require_dri_shared_libs_and_glapi "egl"
2079 fi
2080 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2081 AC_SUBST([EGL_LIB_DEPS])
2082
2083 gallium_st="mesa"
2084
2085 dnl
2086 dnl XA configuration
2087 dnl
2088 if test "x$enable_xa" = xyes; then
2089     if test "x$with_gallium_drivers" = xswrast; then
2090        AC_MSG_ERROR([
2091           Building xa requires at least one non swrast gallium driver.
2092           If you are looking to use libxatracker.so with the VMware driver,
2093           make sure to include svga in the gallium drivers list, apart from
2094           enabling XA.
2095           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2096     fi
2097     gallium_st="$gallium_st xa"
2098 fi
2099 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2100
2101 if echo $platforms | grep -q "x11"; then
2102     have_xvmc_platform=yes
2103 else
2104     have_xvmc_platform=no
2105 fi
2106
2107 if echo $platforms | grep -q "x11"; then
2108     have_vdpau_platform=yes
2109 else
2110     have_vdpau_platform=no
2111 fi
2112
2113 if echo $platforms | grep -q "x11\|drm"; then
2114     have_omx_platform=yes
2115 else
2116     have_omx_platform=no
2117 fi
2118
2119 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2120     have_va_platform=yes
2121 else
2122     have_va_platform=no
2123 fi
2124
2125 dnl
2126 dnl Gallium G3DVL configuration
2127 dnl
2128 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2129     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2130         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2131     fi
2132
2133     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2134         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2135     fi
2136
2137     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2138         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2139     fi
2140
2141     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2142         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2143     fi
2144 fi
2145
2146 if test "x$enable_dri" = xyes -o \
2147         "x$enable_xvmc" = xyes -o \
2148         "x$enable_vdpau" = xyes -o \
2149         "x$enable_omx" = xyes -o \
2150         "x$enable_va" = xyes; then
2151     need_gallium_vl=yes
2152 fi
2153 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2154
2155 if test "x$enable_xvmc" = xyes -o \
2156         "x$enable_vdpau" = xyes -o \
2157         "x$enable_omx" = xyes -o \
2158         "x$enable_va" = xyes; then
2159     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2160     need_gallium_vl_winsys=yes
2161 fi
2162 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2163
2164 if test "x$enable_xvmc" = xyes; then
2165     if test "x$have_xvmc_platform" != xyes; then
2166         AC_MSG_ERROR([XVMC requires the x11 platforms])
2167     fi
2168     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2169     gallium_st="$gallium_st xvmc"
2170 fi
2171 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2172
2173 if test "x$enable_vdpau" = xyes; then
2174     if test "x$have_vdpau_platform" != xyes; then
2175         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2176     fi
2177     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2178     gallium_st="$gallium_st vdpau"
2179     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2180 fi
2181 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2182
2183 if test "x$enable_omx" = xyes; then
2184     if test "x$have_omx_platform" != xyes; then
2185         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2186     fi
2187     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2188     gallium_st="$gallium_st omx"
2189 fi
2190 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2191
2192 if test "x$enable_va" = xyes; then
2193     if test "x$have_va_platform" != xyes; then
2194         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2195     fi
2196     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2197     gallium_st="$gallium_st va"
2198 fi
2199 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2200
2201 dnl
2202 dnl Nine Direct3D9 configuration
2203 dnl
2204 if test "x$enable_nine" = xyes; then
2205     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2206         AC_MSG_ERROR([nine requires the gallium swrast driver])
2207     fi
2208     if test "x$with_gallium_drivers" = xswrast; then
2209         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2210     fi
2211     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2212         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2213     fi
2214
2215     if test "x$enable_dri3" = xno; then
2216         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2217     fi
2218
2219     gallium_st="$gallium_st nine"
2220 fi
2221 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2222
2223 dnl
2224 dnl OpenCL configuration
2225 dnl
2226
2227 AC_ARG_WITH([clang-libdir],
2228    [AS_HELP_STRING([--with-clang-libdir],
2229          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2230    [CLANG_LIBDIR="$withval"],
2231    [CLANG_LIBDIR=''])
2232
2233 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2234
2235 if test "x$enable_opencl" = xyes; then
2236     if test -z "$with_gallium_drivers"; then
2237         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2238     fi
2239
2240     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2241         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2242     fi
2243
2244     if test "x$have_libclc" = xno; then
2245         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2246                     Make sure the directory containing libclc.pc is specified in your
2247                     PKG_CONFIG_PATH environment variable.
2248                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2249     else
2250         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2251         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2252         AC_SUBST([LIBCLC_INCLUDEDIR])
2253         AC_SUBST([LIBCLC_LIBEXECDIR])
2254     fi
2255
2256     gallium_st="$gallium_st clover"
2257
2258     if test "x$enable_opencl_icd" = xyes; then
2259         OPENCL_LIBNAME="MesaOpenCL"
2260     else
2261         OPENCL_LIBNAME="OpenCL"
2262     fi
2263
2264     if test "x$have_libelf" != xyes; then
2265        AC_MSG_ERROR([Clover requires libelf])
2266     fi
2267
2268     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2269         altivec_enabled=no
2270         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2271         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2272         #error "AltiVec not enabled"
2273         #endif
2274         ])], altivec_enabled=yes)
2275
2276         if test "$altivec_enabled" = yes; then
2277             CLOVER_STD_OVERRIDE="-std=gnu++11"
2278         fi
2279         AC_SUBST([CLOVER_STD_OVERRIDE])
2280     fi
2281
2282     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2283
2284     llvm_add_default_components "opencl"
2285     llvm_add_component "all-targets" "opencl"
2286     llvm_add_component "linker" "opencl"
2287     llvm_add_component "instrumentation" "opencl"
2288     llvm_add_component "ipo" "opencl"
2289     llvm_add_component "irreader" "opencl"
2290     llvm_add_component "option" "opencl"
2291     llvm_add_component "objcarcopts" "opencl"
2292     llvm_add_component "profiledata" "opencl"
2293
2294     dnl Check for Clang internal headers
2295     if test -z "$CLANG_LIBDIR"; then
2296         CLANG_LIBDIR=${LLVM_LIBDIR}
2297     fi
2298     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2299     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2300         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2301 fi
2302 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2303 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2304 AC_SUBST([OPENCL_LIBNAME])
2305 AC_SUBST([CLANG_RESOURCE_DIR])
2306
2307 dnl
2308 dnl Gallium configuration
2309 dnl
2310 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2311
2312 # libEGL wants to default to the first platform specified in
2313 # ./configure.  parse that here.
2314 if test "x$platforms" != "x"; then
2315     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2316     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2317 else
2318     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2319 fi
2320
2321 AC_SUBST([EGL_NATIVE_PLATFORM])
2322 AC_SUBST([EGL_CFLAGS])
2323
2324 # If we don't have the X11 platform, set this define so we don't try to include
2325 # the X11 headers.
2326 if ! echo "$platforms" | grep -q 'x11'; then
2327     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2328     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2329 fi
2330
2331 dnl Directory for XVMC libs
2332 AC_ARG_WITH([xvmc-libdir],
2333     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2334         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2335     [XVMC_LIB_INSTALL_DIR="$withval"],
2336     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2337 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2338
2339 dnl
2340 dnl Gallium Tests
2341 dnl
2342 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2343
2344 dnl Directory for VDPAU libs
2345 AC_ARG_WITH([vdpau-libdir],
2346     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2347         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2348     [VDPAU_LIB_INSTALL_DIR="$withval"],
2349     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2350 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2351
2352 dnl Directory for OMX libs
2353
2354 AC_ARG_WITH([omx-libdir],
2355     [AS_HELP_STRING([--with-omx-libdir=DIR],
2356         [directory for the OMX libraries])],
2357     [OMX_LIB_INSTALL_DIR="$withval"],
2358     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2359                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2360 AC_SUBST([OMX_LIB_INSTALL_DIR])
2361
2362 dnl Directory for VA libs
2363
2364 AC_ARG_WITH([va-libdir],
2365     [AS_HELP_STRING([--with-va-libdir=DIR],
2366         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2367     [VA_LIB_INSTALL_DIR="$withval"],
2368     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2369 AC_SUBST([VA_LIB_INSTALL_DIR])
2370
2371 AC_ARG_WITH([d3d-libdir],
2372     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2373         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2374     [D3D_DRIVER_INSTALL_DIR="$withval"],
2375     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2376 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2377
2378 dnl Architectures to build SWR library for
2379
2380 AC_ARG_WITH([swr-archs],
2381     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2382         [comma delimited swr architectures list, e.g.
2383         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2384     [with_swr_archs="$withval"],
2385     [with_swr_archs="avx,avx2"])
2386
2387 dnl
2388 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2389 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2390 dnl architectures.
2391 dnl
2392 r300_require_llvm() {
2393     case "$host" in *gnux32) return;; esac
2394     case "$host_cpu" in
2395     i*86|x86_64|amd64) require_llvm $1
2396         ;;
2397     esac
2398 }
2399
2400 dnl
2401 dnl DRM is needed by X, Wayland, and offscreen rendering.
2402 dnl Surfaceless is an alternative for the last one.
2403 dnl
2404 require_basic_egl() {
2405     case "$with_platforms" in
2406         *drm*|*surfaceless*)
2407             ;;
2408         *)
2409             AC_MSG_ERROR([$1 requires one of these:
2410                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2411                   2) --with-platforms=surfaceless (offscreen only)
2412                   Recommended options: drm,x11])
2413             ;;
2414     esac
2415 }
2416
2417 swr_require_cxx_feature_flags() {
2418     feature_name="$1"
2419     preprocessor_test="$2"
2420     option_list="$3"
2421     output_var="$4"
2422
2423     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2424     AC_LANG_PUSH([C++])
2425     save_CXXFLAGS="$CXXFLAGS"
2426     save_IFS="$IFS"
2427     IFS=","
2428     found=0
2429     for opts in $option_list
2430     do
2431         unset IFS
2432         CXXFLAGS="$opts $save_CXXFLAGS"
2433         AC_COMPILE_IFELSE(
2434             [AC_LANG_PROGRAM(
2435                 [   #if !($preprocessor_test)
2436                     #error
2437                     #endif
2438                 ])],
2439             [found=1; break],
2440             [])
2441         IFS=","
2442     done
2443     IFS="$save_IFS"
2444     CXXFLAGS="$save_CXXFLAGS"
2445     AC_LANG_POP([C++])
2446     if test $found -eq 1; then
2447         AC_MSG_RESULT([$opts])
2448         eval "$output_var=\$opts"
2449         return 0
2450     fi
2451     AC_MSG_RESULT([no])
2452     AC_MSG_ERROR([swr requires $feature_name support])
2453     return 1
2454 }
2455
2456 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2457 if test -n "$with_gallium_drivers"; then
2458     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2459     for driver in $gallium_drivers; do
2460         case "x$driver" in
2461         xsvga)
2462             HAVE_GALLIUM_SVGA=yes
2463             require_libdrm "svga"
2464             ;;
2465         xi915)
2466             HAVE_GALLIUM_I915=yes
2467             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2468             require_libdrm "Gallium i915"
2469             ;;
2470         xr300)
2471             HAVE_GALLIUM_R300=yes
2472             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2473             require_libdrm "r300"
2474             r300_require_llvm "r300"
2475             ;;
2476         xr600)
2477             HAVE_GALLIUM_R600=yes
2478             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2479             require_libdrm "r600"
2480             if test "x$enable_llvm" = xyes; then
2481                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2482
2483                 llvm_add_component "asmparser" "r600"
2484                 llvm_add_component "bitreader" "r600"
2485             fi
2486             ;;
2487         xradeonsi)
2488             HAVE_GALLIUM_RADEONSI=yes
2489             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2490             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2491             require_libdrm "radeonsi"
2492             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2493             if test "x$enable_egl" = xyes; then
2494                 require_basic_egl "radeonsi"
2495             fi
2496             ;;
2497         xnouveau)
2498             HAVE_GALLIUM_NOUVEAU=yes
2499             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2500             require_libdrm "nouveau"
2501             ;;
2502         xfreedreno)
2503             HAVE_GALLIUM_FREEDRENO=yes
2504             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2505             require_libdrm "freedreno"
2506             ;;
2507         xetnaviv)
2508             HAVE_GALLIUM_ETNAVIV=yes
2509             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2510             require_libdrm "etnaviv"
2511             ;;
2512        ximx)
2513             HAVE_GALLIUM_IMX=yes
2514             ;;
2515         xswrast)
2516             HAVE_GALLIUM_SOFTPIPE=yes
2517             if test "x$enable_llvm" = xyes; then
2518                 HAVE_GALLIUM_LLVMPIPE=yes
2519             fi
2520             ;;
2521         xswr)
2522             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2523
2524             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2525                 ",-std=c++11" \
2526                 SWR_CXX11_CXXFLAGS
2527             AC_SUBST([SWR_CXX11_CXXFLAGS])
2528
2529             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2530                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2531                 SWR_AVX_CXXFLAGS
2532             AC_SUBST([SWR_AVX_CXXFLAGS])
2533
2534             swr_archs=`IFS=', '; echo $with_swr_archs`
2535             for arch in $swr_archs; do
2536                 case "x$arch" in
2537                 xavx)
2538                     HAVE_SWR_AVX=yes
2539                     ;;
2540                 xavx2)
2541                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2542                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2543                         SWR_AVX2_CXXFLAGS
2544                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2545                     HAVE_SWR_AVX2=yes
2546                     ;;
2547                 xknl)
2548                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2549                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2550                         SWR_KNL_CXXFLAGS
2551                     AC_SUBST([SWR_KNL_CXXFLAGS])
2552                     HAVE_SWR_KNL=yes
2553                     ;;
2554                 xskx)
2555                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2556                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2557                         SWR_SKX_CXXFLAGS
2558                     AC_SUBST([SWR_SKX_CXXFLAGS])
2559                     HAVE_SWR_SKX=yes
2560                     ;;
2561                 *)
2562                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2563                     ;;
2564                 esac
2565             done
2566
2567             if test "x$HAVE_SWR_AVX" != xyes -a \
2568                     "x$HAVE_SWR_AVX2" != xyes -a \
2569                     "x$HAVE_SWR_KNL" != xyes -a \
2570                     "x$HAVE_SWR_SKX" != xyes; then
2571                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2572             fi
2573
2574             HAVE_GALLIUM_SWR=yes
2575             ;;
2576         xvc4)
2577             HAVE_GALLIUM_VC4=yes
2578             require_libdrm "vc4"
2579
2580             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2581                               [USE_VC4_SIMULATOR=yes;
2582                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2583                               [USE_VC4_SIMULATOR=no])
2584             ;;
2585         xpl111)
2586             HAVE_GALLIUM_PL111=yes
2587             ;;
2588         xvirgl)
2589             HAVE_GALLIUM_VIRGL=yes
2590             require_libdrm "virgl"
2591             if test "x$enable_egl" = xyes; then
2592                 require_basic_egl "virgl"
2593             fi
2594             ;;
2595         *)
2596             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2597             ;;
2598         esac
2599     done
2600 fi
2601
2602 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2603 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2604                                               "x$LLVM_VERSION" != x3.9.1)
2605
2606 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2607     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2608     llvm_add_default_components "gallium"
2609 fi
2610
2611 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2612 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2613 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2614 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2615
2616 dnl We need to validate some needed dependencies for renderonly drivers.
2617
2618 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2619     AC_MSG_ERROR([Building with imx requires etnaviv])
2620 fi
2621
2622 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2623     AC_MSG_ERROR([Building with pl111 requires vc4])
2624 fi
2625
2626 dnl
2627 dnl Set defines and buildtime variables only when using LLVM.
2628 dnl
2629 if test "x$enable_llvm" = xyes; then
2630     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2631
2632     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2633     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2634     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2635
2636     dnl Set LLVM_LIBS - This is done after the driver configuration so
2637     dnl that drivers can add additional components to LLVM_COMPONENTS.
2638     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2639     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2640     dnl this was causing the same libraries to be appear multiple times
2641     dnl in LLVM_LIBS.
2642
2643     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2644        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2645     fi
2646     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2647
2648     if test "x$enable_llvm_shared_libs" = xyes; then
2649         if test $LLVM_VERSION_MAJOR -lt 4 -o "`$LLVM_CONFIG --shared-mode ${LLVM_COMPONENTS}`" = static; then
2650             dnl llvm-config may not give the right answer when llvm is a built as a
2651             dnl single shared library, so we must work the library name out for
2652             dnl ourselves.
2653             dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2654             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2655             LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2656             AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2657
2658             if test "x$llvm_have_one_so" = xyes; then
2659                dnl LLVM was built using auto*, so there is only one shared object.
2660                LLVM_LIBS="-l$LLVM_SO_NAME"
2661             else
2662                 dnl If LLVM was built with CMake, there will be one shared object per
2663                 dnl component.
2664                 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2665                       [AC_MSG_ERROR([Could not find llvm shared libraries:
2666                        Please make sure you have built llvm with the --enable-shared option
2667                        and that your llvm libraries are installed in $LLVM_LIBDIR
2668                        If you have installed your llvm libraries to a different directory you
2669                        can use the --with-llvm-prefix= configure flag to specify this directory.
2670                        NOTE: Mesa is attempting to use llvm shared libraries by default.
2671                        If you do not want to build with llvm shared libraries and instead want to
2672                        use llvm static libraries then add --disable-llvm-shared-libs to your configure
2673                        invocation and rebuild.])])
2674
2675                 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2676                 dnl install uses a shared object for each component and we have
2677                 dnl already added all of these objects to LLVM_LIBS.
2678             fi
2679         fi
2680     else
2681         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2682         dnl We need to link to llvm system libs when using static libs
2683         dnl However, only llvm 3.5+ provides --system-libs
2684         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2685             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2686         fi
2687     fi
2688 fi
2689
2690 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2691 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2692 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2693 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2694 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2695 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2696 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2697                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2698 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2699 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2700 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2701 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2702 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2703 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2704 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2705 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2706                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2707                                          "x$HAVE_GALLIUM_SWR" = xyes)
2708 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2709 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2710
2711 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2712
2713 if test "x$enable_dri" = xyes; then
2714     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2715 fi
2716
2717 if test "x$have_drisw_kms" = xyes; then
2718     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2719 fi
2720 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2721
2722 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2723 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2724 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2725 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2726 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2727 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2728
2729 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2730 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2731
2732 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2733                                       "x$HAVE_RADEON_VULKAN" = xyes)
2734
2735 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2736                                         "x$HAVE_I965_DRI" = xyes)
2737
2738 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2739                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2740                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2741 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2742 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2743 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2744 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2745
2746 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2747 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2748 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2749 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2750                                         "x$enable_gallium_osmesa" = xyes)
2751
2752 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2753 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2754 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2755 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2756 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2757 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2758
2759 AC_SUBST([NINE_MAJOR], 1)
2760 AC_SUBST([NINE_MINOR], 0)
2761 AC_SUBST([NINE_TINY], 0)
2762 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2763
2764 AC_SUBST([VDPAU_MAJOR], 1)
2765 AC_SUBST([VDPAU_MINOR], 0)
2766
2767 if test "x$enable_va" = xyes; then
2768     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2769     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2770 fi
2771 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2772 AC_SUBST([VA_MINOR], $VA_MINOR)
2773
2774 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2775
2776 AC_SUBST([XVMC_MAJOR], 1)
2777 AC_SUBST([XVMC_MINOR], 0)
2778
2779 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2780 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2781 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2782 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2783
2784 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2785 AC_SUBST([XA_MINOR], $XA_MINOR)
2786 AC_SUBST([XA_TINY], $XA_TINY)
2787 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2788
2789 AC_ARG_ENABLE(valgrind,
2790               [AS_HELP_STRING([--enable-valgrind],
2791                              [Build mesa with valgrind support (default: auto)])],
2792                              [VALGRIND=$enableval], [VALGRIND=auto])
2793 if test "x$VALGRIND" != xno; then
2794     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2795 fi
2796 AC_MSG_CHECKING([whether to enable Valgrind support])
2797 if test "x$VALGRIND" = xauto; then
2798     VALGRIND="$have_valgrind"
2799 fi
2800
2801 if test "x$VALGRIND" = "xyes"; then
2802     if ! test "x$have_valgrind" = xyes; then
2803         AC_MSG_ERROR([Valgrind support required but not present])
2804     fi
2805     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2806 fi
2807
2808 AC_MSG_RESULT([$VALGRIND])
2809
2810 dnl Restore LDFLAGS and CPPFLAGS
2811 LDFLAGS="$_SAVE_LDFLAGS"
2812 CPPFLAGS="$_SAVE_CPPFLAGS"
2813
2814 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2815 if test "x$acv_mesa_CLANG" = xyes; then
2816     CFLAGS="$CFLAGS -Qunused-arguments"
2817     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2818 fi
2819
2820 dnl Add user CFLAGS and CXXFLAGS
2821 CFLAGS="$CFLAGS $USER_CFLAGS"
2822 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2823
2824 dnl Substitute the config
2825 AC_CONFIG_FILES([Makefile
2826                  src/Makefile
2827                  src/amd/Makefile
2828                  src/amd/vulkan/Makefile
2829                  src/broadcom/Makefile
2830                  src/compiler/Makefile
2831                  src/egl/Makefile
2832                  src/egl/main/egl.pc
2833                  src/egl/wayland/wayland-drm/Makefile
2834                  src/egl/wayland/wayland-egl/Makefile
2835                  src/egl/wayland/wayland-egl/wayland-egl.pc
2836                  src/gallium/Makefile
2837                  src/gallium/auxiliary/Makefile
2838                  src/gallium/auxiliary/pipe-loader/Makefile
2839                  src/gallium/drivers/freedreno/Makefile
2840                  src/gallium/drivers/ddebug/Makefile
2841                  src/gallium/drivers/i915/Makefile
2842                  src/gallium/drivers/llvmpipe/Makefile
2843                  src/gallium/drivers/noop/Makefile
2844                  src/gallium/drivers/nouveau/Makefile
2845                  src/gallium/drivers/pl111/Makefile
2846                  src/gallium/drivers/r300/Makefile
2847                  src/gallium/drivers/r600/Makefile
2848                  src/gallium/drivers/radeon/Makefile
2849                  src/gallium/drivers/radeonsi/Makefile
2850                  src/gallium/drivers/rbug/Makefile
2851                  src/gallium/drivers/softpipe/Makefile
2852                  src/gallium/drivers/svga/Makefile
2853                  src/gallium/drivers/swr/Makefile
2854                  src/gallium/drivers/trace/Makefile
2855                  src/gallium/drivers/etnaviv/Makefile
2856                  src/gallium/drivers/imx/Makefile
2857                  src/gallium/drivers/vc4/Makefile
2858                  src/gallium/drivers/virgl/Makefile
2859                  src/gallium/state_trackers/clover/Makefile
2860                  src/gallium/state_trackers/dri/Makefile
2861                  src/gallium/state_trackers/glx/xlib/Makefile
2862                  src/gallium/state_trackers/nine/Makefile
2863                  src/gallium/state_trackers/omx/Makefile
2864                  src/gallium/state_trackers/osmesa/Makefile
2865                  src/gallium/state_trackers/va/Makefile
2866                  src/gallium/state_trackers/vdpau/Makefile
2867                  src/gallium/state_trackers/xa/Makefile
2868                  src/gallium/state_trackers/xvmc/Makefile
2869                  src/gallium/targets/d3dadapter9/Makefile
2870                  src/gallium/targets/d3dadapter9/d3d.pc
2871                  src/gallium/targets/dri/Makefile
2872                  src/gallium/targets/libgl-xlib/Makefile
2873                  src/gallium/targets/omx/Makefile
2874                  src/gallium/targets/opencl/Makefile
2875                  src/gallium/targets/opencl/mesa.icd
2876                  src/gallium/targets/osmesa/Makefile
2877                  src/gallium/targets/osmesa/osmesa.pc
2878                  src/gallium/targets/pipe-loader/Makefile
2879                  src/gallium/targets/va/Makefile
2880                  src/gallium/targets/vdpau/Makefile
2881                  src/gallium/targets/xa/Makefile
2882                  src/gallium/targets/xa/xatracker.pc
2883                  src/gallium/targets/xvmc/Makefile
2884                  src/gallium/tests/trivial/Makefile
2885                  src/gallium/tests/unit/Makefile
2886                  src/gallium/winsys/etnaviv/drm/Makefile
2887                  src/gallium/winsys/imx/drm/Makefile
2888                  src/gallium/winsys/freedreno/drm/Makefile
2889                  src/gallium/winsys/i915/drm/Makefile
2890                  src/gallium/winsys/nouveau/drm/Makefile
2891                  src/gallium/winsys/pl111/drm/Makefile
2892                  src/gallium/winsys/radeon/drm/Makefile
2893                  src/gallium/winsys/amdgpu/drm/Makefile
2894                  src/gallium/winsys/svga/drm/Makefile
2895                  src/gallium/winsys/sw/dri/Makefile
2896                  src/gallium/winsys/sw/kms-dri/Makefile
2897                  src/gallium/winsys/sw/null/Makefile
2898                  src/gallium/winsys/sw/wrapper/Makefile
2899                  src/gallium/winsys/sw/xlib/Makefile
2900                  src/gallium/winsys/vc4/drm/Makefile
2901                  src/gallium/winsys/virgl/drm/Makefile
2902                  src/gallium/winsys/virgl/vtest/Makefile
2903                  src/gbm/Makefile
2904                  src/gbm/main/gbm.pc
2905                  src/glx/Makefile
2906                  src/glx/apple/Makefile
2907                  src/glx/tests/Makefile
2908                  src/glx/windows/Makefile
2909                  src/glx/windows/windowsdriproto.pc
2910                  src/gtest/Makefile
2911                  src/intel/Makefile
2912                  src/loader/Makefile
2913                  src/mapi/Makefile
2914                  src/mapi/es1api/glesv1_cm.pc
2915                  src/mapi/es2api/glesv2.pc
2916                  src/mapi/glapi/gen/Makefile
2917                  src/mesa/Makefile
2918                  src/mesa/gl.pc
2919                  src/mesa/drivers/dri/dri.pc
2920                  src/mesa/drivers/dri/common/Makefile
2921                  src/mesa/drivers/dri/i915/Makefile
2922                  src/mesa/drivers/dri/i965/Makefile
2923                  src/mesa/drivers/dri/Makefile
2924                  src/mesa/drivers/dri/nouveau/Makefile
2925                  src/mesa/drivers/dri/r200/Makefile
2926                  src/mesa/drivers/dri/radeon/Makefile
2927                  src/mesa/drivers/dri/swrast/Makefile
2928                  src/mesa/drivers/osmesa/Makefile
2929                  src/mesa/drivers/osmesa/osmesa.pc
2930                  src/mesa/drivers/x11/Makefile
2931                  src/mesa/main/tests/Makefile
2932                  src/util/Makefile
2933                  src/util/tests/hash_table/Makefile
2934                  src/util/xmlpool/Makefile
2935                  src/vulkan/Makefile])
2936
2937 AC_OUTPUT
2938
2939 # Fix up dependencies in *.Plo files, where we changed the extension of a
2940 # source file
2941 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2942
2943 rm -f src/compiler/spirv/spirv_info.lo
2944 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
2945
2946 dnl
2947 dnl Output some configuration info for the user
2948 dnl
2949 echo ""
2950 echo "        prefix:          $prefix"
2951 echo "        exec_prefix:     $exec_prefix"
2952 echo "        libdir:          $libdir"
2953 echo "        includedir:      $includedir"
2954
2955 dnl API info
2956 echo ""
2957 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2958
2959 dnl Driver info
2960 echo ""
2961 case "x$enable_osmesa$enable_gallium_osmesa" in
2962 xnoyes)
2963         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2964         ;;
2965 xyesno)
2966         echo "        OSMesa:          lib$OSMESA_LIB"
2967         ;;
2968 xnono)
2969         echo "        OSMesa:          no"
2970         ;;
2971 esac
2972
2973 echo ""
2974 if test "x$enable_dri" != xno; then
2975         echo "        DRI platform:    $dri_platform"
2976         if test -z "$DRI_DIRS"; then
2977             echo "        DRI drivers:     no"
2978         else
2979             echo "        DRI drivers:     $DRI_DIRS"
2980         fi
2981         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2982 fi
2983
2984 case "x$enable_glx" in
2985 xdri)
2986     echo "        GLX:             DRI-based"
2987     ;;
2988 xxlib)
2989     echo "        GLX:             Xlib-based"
2990     ;;
2991 xgallium-xlib)
2992     echo "        GLX:             Xlib-based (Gallium)"
2993     ;;
2994 *)
2995     echo "        GLX:             $enable_glx"
2996     ;;
2997 esac
2998
2999 dnl EGL
3000 echo ""
3001 echo "        EGL:             $enable_egl"
3002 if test "$enable_egl" = yes; then
3003
3004     egl_drivers=""
3005     if test "x$enable_dri" != "xno"; then
3006         egl_drivers="$egl_drivers builtin:egl_dri2"
3007     fi
3008     if test "x$enable_dri3" != "xno"; then
3009         egl_drivers="$egl_drivers builtin:egl_dri3"
3010     fi
3011
3012     echo "        EGL drivers:    $egl_drivers"
3013 fi
3014 if test "x$enable_gbm" = xyes; then
3015     echo "        GBM:             yes"
3016 else
3017     echo "        GBM:             no"
3018 fi
3019
3020     echo "        EGL/Vulkan/VL platforms:   $platforms"
3021
3022 # Vulkan
3023 echo ""
3024 if test "x$VULKAN_DRIVERS" != x; then
3025     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3026     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3027 else
3028     echo "        Vulkan drivers:  no"
3029 fi
3030
3031 echo ""
3032 if test "x$enable_llvm" = xyes; then
3033     echo "        llvm:            yes"
3034     echo "        llvm-config:     $LLVM_CONFIG"
3035     echo "        llvm-version:    $LLVM_VERSION"
3036 else
3037     echo "        llvm:            no"
3038 fi
3039
3040 echo ""
3041 if test -n "$with_gallium_drivers"; then
3042     echo "        Gallium drivers: $gallium_drivers"
3043     echo "        Gallium st:      $gallium_st"
3044 else
3045     echo "        Gallium:         no"
3046 fi
3047
3048 echo ""
3049 if test "x$enable_gallium_extra_hud" != xyes; then
3050     echo "        HUD extra stats: no"
3051 else
3052     echo "        HUD extra stats: yes"
3053 fi
3054
3055 if test "x$enable_lmsensors" != xyes; then
3056     echo "        HUD lmsensors:   no"
3057 else
3058     echo "        HUD lmsensors:   yes"
3059 fi
3060
3061 echo ""
3062 if test "x$HAVE_GALLIUM_SWR" != x; then
3063     echo "        SWR archs:       $swr_archs"
3064 fi
3065
3066 dnl Libraries
3067 echo ""
3068 echo "        Shared libs:     $enable_shared"
3069 echo "        Static libs:     $enable_static"
3070 echo "        Shared-glapi:    $enable_shared_glapi"
3071
3072 dnl Compiler options
3073 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3074 cflags=`echo $CFLAGS | \
3075     $SED 's/^ *//;s/  */ /;s/ *$//'`
3076 cxxflags=`echo $CXXFLAGS | \
3077     $SED 's/^ *//;s/  */ /;s/ *$//'`
3078 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3079 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3080 echo ""
3081 echo "        CFLAGS:          $cflags"
3082 echo "        CXXFLAGS:        $cxxflags"
3083 echo "        LDFLAGS:         $ldflags"
3084 echo "        Macros:          $defines"
3085 echo ""
3086 if test "x$enable_llvm" = xyes; then
3087     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3088     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3089     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3090     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3091     echo ""
3092 fi
3093 echo "        PYTHON2:         $PYTHON2"
3094
3095 echo ""
3096 echo "        Run '${MAKE-make}' to build Mesa"
3097 echo ""