configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.81
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840 dnl According to the manual when using pthreads, one should add -pthread to
 841 dnl both compile and link-time arguments.
 842 dnl In practise that should be sufficient for all platforms, since any
 843 dnl platforms build with GCC and Clang support the flag.
 844 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 845
 846 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 847 dnl project. Even then there's a notable issue as described in the project README
 848 case "$host_os" in
 849 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 850     pthread_stubs_possible="no"
 851     ;;
 852 * )
 853     pthread_stubs_possible="yes"
 854     ;;
 855 esac
 856
 857 if test "x$pthread_stubs_possible" = xyes; then
 858     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 859     AC_SUBST(PTHREADSTUBS_CFLAGS)
 860     AC_SUBST(PTHREADSTUBS_LIBS)
 861 fi
 862
 863 dnl SELinux awareness.
 864 AC_ARG_ENABLE([selinux],
 865     [AS_HELP_STRING([--enable-selinux],
 866         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 867     [MESA_SELINUX="$enableval"],
 868     [MESA_SELINUX=no])
 869 if test "x$enable_selinux" = "xyes"; then
 870     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 871         [AC_CHECK_HEADER([selinux/selinux.h],[],
 872                          [AC_MSG_ERROR([SELinux headers not found])])
 873          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 874                       [AC_MSG_ERROR([SELinux library not found])])
 875          SELINUX_LIBS="-lselinux"])
 876     DEFINES="$DEFINES -DMESA_SELINUX"
 877 fi
 878 AC_SUBST([SELINUX_CFLAGS])
 879 AC_SUBST([SELINUX_LIBS])
 880
 881 dnl
 882 dnl LLVM
 883 dnl
 884 AC_ARG_ENABLE([llvm-shared-libs],
 885     [AS_HELP_STRING([--enable-llvm-shared-libs],
 886         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 887     [enable_llvm_shared_libs="$enableval"],
 888     [enable_llvm_shared_libs=yes])
 889
 890 AC_ARG_WITH([llvm-prefix],
 891     [AS_HELP_STRING([--with-llvm-prefix],
 892         [Prefix for LLVM installations in non-standard locations])],
 893     [llvm_prefix="$withval"],
 894     [llvm_prefix=''])
 895
 896 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 897 if test "x$have_libelf" = xno; then
 898    LIBELF_LIBS=''
 899    LIBELF_CFLAGS=''
 900    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 901    AC_SUBST([LIBELF_LIBS])
 902    AC_SUBST([LIBELF_CFLAGS])
 903 fi
 904
 905 if test -z "$LLVM_CONFIG"; then
 906     if test -n "$llvm_prefix"; then
 907         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 908     else
 909         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 910     fi
 911 fi
 912
 913 llvm_add_component() {
 914     new_llvm_component=$1
 915     driver_name=$2
 916
 917     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 918         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 919     else
 920         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 921     fi
 922 }
 923
 924 llvm_add_default_components() {
 925     driver_name=$1
 926
 927     # Required default components
 928     llvm_add_component "bitwriter" $driver_name
 929     llvm_add_component "engine" $driver_name
 930     llvm_add_component "mcdisassembler" $driver_name
 931     llvm_add_component "mcjit" $driver_name
 932
 933     # Optional default components
 934     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 935         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 936     fi
 937 }
 938
 939 llvm_add_target() {
 940     new_llvm_target=$1
 941     driver_name=$2
 942
 943     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 944         llvm_add_component $new_llvm_target $driver_name
 945     else
 946         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 947     fi
 948 }
 949
 950 # Call this inside ` ` to get the return value.
 951 # $1 is the llvm-config command with arguments.
 952 strip_unwanted_llvm_flags() {
 953     echo " `$1` " | sed -E \
 954         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 956         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 957         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 958         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 959         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 960         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 961         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 962         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 963         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 964         -e 's/^[[[:space:]]]//' \
 965         -e 's/[[[:space:]]]$//'
 966 }
 967
 968 llvm_set_environment_variables() {
 969     if test "x$LLVM_CONFIG" != xno; then
 970         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 971         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 972         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 973         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 974
 975         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 976         save_CFLAGS="$CFLAGS"
 977         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 978
 979         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 980             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 981         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 982             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 983         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 984             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 985
 986         CFLAGS="$save_CFLAGS"
 987
 988         # Only needed for LLVM < 3.6.0
 989         if test -z "$LLVM_VERSION_PATCH"; then
 990             LLVM_VERSION_PATCH=0
 991         fi
 992
 993         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 994
 995         FOUND_LLVM=yes
 996     else
 997         FOUND_LLVM=no
 998         LLVM_VERSION_INT=0
 999     fi
1000 }
1001
1002 require_llvm() {
1003     if test "x$enable_llvm" != "xyes"; then
1004         AC_MSG_ERROR([--enable-llvm is required when building $1])
1005     fi
1006 }
1007
1008 llvm_require_version() {
1009     require_llvm $2
1010
1011     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1012     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1013     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1014
1015     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1016         # major > required major
1017         #  --> OK
1018         return
1019     fi
1020
1021     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1022         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1023             # major = required major and
1024             # minor > required minor
1025             #  --> OK
1026             return
1027         else
1028             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1029                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1030                     # major = required major and
1031                     # minor = required minor and
1032                     # patch >= required patch
1033                     #  --> OK
1034                     return
1035                 fi
1036             fi
1037         fi
1038     fi
1039
1040     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1041 }
1042
1043 radeon_llvm_check() {
1044     if test ${LLVM_VERSION_INT} -lt 307; then
1045         amdgpu_llvm_target_name='r600'
1046     else
1047         amdgpu_llvm_target_name='amdgpu'
1048     fi
1049
1050     llvm_require_version $*
1051
1052     llvm_add_target $amdgpu_llvm_target_name $2
1053
1054     llvm_add_default_components $2
1055     llvm_add_component "bitreader" $2
1056     llvm_add_component "ipo" $2
1057
1058     if test "x$have_libelf" != xyes; then
1059        AC_MSG_ERROR([$2 requires libelf when using llvm])
1060     fi
1061 }
1062
1063 llvm_set_environment_variables
1064
1065 AC_SUBST([LLVM_CFLAGS])
1066 AC_SUBST([LLVM_CXXFLAGS])
1067 AC_SUBST([LLVM_LIBS])
1068 AC_SUBST([LLVM_LDFLAGS])
1069 AC_SUBST([LLVM_INCLUDEDIR])
1070
1071 dnl
1072 dnl libunwind
1073 dnl
1074 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1075 AC_ARG_ENABLE([libunwind],
1076     [AS_HELP_STRING([--enable-libunwind],
1077             [Use libunwind for backtracing (default: auto)])],
1078         [LIBUNWIND="$enableval"],
1079         [LIBUNWIND="$HAVE_LIBUNWIND"])
1080
1081 if test "x$LIBUNWIND" = "xyes"; then
1082     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1083     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1084 fi
1085
1086
1087 dnl Options for APIs
1088 AC_ARG_ENABLE([opengl],
1089     [AS_HELP_STRING([--disable-opengl],
1090         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1091     [enable_opengl="$enableval"],
1092     [enable_opengl=yes])
1093 AC_ARG_ENABLE([gles1],
1094     [AS_HELP_STRING([--disable-gles1],
1095         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1096     [enable_gles1="$enableval"],
1097     [enable_gles1=yes])
1098 AC_ARG_ENABLE([gles2],
1099     [AS_HELP_STRING([--disable-gles2],
1100         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1101     [enable_gles2="$enableval"],
1102     [enable_gles2=yes])
1103
1104 AC_ARG_ENABLE([dri],
1105     [AS_HELP_STRING([--enable-dri],
1106         [enable DRI modules @<:@default=enabled@:>@])],
1107     [enable_dri="$enableval"],
1108     [enable_dri=yes])
1109
1110 AC_ARG_ENABLE([gallium-extra-hud],
1111     [AS_HELP_STRING([--enable-gallium-extra-hud],
1112         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1113     [enable_gallium_extra_hud="$enableval"],
1114     [enable_gallium_extra_hud=no])
1115 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1116 if test "x$enable_gallium_extra_hud" = xyes ; then
1117     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1118 fi
1119
1120 #TODO: no pkgconfig .pc available for libsensors.
1121 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1122 AC_ARG_ENABLE([lmsensors],
1123     [AS_HELP_STRING([--enable-lmsensors],
1124         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1125     [enable_lmsensors="$enableval"],
1126     [enable_lmsensors=no])
1127 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1128 if test "x$enable_lmsensors" = xyes ; then
1129     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1130     LIBSENSORS_LIBS="-lsensors"
1131 else
1132     LIBSENSORS_LIBS=""
1133 fi
1134 AC_SUBST(LIBSENSORS_LIBS)
1135
1136 case "$host_os" in
1137 linux*)
1138     dri3_default=yes
1139     ;;
1140 *)
1141     dri3_default=no
1142     ;;
1143 esac
1144
1145 if test "x$enable_dri" = xno; then
1146     dri3_default=no
1147 fi
1148
1149 AC_ARG_ENABLE([dri3],
1150     [AS_HELP_STRING([--enable-dri3],
1151         [enable DRI3 @<:@default=auto@:>@])],
1152     [enable_dri3="$enableval"],
1153     [enable_dri3="$dri3_default"])
1154 AC_ARG_ENABLE([glx],
1155     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1156         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1157     [enable_glx="$enableval"],
1158     [enable_glx=yes])
1159 AC_ARG_ENABLE([osmesa],
1160     [AS_HELP_STRING([--enable-osmesa],
1161         [enable OSMesa library @<:@default=disabled@:>@])],
1162     [enable_osmesa="$enableval"],
1163     [enable_osmesa=no])
1164 AC_ARG_ENABLE([gallium-osmesa],
1165     [AS_HELP_STRING([--enable-gallium-osmesa],
1166         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1167     [enable_gallium_osmesa="$enableval"],
1168     [enable_gallium_osmesa=no])
1169 AC_ARG_ENABLE([egl],
1170     [AS_HELP_STRING([--disable-egl],
1171         [disable EGL library @<:@default=enabled@:>@])],
1172     [enable_egl="$enableval"],
1173     [enable_egl=yes])
1174
1175 AC_ARG_ENABLE([xa],
1176     [AS_HELP_STRING([--enable-xa],
1177         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1178     [enable_xa="$enableval"],
1179     [enable_xa=no])
1180 AC_ARG_ENABLE([gbm],
1181    [AS_HELP_STRING([--enable-gbm],
1182          [enable gbm library @<:@default=yes except cygwin@:>@])],
1183    [enable_gbm="$enableval"],
1184    [case "$host_os" in
1185        cygwin*)
1186           enable_gbm=no
1187           ;;
1188        *)
1189           enable_gbm=yes
1190           ;;
1191     esac])
1192 AC_ARG_ENABLE([nine],
1193     [AS_HELP_STRING([--enable-nine],
1194         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1195     [enable_nine="$enableval"],
1196     [enable_nine=no])
1197
1198 AC_ARG_ENABLE([xvmc],
1199    [AS_HELP_STRING([--enable-xvmc],
1200          [enable xvmc library @<:@default=auto@:>@])],
1201    [enable_xvmc="$enableval"],
1202    [enable_xvmc=auto])
1203 AC_ARG_ENABLE([vdpau],
1204    [AS_HELP_STRING([--enable-vdpau],
1205          [enable vdpau library @<:@default=auto@:>@])],
1206    [enable_vdpau="$enableval"],
1207    [enable_vdpau=auto])
1208 AC_ARG_ENABLE([omx],
1209    [AS_HELP_STRING([--enable-omx],
1210          [enable OpenMAX library @<:@default=disabled@:>@])],
1211    [enable_omx="$enableval"],
1212    [enable_omx=no])
1213 AC_ARG_ENABLE([va],
1214    [AS_HELP_STRING([--enable-va],
1215          [enable va library @<:@default=auto@:>@])],
1216    [enable_va="$enableval"],
1217    [enable_va=auto])
1218 AC_ARG_ENABLE([opencl],
1219    [AS_HELP_STRING([--enable-opencl],
1220          [enable OpenCL library @<:@default=disabled@:>@])],
1221    [enable_opencl="$enableval"],
1222    [enable_opencl=no])
1223 AC_ARG_ENABLE([opencl_icd],
1224    [AS_HELP_STRING([--enable-opencl-icd],
1225           [Build an OpenCL ICD library to be loaded by an ICD implementation
1226            @<:@default=disabled@:>@])],
1227     [enable_opencl_icd="$enableval"],
1228     [enable_opencl_icd=no])
1229
1230 AC_ARG_ENABLE([gallium-tests],
1231     [AS_HELP_STRING([--enable-gallium-tests],
1232         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1233     [enable_gallium_tests="$enableval"],
1234     [enable_gallium_tests=no])
1235
1236 # Option for Gallium drivers
1237
1238 # Keep this in sync with the --with-gallium-drivers help string default value
1239 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1240
1241 AC_ARG_WITH([gallium-drivers],
1242     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1243         [comma delimited Gallium drivers list, e.g.
1244         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1245         @<:@default=r300,r600,svga,swrast@:>@])],
1246     [with_gallium_drivers="$withval"],
1247     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1248
1249 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1250 # here so that the script doesn't choke on an unknown driver name later.
1251 case "$with_gallium_drivers" in
1252     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1253     no) with_gallium_drivers='' ;;
1254 esac
1255
1256 if test "x$enable_opengl" = xno -a \
1257         "x$enable_gles1" = xno -a \
1258         "x$enable_gles2" = xno -a \
1259         "x$enable_nine" = xno -a \
1260         "x$enable_xa" = xno -a \
1261         "x$enable_xvmc" = xno -a \
1262         "x$enable_vdpau" = xno -a \
1263         "x$enable_omx" = xno -a \
1264         "x$enable_va" = xno -a \
1265         "x$enable_opencl" = xno; then
1266     AC_MSG_ERROR([at least one API should be enabled])
1267 fi
1268
1269 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1270 if test "x$enable_opengl" = xno -a \
1271         "x$enable_gles1" = xyes; then
1272     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1273 fi
1274
1275 if test "x$enable_opengl" = xno -a \
1276         "x$enable_gles2" = xyes; then
1277     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1278 fi
1279
1280 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1282 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1283 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1284                                         "x$enable_gles1" = xyes -o \
1285                                         "x$enable_gles2" = xyes)
1286
1287 # Validate GLX options
1288 if test "x$enable_glx" = xyes; then
1289     if test "x$enable_dri" = xyes; then
1290         enable_glx=dri
1291     elif test -n "$with_gallium_drivers"; then
1292         enable_glx=gallium-xlib
1293     else
1294         enable_glx=xlib
1295     fi
1296 fi
1297 case "x$enable_glx" in
1298 xdri | xxlib | xgallium-xlib)
1299     # GLX requires OpenGL
1300     if test "x$enable_opengl" = xno; then
1301         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1302     fi
1303
1304     # Check individual dependencies
1305     case "x$enable_glx" in
1306     xdri)
1307         if test "x$enable_dri" = xno; then
1308             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1309         fi
1310         ;;
1311     xxlib)
1312         if test "x$enable_dri" = xyes; then
1313             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1314         fi
1315         ;;
1316     xgallium-xlib )
1317         if test "x$enable_dri" = xyes; then
1318             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1319         fi
1320         if test -z "$with_gallium_drivers"; then
1321             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1322         fi
1323         ;;
1324     esac
1325     ;;
1326 xno)
1327     ;;
1328 *)
1329     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1330     ;;
1331 esac
1332
1333 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1334 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1335 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1336 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1337
1338 DEFAULT_GL_LIB_NAME=GL
1339
1340 dnl
1341 dnl Libglvnd configuration
1342 dnl
1343 AC_ARG_ENABLE([libglvnd],
1344     [AS_HELP_STRING([--enable-libglvnd],
1345         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1346     [enable_libglvnd="$enableval"],
1347     [enable_libglvnd=no])
1348 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1349
1350 if test "x$enable_libglvnd" = xyes ; then
1351     dnl XXX: update once we can handle more than libGL/glx.
1352     dnl Namely: we should error out if neither of the glvnd enabled libraries
1353     dnl are built
1354     case "x$enable_glx" in
1355     xno)
1356         AC_MSG_ERROR([cannot build libglvnd without GLX])
1357         ;;
1358     xxlib | xgallium-xlib )
1359         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1360         ;;
1361     xdri)
1362         ;;
1363     esac
1364
1365     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1366     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1367     AC_SUBST([LIBGLVND_DATADIR])
1368
1369     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1370     DEFAULT_GL_LIB_NAME=GLX_mesa
1371 fi
1372
1373 AC_ARG_WITH([gl-lib-name],
1374   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1375     [specify GL library name @<:@default=GL@:>@])],
1376   [GL_LIB=$withval],
1377   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1378 AC_ARG_WITH([osmesa-lib-name],
1379   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1380     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1381   [OSMESA_LIB=$withval],
1382   [OSMESA_LIB=OSMesa])
1383 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1384 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1385
1386 dnl
1387 dnl Mangled Mesa support
1388 dnl
1389 AC_ARG_ENABLE([mangling],
1390   [AS_HELP_STRING([--enable-mangling],
1391     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1392   [enable_mangling="${enableval}"],
1393   [enable_mangling=no]
1394 )
1395 if test "x${enable_mangling}" = "xyes" ; then
1396   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1397   GL_LIB="Mangled${GL_LIB}"
1398   OSMESA_LIB="Mangled${OSMESA_LIB}"
1399 fi
1400 AC_SUBST([GL_LIB])
1401 AC_SUBST([OSMESA_LIB])
1402
1403 # Check for libdrm
1404 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1405                   [have_libdrm=yes], [have_libdrm=no])
1406 if test "x$have_libdrm" = xyes; then
1407         DEFINES="$DEFINES -DHAVE_LIBDRM"
1408 fi
1409
1410 require_libdrm() {
1411     if test "x$have_libdrm" != xyes; then
1412        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1413     fi
1414 }
1415
1416
1417 # Select which platform-dependent DRI code gets built
1418 case "$host_os" in
1419 darwin*)
1420     dri_platform='apple' ;;
1421 cygwin*)
1422     dri_platform='windows' ;;
1423 gnu*)
1424     dri_platform='none' ;;
1425 *)
1426     dri_platform='drm' ;;
1427 esac
1428
1429 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1430     have_drisw_kms='yes'
1431 fi
1432
1433 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1434 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1435 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1436 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1437 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1438 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1439 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1440 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1441 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1442
1443 AC_ARG_ENABLE([shared-glapi],
1444     [AS_HELP_STRING([--enable-shared-glapi],
1445         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1446     [enable_shared_glapi="$enableval"],
1447     [enable_shared_glapi=yes])
1448
1449 case "x$enable_opengl$enable_gles1$enable_gles2" in
1450 x*yes*yes*)
1451     if test "x$enable_shared_glapi" = xno; then
1452         AC_MSG_ERROR([shared GLAPI required when building two or more of
1453                       the following APIs - opengl, gles1 gles2])
1454     fi
1455     ;;
1456 esac
1457
1458 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1459
1460 # Build the pipe-drivers as separate libraries/modules.
1461 # Do not touch this unless you know what you are doing.
1462 # XXX: Expose via configure option ?
1463 enable_shared_pipe_drivers=no
1464
1465 dnl
1466 dnl Driver specific build directories
1467 dnl
1468
1469 if test "x$enable_gallium_osmesa" = xyes; then
1470     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1471         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1472     fi
1473     if test "x$enable_osmesa" = xyes; then
1474         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1475     fi
1476 fi
1477
1478 require_dri_shared_libs_and_glapi() {
1479     if test "x$enable_static" = xyes; then
1480         AC_MSG_ERROR([$1 cannot be build as static library])
1481     fi
1482
1483     if test "x$enable_dri" != xyes; then
1484         # There is only a single backend which won't be build/used otherwise.
1485         # XXX: Revisit this as the egl/haiku is a thing.
1486         AC_MSG_ERROR([$1 requires --enable-dri])
1487     fi
1488
1489     if test "x$enable_shared_glapi" != xyes; then
1490         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1491     fi
1492 }
1493
1494 if test "x$enable_dri" = xyes; then
1495     require_dri_shared_libs_and_glapi "DRI"
1496
1497     # not a hard requirement as swrast does not depend on it
1498     if test "x$have_libdrm" = xyes; then
1499         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1500     fi
1501 fi
1502
1503 AC_ARG_ENABLE([driglx-direct],
1504     [AS_HELP_STRING([--disable-driglx-direct],
1505         [disable direct rendering in GLX and EGL for DRI \
1506             @<:@default=auto@:>@])],
1507     [driglx_direct="$enableval"],
1508     [driglx_direct="yes"])
1509
1510 dnl
1511 dnl libGL configuration per driver
1512 dnl
1513 if test "x$enable_glx" != xno; then
1514     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1515 fi
1516 case "x$enable_glx" in
1517 xxlib | xgallium-xlib)
1518     # Xlib-based GLX
1519     dri_modules="x11 xext xcb"
1520     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1521     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1522     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1523     GL_LIB_DEPS="$XLIBGL_LIBS"
1524     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1525     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1526     ;;
1527 xdri)
1528     # DRI-based GLX
1529
1530     # find the DRI deps for libGL
1531     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1532
1533     if test x"$driglx_direct" = xyes; then
1534         if test x"$dri_platform" = xdrm ; then
1535             DEFINES="$DEFINES -DGLX_USE_DRM"
1536             require_libdrm "Direct rendering"
1537
1538             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1539             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1540
1541             if test x"$enable_dri" = xyes; then
1542                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1543             fi
1544         fi
1545         if test x"$dri_platform" = xapple ; then
1546             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1547         fi
1548         if test x"$dri_platform" = xwindows ; then
1549             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1550         fi
1551     fi
1552
1553     # add xf86vidmode if available
1554     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1555     if test "$HAVE_XF86VIDMODE" = yes ; then
1556         dri_modules="$dri_modules xxf86vm"
1557     fi
1558
1559     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1560     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1561     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1562     GL_LIB_DEPS="$DRIGL_LIBS"
1563
1564     # need DRM libs, $PTHREAD_LIBS, etc.
1565     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1566     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1567     ;;
1568 esac
1569
1570 # This is outside the case (above) so that it is invoked even for non-GLX
1571 # builds.
1572 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1573
1574 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1576 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1577 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1578
1579 AC_SUBST([X11_INCLUDES])
1580 AC_SUBST([GL_LIB_DEPS])
1581 AC_SUBST([GL_PC_REQ_PRIV])
1582 AC_SUBST([GL_PC_LIB_PRIV])
1583 AC_SUBST([GL_PC_CFLAGS])
1584 AC_SUBST([DRI_PC_REQ_PRIV])
1585 AC_SUBST([GLESv1_CM_LIB_DEPS])
1586 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1587 AC_SUBST([GLESv2_LIB_DEPS])
1588 AC_SUBST([GLESv2_PC_LIB_PRIV])
1589
1590 AC_SUBST([HAVE_XF86VIDMODE])
1591
1592 dnl
1593 dnl More GLX setup
1594 dnl
1595 case "x$enable_glx" in
1596 xxlib | xgallium-xlib)
1597     DEFINES="$DEFINES -DUSE_XSHM"
1598     ;;
1599 xdri)
1600     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1601     if test "x$driglx_direct" = xyes; then
1602         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1603     fi
1604     ;;
1605 esac
1606
1607 dnl
1608 dnl TLS detection
1609 dnl
1610
1611 AC_ARG_ENABLE([glx-tls],
1612     [AS_HELP_STRING([--enable-glx-tls],
1613         [enable TLS support in GLX @<:@default=enabled@:>@])],
1614     [GLX_USE_TLS="$enableval"],
1615     [GLX_USE_TLS=yes])
1616 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1617
1618 if test "x$GLX_USE_TLS" = xyes; then
1619     DEFINES="$DEFINES -DGLX_USE_TLS"
1620 fi
1621
1622 dnl Read-only text section on x86 hardened platforms
1623 AC_ARG_ENABLE([glx-read-only-text],
1624     [AS_HELP_STRING([--enable-glx-read-only-text],
1625         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1626     [enable_glx_read_only_text="$enableval"],
1627     [enable_glx_read_only_text=no])
1628 if test "x$enable_glx_read_only_text" = xyes; then
1629     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1630 fi
1631
1632 dnl
1633 dnl DEPRECATED: EGL Platforms configuration
1634 dnl
1635 AC_ARG_WITH([egl-platforms],
1636     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1637         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1638     [with_egl_platforms="$withval"],
1639     [with_egl_platforms=auto])
1640
1641 if test "x$with_egl_platforms" = xauto; then
1642     with_egl_platforms="x11,surfaceless"
1643     if test "x$enable_gbm" = xyes; then
1644         with_egl_platforms="$with_egl_platforms,drm"
1645     fi
1646 else
1647     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1648 fi
1649
1650 dnl
1651 dnl Platforms configuration
1652 dnl
1653 AC_ARG_WITH([platforms],
1654     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1655         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1656         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1657     [with_platforms="$withval"],
1658     [with_platforms=auto])
1659
1660 # Reuse the autodetection rather than duplicating it.
1661 if test "x$with_platforms" = xauto; then
1662     with_platforms=$with_egl_platforms
1663 fi
1664
1665 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1666         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1667         WAYLAND_SCANNER='')
1668 if test "x$WAYLAND_SCANNER" = x; then
1669     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1670 fi
1671
1672 # Do per platform setups and checks
1673 platforms=`IFS=', '; echo $with_platforms`
1674 for plat in $platforms; do
1675         case "$plat" in
1676         wayland)
1677
1678                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1679
1680                 if test "x$WAYLAND_SCANNER" = "x:"; then
1681                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1682                 fi
1683                 DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1684                 ;;
1685
1686         x11)
1687                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1688                 DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1689                 ;;
1690
1691         drm)
1692                 test "x$enable_gbm" = "xno" &&
1693                         AC_MSG_ERROR([EGL platform drm needs gbm])
1694                 DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1695                 ;;
1696
1697         surfaceless)
1698                 DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1699                 ;;
1700
1701         android)
1702                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1703                 DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1704                 ;;
1705
1706         *)
1707                 AC_MSG_ERROR([platform '$plat' does not exist])
1708                 ;;
1709         esac
1710
1711         case "$plat" in
1712         wayland|drm|surfaceless)
1713                 require_libdrm "Platform $plat"
1714                 ;;
1715         esac
1716 done
1717
1718 if test "x$enable_glx" != xno; then
1719     if ! echo "$platforms" | grep -q 'x11'; then
1720         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1721     fi
1722 fi
1723
1724 if test x"$enable_dri3" = xyes; then
1725     DEFINES="$DEFINES -DHAVE_DRI3"
1726
1727     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1728     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1729 fi
1730
1731 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1732 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1733 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1734 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1735 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1736
1737 dnl
1738 dnl More DRI setup
1739 dnl
1740 dnl Directory for DRI drivers
1741 AC_ARG_WITH([dri-driverdir],
1742     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1743         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1744     [DRI_DRIVER_INSTALL_DIR="$withval"],
1745     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1746 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1747 dnl Extra search path for DRI drivers
1748 AC_ARG_WITH([dri-searchpath],
1749     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1750         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1751     [DRI_DRIVER_SEARCH_DIR="$withval"],
1752     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1753 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1754 dnl Which drivers to build - default is chosen by platform
1755 AC_ARG_WITH([dri-drivers],
1756     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1757         [comma delimited classic DRI drivers list, e.g.
1758         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1759     [with_dri_drivers="$withval"],
1760     [with_dri_drivers=auto])
1761
1762 if test "x$with_dri_drivers" = xauto; then
1763     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1764         with_dri_drivers="yes"
1765     else
1766         with_dri_drivers="no"
1767     fi
1768 fi
1769 if test "x$with_dri_drivers" = xno; then
1770     with_dri_drivers=''
1771 fi
1772
1773 dnl If $with_dri_drivers is yes, drivers will be added through
1774 dnl platform checks. Set DEFINES and LIB_DEPS
1775 if test "x$enable_dri" = xyes; then
1776     # Platform specific settings and drivers to build
1777     case "$host_os" in
1778     linux*)
1779         case "$host_cpu" in
1780         powerpc* | sparc*)
1781             # Build only the drivers for cards that exist on PowerPC/sparc
1782             if test "x$with_dri_drivers" = "xyes"; then
1783                 with_dri_drivers="r200 radeon swrast"
1784             fi
1785             ;;
1786         esac
1787         ;;
1788     cygwin*)
1789         if test "x$with_dri_drivers" = "xyes"; then
1790             with_dri_drivers="swrast"
1791         fi
1792         ;;
1793     darwin*)
1794         DEFINES="$DEFINES -DBUILDING_MESA"
1795         if test "x$with_dri_drivers" = "xyes"; then
1796             with_dri_drivers="swrast"
1797         fi
1798         ;;
1799     esac
1800
1801     # default drivers
1802     if test "x$with_dri_drivers" = "xyes"; then
1803         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1804     fi
1805
1806     # Check for expat
1807     PKG_CHECK_MODULES([EXPAT], [expat], [],
1808         # expat version 2.0 and earlier do not provide expat.pc
1809         [AC_CHECK_HEADER([expat.h],[],
1810                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1811          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1812                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1813          EXPAT_LIBS="-lexpat"])
1814
1815     # put all the necessary libs together
1816     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1817 fi
1818
1819 AC_SUBST([DRI_LIB_DEPS])
1820
1821 DRI_DIRS=''
1822 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1823 if test -n "$with_dri_drivers"; then
1824     if test "x$enable_opengl" != xyes; then
1825         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1826     fi
1827
1828     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1829     for driver in $dri_drivers; do
1830         DRI_DIRS="$DRI_DIRS $driver"
1831         case "x$driver" in
1832         xi915)
1833             require_libdrm "i915"
1834             HAVE_I915_DRI=yes
1835             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1836             ;;
1837         xi965)
1838             require_libdrm "i965"
1839             HAVE_I965_DRI=yes
1840             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1841             ;;
1842         xnouveau)
1843             require_libdrm "nouveau"
1844             HAVE_NOUVEAU_DRI=yes
1845             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1846             ;;
1847         xradeon)
1848             require_libdrm "radeon"
1849             HAVE_RADEON_DRI=yes;
1850             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1851             ;;
1852         xr200)
1853             require_libdrm "r200"
1854             HAVE_R200_DRI=yes
1855             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1856             ;;
1857         xswrast)
1858             HAVE_SWRAST_DRI=yes
1859             ;;
1860         *)
1861             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1862             ;;
1863         esac
1864     done
1865     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1866 fi
1867
1868
1869 dnl
1870 dnl Gallium LLVM
1871 dnl Deprecated: kept for backwards compatibility
1872 dnl
1873 AC_ARG_ENABLE([gallium-llvm],
1874     [AS_HELP_STRING([--enable-gallium-llvm],
1875         [DEPRECATED: use --enable-llvm instead])],
1876     [enable_gallium_llvm="$enableval"],
1877     [enable_gallium_llvm=auto])
1878
1879 if test "x$enable_gallium_llvm" != xauto; then
1880    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1881    enable_llvm=$enable_gallium_llvm
1882 fi
1883
1884 dnl
1885 dnl LLVM
1886 dnl
1887 AC_ARG_ENABLE([llvm],
1888     [AS_HELP_STRING([--enable-llvm],
1889         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1890     [enable_llvm="$enableval"],
1891     [enable_llvm=auto])
1892
1893 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1894     if test "x$FOUND_LLVM" = xyes; then
1895         case "$host_cpu" in
1896         i*86|x86_64|amd64) enable_llvm=yes;;
1897         *) enable_llvm=no;;
1898         esac
1899     else
1900         enable_llvm=no
1901     fi
1902 fi
1903
1904 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1905     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1906 fi
1907
1908 #
1909 # Vulkan driver configuration
1910 #
1911
1912 AC_ARG_WITH([vulkan-drivers],
1913     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1914         [comma delimited Vulkan drivers list, e.g.
1915         "intel,radeon"
1916         @<:@default=no@:>@])],
1917     [with_vulkan_drivers="$withval"],
1918     [with_vulkan_drivers="no"])
1919
1920 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1921 # here so that the script doesn't choke on an unknown driver name later.
1922 case "x$with_vulkan_drivers" in
1923     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1924     xno) with_vulkan_drivers='' ;;
1925 esac
1926
1927 AC_ARG_WITH([vulkan-icddir],
1928     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1929         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1930     [VULKAN_ICD_INSTALL_DIR="$withval"],
1931     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1932 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1933
1934 require_x11_dri3() {
1935     if echo "$platforms" | grep -q 'x11'; then
1936         if test "x$enable_dri3" != xyes; then
1937             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1938         fi
1939     fi
1940 }
1941
1942 if test -n "$with_vulkan_drivers"; then
1943     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1944         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1945     fi
1946
1947     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1948     for driver in $VULKAN_DRIVERS; do
1949         case "x$driver" in
1950         xintel)
1951             require_libdrm "ANV"
1952             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1953             require_x11_dri3 "ANV"
1954             HAVE_INTEL_VULKAN=yes
1955             ;;
1956         xradeon)
1957             require_libdrm "radv"
1958             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1959             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1960             require_x11_dri3 "radv"
1961             HAVE_RADEON_VULKAN=yes
1962             ;;
1963         *)
1964             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1965             ;;
1966         esac
1967     done
1968     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1969 fi
1970
1971
1972 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1973 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1974 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1975                                   "x$enable_osmesa" = xyes -o \
1976                                   -n "$DRI_DIRS")
1977
1978 dnl
1979 dnl OSMesa configuration
1980 dnl
1981
1982 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1983 AC_ARG_WITH([osmesa-bits],
1984     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1985         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1986     [osmesa_bits="$withval"],
1987     [osmesa_bits=8])
1988 if test "x$osmesa_bits" != x8; then
1989     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1990         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1991         osmesa_bits=8
1992     fi
1993 fi
1994 case "x$osmesa_bits" in
1995 x8)
1996     OSMESA_LIB="${OSMESA_LIB}"
1997     ;;
1998 x16|x32)
1999     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2000     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2001     ;;
2002 *)
2003     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2004     ;;
2005 esac
2006
2007 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2008     # only link libraries with osmesa if shared
2009     if test "$enable_static" = no; then
2010         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2011     else
2012         OSMESA_LIB_DEPS=""
2013     fi
2014     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2015 fi
2016
2017 AC_SUBST([OSMESA_LIB_DEPS])
2018 AC_SUBST([OSMESA_PC_REQ])
2019 AC_SUBST([OSMESA_PC_LIB_PRIV])
2020
2021 dnl
2022 dnl gbm configuration
2023 dnl
2024 if test "x$enable_gbm" = xyes; then
2025     require_dri_shared_libs_and_glapi "gbm"
2026 fi
2027 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2028 # FINISHME: GBM has a number of dependencies which we should add below
2029 GBM_PC_REQ_PRIV=""
2030 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2031 AC_SUBST([GBM_PC_REQ_PRIV])
2032 AC_SUBST([GBM_PC_LIB_PRIV])
2033
2034 dnl
2035 dnl EGL configuration
2036 dnl
2037
2038 if test "x$enable_egl" = xyes; then
2039     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2040
2041     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2042
2043     require_dri_shared_libs_and_glapi "egl"
2044 fi
2045 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2046 AC_SUBST([EGL_LIB_DEPS])
2047
2048 gallium_st="mesa"
2049
2050 dnl
2051 dnl XA configuration
2052 dnl
2053 if test "x$enable_xa" = xyes; then
2054     if test "x$with_gallium_drivers" = xswrast; then
2055        AC_MSG_ERROR([
2056           Building xa requires at least one non swrast gallium driver.
2057           If you are looking to use libxatracker.so with the VMware driver,
2058           make sure to include svga in the gallium drivers list, apart from
2059           enabling XA.
2060           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2061     fi
2062     gallium_st="$gallium_st xa"
2063 fi
2064 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2065
2066 if echo $platforms | grep -q "x11"; then
2067     have_xvmc_platform=yes
2068 else
2069     have_xvmc_platform=no
2070 fi
2071
2072 if echo $platforms | grep -q "x11"; then
2073     have_vdpau_platform=yes
2074 else
2075     have_vdpau_platform=no
2076 fi
2077
2078 if echo $platforms | grep -q "x11\|drm"; then
2079     have_omx_platform=yes
2080 else
2081     have_omx_platform=no
2082 fi
2083
2084 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2085     have_va_platform=yes
2086 else
2087     have_va_platform=no
2088 fi
2089
2090 dnl
2091 dnl Gallium G3DVL configuration
2092 dnl
2093 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2094     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2095         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2096     fi
2097
2098     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2099         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2100     fi
2101
2102     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2103         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2104     fi
2105
2106     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2107         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2108     fi
2109 fi
2110
2111 if test "x$enable_dri" = xyes -o \
2112         "x$enable_xvmc" = xyes -o \
2113         "x$enable_vdpau" = xyes -o \
2114         "x$enable_omx" = xyes -o \
2115         "x$enable_va" = xyes; then
2116     need_gallium_vl=yes
2117 fi
2118 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2119
2120 if test "x$enable_xvmc" = xyes -o \
2121         "x$enable_vdpau" = xyes -o \
2122         "x$enable_omx" = xyes -o \
2123         "x$enable_va" = xyes; then
2124     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2125     need_gallium_vl_winsys=yes
2126 fi
2127 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2128
2129 if test "x$enable_xvmc" = xyes; then
2130     if test "x$have_xvmc_platform" != xyes; then
2131         AC_MSG_ERROR([XVMC requires the x11 platforms])
2132     fi
2133     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2134     gallium_st="$gallium_st xvmc"
2135 fi
2136 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2137
2138 if test "x$enable_vdpau" = xyes; then
2139     if test "x$have_vdpau_platform" != xyes; then
2140         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2141     fi
2142     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2143     gallium_st="$gallium_st vdpau"
2144     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2145 fi
2146 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2147
2148 if test "x$enable_omx" = xyes; then
2149     if test "x$have_omx_platform" != xyes; then
2150         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2151     fi
2152     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2153     gallium_st="$gallium_st omx"
2154 fi
2155 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2156
2157 if test "x$enable_va" = xyes; then
2158     if test "x$have_va_platform" != xyes; then
2159         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2160     fi
2161     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2162     gallium_st="$gallium_st va"
2163 fi
2164 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2165
2166 dnl
2167 dnl Nine Direct3D9 configuration
2168 dnl
2169 if test "x$enable_nine" = xyes; then
2170     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2171         AC_MSG_ERROR([nine requires the gallium swrast driver])
2172     fi
2173     if test "x$with_gallium_drivers" = xswrast; then
2174         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2175     fi
2176     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2177         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2178     fi
2179
2180     if test "x$enable_dri3" = xno; then
2181         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2182     fi
2183
2184     gallium_st="$gallium_st nine"
2185 fi
2186 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2187
2188 dnl
2189 dnl OpenCL configuration
2190 dnl
2191
2192 AC_ARG_WITH([clang-libdir],
2193    [AS_HELP_STRING([--with-clang-libdir],
2194          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2195    [CLANG_LIBDIR="$withval"],
2196    [CLANG_LIBDIR=''])
2197
2198 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2199
2200 if test "x$enable_opencl" = xyes; then
2201     if test -z "$with_gallium_drivers"; then
2202         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2203     fi
2204
2205     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2206         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2207     fi
2208
2209     if test "x$have_libclc" = xno; then
2210         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2211                     Make sure the directory containing libclc.pc is specified in your
2212                     PKG_CONFIG_PATH environment variable.
2213                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2214     else
2215         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2216         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2217         AC_SUBST([LIBCLC_INCLUDEDIR])
2218         AC_SUBST([LIBCLC_LIBEXECDIR])
2219     fi
2220
2221     gallium_st="$gallium_st clover"
2222
2223     if test "x$enable_opencl_icd" = xyes; then
2224         OPENCL_LIBNAME="MesaOpenCL"
2225     else
2226         OPENCL_LIBNAME="OpenCL"
2227     fi
2228
2229     if test "x$have_libelf" != xyes; then
2230        AC_MSG_ERROR([Clover requires libelf])
2231     fi
2232
2233     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2234         altivec_enabled=no
2235         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2236         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2237         #error "AltiVec not enabled"
2238         #endif
2239         ])], altivec_enabled=yes)
2240
2241         if test "$altivec_enabled" = yes; then
2242             CLOVER_STD_OVERRIDE="-std=gnu++11"
2243         fi
2244         AC_SUBST([CLOVER_STD_OVERRIDE])
2245     fi
2246
2247     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2248
2249     llvm_add_default_components "opencl"
2250     llvm_add_component "all-targets" "opencl"
2251     llvm_add_component "linker" "opencl"
2252     llvm_add_component "instrumentation" "opencl"
2253     llvm_add_component "ipo" "opencl"
2254     llvm_add_component "irreader" "opencl"
2255     llvm_add_component "option" "opencl"
2256     llvm_add_component "objcarcopts" "opencl"
2257     llvm_add_component "profiledata" "opencl"
2258
2259     dnl Check for Clang internal headers
2260     if test -z "$CLANG_LIBDIR"; then
2261         CLANG_LIBDIR=${LLVM_LIBDIR}
2262     fi
2263     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2264     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2265         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2266 fi
2267 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2268 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2269 AC_SUBST([OPENCL_LIBNAME])
2270 AC_SUBST([CLANG_RESOURCE_DIR])
2271
2272 dnl
2273 dnl Gallium configuration
2274 dnl
2275 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2276
2277 # libEGL wants to default to the first platform specified in
2278 # ./configure.  parse that here.
2279 if test "x$platforms" != "x"; then
2280     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2281     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2282 else
2283     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2284 fi
2285
2286 AC_SUBST([EGL_NATIVE_PLATFORM])
2287 AC_SUBST([EGL_CFLAGS])
2288
2289 # If we don't have the X11 platform, set this define so we don't try to include
2290 # the X11 headers.
2291 if ! echo "$platforms" | grep -q 'x11'; then
2292     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2293     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2294 fi
2295
2296 dnl Directory for XVMC libs
2297 AC_ARG_WITH([xvmc-libdir],
2298     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2299         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2300     [XVMC_LIB_INSTALL_DIR="$withval"],
2301     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2302 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2303
2304 dnl
2305 dnl Gallium Tests
2306 dnl
2307 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2308
2309 dnl Directory for VDPAU libs
2310 AC_ARG_WITH([vdpau-libdir],
2311     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2312         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2313     [VDPAU_LIB_INSTALL_DIR="$withval"],
2314     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2315 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2316
2317 dnl Directory for OMX libs
2318
2319 AC_ARG_WITH([omx-libdir],
2320     [AS_HELP_STRING([--with-omx-libdir=DIR],
2321         [directory for the OMX libraries])],
2322     [OMX_LIB_INSTALL_DIR="$withval"],
2323     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2324                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2325 AC_SUBST([OMX_LIB_INSTALL_DIR])
2326
2327 dnl Directory for VA libs
2328
2329 AC_ARG_WITH([va-libdir],
2330     [AS_HELP_STRING([--with-va-libdir=DIR],
2331         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2332     [VA_LIB_INSTALL_DIR="$withval"],
2333     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2334 AC_SUBST([VA_LIB_INSTALL_DIR])
2335
2336 AC_ARG_WITH([d3d-libdir],
2337     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2338         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2339     [D3D_DRIVER_INSTALL_DIR="$withval"],
2340     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2341 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2342
2343 dnl
2344 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2345 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2346 dnl architectures.
2347 dnl
2348 r300_require_llvm() {
2349     case "$host" in *gnux32) return;; esac
2350     case "$host_cpu" in
2351     i*86|x86_64|amd64) require_llvm $1
2352         ;;
2353     esac
2354 }
2355
2356 dnl
2357 dnl DRM is needed by X, Wayland, and offscreen rendering.
2358 dnl Surfaceless is an alternative for the last one.
2359 dnl
2360 require_basic_egl() {
2361     case "$with_platforms" in
2362         *drm*|*surfaceless*)
2363             ;;
2364         *)
2365             AC_MSG_ERROR([$1 requires one of these:
2366                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2367                   2) --with-platforms=surfaceless (offscreen only)
2368                   Recommended options: drm,x11])
2369             ;;
2370     esac
2371 }
2372
2373 swr_require_cxx_feature_flags() {
2374     feature_name="$1"
2375     preprocessor_test="$2"
2376     option_list="$3"
2377     output_var="$4"
2378
2379     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2380     AC_LANG_PUSH([C++])
2381     save_CXXFLAGS="$CXXFLAGS"
2382     save_IFS="$IFS"
2383     IFS=","
2384     found=0
2385     for opts in $option_list
2386     do
2387         unset IFS
2388         CXXFLAGS="$opts $save_CXXFLAGS"
2389         AC_COMPILE_IFELSE(
2390             [AC_LANG_PROGRAM(
2391                 [   #if !($preprocessor_test)
2392                     #error
2393                     #endif
2394                 ])],
2395             [found=1; break],
2396             [])
2397         IFS=","
2398     done
2399     IFS="$save_IFS"
2400     CXXFLAGS="$save_CXXFLAGS"
2401     AC_LANG_POP([C++])
2402     if test $found -eq 1; then
2403         AC_MSG_RESULT([$opts])
2404         eval "$output_var=\$opts"
2405         return 0
2406     fi
2407     AC_MSG_RESULT([no])
2408     AC_MSG_ERROR([swr requires $feature_name support])
2409     return 1
2410 }
2411
2412 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2413 if test -n "$with_gallium_drivers"; then
2414     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2415     for driver in $gallium_drivers; do
2416         case "x$driver" in
2417         xsvga)
2418             HAVE_GALLIUM_SVGA=yes
2419             require_libdrm "svga"
2420             ;;
2421         xi915)
2422             HAVE_GALLIUM_I915=yes
2423             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2424             require_libdrm "Gallium i915"
2425             ;;
2426         xr300)
2427             HAVE_GALLIUM_R300=yes
2428             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2429             require_libdrm "r300"
2430             r300_require_llvm "r300"
2431             ;;
2432         xr600)
2433             HAVE_GALLIUM_R600=yes
2434             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2435             require_libdrm "r600"
2436             if test "x$enable_llvm" = xyes; then
2437                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2438
2439                 llvm_add_component "asmparser" "r600"
2440                 llvm_add_component "bitreader" "r600"
2441             fi
2442             ;;
2443         xradeonsi)
2444             HAVE_GALLIUM_RADEONSI=yes
2445             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2446             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2447             require_libdrm "radeonsi"
2448             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2449             if test "x$enable_egl" = xyes; then
2450                 require_basic_egl "radeonsi"
2451             fi
2452             ;;
2453         xnouveau)
2454             HAVE_GALLIUM_NOUVEAU=yes
2455             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2456             require_libdrm "nouveau"
2457             ;;
2458         xfreedreno)
2459             HAVE_GALLIUM_FREEDRENO=yes
2460             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2461             require_libdrm "freedreno"
2462             ;;
2463         xetnaviv)
2464             HAVE_GALLIUM_ETNAVIV=yes
2465             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2466             require_libdrm "etnaviv"
2467             ;;
2468        ximx)
2469             HAVE_GALLIUM_IMX=yes
2470             ;;
2471         xswrast)
2472             HAVE_GALLIUM_SOFTPIPE=yes
2473             if test "x$enable_llvm" = xyes; then
2474                 HAVE_GALLIUM_LLVMPIPE=yes
2475             fi
2476             ;;
2477         xswr)
2478             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2479
2480             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2481                 ",-std=c++11" \
2482                 SWR_CXX11_CXXFLAGS
2483             AC_SUBST([SWR_CXX11_CXXFLAGS])
2484
2485             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2486                 ",-mavx,-march=core-avx" \
2487                 SWR_AVX_CXXFLAGS
2488             AC_SUBST([SWR_AVX_CXXFLAGS])
2489
2490             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2491                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2492                 SWR_AVX2_CXXFLAGS
2493             AC_SUBST([SWR_AVX2_CXXFLAGS])
2494
2495             HAVE_GALLIUM_SWR=yes
2496             ;;
2497         xvc4)
2498             HAVE_GALLIUM_VC4=yes
2499             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2500             require_libdrm "vc4"
2501
2502             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2503                               [USE_VC4_SIMULATOR=yes;
2504                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2505                               [USE_VC4_SIMULATOR=no])
2506             ;;
2507         xpl111)
2508             HAVE_GALLIUM_PL111=yes
2509             ;;
2510         xvirgl)
2511             HAVE_GALLIUM_VIRGL=yes
2512             require_libdrm "virgl"
2513             if test "x$enable_egl" = xyes; then
2514                 require_basic_egl "virgl"
2515             fi
2516             ;;
2517         *)
2518             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2519             ;;
2520         esac
2521     done
2522 fi
2523
2524 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2525 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2526                                               "x$LLVM_VERSION" != x3.9.1)
2527
2528 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2529     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2530     llvm_add_default_components "gallium"
2531 fi
2532
2533 dnl We need to validate some needed dependencies for renderonly drivers.
2534
2535 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2536     AC_MSG_ERROR([Building with imx requires etnaviv])
2537 fi
2538
2539 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2540     AC_MSG_ERROR([Building with pl111 requires vc4])
2541 fi
2542
2543 dnl
2544 dnl Set defines and buildtime variables only when using LLVM.
2545 dnl
2546 if test "x$enable_llvm" = xyes; then
2547     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2548
2549     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2550     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2551     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2552
2553     dnl Set LLVM_LIBS - This is done after the driver configuration so
2554     dnl that drivers can add additional components to LLVM_COMPONENTS.
2555     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2556     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2557     dnl this was causing the same libraries to be appear multiple times
2558     dnl in LLVM_LIBS.
2559
2560     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2561        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2562     fi
2563     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2564
2565     dnl llvm-config may not give the right answer when llvm is a built as a
2566     dnl single shared library, so we must work the library name out for
2567     dnl ourselves.
2568     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2569     if test "x$enable_llvm_shared_libs" = xyes; then
2570         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2571         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2572         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2573
2574         if test "x$llvm_have_one_so" = xyes; then
2575             dnl LLVM was built using auto*, so there is only one shared object.
2576             LLVM_LIBS="-l$LLVM_SO_NAME"
2577         else
2578             dnl If LLVM was built with CMake, there will be one shared object per
2579             dnl component.
2580             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2581                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2582         Please make sure you have built llvm with the --enable-shared option
2583         and that your llvm libraries are installed in $LLVM_LIBDIR
2584         If you have installed your llvm libraries to a different directory you
2585         can use the --with-llvm-prefix= configure flag to specify this directory.
2586         NOTE: Mesa is attempting to use llvm shared libraries by default.
2587         If you do not want to build with llvm shared libraries and instead want to
2588         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2589         invocation and rebuild.])])
2590
2591            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2592            dnl install uses a shared object for each component and we have
2593            dnl already added all of these objects to LLVM_LIBS.
2594         fi
2595     else
2596         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2597         dnl We need to link to llvm system libs when using static libs
2598         dnl However, only llvm 3.5+ provides --system-libs
2599         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2600             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2601         fi
2602     fi
2603 fi
2604
2605 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2606 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2608 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2609 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2610 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2612                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2613 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2614 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2617 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2621                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2622                                          "x$HAVE_GALLIUM_SWR" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2625
2626 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2627
2628 if test "x$enable_dri" = xyes; then
2629     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2630 fi
2631
2632 if test "x$have_drisw_kms" = xyes; then
2633     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2634 fi
2635 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2636
2637 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2638 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2639 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2640 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2641 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2642 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2643
2644 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2645 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2646
2647 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2648                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2649                                       "x$HAVE_RADEON_VULKAN" = xyes)
2650
2651 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2652                                         "x$HAVE_I965_DRI" = xyes)
2653
2654 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2655                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2656                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2657 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2658 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2659 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2660 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2661
2662 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2663 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2664 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2665 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2666                                         "x$enable_gallium_osmesa" = xyes)
2667
2668 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2669 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2670 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2671
2672 AC_SUBST([NINE_MAJOR], 1)
2673 AC_SUBST([NINE_MINOR], 0)
2674 AC_SUBST([NINE_TINY], 0)
2675 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2676
2677 AC_SUBST([VDPAU_MAJOR], 1)
2678 AC_SUBST([VDPAU_MINOR], 0)
2679
2680 if test "x$enable_va" = xyes; then
2681     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2682     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2683 fi
2684 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2685 AC_SUBST([VA_MINOR], $VA_MINOR)
2686
2687 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2688
2689 AC_SUBST([XVMC_MAJOR], 1)
2690 AC_SUBST([XVMC_MINOR], 0)
2691
2692 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2693 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2694 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2695 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2696
2697 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2698 AC_SUBST([XA_MINOR], $XA_MINOR)
2699 AC_SUBST([XA_TINY], $XA_TINY)
2700 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2701
2702 AC_ARG_ENABLE(valgrind,
2703               [AS_HELP_STRING([--enable-valgrind],
2704                              [Build mesa with valgrind support (default: auto)])],
2705                              [VALGRIND=$enableval], [VALGRIND=auto])
2706 if test "x$VALGRIND" != xno; then
2707         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2708 fi
2709 AC_MSG_CHECKING([whether to enable Valgrind support])
2710 if test "x$VALGRIND" = xauto; then
2711         VALGRIND="$have_valgrind"
2712 fi
2713
2714 if test "x$VALGRIND" = "xyes"; then
2715         if ! test "x$have_valgrind" = xyes; then
2716                 AC_MSG_ERROR([Valgrind support required but not present])
2717         fi
2718         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2719 fi
2720
2721 AC_MSG_RESULT([$VALGRIND])
2722
2723 dnl Restore LDFLAGS and CPPFLAGS
2724 LDFLAGS="$_SAVE_LDFLAGS"
2725 CPPFLAGS="$_SAVE_CPPFLAGS"
2726
2727 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2728 if test "x$acv_mesa_CLANG" = xyes; then
2729     CFLAGS="$CFLAGS -Qunused-arguments"
2730     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2731 fi
2732
2733 dnl Add user CFLAGS and CXXFLAGS
2734 CFLAGS="$CFLAGS $USER_CFLAGS"
2735 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2736
2737 dnl Substitute the config
2738 AC_CONFIG_FILES([Makefile
2739                 src/Makefile
2740                 src/amd/Makefile
2741                 src/amd/vulkan/Makefile
2742                 src/compiler/Makefile
2743                 src/egl/Makefile
2744                 src/egl/main/egl.pc
2745                 src/egl/wayland/wayland-drm/Makefile
2746                 src/egl/wayland/wayland-egl/Makefile
2747                 src/egl/wayland/wayland-egl/wayland-egl.pc
2748                 src/gallium/Makefile
2749                 src/gallium/auxiliary/Makefile
2750                 src/gallium/auxiliary/pipe-loader/Makefile
2751                 src/gallium/drivers/freedreno/Makefile
2752                 src/gallium/drivers/ddebug/Makefile
2753                 src/gallium/drivers/i915/Makefile
2754                 src/gallium/drivers/llvmpipe/Makefile
2755                 src/gallium/drivers/noop/Makefile
2756                 src/gallium/drivers/nouveau/Makefile
2757                 src/gallium/drivers/pl111/Makefile
2758                 src/gallium/drivers/r300/Makefile
2759                 src/gallium/drivers/r600/Makefile
2760                 src/gallium/drivers/radeon/Makefile
2761                 src/gallium/drivers/radeonsi/Makefile
2762                 src/gallium/drivers/rbug/Makefile
2763                 src/gallium/drivers/softpipe/Makefile
2764                 src/gallium/drivers/svga/Makefile
2765                 src/gallium/drivers/swr/Makefile
2766                 src/gallium/drivers/trace/Makefile
2767                 src/gallium/drivers/etnaviv/Makefile
2768                 src/gallium/drivers/imx/Makefile
2769                 src/gallium/drivers/vc4/Makefile
2770                 src/gallium/drivers/virgl/Makefile
2771                 src/gallium/state_trackers/clover/Makefile
2772                 src/gallium/state_trackers/dri/Makefile
2773                 src/gallium/state_trackers/glx/xlib/Makefile
2774                 src/gallium/state_trackers/nine/Makefile
2775                 src/gallium/state_trackers/omx/Makefile
2776                 src/gallium/state_trackers/osmesa/Makefile
2777                 src/gallium/state_trackers/va/Makefile
2778                 src/gallium/state_trackers/vdpau/Makefile
2779                 src/gallium/state_trackers/xa/Makefile
2780                 src/gallium/state_trackers/xvmc/Makefile
2781                 src/gallium/targets/d3dadapter9/Makefile
2782                 src/gallium/targets/d3dadapter9/d3d.pc
2783                 src/gallium/targets/dri/Makefile
2784                 src/gallium/targets/libgl-xlib/Makefile
2785                 src/gallium/targets/omx/Makefile
2786                 src/gallium/targets/opencl/Makefile
2787                 src/gallium/targets/opencl/mesa.icd
2788                 src/gallium/targets/osmesa/Makefile
2789                 src/gallium/targets/osmesa/osmesa.pc
2790                 src/gallium/targets/pipe-loader/Makefile
2791                 src/gallium/targets/va/Makefile
2792                 src/gallium/targets/vdpau/Makefile
2793                 src/gallium/targets/xa/Makefile
2794                 src/gallium/targets/xa/xatracker.pc
2795                 src/gallium/targets/xvmc/Makefile
2796                 src/gallium/tests/trivial/Makefile
2797                 src/gallium/tests/unit/Makefile
2798                 src/gallium/winsys/etnaviv/drm/Makefile
2799                 src/gallium/winsys/imx/drm/Makefile
2800                 src/gallium/winsys/freedreno/drm/Makefile
2801                 src/gallium/winsys/i915/drm/Makefile
2802                 src/gallium/winsys/nouveau/drm/Makefile
2803                 src/gallium/winsys/pl111/drm/Makefile
2804                 src/gallium/winsys/radeon/drm/Makefile
2805                 src/gallium/winsys/amdgpu/drm/Makefile
2806                 src/gallium/winsys/svga/drm/Makefile
2807                 src/gallium/winsys/sw/dri/Makefile
2808                 src/gallium/winsys/sw/kms-dri/Makefile
2809                 src/gallium/winsys/sw/null/Makefile
2810                 src/gallium/winsys/sw/wrapper/Makefile
2811                 src/gallium/winsys/sw/xlib/Makefile
2812                 src/gallium/winsys/vc4/drm/Makefile
2813                 src/gallium/winsys/virgl/drm/Makefile
2814                 src/gallium/winsys/virgl/vtest/Makefile
2815                 src/gbm/Makefile
2816                 src/gbm/main/gbm.pc
2817                 src/glx/Makefile
2818                 src/glx/apple/Makefile
2819                 src/glx/tests/Makefile
2820                 src/glx/windows/Makefile
2821                 src/glx/windows/windowsdriproto.pc
2822                 src/gtest/Makefile
2823                 src/intel/Makefile
2824                 src/loader/Makefile
2825                 src/mapi/Makefile
2826                 src/mapi/es1api/glesv1_cm.pc
2827                 src/mapi/es2api/glesv2.pc
2828                 src/mapi/glapi/gen/Makefile
2829                 src/mesa/Makefile
2830                 src/mesa/gl.pc
2831                 src/mesa/drivers/dri/dri.pc
2832                 src/mesa/drivers/dri/common/Makefile
2833                 src/mesa/drivers/dri/common/xmlpool/Makefile
2834                 src/mesa/drivers/dri/i915/Makefile
2835                 src/mesa/drivers/dri/i965/Makefile
2836                 src/mesa/drivers/dri/Makefile
2837                 src/mesa/drivers/dri/nouveau/Makefile
2838                 src/mesa/drivers/dri/r200/Makefile
2839                 src/mesa/drivers/dri/radeon/Makefile
2840                 src/mesa/drivers/dri/swrast/Makefile
2841                 src/mesa/drivers/osmesa/Makefile
2842                 src/mesa/drivers/osmesa/osmesa.pc
2843                 src/mesa/drivers/x11/Makefile
2844                 src/mesa/main/tests/Makefile
2845                 src/util/Makefile
2846                 src/util/tests/hash_table/Makefile
2847                 src/vulkan/Makefile])
2848
2849 AC_OUTPUT
2850
2851 # Fix up dependencies in *.Plo files, where we changed the extension of a
2852 # source file
2853 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2854
2855
2856 dnl
2857 dnl Output some configuration info for the user
2858 dnl
2859 echo ""
2860 echo "        prefix:          $prefix"
2861 echo "        exec_prefix:     $exec_prefix"
2862 echo "        libdir:          $libdir"
2863 echo "        includedir:      $includedir"
2864
2865 dnl API info
2866 echo ""
2867 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2868
2869 dnl Driver info
2870 echo ""
2871 case "x$enable_osmesa$enable_gallium_osmesa" in
2872 xnoyes)
2873         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2874         ;;
2875 xyesno)
2876         echo "        OSMesa:          lib$OSMESA_LIB"
2877         ;;
2878 xnono)
2879         echo "        OSMesa:          no"
2880         ;;
2881 esac
2882
2883 echo ""
2884 if test "x$enable_dri" != xno; then
2885         echo "        DRI platform:    $dri_platform"
2886         if test -z "$DRI_DIRS"; then
2887             echo "        DRI drivers:     no"
2888         else
2889             echo "        DRI drivers:     $DRI_DIRS"
2890         fi
2891         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2892 fi
2893
2894 case "x$enable_glx" in
2895 xdri)
2896     echo "        GLX:             DRI-based"
2897     ;;
2898 xxlib)
2899     echo "        GLX:             Xlib-based"
2900     ;;
2901 xgallium-xlib)
2902     echo "        GLX:             Xlib-based (Gallium)"
2903     ;;
2904 *)
2905     echo "        GLX:             $enable_glx"
2906     ;;
2907 esac
2908
2909 dnl EGL
2910 echo ""
2911 echo "        EGL:             $enable_egl"
2912 if test "$enable_egl" = yes; then
2913
2914     egl_drivers=""
2915     if test "x$enable_dri" != "xno"; then
2916         egl_drivers="$egl_drivers builtin:egl_dri2"
2917     fi
2918     if test "x$enable_dri3" != "xno"; then
2919         egl_drivers="$egl_drivers builtin:egl_dri3"
2920     fi
2921
2922     echo "        EGL drivers:    $egl_drivers"
2923 fi
2924 if test "x$enable_gbm" = xyes; then
2925     echo "        GBM:             yes"
2926 else
2927     echo "        GBM:             no"
2928 fi
2929
2930     echo "        EGL/Vulkan/VL platforms:   $platforms"
2931
2932 # Vulkan
2933 echo ""
2934 if test "x$VULKAN_DRIVERS" != x; then
2935     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2936     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2937 else
2938     echo "        Vulkan drivers:  no"
2939 fi
2940
2941 echo ""
2942 if test "x$enable_llvm" = xyes; then
2943     echo "        llvm:            yes"
2944     echo "        llvm-config:     $LLVM_CONFIG"
2945     echo "        llvm-version:    $LLVM_VERSION"
2946 else
2947     echo "        llvm:            no"
2948 fi
2949
2950 echo ""
2951 if test -n "$with_gallium_drivers"; then
2952     echo "        Gallium drivers: $gallium_drivers"
2953     echo "        Gallium st:      $gallium_st"
2954 else
2955     echo "        Gallium:         no"
2956 fi
2957
2958 echo ""
2959 if test "x$enable_gallium_extra_hud" != xyes; then
2960     echo "        HUD extra stats: no"
2961 else
2962     echo "        HUD extra stats: yes"
2963 fi
2964
2965 if test "x$enable_lmsensors" != xyes; then
2966     echo "        HUD lmsensors:   no"
2967 else
2968     echo "        HUD lmsensors:   yes"
2969 fi
2970
2971 dnl Libraries
2972 echo ""
2973 echo "        Shared libs:     $enable_shared"
2974 echo "        Static libs:     $enable_static"
2975 echo "        Shared-glapi:    $enable_shared_glapi"
2976
2977 dnl Compiler options
2978 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2979 cflags=`echo $CFLAGS | \
2980     $SED 's/^ *//;s/  */ /;s/ *$//'`
2981 cxxflags=`echo $CXXFLAGS | \
2982     $SED 's/^ *//;s/  */ /;s/ *$//'`
2983 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2984 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2985 echo ""
2986 echo "        CFLAGS:          $cflags"
2987 echo "        CXXFLAGS:        $cxxflags"
2988 echo "        LDFLAGS:         $ldflags"
2989 echo "        Macros:          $defines"
2990 echo ""
2991 if test "x$enable_llvm" = xyes; then
2992     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2993     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2994     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2995     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2996     echo ""
2997 fi
2998 echo "        PYTHON2:         $PYTHON2"
2999
3000 echo ""
3001 echo "        Run '${MAKE-make}' to build Mesa"
3002 echo ""