configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.24
  22 LIBDRM_RADEON_REQUIRED=2.4.24
  23 LIBDRM_INTEL_REQUIRED=2.4.24
  24 DRI2PROTO_REQUIRED=2.1
  25 GLPROTO_REQUIRED=1.4.11
  26 LIBDRM_XORG_REQUIRED=2.4.24
  27 LIBKMS_XORG_REQUIRED=1.0.0
  28
  29 dnl Check for progs
  30 AC_PROG_CPP
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_CHECK_PROGS([MAKE], [gmake make])
  34 AC_CHECK_PROGS([PYTHON2], [python2 python])
  35 AC_PATH_PROG([MKDEP], [makedepend])
  36 AC_PATH_PROG([SED], [sed])
  37
  38 if test "x$MKDEP" = "x"; then
  39     AC_MSG_ERROR([makedepend is required to build Mesa])
  40 fi
  41
  42 AC_PATH_PROG([FLEX], [flex])
  43 test "x$FLEX" = "x" && AC_MSG_ERROR([flex is needed to build Mesa])
  44
  45 AC_PATH_PROG([BISON], [bison])
  46 test "x$BISON" = "x" && AC_MSG_ERROR([bison is needed to build Mesa])
  47
  48 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  49 dnl configuration in that case.
  50 AC_PROG_INSTALL
  51 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  52
  53 dnl We need a POSIX shell for parts of the build. Assume we have one
  54 dnl in most cases.
  55 case "$host_os" in
  56 solaris*)
  57     # Solaris /bin/sh is too old/non-POSIX compliant
  58     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  59     SHELL="$POSIX_SHELL"
  60     ;;
  61 esac
  62
  63 dnl clang is mostly GCC-compatible, but its version is much lower,
  64 dnl so we have to check for it.
  65 AC_MSG_CHECKING([if compiling with clang])
  66
  67 AC_COMPILE_IFELSE(
  68 [AC_LANG_PROGRAM([], [[
  69 #ifndef __clang__
  70        not clang
  71 #endif
  72 ]])],
  73 [CLANG=yes], [CLANG=no])
  74
  75 AC_MSG_RESULT([$CLANG])
  76
  77 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  78 dnl versions are explictly not supported.
  79 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  80     AC_MSG_CHECKING([whether gcc version is sufficient])
  81     major=0
  82     minor=0
  83
  84     GCC_VERSION=`$CC -dumpversion`
  85     if test $? -eq 0; then
  86         major=`echo $GCC_VERSION | cut -d. -f1`
  87         minor=`echo $GCC_VERSION | cut -d. -f1`
  88     fi
  89
  90     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  91         AC_MSG_RESULT([no])
  92         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  93     else
  94         AC_MSG_RESULT([yes])
  95     fi
  96 fi
  97
  98
  99 MKDEP_OPTIONS=-fdepend
 100 dnl Ask gcc where it's keeping its secret headers
 101 if test "x$GCC" = xyes; then
 102     for dir in include include-fixed; do
 103         GCC_INCLUDES=`$CC -print-file-name=$dir`
 104         if test "x$GCC_INCLUDES" != x && \
 105            test "$GCC_INCLUDES" != "$dir" && \
 106            test -d "$GCC_INCLUDES"; then
 107             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 108         fi
 109     done
 110 fi
 111 AC_SUBST([MKDEP_OPTIONS])
 112
 113 dnl Make sure the pkg-config macros are defined
 114 m4_ifndef([PKG_PROG_PKG_CONFIG],
 115     [m4_fatal([Could not locate the pkg-config autoconf macros.
 116   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 117   are in a different location, try setting the environment variable
 118   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 119 PKG_PROG_PKG_CONFIG()
 120
 121 dnl LIB_DIR - library basename
 122 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 123 AC_SUBST([LIB_DIR])
 124
 125 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 126 _SAVE_LDFLAGS="$LDFLAGS"
 127 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 128 AC_SUBST([EXTRA_LIB_PATH])
 129
 130 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 131 _SAVE_CPPFLAGS="$CPPFLAGS"
 132 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 133 AC_SUBST([X11_INCLUDES])
 134
 135 dnl Compiler macros
 136 DEFINES=""
 137 AC_SUBST([DEFINES])
 138 case "$host_os" in
 139 linux*|*-gnu*|gnu*)
 140     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 141     ;;
 142 solaris*)
 143     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 144     ;;
 145 cygwin*)
 146     DEFINES="$DEFINES -DPTHREADS"
 147     ;;
 148 esac
 149
 150 dnl Add flags for gcc and g++
 151 if test "x$GCC" = xyes; then
 152     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 153     if test "x$CLANG" = "xno"; then
 154        CFLAGS="$CFLAGS -ffast-math"
 155     fi
 156
 157     # Enable -fvisibility=hidden if using a gcc that supports it
 158     save_CFLAGS="$CFLAGS"
 159     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 160     VISIBILITY_CFLAGS="-fvisibility=hidden"
 161     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 162     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 163                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 164
 165     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 166     CFLAGS=$save_CFLAGS
 167
 168     # Work around aliasing bugs - developers should comment this out
 169     CFLAGS="$CFLAGS -fno-strict-aliasing"
 170 fi
 171 if test "x$GXX" = xyes; then
 172     CXXFLAGS="$CXXFLAGS -Wall"
 173
 174     # Enable -fvisibility=hidden if using a gcc that supports it
 175     save_CXXFLAGS="$CXXFLAGS"
 176     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 177     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 178     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 179     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 180                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 181
 182     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 183     CXXFLAGS=$save_CXXFLAGS
 184
 185     # Work around aliasing bugs - developers should comment this out
 186     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 187 fi
 188
 189 AC_SUBST([VISIBILITY_CFLAGS])
 190 AC_SUBST([VISIBILITY_CXXFLAGS])
 191
 192 dnl These should be unnecessary, but let the user set them if they want
 193 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 194     Default is to use CFLAGS.])
 195 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 196     compiler. Default is to use CFLAGS.])
 197 AC_SUBST([OPT_FLAGS])
 198 AC_SUBST([ARCH_FLAGS])
 199
 200 dnl
 201 dnl Hacks to enable 32 or 64 bit build
 202 dnl
 203 AC_ARG_ENABLE([32-bit],
 204     [AS_HELP_STRING([--enable-32-bit],
 205         [build 32-bit libraries @<:@default=auto@:>@])],
 206     [enable_32bit="$enableval"],
 207     [enable_32bit=auto]
 208 )
 209 if test "x$enable_32bit" = xyes; then
 210     if test "x$GCC" = xyes; then
 211         CFLAGS="$CFLAGS -m32"
 212         ARCH_FLAGS="$ARCH_FLAGS -m32"
 213     fi
 214     if test "x$GXX" = xyes; then
 215         CXXFLAGS="$CXXFLAGS -m32"
 216     fi
 217 fi
 218 AC_ARG_ENABLE([64-bit],
 219     [AS_HELP_STRING([--enable-64-bit],
 220         [build 64-bit libraries @<:@default=auto@:>@])],
 221     [enable_64bit="$enableval"],
 222     [enable_64bit=auto]
 223 )
 224 if test "x$enable_64bit" = xyes; then
 225     if test "x$GCC" = xyes; then
 226         CFLAGS="$CFLAGS -m64"
 227     fi
 228     if test "x$GXX" = xyes; then
 229         CXXFLAGS="$CXXFLAGS -m64"
 230     fi
 231 fi
 232
 233 dnl
 234 dnl shared/static libraries, mimic libtool options
 235 dnl
 236 AC_ARG_ENABLE([static],
 237     [AS_HELP_STRING([--enable-static],
 238         [build static libraries @<:@default=disabled@:>@])],
 239     [enable_static="$enableval"],
 240     [enable_static=no]
 241 )
 242 case "x$enable_static" in
 243 xyes|xno ) ;;
 244 x ) enable_static=no ;;
 245 * )
 246     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 247     ;;
 248 esac
 249 AC_ARG_ENABLE([shared],
 250     [AS_HELP_STRING([--disable-shared],
 251         [build shared libraries @<:@default=enabled@:>@])],
 252     [enable_shared="$enableval"],
 253     [enable_shared=yes]
 254 )
 255 case "x$enable_shared" in
 256 xyes|xno ) ;;
 257 x ) enable_shared=yes ;;
 258 * )
 259     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 260     ;;
 261 esac
 262
 263 dnl Can't have static and shared libraries, default to static if user
 264 dnl explicitly requested. If both disabled, set to static since shared
 265 dnl was explicitly requirested.
 266 case "x$enable_static$enable_shared" in
 267 xyesyes )
 268     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 269     enable_shared=no
 270     ;;
 271 xnono )
 272     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 273     enable_static=yes
 274     ;;
 275 esac
 276
 277 dnl
 278 dnl mklib options
 279 dnl
 280 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 281 if test "$enable_static" = yes; then
 282     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 283 fi
 284 AC_SUBST([MKLIB_OPTIONS])
 285
 286 dnl
 287 dnl other compiler options
 288 dnl
 289 AC_ARG_ENABLE([debug],
 290     [AS_HELP_STRING([--enable-debug],
 291         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 292     [enable_debug="$enableval"],
 293     [enable_debug=no]
 294 )
 295 if test "x$enable_debug" = xyes; then
 296     DEFINES="$DEFINES -DDEBUG"
 297     if test "x$GCC" = xyes; then
 298         CFLAGS="$CFLAGS -g"
 299     fi
 300     if test "x$GXX" = xyes; then
 301         CXXFLAGS="$CXXFLAGS -g"
 302     fi
 303 fi
 304
 305 dnl
 306 dnl library names
 307 dnl
 308 LIB_PREFIX_GLOB='lib'
 309 LIB_VERSION_SEPARATOR='.'
 310 if test "$enable_static" = yes; then
 311     LIB_EXTENSION='a'
 312 else
 313     case "$host_os" in
 314     darwin* )
 315         LIB_EXTENSION='dylib' ;;
 316     cygwin* )
 317         dnl prefix can be 'cyg' or 'lib'
 318         LIB_PREFIX_GLOB='???'
 319         LIB_VERSION_SEPARATOR='-'
 320         LIB_EXTENSION='dll' ;;
 321     aix* )
 322         LIB_EXTENSION='a' ;;
 323     * )
 324         LIB_EXTENSION='so' ;;
 325     esac
 326 fi
 327
 328 dnl
 329 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 330 dnl
 331 AC_ARG_ENABLE([texture-float],
 332     [AS_HELP_STRING([--enable-texture-float],
 333         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 334     [enable_texture_float="$enableval"],
 335     [enable_texture_float=no]
 336 )
 337 if test "x$enable_texture_float" = xyes; then
 338     AC_MSG_WARN([Floating-point textures enabled.])
 339     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 340     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 341 fi
 342
 343 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 344 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 345 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 346 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 347 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 348 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 349 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 350 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 351 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 352 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 353 WAYLAND_EGL_LIB_NAME='lib$(WAYLAND_EGL_LIB).'${LIB_EXTENSION}
 354
 355 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 356 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 357 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 358 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 359 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 360 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 361 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 362 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 363 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 364 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 365 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 366 WAYLAND_EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(WAYLAND_EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 367
 368 AC_SUBST([GL_LIB_NAME])
 369 AC_SUBST([GLU_LIB_NAME])
 370 AC_SUBST([GLUT_LIB_NAME])
 371 AC_SUBST([GLW_LIB_NAME])
 372 AC_SUBST([OSMESA_LIB_NAME])
 373 AC_SUBST([EGL_LIB_NAME])
 374 AC_SUBST([GLESv1_CM_LIB_NAME])
 375 AC_SUBST([GLESv2_LIB_NAME])
 376 AC_SUBST([VG_LIB_NAME])
 377 AC_SUBST([GLAPI_LIB_NAME])
 378 AC_SUBST([WAYLAND_EGL_LIB_NAME])
 379
 380 AC_SUBST([GL_LIB_GLOB])
 381 AC_SUBST([GLU_LIB_GLOB])
 382 AC_SUBST([GLUT_LIB_GLOB])
 383 AC_SUBST([GLW_LIB_GLOB])
 384 AC_SUBST([OSMESA_LIB_GLOB])
 385 AC_SUBST([EGL_LIB_GLOB])
 386 AC_SUBST([GLESv1_CM_LIB_GLOB])
 387 AC_SUBST([GLESv2_LIB_GLOB])
 388 AC_SUBST([VG_LIB_GLOB])
 389 AC_SUBST([GLAPI_LIB_GLOB])
 390 AC_SUBST([WAYLAND_EGL_LIB_GLOB])
 391
 392 dnl
 393 dnl Arch/platform-specific settings
 394 dnl
 395 AC_ARG_ENABLE([asm],
 396     [AS_HELP_STRING([--disable-asm],
 397         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 398     [enable_asm="$enableval"],
 399     [enable_asm=yes]
 400 )
 401 asm_arch=""
 402 ASM_FLAGS=""
 403 MESA_ASM_SOURCES=""
 404 GLAPI_ASM_SOURCES=""
 405 AC_MSG_CHECKING([whether to enable assembly])
 406 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 407 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 408 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 409     case "$host_cpu" in
 410     i?86 | x86_64)
 411         enable_asm=no
 412         AC_MSG_RESULT([no, cross compiling])
 413         ;;
 414     esac
 415 fi
 416 # check for supported arches
 417 if test "x$enable_asm" = xyes; then
 418     case "$host_cpu" in
 419     i?86)
 420         case "$host_os" in
 421         linux* | *freebsd* | dragonfly* | *netbsd*)
 422             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 423             ;;
 424         esac
 425         ;;
 426     x86_64)
 427         case "$host_os" in
 428         linux* | *freebsd* | dragonfly* | *netbsd*)
 429             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 430             ;;
 431         esac
 432         ;;
 433     powerpc)
 434         case "$host_os" in
 435         linux*)
 436             asm_arch=ppc
 437             ;;
 438         esac
 439         ;;
 440     sparc*)
 441         case "$host_os" in
 442         linux*)
 443             asm_arch=sparc
 444             ;;
 445         esac
 446         ;;
 447     esac
 448
 449     case "$asm_arch" in
 450     x86)
 451         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 452         MESA_ASM_SOURCES='$(X86_SOURCES)'
 453         GLAPI_ASM_SOURCES='$(X86_API)'
 454         AC_MSG_RESULT([yes, x86])
 455         ;;
 456     x86_64)
 457         ASM_FLAGS="-DUSE_X86_64_ASM"
 458         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 459         GLAPI_ASM_SOURCES='$(X86-64_API)'
 460         AC_MSG_RESULT([yes, x86_64])
 461         ;;
 462     ppc)
 463         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 464         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 465         AC_MSG_RESULT([yes, ppc])
 466         ;;
 467     sparc)
 468         ASM_FLAGS="-DUSE_SPARC_ASM"
 469         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 470         GLAPI_ASM_SOURCES='$(SPARC_API)'
 471         AC_MSG_RESULT([yes, sparc])
 472         ;;
 473     *)
 474         AC_MSG_RESULT([no, platform not supported])
 475         ;;
 476     esac
 477 fi
 478 AC_SUBST([ASM_FLAGS])
 479 AC_SUBST([MESA_ASM_SOURCES])
 480 AC_SUBST([GLAPI_ASM_SOURCES])
 481
 482 dnl PIC code macro
 483 MESA_PIC_FLAGS
 484
 485 dnl Check to see if dlopen is in default libraries (like Solaris, which
 486 dnl has it in libc), or if libdl is needed to get it.
 487 AC_CHECK_FUNC([dlopen], [],
 488     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 489 AC_SUBST([DLOPEN_LIBS])
 490
 491 dnl See if posix_memalign is available
 492 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 493
 494 dnl SELinux awareness.
 495 AC_ARG_ENABLE([selinux],
 496     [AS_HELP_STRING([--enable-selinux],
 497         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 498     [MESA_SELINUX="$enableval"],
 499     [MESA_SELINUX=no])
 500 if test "x$enable_selinux" = "xyes"; then
 501     AC_CHECK_HEADER([selinux/selinux.h],[],
 502                     [AC_MSG_ERROR([SELinux headers not found])])
 503     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 504                  [AC_MSG_ERROR([SELinux library not found])])
 505     SELINUX_LIBS="-lselinux"
 506     DEFINES="$DEFINES -DMESA_SELINUX"
 507 fi
 508
 509 dnl Determine which APIs to support
 510 AC_ARG_ENABLE([opengl],
 511     [AS_HELP_STRING([--disable-opengl],
 512         [disable support for standard OpenGL API @<:@default=no@:>@])],
 513     [enable_opengl="$enableval"],
 514     [enable_opengl=yes])
 515 AC_ARG_ENABLE([gles1],
 516     [AS_HELP_STRING([--enable-gles1],
 517         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 518     [enable_gles1="$enableval"],
 519     [enable_gles1=no])
 520 AC_ARG_ENABLE([gles2],
 521     [AS_HELP_STRING([--enable-gles2],
 522         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 523     [enable_gles2="$enableval"],
 524     [enable_gles2=no])
 525 AC_ARG_ENABLE([gles-overlay],
 526     [AS_HELP_STRING([--enable-gles-overlay],
 527         [DEPRECATED.  Same as --enable-gles1 and --enable-gles2])],
 528     [enable_gles1="$enableval"; enable_gles2="$enableval"],
 529     [])
 530
 531 AC_ARG_ENABLE([openvg],
 532     [AS_HELP_STRING([--enable-openvg],
 533         [enable support for OpenVG API @<:@default=no@:>@])],
 534     [enable_openvg="$enableval"],
 535     [enable_openvg=no])
 536
 537 dnl smooth the transition; should be removed eventually
 538 if test "x$enable_openvg" = xno; then
 539     case "x$with_state_trackers" in
 540     x*vega*)
 541         AC_MSG_WARN([vega state tracker is enabled without --enable-openvg])
 542         enable_openvg=yes
 543         ;;
 544     esac
 545 fi
 546
 547 if test "x$enable_opengl" = xno -a \
 548         "x$enable_gles1" = xno -a \
 549         "x$enable_gles2" = xno -a \
 550         "x$enable_openvg" = xno; then
 551     AC_MSG_ERROR([at least one API should be enabled])
 552 fi
 553
 554 API_DEFINES=""
 555 if test "x$enable_opengl" = xno; then
 556     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 557 else
 558     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 559 fi
 560 if test "x$enable_gles1" = xyes; then
 561     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 562 fi
 563 if test "x$enable_gles2" = xyes; then
 564     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 565 fi
 566 AC_SUBST([API_DEFINES])
 567
 568 AC_ARG_ENABLE([shared-glapi],
 569     [AS_HELP_STRING([--enable-shared-glapi],
 570         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 571     [enable_shared_glapi="$enableval"],
 572     [enable_shared_glapi=no])
 573
 574 SHARED_GLAPI="0"
 575 if test "x$enable_shared_glapi" = xyes; then
 576     SHARED_GLAPI="1"
 577 fi
 578 AC_SUBST([SHARED_GLAPI])
 579
 580 dnl
 581 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 582 dnl More later: fbdev, ...
 583 dnl
 584 default_driver="xlib"
 585
 586 case "$host_os" in
 587 linux*)
 588     case "$host_cpu" in
 589     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 590     esac
 591     ;;
 592 *freebsd* | dragonfly* | *netbsd*)
 593     case "$host_cpu" in
 594     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 595     esac
 596     ;;
 597 esac
 598
 599 if test "x$enable_opengl" = xno; then
 600     default_driver="no"
 601 fi
 602
 603 AC_ARG_WITH([driver],
 604     [AS_HELP_STRING([--with-driver=DRIVER],
 605         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 606     [mesa_driver="$withval"],
 607     [mesa_driver="$default_driver"])
 608 dnl Check for valid option
 609 case "x$mesa_driver" in
 610 xxlib|xdri|xosmesa)
 611     if test "x$enable_opengl" = xno; then
 612         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 613     fi
 614     ;;
 615 xno)
 616     ;;
 617 *)
 618     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 619     ;;
 620 esac
 621
 622 dnl
 623 dnl Driver specific build directories
 624 dnl
 625
 626 dnl this variable will be prepended to SRC_DIRS and is not exported
 627 CORE_DIRS=""
 628
 629 SRC_DIRS=""
 630 GLU_DIRS="sgi"
 631 GALLIUM_DIRS="auxiliary drivers state_trackers"
 632 GALLIUM_TARGET_DIRS=""
 633 GALLIUM_WINSYS_DIRS="sw"
 634 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug noop identity"
 635 GALLIUM_STATE_TRACKERS_DIRS=""
 636
 637 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 638 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 639 x*yes*)
 640     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 641     ;;
 642 esac
 643
 644 # build glapi if OpenGL is enabled
 645 if test "x$enable_opengl" = xyes; then
 646     CORE_DIRS="$CORE_DIRS mapi/glapi"
 647 fi
 648
 649 # build es1api if OpenGL ES 1.x is enabled
 650 if test "x$enable_gles1" = xyes; then
 651     CORE_DIRS="$CORE_DIRS mapi/es1api"
 652 fi
 653
 654 # build es2api if OpenGL ES 2.x is enabled
 655 if test "x$enable_gles2" = xyes; then
 656     CORE_DIRS="$CORE_DIRS mapi/es2api"
 657 fi
 658
 659 # build vgapi if OpenVG is enabled
 660 if test "x$enable_openvg" = xyes; then
 661     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 662 fi
 663
 664 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 665 case "x$enable_opengl$enable_gles1$enable_gles2" in
 666 x*yes*)
 667     CORE_DIRS="$CORE_DIRS glsl mesa"
 668     ;;
 669 esac
 670
 671 case "$mesa_driver" in
 672 xlib)
 673     DRIVER_DIRS="x11"
 674     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 675     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 676     ;;
 677 dri)
 678     SRC_DIRS="$SRC_DIRS glx"
 679     DRIVER_DIRS="dri"
 680     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 681     ;;
 682 osmesa)
 683     DRIVER_DIRS="osmesa"
 684     ;;
 685 no)
 686     DRIVER_DRIS=""
 687     ;;
 688 esac
 689 AC_SUBST([SRC_DIRS])
 690 AC_SUBST([GLU_DIRS])
 691 AC_SUBST([DRIVER_DIRS])
 692 AC_SUBST([GALLIUM_DIRS])
 693 AC_SUBST([GALLIUM_TARGET_DIRS])
 694 AC_SUBST([GALLIUM_WINSYS_DIRS])
 695 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 696 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 697 AC_SUBST([MESA_LLVM])
 698
 699 dnl
 700 dnl Find out if X is available. The variable have_x is set if libX11 is
 701 dnl found to mimic AC_PATH_XTRA.
 702 dnl
 703 if test -n "$PKG_CONFIG"; then
 704     AC_MSG_CHECKING([pkg-config files for X11 are available])
 705     PKG_CHECK_EXISTS([x11],[
 706         x11_pkgconfig=yes
 707         have_x=yes
 708         ],[
 709         x11_pkgconfig=no
 710     ])
 711     AC_MSG_RESULT([$x11_pkgconfig])
 712 else
 713     x11_pkgconfig=no
 714 fi
 715 dnl Use the autoconf macro if no pkg-config files
 716 if test "$x11_pkgconfig" = yes; then
 717     PKG_CHECK_MODULES([X11], [x11])
 718 else
 719     AC_PATH_XTRA
 720     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 721     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 722     AC_SUBST([X11_CFLAGS])
 723     AC_SUBST([X11_LIBS])
 724 fi
 725
 726 dnl Try to tell the user that the --x-* options are only used when
 727 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 728 m4_divert_once([HELP_BEGIN],
 729 [These options are only used when the X libraries cannot be found by the
 730 pkg-config utility.])
 731
 732 dnl We need X for xlib and dri, so bomb now if it's not found
 733 case "$mesa_driver" in
 734 xlib|dri)
 735     if test "$no_x" = yes; then
 736         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 737     fi
 738     ;;
 739 esac
 740
 741 dnl XCB - this is only used for GLX right now
 742 AC_ARG_ENABLE([xcb],
 743     [AS_HELP_STRING([--enable-xcb],
 744         [use XCB for GLX @<:@default=disabled@:>@])],
 745     [enable_xcb="$enableval"],
 746     [enable_xcb=no])
 747 if test "x$enable_xcb" = xyes; then
 748     DEFINES="$DEFINES -DUSE_XCB"
 749 else
 750     enable_xcb=no
 751 fi
 752
 753 dnl Direct rendering or just indirect rendering
 754 case "$host_os" in
 755 gnu*)
 756     dnl Disable by default on GNU/Hurd
 757     driglx_direct_default="no"
 758     ;;
 759 cygwin*)
 760     dnl Disable by default on cygwin
 761     driglx_direct_default="no"
 762     ;;
 763 *)
 764     driglx_direct_default="yes"
 765     ;;
 766 esac
 767 AC_ARG_ENABLE([driglx-direct],
 768     [AS_HELP_STRING([--disable-driglx-direct],
 769         [enable direct rendering in GLX and EGL for DRI \
 770             @<:@default=auto@:>@])],
 771     [driglx_direct="$enableval"],
 772     [driglx_direct="$driglx_direct_default"])
 773
 774 dnl
 775 dnl libGL configuration per driver
 776 dnl
 777 case "$mesa_driver" in
 778 xlib)
 779     if test "$x11_pkgconfig" = yes; then
 780         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 781         GL_PC_REQ_PRIV="x11 xext"
 782         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 783         GL_LIB_DEPS="$XLIBGL_LIBS"
 784     else
 785         # should check these...
 786         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 787         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 788         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 789         GL_PC_CFLAGS="$X11_INCLUDES"
 790     fi
 791     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 792     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 793
 794     # if static, move the external libraries to the programs
 795     # and empty the libraries for libGL
 796     if test "$enable_static" = yes; then
 797         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 798         GL_LIB_DEPS=""
 799     fi
 800     ;;
 801 dri|no) # these checks are still desired when there is no mesa_driver
 802     # DRI must be shared, I think
 803     if test "$enable_static" = yes; then
 804         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 805     fi
 806
 807     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 808     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 809     DRI_PC_REQ_PRIV=""
 810
 811     if test x"$driglx_direct" = xyes; then
 812         # Check for libdrm
 813         PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 814         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 815         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 816         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 817     fi
 818
 819     # find the DRI deps for libGL
 820     if test "$x11_pkgconfig" = yes; then
 821         dri_modules="x11 xext xdamage xfixes"
 822
 823         # add xf86vidmode if available
 824         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 825         if test "$HAVE_XF86VIDMODE" = yes ; then
 826             dri_modules="$dri_modules xxf86vm"
 827         fi
 828
 829         # add xcb modules if necessary
 830         if test "$enable_xcb" = yes; then
 831             dri_modules="$dri_modules x11-xcb xcb-glx"
 832         fi
 833
 834         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 835         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 836         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 837         GL_LIB_DEPS="$DRIGL_LIBS"
 838     else
 839         # should check these...
 840         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 841         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 842         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 843         GL_PC_CFLAGS="$X11_INCLUDES"
 844
 845         # XCB can only be used from pkg-config
 846         if test "$enable_xcb" = yes; then
 847             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 848             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 849             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 850             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 851         fi
 852     fi
 853
 854     # need DRM libs, -lpthread, etc.
 855     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 856     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 857     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 858     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 859     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 860     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 861     ;;
 862 osmesa)
 863     # No libGL for osmesa
 864     GL_LIB_DEPS=""
 865     ;;
 866 esac
 867 AC_SUBST([GL_LIB_DEPS])
 868 AC_SUBST([GL_PC_REQ_PRIV])
 869 AC_SUBST([GL_PC_LIB_PRIV])
 870 AC_SUBST([GL_PC_CFLAGS])
 871 AC_SUBST([DRI_PC_REQ_PRIV])
 872 AC_SUBST([GLESv1_CM_LIB_DEPS])
 873 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 874 AC_SUBST([GLESv2_LIB_DEPS])
 875 AC_SUBST([GLESv2_PC_LIB_PRIV])
 876
 877 GLAPI_LIB_DEPS="-lpthread"
 878 AC_SUBST([GLAPI_LIB_DEPS])
 879
 880
 881 dnl Setup default DRI CFLAGS
 882 DRI_CFLAGS='$(CFLAGS)'
 883 DRI_CXXFLAGS='$(CXXFLAGS)'
 884 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
 885 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
 886
 887 AC_ARG_ENABLE([shared-dricore],
 888     [AS_HELP_STRING([--enable-shared-dricore],
 889         [link DRI modules with shared core DRI routines @<:@default=disabled@:>@])],
 890     [enable_dricore="$enableval"],
 891     [enable_dricore=no])
 892 if test "$mesa_driver" = dri ; then
 893    if test "$enable_dricore" = yes ; then
 894       if test "$GCC$GXX" != yesyes ; then
 895          AC_MSG_WARN([Shared dricore requires GCC-compatible rpath handling.  Disabling shared dricore])
 896          enable_dricore=no
 897       else
 898          DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
 899          DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
 900          DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
 901          DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
 902          DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
 903          DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
 904          MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
 905       fi
 906    fi
 907 fi
 908 AC_SUBST([DRICORE_LIBS])
 909 AC_SUBST([DRICORE_GLSL_LIBS])
 910 AC_SUBST([DRICORE_LIB_DEPS])
 911 AC_SUBST([DRI_CXXFLAGS])
 912 AC_SUBST([DRI_CFLAGS])
 913 AC_SUBST([MESA_MODULES])
 914
 915 AC_SUBST([HAVE_XF86VIDMODE])
 916
 917 PKG_CHECK_MODULES([LIBDRM_RADEON],
 918                   [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED],
 919                   HAVE_LIBDRM_RADEON=yes,
 920                   HAVE_LIBDRM_RADEON=no)
 921
 922 dnl
 923 dnl More X11 setup
 924 dnl
 925 if test "$mesa_driver" = xlib; then
 926     DEFINES="$DEFINES -DUSE_XSHM"
 927 fi
 928
 929 dnl
 930 dnl TLS detection
 931 dnl
 932
 933 AC_ARG_ENABLE([glx-tls],
 934     [AS_HELP_STRING([--enable-glx-tls],
 935         [enable TLS support in GLX @<:@default=disabled@:>@])],
 936     [GLX_USE_TLS="$enableval"],
 937     [GLX_USE_TLS=no])
 938 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 939
 940 AS_IF([test "x$GLX_USE_TLS" = xyes],
 941       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 942
 943 dnl
 944 dnl More DRI setup
 945 dnl
 946 dnl Directory for DRI drivers
 947 AC_ARG_WITH([dri-driverdir],
 948     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 949         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 950     [DRI_DRIVER_INSTALL_DIR="$withval"],
 951     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 952 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 953 dnl Extra search path for DRI drivers
 954 AC_ARG_WITH([dri-searchpath],
 955     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 956         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 957     [DRI_DRIVER_SEARCH_DIR="$withval"],
 958     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 959 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 960 dnl Which drivers to build - default is chosen by platform
 961 AC_ARG_WITH([dri-drivers],
 962     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 963         [comma delimited DRI drivers list, e.g.
 964         "swrast,i965,radeon" @<:@default=auto@:>@])],
 965     [with_dri_drivers="$withval"],
 966     [with_dri_drivers=yes])
 967 if test "x$with_dri_drivers" = x; then
 968     with_dri_drivers=no
 969 fi
 970
 971 dnl If $with_dri_drivers is yes, directories will be added through
 972 dnl platform checks
 973 DRI_DIRS=""
 974 case "$with_dri_drivers" in
 975 no) ;;
 976 yes)
 977     DRI_DIRS="yes"
 978     ;;
 979 *)
 980     # verify the requested driver directories exist
 981     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 982     for driver in $dri_drivers; do
 983         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 984             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 985     done
 986     DRI_DIRS="$dri_drivers"
 987     ;;
 988 esac
 989
 990 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 991 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 992     # Platform specific settings and drivers to build
 993     case "$host_os" in
 994     linux*)
 995         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 996         if test "x$driglx_direct" = xyes; then
 997             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 998         fi
 999         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
