configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.23
  22 LIBDRM_RADEON_REQUIRED=2.4.23
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.23
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319
 320 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330
 331 AC_SUBST([GL_LIB_NAME])
 332 AC_SUBST([GLU_LIB_NAME])
 333 AC_SUBST([GLUT_LIB_NAME])
 334 AC_SUBST([GLW_LIB_NAME])
 335 AC_SUBST([OSMESA_LIB_NAME])
 336 AC_SUBST([EGL_LIB_NAME])
 337 AC_SUBST([GLESv1_CM_LIB_NAME])
 338 AC_SUBST([GLESv2_LIB_NAME])
 339 AC_SUBST([VG_LIB_NAME])
 340
 341 AC_SUBST([GL_LIB_GLOB])
 342 AC_SUBST([GLU_LIB_GLOB])
 343 AC_SUBST([GLUT_LIB_GLOB])
 344 AC_SUBST([GLW_LIB_GLOB])
 345 AC_SUBST([OSMESA_LIB_GLOB])
 346 AC_SUBST([EGL_LIB_GLOB])
 347 AC_SUBST([GLESv1_CM_LIB_GLOB])
 348 AC_SUBST([GLESv2_LIB_GLOB])
 349 AC_SUBST([VG_LIB_GLOB])
 350
 351 dnl
 352 dnl Arch/platform-specific settings
 353 dnl
 354 AC_ARG_ENABLE([asm],
 355     [AS_HELP_STRING([--disable-asm],
 356         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 357     [enable_asm="$enableval"],
 358     [enable_asm=yes]
 359 )
 360 asm_arch=""
 361 ASM_FLAGS=""
 362 MESA_ASM_SOURCES=""
 363 GLAPI_ASM_SOURCES=""
 364 AC_MSG_CHECKING([whether to enable assembly])
 365 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 366 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 367 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 368     case "$host_cpu" in
 369     i?86 | x86_64)
 370         enable_asm=no
 371         AC_MSG_RESULT([no, cross compiling])
 372         ;;
 373     esac
 374 fi
 375 # check for supported arches
 376 if test "x$enable_asm" = xyes; then
 377     case "$host_cpu" in
 378     i?86)
 379         case "$host_os" in
 380         linux* | *freebsd* | dragonfly* | *netbsd*)
 381             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 382             ;;
 383         esac
 384         ;;
 385     x86_64)
 386         case "$host_os" in
 387         linux* | *freebsd* | dragonfly* | *netbsd*)
 388             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 389             ;;
 390         esac
 391         ;;
 392     powerpc)
 393         case "$host_os" in
 394         linux*)
 395             asm_arch=ppc
 396             ;;
 397         esac
 398         ;;
 399     sparc*)
 400         case "$host_os" in
 401         linux*)
 402             asm_arch=sparc
 403             ;;
 404         esac
 405         ;;
 406     esac
 407
 408     case "$asm_arch" in
 409     x86)
 410         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 411         MESA_ASM_SOURCES='$(X86_SOURCES)'
 412         GLAPI_ASM_SOURCES='$(X86_API)'
 413         AC_MSG_RESULT([yes, x86])
 414         ;;
 415     x86_64)
 416         ASM_FLAGS="-DUSE_X86_64_ASM"
 417         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 418         GLAPI_ASM_SOURCES='$(X86-64_API)'
 419         AC_MSG_RESULT([yes, x86_64])
 420         ;;
 421     ppc)
 422         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 423         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 424         AC_MSG_RESULT([yes, ppc])
 425         ;;
 426     sparc)
 427         ASM_FLAGS="-DUSE_SPARC_ASM"
 428         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 429         GLAPI_ASM_SOURCES='$(SPARC_API)'
 430         AC_MSG_RESULT([yes, sparc])
 431         ;;
 432     *)
 433         AC_MSG_RESULT([no, platform not supported])
 434         ;;
 435     esac
 436 fi
 437 AC_SUBST([ASM_FLAGS])
 438 AC_SUBST([MESA_ASM_SOURCES])
 439 AC_SUBST([GLAPI_ASM_SOURCES])
 440
 441 dnl PIC code macro
 442 MESA_PIC_FLAGS
 443
 444 dnl Check to see if dlopen is in default libraries (like Solaris, which
 445 dnl has it in libc), or if libdl is needed to get it.
 446 AC_CHECK_FUNC([dlopen], [],
 447     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 448 AC_SUBST([DLOPEN_LIBS])
 449
 450 dnl See if posix_memalign is available
 451 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 452
 453 dnl SELinux awareness.
 454 AC_ARG_ENABLE([selinux],
 455     [AS_HELP_STRING([--enable-selinux],
 456         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 457     [MESA_SELINUX="$enableval"],
 458     [MESA_SELINUX=no])
 459 if test "x$enable_selinux" = "xyes"; then
 460     AC_CHECK_HEADER([selinux/selinux.h],[],
 461                     [AC_MSG_ERROR([SELinux headers not found])])
 462     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 463                  [AC_MSG_ERROR([SELinux library not found])])
 464     SELINUX_LIBS="-lselinux"
 465     DEFINES="$DEFINES -DMESA_SELINUX"
 466 fi
 467
 468 dnl Determine which APIs to support
 469 AC_ARG_ENABLE([opengl],
 470     [AS_HELP_STRING([--disable-opengl],
 471         [disable support for standard OpenGL API @<:@default=no@:>@])],
 472     [enable_opengl="$enableval"],
 473     [enable_opengl=yes])
 474 AC_ARG_ENABLE([gles1],
 475     [AS_HELP_STRING([--enable-gles1],
 476         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 477     [enable_gles1="$enableval"],
 478     [enable_gles1=no])
 479 AC_ARG_ENABLE([gles2],
 480     [AS_HELP_STRING([--enable-gles2],
 481         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 482     [enable_gles2="$enableval"],
 483     [enable_gles2=no])
 484 AC_ARG_ENABLE([gles-overlay],
 485     [AS_HELP_STRING([--enable-gles-overlay],
 486         [DEPRECATED.  Same as --enable-gles1 and --enable-gles2])],
 487     [enable_gles1="$enableval"; enable_gles2="$enableval"],
 488     [])
 489
 490 AC_ARG_ENABLE([openvg],
 491     [AS_HELP_STRING([--enable-openvg],
 492         [enable support for OpenVG API @<:@default=no@:>@])],
 493     [enable_openvg="$enableval"],
 494     [enable_openvg=no])
 495
 496 dnl smooth the transition; should be removed eventually
 497 if test "x$enable_openvg" = xno; then
 498     case "x$with_state_trackers" in
 499     x*vega*)
 500         AC_MSG_WARN([vega state tracker is enabled without --enable-openvg])
 501         enable_openvg=yes
 502         ;;
 503     esac
 504 fi
 505
 506 if test "x$enable_opengl" = xno -a \
 507         "x$enable_gles1" = xno -a \
 508         "x$enable_gles2" = xno -a \
 509         "x$enable_openvg" = xno; then
 510     AC_MSG_ERROR([at least one API should be enabled])
 511 fi
 512
 513 API_DEFINES=""
 514 if test "x$enable_opengl" = xno; then
 515     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 516 else
 517     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 518 fi
 519 if test "x$enable_gles1" = xyes; then
 520     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 521 fi
 522 if test "x$enable_gles2" = xyes; then
 523     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 524 fi
 525 AC_SUBST([API_DEFINES])
 526
 527 dnl
 528 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 529 dnl More later: fbdev, ...
 530 dnl
 531 default_driver="xlib"
 532
 533 case "$host_os" in
 534 linux*)
 535     case "$host_cpu" in
 536     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 537     esac
 538     ;;
 539 *freebsd* | dragonfly* | *netbsd*)
 540     case "$host_cpu" in
 541     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 542     esac
 543     ;;
 544 esac
 545
 546 if test "x$enable_opengl" = xno; then
 547     default_driver="no"
 548 fi
 549
 550 AC_ARG_WITH([driver],
 551     [AS_HELP_STRING([--with-driver=DRIVER],
 552         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 553     [mesa_driver="$withval"],
 554     [mesa_driver="$default_driver"])
 555 dnl Check for valid option
 556 case "x$mesa_driver" in
 557 xxlib|xdri|xosmesa)
 558     if test "x$enable_opengl" = xno; then
 559         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 560     fi
 561     ;;
 562 xno)
 563     ;;
 564 *)
 565     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 566     ;;
 567 esac
 568
 569 PKG_CHECK_MODULES([TALLOC], [talloc])
 570 AC_SUBST([TALLOC_LIBS])
 571 AC_SUBST([TALLOC_CFLAGS])
 572
 573 dnl
 574 dnl Driver specific build directories
 575 dnl
 576
 577 dnl this variable will be prepended to SRC_DIRS and is not exported
 578 CORE_DIRS=""
 579
 580 SRC_DIRS=""
 581 GLU_DIRS="sgi"
 582 GALLIUM_DIRS="auxiliary drivers state_trackers"
 583 GALLIUM_TARGET_DIRS=""
 584 GALLIUM_WINSYS_DIRS="sw"
 585 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug noop identity"
 586 GALLIUM_STATE_TRACKERS_DIRS=""
 587
 588 # build glapi if OpenGL is enabled
 589 if test "x$enable_opengl" = xyes; then
 590     CORE_DIRS="$CORE_DIRS mapi/glapi"
 591 fi
 592
 593 # build es1api if OpenGL ES 1.x is enabled
 594 if test "x$enable_gles1" = xyes; then
 595     CORE_DIRS="$CORE_DIRS mapi/es1api"
 596 fi
 597
 598 # build es2api if OpenGL ES 2.x is enabled
 599 if test "x$enable_gles2" = xyes; then
 600     CORE_DIRS="$CORE_DIRS mapi/es2api"
 601 fi
 602
 603 # build vgapi if OpenVG is enabled
 604 if test "x$enable_openvg" = xyes; then
 605     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 606 fi
 607
 608 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 609 case "x$enable_opengl$enable_gles1$enable_gles2" in
 610 x*yes*)
 611     CORE_DIRS="$CORE_DIRS glsl mesa"
 612     ;;
 613 esac
 614
 615 case "$mesa_driver" in
 616 xlib)
 617     DRIVER_DIRS="x11"
 618     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 619     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 620     ;;
 621 dri)
 622     SRC_DIRS="$SRC_DIRS glx"
 623     DRIVER_DIRS="dri"
 624     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 625     ;;
 626 osmesa)
 627     DRIVER_DIRS="osmesa"
 628     ;;
 629 no)
 630     DRIVER_DRIS=""
 631     ;;
 632 esac
 633 AC_SUBST([SRC_DIRS])
 634 AC_SUBST([GLU_DIRS])
 635 AC_SUBST([DRIVER_DIRS])
 636 AC_SUBST([GALLIUM_DIRS])
 637 AC_SUBST([GALLIUM_TARGET_DIRS])
 638 AC_SUBST([GALLIUM_WINSYS_DIRS])
 639 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 640 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 641 AC_SUBST([MESA_LLVM])
 642
 643 dnl
 644 dnl Find out if X is available. The variable have_x is set if libX11 is
 645 dnl found to mimic AC_PATH_XTRA.
 646 dnl
 647 if test -n "$PKG_CONFIG"; then
 648     AC_MSG_CHECKING([pkg-config files for X11 are available])
 649     PKG_CHECK_EXISTS([x11],[
 650         x11_pkgconfig=yes
 651         have_x=yes
 652         ],[
 653         x11_pkgconfig=no
 654     ])
 655     AC_MSG_RESULT([$x11_pkgconfig])
 656 else
 657     x11_pkgconfig=no
 658 fi
 659 dnl Use the autoconf macro if no pkg-config files
 660 if test "$x11_pkgconfig" = yes; then
 661     PKG_CHECK_MODULES([X11], [x11])
 662 else
 663     AC_PATH_XTRA
 664     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 665     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 666     AC_SUBST([X11_CFLAGS])
 667     AC_SUBST([X11_LIBS])
 668 fi
 669
 670 dnl Try to tell the user that the --x-* options are only used when
 671 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 672 m4_divert_once([HELP_BEGIN],
 673 [These options are only used when the X libraries cannot be found by the
 674 pkg-config utility.])
 675
 676 dnl We need X for xlib and dri, so bomb now if it's not found
 677 case "$mesa_driver" in
 678 xlib|dri)
 679     if test "$no_x" = yes; then
 680         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 681     fi
 682     ;;
 683 esac
 684
 685 dnl XCB - this is only used for GLX right now
 686 AC_ARG_ENABLE([xcb],
 687     [AS_HELP_STRING([--enable-xcb],
 688         [use XCB for GLX @<:@default=disabled@:>@])],
 689     [enable_xcb="$enableval"],
 690     [enable_xcb=no])
 691 if test "x$enable_xcb" = xyes; then
 692     DEFINES="$DEFINES -DUSE_XCB"
 693 else
 694     enable_xcb=no
 695 fi
 696
 697 dnl
 698 dnl libGL configuration per driver
 699 dnl
 700 case "$mesa_driver" in
 701 xlib)
 702     if test "$x11_pkgconfig" = yes; then
 703         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 704         GL_PC_REQ_PRIV="x11 xext"
 705         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 706         GL_LIB_DEPS="$XLIBGL_LIBS"
 707     else
 708         # should check these...
 709         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 710         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 711         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 712         GL_PC_CFLAGS="$X11_INCLUDES"
 713     fi
 714     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 715     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 716
 717     # if static, move the external libraries to the programs
 718     # and empty the libraries for libGL
 719     if test "$enable_static" = yes; then
 720         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 721         GL_LIB_DEPS=""
 722     fi
 723     ;;
 724 dri|no) # these checks are still desired when there is no mesa_driver
 725     # DRI must be shared, I think
 726     if test "$enable_static" = yes; then
 727         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 728     fi
 729
 730     # Check for libdrm
 731     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 732     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 733     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 734     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 735     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 736
 737     # find the DRI deps for libGL
 738     if test "$x11_pkgconfig" = yes; then
 739         dri_modules="x11 xext xdamage xfixes"
 740
 741         # add xf86vidmode if available
 742         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 743         if test "$HAVE_XF86VIDMODE" = yes ; then
 744             dri_modules="$dri_modules xxf86vm"
 745         fi
 746
 747         # add xcb modules if necessary
 748         if test "$enable_xcb" = yes; then
 749             dri_modules="$dri_modules x11-xcb xcb-glx"
 750         fi
 751
 752         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 753         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 754         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 755         GL_LIB_DEPS="$DRIGL_LIBS"
 756     else
 757         # should check these...
 758         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 759         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 760         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 761         GL_PC_CFLAGS="$X11_INCLUDES"
 762
 763         # XCB can only be used from pkg-config
 764         if test "$enable_xcb" = yes; then
 765             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 766             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 767             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 768             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 769         fi
 770     fi
 771
 772     # need DRM libs, -lpthread, etc.
 773     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 774     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 775     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 776     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 777     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 778     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 779     ;;
 780 osmesa)
 781     # No libGL for osmesa
 782     GL_LIB_DEPS=""
 783     ;;
 784 esac
 785 AC_SUBST([GL_LIB_DEPS])
 786 AC_SUBST([GL_PC_REQ_PRIV])
 787 AC_SUBST([GL_PC_LIB_PRIV])
 788 AC_SUBST([GL_PC_CFLAGS])
 789 AC_SUBST([DRI_PC_REQ_PRIV])
 790 AC_SUBST([GLESv1_CM_LIB_DEPS])
 791 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 792 AC_SUBST([GLESv2_LIB_DEPS])
 793 AC_SUBST([GLESv2_PC_LIB_PRIV])
 794
 795
 796 AC_SUBST([HAVE_XF86VIDMODE])
 797
 798 PKG_CHECK_MODULES([LIBDRM_RADEON],
 799                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 800                   HAVE_LIBDRM_RADEON=yes,
 801                   HAVE_LIBDRM_RADEON=no)
 802
 803 dnl
 804 dnl More X11 setup
 805 dnl
 806 if test "$mesa_driver" = xlib; then
 807     DEFINES="$DEFINES -DUSE_XSHM"
 808 fi
 809
 810 dnl
 811 dnl TLS detection
 812 dnl
 813
 814 AC_ARG_ENABLE([glx-tls],
 815     [AS_HELP_STRING([--enable-glx-tls],
 816         [enable TLS support in GLX @<:@default=disabled@:>@])],
 817     [GLX_USE_TLS="$enableval"],
 818     [GLX_USE_TLS=no])
 819 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 820
 821 dnl
 822 dnl More DRI setup
 823 dnl
 824 dnl Directory for DRI drivers
 825 AC_ARG_WITH([dri-driverdir],
 826     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 827         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 828     [DRI_DRIVER_INSTALL_DIR="$withval"],
 829     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 830 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 831 dnl Extra search path for DRI drivers
 832 AC_ARG_WITH([dri-searchpath],
 833     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 834         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 835     [DRI_DRIVER_SEARCH_DIR="$withval"],
 836     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 837 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 838 dnl Direct rendering or just indirect rendering
 839 AC_ARG_ENABLE([driglx-direct],
 840     [AS_HELP_STRING([--disable-driglx-direct],
 841         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 842     [driglx_direct="$enableval"],
 843     [driglx_direct="yes"])
 844 dnl Which drivers to build - default is chosen by platform
 845 AC_ARG_WITH([dri-drivers],
 846     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 847         [comma delimited DRI drivers list, e.g.
 848         "swrast,i965,radeon" @<:@default=auto@:>@])],
 849     [with_dri_drivers="$withval"],
 850     [with_dri_drivers=yes])
 851 if test "x$with_dri_drivers" = x; then
 852     with_dri_drivers=no
 853 fi
 854
 855 dnl If $with_dri_drivers is yes, directories will be added through
 856 dnl platform checks
 857 DRI_DIRS=""
 858 case "$with_dri_drivers" in
 859 no) ;;
 860 yes)
 861     DRI_DIRS="yes"
 862     ;;
 863 *)
 864     # verify the requested driver directories exist
 865     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 866     for driver in $dri_drivers; do
 867         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 868             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 869     done
 870     DRI_DIRS="$dri_drivers"
 871     ;;
 872 esac
 873
 874 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 875 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 876     # Use TLS in GLX?
 877     if test "x$GLX_USE_TLS" = xyes; then
 878         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 879     fi
 880
 881     # Platform specific settings and drivers to build
 882     case "$host_os" in
 883     linux*)
 884         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 885         if test "x$driglx_direct" = xyes; then
 886             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 887         fi
 888         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 889
 890         case "$host_cpu" in
 891         x86_64)
 892             # sis is missing because they have not be converted to use
 893             # the new interface.  i810 are missing because there is no
 894             # x86-64 system where they could *ever* be used.
 895             if test "x$DRI_DIRS" = "xyes"; then
 896                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 897                     savage tdfx unichrome swrast"
 898             fi
 899             ;;
 900         powerpc*)
 901             # Build only the drivers for cards that exist on PowerPC.
 902             # At some point MGA will be added, but not yet.
 903             if test "x$DRI_DIRS" = "xyes"; then
 904                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 905             fi
 906             ;;
 907         sparc*)
 908             # Build only the drivers for cards that exist on sparc`
 909             if test "x$DRI_DIRS" = "xyes"; then
 910                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 911             fi
 912             ;;
 913         esac
 914         ;;
 915     freebsd* | dragonfly* | *netbsd*)
 916         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 917         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 918         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 919         if test "x$driglx_direct" = xyes; then
 920             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 921         fi
 922
 923         if test "x$DRI_DIRS" = "xyes"; then
 924             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 925                 unichrome savage sis swrast"
 926         fi
 927         ;;
 928     gnu*)
 929         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 930         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 931         ;;
 932     solaris*)
 933         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 934         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 935         if test "x$driglx_direct" = xyes; then
 936             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 937         fi
 938         ;;
 939     esac
 940
 941     # default drivers
 942     if test "x$DRI_DIRS" = "xyes"; then
 943         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 944             savage sis tdfx unichrome swrast"
 945     fi
 946
 947     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 948
 949     # Check for expat
 950     if test "$mesa_driver" = dri; then
 951         EXPAT_INCLUDES=""
 952         EXPAT_LIB=-lexpat
 953         AC_ARG_WITH([expat],
 954             [AS_HELP_STRING([--with-expat=DIR],
 955                 [expat install directory])],[
 956             EXPAT_INCLUDES="-I$withval/include"
 957             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 958             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 959             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 960             ])
 961         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 962         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 963             [AC_MSG_ERROR([Expat required for DRI.])])
 964     fi
 965
 966     # put all the necessary libs together
 967     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 968 fi
 969 AC_SUBST([DRI_DIRS])
 970 AC_SUBST([EXPAT_INCLUDES])
 971 AC_SUBST([DRI_LIB_DEPS])
 972
 973 case $DRI_DIRS in
 974 *i915*|*i965*)
 975     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.23])
 976     ;;
 977 esac
 978
 979 case $DRI_DIRS in
 980 *radeon*|*r200*|*r300*|*r600*)
 981     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
 982         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 983         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 984     fi
 985     ;;
 986 esac
 987 AC_SUBST([RADEON_CFLAGS])
 988 AC_SUBST([RADEON_LDFLAGS])
 989
 990
 991 dnl
 992 dnl OSMesa configuration
 993 dnl
 994 if test "$mesa_driver" = xlib; then
 995     default_gl_osmesa=yes
 996 else
 997     default_gl_osmesa=no
 998 fi
 999 AC_ARG_ENABLE([gl-osmesa],
1000     [AS_HELP_STRING([--enable-gl-osmesa],
1001         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
1002     [gl_osmesa="$enableval"],
1003     [gl_osmesa="$default_gl_osmesa"])
1004 if test "x$gl_osmesa" = xyes; then
1005     if test "x$enable_opengl" = xno; then
1006         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
1007     fi
1008     if test "$mesa_driver" = osmesa; then
1009         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1010     else
1011         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1012     fi
1013 fi
1014
1015 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1016 AC_ARG_WITH([osmesa-bits],
1017     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1018         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1019     [osmesa_bits="$withval"],
1020     [osmesa_bits=8])
1021 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1022     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1023     osmesa_bits=8
1024 fi
1025 case "x$osmesa_bits" in
1026 x8)
1027     OSMESA_LIB=OSMesa
1028     ;;
1029 x16|x32)
1030     OSMESA_LIB="OSMesa$osmesa_bits"
1031     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1032     ;;
1033 *)
1034     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1035     ;;
1036 esac
1037 AC_SUBST([OSMESA_LIB])
1038
1039 case "$DRIVER_DIRS" in
1040 *osmesa*)
1041     # only link libraries with osmesa if shared
1042     if test "$enable_static" = no; then
1043         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1044     else
1045         OSMESA_LIB_DEPS=""
1046     fi
1047     OSMESA_MESA_DEPS=""
1048     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1049     ;;
1050 esac
1051 AC_SUBST([OSMESA_LIB_DEPS])
1052 AC_SUBST([OSMESA_MESA_DEPS])
1053 AC_SUBST([OSMESA_PC_REQ])
1054 AC_SUBST([OSMESA_PC_LIB_PRIV])
1055
1056 dnl
1057 dnl EGL configuration
1058 dnl
1059 AC_ARG_ENABLE([egl],
1060     [AS_HELP_STRING([--disable-egl],
1061         [disable EGL library @<:@default=enabled@:>@])],
1062     [enable_egl="$enableval"],
1063     [enable_egl=yes])
1064 if test "x$enable_egl" = xno; then
1065     if test "x$mesa_driver" = xno; then
1066         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1067     fi
1068     if test "x$enable_openvg" = xyes; then
1069         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1070     fi
1071 fi
1072 if test "x$enable_egl" = xyes; then
1073     SRC_DIRS="$SRC_DIRS egl"
1074     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1075     EGL_DRIVERS_DIRS=""
1076     if test "$enable_static" != yes; then
1077         # build egl_glx when libGL is built
1078         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1079             EGL_DRIVERS_DIRS="glx"
1080         fi
1081
1082         if test "$mesa_driver" = dri; then
1083             # build egl_dri2 when xcb-dri2 is available
1084             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1085                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1086             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1087                           [have_libudev=yes],[have_libudev=no])
1088
1089             if test "$have_xcb_dri2" = yes; then
1090                 EGL_DRIVER_DRI2=dri2
1091                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1092                 if test "$have_libudev" = yes; then
1093                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1094                 fi
1095             fi
1096         fi
1097
1098         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1099     fi
1100 fi
1101 AC_SUBST([EGL_LIB_DEPS])
1102 AC_SUBST([EGL_DRIVERS_DIRS])
1103
1104 dnl
1105 dnl GLU configuration
1106 dnl
1107 AC_ARG_ENABLE([glu],
1108     [AS_HELP_STRING([--disable-glu],
1109         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1110     [enable_glu="$enableval"],
1111     [enable_glu=yes])
1112
1113 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1114     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1115     enable_glu=no
1116 fi
1117
1118 if test "x$enable_glu" = xyes; then
1119     SRC_DIRS="$SRC_DIRS glu"
1120
1121     case "$mesa_driver" in
1122     osmesa)
1123         # Link libGLU to libOSMesa instead of libGL
1124         GLU_LIB_DEPS=""
1125         GLU_PC_REQ="osmesa"
1126         if test "$enable_static" = no; then
1127             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1128         else
1129             GLU_MESA_DEPS=""
1130         fi
1131         ;;
1132     *)
1133         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1134         GLU_PC_REQ="gl"
1135         GLU_PC_LIB_PRIV="-lm"
1136         if test "$enable_static" = no; then
1137             GLU_LIB_DEPS="-lm"
1138             GLU_MESA_DEPS='-l$(GL_LIB)'
1139         else
1140             GLU_LIB_DEPS=""
1141             GLU_MESA_DEPS=""
1142             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1143         fi
1144         ;;
1145     esac
1146 fi
1147 if test "$enable_static" = no; then
1148     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1149 fi
1150 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1151 AC_SUBST([GLU_LIB_DEPS])
1152 AC_SUBST([GLU_MESA_DEPS])
1153 AC_SUBST([GLU_PC_REQ])
1154 AC_SUBST([GLU_PC_REQ_PRIV])
1155 AC_SUBST([GLU_PC_LIB_PRIV])
1156 AC_SUBST([GLU_PC_CFLAGS])
1157
1158 dnl
1159 dnl GLw configuration
1160 dnl
1161 AC_ARG_ENABLE([glw],
1162     [AS_HELP_STRING([--disable-glw],
1163         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1164     [enable_glw="$enableval"],
1165     [enable_glw=yes])
1166 dnl Don't build GLw on osmesa
1167 if test "x$enable_glw" = xyes; then
1168     case "$mesa_driver" in
1169     osmesa|no)
1170         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1171         enable_glw=no
1172         ;;
1173     esac
1174 fi
1175 AC_ARG_ENABLE([motif],
1176     [AS_HELP_STRING([--enable-motif],
1177         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1178     [enable_motif="$enableval"],
1179     [enable_motif=no])
1180
1181 if test "x$enable_glw" = xyes; then
1182     SRC_DIRS="$SRC_DIRS glw"
1183     if test "$x11_pkgconfig" = yes; then
1184         PKG_CHECK_MODULES([GLW],[x11 xt])
1185         GLW_PC_REQ_PRIV="x11 xt"
1186         GLW_LIB_DEPS="$GLW_LIBS"
1187     else
1188         # should check these...
1189         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1190         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1191         GLW_PC_CFLAGS="$X11_INCLUDES"
1192     fi
1193
1194     GLW_SOURCES="GLwDrawA.c"
1195     MOTIF_CFLAGS=
1196     if test "x$enable_motif" = xyes; then
1197         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1198         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1199         if test "x$MOTIF_CONFIG" != xno; then
1200             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1201             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1202         else
1203             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1204                 [AC_MSG_ERROR([Can't locate Motif headers])])
1205             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1206                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1207         fi
1208         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1209         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1210         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1211         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1212     fi
1213
1214     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1215     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1216     if test "$enable_static" = no; then
1217         GLW_MESA_DEPS='-l$(GL_LIB)'
1218         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1219     else
1220         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1221         GLW_LIB_DEPS=""
1222         GLW_MESA_DEPS=""
1223     fi
1224 fi
1225 AC_SUBST([GLW_LIB_DEPS])
1226 AC_SUBST([GLW_MESA_DEPS])
1227 AC_SUBST([GLW_SOURCES])
1228 AC_SUBST([MOTIF_CFLAGS])
1229 AC_SUBST([GLW_PC_REQ_PRIV])
1230 AC_SUBST([GLW_PC_LIB_PRIV])
1231 AC_SUBST([GLW_PC_CFLAGS])
1232
1233 dnl
1234 dnl GLUT configuration
1235 dnl
1236 if test -f "$srcdir/include/GL/glut.h"; then
1237     default_glut=yes
1238 else
1239     default_glut=no
1240 fi
1241 AC_ARG_ENABLE([glut],
1242     [AS_HELP_STRING([--disable-glut],
1243         [enable GLUT library @<:@default=enabled if source available@:>@])],
1244     [enable_glut="$enableval"],
1245     [enable_glut="$default_glut"])
1246
1247 dnl Don't build glut on osmesa
1248 if test "x$enable_glut" = xyes; then
1249     case "$mesa_driver" in
1250     osmesa|no)
1251         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1252         enable_glut=no
1253         ;;
1254     esac
1255 fi
1256 dnl Can't build glut if GLU not available
1257 if test "x$enable_glu$enable_glut" = xnoyes; then
1258     AC_MSG_WARN([Disabling glut since GLU is disabled])
1259     enable_glut=no
1260 fi
1261
1262 if test "x$enable_glut" = xyes; then
1263     SRC_DIRS="$SRC_DIRS glut/glx"
1264     if test "$x11_pkgconfig" = yes; then
1265         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1266         GLUT_PC_REQ_PRIV="x11 xmu xi"
1267         GLUT_LIB_DEPS="$GLUT_LIBS"
1268     else
1269         # should check these...
1270         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1271         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1272         GLUT_PC_CFLAGS="$X11_INCLUDES"
1273     fi
1274     if test "x$GCC" = xyes; then
1275         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1276     fi
1277     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1278     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1279
1280     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1281     if test "$enable_static" = no; then
1282         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1283     else
1284         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1285         GLUT_LIB_DEPS=""
1286         GLUT_MESA_DEPS=""
1287     fi
1288 fi
1289 AC_SUBST([GLUT_LIB_DEPS])
1290 AC_SUBST([GLUT_MESA_DEPS])
1291 AC_SUBST([GLUT_CFLAGS])
1292 AC_SUBST([GLUT_PC_REQ_PRIV])
1293 AC_SUBST([GLUT_PC_LIB_PRIV])
1294 AC_SUBST([GLUT_PC_CFLAGS])
1295
1296 dnl
1297 dnl Program library dependencies
1298 dnl    Only libm is added here if necessary as the libraries should
1299 dnl    be pulled in by the linker
1300 dnl
1301 if test "x$APP_LIB_DEPS" = x; then
1302     case "$host_os" in
1303     solaris*)
1304         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1305         ;;
1306     cygwin*)
1307         APP_LIB_DEPS="-lX11"
1308         ;;
1309     *)
1310         APP_LIB_DEPS="-lm"
1311         ;;
1312     esac
1313 fi
1314 AC_SUBST([APP_LIB_DEPS])
1315 AC_SUBST([PROGRAM_DIRS])
1316
1317 dnl
1318 dnl Gallium configuration
1319 dnl
1320 AC_ARG_ENABLE([gallium],
1321     [AS_HELP_STRING([--disable-gallium],
1322         [build gallium @<:@default=enabled@:>@])],
1323     [enable_gallium="$enableval"],
1324     [enable_gallium=yes])
1325 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1326     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1327 fi
1328 if test "x$enable_gallium" = xyes; then
1329     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1330     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1331                 [HAS_UDIS86="no"])
1332     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1333 fi
1334
1335 AC_SUBST([LLVM_CFLAGS])
1336 AC_SUBST([LLVM_LIBS])
1337 AC_SUBST([LLVM_LDFLAGS])
1338 AC_SUBST([LLVM_VERSION])
1339
1340 dnl
1341 dnl Gallium state trackers configuration
1342 dnl
1343
1344 AC_ARG_ENABLE([gallium-egl],
1345     [AS_HELP_STRING([--enable-gallium-egl],
1346         [enable gallium EGL state tracker @<:@default=auto@:>@])],
1347     [enable_gallium_egl="$enableval"],
1348     [enable_gallium_egl=auto])
1349 if test "x$enable_gallium_egl" = xauto; then
1350     case "$mesa_driver" in
1351     dri|no)
1352         enable_gallium_egl=$enable_egl
1353         ;;
1354     *)
1355         enable_gallium_egl=$enable_openvg
1356         ;;
1357     esac
1358 fi
1359 case "x$enable_egl$enable_gallium_egl" in
1360 xnoyes)
1361     AC_MSG_ERROR([cannot build Gallium EGL state tracker without EGL])
1362 esac
1363
1364 AC_ARG_WITH([state-trackers],
1365     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1366         [comma delimited state_trackers list, e.g.
1367         "egl,glx" @<:@default=auto@:>@])],
1368     [with_state_trackers="$withval"],
1369     [with_state_trackers=yes])
1370
1371 case "$with_state_trackers" in
1372 no)
1373     GALLIUM_STATE_TRACKERS_DIRS=""
1374     ;;
1375 yes)
1376     # look at what else is built
1377     case "$mesa_driver" in
1378     xlib)
1379         GALLIUM_STATE_TRACKERS_DIRS=glx
1380         ;;
1381     dri)
1382         GALLIUM_STATE_TRACKERS_DIRS="dri"
1383         HAVE_ST_DRI="yes"
1384         # Have only tested st/xorg on 1.6.0 servers
1385         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1386             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1387             HAVE_ST_XORG="no")
1388         ;;
1389     esac
1390
1391     if test "x$enable_egl" = xyes; then
1392         if test "$enable_openvg" = yes; then
1393             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1394             st_egl="yes"
1395         fi
1396
1397         if test "$enable_gallium_egl" = yes; then
1398             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1399             HAVE_ST_EGL="yes"
1400         fi
1401     fi
1402     ;;
1403 *)
1404     # verify the requested state tracker exist
1405     state_trackers=""
1406     _state_trackers=`IFS=', '; echo $with_state_trackers`
1407     for tracker in $_state_trackers; do
1408         case "$tracker" in
1409         dri)
1410             if test "x$mesa_driver" != xdri; then
1411                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1412             fi
1413             HAVE_ST_DRI="yes"
1414             ;;
1415         egl)
1416             if test "x$enable_egl" != xyes; then
1417                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1418             fi
1419             HAVE_ST_EGL="yes"
1420             ;;
1421         xorg)
1422             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1423             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1424             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1425             HAVE_ST_XORG="yes"
1426             ;;
1427         vega)
1428             if test "x$enable_openvg" != xyes; then
1429                 AC_MSG_ERROR([cannot build vega state tracker without --enable-openvg])
1430             fi
1431             ;;
1432         xorg/xvmc)
1433             # Check for xvmc?
1434             if test "x$enable_gallium_g3dvl" != xyes; then
1435                 AC_MSG_ERROR([cannot build XvMC state tracker without --enable-gallium-g3dvl])
1436             fi
1437             HAVE_ST_XVMC="yes"
1438             ;;
1439         vdpau)
1440             # Check for libvdpau?
1441             if test "x$enable_gallium_g3dvl" != xyes; then
1442                 AC_MSG_ERROR([cannot build vdpau state tracker without --enable-gallium-g3dvl])
1443             fi
1444             HAVE_ST_VDPAU="yes"
1445             ;;
1446         va)
1447             # Check for libva?
1448             if test "x$enable_gallium_g3dvl" != xyes; then
1449                 AC_MSG_ERROR([cannot build va state tracker without --enable-gallium-g3dvl])
1450             fi
1451             HAVE_ST_VA="yes"
1452             ;;
1453         esac
1454
1455         if test -n "$tracker"; then
1456             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1457                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1458             if test -n "$state_trackers"; then
1459                 state_trackers="$state_trackers $tracker"
1460             else
1461                 state_trackers="$tracker"
1462             fi
1463         fi
1464     done
1465     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1466     ;;
1467 esac
1468
1469
1470 EGL_CLIENT_APIS=""
1471 VG_LIB_DEPS=""
1472
1473 case "x$enable_opengl$enable_gles1$enable_gles2" in
1474 x*yes*)
1475     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1476     ;;
1477 esac
1478 if test "x$enable_openvg" = xyes; then
1479     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1480     VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1481 fi
1482
1483 AC_SUBST([VG_LIB_DEPS])
1484 AC_SUBST([EGL_CLIENT_APIS])
1485
1486 if test "x$HAVE_ST_EGL" = xyes; then
1487         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1488 fi
1489
1490 if test "x$HAVE_ST_XORG" = xyes; then
1491     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1492         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1493         HAVE_XEXTPROTO_71="no")
1494 fi
1495
1496 AC_ARG_WITH([egl-platforms],
1497     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1498         [comma delimited native platforms libEGL supports, e.g.
1499         "x11,drm" @<:@default=auto@:>@])],
1500     [with_egl_platforms="$withval"],
1501     [with_egl_platforms=yes])
1502 AC_ARG_WITH([egl-displays],
1503     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1504         [DEPRECATED.  Use --with-egl-platforms instead])],
1505     [with_egl_platforms="$withval"])
1506
1507 EGL_PLATFORMS=""
1508 case "$with_egl_platforms" in
1509 yes)
1510     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1511         EGL_PLATFORMS="x11"
1512         if test "$mesa_driver" = dri; then
1513             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1514         fi
1515     fi
1516     ;;
1517 *)
1518     if test "x$enable_egl" != xyes; then
1519         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1520     fi
1521     # verify the requested driver directories exist
1522     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1523     for plat in $egl_platforms; do
1524         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1525             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1526         if test "$plat" = "fbdev"; then
1527                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1528         fi
1529     done
1530     EGL_PLATFORMS="$egl_platforms"
1531     ;;
1532 esac
1533 AC_SUBST([EGL_PLATFORMS])
1534
1535 AC_ARG_WITH([egl-driver-dir],
1536     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1537                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1538     [EGL_DRIVER_INSTALL_DIR="$withval"],
1539     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1540 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1541
1542 AC_ARG_WITH([xorg-driver-dir],
1543     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1544                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1545     [XORG_DRIVER_INSTALL_DIR="$withval"],
1546     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1547 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1548
1549 AC_ARG_WITH([max-width],
1550     [AS_HELP_STRING([--with-max-width=N],
1551                     [Maximum framebuffer width (4096)])],
1552     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1553      AS_IF([test "${withval}" -gt "4096"],
1554            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1555 )
1556 AC_ARG_WITH([max-height],
1557     [AS_HELP_STRING([--with-max-height=N],
1558                     [Maximum framebuffer height (4096)])],
1559     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1560      AS_IF([test "${withval}" -gt "4096"],
1561            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1562 )
1563
1564 dnl
1565 dnl Gallium LLVM
1566 dnl
1567 AC_ARG_ENABLE([gallium-llvm],
1568     [AS_HELP_STRING([--enable-gallium-llvm],
1569         [build gallium LLVM support @<:@default=disabled@:>@])],
1570     [enable_gallium_llvm="$enableval"],
1571     [enable_gallium_llvm=auto])
1572 if test "x$enable_gallium_llvm" = xyes; then
1573     if test "x$LLVM_CONFIG" != xno; then
1574         LLVM_VERSION=`$LLVM_CONFIG --version`
1575         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags`
1576         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1577
1578         if test "x$HAS_UDIS86" != xno; then
1579             LLVM_LIBS="$LLVM_LIBS -ludis86"
1580             DEFINES="$DEFINES -DHAVE_UDIS86"
1581         fi
1582         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1583         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1584         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1585         MESA_LLVM=1
1586     else
1587         MESA_LLVM=0
1588     fi
1589 else
1590     MESA_LLVM=0
1591 fi
1592
1593 dnl
1594 dnl Gallium helper functions
1595 dnl
1596 gallium_check_st() {
1597     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes || test "x$HAVE_ST_XVMC" = xyes || test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1598          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1599     fi
1600     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1601          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1602     fi
1603     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1604          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1605     fi
1606     if test "x$HAVE_ST_XVMC" = xyes && test "x$4" != x; then
1607          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1608     fi
1609     if test "x$HAVE_ST_VDPAU" = xyes && test "x$5" != x; then
1610          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1611     fi
1612     if test "x$HAVE_ST_VA" = xyes && test "x$6" != x; then
1613          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1614     fi
1615 }
1616
1617
1618 dnl
1619 dnl Gallium SVGA configuration
1620 dnl
1621 AC_ARG_ENABLE([gallium-svga],
1622     [AS_HELP_STRING([--enable-gallium-svga],
1623         [build gallium SVGA @<:@default=disabled@:>@])],
1624     [enable_gallium_svga="$enableval"],
1625     [enable_gallium_svga=auto])
1626 if test "x$enable_gallium_svga" = xyes; then
1627     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1628     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1629 elif test "x$enable_gallium_svga" = xauto; then
1630     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1631 fi
1632
1633 dnl
1634 dnl Gallium i915 configuration
1635 dnl
1636 AC_ARG_ENABLE([gallium-i915],
1637     [AS_HELP_STRING([--enable-gallium-i915],
1638         [build gallium i915 @<:@default=disabled@:>@])],
1639     [enable_gallium_i915="$enableval"],
1640     [enable_gallium_i915=auto])
1641 if test "x$enable_gallium_i915" = xyes; then
1642     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1643     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1644     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1645 elif test "x$enable_gallium_i915" = xauto; then
1646     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1647     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1648 fi
1649
1650 dnl
1651 dnl Gallium i965 configuration
1652 dnl
1653 AC_ARG_ENABLE([gallium-i965],
1654     [AS_HELP_STRING([--enable-gallium-i965],
1655         [build gallium i965 @<:@default=disabled@:>@])],
1656     [enable_gallium_i965="$enableval"],
1657     [enable_gallium_i965=auto])
1658 if test "x$enable_gallium_i965" = xyes; then
1659     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1660     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1661 elif test "x$enable_gallium_i965" = xauto; then
1662     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1663 fi
1664
1665 dnl
1666 dnl Gallium Radeon r300g configuration
1667 dnl
1668 AC_ARG_ENABLE([gallium-radeon],
1669     [AS_HELP_STRING([--enable-gallium-radeon],
1670         [build gallium radeon @<:@default=disabled@:>@])],
1671     [enable_gallium_radeon="$enableval"],
1672     [enable_gallium_radeon=auto])
1673 if test "x$enable_gallium_radeon" = xauto; then
1674     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1675         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1676         gallium_check_st "radeon/drm" "dri-r300"
1677     else
1678         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1679     fi
1680 fi
1681 if test "x$enable_gallium_radeon" = xyes; then
1682     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1683         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1684         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1685     else
1686         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1687     fi
1688 fi
1689
1690 dnl
1691 dnl Gallium Radeon r600g configuration
1692 dnl
1693 AC_ARG_ENABLE([gallium-r600],
1694     [AS_HELP_STRING([--enable-gallium-r600],
1695         [build gallium radeon @<:@default=disabled@:>@])],
1696     [enable_gallium_r600="$enableval"],
1697     [enable_gallium_r600=auto])
1698 if test "x$enable_gallium_r600" = xyes; then
1699     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1700         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1701         gallium_check_st "r600/drm" "dri-r600" "xvmc-r600" "va-r600"
1702     else
1703         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1704     fi
1705 fi
1706
1707 dnl
1708 dnl Gallium Nouveau configuration
1709 dnl
1710 AC_ARG_ENABLE([gallium-nouveau],
1711     [AS_HELP_STRING([--enable-gallium-nouveau],
1712         [build gallium nouveau @<:@default=disabled@:>@])],
1713     [enable_gallium_nouveau="$enableval"],
1714     [enable_gallium_nouveau=no])
1715 if test "x$enable_gallium_nouveau" = xyes; then
1716     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1717     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "xvmc-nouveau"
1718 fi
1719
1720 dnl
1721 dnl Gallium G3DVL configuration
1722 dnl
1723 AC_ARG_ENABLE([gallium-g3dvl],
1724     [AS_HELP_STRING([--enable-gallium-g3dvl],
1725         [build gallium g3dvl @<:@default=disabled@:>@])],
1726     [enable_gallium_g3dvl="$enableval"],
1727     [enable_gallium_g3dvl=no])
1728 if test "x$enable_gallium_g3dvl" = xyes; then
1729     case "$mesa_driver" in
1730     xlib)
1731         if test "x$HAVE_ST_VDPAU" = xyes; then
1732         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1733         fi
1734         if test "x$HAVE_ST_XVMC" = xyes; then
1735         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1736         fi
1737         if test "x$HAVE_ST_VA" = xyes; then
1738         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1739         fi
1740         ;;
1741     dri)
1742         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS g3dvl/dri"
1743         ;;
1744     esac
1745 fi
1746 dnl Directory for VDPAU libs
1747 AC_ARG_WITH([vdpau-libdir],
1748     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1749         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1750     [VDPAU_LIB_INSTALL_DIR="$withval"],
1751     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1752 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1753
1754 dnl Directory for VA libs
1755 AC_ARG_WITH([va-libdir],
1756     [AS_HELP_STRING([--with-va-libdir=DIR],
1757         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1758     [VA_LIB_INSTALL_DIR="$withval"],
1759     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1760 AC_SUBST([VA_LIB_INSTALL_DIR])
1761
1762 dnl
1763 dnl Gallium swrast configuration
1764 dnl
1765 AC_ARG_ENABLE([gallium-swrast],
1766     [AS_HELP_STRING([--enable-gallium-swrast],
1767         [build gallium swrast @<:@default=auto@:>@])],
1768     [enable_gallium_swrast="$enableval"],
1769     [enable_gallium_swrast=auto])
1770 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1771     if test "x$HAVE_ST_DRI" = xyes; then
1772         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1773     fi
1774 fi
1775
1776 dnl prepend CORE_DIRS to SRC_DIRS
1777 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1778
1779 dnl Restore LDFLAGS and CPPFLAGS
1780 LDFLAGS="$_SAVE_LDFLAGS"
1781 CPPFLAGS="$_SAVE_CPPFLAGS"
1782
1783 dnl Substitute the config
1784 AC_CONFIG_FILES([configs/autoconf])
1785
1786 dnl Replace the configs/current symlink
1787 AC_CONFIG_COMMANDS([configs],[
1788 if test -f configs/current || test -L configs/current; then
1789     rm -f configs/current
1790 fi
1791 ln -s autoconf configs/current
1792 ])
1793
1794 AC_OUTPUT
1795
1796 dnl
1797 dnl Output some configuration info for the user
1798 dnl
1799 echo ""
1800 echo "        prefix:          $prefix"
1801 echo "        exec_prefix:     $exec_prefix"
1802 echo "        libdir:          $libdir"
1803 echo "        includedir:      $includedir"
1804
1805 dnl API info
1806 echo ""
1807 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1808 echo "        OpenVG:          $enable_openvg"
1809
1810 dnl Driver info
1811 echo ""
1812 echo "        Driver:          $mesa_driver"
1813 if test "$mesa_driver" != no; then
1814     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1815         echo "        OSMesa:          lib$OSMESA_LIB"
1816     else
1817         echo "        OSMesa:          no"
1818     fi
1819     if test "$mesa_driver" = dri; then
1820         # cleanup the drivers var
1821         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1822         if test "x$DRI_DIRS" = x; then
1823             echo "        DRI drivers:     no"
1824         else
1825             echo "        DRI drivers:     $dri_dirs"
1826         fi
1827         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1828         echo "        Use XCB:         $enable_xcb"
1829     fi
1830 fi
1831 echo ""
1832 echo "        GLU:             $enable_glu"
1833 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1834 echo "        glut:            $enable_glut"
1835
1836 dnl EGL
1837 echo ""
1838 echo "        EGL:             $enable_egl"
1839 if test "$enable_egl" = yes; then
1840     echo "        EGL platforms:   $EGL_PLATFORMS"
1841
1842     egl_drivers=""
1843     for d in $EGL_DRIVERS_DIRS; do
1844         egl_drivers="$egl_drivers builtin:egl_$d"
1845     done
1846
1847     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1848         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
1849         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
1850     else
1851         echo "        EGL drivers:    $egl_drivers"
1852     fi
1853 fi
1854
1855 echo ""
1856 if test "x$MESA_LLVM" = x1; then
1857     echo "        llvm:            yes"
1858     echo "        llvm-config:     $LLVM_CONFIG"
1859     echo "        llvm-version:    $LLVM_VERSION"
1860 else
1861     echo "        llvm:            no"
1862 fi
1863
1864 echo ""
1865 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1866     echo "        Gallium:         yes"
1867     echo "        Gallium dirs:    $GALLIUM_DIRS"
1868     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1869     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1870     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1871     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1872 else
1873     echo "        Gallium:         no"
1874 fi
1875
1876 dnl Libraries
1877 echo ""
1878 echo "        Shared libs:     $enable_shared"
1879 echo "        Static libs:     $enable_static"
1880
1881 dnl Compiler options
1882 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1883 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1884     $SED 's/^ *//;s/  */ /;s/ *$//'`
1885 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1886     $SED 's/^ *//;s/  */ /;s/ *$//'`
1887 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1888 echo ""
1889 echo "        CFLAGS:          $cflags"
1890 echo "        CXXFLAGS:        $cxxflags"
1891 echo "        Macros:          $defines"
1892 echo ""
1893 echo "        PYTHON2:         $PYTHON2"
1894
1895 echo ""
1896 echo "        Run '${MAKE-make}' to build Mesa"
1897 echo ""