configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.82
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl
 286 dnl Check compiler flags
 287 dnl
 288 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 289 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 290 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 291 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 292 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 293 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 294 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 295
 296 dnl
 297 dnl Check C++ compiler flags
 298 dnl
 299 AC_LANG_PUSH([C++])
 300 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 301 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 302 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 303 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 304 AC_LANG_POP([C++])
 305
 306 # Flags to help ensure that certain portions of the code -- and only those
 307 # portions -- can be built with MSVC:
 308 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 309 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 310 #   supports most of C99)
 311 # - the rest has no compiler compiler restrictions
 312 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"])
 313 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="-Werror=vla"])
 314 AC_LANG_PUSH([C++])
 315 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"])
 316 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="-Werror=vla"])
 317 AC_LANG_POP([C++])
 318
 319 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 320 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 321
 322 if test "x$GCC" = xyes; then
 323     if test "x$USE_GNU99" = xyes; then
 324         CFLAGS="$CFLAGS -std=gnu99"
 325     else
 326         CFLAGS="$CFLAGS -std=c99"
 327     fi
 328 fi
 329
 330 dnl even if the compiler appears to support it, using visibility attributes isn't
 331 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 332 case "$host_os" in
 333 cygwin*)
 334     VISIBILITY_CFLAGS=""
 335     VISIBILITY_CXXFLAGS=""
 336     ;;
 337 esac
 338
 339 AC_SUBST([VISIBILITY_CFLAGS])
 340 AC_SUBST([VISIBILITY_CXXFLAGS])
 341
 342 AX_CHECK_COMPILE_FLAG([-Wno-override-init],                    [WNO_OVERRIDE_INIT="-Wno-override-init"])         # gcc
 343 AX_CHECK_COMPILE_FLAG([-Wno-initializer-overrides],            [WNO_OVERRIDE_INIT="-Wno-initializer-overrides"]) # clang
 344 AC_SUBST([WNO_OVERRIDE_INIT])
 345
 346 dnl
 347 dnl Optional flags, check for compiler support
 348 dnl
 349 SSE41_CFLAGS="-msse4.1"
 350 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 351 dnl stack, but on x86-32 such alignment is not guaranteed.
 352 case "$target_cpu" in
 353 i?86)
 354     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 355     ;;
 356 esac
 357 save_CFLAGS="$CFLAGS"
 358 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 359 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 360 #include <smmintrin.h>
 361 int param;
 362 int main () {
 363     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 364     c = _mm_max_epu32(a, b);
 365     return _mm_cvtsi128_si32(c);
 366 }]])], SSE41_SUPPORTED=1)
 367 CFLAGS="$save_CFLAGS"
 368 if test "x$SSE41_SUPPORTED" = x1; then
 369     DEFINES="$DEFINES -DUSE_SSE41"
 370 fi
 371 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 372 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 373
 374 dnl Check for new-style atomic builtins
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 int main() {
 377     int n;
 378     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 379 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 380 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 381     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 382 fi
 383 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 384
 385 dnl Check if host supports 64-bit atomics
 386 dnl note that lack of support usually results in link (not compile) error
 387 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 388 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 389 #include <stdint.h>
 390 uint64_t v;
 391 int main() {
 392     return __sync_add_and_fetch(&v, (uint64_t)1);
 393 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 394 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 395     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 396 fi
 397 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 398
 399 dnl Check for Endianness
 400 AC_C_BIGENDIAN(
 401    little_endian=no,
 402    little_endian=yes,
 403    little_endian=no,
 404    little_endian=no
 405 )
 406
 407 dnl Check for POWER8 Architecture
 408 PWR8_CFLAGS="-mpower8-vector"
 409 have_pwr8_intrinsics=no
 410 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 411 save_CFLAGS=$CFLAGS
 412 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 413 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 414 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 415 #error "Need GCC >= 4.8 for sane POWER8 support"
 416 #endif
 417 #include <altivec.h>
 418 int main () {
 419     vector unsigned char r;
 420     vector unsigned int v = vec_splat_u32 (1);
 421     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 422     return 0;
 423 }]])], have_pwr8_intrinsics=yes)
 424 CFLAGS=$save_CFLAGS
 425
 426 AC_ARG_ENABLE(pwr8,
 427    [AS_HELP_STRING([--disable-pwr8],
 428                    [disable POWER8-specific instructions])],
 429    [enable_pwr8=$enableval], [enable_pwr8=auto])
 430
 431 if test "x$enable_pwr8" = xno ; then
 432    have_pwr8_intrinsics=disabled
 433 fi
 434
 435 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 436    DEFINES="$DEFINES -D_ARCH_PWR8"
 437    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 438    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 439 else
 440    PWR8_CFLAGS=
 441 fi
 442
 443 AC_MSG_RESULT($have_pwr8_intrinsics)
 444 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 445    AC_MSG_ERROR([POWER8 compiler support not detected])
 446 fi
 447
 448 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 449    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 450 fi
 451
 452 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 453
 454 dnl Can't have static and shared libraries, default to static if user
 455 dnl explicitly requested. If both disabled, set to static since shared
 456 dnl was explicitly requested.
 457 case "x$enable_static$enable_shared" in
 458 xyesyes)
 459     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 460     ;;
 461 xnono)
 462     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 463     ;;
 464 esac
 465
 466 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 467
 468 dnl
 469 dnl other compiler options
 470 dnl
 471 AC_ARG_ENABLE([debug],
 472     [AS_HELP_STRING([--enable-debug],
 473         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 474     [enable_debug="$enableval"],
 475     [enable_debug=no]
 476 )
 477
 478 AC_ARG_ENABLE([profile],
 479     [AS_HELP_STRING([--enable-profile],
 480         [enable profiling of code @<:@default=disabled@:>@])],
 481     [enable_profile="$enableval"],
 482     [enable_profile=no]
 483 )
 484
 485 AC_ARG_ENABLE([sanitize],
 486     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 487         [enable code sanitizer @<:@default=disabled@:>@])],
 488     [enable_sanitize="$enableval"],
 489     [enable_sanitize=no])
 490
 491 if test "x$enable_profile" = xyes; then
 492     DEFINES="$DEFINES -DPROFILE"
 493     if test "x$GCC" = xyes; then
 494         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 495     fi
 496     if test "x$GXX" = xyes; then
 497         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 498     fi
 499 fi
 500
 501 if test "x$enable_debug" = xyes; then
 502     DEFINES="$DEFINES -DDEBUG"
 503     if test "x$enable_profile" = xyes; then
 504         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 505     fi
 506     if test "x$GCC" = xyes; then
 507         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 508             CFLAGS="$CFLAGS -g"
 509         fi
 510         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 511             CFLAGS="$CFLAGS -O0"
 512         fi
 513     fi
 514     if test "x$GXX" = xyes; then
 515         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 516             CXXFLAGS="$CXXFLAGS -g"
 517         fi
 518         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 519             CXXFLAGS="$CXXFLAGS -O0"
 520         fi
 521     fi
 522 else
 523    DEFINES="$DEFINES -DNDEBUG"
 524 fi
 525
 526 if test "x$enable_sanitize" != xno; then
 527     if test "x$enable_profile" = xyes; then
 528         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 529     fi
 530
 531     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 532     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 533     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 534
 535     AC_LINK_IFELSE(
 536         [AC_LANG_SOURCE([int main(){return 0;}])],
 537         [],
 538         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 539 fi
 540
 541 dnl
 542 dnl Check if linker supports -Bsymbolic
 543 dnl
 544 save_LDFLAGS=$LDFLAGS
 545 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 546 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 547 AC_LINK_IFELSE(
 548     [AC_LANG_SOURCE([int main() { return 0;}])],
 549     [AC_MSG_RESULT([yes])
 550         BSYMBOLIC="-Wl,-Bsymbolic";],
 551     [AC_MSG_RESULT([no])
 552         BSYMBOLIC="";])
 553 LDFLAGS=$save_LDFLAGS
 554
 555 AC_SUBST([BSYMBOLIC])
 556
 557 dnl
 558 dnl Check if linker supports garbage collection
 559 dnl
 560 save_LDFLAGS=$LDFLAGS
 561 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 562 AC_MSG_CHECKING([whether ld supports --gc-sections])
 563 AC_LINK_IFELSE(
 564     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 565     [AC_MSG_RESULT([yes])
 566         GC_SECTIONS="-Wl,--gc-sections";],
 567     [AC_MSG_RESULT([no])
 568         GC_SECTIONS="";])
 569 LDFLAGS=$save_LDFLAGS
 570
 571 AC_SUBST([GC_SECTIONS])
 572
 573 dnl
 574 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 575 dnl so when these flags are passed to ld via libtool the checks will fail
 576 dnl
 577 case "$host_os" in
 578 openbsd* | darwin* )
 579     LD_NO_UNDEFINED="" ;;
 580 *)
 581     if test "x$enable_sanitize" = xno; then
 582         LD_NO_UNDEFINED="-Wl,--no-undefined"
 583     else
 584         LD_NO_UNDEFINED=""
 585     fi
 586     ;;
 587 esac
 588
 589 AC_SUBST([LD_NO_UNDEFINED])
 590
 591 dnl
 592 dnl Check if linker supports version scripts
 593 dnl
 594 AC_MSG_CHECKING([if the linker supports version-scripts])
 595 save_LDFLAGS=$LDFLAGS
 596 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 597 cat > conftest.map <<EOF
 598 VERSION_1 {
 599      global:
 600          main;
 601
 602      local:
 603          *;
 604 };
 605 EOF
 606 AC_LINK_IFELSE(
 607     [AC_LANG_SOURCE([int main() { return 0;}])],
 608     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 609     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 610 LDFLAGS=$save_LDFLAGS
 611 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 612
 613 dnl
 614 dnl Check if linker supports dynamic list files
 615 dnl
 616 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 617 save_LDFLAGS=$LDFLAGS
 618 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 619 cat > conftest.dyn <<EOF
 620 {
 621         radeon_drm_winsys_create;
 622 };
 623 EOF
 624 AC_LINK_IFELSE(
 625     [AC_LANG_SOURCE([int main() { return 0;}])],
 626     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 627     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 628 LDFLAGS=$save_LDFLAGS
 629 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 630
 631 dnl
 632 dnl compatibility symlinks
 633 dnl
 634 case "$host_os" in
 635 linux* )
 636     HAVE_COMPAT_SYMLINKS=yes ;;
 637 * )
 638     HAVE_COMPAT_SYMLINKS=no ;;
 639 esac
 640
 641 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 642
 643 dnl
 644 dnl library names
 645 dnl
 646 dnl Unfortunately we need to do a few things that libtool can't help us with,
 647 dnl so we need some knowledge of shared library filenames:
 648 dnl
 649 dnl LIB_EXT is the extension used when creating symlinks for alternate
 650 dnl filenames for a shared library which will be dynamically loaded
 651 dnl
 652 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 653 dnl the file for a shared library we wish to link with
 654 dnl
 655 case "$host_os" in
 656 darwin* )
 657     LIB_EXT='dylib'
 658     IMP_LIB_EXT=$LIB_EXT
 659     ;;
 660 cygwin* )
 661     LIB_EXT='dll'
 662     IMP_LIB_EXT='dll.a'
 663     ;;
 664 aix* )
 665     LIB_EXT='a'
 666     IMP_LIB_EXT=$LIB_EXT
 667     ;;
 668 * )
 669     LIB_EXT='so'
 670     IMP_LIB_EXT=$LIB_EXT
 671     ;;
 672 esac
 673
 674 AC_SUBST([LIB_EXT])
 675
 676 dnl
 677 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 678 dnl
 679 AC_ARG_ENABLE([texture-float],
 680     [AS_HELP_STRING([--enable-texture-float],
 681         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 682     [enable_texture_float="$enableval"],
 683     [enable_texture_float=no]
 684 )
 685 if test "x$enable_texture_float" = xyes; then
 686     AC_MSG_WARN([Floating-point textures enabled.])
 687     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 688     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 689 fi
 690
 691 dnl
 692 dnl Arch/platform-specific settings
 693 dnl
 694 AC_ARG_ENABLE([asm],
 695     [AS_HELP_STRING([--disable-asm],
 696         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 697     [enable_asm="$enableval"],
 698     [enable_asm=yes]
 699 )
 700 asm_arch=""
 701 AC_MSG_CHECKING([whether to enable assembly])
 702 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 703 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 704 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 705     case "$host_cpu" in
 706     i?86 | x86_64 | amd64)
 707         if test "x$host_cpu" != "x$target_cpu"; then
 708             enable_asm=no
 709             AC_MSG_RESULT([no, cross compiling])
 710         fi
 711         ;;
 712     esac
 713 fi
 714 # check for supported arches
 715 if test "x$enable_asm" = xyes; then
 716     case "$host_cpu" in
 717     i?86)
 718         case "$host_os" in
 719         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 720             asm_arch=x86
 721             ;;
 722         esac
 723         ;;
 724     x86_64|amd64)
 725         case "$host_os" in
 726         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 727             asm_arch=x86_64
 728             ;;
 729         esac
 730         ;;
 731     sparc*)
 732         case "$host_os" in
 733         linux*)
 734             asm_arch=sparc
 735             ;;
 736         esac
 737         ;;
 738     powerpc64le)
 739         case "$host_os" in
 740         linux*)
 741             asm_arch=ppc64le
 742             ;;
 743         esac
 744         ;;
 745     aarch64)
 746         case "$host_os" in
 747         linux*)
 748             asm_arch=aarch64
 749             ;;
 750         esac
 751         ;;
 752     arm)
 753         case "$host_os" in
 754         linux*)
 755             asm_arch=arm
 756             ;;
 757         esac
 758         ;;
 759     esac
 760
 761     case "$asm_arch" in
 762     x86)
 763         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 764         AC_MSG_RESULT([yes, x86])
 765         ;;
 766     x86_64|amd64)
 767         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 768         AC_MSG_RESULT([yes, x86_64])
 769         ;;
 770     sparc)
 771         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 772         AC_MSG_RESULT([yes, sparc])
 773         ;;
 774     ppc64le)
 775         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 776         AC_MSG_RESULT([yes, ppc64le])
 777         ;;
 778     aarch64)
 779         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 780         AC_MSG_RESULT([yes, aarch64])
 781         ;;
 782     arm)
 783         DEFINES="$DEFINES -DUSE_ARM_ASM"
 784         AC_MSG_RESULT([yes, arm])
 785         ;;
 786     *)
 787         AC_MSG_RESULT([no, platform not supported])
 788         ;;
 789     esac
 790 fi
 791
 792 AC_HEADER_MAJOR
 793 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 794 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 795 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 796 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 797
 798 AC_MSG_CHECKING([whether strtod has locale support])
 799 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 800     #define _GNU_SOURCE
 801     #include <stdlib.h>
 802     #include <locale.h>
 803     #ifdef HAVE_XLOCALE_H
 804     #include <xlocale.h>
 805     #endif
 806     int main() {
 807        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 808        const char *s = "1.0";
 809        char *end;
 810        double d = strtod_l(s, end, loc);
 811        float f = strtof_l(s, end, loc);
 812        freelocale(loc);
 813        return 0;
 814     }]])],
 815   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 816    AC_MSG_RESULT([yes]),
 817    AC_MSG_RESULT([no]))
 818
 819 dnl Check to see if dlopen is in default libraries (like Solaris, which
 820 dnl has it in libc), or if libdl is needed to get it.
 821 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 822     [AC_CHECK_LIB([dl], [dlopen],
 823        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 824 AC_SUBST([DLOPEN_LIBS])
 825
 826 dnl Check if that library also has dladdr
 827 save_LIBS="$LIBS"
 828 LIBS="$LIBS $DLOPEN_LIBS"
 829 AC_CHECK_FUNCS([dladdr])
 830 LIBS="$save_LIBS"
 831
 832 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 833
 834 case "$host_os" in
 835 darwin*)
 836     ;;
 837 *)
 838     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 839                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 840                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 841     AC_SUBST([CLOCK_LIB])
 842     ;;
 843 esac
 844
 845 dnl See if posix_memalign is available
 846 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 847
 848 dnl Check for zlib
 849 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 850
 851 dnl Check for pthreads
 852 AX_PTHREAD
 853 if test "x$ax_pthread_ok" = xno; then
 854     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 855 fi
 856 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 857 dnl to -pthread, which causes problems if we need -lpthread to appear in
 858 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 859 dnl is not valid for that platform.
 860 if test "x$android" = xno; then
 861     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 862 fi
 863 dnl According to the manual when using pthreads, one should add -pthread to
 864 dnl both compile and link-time arguments.
 865 dnl In practise that should be sufficient for all platforms, since any
 866 dnl platforms build with GCC and Clang support the flag.
 867 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 868
 869 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 870 dnl project. Even then there's a notable issue as described in the project README
 871 case "$host_os" in
 872 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 873     pthread_stubs_possible="no"
 874     ;;
 875 * )
 876     pthread_stubs_possible="yes"
 877     ;;
 878 esac
 879
 880 if test "x$pthread_stubs_possible" = xyes; then
 881     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 882 fi
 883
 884 dnl SELinux awareness.
 885 AC_ARG_ENABLE([selinux],
 886     [AS_HELP_STRING([--enable-selinux],
 887         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 888     [MESA_SELINUX="$enableval"],
 889     [MESA_SELINUX=no])
 890 if test "x$enable_selinux" = "xyes"; then
 891     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 892         [AC_CHECK_HEADER([selinux/selinux.h],[],
 893                          [AC_MSG_ERROR([SELinux headers not found])])
 894          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 895                       [AC_MSG_ERROR([SELinux library not found])])
 896          SELINUX_LIBS="-lselinux"])
 897     DEFINES="$DEFINES -DMESA_SELINUX"
 898 fi
 899 AC_SUBST([SELINUX_CFLAGS])
 900 AC_SUBST([SELINUX_LIBS])
 901
 902 dnl
 903 dnl LLVM
 904 dnl
 905 AC_ARG_ENABLE([llvm-shared-libs],
 906     [AS_HELP_STRING([--enable-llvm-shared-libs],
 907         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 908     [enable_llvm_shared_libs="$enableval"],
 909     [enable_llvm_shared_libs=yes])
 910
 911 AC_ARG_WITH([llvm-prefix],
 912     [AS_HELP_STRING([--with-llvm-prefix],
 913         [Prefix for LLVM installations in non-standard locations])],
 914     [llvm_prefix="$withval"],
 915     [llvm_prefix=''])
 916
 917 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 918 if test "x$have_libelf" = xno; then
 919    LIBELF_LIBS=''
 920    LIBELF_CFLAGS=''
 921    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 922    AC_SUBST([LIBELF_LIBS])
 923    AC_SUBST([LIBELF_CFLAGS])
 924 fi
 925
 926 if test -z "$LLVM_CONFIG"; then
 927     if test -n "$llvm_prefix"; then
 928         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 929     else
 930         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 931     fi
 932 fi
 933
 934 llvm_add_component() {
 935     new_llvm_component=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 939         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 940     else
 941         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 llvm_add_default_components() {
 946     driver_name=$1
 947
 948     # Required default components
 949     llvm_add_component "bitwriter" $driver_name
 950     llvm_add_component "engine" $driver_name
 951     llvm_add_component "mcdisassembler" $driver_name
 952     llvm_add_component "mcjit" $driver_name
 953
 954     # Optional default components
 955     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 956         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 957     fi
 958 }
 959
 960 llvm_add_target() {
 961     new_llvm_target=$1
 962     driver_name=$2
 963
 964     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 965         llvm_add_component $new_llvm_target $driver_name
 966     else
 967         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 968     fi
 969 }
 970
 971 # Call this inside ` ` to get the return value.
 972 # $1 is the llvm-config command with arguments.
 973 strip_unwanted_llvm_flags() {
 974     echo " `$1` " | sed -E \
 975         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 976         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 977         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 978         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 979         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 980         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 981         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 982         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 983         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 984         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 985         -e 's/^[[[:space:]]]//' \
 986         -e 's/[[[:space:]]]$//'
 987 }
 988
 989 llvm_set_environment_variables() {
 990     if test "x$LLVM_CONFIG" != xno; then
 991         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 992         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 993         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 994         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 995
 996         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 997         save_CFLAGS="$CFLAGS"
 998         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 999
1000         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1001             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1002         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1003             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1004         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1005             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1006
1007         CFLAGS="$save_CFLAGS"
1008
1009         # Only needed for LLVM < 3.6.0
1010         if test -z "$LLVM_VERSION_PATCH"; then
1011             LLVM_VERSION_PATCH=0
1012         fi
1013
1014         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1015
1016         FOUND_LLVM=yes
1017     else
1018         FOUND_LLVM=no
1019         LLVM_VERSION_INT=0
1020     fi
1021 }
1022
1023 require_llvm() {
1024     if test "x$enable_llvm" != "xyes"; then
1025         AC_MSG_ERROR([--enable-llvm is required when building $1])
1026     fi
1027 }
1028
1029 llvm_require_version() {
1030     require_llvm $2
1031
1032     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1033     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1034     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1035
1036     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1037         # major > required major
1038         #  --> OK
1039         return
1040     fi
1041
1042     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1043         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1044             # major = required major and
1045             # minor > required minor
1046             #  --> OK
1047             return
1048         else
1049             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1050                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1051                     # major = required major and
1052                     # minor = required minor and
1053                     # patch >= required patch
1054                     #  --> OK
1055                     return
1056                 fi
1057             fi
1058         fi
1059     fi
1060
1061     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1062 }
1063
1064 radeon_llvm_check() {
1065     if test ${LLVM_VERSION_INT} -lt 307; then
1066         amdgpu_llvm_target_name='r600'
1067     else
1068         amdgpu_llvm_target_name='amdgpu'
1069     fi
1070
1071     llvm_require_version $*
1072
1073     llvm_add_target $amdgpu_llvm_target_name $2
1074
1075     llvm_add_default_components $2
1076     llvm_add_component "bitreader" $2
1077     llvm_add_component "ipo" $2
1078
1079     if test "x$have_libelf" != xyes; then
1080        AC_MSG_ERROR([$2 requires libelf when using llvm])
1081     fi
1082 }
1083
1084 llvm_set_environment_variables
1085
1086 AC_SUBST([LLVM_CFLAGS])
1087 AC_SUBST([LLVM_CXXFLAGS])
1088 AC_SUBST([LLVM_LIBS])
1089 AC_SUBST([LLVM_LDFLAGS])
1090 AC_SUBST([LLVM_INCLUDEDIR])
1091
1092 dnl
1093 dnl libunwind
1094 dnl
1095 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1096 AC_ARG_ENABLE([libunwind],
1097     [AS_HELP_STRING([--enable-libunwind],
1098             [Use libunwind for backtracing (default: auto)])],
1099         [LIBUNWIND="$enableval"],
1100         [LIBUNWIND="$HAVE_LIBUNWIND"])
1101
1102 if test "x$LIBUNWIND" = "xyes"; then
1103     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1104     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1105 fi
1106
1107
1108 dnl Options for APIs
1109 AC_ARG_ENABLE([opengl],
1110     [AS_HELP_STRING([--disable-opengl],
1111         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1112     [enable_opengl="$enableval"],
1113     [enable_opengl=yes])
1114 AC_ARG_ENABLE([gles1],
1115     [AS_HELP_STRING([--disable-gles1],
1116         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1117     [enable_gles1="$enableval"],
1118     [enable_gles1=yes])
1119 AC_ARG_ENABLE([gles2],
1120     [AS_HELP_STRING([--disable-gles2],
1121         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1122     [enable_gles2="$enableval"],
1123     [enable_gles2=yes])
1124
1125 AC_ARG_ENABLE([dri],
1126     [AS_HELP_STRING([--enable-dri],
1127         [enable DRI modules @<:@default=enabled@:>@])],
1128     [enable_dri="$enableval"],
1129     [enable_dri=yes])
1130
1131 AC_ARG_ENABLE([gallium-extra-hud],
1132     [AS_HELP_STRING([--enable-gallium-extra-hud],
1133         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1134     [enable_gallium_extra_hud="$enableval"],
1135     [enable_gallium_extra_hud=no])
1136 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1137 if test "x$enable_gallium_extra_hud" = xyes ; then
1138     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1139 fi
1140
1141 #TODO: no pkgconfig .pc available for libsensors.
1142 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1143 AC_ARG_ENABLE([lmsensors],
1144     [AS_HELP_STRING([--enable-lmsensors],
1145         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1146     [enable_lmsensors="$enableval"],
1147     [enable_lmsensors=no])
1148 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1149 if test "x$enable_lmsensors" = xyes ; then
1150     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1151     LIBSENSORS_LIBS="-lsensors"
1152 else
1153     LIBSENSORS_LIBS=""
1154 fi
1155 AC_SUBST(LIBSENSORS_LIBS)
1156
1157 case "$host_os" in
1158 linux*)
1159     dri3_default=yes
1160     ;;
1161 *)
1162     dri3_default=no
1163     ;;
1164 esac
1165
1166 if test "x$enable_dri" = xno; then
1167     dri3_default=no
1168 fi
1169
1170 AC_ARG_ENABLE([dri3],
1171     [AS_HELP_STRING([--enable-dri3],
1172         [enable DRI3 @<:@default=auto@:>@])],
1173     [enable_dri3="$enableval"],
1174     [enable_dri3="$dri3_default"])
1175 AC_ARG_ENABLE([glx],
1176     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1177         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1178     [enable_glx="$enableval"],
1179     [enable_glx=yes])
1180 AC_ARG_ENABLE([osmesa],
1181     [AS_HELP_STRING([--enable-osmesa],
1182         [enable OSMesa library @<:@default=disabled@:>@])],
1183     [enable_osmesa="$enableval"],
1184     [enable_osmesa=no])
1185 AC_ARG_ENABLE([gallium-osmesa],
1186     [AS_HELP_STRING([--enable-gallium-osmesa],
1187         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1188     [enable_gallium_osmesa="$enableval"],
1189     [enable_gallium_osmesa=no])
1190 AC_ARG_ENABLE([egl],
1191     [AS_HELP_STRING([--disable-egl],
1192         [disable EGL library @<:@default=enabled@:>@])],
1193     [enable_egl="$enableval"],
1194     [enable_egl=yes])
1195
1196 AC_ARG_ENABLE([xa],
1197     [AS_HELP_STRING([--enable-xa],
1198         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1199     [enable_xa="$enableval"],
1200     [enable_xa=no])
1201 AC_ARG_ENABLE([gbm],
1202    [AS_HELP_STRING([--enable-gbm],
1203          [enable gbm library @<:@default=yes except cygwin@:>@])],
1204    [enable_gbm="$enableval"],
1205    [case "$host_os" in
1206        cygwin*)
1207           enable_gbm=no
1208           ;;
1209        *)
1210           enable_gbm=yes
1211           ;;
1212     esac])
1213 AC_ARG_ENABLE([nine],
1214     [AS_HELP_STRING([--enable-nine],
1215         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1216     [enable_nine="$enableval"],
1217     [enable_nine=no])
1218
1219 AC_ARG_ENABLE([xvmc],
1220    [AS_HELP_STRING([--enable-xvmc],
1221          [enable xvmc library @<:@default=auto@:>@])],
1222    [enable_xvmc="$enableval"],
1223    [enable_xvmc=auto])
1224 AC_ARG_ENABLE([vdpau],
1225    [AS_HELP_STRING([--enable-vdpau],
1226          [enable vdpau library @<:@default=auto@:>@])],
1227    [enable_vdpau="$enableval"],
1228    [enable_vdpau=auto])
1229 AC_ARG_ENABLE([omx],
1230    [AS_HELP_STRING([--enable-omx],
1231          [enable OpenMAX library @<:@default=disabled@:>@])],
1232    [enable_omx="$enableval"],
1233    [enable_omx=no])
1234 AC_ARG_ENABLE([va],
1235    [AS_HELP_STRING([--enable-va],
1236          [enable va library @<:@default=auto@:>@])],
1237    [enable_va="$enableval"],
1238    [enable_va=auto])
1239 AC_ARG_ENABLE([opencl],
1240    [AS_HELP_STRING([--enable-opencl],
1241          [enable OpenCL library @<:@default=disabled@:>@])],
1242    [enable_opencl="$enableval"],
1243    [enable_opencl=no])
1244 AC_ARG_ENABLE([opencl_icd],
1245    [AS_HELP_STRING([--enable-opencl-icd],
1246           [Build an OpenCL ICD library to be loaded by an ICD implementation
1247            @<:@default=disabled@:>@])],
1248     [enable_opencl_icd="$enableval"],
1249     [enable_opencl_icd=no])
1250
1251 AC_ARG_ENABLE([gallium-tests],
1252     [AS_HELP_STRING([--enable-gallium-tests],
1253         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1254     [enable_gallium_tests="$enableval"],
1255     [enable_gallium_tests=no])
1256
1257 # Option for Gallium drivers
1258
1259 # Keep this in sync with the --with-gallium-drivers help string default value
1260 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1261
1262 AC_ARG_WITH([gallium-drivers],
1263     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1264         [comma delimited Gallium drivers list, e.g.
1265         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1266         @<:@default=r300,r600,svga,swrast@:>@])],
1267     [with_gallium_drivers="$withval"],
1268     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1269
1270 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1271 # here so that the script doesn't choke on an unknown driver name later.
1272 case "$with_gallium_drivers" in
1273     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1274     no) with_gallium_drivers='' ;;
1275 esac
1276
1277 if test "x$enable_opengl" = xno -a \
1278         "x$enable_gles1" = xno -a \
1279         "x$enable_gles2" = xno -a \
1280         "x$enable_nine" = xno -a \
1281         "x$enable_xa" = xno -a \
1282         "x$enable_xvmc" = xno -a \
1283         "x$enable_vdpau" = xno -a \
1284         "x$enable_omx" = xno -a \
1285         "x$enable_va" = xno -a \
1286         "x$enable_opencl" = xno; then
1287     AC_MSG_ERROR([at least one API should be enabled])
1288 fi
1289
1290 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1291 if test "x$enable_opengl" = xno -a \
1292         "x$enable_gles1" = xyes; then
1293     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1294 fi
1295
1296 if test "x$enable_opengl" = xno -a \
1297         "x$enable_gles2" = xyes; then
1298     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1299 fi
1300
1301 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1302 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1303 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1304 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1305                                         "x$enable_gles1" = xyes -o \
1306                                         "x$enable_gles2" = xyes)
1307 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1308                                       "x$enable_gles1" = xyes -o \
1309                                       "x$enable_gles2" = xyes)
1310
1311 # Validate GLX options
1312 if test "x$enable_glx" = xyes; then
1313     if test "x$enable_dri" = xyes; then
1314         enable_glx=dri
1315     elif test -n "$with_gallium_drivers"; then
1316         enable_glx=gallium-xlib
1317     else
1318         enable_glx=xlib
1319     fi
1320 fi
1321 case "x$enable_glx" in
1322 xdri | xxlib | xgallium-xlib)
1323     # GLX requires OpenGL
1324     if test "x$enable_opengl" = xno; then
1325         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1326     fi
1327
1328     # Check individual dependencies
1329     case "x$enable_glx" in
1330     xdri)
1331         if test "x$enable_dri" = xno; then
1332             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1333         fi
1334         ;;
1335     xxlib)
1336         if test "x$enable_dri" = xyes; then
1337             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1338         fi
1339         ;;
1340     xgallium-xlib )
1341         if test "x$enable_dri" = xyes; then
1342             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1343         fi
1344         if test -z "$with_gallium_drivers"; then
1345             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1346         fi
1347         ;;
1348     esac
1349     ;;
1350 xno)
1351     ;;
1352 *)
1353     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1354     ;;
1355 esac
1356
1357 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1358 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1359 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1360 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1361
1362 DEFAULT_GL_LIB_NAME=GL
1363
1364 dnl
1365 dnl Libglvnd configuration
1366 dnl
1367 AC_ARG_ENABLE([libglvnd],
1368     [AS_HELP_STRING([--enable-libglvnd],
1369         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1370     [enable_libglvnd="$enableval"],
1371     [enable_libglvnd=no])
1372 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1373
1374 if test "x$enable_libglvnd" = xyes ; then
1375     dnl XXX: update once we can handle more than libGL/glx.
1376     dnl Namely: we should error out if neither of the glvnd enabled libraries
1377     dnl are built
1378     case "x$enable_glx" in
1379     xno)
1380         AC_MSG_ERROR([cannot build libglvnd without GLX])
1381         ;;
1382     xxlib | xgallium-xlib )
1383         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1384         ;;
1385     xdri)
1386         ;;
1387     esac
1388
1389     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1390     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1391     AC_SUBST([LIBGLVND_DATADIR])
1392
1393     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1394     DEFAULT_GL_LIB_NAME=GLX_mesa
1395 fi
1396
1397 AC_ARG_WITH([gl-lib-name],
1398   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1399     [specify GL library name @<:@default=GL@:>@])],
1400   [GL_LIB=$withval],
1401   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1402 AC_ARG_WITH([osmesa-lib-name],
1403   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1404     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1405   [OSMESA_LIB=$withval],
1406   [OSMESA_LIB=OSMesa])
1407 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1408 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1409
1410 dnl
1411 dnl Mangled Mesa support
1412 dnl
1413 AC_ARG_ENABLE([mangling],
1414   [AS_HELP_STRING([--enable-mangling],
1415     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1416   [enable_mangling="${enableval}"],
1417   [enable_mangling=no]
1418 )
1419 if test "x${enable_mangling}" = "xyes" ; then
1420   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1421   GL_LIB="Mangled${GL_LIB}"
1422   OSMESA_LIB="Mangled${OSMESA_LIB}"
1423 fi
1424 AC_SUBST([GL_LIB])
1425 AC_SUBST([OSMESA_LIB])
1426
1427 # Check for libdrm
1428 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1429                   [have_libdrm=yes], [have_libdrm=no])
1430 if test "x$have_libdrm" = xyes; then
1431     DEFINES="$DEFINES -DHAVE_LIBDRM"
1432 fi
1433
1434 require_libdrm() {
1435     if test "x$have_libdrm" != xyes; then
1436        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1437     fi
1438 }
1439
1440
1441 # Select which platform-dependent DRI code gets built
1442 case "$host_os" in
1443 darwin*)
1444     dri_platform='apple' ;;
1445 cygwin*)
1446     dri_platform='windows' ;;
1447 gnu*)
1448     dri_platform='none' ;;
1449 *)
1450     dri_platform='drm' ;;
1451 esac
1452
1453 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1454     have_drisw_kms='yes'
1455 fi
1456
1457 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1458 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1459 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1460 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1461 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1462 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1463 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1464 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1465 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1466
1467 AC_ARG_ENABLE([shared-glapi],
1468     [AS_HELP_STRING([--enable-shared-glapi],
1469         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1470     [enable_shared_glapi="$enableval"],
1471     [enable_shared_glapi=yes])
1472
1473 case "x$enable_opengl$enable_gles1$enable_gles2" in
1474 x*yes*yes*)
1475     if test "x$enable_shared_glapi" = xno; then
1476         AC_MSG_ERROR([shared GLAPI required when building two or more of
1477                       the following APIs - opengl, gles1 gles2])
1478     fi
1479     ;;
1480 esac
1481
1482 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1483
1484 # Build the pipe-drivers as separate libraries/modules.
1485 # Do not touch this unless you know what you are doing.
1486 # XXX: Expose via configure option ?
1487 enable_shared_pipe_drivers=no
1488
1489 dnl
1490 dnl Driver specific build directories
1491 dnl
1492
1493 if test "x$enable_gallium_osmesa" = xyes; then
1494     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1495         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1496     fi
1497     if test "x$enable_osmesa" = xyes; then
1498         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1499     fi
1500 fi
1501
1502 require_dri_shared_libs_and_glapi() {
1503     if test "x$enable_static" = xyes; then
1504         AC_MSG_ERROR([$1 cannot be build as static library])
1505     fi
1506
1507     if test "x$enable_dri" != xyes; then
1508         # There is only a single backend which won't be build/used otherwise.
1509         # XXX: Revisit this as the egl/haiku is a thing.
1510         AC_MSG_ERROR([$1 requires --enable-dri])
1511     fi
1512
1513     if test "x$enable_shared_glapi" != xyes; then
1514         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1515     fi
1516 }
1517
1518 if test "x$enable_dri" = xyes; then
1519     require_dri_shared_libs_and_glapi "DRI"
1520
1521     # not a hard requirement as swrast does not depend on it
1522     if test "x$have_libdrm" = xyes; then
1523         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1524     fi
1525 fi
1526
1527 AC_ARG_ENABLE([driglx-direct],
1528     [AS_HELP_STRING([--disable-driglx-direct],
1529         [disable direct rendering in GLX and EGL for DRI \
1530             @<:@default=auto@:>@])],
1531     [driglx_direct="$enableval"],
1532     [driglx_direct="yes"])
1533
1534 dnl
1535 dnl libGL configuration per driver
1536 dnl
1537 if test "x$enable_glx" != xno; then
1538     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1539 fi
1540 case "x$enable_glx" in
1541 xxlib | xgallium-xlib)
1542     # Xlib-based GLX
1543     dri_modules="x11 xext xcb"
1544     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1545     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1546     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1547     GL_LIB_DEPS="$XLIBGL_LIBS"
1548     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1549     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1550     ;;
1551 xdri)
1552     # DRI-based GLX
1553
1554     # find the DRI deps for libGL
1555     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1556
1557     if test x"$driglx_direct" = xyes; then
1558         if test x"$dri_platform" = xdrm ; then
1559             DEFINES="$DEFINES -DGLX_USE_DRM"
1560             require_libdrm "Direct rendering"
1561
1562             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1563             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1564
1565             if test x"$enable_dri" = xyes; then
1566                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1567             fi
1568         fi
1569         if test x"$dri_platform" = xapple ; then
1570             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1571         fi
1572         if test x"$dri_platform" = xwindows ; then
1573             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1574         fi
1575     fi
1576
1577     # add xf86vidmode if available
1578     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1579     if test "$HAVE_XF86VIDMODE" = yes ; then
1580         dri_modules="$dri_modules xxf86vm"
1581     fi
1582
1583     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1584     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1585     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1586     GL_LIB_DEPS="$DRIGL_LIBS"
1587
1588     # need DRM libs, $PTHREAD_LIBS, etc.
1589     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1590     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1591     ;;
1592 esac
1593
1594 # This is outside the case (above) so that it is invoked even for non-GLX
1595 # builds.
1596 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1597
1598 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1599 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1600 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1601 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1602
1603 AC_SUBST([X11_INCLUDES])
1604 AC_SUBST([GL_LIB_DEPS])
1605 AC_SUBST([GL_PC_REQ_PRIV])
1606 AC_SUBST([GL_PC_LIB_PRIV])
1607 AC_SUBST([GL_PC_CFLAGS])
1608 AC_SUBST([DRI_PC_REQ_PRIV])
1609 AC_SUBST([GLESv1_CM_LIB_DEPS])
1610 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1611 AC_SUBST([GLESv2_LIB_DEPS])
1612 AC_SUBST([GLESv2_PC_LIB_PRIV])
1613
1614 AC_SUBST([HAVE_XF86VIDMODE])
1615
1616 dnl
1617 dnl More GLX setup
1618 dnl
1619 case "x$enable_glx" in
1620 xxlib | xgallium-xlib)
1621     DEFINES="$DEFINES -DUSE_XSHM"
1622     ;;
1623 xdri)
1624     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1625     if test "x$driglx_direct" = xyes; then
1626         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1627     fi
1628     ;;
1629 esac
1630
1631 dnl
1632 dnl TLS detection
1633 dnl
1634
1635 AC_ARG_ENABLE([glx-tls],
1636     [AS_HELP_STRING([--enable-glx-tls],
1637         [enable TLS support in GLX @<:@default=enabled@:>@])],
1638     [GLX_USE_TLS="$enableval"],
1639     [GLX_USE_TLS=yes])
1640 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1641
1642 if test "x$GLX_USE_TLS" = xyes; then
1643     DEFINES="$DEFINES -DGLX_USE_TLS"
1644 fi
1645
1646 dnl Read-only text section on x86 hardened platforms
1647 AC_ARG_ENABLE([glx-read-only-text],
1648     [AS_HELP_STRING([--enable-glx-read-only-text],
1649         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1650     [enable_glx_read_only_text="$enableval"],
1651     [enable_glx_read_only_text=no])
1652 if test "x$enable_glx_read_only_text" = xyes; then
1653     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1654 fi
1655
1656 dnl
1657 dnl DEPRECATED: EGL Platforms configuration
1658 dnl
1659 AC_ARG_WITH([egl-platforms],
1660     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1661         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1662     [with_egl_platforms="$withval"],
1663     [with_egl_platforms=auto])
1664
1665 if test "x$with_egl_platforms" = xauto; then
1666     with_egl_platforms="x11,surfaceless"
1667     if test "x$enable_gbm" = xyes; then
1668         with_egl_platforms="$with_egl_platforms,drm"
1669     fi
1670 else
1671     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1672 fi
1673
1674 dnl
1675 dnl Platforms configuration
1676 dnl
1677 AC_ARG_WITH([platforms],
1678     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1679         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1680         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1681     [with_platforms="$withval"],
1682     [with_platforms=auto])
1683
1684 # Reuse the autodetection rather than duplicating it.
1685 if test "x$with_platforms" = xauto; then
1686     with_platforms=$with_egl_platforms
1687 fi
1688
1689 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1690         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1691         WAYLAND_SCANNER='')
1692 if test "x$WAYLAND_SCANNER" = x; then
1693     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1694 fi
1695
1696 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1697 if test "x$have_wayland_protocols" = xyes; then
1698     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1699 fi
1700 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1701
1702 # Do per platform setups and checks
1703 platforms=`IFS=', '; echo $with_platforms`
1704 for plat in $platforms; do
1705     case "$plat" in
1706     wayland)
1707
1708         PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1709
1710         if test "x$WAYLAND_SCANNER" = "x:"; then
1711                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1712         fi
1713         if test "x$have_wayland_protocols" = xno; then
1714                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1715         fi
1716         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1717         ;;
1718
1719     x11)
1720         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1721         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1722         ;;
1723
1724     drm)
1725         test "x$enable_gbm" = "xno" &&
1726                 AC_MSG_ERROR([EGL platform drm needs gbm])
1727         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1728         ;;
1729
1730     surfaceless)
1731         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1732         ;;
1733
1734     android)
1735         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1736         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1737         ;;
1738
1739     *)
1740         AC_MSG_ERROR([platform '$plat' does not exist])
1741         ;;
1742     esac
1743
1744     case "$plat" in
1745     wayland|drm|surfaceless)
1746         require_libdrm "Platform $plat"
1747         ;;
1748     esac
1749 done
1750
1751 if test "x$enable_glx" != xno; then
1752     if ! echo "$platforms" | grep -q 'x11'; then
1753         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1754     fi
1755 fi
1756
1757 if test x"$enable_dri3" = xyes; then
1758     DEFINES="$DEFINES -DHAVE_DRI3"
1759
1760     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1761     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1762 fi
1763
1764 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1765 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1766 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1767 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1768 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1769
1770 dnl
1771 dnl More DRI setup
1772 dnl
1773 dnl Directory for DRI drivers
1774 AC_ARG_WITH([dri-driverdir],
1775     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1776         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1777     [DRI_DRIVER_INSTALL_DIR="$withval"],
1778     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1779 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1780 dnl Extra search path for DRI drivers
1781 AC_ARG_WITH([dri-searchpath],
1782     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1783         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1784     [DRI_DRIVER_SEARCH_DIR="$withval"],
1785     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1786 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1787 dnl Which drivers to build - default is chosen by platform
1788 AC_ARG_WITH([dri-drivers],
1789     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1790         [comma delimited classic DRI drivers list, e.g.
1791         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1792     [with_dri_drivers="$withval"],
1793     [with_dri_drivers=auto])
1794
1795 if test "x$with_dri_drivers" = xauto; then
1796     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1797         with_dri_drivers="yes"
1798     else
1799         with_dri_drivers="no"
1800     fi
1801 fi
1802 if test "x$with_dri_drivers" = xno; then
1803     with_dri_drivers=''
1804 fi
1805
1806 # Check for expat
1807 PKG_CHECK_MODULES([EXPAT], [expat],,
1808     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1809 )
1810
1811 dnl If $with_dri_drivers is yes, drivers will be added through
1812 dnl platform checks. Set DEFINES and LIB_DEPS
1813 if test "x$enable_dri" = xyes; then
1814     # Platform specific settings and drivers to build
1815     case "$host_os" in
1816     linux*)
1817         case "$host_cpu" in
1818         powerpc* | sparc*)
1819             # Build only the drivers for cards that exist on PowerPC/sparc
1820             if test "x$with_dri_drivers" = "xyes"; then
1821                 with_dri_drivers="r200 radeon swrast"
1822             fi
1823             ;;
1824         esac
1825         ;;
1826     cygwin*)
1827         if test "x$with_dri_drivers" = "xyes"; then
1828             with_dri_drivers="swrast"
1829         fi
1830         ;;
1831     darwin*)
1832         DEFINES="$DEFINES -DBUILDING_MESA"
1833         if test "x$with_dri_drivers" = "xyes"; then
1834             with_dri_drivers="swrast"
1835         fi
1836         ;;
1837     esac
1838
1839     # default drivers
1840     if test "x$with_dri_drivers" = "xyes"; then
1841         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1842     fi
1843
1844     # put all the necessary libs together
1845     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1846 fi
1847
1848 AC_SUBST([DRI_LIB_DEPS])
1849
1850 DRI_DIRS=''
1851 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1852 if test -n "$with_dri_drivers"; then
1853     if test "x$enable_opengl" != xyes; then
1854         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1855     fi
1856
1857     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1858     for driver in $dri_drivers; do
1859         DRI_DIRS="$DRI_DIRS $driver"
1860         case "x$driver" in
1861         xi915)
1862             require_libdrm "i915"
1863             HAVE_I915_DRI=yes
1864             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1865             ;;
1866         xi965)
1867             require_libdrm "i965"
1868             HAVE_I965_DRI=yes
1869             ;;
1870         xnouveau)
1871             require_libdrm "nouveau"
1872             HAVE_NOUVEAU_DRI=yes
1873             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1874             ;;
1875         xradeon)
1876             require_libdrm "radeon"
1877             HAVE_RADEON_DRI=yes;
1878             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1879             ;;
1880         xr200)
1881             require_libdrm "r200"
1882             HAVE_R200_DRI=yes
1883             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1884             ;;
1885         xswrast)
1886             HAVE_SWRAST_DRI=yes
1887             ;;
1888         *)
1889             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1890             ;;
1891         esac
1892     done
1893     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1894 fi
1895
1896
1897 dnl
1898 dnl Gallium LLVM
1899 dnl Deprecated: kept for backwards compatibility
1900 dnl
1901 AC_ARG_ENABLE([gallium-llvm],
1902     [AS_HELP_STRING([--enable-gallium-llvm],
1903         [DEPRECATED: use --enable-llvm instead])],
1904     [enable_gallium_llvm="$enableval"],
1905     [enable_gallium_llvm=auto])
1906
1907 if test "x$enable_gallium_llvm" != xauto; then
1908    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1909    enable_llvm=$enable_gallium_llvm
1910 fi
1911
1912 dnl
1913 dnl LLVM
1914 dnl
1915 AC_ARG_ENABLE([llvm],
1916     [AS_HELP_STRING([--enable-llvm],
1917         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1918     [enable_llvm="$enableval"],
1919     [enable_llvm=auto])
1920
1921 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1922     if test "x$FOUND_LLVM" = xyes; then
1923         case "$host_cpu" in
1924         i*86|x86_64|amd64) enable_llvm=yes;;
1925         *) enable_llvm=no;;
1926         esac
1927     else
1928         enable_llvm=no
1929     fi
1930 fi
1931
1932 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1933     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1934 fi
1935
1936 #
1937 # Vulkan driver configuration
1938 #
1939
1940 AC_ARG_WITH([vulkan-drivers],
1941     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1942         [comma delimited Vulkan drivers list, e.g.
1943         "intel,radeon"
1944         @<:@default=no@:>@])],
1945     [with_vulkan_drivers="$withval"],
1946     [with_vulkan_drivers="no"])
1947
1948 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1949 # here so that the script doesn't choke on an unknown driver name later.
1950 case "x$with_vulkan_drivers" in
1951     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1952     xno) with_vulkan_drivers='' ;;
1953 esac
1954
1955 AC_ARG_WITH([vulkan-icddir],
1956     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1957         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1958     [VULKAN_ICD_INSTALL_DIR="$withval"],
1959     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1960 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1961
1962 require_x11_dri3() {
1963     if echo "$platforms" | grep -q 'x11'; then
1964         if test "x$enable_dri3" != xyes; then
1965             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1966         fi
1967     fi
1968 }
1969
1970 if test -n "$with_vulkan_drivers"; then
1971     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1972         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1973     fi
1974
1975     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1976     for driver in $VULKAN_DRIVERS; do
1977         case "x$driver" in
1978         xintel)
1979             require_libdrm "ANV"
1980             require_x11_dri3 "ANV"
1981             HAVE_INTEL_VULKAN=yes
1982             ;;
1983         xradeon)
1984             require_libdrm "radv"
1985             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1986             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1987             require_x11_dri3 "radv"
1988             HAVE_RADEON_VULKAN=yes
1989             ;;
1990         *)
1991             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1992             ;;
1993         esac
1994     done
1995     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1996 fi
1997
1998
1999 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2000 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2001 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2002                                   "x$enable_osmesa" = xyes -o \
2003                                   -n "$DRI_DIRS")
2004
2005 dnl
2006 dnl OSMesa configuration
2007 dnl
2008
2009 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2010 AC_ARG_WITH([osmesa-bits],
2011     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2012         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2013     [osmesa_bits="$withval"],
2014     [osmesa_bits=8])
2015 if test "x$osmesa_bits" != x8; then
2016     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2017         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2018         osmesa_bits=8
2019     fi
2020 fi
2021 case "x$osmesa_bits" in
2022 x8)
2023     OSMESA_LIB="${OSMESA_LIB}"
2024     ;;
2025 x16|x32)
2026     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2027     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2028     ;;
2029 *)
2030     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2031     ;;
2032 esac
2033
2034 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2035     # only link libraries with osmesa if shared
2036     if test "$enable_static" = no; then
2037         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2038     else
2039         OSMESA_LIB_DEPS=""
2040     fi
2041     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2042 fi
2043
2044 AC_SUBST([OSMESA_LIB_DEPS])
2045 AC_SUBST([OSMESA_PC_REQ])
2046 AC_SUBST([OSMESA_PC_LIB_PRIV])
2047
2048 dnl
2049 dnl gbm configuration
2050 dnl
2051 if test "x$enable_gbm" = xyes; then
2052     require_dri_shared_libs_and_glapi "gbm"
2053 fi
2054 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2055 # FINISHME: GBM has a number of dependencies which we should add below
2056 GBM_PC_REQ_PRIV=""
2057 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2058 AC_SUBST([GBM_PC_REQ_PRIV])
2059 AC_SUBST([GBM_PC_LIB_PRIV])
2060
2061 dnl
2062 dnl EGL configuration
2063 dnl
2064
2065 if test "x$enable_egl" = xyes; then
2066     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2067
2068     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2069
2070     require_dri_shared_libs_and_glapi "egl"
2071 fi
2072 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2073 AC_SUBST([EGL_LIB_DEPS])
2074
2075 gallium_st="mesa"
2076
2077 dnl
2078 dnl XA configuration
2079 dnl
2080 if test "x$enable_xa" = xyes; then
2081     if test "x$with_gallium_drivers" = xswrast; then
2082        AC_MSG_ERROR([
2083           Building xa requires at least one non swrast gallium driver.
2084           If you are looking to use libxatracker.so with the VMware driver,
2085           make sure to include svga in the gallium drivers list, apart from
2086           enabling XA.
2087           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2088     fi
2089     gallium_st="$gallium_st xa"
2090 fi
2091 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2092
2093 if echo $platforms | grep -q "x11"; then
2094     have_xvmc_platform=yes
2095 else
2096     have_xvmc_platform=no
2097 fi
2098
2099 if echo $platforms | grep -q "x11"; then
2100     have_vdpau_platform=yes
2101 else
2102     have_vdpau_platform=no
2103 fi
2104
2105 if echo $platforms | grep -q "x11\|drm"; then
2106     have_omx_platform=yes
2107 else
2108     have_omx_platform=no
2109 fi
2110
2111 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2112     have_va_platform=yes
2113 else
2114     have_va_platform=no
2115 fi
2116
2117 dnl
2118 dnl Gallium G3DVL configuration
2119 dnl
2120 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2121     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2122         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2123     fi
2124
2125     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2126         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2127     fi
2128
2129     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2130         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2131     fi
2132
2133     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2134         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2135     fi
2136 fi
2137
2138 if test "x$enable_dri" = xyes -o \
2139         "x$enable_xvmc" = xyes -o \
2140         "x$enable_vdpau" = xyes -o \
2141         "x$enable_omx" = xyes -o \
2142         "x$enable_va" = xyes; then
2143     need_gallium_vl=yes
2144 fi
2145 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2146
2147 if test "x$enable_xvmc" = xyes -o \
2148         "x$enable_vdpau" = xyes -o \
2149         "x$enable_omx" = xyes -o \
2150         "x$enable_va" = xyes; then
2151     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2152     need_gallium_vl_winsys=yes
2153 fi
2154 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2155
2156 if test "x$enable_xvmc" = xyes; then
2157     if test "x$have_xvmc_platform" != xyes; then
2158         AC_MSG_ERROR([XVMC requires the x11 platforms])
2159     fi
2160     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2161     gallium_st="$gallium_st xvmc"
2162 fi
2163 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2164
2165 if test "x$enable_vdpau" = xyes; then
2166     if test "x$have_vdpau_platform" != xyes; then
2167         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2168     fi
2169     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2170     gallium_st="$gallium_st vdpau"
2171     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2172 fi
2173 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2174
2175 if test "x$enable_omx" = xyes; then
2176     if test "x$have_omx_platform" != xyes; then
2177         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2178     fi
2179     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2180     gallium_st="$gallium_st omx"
2181 fi
2182 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2183
2184 if test "x$enable_va" = xyes; then
2185     if test "x$have_va_platform" != xyes; then
2186         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2187     fi
2188     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2189     gallium_st="$gallium_st va"
2190 fi
2191 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2192
2193 dnl
2194 dnl Nine Direct3D9 configuration
2195 dnl
2196 if test "x$enable_nine" = xyes; then
2197     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2198         AC_MSG_ERROR([nine requires the gallium swrast driver])
2199     fi
2200     if test "x$with_gallium_drivers" = xswrast; then
2201         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2202     fi
2203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2204         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2205     fi
2206
2207     if test "x$enable_dri3" = xno; then
2208         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2209     fi
2210
2211     gallium_st="$gallium_st nine"
2212 fi
2213 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2214
2215 dnl
2216 dnl OpenCL configuration
2217 dnl
2218
2219 AC_ARG_WITH([clang-libdir],
2220    [AS_HELP_STRING([--with-clang-libdir],
2221          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2222    [CLANG_LIBDIR="$withval"],
2223    [CLANG_LIBDIR=''])
2224
2225 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2226
2227 if test "x$enable_opencl" = xyes; then
2228     if test -z "$with_gallium_drivers"; then
2229         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2230     fi
2231
2232     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2233         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2234     fi
2235
2236     if test "x$have_libclc" = xno; then
2237         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2238                     Make sure the directory containing libclc.pc is specified in your
2239                     PKG_CONFIG_PATH environment variable.
2240                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2241     else
2242         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2243         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2244         AC_SUBST([LIBCLC_INCLUDEDIR])
2245         AC_SUBST([LIBCLC_LIBEXECDIR])
2246     fi
2247
2248     gallium_st="$gallium_st clover"
2249
2250     if test "x$enable_opencl_icd" = xyes; then
2251         OPENCL_LIBNAME="MesaOpenCL"
2252     else
2253         OPENCL_LIBNAME="OpenCL"
2254     fi
2255
2256     if test "x$have_libelf" != xyes; then
2257        AC_MSG_ERROR([Clover requires libelf])
2258     fi
2259
2260     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2261         altivec_enabled=no
2262         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2263         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2264         #error "AltiVec not enabled"
2265         #endif
2266         ])], altivec_enabled=yes)
2267
2268         if test "$altivec_enabled" = yes; then
2269             CLOVER_STD_OVERRIDE="-std=gnu++11"
2270         fi
2271         AC_SUBST([CLOVER_STD_OVERRIDE])
2272     fi
2273
2274     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2275
2276     llvm_add_default_components "opencl"
2277     llvm_add_component "all-targets" "opencl"
2278     llvm_add_component "linker" "opencl"
2279     llvm_add_component "instrumentation" "opencl"
2280     llvm_add_component "ipo" "opencl"
2281     llvm_add_component "irreader" "opencl"
2282     llvm_add_component "option" "opencl"
2283     llvm_add_component "objcarcopts" "opencl"
2284     llvm_add_component "profiledata" "opencl"
2285
2286     dnl Check for Clang internal headers
2287     if test -z "$CLANG_LIBDIR"; then
2288         CLANG_LIBDIR=${LLVM_LIBDIR}
2289     fi
2290     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2291     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2292         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2293 fi
2294 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2295 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2296 AC_SUBST([OPENCL_LIBNAME])
2297 AC_SUBST([CLANG_RESOURCE_DIR])
2298
2299 dnl
2300 dnl Gallium configuration
2301 dnl
2302 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2303
2304 # libEGL wants to default to the first platform specified in
2305 # ./configure.  parse that here.
2306 if test "x$platforms" != "x"; then
2307     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2308     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2309 else
2310     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2311 fi
2312
2313 AC_SUBST([EGL_NATIVE_PLATFORM])
2314 AC_SUBST([EGL_CFLAGS])
2315
2316 # If we don't have the X11 platform, set this define so we don't try to include
2317 # the X11 headers.
2318 if ! echo "$platforms" | grep -q 'x11'; then
2319     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2320     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2321 fi
2322
2323 dnl Directory for XVMC libs
2324 AC_ARG_WITH([xvmc-libdir],
2325     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2326         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2327     [XVMC_LIB_INSTALL_DIR="$withval"],
2328     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2329 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2330
2331 dnl
2332 dnl Gallium Tests
2333 dnl
2334 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2335
2336 dnl Directory for VDPAU libs
2337 AC_ARG_WITH([vdpau-libdir],
2338     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2339         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2340     [VDPAU_LIB_INSTALL_DIR="$withval"],
2341     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2342 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2343
2344 dnl Directory for OMX libs
2345
2346 AC_ARG_WITH([omx-libdir],
2347     [AS_HELP_STRING([--with-omx-libdir=DIR],
2348         [directory for the OMX libraries])],
2349     [OMX_LIB_INSTALL_DIR="$withval"],
2350     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2351                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2352 AC_SUBST([OMX_LIB_INSTALL_DIR])
2353
2354 dnl Directory for VA libs
2355
2356 AC_ARG_WITH([va-libdir],
2357     [AS_HELP_STRING([--with-va-libdir=DIR],
2358         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2359     [VA_LIB_INSTALL_DIR="$withval"],
2360     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2361 AC_SUBST([VA_LIB_INSTALL_DIR])
2362
2363 AC_ARG_WITH([d3d-libdir],
2364     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2365         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2366     [D3D_DRIVER_INSTALL_DIR="$withval"],
2367     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2368 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2369
2370 dnl Architectures to build SWR library for
2371
2372 AC_ARG_WITH([swr-archs],
2373     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2374         [comma delimited swr architectures list, e.g.
2375         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2376     [with_swr_archs="$withval"],
2377     [with_swr_archs="avx,avx2"])
2378
2379 dnl
2380 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2381 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2382 dnl architectures.
2383 dnl
2384 r300_require_llvm() {
2385     case "$host" in *gnux32) return;; esac
2386     case "$host_cpu" in
2387     i*86|x86_64|amd64) require_llvm $1
2388         ;;
2389     esac
2390 }
2391
2392 dnl
2393 dnl DRM is needed by X, Wayland, and offscreen rendering.
2394 dnl Surfaceless is an alternative for the last one.
2395 dnl
2396 require_basic_egl() {
2397     case "$with_platforms" in
2398         *drm*|*surfaceless*)
2399             ;;
2400         *)
2401             AC_MSG_ERROR([$1 requires one of these:
2402                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2403                   2) --with-platforms=surfaceless (offscreen only)
2404                   Recommended options: drm,x11])
2405             ;;
2406     esac
2407 }
2408
2409 swr_require_cxx_feature_flags() {
2410     feature_name="$1"
2411     preprocessor_test="$2"
2412     option_list="$3"
2413     output_var="$4"
2414
2415     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2416     AC_LANG_PUSH([C++])
2417     save_CXXFLAGS="$CXXFLAGS"
2418     save_IFS="$IFS"
2419     IFS=","
2420     found=0
2421     for opts in $option_list
2422     do
2423         unset IFS
2424         CXXFLAGS="$opts $save_CXXFLAGS"
2425         AC_COMPILE_IFELSE(
2426             [AC_LANG_PROGRAM(
2427                 [   #if !($preprocessor_test)
2428                     #error
2429                     #endif
2430                 ])],
2431             [found=1; break],
2432             [])
2433         IFS=","
2434     done
2435     IFS="$save_IFS"
2436     CXXFLAGS="$save_CXXFLAGS"
2437     AC_LANG_POP([C++])
2438     if test $found -eq 1; then
2439         AC_MSG_RESULT([$opts])
2440         eval "$output_var=\$opts"
2441         return 0
2442     fi
2443     AC_MSG_RESULT([no])
2444     AC_MSG_ERROR([swr requires $feature_name support])
2445     return 1
2446 }
2447
2448 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2449 if test -n "$with_gallium_drivers"; then
2450     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2451     for driver in $gallium_drivers; do
2452         case "x$driver" in
2453         xsvga)
2454             HAVE_GALLIUM_SVGA=yes
2455             require_libdrm "svga"
2456             ;;
2457         xi915)
2458             HAVE_GALLIUM_I915=yes
2459             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2460             require_libdrm "Gallium i915"
2461             ;;
2462         xr300)
2463             HAVE_GALLIUM_R300=yes
2464             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2465             require_libdrm "r300"
2466             r300_require_llvm "r300"
2467             ;;
2468         xr600)
2469             HAVE_GALLIUM_R600=yes
2470             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2471             require_libdrm "r600"
2472             if test "x$enable_llvm" = xyes; then
2473                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2474
2475                 llvm_add_component "asmparser" "r600"
2476                 llvm_add_component "bitreader" "r600"
2477             fi
2478             ;;
2479         xradeonsi)
2480             HAVE_GALLIUM_RADEONSI=yes
2481             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2482             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2483             require_libdrm "radeonsi"
2484             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2485             if test "x$enable_egl" = xyes; then
2486                 require_basic_egl "radeonsi"
2487             fi
2488             ;;
2489         xnouveau)
2490             HAVE_GALLIUM_NOUVEAU=yes
2491             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2492             require_libdrm "nouveau"
2493             ;;
2494         xfreedreno)
2495             HAVE_GALLIUM_FREEDRENO=yes
2496             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2497             require_libdrm "freedreno"
2498             ;;
2499         xetnaviv)
2500             HAVE_GALLIUM_ETNAVIV=yes
2501             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2502             require_libdrm "etnaviv"
2503             ;;
2504        ximx)
2505             HAVE_GALLIUM_IMX=yes
2506             ;;
2507         xswrast)
2508             HAVE_GALLIUM_SOFTPIPE=yes
2509             if test "x$enable_llvm" = xyes; then
2510                 HAVE_GALLIUM_LLVMPIPE=yes
2511             fi
2512             ;;
2513         xswr)
2514             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2515
2516             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2517                 ",-std=c++11" \
2518                 SWR_CXX11_CXXFLAGS
2519             AC_SUBST([SWR_CXX11_CXXFLAGS])
2520
2521             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2522                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2523                 SWR_AVX_CXXFLAGS
2524             AC_SUBST([SWR_AVX_CXXFLAGS])
2525
2526             swr_archs=`IFS=', '; echo $with_swr_archs`
2527             for arch in $swr_archs; do
2528                 case "x$arch" in
2529                 xavx)
2530                     HAVE_SWR_AVX=yes
2531                     ;;
2532                 xavx2)
2533                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2534                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2535                         SWR_AVX2_CXXFLAGS
2536                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2537                     HAVE_SWR_AVX2=yes
2538                     ;;
2539                 xknl)
2540                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2541                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2542                         SWR_KNL_CXXFLAGS
2543                     AC_SUBST([SWR_KNL_CXXFLAGS])
2544                     HAVE_SWR_KNL=yes
2545                     ;;
2546                 xskx)
2547                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2548                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2549                         SWR_SKX_CXXFLAGS
2550                     AC_SUBST([SWR_SKX_CXXFLAGS])
2551                     HAVE_SWR_SKX=yes
2552                     ;;
2553                 *)
2554                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2555                     ;;
2556                 esac
2557             done
2558
2559             if test "x$HAVE_SWR_AVX" != xyes -a \
2560                     "x$HAVE_SWR_AVX2" != xyes -a \
2561                     "x$HAVE_SWR_KNL" != xyes -a \
2562                     "x$HAVE_SWR_SKX" != xyes; then
2563                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2564             fi
2565
2566             HAVE_GALLIUM_SWR=yes
2567             ;;
2568         xvc4)
2569             HAVE_GALLIUM_VC4=yes
2570             require_libdrm "vc4"
2571
2572             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2573                               [USE_VC4_SIMULATOR=yes;
2574                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2575                               [USE_VC4_SIMULATOR=no])
2576             ;;
2577         xpl111)
2578             HAVE_GALLIUM_PL111=yes
2579             ;;
2580         xvirgl)
2581             HAVE_GALLIUM_VIRGL=yes
2582             require_libdrm "virgl"
2583             if test "x$enable_egl" = xyes; then
2584                 require_basic_egl "virgl"
2585             fi
2586             ;;
2587         *)
2588             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2589             ;;
2590         esac
2591     done
2592 fi
2593
2594 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2595 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2596                                               "x$LLVM_VERSION" != x3.9.1)
2597
2598 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2599     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2600     llvm_add_default_components "gallium"
2601 fi
2602
2603 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2604 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2605 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2606 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2607
2608 dnl We need to validate some needed dependencies for renderonly drivers.
2609
2610 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2611     AC_MSG_ERROR([Building with imx requires etnaviv])
2612 fi
2613
2614 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2615     AC_MSG_ERROR([Building with pl111 requires vc4])
2616 fi
2617
2618 dnl
2619 dnl Set defines and buildtime variables only when using LLVM.
2620 dnl
2621 if test "x$enable_llvm" = xyes; then
2622     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2623
2624     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2625     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2626     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2627
2628     dnl Set LLVM_LIBS - This is done after the driver configuration so
2629     dnl that drivers can add additional components to LLVM_COMPONENTS.
2630     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2631     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2632     dnl this was causing the same libraries to be appear multiple times
2633     dnl in LLVM_LIBS.
2634
2635     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2636        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2637     fi
2638     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2639
2640     if test "x$enable_llvm_shared_libs" = xyes; then
2641         if test $LLVM_VERSION_MAJOR -lt 4 -o "`$LLVM_CONFIG --shared-mode ${LLVM_COMPONENTS}`" = static; then
2642             dnl llvm-config may not give the right answer when llvm is a built as a
2643             dnl single shared library, so we must work the library name out for
2644             dnl ourselves.
2645             dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2646             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2647             LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2648             AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2649
2650             if test "x$llvm_have_one_so" = xyes; then
2651                dnl LLVM was built using auto*, so there is only one shared object.
2652                LLVM_LIBS="-l$LLVM_SO_NAME"
2653             else
2654                 dnl If LLVM was built with CMake, there will be one shared object per
2655                 dnl component.
2656                 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2657                       [AC_MSG_ERROR([Could not find llvm shared libraries:
2658                        Please make sure you have built llvm with the --enable-shared option
2659                        and that your llvm libraries are installed in $LLVM_LIBDIR
2660                        If you have installed your llvm libraries to a different directory you
2661                        can use the --with-llvm-prefix= configure flag to specify this directory.
2662                        NOTE: Mesa is attempting to use llvm shared libraries by default.
2663                        If you do not want to build with llvm shared libraries and instead want to
2664                        use llvm static libraries then add --disable-llvm-shared-libs to your configure
2665                        invocation and rebuild.])])
2666
2667                 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2668                 dnl install uses a shared object for each component and we have
2669                 dnl already added all of these objects to LLVM_LIBS.
2670             fi
2671         fi
2672     else
2673         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2674         dnl We need to link to llvm system libs when using static libs
2675         dnl However, only llvm 3.5+ provides --system-libs
2676         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2677             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2678         fi
2679     fi
2680 fi
2681
2682 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2683 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2684 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2685 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2686 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2687 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2688 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2689                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2690 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2691 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2692 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2693 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2694 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2695 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2696 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2697 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2698                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2699                                          "x$HAVE_GALLIUM_SWR" = xyes)
2700 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2701 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2702
2703 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2704
2705 if test "x$enable_dri" = xyes; then
2706     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2707 fi
2708
2709 if test "x$have_drisw_kms" = xyes; then
2710     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2711 fi
2712 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2713
2714 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2715 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2716 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2717 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2718 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2719 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2720
2721 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2722 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2723
2724 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2725                                       "x$HAVE_RADEON_VULKAN" = xyes)
2726
2727 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2728                                         "x$HAVE_I965_DRI" = xyes)
2729
2730 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2731                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2732                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2733 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2734 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2735 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2736 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2737
2738 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2739 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2740 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2741 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2742                                         "x$enable_gallium_osmesa" = xyes)
2743
2744 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2745 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2746 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2747 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2748 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2749 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2750
2751 AC_SUBST([NINE_MAJOR], 1)
2752 AC_SUBST([NINE_MINOR], 0)
2753 AC_SUBST([NINE_TINY], 0)
2754 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2755
2756 AC_SUBST([VDPAU_MAJOR], 1)
2757 AC_SUBST([VDPAU_MINOR], 0)
2758
2759 if test "x$enable_va" = xyes; then
2760     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2761     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2762 fi
2763 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2764 AC_SUBST([VA_MINOR], $VA_MINOR)
2765
2766 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2767
2768 AC_SUBST([XVMC_MAJOR], 1)
2769 AC_SUBST([XVMC_MINOR], 0)
2770
2771 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2772 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2773 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2774 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2775
2776 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2777 AC_SUBST([XA_MINOR], $XA_MINOR)
2778 AC_SUBST([XA_TINY], $XA_TINY)
2779 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2780
2781 AC_ARG_ENABLE(valgrind,
2782               [AS_HELP_STRING([--enable-valgrind],
2783                              [Build mesa with valgrind support (default: auto)])],
2784                              [VALGRIND=$enableval], [VALGRIND=auto])
2785 if test "x$VALGRIND" != xno; then
2786     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2787 fi
2788 AC_MSG_CHECKING([whether to enable Valgrind support])
2789 if test "x$VALGRIND" = xauto; then
2790     VALGRIND="$have_valgrind"
2791 fi
2792
2793 if test "x$VALGRIND" = "xyes"; then
2794     if ! test "x$have_valgrind" = xyes; then
2795         AC_MSG_ERROR([Valgrind support required but not present])
2796     fi
2797     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2798 fi
2799
2800 AC_MSG_RESULT([$VALGRIND])
2801
2802 dnl Restore LDFLAGS and CPPFLAGS
2803 LDFLAGS="$_SAVE_LDFLAGS"
2804 CPPFLAGS="$_SAVE_CPPFLAGS"
2805
2806 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2807 if test "x$acv_mesa_CLANG" = xyes; then
2808     CFLAGS="$CFLAGS -Qunused-arguments"
2809     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2810 fi
2811
2812 dnl Add user CFLAGS and CXXFLAGS
2813 CFLAGS="$CFLAGS $USER_CFLAGS"
2814 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2815
2816 dnl Substitute the config
2817 AC_CONFIG_FILES([Makefile
2818                  src/Makefile
2819                  src/amd/Makefile
2820                  src/amd/vulkan/Makefile
2821                  src/broadcom/Makefile
2822                  src/compiler/Makefile
2823                  src/egl/Makefile
2824                  src/egl/main/egl.pc
2825                  src/egl/wayland/wayland-drm/Makefile
2826                  src/egl/wayland/wayland-egl/Makefile
2827                  src/egl/wayland/wayland-egl/wayland-egl.pc
2828                  src/gallium/Makefile
2829                  src/gallium/auxiliary/Makefile
2830                  src/gallium/auxiliary/pipe-loader/Makefile
2831                  src/gallium/drivers/freedreno/Makefile
2832                  src/gallium/drivers/ddebug/Makefile
2833                  src/gallium/drivers/i915/Makefile
2834                  src/gallium/drivers/llvmpipe/Makefile
2835                  src/gallium/drivers/noop/Makefile
2836                  src/gallium/drivers/nouveau/Makefile
2837                  src/gallium/drivers/pl111/Makefile
2838                  src/gallium/drivers/r300/Makefile
2839                  src/gallium/drivers/r600/Makefile
2840                  src/gallium/drivers/radeon/Makefile
2841                  src/gallium/drivers/radeonsi/Makefile
2842                  src/gallium/drivers/rbug/Makefile
2843                  src/gallium/drivers/softpipe/Makefile
2844                  src/gallium/drivers/svga/Makefile
2845                  src/gallium/drivers/swr/Makefile
2846                  src/gallium/drivers/trace/Makefile
2847                  src/gallium/drivers/etnaviv/Makefile
2848                  src/gallium/drivers/imx/Makefile
2849                  src/gallium/drivers/vc4/Makefile
2850                  src/gallium/drivers/virgl/Makefile
2851                  src/gallium/state_trackers/clover/Makefile
2852                  src/gallium/state_trackers/dri/Makefile
2853                  src/gallium/state_trackers/glx/xlib/Makefile
2854                  src/gallium/state_trackers/nine/Makefile
2855                  src/gallium/state_trackers/omx/Makefile
2856                  src/gallium/state_trackers/osmesa/Makefile
2857                  src/gallium/state_trackers/va/Makefile
2858                  src/gallium/state_trackers/vdpau/Makefile
2859                  src/gallium/state_trackers/xa/Makefile
2860                  src/gallium/state_trackers/xvmc/Makefile
2861                  src/gallium/targets/d3dadapter9/Makefile
2862                  src/gallium/targets/d3dadapter9/d3d.pc
2863                  src/gallium/targets/dri/Makefile
2864                  src/gallium/targets/libgl-xlib/Makefile
2865                  src/gallium/targets/omx/Makefile
2866                  src/gallium/targets/opencl/Makefile
2867                  src/gallium/targets/opencl/mesa.icd
2868                  src/gallium/targets/osmesa/Makefile
2869                  src/gallium/targets/osmesa/osmesa.pc
2870                  src/gallium/targets/pipe-loader/Makefile
2871                  src/gallium/targets/va/Makefile
2872                  src/gallium/targets/vdpau/Makefile
2873                  src/gallium/targets/xa/Makefile
2874                  src/gallium/targets/xa/xatracker.pc
2875                  src/gallium/targets/xvmc/Makefile
2876                  src/gallium/tests/trivial/Makefile
2877                  src/gallium/tests/unit/Makefile
2878                  src/gallium/winsys/etnaviv/drm/Makefile
2879                  src/gallium/winsys/imx/drm/Makefile
2880                  src/gallium/winsys/freedreno/drm/Makefile
2881                  src/gallium/winsys/i915/drm/Makefile
2882                  src/gallium/winsys/nouveau/drm/Makefile
2883                  src/gallium/winsys/pl111/drm/Makefile
2884                  src/gallium/winsys/radeon/drm/Makefile
2885                  src/gallium/winsys/amdgpu/drm/Makefile
2886                  src/gallium/winsys/svga/drm/Makefile
2887                  src/gallium/winsys/sw/dri/Makefile
2888                  src/gallium/winsys/sw/kms-dri/Makefile
2889                  src/gallium/winsys/sw/null/Makefile
2890                  src/gallium/winsys/sw/wrapper/Makefile
2891                  src/gallium/winsys/sw/xlib/Makefile
2892                  src/gallium/winsys/vc4/drm/Makefile
2893                  src/gallium/winsys/virgl/drm/Makefile
2894                  src/gallium/winsys/virgl/vtest/Makefile
2895                  src/gbm/Makefile
2896                  src/gbm/main/gbm.pc
2897                  src/glx/Makefile
2898                  src/glx/apple/Makefile
2899                  src/glx/tests/Makefile
2900                  src/glx/windows/Makefile
2901                  src/glx/windows/windowsdriproto.pc
2902                  src/gtest/Makefile
2903                  src/intel/Makefile
2904                  src/loader/Makefile
2905                  src/mapi/Makefile
2906                  src/mapi/es1api/glesv1_cm.pc
2907                  src/mapi/es2api/glesv2.pc
2908                  src/mapi/glapi/gen/Makefile
2909                  src/mesa/Makefile
2910                  src/mesa/gl.pc
2911                  src/mesa/drivers/dri/dri.pc
2912                  src/mesa/drivers/dri/common/Makefile
2913                  src/mesa/drivers/dri/i915/Makefile
2914                  src/mesa/drivers/dri/i965/Makefile
2915                  src/mesa/drivers/dri/Makefile
2916                  src/mesa/drivers/dri/nouveau/Makefile
2917                  src/mesa/drivers/dri/r200/Makefile
2918                  src/mesa/drivers/dri/radeon/Makefile
2919                  src/mesa/drivers/dri/swrast/Makefile
2920                  src/mesa/drivers/osmesa/Makefile
2921                  src/mesa/drivers/osmesa/osmesa.pc
2922                  src/mesa/drivers/x11/Makefile
2923                  src/mesa/main/tests/Makefile
2924                  src/util/Makefile
2925                  src/util/tests/hash_table/Makefile
2926                  src/util/xmlpool/Makefile
2927                  src/vulkan/Makefile])
2928
2929 AC_OUTPUT
2930
2931 # Fix up dependencies in *.Plo files, where we changed the extension of a
2932 # source file
2933 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2934
2935 rm -f src/compiler/spirv/spirv_info.lo
2936 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
2937
2938 dnl
2939 dnl Output some configuration info for the user
2940 dnl
2941 echo ""
2942 echo "        prefix:          $prefix"
2943 echo "        exec_prefix:     $exec_prefix"
2944 echo "        libdir:          $libdir"
2945 echo "        includedir:      $includedir"
2946
2947 dnl API info
2948 echo ""
2949 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2950
2951 dnl Driver info
2952 echo ""
2953 case "x$enable_osmesa$enable_gallium_osmesa" in
2954 xnoyes)
2955         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2956         ;;
2957 xyesno)
2958         echo "        OSMesa:          lib$OSMESA_LIB"
2959         ;;
2960 xnono)
2961         echo "        OSMesa:          no"
2962         ;;
2963 esac
2964
2965 echo ""
2966 if test "x$enable_dri" != xno; then
2967         echo "        DRI platform:    $dri_platform"
2968         if test -z "$DRI_DIRS"; then
2969             echo "        DRI drivers:     no"
2970         else
2971             echo "        DRI drivers:     $DRI_DIRS"
2972         fi
2973         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2974 fi
2975
2976 case "x$enable_glx" in
2977 xdri)
2978     echo "        GLX:             DRI-based"
2979     ;;
2980 xxlib)
2981     echo "        GLX:             Xlib-based"
2982     ;;
2983 xgallium-xlib)
2984     echo "        GLX:             Xlib-based (Gallium)"
2985     ;;
2986 *)
2987     echo "        GLX:             $enable_glx"
2988     ;;
2989 esac
2990
2991 dnl EGL
2992 echo ""
2993 echo "        EGL:             $enable_egl"
2994 if test "$enable_egl" = yes; then
2995
2996     egl_drivers=""
2997     if test "x$enable_dri" != "xno"; then
2998         egl_drivers="$egl_drivers builtin:egl_dri2"
2999     fi
3000     if test "x$enable_dri3" != "xno"; then
3001         egl_drivers="$egl_drivers builtin:egl_dri3"
3002     fi
3003
3004     echo "        EGL drivers:    $egl_drivers"
3005 fi
3006 if test "x$enable_gbm" = xyes; then
3007     echo "        GBM:             yes"
3008 else
3009     echo "        GBM:             no"
3010 fi
3011
3012     echo "        EGL/Vulkan/VL platforms:   $platforms"
3013
3014 # Vulkan
3015 echo ""
3016 if test "x$VULKAN_DRIVERS" != x; then
3017     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3018     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3019 else
3020     echo "        Vulkan drivers:  no"
3021 fi
3022
3023 echo ""
3024 if test "x$enable_llvm" = xyes; then
3025     echo "        llvm:            yes"
3026     echo "        llvm-config:     $LLVM_CONFIG"
3027     echo "        llvm-version:    $LLVM_VERSION"
3028 else
3029     echo "        llvm:            no"
3030 fi
3031
3032 echo ""
3033 if test -n "$with_gallium_drivers"; then
3034     echo "        Gallium drivers: $gallium_drivers"
3035     echo "        Gallium st:      $gallium_st"
3036 else
3037     echo "        Gallium:         no"
3038 fi
3039
3040 echo ""
3041 if test "x$enable_gallium_extra_hud" != xyes; then
3042     echo "        HUD extra stats: no"
3043 else
3044     echo "        HUD extra stats: yes"
3045 fi
3046
3047 if test "x$enable_lmsensors" != xyes; then
3048     echo "        HUD lmsensors:   no"
3049 else
3050     echo "        HUD lmsensors:   yes"
3051 fi
3052
3053 echo ""
3054 if test "x$HAVE_GALLIUM_SWR" != x; then
3055     echo "        SWR archs:       $swr_archs"
3056 fi
3057
3058 dnl Libraries
3059 echo ""
3060 echo "        Shared libs:     $enable_shared"
3061 echo "        Static libs:     $enable_static"
3062 echo "        Shared-glapi:    $enable_shared_glapi"
3063
3064 dnl Compiler options
3065 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3066 cflags=`echo $CFLAGS | \
3067     $SED 's/^ *//;s/  */ /;s/ *$//'`
3068 cxxflags=`echo $CXXFLAGS | \
3069     $SED 's/^ *//;s/  */ /;s/ *$//'`
3070 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3071 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3072 echo ""
3073 echo "        CFLAGS:          $cflags"
3074 echo "        CXXFLAGS:        $cxxflags"
3075 echo "        LDFLAGS:         $ldflags"
3076 echo "        Macros:          $defines"
3077 echo ""
3078 if test "x$enable_llvm" = xyes; then
3079     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3080     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3081     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3082     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3083     echo ""
3084 fi
3085 echo "        PYTHON2:         $PYTHON2"
3086
3087 echo ""
3088 echo "        Run '${MAKE-make}' to build Mesa"
3089 echo ""