configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282
 283 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 284 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 285 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 286 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 287 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 288 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 289
 290 AC_SUBST([GL_LIB_NAME])
 291 AC_SUBST([GLU_LIB_NAME])
 292 AC_SUBST([GLUT_LIB_NAME])
 293 AC_SUBST([GLW_LIB_NAME])
 294 AC_SUBST([OSMESA_LIB_NAME])
 295 AC_SUBST([EGL_LIB_NAME])
 296
 297 AC_SUBST([GL_LIB_GLOB])
 298 AC_SUBST([GLU_LIB_GLOB])
 299 AC_SUBST([GLUT_LIB_GLOB])
 300 AC_SUBST([GLW_LIB_GLOB])
 301 AC_SUBST([OSMESA_LIB_GLOB])
 302 AC_SUBST([EGL_LIB_GLOB])
 303
 304 dnl
 305 dnl Arch/platform-specific settings
 306 dnl
 307 AC_ARG_ENABLE([asm],
 308     [AS_HELP_STRING([--disable-asm],
 309         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 310     [enable_asm="$enableval"],
 311     [enable_asm=yes]
 312 )
 313 asm_arch=""
 314 ASM_FLAGS=""
 315 MESA_ASM_SOURCES=""
 316 GLAPI_ASM_SOURCES=""
 317 AC_MSG_CHECKING([whether to enable assembly])
 318 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 319 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 320 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 321     case "$host_cpu" in
 322     i?86 | x86_64)
 323         enable_asm=no
 324         AC_MSG_RESULT([no, cross compiling])
 325         ;;
 326     esac
 327 fi
 328 # check for supported arches
 329 if test "x$enable_asm" = xyes; then
 330     case "$host_cpu" in
 331     i?86)
 332         case "$host_os" in
 333         linux* | *freebsd* | dragonfly*)
 334             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 335             ;;
 336         esac
 337         ;;
 338     x86_64)
 339         case "$host_os" in
 340         linux* | *freebsd* | dragonfly*)
 341             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 342             ;;
 343         esac
 344         ;;
 345     powerpc)
 346         case "$host_os" in
 347         linux*)
 348             asm_arch=ppc
 349             ;;
 350         esac
 351         ;;
 352     sparc*)
 353         case "$host_os" in
 354         linux*)
 355             asm_arch=sparc
 356             ;;
 357         esac
 358         ;;
 359     esac
 360
 361     case "$asm_arch" in
 362     x86)
 363         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 364         MESA_ASM_SOURCES='$(X86_SOURCES)'
 365         GLAPI_ASM_SOURCES='$(X86_API)'
 366         AC_MSG_RESULT([yes, x86])
 367         ;;
 368     x86_64)
 369         ASM_FLAGS="-DUSE_X86_64_ASM"
 370         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 371         GLAPI_ASM_SOURCES='$(X86-64_API)'
 372         AC_MSG_RESULT([yes, x86_64])
 373         ;;
 374     ppc)
 375         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 376         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 377         AC_MSG_RESULT([yes, ppc])
 378         ;;
 379     sparc)
 380         ASM_FLAGS="-DUSE_SPARC_ASM"
 381         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 382         GLAPI_ASM_SOURCES='$(SPARC_API)'
 383         AC_MSG_RESULT([yes, sparc])
 384         ;;
 385     *)
 386         AC_MSG_RESULT([no, platform not supported])
 387         ;;
 388     esac
 389 fi
 390 AC_SUBST([ASM_FLAGS])
 391 AC_SUBST([MESA_ASM_SOURCES])
 392 AC_SUBST([GLAPI_ASM_SOURCES])
 393
 394 dnl PIC code macro
 395 MESA_PIC_FLAGS
 396
 397 dnl Check to see if dlopen is in default libraries (like Solaris, which
 398 dnl has it in libc), or if libdl is needed to get it.
 399 AC_CHECK_FUNC([dlopen], [],
 400     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 401
 402 dnl See if posix_memalign is available
 403 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 404
 405 dnl SELinux awareness.
 406 AC_ARG_ENABLE([selinux],
 407     [AS_HELP_STRING([--enable-selinux],
 408         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 409     [MESA_SELINUX="$enableval"],
 410     [MESA_SELINUX=no])
 411 if test "x$enable_selinux" = "xyes"; then
 412     AC_CHECK_HEADER([selinux/selinux.h],[],
 413                     [AC_MSG_ERROR([SELinux headers not found])])
 414     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 415                  [AC_MSG_ERROR([SELinux library not found])])
 416     SELINUX_LIBS="-lselinux"
 417     DEFINES="$DEFINES -DMESA_SELINUX"
 418 fi
 419
 420 dnl
 421 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 422 dnl More later: fbdev, ...
 423 dnl
 424 default_driver="xlib"
 425
 426 case "$host_os" in
 427 linux*)
 428     case "$host_cpu" in
 429     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 430     esac
 431     ;;
 432 *freebsd* | dragonfly*)
 433     case "$host_cpu" in
 434     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 435     esac
 436     ;;
 437 esac
 438
 439 AC_ARG_WITH([driver],
 440     [AS_HELP_STRING([--with-driver=DRIVER],
 441         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 442     [mesa_driver="$withval"],
 443     [mesa_driver="$default_driver"])
 444 dnl Check for valid option
 445 case "x$mesa_driver" in
 446 xxlib|xdri|xosmesa)
 447     ;;
 448 *)
 449     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 450     ;;
 451 esac
 452
 453 dnl
 454 dnl Driver specific build directories
 455 dnl
 456
 457 dnl this variable will be prepended to SRC_DIRS and is not exported
 458 CORE_DIRS="glsl mesa"
 459
 460 SRC_DIRS="glew"
 461 GLU_DIRS="sgi"
 462 GALLIUM_DIRS="auxiliary drivers state_trackers"
 463 GALLIUM_TARGET_DIRS=""
 464 GALLIUM_WINSYS_DIRS=""
 465 GALLIUM_WINSYS_DRM_DIRS=""
 466 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 467 GALLIUM_STATE_TRACKERS_DIRS=""
 468
 469 case "$mesa_driver" in
 470 xlib)
 471     DRIVER_DIRS="x11"
 472     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 473     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 474     ;;
 475 dri)
 476     SRC_DIRS="$SRC_DIRS glx"
 477     DRIVER_DIRS="dri"
 478     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib drm"
 479     ;;
 480 osmesa)
 481     DRIVER_DIRS="osmesa"
 482     ;;
 483 esac
 484 AC_SUBST([SRC_DIRS])
 485 AC_SUBST([GLU_DIRS])
 486 AC_SUBST([DRIVER_DIRS])
 487 AC_SUBST([GALLIUM_DIRS])
 488 AC_SUBST([GALLIUM_TARGET_DIRS])
 489 AC_SUBST([GALLIUM_WINSYS_DIRS])
 490 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 491 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 492 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 493
 494 dnl
 495 dnl User supplied program configuration
 496 dnl
 497 if test -d "$srcdir/progs/demos"; then
 498     default_demos=yes
 499 else
 500     default_demos=no
 501 fi
 502 AC_ARG_WITH([demos],
 503     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 504         [optional comma delimited demo directories to build
 505         @<:@default=auto if source available@:>@])],
 506     [with_demos="$withval"],
 507     [with_demos="$default_demos"])
 508 if test "x$with_demos" = x; then
 509     with_demos=no
 510 fi
 511
 512 dnl If $with_demos is yes, directories will be added as libs available
 513 PROGRAM_DIRS=""
 514 case "$with_demos" in
 515 no) ;;
 516 yes)
 517     # If the driver isn't osmesa, we have libGL and can build xdemos
 518     if test "$mesa_driver" != osmesa; then
 519         PROGRAM_DIRS="xdemos"
 520     fi
 521     ;;
 522 *)
 523     # verify the requested demos directories exist
 524     demos=`IFS=,; echo $with_demos`
 525     for demo in $demos; do
 526         test -d "$srcdir/progs/$demo" || \
 527             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 528     done
 529     PROGRAM_DIRS="$demos"
 530     ;;
 531 esac
 532
 533 dnl
 534 dnl Find out if X is available. The variable have_x is set if libX11 is
 535 dnl found to mimic AC_PATH_XTRA.
 536 dnl
 537 if test -n "$PKG_CONFIG"; then
 538     AC_MSG_CHECKING([pkg-config files for X11 are available])
 539     PKG_CHECK_EXISTS([x11],[
 540         x11_pkgconfig=yes
 541         have_x=yes
 542         ],[
 543         x11_pkgconfig=no
 544     ])
 545     AC_MSG_RESULT([$x11_pkgconfig])
 546 else
 547     x11_pkgconfig=no
 548 fi
 549 dnl Use the autoconf macro if no pkg-config files
 550 if test "$x11_pkgconfig" = yes; then
 551     PKG_CHECK_MODULES([X], [x11])
 552 else
 553     AC_PATH_XTRA
 554 fi
 555
 556 dnl Try to tell the user that the --x-* options are only used when
 557 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 558 m4_divert_once([HELP_BEGIN],
 559 [These options are only used when the X libraries cannot be found by the
 560 pkg-config utility.])
 561
 562 dnl We need X for xlib and dri, so bomb now if it's not found
 563 case "$mesa_driver" in
 564 xlib|dri)
 565     if test "$no_x" = yes; then
 566         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 567     fi
 568     ;;
 569 esac
 570
 571 dnl XCB - this is only used for GLX right now
 572 AC_ARG_ENABLE([xcb],
 573     [AS_HELP_STRING([--enable-xcb],
 574         [use XCB for GLX @<:@default=disabled@:>@])],
 575     [enable_xcb="$enableval"],
 576     [enable_xcb=no])
 577 if test "x$enable_xcb" = xyes; then
 578     DEFINES="$DEFINES -DUSE_XCB"
 579 else
 580     enable_xcb=no
 581 fi
 582
 583 dnl
 584 dnl libGL configuration per driver
 585 dnl
 586 case "$mesa_driver" in
 587 xlib)
 588     if test "$x11_pkgconfig" = yes; then
 589         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 590         GL_PC_REQ_PRIV="x11 xext"
 591         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 592         GL_LIB_DEPS="$XLIBGL_LIBS"
 593     else
 594         # should check these...
 595         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 596         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 597         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 598         GL_PC_CFLAGS="$X11_INCLUDES"
 599     fi
 600     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 601     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 602
 603     # if static, move the external libraries to the programs
 604     # and empty the libraries for libGL
 605     if test "$enable_static" = yes; then
 606         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 607         GL_LIB_DEPS=""
 608     fi
 609     ;;
 610 dri)
 611     # DRI must be shared, I think
 612     if test "$enable_static" = yes; then
 613         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 614     fi
 615
 616     # Check for libdrm
 617     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 618     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 619     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 620     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 621     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 622
 623     # find the DRI deps for libGL
 624     if test "$x11_pkgconfig" = yes; then
 625         # add xcb modules if necessary
 626         dri_modules="x11 xext xxf86vm xdamage xfixes"
 627         if test "$enable_xcb" = yes; then
 628             dri_modules="$dri_modules x11-xcb xcb-glx"
 629         fi
 630
 631         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 632         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 633         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 634         GL_LIB_DEPS="$DRIGL_LIBS"
 635     else
 636         # should check these...
 637         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 638         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 639         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 640         GL_PC_CFLAGS="$X11_INCLUDES"
 641
 642         # XCB can only be used from pkg-config
 643         if test "$enable_xcb" = yes; then
 644             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 645             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 646             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 647             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 648         fi
 649     fi
 650
 651     # need DRM libs, -lpthread, etc.
 652     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 653     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 654     ;;
 655 osmesa)
 656     # No libGL for osmesa
 657     GL_LIB_DEPS=""
 658     ;;
 659 esac
 660 AC_SUBST([GL_LIB_DEPS])
 661 AC_SUBST([GL_PC_REQ_PRIV])
 662 AC_SUBST([GL_PC_LIB_PRIV])
 663 AC_SUBST([GL_PC_CFLAGS])
 664 AC_SUBST([DRI_PC_REQ_PRIV])
 665
 666 dnl
 667 dnl More X11 setup
 668 dnl
 669 if test "$mesa_driver" = xlib; then
 670     DEFINES="$DEFINES -DUSE_XSHM"
 671 fi
 672
 673 dnl
 674 dnl More DRI setup
 675 dnl
 676 AC_ARG_ENABLE([glx-tls],
 677     [AS_HELP_STRING([--enable-glx-tls],
 678         [enable TLS support in GLX @<:@default=disabled@:>@])],
 679     [GLX_USE_TLS="$enableval"],
 680     [GLX_USE_TLS=no])
 681 dnl Directory for DRI drivers
 682 AC_ARG_WITH([dri-driverdir],
 683     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 684         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 685     [DRI_DRIVER_INSTALL_DIR="$withval"],
 686     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 687 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 688 dnl Extra search path for DRI drivers
 689 AC_ARG_WITH([dri-searchpath],
 690     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 691         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 692     [DRI_DRIVER_SEARCH_DIR="$withval"],
 693     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 694 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 695 dnl Direct rendering or just indirect rendering
 696 AC_ARG_ENABLE([driglx-direct],
 697     [AS_HELP_STRING([--disable-driglx-direct],
 698         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 699     [driglx_direct="$enableval"],
 700     [driglx_direct="yes"])
 701 dnl Which drivers to build - default is chosen by platform
 702 AC_ARG_WITH([dri-drivers],
 703     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 704         [comma delimited DRI drivers list, e.g.
 705         "swrast,i965,radeon" @<:@default=auto@:>@])],
 706     [with_dri_drivers="$withval"],
 707     [with_dri_drivers=yes])
 708 if test "x$with_dri_drivers" = x; then
 709     with_dri_drivers=no
 710 fi
 711
 712 dnl If $with_dri_drivers is yes, directories will be added through
 713 dnl platform checks
 714 DRI_DIRS=""
 715 case "$with_dri_drivers" in
 716 no) ;;
 717 yes)
 718     DRI_DIRS="yes"
 719     ;;
 720 *)
 721     # verify the requested driver directories exist
 722     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 723     for driver in $dri_drivers; do
 724         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 725             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 726     done
 727     DRI_DIRS="$dri_drivers"
 728     ;;
 729 esac
 730
 731 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 732 if test "$mesa_driver" = dri; then
 733     # Use TLS in GLX?
 734     if test "x$GLX_USE_TLS" = xyes; then
 735         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 736     fi
 737
 738     # Platform specific settings and drivers to build
 739     case "$host_os" in
 740     linux*)
 741         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 742         if test "x$driglx_direct" = xyes; then
 743             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 744         fi
 745         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 746
 747         case "$host_cpu" in
 748         x86_64)
 749             # sis is missing because they have not be converted to use
 750             # the new interface.  i810 are missing because there is no
 751             # x86-64 system where they could *ever* be used.
 752             if test "x$DRI_DIRS" = "xyes"; then
 753                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 754                     savage tdfx unichrome swrast"
 755             fi
 756             ;;
 757         powerpc*)
 758             # Build only the drivers for cards that exist on PowerPC.
 759             # At some point MGA will be added, but not yet.
 760             if test "x$DRI_DIRS" = "xyes"; then
 761                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 762             fi
 763             ;;
 764         sparc*)
 765             # Build only the drivers for cards that exist on sparc`
 766             if test "x$DRI_DIRS" = "xyes"; then
 767                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 768             fi
 769             ;;
 770         esac
 771         ;;
 772     freebsd* | dragonfly*)
 773         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 774         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 775         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 776         if test "x$driglx_direct" = xyes; then
 777             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 778         fi
 779         if test "x$GXX" = xyes; then
 780             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 781         fi
 782
 783         if test "x$DRI_DIRS" = "xyes"; then
 784             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 785                 unichrome savage sis swrast"
 786         fi
 787         ;;
 788     gnu*)
 789         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 790         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 791         ;;
 792     solaris*)
 793         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 794         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 795         if test "x$driglx_direct" = xyes; then
 796             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 797         fi
 798         ;;
 799     esac
 800
 801     # default drivers
 802     if test "x$DRI_DIRS" = "xyes"; then
 803         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 804             savage sis tdfx unichrome swrast"
 805     fi
 806
 807     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 808
 809     # Check for expat
 810     EXPAT_INCLUDES=""
 811     EXPAT_LIB=-lexpat
 812     AC_ARG_WITH([expat],
 813         [AS_HELP_STRING([--with-expat=DIR],
 814             [expat install directory])],[
 815         EXPAT_INCLUDES="-I$withval/include"
 816         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 817         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 818         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 819         ])
 820     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 821     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 822         [AC_MSG_ERROR([Expat required for DRI.])])
 823
 824     # put all the necessary libs together
 825     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 826 fi
 827 AC_SUBST([DRI_DIRS])
 828 AC_SUBST([EXPAT_INCLUDES])
 829 AC_SUBST([DRI_LIB_DEPS])
 830
 831 case $DRI_DIRS in
 832 *i915*|*i965*)
 833     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 834     ;;
 835 esac
 836
 837 case $DRI_DIRS in
 838 *radeon*|*r200*|*r300*|*r600*)
 839     PKG_CHECK_MODULES([LIBDRM_RADEON],
 840                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 841                       HAVE_LIBDRM_RADEON=yes,
 842                       HAVE_LIBDRM_RADEON=no)
 843
 844     if test "$HAVE_LIBDRM_RADEON" = yes; then
 845         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 846         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 847     fi
 848     ;;
 849 esac
 850 AC_SUBST([RADEON_CFLAGS])
 851 AC_SUBST([RADEON_LDFLAGS])
 852
 853
 854 dnl
 855 dnl OSMesa configuration
 856 dnl
 857 if test "$mesa_driver" = xlib; then
 858     default_gl_osmesa=yes
 859 else
 860     default_gl_osmesa=no
 861 fi
 862 AC_ARG_ENABLE([gl-osmesa],
 863     [AS_HELP_STRING([--enable-gl-osmesa],
 864         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 865     [gl_osmesa="$enableval"],
 866     [gl_osmesa="$default_gl_osmesa"])
 867 if test "x$gl_osmesa" = xyes; then
 868     if test "$mesa_driver" = osmesa; then
 869         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 870     else
 871         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 872     fi
 873 fi
 874
 875 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 876 AC_ARG_WITH([osmesa-bits],
 877     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 878         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 879     [osmesa_bits="$withval"],
 880     [osmesa_bits=8])
 881 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 882     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 883     osmesa_bits=8
 884 fi
 885 case "x$osmesa_bits" in
 886 x8)
 887     OSMESA_LIB=OSMesa
 888     ;;
 889 x16|x32)
 890     OSMESA_LIB="OSMesa$osmesa_bits"
 891     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 892     ;;
 893 *)
 894     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 895     ;;
 896 esac
 897 AC_SUBST([OSMESA_LIB])
 898
 899 case "$mesa_driver" in
 900 osmesa)
 901     # only link libraries with osmesa if shared
 902     if test "$enable_static" = no; then
 903         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 904     else
 905         OSMESA_LIB_DEPS=""
 906     fi
 907     OSMESA_MESA_DEPS=""
 908     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 909     ;;
 910 *)
 911     # Link OSMesa to libGL otherwise
 912     OSMESA_LIB_DEPS=""
 913     # only link libraries with osmesa if shared
 914     if test "$enable_static" = no; then
 915         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 916     else
 917         OSMESA_MESA_DEPS=""
 918     fi
 919     OSMESA_PC_REQ="gl"
 920     ;;
 921 esac
 922 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 923 AC_SUBST([OSMESA_LIB_DEPS])
 924 AC_SUBST([OSMESA_MESA_DEPS])
 925 AC_SUBST([OSMESA_PC_REQ])
 926 AC_SUBST([OSMESA_PC_LIB_PRIV])
 927
 928 dnl
 929 dnl EGL configuration
 930 dnl
 931 AC_ARG_ENABLE([egl],
 932     [AS_HELP_STRING([--disable-egl],
 933         [disable EGL library @<:@default=enabled@:>@])],
 934     [enable_egl="$enableval"],
 935     [enable_egl=yes])
 936 if test "x$enable_egl" = xyes; then
 937     SRC_DIRS="$SRC_DIRS egl"
 938     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 939     EGL_DRIVERS_DIRS=""
 940     if test "$enable_static" != yes; then
 941         # build egl_glx when libGL is built
 942         if test "$mesa_driver" != osmesa; then
 943             EGL_DRIVERS_DIRS="glx"
 944         fi
 945
 946         # build egl_dri2 when xcb-dri2 is available
 947         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
 948                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 949         if test "$have_xcb_dri2" = yes; then
 950             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
 951         fi
 952     fi
 953
 954     if test "$with_demos" = yes; then
 955         PROGRAM_DIRS="$PROGRAM_DIRS egl"
 956     fi
 957 fi
 958 AC_SUBST([EGL_LIB_DEPS])
 959 AC_SUBST([EGL_DRIVERS_DIRS])
 960
 961 dnl
 962 dnl GLU configuration
 963 dnl
 964 AC_ARG_ENABLE([glu],
 965     [AS_HELP_STRING([--disable-glu],
 966         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 967     [enable_glu="$enableval"],
 968     [enable_glu=yes])
 969 if test "x$enable_glu" = xyes; then
 970     SRC_DIRS="$SRC_DIRS glu"
 971
 972     case "$mesa_driver" in
 973     osmesa)
 974         # If GLU is available and we have libOSMesa (not 16 or 32),
 975         # we can build the osdemos
 976         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 977             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 978         fi
 979
 980         # Link libGLU to libOSMesa instead of libGL
 981         GLU_LIB_DEPS=""
 982         GLU_PC_REQ="osmesa"
 983         if test "$enable_static" = no; then
 984             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 985         else
 986             GLU_MESA_DEPS=""
 987         fi
 988         ;;
 989     *)
 990         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 991         GLU_PC_REQ="gl"
 992         GLU_PC_LIB_PRIV="-lm"
 993         if test "$enable_static" = no; then
 994             GLU_LIB_DEPS="-lm"
 995             GLU_MESA_DEPS='-l$(GL_LIB)'
 996         else
 997             GLU_LIB_DEPS=""
 998             GLU_MESA_DEPS=""
 999             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1000         fi
