projects / mesa.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
radeonsi: don't build libradeon.la separately
[mesa.git] / configure.ac
1 dnl Copyright © 2011-2014 Intel Corporation
2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
3 dnl Copyright © 2007-2010 Dan Nicholson
4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
5 dnl Copyright © 2010-2014 Christian König
6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
7 dnl Copyright © 2009-2012 Jakob Bornecrantz
8 dnl Copyright © 2009-2014 Jon TURNEY
9 dnl Copyright © 2011-2012 Benjamin Franzke
10 dnl Copyright © 2008-2014 David Airlie
11 dnl Copyright © 2009-2013 Brian Paul
12 dnl
13 dnl Permission is hereby granted, free of charge, to any person obtaining a
14 dnl copy of this software and associated documentation files (the "Software"),
15 dnl to deal in the Software without restriction, including without limitation
16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
17 dnl and/or sell copies of the Software, and to permit persons to whom the
18 dnl Software is furnished to do so, subject to the following conditions:
19 dnl
20 dnl The above copyright notice and this permission notice (including the next
21 dnl paragraph) shall be included in all copies or substantial portions of the
22 dnl Software.
23 dnl
24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
30 dnl DEALINGS IN THE SOFTWARE.
31 dnl
32 dnl Process this file with autoconf to create configure.
33
34 AC_PREREQ([2.60])
35
36 dnl Tell the user about autoconf.html in the --help output
37 m4_divert_once([HELP_END], [
38 See docs/autoconf.html for more details on the options for Mesa.])
39
40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
41 AC_INIT([Mesa], [MESA_VERSION],
42 [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
43 AC_CONFIG_AUX_DIR([bin])
44 AC_CONFIG_MACRO_DIR([m4])
45 AC_CANONICAL_SYSTEM
46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
47
48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
49 case "$host_os" in
50 mingw*)
51 AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
52 ;;
53 esac
54
55 # Support silent build rules, requires at least automake-1.11. Disable
56 # by either passing --disable-silent-rules to configure or passing V=1
57 # to make
58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
59 [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
60
61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
62
63 dnl Set internal versions
64 OSMESA_VERSION=8
65 AC_SUBST([OSMESA_VERSION])
66 OPENCL_VERSION=1
67 AC_SUBST([OPENCL_VERSION])
68
69 # The idea is that libdrm is distributed as one cohesive package, even
70 # though it is composed of multiple libraries. However some drivers
71 # may have different version requirements than others. This list
72 # codifies which drivers need which version of libdrm. Any libdrm
73 # version dependencies in non-driver-specific code should be reflected
74 # in the first entry.
75 LIBDRM_REQUIRED=2.4.75
76 LIBDRM_RADEON_REQUIRED=2.4.71
77 LIBDRM_AMDGPU_REQUIRED=2.4.91
78 LIBDRM_INTEL_REQUIRED=2.4.75
79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
81 LIBDRM_FREEDRENO_REQUIRED=2.4.91
82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
83
84 dnl Versions for external dependencies
85 DRI2PROTO_REQUIRED=2.8
86 GLPROTO_REQUIRED=1.4.14
87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
88 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
89 LIBVA_REQUIRED=0.38.0
90 VDPAU_REQUIRED=1.1
91 WAYLAND_REQUIRED=1.11
92 WAYLAND_PROTOCOLS_REQUIRED=1.8
93 XCB_REQUIRED=1.9.3
94 XCBDRI2_REQUIRED=1.8
95 XCBDRI3_MODIFIERS_REQUIRED=1.13
96 XCBGLX_REQUIRED=1.8.1
97 XCBPRESENT_MODIFIERS_REQUIRED=1.13
98 XDAMAGE_REQUIRED=1.1
99 XSHMFENCE_REQUIRED=1.1
100 XVMC_REQUIRED=1.0.6
101 PYTHON_MAKO_REQUIRED=0.8.0
102 LIBSENSORS_REQUIRED=4.0.0
103 ZLIB_REQUIRED=1.2.3
104
105 dnl LLVM versions
106 LLVM_REQUIRED_GALLIUM=3.3.0
107 LLVM_REQUIRED_OPENCL=3.9.0
108 LLVM_REQUIRED_R600=3.9.0
109 LLVM_REQUIRED_RADEONSI=4.0.0
110 LLVM_REQUIRED_RADV=4.0.0
111 LLVM_REQUIRED_SWR=4.0.0
112
113 dnl Check for progs
114 AC_PROG_CPP
115 AC_PROG_CC
116 AC_PROG_CXX
117 dnl add this here, so the help for this environmnet variable is close to
118 dnl other CC/CXX flags related help
119 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
120 enabled by default and different from -std=c++11)])
121 AM_PROG_CC_C_O
122 AC_PROG_NM
123 AM_PROG_AS
124 AX_CHECK_GNU_MAKE
125 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
126 AC_PROG_SED
127 AC_PROG_MKDIR_P
128
129 AC_SYS_LARGEFILE
130
131
132 LT_PREREQ([2.2])
133 LT_INIT([disable-static])
134
135 AC_CHECK_PROG(RM, rm, [rm -f])
136
137 AX_PROG_BISON([],
138 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
139 [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
140 AX_PROG_FLEX([],
141 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
142 [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
143
144 AC_CHECK_PROG(INDENT, indent, indent, cat)
145 if test "x$INDENT" != "xcat"; then
146 # Only GNU indent is supported
147 INDENT_VERSION=`indent --version | grep GNU`
148 if test $? -eq 0; then
149 AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
150 else
151 INDENT="cat"
152 fi
153 fi
154
155 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
156
157 if test -z "$PYTHON2"; then
158 if test ! -f "$srcdir/src/util/format_srgb.c"; then
159 AC_MSG_ERROR([Python not found - unable to generate sources])
160 fi
161 else
162 if test "x$acv_mako_found" = xno; then
163 if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
164 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
165 fi
166 fi
167 fi
168
169 AC_PROG_INSTALL
170
171 dnl We need a POSIX shell for parts of the build. Assume we have one
172 dnl in most cases.
173 case "$host_os" in
174 solaris*)
175 # Solaris /bin/sh is too old/non-POSIX compliant
176 AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
177 SHELL="$POSIX_SHELL"
178 ;;
179 esac
180
181 dnl clang is mostly GCC-compatible, but its version is much lower,
182 dnl so we have to check for it.
183 AC_MSG_CHECKING([if compiling with clang])
184
185 AC_COMPILE_IFELSE(
186 [AC_LANG_PROGRAM([], [[
187 #ifndef __clang__
188 not clang
189 #endif
190 ]])],
191 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
192
193 AC_MSG_RESULT([$acv_mesa_CLANG])
194
195 dnl If we're using GCC, make sure that it is at least version 4.2.0. Older
196 dnl versions are explictly not supported.
197 GEN_ASM_OFFSETS=no
198 USE_GNU99=no
199 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
200 AC_MSG_CHECKING([whether gcc version is sufficient])
201 major=0
202 minor=0
203
204 GCC_VERSION=`$CC -dumpversion`
205 if test $? -eq 0; then
206 GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
207 GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
208 fi
209
210 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
211 AC_MSG_RESULT([no])
212 AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
213 else
214 AC_MSG_RESULT([yes])
215 fi
216
217 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
218 USE_GNU99=yes
219 fi
220 if test "x$cross_compiling" = xyes; then
221 GEN_ASM_OFFSETS=yes
222 fi
223 fi
224
225 dnl We don't support building Mesa with Sun C compiler
226 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
227 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
228 if test "x$SUNCC" = xyes; then
229 AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
230 fi
231
232 dnl Check for compiler builtins
233 AX_GCC_BUILTIN([__builtin_bswap32])
234 AX_GCC_BUILTIN([__builtin_bswap64])
235 AX_GCC_BUILTIN([__builtin_clz])
236 AX_GCC_BUILTIN([__builtin_clzll])
237 AX_GCC_BUILTIN([__builtin_ctz])
238 AX_GCC_BUILTIN([__builtin_expect])
239 AX_GCC_BUILTIN([__builtin_ffs])
240 AX_GCC_BUILTIN([__builtin_ffsll])
241 AX_GCC_BUILTIN([__builtin_popcount])
242 AX_GCC_BUILTIN([__builtin_popcountll])
243 AX_GCC_BUILTIN([__builtin_unreachable])
244
245 AX_GCC_FUNC_ATTRIBUTE([const])
246 AX_GCC_FUNC_ATTRIBUTE([flatten])
247 AX_GCC_FUNC_ATTRIBUTE([format])
248 AX_GCC_FUNC_ATTRIBUTE([malloc])
249 AX_GCC_FUNC_ATTRIBUTE([packed])
250 AX_GCC_FUNC_ATTRIBUTE([pure])
251 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
252 AX_GCC_FUNC_ATTRIBUTE([unused])
253 AX_GCC_FUNC_ATTRIBUTE([visibility])
254 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
255 AX_GCC_FUNC_ATTRIBUTE([weak])
256 AX_GCC_FUNC_ATTRIBUTE([alias])
257 AX_GCC_FUNC_ATTRIBUTE([noreturn])
258
259 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
260
261 dnl Make sure the pkg-config macros are defined
262 m4_ifndef([PKG_PROG_PKG_CONFIG],
263 [m4_fatal([Could not locate the pkg-config autoconf macros.
264 These are usually located in /usr/share/aclocal/pkg.m4. If your macros
265 are in a different location, try setting the environment variable
266 ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
267 PKG_PROG_PKG_CONFIG()
268
269 dnl LIB_DIR - library basename
270 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
271 AC_SUBST([LIB_DIR])
272
273 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
274 _SAVE_LDFLAGS="$LDFLAGS"
275 _SAVE_CPPFLAGS="$CPPFLAGS"
276
277 dnl Compiler macros
278 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
279 AC_SUBST([DEFINES])
280 android=no
281 case "$host_os" in
282 *-android*)
283 android=yes
284 ;;
285 linux*|*-gnu*|gnu*|cygwin*)
286 DEFINES="$DEFINES -D_GNU_SOURCE"
287 ;;
288 solaris*)
289 DEFINES="$DEFINES -DSVR4"
290 ;;
291 esac
292
293 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
294
295 dnl
296 dnl Check compiler flags
297 dnl
298 AX_CHECK_COMPILE_FLAG([-Wall], [CFLAGS="$CFLAGS -Wall"])
299 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
300 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes], [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
301 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes], [CFLAGS="$CFLAGS -Wmissing-prototypes"])
302 AX_CHECK_COMPILE_FLAG([-fno-math-errno], [CFLAGS="$CFLAGS -fno-math-errno"])
303 AX_CHECK_COMPILE_FLAG([-fno-trapping-math], [CFLAGS="$CFLAGS -fno-trapping-math"])
304 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
305
306 dnl
307 dnl Check C++ compiler flags
308 dnl
309 AC_LANG_PUSH([C++])
310 AX_CHECK_COMPILE_FLAG([-Wall], [CXXFLAGS="$CXXFLAGS -Wall"])
311 AX_CHECK_COMPILE_FLAG([-fno-math-errno], [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
312 AX_CHECK_COMPILE_FLAG([-fno-trapping-math], [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
313 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
314 AC_LANG_POP([C++])
315
316 # Flags to help ensure that certain portions of the code -- and only those
317 # portions -- can be built with MSVC:
318 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
319 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
320 # supports most of C99)
321 # - the rest has no compiler compiler restrictions
322 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith], [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
323 AX_CHECK_COMPILE_FLAG([-Werror=vla], [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
324 AC_LANG_PUSH([C++])
325 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith], [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
326 AX_CHECK_COMPILE_FLAG([-Werror=vla], [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
327 AC_LANG_POP([C++])
328
329 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
330 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
331
332 if test "x$GCC" = xyes; then
333 if test "x$USE_GNU99" = xyes; then
334 CFLAGS="$CFLAGS -std=gnu99"
335 else
336 CFLAGS="$CFLAGS -std=c99"
337 fi
338 fi
339
340 dnl
341 dnl Check whether C++11 is supported, if the environment variable
342 dnl CXX11_CXXFLAGS is set it takes precedence.
343 dnl
344
345 AC_LANG_PUSH([C++])
346
347 check_cxx11_available() {
348 output_support=$1
349 AC_COMPILE_IFELSE(
350 [AC_LANG_PROGRAM([
351 #if !(__cplusplus >= 201103L)
352 #error
353 #endif
354 #include <tuple>
355 ])
356 ], [
357 AC_MSG_RESULT(yes)
358 cxx11_support=yes
359 ], AC_MSG_RESULT(no))
360 eval "$output_support=\$cxx11_support"
361 }
362
363 HAVE_CXX11=no
364 save_CXXFLAGS="$CXXFLAGS"
365
366 dnl If the user provides a flag to enable c++11, then we test only this
367 if test "x$CXX11_CXXFLAGS" != "x"; then
368 CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
369 AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
370 check_cxx11_available HAVE_CXX11
371 else
372 dnl test whether c++11 is enabled by default
373 AC_MSG_CHECKING(whether c++11 is enabled by default)
374 check_cxx11_available HAVE_CXX11
375
376 dnl C++11 not enabled by default, test whether -std=c++11 does the job
377 if test "x$HAVE_CXX11" != "xyes"; then
378 CXX11_CXXFLAGS=-std=c++11
379 CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
380 AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
381 check_cxx11_available HAVE_CXX11
382 fi
383 fi
384
385 CXXFLAGS="$save_CXXFLAGS"
386 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
387 AC_SUBST(CXX11_CXXFLAGS)
388 AC_LANG_POP([C++])
389
390 dnl even if the compiler appears to support it, using visibility attributes isn't
391 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
392 case "$host_os" in
393 cygwin*)
394 VISIBILITY_CFLAGS=""
395 VISIBILITY_CXXFLAGS=""
396 ;;
397 esac
398
399 AC_SUBST([VISIBILITY_CFLAGS])
400 AC_SUBST([VISIBILITY_CXXFLAGS])
401
402 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
403 dnl option is not supported. Hence, check for -Wfoo instead.
404 AX_CHECK_COMPILE_FLAG([-Woverride-init], [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"]) # gcc
405 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides], [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
406 AC_SUBST([WNO_OVERRIDE_INIT])
407
408 dnl
409 dnl Optional flags, check for compiler support
410 dnl
411 SSE41_CFLAGS="-msse4.1"
412 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
413 dnl stack, but on x86-32 such alignment is not guaranteed.
414 case "$target_cpu" in
415 i?86)
416 SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
417 ;;
418 esac
419 save_CFLAGS="$CFLAGS"
420 CFLAGS="$SSE41_CFLAGS $CFLAGS"
421 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
422 #include <smmintrin.h>
423 int param;
424 int main () {
425 __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
426 c = _mm_max_epu32(a, b);
427 return _mm_cvtsi128_si32(c);
428 }]])], SSE41_SUPPORTED=1)
429 CFLAGS="$save_CFLAGS"
430 if test "x$SSE41_SUPPORTED" = x1; then
431 DEFINES="$DEFINES -DUSE_SSE41"
432 fi
433 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
434 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
435
436 dnl Check for new-style atomic builtins
437 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
438 int main() {
439 int n;
440 return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
441 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
442 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
443 DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
444 dnl On some platforms, new-style atomics need a helper library
445 AC_MSG_CHECKING(whether -latomic is needed)
446 AC_LINK_IFELSE([AC_LANG_SOURCE([[
447 #include <stdint.h>
448 uint64_t v;
449 int main() {
450 return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
451 }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
452 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
453 if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
454 LIBATOMIC_LIBS="-latomic"
455 fi
456 fi
457 AC_SUBST([LIBATOMIC_LIBS])
458
459 dnl Check if host supports 64-bit atomics
460 dnl note that lack of support usually results in link (not compile) error
461 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
462 AC_LINK_IFELSE([AC_LANG_SOURCE([[
463 #include <stdint.h>
464 uint64_t v;
465 int main() {
466 return __sync_add_and_fetch(&v, (uint64_t)1);
467 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
468 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
469 DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
470 fi
471 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
472
473 dnl Check for Endianness
474 AC_C_BIGENDIAN(
475 little_endian=no,
476 little_endian=yes,
477 little_endian=no,
478 little_endian=no
479 )
480
481 dnl Check for POWER8 Architecture
482 PWR8_CFLAGS="-mpower8-vector"
483 have_pwr8_intrinsics=no
484 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
485 save_CFLAGS=$CFLAGS
486 CFLAGS="$PWR8_CFLAGS $CFLAGS"
487 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
488 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
489 #error "Need GCC >= 4.8 for sane POWER8 support"
490 #endif
491 #include <altivec.h>
492 int main () {
493 vector unsigned char r;
494 vector unsigned int v = vec_splat_u32 (1);
495 r = __builtin_vec_vgbbd ((vector unsigned char) v);
496 return 0;
497 }]])], have_pwr8_intrinsics=yes)
498 CFLAGS=$save_CFLAGS
499
500 AC_ARG_ENABLE(pwr8,
501 [AS_HELP_STRING([--disable-pwr8],
502 [disable POWER8-specific instructions])],
503 [enable_pwr8=$enableval], [enable_pwr8=auto])
504
505 if test "x$enable_pwr8" = xno ; then
506 have_pwr8_intrinsics=disabled
507 fi
508
509 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
510 DEFINES="$DEFINES -D_ARCH_PWR8"
511 CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
512 CFLAGS="$CFLAGS $PWR8_CFLAGS"
513 else
514 PWR8_CFLAGS=
515 fi
516
517 AC_MSG_RESULT($have_pwr8_intrinsics)
518 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
519 AC_MSG_ERROR([POWER8 compiler support not detected])
520 fi
521
522 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
523 AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
524 fi
525
526 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
527
528 dnl Can't have static and shared libraries, default to static if user
529 dnl explicitly requested. If both disabled, set to static since shared
530 dnl was explicitly requested.
531 case "x$enable_static$enable_shared" in
532 xyesyes)
533 AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
534 ;;
535 xnono)
536 AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
537 ;;
538 esac
539
540 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
541
542 dnl
543 dnl other compiler options
544 dnl
545 AC_ARG_ENABLE([debug],
546 [AS_HELP_STRING([--enable-debug],
547 [use debug compiler flags and macros @<:@default=disabled@:>@])],
548 [enable_debug="$enableval"],
549 [enable_debug=no]
550 )
551
552 AC_ARG_ENABLE([profile],
553 [AS_HELP_STRING([--enable-profile],
554 [enable profiling of code @<:@default=disabled@:>@])],
555 [enable_profile="$enableval"],
556 [enable_profile=no]
557 )
558
559 AC_ARG_ENABLE([sanitize],
560 [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
561 [enable code sanitizer @<:@default=disabled@:>@])],
562 [enable_sanitize="$enableval"],
563 [enable_sanitize=no])
564
565 if test "x$enable_profile" = xyes; then
566 DEFINES="$DEFINES -DPROFILE"
567 if test "x$GCC" = xyes; then
568 CFLAGS="$CFLAGS -fno-omit-frame-pointer"
569 fi
570 if test "x$GXX" = xyes; then
571 CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
572 fi
573 fi
574
575 if test "x$enable_debug" = xyes; then
576 DEFINES="$DEFINES -DDEBUG"
577 if test "x$enable_profile" = xyes; then
578 AC_MSG_WARN([Debug and Profile are enabled at the same time])
579 fi
580 if test "x$GCC" = xyes; then
581 if ! echo "$CFLAGS" | grep -q -e '-g'; then
582 CFLAGS="$CFLAGS -g"
583 fi
584 if ! echo "$CFLAGS" | grep -q -e '-O'; then
585 CFLAGS="$CFLAGS -O0"
586 fi
587 fi
588 if test "x$GXX" = xyes; then
589 if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
590 CXXFLAGS="$CXXFLAGS -g"
591 fi
592 if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
593 CXXFLAGS="$CXXFLAGS -O0"
594 fi
595 fi
596 else
597 DEFINES="$DEFINES -DNDEBUG"
598 fi
599
600 if test "x$enable_sanitize" != xno; then
601 if test "x$enable_profile" = xyes; then
602 AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
603 fi
604
605 CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
606 CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
607 LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
608
609 AC_LINK_IFELSE(
610 [AC_LANG_SOURCE([int main(){return 0;}])],
611 [],
612 [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
613 fi
614
615 dnl
616 dnl Check if linker supports -Bsymbolic
617 dnl
618 save_LDFLAGS=$LDFLAGS
619 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
620 AC_MSG_CHECKING([if ld supports -Bsymbolic])
621 AC_LINK_IFELSE(
622 [AC_LANG_SOURCE([int main() { return 0;}])],
623 [AC_MSG_RESULT([yes])
624 BSYMBOLIC="-Wl,-Bsymbolic";],
625 [AC_MSG_RESULT([no])
626 BSYMBOLIC="";])
627 LDFLAGS=$save_LDFLAGS
628
629 AC_SUBST([BSYMBOLIC])
630
631 dnl
632 dnl Check if linker supports garbage collection
633 dnl
634 save_LDFLAGS=$LDFLAGS
635 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
636 AC_MSG_CHECKING([whether ld supports --gc-sections])
637 AC_LINK_IFELSE(
638 [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
639 [AC_MSG_RESULT([yes])
640 GC_SECTIONS="-Wl,--gc-sections";],
641 [AC_MSG_RESULT([no])
642 GC_SECTIONS="";])
643 LDFLAGS=$save_LDFLAGS
644
645 AC_SUBST([GC_SECTIONS])
646
647 dnl
648 dnl OpenBSD does not have DT_NEEDED entries for libc by design
649 dnl so when these flags are passed to ld via libtool the checks will fail
650 dnl
651 case "$host_os" in
652 openbsd* | darwin* )
653 LD_NO_UNDEFINED="" ;;
654 *)
655 if test "x$enable_sanitize" = xno; then
656 LD_NO_UNDEFINED="-Wl,--no-undefined"
657 else
658 LD_NO_UNDEFINED=""
659 fi
660 ;;
661 esac
662
663 AC_SUBST([LD_NO_UNDEFINED])
664
665 dnl
666 dnl Check if linker supports version scripts
667 dnl
668 AC_MSG_CHECKING([if the linker supports version-scripts])
669 save_LDFLAGS=$LDFLAGS
670 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
671 AC_LINK_IFELSE(
672 [AC_LANG_SOURCE([int main() { return 0;}])],
673 [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
674 [have_ld_version_script=no; AC_MSG_RESULT(no)])
675 LDFLAGS=$save_LDFLAGS
676 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
677
678 dnl
679 dnl Check if linker supports dynamic list files
680 dnl
681 AC_MSG_CHECKING([if the linker supports --dynamic-list])
682 save_LDFLAGS=$LDFLAGS
683 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
684 AC_LINK_IFELSE(
685 [AC_LANG_SOURCE([int main() { return 0;}])],
686 [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
687 [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
688 LDFLAGS=$save_LDFLAGS
689 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
690
691 dnl
692 dnl OSX linker does not support build-id
693 dnl
694 case "$host_os" in
695 darwin*)
696 LD_BUILD_ID=""
697 ;;
698 *)
699 LD_BUILD_ID="-Wl,--build-id=sha1"
700 ;;
701 esac
702 AC_SUBST([LD_BUILD_ID])
703
704 dnl
705 dnl compatibility symlinks
706 dnl
707 case "$host_os" in
708 linux* )
709 HAVE_COMPAT_SYMLINKS=yes ;;
710 * )
711 HAVE_COMPAT_SYMLINKS=no ;;
712 esac
713
714 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
715
716 dnl
717 dnl library names
718 dnl
719 dnl Unfortunately we need to do a few things that libtool can't help us with,
720 dnl so we need some knowledge of shared library filenames:
721 dnl
722 dnl LIB_EXT is the extension used when creating symlinks for alternate
723 dnl filenames for a shared library which will be dynamically loaded
724 dnl
725 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
726 dnl the file for a shared library we wish to link with
727 dnl
728 case "$host_os" in
729 darwin* )
730 LIB_EXT='dylib'
731 IMP_LIB_EXT=$LIB_EXT
732 ;;
733 cygwin* )
734 LIB_EXT='dll'
735 IMP_LIB_EXT='dll.a'
736 ;;
737 aix* )
738 LIB_EXT='a'
739 IMP_LIB_EXT=$LIB_EXT
740 ;;
741 * )
742 LIB_EXT='so'
743 IMP_LIB_EXT=$LIB_EXT
744 ;;
745 esac
746
747 AC_SUBST([LIB_EXT])
748
749 dnl
750 dnl potentially-infringing-but-nobody-knows-for-sure stuff
751 dnl
752 AC_ARG_ENABLE([texture-float],
753 [AS_HELP_STRING([--enable-texture-float],
754 [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
755 [enable_texture_float="$enableval"],
756 [enable_texture_float=no]
757 )
758 if test "x$enable_texture_float" = xyes; then
759 AC_MSG_WARN([Floating-point textures enabled.])
760 AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
761 DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
762 fi
763
764 dnl
765 dnl Arch/platform-specific settings
766 dnl
767 AC_ARG_ENABLE([asm],
768 [AS_HELP_STRING([--disable-asm],
769 [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
770 [enable_asm="$enableval"],
771 [enable_asm=yes]
772 )
773 asm_arch=""
774 AC_MSG_CHECKING([whether to enable assembly])
775 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
776 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
777 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
778 case "$host_cpu" in
779 i?86 | x86_64 | amd64)
780 if test "x$host_cpu" != "x$target_cpu"; then
781 enable_asm=no
782 AC_MSG_RESULT([no, cross compiling])
783 fi
784 ;;
785 esac
786 fi
787 # check for supported arches
788 if test "x$enable_asm" = xyes; then
789 case "$host_cpu" in
790 i?86)
791 case "$host_os" in
792 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
793 asm_arch=x86
794 ;;
795 esac
796 ;;
797 x86_64|amd64)
798 case "$host_os" in
799 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
800 asm_arch=x86_64
801 ;;
802 esac
803 ;;
804 sparc*)
805 case "$host_os" in
806 linux*)
807 asm_arch=sparc
808 ;;
809 esac
810 ;;
811 powerpc64le)
812 case "$host_os" in
813 linux*)
814 asm_arch=ppc64le
815 ;;
816 esac
817 ;;
818 aarch64)
819 case "$host_os" in
820 linux*)
821 asm_arch=aarch64
822 ;;
823 esac
824 ;;
825 arm)
826 case "$host_os" in
827 linux*)
828 asm_arch=arm
829 ;;
830 esac
831 ;;
832 esac
833
834 case "$asm_arch" in
835 x86)
836 DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
837 AC_MSG_RESULT([yes, x86])
838 ;;
839 x86_64|amd64)
840 DEFINES="$DEFINES -DUSE_X86_64_ASM"
841 AC_MSG_RESULT([yes, x86_64])
842 ;;
843 sparc)
844 DEFINES="$DEFINES -DUSE_SPARC_ASM"
845 AC_MSG_RESULT([yes, sparc])
846 ;;
847 ppc64le)
848 DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
849 AC_MSG_RESULT([yes, ppc64le])
850 ;;
851 aarch64)
852 DEFINES="$DEFINES -DUSE_AARCH64_ASM"
853 AC_MSG_RESULT([yes, aarch64])
854 ;;
855 arm)
856 DEFINES="$DEFINES -DUSE_ARM_ASM"
857 AC_MSG_RESULT([yes, arm])
858 ;;
859 *)
860 AC_MSG_RESULT([no, platform not supported])
861 ;;
862 esac
863 fi
864
865 AC_HEADER_MAJOR
866 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
867 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
868 AC_CHECK_HEADERS([endian.h])
869 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
870 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
871 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
872 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
873
874 AC_MSG_CHECKING([whether strtod has locale support])
875 AC_LINK_IFELSE([AC_LANG_SOURCE([[
876 #define _GNU_SOURCE
877 #include <stdlib.h>
878 #include <locale.h>
879 #ifdef HAVE_XLOCALE_H
880 #include <xlocale.h>
881 #endif
882 int main() {
883 locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
884 const char *s = "1.0";
885 char *end;
886 double d = strtod_l(s, end, loc);
887 float f = strtof_l(s, end, loc);
888 freelocale(loc);
889 return 0;
890 }]])],
891 [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
892 AC_MSG_RESULT([yes]),
893 AC_MSG_RESULT([no]))
894
895 dnl Check to see if dlopen is in default libraries (like Solaris, which
896 dnl has it in libc), or if libdl is needed to get it.
897 AC_CHECK_FUNC([dlopen], [],
898 [AC_CHECK_LIB([dl], [dlopen],
899 [DLOPEN_LIBS="-ldl"])])
900 AC_SUBST([DLOPEN_LIBS])
901
902 dnl Check if that library also has dladdr
903 save_LIBS="$LIBS"
904 LIBS="$LIBS $DLOPEN_LIBS"
905 AC_CHECK_FUNCS([dladdr])
906 LIBS="$save_LIBS"
907
908 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
909
910 case "$host_os" in
911 darwin*)
912 ;;
913 *)
914 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
915 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
916 [AC_MSG_ERROR([Could not find clock_gettime])])])
917 AC_SUBST([CLOCK_LIB])
918 ;;
919 esac
920
921 dnl See if posix_memalign is available
922 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
923
924 dnl Check for zlib
925 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
926 DEFINES="$DEFINES -DHAVE_ZLIB"
927
928 dnl Check for pthreads
929 AX_PTHREAD
930 if test "x$ax_pthread_ok" = xno; then
931 AC_MSG_ERROR([Building mesa on this platform requires pthreads])
932 fi
933 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
934 dnl to -pthread, which causes problems if we need -lpthread to appear in
935 dnl pkgconfig files. Since Android doesn't have a pthread lib, this check
936 dnl is not valid for that platform.
937 if test "x$android" = xno; then
938 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
939 fi
940 dnl According to the manual when using pthreads, one should add -pthread to
941 dnl both compile and link-time arguments.
942 dnl In practise that should be sufficient for all platforms, since any
943 dnl platforms build with GCC and Clang support the flag.
944 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
945
946 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
947 dnl project. Even then there's a notable issue as described in the project README
948 case "$host_os" in
949 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
950 pthread_stubs_possible="no"
951 ;;
952 * )
953 pthread_stubs_possible="yes"
954 ;;
955 esac
956
957 if test "x$pthread_stubs_possible" = xyes; then
958 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
959 fi
960
961 dnl Check for futex for fast inline simple_mtx_t.
962 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
963
964 dnl SELinux awareness.
965 AC_ARG_ENABLE([selinux],
966 [AS_HELP_STRING([--enable-selinux],
967 [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
968 [MESA_SELINUX="$enableval"],
969 [MESA_SELINUX=no])
970 if test "x$enable_selinux" = "xyes"; then
971 PKG_CHECK_MODULES([SELINUX], [libselinux], [],
972 [AC_CHECK_HEADER([selinux/selinux.h],[],
973 [AC_MSG_ERROR([SELinux headers not found])])
974 AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
975 [AC_MSG_ERROR([SELinux library not found])])
976 SELINUX_LIBS="-lselinux"])
977 DEFINES="$DEFINES -DMESA_SELINUX"
978 fi
979 AC_SUBST([SELINUX_CFLAGS])
980 AC_SUBST([SELINUX_LIBS])
981
982 dnl
983 dnl LLVM
984 dnl
985 AC_ARG_ENABLE([llvm-shared-libs],
986 [AS_HELP_STRING([--enable-llvm-shared-libs],
987 [link with LLVM shared libraries @<:@default=enabled@:>@])],
988 [enable_llvm_shared_libs="$enableval"],
989 [enable_llvm_shared_libs=yes])
990
991 AC_ARG_WITH([llvm-prefix],
992 [AS_HELP_STRING([--with-llvm-prefix],
993 [Prefix for LLVM installations in non-standard locations])],
994 [llvm_prefix="$withval"],
995 [llvm_prefix=''])
996
997 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
998 if test "x$have_libelf" = xno; then
999 LIBELF_LIBS=''
1000 LIBELF_CFLAGS=''
1001 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1002 AC_SUBST([LIBELF_LIBS])
1003 AC_SUBST([LIBELF_CFLAGS])
1004 fi
1005
1006 if test -z "$LLVM_CONFIG"; then
1007 if test -n "$llvm_prefix"; then
1008 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1009 else
1010 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1011 fi
1012 fi
1013
1014 llvm_add_component() {
1015 new_llvm_component=$1
1016 driver_name=$2
1017
1018 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1019 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1020 else
1021 AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1022 fi
1023 }
1024
1025 llvm_add_optional_component() {
1026 new_llvm_component=$1
1027 driver_name=$2
1028
1029 if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1030 LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1031 fi
1032 }
1033
1034 llvm_add_default_components() {
1035 driver_name=$1
1036
1037 # Required default components
1038 llvm_add_component "bitwriter" $driver_name
1039 llvm_add_component "engine" $driver_name
1040 llvm_add_component "mcdisassembler" $driver_name
1041 llvm_add_component "mcjit" $driver_name
1042
1043 # Optional default components
1044 llvm_add_optional_component "inteljitevents" $driver_name
1045 }
1046
1047 llvm_add_target() {
1048 new_llvm_target=$1
1049 driver_name=$2
1050
1051 if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1052 llvm_add_component $new_llvm_target $driver_name
1053 else
1054 AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1055 fi
1056 }
1057
1058 # Call this inside ` ` to get the return value.
1059 # $1 is the llvm-config command with arguments.
1060 strip_unwanted_llvm_flags() {
1061 echo " `$1` " | sed -E \
1062 -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1063 -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1064 -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1065 -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1066 -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1067 -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1068 -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1069 -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1070 -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1071 -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1072 -e 's/^[[[:space:]]]//' \
1073 -e 's/[[[:space:]]]$//'
1074 }
1075
1076 llvm_set_environment_variables() {
1077 if test "x$LLVM_CONFIG" != xno; then
1078 LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1079 LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1080 LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1081 LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1082
1083 # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1084 save_CFLAGS="$CFLAGS"
1085 CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1086
1087 AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1088 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1089 AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1090 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1091 AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1092 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1093
1094 CFLAGS="$save_CFLAGS"
1095
1096 # Only needed for LLVM < 3.6.0
1097 if test -z "$LLVM_VERSION_PATCH"; then
1098 LLVM_VERSION_PATCH=0
1099 fi
1100
1101 LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1102
1103 FOUND_LLVM=yes
1104 else
1105 FOUND_LLVM=no
1106 LLVM_VERSION_INT=0
1107 fi
1108 }
1109
1110 require_llvm() {
1111 if test "x$enable_llvm" != "xyes"; then
1112 AC_MSG_ERROR([--enable-llvm is required when building $1])
1113 fi
1114 }
1115
1116 llvm_require_version() {
1117 require_llvm $2
1118
1119 llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1120 llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1121 llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1122
1123 if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1124 # major > required major
1125 # --> OK
1126 return
1127 fi
1128
1129 if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1130 if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1131 # major = required major and
1132 # minor > required minor
1133 # --> OK
1134 return
1135 else
1136 if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1137 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1138 # major = required major and
1139 # minor = required minor and
1140 # patch >= required patch
1141 # --> OK
1142 return
1143 fi
1144 fi
1145 fi
1146 fi
1147
1148 AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1149 }
1150
1151 radeon_llvm_check() {
1152 if test ${LLVM_VERSION_INT} -lt 307; then
1153 amdgpu_llvm_target_name='r600'
1154 else
1155 amdgpu_llvm_target_name='amdgpu'
1156 fi
1157
1158 llvm_require_version $*
1159
1160 llvm_add_target $amdgpu_llvm_target_name $2
1161
1162 llvm_add_default_components $2
1163 llvm_add_component "bitreader" $2
1164 llvm_add_component "ipo" $2
1165
1166 if test "x$have_libelf" != xyes; then
1167 AC_MSG_ERROR([$2 requires libelf when using llvm])
1168 fi
1169 }
1170
1171 llvm_set_environment_variables
1172
1173 AC_SUBST([LLVM_CFLAGS])
1174 AC_SUBST([LLVM_CXXFLAGS])
1175 AC_SUBST([LLVM_LIBS])
1176 AC_SUBST([LLVM_LDFLAGS])
1177 AC_SUBST([LLVM_INCLUDEDIR])
1178
1179 dnl
1180 dnl libunwind
1181 dnl
1182 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1183 AC_ARG_ENABLE([libunwind],
1184 [AS_HELP_STRING([--enable-libunwind],
1185 [Use libunwind for backtracing (default: auto)])],
1186 [LIBUNWIND="$enableval"],
1187 [LIBUNWIND="$HAVE_LIBUNWIND"])
1188
1189 if test "x$LIBUNWIND" = "xyes"; then
1190 PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1191 AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1192 fi
1193
1194
1195 dnl Options for APIs
1196 AC_ARG_ENABLE([opengl],
1197 [AS_HELP_STRING([--disable-opengl],
1198 [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1199 [enable_opengl="$enableval"],
1200 [enable_opengl=yes])
1201 AC_ARG_ENABLE([gles1],
1202 [AS_HELP_STRING([--disable-gles1],
1203 [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1204 [enable_gles1="$enableval"],
1205 [enable_gles1=yes])
1206 AC_ARG_ENABLE([gles2],
1207 [AS_HELP_STRING([--disable-gles2],
1208 [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1209 [enable_gles2="$enableval"],
1210 [enable_gles2=yes])
1211
1212 AC_ARG_ENABLE([dri],
1213 [AS_HELP_STRING([--enable-dri],
1214 [enable DRI modules @<:@default=enabled@:>@])],
1215 [enable_dri="$enableval"],
1216 [enable_dri=yes])
1217
1218 AC_ARG_ENABLE([gallium-extra-hud],
1219 [AS_HELP_STRING([--enable-gallium-extra-hud],
1220 [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1221 [enable_gallium_extra_hud="$enableval"],
1222 [enable_gallium_extra_hud=no])
1223 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1224 if test "x$enable_gallium_extra_hud" = xyes ; then
1225 DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1226 fi
1227
1228 #TODO: no pkgconfig .pc available for libsensors.
1229 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1230 AC_ARG_ENABLE([lmsensors],
1231 [AS_HELP_STRING([--enable-lmsensors],
1232 [enable HUD lmsensor support @<:@default=disabled@:>@])],
1233 [enable_lmsensors="$enableval"],
1234 [enable_lmsensors=no])
1235 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1236 if test "x$enable_lmsensors" = xyes ; then
1237 DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1238 LIBSENSORS_LIBS="-lsensors"
1239 else
1240 LIBSENSORS_LIBS=""
1241 fi
1242 AC_SUBST(LIBSENSORS_LIBS)
1243
1244 case "$host_os" in
1245 linux*)
1246 dri3_default=yes
1247 ;;
1248 *)
1249 dri3_default=no
1250 ;;
1251 esac
1252
1253 if test "x$enable_dri" = xno; then
1254 dri3_default=no
1255 fi
1256
1257 AC_ARG_ENABLE([dri3],
1258 [AS_HELP_STRING([--enable-dri3],
1259 [enable DRI3 @<:@default=auto@:>@])],
1260 [enable_dri3="$enableval"],
1261 [enable_dri3="$dri3_default"])
1262 AC_ARG_ENABLE([glx],
1263 [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1264 [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1265 [enable_glx="$enableval"],
1266 [enable_glx=yes])
1267 AC_ARG_ENABLE([osmesa],
1268 [AS_HELP_STRING([--enable-osmesa],
1269 [enable OSMesa library @<:@default=disabled@:>@])],
1270 [enable_osmesa="$enableval"],
1271 [enable_osmesa=no])
1272 AC_ARG_ENABLE([gallium-osmesa],
1273 [AS_HELP_STRING([--enable-gallium-osmesa],
1274 [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1275 [enable_gallium_osmesa="$enableval"],
1276 [enable_gallium_osmesa=no])
1277 AC_ARG_ENABLE([egl],
1278 [AS_HELP_STRING([--disable-egl],
1279 [disable EGL library @<:@default=enabled@:>@])],
1280 [enable_egl="$enableval"],
1281 [enable_egl=yes])
1282
1283 AC_ARG_ENABLE([xa],
1284 [AS_HELP_STRING([--enable-xa],
1285 [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1286 [enable_xa="$enableval"],
1287 [enable_xa=no])
1288 AC_ARG_ENABLE([gbm],
1289 [AS_HELP_STRING([--enable-gbm],
1290 [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1291 [enable_gbm="$enableval"],
1292 [case "$host_os" in
1293 cygwin* | darwin*)
1294 enable_gbm=no
1295 ;;
1296 *)
1297 enable_gbm=yes
1298 ;;
1299 esac])
1300 AC_ARG_ENABLE([nine],
1301 [AS_HELP_STRING([--enable-nine],
1302 [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1303 [enable_nine="$enableval"],
1304 [enable_nine=no])
1305
1306 AC_ARG_ENABLE([xvmc],
1307 [AS_HELP_STRING([--enable-xvmc],
1308 [enable xvmc library @<:@default=auto@:>@])],
1309 [enable_xvmc="$enableval"],
1310 [enable_xvmc=auto])
1311 AC_ARG_ENABLE([vdpau],
1312 [AS_HELP_STRING([--enable-vdpau],
1313 [enable vdpau library @<:@default=auto@:>@])],
1314 [enable_vdpau="$enableval"],
1315 [enable_vdpau=auto])
1316 AC_ARG_ENABLE([omx],
1317 [AS_HELP_STRING([--enable-omx],
1318 [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1319 [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1320 [])
1321 AC_ARG_ENABLE([omx-bellagio],
1322 [AS_HELP_STRING([--enable-omx-bellagio],
1323 [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1324 [enable_omx_bellagio="$enableval"],
1325 [enable_omx_bellagio=no])
1326 AC_ARG_ENABLE([omx-tizonia],
1327 [AS_HELP_STRING([--enable-omx-tizonia],
1328 [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1329 [enable_omx_tizonia="$enableval"],
1330 [enable_omx_tizonia=no])
1331 AC_ARG_ENABLE([va],
1332 [AS_HELP_STRING([--enable-va],
1333 [enable va library @<:@default=auto@:>@])],
1334 [enable_va="$enableval"],
1335 [enable_va=auto])
1336 AC_ARG_ENABLE([opencl],
1337 [AS_HELP_STRING([--enable-opencl],
1338 [enable OpenCL library @<:@default=disabled@:>@])],
1339 [enable_opencl="$enableval"],
1340 [enable_opencl=no])
1341 AC_ARG_ENABLE([opencl_icd],
1342 [AS_HELP_STRING([--enable-opencl-icd],
1343 [Build an OpenCL ICD library to be loaded by an ICD implementation
1344 @<:@default=enabled@:>@])],
1345 [enable_opencl_icd="$enableval"],
1346 [enable_opencl_icd=yes])
1347
1348 AC_ARG_ENABLE([gallium-tests],
1349 [AS_HELP_STRING([--enable-gallium-tests],
1350 [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1351 [enable_gallium_tests="$enableval"],
1352 [enable_gallium_tests=no])
1353
1354 # Option for Gallium drivers
1355
1356 # Keep this in sync with the --with-gallium-drivers help string default value
1357 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1358
1359 AC_ARG_WITH([gallium-drivers],
1360 [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1361 [comma delimited Gallium drivers list, e.g.
1362 "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,vc4,vc5,virgl,etnaviv,imx"
1363 @<:@default=r300,r600,svga,swrast@:>@])],
1364 [with_gallium_drivers="$withval"],
1365 [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1366
1367 # Doing '--without-gallium-drivers' will set this variable to 'no'. Clear it
1368 # here so that the script doesn't choke on an unknown driver name later.
1369 case "$with_gallium_drivers" in
1370 yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1371 no) with_gallium_drivers='' ;;
1372 esac
1373
1374 if test "x$enable_opengl" = xno -a \
1375 "x$enable_gles1" = xno -a \
1376 "x$enable_gles2" = xno -a \
1377 "x$enable_nine" = xno -a \
1378 "x$enable_xa" = xno -a \
1379 "x$enable_xvmc" = xno -a \
1380 "x$enable_vdpau" = xno -a \
1381 "x$enable_omx_bellagio" = xno -a \
1382 "x$enable_omx_tizonia" = xno -a \
1383 "x$enable_va" = xno -a \
1384 "x$enable_opencl" = xno; then
1385 AC_MSG_ERROR([at least one API should be enabled])
1386 fi
1387
1388 if test "x$enable_omx_bellagio" = xyes -a \
1389 "x$enable_omx_tizonia" = xyes; then
1390 AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1391 fi
1392
1393 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1394 if test "x$enable_opengl" = xno -a \
1395 "x$enable_gles1" = xyes; then
1396 AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1397 fi
1398
1399 if test "x$enable_opengl" = xno -a \
1400 "x$enable_gles2" = xyes; then
1401 AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1402 fi
1403
1404 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1405 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1406 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1407 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1408 "x$enable_gles1" = xyes -o \
1409 "x$enable_gles2" = xyes)
1410 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1411 "x$enable_gles1" = xyes -o \
1412 "x$enable_gles2" = xyes)
1413
1414 # Validate GLX options
1415 if test "x$enable_glx" = xyes; then
1416 if test "x$enable_dri" = xyes; then
1417 enable_glx=dri
1418 elif test -n "$with_gallium_drivers"; then
1419 enable_glx=gallium-xlib
1420 else
1421 enable_glx=xlib
1422 fi
1423 fi
1424 case "x$enable_glx" in
1425 xdri | xxlib | xgallium-xlib)
1426 # GLX requires OpenGL
1427 if test "x$enable_opengl" = xno; then
1428 AC_MSG_ERROR([GLX cannot be built without OpenGL])
1429 fi
1430
1431 # Check individual dependencies
1432 case "x$enable_glx" in
1433 xdri)
1434 if test "x$enable_dri" = xno; then
1435 AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1436 fi
1437 ;;
1438 xxlib)
1439 if test "x$enable_dri" = xyes; then
1440 AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1441 fi
1442 ;;
1443 xgallium-xlib )
1444 if test "x$enable_dri" = xyes; then
1445 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1446 fi
1447 if test -z "$with_gallium_drivers"; then
1448 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1449 fi
1450 ;;
1451 esac
1452 ;;
1453 xno)
1454 ;;
1455 *)
1456 AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1457 ;;
1458 esac
1459
1460 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1461 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1462 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1463 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1464
1465 DEFAULT_GL_LIB_NAME=GL
1466
1467 dnl
1468 dnl Libglvnd configuration
1469 dnl
1470 AC_ARG_ENABLE([libglvnd],
1471 [AS_HELP_STRING([--enable-libglvnd],
1472 [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1473 [enable_libglvnd="$enableval"],
1474 [enable_libglvnd=no])
1475 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1476
1477 if test "x$enable_libglvnd" = xyes ; then
1478 case "x$enable_glx" in
1479 xxlib | xgallium-xlib )
1480 AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1481 ;;
1482 esac
1483
1484 PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1485 LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1486 AC_SUBST([LIBGLVND_DATADIR])
1487
1488 DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1489 DEFAULT_GL_LIB_NAME=GLX_mesa
1490
1491 if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1492 AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1493 fi
1494 fi
1495
1496 AC_ARG_WITH([gl-lib-name],
1497 [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1498 [specify GL library name @<:@default=GL@:>@])],
1499 [GL_LIB=$withval],
1500 [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1501 AC_ARG_WITH([osmesa-lib-name],
1502 [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1503 [specify OSMesa library name @<:@default=OSMesa@:>@])],
1504 [OSMESA_LIB=$withval],
1505 [OSMESA_LIB=OSMesa])
1506 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1507 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1508
1509 dnl
1510 dnl Mangled Mesa support
1511 dnl
1512 AC_ARG_ENABLE([mangling],
1513 [AS_HELP_STRING([--enable-mangling],
1514 [enable mangled symbols and library name @<:@default=disabled@:>@])],
1515 [enable_mangling="${enableval}"],
1516 [enable_mangling=no]
1517 )
1518 if test "x${enable_mangling}" = "xyes" ; then
1519 DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1520 GL_LIB="Mangled${GL_LIB}"
1521 OSMESA_LIB="Mangled${OSMESA_LIB}"
1522 fi
1523 AC_SUBST([GL_LIB])
1524 AC_SUBST([OSMESA_LIB])
1525
1526 # Check for libdrm
1527 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1528 [have_libdrm=yes], [have_libdrm=no])
1529 if test "x$have_libdrm" = xyes; then
1530 DEFINES="$DEFINES -DHAVE_LIBDRM"
1531 fi
1532
1533 require_libdrm() {
1534 if test "x$have_libdrm" != xyes; then
1535 AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1536 fi
1537 }
1538
1539
1540 # Select which platform-dependent DRI code gets built
1541 case "$host_os" in
1542 darwin*)
1543 dri_platform='apple' ;;
1544 cygwin*)
1545 dri_platform='windows' ;;
1546 gnu*)
1547 dri_platform='none' ;;
1548 *)
1549 dri_platform='drm' ;;
1550 esac
1551
1552 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1553 have_drisw_kms='yes'
1554 fi
1555
1556 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1557 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1558 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1559 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1560 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1561 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1562 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1563 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1564 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1565
1566 AC_ARG_ENABLE([shared-glapi],
1567 [AS_HELP_STRING([--enable-shared-glapi],
1568 [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1569 [enable_shared_glapi="$enableval"],
1570 [enable_shared_glapi=yes])
1571
1572 case "x$enable_opengl$enable_gles1$enable_gles2" in
1573 x*yes*yes*)
1574 if test "x$enable_shared_glapi" = xno; then
1575 AC_MSG_ERROR([shared GLAPI required when building two or more of
1576 the following APIs - opengl, gles1 gles2])
1577 fi
1578 ;;
1579 esac
1580
1581 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1582
1583 # Build the pipe-drivers as separate libraries/modules.
1584 # Do not touch this unless you know what you are doing.
1585 # XXX: Expose via configure option ?
1586 enable_shared_pipe_drivers=no
1587
1588 dnl
1589 dnl Driver specific build directories
1590 dnl
1591
1592 if test "x$enable_gallium_osmesa" = xyes; then
1593 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1594 AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1595 fi
1596 if test "x$enable_osmesa" = xyes; then
1597 AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1598 fi
1599 fi
1600
1601 require_dri_shared_libs_and_glapi() {
1602 if test "x$enable_static" = xyes; then
1603 AC_MSG_ERROR([$1 cannot be build as static library])
1604 fi
1605
1606 if test "x$enable_dri" != xyes; then
1607 # There is only a single backend which won't be build/used otherwise.
1608 # XXX: Revisit this as the egl/haiku is a thing.
1609 AC_MSG_ERROR([$1 requires --enable-dri])
1610 fi
1611
1612 if test "x$enable_shared_glapi" != xyes; then
1613 AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1614 fi
1615 }
1616
1617 if test "x$enable_dri" = xyes; then
1618 require_dri_shared_libs_and_glapi "DRI"
1619
1620 # not a hard requirement as swrast does not depend on it
1621 if test "x$have_libdrm" = xyes; then
1622 DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1623 fi
1624 fi
1625
1626 AC_ARG_ENABLE([driglx-direct],
1627 [AS_HELP_STRING([--disable-driglx-direct],
1628 [disable direct rendering in GLX and EGL for DRI \
1629 @<:@default=enabled@:>@])],
1630 [driglx_direct="$enableval"],
1631 [driglx_direct="yes"])
1632
1633 dnl
1634 dnl libGL configuration per driver
1635 dnl
1636 if test "x$enable_glx" != xno; then
1637 PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1638 fi
1639 case "x$enable_glx" in
1640 xxlib | xgallium-xlib)
1641 # Xlib-based GLX
1642 dri_modules="x11 xext xcb"
1643 PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1644 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1645 X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1646 GL_LIB_DEPS="$XLIBGL_LIBS"
1647 GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1648 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1649 ;;
1650 xdri)
1651 # DRI-based GLX
1652
1653 # find the DRI deps for libGL
1654 dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1655
1656 if test x"$driglx_direct" = xyes; then
1657 if test x"$dri_platform" = xdrm ; then
1658 DEFINES="$DEFINES -DGLX_USE_DRM"
1659 require_libdrm "Direct rendering"
1660
1661 PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1662 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1663
1664 if test x"$enable_dri" = xyes; then
1665 dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1666 fi
1667 fi
1668 if test x"$dri_platform" = xapple ; then
1669 DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1670 fi
1671 if test x"$dri_platform" = xwindows ; then
1672 DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1673 fi
1674 fi
1675
1676 # add xf86vidmode if available
1677 PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1678 if test "$HAVE_XF86VIDMODE" = yes ; then
1679 dri_modules="$dri_modules xxf86vm"
1680 fi
1681
1682 PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1683 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1684 X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1685 GL_LIB_DEPS="$DRIGL_LIBS"
1686
1687 # need DRM libs, $PTHREAD_LIBS, etc.
1688 GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1689 GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1690 ;;
1691 esac
1692
1693 # This is outside the case (above) so that it is invoked even for non-GLX
1694 # builds.
1695 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1696
1697 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1698 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1699 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1700 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1701
1702 AC_SUBST([X11_INCLUDES])
1703 AC_SUBST([GL_LIB_DEPS])
1704 AC_SUBST([GL_PC_REQ_PRIV])
1705 AC_SUBST([GL_PC_LIB_PRIV])
1706 AC_SUBST([GL_PC_CFLAGS])
1707 AC_SUBST([DRI_PC_REQ_PRIV])
1708 AC_SUBST([GLESv1_CM_LIB_DEPS])
1709 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1710 AC_SUBST([GLESv2_LIB_DEPS])
1711 AC_SUBST([GLESv2_PC_LIB_PRIV])
1712
1713 AC_SUBST([HAVE_XF86VIDMODE])
1714
1715 dnl
1716 dnl More GLX setup
1717 dnl
1718 case "x$enable_glx" in
1719 xxlib | xgallium-xlib)
1720 DEFINES="$DEFINES -DUSE_XSHM"
1721 ;;
1722 xdri)
1723 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1724 if test "x$driglx_direct" = xyes; then
1725 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1726 fi
1727 ;;
1728 esac
1729
1730 dnl
1731 dnl TLS detection
1732 dnl
1733
1734 AC_ARG_ENABLE([glx-tls],
1735 [AS_HELP_STRING([--enable-glx-tls],
1736 [enable TLS support in GLX @<:@default=enabled@:>@])],
1737 [GLX_USE_TLS="$enableval"],
1738 [GLX_USE_TLS=yes])
1739 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1740
1741 if test "x$GLX_USE_TLS" = xyes; then
1742 DEFINES="$DEFINES -DGLX_USE_TLS"
1743 fi
1744
1745 dnl Read-only text section on x86 hardened platforms
1746 AC_ARG_ENABLE([glx-read-only-text],
1747 [AS_HELP_STRING([--enable-glx-read-only-text],
1748 [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1749 [enable_glx_read_only_text="$enableval"],
1750 [enable_glx_read_only_text=no])
1751 if test "x$enable_glx_read_only_text" = xyes; then
1752 DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1753 fi
1754
1755 dnl
1756 dnl DEPRECATED: EGL Platforms configuration
1757 dnl
1758 AC_ARG_WITH([egl-platforms],
1759 [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1760 [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1761 [with_egl_platforms="$withval"],
1762 [with_egl_platforms=auto])
1763
1764 if test "x$with_egl_platforms" = xauto; then
1765 with_egl_platforms="x11,surfaceless"
1766 if test "x$enable_gbm" = xyes; then
1767 with_egl_platforms="$with_egl_platforms,drm"
1768 fi
1769 else
1770 AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1771 fi
1772
1773 dnl
1774 dnl Platforms configuration
1775 dnl
1776 AC_ARG_WITH([platforms],
1777 [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1778 [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1779 "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1780 [with_platforms="$withval"],
1781 [with_platforms=auto])
1782
1783 # Reuse the autodetection rather than duplicating it.
1784 if test "x$with_platforms" = xauto; then
1785 with_platforms=$with_egl_platforms
1786 fi
1787
1788 # Do per platform setups and checks
1789 platforms=`IFS=', '; echo $with_platforms`
1790 for plat in $platforms; do
1791 case "$plat" in
1792 wayland)
1793
1794 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1795 PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1796 PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1797 WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1798
1799 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1800 WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1801 WAYLAND_SCANNER='')
1802 if test "x$WAYLAND_SCANNER" = x; then
1803 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1804 fi
1805
1806 if test "x$WAYLAND_SCANNER" = "x:"; then
1807 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1808 fi
1809 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1810 ;;
1811
1812 x11)
1813 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1814 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1815 ;;
1816
1817 drm)
1818 test "x$enable_gbm" = "xno" &&
1819 AC_MSG_ERROR([EGL platform drm needs gbm])
1820 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1821 ;;
1822
1823 surfaceless)
1824 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1825 ;;
1826
1827 android)
1828 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1829 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1830 ;;
1831
1832 *)
1833 AC_MSG_ERROR([platform '$plat' does not exist])
1834 ;;
1835 esac
1836
1837 case "$plat" in
1838 wayland|drm|surfaceless)
1839 require_libdrm "Platform $plat"
1840 ;;
1841 esac
1842 done
1843 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1844
1845 if test "x$enable_glx" != xno; then
1846 if ! echo "$platforms" | grep -q 'x11'; then
1847 AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1848 fi
1849 fi
1850
1851 if test x"$enable_dri3" = xyes; then
1852 DEFINES="$DEFINES -DHAVE_DRI3"
1853
1854 dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1855 PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1856 dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1857 PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1858
1859 if test "x$have_dri3_modifiers" == xyes; then
1860 DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1861 fi
1862 fi
1863
1864 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1865 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1866 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1867 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1868 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1869
1870 dnl
1871 dnl More DRI setup
1872 dnl
1873 dnl Directory for DRI drivers
1874 AC_ARG_WITH([dri-driverdir],
1875 [AS_HELP_STRING([--with-dri-driverdir=DIR],
1876 [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1877 [DRI_DRIVER_INSTALL_DIR="$withval"],
1878 [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1879 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1880 dnl Extra search path for DRI drivers
1881 AC_ARG_WITH([dri-searchpath],
1882 [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1883 [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1884 [DRI_DRIVER_SEARCH_DIR="$withval"],
1885 [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1886 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1887 dnl Which drivers to build - default is chosen by platform
1888 AC_ARG_WITH([dri-drivers],
1889 [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1890 [comma delimited classic DRI drivers list, e.g.
1891 "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1892 [with_dri_drivers="$withval"],
1893 [with_dri_drivers=auto])
1894
1895 if test "x$with_dri_drivers" = xauto; then
1896 if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1897 with_dri_drivers="yes"
1898 else
1899 with_dri_drivers="no"
1900 fi
1901 fi
1902 if test "x$with_dri_drivers" = xno; then
1903 with_dri_drivers=''
1904 fi
1905
1906 # Check for expat
1907 PKG_CHECK_MODULES([EXPAT], [expat],,
1908 [PKG_CHECK_MODULES([EXPAT], [expat21])]
1909 )
1910
1911 dnl If $with_dri_drivers is yes, drivers will be added through
1912 dnl platform checks. Set DEFINES and LIB_DEPS
1913 if test "x$enable_dri" = xyes; then
1914 # Platform specific settings and drivers to build
1915 case "$host_os" in
1916 linux*)
1917 case "$host_cpu" in
1918 powerpc* | sparc*)
1919 # Build only the drivers for cards that exist on PowerPC/sparc
1920 if test "x$with_dri_drivers" = "xyes"; then
1921 with_dri_drivers="r200 radeon swrast"
1922 fi
1923 ;;
1924 esac
1925 ;;
1926 cygwin*)
1927 if test "x$with_dri_drivers" = "xyes"; then
1928 with_dri_drivers="swrast"
1929 fi
1930 ;;
1931 darwin*)
1932 DEFINES="$DEFINES -DBUILDING_MESA"
1933 if test "x$with_dri_drivers" = "xyes"; then
1934 with_dri_drivers="swrast"
1935 fi
1936 ;;
1937 esac
1938
1939 # default drivers
1940 if test "x$with_dri_drivers" = "xyes"; then
1941 with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1942 fi
1943
1944 # put all the necessary libs together
1945 DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1946 fi
1947
1948 AC_SUBST([DRI_LIB_DEPS])
1949
1950 DRI_DIRS=''
1951 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1952 if test -n "$with_dri_drivers"; then
1953 if test "x$enable_opengl" != xyes; then
1954 AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1955 fi
1956
1957 dri_drivers=`IFS=', '; echo $with_dri_drivers`
1958 for driver in $dri_drivers; do
1959 DRI_DIRS="$DRI_DIRS $driver"
1960 case "x$driver" in
1961 xi915)
1962 require_libdrm "i915"
1963 HAVE_I915_DRI=yes
1964 PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1965 ;;
1966 xi965)
1967 require_libdrm "i965"
1968 HAVE_I965_DRI=yes
1969 ;;
1970 xnouveau)
1971 require_libdrm "nouveau"
1972 HAVE_NOUVEAU_DRI=yes
1973 PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1974 ;;
1975 xradeon)
1976 require_libdrm "radeon"
1977 HAVE_RADEON_DRI=yes;
1978 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1979 ;;
1980 xr200)
1981 require_libdrm "r200"
1982 HAVE_R200_DRI=yes
1983 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1984 ;;
1985 xswrast)
1986 HAVE_SWRAST_DRI=yes
1987 ;;
1988 *)
1989 AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1990 ;;
1991 esac
1992 done
1993 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1994 fi
1995
1996
1997 dnl
1998 dnl Gallium LLVM
1999 dnl Deprecated: kept for backwards compatibility
2000 dnl
2001 AC_ARG_ENABLE([gallium-llvm],
2002 [AS_HELP_STRING([--enable-gallium-llvm],
2003 [DEPRECATED: use --enable-llvm instead])],
2004 [enable_gallium_llvm="$enableval"],
2005 [enable_gallium_llvm=auto])
2006
2007 if test "x$enable_gallium_llvm" != xauto; then
2008 AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2009 enable_llvm=$enable_gallium_llvm
2010 fi
2011
2012 dnl
2013 dnl LLVM
2014 dnl
2015 AC_ARG_ENABLE([llvm],
2016 [AS_HELP_STRING([--enable-llvm],
2017 [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2018 [enable_llvm="$enableval"],
2019 [enable_llvm=auto])
2020
2021 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2022 if test "x$FOUND_LLVM" = xyes; then
2023 case "$host_cpu" in
2024 i*86|x86_64|amd64) enable_llvm=yes;;
2025 *) enable_llvm=no;;
2026 esac
2027 else
2028 enable_llvm=no
2029 fi
2030 fi
2031
2032 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2033 AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2034 fi
2035
2036 #
2037 # Vulkan driver configuration
2038 #
2039
2040 AC_ARG_WITH([vulkan-drivers],
2041 [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2042 [comma delimited Vulkan drivers list, e.g.
2043 "intel,radeon"
2044 @<:@default=no@:>@])],
2045 [with_vulkan_drivers="$withval"],
2046 [with_vulkan_drivers="no"])
2047
2048 # Doing '--without-vulkan-drivers' will set this variable to 'no'. Clear it
2049 # here so that the script doesn't choke on an unknown driver name later.
2050 case "x$with_vulkan_drivers" in
2051 xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2052 xno) with_vulkan_drivers='' ;;
2053 esac
2054
2055 AC_ARG_WITH([vulkan-icddir],
2056 [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2057 [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2058 [VULKAN_ICD_INSTALL_DIR="$withval"],
2059 [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2060 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2061
2062 require_x11_dri3() {
2063 if echo "$platforms" | grep -q 'x11'; then
2064 if test "x$enable_dri3" != xyes; then
2065 AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2066 fi
2067 fi
2068 }
2069
2070 if test -n "$with_vulkan_drivers"; then
2071 if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2072 AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2073 fi
2074
2075 VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2076 for driver in $VULKAN_DRIVERS; do
2077 case "x$driver" in
2078 xintel)
2079 require_libdrm "ANV"
2080 require_x11_dri3 "ANV"
2081 HAVE_INTEL_VULKAN=yes
2082 ;;
2083 xradeon)
2084 require_libdrm "radv"
2085 PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2086 radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2087 require_x11_dri3 "radv"
2088 HAVE_RADEON_VULKAN=yes
2089 ;;
2090 *)
2091 AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2092 ;;
2093 esac
2094 done
2095 VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2096 fi
2097
2098
2099 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2100 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2101 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2102 "x$enable_osmesa" = xyes -o \
2103 -n "$DRI_DIRS")
2104
2105 dnl
2106 dnl OSMesa configuration
2107 dnl
2108
2109 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2110 AC_ARG_WITH([osmesa-bits],
2111 [AS_HELP_STRING([--with-osmesa-bits=BITS],
2112 [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2113 [osmesa_bits="$withval"],
2114 [osmesa_bits=8])
2115 if test "x$osmesa_bits" != x8; then
2116 if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2117 AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2118 osmesa_bits=8
2119 fi
2120 fi
2121 case "x$osmesa_bits" in
2122 x8)
2123 OSMESA_LIB="${OSMESA_LIB}"
2124 ;;
2125 x16|x32)
2126 OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2127 DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2128 ;;
2129 *)
2130 AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2131 ;;
2132 esac
2133
2134 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2135 # only link libraries with osmesa if shared
2136 if test "$enable_static" = no; then
2137 OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2138 else
2139 OSMESA_LIB_DEPS=""
2140 fi
2141 OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2142 fi
2143
2144 AC_SUBST([OSMESA_LIB_DEPS])
2145 AC_SUBST([OSMESA_PC_REQ])
2146 AC_SUBST([OSMESA_PC_LIB_PRIV])
2147
2148 dnl
2149 dnl gbm configuration
2150 dnl
2151 if test "x$enable_gbm" = xyes; then
2152 require_dri_shared_libs_and_glapi "gbm"
2153 fi
2154 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2155 # FINISHME: GBM has a number of dependencies which we should add below
2156 GBM_PC_REQ_PRIV=""
2157 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2158 AC_SUBST([GBM_PC_REQ_PRIV])
2159 AC_SUBST([GBM_PC_LIB_PRIV])
2160
2161 dnl
2162 dnl EGL configuration
2163 dnl
2164
2165 if test "x$enable_egl" = xyes; then
2166 EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2167
2168 AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2169
2170 require_dri_shared_libs_and_glapi "egl"
2171 fi
2172 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2173 AC_SUBST([EGL_LIB_DEPS])
2174
2175 gallium_st="mesa"
2176
2177 dnl
2178 dnl XA configuration
2179 dnl
2180 if test "x$enable_xa" = xyes; then
2181 if test "x$with_gallium_drivers" = xswrast; then
2182 AC_MSG_ERROR([
2183 Building xa requires at least one non swrast gallium driver.
2184 If you are looking to use libxatracker.so with the VMware driver,
2185 make sure to include svga in the gallium drivers list, apart from
2186 enabling XA.
2187 Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2188 fi
2189 gallium_st="$gallium_st xa"
2190 fi
2191 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2192
2193 if echo $platforms | grep -q "x11"; then
2194 have_xvmc_platform=yes
2195 else
2196 have_xvmc_platform=no
2197 fi
2198
2199 if echo $platforms | grep -q "x11"; then
2200 have_vdpau_platform=yes
2201 else
2202 have_vdpau_platform=no
2203 fi
2204
2205 if echo $platforms | grep -q "x11\|drm"; then
2206 have_omx_platform=yes
2207 else
2208 have_omx_platform=no
2209 fi
2210
2211 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2212 have_va_platform=yes
2213 else
2214 have_va_platform=no
2215 fi
2216
2217 dnl
2218 dnl Gallium G3DVL configuration
2219 dnl
2220 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2221 if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2222 PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2223 fi
2224
2225 if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2226 PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2227 fi
2228
2229 if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2230 PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2231 fi
2232
2233 if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2234 PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2235 fi
2236
2237 if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2238 PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2239 fi
2240 fi
2241
2242 if test "x$enable_dri" = xyes -o \
2243 "x$enable_xvmc" = xyes -o \
2244 "x$enable_vdpau" = xyes -o \
2245 "x$enable_omx_bellagio" = xyes -o \
2246 "x$enable_omx_tizonia" = xyes -o \
2247 "x$enable_va" = xyes; then
2248 need_gallium_vl=yes
2249 fi
2250 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2251
2252 if test "x$enable_xvmc" = xyes -o \
2253 "x$enable_vdpau" = xyes -o \
2254 "x$enable_omx_bellagio" = xyes -o \
2255 "x$enable_omx_tizonia" = xyes -o \
2256 "x$enable_va" = xyes; then
2257 if echo $platforms | grep -q "x11"; then
2258 PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2259 fi
2260 need_gallium_vl_winsys=yes
2261 fi
2262 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2263
2264 if test "x$enable_xvmc" = xyes; then
2265 if test "x$have_xvmc_platform" != xyes; then
2266 AC_MSG_ERROR([XVMC requires the x11 platforms])
2267 fi
2268 PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2269 gallium_st="$gallium_st xvmc"
2270 fi
2271 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2272
2273 if test "x$enable_vdpau" = xyes; then
2274 if test "x$have_vdpau_platform" != xyes; then
2275 AC_MSG_ERROR([VDPAU requires the x11 platforms])
2276 fi
2277 PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2278 gallium_st="$gallium_st vdpau"
2279 DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2280 fi
2281 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2282
2283 if test "x$enable_omx_bellagio" = xyes; then
2284 if test "x$have_omx_platform" != xyes; then
2285 AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2286 fi
2287 PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2288 gallium_st="$gallium_st omx_bellagio"
2289 AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2290 else
2291 AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2292 fi
2293 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2294
2295 if test "x$enable_omx_tizonia" = xyes; then
2296 if test "x$have_omx_platform" != xyes; then
2297 AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2298 fi
2299 PKG_CHECK_MODULES([OMX_TIZONIA],
2300 [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2301 tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2302 libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2303 gallium_st="$gallium_st omx_tizonia"
2304 AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2305 else
2306 AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2307 fi
2308 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2309
2310 if test "x$enable_va" = xyes; then
2311 if test "x$have_va_platform" != xyes; then
2312 AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2313 fi
2314 PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2315 gallium_st="$gallium_st va"
2316 fi
2317 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2318
2319 dnl
2320 dnl Nine Direct3D9 configuration
2321 dnl
2322 if test "x$enable_nine" = xyes; then
2323 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2324 AC_MSG_ERROR([nine requires the gallium swrast driver])
2325 fi
2326 if test "x$with_gallium_drivers" = xswrast; then
2327 AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2328 fi
2329 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2330 AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2331 fi
2332
2333 if test "x$enable_dri3" = xno; then
2334 AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2335 fi
2336
2337 gallium_st="$gallium_st nine"
2338 fi
2339 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2340
2341 dnl
2342 dnl OpenCL configuration
2343 dnl
2344
2345 AC_ARG_WITH([clang-libdir],
2346 [AS_HELP_STRING([--with-clang-libdir],
2347 [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2348 [CLANG_LIBDIR="$withval"],
2349 [CLANG_LIBDIR=''])
2350
2351 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2352
2353 if test "x$enable_opencl" = xyes; then
2354 if test -z "$with_gallium_drivers"; then
2355 AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2356 fi
2357
2358 if test "x$HAVE_CXX11" != "xyes"; then
2359 AC_MSG_ERROR([clover requires c++11 support])
2360 fi
2361
2362 if test "x$have_libclc" = xno; then
2363 AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2364 Make sure the directory containing libclc.pc is specified in your
2365 PKG_CONFIG_PATH environment variable.
2366 By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2367 else
2368 LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2369 LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2370 AC_SUBST([LIBCLC_INCLUDEDIR])
2371 AC_SUBST([LIBCLC_LIBEXECDIR])
2372 fi
2373
2374 gallium_st="$gallium_st clover"
2375
2376 if test "x$enable_opencl_icd" = xyes; then
2377 OPENCL_LIBNAME="MesaOpenCL"
2378 else
2379 OPENCL_LIBNAME="OpenCL"
2380 fi
2381
2382 if test "x$have_libelf" != xyes; then
2383 AC_MSG_ERROR([Clover requires libelf])
2384 fi
2385
2386 if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2387 altivec_enabled=no
2388 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2389 #if !defined(__VEC__) || !defined(__ALTIVEC__)
2390 #error "AltiVec not enabled"
2391 #endif
2392 ])], altivec_enabled=yes)
2393
2394 if test "$altivec_enabled" = yes; then
2395 CLOVER_STD_OVERRIDE="-std=gnu++11"
2396 fi
2397 AC_SUBST([CLOVER_STD_OVERRIDE])
2398 fi
2399
2400 llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2401
2402 llvm_add_default_components "opencl"
2403 llvm_add_component "all-targets" "opencl"
2404 llvm_add_component "coverage" "opencl"
2405 llvm_add_component "linker" "opencl"
2406 llvm_add_component "instrumentation" "opencl"
2407 llvm_add_component "ipo" "opencl"
2408 llvm_add_component "irreader" "opencl"
2409 llvm_add_component "lto" "opencl"
2410 llvm_add_component "option" "opencl"
2411 llvm_add_component "objcarcopts" "opencl"
2412 llvm_add_component "profiledata" "opencl"
2413 llvm_add_optional_component "coroutines" "opencl"
2414
2415 dnl Check for Clang internal headers
2416 if test -z "$CLANG_LIBDIR"; then
2417 CLANG_LIBDIR=${LLVM_LIBDIR}
2418 fi
2419 CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2420 AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2421 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2422 fi
2423 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2424 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2425 AC_SUBST([OPENCL_LIBNAME])
2426 AC_SUBST([CLANG_RESOURCE_DIR])
2427
2428 dnl
2429 dnl Gallium configuration
2430 dnl
2431 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2432
2433 # libEGL wants to default to the first platform specified in
2434 # ./configure. parse that here.
2435 if test "x$platforms" != "x"; then
2436 FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2437 EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2438 else
2439 EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2440 fi
2441
2442 AC_SUBST([EGL_NATIVE_PLATFORM])
2443 AC_SUBST([EGL_CFLAGS])
2444
2445 # If we don't have the X11 platform, set this define so we don't try to include
2446 # the X11 headers.
2447 if ! echo "$platforms" | grep -q 'x11'; then
2448 DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2449 GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2450 fi
2451
2452 dnl Directory for XVMC libs
2453 AC_ARG_WITH([xvmc-libdir],
2454 [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2455 [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2456 [XVMC_LIB_INSTALL_DIR="$withval"],
2457 [XVMC_LIB_INSTALL_DIR='${libdir}'])
2458 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2459
2460 dnl
2461 dnl Gallium Tests
2462 dnl
2463 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2464
2465 dnl Directory for VDPAU libs
2466 AC_ARG_WITH([vdpau-libdir],
2467 [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2468 [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2469 [VDPAU_LIB_INSTALL_DIR="$withval"],
2470 [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2471 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2472
2473 dnl Directory for OMX_BELLAGIO libs
2474
2475 AC_ARG_WITH([omx-bellagio-libdir],
2476 [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2477 [directory for the OMX_BELLAGIO libraries])],
2478 [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2479 [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2480 $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2481 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2482
2483 dnl Directory for OMX_TIZONIA libs
2484
2485 AC_ARG_WITH([omx-tizonia-libdir],
2486 [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2487 [directory for the OMX_TIZONIA libraries])],
2488 [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2489 [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2490 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2491
2492 dnl Directory for VA libs
2493
2494 AC_ARG_WITH([va-libdir],
2495 [AS_HELP_STRING([--with-va-libdir=DIR],
2496 [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2497 [VA_LIB_INSTALL_DIR="$withval"],
2498 [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2499 AC_SUBST([VA_LIB_INSTALL_DIR])
2500
2501 AC_ARG_WITH([d3d-libdir],
2502 [AS_HELP_STRING([--with-d3d-libdir=DIR],
2503 [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2504 [D3D_DRIVER_INSTALL_DIR="$withval"],
2505 [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2506 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2507
2508 dnl Architectures to build SWR library for
2509
2510 AC_ARG_WITH([swr-archs],
2511 [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2512 [comma delimited swr architectures list, e.g.
2513 "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2514 [with_swr_archs="$withval"],
2515 [with_swr_archs="avx,avx2"])
2516
2517 dnl
2518 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2519 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2520 dnl architectures.
2521 dnl
2522 r300_require_llvm() {
2523 case "$host" in *gnux32) return;; esac
2524 case "$host_cpu" in
2525 i*86|x86_64|amd64) require_llvm $1
2526 ;;
2527 esac
2528 }
2529
2530 dnl
2531 dnl DRM is needed by X, Wayland, and offscreen rendering.
2532 dnl Surfaceless is an alternative for the last one.
2533 dnl
2534 require_basic_egl() {
2535 case "$with_platforms" in
2536 *drm*|*surfaceless*|*android*)
2537 ;;
2538 *)
2539 AC_MSG_ERROR([$1 requires one of these:
2540 1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2541 2) --with-platforms=surfaceless (offscreen only)
2542 3) --with-platforms=android (Android only)
2543 Recommended options: drm,x11])
2544 ;;
2545 esac
2546 }
2547
2548 swr_require_cxx_feature_flags() {
2549 feature_name="$1"
2550 preprocessor_test="$2"
2551 option_list="$3"
2552 output_var="$4"
2553
2554 AC_MSG_CHECKING([whether $CXX supports $feature_name])
2555 AC_LANG_PUSH([C++])
2556 save_CXXFLAGS="$CXXFLAGS"
2557 save_IFS="$IFS"
2558 IFS=","
2559 found=0
2560 for opts in $option_list
2561 do
2562 unset IFS
2563 CXXFLAGS="$opts $save_CXXFLAGS"
2564 AC_COMPILE_IFELSE(
2565 [AC_LANG_PROGRAM(
2566 [ #if !($preprocessor_test)
2567 #error
2568 #endif
2569 ])],
2570 [found=1; break],
2571 [])
2572 IFS=","
2573 done
2574 IFS="$save_IFS"
2575 CXXFLAGS="$save_CXXFLAGS"
2576 AC_LANG_POP([C++])
2577 if test $found -eq 1; then
2578 AC_MSG_RESULT([$opts])
2579 eval "$output_var=\$opts"
2580 return 0
2581 fi
2582 AC_MSG_RESULT([no])
2583 AC_MSG_ERROR([swr requires $feature_name support])
2584 return 1
2585 }
2586
2587 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2588 if test -n "$with_gallium_drivers"; then
2589 gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2590 for driver in $gallium_drivers; do
2591 case "x$driver" in
2592 xsvga)
2593 HAVE_GALLIUM_SVGA=yes
2594 require_libdrm "svga"
2595 ;;
2596 xi915)
2597 HAVE_GALLIUM_I915=yes
2598 PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2599 require_libdrm "Gallium i915"
2600 ;;
2601 xr300)
2602 HAVE_GALLIUM_R300=yes
2603 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2604 require_libdrm "r300"
2605 r300_require_llvm "r300"
2606 ;;
2607 xr600)
2608 HAVE_GALLIUM_R600=yes
2609 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2610 require_libdrm "r600"
2611 if test "x$enable_llvm" = xyes; then
2612 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2613
2614 llvm_add_component "asmparser" "r600"
2615 llvm_add_component "bitreader" "r600"
2616 fi
2617 ;;
2618 xradeonsi)
2619 HAVE_GALLIUM_RADEONSI=yes
2620 PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2621 PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2622 require_libdrm "radeonsi"
2623 radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2624 if test "x$enable_egl" = xyes; then
2625 require_basic_egl "radeonsi"
2626 fi
2627 ;;
2628 xnouveau)
2629 HAVE_GALLIUM_NOUVEAU=yes
2630 PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2631 require_libdrm "nouveau"
2632 ;;
2633 xfreedreno)
2634 HAVE_GALLIUM_FREEDRENO=yes
2635 PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2636 require_libdrm "freedreno"
2637 ;;
2638 xetnaviv)
2639 HAVE_GALLIUM_ETNAVIV=yes
2640 PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2641 require_libdrm "etnaviv"
2642 ;;
2643 ximx)
2644 HAVE_GALLIUM_IMX=yes
2645 ;;
2646 xtegra)
2647 HAVE_GALLIUM_TEGRA=yes
2648 require_libdrm "tegra"
2649 ;;
2650 xswrast)
2651 HAVE_GALLIUM_SOFTPIPE=yes
2652 if test "x$enable_llvm" = xyes; then
2653 HAVE_GALLIUM_LLVMPIPE=yes
2654 fi
2655 ;;
2656 xswr)
2657 llvm_require_version $LLVM_REQUIRED_SWR "swr"
2658
2659 if test "x$HAVE_CXX11" != "xyes"; then
2660 AC_MSG_ERROR([swr requires c++11 support])
2661 fi
2662
2663 swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2664 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2665 SWR_AVX_CXXFLAGS
2666 AC_SUBST([SWR_AVX_CXXFLAGS])
2667
2668 swr_archs=`IFS=', '; echo $with_swr_archs`
2669 for arch in $swr_archs; do
2670 case "x$arch" in
2671 xavx)
2672 HAVE_SWR_AVX=yes
2673 ;;
2674 xavx2)
2675 swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2676 ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2677 SWR_AVX2_CXXFLAGS
2678 AC_SUBST([SWR_AVX2_CXXFLAGS])
2679 HAVE_SWR_AVX2=yes
2680 ;;
2681 xknl)
2682 swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2683 ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2684 SWR_KNL_CXXFLAGS
2685 AC_SUBST([SWR_KNL_CXXFLAGS])
2686 HAVE_SWR_KNL=yes
2687 ;;
2688 xskx)
2689 swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2690 ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2691 SWR_SKX_CXXFLAGS
2692 AC_SUBST([SWR_SKX_CXXFLAGS])
2693 HAVE_SWR_SKX=yes
2694 ;;
2695 *)
2696 AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2697 ;;
2698 esac
2699 done
2700
2701 if test "x$HAVE_SWR_AVX" != xyes -a \
2702 "x$HAVE_SWR_AVX2" != xyes -a \
2703 "x$HAVE_SWR_KNL" != xyes -a \
2704 "x$HAVE_SWR_SKX" != xyes; then
2705 AC_MSG_ERROR([swr enabled but no swr architectures selected])
2706 fi
2707
2708 # test if more than one swr arch configured
2709 if test `echo $swr_archs | wc -w` -eq 1; then
2710 HAVE_SWR_BUILTIN=yes
2711 fi
2712
2713 HAVE_GALLIUM_SWR=yes
2714 ;;
2715 xvc4)
2716 HAVE_GALLIUM_VC4=yes
2717 require_libdrm "vc4"
2718
2719 PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2720 [USE_VC4_SIMULATOR=yes;
2721 DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2722 [USE_VC4_SIMULATOR=no])
2723 ;;
2724 xvc5)
2725 HAVE_GALLIUM_VC5=yes
2726
2727 PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2728 [USE_VC5_SIMULATOR=yes;
2729 DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2730 [AC_MSG_ERROR([vc5 requires the simulator])])
2731 ;;
2732 xpl111)
2733 HAVE_GALLIUM_PL111=yes
2734 ;;
2735 xvirgl)
2736 HAVE_GALLIUM_VIRGL=yes
2737 require_libdrm "virgl"
2738 if test "x$enable_egl" = xyes; then
2739 require_basic_egl "virgl"
2740 fi
2741 ;;
2742 *)
2743 AC_MSG_ERROR([Unknown Gallium driver: $driver])
2744 ;;
2745 esac
2746 done
2747 fi
2748
2749 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2750 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x4.0.0 -a \
2751 "x$LLVM_VERSION" != x4.0.1)
2752
2753 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2754 llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2755 llvm_add_default_components "gallium"
2756 fi
2757
2758 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2759 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2760 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2761 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2762 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2763
2764 dnl We need to validate some needed dependencies for renderonly drivers.
2765
2766 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes ; then
2767 AC_MSG_ERROR([Building with imx requires etnaviv])
2768 fi
2769
2770 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes ; then
2771 AC_MSG_ERROR([Building with pl111 requires vc4])
2772 fi
2773
2774 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2775 AC_MSG_ERROR([Building with tegra requires nouveau])
2776 fi
2777
2778 detect_old_buggy_llvm() {
2779 dnl llvm-config may not give the right answer when llvm is a built as a
2780 dnl single shared library, so we must work the library name out for
2781 dnl ourselves.
2782 dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2783 dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2784 LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2785 AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2786
2787 if test "x$llvm_have_one_so" = xyes; then
2788 dnl LLVM was built using auto*, so there is only one shared object.
2789 LLVM_LIBS="-l$LLVM_SO_NAME"
2790 else
2791 dnl If LLVM was built with CMake, there will be one shared object per
2792 dnl component.
2793 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2794 [AC_MSG_ERROR([Could not find llvm shared libraries:
2795 Please make sure you have built llvm with the --enable-shared option
2796 and that your llvm libraries are installed in $LLVM_LIBDIR
2797 If you have installed your llvm libraries to a different directory you
2798 can use the --with-llvm-prefix= configure flag to specify this directory.
2799 NOTE: Mesa is attempting to use llvm shared libraries by default.
2800 If you do not want to build with llvm shared libraries and instead want to
2801 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2802 invocation and rebuild.])])
2803
2804 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2805 dnl install uses a shared object for each component and we have
2806 dnl already added all of these objects to LLVM_LIBS.
2807 fi
2808 }
2809
2810 dnl
2811 dnl Set defines and buildtime variables only when using LLVM.
2812 dnl
2813 if test "x$enable_llvm" = xyes; then
2814 DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2815
2816 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2817 LLVM_CFLAGS=$LLVM_CPPFLAGS # CPPFLAGS seem to be sufficient
2818 LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2819
2820 dnl Set LLVM_LIBS - This is done after the driver configuration so
2821 dnl that drivers can add additional components to LLVM_COMPONENTS.
2822 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2823 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2824 dnl this was causing the same libraries to be appear multiple times
2825 dnl in LLVM_LIBS.
2826
2827 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2828 if test "x$enable_llvm_shared_libs" = xyes; then
2829 LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2830 else
2831 dnl Invoking llvm-config with both -libs and --system-libs produces the
2832 dnl two separate lines - each for the set of libraries.
2833 dnl Call the program twice, effectively folding them into a single line.
2834 LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2835 dnl We need to link to llvm system libs when using static libs
2836 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2837 fi
2838 else
2839 LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2840 if test "x$enable_llvm_shared_libs" = xyes; then
2841 detect_old_buggy_llvm
2842 else
2843 AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2844 dnl We need to link to llvm system libs when using static libs
2845 dnl However, only llvm 3.5+ provides --system-libs
2846 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2847 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2848 fi
2849 fi
2850 fi
2851
2852 dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2853 dnl swr/llvmpipe driver into the final binary. Adding LLVM_LIBS results in
2854 dnl the LLVM library propagated in the Libs.private of the respective .pc
2855 dnl file which ensures complete dependency information when statically
2856 dnl linking.
2857 if test "x$enable_glx" == xgallium-xlib; then
2858 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2859 fi
2860 if test "x$enable_gallium_osmesa" = xyes; then
2861 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2862 fi
2863 fi
2864
2865 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2866 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2867 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2868 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2869 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2870 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2871 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2872 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2873 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2874 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2875 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2876 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2877 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2878 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2879 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2880 "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2881 "x$HAVE_GALLIUM_SWR" = xyes)
2882 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2883 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2884 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2885
2886 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2887
2888 if test "x$enable_dri" = xyes; then
2889 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2890 fi
2891
2892 if test "x$have_drisw_kms" = xyes; then
2893 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2894 fi
2895 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2896
2897 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2898 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2899 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2900 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2901 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2902 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2903
2904 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2905 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2906
2907 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2908 "x$HAVE_RADEON_VULKAN" = xyes)
2909
2910 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2911 "x$HAVE_GALLIUM_VC5" = xyes)
2912
2913 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2914 "x$HAVE_I965_DRI" = xyes)
2915
2916 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2917 "x$HAVE_GALLIUM_R600" = xyes -o \
2918 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2919 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2920 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2921 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2922 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2923 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2924
2925 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2926 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2927 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2928 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2929 "x$enable_gallium_osmesa" = xyes)
2930
2931 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2932 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2933 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2934 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2935 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2936 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2937
2938 AC_SUBST([NINE_MAJOR], 1)
2939 AC_SUBST([NINE_MINOR], 0)
2940 AC_SUBST([NINE_PATCH], 0)
2941 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
2942
2943 AC_SUBST([VDPAU_MAJOR], 1)
2944 AC_SUBST([VDPAU_MINOR], 0)
2945
2946 if test "x$enable_va" = xyes; then
2947 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2948 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2949 fi
2950 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2951 AC_SUBST([VA_MINOR], $VA_MINOR)
2952
2953 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2954
2955 AC_SUBST([XVMC_MAJOR], 1)
2956 AC_SUBST([XVMC_MINOR], 0)
2957
2958 AC_SUBST([XA_MAJOR], 2)
2959 AC_SUBST([XA_MINOR], 3)
2960 AC_SUBST([XA_PATCH], 0)
2961 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
2962
2963 AC_ARG_ENABLE(valgrind,
2964 [AS_HELP_STRING([--enable-valgrind],
2965 [Build mesa with valgrind support (default: auto)])],
2966 [VALGRIND=$enableval], [VALGRIND=auto])
2967 if test "x$VALGRIND" != xno; then
2968 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2969 fi
2970 AC_MSG_CHECKING([whether to enable Valgrind support])
2971 if test "x$VALGRIND" = xauto; then
2972 VALGRIND="$have_valgrind"
2973 fi
2974
2975 if test "x$VALGRIND" = "xyes"; then
2976 if ! test "x$have_valgrind" = xyes; then
2977 AC_MSG_ERROR([Valgrind support required but not present])
2978 fi
2979 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2980 fi
2981
2982 AC_MSG_RESULT([$VALGRIND])
2983
2984 dnl Restore LDFLAGS and CPPFLAGS
2985 LDFLAGS="$_SAVE_LDFLAGS"
2986 CPPFLAGS="$_SAVE_CPPFLAGS"
2987
2988 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2989 if test "x$acv_mesa_CLANG" = xyes; then
2990 CFLAGS="$CFLAGS -Qunused-arguments"
2991 CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2992 fi
2993
2994 dnl Add user CFLAGS and CXXFLAGS
2995 CFLAGS="$CFLAGS $USER_CFLAGS"
2996 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2997
2998 dnl Substitute the config
2999 AC_CONFIG_FILES([Makefile
3000 src/Makefile
3001 src/amd/Makefile
3002 src/amd/vulkan/Makefile
3003 src/broadcom/Makefile
3004 src/compiler/Makefile
3005 src/egl/Makefile
3006 src/egl/main/egl.pc
3007 src/egl/wayland/wayland-drm/Makefile
3008 src/egl/wayland/wayland-egl/Makefile
3009 src/egl/wayland/wayland-egl/wayland-egl.pc
3010 src/gallium/Makefile
3011 src/gallium/auxiliary/Makefile
3012 src/gallium/auxiliary/pipe-loader/Makefile
3013 src/gallium/drivers/freedreno/Makefile
3014 src/gallium/drivers/ddebug/Makefile
3015 src/gallium/drivers/i915/Makefile
3016 src/gallium/drivers/llvmpipe/Makefile
3017 src/gallium/drivers/noop/Makefile
3018 src/gallium/drivers/nouveau/Makefile
3019 src/gallium/drivers/pl111/Makefile
3020 src/gallium/drivers/r300/Makefile
3021 src/gallium/drivers/r600/Makefile
3022 src/gallium/drivers/radeonsi/Makefile
3023 src/gallium/drivers/rbug/Makefile
3024 src/gallium/drivers/softpipe/Makefile
3025 src/gallium/drivers/svga/Makefile
3026 src/gallium/drivers/swr/Makefile
3027 src/gallium/drivers/tegra/Makefile
3028 src/gallium/drivers/trace/Makefile
3029 src/gallium/drivers/etnaviv/Makefile
3030 src/gallium/drivers/imx/Makefile
3031 src/gallium/drivers/vc4/Makefile
3032 src/gallium/drivers/vc5/Makefile
3033 src/gallium/drivers/virgl/Makefile
3034 src/gallium/state_trackers/clover/Makefile
3035 src/gallium/state_trackers/dri/Makefile
3036 src/gallium/state_trackers/glx/xlib/Makefile
3037 src/gallium/state_trackers/nine/Makefile
3038 src/gallium/state_trackers/omx/Makefile
3039 src/gallium/state_trackers/omx/bellagio/Makefile
3040 src/gallium/state_trackers/omx/tizonia/Makefile
3041 src/gallium/state_trackers/osmesa/Makefile
3042 src/gallium/state_trackers/va/Makefile
3043 src/gallium/state_trackers/vdpau/Makefile
3044 src/gallium/state_trackers/xa/Makefile
3045 src/gallium/state_trackers/xa/xa_tracker.h
3046 src/gallium/state_trackers/xvmc/Makefile
3047 src/gallium/targets/d3dadapter9/Makefile
3048 src/gallium/targets/d3dadapter9/d3d.pc
3049 src/gallium/targets/dri/Makefile
3050 src/gallium/targets/libgl-xlib/Makefile
3051 src/gallium/targets/omx/Makefile
3052 src/gallium/targets/opencl/Makefile
3053 src/gallium/targets/opencl/mesa.icd
3054 src/gallium/targets/osmesa/Makefile
3055 src/gallium/targets/osmesa/osmesa.pc
3056 src/gallium/targets/pipe-loader/Makefile
3057 src/gallium/targets/va/Makefile
3058 src/gallium/targets/vdpau/Makefile
3059 src/gallium/targets/xa/Makefile
3060 src/gallium/targets/xa/xatracker.pc
3061 src/gallium/targets/xvmc/Makefile
3062 src/gallium/tests/trivial/Makefile
3063 src/gallium/tests/unit/Makefile
3064 src/gallium/winsys/etnaviv/drm/Makefile
3065 src/gallium/winsys/imx/drm/Makefile
3066 src/gallium/winsys/freedreno/drm/Makefile
3067 src/gallium/winsys/i915/drm/Makefile
3068 src/gallium/winsys/nouveau/drm/Makefile
3069 src/gallium/winsys/pl111/drm/Makefile
3070 src/gallium/winsys/radeon/drm/Makefile
3071 src/gallium/winsys/amdgpu/drm/Makefile
3072 src/gallium/winsys/svga/drm/Makefile
3073 src/gallium/winsys/sw/dri/Makefile
3074 src/gallium/winsys/sw/kms-dri/Makefile
3075 src/gallium/winsys/sw/null/Makefile
3076 src/gallium/winsys/sw/wrapper/Makefile
3077 src/gallium/winsys/sw/xlib/Makefile
3078 src/gallium/winsys/tegra/drm/Makefile
3079 src/gallium/winsys/vc4/drm/Makefile
3080 src/gallium/winsys/vc5/drm/Makefile
3081 src/gallium/winsys/virgl/drm/Makefile
3082 src/gallium/winsys/virgl/vtest/Makefile
3083 src/gbm/Makefile
3084 src/gbm/main/gbm.pc
3085 src/glx/Makefile
3086 src/glx/apple/Makefile
3087 src/glx/tests/Makefile
3088 src/glx/windows/Makefile
3089 src/glx/windows/windowsdriproto.pc
3090 src/gtest/Makefile
3091 src/intel/Makefile
3092 src/loader/Makefile
3093 src/mapi/Makefile
3094 src/mapi/es1api/glesv1_cm.pc
3095 src/mapi/es2api/glesv2.pc
3096 src/mapi/glapi/gen/Makefile
3097 src/mesa/Makefile
3098 src/mesa/gl.pc
3099 src/mesa/drivers/dri/dri.pc
3100 src/mesa/drivers/dri/common/Makefile
3101 src/mesa/drivers/dri/i915/Makefile
3102 src/mesa/drivers/dri/i965/Makefile
3103 src/mesa/drivers/dri/Makefile
3104 src/mesa/drivers/dri/nouveau/Makefile
3105 src/mesa/drivers/dri/r200/Makefile
3106 src/mesa/drivers/dri/radeon/Makefile
3107 src/mesa/drivers/dri/swrast/Makefile
3108 src/mesa/drivers/osmesa/Makefile
3109 src/mesa/drivers/osmesa/osmesa.pc
3110 src/mesa/drivers/x11/Makefile
3111 src/mesa/main/tests/Makefile
3112 src/mesa/state_tracker/tests/Makefile
3113 src/util/Makefile
3114 src/util/tests/hash_table/Makefile
3115 src/util/tests/string_buffer/Makefile
3116 src/util/xmlpool/Makefile
3117 src/vulkan/Makefile])
3118
3119 AC_OUTPUT
3120
3121 # Fix up dependencies in *.Plo files, where we changed the extension of a
3122 # source file
3123 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3124
3125 rm -f src/compiler/spirv/spirv_info.lo
3126 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3127
3128 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3129 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3130
3131 dnl
3132 dnl Output some configuration info for the user
3133 dnl
3134 echo ""
3135 echo " prefix: $prefix"
3136 echo " exec_prefix: $exec_prefix"
3137 echo " libdir: $libdir"
3138 echo " includedir: $includedir"
3139
3140 dnl API info
3141 echo ""
3142 echo " OpenGL: $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3143
3144 dnl Driver info
3145 echo ""
3146 case "x$enable_osmesa$enable_gallium_osmesa" in
3147 xnoyes)
3148 echo " OSMesa: lib$OSMESA_LIB (Gallium)"
3149 ;;
3150 xyesno)
3151 echo " OSMesa: lib$OSMESA_LIB"
3152 ;;
3153 xnono)
3154 echo " OSMesa: no"
3155 ;;
3156 esac
3157
3158 echo ""
3159 if test "x$enable_dri" != xno; then
3160 echo " DRI platform: $dri_platform"
3161 if test -z "$DRI_DIRS"; then
3162 echo " DRI drivers: no"
3163 else
3164 echo " DRI drivers: $DRI_DIRS"
3165 fi
3166 echo " DRI driver dir: $DRI_DRIVER_INSTALL_DIR"
3167 fi
3168
3169 case "x$enable_glx" in
3170 xdri)
3171 echo " GLX: DRI-based"
3172 ;;
3173 xxlib)
3174 echo " GLX: Xlib-based"
3175 ;;
3176 xgallium-xlib)
3177 echo " GLX: Xlib-based (Gallium)"
3178 ;;
3179 *)
3180 echo " GLX: $enable_glx"
3181 ;;
3182 esac
3183
3184 dnl EGL
3185 echo ""
3186 echo " EGL: $enable_egl"
3187 if test "$enable_egl" = yes; then
3188
3189 egl_drivers=""
3190 if test "x$enable_dri" != "xno"; then
3191 egl_drivers="$egl_drivers builtin:egl_dri2"
3192 fi
3193 if test "x$enable_dri3" != "xno"; then
3194 egl_drivers="$egl_drivers builtin:egl_dri3"
3195 fi
3196
3197 echo " EGL drivers: $egl_drivers"
3198 fi
3199 if test "x$enable_gbm" = xyes; then
3200 echo " GBM: yes"
3201 else
3202 echo " GBM: no"
3203 fi
3204
3205 echo " EGL/Vulkan/VL platforms: $platforms"
3206
3207 # Vulkan
3208 echo ""
3209 if test "x$VULKAN_DRIVERS" != x; then
3210 echo " Vulkan drivers: $VULKAN_DRIVERS"
3211 echo " Vulkan ICD dir: $VULKAN_ICD_INSTALL_DIR"
3212 else
3213 echo " Vulkan drivers: no"
3214 fi
3215
3216 echo ""
3217 if test "x$enable_llvm" = xyes; then
3218 echo " llvm: yes"
3219 echo " llvm-config: $LLVM_CONFIG"
3220 echo " llvm-version: $LLVM_VERSION"
3221 else
3222 echo " llvm: no"
3223 fi
3224
3225 echo ""
3226 if test -n "$with_gallium_drivers"; then
3227 echo " Gallium drivers: $gallium_drivers"
3228 echo " Gallium st: $gallium_st"
3229 else
3230 echo " Gallium: no"
3231 fi
3232
3233 echo ""
3234 if test "x$enable_gallium_extra_hud" != xyes; then
3235 echo " HUD extra stats: no"
3236 else
3237 echo " HUD extra stats: yes"
3238 fi
3239
3240 if test "x$enable_lmsensors" != xyes; then
3241 echo " HUD lmsensors: no"
3242 else
3243 echo " HUD lmsensors: yes"
3244 fi
3245
3246 echo ""
3247 if test "x$HAVE_GALLIUM_SWR" != x; then
3248 if test "x$HAVE_SWR_BUILTIN" = xyes; then
3249 echo " SWR archs: $swr_archs (builtin)"
3250 else
3251 echo " SWR archs: $swr_archs"
3252 fi
3253 fi
3254
3255 dnl Libraries
3256 echo ""
3257 echo " Shared libs: $enable_shared"
3258 echo " Static libs: $enable_static"
3259 echo " Shared-glapi: $enable_shared_glapi"
3260
3261 dnl Compiler options
3262 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3263 cflags=`echo $CFLAGS | \
3264 $SED 's/^ *//;s/ */ /;s/ *$//'`
3265 cxxflags=`echo $CXXFLAGS | \
3266 $SED 's/^ *//;s/ */ /;s/ *$//'`
3267 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/ */ /;s/ *$//'`
3268 defines=`echo $DEFINES | $SED 's/^ *//;s/ */ /;s/ *$//'`
3269 echo ""
3270 echo " CFLAGS: $cflags"
3271 echo " CXXFLAGS: $cxxflags"
3272 echo " CXX11_CXXFLAGS: $CXX11_CXXFLAGS"
3273 echo " LDFLAGS: $ldflags"
3274 echo " Macros: $defines"
3275 echo ""
3276 if test "x$enable_llvm" = xyes; then
3277 echo " LLVM_CFLAGS: $LLVM_CFLAGS"
3278 echo " LLVM_CXXFLAGS: $LLVM_CXXFLAGS"
3279 echo " LLVM_CPPFLAGS: $LLVM_CPPFLAGS"
3280 echo " LLVM_LDFLAGS: $LLVM_LDFLAGS"
3281 echo ""
3282 fi
3283 echo " PYTHON2: $PYTHON2"
3284
3285 echo ""
3286 echo " Run '${MAKE-make}' to build Mesa"
3287 echo ""