configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.79
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.8
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 842 dnl project. Even then there's a notable issue as described in the project README
 843 case "$host_os" in
 844 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 845     pthread_stubs_possible="no"
 846     ;;
 847 * )
 848     pthread_stubs_possible="yes"
 849     ;;
 850 esac
 851
 852 if test "x$pthread_stubs_possible" = xyes; then
 853     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 854     AC_SUBST(PTHREADSTUBS_CFLAGS)
 855     AC_SUBST(PTHREADSTUBS_LIBS)
 856 fi
 857
 858 dnl SELinux awareness.
 859 AC_ARG_ENABLE([selinux],
 860     [AS_HELP_STRING([--enable-selinux],
 861         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 862     [MESA_SELINUX="$enableval"],
 863     [MESA_SELINUX=no])
 864 if test "x$enable_selinux" = "xyes"; then
 865     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 866         [AC_CHECK_HEADER([selinux/selinux.h],[],
 867                          [AC_MSG_ERROR([SELinux headers not found])])
 868          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 869                       [AC_MSG_ERROR([SELinux library not found])])
 870          SELINUX_LIBS="-lselinux"])
 871     DEFINES="$DEFINES -DMESA_SELINUX"
 872 fi
 873 AC_SUBST([SELINUX_CFLAGS])
 874 AC_SUBST([SELINUX_LIBS])
 875
 876 dnl
 877 dnl LLVM
 878 dnl
 879 AC_ARG_ENABLE([llvm-shared-libs],
 880     [AS_HELP_STRING([--enable-llvm-shared-libs],
 881         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 882     [enable_llvm_shared_libs="$enableval"],
 883     [enable_llvm_shared_libs=yes])
 884
 885 AC_ARG_WITH([llvm-prefix],
 886     [AS_HELP_STRING([--with-llvm-prefix],
 887         [Prefix for LLVM installations in non-standard locations])],
 888     [llvm_prefix="$withval"],
 889     [llvm_prefix=''])
 890
 891 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 892 if test "x$have_libelf" = xno; then
 893    LIBELF_LIBS=''
 894    LIBELF_CFLAGS=''
 895    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 896    AC_SUBST([LIBELF_LIBS])
 897    AC_SUBST([LIBELF_CFLAGS])
 898 fi
 899
 900 if test -z "$LLVM_CONFIG"; then
 901     if test -n "$llvm_prefix"; then
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 903     else
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 905     fi
 906 fi
 907
 908 llvm_add_component() {
 909     new_llvm_component=$1
 910     driver_name=$2
 911
 912     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 913         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 914     else
 915         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 916     fi
 917 }
 918
 919 llvm_add_default_components() {
 920     driver_name=$1
 921
 922     # Required default components
 923     llvm_add_component "bitwriter" $driver_name
 924     llvm_add_component "engine" $driver_name
 925     llvm_add_component "mcdisassembler" $driver_name
 926     llvm_add_component "mcjit" $driver_name
 927
 928     # Optional default components
 929     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 930         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 931     fi
 932 }
 933
 934 llvm_add_target() {
 935     new_llvm_target=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 939         llvm_add_component $new_llvm_target $driver_name
 940     else
 941         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 # Call this inside ` ` to get the return value.
 946 # $1 is the llvm-config command with arguments.
 947 strip_unwanted_llvm_flags() {
 948     echo " `$1` " | sed -E \
 949         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 950         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 951         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 952         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 954         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 956         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 957         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 958         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 959         -e 's/^[[[:space:]]]//' \
 960         -e 's/[[[:space:]]]$//'
 961 }
 962
 963 llvm_set_environment_variables() {
 964     if test "x$LLVM_CONFIG" != xno; then
 965         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 966         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 967         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 968         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 969
 970         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 971         save_CFLAGS="$CFLAGS"
 972         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 973
 974         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 975             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 976         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980
 981         CFLAGS="$save_CFLAGS"
 982
 983         # Only needed for LLVM < 3.6.0
 984         if test -z "$LLVM_VERSION_PATCH"; then
 985             LLVM_VERSION_PATCH=0
 986         fi
 987
 988         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 989
 990         FOUND_LLVM=yes
 991     else
 992         FOUND_LLVM=no
 993         LLVM_VERSION_INT=0
 994     fi
 995 }
 996
 997 require_llvm() {
 998     if test "x$enable_llvm" != "xyes"; then
 999         AC_MSG_ERROR([--enable-llvm is required when building $1])
1000     fi
1001 }
1002
1003 llvm_require_version() {
1004     require_llvm $2
1005
1006     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1007     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1008     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1009
1010     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1011         # major > required major
1012         #  --> OK
1013         return
1014     fi
1015
1016     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1017         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1018             # major = required major and
1019             # minor > required minor
1020             #  --> OK
1021             return
1022         else
1023             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1024                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1025                     # major = required major and
1026                     # minor = required minor and
1027                     # patch >= required patch
1028                     #  --> OK
1029                     return
1030                 fi
1031             fi
1032         fi
1033     fi
1034
1035     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1036 }
1037
1038 radeon_llvm_check() {
1039     if test ${LLVM_VERSION_INT} -lt 307; then
1040         amdgpu_llvm_target_name='r600'
1041     else
1042         amdgpu_llvm_target_name='amdgpu'
1043     fi
1044
1045     llvm_require_version $*
1046
1047     llvm_add_target $amdgpu_llvm_target_name $2
1048
1049     llvm_add_default_components $2
1050     llvm_add_component "bitreader" $2
1051     llvm_add_component "ipo" $2
1052
1053     if test "x$have_libelf" != xyes; then
1054        AC_MSG_ERROR([$2 requires libelf when using llvm])
1055     fi
1056 }
1057
1058 llvm_set_environment_variables
1059
1060 AC_SUBST([LLVM_CFLAGS])
1061 AC_SUBST([LLVM_CXXFLAGS])
1062 AC_SUBST([LLVM_LIBS])
1063 AC_SUBST([LLVM_LDFLAGS])
1064 AC_SUBST([LLVM_INCLUDEDIR])
1065
1066 dnl
1067 dnl libunwind
1068 dnl
1069 AC_ARG_ENABLE([libunwind],
1070     [AS_HELP_STRING([--enable-libunwind],
1071             [Use libunwind for backtracing (default: auto)])],
1072         [LIBUNWIND="$enableval"],
1073         [LIBUNWIND="auto"])
1074
1075 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1076 if test "x$LIBUNWIND" = "xauto"; then
1077     LIBUNWIND="$HAVE_LIBUNWIND"
1078 fi
1079
1080 if test "x$LIBUNWIND" = "xyes"; then
1081     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1082     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1083 fi
1084
1085
1086 dnl Options for APIs
1087 AC_ARG_ENABLE([opengl],
1088     [AS_HELP_STRING([--disable-opengl],
1089         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1090     [enable_opengl="$enableval"],
1091     [enable_opengl=yes])
1092 AC_ARG_ENABLE([gles1],
1093     [AS_HELP_STRING([--disable-gles1],
1094         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1095     [enable_gles1="$enableval"],
1096     [enable_gles1=yes])
1097 AC_ARG_ENABLE([gles2],
1098     [AS_HELP_STRING([--disable-gles2],
1099         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1100     [enable_gles2="$enableval"],
1101     [enable_gles2=yes])
1102
1103 AC_ARG_ENABLE([dri],
1104     [AS_HELP_STRING([--enable-dri],
1105         [enable DRI modules @<:@default=enabled@:>@])],
1106     [enable_dri="$enableval"],
1107     [enable_dri=yes])
1108
1109 AC_ARG_ENABLE([gallium-extra-hud],
1110     [AS_HELP_STRING([--enable-gallium-extra-hud],
1111         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1112     [enable_gallium_extra_hud="$enableval"],
1113     [enable_gallium_extra_hud=no])
1114 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1115 if test "x$enable_gallium_extra_hud" = xyes ; then
1116     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1117 fi
1118
1119 #TODO: no pkgconfig .pc available for libsensors.
1120 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1121 AC_ARG_ENABLE([lmsensors],
1122     [AS_HELP_STRING([--enable-lmsensors],
1123         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1124     [enable_lmsensors="$enableval"],
1125     [enable_lmsensors=no])
1126 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1127 if test "x$enable_lmsensors" = xyes ; then
1128     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1129     LIBSENSORS_LIBS="-lsensors"
1130 else
1131     LIBSENSORS_LIBS=""
1132 fi
1133 AC_SUBST(LIBSENSORS_LIBS)
1134
1135 case "$host_os" in
1136 linux*)
1137     dri3_default=yes
1138     ;;
1139 *)
1140     dri3_default=no
1141     ;;
1142 esac
1143
1144 if test "x$enable_dri" = xno; then
1145     dri3_default=no
1146 fi
1147
1148 AC_ARG_ENABLE([dri3],
1149     [AS_HELP_STRING([--enable-dri3],
1150         [enable DRI3 @<:@default=auto@:>@])],
1151     [enable_dri3="$enableval"],
1152     [enable_dri3="$dri3_default"])
1153 AC_ARG_ENABLE([glx],
1154     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1155         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1156     [enable_glx="$enableval"],
1157     [enable_glx=yes])
1158 AC_ARG_ENABLE([osmesa],
1159     [AS_HELP_STRING([--enable-osmesa],
1160         [enable OSMesa library @<:@default=disabled@:>@])],
1161     [enable_osmesa="$enableval"],
1162     [enable_osmesa=no])
1163 AC_ARG_ENABLE([gallium-osmesa],
1164     [AS_HELP_STRING([--enable-gallium-osmesa],
1165         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1166     [enable_gallium_osmesa="$enableval"],
1167     [enable_gallium_osmesa=no])
1168 AC_ARG_ENABLE([egl],
1169     [AS_HELP_STRING([--disable-egl],
1170         [disable EGL library @<:@default=enabled@:>@])],
1171     [enable_egl="$enableval"],
1172     [enable_egl=yes])
1173
1174 AC_ARG_ENABLE([xa],
1175     [AS_HELP_STRING([--enable-xa],
1176         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1177     [enable_xa="$enableval"],
1178     [enable_xa=no])
1179 AC_ARG_ENABLE([gbm],
1180    [AS_HELP_STRING([--enable-gbm],
1181          [enable gbm library @<:@default=yes except cygwin@:>@])],
1182    [enable_gbm="$enableval"],
1183    [case "$host_os" in
1184        cygwin*)
1185           enable_gbm=no
1186           ;;
1187        *)
1188           enable_gbm=yes
1189           ;;
1190     esac])
1191 AC_ARG_ENABLE([nine],
1192     [AS_HELP_STRING([--enable-nine],
1193         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1194     [enable_nine="$enableval"],
1195     [enable_nine=no])
1196
1197 AC_ARG_ENABLE([xvmc],
1198    [AS_HELP_STRING([--enable-xvmc],
1199          [enable xvmc library @<:@default=auto@:>@])],
1200    [enable_xvmc="$enableval"],
1201    [enable_xvmc=auto])
1202 AC_ARG_ENABLE([vdpau],
1203    [AS_HELP_STRING([--enable-vdpau],
1204          [enable vdpau library @<:@default=auto@:>@])],
1205    [enable_vdpau="$enableval"],
1206    [enable_vdpau=auto])
1207 AC_ARG_ENABLE([omx],
1208    [AS_HELP_STRING([--enable-omx],
1209          [enable OpenMAX library @<:@default=disabled@:>@])],
1210    [enable_omx="$enableval"],
1211    [enable_omx=no])
1212 AC_ARG_ENABLE([va],
1213    [AS_HELP_STRING([--enable-va],
1214          [enable va library @<:@default=auto@:>@])],
1215    [enable_va="$enableval"],
1216    [enable_va=auto])
1217 AC_ARG_ENABLE([opencl],
1218    [AS_HELP_STRING([--enable-opencl],
1219          [enable OpenCL library @<:@default=disabled@:>@])],
1220    [enable_opencl="$enableval"],
1221    [enable_opencl=no])
1222 AC_ARG_ENABLE([opencl_icd],
1223    [AS_HELP_STRING([--enable-opencl-icd],
1224           [Build an OpenCL ICD library to be loaded by an ICD implementation
1225            @<:@default=disabled@:>@])],
1226     [enable_opencl_icd="$enableval"],
1227     [enable_opencl_icd=no])
1228
1229 AC_ARG_ENABLE([gallium-tests],
1230     [AS_HELP_STRING([--enable-gallium-tests],
1231         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1232     [enable_gallium_tests="$enableval"],
1233     [enable_gallium_tests=no])
1234
1235 # Option for Gallium drivers
1236
1237 # Keep this in sync with the --with-gallium-drivers help string default value
1238 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1239
1240 AC_ARG_WITH([gallium-drivers],
1241     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1242         [comma delimited Gallium drivers list, e.g.
1243         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1244         @<:@default=r300,r600,svga,swrast@:>@])],
1245     [with_gallium_drivers="$withval"],
1246     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1247
1248 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1249 # here so that the script doesn't choke on an unknown driver name later.
1250 case "$with_gallium_drivers" in
1251     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1252     no) with_gallium_drivers='' ;;
1253 esac
1254
1255 if test "x$enable_opengl" = xno -a \
1256         "x$enable_gles1" = xno -a \
1257         "x$enable_gles2" = xno -a \
1258         "x$enable_nine" = xno -a \
1259         "x$enable_xa" = xno -a \
1260         "x$enable_xvmc" = xno -a \
1261         "x$enable_vdpau" = xno -a \
1262         "x$enable_omx" = xno -a \
1263         "x$enable_va" = xno -a \
1264         "x$enable_opencl" = xno; then
1265     AC_MSG_ERROR([at least one API should be enabled])
1266 fi
1267
1268 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1269 if test "x$enable_opengl" = xno -a \
1270         "x$enable_gles1" = xyes; then
1271     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1272 fi
1273
1274 if test "x$enable_opengl" = xno -a \
1275         "x$enable_gles2" = xyes; then
1276     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1277 fi
1278
1279 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1280 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1282 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1283                                         "x$enable_gles1" = xyes -o \
1284                                         "x$enable_gles2" = xyes)
1285
1286 # Validate GLX options
1287 if test "x$enable_glx" = xyes; then
1288     if test "x$enable_dri" = xyes; then
1289         enable_glx=dri
1290     elif test -n "$with_gallium_drivers"; then
1291         enable_glx=gallium-xlib
1292     else
1293         enable_glx=xlib
1294     fi
1295 fi
1296 case "x$enable_glx" in
1297 xdri | xxlib | xgallium-xlib)
1298     # GLX requires OpenGL
1299     if test "x$enable_opengl" = xno; then
1300         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1301     fi
1302
1303     # Check individual dependencies
1304     case "x$enable_glx" in
1305     xdri)
1306         if test "x$enable_dri" = xno; then
1307             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1308         fi
1309         ;;
1310     xxlib)
1311         if test "x$enable_dri" = xyes; then
1312             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1313         fi
1314         ;;
1315     xgallium-xlib )
1316         if test "x$enable_dri" = xyes; then
1317             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1318         fi
1319         if test -z "$with_gallium_drivers"; then
1320             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1321         fi
1322         ;;
1323     esac
1324     ;;
1325 xno)
1326     ;;
1327 *)
1328     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1329     ;;
1330 esac
1331
1332 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1333 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1334 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1335 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1336
1337 DEFAULT_GL_LIB_NAME=GL
1338
1339 dnl
1340 dnl Libglvnd configuration
1341 dnl
1342 AC_ARG_ENABLE([libglvnd],
1343     [AS_HELP_STRING([--enable-libglvnd],
1344         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1345     [enable_libglvnd="$enableval"],
1346     [enable_libglvnd=no])
1347 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1348
1349 if test "x$enable_libglvnd" = xyes ; then
1350     dnl XXX: update once we can handle more than libGL/glx.
1351     dnl Namely: we should error out if neither of the glvnd enabled libraries
1352     dnl are built
1353     case "x$enable_glx" in
1354     xno)
1355         AC_MSG_ERROR([cannot build libglvnd without GLX])
1356         ;;
1357     xxlib | xgallium-xlib )
1358         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1359         ;;
1360     xdri)
1361         ;;
1362     esac
1363
1364     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1365     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1366     AC_SUBST([LIBGLVND_DATADIR])
1367
1368     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1369     DEFAULT_GL_LIB_NAME=GLX_mesa
1370 fi
1371
1372 AC_ARG_WITH([gl-lib-name],
1373   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1374     [specify GL library name @<:@default=GL@:>@])],
1375   [GL_LIB=$withval],
1376   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1377 AC_ARG_WITH([osmesa-lib-name],
1378   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1379     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1380   [OSMESA_LIB=$withval],
1381   [OSMESA_LIB=OSMesa])
1382 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1383 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1384
1385 dnl
1386 dnl Mangled Mesa support
1387 dnl
1388 AC_ARG_ENABLE([mangling],
1389   [AS_HELP_STRING([--enable-mangling],
1390     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1391   [enable_mangling="${enableval}"],
1392   [enable_mangling=no]
1393 )
1394 if test "x${enable_mangling}" = "xyes" ; then
1395   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1396   GL_LIB="Mangled${GL_LIB}"
1397   OSMESA_LIB="Mangled${OSMESA_LIB}"
1398 fi
1399 AC_SUBST([GL_LIB])
1400 AC_SUBST([OSMESA_LIB])
1401
1402 # Check for libdrm
1403 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1404                   [have_libdrm=yes], [have_libdrm=no])
1405 if test "x$have_libdrm" = xyes; then
1406         DEFINES="$DEFINES -DHAVE_LIBDRM"
1407 fi
1408
1409 require_libdrm() {
1410     if test "x$have_libdrm" != xyes; then
1411        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1412     fi
1413 }
1414
1415
1416 # Select which platform-dependent DRI code gets built
1417 case "$host_os" in
1418 darwin*)
1419     dri_platform='apple' ;;
1420 cygwin*)
1421     dri_platform='windows' ;;
1422 gnu*)
1423     dri_platform='none' ;;
1424 *)
1425     dri_platform='drm' ;;
1426 esac
1427
1428 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1429     have_drisw_kms='yes'
1430 fi
1431
1432 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1433 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1434 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1435 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1436 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1437 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1438 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1439 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1440 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1441
1442 AC_ARG_ENABLE([shared-glapi],
1443     [AS_HELP_STRING([--enable-shared-glapi],
1444         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1445     [enable_shared_glapi="$enableval"],
1446     [enable_shared_glapi=yes])
1447
1448 case "x$enable_opengl$enable_gles1$enable_gles2" in
1449 x*yes*yes*)
1450     if test "x$enable_shared_glapi" = xno; then
1451         AC_MSG_ERROR([shared GLAPI required when building two or more of
1452                       the following APIs - opengl, gles1 gles2])
1453     fi
1454     ;;
1455 esac
1456
1457 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1458
1459 # Build the pipe-drivers as separate libraries/modules.
1460 # Do not touch this unless you know what you are doing.
1461 # XXX: Expose via configure option ?
1462 enable_shared_pipe_drivers=no
1463
1464 dnl
1465 dnl Driver specific build directories
1466 dnl
1467
1468 if test "x$enable_gallium_osmesa" = xyes; then
1469     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1470         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1471     fi
1472     if test "x$enable_osmesa" = xyes; then
1473         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1474     fi
1475 fi
1476
1477 require_dri_shared_libs_and_glapi() {
1478     if test "x$enable_static" = xyes; then
1479         AC_MSG_ERROR([$1 cannot be build as static library])
1480     fi
1481
1482     if test "x$enable_dri" != xyes; then
1483         # There is only a single backend which won't be build/used otherwise.
1484         # XXX: Revisit this as the egl/haiku is a thing.
1485         AC_MSG_ERROR([$1 requires --enable-dri])
1486     fi
1487
1488     if test "x$enable_shared_glapi" != xyes; then
1489         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1490     fi
1491 }
1492
1493 if test "x$enable_dri" = xyes; then
1494     require_dri_shared_libs_and_glapi "DRI"
1495
1496     # not a hard requirement as swrast does not depend on it
1497     if test "x$have_libdrm" = xyes; then
1498         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1499     fi
1500 fi
1501
1502 AC_ARG_ENABLE([driglx-direct],
1503     [AS_HELP_STRING([--disable-driglx-direct],
1504         [disable direct rendering in GLX and EGL for DRI \
1505             @<:@default=auto@:>@])],
1506     [driglx_direct="$enableval"],
1507     [driglx_direct="yes"])
1508
1509 dnl
1510 dnl libGL configuration per driver
1511 dnl
1512 if test "x$enable_glx" != xno; then
1513     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1514 fi
1515 case "x$enable_glx" in
1516 xxlib | xgallium-xlib)
1517     # Xlib-based GLX
1518     dri_modules="x11 xext xcb"
1519     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1520     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1521     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1522     GL_LIB_DEPS="$XLIBGL_LIBS"
1523     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1524     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1525     ;;
1526 xdri)
1527     # DRI-based GLX
1528
1529     # find the DRI deps for libGL
1530     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1531
1532     if test x"$driglx_direct" = xyes; then
1533         if test x"$dri_platform" = xdrm ; then
1534             DEFINES="$DEFINES -DGLX_USE_DRM"
1535             require_libdrm "Direct rendering"
1536
1537             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1538             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1539             if test x"$enable_dri" = xyes; then
1540                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1541             fi
1542
1543             if test x"$enable_dri3" = xyes; then
1544                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1545                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1546                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1547             fi
1548         fi
1549         if test x"$dri_platform" = xapple ; then
1550             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1551         fi
1552         if test x"$dri_platform" = xwindows ; then
1553             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1554         fi
1555     fi
1556
1557     # add xf86vidmode if available
1558     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1559     if test "$HAVE_XF86VIDMODE" = yes ; then
1560         dri_modules="$dri_modules xxf86vm"
1561     fi
1562
1563     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1564     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1565     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1566     GL_LIB_DEPS="$DRIGL_LIBS"
1567
1568     # need DRM libs, $PTHREAD_LIBS, etc.
1569     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1570     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1571     ;;
1572 esac
1573
1574 # This is outside the case (above) so that it is invoked even for non-GLX
1575 # builds.
1576 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1577
1578 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1579 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1580 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1581 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1582
1583 AC_SUBST([X11_INCLUDES])
1584 AC_SUBST([GL_LIB_DEPS])
1585 AC_SUBST([GL_PC_REQ_PRIV])
1586 AC_SUBST([GL_PC_LIB_PRIV])
1587 AC_SUBST([GL_PC_CFLAGS])
1588 AC_SUBST([DRI_PC_REQ_PRIV])
1589 AC_SUBST([GLESv1_CM_LIB_DEPS])
1590 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1591 AC_SUBST([GLESv2_LIB_DEPS])
1592 AC_SUBST([GLESv2_PC_LIB_PRIV])
1593
1594 AC_SUBST([HAVE_XF86VIDMODE])
1595
1596 dnl
1597 dnl More GLX setup
1598 dnl
1599 case "x$enable_glx" in
1600 xxlib | xgallium-xlib)
1601     DEFINES="$DEFINES -DUSE_XSHM"
1602     ;;
1603 xdri)
1604     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1605     if test "x$driglx_direct" = xyes; then
1606         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1607     fi
1608     ;;
1609 esac
1610
1611 dnl
1612 dnl TLS detection
1613 dnl
1614
1615 AC_ARG_ENABLE([glx-tls],
1616     [AS_HELP_STRING([--enable-glx-tls],
1617         [enable TLS support in GLX @<:@default=enabled@:>@])],
1618     [GLX_USE_TLS="$enableval"],
1619     [GLX_USE_TLS=yes])
1620 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1621
1622 if test "x$GLX_USE_TLS" = xyes; then
1623     DEFINES="$DEFINES -DGLX_USE_TLS"
1624 fi
1625
1626 dnl Read-only text section on x86 hardened platforms
1627 AC_ARG_ENABLE([glx-read-only-text],
1628     [AS_HELP_STRING([--enable-glx-read-only-text],
1629         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1630     [enable_glx_read_only_text="$enableval"],
1631     [enable_glx_read_only_text=no])
1632 if test "x$enable_glx_read_only_text" = xyes; then
1633     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1634 fi
1635
1636 dnl
1637 dnl DEPRECATED: EGL Platforms configuration
1638 dnl
1639 AC_ARG_WITH([egl-platforms],
1640     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1641         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1642     [with_egl_platforms="$withval"],
1643     [with_egl_platforms=auto])
1644
1645 if test "x$with_egl_platforms" = xauto; then
1646     if test "x$enable_gbm" = xyes; then
1647         with_egl_platforms="x11,drm"
1648     else
1649         with_egl_platforms="x11"
1650     fi
1651 else
1652     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1653 fi
1654
1655 dnl
1656 dnl Platforms configuration
1657 dnl
1658 AC_ARG_WITH([platforms],
1659     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1660         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1661         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1662     [with_platforms="$withval"],
1663     [with_platforms=auto])
1664
1665 # Reuse the autodetection rather than duplicating it.
1666 if test "x$with_platforms" = xauto; then
1667     with_platforms=$with_egl_platforms
1668 fi
1669
1670 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1671         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1672         WAYLAND_SCANNER='')
1673 if test "x$WAYLAND_SCANNER" = x; then
1674     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1675 fi
1676
1677 # Do per platform setups and checks
1678 platforms=`IFS=', '; echo $with_platforms`
1679 for plat in $platforms; do
1680         case "$plat" in
1681         wayland)
1682
1683                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1684
1685                 if test "x$WAYLAND_SCANNER" = "x:"; then
1686                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1687                 fi
1688                 ;;
1689
1690         x11)
1691                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1692                 ;;
1693
1694         drm)
1695                 test "x$enable_gbm" = "xno" &&
1696                         AC_MSG_ERROR([EGL platform drm needs gbm])
1697                 ;;
1698
1699         surfaceless)
1700                 ;;
1701
1702         android)
1703                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1704                 ;;
1705
1706         *)
1707                 AC_MSG_ERROR([platform '$plat' does not exist])
1708                 ;;
1709         esac
1710
1711         case "$plat" in
1712         wayland|drm|surfaceless)
1713                 require_libdrm "Platform $plat"
1714                 ;;
1715         esac
1716 done
1717
1718 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1719 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1720 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1721 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1722 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1723
1724 dnl
1725 dnl More DRI setup
1726 dnl
1727 dnl Directory for DRI drivers
1728 AC_ARG_WITH([dri-driverdir],
1729     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1730         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1731     [DRI_DRIVER_INSTALL_DIR="$withval"],
1732     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1733 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1734 dnl Extra search path for DRI drivers
1735 AC_ARG_WITH([dri-searchpath],
1736     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1737         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1738     [DRI_DRIVER_SEARCH_DIR="$withval"],
1739     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1740 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1741 dnl Which drivers to build - default is chosen by platform
1742 AC_ARG_WITH([dri-drivers],
1743     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1744         [comma delimited classic DRI drivers list, e.g.
1745         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1746     [with_dri_drivers="$withval"],
1747     [with_dri_drivers=auto])
1748
1749 if test "x$with_dri_drivers" = xauto; then
1750     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1751         with_dri_drivers="yes"
1752     else
1753         with_dri_drivers="no"
1754     fi
1755 fi
1756 if test "x$with_dri_drivers" = xno; then
1757     with_dri_drivers=''
1758 fi
1759
1760 dnl If $with_dri_drivers is yes, drivers will be added through
1761 dnl platform checks. Set DEFINES and LIB_DEPS
1762 if test "x$enable_dri" = xyes; then
1763     # Platform specific settings and drivers to build
1764     case "$host_os" in
1765     linux*)
1766         if test "x$enable_dri3" = xyes; then
1767             DEFINES="$DEFINES -DHAVE_DRI3"
1768         fi
1769
1770         case "$host_cpu" in
1771         powerpc* | sparc*)
1772             # Build only the drivers for cards that exist on PowerPC/sparc
1773             if test "x$with_dri_drivers" = "xyes"; then
1774                 with_dri_drivers="r200 radeon swrast"
1775             fi
1776             ;;
1777         esac
1778         ;;
1779     cygwin*)
1780         if test "x$with_dri_drivers" = "xyes"; then
1781             with_dri_drivers="swrast"
1782         fi
1783         ;;
1784     darwin*)
1785         DEFINES="$DEFINES -DBUILDING_MESA"
1786         if test "x$with_dri_drivers" = "xyes"; then
1787             with_dri_drivers="swrast"
1788         fi
1789         ;;
1790     esac
1791
1792     # default drivers
1793     if test "x$with_dri_drivers" = "xyes"; then
1794         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1795     fi
1796
1797     # Check for expat
1798     PKG_CHECK_MODULES([EXPAT], [expat], [],
1799         # expat version 2.0 and earlier do not provide expat.pc
1800         [AC_CHECK_HEADER([expat.h],[],
1801                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1802          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1803                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1804          EXPAT_LIBS="-lexpat"])
1805
1806     # put all the necessary libs together
1807     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1808 fi
1809
1810 AC_SUBST([DRI_LIB_DEPS])
1811
1812 DRI_DIRS=''
1813 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1814 if test -n "$with_dri_drivers"; then
1815     if test "x$enable_opengl" != xyes; then
1816         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1817     fi
1818
1819     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1820     for driver in $dri_drivers; do
1821         DRI_DIRS="$DRI_DIRS $driver"
1822         case "x$driver" in
1823         xi915)
1824             require_libdrm "i915"
1825             HAVE_I915_DRI=yes
1826             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1827             ;;
1828         xi965)
1829             require_libdrm "i965"
1830             HAVE_I965_DRI=yes
1831             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1832             ;;
1833         xnouveau)
1834             require_libdrm "nouveau"
1835             HAVE_NOUVEAU_DRI=yes
1836             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1837             ;;
1838         xradeon)
1839             require_libdrm "radeon"
1840             HAVE_RADEON_DRI=yes;
1841             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1842             ;;
1843         xr200)
1844             require_libdrm "r200"
1845             HAVE_R200_DRI=yes
1846             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1847             ;;
1848         xswrast)
1849             HAVE_SWRAST_DRI=yes
1850             ;;
1851         *)
1852             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1853             ;;
1854         esac
1855     done
1856     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1857 fi
1858
1859
1860 dnl
1861 dnl Gallium LLVM
1862 dnl Deprecated: kept for backwards compatibility
1863 dnl
1864 AC_ARG_ENABLE([gallium-llvm],
1865     [AS_HELP_STRING([--enable-gallium-llvm],
1866         [DEPRECATED: use --enable-llvm instead])],
1867     [enable_gallium_llvm="$enableval"],
1868     [enable_gallium_llvm=auto])
1869
1870 if test "x$enable_gallium_llvm" != xauto; then
1871    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1872    enable_llvm=$enable_gallium_llvm
1873 fi
1874
1875 dnl
1876 dnl LLVM
1877 dnl
1878 AC_ARG_ENABLE([llvm],
1879     [AS_HELP_STRING([--enable-llvm],
1880         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1881     [enable_llvm="$enableval"],
1882     [enable_llvm=auto])
1883
1884 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1885     if test "x$FOUND_LLVM" = xyes; then
1886         case "$host_cpu" in
1887         i*86|x86_64|amd64) enable_llvm=yes;;
1888         *) enable_llvm=no;;
1889         esac
1890     else
1891         enable_llvm=no
1892     fi
1893 fi
1894
1895 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1896     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1897 fi
1898
1899 #
1900 # Vulkan driver configuration
1901 #
1902
1903 AC_ARG_WITH([vulkan-drivers],
1904     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1905         [comma delimited Vulkan drivers list, e.g.
1906         "intel,radeon"
1907         @<:@default=no@:>@])],
1908     [with_vulkan_drivers="$withval"],
1909     [with_vulkan_drivers="no"])
1910
1911 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1912 # here so that the script doesn't choke on an unknown driver name later.
1913 case "x$with_vulkan_drivers" in
1914     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1915     xno) with_vulkan_drivers='' ;;
1916 esac
1917
1918 AC_ARG_WITH([vulkan-icddir],
1919     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1920         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1921     [VULKAN_ICD_INSTALL_DIR="$withval"],
1922     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1923 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1924
1925 if test -n "$with_vulkan_drivers"; then
1926     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1927         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1928     fi
1929
1930     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1931     for driver in $VULKAN_DRIVERS; do
1932         case "x$driver" in
1933         xintel)
1934             require_libdrm "ANV"
1935             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1936             HAVE_INTEL_VULKAN=yes
1937             ;;
1938         xradeon)
1939             require_libdrm "radv"
1940             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1941             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1942             HAVE_RADEON_VULKAN=yes
1943             ;;
1944         *)
1945             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1946             ;;
1947         esac
1948     done
1949     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1950 fi
1951
1952
1953 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1954 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1955 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1956                                   "x$enable_osmesa" = xyes -o \
1957                                   -n "$DRI_DIRS")
1958
1959 dnl
1960 dnl OSMesa configuration
1961 dnl
1962
1963 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1964 AC_ARG_WITH([osmesa-bits],
1965     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1966         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1967     [osmesa_bits="$withval"],
1968     [osmesa_bits=8])
1969 if test "x$osmesa_bits" != x8; then
1970     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1971         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1972         osmesa_bits=8
1973     fi
1974 fi
1975 case "x$osmesa_bits" in
1976 x8)
1977     OSMESA_LIB="${OSMESA_LIB}"
1978     ;;
1979 x16|x32)
1980     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1981     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1982     ;;
1983 *)
1984     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1985     ;;
1986 esac
1987
1988 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1989     # only link libraries with osmesa if shared
1990     if test "$enable_static" = no; then
1991         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1992     else
1993         OSMESA_LIB_DEPS=""
1994     fi
1995     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1996 fi
1997
1998 AC_SUBST([OSMESA_LIB_DEPS])
1999 AC_SUBST([OSMESA_PC_REQ])
2000 AC_SUBST([OSMESA_PC_LIB_PRIV])
2001
2002 dnl
2003 dnl gbm configuration
2004 dnl
2005 if test "x$enable_gbm" = xyes; then
2006     require_dri_shared_libs_and_glapi "gbm"
2007 fi
2008 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2009 # FINISHME: GBM has a number of dependencies which we should add below
2010 GBM_PC_REQ_PRIV=""
2011 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2012 AC_SUBST([GBM_PC_REQ_PRIV])
2013 AC_SUBST([GBM_PC_LIB_PRIV])
2014
2015 dnl
2016 dnl EGL configuration
2017 dnl
2018
2019 if test "x$enable_egl" = xyes; then
2020     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2021
2022     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2023
2024     require_dri_shared_libs_and_glapi "egl"
2025 fi
2026 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2027 AC_SUBST([EGL_LIB_DEPS])
2028
2029 gallium_st="mesa"
2030
2031 dnl
2032 dnl XA configuration
2033 dnl
2034 if test "x$enable_xa" = xyes; then
2035     if test "x$with_gallium_drivers" = xswrast; then
2036        AC_MSG_ERROR([
2037           Building xa requires at least one non swrast gallium driver.
2038           If you are looking to use libxatracker.so with the VMware driver,
2039           make sure to include svga in the gallium drivers list, apart from
2040           enabling XA.
2041           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2042     fi
2043     gallium_st="$gallium_st xa"
2044 fi
2045 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2046
2047 dnl
2048 dnl Gallium G3DVL configuration
2049 dnl
2050 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2051     if test "x$enable_xvmc" = xauto; then
2052         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2053     fi
2054
2055     if test "x$enable_vdpau" = xauto; then
2056         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2057     fi
2058
2059     if test "x$enable_omx" = xauto; then
2060         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2061     fi
2062
2063     if test "x$enable_va" = xauto; then
2064         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2065     fi
2066 fi
2067
2068 if test "x$enable_dri" = xyes -o \
2069         "x$enable_xvmc" = xyes -o \
2070         "x$enable_vdpau" = xyes -o \
2071         "x$enable_omx" = xyes -o \
2072         "x$enable_va" = xyes; then
2073     need_gallium_vl=yes
2074 fi
2075 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2076
2077 if test "x$enable_xvmc" = xyes -o \
2078         "x$enable_vdpau" = xyes -o \
2079         "x$enable_omx" = xyes -o \
2080         "x$enable_va" = xyes; then
2081     if test x"$enable_dri3" = xyes; then
2082         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2083                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2084     else
2085         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2086     fi
2087     need_gallium_vl_winsys=yes
2088 fi
2089 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2090
2091 if test "x$enable_xvmc" = xyes; then
2092     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2093     gallium_st="$gallium_st xvmc"
2094 fi
2095 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2096
2097 if test "x$enable_vdpau" = xyes; then
2098     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2099     gallium_st="$gallium_st vdpau"
2100     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2101 fi
2102 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2103
2104 if test "x$enable_omx" = xyes; then
2105     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2106     gallium_st="$gallium_st omx"
2107 fi
2108 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2109
2110 if test "x$enable_va" = xyes; then
2111     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2112     gallium_st="$gallium_st va"
2113 fi
2114 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2115
2116 dnl
2117 dnl Nine Direct3D9 configuration
2118 dnl
2119 if test "x$enable_nine" = xyes; then
2120     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2121         AC_MSG_ERROR([nine requires the gallium swrast driver])
2122     fi
2123     if test "x$with_gallium_drivers" = xswrast; then
2124         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2125     fi
2126     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2127         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2128     fi
2129
2130     if test "x$enable_dri3" = xno; then
2131         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2132     fi
2133
2134     gallium_st="$gallium_st nine"
2135 fi
2136 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2137
2138 dnl
2139 dnl OpenCL configuration
2140 dnl
2141
2142 AC_ARG_WITH([clang-libdir],
2143    [AS_HELP_STRING([--with-clang-libdir],
2144          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2145    [CLANG_LIBDIR="$withval"],
2146    [CLANG_LIBDIR=''])
2147
2148 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2149
2150 if test "x$enable_opencl" = xyes; then
2151     if test -z "$with_gallium_drivers"; then
2152         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2153     fi
2154
2155     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2156         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2157     fi
2158
2159     if test "x$have_libclc" = xno; then
2160         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2161                     Make sure the directory containing libclc.pc is specified in your
2162                     PKG_CONFIG_PATH environment variable.
2163                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2164     else
2165         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2166         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2167         AC_SUBST([LIBCLC_INCLUDEDIR])
2168         AC_SUBST([LIBCLC_LIBEXECDIR])
2169     fi
2170
2171     gallium_st="$gallium_st clover"
2172
2173     if test "x$enable_opencl_icd" = xyes; then
2174         OPENCL_LIBNAME="MesaOpenCL"
2175     else
2176         OPENCL_LIBNAME="OpenCL"
2177     fi
2178
2179     if test "x$have_libelf" != xyes; then
2180        AC_MSG_ERROR([Clover requires libelf])
2181     fi
2182
2183     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2184         altivec_enabled=no
2185         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2186         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2187         #error "AltiVec not enabled"
2188         #endif
2189         ])], altivec_enabled=yes)
2190
2191         if test "$altivec_enabled" = yes; then
2192             CLOVER_STD_OVERRIDE="-std=gnu++11"
2193         fi
2194         AC_SUBST([CLOVER_STD_OVERRIDE])
2195     fi
2196
2197     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2198
2199     llvm_add_default_components "opencl"
2200     llvm_add_component "all-targets" "opencl"
2201     llvm_add_component "linker" "opencl"
2202     llvm_add_component "instrumentation" "opencl"
2203     llvm_add_component "ipo" "opencl"
2204     llvm_add_component "irreader" "opencl"
2205     llvm_add_component "option" "opencl"
2206     llvm_add_component "objcarcopts" "opencl"
2207     llvm_add_component "profiledata" "opencl"
2208
2209     dnl Check for Clang internal headers
2210     if test -z "$CLANG_LIBDIR"; then
2211         CLANG_LIBDIR=${LLVM_LIBDIR}
2212     fi
2213     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2214     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2215         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2216 fi
2217 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2218 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2219 AC_SUBST([OPENCL_LIBNAME])
2220 AC_SUBST([CLANG_RESOURCE_DIR])
2221
2222 dnl
2223 dnl Gallium configuration
2224 dnl
2225 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2226
2227 # libEGL wants to default to the first platform specified in
2228 # ./configure.  parse that here.
2229 if test "x$platforms" != "x"; then
2230     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2231     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2232 else
2233     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2234 fi
2235
2236 AC_SUBST([EGL_NATIVE_PLATFORM])
2237 AC_SUBST([EGL_CFLAGS])
2238
2239 # If we don't have the X11 platform, set this define so we don't try to include
2240 # the X11 headers.
2241 if ! echo "$platforms" | grep -q 'x11'; then
2242     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2243     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2244 fi
2245
2246 dnl Directory for XVMC libs
2247 AC_ARG_WITH([xvmc-libdir],
2248     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2249         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2250     [XVMC_LIB_INSTALL_DIR="$withval"],
2251     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2252 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2253
2254 dnl
2255 dnl Gallium Tests
2256 dnl
2257 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2258
2259 dnl Directory for VDPAU libs
2260 AC_ARG_WITH([vdpau-libdir],
2261     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2262         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2263     [VDPAU_LIB_INSTALL_DIR="$withval"],
2264     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2265 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2266
2267 dnl Directory for OMX libs
2268
2269 AC_ARG_WITH([omx-libdir],
2270     [AS_HELP_STRING([--with-omx-libdir=DIR],
2271         [directory for the OMX libraries])],
2272     [OMX_LIB_INSTALL_DIR="$withval"],
2273     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2274                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2275 AC_SUBST([OMX_LIB_INSTALL_DIR])
2276
2277 dnl Directory for VA libs
2278
2279 AC_ARG_WITH([va-libdir],
2280     [AS_HELP_STRING([--with-va-libdir=DIR],
2281         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2282     [VA_LIB_INSTALL_DIR="$withval"],
2283     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2284 AC_SUBST([VA_LIB_INSTALL_DIR])
2285
2286 AC_ARG_WITH([d3d-libdir],
2287     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2288         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2289     [D3D_DRIVER_INSTALL_DIR="$withval"],
2290     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2291 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2292
2293 dnl
2294 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2295 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2296 dnl architectures.
2297 dnl
2298 r300_require_llvm() {
2299     case "$host" in *gnux32) return;; esac
2300     case "$host_cpu" in
2301     i*86|x86_64|amd64) require_llvm $1
2302         ;;
2303     esac
2304 }
2305
2306 dnl
2307 dnl DRM is needed by X, Wayland, and offscreen rendering.
2308 dnl Surfaceless is an alternative for the last one.
2309 dnl
2310 require_basic_egl() {
2311     case "$with_platforms" in
2312         *drm*|*surfaceless*)
2313             ;;
2314         *)
2315             AC_MSG_ERROR([$1 requires one of these:
2316                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2317                   2) --with-platforms=surfaceless (offscreen only)
2318                   Recommended options: drm,x11])
2319             ;;
2320     esac
2321 }
2322
2323 swr_require_cxx_feature_flags() {
2324     feature_name="$1"
2325     preprocessor_test="$2"
2326     option_list="$3"
2327     output_var="$4"
2328
2329     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2330     AC_LANG_PUSH([C++])
2331     save_CXXFLAGS="$CXXFLAGS"
2332     save_IFS="$IFS"
2333     IFS=","
2334     found=0
2335     for opts in $option_list
2336     do
2337         unset IFS
2338         CXXFLAGS="$opts $save_CXXFLAGS"
2339         AC_COMPILE_IFELSE(
2340             [AC_LANG_PROGRAM(
2341                 [   #if !($preprocessor_test)
2342                     #error
2343                     #endif
2344                 ])],
2345             [found=1; break],
2346             [])
2347         IFS=","
2348     done
2349     IFS="$save_IFS"
2350     CXXFLAGS="$save_CXXFLAGS"
2351     AC_LANG_POP([C++])
2352     if test $found -eq 1; then
2353         AC_MSG_RESULT([$opts])
2354         eval "$output_var=\$opts"
2355         return 0
2356     fi
2357     AC_MSG_RESULT([no])
2358     AC_MSG_ERROR([swr requires $feature_name support])
2359     return 1
2360 }
2361
2362 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2363 if test -n "$with_gallium_drivers"; then
2364     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2365     for driver in $gallium_drivers; do
2366         case "x$driver" in
2367         xsvga)
2368             HAVE_GALLIUM_SVGA=yes
2369             require_libdrm "svga"
2370             ;;
2371         xi915)
2372             HAVE_GALLIUM_I915=yes
2373             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2374             require_libdrm "Gallium i915"
2375             ;;
2376         xr300)
2377             HAVE_GALLIUM_R300=yes
2378             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2379             require_libdrm "r300"
2380             r300_require_llvm "r300"
2381             ;;
2382         xr600)
2383             HAVE_GALLIUM_R600=yes
2384             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2385             require_libdrm "r600"
2386             if test "x$enable_llvm" = xyes; then
2387                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2388
2389                 llvm_add_component "asmparser" "r600"
2390                 llvm_add_component "bitreader" "r600"
2391             fi
2392             ;;
2393         xradeonsi)
2394             HAVE_GALLIUM_RADEONSI=yes
2395             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2396             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2397             require_libdrm "radeonsi"
2398             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2399             if test "x$enable_egl" = xyes; then
2400                 require_basic_egl "radeonsi"
2401             fi
2402             ;;
2403         xnouveau)
2404             HAVE_GALLIUM_NOUVEAU=yes
2405             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2406             require_libdrm "nouveau"
2407             ;;
2408         xfreedreno)
2409             HAVE_GALLIUM_FREEDRENO=yes
2410             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2411             require_libdrm "freedreno"
2412             ;;
2413         xetnaviv)
2414             HAVE_GALLIUM_ETNAVIV=yes
2415             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2416             require_libdrm "etnaviv"
2417             ;;
2418        ximx)
2419             HAVE_GALLIUM_IMX=yes
2420             ;;
2421         xswrast)
2422             HAVE_GALLIUM_SOFTPIPE=yes
2423             if test "x$enable_llvm" = xyes; then
2424                 HAVE_GALLIUM_LLVMPIPE=yes
2425             fi
2426             ;;
2427         xswr)
2428             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2429
2430             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2431                 "-std=c++14" \
2432                 SWR_CXX14_CXXFLAGS
2433             AC_SUBST([SWR_CXX14_CXXFLAGS])
2434
2435             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2436                 ",-mavx,-march=core-avx" \
2437                 SWR_AVX_CXXFLAGS
2438             AC_SUBST([SWR_AVX_CXXFLAGS])
2439
2440             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2441                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2442                 SWR_AVX2_CXXFLAGS
2443             AC_SUBST([SWR_AVX2_CXXFLAGS])
2444
2445             HAVE_GALLIUM_SWR=yes
2446             ;;
2447         xvc4)
2448             HAVE_GALLIUM_VC4=yes
2449             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2450             require_libdrm "vc4"
2451
2452             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2453                               [USE_VC4_SIMULATOR=yes;
2454                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2455                               [USE_VC4_SIMULATOR=no])
2456             ;;
2457         xvirgl)
2458             HAVE_GALLIUM_VIRGL=yes
2459             require_libdrm "virgl"
2460             if test "x$enable_egl" = xyes; then
2461                 require_basic_egl "virgl"
2462             fi
2463             ;;
2464         *)
2465             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2466             ;;
2467         esac
2468     done
2469 fi
2470
2471 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2472     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2473     llvm_add_default_components "gallium"
2474 fi
2475
2476 dnl We need to validate some needed dependencies for renderonly drivers.
2477
2478 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2479     AC_MSG_ERROR([Building with imx requires etnaviv])
2480 fi
2481
2482 dnl
2483 dnl Set defines and buildtime variables only when using LLVM.
2484 dnl
2485 if test "x$enable_llvm" = xyes; then
2486     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2487
2488     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2489     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2490     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2491
2492     dnl Set LLVM_LIBS - This is done after the driver configuration so
2493     dnl that drivers can add additional components to LLVM_COMPONENTS.
2494     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2495     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2496     dnl this was causing the same libraries to be appear multiple times
2497     dnl in LLVM_LIBS.
2498
2499     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2500        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2501     fi
2502     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2503
2504     dnl llvm-config may not give the right answer when llvm is a built as a
2505     dnl single shared library, so we must work the library name out for
2506     dnl ourselves.
2507     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2508     if test "x$enable_llvm_shared_libs" = xyes; then
2509         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2510         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2511         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2512
2513         if test "x$llvm_have_one_so" = xyes; then
2514             dnl LLVM was built using auto*, so there is only one shared object.
2515             LLVM_LIBS="-l$LLVM_SO_NAME"
2516         else
2517             dnl If LLVM was built with CMake, there will be one shared object per
2518             dnl component.
2519             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2520                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2521         Please make sure you have built llvm with the --enable-shared option
2522         and that your llvm libraries are installed in $LLVM_LIBDIR
2523         If you have installed your llvm libraries to a different directory you
2524         can use the --with-llvm-prefix= configure flag to specify this directory.
2525         NOTE: Mesa is attempting to use llvm shared libraries by default.
2526         If you do not want to build with llvm shared libraries and instead want to
2527         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2528         invocation and rebuild.])])
2529
2530            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2531            dnl install uses a shared object for each component and we have
2532            dnl already added all of these objects to LLVM_LIBS.
2533         fi
2534     else
2535         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2536         dnl We need to link to llvm system libs when using static libs
2537         dnl However, only llvm 3.5+ provides --system-libs
2538         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2539             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2540         fi
2541     fi
2542 fi
2543
2544 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2545 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2546 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2547 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2548 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2550                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2557 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2558 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2559                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2560                                          "x$HAVE_GALLIUM_SWR" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2563
2564 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2565
2566 if test "x$enable_dri" = xyes; then
2567     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2568 fi
2569
2570 if test "x$have_drisw_kms" = xyes; then
2571     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2572 fi
2573 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2574
2575 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2576 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2577 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2578 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2579 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2580 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2581
2582 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2583 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2584
2585 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2586                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2587                                       "x$HAVE_RADEON_VULKAN" = xyes)
2588
2589 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2590                                         "x$HAVE_I965_DRI" = xyes)
2591
2592 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2593                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2594                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2595 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2596 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2597 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2598 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2599
2600 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2601 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2602 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2603 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2604                                         "x$enable_gallium_osmesa" = xyes)
2605
2606 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2607 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2608 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2609
2610 AC_SUBST([NINE_MAJOR], 1)
2611 AC_SUBST([NINE_MINOR], 0)
2612 AC_SUBST([NINE_TINY], 0)
2613 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2614
2615 AC_SUBST([VDPAU_MAJOR], 1)
2616 AC_SUBST([VDPAU_MINOR], 0)
2617
2618 if test "x$enable_va" = xyes; then
2619     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2620     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2621 fi
2622 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2623 AC_SUBST([VA_MINOR], $VA_MINOR)
2624
2625 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2626
2627 AC_SUBST([XVMC_MAJOR], 1)
2628 AC_SUBST([XVMC_MINOR], 0)
2629
2630 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2631 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2632 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2633 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2634
2635 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2636 AC_SUBST([XA_MINOR], $XA_MINOR)
2637 AC_SUBST([XA_TINY], $XA_TINY)
2638 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2639
2640 AC_ARG_ENABLE(valgrind,
2641               [AS_HELP_STRING([--enable-valgrind],
2642                              [Build mesa with valgrind support (default: auto)])],
2643                              [VALGRIND=$enableval], [VALGRIND=auto])
2644 if test "x$VALGRIND" != xno; then
2645         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2646 fi
2647 AC_MSG_CHECKING([whether to enable Valgrind support])
2648 if test "x$VALGRIND" = xauto; then
2649         VALGRIND="$have_valgrind"
2650 fi
2651
2652 if test "x$VALGRIND" = "xyes"; then
2653         if ! test "x$have_valgrind" = xyes; then
2654                 AC_MSG_ERROR([Valgrind support required but not present])
2655         fi
2656         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2657 fi
2658
2659 AC_MSG_RESULT([$VALGRIND])
2660
2661 dnl Restore LDFLAGS and CPPFLAGS
2662 LDFLAGS="$_SAVE_LDFLAGS"
2663 CPPFLAGS="$_SAVE_CPPFLAGS"
2664
2665 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2666 if test "x$acv_mesa_CLANG" = xyes; then
2667     CFLAGS="$CFLAGS -Qunused-arguments"
2668     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2669 fi
2670
2671 dnl Add user CFLAGS and CXXFLAGS
2672 CFLAGS="$CFLAGS $USER_CFLAGS"
2673 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2674
2675 dnl Substitute the config
2676 AC_CONFIG_FILES([Makefile
2677                 src/Makefile
2678                 src/amd/Makefile
2679                 src/amd/vulkan/Makefile
2680                 src/compiler/Makefile
2681                 src/egl/Makefile
2682                 src/egl/main/egl.pc
2683                 src/egl/wayland/wayland-drm/Makefile
2684                 src/egl/wayland/wayland-egl/Makefile
2685                 src/egl/wayland/wayland-egl/wayland-egl.pc
2686                 src/gallium/Makefile
2687                 src/gallium/auxiliary/Makefile
2688                 src/gallium/auxiliary/pipe-loader/Makefile
2689                 src/gallium/drivers/freedreno/Makefile
2690                 src/gallium/drivers/ddebug/Makefile
2691                 src/gallium/drivers/i915/Makefile
2692                 src/gallium/drivers/llvmpipe/Makefile
2693                 src/gallium/drivers/noop/Makefile
2694                 src/gallium/drivers/nouveau/Makefile
2695                 src/gallium/drivers/r300/Makefile
2696                 src/gallium/drivers/r600/Makefile
2697                 src/gallium/drivers/radeon/Makefile
2698                 src/gallium/drivers/radeonsi/Makefile
2699                 src/gallium/drivers/rbug/Makefile
2700                 src/gallium/drivers/softpipe/Makefile
2701                 src/gallium/drivers/svga/Makefile
2702                 src/gallium/drivers/swr/Makefile
2703                 src/gallium/drivers/trace/Makefile
2704                 src/gallium/drivers/etnaviv/Makefile
2705                 src/gallium/drivers/imx/Makefile
2706                 src/gallium/drivers/vc4/Makefile
2707                 src/gallium/drivers/virgl/Makefile
2708                 src/gallium/state_trackers/clover/Makefile
2709                 src/gallium/state_trackers/dri/Makefile
2710                 src/gallium/state_trackers/glx/xlib/Makefile
2711                 src/gallium/state_trackers/nine/Makefile
2712                 src/gallium/state_trackers/omx/Makefile
2713                 src/gallium/state_trackers/osmesa/Makefile
2714                 src/gallium/state_trackers/va/Makefile
2715                 src/gallium/state_trackers/vdpau/Makefile
2716                 src/gallium/state_trackers/xa/Makefile
2717                 src/gallium/state_trackers/xvmc/Makefile
2718                 src/gallium/targets/d3dadapter9/Makefile
2719                 src/gallium/targets/d3dadapter9/d3d.pc
2720                 src/gallium/targets/dri/Makefile
2721                 src/gallium/targets/libgl-xlib/Makefile
2722                 src/gallium/targets/omx/Makefile
2723                 src/gallium/targets/opencl/Makefile
2724                 src/gallium/targets/opencl/mesa.icd
2725                 src/gallium/targets/osmesa/Makefile
2726                 src/gallium/targets/osmesa/osmesa.pc
2727                 src/gallium/targets/pipe-loader/Makefile
2728                 src/gallium/targets/va/Makefile
2729                 src/gallium/targets/vdpau/Makefile
2730                 src/gallium/targets/xa/Makefile
2731                 src/gallium/targets/xa/xatracker.pc
2732                 src/gallium/targets/xvmc/Makefile
2733                 src/gallium/tests/trivial/Makefile
2734                 src/gallium/tests/unit/Makefile
2735                 src/gallium/winsys/etnaviv/drm/Makefile
2736                 src/gallium/winsys/imx/drm/Makefile
2737                 src/gallium/winsys/freedreno/drm/Makefile
2738                 src/gallium/winsys/i915/drm/Makefile
2739                 src/gallium/winsys/nouveau/drm/Makefile
2740                 src/gallium/winsys/radeon/drm/Makefile
2741                 src/gallium/winsys/amdgpu/drm/Makefile
2742                 src/gallium/winsys/svga/drm/Makefile
2743                 src/gallium/winsys/sw/dri/Makefile
2744                 src/gallium/winsys/sw/kms-dri/Makefile
2745                 src/gallium/winsys/sw/null/Makefile
2746                 src/gallium/winsys/sw/wrapper/Makefile
2747                 src/gallium/winsys/sw/xlib/Makefile
2748                 src/gallium/winsys/vc4/drm/Makefile
2749                 src/gallium/winsys/virgl/drm/Makefile
2750                 src/gallium/winsys/virgl/vtest/Makefile
2751                 src/gbm/Makefile
2752                 src/gbm/main/gbm.pc
2753                 src/glx/Makefile
2754                 src/glx/apple/Makefile
2755                 src/glx/tests/Makefile
2756                 src/glx/windows/Makefile
2757                 src/glx/windows/windowsdriproto.pc
2758                 src/gtest/Makefile
2759                 src/intel/Makefile
2760                 src/loader/Makefile
2761                 src/mapi/Makefile
2762                 src/mapi/es1api/glesv1_cm.pc
2763                 src/mapi/es2api/glesv2.pc
2764                 src/mapi/glapi/gen/Makefile
2765                 src/mesa/Makefile
2766                 src/mesa/gl.pc
2767                 src/mesa/drivers/dri/dri.pc
2768                 src/mesa/drivers/dri/common/Makefile
2769                 src/mesa/drivers/dri/common/xmlpool/Makefile
2770                 src/mesa/drivers/dri/i915/Makefile
2771                 src/mesa/drivers/dri/i965/Makefile
2772                 src/mesa/drivers/dri/Makefile
2773                 src/mesa/drivers/dri/nouveau/Makefile
2774                 src/mesa/drivers/dri/r200/Makefile
2775                 src/mesa/drivers/dri/radeon/Makefile
2776                 src/mesa/drivers/dri/swrast/Makefile
2777                 src/mesa/drivers/osmesa/Makefile
2778                 src/mesa/drivers/osmesa/osmesa.pc
2779                 src/mesa/drivers/x11/Makefile
2780                 src/mesa/main/tests/Makefile
2781                 src/util/Makefile
2782                 src/util/tests/hash_table/Makefile
2783                 src/vulkan/Makefile])
2784
2785 AC_OUTPUT
2786
2787 # Fix up dependencies in *.Plo files, where we changed the extension of a
2788 # source file
2789 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2790
2791
2792 dnl
2793 dnl Output some configuration info for the user
2794 dnl
2795 echo ""
2796 echo "        prefix:          $prefix"
2797 echo "        exec_prefix:     $exec_prefix"
2798 echo "        libdir:          $libdir"
2799 echo "        includedir:      $includedir"
2800
2801 dnl API info
2802 echo ""
2803 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2804
2805 dnl Driver info
2806 echo ""
2807 case "x$enable_osmesa$enable_gallium_osmesa" in
2808 xnoyes)
2809         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2810         ;;
2811 xyesno)
2812         echo "        OSMesa:          lib$OSMESA_LIB"
2813         ;;
2814 xnono)
2815         echo "        OSMesa:          no"
2816         ;;
2817 esac
2818
2819 echo ""
2820 if test "x$enable_dri" != xno; then
2821         echo "        DRI platform:    $dri_platform"
2822         if test -z "$DRI_DIRS"; then
2823             echo "        DRI drivers:     no"
2824         else
2825             echo "        DRI drivers:     $DRI_DIRS"
2826         fi
2827         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2828 fi
2829
2830 case "x$enable_glx" in
2831 xdri)
2832     echo "        GLX:             DRI-based"
2833     ;;
2834 xxlib)
2835     echo "        GLX:             Xlib-based"
2836     ;;
2837 xgallium-xlib)
2838     echo "        GLX:             Xlib-based (Gallium)"
2839     ;;
2840 *)
2841     echo "        GLX:             $enable_glx"
2842     ;;
2843 esac
2844
2845 dnl EGL
2846 echo ""
2847 echo "        EGL:             $enable_egl"
2848 if test "$enable_egl" = yes; then
2849
2850     egl_drivers=""
2851     if test "x$enable_dri" != "xno"; then
2852         egl_drivers="$egl_drivers builtin:egl_dri2"
2853     fi
2854     if test "x$enable_dri3" != "xno"; then
2855         egl_drivers="$egl_drivers builtin:egl_dri3"
2856     fi
2857
2858     echo "        EGL drivers:    $egl_drivers"
2859 fi
2860 if test "x$enable_gbm" = xyes; then
2861     echo "        GBM:             yes"
2862 else
2863     echo "        GBM:             no"
2864 fi
2865
2866     echo "        EGL/Vulkan/VL platforms:   $platforms"
2867
2868 # Vulkan
2869 echo ""
2870 if test "x$VULKAN_DRIVERS" != x; then
2871     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2872     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2873 else
2874     echo "        Vulkan drivers:  no"
2875 fi
2876
2877 echo ""
2878 if test "x$enable_llvm" = xyes; then
2879     echo "        llvm:            yes"
2880     echo "        llvm-config:     $LLVM_CONFIG"
2881     echo "        llvm-version:    $LLVM_VERSION"
2882 else
2883     echo "        llvm:            no"
2884 fi
2885
2886 echo ""
2887 if test -n "$with_gallium_drivers"; then
2888     echo "        Gallium drivers: $gallium_drivers"
2889     echo "        Gallium st:      $gallium_st"
2890 else
2891     echo "        Gallium:         no"
2892 fi
2893
2894 echo ""
2895 if test "x$enable_gallium_extra_hud" != xyes; then
2896     echo "        HUD extra stats: no"
2897 else
2898     echo "        HUD extra stats: yes"
2899 fi
2900
2901 if test "x$enable_lmsensors" != xyes; then
2902     echo "        HUD lmsensors:   no"
2903 else
2904     echo "        HUD lmsensors:   yes"
2905 fi
2906
2907 dnl Libraries
2908 echo ""
2909 echo "        Shared libs:     $enable_shared"
2910 echo "        Static libs:     $enable_static"
2911 echo "        Shared-glapi:    $enable_shared_glapi"
2912
2913 dnl Compiler options
2914 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
2915 cflags=`echo $CFLAGS | \
2916     $SED 's/^ *//;s/  */ /;s/ *$//'`
2917 cxxflags=`echo $CXXFLAGS | \
2918     $SED 's/^ *//;s/  */ /;s/ *$//'`
2919 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2920 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2921 echo ""
2922 echo "        CFLAGS:          $cflags"
2923 echo "        CXXFLAGS:        $cxxflags"
2924 echo "        LDFLAGS:         $ldflags"
2925 echo "        Macros:          $defines"
2926 echo ""
2927 if test "x$enable_llvm" = xyes; then
2928     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2929     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2930     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2931     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2932     echo ""
2933 fi
2934 echo "        PYTHON2:         $PYTHON2"
2935
2936 echo ""
2937 echo "        Run '${MAKE-make}' to build Mesa"
2938 echo ""