configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284
 285 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 286 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 287 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 288 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 289 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 290 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 291 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 293
 294 AC_SUBST([GL_LIB_NAME])
 295 AC_SUBST([GLU_LIB_NAME])
 296 AC_SUBST([GLUT_LIB_NAME])
 297 AC_SUBST([GLW_LIB_NAME])
 298 AC_SUBST([OSMESA_LIB_NAME])
 299 AC_SUBST([EGL_LIB_NAME])
 300 AC_SUBST([GLESv1_CM_LIB_NAME])
 301 AC_SUBST([GLESv2_LIB_NAME])
 302
 303 AC_SUBST([GL_LIB_GLOB])
 304 AC_SUBST([GLU_LIB_GLOB])
 305 AC_SUBST([GLUT_LIB_GLOB])
 306 AC_SUBST([GLW_LIB_GLOB])
 307 AC_SUBST([OSMESA_LIB_GLOB])
 308 AC_SUBST([EGL_LIB_GLOB])
 309 AC_SUBST([GLESv1_CM_LIB_GLOB])
 310 AC_SUBST([GLESv2_LIB_GLOB])
 311
 312 dnl
 313 dnl Arch/platform-specific settings
 314 dnl
 315 AC_ARG_ENABLE([asm],
 316     [AS_HELP_STRING([--disable-asm],
 317         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 318     [enable_asm="$enableval"],
 319     [enable_asm=yes]
 320 )
 321 asm_arch=""
 322 ASM_FLAGS=""
 323 MESA_ASM_SOURCES=""
 324 GLAPI_ASM_SOURCES=""
 325 AC_MSG_CHECKING([whether to enable assembly])
 326 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 327 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 328 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 329     case "$host_cpu" in
 330     i?86 | x86_64)
 331         enable_asm=no
 332         AC_MSG_RESULT([no, cross compiling])
 333         ;;
 334     esac
 335 fi
 336 # check for supported arches
 337 if test "x$enable_asm" = xyes; then
 338     case "$host_cpu" in
 339     i?86)
 340         case "$host_os" in
 341         linux* | *freebsd* | dragonfly*)
 342             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 343             ;;
 344         esac
 345         ;;
 346     x86_64)
 347         case "$host_os" in
 348         linux* | *freebsd* | dragonfly*)
 349             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 350             ;;
 351         esac
 352         ;;
 353     powerpc)
 354         case "$host_os" in
 355         linux*)
 356             asm_arch=ppc
 357             ;;
 358         esac
 359         ;;
 360     sparc*)
 361         case "$host_os" in
 362         linux*)
 363             asm_arch=sparc
 364             ;;
 365         esac
 366         ;;
 367     esac
 368
 369     case "$asm_arch" in
 370     x86)
 371         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 372         MESA_ASM_SOURCES='$(X86_SOURCES)'
 373         GLAPI_ASM_SOURCES='$(X86_API)'
 374         AC_MSG_RESULT([yes, x86])
 375         ;;
 376     x86_64)
 377         ASM_FLAGS="-DUSE_X86_64_ASM"
 378         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 379         GLAPI_ASM_SOURCES='$(X86-64_API)'
 380         AC_MSG_RESULT([yes, x86_64])
 381         ;;
 382     ppc)
 383         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 384         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 385         AC_MSG_RESULT([yes, ppc])
 386         ;;
 387     sparc)
 388         ASM_FLAGS="-DUSE_SPARC_ASM"
 389         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 390         GLAPI_ASM_SOURCES='$(SPARC_API)'
 391         AC_MSG_RESULT([yes, sparc])
 392         ;;
 393     *)
 394         AC_MSG_RESULT([no, platform not supported])
 395         ;;
 396     esac
 397 fi
 398 AC_SUBST([ASM_FLAGS])
 399 AC_SUBST([MESA_ASM_SOURCES])
 400 AC_SUBST([GLAPI_ASM_SOURCES])
 401
 402 dnl PIC code macro
 403 MESA_PIC_FLAGS
 404
 405 dnl Check to see if dlopen is in default libraries (like Solaris, which
 406 dnl has it in libc), or if libdl is needed to get it.
 407 AC_CHECK_FUNC([dlopen], [],
 408     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 409
 410 dnl See if posix_memalign is available
 411 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 412
 413 dnl SELinux awareness.
 414 AC_ARG_ENABLE([selinux],
 415     [AS_HELP_STRING([--enable-selinux],
 416         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 417     [MESA_SELINUX="$enableval"],
 418     [MESA_SELINUX=no])
 419 if test "x$enable_selinux" = "xyes"; then
 420     AC_CHECK_HEADER([selinux/selinux.h],[],
 421                     [AC_MSG_ERROR([SELinux headers not found])])
 422     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 423                  [AC_MSG_ERROR([SELinux library not found])])
 424     SELINUX_LIBS="-lselinux"
 425     DEFINES="$DEFINES -DMESA_SELINUX"
 426 fi
 427
 428 dnl
 429 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 430 dnl More later: fbdev, ...
 431 dnl
 432 default_driver="xlib"
 433
 434 case "$host_os" in
 435 linux*)
 436     case "$host_cpu" in
 437     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 438     esac
 439     ;;
 440 *freebsd* | dragonfly*)
 441     case "$host_cpu" in
 442     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 443     esac
 444     ;;
 445 esac
 446
 447 AC_ARG_WITH([driver],
 448     [AS_HELP_STRING([--with-driver=DRIVER],
 449         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 450     [mesa_driver="$withval"],
 451     [mesa_driver="$default_driver"])
 452 dnl Check for valid option
 453 case "x$mesa_driver" in
 454 xxlib|xdri|xosmesa)
 455     ;;
 456 *)
 457     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 458     ;;
 459 esac
 460
 461 dnl
 462 dnl Driver specific build directories
 463 dnl
 464
 465 dnl this variable will be prepended to SRC_DIRS and is not exported
 466 CORE_DIRS="glsl mesa"
 467
 468 SRC_DIRS="glew"
 469 GLU_DIRS="sgi"
 470 GALLIUM_DIRS="auxiliary drivers state_trackers"
 471 GALLIUM_TARGET_DIRS=""
 472 GALLIUM_WINSYS_DIRS="sw"
 473 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 474 GALLIUM_STATE_TRACKERS_DIRS=""
 475
 476 case "$mesa_driver" in
 477 xlib)
 478     DRIVER_DIRS="x11"
 479     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 480     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 481     ;;
 482 dri)
 483     SRC_DIRS="$SRC_DIRS glx"
 484     DRIVER_DIRS="dri"
 485     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
 486     ;;
 487 osmesa)
 488     DRIVER_DIRS="osmesa"
 489     ;;
 490 esac
 491 AC_SUBST([SRC_DIRS])
 492 AC_SUBST([GLU_DIRS])
 493 AC_SUBST([DRIVER_DIRS])
 494 AC_SUBST([GALLIUM_DIRS])
 495 AC_SUBST([GALLIUM_TARGET_DIRS])
 496 AC_SUBST([GALLIUM_WINSYS_DIRS])
 497 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 498 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 499 AC_SUBST([MESA_LLVM])
 500
 501 dnl
 502 dnl User supplied program configuration
 503 dnl
 504 if test -d "$srcdir/progs/demos"; then
 505     default_demos=yes
 506 else
 507     default_demos=no
 508 fi
 509 AC_ARG_WITH([demos],
 510     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 511         [optional comma delimited demo directories to build
 512         @<:@default=auto if source available@:>@])],
 513     [with_demos="$withval"],
 514     [with_demos="$default_demos"])
 515 if test "x$with_demos" = x; then
 516     with_demos=no
 517 fi
 518
 519 dnl If $with_demos is yes, directories will be added as libs available
 520 PROGRAM_DIRS=""
 521 case "$with_demos" in
 522 no) ;;
 523 yes)
 524     # If the driver isn't osmesa, we have libGL and can build xdemos
 525     if test "$mesa_driver" != osmesa; then
 526         PROGRAM_DIRS="xdemos"
 527     fi
 528     ;;
 529 *)
 530     # verify the requested demos directories exist
 531     demos=`IFS=,; echo $with_demos`
 532     for demo in $demos; do
 533         test -d "$srcdir/progs/$demo" || \
 534             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 535     done
 536     PROGRAM_DIRS="$demos"
 537     ;;
 538 esac
 539
 540 dnl
 541 dnl Find out if X is available. The variable have_x is set if libX11 is
 542 dnl found to mimic AC_PATH_XTRA.
 543 dnl
 544 if test -n "$PKG_CONFIG"; then
 545     AC_MSG_CHECKING([pkg-config files for X11 are available])
 546     PKG_CHECK_EXISTS([x11],[
 547         x11_pkgconfig=yes
 548         have_x=yes
 549         ],[
 550         x11_pkgconfig=no
 551     ])
 552     AC_MSG_RESULT([$x11_pkgconfig])
 553 else
 554     x11_pkgconfig=no
 555 fi
 556 dnl Use the autoconf macro if no pkg-config files
 557 if test "$x11_pkgconfig" = yes; then
 558     PKG_CHECK_MODULES([X11], [x11])
 559 else
 560     AC_PATH_XTRA
 561     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 562     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 563     AC_SUBST([X11_CFLAGS])
 564     AC_SUBST([X11_LIBS])
 565 fi
 566
 567 dnl Try to tell the user that the --x-* options are only used when
 568 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 569 m4_divert_once([HELP_BEGIN],
 570 [These options are only used when the X libraries cannot be found by the
 571 pkg-config utility.])
 572
 573 dnl We need X for xlib and dri, so bomb now if it's not found
 574 case "$mesa_driver" in
 575 xlib|dri)
 576     if test "$no_x" = yes; then
 577         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 578     fi
 579     ;;
 580 esac
 581
 582 dnl XCB - this is only used for GLX right now
 583 AC_ARG_ENABLE([xcb],
 584     [AS_HELP_STRING([--enable-xcb],
 585         [use XCB for GLX @<:@default=disabled@:>@])],
 586     [enable_xcb="$enableval"],
 587     [enable_xcb=no])
 588 if test "x$enable_xcb" = xyes; then
 589     DEFINES="$DEFINES -DUSE_XCB"
 590 else
 591     enable_xcb=no
 592 fi
 593
 594 dnl
 595 dnl libGL configuration per driver
 596 dnl
 597 case "$mesa_driver" in
 598 xlib)
 599     if test "$x11_pkgconfig" = yes; then
 600         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 601         GL_PC_REQ_PRIV="x11 xext"
 602         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 603         GL_LIB_DEPS="$XLIBGL_LIBS"
 604     else
 605         # should check these...
 606         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 607         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 608         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 609         GL_PC_CFLAGS="$X11_INCLUDES"
 610     fi
 611     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 612     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 613
 614     # if static, move the external libraries to the programs
 615     # and empty the libraries for libGL
 616     if test "$enable_static" = yes; then
 617         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 618         GL_LIB_DEPS=""
 619     fi
 620     ;;
 621 dri)
 622     # DRI must be shared, I think
 623     if test "$enable_static" = yes; then
 624         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 625     fi
 626
 627     # Check for libdrm
 628     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 629     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 630     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 631     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 632     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 633
 634     # find the DRI deps for libGL
 635     if test "$x11_pkgconfig" = yes; then
 636         # add xcb modules if necessary
 637         dri_modules="x11 xext xxf86vm xdamage xfixes"
 638         if test "$enable_xcb" = yes; then
 639             dri_modules="$dri_modules x11-xcb xcb-glx"
 640         fi
 641
 642         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 643         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 644         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 645         GL_LIB_DEPS="$DRIGL_LIBS"
 646     else
 647         # should check these...
 648         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 649         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 650         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 651         GL_PC_CFLAGS="$X11_INCLUDES"
 652
 653         # XCB can only be used from pkg-config
 654         if test "$enable_xcb" = yes; then
 655             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 656             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 657             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 658             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 659         fi
 660     fi
 661
 662     # need DRM libs, -lpthread, etc.
 663     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 664     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 665     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 666     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 667     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 668     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 669     ;;
 670 osmesa)
 671     # No libGL for osmesa
 672     GL_LIB_DEPS=""
 673     ;;
 674 esac
 675 AC_SUBST([GL_LIB_DEPS])
 676 AC_SUBST([GL_PC_REQ_PRIV])
 677 AC_SUBST([GL_PC_LIB_PRIV])
 678 AC_SUBST([GL_PC_CFLAGS])
 679 AC_SUBST([DRI_PC_REQ_PRIV])
 680 AC_SUBST([GLESv1_LIB_DEPS])
 681 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 682 AC_SUBST([GLESv2_LIB_DEPS])
 683 AC_SUBST([GLESv2_PC_LIB_PRIV])
 684
 685
 686 dnl
 687 dnl More X11 setup
 688 dnl
 689 if test "$mesa_driver" = xlib; then
 690     DEFINES="$DEFINES -DUSE_XSHM"
 691 fi
 692
 693 dnl
 694 dnl More DRI setup
 695 dnl
 696 AC_ARG_ENABLE([glx-tls],
 697     [AS_HELP_STRING([--enable-glx-tls],
 698         [enable TLS support in GLX @<:@default=disabled@:>@])],
 699     [GLX_USE_TLS="$enableval"],
 700     [GLX_USE_TLS=no])
 701 dnl Directory for DRI drivers
 702 AC_ARG_WITH([dri-driverdir],
 703     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 704         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 705     [DRI_DRIVER_INSTALL_DIR="$withval"],
 706     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 707 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 708 dnl Extra search path for DRI drivers
 709 AC_ARG_WITH([dri-searchpath],
 710     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 711         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 712     [DRI_DRIVER_SEARCH_DIR="$withval"],
 713     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 714 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 715 dnl Direct rendering or just indirect rendering
 716 AC_ARG_ENABLE([driglx-direct],
 717     [AS_HELP_STRING([--disable-driglx-direct],
 718         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 719     [driglx_direct="$enableval"],
 720     [driglx_direct="yes"])
 721 dnl Which drivers to build - default is chosen by platform
 722 AC_ARG_WITH([dri-drivers],
 723     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 724         [comma delimited DRI drivers list, e.g.
 725         "swrast,i965,radeon" @<:@default=auto@:>@])],
 726     [with_dri_drivers="$withval"],
 727     [with_dri_drivers=yes])
 728 if test "x$with_dri_drivers" = x; then
 729     with_dri_drivers=no
 730 fi
 731
 732 dnl Determine which APIs to support
 733 AC_ARG_ENABLE([opengl],
 734     [AS_HELP_STRING([--disable-opengl],
 735         [disable support for standard OpenGL API @<:@default=no@:>@])],
 736     [enable_opengl="$enableval"],
 737     [enable_opengl=yes])
 738 AC_ARG_ENABLE([gles1],
 739     [AS_HELP_STRING([--enable-gles1],
 740         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 741     [enable_gles1="$enableval"],
 742     [enable_gles1=no])
 743 AC_ARG_ENABLE([gles2],
 744     [AS_HELP_STRING([--enable-gles2],
 745         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 746     [enable_gles2="$enableval"],
 747     [enable_gles2=no])
 748
 749 API_DEFINES=""
 750 APIS=""
 751 if test "x$enable_opengl" = xno; then
 752     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 753 else
 754     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 755     APIS="$APIS gl"
 756 fi
 757 if test "x$enable_gles1" = xyes; then
 758     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 759     APIS="$APIS es1"
 760 fi
 761 if test "x$enable_gles2" = xyes; then
 762     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 763     APIS="$APIS es2"
 764 fi
 765 if test "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 766     SRC_DIRS="$SRC_DIRS gles"
 767 fi
 768 AC_SUBST([API_DEFINES])
 769 AC_SUBST([APIS])
 770
 771 dnl If $with_dri_drivers is yes, directories will be added through
 772 dnl platform checks
 773 DRI_DIRS=""
 774 case "$with_dri_drivers" in
 775 no) ;;
 776 yes)
 777     DRI_DIRS="yes"
 778     ;;
 779 *)
 780     # verify the requested driver directories exist
 781     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 782     for driver in $dri_drivers; do
 783         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 784             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 785     done
 786     DRI_DIRS="$dri_drivers"
 787     ;;
 788 esac
 789
 790 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 791 if test "$mesa_driver" = dri; then
 792     # Use TLS in GLX?
 793     if test "x$GLX_USE_TLS" = xyes; then
 794         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 795     fi
 796
 797     # Platform specific settings and drivers to build
 798     case "$host_os" in
 799     linux*)
 800         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 801         if test "x$driglx_direct" = xyes; then
 802             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 803         fi
 804         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 805
 806         case "$host_cpu" in
 807         x86_64)
 808             # sis is missing because they have not be converted to use
 809             # the new interface.  i810 are missing because there is no
 810             # x86-64 system where they could *ever* be used.
 811             if test "x$DRI_DIRS" = "xyes"; then
 812                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 813                     savage tdfx unichrome swrast"
 814             fi
 815             ;;
 816         powerpc*)
 817             # Build only the drivers for cards that exist on PowerPC.
 818             # At some point MGA will be added, but not yet.
 819             if test "x$DRI_DIRS" = "xyes"; then
 820                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 821             fi
 822             ;;
 823         sparc*)
 824             # Build only the drivers for cards that exist on sparc`
 825             if test "x$DRI_DIRS" = "xyes"; then
 826                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 827             fi
 828             ;;
 829         esac
 830         ;;
 831     freebsd* | dragonfly*)
 832         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 833         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 834         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 835         if test "x$driglx_direct" = xyes; then
 836             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 837         fi
 838         if test "x$GXX" = xyes; then
 839             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 840         fi
 841
 842         if test "x$DRI_DIRS" = "xyes"; then
 843             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 844                 unichrome savage sis swrast"
 845         fi
 846         ;;
 847     gnu*)
 848         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 849         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 850         ;;
 851     solaris*)
 852         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 853         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 854         if test "x$driglx_direct" = xyes; then
 855             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 856         fi
 857         ;;
 858     esac
 859
 860     # default drivers
 861     if test "x$DRI_DIRS" = "xyes"; then
 862         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 863             savage sis tdfx unichrome swrast"
 864     fi
 865
 866     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 867
 868     # Check for expat
 869     EXPAT_INCLUDES=""
 870     EXPAT_LIB=-lexpat
 871     AC_ARG_WITH([expat],
 872         [AS_HELP_STRING([--with-expat=DIR],
 873             [expat install directory])],[
 874         EXPAT_INCLUDES="-I$withval/include"
 875         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 876         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 877         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 878         ])
 879     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 880     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 881         [AC_MSG_ERROR([Expat required for DRI.])])
 882
 883     # put all the necessary libs together
 884     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 885 fi
 886 AC_SUBST([DRI_DIRS])
 887 AC_SUBST([EXPAT_INCLUDES])
 888 AC_SUBST([DRI_LIB_DEPS])
 889
 890 case $DRI_DIRS in
 891 *i915*|*i965*)
 892     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 893     ;;
 894 esac
 895
 896 case $DRI_DIRS in
 897 *radeon*|*r200*|*r300*|*r600*)
 898     PKG_CHECK_MODULES([LIBDRM_RADEON],
 899                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 900                       HAVE_LIBDRM_RADEON=yes,
 901                       HAVE_LIBDRM_RADEON=no)
 902
 903     if test "$HAVE_LIBDRM_RADEON" = yes; then
 904         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 905         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 906     fi
 907     ;;
 908 esac
 909 AC_SUBST([RADEON_CFLAGS])
 910 AC_SUBST([RADEON_LDFLAGS])
 911
 912
 913 dnl
 914 dnl OSMesa configuration
 915 dnl
 916 if test "$mesa_driver" = xlib; then
 917     default_gl_osmesa=yes
 918 else
 919     default_gl_osmesa=no
 920 fi
 921 AC_ARG_ENABLE([gl-osmesa],
 922     [AS_HELP_STRING([--enable-gl-osmesa],
 923         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 924     [gl_osmesa="$enableval"],
 925     [gl_osmesa="$default_gl_osmesa"])
 926 if test "x$gl_osmesa" = xyes; then
 927     if test "$mesa_driver" = osmesa; then
 928         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 929     else
 930         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 931     fi
 932 fi
 933
 934 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 935 AC_ARG_WITH([osmesa-bits],
 936     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 937         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 938     [osmesa_bits="$withval"],
 939     [osmesa_bits=8])
 940 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 941     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 942     osmesa_bits=8
 943 fi
 944 case "x$osmesa_bits" in
 945 x8)
 946     OSMESA_LIB=OSMesa
 947     ;;
 948 x16|x32)
 949     OSMESA_LIB="OSMesa$osmesa_bits"
 950     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 951     ;;
 952 *)
 953     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 954     ;;
 955 esac
 956 AC_SUBST([OSMESA_LIB])
 957
 958 case "$mesa_driver" in
 959 osmesa)
 960     # only link libraries with osmesa if shared
 961     if test "$enable_static" = no; then
 962         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 963     else
 964         OSMESA_LIB_DEPS=""
 965     fi
 966     OSMESA_MESA_DEPS=""
 967     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 968     ;;
 969 *)
 970     # Link OSMesa to libGL otherwise
 971     OSMESA_LIB_DEPS=""
 972     # only link libraries with osmesa if shared
 973     if test "$enable_static" = no; then
 974         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 975     else
 976         OSMESA_MESA_DEPS=""
 977     fi
 978     OSMESA_PC_REQ="gl"
 979     ;;
 980 esac
 981 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 982 AC_SUBST([OSMESA_LIB_DEPS])
 983 AC_SUBST([OSMESA_MESA_DEPS])
 984 AC_SUBST([OSMESA_PC_REQ])
 985 AC_SUBST([OSMESA_PC_LIB_PRIV])
 986
 987 dnl
 988 dnl EGL configuration
 989 dnl
 990 AC_ARG_ENABLE([egl],
 991     [AS_HELP_STRING([--disable-egl],
 992         [disable EGL library @<:@default=enabled@:>@])],
 993     [enable_egl="$enableval"],
 994     [enable_egl=yes])
 995 if test "x$enable_egl" = xyes; then
 996     SRC_DIRS="$SRC_DIRS egl"
 997     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 998     EGL_DRIVERS_DIRS=""
 999     if test "$enable_static" != yes; then