1001         ;;
1002     esac
1003 fi
1004 if test "$enable_static" = no; then
1005     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1006 fi
1007 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1008 AC_SUBST([GLU_LIB_DEPS])
1009 AC_SUBST([GLU_MESA_DEPS])
1010 AC_SUBST([GLU_PC_REQ])
1011 AC_SUBST([GLU_PC_REQ_PRIV])
1012 AC_SUBST([GLU_PC_LIB_PRIV])
1013 AC_SUBST([GLU_PC_CFLAGS])
1014
1015 dnl
1016 dnl GLw configuration
1017 dnl
1018 AC_ARG_ENABLE([glw],
1019     [AS_HELP_STRING([--disable-glw],
1020         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1021     [enable_glw="$enableval"],
1022     [enable_glw=yes])
1023 dnl Don't build GLw on osmesa
1024 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1025     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1026     enable_glw=no
1027 fi
1028 AC_ARG_ENABLE([motif],
1029     [AS_HELP_STRING([--enable-motif],
1030         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1031     [enable_motif="$enableval"],
1032     [enable_motif=no])
1033
1034 if test "x$enable_glw" = xyes; then
1035     SRC_DIRS="$SRC_DIRS glw"
1036     if test "$x11_pkgconfig" = yes; then
1037         PKG_CHECK_MODULES([GLW],[x11 xt])
1038         GLW_PC_REQ_PRIV="x11 xt"
1039         GLW_LIB_DEPS="$GLW_LIBS"
1040     else
1041         # should check these...
1042         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1043         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1044         GLW_PC_CFLAGS="$X11_INCLUDES"
1045     fi
1046
1047     GLW_SOURCES="GLwDrawA.c"
1048     MOTIF_CFLAGS=
1049     if test "x$enable_motif" = xyes; then
1050         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1051         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1052         if test "x$MOTIF_CONFIG" != xno; then
1053             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1054             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1055         else
1056             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1057                 [AC_MSG_ERROR([Can't locate Motif headers])])
1058             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1059                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1060         fi
1061         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1062         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1063         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1064         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1065     fi
1066
1067     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1068     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1069     if test "$enable_static" = no; then
1070         GLW_MESA_DEPS='-l$(GL_LIB)'
1071         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1072     else
1073         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1074         GLW_LIB_DEPS=""
1075         GLW_MESA_DEPS=""
1076     fi
1077 fi
1078 AC_SUBST([GLW_LIB_DEPS])
1079 AC_SUBST([GLW_MESA_DEPS])
1080 AC_SUBST([GLW_SOURCES])
1081 AC_SUBST([MOTIF_CFLAGS])
1082 AC_SUBST([GLW_PC_REQ_PRIV])
1083 AC_SUBST([GLW_PC_LIB_PRIV])
1084 AC_SUBST([GLW_PC_CFLAGS])
1085
1086 dnl
1087 dnl GLUT configuration
1088 dnl
1089 if test -f "$srcdir/include/GL/glut.h"; then
1090     default_glut=yes
1091 else
1092     default_glut=no
1093 fi
1094 AC_ARG_ENABLE([glut],
1095     [AS_HELP_STRING([--disable-glut],
1096         [enable GLUT library @<:@default=enabled if source available@:>@])],
1097     [enable_glut="$enableval"],
1098     [enable_glut="$default_glut"])
1099
1100 dnl Can't build glut if GLU not available
1101 if test "x$enable_glu$enable_glut" = xnoyes; then
1102     AC_MSG_WARN([Disabling glut since GLU is disabled])
1103     enable_glut=no
1104 fi
1105 dnl Don't build glut on osmesa
1106 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1107     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1108     enable_glut=no
1109 fi
1110
1111 if test "x$enable_glut" = xyes; then
1112     SRC_DIRS="$SRC_DIRS glut/glx"
1113     GLUT_CFLAGS=""
1114     if test "x$GCC" = xyes; then
1115         GLUT_CFLAGS="-fexceptions"
1116     fi
1117     if test "$x11_pkgconfig" = yes; then
1118         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1119         GLUT_PC_REQ_PRIV="x11 xmu xi"
1120         GLUT_LIB_DEPS="$GLUT_LIBS"
1121     else
1122         # should check these...
1123         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1124         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1125         GLUT_PC_CFLAGS="$X11_INCLUDES"
1126     fi
1127     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1128     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1129
1130     # If glut is available, we can build most programs
1131     if test "$with_demos" = yes; then
1132         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1133     fi
1134
1135     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1136     if test "$enable_static" = no; then
1137         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1138     else
1139         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1140         GLUT_LIB_DEPS=""
1141         GLUT_MESA_DEPS=""
1142     fi
1143 fi
1144 AC_SUBST([GLUT_LIB_DEPS])
1145 AC_SUBST([GLUT_MESA_DEPS])
1146 AC_SUBST([GLUT_CFLAGS])
1147 AC_SUBST([GLUT_PC_REQ_PRIV])
1148 AC_SUBST([GLUT_PC_LIB_PRIV])
1149 AC_SUBST([GLUT_PC_CFLAGS])
1150
1151 dnl
1152 dnl Program library dependencies
1153 dnl    Only libm is added here if necessary as the libraries should
1154 dnl    be pulled in by the linker
1155 dnl
1156 if test "x$APP_LIB_DEPS" = x; then
1157     case "$host_os" in
1158     solaris*)
1159         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1160         ;;
1161     cygwin*)
1162         APP_LIB_DEPS="-lX11"
1163         ;;
1164     *)
1165         APP_LIB_DEPS="-lm"
1166         ;;
1167     esac
1168 fi
1169 AC_SUBST([APP_LIB_DEPS])
1170 AC_SUBST([PROGRAM_DIRS])
1171
1172 dnl
1173 dnl Gallium configuration
1174 dnl
1175 AC_ARG_ENABLE([gallium],
1176     [AS_HELP_STRING([--disable-gallium],
1177         [build gallium @<:@default=enabled@:>@])],
1178     [enable_gallium="$enableval"],
1179     [enable_gallium=yes])
1180 if test "x$enable_gallium" = xyes; then
1181     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1182 fi
1183
1184 dnl
1185 dnl Gallium state trackers configuration
1186 dnl
1187 AC_ARG_WITH([state-trackers],
1188     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1189         [comma delimited state_trackers list, e.g.
1190         "egl,glx" @<:@default=auto@:>@])],
1191     [with_state_trackers="$withval"],
1192     [with_state_trackers=yes])
1193
1194 case "$with_state_trackers" in
1195 no)
1196     GALLIUM_STATE_TRACKERS_DIRS=""
1197     ;;
1198 yes)
1199     # look at what else is built
1200     case "$mesa_driver" in
1201     xlib)
1202         GALLIUM_STATE_TRACKERS_DIRS=glx
1203         ;;
1204     dri)
1205         GALLIUM_STATE_TRACKERS_DIRS="dri"
1206         if test "x$enable_egl" = xyes; then
1207             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1208         fi
1209         # Have only tested st/xorg on 1.6.0 servers
1210         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1211             HAVE_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1212             HAVE_XORG="no")
1213         ;;
1214     esac
1215     ;;
1216 *)
1217     # verify the requested state tracker exist
1218     state_trackers=`IFS=', '; echo $with_state_trackers`
1219     for tracker in $state_trackers; do
1220         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1221             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1222
1223         case "$tracker" in
1224         egl)
1225             if test "x$enable_egl" != xyes; then
1226                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1227             fi
1228             ;;
1229         xorg)
1230             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1231             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1232             HAVE_XORG="yes"
1233             ;;
1234         es)
1235             # mesa/es is required to build es state tracker
1236             CORE_DIRS="$CORE_DIRS mesa/es"
1237             ;;
1238         esac
1239     done
1240     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1241     ;;
1242 esac
1243
1244 if test "x$HAVE_XORG" = xyes; then
1245     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1246         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1247         HAVE_XEXTPROTO_71="no")
1248 fi
1249
1250 AC_ARG_WITH([egl-displays],
1251     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1252         [comma delimited native displays libEGL supports, e.g.
1253         "x11,kms" @<:@default=auto@:>@])],
1254     [with_egl_displays="$withval"],
1255     [with_egl_displays=yes])
1256
1257 EGL_DISPLAYS=""
1258 case "$with_egl_displays" in
1259 yes)
1260     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1261         EGL_DISPLAYS="x11"
1262     fi
1263     ;;
1264 *)
1265     if test "x$enable_egl" != xyes; then
1266         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1267     fi
1268     # verify the requested driver directories exist
1269     egl_displays=`IFS=', '; echo $with_egl_displays`
1270     for dpy in $egl_displays; do
1271         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1272             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1273     done
1274     EGL_DISPLAYS="$egl_displays"
1275     ;;
1276 esac
1277 AC_SUBST([EGL_DISPLAYS])
1278
1279 AC_ARG_WITH([egl-driver-dir],
1280     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1281                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1282     [EGL_DRIVER_INSTALL_DIR="$withval"],
1283     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1284 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1285
1286 AC_ARG_WITH([xorg-driver-dir],
1287     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1288                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1289     [XORG_DRIVER_INSTALL_DIR="$withval"],
1290     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1291 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1292
1293 AC_ARG_WITH([max-width],
1294     [AS_HELP_STRING([--with-max-width=N],
1295                     [Maximum framebuffer width (4096)])],
1296     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1297      AS_IF([test "${withval}" -gt "4096"],
1298            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1299 )
1300 AC_ARG_WITH([max-height],
1301     [AS_HELP_STRING([--with-max-height=N],
1302                     [Maximum framebuffer height (4096)])],
1303     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1304      AS_IF([test "${withval}" -gt "4096"],
1305            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1306 )
1307
1308 dnl
1309 dnl Gallium SVGA configuration
1310 dnl
1311 AC_ARG_ENABLE([gallium-svga],
1312     [AS_HELP_STRING([--enable-gallium-svga],
1313         [build gallium SVGA @<:@default=disabled@:>@])],
1314     [enable_gallium_svga="$enableval"],
1315     [enable_gallium_svga=auto])
1316 if test "x$enable_gallium_svga" = xyes; then
1317     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS vmware"
1318     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1319 elif test "x$enable_gallium_svga" = xauto; then
1320     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1321 fi
1322
1323 dnl
1324 dnl Gallium Intel configuration
1325 dnl
1326 AC_ARG_ENABLE([gallium-intel],
1327     [AS_HELP_STRING([--enable-gallium-intel],
1328         [build gallium intel @<:@default=disabled@:>@])],
1329     [enable_gallium_intel="$enableval"],
1330     [enable_gallium_intel=auto])
1331 if test "x$enable_gallium_intel" = xyes; then
1332     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel i965"
1333     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1334 elif test "x$enable_gallium_intel" = xauto; then
1335     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1336 fi
1337
1338 dnl
1339 dnl Gallium Radeon configuration
1340 dnl
1341 AC_ARG_ENABLE([gallium-radeon],
1342     [AS_HELP_STRING([--enable-gallium-radeon],
1343         [build gallium radeon @<:@default=disabled@:>@])],
1344     [enable_gallium_radeon="$enableval"],
1345     [enable_gallium_radeon=auto])
1346 if test "x$enable_gallium_radeon" = xyes; then
1347     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1348     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1349 elif test "x$enable_gallium_radeon" = xauto; then
1350     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1351 fi
1352
1353 dnl
1354 dnl Gallium Nouveau configuration
1355 dnl
1356 AC_ARG_ENABLE([gallium-nouveau],
1357     [AS_HELP_STRING([--enable-gallium-nouveau],
1358         [build gallium nouveau @<:@default=disabled@:>@])],
1359     [enable_gallium_nouveau="$enableval"],
1360     [enable_gallium_nouveau=no])
1361 if test "x$enable_gallium_nouveau" = xyes; then
1362     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1363     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv30 nv40 nv50"
1364 fi
1365
1366 dnl
1367 dnl Gallium swrast configuration
1368 dnl
1369 AC_ARG_ENABLE([gallium-swrast],
1370     [AS_HELP_STRING([--enable-gallium-swrast],
1371         [build gallium swrast @<:@default=disabled@:>@])],
1372     [enable_gallium_swrast="$enableval"],
1373     [enable_gallium_swrast=auto])
1374 if test "x$enable_gallium_swrast" = xyes; then
1375     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS swrast"
1376 fi
1377
1378 dnl prepend CORE_DIRS to SRC_DIRS
1379 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1380
1381 dnl Restore LDFLAGS and CPPFLAGS
1382 LDFLAGS="$_SAVE_LDFLAGS"
1383 CPPFLAGS="$_SAVE_CPPFLAGS"
1384
1385 dnl Substitute the config
1386 AC_CONFIG_FILES([configs/autoconf])
1387
1388 dnl Replace the configs/current symlink
1389 AC_CONFIG_COMMANDS([configs],[
1390 if test -f configs/current || test -L configs/current; then
1391     rm -f configs/current
1392 fi
1393 ln -s autoconf configs/current
1394 ])
1395
1396 AC_OUTPUT
1397
1398 dnl
1399 dnl Output some configuration info for the user
1400 dnl
1401 echo ""
1402 echo "        prefix:          $prefix"
1403 echo "        exec_prefix:     $exec_prefix"
1404 echo "        libdir:          $libdir"
1405 echo "        includedir:      $includedir"
1406
1407 dnl Driver info
1408 echo ""
1409 echo "        Driver:          $mesa_driver"
1410 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1411     echo "        OSMesa:          lib$OSMESA_LIB"
1412 else
1413     echo "        OSMesa:          no"
1414 fi
1415 if test "$mesa_driver" = dri; then
1416     # cleanup the drivers var
1417     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1418 if test "x$DRI_DIRS" = x; then
1419     echo "        DRI drivers:     no"
1420 else
1421     echo "        DRI drivers:     $dri_dirs"
1422 fi
1423     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1424 fi
1425 echo "        Use XCB:         $enable_xcb"
1426
1427 echo ""
1428 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1429     echo "        Gallium:         yes"
1430     echo "        Gallium dirs:    $GALLIUM_DIRS"
1431     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1432     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1433     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1434     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1435     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1436 else
1437     echo "        Gallium:         no"
1438 fi
1439
1440 dnl Libraries
1441 echo ""
1442 echo "        Shared libs:     $enable_shared"
1443 echo "        Static libs:     $enable_static"
1444 if test "$enable_egl" = yes; then
1445     echo "        EGL:             $EGL_DRIVERS_DIRS"
1446 else
1447     echo "        EGL:             no"
1448 fi
1449 echo "        GLU:             $enable_glu"
1450 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1451 echo "        glut:            $enable_glut"
1452
1453 dnl Programs
1454 # cleanup the programs var for display
1455 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1456 if test "x$program_dirs" = x; then
1457     echo "        Demos:           no"
1458 else
1459     echo "        Demos:           $program_dirs"
1460 fi
1461
1462 dnl Compiler options
1463 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1464 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1465     $SED 's/^ *//;s/  */ /;s/ *$//'`
1466 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1467     $SED 's/^ *//;s/  */ /;s/ *$//'`
1468 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1469 echo ""
1470 echo "        CFLAGS:          $cflags"
1471 echo "        CXXFLAGS:        $cxxflags"
1472 echo "        Macros:          $defines"
1473
1474 echo ""
1475 echo "        Run '${MAKE-make}' to build Mesa"
1476 echo ""