1000
1001         case "$host_cpu" in
1002         x86_64)
1003             # sis is missing because they have not be converted to use
1004             # the new interface.  i810 are missing because there is no
1005             # x86-64 system where they could *ever* be used.
1006             if test "x$DRI_DIRS" = "xyes"; then
1007                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
1008                     savage tdfx unichrome swrast"
1009             fi
1010             ;;
1011         powerpc*)
1012             # Build only the drivers for cards that exist on PowerPC.
1013             # At some point MGA will be added, but not yet.
1014             if test "x$DRI_DIRS" = "xyes"; then
1015                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
1016             fi
1017             ;;
1018         sparc*)
1019             # Build only the drivers for cards that exist on sparc`
1020             if test "x$DRI_DIRS" = "xyes"; then
1021                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
1022             fi
1023             ;;
1024         esac
1025         ;;
1026     freebsd* | dragonfly* | *netbsd*)
1027         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1028         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1029         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1030         if test "x$driglx_direct" = xyes; then
1031             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1032         fi
1033
1034         if test "x$DRI_DIRS" = "xyes"; then
1035             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
1036                 unichrome savage sis swrast"
1037         fi
1038         ;;
1039     gnu*)
1040         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1041         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
1042         ;;
1043     solaris*)
1044         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1045         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1046         if test "x$driglx_direct" = xyes; then
1047             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1048         fi
1049         ;;
1050     cygwin*)
1051         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1052         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1053         if test "x$driglx_direct" = xyes; then
1054             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1055         fi
1056         if test "x$DRI_DIRS" = "xyes"; then
1057             DRI_DIRS="swrast"
1058         fi
1059         ;;
1060     esac
1061
1062     # default drivers
1063     if test "x$DRI_DIRS" = "xyes"; then
1064         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
1065             savage sis tdfx unichrome swrast"
1066     fi
1067
1068     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1069
1070     # Check for expat
1071     if test "$mesa_driver" = dri; then
1072         EXPAT_INCLUDES=""
1073         EXPAT_LIB=-lexpat
1074         AC_ARG_WITH([expat],
1075             [AS_HELP_STRING([--with-expat=DIR],
1076                 [expat install directory])],[
1077             EXPAT_INCLUDES="-I$withval/include"
1078             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1079             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1080             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1081             ])
1082         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1083         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1084             [AC_MSG_ERROR([Expat required for DRI.])])
1085     fi
1086
1087     # put all the necessary libs together, including possibly libdricore
1088     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1089 fi
1090 AC_SUBST([DRI_DIRS])
1091 AC_SUBST([EXPAT_INCLUDES])
1092 AC_SUBST([DRI_LIB_DEPS])
1093
1094 case $DRI_DIRS in
1095 *i915*|*i965*)
1096     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1097     ;;
1098 esac
1099
1100 case $DRI_DIRS in
1101 *radeon*|*r200*|*r300*|*r600*)
1102     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1103         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
1104         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
1105     fi
1106     ;;
1107 esac
1108 AC_SUBST([RADEON_CFLAGS])
1109 AC_SUBST([RADEON_LDFLAGS])
1110
1111
1112 dnl
1113 dnl OSMesa configuration
1114 dnl
1115 if test "$mesa_driver" = xlib; then
1116     default_gl_osmesa=yes
1117 else
1118     default_gl_osmesa=no
1119 fi
1120 AC_ARG_ENABLE([gl-osmesa],
1121     [AS_HELP_STRING([--enable-gl-osmesa],
1122         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
1123     [gl_osmesa="$enableval"],
1124     [gl_osmesa="$default_gl_osmesa"])
1125 if test "x$gl_osmesa" = xyes; then
1126     if test "x$enable_opengl" = xno; then
1127         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
1128     fi
1129     if test "$mesa_driver" = osmesa; then
1130         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1131     else
1132         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1133     fi
1134 fi
1135
1136 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1137 AC_ARG_WITH([osmesa-bits],
1138     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1139         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1140     [osmesa_bits="$withval"],
1141     [osmesa_bits=8])
1142 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1143     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1144     osmesa_bits=8
1145 fi
1146 case "x$osmesa_bits" in
1147 x8)
1148     OSMESA_LIB=OSMesa
1149     ;;
1150 x16|x32)
1151     OSMESA_LIB="OSMesa$osmesa_bits"
1152     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1153     ;;
1154 *)
1155     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1156     ;;
1157 esac
1158 AC_SUBST([OSMESA_LIB])
1159
1160 case "$DRIVER_DIRS" in
1161 *osmesa*)
1162     # only link libraries with osmesa if shared
1163     if test "$enable_static" = no; then
1164         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1165     else
1166         OSMESA_LIB_DEPS=""
1167     fi
1168     OSMESA_MESA_DEPS=""
1169     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1170     ;;
1171 esac
1172 AC_SUBST([OSMESA_LIB_DEPS])
1173 AC_SUBST([OSMESA_MESA_DEPS])
1174 AC_SUBST([OSMESA_PC_REQ])
1175 AC_SUBST([OSMESA_PC_LIB_PRIV])
1176
1177 dnl
1178 dnl EGL configuration
1179 dnl
1180 AC_ARG_ENABLE([egl],
1181     [AS_HELP_STRING([--disable-egl],
1182         [disable EGL library @<:@default=enabled@:>@])],
1183     [enable_egl="$enableval"],
1184     [enable_egl=yes])
1185 if test "x$enable_egl" = xno; then
1186     if test "x$mesa_driver" = xno; then
1187         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1188     fi
1189     if test "x$enable_openvg" = xyes; then
1190         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1191     fi
1192 fi
1193 if test "x$enable_egl" = xyes; then
1194     SRC_DIRS="$SRC_DIRS egl"
1195     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1196     EGL_DRIVERS_DIRS=""
1197     if test "$enable_static" != yes; then
1198         # build egl_glx when libGL is built
1199         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1200             EGL_DRIVERS_DIRS="glx"
1201         fi
1202
1203         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1204                           [have_libudev=yes],[have_libudev=no])
1205         if test "$mesa_driver" = dri; then
1206             # build egl_dri2 when xcb-dri2 is available
1207             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1208                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1209
1210             if test "$have_xcb_dri2" = yes; then
1211                 EGL_DRIVER_DRI2=dri2
1212                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1213                 if test "$have_libudev" = yes; then
1214                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1215                 fi
1216                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1217                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1218                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1219             fi
1220         fi
1221
1222         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1223     fi
1224 fi
1225 AC_SUBST([EGL_LIB_DEPS])
1226 AC_SUBST([EGL_DRIVERS_DIRS])
1227
1228 dnl
1229 dnl GLU configuration
1230 dnl
1231 AC_ARG_ENABLE([glu],
1232     [AS_HELP_STRING([--disable-glu],
1233         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1234     [enable_glu="$enableval"],
1235     [enable_glu=yes])
1236
1237 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1238     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1239     enable_glu=no
1240 fi
1241
1242 if test "x$enable_glu" = xyes; then
1243     SRC_DIRS="$SRC_DIRS glu"
1244
1245     case "$mesa_driver" in
1246     osmesa)
1247         # Link libGLU to libOSMesa instead of libGL
1248         GLU_LIB_DEPS=""
1249         GLU_PC_REQ="osmesa"
1250         if test "$enable_static" = no; then
1251             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1252         else
1253             GLU_MESA_DEPS=""
1254         fi
1255         ;;
1256     *)
1257         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1258         GLU_PC_REQ="gl"
1259         GLU_PC_LIB_PRIV="-lm"
1260         if test "$enable_static" = no; then
1261             GLU_LIB_DEPS="-lm"
1262             GLU_MESA_DEPS='-l$(GL_LIB)'
1263         else
1264             GLU_LIB_DEPS=""
1265             GLU_MESA_DEPS=""
1266             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1267         fi
1268         ;;
1269     esac
1270 fi
1271 if test "$enable_static" = no; then
1272     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1273 fi
1274 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1275 AC_SUBST([GLU_LIB_DEPS])
1276 AC_SUBST([GLU_MESA_DEPS])
1277 AC_SUBST([GLU_PC_REQ])
1278 AC_SUBST([GLU_PC_REQ_PRIV])
1279 AC_SUBST([GLU_PC_LIB_PRIV])
1280 AC_SUBST([GLU_PC_CFLAGS])
1281
1282 dnl
1283 dnl GLw configuration
1284 dnl
1285 AC_ARG_ENABLE([glw],
1286     [AS_HELP_STRING([--disable-glw],
1287         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1288     [enable_glw="$enableval"],
1289     [enable_glw=yes])
1290 dnl Don't build GLw on osmesa
1291 if test "x$enable_glw" = xyes; then
1292     case "$mesa_driver" in
1293     osmesa|no)
1294         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1295         enable_glw=no
1296         ;;
1297     esac
1298 fi
1299 AC_ARG_ENABLE([motif],
1300     [AS_HELP_STRING([--enable-motif],
1301         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1302     [enable_motif="$enableval"],
1303     [enable_motif=no])
1304
1305 if test "x$enable_glw" = xyes; then
1306     SRC_DIRS="$SRC_DIRS glw"
1307     if test "$x11_pkgconfig" = yes; then
1308         PKG_CHECK_MODULES([GLW],[x11 xt])
1309         GLW_PC_REQ_PRIV="x11 xt"
1310         GLW_LIB_DEPS="$GLW_LIBS"
1311     else
1312         # should check these...
1313         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1314         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1315         GLW_PC_CFLAGS="$X11_INCLUDES"
1316     fi
1317
1318     GLW_SOURCES="GLwDrawA.c"
1319     MOTIF_CFLAGS=
1320     if test "x$enable_motif" = xyes; then
1321         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1322         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1323         if test "x$MOTIF_CONFIG" != xno; then
1324             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1325             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1326         else
1327             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1328                 [AC_MSG_ERROR([Can't locate Motif headers])])
1329             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1330                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1331         fi
1332         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1333         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1334         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1335         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1336     fi
1337
1338     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1339     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1340     if test "$enable_static" = no; then
1341         GLW_MESA_DEPS='-l$(GL_LIB)'
1342         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1343     else
1344         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1345         GLW_LIB_DEPS=""
1346         GLW_MESA_DEPS=""
1347     fi
1348 fi
1349 AC_SUBST([GLW_LIB_DEPS])
1350 AC_SUBST([GLW_MESA_DEPS])
1351 AC_SUBST([GLW_SOURCES])
1352 AC_SUBST([MOTIF_CFLAGS])
1353 AC_SUBST([GLW_PC_REQ_PRIV])
1354 AC_SUBST([GLW_PC_LIB_PRIV])
1355 AC_SUBST([GLW_PC_CFLAGS])
1356
1357 dnl
1358 dnl GLUT configuration
1359 dnl
1360 if test -f "$srcdir/include/GL/glut.h"; then
1361     default_glut=yes
1362 else
1363     default_glut=no
1364 fi
1365 AC_ARG_ENABLE([glut],
1366     [AS_HELP_STRING([--disable-glut],
1367         [enable GLUT library @<:@default=enabled if source available@:>@])],
1368     [enable_glut="$enableval"],
1369     [enable_glut="$default_glut"])
1370
1371 dnl Don't build glut on osmesa
1372 if test "x$enable_glut" = xyes; then
1373     case "$mesa_driver" in
1374     osmesa|no)
1375         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1376         enable_glut=no
1377         ;;
1378     esac
1379 fi
1380 dnl Can't build glut if GLU not available
1381 if test "x$enable_glu$enable_glut" = xnoyes; then
1382     AC_MSG_WARN([Disabling glut since GLU is disabled])
1383     enable_glut=no
1384 fi
1385
1386 if test "x$enable_glut" = xyes; then
1387     SRC_DIRS="$SRC_DIRS glut/glx"
1388     if test "$x11_pkgconfig" = yes; then
1389         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1390         GLUT_PC_REQ_PRIV="x11 xmu xi"
1391         GLUT_LIB_DEPS="$GLUT_LIBS"
1392     else
1393         # should check these...
1394         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1395         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1396         GLUT_PC_CFLAGS="$X11_INCLUDES"
1397     fi
1398     if test "x$GCC" = xyes; then
1399         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1400     fi
1401     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1402     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1403
1404     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1405     if test "$enable_static" = no; then
1406         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1407     else
1408         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1409         GLUT_LIB_DEPS=""
1410         GLUT_MESA_DEPS=""
1411     fi
1412 fi
1413 AC_SUBST([GLUT_LIB_DEPS])
1414 AC_SUBST([GLUT_MESA_DEPS])
1415 AC_SUBST([GLUT_CFLAGS])
1416 AC_SUBST([GLUT_PC_REQ_PRIV])
1417 AC_SUBST([GLUT_PC_LIB_PRIV])
1418 AC_SUBST([GLUT_PC_CFLAGS])
1419
1420 dnl
1421 dnl Program library dependencies
1422 dnl    Only libm is added here if necessary as the libraries should
1423 dnl    be pulled in by the linker
1424 dnl
1425 if test "x$APP_LIB_DEPS" = x; then
1426     case "$host_os" in
1427     solaris*)
1428         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1429         ;;
1430     cygwin*)
1431         APP_LIB_DEPS="-lX11"
1432         ;;
1433     *)
1434         APP_LIB_DEPS="-lm"
1435         ;;
1436     esac
1437 fi
1438 AC_SUBST([APP_LIB_DEPS])
1439 AC_SUBST([PROGRAM_DIRS])
1440
1441 dnl
1442 dnl Gallium configuration
1443 dnl
1444 AC_ARG_ENABLE([gallium],
1445     [AS_HELP_STRING([--disable-gallium],
1446         [build gallium @<:@default=enabled@:>@])],
1447     [enable_gallium="$enableval"],
1448     [enable_gallium=yes])
1449 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1450     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1451 fi
1452 if test "x$enable_gallium" = xyes; then
1453     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1454     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1455 fi
1456
1457 AC_SUBST([LLVM_CFLAGS])
1458 AC_SUBST([LLVM_LIBS])
1459 AC_SUBST([LLVM_LDFLAGS])
1460 AC_SUBST([LLVM_VERSION])
1461
1462 dnl
1463 dnl Gallium state trackers configuration
1464 dnl
1465
1466 AC_ARG_ENABLE([gallium-egl],
1467     [AS_HELP_STRING([--enable-gallium-egl],
1468         [enable gallium EGL state tracker @<:@default=auto@:>@])],
1469     [enable_gallium_egl="$enableval"],
1470     [enable_gallium_egl=auto])
1471 if test "x$enable_gallium_egl" = xauto; then
1472     case "$mesa_driver" in
1473     dri|no)
1474         enable_gallium_egl=$enable_egl
1475         ;;
1476     *)
1477         enable_gallium_egl=$enable_openvg
1478         ;;
1479     esac
1480 fi
1481 case "x$enable_egl$enable_gallium_egl" in
1482 xnoyes)
1483     AC_MSG_ERROR([cannot build Gallium EGL state tracker without EGL])
1484 esac
1485
1486 AC_ARG_WITH([state-trackers],
1487     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1488         [comma delimited state_trackers list, e.g.
1489         "egl,glx" @<:@default=auto@:>@])],
1490     [with_state_trackers="$withval"],
1491     [with_state_trackers=yes])
1492
1493 case "$with_state_trackers" in
1494 no)
1495     GALLIUM_STATE_TRACKERS_DIRS=""
1496     ;;
1497 yes)
1498     # look at what else is built
1499     case "$mesa_driver" in
1500     xlib)
1501         GALLIUM_STATE_TRACKERS_DIRS=glx
1502         ;;
1503     dri)
1504         GALLIUM_STATE_TRACKERS_DIRS="dri"
1505         HAVE_ST_DRI="yes"
1506         # Have only tested st/xorg on 1.6.0 servers
1507         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1508             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1509             HAVE_ST_XORG="no")
1510         ;;
1511     esac
1512
1513     if test "x$enable_egl" = xyes; then
1514         if test "$enable_openvg" = yes; then
1515             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1516             st_egl="yes"
1517         fi
1518
1519         if test "$enable_gallium_egl" = yes; then
1520             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1521             HAVE_ST_EGL="yes"
1522         fi
1523     fi
1524     ;;
1525 *)
1526     # verify the requested state tracker exist
1527     state_trackers=""
1528     _state_trackers=`IFS=', '; echo $with_state_trackers`
1529     for tracker in $_state_trackers; do
1530         case "$tracker" in
1531         dri)
1532             if test "x$mesa_driver" != xdri; then
1533                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1534             fi
1535             HAVE_ST_DRI="yes"
1536             ;;
1537         egl)
1538             if test "x$enable_egl" != xyes; then
1539                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1540             fi
1541             HAVE_ST_EGL="yes"
1542             ;;
1543         xorg)
1544             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1545             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1546             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1547             HAVE_ST_XORG="yes"
1548             ;;
1549         vega)
1550             if test "x$enable_openvg" != xyes; then
1551                 AC_MSG_ERROR([cannot build vega state tracker without --enable-openvg])
1552             fi
1553             have_st_vega="yes"
1554             ;;
1555         esac
1556
1557         if test -n "$tracker"; then
1558             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1559                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1560             if test -n "$state_trackers"; then
1561                 state_trackers="$state_trackers $tracker"
1562             else
1563                 state_trackers="$tracker"
1564             fi
1565         fi
1566     done
1567     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1568
1569     # append --enable-openvg/--enable-gallium-egl to --with-state-trackers
1570     if test "x$have_st_vega" != xyes -a "x$enable_openvg" = xyes; then
1571         AC_MSG_ERROR([--with-state-trackers specified but vega is missing])
1572     fi
1573     if test "x$HAVE_ST_EGL" != xyes -a "x$enable_gallium_egl" = xyes; then
1574         AC_MSG_ERROR([--with-state-trackers specified but egl is missing])
1575     fi
1576     ;;
1577 esac
1578
1579
1580 EGL_CLIENT_APIS=""
1581 VG_LIB_DEPS=""
1582
1583 case "x$enable_opengl$enable_gles1$enable_gles2" in
1584 x*yes*)
1585     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1586     ;;
1587 esac
1588 if test "x$enable_openvg" = xyes; then
1589     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1590     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1591 fi
1592
1593 AC_SUBST([VG_LIB_DEPS])
1594 AC_SUBST([EGL_CLIENT_APIS])
1595
1596 if test "x$HAVE_ST_EGL" = xyes; then
1597         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1598 fi
1599
1600 if test "x$HAVE_ST_XORG" = xyes; then
1601     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1602         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1603         HAVE_XEXTPROTO_71="no")
1604 fi
1605
1606 AC_ARG_WITH([egl-platforms],
1607     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1608         [comma delimited native platforms libEGL supports, e.g.
1609         "x11,drm" @<:@default=auto@:>@])],
1610     [with_egl_platforms="$withval"],
1611     [with_egl_platforms=yes])
1612 AC_ARG_WITH([egl-displays],
1613     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1614         [DEPRECATED.  Use --with-egl-platforms instead])],
1615     [with_egl_platforms="$withval"])
1616
1617 EGL_PLATFORMS=""
1618 WAYLAND_EGL_LIB_DEPS=""
1619
1620 case "$with_egl_platforms" in
1621 yes)
1622     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1623         EGL_PLATFORMS="x11"
1624         if test "$mesa_driver" = dri; then
1625             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1626         fi
1627     fi
1628     ;;
1629 *)
1630     if test "x$enable_egl" != xyes; then
1631         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1632     fi
1633     # verify the requested driver directories exist
1634     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1635     for plat in $egl_platforms; do
1636         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1637             AC_MSG_ERROR([EGL platform '$plat' doesn't exist])
1638         if test "$plat" = "fbdev"; then
1639                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1640         fi
1641         if test "$plat" = "wayland"; then
1642                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1643                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1644                 WAYLAND_EGL_LIB_DEPS="$WAYLAND_LIBS $LIBDRM_LIBS"
1645                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1646         fi
1647     done
1648     EGL_PLATFORMS="$egl_platforms"
1649     ;;
1650 esac
1651 AC_SUBST([EGL_PLATFORMS])
1652
1653 AC_SUBST([WAYLAND_EGL_LIB_DEPS])
1654 WAYLAND_EGL_PC_REQ_PRIV="wayland-client libdrm"
1655 WAYLAND_EGL_PC_LIB_PRIV=
1656 WAYLAND_EGL_PC_CFLAGS=
1657
1658 AC_SUBST([WAYLAND_EGL_PC_REQ_PRIV])
1659 AC_SUBST([WAYLAND_EGL_PC_LIB_PRIV])
1660 AC_SUBST([WAYLAND_EGL_PC_CFLAGS])
1661
1662
1663 AC_ARG_WITH([egl-driver-dir],
1664     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1665                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1666     [EGL_DRIVER_INSTALL_DIR="$withval"],
1667     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1668 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1669
1670 AC_ARG_WITH([xorg-driver-dir],
1671     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1672                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1673     [XORG_DRIVER_INSTALL_DIR="$withval"],
1674     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1675 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1676
1677 AC_ARG_WITH([max-width],
1678     [AS_HELP_STRING([--with-max-width=N],
1679                     [Maximum framebuffer width (4096)])],
1680     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1681      AS_IF([test "${withval}" -gt "4096"],
1682            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1683 )
1684 AC_ARG_WITH([max-height],
1685     [AS_HELP_STRING([--with-max-height=N],
1686                     [Maximum framebuffer height (4096)])],
1687     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1688      AS_IF([test "${withval}" -gt "4096"],
1689            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1690 )
1691
1692 dnl
1693 dnl Gallium LLVM
1694 dnl
1695 AC_ARG_ENABLE([gallium-llvm],
1696     [AS_HELP_STRING([--enable-gallium-llvm],
1697         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1698     [enable_gallium_llvm="$enableval"],
1699     [enable_gallium_llvm=auto])
1700 if test "x$enable_gallium_llvm" = xauto; then
1701     case "$host_cpu" in
1702     i*86|x86_64) enable_gallium_llvm=yes;;
1703     esac
1704 fi
1705 if test "x$enable_gallium_llvm" = xyes; then
1706     if test "x$LLVM_CONFIG" != xno; then
1707         LLVM_VERSION=`$LLVM_CONFIG --version`
1708         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags`
1709         LLVM_LIBS="`$LLVM_CONFIG --libs` -lstdc++"
1710
1711         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1712         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1713         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1714         MESA_LLVM=1
1715     else
1716         MESA_LLVM=0
1717     fi
1718 else
1719     MESA_LLVM=0
1720 fi
1721
1722 dnl
1723 dnl Gallium helper functions
1724 dnl
1725 gallium_check_st() {
1726     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1727          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1728     fi
1729     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1730          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1731     fi
1732     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1733          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1734     fi
1735 }
1736
1737
1738 dnl
1739 dnl Gallium SVGA configuration
1740 dnl
1741 AC_ARG_ENABLE([gallium-svga],
1742     [AS_HELP_STRING([--enable-gallium-svga],
1743         [build gallium SVGA @<:@default=disabled@:>@])],
1744     [enable_gallium_svga="$enableval"],
1745     [enable_gallium_svga=auto])
1746 if test "x$enable_gallium_svga" = xyes; then
1747     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1748     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1749 elif test "x$enable_gallium_svga" = xauto; then
1750     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1751 fi
1752
1753 dnl
1754 dnl Gallium i915 configuration
1755 dnl
1756 AC_ARG_ENABLE([gallium-i915],
1757     [AS_HELP_STRING([--enable-gallium-i915],
1758         [build gallium i915 @<:@default=disabled@:>@])],
1759     [enable_gallium_i915="$enableval"],
1760     [enable_gallium_i915=auto])
1761 if test "x$enable_gallium_i915" = xyes; then
1762     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1763     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1764     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1765 elif test "x$enable_gallium_i915" = xauto; then
1766     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1767     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1768 fi
1769
1770 dnl
1771 dnl Gallium i965 configuration
1772 dnl
1773 AC_ARG_ENABLE([gallium-i965],
1774     [AS_HELP_STRING([--enable-gallium-i965],
1775         [build gallium i965 @<:@default=disabled@:>@])],
1776     [enable_gallium_i965="$enableval"],
1777     [enable_gallium_i965=auto])
1778 if test "x$enable_gallium_i965" = xyes; then
1779     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1780     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1781 elif test "x$enable_gallium_i965" = xauto; then
1782     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1783 fi
1784
1785 dnl
1786 dnl Gallium Radeon r300g configuration
1787 dnl
1788 AC_ARG_ENABLE([gallium-r300],
1789     [AS_HELP_STRING([--enable-gallium-r300],
1790         [build gallium r300 @<:@default=build DRI driver only@:>@])],
1791     [enable_gallium_r300="$enableval"],
1792     [enable_gallium_r300=auto])
1793
1794 if test "$mesa_driver" != dri ; then
1795     if test "x$enable_gallium_r300" = xauto; then
1796       enable_gallium_r300=no
1797     fi
1798 fi
1799
1800 if test "x$enable_gallium_r300" != xno; then
1801     if test "x$MESA_LLVM" = x0; then
1802         case "$host_cpu" in
1803         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build Gallium R300 on x86 and x86_64]);;
1804         esac
1805     fi
1806 fi
1807 if test "x$enable_gallium_r300" = xauto; then
1808     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1809     gallium_check_st "radeon/drm" "dri-r300"
1810 elif test "x$enable_gallium_r300" = xyes; then
1811     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1812     gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1813 fi
1814
1815 dnl
1816 dnl Gallium Radeon r600g configuration
1817 dnl
1818 AC_ARG_ENABLE([gallium-r600],
1819     [AS_HELP_STRING([--enable-gallium-r600],
1820         [build gallium r600 @<:@default=disabled@:>@])],
1821     [enable_gallium_r600="$enableval"],
1822     [enable_gallium_r600=auto])
1823 if test "x$enable_gallium_r600" = xyes; then
1824     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1825     gallium_check_st "r600/drm" "dri-r600"
1826 fi
1827
1828 dnl
1829 dnl Gallium Nouveau configuration
1830 dnl
1831 AC_ARG_ENABLE([gallium-nouveau],
1832     [AS_HELP_STRING([--enable-gallium-nouveau],
1833         [build gallium nouveau @<:@default=disabled@:>@])],
1834     [enable_gallium_nouveau="$enableval"],
1835     [enable_gallium_nouveau=no])
1836 if test "x$enable_gallium_nouveau" = xyes; then
1837     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1838     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1839 fi
1840
1841 dnl
1842 dnl Gallium swrast configuration
1843 dnl
1844 AC_ARG_ENABLE([gallium-swrast],
1845     [AS_HELP_STRING([--enable-gallium-swrast],
1846         [build gallium swrast @<:@default=auto@:>@])],
1847     [enable_gallium_swrast="$enableval"],
1848     [enable_gallium_swrast=auto])
1849 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1850     if test "x$HAVE_ST_DRI" = xyes; then
1851         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1852     fi
1853 fi
1854
1855 dnl prepend CORE_DIRS to SRC_DIRS
1856 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1857
1858 dnl Restore LDFLAGS and CPPFLAGS
1859 LDFLAGS="$_SAVE_LDFLAGS"
1860 CPPFLAGS="$_SAVE_CPPFLAGS"
1861
1862 dnl Substitute the config
1863 AC_CONFIG_FILES([configs/autoconf])
1864
1865 dnl Replace the configs/current symlink
1866 AC_CONFIG_COMMANDS([configs],[
1867 if test -f configs/current || test -L configs/current; then
1868     rm -f configs/current
1869 fi
1870 ln -s autoconf configs/current
1871 ])
1872
1873 AC_OUTPUT
1874
1875 dnl
1876 dnl Output some configuration info for the user
1877 dnl
1878 echo ""
1879 echo "        prefix:          $prefix"
1880 echo "        exec_prefix:     $exec_prefix"
1881 echo "        libdir:          $libdir"
1882 echo "        includedir:      $includedir"
1883
1884 dnl API info
1885 echo ""
1886 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1887 echo "        OpenVG:          $enable_openvg"
1888
1889 dnl Driver info
1890 echo ""
1891 echo "        Driver:          $mesa_driver"
1892 if test "$mesa_driver" != no; then
1893     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1894         echo "        OSMesa:          lib$OSMESA_LIB"
1895     else
1896         echo "        OSMesa:          no"
1897     fi
1898     if test "$mesa_driver" = dri; then
1899         # cleanup the drivers var
1900         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1901         if test "x$DRI_DIRS" = x; then
1902             echo "        DRI drivers:     no"
1903         else
1904             echo "        DRI drivers:     $dri_dirs"
1905         fi
1906         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1907         echo "        Use XCB:         $enable_xcb"
1908         echo "        Shared dricore:  $enable_dricore"
1909     fi
1910 fi
1911 echo ""
1912 echo "        GLU:             $enable_glu"
1913 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1914 echo "        glut:            $enable_glut"
1915
1916 dnl EGL
1917 echo ""
1918 echo "        EGL:             $enable_egl"
1919 if test "$enable_egl" = yes; then
1920     echo "        EGL platforms:   $EGL_PLATFORMS"
1921
1922     egl_drivers=""
1923     for d in $EGL_DRIVERS_DIRS; do
1924         egl_drivers="$egl_drivers builtin:egl_$d"
1925     done
1926
1927     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1928         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
1929         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
1930     else
1931         echo "        EGL drivers:    $egl_drivers"
1932     fi
1933 fi
1934
1935 echo ""
1936 if test "x$MESA_LLVM" = x1; then
1937     echo "        llvm:            yes"
1938     echo "        llvm-config:     $LLVM_CONFIG"
1939     echo "        llvm-version:    $LLVM_VERSION"
1940 else
1941     echo "        llvm:            no"
1942 fi
1943
1944 echo ""
1945 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1946     echo "        Gallium:         yes"
1947     echo "        Gallium dirs:    $GALLIUM_DIRS"
1948     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1949     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1950     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1951     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1952 else
1953     echo "        Gallium:         no"
1954 fi
1955
1956 dnl Libraries
1957 echo ""
1958 echo "        Shared libs:     $enable_shared"
1959 echo "        Static libs:     $enable_static"
1960
1961 dnl Compiler options
1962 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1963 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1964     $SED 's/^ *//;s/  */ /;s/ *$//'`
1965 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1966     $SED 's/^ *//;s/  */ /;s/ *$//'`
1967 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1968 echo ""
1969 echo "        CFLAGS:          $cflags"
1970 echo "        CXXFLAGS:        $cxxflags"
1971 echo "        Macros:          $defines"
1972 echo ""
1973 echo "        PYTHON2:         $PYTHON2"
1974
1975 echo ""
1976 echo "        Run '${MAKE-make}' to build Mesa"
1977 echo ""