configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.63
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XDAMAGE_REQUIRED=1.1
  98 XSHMFENCE_REQUIRED=1.1
  99 XVMC_REQUIRED=1.0.6
 100 PYTHON_MAKO_REQUIRED=0.8.0
 101 LIBSENSORS_REQUIRED=4.0.0
 102 ZLIB_REQUIRED=1.2.8
 103
 104 dnl LLVM versions
 105 LLVM_REQUIRED_GALLIUM=3.3.0
 106 LLVM_REQUIRED_OPENCL=3.6.0
 107 LLVM_REQUIRED_R600=3.8.0
 108 LLVM_REQUIRED_RADEONSI=3.8.0
 109 LLVM_REQUIRED_RADV=3.9.0
 110 LLVM_REQUIRED_SWR=3.9.0
 111
 112 dnl Check for progs
 113 AC_PROG_CPP
 114 AC_PROG_CC
 115 AC_PROG_CXX
 116 AM_PROG_CC_C_O
 117 AM_PROG_AS
 118 AX_CHECK_GNU_MAKE
 119 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 120 AC_PROG_SED
 121 AC_PROG_MKDIR_P
 122
 123 AC_SYS_LARGEFILE
 124
 125 LT_PREREQ([2.2])
 126 LT_INIT([disable-static])
 127
 128 AC_CHECK_PROG(RM, rm, [rm -f])
 129
 130 AX_PROG_BISON([],
 131               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 132                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 133 AX_PROG_FLEX([],
 134              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 135                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 136
 137 AC_CHECK_PROG(INDENT, indent, indent, cat)
 138 if test "x$INDENT" != "xcat"; then
 139     # Only GNU indent is supported
 140     INDENT_VERSION=`indent --version | grep GNU`
 141     if test $? -eq 0; then
 142        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 143     else
 144        INDENT="cat"
 145     fi
 146 fi
 147
 148 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 149
 150 if test -z "$PYTHON2"; then
 151     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 152         AC_MSG_ERROR([Python not found - unable to generate sources])
 153     fi
 154 else
 155     if test "x$acv_mako_found" = xno; then
 156         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 157             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 158         fi
 159     fi
 160 fi
 161
 162 AC_PROG_INSTALL
 163
 164 dnl We need a POSIX shell for parts of the build. Assume we have one
 165 dnl in most cases.
 166 case "$host_os" in
 167 solaris*)
 168     # Solaris /bin/sh is too old/non-POSIX compliant
 169     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 170     SHELL="$POSIX_SHELL"
 171     ;;
 172 esac
 173
 174 dnl clang is mostly GCC-compatible, but its version is much lower,
 175 dnl so we have to check for it.
 176 AC_MSG_CHECKING([if compiling with clang])
 177
 178 AC_COMPILE_IFELSE(
 179 [AC_LANG_PROGRAM([], [[
 180 #ifndef __clang__
 181        not clang
 182 #endif
 183 ]])],
 184 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 185
 186 AC_MSG_RESULT([$acv_mesa_CLANG])
 187
 188 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 189 dnl versions are explictly not supported.
 190 GEN_ASM_OFFSETS=no
 191 USE_GNU99=no
 192 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 193     AC_MSG_CHECKING([whether gcc version is sufficient])
 194     major=0
 195     minor=0
 196
 197     GCC_VERSION=`$CC -dumpversion`
 198     if test $? -eq 0; then
 199         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 200         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 204         AC_MSG_RESULT([no])
 205         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 206     else
 207         AC_MSG_RESULT([yes])
 208     fi
 209
 210     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 211         USE_GNU99=yes
 212     fi
 213     if test "x$cross_compiling" = xyes; then
 214         GEN_ASM_OFFSETS=yes
 215     fi
 216 fi
 217
 218 dnl We don't support building Mesa with Sun C compiler
 219 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 220 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 221 if test "x$SUNCC" = xyes; then
 222     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 223 fi
 224
 225 dnl Check for compiler builtins
 226 AX_GCC_BUILTIN([__builtin_bswap32])
 227 AX_GCC_BUILTIN([__builtin_bswap64])
 228 AX_GCC_BUILTIN([__builtin_clz])
 229 AX_GCC_BUILTIN([__builtin_clzll])
 230 AX_GCC_BUILTIN([__builtin_ctz])
 231 AX_GCC_BUILTIN([__builtin_expect])
 232 AX_GCC_BUILTIN([__builtin_ffs])
 233 AX_GCC_BUILTIN([__builtin_ffsll])
 234 AX_GCC_BUILTIN([__builtin_popcount])
 235 AX_GCC_BUILTIN([__builtin_popcountll])
 236 AX_GCC_BUILTIN([__builtin_unreachable])
 237
 238 AX_GCC_FUNC_ATTRIBUTE([const])
 239 AX_GCC_FUNC_ATTRIBUTE([flatten])
 240 AX_GCC_FUNC_ATTRIBUTE([format])
 241 AX_GCC_FUNC_ATTRIBUTE([malloc])
 242 AX_GCC_FUNC_ATTRIBUTE([packed])
 243 AX_GCC_FUNC_ATTRIBUTE([pure])
 244 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 245 AX_GCC_FUNC_ATTRIBUTE([unused])
 246 AX_GCC_FUNC_ATTRIBUTE([visibility])
 247 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 248 AX_GCC_FUNC_ATTRIBUTE([weak])
 249 AX_GCC_FUNC_ATTRIBUTE([alias])
 250
 251 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 252
 253 dnl Make sure the pkg-config macros are defined
 254 m4_ifndef([PKG_PROG_PKG_CONFIG],
 255     [m4_fatal([Could not locate the pkg-config autoconf macros.
 256   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 257   are in a different location, try setting the environment variable
 258   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 259 PKG_PROG_PKG_CONFIG()
 260
 261 dnl LIB_DIR - library basename
 262 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 263 AC_SUBST([LIB_DIR])
 264
 265 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 266 _SAVE_LDFLAGS="$LDFLAGS"
 267 _SAVE_CPPFLAGS="$CPPFLAGS"
 268
 269 dnl Compiler macros
 270 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 271 AC_SUBST([DEFINES])
 272 android=no
 273 case "$host_os" in
 274 *-android)
 275     android=yes
 276     ;;
 277 linux*|*-gnu*|gnu*|cygwin*)
 278     DEFINES="$DEFINES -D_GNU_SOURCE"
 279     ;;
 280 solaris*)
 281     DEFINES="$DEFINES -DSVR4"
 282     ;;
 283 esac
 284
 285 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 286
 287 dnl Add flags for gcc and g++
 288 if test "x$GCC" = xyes; then
 289     CFLAGS="$CFLAGS -Wall"
 290
 291     if test "x$USE_GNU99" = xyes; then
 292         CFLAGS="$CFLAGS -std=gnu99"
 293     else
 294         CFLAGS="$CFLAGS -std=c99"
 295     fi
 296
 297     # Enable -Werror=implicit-function-declaration and
 298     # -Werror=missing-prototypes, if available, or otherwise, just
 299     # -Wmissing-prototypes.  This is particularly useful to avoid
 300     # generating a loadable driver module that has undefined symbols.
 301     save_CFLAGS="$CFLAGS"
 302     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 303     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 304     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    AC_MSG_RESULT([yes]),
 307                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 308                     AC_MSG_RESULT([no])])
 309
 310     # Enable -fvisibility=hidden if using a gcc that supports it
 311     save_CFLAGS="$CFLAGS"
 312     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 313     VISIBILITY_CFLAGS="-fvisibility=hidden"
 314     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 316                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 317
 318     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 319     CFLAGS=$save_CFLAGS
 320
 321     # We don't want floating-point math functions to set errno or trap
 322     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 323
 324     # Flags to help ensure that certain portions of the code -- and only those
 325     # portions -- can be built with MSVC:
 326     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 327     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 328     #   supports most of C99)
 329     # - the rest has no compiler compiler restrictions
 330     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 331     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 332
 333     # Enable -Werror=vla if compiler supports it
 334     save_CFLAGS="$CFLAGS"
 335     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 336     CFLAGS="$CFLAGS -Werror=vla"
 337     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 338                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 339                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 340                     AC_MSG_RESULT([yes])],
 341                     AC_MSG_RESULT([no]))
 342     CFLAGS="$save_CFLAGS"
 343 fi
 344 if test "x$GXX" = xyes; then
 345     CXXFLAGS="$CXXFLAGS -Wall"
 346
 347     # Enable -fvisibility=hidden if using a gcc that supports it
 348     save_CXXFLAGS="$CXXFLAGS"
 349     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 350     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 351     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 352     AC_LANG_PUSH([C++])
 353     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 354                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 355     AC_LANG_POP([C++])
 356
 357     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 358     CXXFLAGS=$save_CXXFLAGS
 359
 360     # We don't want floating-point math functions to set errno or trap
 361     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 362 fi
 363
 364 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 365 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 366
 367 dnl even if the compiler appears to support it, using visibility attributes isn't
 368 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 369 case "$host_os" in
 370 cygwin*)
 371     VISIBILITY_CFLAGS=""
 372     VISIBILITY_CXXFLAGS=""
 373     ;;
 374 esac
 375
 376 AC_SUBST([VISIBILITY_CFLAGS])
 377 AC_SUBST([VISIBILITY_CXXFLAGS])
 378
 379 dnl
 380 dnl Optional flags, check for compiler support
 381 dnl
 382 SSE41_CFLAGS="-msse4.1"
 383 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 384 dnl stack, but on x86-32 such alignment is not guaranteed.
 385 case "$target_cpu" in
 386 i?86)
 387     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 388     ;;
 389 esac
 390 save_CFLAGS="$CFLAGS"
 391 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 393 #include <smmintrin.h>
 394 int param;
 395 int main () {
 396     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 397     c = _mm_max_epu32(a, b);
 398     return _mm_cvtsi128_si32(c);
 399 }]])], SSE41_SUPPORTED=1)
 400 CFLAGS="$save_CFLAGS"
 401 if test "x$SSE41_SUPPORTED" = x1; then
 402     DEFINES="$DEFINES -DUSE_SSE41"
 403 fi
 404 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 405 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 406
 407 dnl Check for new-style atomic builtins
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409 int main() {
 410     int n;
 411     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 412 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 413 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 414     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 415 fi
 416 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 417
 418 dnl Check for Endianness
 419 AC_C_BIGENDIAN(
 420    little_endian=no,
 421    little_endian=yes,
 422    little_endian=no,
 423    little_endian=no
 424 )
 425
 426 dnl Check for POWER8 Architecture
 427 PWR8_CFLAGS="-mpower8-vector"
 428 have_pwr8_intrinsics=no
 429 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 430 save_CFLAGS=$CFLAGS
 431 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 432 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 433 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 434 #error "Need GCC >= 4.8 for sane POWER8 support"
 435 #endif
 436 #include <altivec.h>
 437 int main () {
 438     vector unsigned char r;
 439     vector unsigned int v = vec_splat_u32 (1);
 440     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 441     return 0;
 442 }]])], have_pwr8_intrinsics=yes)
 443 CFLAGS=$save_CFLAGS
 444
 445 AC_ARG_ENABLE(pwr8,
 446    [AS_HELP_STRING([--disable-pwr8-inst],
 447                    [disable POWER8-specific instructions])],
 448    [enable_pwr8=$enableval], [enable_pwr8=auto])
 449
 450 if test "x$enable_pwr8" = xno ; then
 451    have_pwr8_intrinsics=disabled
 452 fi
 453
 454 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 455    DEFINES="$DEFINES -D_ARCH_PWR8"
 456    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 457    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 458 else
 459    PWR8_CFLAGS=
 460 fi
 461
 462 AC_MSG_RESULT($have_pwr8_intrinsics)
 463 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 464    AC_MSG_ERROR([POWER8 compiler support not detected])
 465 fi
 466
 467 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 468    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 469 fi
 470
 471 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 472
 473 dnl Can't have static and shared libraries, default to static if user
 474 dnl explicitly requested. If both disabled, set to static since shared
 475 dnl was explicitly requested.
 476 case "x$enable_static$enable_shared" in
 477 xyesyes)
 478     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 479     ;;
 480 xnono)
 481     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 482     ;;
 483 esac
 484
 485 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 486
 487 dnl
 488 dnl other compiler options
 489 dnl
 490 AC_ARG_ENABLE([debug],
 491     [AS_HELP_STRING([--enable-debug],
 492         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 493     [enable_debug="$enableval"],
 494     [enable_debug=no]
 495 )
 496
 497 AC_ARG_ENABLE([profile],
 498     [AS_HELP_STRING([--enable-profile],
 499         [enable profiling of code @<:@default=disabled@:>@])],
 500     [enable_profile="$enableval"],
 501     [enable_profile=no]
 502 )
 503
 504 if test "x$enable_profile" = xyes; then
 505     DEFINES="$DEFINES -DPROFILE"
 506     if test "x$GCC" = xyes; then
 507         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 508     fi
 509     if test "x$GXX" = xyes; then
 510         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 511     fi
 512 fi
 513
 514 if test "x$enable_debug" = xyes; then
 515     DEFINES="$DEFINES -DDEBUG"
 516     if test "x$enable_profile" = xyes; then
 517         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 518     fi
 519     if test "x$GCC" = xyes; then
 520         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 521             CFLAGS="$CFLAGS -g"
 522         fi
 523         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 524             CFLAGS="$CFLAGS -O0"
 525         fi
 526     fi
 527     if test "x$GXX" = xyes; then
 528         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 529             CXXFLAGS="$CXXFLAGS -g"
 530         fi
 531         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 532             CXXFLAGS="$CXXFLAGS -O0"
 533         fi
 534     fi
 535 else
 536    DEFINES="$DEFINES -DNDEBUG"
 537 fi
 538
 539 dnl
 540 dnl Check if linker supports -Bsymbolic
 541 dnl
 542 save_LDFLAGS=$LDFLAGS
 543 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 544 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 545 AC_LINK_IFELSE(
 546     [AC_LANG_SOURCE([int main() { return 0;}])],
 547     [AC_MSG_RESULT([yes])
 548         BSYMBOLIC="-Wl,-Bsymbolic";],
 549     [AC_MSG_RESULT([no])
 550         BSYMBOLIC="";])
 551 LDFLAGS=$save_LDFLAGS
 552
 553 AC_SUBST([BSYMBOLIC])
 554
 555 dnl
 556 dnl Check if linker supports garbage collection
 557 dnl
 558 save_LDFLAGS=$LDFLAGS
 559 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 560 AC_MSG_CHECKING([whether ld supports --gc-sections])
 561 AC_LINK_IFELSE(
 562     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 563     [AC_MSG_RESULT([yes])
 564         GC_SECTIONS="-Wl,--gc-sections";],
 565     [AC_MSG_RESULT([no])
 566         GC_SECTIONS="";])
 567 LDFLAGS=$save_LDFLAGS
 568
 569 AC_SUBST([GC_SECTIONS])
 570
 571 dnl
 572 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 573 dnl so when these flags are passed to ld via libtool the checks will fail
 574 dnl
 575 case "$host_os" in
 576 openbsd* | darwin* )
 577     LD_NO_UNDEFINED="" ;;
 578 *)
 579     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 580 esac
 581
 582 AC_SUBST([LD_NO_UNDEFINED])
 583
 584 dnl
 585 dnl Check if linker supports version scripts
 586 dnl
 587 AC_MSG_CHECKING([if the linker supports version-scripts])
 588 save_LDFLAGS=$LDFLAGS
 589 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 590 cat > conftest.map <<EOF
 591 VERSION_1 {
 592      global:
 593          main;
 594
 595      local:
 596          *;
 597 };
 598 EOF
 599 AC_LINK_IFELSE(
 600     [AC_LANG_SOURCE([int main() { return 0;}])],
 601     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 602     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 603 LDFLAGS=$save_LDFLAGS
 604 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 605
 606 dnl
 607 dnl Check if linker supports dynamic list files
 608 dnl
 609 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 610 save_LDFLAGS=$LDFLAGS
 611 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 612 cat > conftest.dyn <<EOF
 613 {
 614         radeon_drm_winsys_create;
 615 };
 616 EOF
 617 AC_LINK_IFELSE(
 618     [AC_LANG_SOURCE([int main() { return 0;}])],
 619     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 620     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 621 LDFLAGS=$save_LDFLAGS
 622 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 623
 624 dnl
 625 dnl compatibility symlinks
 626 dnl
 627 case "$host_os" in
 628 linux* )
 629     HAVE_COMPAT_SYMLINKS=yes ;;
 630 * )
 631     HAVE_COMPAT_SYMLINKS=no ;;
 632 esac
 633
 634 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 635
 636 dnl
 637 dnl library names
 638 dnl
 639 dnl Unfortunately we need to do a few things that libtool can't help us with,
 640 dnl so we need some knowledge of shared library filenames:
 641 dnl
 642 dnl LIB_EXT is the extension used when creating symlinks for alternate
 643 dnl filenames for a shared library which will be dynamically loaded
 644 dnl
 645 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 646 dnl the file for a shared library we wish to link with
 647 dnl
 648 case "$host_os" in
 649 darwin* )
 650     LIB_EXT='dylib'
 651     IMP_LIB_EXT=$LIB_EXT
 652     ;;
 653 cygwin* )
 654     LIB_EXT='dll'
 655     IMP_LIB_EXT='dll.a'
 656     ;;
 657 aix* )
 658     LIB_EXT='a'
 659     IMP_LIB_EXT=$LIB_EXT
 660     ;;
 661 * )
 662     LIB_EXT='so'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 esac
 666
 667 AC_SUBST([LIB_EXT])
 668
 669 dnl
 670 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 671 dnl
 672 AC_ARG_ENABLE([texture-float],
 673     [AS_HELP_STRING([--enable-texture-float],
 674         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 675     [enable_texture_float="$enableval"],
 676     [enable_texture_float=no]
 677 )
 678 if test "x$enable_texture_float" = xyes; then
 679     AC_MSG_WARN([Floating-point textures enabled.])
 680     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 681     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 682 fi
 683
 684 dnl
 685 dnl Arch/platform-specific settings
 686 dnl
 687 AC_ARG_ENABLE([asm],
 688     [AS_HELP_STRING([--disable-asm],
 689         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 690     [enable_asm="$enableval"],
 691     [enable_asm=yes]
 692 )
 693 asm_arch=""
 694 AC_MSG_CHECKING([whether to enable assembly])
 695 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 696 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 697 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 698     case "$host_cpu" in
 699     i?86 | x86_64 | amd64)
 700         if test "x$host_cpu" != "x$target_cpu"; then
 701             enable_asm=no
 702             AC_MSG_RESULT([no, cross compiling])
 703         fi
 704         ;;
 705     esac
 706 fi
 707 # check for supported arches
 708 if test "x$enable_asm" = xyes; then
 709     case "$host_cpu" in
 710     i?86)
 711         case "$host_os" in
 712         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 713             asm_arch=x86
 714             ;;
 715         esac
 716         ;;
 717     x86_64|amd64)
 718         case "$host_os" in
 719         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 720             asm_arch=x86_64
 721             ;;
 722         esac
 723         ;;
 724     sparc*)
 725         case "$host_os" in
 726         linux*)
 727             asm_arch=sparc
 728             ;;
 729         esac
 730         ;;
 731     esac
 732
 733     case "$asm_arch" in
 734     x86)
 735         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 736         AC_MSG_RESULT([yes, x86])
 737         ;;
 738     x86_64|amd64)
 739         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 740         AC_MSG_RESULT([yes, x86_64])
 741         ;;
 742     sparc)
 743         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 744         AC_MSG_RESULT([yes, sparc])
 745         ;;
 746     *)
 747         AC_MSG_RESULT([no, platform not supported])
 748         ;;
 749     esac
 750 fi
 751
 752 AC_HEADER_MAJOR
 753 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 754 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 755 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 756 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 757
 758 dnl Check to see if dlopen is in default libraries (like Solaris, which
 759 dnl has it in libc), or if libdl is needed to get it.
 760 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 761     [AC_CHECK_LIB([dl], [dlopen],
 762        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 763 AC_SUBST([DLOPEN_LIBS])
 764
 765 dnl Check if that library also has dladdr
 766 save_LIBS="$LIBS"
 767 LIBS="$LIBS $DLOPEN_LIBS"
 768 AC_CHECK_FUNCS([dladdr])
 769 LIBS="$save_LIBS"
 770
 771 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 772
 773 case "$host_os" in
 774 darwin*)
 775     ;;
 776 *)
 777     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 778                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 779                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 780     AC_SUBST([CLOCK_LIB])
 781     ;;
 782 esac
 783
 784 dnl See if posix_memalign is available
 785 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 786
 787 dnl Check for zlib
 788 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 789
 790 dnl Check for pthreads
 791 AX_PTHREAD
 792 if test "x$ax_pthread_ok" = xno; then
 793     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 794 fi
 795 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 796 dnl to -pthread, which causes problems if we need -lpthread to appear in
 797 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 798 dnl is not valid for that platform.
 799 if test "x$android" = xno; then
 800     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 801 fi
 802
 803 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 804 dnl project. Even then there's a notable issue as described in the project README
 805 case "$host_os" in
 806 linux* | cygwin* | darwin* | solaris* | gnu*)
 807     pthread_stubs_possible="no"
 808     ;;
 809 * )
 810     pthread_stubs_possible="yes"
 811     ;;
 812 esac
 813
 814 if test "x$pthread_stubs_possible" = xyes; then
 815     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 816     AC_SUBST(PTHREADSTUBS_CFLAGS)
 817     AC_SUBST(PTHREADSTUBS_LIBS)
 818 fi
 819
 820 dnl SELinux awareness.
 821 AC_ARG_ENABLE([selinux],
 822     [AS_HELP_STRING([--enable-selinux],
 823         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 824     [MESA_SELINUX="$enableval"],
 825     [MESA_SELINUX=no])
 826 if test "x$enable_selinux" = "xyes"; then
 827     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 828         [AC_CHECK_HEADER([selinux/selinux.h],[],
 829                          [AC_MSG_ERROR([SELinux headers not found])])
 830          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 831                       [AC_MSG_ERROR([SELinux library not found])])
 832          SELINUX_LIBS="-lselinux"])
 833     DEFINES="$DEFINES -DMESA_SELINUX"
 834 fi
 835 AC_SUBST([SELINUX_CFLAGS])
 836 AC_SUBST([SELINUX_LIBS])
 837
 838 dnl
 839 dnl LLVM
 840 dnl
 841 AC_ARG_ENABLE([llvm-shared-libs],
 842     [AS_HELP_STRING([--enable-llvm-shared-libs],
 843         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 844     [enable_llvm_shared_libs="$enableval"],
 845     [enable_llvm_shared_libs=yes])
 846
 847 AC_ARG_WITH([llvm-prefix],
 848     [AS_HELP_STRING([--with-llvm-prefix],
 849         [Prefix for LLVM installations in non-standard locations])],
 850     [llvm_prefix="$withval"],
 851     [llvm_prefix=''])
 852
 853 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 854 if test "x$have_libelf" = xno; then
 855    LIBELF_LIBS=''
 856    LIBELF_CFLAGS=''
 857    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 858    AC_SUBST([LIBELF_LIBS])
 859    AC_SUBST([LIBELF_CFLAGS])
 860 fi
 861
 862 if test -z "$LLVM_CONFIG"; then
 863     if test -n "$llvm_prefix"; then
 864         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 865     else
 866         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 867     fi
 868 fi
 869
 870 llvm_add_component() {
 871     new_llvm_component=$1
 872     driver_name=$2
 873
 874     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 875         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 876     else
 877         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 878     fi
 879 }
 880
 881 llvm_add_default_components() {
 882     driver_name=$1
 883
 884     # Required default components
 885     llvm_add_component "bitwriter" $driver_name
 886     llvm_add_component "engine" $driver_name
 887     llvm_add_component "mcdisassembler" $driver_name
 888     llvm_add_component "mcjit" $driver_name
 889
 890     # Optional default components
 891     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 892         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 893     fi
 894 }
 895
 896 llvm_add_target() {
 897     new_llvm_target=$1
 898     driver_name=$2
 899
 900     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 901         llvm_add_component $new_llvm_target $driver_name
 902     else
 903         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 904     fi
 905 }
 906
 907 # Call this inside ` ` to get the return value.
 908 # $1 is the llvm-config command with arguments.
 909 strip_unwanted_llvm_flags() {
 910     # Use \> (marks the end of the word)
 911     echo " `$1`" | sed -E \
 912         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 913         -e 's/[[[:space:]]]+-DNDEBUG\>//g' \
 914         -e 's/[[[:space:]]]+-D_GNU_SOURCE\>//g' \
 915         -e 's/[[[:space:]]]+-pedantic\>//g' \
 916         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 917         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 918         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 919         -e 's/-fno-rtti\>/-Fno-rtti/g' \
 920         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 921         -e 's/-Fno-rtti\>/-fno-rtti/g' \
 922         -e 's/^[[[:space:]]]//'
 923 }
 924
 925 llvm_set_environment_variables() {
 926     if test "x$LLVM_CONFIG" != xno; then
 927         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 928         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 929         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 930         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 931
 932         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 933         save_CFLAGS="$CFLAGS"
 934         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 935
 936         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 937             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 938         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 939             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 940         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 941             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 942
 943         CFLAGS="$save_CFLAGS"
 944
 945         # Only needed for LLVM < 3.6.0
 946         if test -z "$LLVM_VERSION_PATCH"; then
 947             LLVM_VERSION_PATCH=0
 948         fi
 949
 950         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 951
 952         FOUND_LLVM=yes
 953     else
 954         FOUND_LLVM=no
 955         LLVM_VERSION_INT=0
 956     fi
 957 }
 958
 959 require_llvm() {
 960     if test "x$enable_llvm" != "xyes"; then
 961         AC_MSG_ERROR([--enable-llvm is required when building $1])
 962     fi
 963 }
 964
 965 llvm_require_version() {
 966     require_llvm $2
 967
 968     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
 969     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
 970     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 971
 972     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
 973         # major > required major
 974         #  --> OK
 975         return
 976     fi
 977
 978     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
 979         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
 980             # major = required major and
 981             # minor > required minor
 982             #  --> OK
 983             return
 984         else
 985             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
 986                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
 987                     # major = required major and
 988                     # minor = required minor and
 989                     # patch >= required patch
 990                     #  --> OK
 991                     return
 992                 fi
 993             fi
 994         fi
 995     fi
 996
 997     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
 998 }
 999
1000 radeon_llvm_check() {
1001     if test ${LLVM_VERSION_INT} -lt 307; then
1002         amdgpu_llvm_target_name='r600'
1003     else
1004         amdgpu_llvm_target_name='amdgpu'
1005     fi
1006
1007     llvm_require_version $*
1008
1009     llvm_add_target $amdgpu_llvm_target_name $2
1010
1011     llvm_add_default_components $2
1012     llvm_add_component "bitreader" $2
1013     llvm_add_component "ipo" $2
1014
1015     if test "x$have_libelf" != xyes; then
1016        AC_MSG_ERROR([$2 requires libelf when using llvm])
1017     fi
1018 }
1019
1020 llvm_set_environment_variables
1021
1022 AC_SUBST([LLVM_CFLAGS])
1023 AC_SUBST([LLVM_CXXFLAGS])
1024 AC_SUBST([LLVM_LIBS])
1025 AC_SUBST([LLVM_LDFLAGS])
1026 AC_SUBST([LLVM_INCLUDEDIR])
1027
1028 dnl Options for APIs
1029 AC_ARG_ENABLE([opengl],
1030     [AS_HELP_STRING([--disable-opengl],
1031         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1032     [enable_opengl="$enableval"],
1033     [enable_opengl=yes])
1034 AC_ARG_ENABLE([gles1],
1035     [AS_HELP_STRING([--disable-gles1],
1036         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1037     [enable_gles1="$enableval"],
1038     [enable_gles1=yes])
1039 AC_ARG_ENABLE([gles2],
1040     [AS_HELP_STRING([--disable-gles2],
1041         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1042     [enable_gles2="$enableval"],
1043     [enable_gles2=yes])
1044
1045 AC_ARG_ENABLE([dri],
1046     [AS_HELP_STRING([--enable-dri],
1047         [enable DRI modules @<:@default=enabled@:>@])],
1048     [enable_dri="$enableval"],
1049     [enable_dri=yes])
1050
1051 AC_ARG_ENABLE([gallium-extra-hud],
1052     [AS_HELP_STRING([--enable-gallium-extra-hud],
1053         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1054     [enable_gallium_extra_hud="$enableval"],
1055     [enable_gallium_extra_hud=no])
1056 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1057 if test "x$enable_gallium_extra_hud" = xyes ; then
1058     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1059 fi
1060
1061 #TODO: no pkgconfig .pc available for libsensors.
1062 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1063 AC_ARG_ENABLE([lmsensors],
1064     [AS_HELP_STRING([--enable-lmsensors],
1065         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1066     [enable_lmsensors="$enableval"],
1067     [enable_lmsensors=no])
1068 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1069 if test "x$enable_lmsensors" = xyes ; then
1070     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1071     LIBSENSORS_LIBS="-lsensors"
1072 else
1073     LIBSENSORS_LIBS=""
1074 fi
1075 AC_SUBST(LIBSENSORS_LIBS)
1076
1077 case "$host_os" in
1078 linux*)
1079     dri3_default=yes
1080     ;;
1081 *)
1082     dri3_default=no
1083     ;;
1084 esac
1085
1086 if test "x$enable_dri" = xno; then
1087     dri3_default=no
1088 fi
1089
1090 AC_ARG_ENABLE([dri3],
1091     [AS_HELP_STRING([--enable-dri3],
1092         [enable DRI3 @<:@default=auto@:>@])],
1093     [enable_dri3="$enableval"],
1094     [enable_dri3="$dri3_default"])
1095 AC_ARG_ENABLE([glx],
1096     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1097         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1098     [enable_glx="$enableval"],
1099     [enable_glx=yes])
1100 AC_ARG_ENABLE([osmesa],
1101     [AS_HELP_STRING([--enable-osmesa],
1102         [enable OSMesa library @<:@default=disabled@:>@])],
1103     [enable_osmesa="$enableval"],
1104     [enable_osmesa=no])
1105 AC_ARG_ENABLE([gallium-osmesa],
1106     [AS_HELP_STRING([--enable-gallium-osmesa],
1107         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1108     [enable_gallium_osmesa="$enableval"],
1109     [enable_gallium_osmesa=no])
1110 AC_ARG_ENABLE([egl],
1111     [AS_HELP_STRING([--disable-egl],
1112         [disable EGL library @<:@default=enabled@:>@])],
1113     [enable_egl="$enableval"],
1114     [enable_egl=yes])
1115
1116 AC_ARG_ENABLE([xa],
1117     [AS_HELP_STRING([--enable-xa],
1118         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1119     [enable_xa="$enableval"],
1120     [enable_xa=no])
1121 AC_ARG_ENABLE([gbm],
1122    [AS_HELP_STRING([--enable-gbm],
1123          [enable gbm library @<:@default=yes except cygwin@:>@])],
1124    [enable_gbm="$enableval"],
1125    [case "$host_os" in
1126        cygwin*)
1127           enable_gbm=no
1128           ;;
1129        *)
1130           enable_gbm=yes
1131           ;;
1132     esac])
1133 AC_ARG_ENABLE([nine],
1134     [AS_HELP_STRING([--enable-nine],
1135         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1136     [enable_nine="$enableval"],
1137     [enable_nine=no])
1138
1139 AC_ARG_ENABLE([xvmc],
1140    [AS_HELP_STRING([--enable-xvmc],
1141          [enable xvmc library @<:@default=auto@:>@])],
1142    [enable_xvmc="$enableval"],
1143    [enable_xvmc=auto])
1144 AC_ARG_ENABLE([vdpau],
1145    [AS_HELP_STRING([--enable-vdpau],
1146          [enable vdpau library @<:@default=auto@:>@])],
1147    [enable_vdpau="$enableval"],
1148    [enable_vdpau=auto])
1149 AC_ARG_ENABLE([omx],
1150    [AS_HELP_STRING([--enable-omx],
1151          [enable OpenMAX library @<:@default=disabled@:>@])],
1152    [enable_omx="$enableval"],
1153    [enable_omx=no])
1154 AC_ARG_ENABLE([va],
1155    [AS_HELP_STRING([--enable-va],
1156          [enable va library @<:@default=auto@:>@])],
1157    [enable_va="$enableval"],
1158    [enable_va=auto])
1159 AC_ARG_ENABLE([opencl],
1160    [AS_HELP_STRING([--enable-opencl],
1161          [enable OpenCL library @<:@default=disabled@:>@])],
1162    [enable_opencl="$enableval"],
1163    [enable_opencl=no])
1164 AC_ARG_ENABLE([opencl_icd],
1165    [AS_HELP_STRING([--enable-opencl-icd],
1166           [Build an OpenCL ICD library to be loaded by an ICD implementation
1167            @<:@default=disabled@:>@])],
1168     [enable_opencl_icd="$enableval"],
1169     [enable_opencl_icd=no])
1170
1171 AC_ARG_ENABLE([gallium-tests],
1172     [AS_HELP_STRING([--enable-gallium-tests],
1173         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1174     [enable_gallium_tests="$enableval"],
1175     [enable_gallium_tests=no])
1176
1177 # Option for Gallium drivers
1178
1179 # Keep this in sync with the --with-gallium-drivers help string default value
1180 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1181
1182 AC_ARG_WITH([gallium-drivers],
1183     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1184         [comma delimited Gallium drivers list, e.g.
1185         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1186         @<:@default=r300,r600,svga,swrast@:>@])],
1187     [with_gallium_drivers="$withval"],
1188     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1189
1190 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1191 # here so that the script doesn't choke on an unknown driver name later.
1192 case "$with_gallium_drivers" in
1193     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1194     no) with_gallium_drivers='' ;;
1195 esac
1196
1197 if test "x$enable_opengl" = xno -a \
1198         "x$enable_gles1" = xno -a \
1199         "x$enable_gles2" = xno -a \
1200         "x$enable_nine" = xno -a \
1201         "x$enable_xa" = xno -a \
1202         "x$enable_xvmc" = xno -a \
1203         "x$enable_vdpau" = xno -a \
1204         "x$enable_omx" = xno -a \
1205         "x$enable_va" = xno -a \
1206         "x$enable_opencl" = xno; then
1207     AC_MSG_ERROR([at least one API should be enabled])
1208 fi
1209
1210 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1211 if test "x$enable_opengl" = xno -a \
1212         "x$enable_gles1" = xyes; then
1213     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1214 fi
1215
1216 if test "x$enable_opengl" = xno -a \
1217         "x$enable_gles2" = xyes; then
1218     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1219 fi
1220
1221 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1222 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1223 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1224 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1225                                         "x$enable_gles1" = xyes -o \
1226                                         "x$enable_gles2" = xyes)
1227
1228 # Validate GLX options
1229 if test "x$enable_glx" = xyes; then
1230     if test "x$enable_dri" = xyes; then
1231         enable_glx=dri
1232     elif test -n "$with_gallium_drivers"; then
1233         enable_glx=gallium-xlib
1234     else
1235         enable_glx=xlib
1236     fi
1237 fi
1238 case "x$enable_glx" in
1239 xdri | xxlib | xgallium-xlib)
1240     # GLX requires OpenGL
1241     if test "x$enable_opengl" = xno; then
1242         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1243     fi
1244
1245     # Check individual dependencies
1246     case "x$enable_glx" in
1247     xdri)
1248         if test "x$enable_dri" = xno; then
1249             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1250         fi
1251         ;;
1252     xxlib)
1253         if test "x$enable_dri" = xyes; then
1254             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1255         fi
1256         ;;
1257     xgallium-xlib )
1258         if test "x$enable_dri" = xyes; then
1259             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1260         fi
1261         if test -z "$with_gallium_drivers"; then
1262             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1263         fi
1264         ;;
1265     esac
1266     ;;
1267 xno)
1268     ;;
1269 *)
1270     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1271     ;;
1272 esac
1273
1274 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1275 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1276 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1277 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1278
1279 DEFAULT_GL_LIB_NAME=GL
1280
1281 dnl
1282 dnl Libglvnd configuration
1283 dnl
1284 AC_ARG_ENABLE([libglvnd],
1285     [AS_HELP_STRING([--enable-libglvnd],
1286         [Build for libglvnd @<:@default=disabled@:>@])],
1287     [enable_libglvnd="$enableval"],
1288     [enable_libglvnd=no])
1289 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1290 if test "x$enable_libglvnd" = xyes ; then
1291     dnl XXX: update once we can handle more than libGL/glx.
1292     dnl Namely: we should error out if neither of the glvnd enabled libraries
1293     dnl are built
1294     case "x$enable_glx" in
1295     xno)
1296         AC_MSG_ERROR([cannot build libglvnd without GLX])
1297         ;;
1298     xxlib | xgallium-xlib )
1299         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1300         ;;
1301     xdri)
1302         ;;
1303     esac
1304
1305     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1306     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1307     DEFAULT_GL_LIB_NAME=GLX_mesa
1308 fi
1309
1310 AC_ARG_WITH([gl-lib-name],
1311   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1312     [specify GL library name @<:@default=GL@:>@])],
1313   [GL_LIB=$withval],
1314   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1315 AC_ARG_WITH([osmesa-lib-name],
1316   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1317     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1318   [OSMESA_LIB=$withval],
1319   [OSMESA_LIB=OSMesa])
1320 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1321 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1322
1323 dnl
1324 dnl Mangled Mesa support
1325 dnl
1326 AC_ARG_ENABLE([mangling],
1327   [AS_HELP_STRING([--enable-mangling],
1328     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1329   [enable_mangling="${enableval}"],
1330   [enable_mangling=no]
1331 )
1332 if test "x${enable_mangling}" = "xyes" ; then
1333   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1334   GL_LIB="Mangled${GL_LIB}"
1335   OSMESA_LIB="Mangled${OSMESA_LIB}"
1336 fi
1337 AC_SUBST([GL_LIB])
1338 AC_SUBST([OSMESA_LIB])
1339
1340 # Check for libdrm
1341 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1342                   [have_libdrm=yes], [have_libdrm=no])
1343 if test "x$have_libdrm" = xyes; then
1344         DEFINES="$DEFINES -DHAVE_LIBDRM"
1345 fi
1346
1347 require_libdrm() {
1348     if test "x$have_libdrm" != xyes; then
1349        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1350     fi
1351 }
1352
1353
1354 # Select which platform-dependent DRI code gets built
1355 case "$host_os" in
1356 darwin*)
1357     dri_platform='apple' ;;
1358 cygwin*)
1359     dri_platform='windows' ;;
1360 gnu*)
1361     dri_platform='none' ;;
1362 *)
1363     dri_platform='drm' ;;
1364 esac
1365
1366 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1367     have_drisw_kms='yes'
1368 fi
1369
1370 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1371 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1372 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1373 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1374 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1375 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1376 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1377 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1378 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1379
1380 AC_ARG_ENABLE([shared-glapi],
1381     [AS_HELP_STRING([--enable-shared-glapi],
1382         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1383     [enable_shared_glapi="$enableval"],
1384     [enable_shared_glapi=yes])
1385
1386 case "x$enable_opengl$enable_gles1$enable_gles2" in
1387 x*yes*yes*)
1388     if test "x$enable_shared_glapi" = xno; then
1389         AC_MSG_ERROR([shared GLAPI required when building two or more of
1390                       the following APIs - opengl, gles1 gles2])
1391     fi
1392     ;;
1393 esac
1394
1395 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1396
1397 # Build the pipe-drivers as separate libraries/modules.
1398 # Do not touch this unless you know what you are doing.
1399 # XXX: Expose via configure option ?
1400 enable_shared_pipe_drivers=no
1401
1402 dnl
1403 dnl Driver specific build directories
1404 dnl
1405
1406 if test "x$enable_gallium_osmesa" = xyes; then
1407     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1408         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1409     fi
1410     if test "x$enable_osmesa" = xyes; then
1411         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1412     fi
1413 fi
1414
1415 require_dri_shared_libs_and_glapi() {
1416     if test "x$enable_static" = xyes; then
1417         AC_MSG_ERROR([$1 cannot be build as static library])
1418     fi
1419
1420     if test "x$enable_dri" != xyes; then
1421         # There is only a single backend which won't be build/used otherwise.
1422         # XXX: Revisit this as the egl/haiku is a thing.
1423         AC_MSG_ERROR([$1 requires --enable-dri])
1424     fi
1425
1426     if test "x$enable_shared_glapi" != xyes; then
1427         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1428     fi
1429 }
1430
1431 if test "x$enable_dri" = xyes; then
1432     require_dri_shared_libs_and_glapi "DRI"
1433
1434     # not a hard requirement as swrast does not depend on it
1435     if test "x$have_libdrm" = xyes; then
1436         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1437     fi
1438 fi
1439
1440 AC_ARG_ENABLE([driglx-direct],
1441     [AS_HELP_STRING([--disable-driglx-direct],
1442         [disable direct rendering in GLX and EGL for DRI \
1443             @<:@default=auto@:>@])],
1444     [driglx_direct="$enableval"],
1445     [driglx_direct="yes"])
1446
1447 dnl
1448 dnl libGL configuration per driver
1449 dnl
1450 if test "x$enable_glx" != xno; then
1451     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1452 fi
1453 case "x$enable_glx" in
1454 xxlib | xgallium-xlib)
1455     # Xlib-based GLX
1456     dri_modules="x11 xext xcb"
1457     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1458     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1459     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1460     GL_LIB_DEPS="$XLIBGL_LIBS"
1461     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1462     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1463     ;;
1464 xdri)
1465     # DRI-based GLX
1466
1467     # find the DRI deps for libGL
1468     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1469
1470     if test x"$driglx_direct" = xyes; then
1471         if test x"$dri_platform" = xdrm ; then
1472             DEFINES="$DEFINES -DGLX_USE_DRM"
1473             require_libdrm "Direct rendering"
1474
1475             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1476             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1477             if test x"$enable_dri3" = xyes; then
1478                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1479                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1480             fi
1481
1482             if test x"$enable_dri" = xyes; then
1483                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1484             fi
1485
1486             if test x"$enable_dri3" = xyes; then
1487                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1488                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1489                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1490             fi
1491         fi
1492         if test x"$dri_platform" = xapple ; then
1493             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1494         fi
1495         if test x"$dri_platform" = xwindows ; then
1496             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1497         fi
1498     fi
1499
1500     # add xf86vidmode if available
1501     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1502     if test "$HAVE_XF86VIDMODE" = yes ; then
1503         dri_modules="$dri_modules xxf86vm"
1504     fi
1505
1506     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1507     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1508     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1509     GL_LIB_DEPS="$DRIGL_LIBS"
1510
1511     # need DRM libs, $PTHREAD_LIBS, etc.
1512     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1513     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1514     ;;
1515 esac
1516
1517 # This is outside the case (above) so that it is invoked even for non-GLX
1518 # builds.
1519 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1520
1521 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1522 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1523 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1524 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1525
1526 AC_SUBST([X11_INCLUDES])
1527 AC_SUBST([GL_LIB_DEPS])
1528 AC_SUBST([GL_PC_REQ_PRIV])
1529 AC_SUBST([GL_PC_LIB_PRIV])
1530 AC_SUBST([GL_PC_CFLAGS])
1531 AC_SUBST([DRI_PC_REQ_PRIV])
1532 AC_SUBST([GLESv1_CM_LIB_DEPS])
1533 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1534 AC_SUBST([GLESv2_LIB_DEPS])
1535 AC_SUBST([GLESv2_PC_LIB_PRIV])
1536
1537 AC_SUBST([HAVE_XF86VIDMODE])
1538
1539 dnl
1540 dnl More GLX setup
1541 dnl
1542 case "x$enable_glx" in
1543 xxlib | xgallium-xlib)
1544     DEFINES="$DEFINES -DUSE_XSHM"
1545     ;;
1546 xdri)
1547     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1548     if test "x$driglx_direct" = xyes; then
1549         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1550     fi
1551     ;;
1552 esac
1553
1554 dnl
1555 dnl TLS detection
1556 dnl
1557
1558 AC_ARG_ENABLE([glx-tls],
1559     [AS_HELP_STRING([--enable-glx-tls],
1560         [enable TLS support in GLX @<:@default=enabled@:>@])],
1561     [GLX_USE_TLS="$enableval"],
1562     [GLX_USE_TLS=yes])
1563 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1564
1565 if test "x$GLX_USE_TLS" = xyes; then
1566     DEFINES="$DEFINES -DGLX_USE_TLS"
1567 fi
1568
1569 dnl Read-only text section on x86 hardened platforms
1570 AC_ARG_ENABLE([glx-read-only-text],
1571     [AS_HELP_STRING([--enable-glx-read-only-text],
1572         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1573     [enable_glx_read_only_text="$enableval"],
1574     [enable_glx_read_only_text=no])
1575 if test "x$enable_glx_read_only_text" = xyes; then
1576     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1577 fi
1578
1579 dnl
1580 dnl More DRI setup
1581 dnl
1582 dnl Directory for DRI drivers
1583 AC_ARG_WITH([dri-driverdir],
1584     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1585         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1586     [DRI_DRIVER_INSTALL_DIR="$withval"],
1587     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1588 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1589 dnl Extra search path for DRI drivers
1590 AC_ARG_WITH([dri-searchpath],
1591     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1592         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1593     [DRI_DRIVER_SEARCH_DIR="$withval"],
1594     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1595 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1596 dnl Which drivers to build - default is chosen by platform
1597 AC_ARG_WITH([dri-drivers],
1598     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1599         [comma delimited classic DRI drivers list, e.g.
1600         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1601     [with_dri_drivers="$withval"],
1602     [with_dri_drivers=auto])
1603
1604 if test "x$with_dri_drivers" = xauto; then
1605     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1606         with_dri_drivers="yes"
1607     else
1608         with_dri_drivers="no"
1609     fi
1610 fi
1611 if test "x$with_dri_drivers" = xno; then
1612     with_dri_drivers=''
1613 fi
1614
1615 dnl If $with_dri_drivers is yes, drivers will be added through
1616 dnl platform checks. Set DEFINES and LIB_DEPS
1617 if test "x$enable_dri" = xyes; then
1618     # Platform specific settings and drivers to build
1619     case "$host_os" in
1620     linux*)
1621         if test "x$enable_dri3" = xyes; then
1622             DEFINES="$DEFINES -DHAVE_DRI3"
1623         fi
1624
1625         case "$host_cpu" in
1626         powerpc* | sparc*)
1627             # Build only the drivers for cards that exist on PowerPC/sparc
1628             if test "x$with_dri_drivers" = "xyes"; then
1629                 with_dri_drivers="r200 radeon swrast"
1630             fi
1631             ;;
1632         esac
1633         ;;
1634     cygwin*)
1635         if test "x$with_dri_drivers" = "xyes"; then
1636             with_dri_drivers="swrast"
1637         fi
1638         ;;
1639     darwin*)
1640         DEFINES="$DEFINES -DBUILDING_MESA"
1641         if test "x$with_dri_drivers" = "xyes"; then
1642             with_dri_drivers="swrast"
1643         fi
1644         ;;
1645     esac
1646
1647     # default drivers
1648     if test "x$with_dri_drivers" = "xyes"; then
1649         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1650     fi
1651
1652     # Check for expat
1653     PKG_CHECK_MODULES([EXPAT], [expat], [],
1654         # expat version 2.0 and earlier do not provide expat.pc
1655         [AC_CHECK_HEADER([expat.h],[],
1656                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1657          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1658                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1659          EXPAT_LIBS="-lexpat"])
1660
1661     # put all the necessary libs together
1662     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1663 fi
1664
1665 AC_SUBST([DRI_LIB_DEPS])
1666
1667 DRI_DIRS=''
1668 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1669 if test -n "$with_dri_drivers"; then
1670     if test "x$enable_opengl" != xyes; then
1671         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1672     fi
1673
1674     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1675     for driver in $dri_drivers; do
1676         DRI_DIRS="$DRI_DIRS $driver"
1677         case "x$driver" in
1678         xi915)
1679             require_libdrm "i915"
1680             HAVE_I915_DRI=yes
1681             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1682             ;;
1683         xi965)
1684             require_libdrm "i965"
1685             HAVE_I965_DRI=yes
1686             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1687             ;;
1688         xnouveau)
1689             require_libdrm "nouveau"
1690             HAVE_NOUVEAU_DRI=yes
1691             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1692             ;;
1693         xradeon)
1694             require_libdrm "radeon"
1695             HAVE_RADEON_DRI=yes;
1696             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1697             ;;
1698         xr200)
1699             require_libdrm "r200"
1700             HAVE_R200_DRI=yes
1701             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1702             ;;
1703         xswrast)
1704             HAVE_SWRAST_DRI=yes
1705             ;;
1706         *)
1707             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1708             ;;
1709         esac
1710     done
1711     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1712 fi
1713
1714
1715 dnl
1716 dnl Gallium LLVM
1717 dnl Deprecated: kept for backwards compatibility
1718 dnl
1719 AC_ARG_ENABLE([gallium-llvm],
1720     [AS_HELP_STRING([--enable-gallium-llvm],
1721         [DEPRECATED: use --enable-llvm instead])],
1722     [enable_gallium_llvm="$enableval"],
1723     [enable_gallium_llvm=auto])
1724
1725 if test "x$enable_gallium_llvm" != xauto; then
1726    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1727    enable_llvm=$enable_gallium_llvm
1728 fi
1729
1730 dnl
1731 dnl LLVM
1732 dnl
1733 AC_ARG_ENABLE([llvm],
1734     [AS_HELP_STRING([--enable-llvm],
1735         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1736     [enable_llvm="$enableval"],
1737     [enable_llvm=auto])
1738
1739 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1740     if test "x$FOUND_LLVM" = xyes; then
1741         case "$host_cpu" in
1742         i*86|x86_64|amd64) enable_llvm=yes;;
1743         *) enable_llvm=no;;
1744         esac
1745     else
1746         enable_llvm=no
1747     fi
1748 fi
1749
1750 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1751     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1752 fi
1753
1754 #
1755 # Vulkan driver configuration
1756 #
1757
1758 AC_ARG_WITH([vulkan-drivers],
1759     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1760         [comma delimited Vulkan drivers list, e.g.
1761         "intel,radeon"
1762         @<:@default=no@:>@])],
1763     [with_vulkan_drivers="$withval"],
1764     [with_vulkan_drivers="no"])
1765
1766 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1767 # here so that the script doesn't choke on an unknown driver name later.
1768 case "x$with_vulkan_drivers" in
1769     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1770     xno) with_vulkan_drivers='' ;;
1771 esac
1772
1773 AC_ARG_WITH([vulkan-icddir],
1774     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1775         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1776     [VULKAN_ICD_INSTALL_DIR="$withval"],
1777     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1778 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1779
1780 if test -n "$with_vulkan_drivers"; then
1781     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1782         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1783     fi
1784
1785     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1786     for driver in $VULKAN_DRIVERS; do
1787         case "x$driver" in
1788         xintel)
1789             require_libdrm "ANV"
1790             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1791             HAVE_INTEL_VULKAN=yes
1792             ;;
1793         xradeon)
1794             require_libdrm "radv"
1795             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1796             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1797             HAVE_RADEON_VULKAN=yes
1798             ;;
1799         *)
1800             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1801             ;;
1802         esac
1803     done
1804     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1805 fi
1806
1807
1808 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1809 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1810 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1811                                   "x$enable_osmesa" = xyes -o \
1812                                   -n "$DRI_DIRS")
1813
1814 dnl
1815 dnl OSMesa configuration
1816 dnl
1817
1818 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1819 AC_ARG_WITH([osmesa-bits],
1820     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1821         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1822     [osmesa_bits="$withval"],
1823     [osmesa_bits=8])
1824 if test "x$osmesa_bits" != x8; then
1825     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1826         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1827         osmesa_bits=8
1828     fi
1829 fi
1830 case "x$osmesa_bits" in
1831 x8)
1832     OSMESA_LIB="${OSMESA_LIB}"
1833     ;;
1834 x16|x32)
1835     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1836     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1837     ;;
1838 *)
1839     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1840     ;;
1841 esac
1842
1843 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1844     # only link libraries with osmesa if shared
1845     if test "$enable_static" = no; then
1846         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1847     else
1848         OSMESA_LIB_DEPS=""
1849     fi
1850     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1851 fi
1852
1853 AC_SUBST([OSMESA_LIB_DEPS])
1854 AC_SUBST([OSMESA_PC_REQ])
1855 AC_SUBST([OSMESA_PC_LIB_PRIV])
1856
1857 dnl
1858 dnl gbm configuration
1859 dnl
1860 if test "x$enable_gbm" = xyes; then
1861     require_dri_shared_libs_and_glapi "gbm"
1862 fi
1863 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1864 # FINISHME: GBM has a number of dependencies which we should add below
1865 GBM_PC_REQ_PRIV=""
1866 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1867 AC_SUBST([GBM_PC_REQ_PRIV])
1868 AC_SUBST([GBM_PC_LIB_PRIV])
1869
1870 dnl
1871 dnl EGL configuration
1872 dnl
1873
1874 if test "x$enable_egl" = xyes; then
1875     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1876
1877     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1878
1879     require_dri_shared_libs_and_glapi "egl"
1880 fi
1881 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1882 AC_SUBST([EGL_LIB_DEPS])
1883
1884 gallium_st="mesa"
1885
1886 dnl
1887 dnl XA configuration
1888 dnl
1889 if test "x$enable_xa" = xyes; then
1890     if test "x$with_gallium_drivers" = xswrast; then
1891        AC_MSG_ERROR([
1892           Building xa requires at least one non swrast gallium driver.
1893           If you are looking to use libxatracker.so with the VMware driver,
1894           make sure to include svga in the gallium drivers list, apart from
1895           enabling XA.
1896           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1897     fi
1898     gallium_st="$gallium_st xa"
1899 fi
1900 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1901
1902 dnl
1903 dnl Gallium G3DVL configuration
1904 dnl
1905 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1906     if test "x$enable_xvmc" = xauto; then
1907         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1908     fi
1909
1910     if test "x$enable_vdpau" = xauto; then
1911         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1912     fi
1913
1914     if test "x$enable_omx" = xauto; then
1915         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1916     fi
1917
1918     if test "x$enable_va" = xauto; then
1919         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1920     fi
1921 fi
1922
1923 if test "x$enable_dri" = xyes -o \
1924         "x$enable_xvmc" = xyes -o \
1925         "x$enable_vdpau" = xyes -o \
1926         "x$enable_omx" = xyes -o \
1927         "x$enable_va" = xyes; then
1928     need_gallium_vl=yes
1929 fi
1930 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1931
1932 if test "x$enable_xvmc" = xyes -o \
1933         "x$enable_vdpau" = xyes -o \
1934         "x$enable_omx" = xyes -o \
1935         "x$enable_va" = xyes; then
1936     if test x"$enable_dri3" = xyes; then
1937         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1938                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1939     else
1940         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1941     fi
1942     need_gallium_vl_winsys=yes
1943 fi
1944 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1945
1946 if test "x$enable_xvmc" = xyes; then
1947     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1948     gallium_st="$gallium_st xvmc"
1949 fi
1950 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1951
1952 if test "x$enable_vdpau" = xyes; then
1953     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1954     gallium_st="$gallium_st vdpau"
1955     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1956 fi
1957 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1958
1959 if test "x$enable_omx" = xyes; then
1960     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1961     gallium_st="$gallium_st omx"
1962 fi
1963 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1964
1965 if test "x$enable_va" = xyes; then
1966     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1967     gallium_st="$gallium_st va"
1968 fi
1969 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1970
1971 dnl
1972 dnl Nine Direct3D9 configuration
1973 dnl
1974 if test "x$enable_nine" = xyes; then
1975     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1976         AC_MSG_ERROR([nine requires the gallium swrast driver])
1977     fi
1978     if test "x$with_gallium_drivers" = xswrast; then
1979         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1980     fi
1981     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1982         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1983     fi
1984
1985     if test "x$enable_dri3" = xno; then
1986         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1987     fi
1988
1989     gallium_st="$gallium_st nine"
1990 fi
1991 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1992
1993 dnl
1994 dnl OpenCL configuration
1995 dnl
1996
1997 AC_ARG_WITH([clang-libdir],
1998    [AS_HELP_STRING([--with-clang-libdir],
1999          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2000    [CLANG_LIBDIR="$withval"],
2001    [CLANG_LIBDIR=''])
2002
2003 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2004
2005 if test "x$enable_opencl" = xyes; then
2006     if test -z "$with_gallium_drivers"; then
2007         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2008     fi
2009
2010     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2011         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2012     fi
2013
2014     if test "x$have_libclc" = xno; then
2015         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2016                     Make sure the directory containing libclc.pc is specified in your
2017                     PKG_CONFIG_PATH environment variable.
2018                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2019     else
2020         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2021         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2022         AC_SUBST([LIBCLC_INCLUDEDIR])
2023         AC_SUBST([LIBCLC_LIBEXECDIR])
2024     fi
2025
2026     gallium_st="$gallium_st clover"
2027
2028     if test "x$enable_opencl_icd" = xyes; then
2029         OPENCL_LIBNAME="MesaOpenCL"
2030     else
2031         OPENCL_LIBNAME="OpenCL"
2032     fi
2033
2034     if test "x$have_libelf" != xyes; then
2035        AC_MSG_ERROR([Clover requires libelf])
2036     fi
2037
2038     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2039         altivec_enabled=no
2040         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2041         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2042         #error "AltiVec not enabled"
2043         #endif
2044         ])], altivec_enabled=yes)
2045
2046         if test "$altivec_enabled" = yes; then
2047             CLOVER_STD_OVERRIDE="-std=gnu++11"
2048         fi
2049         AC_SUBST([CLOVER_STD_OVERRIDE])
2050     fi
2051
2052     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2053
2054     llvm_add_default_components "opencl"
2055     llvm_add_component "all-targets" "opencl"
2056     llvm_add_component "linker" "opencl"
2057     llvm_add_component "instrumentation" "opencl"
2058     llvm_add_component "ipo" "opencl"
2059     llvm_add_component "irreader" "opencl"
2060     llvm_add_component "option" "opencl"
2061     llvm_add_component "objcarcopts" "opencl"
2062     llvm_add_component "profiledata" "opencl"
2063
2064     dnl Check for Clang internal headers
2065     if test -z "$CLANG_LIBDIR"; then
2066         CLANG_LIBDIR=${LLVM_LIBDIR}
2067     fi
2068     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2069     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2070         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2071 fi
2072 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2073 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2074 AC_SUBST([OPENCL_LIBNAME])
2075 AC_SUBST([CLANG_RESOURCE_DIR])
2076
2077 dnl
2078 dnl Gallium configuration
2079 dnl
2080 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2081
2082 dnl
2083 dnl EGL Platforms configuration
2084 dnl
2085 AC_ARG_WITH([egl-platforms],
2086     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2087         [comma delimited native platforms libEGL supports, e.g.
2088         "x11,drm" @<:@default=auto@:>@])],
2089     [with_egl_platforms="$withval"],
2090     [if test "x$enable_egl" = xyes; then
2091         if test "x$enable_gbm" = xyes; then
2092            with_egl_platforms="x11,drm"
2093         else
2094            with_egl_platforms="x11"
2095         fi
2096     else
2097         with_egl_platforms=""
2098     fi])
2099
2100 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2101     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2102 fi
2103
2104 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2105         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2106         WAYLAND_SCANNER='')
2107 if test "x$WAYLAND_SCANNER" = x; then
2108     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
2109 fi
2110
2111 # Do per-EGL platform setups and checks
2112 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2113 for plat in $egl_platforms; do
2114         case "$plat" in
2115         wayland)
2116
2117                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2118
2119                 if test "x$WAYLAND_SCANNER" = "x:"; then
2120                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2121                 fi
2122                 ;;
2123
2124         x11)
2125                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2126                 ;;
2127
2128         drm)
2129                 test "x$enable_gbm" = "xno" &&
2130                         AC_MSG_ERROR([EGL platform drm needs gbm])
2131                 ;;
2132
2133         surfaceless)
2134                 ;;
2135
2136         android)
2137                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2138                 ;;
2139
2140         *)
2141                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2142                 ;;
2143         esac
2144
2145         case "$plat" in
2146         wayland|drm|surfaceless)
2147                 require_libdrm "Platform $plat"
2148                 ;;
2149         esac
2150 done
2151
2152 # libEGL wants to default to the first platform specified in
2153 # ./configure.  parse that here.
2154 if test "x$egl_platforms" != "x"; then
2155     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2156     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2157 else
2158     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2159 fi
2160
2161 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2162 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2163 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2164 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2165 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2166
2167 AC_SUBST([EGL_NATIVE_PLATFORM])
2168 AC_SUBST([EGL_CFLAGS])
2169
2170 # If we don't have the X11 platform, set this define so we don't try to include
2171 # the X11 headers.
2172 if ! echo "$egl_platforms" | grep -q 'x11'; then
2173     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2174     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2175 fi
2176
2177 dnl Directory for XVMC libs
2178 AC_ARG_WITH([xvmc-libdir],
2179     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2180         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2181     [XVMC_LIB_INSTALL_DIR="$withval"],
2182     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2183 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2184
2185 dnl
2186 dnl Gallium Tests
2187 dnl
2188 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2189
2190 dnl Directory for VDPAU libs
2191 AC_ARG_WITH([vdpau-libdir],
2192     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2193         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2194     [VDPAU_LIB_INSTALL_DIR="$withval"],
2195     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2196 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2197
2198 dnl Directory for OMX libs
2199
2200 AC_ARG_WITH([omx-libdir],
2201     [AS_HELP_STRING([--with-omx-libdir=DIR],
2202         [directory for the OMX libraries])],
2203     [OMX_LIB_INSTALL_DIR="$withval"],
2204     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2205                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2206 AC_SUBST([OMX_LIB_INSTALL_DIR])
2207
2208 dnl Directory for VA libs
2209
2210 AC_ARG_WITH([va-libdir],
2211     [AS_HELP_STRING([--with-va-libdir=DIR],
2212         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2213     [VA_LIB_INSTALL_DIR="$withval"],
2214     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2215 AC_SUBST([VA_LIB_INSTALL_DIR])
2216
2217 AC_ARG_WITH([d3d-libdir],
2218     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2219         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2220     [D3D_DRIVER_INSTALL_DIR="$withval"],
2221     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2222 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2223
2224 dnl
2225 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2226 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2227 dnl architectures.
2228 dnl
2229 r300_require_llvm() {
2230     case "$host" in *gnux32) return;; esac
2231     case "$host_cpu" in
2232     i*86|x86_64|amd64) require_llvm $1
2233         ;;
2234     esac
2235 }
2236
2237 dnl
2238 dnl DRM is needed by X, Wayland, and offscreen rendering.
2239 dnl Surfaceless is an alternative for the last one.
2240 dnl
2241 require_basic_egl() {
2242     case "$with_egl_platforms" in
2243         *drm*|*surfaceless*)
2244             ;;
2245         *)
2246             AC_MSG_ERROR([$1 requires one of these:
2247                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2248                   2) --with-egl-platforms=surfaceless (offscreen only)
2249                   Recommended options: drm,x11])
2250             ;;
2251     esac
2252 }
2253
2254 swr_require_cxx_feature_flags() {
2255     feature_name="$1"
2256     preprocessor_test="$2"
2257     option_list="$3"
2258     output_var="$4"
2259
2260     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2261     AC_LANG_PUSH([C++])
2262     save_CXXFLAGS="$CXXFLAGS"
2263     save_IFS="$IFS"
2264     IFS=","
2265     found=0
2266     for opts in $option_list
2267     do
2268         unset IFS
2269         CXXFLAGS="$opts $save_CXXFLAGS"
2270         AC_COMPILE_IFELSE(
2271             [AC_LANG_PROGRAM(
2272                 [   #if !($preprocessor_test)
2273                     #error
2274                     #endif
2275                 ])],
2276             [found=1; break],
2277             [])
2278         IFS=","
2279     done
2280     IFS="$save_IFS"
2281     CXXFLAGS="$save_CXXFLAGS"
2282     AC_LANG_POP([C++])
2283     if test $found -eq 1; then
2284         AC_MSG_RESULT([$opts])
2285         eval "$output_var=\$opts"
2286         return 0
2287     fi
2288     AC_MSG_RESULT([no])
2289     AC_MSG_ERROR([swr requires $feature_name support])
2290     return 1
2291 }
2292
2293 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2294 if test -n "$with_gallium_drivers"; then
2295     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2296     for driver in $gallium_drivers; do
2297         case "x$driver" in
2298         xsvga)
2299             HAVE_GALLIUM_SVGA=yes
2300             require_libdrm "svga"
2301             ;;
2302         xi915)
2303             HAVE_GALLIUM_I915=yes
2304             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2305             require_libdrm "Gallium i915"
2306             ;;
2307         xr300)
2308             HAVE_GALLIUM_R300=yes
2309             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2310             require_libdrm "r300"
2311             r300_require_llvm "r300"
2312             ;;
2313         xr600)
2314             HAVE_GALLIUM_R600=yes
2315             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2316             require_libdrm "r600"
2317             if test "x$enable_llvm" = xyes; then
2318                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2319
2320                 llvm_add_component "asmparser" "r600"
2321                 llvm_add_component "bitreader" "r600"
2322             fi
2323             ;;
2324         xradeonsi)
2325             HAVE_GALLIUM_RADEONSI=yes
2326             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2327             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2328             require_libdrm "radeonsi"
2329             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2330             if test "x$enable_egl" = xyes; then
2331                 require_basic_egl "radeonsi"
2332             fi
2333             ;;
2334         xnouveau)
2335             HAVE_GALLIUM_NOUVEAU=yes
2336             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2337             require_libdrm "nouveau"
2338             ;;
2339         xfreedreno)
2340             HAVE_GALLIUM_FREEDRENO=yes
2341             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2342             require_libdrm "freedreno"
2343             ;;
2344         xetnaviv)
2345             HAVE_GALLIUM_ETNAVIV=yes
2346             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2347             require_libdrm "etnaviv"
2348             ;;
2349        ximx)
2350             HAVE_GALLIUM_IMX=yes
2351             ;;
2352         xswrast)
2353             HAVE_GALLIUM_SOFTPIPE=yes
2354             if test "x$enable_llvm" = xyes; then
2355                 HAVE_GALLIUM_LLVMPIPE=yes
2356             fi
2357             ;;
2358         xswr)
2359             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2360
2361             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2362                 ",-std=c++11" \
2363                 SWR_CXX11_CXXFLAGS
2364             AC_SUBST([SWR_CXX11_CXXFLAGS])
2365
2366             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2367                 ",-mavx,-march=core-avx" \
2368                 SWR_AVX_CXXFLAGS
2369             AC_SUBST([SWR_AVX_CXXFLAGS])
2370
2371             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2372                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2373                 SWR_AVX2_CXXFLAGS
2374             AC_SUBST([SWR_AVX2_CXXFLAGS])
2375
2376             HAVE_GALLIUM_SWR=yes
2377             ;;
2378         xvc4)
2379             HAVE_GALLIUM_VC4=yes
2380             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2381             require_libdrm "vc4"
2382
2383             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2384                               [USE_VC4_SIMULATOR=yes;
2385                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2386                               [USE_VC4_SIMULATOR=no])
2387             ;;
2388         xvirgl)
2389             HAVE_GALLIUM_VIRGL=yes
2390             require_libdrm "virgl"
2391             require_basic_egl "virgl"
2392             ;;
2393         *)
2394             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2395             ;;
2396         esac
2397     done
2398 fi
2399
2400 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2401     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2402     llvm_add_default_components "gallium"
2403 fi
2404
2405 dnl We need to validate some needed dependencies for renderonly drivers.
2406
2407 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2408     AC_MSG_ERROR([Building with imx requires etnaviv])
2409 fi
2410
2411 dnl
2412 dnl Set defines and buildtime variables only when using LLVM.
2413 dnl
2414 if test "x$enable_llvm" = xyes; then
2415     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2416
2417     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2418     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2419     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2420
2421     dnl Set LLVM_LIBS - This is done after the driver configuration so
2422     dnl that drivers can add additional components to LLVM_COMPONENTS.
2423     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2424     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2425     dnl this was causing the same libraries to be appear multiple times
2426     dnl in LLVM_LIBS.
2427
2428     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2429        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2430     fi
2431     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2432
2433     dnl llvm-config may not give the right answer when llvm is a built as a
2434     dnl single shared library, so we must work the library name out for
2435     dnl ourselves.
2436     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2437     if test "x$enable_llvm_shared_libs" = xyes; then
2438         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2439         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2440         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2441
2442         if test "x$llvm_have_one_so" = xyes; then
2443             dnl LLVM was built using auto*, so there is only one shared object.
2444             LLVM_LIBS="-l$LLVM_SO_NAME"
2445         else
2446             dnl If LLVM was built with CMake, there will be one shared object per
2447             dnl component.
2448             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2449                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2450         Please make sure you have built llvm with the --enable-shared option
2451         and that your llvm libraries are installed in $LLVM_LIBDIR
2452         If you have installed your llvm libraries to a different directory you
2453         can use the --with-llvm-prefix= configure flag to specify this directory.
2454         NOTE: Mesa is attempting to use llvm shared libraries by default.
2455         If you do not want to build with llvm shared libraries and instead want to
2456         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2457         invocation and rebuild.])])
2458
2459            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2460            dnl install uses a shared object for each component and we have
2461            dnl already added all of these objects to LLVM_LIBS.
2462         fi
2463     else
2464         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2465         dnl We need to link to llvm system libs when using static libs
2466         dnl However, only llvm 3.5+ provides --system-libs
2467         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2468             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2469         fi
2470     fi
2471 fi
2472
2473 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2474 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2475 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2476 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2477 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2478 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2479                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2480 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2481 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2482 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2483 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2484 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2485 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2486 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2487 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2488                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2489                                          "x$HAVE_GALLIUM_SWR" = xyes)
2490 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2491 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2492
2493 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2494
2495 if test "x$enable_dri" = xyes; then
2496     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2497 fi
2498
2499 if test "x$have_drisw_kms" = xyes; then
2500     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2501 fi
2502 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2503
2504 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2505 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2506 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2507 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2508 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2509 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2510
2511 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2512 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2513
2514 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2515                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2516                                       "x$HAVE_RADEON_VULKAN" = xyes)
2517
2518 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2519                                         "x$HAVE_I965_DRI" = xyes)
2520
2521 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2522                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2523                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2524 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2525 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2526 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2527 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2528
2529 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2530 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2531 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2532 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2533                                         "x$enable_gallium_osmesa" = xyes)
2534
2535 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2536 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2537 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2538
2539 AC_SUBST([NINE_MAJOR], 1)
2540 AC_SUBST([NINE_MINOR], 0)
2541 AC_SUBST([NINE_TINY], 0)
2542 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2543
2544 AC_SUBST([VDPAU_MAJOR], 1)
2545 AC_SUBST([VDPAU_MINOR], 0)
2546
2547 if test "x$enable_va" = xyes; then
2548     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2549     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2550 fi
2551 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2552 AC_SUBST([VA_MINOR], $VA_MINOR)
2553
2554 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2555
2556 AC_SUBST([XVMC_MAJOR], 1)
2557 AC_SUBST([XVMC_MINOR], 0)
2558
2559 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2560 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2561 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2562 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2563
2564 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2565 AC_SUBST([XA_MINOR], $XA_MINOR)
2566 AC_SUBST([XA_TINY], $XA_TINY)
2567 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2568
2569 AC_ARG_ENABLE(valgrind,
2570               [AS_HELP_STRING([--enable-valgrind],
2571                              [Build mesa with valgrind support (default: auto)])],
2572                              [VALGRIND=$enableval], [VALGRIND=auto])
2573 if test "x$VALGRIND" != xno; then
2574         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2575 fi
2576 AC_MSG_CHECKING([whether to enable Valgrind support])
2577 if test "x$VALGRIND" = xauto; then
2578         VALGRIND="$have_valgrind"
2579 fi
2580
2581 if test "x$VALGRIND" = "xyes"; then
2582         if ! test "x$have_valgrind" = xyes; then
2583                 AC_MSG_ERROR([Valgrind support required but not present])
2584         fi
2585         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2586 fi
2587
2588 AC_MSG_RESULT([$VALGRIND])
2589
2590 dnl Restore LDFLAGS and CPPFLAGS
2591 LDFLAGS="$_SAVE_LDFLAGS"
2592 CPPFLAGS="$_SAVE_CPPFLAGS"
2593
2594 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2595 if test "x$acv_mesa_CLANG" = xyes; then
2596     CFLAGS="$CFLAGS -Qunused-arguments"
2597     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2598 fi
2599
2600 dnl Add user CFLAGS and CXXFLAGS
2601 CFLAGS="$CFLAGS $USER_CFLAGS"
2602 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2603
2604 dnl Substitute the config
2605 AC_CONFIG_FILES([Makefile
2606                 src/Makefile
2607                 src/amd/Makefile
2608                 src/amd/vulkan/Makefile
2609                 src/compiler/Makefile
2610                 src/egl/Makefile
2611                 src/egl/main/egl.pc
2612                 src/egl/wayland/wayland-drm/Makefile
2613                 src/egl/wayland/wayland-egl/Makefile
2614                 src/egl/wayland/wayland-egl/wayland-egl.pc
2615                 src/gallium/Makefile
2616                 src/gallium/auxiliary/Makefile
2617                 src/gallium/auxiliary/pipe-loader/Makefile
2618                 src/gallium/drivers/freedreno/Makefile
2619                 src/gallium/drivers/ddebug/Makefile
2620                 src/gallium/drivers/i915/Makefile
2621                 src/gallium/drivers/llvmpipe/Makefile
2622                 src/gallium/drivers/noop/Makefile
2623                 src/gallium/drivers/nouveau/Makefile
2624                 src/gallium/drivers/r300/Makefile
2625                 src/gallium/drivers/r600/Makefile
2626                 src/gallium/drivers/radeon/Makefile
2627                 src/gallium/drivers/radeonsi/Makefile
2628                 src/gallium/drivers/rbug/Makefile
2629                 src/gallium/drivers/softpipe/Makefile
2630                 src/gallium/drivers/svga/Makefile
2631                 src/gallium/drivers/swr/Makefile
2632                 src/gallium/drivers/trace/Makefile
2633                 src/gallium/drivers/etnaviv/Makefile
2634                 src/gallium/drivers/imx/Makefile
2635                 src/gallium/drivers/vc4/Makefile
2636                 src/gallium/drivers/virgl/Makefile
2637                 src/gallium/state_trackers/clover/Makefile
2638                 src/gallium/state_trackers/dri/Makefile
2639                 src/gallium/state_trackers/glx/xlib/Makefile
2640                 src/gallium/state_trackers/nine/Makefile
2641                 src/gallium/state_trackers/omx/Makefile
2642                 src/gallium/state_trackers/osmesa/Makefile
2643                 src/gallium/state_trackers/va/Makefile
2644                 src/gallium/state_trackers/vdpau/Makefile
2645                 src/gallium/state_trackers/xa/Makefile
2646                 src/gallium/state_trackers/xvmc/Makefile
2647                 src/gallium/targets/d3dadapter9/Makefile
2648                 src/gallium/targets/d3dadapter9/d3d.pc
2649                 src/gallium/targets/dri/Makefile
2650                 src/gallium/targets/libgl-xlib/Makefile
2651                 src/gallium/targets/omx/Makefile
2652                 src/gallium/targets/opencl/Makefile
2653                 src/gallium/targets/opencl/mesa.icd
2654                 src/gallium/targets/osmesa/Makefile
2655                 src/gallium/targets/osmesa/osmesa.pc
2656                 src/gallium/targets/pipe-loader/Makefile
2657                 src/gallium/targets/va/Makefile
2658                 src/gallium/targets/vdpau/Makefile
2659                 src/gallium/targets/xa/Makefile
2660                 src/gallium/targets/xa/xatracker.pc
2661                 src/gallium/targets/xvmc/Makefile
2662                 src/gallium/tests/trivial/Makefile
2663                 src/gallium/tests/unit/Makefile
2664                 src/gallium/winsys/etnaviv/drm/Makefile
2665                 src/gallium/winsys/imx/drm/Makefile
2666                 src/gallium/winsys/freedreno/drm/Makefile
2667                 src/gallium/winsys/i915/drm/Makefile
2668                 src/gallium/winsys/nouveau/drm/Makefile
2669                 src/gallium/winsys/radeon/drm/Makefile
2670                 src/gallium/winsys/amdgpu/drm/Makefile
2671                 src/gallium/winsys/svga/drm/Makefile
2672                 src/gallium/winsys/sw/dri/Makefile
2673                 src/gallium/winsys/sw/kms-dri/Makefile
2674                 src/gallium/winsys/sw/null/Makefile
2675                 src/gallium/winsys/sw/wrapper/Makefile
2676                 src/gallium/winsys/sw/xlib/Makefile
2677                 src/gallium/winsys/vc4/drm/Makefile
2678                 src/gallium/winsys/virgl/drm/Makefile
2679                 src/gallium/winsys/virgl/vtest/Makefile
2680                 src/gbm/Makefile
2681                 src/gbm/main/gbm.pc
2682                 src/glx/Makefile
2683                 src/glx/apple/Makefile
2684                 src/glx/tests/Makefile
2685                 src/glx/windows/Makefile
2686                 src/glx/windows/windowsdriproto.pc
2687                 src/gtest/Makefile
2688                 src/intel/Makefile
2689                 src/loader/Makefile
2690                 src/mapi/Makefile
2691                 src/mapi/es1api/glesv1_cm.pc
2692                 src/mapi/es2api/glesv2.pc
2693                 src/mapi/glapi/gen/Makefile
2694                 src/mesa/Makefile
2695                 src/mesa/gl.pc
2696                 src/mesa/drivers/dri/dri.pc
2697                 src/mesa/drivers/dri/common/Makefile
2698                 src/mesa/drivers/dri/common/xmlpool/Makefile
2699                 src/mesa/drivers/dri/i915/Makefile
2700                 src/mesa/drivers/dri/i965/Makefile
2701                 src/mesa/drivers/dri/Makefile
2702                 src/mesa/drivers/dri/nouveau/Makefile
2703                 src/mesa/drivers/dri/r200/Makefile
2704                 src/mesa/drivers/dri/radeon/Makefile
2705                 src/mesa/drivers/dri/swrast/Makefile
2706                 src/mesa/drivers/osmesa/Makefile
2707                 src/mesa/drivers/osmesa/osmesa.pc
2708                 src/mesa/drivers/x11/Makefile
2709                 src/mesa/main/tests/Makefile
2710                 src/util/Makefile
2711                 src/util/tests/hash_table/Makefile
2712                 src/vulkan/Makefile])
2713
2714 AC_OUTPUT
2715
2716 # Fix up dependencies in *.Plo files, where we changed the extension of a
2717 # source file
2718 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2719
2720
2721 dnl
2722 dnl Output some configuration info for the user
2723 dnl
2724 echo ""
2725 echo "        prefix:          $prefix"
2726 echo "        exec_prefix:     $exec_prefix"
2727 echo "        libdir:          $libdir"
2728 echo "        includedir:      $includedir"
2729
2730 dnl API info
2731 echo ""
2732 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2733
2734 dnl Driver info
2735 echo ""
2736 case "x$enable_osmesa$enable_gallium_osmesa" in
2737 xnoyes)
2738         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2739         ;;
2740 xyesno)
2741         echo "        OSMesa:          lib$OSMESA_LIB"
2742         ;;
2743 xnono)
2744         echo "        OSMesa:          no"
2745         ;;
2746 esac
2747
2748 echo ""
2749 if test "x$enable_dri" != xno; then
2750         echo "        DRI platform:    $dri_platform"
2751         if test -z "$DRI_DIRS"; then
2752             echo "        DRI drivers:     no"
2753         else
2754             echo "        DRI drivers:     $DRI_DIRS"
2755         fi
2756         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2757 fi
2758
2759 case "x$enable_glx" in
2760 xdri)
2761     echo "        GLX:             DRI-based"
2762     ;;
2763 xxlib)
2764     echo "        GLX:             Xlib-based"
2765     ;;
2766 xgallium-xlib)
2767     echo "        GLX:             Xlib-based (Gallium)"
2768     ;;
2769 *)
2770     echo "        GLX:             $enable_glx"
2771     ;;
2772 esac
2773
2774 dnl EGL
2775 echo ""
2776 echo "        EGL:             $enable_egl"
2777 if test "$enable_egl" = yes; then
2778     echo "        EGL platforms:   $egl_platforms"
2779
2780     egl_drivers=""
2781     if test "x$enable_dri" != "xno"; then
2782         egl_drivers="$egl_drivers builtin:egl_dri2"
2783     fi
2784     if test "x$enable_dri3" != "xno"; then
2785         egl_drivers="$egl_drivers builtin:egl_dri3"
2786     fi
2787
2788     echo "        EGL drivers:    $egl_drivers"
2789 fi
2790 if test "x$enable_gbm" = xyes; then
2791     echo "        GBM:             yes"
2792 else
2793     echo "        GBM:             no"
2794 fi
2795
2796 # Vulkan
2797 echo ""
2798 if test "x$VULKAN_DRIVERS" != x; then
2799     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2800     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2801 else
2802     echo "        Vulkan drivers:  no"
2803 fi
2804
2805 echo ""
2806 if test "x$enable_llvm" = xyes; then
2807     echo "        llvm:            yes"
2808     echo "        llvm-config:     $LLVM_CONFIG"
2809     echo "        llvm-version:    $LLVM_VERSION"
2810 else
2811     echo "        llvm:            no"
2812 fi
2813
2814 echo ""
2815 if test -n "$with_gallium_drivers"; then
2816     echo "        Gallium drivers: $gallium_drivers"
2817     echo "        Gallium st:      $gallium_st"
2818 else
2819     echo "        Gallium:         no"
2820 fi
2821
2822 echo ""
2823 if test "x$enable_gallium_extra_hud" != xyes; then
2824     echo "        HUD extra stats: no"
2825 else
2826     echo "        HUD extra stats: yes"
2827 fi
2828
2829 if test "x$enable_lmsensors" != xyes; then
2830     echo "        HUD lmsensors:   no"
2831 else
2832     echo "        HUD lmsensors:   yes"
2833 fi
2834
2835 dnl Libraries
2836 echo ""
2837 echo "        Shared libs:     $enable_shared"
2838 echo "        Static libs:     $enable_static"
2839 echo "        Shared-glapi:    $enable_shared_glapi"
2840
2841 dnl Compiler options
2842 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2843 cflags=`echo $CFLAGS | \
2844     $SED 's/^ *//;s/  */ /;s/ *$//'`
2845 cxxflags=`echo $CXXFLAGS | \
2846     $SED 's/^ *//;s/  */ /;s/ *$//'`
2847 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2848 echo ""
2849 echo "        CFLAGS:          $cflags"
2850 echo "        CXXFLAGS:        $cxxflags"
2851 echo "        Macros:          $defines"
2852 echo ""
2853 if test "x$enable_llvm" = xyes; then
2854     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2855     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2856     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2857     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2858     echo ""
2859 fi
2860 echo "        PYTHON2:         $PYTHON2"
2861
2862 echo ""
2863 echo "        Run '${MAKE-make}' to build Mesa"
2864 echo ""