configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282
 283 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 284 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 285 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 286 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 287 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 288 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 289
 290 AC_SUBST([GL_LIB_NAME])
 291 AC_SUBST([GLU_LIB_NAME])
 292 AC_SUBST([GLUT_LIB_NAME])
 293 AC_SUBST([GLW_LIB_NAME])
 294 AC_SUBST([OSMESA_LIB_NAME])
 295 AC_SUBST([EGL_LIB_NAME])
 296
 297 AC_SUBST([GL_LIB_GLOB])
 298 AC_SUBST([GLU_LIB_GLOB])
 299 AC_SUBST([GLUT_LIB_GLOB])
 300 AC_SUBST([GLW_LIB_GLOB])
 301 AC_SUBST([OSMESA_LIB_GLOB])
 302 AC_SUBST([EGL_LIB_GLOB])
 303
 304 dnl
 305 dnl Arch/platform-specific settings
 306 dnl
 307 AC_ARG_ENABLE([asm],
 308     [AS_HELP_STRING([--disable-asm],
 309         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 310     [enable_asm="$enableval"],
 311     [enable_asm=yes]
 312 )
 313 asm_arch=""
 314 ASM_FLAGS=""
 315 MESA_ASM_SOURCES=""
 316 GLAPI_ASM_SOURCES=""
 317 AC_MSG_CHECKING([whether to enable assembly])
 318 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 319 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 320 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 321     case "$host_cpu" in
 322     i?86 | x86_64)
 323         enable_asm=no
 324         AC_MSG_RESULT([no, cross compiling])
 325         ;;
 326     esac
 327 fi
 328 # check for supported arches
 329 if test "x$enable_asm" = xyes; then
 330     case "$host_cpu" in
 331     i?86)
 332         case "$host_os" in
 333         linux* | *freebsd* | dragonfly*)
 334             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 335             ;;
 336         esac
 337         ;;
 338     x86_64)
 339         case "$host_os" in
 340         linux* | *freebsd* | dragonfly*)
 341             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 342             ;;
 343         esac
 344         ;;
 345     powerpc)
 346         case "$host_os" in
 347         linux*)
 348             asm_arch=ppc
 349             ;;
 350         esac
 351         ;;
 352     sparc*)
 353         case "$host_os" in
 354         linux*)
 355             asm_arch=sparc
 356             ;;
 357         esac
 358         ;;
 359     esac
 360
 361     case "$asm_arch" in
 362     x86)
 363         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 364         MESA_ASM_SOURCES='$(X86_SOURCES)'
 365         GLAPI_ASM_SOURCES='$(X86_API)'
 366         AC_MSG_RESULT([yes, x86])
 367         ;;
 368     x86_64)
 369         ASM_FLAGS="-DUSE_X86_64_ASM"
 370         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 371         GLAPI_ASM_SOURCES='$(X86-64_API)'
 372         AC_MSG_RESULT([yes, x86_64])
 373         ;;
 374     ppc)
 375         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 376         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 377         AC_MSG_RESULT([yes, ppc])
 378         ;;
 379     sparc)
 380         ASM_FLAGS="-DUSE_SPARC_ASM"
 381         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 382         GLAPI_ASM_SOURCES='$(SPARC_API)'
 383         AC_MSG_RESULT([yes, sparc])
 384         ;;
 385     *)
 386         AC_MSG_RESULT([no, platform not supported])
 387         ;;
 388     esac
 389 fi
 390 AC_SUBST([ASM_FLAGS])
 391 AC_SUBST([MESA_ASM_SOURCES])
 392 AC_SUBST([GLAPI_ASM_SOURCES])
 393
 394 dnl PIC code macro
 395 MESA_PIC_FLAGS
 396
 397 dnl Check to see if dlopen is in default libraries (like Solaris, which
 398 dnl has it in libc), or if libdl is needed to get it.
 399 AC_CHECK_FUNC([dlopen], [],
 400     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 401
 402 dnl See if posix_memalign is available
 403 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 404
 405 dnl SELinux awareness.
 406 AC_ARG_ENABLE([selinux],
 407     [AS_HELP_STRING([--enable-selinux],
 408         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 409     [MESA_SELINUX="$enableval"],
 410     [MESA_SELINUX=no])
 411 if test "x$enable_selinux" = "xyes"; then
 412     AC_CHECK_HEADER([selinux/selinux.h],[],
 413                     [AC_MSG_ERROR([SELinux headers not found])])
 414     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 415                  [AC_MSG_ERROR([SELinux library not found])])
 416     SELINUX_LIBS="-lselinux"
 417     DEFINES="$DEFINES -DMESA_SELINUX"
 418 fi
 419
 420 dnl
 421 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 422 dnl More later: fbdev, ...
 423 dnl
 424 default_driver="xlib"
 425
 426 case "$host_os" in
 427 linux*)
 428     case "$host_cpu" in
 429     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 430     esac
 431     ;;
 432 *freebsd* | dragonfly*)
 433     case "$host_cpu" in
 434     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 435     esac
 436     ;;
 437 esac
 438
 439 AC_ARG_WITH([driver],
 440     [AS_HELP_STRING([--with-driver=DRIVER],
 441         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 442     [mesa_driver="$withval"],
 443     [mesa_driver="$default_driver"])
 444 dnl Check for valid option
 445 case "x$mesa_driver" in
 446 xxlib|xdri|xosmesa)
 447     ;;
 448 *)
 449     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 450     ;;
 451 esac
 452
 453 dnl
 454 dnl Driver specific build directories
 455 dnl
 456
 457 dnl this variable will be prepended to SRC_DIRS and is not exported
 458 CORE_DIRS="glsl mesa"
 459
 460 SRC_DIRS="glew"
 461 GLU_DIRS="sgi"
 462 GALLIUM_DIRS="auxiliary drivers state_trackers"
 463 GALLIUM_TARGET_DIRS=""
 464 GALLIUM_WINSYS_DIRS=""
 465 GALLIUM_WINSYS_DRM_DIRS=""
 466 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 467 GALLIUM_STATE_TRACKERS_DIRS=""
 468
 469 case "$mesa_driver" in
 470 xlib)
 471     DRIVER_DIRS="x11"
 472     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 473     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 474     ;;
 475 dri)
 476     SRC_DIRS="$SRC_DIRS glx"
 477     DRIVER_DIRS="dri"
 478     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib drm"
 479     ;;
 480 osmesa)
 481     DRIVER_DIRS="osmesa"
 482     ;;
 483 esac
 484 AC_SUBST([SRC_DIRS])
 485 AC_SUBST([GLU_DIRS])
 486 AC_SUBST([DRIVER_DIRS])
 487 AC_SUBST([GALLIUM_DIRS])
 488 AC_SUBST([GALLIUM_TARGET_DIRS])
 489 AC_SUBST([GALLIUM_WINSYS_DIRS])
 490 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 491 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 492 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 493
 494 dnl
 495 dnl User supplied program configuration
 496 dnl
 497 if test -d "$srcdir/progs/demos"; then
 498     default_demos=yes
 499 else
 500     default_demos=no
 501 fi
 502 AC_ARG_WITH([demos],
 503     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 504         [optional comma delimited demo directories to build
 505         @<:@default=auto if source available@:>@])],
 506     [with_demos="$withval"],
 507     [with_demos="$default_demos"])
 508 if test "x$with_demos" = x; then
 509     with_demos=no
 510 fi
 511
 512 dnl If $with_demos is yes, directories will be added as libs available
 513 PROGRAM_DIRS=""
 514 case "$with_demos" in
 515 no) ;;
 516 yes)
 517     # If the driver isn't osmesa, we have libGL and can build xdemos
 518     if test "$mesa_driver" != osmesa; then
 519         PROGRAM_DIRS="xdemos"
 520     fi
 521     ;;
 522 *)
 523     # verify the requested demos directories exist
 524     demos=`IFS=,; echo $with_demos`
 525     for demo in $demos; do
 526         test -d "$srcdir/progs/$demo" || \
 527             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 528     done
 529     PROGRAM_DIRS="$demos"
 530     ;;
 531 esac
 532
 533 dnl
 534 dnl Find out if X is available. The variable have_x is set if libX11 is
 535 dnl found to mimic AC_PATH_XTRA.
 536 dnl
 537 if test -n "$PKG_CONFIG"; then
 538     AC_MSG_CHECKING([pkg-config files for X11 are available])
 539     PKG_CHECK_EXISTS([x11],[
 540         x11_pkgconfig=yes
 541         have_x=yes
 542         ],[
 543         x11_pkgconfig=no
 544     ])
 545     AC_MSG_RESULT([$x11_pkgconfig])
 546 else
 547     x11_pkgconfig=no
 548 fi
 549 dnl Use the autoconf macro if no pkg-config files
 550 if test "$x11_pkgconfig" = yes; then
 551     PKG_CHECK_MODULES([X11], [x11])
 552 else
 553     AC_PATH_XTRA
 554     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 555     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 556     AC_SUBST([X11_CFLAGS])
 557     AC_SUBST([X11_LIBS])
 558 fi
 559
 560 dnl Try to tell the user that the --x-* options are only used when
 561 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 562 m4_divert_once([HELP_BEGIN],
 563 [These options are only used when the X libraries cannot be found by the
 564 pkg-config utility.])
 565
 566 dnl We need X for xlib and dri, so bomb now if it's not found
 567 case "$mesa_driver" in
 568 xlib|dri)
 569     if test "$no_x" = yes; then
 570         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 571     fi
 572     ;;
 573 esac
 574
 575 dnl XCB - this is only used for GLX right now
 576 AC_ARG_ENABLE([xcb],
 577     [AS_HELP_STRING([--enable-xcb],
 578         [use XCB for GLX @<:@default=disabled@:>@])],
 579     [enable_xcb="$enableval"],
 580     [enable_xcb=no])
 581 if test "x$enable_xcb" = xyes; then
 582     DEFINES="$DEFINES -DUSE_XCB"
 583 else
 584     enable_xcb=no
 585 fi
 586
 587 dnl
 588 dnl libGL configuration per driver
 589 dnl
 590 case "$mesa_driver" in
 591 xlib)
 592     if test "$x11_pkgconfig" = yes; then
 593         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 594         GL_PC_REQ_PRIV="x11 xext"
 595         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 596         GL_LIB_DEPS="$XLIBGL_LIBS"
 597     else
 598         # should check these...
 599         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 600         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 601         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 602         GL_PC_CFLAGS="$X11_INCLUDES"
 603     fi
 604     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 605     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 606
 607     # if static, move the external libraries to the programs
 608     # and empty the libraries for libGL
 609     if test "$enable_static" = yes; then
 610         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 611         GL_LIB_DEPS=""
 612     fi
 613     ;;
 614 dri)
 615     # DRI must be shared, I think
 616     if test "$enable_static" = yes; then
 617         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 618     fi
 619
 620     # Check for libdrm
 621     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 622     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 623     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 624     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 625     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 626
 627     # find the DRI deps for libGL
 628     if test "$x11_pkgconfig" = yes; then
 629         # add xcb modules if necessary
 630         dri_modules="x11 xext xxf86vm xdamage xfixes"
 631         if test "$enable_xcb" = yes; then
 632             dri_modules="$dri_modules x11-xcb xcb-glx"
 633         fi
 634
 635         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 636         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 637         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 638         GL_LIB_DEPS="$DRIGL_LIBS"
 639     else
 640         # should check these...
 641         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 642         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 643         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 644         GL_PC_CFLAGS="$X11_INCLUDES"
 645
 646         # XCB can only be used from pkg-config
 647         if test "$enable_xcb" = yes; then
 648             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 649             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 650             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 651             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 652         fi
 653     fi
 654
 655     # need DRM libs, -lpthread, etc.
 656     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 657     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 658     ;;
 659 osmesa)
 660     # No libGL for osmesa
 661     GL_LIB_DEPS=""
 662     ;;
 663 esac
 664 AC_SUBST([GL_LIB_DEPS])
 665 AC_SUBST([GL_PC_REQ_PRIV])
 666 AC_SUBST([GL_PC_LIB_PRIV])
 667 AC_SUBST([GL_PC_CFLAGS])
 668 AC_SUBST([DRI_PC_REQ_PRIV])
 669
 670 dnl
 671 dnl More X11 setup
 672 dnl
 673 if test "$mesa_driver" = xlib; then
 674     DEFINES="$DEFINES -DUSE_XSHM"
 675 fi
 676
 677 dnl
 678 dnl More DRI setup
 679 dnl
 680 AC_ARG_ENABLE([glx-tls],
 681     [AS_HELP_STRING([--enable-glx-tls],
 682         [enable TLS support in GLX @<:@default=disabled@:>@])],
 683     [GLX_USE_TLS="$enableval"],
 684     [GLX_USE_TLS=no])
 685 dnl Directory for DRI drivers
 686 AC_ARG_WITH([dri-driverdir],
 687     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 688         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 689     [DRI_DRIVER_INSTALL_DIR="$withval"],
 690     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 691 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 692 dnl Extra search path for DRI drivers
 693 AC_ARG_WITH([dri-searchpath],
 694     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 695         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 696     [DRI_DRIVER_SEARCH_DIR="$withval"],
 697     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 698 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 699 dnl Direct rendering or just indirect rendering
 700 AC_ARG_ENABLE([driglx-direct],
 701     [AS_HELP_STRING([--disable-driglx-direct],
 702         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 703     [driglx_direct="$enableval"],
 704     [driglx_direct="yes"])
 705 dnl Which drivers to build - default is chosen by platform
 706 AC_ARG_WITH([dri-drivers],
 707     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 708         [comma delimited DRI drivers list, e.g.
 709         "swrast,i965,radeon" @<:@default=auto@:>@])],
 710     [with_dri_drivers="$withval"],
 711     [with_dri_drivers=yes])
 712 if test "x$with_dri_drivers" = x; then
 713     with_dri_drivers=no
 714 fi
 715
 716 dnl If $with_dri_drivers is yes, directories will be added through
 717 dnl platform checks
 718 DRI_DIRS=""
 719 case "$with_dri_drivers" in
 720 no) ;;
 721 yes)
 722     DRI_DIRS="yes"
 723     ;;
 724 *)
 725     # verify the requested driver directories exist
 726     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 727     for driver in $dri_drivers; do
 728         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 729             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 730     done
 731     DRI_DIRS="$dri_drivers"
 732     ;;
 733 esac
 734
 735 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 736 if test "$mesa_driver" = dri; then
 737     # Use TLS in GLX?
 738     if test "x$GLX_USE_TLS" = xyes; then
 739         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 740     fi
 741
 742     # Platform specific settings and drivers to build
 743     case "$host_os" in
 744     linux*)
 745         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 746         if test "x$driglx_direct" = xyes; then
 747             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 748         fi
 749         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 750
 751         case "$host_cpu" in
 752         x86_64)
 753             # sis is missing because they have not be converted to use
 754             # the new interface.  i810 are missing because there is no
 755             # x86-64 system where they could *ever* be used.
 756             if test "x$DRI_DIRS" = "xyes"; then
 757                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 758                     savage tdfx unichrome swrast"
 759             fi
 760             ;;
 761         powerpc*)
 762             # Build only the drivers for cards that exist on PowerPC.
 763             # At some point MGA will be added, but not yet.
 764             if test "x$DRI_DIRS" = "xyes"; then
 765                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 766             fi
 767             ;;
 768         sparc*)
 769             # Build only the drivers for cards that exist on sparc`
 770             if test "x$DRI_DIRS" = "xyes"; then
 771                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 772             fi
 773             ;;
 774         esac
 775         ;;
 776     freebsd* | dragonfly*)
 777         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 778         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 779         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 780         if test "x$driglx_direct" = xyes; then
 781             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 782         fi
 783         if test "x$GXX" = xyes; then
 784             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 785         fi
 786
 787         if test "x$DRI_DIRS" = "xyes"; then
 788             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 789                 unichrome savage sis swrast"
 790         fi
 791         ;;
 792     gnu*)
 793         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 794         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 795         ;;
 796     solaris*)
 797         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 798         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 799         if test "x$driglx_direct" = xyes; then
 800             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 801         fi
 802         ;;
 803     esac
 804
 805     # default drivers
 806     if test "x$DRI_DIRS" = "xyes"; then
 807         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 808             savage sis tdfx unichrome swrast"
 809     fi
 810
 811     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 812
 813     # Check for expat
 814     EXPAT_INCLUDES=""
 815     EXPAT_LIB=-lexpat
 816     AC_ARG_WITH([expat],
 817         [AS_HELP_STRING([--with-expat=DIR],
 818             [expat install directory])],[
 819         EXPAT_INCLUDES="-I$withval/include"
 820         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 821         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 822         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 823         ])
 824     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 825     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 826         [AC_MSG_ERROR([Expat required for DRI.])])
 827
 828     # put all the necessary libs together
 829     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 830 fi
 831 AC_SUBST([DRI_DIRS])
 832 AC_SUBST([EXPAT_INCLUDES])
 833 AC_SUBST([DRI_LIB_DEPS])
 834
 835 case $DRI_DIRS in
 836 *i915*|*i965*)
 837     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 838     ;;
 839 esac
 840
 841 case $DRI_DIRS in
 842 *radeon*|*r200*|*r300*|*r600*)
 843     PKG_CHECK_MODULES([LIBDRM_RADEON],
 844                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 845                       HAVE_LIBDRM_RADEON=yes,
 846                       HAVE_LIBDRM_RADEON=no)
 847
 848     if test "$HAVE_LIBDRM_RADEON" = yes; then
 849         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 850         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 851     fi
 852     ;;
 853 esac
 854 AC_SUBST([RADEON_CFLAGS])
 855 AC_SUBST([RADEON_LDFLAGS])
 856
 857
 858 dnl
 859 dnl OSMesa configuration
 860 dnl
 861 if test "$mesa_driver" = xlib; then
 862     default_gl_osmesa=yes
 863 else
 864     default_gl_osmesa=no
 865 fi
 866 AC_ARG_ENABLE([gl-osmesa],
 867     [AS_HELP_STRING([--enable-gl-osmesa],
 868         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 869     [gl_osmesa="$enableval"],
 870     [gl_osmesa="$default_gl_osmesa"])
 871 if test "x$gl_osmesa" = xyes; then
 872     if test "$mesa_driver" = osmesa; then
 873         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 874     else
 875         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 876     fi
 877 fi
 878
 879 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 880 AC_ARG_WITH([osmesa-bits],
 881     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 882         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 883     [osmesa_bits="$withval"],
 884     [osmesa_bits=8])
 885 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 886     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 887     osmesa_bits=8
 888 fi
 889 case "x$osmesa_bits" in
 890 x8)
 891     OSMESA_LIB=OSMesa
 892     ;;
 893 x16|x32)
 894     OSMESA_LIB="OSMesa$osmesa_bits"
 895     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 896     ;;
 897 *)
 898     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 899     ;;
 900 esac
 901 AC_SUBST([OSMESA_LIB])
 902
 903 case "$mesa_driver" in
 904 osmesa)
 905     # only link libraries with osmesa if shared
 906     if test "$enable_static" = no; then
 907         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 908     else
 909         OSMESA_LIB_DEPS=""
 910     fi
 911     OSMESA_MESA_DEPS=""
 912     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 913     ;;
 914 *)
 915     # Link OSMesa to libGL otherwise
 916     OSMESA_LIB_DEPS=""
 917     # only link libraries with osmesa if shared
 918     if test "$enable_static" = no; then
 919         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 920     else
 921         OSMESA_MESA_DEPS=""
 922     fi
 923     OSMESA_PC_REQ="gl"
 924     ;;
 925 esac
 926 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 927 AC_SUBST([OSMESA_LIB_DEPS])
 928 AC_SUBST([OSMESA_MESA_DEPS])
 929 AC_SUBST([OSMESA_PC_REQ])
 930 AC_SUBST([OSMESA_PC_LIB_PRIV])
 931
 932 dnl
 933 dnl EGL configuration
 934 dnl
 935 AC_ARG_ENABLE([egl],
 936     [AS_HELP_STRING([--disable-egl],
 937         [disable EGL library @<:@default=enabled@:>@])],
 938     [enable_egl="$enableval"],
 939     [enable_egl=yes])
 940 if test "x$enable_egl" = xyes; then
 941     SRC_DIRS="$SRC_DIRS egl"
 942     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 943     EGL_DRIVERS_DIRS=""
 944     if test "$enable_static" != yes; then
 945         # build egl_glx when libGL is built
 946         if test "$mesa_driver" != osmesa; then
 947             EGL_DRIVERS_DIRS="glx"
 948         fi
 949
 950         # build egl_dri2 when xcb-dri2 is available
 951         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
 952                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 953         if test "$have_xcb_dri2" = yes; then
 954             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
 955         fi
 956     fi
 957
 958     if test "$with_demos" = yes; then
 959         PROGRAM_DIRS="$PROGRAM_DIRS egl"
 960     fi
 961 fi
 962 AC_SUBST([EGL_LIB_DEPS])
 963 AC_SUBST([EGL_DRIVERS_DIRS])
 964
 965 dnl
 966 dnl GLU configuration
 967 dnl
 968 AC_ARG_ENABLE([glu],
 969     [AS_HELP_STRING([--disable-glu],
 970         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 971     [enable_glu="$enableval"],
 972     [enable_glu=yes])
 973 if test "x$enable_glu" = xyes; then
 974     SRC_DIRS="$SRC_DIRS glu"
 975
 976     case "$mesa_driver" in
 977     osmesa)
 978         # If GLU is available and we have libOSMesa (not 16 or 32),
 979         # we can build the osdemos
 980         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 981             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 982         fi
 983
 984         # Link libGLU to libOSMesa instead of libGL
 985         GLU_LIB_DEPS=""
 986         GLU_PC_REQ="osmesa"
 987         if test "$enable_static" = no; then
 988             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 989         else
 990             GLU_MESA_DEPS=""
 991         fi
 992         ;;
 993     *)
 994         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 995         GLU_PC_REQ="gl"
 996         GLU_PC_LIB_PRIV="-lm"
 997         if test "$enable_static" = no; then
 998             GLU_LIB_DEPS="-lm"
 999             GLU_MESA_DEPS='-l$(GL_LIB)'