1000         # build egl_glx when libGL is built
1001         if test "$mesa_driver" != osmesa; then
1002             EGL_DRIVERS_DIRS="glx"
1003         fi
1004
1005         # build egl_dri2 when xcb-dri2 is available
1006         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
1007                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1008         if test "$have_xcb_dri2" = yes; then
1009             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
1010         fi
1011     fi
1012
1013     if test "$with_demos" = yes; then
1014         PROGRAM_DIRS="$PROGRAM_DIRS egl/eglut egl/opengl"
1015     fi
1016 fi
1017 AC_SUBST([EGL_LIB_DEPS])
1018 AC_SUBST([EGL_DRIVERS_DIRS])
1019
1020 dnl
1021 dnl GLU configuration
1022 dnl
1023 AC_ARG_ENABLE([glu],
1024     [AS_HELP_STRING([--disable-glu],
1025         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1026     [enable_glu="$enableval"],
1027     [enable_glu=yes])
1028 if test "x$enable_glu" = xyes; then
1029     SRC_DIRS="$SRC_DIRS glu"
1030
1031     case "$mesa_driver" in
1032     osmesa)
1033         # If GLU is available and we have libOSMesa (not 16 or 32),
1034         # we can build the osdemos
1035         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
1036             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
1037         fi
1038
1039         # Link libGLU to libOSMesa instead of libGL
1040         GLU_LIB_DEPS=""
1041         GLU_PC_REQ="osmesa"
1042         if test "$enable_static" = no; then
1043             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1044         else
1045             GLU_MESA_DEPS=""
1046         fi
1047         ;;
1048     *)
1049         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1050         GLU_PC_REQ="gl"
1051         GLU_PC_LIB_PRIV="-lm"
1052         if test "$enable_static" = no; then
1053             GLU_LIB_DEPS="-lm"
1054             GLU_MESA_DEPS='-l$(GL_LIB)'
1055         else
1056             GLU_LIB_DEPS=""
1057             GLU_MESA_DEPS=""
1058             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1059         fi
1060         ;;
1061     esac
1062 fi
1063 if test "$enable_static" = no; then
1064     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1065 fi
1066 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1067 AC_SUBST([GLU_LIB_DEPS])
1068 AC_SUBST([GLU_MESA_DEPS])
1069 AC_SUBST([GLU_PC_REQ])
1070 AC_SUBST([GLU_PC_REQ_PRIV])
1071 AC_SUBST([GLU_PC_LIB_PRIV])
1072 AC_SUBST([GLU_PC_CFLAGS])
1073
1074 dnl
1075 dnl GLw configuration
1076 dnl
1077 AC_ARG_ENABLE([glw],
1078     [AS_HELP_STRING([--disable-glw],
1079         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1080     [enable_glw="$enableval"],
1081     [enable_glw=yes])
1082 dnl Don't build GLw on osmesa
1083 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1084     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1085     enable_glw=no
1086 fi
1087 AC_ARG_ENABLE([motif],
1088     [AS_HELP_STRING([--enable-motif],
1089         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1090     [enable_motif="$enableval"],
1091     [enable_motif=no])
1092
1093 if test "x$enable_glw" = xyes; then
1094     SRC_DIRS="$SRC_DIRS glw"
1095     if test "$x11_pkgconfig" = yes; then
1096         PKG_CHECK_MODULES([GLW],[x11 xt])
1097         GLW_PC_REQ_PRIV="x11 xt"
1098         GLW_LIB_DEPS="$GLW_LIBS"
1099     else
1100         # should check these...
1101         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1102         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1103         GLW_PC_CFLAGS="$X11_INCLUDES"
1104     fi
1105
1106     GLW_SOURCES="GLwDrawA.c"
1107     MOTIF_CFLAGS=
1108     if test "x$enable_motif" = xyes; then
1109         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1110         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1111         if test "x$MOTIF_CONFIG" != xno; then
1112             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1113             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1114         else
1115             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1116                 [AC_MSG_ERROR([Can't locate Motif headers])])
1117             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1118                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1119         fi
1120         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1121         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1122         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1123         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1124     fi
1125
1126     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1127     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1128     if test "$enable_static" = no; then
1129         GLW_MESA_DEPS='-l$(GL_LIB)'
1130         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1131     else
1132         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1133         GLW_LIB_DEPS=""
1134         GLW_MESA_DEPS=""
1135     fi
1136 fi
1137 AC_SUBST([GLW_LIB_DEPS])
1138 AC_SUBST([GLW_MESA_DEPS])
1139 AC_SUBST([GLW_SOURCES])
1140 AC_SUBST([MOTIF_CFLAGS])
1141 AC_SUBST([GLW_PC_REQ_PRIV])
1142 AC_SUBST([GLW_PC_LIB_PRIV])
1143 AC_SUBST([GLW_PC_CFLAGS])
1144
1145 dnl
1146 dnl GLUT configuration
1147 dnl
1148 if test -f "$srcdir/include/GL/glut.h"; then
1149     default_glut=yes
1150 else
1151     default_glut=no
1152 fi
1153 AC_ARG_ENABLE([glut],
1154     [AS_HELP_STRING([--disable-glut],
1155         [enable GLUT library @<:@default=enabled if source available@:>@])],
1156     [enable_glut="$enableval"],
1157     [enable_glut="$default_glut"])
1158
1159 dnl Can't build glut if GLU not available
1160 if test "x$enable_glu$enable_glut" = xnoyes; then
1161     AC_MSG_WARN([Disabling glut since GLU is disabled])
1162     enable_glut=no
1163 fi
1164 dnl Don't build glut on osmesa
1165 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1166     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1167     enable_glut=no
1168 fi
1169
1170 if test "x$enable_glut" = xyes; then
1171     SRC_DIRS="$SRC_DIRS glut/glx"
1172     GLUT_CFLAGS=""
1173     if test "x$GCC" = xyes; then
1174         GLUT_CFLAGS="-fexceptions"
1175     fi
1176     if test "$x11_pkgconfig" = yes; then
1177         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1178         GLUT_PC_REQ_PRIV="x11 xmu xi"
1179         GLUT_LIB_DEPS="$GLUT_LIBS"
1180     else
1181         # should check these...
1182         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1183         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1184         GLUT_PC_CFLAGS="$X11_INCLUDES"
1185     fi
1186     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1187     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1188
1189     # If glut is available, we can build most programs
1190     if test "$with_demos" = yes; then
1191         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1192     fi
1193
1194     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1195     if test "$enable_static" = no; then
1196         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1197     else
1198         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1199         GLUT_LIB_DEPS=""
1200         GLUT_MESA_DEPS=""
1201     fi
1202 fi
1203 AC_SUBST([GLUT_LIB_DEPS])
1204 AC_SUBST([GLUT_MESA_DEPS])
1205 AC_SUBST([GLUT_CFLAGS])
1206 AC_SUBST([GLUT_PC_REQ_PRIV])
1207 AC_SUBST([GLUT_PC_LIB_PRIV])
1208 AC_SUBST([GLUT_PC_CFLAGS])
1209
1210 dnl
1211 dnl Program library dependencies
1212 dnl    Only libm is added here if necessary as the libraries should
1213 dnl    be pulled in by the linker
1214 dnl
1215 if test "x$APP_LIB_DEPS" = x; then
1216     case "$host_os" in
1217     solaris*)
1218         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1219         ;;
1220     cygwin*)
1221         APP_LIB_DEPS="-lX11"
1222         ;;
1223     *)
1224         APP_LIB_DEPS="-lm"
1225         ;;
1226     esac
1227 fi
1228 AC_SUBST([APP_LIB_DEPS])
1229 AC_SUBST([PROGRAM_DIRS])
1230
1231 dnl
1232 dnl Gallium configuration
1233 dnl
1234 AC_ARG_ENABLE([gallium],
1235     [AS_HELP_STRING([--disable-gallium],
1236         [build gallium @<:@default=enabled@:>@])],
1237     [enable_gallium="$enableval"],
1238     [enable_gallium=yes])
1239 if test "x$enable_gallium" = xyes; then
1240     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1241     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1242                 [HAS_UDIS86="no"])
1243     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1244 fi
1245
1246 AC_SUBST([LLVM_CFLAGS])
1247 AC_SUBST([LLVM_LIBS])
1248 AC_SUBST([LLVM_LDFLAGS])
1249 AC_SUBST([LLVM_VERSION])
1250
1251 dnl
1252 dnl Gallium state trackers configuration
1253 dnl
1254 AC_ARG_WITH([state-trackers],
1255     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1256         [comma delimited state_trackers list, e.g.
1257         "egl,glx" @<:@default=auto@:>@])],
1258     [with_state_trackers="$withval"],
1259     [with_state_trackers=yes])
1260
1261 case "$with_state_trackers" in
1262 no)
1263     GALLIUM_STATE_TRACKERS_DIRS=""
1264     ;;
1265 yes)
1266     # look at what else is built
1267     case "$mesa_driver" in
1268     xlib)
1269         GALLIUM_STATE_TRACKERS_DIRS=glx
1270         ;;
1271     dri)
1272         GALLIUM_STATE_TRACKERS_DIRS="dri"
1273         HAVE_ST_DRI="yes"
1274         if test "x$enable_egl" = xyes; then
1275             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1276             HAVE_ST_EGL="yes"
1277         fi
1278         # Have only tested st/xorg on 1.6.0 servers
1279         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1280             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1281             HAVE_ST_XORG="no")
1282         ;;
1283     esac
1284     ;;
1285 *)
1286     # verify the requested state tracker exist
1287     state_trackers=`IFS=', '; echo $with_state_trackers`
1288     for tracker in $state_trackers; do
1289         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1290             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1291
1292         case "$tracker" in
1293         dri)
1294             if test "x$mesa_driver" != xdri; then
1295                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1296             fi
1297             HAVE_ST_DRI="yes"
1298             ;;
1299         egl)
1300             if test "x$enable_egl" != xyes; then
1301                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1302             fi
1303             HAVE_ST_EGL="yes"
1304             ;;
1305         xorg)
1306             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1307             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1308             HAVE_ST_XORG="yes"
1309             ;;
1310         es)
1311             # mesa/es is required to build es state tracker
1312             CORE_DIRS="$CORE_DIRS mesa/es"
1313             ;;
1314         esac
1315     done
1316     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1317     ;;
1318 esac
1319
1320 if test "x$HAVE_ST_XORG" = xyes; then
1321     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1322         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1323         HAVE_XEXTPROTO_71="no")
1324 fi
1325
1326 AC_ARG_WITH([egl-displays],
1327     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1328         [comma delimited native displays libEGL supports, e.g.
1329         "x11,kms" @<:@default=auto@:>@])],
1330     [with_egl_displays="$withval"],
1331     [with_egl_displays=yes])
1332
1333 EGL_DISPLAYS=""
1334 case "$with_egl_displays" in
1335 yes)
1336     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1337         EGL_DISPLAYS="x11"
1338     fi
1339     ;;
1340 *)
1341     if test "x$enable_egl" != xyes; then
1342         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1343     fi
1344     # verify the requested driver directories exist
1345     egl_displays=`IFS=', '; echo $with_egl_displays`
1346     for dpy in $egl_displays; do
1347         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1348             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1349     done
1350     EGL_DISPLAYS="$egl_displays"
1351     ;;
1352 esac
1353 AC_SUBST([EGL_DISPLAYS])
1354
1355 AC_ARG_WITH([egl-driver-dir],
1356     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1357                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1358     [EGL_DRIVER_INSTALL_DIR="$withval"],
1359     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1360 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1361
1362 AC_ARG_WITH([xorg-driver-dir],
1363     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1364                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1365     [XORG_DRIVER_INSTALL_DIR="$withval"],
1366     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1367 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1368
1369 AC_ARG_WITH([max-width],
1370     [AS_HELP_STRING([--with-max-width=N],
1371                     [Maximum framebuffer width (4096)])],
1372     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1373      AS_IF([test "${withval}" -gt "4096"],
1374            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1375 )
1376 AC_ARG_WITH([max-height],
1377     [AS_HELP_STRING([--with-max-height=N],
1378                     [Maximum framebuffer height (4096)])],
1379     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1380      AS_IF([test "${withval}" -gt "4096"],
1381            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1382 )
1383
1384 dnl
1385 dnl Gallium LLVM
1386 dnl
1387 AC_ARG_ENABLE([gallium-llvm],
1388     [AS_HELP_STRING([--enable-gallium-llvm],
1389         [build gallium LLVM support @<:@default=disabled@:>@])],
1390     [enable_gallium_llvm="$enableval"],
1391     [enable_gallium_llvm=auto])
1392 if test "x$enable_gallium_llvm" = xyes; then
1393     if test "x$LLVM_CONFIG" != xno; then
1394         LLVM_VERSION=`$LLVM_CONFIG --version`
1395         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1396         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1397
1398         if test "x$HAS_UDIS86" != xno; then
1399             LLVM_LIBS="$LLVM_LIBS -ludis86"
1400             DEFINES="$DEFINES -DHAVE_UDIS86"
1401         fi
1402         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1403         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1404         DEFINES="$DEFINES -DMESA_LLVM -D__STDC_CONSTANT_MACROS"
1405         MESA_LLVM=1
1406     else
1407         MESA_LLVM=0
1408     fi
1409 else
1410     MESA_LLVM=0
1411 fi
1412
1413 dnl
1414 dnl Gallium helper functions
1415 dnl
1416 gallium_check_st() {
1417     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1418          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1419     fi
1420     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1421          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1422     fi
1423     if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1424          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1425     fi
1426     if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1427          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1428     fi
1429 }
1430
1431
1432 dnl
1433 dnl Gallium SVGA configuration
1434 dnl
1435 AC_ARG_ENABLE([gallium-svga],
1436     [AS_HELP_STRING([--enable-gallium-svga],
1437         [build gallium SVGA @<:@default=disabled@:>@])],
1438     [enable_gallium_svga="$enableval"],
1439     [enable_gallium_svga=auto])
1440 if test "x$enable_gallium_svga" = xyes; then
1441     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1442     gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1443 elif test "x$enable_gallium_svga" = xauto; then
1444     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1445 fi
1446
1447 dnl
1448 dnl Gallium Intel configuration
1449 dnl
1450 AC_ARG_ENABLE([gallium-intel],
1451     [AS_HELP_STRING([--enable-gallium-intel],
1452         [build gallium intel @<:@default=disabled@:>@])],
1453     [enable_gallium_intel="$enableval"],
1454     [enable_gallium_intel=auto])
1455 if test "x$enable_gallium_intel" = xyes; then
1456     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1457     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1458     gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1459 elif test "x$enable_gallium_intel" = xauto; then
1460     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1461     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1462 fi
1463
1464 dnl
1465 dnl Gallium Radeon configuration
1466 dnl
1467 AC_ARG_ENABLE([gallium-radeon],
1468     [AS_HELP_STRING([--enable-gallium-radeon],
1469         [build gallium radeon @<:@default=disabled@:>@])],
1470     [enable_gallium_radeon="$enableval"],
1471     [enable_gallium_radeon=auto])
1472 if test "x$enable_gallium_radeon" = xyes; then
1473     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1474     gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1475 elif test "x$enable_gallium_radeon" = xauto; then
1476     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1477 fi
1478
1479 dnl
1480 dnl Gallium Nouveau configuration
1481 dnl
1482 AC_ARG_ENABLE([gallium-nouveau],
1483     [AS_HELP_STRING([--enable-gallium-nouveau],
1484         [build gallium nouveau @<:@default=disabled@:>@])],
1485     [enable_gallium_nouveau="$enableval"],
1486     [enable_gallium_nouveau=no])
1487 if test "x$enable_gallium_nouveau" = xyes; then
1488     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1489     gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1490 fi
1491
1492 dnl
1493 dnl Gallium swrast configuration
1494 dnl
1495 AC_ARG_ENABLE([gallium-swrast],
1496     [AS_HELP_STRING([--enable-gallium-swrast],
1497         [build gallium swrast @<:@default=auto@:>@])],
1498     [enable_gallium_swrast="$enableval"],
1499     [enable_gallium_swrast=auto])
1500 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1501     if test "x$HAVE_ST_DRI" = xyes; then
1502         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1503     fi
1504     if test "x$HAVE_ST_EGL" = xyes; then
1505         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1506     fi
1507 fi
1508
1509 dnl prepend CORE_DIRS to SRC_DIRS
1510 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1511
1512 dnl Restore LDFLAGS and CPPFLAGS
1513 LDFLAGS="$_SAVE_LDFLAGS"
1514 CPPFLAGS="$_SAVE_CPPFLAGS"
1515
1516 dnl Substitute the config
1517 AC_CONFIG_FILES([configs/autoconf])
1518
1519 dnl Replace the configs/current symlink
1520 AC_CONFIG_COMMANDS([configs],[
1521 if test -f configs/current || test -L configs/current; then
1522     rm -f configs/current
1523 fi
1524 ln -s autoconf configs/current
1525 ])
1526
1527 AC_OUTPUT
1528
1529 dnl
1530 dnl Output some configuration info for the user
1531 dnl
1532 echo ""
1533 echo "        prefix:          $prefix"
1534 echo "        exec_prefix:     $exec_prefix"
1535 echo "        libdir:          $libdir"
1536 echo "        includedir:      $includedir"
1537
1538 dnl Driver info
1539 echo ""
1540 echo "        Driver:          $mesa_driver"
1541 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1542     echo "        OSMesa:          lib$OSMESA_LIB"
1543 else
1544     echo "        OSMesa:          no"
1545 fi
1546 if test "$mesa_driver" = dri; then
1547     # cleanup the drivers var
1548     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1549 if test "x$DRI_DIRS" = x; then
1550     echo "        DRI drivers:     no"
1551 else
1552     echo "        DRI drivers:     $dri_dirs"
1553 fi
1554     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1555 fi
1556 echo "        Use XCB:         $enable_xcb"
1557
1558 echo ""
1559 if test "x$MESA_LLVM" == x1; then
1560     echo "        llvm:            yes"
1561     echo "        llvm-config:     $LLVM_CONFIG"
1562     echo "        llvm-version:    $LLVM_VERSION"
1563 else
1564     echo "        llvm:            no"
1565 fi
1566
1567 echo ""
1568 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1569     echo "        Gallium:         yes"
1570     echo "        Gallium dirs:    $GALLIUM_DIRS"
1571     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1572     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1573     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1574     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1575 else
1576     echo "        Gallium:         no"
1577 fi
1578
1579 dnl Libraries
1580 echo ""
1581 echo "        Shared libs:     $enable_shared"
1582 echo "        Static libs:     $enable_static"
1583 if test "$enable_egl" = yes; then
1584     echo "        EGL:             $EGL_DRIVERS_DIRS"
1585 else
1586     echo "        EGL:             no"
1587 fi
1588 echo "        GLU:             $enable_glu"
1589 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1590 echo "        glut:            $enable_glut"
1591
1592 dnl Programs
1593 # cleanup the programs var for display
1594 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1595 if test "x$program_dirs" = x; then
1596     echo "        Demos:           no"
1597 else
1598     echo "        Demos:           $program_dirs"
1599 fi
1600
1601 dnl Compiler options
1602 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1603 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1604     $SED 's/^ *//;s/  */ /;s/ *$//'`
1605 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1606     $SED 's/^ *//;s/  */ /;s/ *$//'`
1607 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1608 echo ""
1609 echo "        CFLAGS:          $cflags"
1610 echo "        CXXFLAGS:        $cxxflags"
1611 echo "        Macros:          $defines"
1612
1613 echo ""
1614 echo "        Run '${MAKE-make}' to build Mesa"
1615 echo ""