configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.2
  24 GLPROTO_REQUIRED=1.4.11
  25
  26 dnl Check for progs
  27 AC_PROG_CPP
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_CHECK_PROGS([MAKE], [gmake make])
  31 AC_PATH_PROG([MKDEP], [makedepend])
  32 AC_PATH_PROG([SED], [sed])
  33
  34 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  35 dnl configuration in that case.
  36 AC_PROG_INSTALL
  37 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  38
  39 dnl We need a POSIX shell for parts of the build. Assume we have one
  40 dnl in most cases.
  41 case "$host_os" in
  42 solaris*)
  43     # Solaris /bin/sh is too old/non-POSIX compliant
  44     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  45     SHELL="$POSIX_SHELL"
  46     ;;
  47 esac
  48
  49 MKDEP_OPTIONS=-fdepend
  50 dnl Ask gcc where it's keeping its secret headers
  51 if test "x$GCC" = xyes; then
  52     for dir in include include-fixed; do
  53         GCC_INCLUDES=`$CC -print-file-name=$dir`
  54         if test "x$GCC_INCLUDES" != x && \
  55            test "$GCC_INCLUDES" != "$dir" && \
  56            test -d "$GCC_INCLUDES"; then
  57             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  58         fi
  59     done
  60 fi
  61 AC_SUBST([MKDEP_OPTIONS])
  62
  63 dnl Make sure the pkg-config macros are defined
  64 m4_ifndef([PKG_PROG_PKG_CONFIG],
  65     [m4_fatal([Could not locate the pkg-config autoconf macros.
  66   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  67   are in a different location, try setting the environment variable
  68   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  69 PKG_PROG_PKG_CONFIG()
  70
  71 dnl LIB_DIR - library basename
  72 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  73 AC_SUBST([LIB_DIR])
  74
  75 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  76 _SAVE_LDFLAGS="$LDFLAGS"
  77 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  78 AC_SUBST([EXTRA_LIB_PATH])
  79
  80 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  81 _SAVE_CPPFLAGS="$CPPFLAGS"
  82 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  83 AC_SUBST([X11_INCLUDES])
  84
  85 dnl Compiler macros
  86 DEFINES=""
  87 AC_SUBST([DEFINES])
  88 case "$host_os" in
  89 linux*|*-gnu*|gnu*)
  90     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  91     ;;
  92 solaris*)
  93     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  94     ;;
  95 esac
  96
  97 dnl Add flags for gcc and g++
  98 if test "x$GCC" = xyes; then
  99     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 100
 101     # Enable -fvisibility=hidden if using a gcc that supports it
 102     save_CFLAGS="$CFLAGS"
 103     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 104     CFLAGS="$CFLAGS -fvisibility=hidden"
 105     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 106                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CFLAGS="$CFLAGS -fno-strict-aliasing"
 110 fi
 111 if test "x$GXX" = xyes; then
 112     CXXFLAGS="$CXXFLAGS -Wall"
 113
 114     # Work around aliasing bugs - developers should comment this out
 115     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 116 fi
 117
 118 dnl These should be unnecessary, but let the user set them if they want
 119 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 120     Default is to use CFLAGS.])
 121 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 122     compiler. Default is to use CFLAGS.])
 123 AC_SUBST([OPT_FLAGS])
 124 AC_SUBST([ARCH_FLAGS])
 125
 126 dnl
 127 dnl Hacks to enable 32 or 64 bit build
 128 dnl
 129 AC_ARG_ENABLE([32-bit],
 130     [AS_HELP_STRING([--enable-32-bit],
 131         [build 32-bit libraries @<:@default=auto@:>@])],
 132     [enable_32bit="$enableval"],
 133     [enable_32bit=auto]
 134 )
 135 if test "x$enable_32bit" = xyes; then
 136     if test "x$GCC" = xyes; then
 137         CFLAGS="$CFLAGS -m32"
 138         ARCH_FLAGS="$ARCH_FLAGS -m32"
 139     fi
 140     if test "x$GXX" = xyes; then
 141         CXXFLAGS="$CXXFLAGS -m32"
 142     fi
 143 fi
 144 AC_ARG_ENABLE([64-bit],
 145     [AS_HELP_STRING([--enable-64-bit],
 146         [build 64-bit libraries @<:@default=auto@:>@])],
 147     [enable_64bit="$enableval"],
 148     [enable_64bit=auto]
 149 )
 150 if test "x$enable_64bit" = xyes; then
 151     if test "x$GCC" = xyes; then
 152         CFLAGS="$CFLAGS -m64"
 153     fi
 154     if test "x$GXX" = xyes; then
 155         CXXFLAGS="$CXXFLAGS -m64"
 156     fi
 157 fi
 158
 159 dnl
 160 dnl shared/static libraries, mimic libtool options
 161 dnl
 162 AC_ARG_ENABLE([static],
 163     [AS_HELP_STRING([--enable-static],
 164         [build static libraries @<:@default=disabled@:>@])],
 165     [enable_static="$enableval"],
 166     [enable_static=no]
 167 )
 168 case "x$enable_static" in
 169 xyes|xno ) ;;
 170 x ) enable_static=no ;;
 171 * )
 172     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 173     ;;
 174 esac
 175 AC_ARG_ENABLE([shared],
 176     [AS_HELP_STRING([--disable-shared],
 177         [build shared libraries @<:@default=enabled@:>@])],
 178     [enable_shared="$enableval"],
 179     [enable_shared=yes]
 180 )
 181 case "x$enable_shared" in
 182 xyes|xno ) ;;
 183 x ) enable_shared=yes ;;
 184 * )
 185     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 186     ;;
 187 esac
 188
 189 dnl Can't have static and shared libraries, default to static if user
 190 dnl explicitly requested. If both disabled, set to static since shared
 191 dnl was explicitly requirested.
 192 case "x$enable_static$enable_shared" in
 193 xyesyes )
 194     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 195     enable_shared=no
 196     ;;
 197 xnono )
 198     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 199     enable_static=yes
 200     ;;
 201 esac
 202
 203 dnl
 204 dnl mklib options
 205 dnl
 206 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 207 if test "$enable_static" = yes; then
 208     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 209 fi
 210 AC_SUBST([MKLIB_OPTIONS])
 211
 212 dnl
 213 dnl other compiler options
 214 dnl
 215 AC_ARG_ENABLE([debug],
 216     [AS_HELP_STRING([--enable-debug],
 217         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 218     [enable_debug="$enableval"],
 219     [enable_debug=no]
 220 )
 221 if test "x$enable_debug" = xyes; then
 222     DEFINES="$DEFINES -DDEBUG"
 223     if test "x$GCC" = xyes; then
 224         CFLAGS="$CFLAGS -g"
 225     fi
 226     if test "x$GXX" = xyes; then
 227         CXXFLAGS="$CXXFLAGS -g"
 228     fi
 229 fi
 230
 231 dnl
 232 dnl library names
 233 dnl
 234 if test "$enable_static" = yes; then
 235     LIB_EXTENSION='a'
 236 else
 237     case "$host_os" in
 238     darwin* )
 239         LIB_EXTENSION='dylib' ;;
 240     cygwin* )
 241         LIB_EXTENSION='dll' ;;
 242     aix* )
 243         LIB_EXTENSION='a' ;;
 244     * )
 245         LIB_EXTENSION='so' ;;
 246     esac
 247 fi
 248
 249 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 250 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 251 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 252 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 253 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 254 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 255
 256 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 257 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 258 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 259 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 260 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 261 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 262
 263 AC_SUBST([GL_LIB_NAME])
 264 AC_SUBST([GLU_LIB_NAME])
 265 AC_SUBST([GLUT_LIB_NAME])
 266 AC_SUBST([GLW_LIB_NAME])
 267 AC_SUBST([OSMESA_LIB_NAME])
 268 AC_SUBST([EGL_LIB_NAME])
 269
 270 AC_SUBST([GL_LIB_GLOB])
 271 AC_SUBST([GLU_LIB_GLOB])
 272 AC_SUBST([GLUT_LIB_GLOB])
 273 AC_SUBST([GLW_LIB_GLOB])
 274 AC_SUBST([OSMESA_LIB_GLOB])
 275 AC_SUBST([EGL_LIB_GLOB])
 276
 277 dnl
 278 dnl Arch/platform-specific settings
 279 dnl
 280 AC_ARG_ENABLE([asm],
 281     [AS_HELP_STRING([--disable-asm],
 282         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 283     [enable_asm="$enableval"],
 284     [enable_asm=yes]
 285 )
 286 asm_arch=""
 287 ASM_FLAGS=""
 288 MESA_ASM_SOURCES=""
 289 GLAPI_ASM_SOURCES=""
 290 AC_MSG_CHECKING([whether to enable assembly])
 291 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 292 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 293 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 294     case "$host_cpu" in
 295     i?86 | x86_64)
 296         enable_asm=no
 297         AC_MSG_RESULT([no, cross compiling])
 298         ;;
 299     esac
 300 fi
 301 # check for supported arches
 302 if test "x$enable_asm" = xyes; then
 303     case "$host_cpu" in
 304     i?86)
 305         case "$host_os" in
 306         linux* | *freebsd* | dragonfly*)
 307             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 308             ;;
 309         esac
 310         ;;
 311     x86_64)
 312         case "$host_os" in
 313         linux* | *freebsd* | dragonfly*)
 314             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 315             ;;
 316         esac
 317         ;;
 318     powerpc)
 319         case "$host_os" in
 320         linux*)
 321             asm_arch=ppc
 322             ;;
 323         esac
 324         ;;
 325     sparc*)
 326         case "$host_os" in
 327         linux*)
 328             asm_arch=sparc
 329             ;;
 330         esac
 331         ;;
 332     esac
 333
 334     case "$asm_arch" in
 335     x86)
 336         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 337         MESA_ASM_SOURCES='$(X86_SOURCES)'
 338         GLAPI_ASM_SOURCES='$(X86_API)'
 339         AC_MSG_RESULT([yes, x86])
 340         ;;
 341     x86_64)
 342         ASM_FLAGS="-DUSE_X86_64_ASM"
 343         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 344         GLAPI_ASM_SOURCES='$(X86-64_API)'
 345         AC_MSG_RESULT([yes, x86_64])
 346         ;;
 347     ppc)
 348         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 349         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 350         AC_MSG_RESULT([yes, ppc])
 351         ;;
 352     sparc)
 353         ASM_FLAGS="-DUSE_SPARC_ASM"
 354         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 355         GLAPI_ASM_SOURCES='$(SPARC_API)'
 356         AC_MSG_RESULT([yes, sparc])
 357         ;;
 358     *)
 359         AC_MSG_RESULT([no, platform not supported])
 360         ;;
 361     esac
 362 fi
 363 AC_SUBST([ASM_FLAGS])
 364 AC_SUBST([MESA_ASM_SOURCES])
 365 AC_SUBST([GLAPI_ASM_SOURCES])
 366
 367 dnl PIC code macro
 368 MESA_PIC_FLAGS
 369
 370 dnl Check to see if dlopen is in default libraries (like Solaris, which
 371 dnl has it in libc), or if libdl is needed to get it.
 372 AC_CHECK_FUNC([dlopen], [],
 373     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 374
 375 dnl See if posix_memalign is available
 376 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 377
 378 dnl SELinux awareness.
 379 AC_ARG_ENABLE([selinux],
 380     [AS_HELP_STRING([--enable-selinux],
 381         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 382     [MESA_SELINUX="$enableval"],
 383     [MESA_SELINUX=no])
 384 if test "x$enable_selinux" = "xyes"; then
 385     AC_CHECK_HEADER([selinux/selinux.h],[],
 386                     [AC_MSG_ERROR([SELinux headers not found])])
 387     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 388                  [AC_MSG_ERROR([SELinux library not found])])
 389     SELINUX_LIBS="-lselinux"
 390     DEFINES="$DEFINES -DMESA_SELINUX"
 391 fi
 392
 393 dnl
 394 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 395 dnl More later: directfb, fbdev, ...
 396 dnl
 397 default_driver="xlib"
 398
 399 case "$host_os" in
 400 linux*)
 401     case "$host_cpu" in
 402     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 403     esac
 404     ;;
 405 *freebsd* | dragonfly*)
 406     case "$host_cpu" in
 407     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 408     esac
 409     ;;
 410 esac
 411
 412 AC_ARG_WITH([driver],
 413     [AS_HELP_STRING([--with-driver=DRIVER],
 414         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 415     [mesa_driver="$withval"],
 416     [mesa_driver="$default_driver"])
 417 dnl Check for valid option
 418 case "x$mesa_driver" in
 419 xxlib|xdri|xosmesa)
 420     ;;
 421 *)
 422     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 423     ;;
 424 esac
 425
 426 dnl
 427 dnl Driver specific build directories
 428 dnl
 429
 430 dnl this variable will be prepended to SRC_DIRS and is not exported
 431 CORE_DIRS="glsl mesa"
 432
 433 SRC_DIRS="glew"
 434 GLU_DIRS="sgi"
 435 WINDOW_SYSTEM=""
 436 GALLIUM_DIRS="auxiliary drivers state_trackers"
 437 GALLIUM_WINSYS_DIRS=""
 438 GALLIUM_WINSYS_DRM_DIRS=""
 439 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 440 GALLIUM_STATE_TRACKERS_DIRS=""
 441
 442 case "$mesa_driver" in
 443 xlib)
 444     DRIVER_DIRS="x11"
 445     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 446     ;;
 447 dri)
 448     CORE_DIRS="glx/x11 $CORE_DIRS"
 449     DRIVER_DIRS="dri"
 450     WINDOW_SYSTEM="dri"
 451     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 452     ;;
 453 osmesa)
 454     DRIVER_DIRS="osmesa"
 455     ;;
 456 esac
 457 AC_SUBST([SRC_DIRS])
 458 AC_SUBST([GLU_DIRS])
 459 AC_SUBST([DRIVER_DIRS])
 460 AC_SUBST([WINDOW_SYSTEM])
 461 AC_SUBST([GALLIUM_DIRS])
 462 AC_SUBST([GALLIUM_WINSYS_DIRS])
 463 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 464 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 465 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 466
 467 dnl
 468 dnl User supplied program configuration
 469 dnl
 470 if test -d "$srcdir/progs/demos"; then
 471     default_demos=yes
 472 else
 473     default_demos=no
 474 fi
 475 AC_ARG_WITH([demos],
 476     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 477         [optional comma delimited demo directories to build
 478         @<:@default=auto if source available@:>@])],
 479     [with_demos="$withval"],
 480     [with_demos="$default_demos"])
 481 if test "x$with_demos" = x; then
 482     with_demos=no
 483 fi
 484
 485 dnl If $with_demos is yes, directories will be added as libs available
 486 PROGRAM_DIRS=""
 487 case "$with_demos" in
 488 no) ;;
 489 yes)
 490     # If the driver isn't osmesa, we have libGL and can build xdemos
 491     if test "$mesa_driver" != osmesa; then
 492         PROGRAM_DIRS="xdemos"
 493     fi
 494     ;;
 495 *)
 496     # verify the requested demos directories exist
 497     demos=`IFS=,; echo $with_demos`
 498     for demo in $demos; do
 499         test -d "$srcdir/progs/$demo" || \
 500             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 501     done
 502     PROGRAM_DIRS="$demos"
 503     ;;
 504 esac
 505
 506 dnl
 507 dnl Find out if X is available. The variable have_x is set if libX11 is
 508 dnl found to mimic AC_PATH_XTRA.
 509 dnl
 510 if test -n "$PKG_CONFIG"; then
 511     AC_MSG_CHECKING([pkg-config files for X11 are available])
 512     PKG_CHECK_EXISTS([x11],[
 513         x11_pkgconfig=yes
 514         have_x=yes
 515         ],[
 516         x11_pkgconfig=no
 517     ])
 518     AC_MSG_RESULT([$x11_pkgconfig])
 519 else
 520     x11_pkgconfig=no
 521 fi
 522 dnl Use the autoconf macro if no pkg-config files
 523 if test "$x11_pkgconfig" = no; then
 524     AC_PATH_XTRA
 525 fi
 526
 527 dnl Try to tell the user that the --x-* options are only used when
 528 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 529 m4_divert_once([HELP_BEGIN],
 530 [These options are only used when the X libraries cannot be found by the
 531 pkg-config utility.])
 532
 533 dnl We need X for xlib and dri, so bomb now if it's not found
 534 case "$mesa_driver" in
 535 xlib|dri)
 536     if test "$no_x" = yes; then
 537         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 538     fi
 539     ;;
 540 esac
 541
 542 dnl XCB - this is only used for GLX right now
 543 AC_ARG_ENABLE([xcb],
 544     [AS_HELP_STRING([--enable-xcb],
 545         [use XCB for GLX @<:@default=disabled@:>@])],
 546     [enable_xcb="$enableval"],
 547     [enable_xcb=no])
 548 if test "x$enable_xcb" = xyes; then
 549     DEFINES="$DEFINES -DUSE_XCB"
 550 else
 551     enable_xcb=no
 552 fi
 553
 554 dnl
 555 dnl libGL configuration per driver
 556 dnl
 557 case "$mesa_driver" in
 558 xlib)
 559     if test "$x11_pkgconfig" = yes; then
 560         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 561         GL_PC_REQ_PRIV="x11 xext"
 562         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 563         GL_LIB_DEPS="$XLIBGL_LIBS"
 564     else
 565         # should check these...
 566         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 567         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 568         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 569         GL_PC_CFLAGS="$X11_INCLUDES"
 570     fi
 571     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 572     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 573
 574     # if static, move the external libraries to the programs
 575     # and empty the libraries for libGL
 576     if test "$enable_static" = yes; then
 577         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 578         GL_LIB_DEPS=""
 579     fi
 580     ;;
 581 dri)
 582     # DRI must be shared, I think
 583     if test "$enable_static" = yes; then
 584         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 585     fi
 586
 587     # Check for libdrm
 588     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 589     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 590     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 591     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 592     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 593
 594     # find the DRI deps for libGL
 595     if test "$x11_pkgconfig" = yes; then
 596         # add xcb modules if necessary
 597         dri_modules="x11 xext xxf86vm xdamage xfixes"
 598         if test "$enable_xcb" = yes; then
 599             dri_modules="$dri_modules x11-xcb xcb-glx"
 600         fi
 601
 602         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 603         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 604         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 605         GL_LIB_DEPS="$DRIGL_LIBS"
 606     else
 607         # should check these...
 608         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 609         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 610         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 611         GL_PC_CFLAGS="$X11_INCLUDES"
 612
 613         # XCB can only be used from pkg-config
 614         if test "$enable_xcb" = yes; then
 615             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 616             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 617             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 618             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 619         fi
 620     fi
 621
 622     # need DRM libs, -lpthread, etc.
 623     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 624     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 625     ;;
 626 osmesa)
 627     # No libGL for osmesa
 628     GL_LIB_DEPS=""
 629     ;;
 630 esac
 631 AC_SUBST([GL_LIB_DEPS])
 632 AC_SUBST([GL_PC_REQ_PRIV])
 633 AC_SUBST([GL_PC_LIB_PRIV])
 634 AC_SUBST([GL_PC_CFLAGS])
 635 AC_SUBST([DRI_PC_REQ_PRIV])
 636
 637 dnl
 638 dnl More X11 setup
 639 dnl
 640 if test "$mesa_driver" = xlib; then
 641     DEFINES="$DEFINES -DUSE_XSHM"
 642 fi
 643
 644 dnl
 645 dnl More DRI setup
 646 dnl
 647 AC_ARG_ENABLE([glx-tls],
 648     [AS_HELP_STRING([--enable-glx-tls],
 649         [enable TLS support in GLX @<:@default=disabled@:>@])],
 650     [GLX_USE_TLS="$enableval"],
 651     [GLX_USE_TLS=no])
 652 dnl Directory for DRI drivers
 653 AC_ARG_WITH([dri-driverdir],
 654     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 655         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 656     [DRI_DRIVER_INSTALL_DIR="$withval"],
 657     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 658 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 659 dnl Extra search path for DRI drivers
 660 AC_ARG_WITH([dri-searchpath],
 661     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 662         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 663     [DRI_DRIVER_SEARCH_DIR="$withval"],
 664     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 665 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 666 dnl Direct rendering or just indirect rendering
 667 AC_ARG_ENABLE([driglx-direct],
 668     [AS_HELP_STRING([--disable-driglx-direct],
 669         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 670     [driglx_direct="$enableval"],
 671     [driglx_direct="yes"])
 672 dnl Which drivers to build - default is chosen by platform
 673 AC_ARG_WITH([dri-drivers],
 674     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 675         [comma delimited DRI drivers list, e.g.
 676         "swrast,i965,radeon" @<:@default=auto@:>@])],
 677     [with_dri_drivers="$withval"],
 678     [with_dri_drivers=yes])
 679 if test "x$with_dri_drivers" = x; then
 680     with_dri_drivers=no
 681 fi
 682
 683 dnl If $with_dri_drivers is yes, directories will be added through
 684 dnl platform checks
 685 DRI_DIRS=""
 686 case "$with_dri_drivers" in
 687 no) ;;
 688 yes)
 689     DRI_DIRS="yes"
 690     ;;
 691 *)
 692     # verify the requested driver directories exist
 693     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 694     for driver in $dri_drivers; do
 695         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 696             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 697     done
 698     DRI_DIRS="$dri_drivers"
 699     ;;
 700 esac
 701
 702 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 703 if test "$mesa_driver" = dri; then
 704     # Use TLS in GLX?
 705     if test "x$GLX_USE_TLS" = xyes; then
 706         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 707     fi
 708
 709     # Platform specific settings and drivers to build
 710     case "$host_os" in
 711     linux*)
 712         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 713         if test "x$driglx_direct" = xyes; then
 714             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 715         fi
 716         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 717
 718         case "$host_cpu" in
 719         x86_64)
 720             # ffb, gamma, and sis are missing because they have not be
 721             # converted to use the new interface.  i810 are missing
 722             # because there is no x86-64 system where they could *ever*
 723             # be used.
 724             if test "x$DRI_DIRS" = "xyes"; then
 725                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 726                     savage tdfx unichrome swrast"
 727             fi
 728             ;;
 729         powerpc*)
 730             # Build only the drivers for cards that exist on PowerPC.
 731             # At some point MGA will be added, but not yet.
 732             if test "x$DRI_DIRS" = "xyes"; then
 733                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 734             fi
 735             ;;
 736         sparc*)
 737             # Build only the drivers for cards that exist on sparc`
 738             if test "x$DRI_DIRS" = "xyes"; then
 739                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon ffb swrast"
 740             fi
 741             ;;
 742         esac
 743         ;;
 744     freebsd* | dragonfly*)
 745         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 746         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 747         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 748         if test "x$driglx_direct" = xyes; then
 749             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 750         fi
 751         if test "x$GXX" = xyes; then
 752             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 753         fi
 754
 755         # ffb and gamma are missing because they have not been converted
 756         # to use the new interface.
 757         if test "x$DRI_DIRS" = "xyes"; then
 758             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 759                 unichrome savage sis swrast"
 760         fi
 761         ;;
 762     gnu*)
 763         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 764         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 765         ;;
 766     solaris*)
 767         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 768         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 769         if test "x$driglx_direct" = xyes; then
 770             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 771         fi
 772         ;;
 773     esac
 774
 775     # default drivers
 776     if test "x$DRI_DIRS" = "xyes"; then
 777         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 778             savage sis tdfx unichrome ffb swrast"
 779     fi
 780
 781     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 782
 783     # Check for expat
 784     EXPAT_INCLUDES=""
 785     EXPAT_LIB=-lexpat
 786     AC_ARG_WITH([expat],
 787         [AS_HELP_STRING([--with-expat=DIR],
 788             [expat install directory])],[
 789         EXPAT_INCLUDES="-I$withval/include"
 790         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 791         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 792         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 793         ])
 794     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 795     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 796         [AC_MSG_ERROR([Expat required for DRI.])])
 797
 798     # put all the necessary libs together
 799     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 800 fi
 801 AC_SUBST([DRI_DIRS])
 802 AC_SUBST([EXPAT_INCLUDES])
 803 AC_SUBST([DRI_LIB_DEPS])
 804
 805 case $DRI_DIRS in
 806 *i915*|*i965*)
 807     PKG_CHECK_MODULES([INTEL], [libdrm_intel])
 808     ;;
 809 esac
 810
 811 case $DRI_DIRS in
 812 *radeon*|*r200*|*r300*|*r600*)
 813     PKG_CHECK_MODULES([LIBDRM_RADEON],
 814                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 815                       HAVE_LIBDRM_RADEON=yes,
 816                       HAVE_LIBDRM_RADEON=no)
 817
 818     if test "$HAVE_LIBDRM_RADEON" = yes; then
 819         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 820         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 821     fi
 822     ;;
 823 esac
 824 AC_SUBST([RADEON_CFLAGS])
 825 AC_SUBST([RADEON_LDFLAGS])
 826
 827
 828 dnl
 829 dnl OSMesa configuration
 830 dnl
 831 if test "$mesa_driver" = xlib; then
 832     default_gl_osmesa=yes
 833 else
 834     default_gl_osmesa=no
 835 fi
 836 AC_ARG_ENABLE([gl-osmesa],
 837     [AS_HELP_STRING([--enable-gl-osmesa],
 838         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 839     [gl_osmesa="$enableval"],
 840     [gl_osmesa="$default_gl_osmesa"])
 841 if test "x$gl_osmesa" = xyes; then
 842     if test "$mesa_driver" = osmesa; then
 843         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 844     else
 845         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 846     fi
 847 fi
 848
 849 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 850 AC_ARG_WITH([osmesa-bits],
 851     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 852         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 853     [osmesa_bits="$withval"],
 854     [osmesa_bits=8])
 855 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 856     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 857     osmesa_bits=8
 858 fi
 859 case "x$osmesa_bits" in
 860 x8)
 861     OSMESA_LIB=OSMesa
 862     ;;
 863 x16|x32)
 864     OSMESA_LIB="OSMesa$osmesa_bits"
 865     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 866     ;;
 867 *)
 868     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 869     ;;
 870 esac
 871 AC_SUBST([OSMESA_LIB])
 872
 873 case "$mesa_driver" in
 874 osmesa)
 875     # only link libraries with osmesa if shared
 876     if test "$enable_static" = no; then
 877         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 878     else
 879         OSMESA_LIB_DEPS=""
 880     fi
 881     OSMESA_MESA_DEPS=""
 882     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 883     ;;
 884 *)
 885     # Link OSMesa to libGL otherwise
 886     OSMESA_LIB_DEPS=""
 887     # only link libraries with osmesa if shared
 888     if test "$enable_static" = no; then
 889         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 890     else
 891         OSMESA_MESA_DEPS=""
 892     fi
 893     OSMESA_PC_REQ="gl"
 894     ;;
 895 esac
 896 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 897 AC_SUBST([OSMESA_LIB_DEPS])
 898 AC_SUBST([OSMESA_MESA_DEPS])
 899 AC_SUBST([OSMESA_PC_REQ])
 900 AC_SUBST([OSMESA_PC_LIB_PRIV])
 901
 902 dnl
 903 dnl EGL configuration
 904 dnl
 905 AC_ARG_ENABLE([egl],
 906     [AS_HELP_STRING([--disable-egl],
 907         [disable EGL library @<:@default=enabled@:>@])],
 908     [enable_egl="$enableval"],
 909     [enable_egl=yes])
 910 if test "x$enable_egl" = xyes; then
 911     SRC_DIRS="$SRC_DIRS egl"
 912     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 913     EGL_DRIVERS_DIRS=""
 914     if test "$enable_static" != yes && test "$mesa_driver" != osmesa; then
 915         # build egl_glx when libGL is built
 916         EGL_DRIVERS_DIRS="glx"
 917     fi
 918 fi
 919 AC_SUBST([EGL_LIB_DEPS])
 920 AC_SUBST([EGL_DRIVERS_DIRS])
 921
 922 dnl
 923 dnl GLU configuration
 924 dnl
 925 AC_ARG_ENABLE([glu],
 926     [AS_HELP_STRING([--disable-glu],
 927         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 928     [enable_glu="$enableval"],
 929     [enable_glu=yes])
 930 if test "x$enable_glu" = xyes; then
 931     SRC_DIRS="$SRC_DIRS glu"
 932
 933     case "$mesa_driver" in
 934     osmesa)
 935         # If GLU is available and we have libOSMesa (not 16 or 32),
 936         # we can build the osdemos
 937         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 938             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 939         fi
 940
 941         # Link libGLU to libOSMesa instead of libGL
 942         GLU_LIB_DEPS=""
 943         GLU_PC_REQ="osmesa"
 944         if test "$enable_static" = no; then
 945             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 946         else
 947             GLU_MESA_DEPS=""
 948         fi
 949         ;;
 950     *)
 951         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 952         GLU_PC_REQ="gl"
 953         GLU_PC_LIB_PRIV="-lm"
 954         if test "$enable_static" = no; then
 955             GLU_LIB_DEPS="-lm"
 956             GLU_MESA_DEPS='-l$(GL_LIB)'
 957         else
 958             GLU_LIB_DEPS=""
 959             GLU_MESA_DEPS=""
 960             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 961         fi
 962         ;;
 963     esac
 964 fi
 965 if test "$enable_static" = no; then
 966     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 967 fi
 968 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 969 AC_SUBST([GLU_LIB_DEPS])
 970 AC_SUBST([GLU_MESA_DEPS])
 971 AC_SUBST([GLU_PC_REQ])
 972 AC_SUBST([GLU_PC_REQ_PRIV])
 973 AC_SUBST([GLU_PC_LIB_PRIV])
 974 AC_SUBST([GLU_PC_CFLAGS])
 975
 976 dnl
 977 dnl GLw configuration
 978 dnl
 979 AC_ARG_ENABLE([glw],
 980     [AS_HELP_STRING([--disable-glw],
 981         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 982     [enable_glw="$enableval"],
 983     [enable_glw=yes])
 984 dnl Don't build GLw on osmesa
 985 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 986     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 987     enable_glw=no
 988 fi
 989 AC_ARG_ENABLE([motif],
 990     [AS_HELP_STRING([--enable-motif],
 991         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 992     [enable_motif="$enableval"],
 993     [enable_motif=no])
 994
 995 if test "x$enable_glw" = xyes; then
 996     SRC_DIRS="$SRC_DIRS glw"
 997     if test "$x11_pkgconfig" = yes; then
 998         PKG_CHECK_MODULES([GLW],[x11 xt])
 999         GLW_PC_REQ_PRIV="x11 xt"
1000         GLW_LIB_DEPS="$GLW_LIBS"
1001     else
1002         # should check these...
1003         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1004         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1005         GLW_PC_CFLAGS="$X11_INCLUDES"
1006     fi
1007
1008     GLW_SOURCES="GLwDrawA.c"
1009     MOTIF_CFLAGS=
1010     if test "x$enable_motif" = xyes; then
1011         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1012         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1013         if test "x$MOTIF_CONFIG" != xno; then
1014             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1015             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1016         else
1017             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1018                 [AC_MSG_ERROR([Can't locate Motif headers])])
1019             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1020                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1021         fi
1022         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1023         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1024         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1025         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1026     fi
1027
1028     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1029     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1030     if test "$enable_static" = no; then
1031         GLW_MESA_DEPS='-l$(GL_LIB)'
1032         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1033     else
1034         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1035         GLW_LIB_DEPS=""
1036         GLW_MESA_DEPS=""
1037     fi
1038 fi
1039 AC_SUBST([GLW_LIB_DEPS])
1040 AC_SUBST([GLW_MESA_DEPS])
1041 AC_SUBST([GLW_SOURCES])
1042 AC_SUBST([MOTIF_CFLAGS])
1043 AC_SUBST([GLW_PC_REQ_PRIV])
1044 AC_SUBST([GLW_PC_LIB_PRIV])
1045 AC_SUBST([GLW_PC_CFLAGS])
1046
1047 dnl
1048 dnl GLUT configuration
1049 dnl
1050 if test -f "$srcdir/include/GL/glut.h"; then
1051     default_glut=yes
1052 else
1053     default_glut=no
1054 fi
1055 AC_ARG_ENABLE([glut],
1056     [AS_HELP_STRING([--disable-glut],
1057         [enable GLUT library @<:@default=enabled if source available@:>@])],
1058     [enable_glut="$enableval"],
1059     [enable_glut="$default_glut"])
1060
1061 dnl Can't build glut if GLU not available
1062 if test "x$enable_glu$enable_glut" = xnoyes; then
1063     AC_MSG_WARN([Disabling glut since GLU is disabled])
1064     enable_glut=no
1065 fi
1066 dnl Don't build glut on osmesa
1067 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1068     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1069     enable_glut=no
1070 fi
1071
1072 if test "x$enable_glut" = xyes; then
1073     SRC_DIRS="$SRC_DIRS glut/glx"
1074     GLUT_CFLAGS=""
1075     if test "x$GCC" = xyes; then
1076         GLUT_CFLAGS="-fexceptions"
1077     fi
1078     if test "$x11_pkgconfig" = yes; then
1079         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1080         GLUT_PC_REQ_PRIV="x11 xmu xi"
1081         GLUT_LIB_DEPS="$GLUT_LIBS"
1082     else
1083         # should check these...
1084         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1085         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1086         GLUT_PC_CFLAGS="$X11_INCLUDES"
1087     fi
1088     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1089     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1090
1091     # If glut is available, we can build most programs
1092     if test "$with_demos" = yes; then
1093         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1094     fi
1095
1096     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1097     if test "$enable_static" = no; then
1098         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1099     else
1100         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1101         GLUT_LIB_DEPS=""
1102         GLUT_MESA_DEPS=""
1103     fi
1104 fi
1105 AC_SUBST([GLUT_LIB_DEPS])
1106 AC_SUBST([GLUT_MESA_DEPS])
1107 AC_SUBST([GLUT_CFLAGS])
1108 AC_SUBST([GLUT_PC_REQ_PRIV])
1109 AC_SUBST([GLUT_PC_LIB_PRIV])
1110 AC_SUBST([GLUT_PC_CFLAGS])
1111
1112 dnl
1113 dnl Program library dependencies
1114 dnl    Only libm is added here if necessary as the libraries should
1115 dnl    be pulled in by the linker
1116 dnl
1117 if test "x$APP_LIB_DEPS" = x; then
1118     case "$host_os" in
1119     solaris*)
1120         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1121         ;;
1122     cygwin*)
1123         APP_LIB_DEPS="-lX11"
1124         ;;
1125     *)
1126         APP_LIB_DEPS="-lm"
1127         ;;
1128     esac
1129 fi
1130 AC_SUBST([APP_LIB_DEPS])
1131 AC_SUBST([PROGRAM_DIRS])
1132
1133 dnl
1134 dnl Gallium configuration
1135 dnl
1136 AC_ARG_ENABLE([gallium],
1137     [AS_HELP_STRING([--disable-gallium],
1138         [build gallium @<:@default=enabled@:>@])],
1139     [enable_gallium="$enableval"],
1140     [enable_gallium=yes])
1141 if test "x$enable_gallium" = xyes; then
1142     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1143 fi
1144
1145 dnl
1146 dnl Gallium state trackers configuration
1147 dnl
1148 AC_ARG_WITH([state-trackers],
1149     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1150         [comma delimited state_trackers list, e.g.
1151         "egl,glx" @<:@default=auto@:>@])],
1152     [with_state_trackers="$withval"],
1153     [with_state_trackers=yes])
1154
1155 case "$with_state_trackers" in
1156 no)
1157     GALLIUM_STATE_TRACKERS_DIRS=""
1158     ;;
1159 yes)
1160     # look at what else is built
1161     case "$mesa_driver" in
1162     xlib)
1163         GALLIUM_STATE_TRACKERS_DIRS=glx
1164         ;;
1165     dri)
1166         GALLIUM_STATE_TRACKERS_DIRS="dri"
1167         if test "x$enable_egl" = xyes; then
1168             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1169         fi
1170         # Have only tested st/xorg on 1.6.0 servers
1171         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0],
1172             HAVE_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1173             HAVE_XORG="no")
1174         ;;
1175     esac
1176     ;;
1177 *)
1178     # verify the requested state tracker exist
1179     state_trackers=`IFS=', '; echo $with_state_trackers`
1180     for tracker in $state_trackers; do
1181         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1182             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1183
1184         case "$tracker" in
1185         egl)
1186             if test "x$enable_egl" != xyes; then
1187                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1188             fi
1189             ;;
1190         xorg)
1191             PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1192                   HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1193                   HAVE_XEXTPROTO_71="no")
1194             ;;
1195         es)
1196             # mesa/es is required to build es state tracker
1197             CORE_DIRS="$CORE_DIRS mesa/es"
1198             ;;
1199         esac
1200     done
1201     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1202     ;;
1203 esac
1204
1205 AC_ARG_WITH([egl-displays],
1206     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1207         [comma delimited native displays libEGL supports, e.g.
1208         "x11,kms" @<:@default=auto@:>@])],
1209     [with_egl_displays="$withval"],
1210     [with_egl_displays=yes])
1211
1212 EGL_DISPLAYS=""
1213 case "$with_egl_displays" in
1214 yes)
1215     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1216         EGL_DISPLAYS="x11"
1217     fi
1218     ;;
1219 *)
1220     if test "x$enable_egl" != xyes; then
1221         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1222     fi
1223     # verify the requested driver directories exist
1224     egl_displays=`IFS=', '; echo $with_egl_displays`
1225     for dpy in $egl_displays; do
1226         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1227             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1228     done
1229     EGL_DISPLAYS="$egl_displays"
1230     ;;
1231 esac
1232 AC_SUBST([EGL_DISPLAYS])
1233
1234 AC_ARG_WITH([xorg-driver-dir],
1235     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1236                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1237     [XORG_DRIVER_INSTALL_DIR="$withval"],
1238     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1239 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1240
1241 AC_ARG_WITH([max-width],
1242     [AS_HELP_STRING([--with-max-width=N],
1243                     [Maximum framebuffer width (4096)])],
1244     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1245      AS_IF([test "${withval}" -gt "4096"],
1246            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1247 )
1248 AC_ARG_WITH([max-height],
1249     [AS_HELP_STRING([--with-max-height=N],
1250                     [Maximum framebuffer height (4096)])],
1251     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1252      AS_IF([test "${withval}" -gt "4096"],
1253            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1254 )
1255
1256 dnl
1257 dnl Gallium SVGA configuration
1258 dnl
1259 AC_ARG_ENABLE([gallium-svga],
1260     [AS_HELP_STRING([--enable-gallium-svga],
1261         [build gallium SVGA @<:@default=disabled@:>@])],
1262     [enable_gallium_svga="$enableval"],
1263     [enable_gallium_svga=auto])
1264 if test "x$enable_gallium_svga" = xyes; then
1265     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS vmware"
1266     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1267 elif test "x$enable_gallium_svga" = xauto; then
1268     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1269 fi
1270
1271 dnl
1272 dnl Gallium Intel configuration
1273 dnl
1274 AC_ARG_ENABLE([gallium-intel],
1275     [AS_HELP_STRING([--enable-gallium-intel],
1276         [build gallium intel @<:@default=disabled@:>@])],
1277     [enable_gallium_intel="$enableval"],
1278     [enable_gallium_intel=auto])
1279 if test "x$enable_gallium_intel" = xyes; then
1280     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel i965"
1281     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1282 elif test "x$enable_gallium_intel" = xauto; then
1283     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1284 fi
1285
1286 dnl
1287 dnl Gallium Radeon configuration
1288 dnl
1289 AC_ARG_ENABLE([gallium-radeon],
1290     [AS_HELP_STRING([--enable-gallium-radeon],
1291         [build gallium radeon @<:@default=disabled@:>@])],
1292     [enable_gallium_radeon="$enableval"],
1293     [enable_gallium_radeon=auto])
1294 if test "x$enable_gallium_radeon" = xyes; then
1295     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1296     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1297 elif test "x$enable_gallium_radeon" = xauto; then
1298     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1299 fi
1300
1301 dnl
1302 dnl Gallium Nouveau configuration
1303 dnl
1304 AC_ARG_ENABLE([gallium-nouveau],
1305     [AS_HELP_STRING([--enable-gallium-nouveau],
1306         [build gallium nouveau @<:@default=disabled@:>@])],
1307     [enable_gallium_nouveau="$enableval"],
1308     [enable_gallium_nouveau=no])
1309 if test "x$enable_gallium_nouveau" = xyes; then
1310     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1311     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv04 nv10 nv20 nv30 nv40 nv50"
1312 fi
1313
1314 dnl
1315 dnl Gallium swrast configuration
1316 dnl
1317 AC_ARG_ENABLE([gallium-swrast],
1318     [AS_HELP_STRING([--enable-gallium-swrast],
1319         [build gallium swrast @<:@default=disabled@:>@])],
1320     [enable_gallium_swrast="$enableval"],
1321     [enable_gallium_swrast=auto])
1322 if test "x$enable_gallium_swrast" = xyes; then
1323     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS swrast"
1324 fi
1325
1326 dnl prepend CORE_DIRS to SRC_DIRS
1327 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1328
1329 dnl Restore LDFLAGS and CPPFLAGS
1330 LDFLAGS="$_SAVE_LDFLAGS"
1331 CPPFLAGS="$_SAVE_CPPFLAGS"
1332
1333 dnl Substitute the config
1334 AC_CONFIG_FILES([configs/autoconf])
1335
1336 dnl Replace the configs/current symlink
1337 AC_CONFIG_COMMANDS([configs],[
1338 if test -f configs/current || test -L configs/current; then
1339     rm -f configs/current
1340 fi
1341 ln -s autoconf configs/current
1342 ])
1343
1344 AC_OUTPUT
1345
1346 dnl
1347 dnl Output some configuration info for the user
1348 dnl
1349 echo ""
1350 echo "        prefix:          $prefix"
1351 echo "        exec_prefix:     $exec_prefix"
1352 echo "        libdir:          $libdir"
1353 echo "        includedir:      $includedir"
1354
1355 dnl Driver info
1356 echo ""
1357 echo "        Driver:          $mesa_driver"
1358 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1359     echo "        OSMesa:          lib$OSMESA_LIB"
1360 else
1361     echo "        OSMesa:          no"
1362 fi
1363 if test "$mesa_driver" = dri; then
1364     # cleanup the drivers var
1365     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1366 if test "x$DRI_DIRS" = x; then
1367     echo "        DRI drivers:     no"
1368 else
1369     echo "        DRI drivers:     $dri_dirs"
1370 fi
1371     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1372 fi
1373 echo "        Use XCB:         $enable_xcb"
1374
1375 echo ""
1376 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1377     echo "        Gallium:         yes"
1378     echo "        Gallium dirs:    $GALLIUM_DIRS"
1379     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1380     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1381     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1382     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1383 else
1384     echo "        Gallium:         no"
1385 fi
1386
1387 dnl Libraries
1388 echo ""
1389 echo "        Shared libs:     $enable_shared"
1390 echo "        Static libs:     $enable_static"
1391 echo "        EGL:             $enable_egl"
1392 echo "        GLU:             $enable_glu"
1393 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1394 echo "        glut:            $enable_glut"
1395
1396 dnl Programs
1397 # cleanup the programs var for display
1398 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1399 if test "x$program_dirs" = x; then
1400     echo "        Demos:           no"
1401 else
1402     echo "        Demos:           $program_dirs"
1403 fi
1404
1405 dnl Compiler options
1406 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1407 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1408     $SED 's/^ *//;s/  */ /;s/ *$//'`
1409 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1410     $SED 's/^ *//;s/  */ /;s/ *$//'`
1411 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1412 echo ""
1413 echo "        CFLAGS:          $cflags"
1414 echo "        CXXFLAGS:        $cxxflags"
1415 echo "        Macros:          $defines"
1416
1417 echo ""
1418 echo "        Run '${MAKE-make}' to build Mesa"
1419 echo ""