1000         else
1001             GLU_LIB_DEPS=""
1002             GLU_MESA_DEPS=""
1003             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1004         fi
1005         ;;
1006     esac
1007 fi
1008 if test "$enable_static" = no; then
1009     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1010 fi
1011 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1012 AC_SUBST([GLU_LIB_DEPS])
1013 AC_SUBST([GLU_MESA_DEPS])
1014 AC_SUBST([GLU_PC_REQ])
1015 AC_SUBST([GLU_PC_REQ_PRIV])
1016 AC_SUBST([GLU_PC_LIB_PRIV])
1017 AC_SUBST([GLU_PC_CFLAGS])
1018
1019 dnl
1020 dnl GLw configuration
1021 dnl
1022 AC_ARG_ENABLE([glw],
1023     [AS_HELP_STRING([--disable-glw],
1024         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1025     [enable_glw="$enableval"],
1026     [enable_glw=yes])
1027 dnl Don't build GLw on osmesa
1028 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1029     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1030     enable_glw=no
1031 fi
1032 AC_ARG_ENABLE([motif],
1033     [AS_HELP_STRING([--enable-motif],
1034         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1035     [enable_motif="$enableval"],
1036     [enable_motif=no])
1037
1038 if test "x$enable_glw" = xyes; then
1039     SRC_DIRS="$SRC_DIRS glw"
1040     if test "$x11_pkgconfig" = yes; then
1041         PKG_CHECK_MODULES([GLW],[x11 xt])
1042         GLW_PC_REQ_PRIV="x11 xt"
1043         GLW_LIB_DEPS="$GLW_LIBS"
1044     else
1045         # should check these...
1046         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1047         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1048         GLW_PC_CFLAGS="$X11_INCLUDES"
1049     fi
1050
1051     GLW_SOURCES="GLwDrawA.c"
1052     MOTIF_CFLAGS=
1053     if test "x$enable_motif" = xyes; then
1054         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1055         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1056         if test "x$MOTIF_CONFIG" != xno; then
1057             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1058             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1059         else
1060             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1061                 [AC_MSG_ERROR([Can't locate Motif headers])])
1062             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1063                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1064         fi
1065         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1066         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1067         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1068         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1069     fi
1070
1071     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1072     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1073     if test "$enable_static" = no; then
1074         GLW_MESA_DEPS='-l$(GL_LIB)'
1075         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1076     else
1077         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1078         GLW_LIB_DEPS=""
1079         GLW_MESA_DEPS=""
1080     fi
1081 fi
1082 AC_SUBST([GLW_LIB_DEPS])
1083 AC_SUBST([GLW_MESA_DEPS])
1084 AC_SUBST([GLW_SOURCES])
1085 AC_SUBST([MOTIF_CFLAGS])
1086 AC_SUBST([GLW_PC_REQ_PRIV])
1087 AC_SUBST([GLW_PC_LIB_PRIV])
1088 AC_SUBST([GLW_PC_CFLAGS])
1089
1090 dnl
1091 dnl GLUT configuration
1092 dnl
1093 if test -f "$srcdir/include/GL/glut.h"; then
1094     default_glut=yes
1095 else
1096     default_glut=no
1097 fi
1098 AC_ARG_ENABLE([glut],
1099     [AS_HELP_STRING([--disable-glut],
1100         [enable GLUT library @<:@default=enabled if source available@:>@])],
1101     [enable_glut="$enableval"],
1102     [enable_glut="$default_glut"])
1103
1104 dnl Can't build glut if GLU not available
1105 if test "x$enable_glu$enable_glut" = xnoyes; then
1106     AC_MSG_WARN([Disabling glut since GLU is disabled])
1107     enable_glut=no
1108 fi
1109 dnl Don't build glut on osmesa
1110 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1111     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1112     enable_glut=no
1113 fi
1114
1115 if test "x$enable_glut" = xyes; then
1116     SRC_DIRS="$SRC_DIRS glut/glx"
1117     GLUT_CFLAGS=""
1118     if test "x$GCC" = xyes; then
1119         GLUT_CFLAGS="-fexceptions"
1120     fi
1121     if test "$x11_pkgconfig" = yes; then
1122         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1123         GLUT_PC_REQ_PRIV="x11 xmu xi"
1124         GLUT_LIB_DEPS="$GLUT_LIBS"
1125     else
1126         # should check these...
1127         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1128         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1129         GLUT_PC_CFLAGS="$X11_INCLUDES"
1130     fi
1131     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1132     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1133
1134     # If glut is available, we can build most programs
1135     if test "$with_demos" = yes; then
1136         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1137     fi
1138
1139     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1140     if test "$enable_static" = no; then
1141         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1142     else
1143         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1144         GLUT_LIB_DEPS=""
1145         GLUT_MESA_DEPS=""
1146     fi
1147 fi
1148 AC_SUBST([GLUT_LIB_DEPS])
1149 AC_SUBST([GLUT_MESA_DEPS])
1150 AC_SUBST([GLUT_CFLAGS])
1151 AC_SUBST([GLUT_PC_REQ_PRIV])
1152 AC_SUBST([GLUT_PC_LIB_PRIV])
1153 AC_SUBST([GLUT_PC_CFLAGS])
1154
1155 dnl
1156 dnl Program library dependencies
1157 dnl    Only libm is added here if necessary as the libraries should
1158 dnl    be pulled in by the linker
1159 dnl
1160 if test "x$APP_LIB_DEPS" = x; then
1161     case "$host_os" in
1162     solaris*)
1163         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1164         ;;
1165     cygwin*)
1166         APP_LIB_DEPS="-lX11"
1167         ;;
1168     *)
1169         APP_LIB_DEPS="-lm"
1170         ;;
1171     esac
1172 fi
1173 AC_SUBST([APP_LIB_DEPS])
1174 AC_SUBST([PROGRAM_DIRS])
1175
1176 dnl
1177 dnl Gallium configuration
1178 dnl
1179 AC_ARG_ENABLE([gallium],
1180     [AS_HELP_STRING([--disable-gallium],
1181         [build gallium @<:@default=enabled@:>@])],
1182     [enable_gallium="$enableval"],
1183     [enable_gallium=yes])
1184 if test "x$enable_gallium" = xyes; then
1185     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1186 fi
1187
1188 dnl
1189 dnl Gallium state trackers configuration
1190 dnl
1191 AC_ARG_WITH([state-trackers],
1192     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1193         [comma delimited state_trackers list, e.g.
1194         "egl,glx" @<:@default=auto@:>@])],
1195     [with_state_trackers="$withval"],
1196     [with_state_trackers=yes])
1197
1198 case "$with_state_trackers" in
1199 no)
1200     GALLIUM_STATE_TRACKERS_DIRS=""
1201     ;;
1202 yes)
1203     # look at what else is built
1204     case "$mesa_driver" in
1205     xlib)
1206         GALLIUM_STATE_TRACKERS_DIRS=glx
1207         ;;
1208     dri)
1209         GALLIUM_STATE_TRACKERS_DIRS="dri"
1210         if test "x$enable_egl" = xyes; then
1211             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1212         fi
1213         # Have only tested st/xorg on 1.6.0 servers
1214         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1215             HAVE_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1216             HAVE_XORG="no")
1217         ;;
1218     esac
1219     ;;
1220 *)
1221     # verify the requested state tracker exist
1222     state_trackers=`IFS=', '; echo $with_state_trackers`
1223     for tracker in $state_trackers; do
1224         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1225             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1226
1227         case "$tracker" in
1228         egl)
1229             if test "x$enable_egl" != xyes; then
1230                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1231             fi
1232             ;;
1233         xorg)
1234             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1235             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1236             HAVE_XORG="yes"
1237             ;;
1238         es)
1239             # mesa/es is required to build es state tracker
1240             CORE_DIRS="$CORE_DIRS mesa/es"
1241             ;;
1242         esac
1243     done
1244     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1245     ;;
1246 esac
1247
1248 if test "x$HAVE_XORG" = xyes; then
1249     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1250         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1251         HAVE_XEXTPROTO_71="no")
1252 fi
1253
1254 AC_ARG_WITH([egl-displays],
1255     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1256         [comma delimited native displays libEGL supports, e.g.
1257         "x11,kms" @<:@default=auto@:>@])],
1258     [with_egl_displays="$withval"],
1259     [with_egl_displays=yes])
1260
1261 EGL_DISPLAYS=""
1262 case "$with_egl_displays" in
1263 yes)
1264     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1265         EGL_DISPLAYS="x11"
1266     fi
1267     ;;
1268 *)
1269     if test "x$enable_egl" != xyes; then
1270         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1271     fi
1272     # verify the requested driver directories exist
1273     egl_displays=`IFS=', '; echo $with_egl_displays`
1274     for dpy in $egl_displays; do
1275         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1276             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1277     done
1278     EGL_DISPLAYS="$egl_displays"
1279     ;;
1280 esac
1281 AC_SUBST([EGL_DISPLAYS])
1282
1283 AC_ARG_WITH([egl-driver-dir],
1284     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1285                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1286     [EGL_DRIVER_INSTALL_DIR="$withval"],
1287     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1288 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1289
1290 AC_ARG_WITH([xorg-driver-dir],
1291     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1292                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1293     [XORG_DRIVER_INSTALL_DIR="$withval"],
1294     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1295 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1296
1297 AC_ARG_WITH([max-width],
1298     [AS_HELP_STRING([--with-max-width=N],
1299                     [Maximum framebuffer width (4096)])],
1300     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1301      AS_IF([test "${withval}" -gt "4096"],
1302            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1303 )
1304 AC_ARG_WITH([max-height],
1305     [AS_HELP_STRING([--with-max-height=N],
1306                     [Maximum framebuffer height (4096)])],
1307     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1308      AS_IF([test "${withval}" -gt "4096"],
1309            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1310 )
1311
1312 dnl
1313 dnl Gallium SVGA configuration
1314 dnl
1315 AC_ARG_ENABLE([gallium-svga],
1316     [AS_HELP_STRING([--enable-gallium-svga],
1317         [build gallium SVGA @<:@default=disabled@:>@])],
1318     [enable_gallium_svga="$enableval"],
1319     [enable_gallium_svga=auto])
1320 if test "x$enable_gallium_svga" = xyes; then
1321     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS vmware"
1322     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1323 elif test "x$enable_gallium_svga" = xauto; then
1324     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1325 fi
1326
1327 dnl
1328 dnl Gallium Intel configuration
1329 dnl
1330 AC_ARG_ENABLE([gallium-intel],
1331     [AS_HELP_STRING([--enable-gallium-intel],
1332         [build gallium intel @<:@default=disabled@:>@])],
1333     [enable_gallium_intel="$enableval"],
1334     [enable_gallium_intel=auto])
1335 if test "x$enable_gallium_intel" = xyes; then
1336     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel i965"
1337     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1338 elif test "x$enable_gallium_intel" = xauto; then
1339     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1340 fi
1341
1342 dnl
1343 dnl Gallium Radeon configuration
1344 dnl
1345 AC_ARG_ENABLE([gallium-radeon],
1346     [AS_HELP_STRING([--enable-gallium-radeon],
1347         [build gallium radeon @<:@default=disabled@:>@])],
1348     [enable_gallium_radeon="$enableval"],
1349     [enable_gallium_radeon=auto])
1350 if test "x$enable_gallium_radeon" = xyes; then
1351     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1352     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1353 elif test "x$enable_gallium_radeon" = xauto; then
1354     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1355 fi
1356
1357 dnl
1358 dnl Gallium Nouveau configuration
1359 dnl
1360 AC_ARG_ENABLE([gallium-nouveau],
1361     [AS_HELP_STRING([--enable-gallium-nouveau],
1362         [build gallium nouveau @<:@default=disabled@:>@])],
1363     [enable_gallium_nouveau="$enableval"],
1364     [enable_gallium_nouveau=no])
1365 if test "x$enable_gallium_nouveau" = xyes; then
1366     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1367     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1368 fi
1369
1370 dnl
1371 dnl Gallium swrast configuration
1372 dnl
1373 AC_ARG_ENABLE([gallium-swrast],
1374     [AS_HELP_STRING([--enable-gallium-swrast],
1375         [build gallium swrast @<:@default=disabled@:>@])],
1376     [enable_gallium_swrast="$enableval"],
1377     [enable_gallium_swrast=auto])
1378 if test "x$enable_gallium_swrast" = xyes; then
1379     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS swrast"
1380 fi
1381
1382 dnl prepend CORE_DIRS to SRC_DIRS
1383 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1384
1385 dnl Restore LDFLAGS and CPPFLAGS
1386 LDFLAGS="$_SAVE_LDFLAGS"
1387 CPPFLAGS="$_SAVE_CPPFLAGS"
1388
1389 dnl Substitute the config
1390 AC_CONFIG_FILES([configs/autoconf])
1391
1392 dnl Replace the configs/current symlink
1393 AC_CONFIG_COMMANDS([configs],[
1394 if test -f configs/current || test -L configs/current; then
1395     rm -f configs/current
1396 fi
1397 ln -s autoconf configs/current
1398 ])
1399
1400 AC_OUTPUT
1401
1402 dnl
1403 dnl Output some configuration info for the user
1404 dnl
1405 echo ""
1406 echo "        prefix:          $prefix"
1407 echo "        exec_prefix:     $exec_prefix"
1408 echo "        libdir:          $libdir"
1409 echo "        includedir:      $includedir"
1410
1411 dnl Driver info
1412 echo ""
1413 echo "        Driver:          $mesa_driver"
1414 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1415     echo "        OSMesa:          lib$OSMESA_LIB"
1416 else
1417     echo "        OSMesa:          no"
1418 fi
1419 if test "$mesa_driver" = dri; then
1420     # cleanup the drivers var
1421     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1422 if test "x$DRI_DIRS" = x; then
1423     echo "        DRI drivers:     no"
1424 else
1425     echo "        DRI drivers:     $dri_dirs"
1426 fi
1427     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1428 fi
1429 echo "        Use XCB:         $enable_xcb"
1430
1431 echo ""
1432 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1433     echo "        Gallium:         yes"
1434     echo "        Gallium dirs:    $GALLIUM_DIRS"
1435     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1436     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1437     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1438     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1439     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1440 else
1441     echo "        Gallium:         no"
1442 fi
1443
1444 dnl Libraries
1445 echo ""
1446 echo "        Shared libs:     $enable_shared"
1447 echo "        Static libs:     $enable_static"
1448 if test "$enable_egl" = yes; then
1449     echo "        EGL:             $EGL_DRIVERS_DIRS"
1450 else
1451     echo "        EGL:             no"
1452 fi
1453 echo "        GLU:             $enable_glu"
1454 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1455 echo "        glut:            $enable_glut"
1456
1457 dnl Programs
1458 # cleanup the programs var for display
1459 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1460 if test "x$program_dirs" = x; then
1461     echo "        Demos:           no"
1462 else
1463     echo "        Demos:           $program_dirs"
1464 fi
1465
1466 dnl Compiler options
1467 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1468 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1469     $SED 's/^ *//;s/  */ /;s/ *$//'`
1470 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1471     $SED 's/^ *//;s/  */ /;s/ *$//'`
1472 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1473 echo ""
1474 echo "        CFLAGS:          $cflags"
1475 echo "        CXXFLAGS:        $cxxflags"
1476 echo "        Macros:          $defines"
1477
1478 echo ""
1479 echo "        Run '${MAKE-make}' to build Mesa"
1480 echo ""