configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.79
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.8
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 842 dnl project. Even then there's a notable issue as described in the project README
 843 case "$host_os" in
 844 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 845     pthread_stubs_possible="no"
 846     ;;
 847 * )
 848     pthread_stubs_possible="yes"
 849     ;;
 850 esac
 851
 852 if test "x$pthread_stubs_possible" = xyes; then
 853     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 854     AC_SUBST(PTHREADSTUBS_CFLAGS)
 855     AC_SUBST(PTHREADSTUBS_LIBS)
 856 fi
 857
 858 dnl SELinux awareness.
 859 AC_ARG_ENABLE([selinux],
 860     [AS_HELP_STRING([--enable-selinux],
 861         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 862     [MESA_SELINUX="$enableval"],
 863     [MESA_SELINUX=no])
 864 if test "x$enable_selinux" = "xyes"; then
 865     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 866         [AC_CHECK_HEADER([selinux/selinux.h],[],
 867                          [AC_MSG_ERROR([SELinux headers not found])])
 868          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 869                       [AC_MSG_ERROR([SELinux library not found])])
 870          SELINUX_LIBS="-lselinux"])
 871     DEFINES="$DEFINES -DMESA_SELINUX"
 872 fi
 873 AC_SUBST([SELINUX_CFLAGS])
 874 AC_SUBST([SELINUX_LIBS])
 875
 876 dnl
 877 dnl LLVM
 878 dnl
 879 AC_ARG_ENABLE([llvm-shared-libs],
 880     [AS_HELP_STRING([--enable-llvm-shared-libs],
 881         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 882     [enable_llvm_shared_libs="$enableval"],
 883     [enable_llvm_shared_libs=yes])
 884
 885 AC_ARG_WITH([llvm-prefix],
 886     [AS_HELP_STRING([--with-llvm-prefix],
 887         [Prefix for LLVM installations in non-standard locations])],
 888     [llvm_prefix="$withval"],
 889     [llvm_prefix=''])
 890
 891 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 892 if test "x$have_libelf" = xno; then
 893    LIBELF_LIBS=''
 894    LIBELF_CFLAGS=''
 895    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 896    AC_SUBST([LIBELF_LIBS])
 897    AC_SUBST([LIBELF_CFLAGS])
 898 fi
 899
 900 if test -z "$LLVM_CONFIG"; then
 901     if test -n "$llvm_prefix"; then
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 903     else
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 905     fi
 906 fi
 907
 908 llvm_add_component() {
 909     new_llvm_component=$1
 910     driver_name=$2
 911
 912     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 913         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 914     else
 915         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 916     fi
 917 }
 918
 919 llvm_add_default_components() {
 920     driver_name=$1
 921
 922     # Required default components
 923     llvm_add_component "bitwriter" $driver_name
 924     llvm_add_component "engine" $driver_name
 925     llvm_add_component "mcdisassembler" $driver_name
 926     llvm_add_component "mcjit" $driver_name
 927
 928     # Optional default components
 929     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 930         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 931     fi
 932 }
 933
 934 llvm_add_target() {
 935     new_llvm_target=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 939         llvm_add_component $new_llvm_target $driver_name
 940     else
 941         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 # Call this inside ` ` to get the return value.
 946 # $1 is the llvm-config command with arguments.
 947 strip_unwanted_llvm_flags() {
 948     echo " `$1` " | sed -E \
 949         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 950         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 951         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 952         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 954         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 956         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 957         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 958         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 959         -e 's/^[[[:space:]]]//' \
 960         -e 's/[[[:space:]]]$//'
 961 }
 962
 963 llvm_set_environment_variables() {
 964     if test "x$LLVM_CONFIG" != xno; then
 965         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 966         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 967         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 968         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 969
 970         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 971         save_CFLAGS="$CFLAGS"
 972         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 973
 974         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 975             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 976         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980
 981         CFLAGS="$save_CFLAGS"
 982
 983         # Only needed for LLVM < 3.6.0
 984         if test -z "$LLVM_VERSION_PATCH"; then
 985             LLVM_VERSION_PATCH=0
 986         fi
 987
 988         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 989
 990         FOUND_LLVM=yes
 991     else
 992         FOUND_LLVM=no
 993         LLVM_VERSION_INT=0
 994     fi
 995 }
 996
 997 require_llvm() {
 998     if test "x$enable_llvm" != "xyes"; then
 999         AC_MSG_ERROR([--enable-llvm is required when building $1])
1000     fi
1001 }
1002
1003 llvm_require_version() {
1004     require_llvm $2
1005
1006     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1007     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1008     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1009
1010     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1011         # major > required major
1012         #  --> OK
1013         return
1014     fi
1015
1016     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1017         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1018             # major = required major and
1019             # minor > required minor
1020             #  --> OK
1021             return
1022         else
1023             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1024                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1025                     # major = required major and
1026                     # minor = required minor and
1027                     # patch >= required patch
1028                     #  --> OK
1029                     return
1030                 fi
1031             fi
1032         fi
1033     fi
1034
1035     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1036 }
1037
1038 radeon_llvm_check() {
1039     if test ${LLVM_VERSION_INT} -lt 307; then
1040         amdgpu_llvm_target_name='r600'
1041     else
1042         amdgpu_llvm_target_name='amdgpu'
1043     fi
1044
1045     llvm_require_version $*
1046
1047     llvm_add_target $amdgpu_llvm_target_name $2
1048
1049     llvm_add_default_components $2
1050     llvm_add_component "bitreader" $2
1051     llvm_add_component "ipo" $2
1052
1053     if test "x$have_libelf" != xyes; then
1054        AC_MSG_ERROR([$2 requires libelf when using llvm])
1055     fi
1056 }
1057
1058 llvm_set_environment_variables
1059
1060 AC_SUBST([LLVM_CFLAGS])
1061 AC_SUBST([LLVM_CXXFLAGS])
1062 AC_SUBST([LLVM_LIBS])
1063 AC_SUBST([LLVM_LDFLAGS])
1064 AC_SUBST([LLVM_INCLUDEDIR])
1065
1066 dnl
1067 dnl libunwind
1068 dnl
1069 AC_ARG_ENABLE([libunwind],
1070     [AS_HELP_STRING([--enable-libunwind],
1071             [Use libunwind for backtracing (default: auto)])],
1072         [LIBUNWIND="$enableval"],
1073         [LIBUNWIND="auto"])
1074
1075 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1076 if test "x$LIBUNWIND" = "xauto"; then
1077     LIBUNWIND="$HAVE_LIBUNWIND"
1078 fi
1079
1080 if test "x$LIBUNWIND" = "xyes"; then
1081     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1082     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1083 fi
1084
1085
1086 dnl Options for APIs
1087 AC_ARG_ENABLE([opengl],
1088     [AS_HELP_STRING([--disable-opengl],
1089         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1090     [enable_opengl="$enableval"],
1091     [enable_opengl=yes])
1092 AC_ARG_ENABLE([gles1],
1093     [AS_HELP_STRING([--disable-gles1],
1094         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1095     [enable_gles1="$enableval"],
1096     [enable_gles1=yes])
1097 AC_ARG_ENABLE([gles2],
1098     [AS_HELP_STRING([--disable-gles2],
1099         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1100     [enable_gles2="$enableval"],
1101     [enable_gles2=yes])
1102
1103 AC_ARG_ENABLE([dri],
1104     [AS_HELP_STRING([--enable-dri],
1105         [enable DRI modules @<:@default=enabled@:>@])],
1106     [enable_dri="$enableval"],
1107     [enable_dri=yes])
1108
1109 AC_ARG_ENABLE([gallium-extra-hud],
1110     [AS_HELP_STRING([--enable-gallium-extra-hud],
1111         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1112     [enable_gallium_extra_hud="$enableval"],
1113     [enable_gallium_extra_hud=no])
1114 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1115 if test "x$enable_gallium_extra_hud" = xyes ; then
1116     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1117 fi
1118
1119 #TODO: no pkgconfig .pc available for libsensors.
1120 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1121 AC_ARG_ENABLE([lmsensors],
1122     [AS_HELP_STRING([--enable-lmsensors],
1123         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1124     [enable_lmsensors="$enableval"],
1125     [enable_lmsensors=no])
1126 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1127 if test "x$enable_lmsensors" = xyes ; then
1128     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1129     LIBSENSORS_LIBS="-lsensors"
1130 else
1131     LIBSENSORS_LIBS=""
1132 fi
1133 AC_SUBST(LIBSENSORS_LIBS)
1134
1135 case "$host_os" in
1136 linux*)
1137     dri3_default=yes
1138     ;;
1139 *)
1140     dri3_default=no
1141     ;;
1142 esac
1143
1144 if test "x$enable_dri" = xno; then
1145     dri3_default=no
1146 fi
1147
1148 AC_ARG_ENABLE([dri3],
1149     [AS_HELP_STRING([--enable-dri3],
1150         [enable DRI3 @<:@default=auto@:>@])],
1151     [enable_dri3="$enableval"],
1152     [enable_dri3="$dri3_default"])
1153 AC_ARG_ENABLE([glx],
1154     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1155         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1156     [enable_glx="$enableval"],
1157     [enable_glx=yes])
1158 AC_ARG_ENABLE([osmesa],
1159     [AS_HELP_STRING([--enable-osmesa],
1160         [enable OSMesa library @<:@default=disabled@:>@])],
1161     [enable_osmesa="$enableval"],
1162     [enable_osmesa=no])
1163 AC_ARG_ENABLE([gallium-osmesa],
1164     [AS_HELP_STRING([--enable-gallium-osmesa],
1165         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1166     [enable_gallium_osmesa="$enableval"],
1167     [enable_gallium_osmesa=no])
1168 AC_ARG_ENABLE([egl],
1169     [AS_HELP_STRING([--disable-egl],
1170         [disable EGL library @<:@default=enabled@:>@])],
1171     [enable_egl="$enableval"],
1172     [enable_egl=yes])
1173
1174 AC_ARG_ENABLE([xa],
1175     [AS_HELP_STRING([--enable-xa],
1176         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1177     [enable_xa="$enableval"],
1178     [enable_xa=no])
1179 AC_ARG_ENABLE([gbm],
1180    [AS_HELP_STRING([--enable-gbm],
1181          [enable gbm library @<:@default=yes except cygwin@:>@])],
1182    [enable_gbm="$enableval"],
1183    [case "$host_os" in
1184        cygwin*)
1185           enable_gbm=no
1186           ;;
1187        *)
1188           enable_gbm=yes
1189           ;;
1190     esac])
1191 AC_ARG_ENABLE([nine],
1192     [AS_HELP_STRING([--enable-nine],
1193         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1194     [enable_nine="$enableval"],
1195     [enable_nine=no])
1196
1197 AC_ARG_ENABLE([xvmc],
1198    [AS_HELP_STRING([--enable-xvmc],
1199          [enable xvmc library @<:@default=auto@:>@])],
1200    [enable_xvmc="$enableval"],
1201    [enable_xvmc=auto])
1202 AC_ARG_ENABLE([vdpau],
1203    [AS_HELP_STRING([--enable-vdpau],
1204          [enable vdpau library @<:@default=auto@:>@])],
1205    [enable_vdpau="$enableval"],
1206    [enable_vdpau=auto])
1207 AC_ARG_ENABLE([omx],
1208    [AS_HELP_STRING([--enable-omx],
1209          [enable OpenMAX library @<:@default=disabled@:>@])],
1210    [enable_omx="$enableval"],
1211    [enable_omx=no])
1212 AC_ARG_ENABLE([va],
1213    [AS_HELP_STRING([--enable-va],
1214          [enable va library @<:@default=auto@:>@])],
1215    [enable_va="$enableval"],
1216    [enable_va=auto])
1217 AC_ARG_ENABLE([opencl],
1218    [AS_HELP_STRING([--enable-opencl],
1219          [enable OpenCL library @<:@default=disabled@:>@])],
1220    [enable_opencl="$enableval"],
1221    [enable_opencl=no])
1222 AC_ARG_ENABLE([opencl_icd],
1223    [AS_HELP_STRING([--enable-opencl-icd],
1224           [Build an OpenCL ICD library to be loaded by an ICD implementation
1225            @<:@default=disabled@:>@])],
1226     [enable_opencl_icd="$enableval"],
1227     [enable_opencl_icd=no])
1228
1229 AC_ARG_ENABLE([gallium-tests],
1230     [AS_HELP_STRING([--enable-gallium-tests],
1231         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1232     [enable_gallium_tests="$enableval"],
1233     [enable_gallium_tests=no])
1234
1235 # Option for Gallium drivers
1236
1237 # Keep this in sync with the --with-gallium-drivers help string default value
1238 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1239
1240 AC_ARG_WITH([gallium-drivers],
1241     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1242         [comma delimited Gallium drivers list, e.g.
1243         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1244         @<:@default=r300,r600,svga,swrast@:>@])],
1245     [with_gallium_drivers="$withval"],
1246     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1247
1248 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1249 # here so that the script doesn't choke on an unknown driver name later.
1250 case "$with_gallium_drivers" in
1251     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1252     no) with_gallium_drivers='' ;;
1253 esac
1254
1255 if test "x$enable_opengl" = xno -a \
1256         "x$enable_gles1" = xno -a \
1257         "x$enable_gles2" = xno -a \
1258         "x$enable_nine" = xno -a \
1259         "x$enable_xa" = xno -a \
1260         "x$enable_xvmc" = xno -a \
1261         "x$enable_vdpau" = xno -a \
1262         "x$enable_omx" = xno -a \
1263         "x$enable_va" = xno -a \
1264         "x$enable_opencl" = xno; then
1265     AC_MSG_ERROR([at least one API should be enabled])
1266 fi
1267
1268 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1269 if test "x$enable_opengl" = xno -a \
1270         "x$enable_gles1" = xyes; then
1271     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1272 fi
1273
1274 if test "x$enable_opengl" = xno -a \
1275         "x$enable_gles2" = xyes; then
1276     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1277 fi
1278
1279 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1280 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1282 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1283                                         "x$enable_gles1" = xyes -o \
1284                                         "x$enable_gles2" = xyes)
1285
1286 # Validate GLX options
1287 if test "x$enable_glx" = xyes; then
1288     if test "x$enable_dri" = xyes; then
1289         enable_glx=dri
1290     elif test -n "$with_gallium_drivers"; then
1291         enable_glx=gallium-xlib
1292     else
1293         enable_glx=xlib
1294     fi
1295 fi
1296 case "x$enable_glx" in
1297 xdri | xxlib | xgallium-xlib)
1298     # GLX requires OpenGL
1299     if test "x$enable_opengl" = xno; then
1300         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1301     fi
1302
1303     # Check individual dependencies
1304     case "x$enable_glx" in
1305     xdri)
1306         if test "x$enable_dri" = xno; then
1307             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1308         fi
1309         ;;
1310     xxlib)
1311         if test "x$enable_dri" = xyes; then
1312             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1313         fi
1314         ;;
1315     xgallium-xlib )
1316         if test "x$enable_dri" = xyes; then
1317             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1318         fi
1319         if test -z "$with_gallium_drivers"; then
1320             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1321         fi
1322         ;;
1323     esac
1324     ;;
1325 xno)
1326     ;;
1327 *)
1328     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1329     ;;
1330 esac
1331
1332 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1333 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1334 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1335 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1336
1337 DEFAULT_GL_LIB_NAME=GL
1338
1339 dnl
1340 dnl Libglvnd configuration
1341 dnl
1342 AC_ARG_ENABLE([libglvnd],
1343     [AS_HELP_STRING([--enable-libglvnd],
1344         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1345     [enable_libglvnd="$enableval"],
1346     [enable_libglvnd=no])
1347 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1348
1349 if test "x$enable_libglvnd" = xyes ; then
1350     dnl XXX: update once we can handle more than libGL/glx.
1351     dnl Namely: we should error out if neither of the glvnd enabled libraries
1352     dnl are built
1353     case "x$enable_glx" in
1354     xno)
1355         AC_MSG_ERROR([cannot build libglvnd without GLX])
1356         ;;
1357     xxlib | xgallium-xlib )
1358         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1359         ;;
1360     xdri)
1361         ;;
1362     esac
1363
1364     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1365     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1366     AC_SUBST([LIBGLVND_DATADIR])
1367
1368     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1369     DEFAULT_GL_LIB_NAME=GLX_mesa
1370 fi
1371
1372 AC_ARG_WITH([gl-lib-name],
1373   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1374     [specify GL library name @<:@default=GL@:>@])],
1375   [GL_LIB=$withval],
1376   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1377 AC_ARG_WITH([osmesa-lib-name],
1378   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1379     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1380   [OSMESA_LIB=$withval],
1381   [OSMESA_LIB=OSMesa])
1382 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1383 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1384
1385 dnl
1386 dnl Mangled Mesa support
1387 dnl
1388 AC_ARG_ENABLE([mangling],
1389   [AS_HELP_STRING([--enable-mangling],
1390     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1391   [enable_mangling="${enableval}"],
1392   [enable_mangling=no]
1393 )
1394 if test "x${enable_mangling}" = "xyes" ; then
1395   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1396   GL_LIB="Mangled${GL_LIB}"
1397   OSMESA_LIB="Mangled${OSMESA_LIB}"
1398 fi
1399 AC_SUBST([GL_LIB])
1400 AC_SUBST([OSMESA_LIB])
1401
1402 # Check for libdrm
1403 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1404                   [have_libdrm=yes], [have_libdrm=no])
1405 if test "x$have_libdrm" = xyes; then
1406         DEFINES="$DEFINES -DHAVE_LIBDRM"
1407 fi
1408
1409 require_libdrm() {
1410     if test "x$have_libdrm" != xyes; then
1411        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1412     fi
1413 }
1414
1415
1416 # Select which platform-dependent DRI code gets built
1417 case "$host_os" in
1418 darwin*)
1419     dri_platform='apple' ;;
1420 cygwin*)
1421     dri_platform='windows' ;;
1422 gnu*)
1423     dri_platform='none' ;;
1424 *)
1425     dri_platform='drm' ;;
1426 esac
1427
1428 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1429     have_drisw_kms='yes'
1430 fi
1431
1432 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1433 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1434 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1435 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1436 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1437 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1438 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1439 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1440 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1441
1442 AC_ARG_ENABLE([shared-glapi],
1443     [AS_HELP_STRING([--enable-shared-glapi],
1444         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1445     [enable_shared_glapi="$enableval"],
1446     [enable_shared_glapi=yes])
1447
1448 case "x$enable_opengl$enable_gles1$enable_gles2" in
1449 x*yes*yes*)
1450     if test "x$enable_shared_glapi" = xno; then
1451         AC_MSG_ERROR([shared GLAPI required when building two or more of
1452                       the following APIs - opengl, gles1 gles2])
1453     fi
1454     ;;
1455 esac
1456
1457 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1458
1459 # Build the pipe-drivers as separate libraries/modules.
1460 # Do not touch this unless you know what you are doing.
1461 # XXX: Expose via configure option ?
1462 enable_shared_pipe_drivers=no
1463
1464 dnl
1465 dnl Driver specific build directories
1466 dnl
1467
1468 if test "x$enable_gallium_osmesa" = xyes; then
1469     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1470         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1471     fi
1472     if test "x$enable_osmesa" = xyes; then
1473         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1474     fi
1475 fi
1476
1477 require_dri_shared_libs_and_glapi() {
1478     if test "x$enable_static" = xyes; then
1479         AC_MSG_ERROR([$1 cannot be build as static library])
1480     fi
1481
1482     if test "x$enable_dri" != xyes; then
1483         # There is only a single backend which won't be build/used otherwise.
1484         # XXX: Revisit this as the egl/haiku is a thing.
1485         AC_MSG_ERROR([$1 requires --enable-dri])
1486     fi
1487
1488     if test "x$enable_shared_glapi" != xyes; then
1489         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1490     fi
1491 }
1492
1493 if test "x$enable_dri" = xyes; then
1494     require_dri_shared_libs_and_glapi "DRI"
1495
1496     # not a hard requirement as swrast does not depend on it
1497     if test "x$have_libdrm" = xyes; then
1498         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1499     fi
1500 fi
1501
1502 AC_ARG_ENABLE([driglx-direct],
1503     [AS_HELP_STRING([--disable-driglx-direct],
1504         [disable direct rendering in GLX and EGL for DRI \
1505             @<:@default=auto@:>@])],
1506     [driglx_direct="$enableval"],
1507     [driglx_direct="yes"])
1508
1509 dnl
1510 dnl libGL configuration per driver
1511 dnl
1512 if test "x$enable_glx" != xno; then
1513     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1514 fi
1515 case "x$enable_glx" in
1516 xxlib | xgallium-xlib)
1517     # Xlib-based GLX
1518     dri_modules="x11 xext xcb"
1519     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1520     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1521     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1522     GL_LIB_DEPS="$XLIBGL_LIBS"
1523     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1524     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1525     ;;
1526 xdri)
1527     # DRI-based GLX
1528
1529     # find the DRI deps for libGL
1530     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1531
1532     if test x"$driglx_direct" = xyes; then
1533         if test x"$dri_platform" = xdrm ; then
1534             DEFINES="$DEFINES -DGLX_USE_DRM"
1535             require_libdrm "Direct rendering"
1536
1537             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1538             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1539             if test x"$enable_dri" = xyes; then
1540                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1541             fi
1542
1543             if test x"$enable_dri3" = xyes; then
1544                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1545                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1546                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1547             fi
1548         fi
1549         if test x"$dri_platform" = xapple ; then
1550             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1551         fi
1552         if test x"$dri_platform" = xwindows ; then
1553             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1554         fi
1555     fi
1556
1557     # add xf86vidmode if available
1558     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1559     if test "$HAVE_XF86VIDMODE" = yes ; then
1560         dri_modules="$dri_modules xxf86vm"
1561     fi
1562
1563     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1564     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1565     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1566     GL_LIB_DEPS="$DRIGL_LIBS"
1567
1568     # need DRM libs, $PTHREAD_LIBS, etc.
1569     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1570     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1571     ;;
1572 esac
1573
1574 # This is outside the case (above) so that it is invoked even for non-GLX
1575 # builds.
1576 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1577
1578 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1579 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1580 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1581 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1582
1583 AC_SUBST([X11_INCLUDES])
1584 AC_SUBST([GL_LIB_DEPS])
1585 AC_SUBST([GL_PC_REQ_PRIV])
1586 AC_SUBST([GL_PC_LIB_PRIV])
1587 AC_SUBST([GL_PC_CFLAGS])
1588 AC_SUBST([DRI_PC_REQ_PRIV])
1589 AC_SUBST([GLESv1_CM_LIB_DEPS])
1590 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1591 AC_SUBST([GLESv2_LIB_DEPS])
1592 AC_SUBST([GLESv2_PC_LIB_PRIV])
1593
1594 AC_SUBST([HAVE_XF86VIDMODE])
1595
1596 dnl
1597 dnl More GLX setup
1598 dnl
1599 case "x$enable_glx" in
1600 xxlib | xgallium-xlib)
1601     DEFINES="$DEFINES -DUSE_XSHM"
1602     ;;
1603 xdri)
1604     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1605     if test "x$driglx_direct" = xyes; then
1606         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1607     fi
1608     ;;
1609 esac
1610
1611 dnl
1612 dnl TLS detection
1613 dnl
1614
1615 AC_ARG_ENABLE([glx-tls],
1616     [AS_HELP_STRING([--enable-glx-tls],
1617         [enable TLS support in GLX @<:@default=enabled@:>@])],
1618     [GLX_USE_TLS="$enableval"],
1619     [GLX_USE_TLS=yes])
1620 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1621
1622 if test "x$GLX_USE_TLS" = xyes; then
1623     DEFINES="$DEFINES -DGLX_USE_TLS"
1624 fi
1625
1626 dnl Read-only text section on x86 hardened platforms
1627 AC_ARG_ENABLE([glx-read-only-text],
1628     [AS_HELP_STRING([--enable-glx-read-only-text],
1629         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1630     [enable_glx_read_only_text="$enableval"],
1631     [enable_glx_read_only_text=no])
1632 if test "x$enable_glx_read_only_text" = xyes; then
1633     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1634 fi
1635
1636 dnl
1637 dnl DEPRECATED: EGL Platforms configuration
1638 dnl
1639 AC_ARG_WITH([egl-platforms],
1640     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1641         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1642     [with_egl_platforms="$withval"],
1643     [with_egl_platforms=auto])
1644
1645 if test "x$with_egl_platforms" = xauto; then
1646     with_egl_platforms="x11,surfaceless"
1647     if test "x$enable_gbm" = xyes; then
1648         with_egl_platforms="$with_egl_platforms,drm"
1649     fi
1650 else
1651     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1652 fi
1653
1654 dnl
1655 dnl Platforms configuration
1656 dnl
1657 AC_ARG_WITH([platforms],
1658     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1659         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1660         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1661     [with_platforms="$withval"],
1662     [with_platforms=auto])
1663
1664 # Reuse the autodetection rather than duplicating it.
1665 if test "x$with_platforms" = xauto; then
1666     with_platforms=$with_egl_platforms
1667 fi
1668
1669 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1670         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1671         WAYLAND_SCANNER='')
1672 if test "x$WAYLAND_SCANNER" = x; then
1673     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1674 fi
1675
1676 # Do per platform setups and checks
1677 platforms=`IFS=', '; echo $with_platforms`
1678 for plat in $platforms; do
1679         case "$plat" in
1680         wayland)
1681
1682                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1683
1684                 if test "x$WAYLAND_SCANNER" = "x:"; then
1685                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1686                 fi
1687                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1688                 ;;
1689
1690         x11)
1691                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1692                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1693                 ;;
1694
1695         drm)
1696                 test "x$enable_gbm" = "xno" &&
1697                         AC_MSG_ERROR([EGL platform drm needs gbm])
1698                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1699                 ;;
1700
1701         surfaceless)
1702                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1703                 ;;
1704
1705         android)
1706                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1707                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1708                 ;;
1709
1710         *)
1711                 AC_MSG_ERROR([platform '$plat' does not exist])
1712                 ;;
1713         esac
1714
1715         case "$plat" in
1716         wayland|drm|surfaceless)
1717                 require_libdrm "Platform $plat"
1718                 ;;
1719         esac
1720 done
1721
1722 if test "x$enable_glx" != xno; then
1723     if ! echo "$platforms" | grep -q 'x11'; then
1724         AC_MSG_ERROR([Building without the x11 platform as GLX is enabled, is not supported])
1725     fi
1726 fi
1727
1728 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1729 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1730 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1731 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1732 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1733
1734 dnl
1735 dnl More DRI setup
1736 dnl
1737 dnl Directory for DRI drivers
1738 AC_ARG_WITH([dri-driverdir],
1739     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1740         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1741     [DRI_DRIVER_INSTALL_DIR="$withval"],
1742     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1743 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1744 dnl Extra search path for DRI drivers
1745 AC_ARG_WITH([dri-searchpath],
1746     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1747         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1748     [DRI_DRIVER_SEARCH_DIR="$withval"],
1749     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1750 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1751 dnl Which drivers to build - default is chosen by platform
1752 AC_ARG_WITH([dri-drivers],
1753     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1754         [comma delimited classic DRI drivers list, e.g.
1755         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1756     [with_dri_drivers="$withval"],
1757     [with_dri_drivers=auto])
1758
1759 if test "x$with_dri_drivers" = xauto; then
1760     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1761         with_dri_drivers="yes"
1762     else
1763         with_dri_drivers="no"
1764     fi
1765 fi
1766 if test "x$with_dri_drivers" = xno; then
1767     with_dri_drivers=''
1768 fi
1769
1770 dnl If $with_dri_drivers is yes, drivers will be added through
1771 dnl platform checks. Set DEFINES and LIB_DEPS
1772 if test "x$enable_dri" = xyes; then
1773     # Platform specific settings and drivers to build
1774     case "$host_os" in
1775     linux*)
1776         if test "x$enable_dri3" = xyes; then
1777             DEFINES="$DEFINES -DHAVE_DRI3"
1778         fi
1779
1780         case "$host_cpu" in
1781         powerpc* | sparc*)
1782             # Build only the drivers for cards that exist on PowerPC/sparc
1783             if test "x$with_dri_drivers" = "xyes"; then
1784                 with_dri_drivers="r200 radeon swrast"
1785             fi
1786             ;;
1787         esac
1788         ;;
1789     cygwin*)
1790         if test "x$with_dri_drivers" = "xyes"; then
1791             with_dri_drivers="swrast"
1792         fi
1793         ;;
1794     darwin*)
1795         DEFINES="$DEFINES -DBUILDING_MESA"
1796         if test "x$with_dri_drivers" = "xyes"; then
1797             with_dri_drivers="swrast"
1798         fi
1799         ;;
1800     esac
1801
1802     # default drivers
1803     if test "x$with_dri_drivers" = "xyes"; then
1804         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1805     fi
1806
1807     # Check for expat
1808     PKG_CHECK_MODULES([EXPAT], [expat], [],
1809         # expat version 2.0 and earlier do not provide expat.pc
1810         [AC_CHECK_HEADER([expat.h],[],
1811                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1812          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1813                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1814          EXPAT_LIBS="-lexpat"])
1815
1816     # put all the necessary libs together
1817     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1818 fi
1819
1820 AC_SUBST([DRI_LIB_DEPS])
1821
1822 DRI_DIRS=''
1823 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1824 if test -n "$with_dri_drivers"; then
1825     if test "x$enable_opengl" != xyes; then
1826         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1827     fi
1828
1829     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1830     for driver in $dri_drivers; do
1831         DRI_DIRS="$DRI_DIRS $driver"
1832         case "x$driver" in
1833         xi915)
1834             require_libdrm "i915"
1835             HAVE_I915_DRI=yes
1836             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1837             ;;
1838         xi965)
1839             require_libdrm "i965"
1840             HAVE_I965_DRI=yes
1841             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1842             ;;
1843         xnouveau)
1844             require_libdrm "nouveau"
1845             HAVE_NOUVEAU_DRI=yes
1846             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1847             ;;
1848         xradeon)
1849             require_libdrm "radeon"
1850             HAVE_RADEON_DRI=yes;
1851             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1852             ;;
1853         xr200)
1854             require_libdrm "r200"
1855             HAVE_R200_DRI=yes
1856             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1857             ;;
1858         xswrast)
1859             HAVE_SWRAST_DRI=yes
1860             ;;
1861         *)
1862             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1863             ;;
1864         esac
1865     done
1866     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1867 fi
1868
1869
1870 dnl
1871 dnl Gallium LLVM
1872 dnl Deprecated: kept for backwards compatibility
1873 dnl
1874 AC_ARG_ENABLE([gallium-llvm],
1875     [AS_HELP_STRING([--enable-gallium-llvm],
1876         [DEPRECATED: use --enable-llvm instead])],
1877     [enable_gallium_llvm="$enableval"],
1878     [enable_gallium_llvm=auto])
1879
1880 if test "x$enable_gallium_llvm" != xauto; then
1881    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1882    enable_llvm=$enable_gallium_llvm
1883 fi
1884
1885 dnl
1886 dnl LLVM
1887 dnl
1888 AC_ARG_ENABLE([llvm],
1889     [AS_HELP_STRING([--enable-llvm],
1890         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1891     [enable_llvm="$enableval"],
1892     [enable_llvm=auto])
1893
1894 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1895     if test "x$FOUND_LLVM" = xyes; then
1896         case "$host_cpu" in
1897         i*86|x86_64|amd64) enable_llvm=yes;;
1898         *) enable_llvm=no;;
1899         esac
1900     else
1901         enable_llvm=no
1902     fi
1903 fi
1904
1905 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1906     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1907 fi
1908
1909 #
1910 # Vulkan driver configuration
1911 #
1912
1913 AC_ARG_WITH([vulkan-drivers],
1914     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1915         [comma delimited Vulkan drivers list, e.g.
1916         "intel,radeon"
1917         @<:@default=no@:>@])],
1918     [with_vulkan_drivers="$withval"],
1919     [with_vulkan_drivers="no"])
1920
1921 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1922 # here so that the script doesn't choke on an unknown driver name later.
1923 case "x$with_vulkan_drivers" in
1924     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1925     xno) with_vulkan_drivers='' ;;
1926 esac
1927
1928 AC_ARG_WITH([vulkan-icddir],
1929     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1930         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1931     [VULKAN_ICD_INSTALL_DIR="$withval"],
1932     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1933 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1934
1935 if test -n "$with_vulkan_drivers"; then
1936     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1937         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1938     fi
1939
1940     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1941     for driver in $VULKAN_DRIVERS; do
1942         case "x$driver" in
1943         xintel)
1944             require_libdrm "ANV"
1945             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1946             HAVE_INTEL_VULKAN=yes
1947             ;;
1948         xradeon)
1949             require_libdrm "radv"
1950             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1951             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1952             HAVE_RADEON_VULKAN=yes
1953             ;;
1954         *)
1955             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1956             ;;
1957         esac
1958     done
1959     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1960 fi
1961
1962
1963 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1964 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1965 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1966                                   "x$enable_osmesa" = xyes -o \
1967                                   -n "$DRI_DIRS")
1968
1969 dnl
1970 dnl OSMesa configuration
1971 dnl
1972
1973 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1974 AC_ARG_WITH([osmesa-bits],
1975     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1976         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1977     [osmesa_bits="$withval"],
1978     [osmesa_bits=8])
1979 if test "x$osmesa_bits" != x8; then
1980     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1981         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1982         osmesa_bits=8
1983     fi
1984 fi
1985 case "x$osmesa_bits" in
1986 x8)
1987     OSMESA_LIB="${OSMESA_LIB}"
1988     ;;
1989 x16|x32)
1990     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1991     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1992     ;;
1993 *)
1994     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1995     ;;
1996 esac
1997
1998 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1999     # only link libraries with osmesa if shared
2000     if test "$enable_static" = no; then
2001         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2002     else
2003         OSMESA_LIB_DEPS=""
2004     fi
2005     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2006 fi
2007
2008 AC_SUBST([OSMESA_LIB_DEPS])
2009 AC_SUBST([OSMESA_PC_REQ])
2010 AC_SUBST([OSMESA_PC_LIB_PRIV])
2011
2012 dnl
2013 dnl gbm configuration
2014 dnl
2015 if test "x$enable_gbm" = xyes; then
2016     require_dri_shared_libs_and_glapi "gbm"
2017 fi
2018 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2019 # FINISHME: GBM has a number of dependencies which we should add below
2020 GBM_PC_REQ_PRIV=""
2021 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2022 AC_SUBST([GBM_PC_REQ_PRIV])
2023 AC_SUBST([GBM_PC_LIB_PRIV])
2024
2025 dnl
2026 dnl EGL configuration
2027 dnl
2028
2029 if test "x$enable_egl" = xyes; then
2030     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2031
2032     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2033
2034     require_dri_shared_libs_and_glapi "egl"
2035 fi
2036 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2037 AC_SUBST([EGL_LIB_DEPS])
2038
2039 gallium_st="mesa"
2040
2041 dnl
2042 dnl XA configuration
2043 dnl
2044 if test "x$enable_xa" = xyes; then
2045     if test "x$with_gallium_drivers" = xswrast; then
2046        AC_MSG_ERROR([
2047           Building xa requires at least one non swrast gallium driver.
2048           If you are looking to use libxatracker.so with the VMware driver,
2049           make sure to include svga in the gallium drivers list, apart from
2050           enabling XA.
2051           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2052     fi
2053     gallium_st="$gallium_st xa"
2054 fi
2055 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2056
2057 dnl
2058 dnl Gallium G3DVL configuration
2059 dnl
2060 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2061     if test "x$enable_xvmc" = xauto; then
2062         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2063     fi
2064
2065     if test "x$enable_vdpau" = xauto; then
2066         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2067     fi
2068
2069     if test "x$enable_omx" = xauto; then
2070         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2071     fi
2072
2073     if test "x$enable_va" = xauto; then
2074         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2075     fi
2076 fi
2077
2078 if test "x$enable_dri" = xyes -o \
2079         "x$enable_xvmc" = xyes -o \
2080         "x$enable_vdpau" = xyes -o \
2081         "x$enable_omx" = xyes -o \
2082         "x$enable_va" = xyes; then
2083     need_gallium_vl=yes
2084 fi
2085 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2086
2087 if test "x$enable_xvmc" = xyes -o \
2088         "x$enable_vdpau" = xyes -o \
2089         "x$enable_omx" = xyes -o \
2090         "x$enable_va" = xyes; then
2091     if test x"$enable_dri3" = xyes; then
2092         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2093                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2094     else
2095         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2096     fi
2097     need_gallium_vl_winsys=yes
2098 fi
2099 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2100
2101 if test "x$enable_xvmc" = xyes; then
2102     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2103     gallium_st="$gallium_st xvmc"
2104 fi
2105 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2106
2107 if test "x$enable_vdpau" = xyes; then
2108     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2109     gallium_st="$gallium_st vdpau"
2110     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2111 fi
2112 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2113
2114 if test "x$enable_omx" = xyes; then
2115     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2116     gallium_st="$gallium_st omx"
2117 fi
2118 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2119
2120 if test "x$enable_va" = xyes; then
2121     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2122     gallium_st="$gallium_st va"
2123 fi
2124 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2125
2126 dnl
2127 dnl Nine Direct3D9 configuration
2128 dnl
2129 if test "x$enable_nine" = xyes; then
2130     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2131         AC_MSG_ERROR([nine requires the gallium swrast driver])
2132     fi
2133     if test "x$with_gallium_drivers" = xswrast; then
2134         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2135     fi
2136     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2137         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2138     fi
2139
2140     if test "x$enable_dri3" = xno; then
2141         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2142     fi
2143
2144     gallium_st="$gallium_st nine"
2145 fi
2146 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2147
2148 dnl
2149 dnl OpenCL configuration
2150 dnl
2151
2152 AC_ARG_WITH([clang-libdir],
2153    [AS_HELP_STRING([--with-clang-libdir],
2154          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2155    [CLANG_LIBDIR="$withval"],
2156    [CLANG_LIBDIR=''])
2157
2158 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2159
2160 if test "x$enable_opencl" = xyes; then
2161     if test -z "$with_gallium_drivers"; then
2162         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2163     fi
2164
2165     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2166         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2167     fi
2168
2169     if test "x$have_libclc" = xno; then
2170         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2171                     Make sure the directory containing libclc.pc is specified in your
2172                     PKG_CONFIG_PATH environment variable.
2173                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2174     else
2175         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2176         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2177         AC_SUBST([LIBCLC_INCLUDEDIR])
2178         AC_SUBST([LIBCLC_LIBEXECDIR])
2179     fi
2180
2181     gallium_st="$gallium_st clover"
2182
2183     if test "x$enable_opencl_icd" = xyes; then
2184         OPENCL_LIBNAME="MesaOpenCL"
2185     else
2186         OPENCL_LIBNAME="OpenCL"
2187     fi
2188
2189     if test "x$have_libelf" != xyes; then
2190        AC_MSG_ERROR([Clover requires libelf])
2191     fi
2192
2193     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2194         altivec_enabled=no
2195         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2196         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2197         #error "AltiVec not enabled"
2198         #endif
2199         ])], altivec_enabled=yes)
2200
2201         if test "$altivec_enabled" = yes; then
2202             CLOVER_STD_OVERRIDE="-std=gnu++11"
2203         fi
2204         AC_SUBST([CLOVER_STD_OVERRIDE])
2205     fi
2206
2207     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2208
2209     llvm_add_default_components "opencl"
2210     llvm_add_component "all-targets" "opencl"
2211     llvm_add_component "linker" "opencl"
2212     llvm_add_component "instrumentation" "opencl"
2213     llvm_add_component "ipo" "opencl"
2214     llvm_add_component "irreader" "opencl"
2215     llvm_add_component "option" "opencl"
2216     llvm_add_component "objcarcopts" "opencl"
2217     llvm_add_component "profiledata" "opencl"
2218
2219     dnl Check for Clang internal headers
2220     if test -z "$CLANG_LIBDIR"; then
2221         CLANG_LIBDIR=${LLVM_LIBDIR}
2222     fi
2223     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2224     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2225         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2226 fi
2227 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2228 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2229 AC_SUBST([OPENCL_LIBNAME])
2230 AC_SUBST([CLANG_RESOURCE_DIR])
2231
2232 dnl
2233 dnl Gallium configuration
2234 dnl
2235 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2236
2237 # libEGL wants to default to the first platform specified in
2238 # ./configure.  parse that here.
2239 if test "x$platforms" != "x"; then
2240     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2241     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2242 else
2243     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2244 fi
2245
2246 AC_SUBST([EGL_NATIVE_PLATFORM])
2247 AC_SUBST([EGL_CFLAGS])
2248
2249 # If we don't have the X11 platform, set this define so we don't try to include
2250 # the X11 headers.
2251 if ! echo "$platforms" | grep -q 'x11'; then
2252     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2253     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2254 fi
2255
2256 dnl Directory for XVMC libs
2257 AC_ARG_WITH([xvmc-libdir],
2258     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2259         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2260     [XVMC_LIB_INSTALL_DIR="$withval"],
2261     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2262 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2263
2264 dnl
2265 dnl Gallium Tests
2266 dnl
2267 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2268
2269 dnl Directory for VDPAU libs
2270 AC_ARG_WITH([vdpau-libdir],
2271     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2272         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2273     [VDPAU_LIB_INSTALL_DIR="$withval"],
2274     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2275 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2276
2277 dnl Directory for OMX libs
2278
2279 AC_ARG_WITH([omx-libdir],
2280     [AS_HELP_STRING([--with-omx-libdir=DIR],
2281         [directory for the OMX libraries])],
2282     [OMX_LIB_INSTALL_DIR="$withval"],
2283     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2284                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2285 AC_SUBST([OMX_LIB_INSTALL_DIR])
2286
2287 dnl Directory for VA libs
2288
2289 AC_ARG_WITH([va-libdir],
2290     [AS_HELP_STRING([--with-va-libdir=DIR],
2291         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2292     [VA_LIB_INSTALL_DIR="$withval"],
2293     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2294 AC_SUBST([VA_LIB_INSTALL_DIR])
2295
2296 AC_ARG_WITH([d3d-libdir],
2297     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2298         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2299     [D3D_DRIVER_INSTALL_DIR="$withval"],
2300     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2301 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2302
2303 dnl
2304 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2305 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2306 dnl architectures.
2307 dnl
2308 r300_require_llvm() {
2309     case "$host" in *gnux32) return;; esac
2310     case "$host_cpu" in
2311     i*86|x86_64|amd64) require_llvm $1
2312         ;;
2313     esac
2314 }
2315
2316 dnl
2317 dnl DRM is needed by X, Wayland, and offscreen rendering.
2318 dnl Surfaceless is an alternative for the last one.
2319 dnl
2320 require_basic_egl() {
2321     case "$with_platforms" in
2322         *drm*|*surfaceless*)
2323             ;;
2324         *)
2325             AC_MSG_ERROR([$1 requires one of these:
2326                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2327                   2) --with-platforms=surfaceless (offscreen only)
2328                   Recommended options: drm,x11])
2329             ;;
2330     esac
2331 }
2332
2333 swr_require_cxx_feature_flags() {
2334     feature_name="$1"
2335     preprocessor_test="$2"
2336     option_list="$3"
2337     output_var="$4"
2338
2339     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2340     AC_LANG_PUSH([C++])
2341     save_CXXFLAGS="$CXXFLAGS"
2342     save_IFS="$IFS"
2343     IFS=","
2344     found=0
2345     for opts in $option_list
2346     do
2347         unset IFS
2348         CXXFLAGS="$opts $save_CXXFLAGS"
2349         AC_COMPILE_IFELSE(
2350             [AC_LANG_PROGRAM(
2351                 [   #if !($preprocessor_test)
2352                     #error
2353                     #endif
2354                 ])],
2355             [found=1; break],
2356             [])
2357         IFS=","
2358     done
2359     IFS="$save_IFS"
2360     CXXFLAGS="$save_CXXFLAGS"
2361     AC_LANG_POP([C++])
2362     if test $found -eq 1; then
2363         AC_MSG_RESULT([$opts])
2364         eval "$output_var=\$opts"
2365         return 0
2366     fi
2367     AC_MSG_RESULT([no])
2368     AC_MSG_ERROR([swr requires $feature_name support])
2369     return 1
2370 }
2371
2372 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2373 if test -n "$with_gallium_drivers"; then
2374     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2375     for driver in $gallium_drivers; do
2376         case "x$driver" in
2377         xsvga)
2378             HAVE_GALLIUM_SVGA=yes
2379             require_libdrm "svga"
2380             ;;
2381         xi915)
2382             HAVE_GALLIUM_I915=yes
2383             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2384             require_libdrm "Gallium i915"
2385             ;;
2386         xr300)
2387             HAVE_GALLIUM_R300=yes
2388             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2389             require_libdrm "r300"
2390             r300_require_llvm "r300"
2391             ;;
2392         xr600)
2393             HAVE_GALLIUM_R600=yes
2394             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2395             require_libdrm "r600"
2396             if test "x$enable_llvm" = xyes; then
2397                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2398
2399                 llvm_add_component "asmparser" "r600"
2400                 llvm_add_component "bitreader" "r600"
2401             fi
2402             ;;
2403         xradeonsi)
2404             HAVE_GALLIUM_RADEONSI=yes
2405             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2406             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2407             require_libdrm "radeonsi"
2408             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2409             if test "x$enable_egl" = xyes; then
2410                 require_basic_egl "radeonsi"
2411             fi
2412             ;;
2413         xnouveau)
2414             HAVE_GALLIUM_NOUVEAU=yes
2415             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2416             require_libdrm "nouveau"
2417             ;;
2418         xfreedreno)
2419             HAVE_GALLIUM_FREEDRENO=yes
2420             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2421             require_libdrm "freedreno"
2422             ;;
2423         xetnaviv)
2424             HAVE_GALLIUM_ETNAVIV=yes
2425             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2426             require_libdrm "etnaviv"
2427             ;;
2428        ximx)
2429             HAVE_GALLIUM_IMX=yes
2430             ;;
2431         xswrast)
2432             HAVE_GALLIUM_SOFTPIPE=yes
2433             if test "x$enable_llvm" = xyes; then
2434                 HAVE_GALLIUM_LLVMPIPE=yes
2435             fi
2436             ;;
2437         xswr)
2438             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2439
2440             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2441                 "-std=c++14" \
2442                 SWR_CXX14_CXXFLAGS
2443             AC_SUBST([SWR_CXX14_CXXFLAGS])
2444
2445             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2446                 ",-mavx,-march=core-avx" \
2447                 SWR_AVX_CXXFLAGS
2448             AC_SUBST([SWR_AVX_CXXFLAGS])
2449
2450             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2451                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2452                 SWR_AVX2_CXXFLAGS
2453             AC_SUBST([SWR_AVX2_CXXFLAGS])
2454
2455             HAVE_GALLIUM_SWR=yes
2456             ;;
2457         xvc4)
2458             HAVE_GALLIUM_VC4=yes
2459             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2460             require_libdrm "vc4"
2461
2462             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2463                               [USE_VC4_SIMULATOR=yes;
2464                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2465                               [USE_VC4_SIMULATOR=no])
2466             ;;
2467         xvirgl)
2468             HAVE_GALLIUM_VIRGL=yes
2469             require_libdrm "virgl"
2470             if test "x$enable_egl" = xyes; then
2471                 require_basic_egl "virgl"
2472             fi
2473             ;;
2474         *)
2475             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2476             ;;
2477         esac
2478     done
2479 fi
2480
2481 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2482     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2483     llvm_add_default_components "gallium"
2484 fi
2485
2486 dnl We need to validate some needed dependencies for renderonly drivers.
2487
2488 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2489     AC_MSG_ERROR([Building with imx requires etnaviv])
2490 fi
2491
2492 dnl
2493 dnl Set defines and buildtime variables only when using LLVM.
2494 dnl
2495 if test "x$enable_llvm" = xyes; then
2496     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2497
2498     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2499     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2500     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2501
2502     dnl Set LLVM_LIBS - This is done after the driver configuration so
2503     dnl that drivers can add additional components to LLVM_COMPONENTS.
2504     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2505     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2506     dnl this was causing the same libraries to be appear multiple times
2507     dnl in LLVM_LIBS.
2508
2509     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2510        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2511     fi
2512     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2513
2514     dnl llvm-config may not give the right answer when llvm is a built as a
2515     dnl single shared library, so we must work the library name out for
2516     dnl ourselves.
2517     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2518     if test "x$enable_llvm_shared_libs" = xyes; then
2519         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2520         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2521         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2522
2523         if test "x$llvm_have_one_so" = xyes; then
2524             dnl LLVM was built using auto*, so there is only one shared object.
2525             LLVM_LIBS="-l$LLVM_SO_NAME"
2526         else
2527             dnl If LLVM was built with CMake, there will be one shared object per
2528             dnl component.
2529             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2530                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2531         Please make sure you have built llvm with the --enable-shared option
2532         and that your llvm libraries are installed in $LLVM_LIBDIR
2533         If you have installed your llvm libraries to a different directory you
2534         can use the --with-llvm-prefix= configure flag to specify this directory.
2535         NOTE: Mesa is attempting to use llvm shared libraries by default.
2536         If you do not want to build with llvm shared libraries and instead want to
2537         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2538         invocation and rebuild.])])
2539
2540            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2541            dnl install uses a shared object for each component and we have
2542            dnl already added all of these objects to LLVM_LIBS.
2543         fi
2544     else
2545         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2546         dnl We need to link to llvm system libs when using static libs
2547         dnl However, only llvm 3.5+ provides --system-libs
2548         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2549             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2550         fi
2551     fi
2552 fi
2553
2554 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2557 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2558 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2560                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2563 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2564 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2565 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2566 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2567 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2568 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2569                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2570                                          "x$HAVE_GALLIUM_SWR" = xyes)
2571 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2572 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2573
2574 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2575
2576 if test "x$enable_dri" = xyes; then
2577     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2578 fi
2579
2580 if test "x$have_drisw_kms" = xyes; then
2581     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2582 fi
2583 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2584
2585 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2586 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2587 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2588 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2589 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2590 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2591
2592 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2593 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2594
2595 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2596                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2597                                       "x$HAVE_RADEON_VULKAN" = xyes)
2598
2599 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2600                                         "x$HAVE_I965_DRI" = xyes)
2601
2602 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2603                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2604                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2605 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2606 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2608 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2609
2610 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2611 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2612 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2613 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2614                                         "x$enable_gallium_osmesa" = xyes)
2615
2616 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2617 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2618 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2619
2620 AC_SUBST([NINE_MAJOR], 1)
2621 AC_SUBST([NINE_MINOR], 0)
2622 AC_SUBST([NINE_TINY], 0)
2623 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2624
2625 AC_SUBST([VDPAU_MAJOR], 1)
2626 AC_SUBST([VDPAU_MINOR], 0)
2627
2628 if test "x$enable_va" = xyes; then
2629     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2630     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2631 fi
2632 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2633 AC_SUBST([VA_MINOR], $VA_MINOR)
2634
2635 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2636
2637 AC_SUBST([XVMC_MAJOR], 1)
2638 AC_SUBST([XVMC_MINOR], 0)
2639
2640 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2641 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2642 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2643 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2644
2645 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2646 AC_SUBST([XA_MINOR], $XA_MINOR)
2647 AC_SUBST([XA_TINY], $XA_TINY)
2648 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2649
2650 AC_ARG_ENABLE(valgrind,
2651               [AS_HELP_STRING([--enable-valgrind],
2652                              [Build mesa with valgrind support (default: auto)])],
2653                              [VALGRIND=$enableval], [VALGRIND=auto])
2654 if test "x$VALGRIND" != xno; then
2655         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2656 fi
2657 AC_MSG_CHECKING([whether to enable Valgrind support])
2658 if test "x$VALGRIND" = xauto; then
2659         VALGRIND="$have_valgrind"
2660 fi
2661
2662 if test "x$VALGRIND" = "xyes"; then
2663         if ! test "x$have_valgrind" = xyes; then
2664                 AC_MSG_ERROR([Valgrind support required but not present])
2665         fi
2666         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2667 fi
2668
2669 AC_MSG_RESULT([$VALGRIND])
2670
2671 dnl Restore LDFLAGS and CPPFLAGS
2672 LDFLAGS="$_SAVE_LDFLAGS"
2673 CPPFLAGS="$_SAVE_CPPFLAGS"
2674
2675 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2676 if test "x$acv_mesa_CLANG" = xyes; then
2677     CFLAGS="$CFLAGS -Qunused-arguments"
2678     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2679 fi
2680
2681 dnl Add user CFLAGS and CXXFLAGS
2682 CFLAGS="$CFLAGS $USER_CFLAGS"
2683 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2684
2685 dnl Substitute the config
2686 AC_CONFIG_FILES([Makefile
2687                 src/Makefile
2688                 src/amd/Makefile
2689                 src/amd/vulkan/Makefile
2690                 src/compiler/Makefile
2691                 src/egl/Makefile
2692                 src/egl/main/egl.pc
2693                 src/egl/wayland/wayland-drm/Makefile
2694                 src/egl/wayland/wayland-egl/Makefile
2695                 src/egl/wayland/wayland-egl/wayland-egl.pc
2696                 src/gallium/Makefile
2697                 src/gallium/auxiliary/Makefile
2698                 src/gallium/auxiliary/pipe-loader/Makefile
2699                 src/gallium/drivers/freedreno/Makefile
2700                 src/gallium/drivers/ddebug/Makefile
2701                 src/gallium/drivers/i915/Makefile
2702                 src/gallium/drivers/llvmpipe/Makefile
2703                 src/gallium/drivers/noop/Makefile
2704                 src/gallium/drivers/nouveau/Makefile
2705                 src/gallium/drivers/r300/Makefile
2706                 src/gallium/drivers/r600/Makefile
2707                 src/gallium/drivers/radeon/Makefile
2708                 src/gallium/drivers/radeonsi/Makefile
2709                 src/gallium/drivers/rbug/Makefile
2710                 src/gallium/drivers/softpipe/Makefile
2711                 src/gallium/drivers/svga/Makefile
2712                 src/gallium/drivers/swr/Makefile
2713                 src/gallium/drivers/trace/Makefile
2714                 src/gallium/drivers/etnaviv/Makefile
2715                 src/gallium/drivers/imx/Makefile
2716                 src/gallium/drivers/vc4/Makefile
2717                 src/gallium/drivers/virgl/Makefile
2718                 src/gallium/state_trackers/clover/Makefile
2719                 src/gallium/state_trackers/dri/Makefile
2720                 src/gallium/state_trackers/glx/xlib/Makefile
2721                 src/gallium/state_trackers/nine/Makefile
2722                 src/gallium/state_trackers/omx/Makefile
2723                 src/gallium/state_trackers/osmesa/Makefile
2724                 src/gallium/state_trackers/va/Makefile
2725                 src/gallium/state_trackers/vdpau/Makefile
2726                 src/gallium/state_trackers/xa/Makefile
2727                 src/gallium/state_trackers/xvmc/Makefile
2728                 src/gallium/targets/d3dadapter9/Makefile
2729                 src/gallium/targets/d3dadapter9/d3d.pc
2730                 src/gallium/targets/dri/Makefile
2731                 src/gallium/targets/libgl-xlib/Makefile
2732                 src/gallium/targets/omx/Makefile
2733                 src/gallium/targets/opencl/Makefile
2734                 src/gallium/targets/opencl/mesa.icd
2735                 src/gallium/targets/osmesa/Makefile
2736                 src/gallium/targets/osmesa/osmesa.pc
2737                 src/gallium/targets/pipe-loader/Makefile
2738                 src/gallium/targets/va/Makefile
2739                 src/gallium/targets/vdpau/Makefile
2740                 src/gallium/targets/xa/Makefile
2741                 src/gallium/targets/xa/xatracker.pc
2742                 src/gallium/targets/xvmc/Makefile
2743                 src/gallium/tests/trivial/Makefile
2744                 src/gallium/tests/unit/Makefile
2745                 src/gallium/winsys/etnaviv/drm/Makefile
2746                 src/gallium/winsys/imx/drm/Makefile
2747                 src/gallium/winsys/freedreno/drm/Makefile
2748                 src/gallium/winsys/i915/drm/Makefile
2749                 src/gallium/winsys/nouveau/drm/Makefile
2750                 src/gallium/winsys/radeon/drm/Makefile
2751                 src/gallium/winsys/amdgpu/drm/Makefile
2752                 src/gallium/winsys/svga/drm/Makefile
2753                 src/gallium/winsys/sw/dri/Makefile
2754                 src/gallium/winsys/sw/kms-dri/Makefile
2755                 src/gallium/winsys/sw/null/Makefile
2756                 src/gallium/winsys/sw/wrapper/Makefile
2757                 src/gallium/winsys/sw/xlib/Makefile
2758                 src/gallium/winsys/vc4/drm/Makefile
2759                 src/gallium/winsys/virgl/drm/Makefile
2760                 src/gallium/winsys/virgl/vtest/Makefile
2761                 src/gbm/Makefile
2762                 src/gbm/main/gbm.pc
2763                 src/glx/Makefile
2764                 src/glx/apple/Makefile
2765                 src/glx/tests/Makefile
2766                 src/glx/windows/Makefile
2767                 src/glx/windows/windowsdriproto.pc
2768                 src/gtest/Makefile
2769                 src/intel/Makefile
2770                 src/loader/Makefile
2771                 src/mapi/Makefile
2772                 src/mapi/es1api/glesv1_cm.pc
2773                 src/mapi/es2api/glesv2.pc
2774                 src/mapi/glapi/gen/Makefile
2775                 src/mesa/Makefile
2776                 src/mesa/gl.pc
2777                 src/mesa/drivers/dri/dri.pc
2778                 src/mesa/drivers/dri/common/Makefile
2779                 src/mesa/drivers/dri/common/xmlpool/Makefile
2780                 src/mesa/drivers/dri/i915/Makefile
2781                 src/mesa/drivers/dri/i965/Makefile
2782                 src/mesa/drivers/dri/Makefile
2783                 src/mesa/drivers/dri/nouveau/Makefile
2784                 src/mesa/drivers/dri/r200/Makefile
2785                 src/mesa/drivers/dri/radeon/Makefile
2786                 src/mesa/drivers/dri/swrast/Makefile
2787                 src/mesa/drivers/osmesa/Makefile
2788                 src/mesa/drivers/osmesa/osmesa.pc
2789                 src/mesa/drivers/x11/Makefile
2790                 src/mesa/main/tests/Makefile
2791                 src/util/Makefile
2792                 src/util/tests/hash_table/Makefile
2793                 src/vulkan/Makefile])
2794
2795 AC_OUTPUT
2796
2797 # Fix up dependencies in *.Plo files, where we changed the extension of a
2798 # source file
2799 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2800
2801
2802 dnl
2803 dnl Output some configuration info for the user
2804 dnl
2805 echo ""
2806 echo "        prefix:          $prefix"
2807 echo "        exec_prefix:     $exec_prefix"
2808 echo "        libdir:          $libdir"
2809 echo "        includedir:      $includedir"
2810
2811 dnl API info
2812 echo ""
2813 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2814
2815 dnl Driver info
2816 echo ""
2817 case "x$enable_osmesa$enable_gallium_osmesa" in
2818 xnoyes)
2819         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2820         ;;
2821 xyesno)
2822         echo "        OSMesa:          lib$OSMESA_LIB"
2823         ;;
2824 xnono)
2825         echo "        OSMesa:          no"
2826         ;;
2827 esac
2828
2829 echo ""
2830 if test "x$enable_dri" != xno; then
2831         echo "        DRI platform:    $dri_platform"
2832         if test -z "$DRI_DIRS"; then
2833             echo "        DRI drivers:     no"
2834         else
2835             echo "        DRI drivers:     $DRI_DIRS"
2836         fi
2837         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2838 fi
2839
2840 case "x$enable_glx" in
2841 xdri)
2842     echo "        GLX:             DRI-based"
2843     ;;
2844 xxlib)
2845     echo "        GLX:             Xlib-based"
2846     ;;
2847 xgallium-xlib)
2848     echo "        GLX:             Xlib-based (Gallium)"
2849     ;;
2850 *)
2851     echo "        GLX:             $enable_glx"
2852     ;;
2853 esac
2854
2855 dnl EGL
2856 echo ""
2857 echo "        EGL:             $enable_egl"
2858 if test "$enable_egl" = yes; then
2859
2860     egl_drivers=""
2861     if test "x$enable_dri" != "xno"; then
2862         egl_drivers="$egl_drivers builtin:egl_dri2"
2863     fi
2864     if test "x$enable_dri3" != "xno"; then
2865         egl_drivers="$egl_drivers builtin:egl_dri3"
2866     fi
2867
2868     echo "        EGL drivers:    $egl_drivers"
2869 fi
2870 if test "x$enable_gbm" = xyes; then
2871     echo "        GBM:             yes"
2872 else
2873     echo "        GBM:             no"
2874 fi
2875
2876     echo "        EGL/Vulkan/VL platforms:   $platforms"
2877
2878 # Vulkan
2879 echo ""
2880 if test "x$VULKAN_DRIVERS" != x; then
2881     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2882     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2883 else
2884     echo "        Vulkan drivers:  no"
2885 fi
2886
2887 echo ""
2888 if test "x$enable_llvm" = xyes; then
2889     echo "        llvm:            yes"
2890     echo "        llvm-config:     $LLVM_CONFIG"
2891     echo "        llvm-version:    $LLVM_VERSION"
2892 else
2893     echo "        llvm:            no"
2894 fi
2895
2896 echo ""
2897 if test -n "$with_gallium_drivers"; then
2898     echo "        Gallium drivers: $gallium_drivers"
2899     echo "        Gallium st:      $gallium_st"
2900 else
2901     echo "        Gallium:         no"
2902 fi
2903
2904 echo ""
2905 if test "x$enable_gallium_extra_hud" != xyes; then
2906     echo "        HUD extra stats: no"
2907 else
2908     echo "        HUD extra stats: yes"
2909 fi
2910
2911 if test "x$enable_lmsensors" != xyes; then
2912     echo "        HUD lmsensors:   no"
2913 else
2914     echo "        HUD lmsensors:   yes"
2915 fi
2916
2917 dnl Libraries
2918 echo ""
2919 echo "        Shared libs:     $enable_shared"
2920 echo "        Static libs:     $enable_static"
2921 echo "        Shared-glapi:    $enable_shared_glapi"
2922
2923 dnl Compiler options
2924 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2925 cflags=`echo $CFLAGS | \
2926     $SED 's/^ *//;s/  */ /;s/ *$//'`
2927 cxxflags=`echo $CXXFLAGS | \
2928     $SED 's/^ *//;s/  */ /;s/ *$//'`
2929 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2930 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2931 echo ""
2932 echo "        CFLAGS:          $cflags"
2933 echo "        CXXFLAGS:        $cxxflags"
2934 echo "        LDFLAGS:         $ldflags"
2935 echo "        Macros:          $defines"
2936 echo ""
2937 if test "x$enable_llvm" = xyes; then
2938     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2939     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2940     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2941     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2942     echo ""
2943 fi
2944 echo "        PYTHON2:         $PYTHON2"
2945
2946 echo ""
2947 echo "        Run '${MAKE-make}' to build Mesa"
2948 echo ""