configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282
 283 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 284 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 285 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 286 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 287 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 288 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 289
 290 AC_SUBST([GL_LIB_NAME])
 291 AC_SUBST([GLU_LIB_NAME])
 292 AC_SUBST([GLUT_LIB_NAME])
 293 AC_SUBST([GLW_LIB_NAME])
 294 AC_SUBST([OSMESA_LIB_NAME])
 295 AC_SUBST([EGL_LIB_NAME])
 296
 297 AC_SUBST([GL_LIB_GLOB])
 298 AC_SUBST([GLU_LIB_GLOB])
 299 AC_SUBST([GLUT_LIB_GLOB])
 300 AC_SUBST([GLW_LIB_GLOB])
 301 AC_SUBST([OSMESA_LIB_GLOB])
 302 AC_SUBST([EGL_LIB_GLOB])
 303
 304 dnl
 305 dnl Arch/platform-specific settings
 306 dnl
 307 AC_ARG_ENABLE([asm],
 308     [AS_HELP_STRING([--disable-asm],
 309         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 310     [enable_asm="$enableval"],
 311     [enable_asm=yes]
 312 )
 313 asm_arch=""
 314 ASM_FLAGS=""
 315 MESA_ASM_SOURCES=""
 316 GLAPI_ASM_SOURCES=""
 317 AC_MSG_CHECKING([whether to enable assembly])
 318 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 319 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 320 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 321     case "$host_cpu" in
 322     i?86 | x86_64)
 323         enable_asm=no
 324         AC_MSG_RESULT([no, cross compiling])
 325         ;;
 326     esac
 327 fi
 328 # check for supported arches
 329 if test "x$enable_asm" = xyes; then
 330     case "$host_cpu" in
 331     i?86)
 332         case "$host_os" in
 333         linux* | *freebsd* | dragonfly*)
 334             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 335             ;;
 336         esac
 337         ;;
 338     x86_64)
 339         case "$host_os" in
 340         linux* | *freebsd* | dragonfly*)
 341             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 342             ;;
 343         esac
 344         ;;
 345     powerpc)
 346         case "$host_os" in
 347         linux*)
 348             asm_arch=ppc
 349             ;;
 350         esac
 351         ;;
 352     sparc*)
 353         case "$host_os" in
 354         linux*)
 355             asm_arch=sparc
 356             ;;
 357         esac
 358         ;;
 359     esac
 360
 361     case "$asm_arch" in
 362     x86)
 363         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 364         MESA_ASM_SOURCES='$(X86_SOURCES)'
 365         GLAPI_ASM_SOURCES='$(X86_API)'
 366         AC_MSG_RESULT([yes, x86])
 367         ;;
 368     x86_64)
 369         ASM_FLAGS="-DUSE_X86_64_ASM"
 370         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 371         GLAPI_ASM_SOURCES='$(X86-64_API)'
 372         AC_MSG_RESULT([yes, x86_64])
 373         ;;
 374     ppc)
 375         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 376         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 377         AC_MSG_RESULT([yes, ppc])
 378         ;;
 379     sparc)
 380         ASM_FLAGS="-DUSE_SPARC_ASM"
 381         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 382         GLAPI_ASM_SOURCES='$(SPARC_API)'
 383         AC_MSG_RESULT([yes, sparc])
 384         ;;
 385     *)
 386         AC_MSG_RESULT([no, platform not supported])
 387         ;;
 388     esac
 389 fi
 390 AC_SUBST([ASM_FLAGS])
 391 AC_SUBST([MESA_ASM_SOURCES])
 392 AC_SUBST([GLAPI_ASM_SOURCES])
 393
 394 dnl PIC code macro
 395 MESA_PIC_FLAGS
 396
 397 dnl Check to see if dlopen is in default libraries (like Solaris, which
 398 dnl has it in libc), or if libdl is needed to get it.
 399 AC_CHECK_FUNC([dlopen], [],
 400     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 401
 402 dnl See if posix_memalign is available
 403 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 404
 405 dnl SELinux awareness.
 406 AC_ARG_ENABLE([selinux],
 407     [AS_HELP_STRING([--enable-selinux],
 408         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 409     [MESA_SELINUX="$enableval"],
 410     [MESA_SELINUX=no])
 411 if test "x$enable_selinux" = "xyes"; then
 412     AC_CHECK_HEADER([selinux/selinux.h],[],
 413                     [AC_MSG_ERROR([SELinux headers not found])])
 414     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 415                  [AC_MSG_ERROR([SELinux library not found])])
 416     SELINUX_LIBS="-lselinux"
 417     DEFINES="$DEFINES -DMESA_SELINUX"
 418 fi
 419
 420 dnl
 421 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 422 dnl More later: fbdev, ...
 423 dnl
 424 default_driver="xlib"
 425
 426 case "$host_os" in
 427 linux*)
 428     case "$host_cpu" in
 429     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 430     esac
 431     ;;
 432 *freebsd* | dragonfly*)
 433     case "$host_cpu" in
 434     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 435     esac
 436     ;;
 437 esac
 438
 439 AC_ARG_WITH([driver],
 440     [AS_HELP_STRING([--with-driver=DRIVER],
 441         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 442     [mesa_driver="$withval"],
 443     [mesa_driver="$default_driver"])
 444 dnl Check for valid option
 445 case "x$mesa_driver" in
 446 xxlib|xdri|xosmesa)
 447     ;;
 448 *)
 449     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 450     ;;
 451 esac
 452
 453 dnl
 454 dnl Driver specific build directories
 455 dnl
 456
 457 dnl this variable will be prepended to SRC_DIRS and is not exported
 458 CORE_DIRS="glsl mesa"
 459
 460 SRC_DIRS="glew"
 461 GLU_DIRS="sgi"
 462 GALLIUM_DIRS="auxiliary drivers state_trackers"
 463 GALLIUM_TARGET_DIRS=""
 464 GALLIUM_WINSYS_DIRS="sw"
 465 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 466 GALLIUM_STATE_TRACKERS_DIRS=""
 467
 468 case "$mesa_driver" in
 469 xlib)
 470     DRIVER_DIRS="x11"
 471     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 472     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 473     ;;
 474 dri)
 475     SRC_DIRS="$SRC_DIRS glx"
 476     DRIVER_DIRS="dri"
 477     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
 478     ;;
 479 osmesa)
 480     DRIVER_DIRS="osmesa"
 481     ;;
 482 esac
 483 AC_SUBST([SRC_DIRS])
 484 AC_SUBST([GLU_DIRS])
 485 AC_SUBST([DRIVER_DIRS])
 486 AC_SUBST([GALLIUM_DIRS])
 487 AC_SUBST([GALLIUM_TARGET_DIRS])
 488 AC_SUBST([GALLIUM_WINSYS_DIRS])
 489 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 490 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 491
 492 dnl
 493 dnl User supplied program configuration
 494 dnl
 495 if test -d "$srcdir/progs/demos"; then
 496     default_demos=yes
 497 else
 498     default_demos=no
 499 fi
 500 AC_ARG_WITH([demos],
 501     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 502         [optional comma delimited demo directories to build
 503         @<:@default=auto if source available@:>@])],
 504     [with_demos="$withval"],
 505     [with_demos="$default_demos"])
 506 if test "x$with_demos" = x; then
 507     with_demos=no
 508 fi
 509
 510 dnl If $with_demos is yes, directories will be added as libs available
 511 PROGRAM_DIRS=""
 512 case "$with_demos" in
 513 no) ;;
 514 yes)
 515     # If the driver isn't osmesa, we have libGL and can build xdemos
 516     if test "$mesa_driver" != osmesa; then
 517         PROGRAM_DIRS="xdemos"
 518     fi
 519     ;;
 520 *)
 521     # verify the requested demos directories exist
 522     demos=`IFS=,; echo $with_demos`
 523     for demo in $demos; do
 524         test -d "$srcdir/progs/$demo" || \
 525             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 526     done
 527     PROGRAM_DIRS="$demos"
 528     ;;
 529 esac
 530
 531 dnl
 532 dnl Find out if X is available. The variable have_x is set if libX11 is
 533 dnl found to mimic AC_PATH_XTRA.
 534 dnl
 535 if test -n "$PKG_CONFIG"; then
 536     AC_MSG_CHECKING([pkg-config files for X11 are available])
 537     PKG_CHECK_EXISTS([x11],[
 538         x11_pkgconfig=yes
 539         have_x=yes
 540         ],[
 541         x11_pkgconfig=no
 542     ])
 543     AC_MSG_RESULT([$x11_pkgconfig])
 544 else
 545     x11_pkgconfig=no
 546 fi
 547 dnl Use the autoconf macro if no pkg-config files
 548 if test "$x11_pkgconfig" = yes; then
 549     PKG_CHECK_MODULES([X11], [x11])
 550 else
 551     AC_PATH_XTRA
 552     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 553     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 554     AC_SUBST([X11_CFLAGS])
 555     AC_SUBST([X11_LIBS])
 556 fi
 557
 558 dnl Try to tell the user that the --x-* options are only used when
 559 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 560 m4_divert_once([HELP_BEGIN],
 561 [These options are only used when the X libraries cannot be found by the
 562 pkg-config utility.])
 563
 564 dnl We need X for xlib and dri, so bomb now if it's not found
 565 case "$mesa_driver" in
 566 xlib|dri)
 567     if test "$no_x" = yes; then
 568         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 569     fi
 570     ;;
 571 esac
 572
 573 dnl XCB - this is only used for GLX right now
 574 AC_ARG_ENABLE([xcb],
 575     [AS_HELP_STRING([--enable-xcb],
 576         [use XCB for GLX @<:@default=disabled@:>@])],
 577     [enable_xcb="$enableval"],
 578     [enable_xcb=no])
 579 if test "x$enable_xcb" = xyes; then
 580     DEFINES="$DEFINES -DUSE_XCB"
 581 else
 582     enable_xcb=no
 583 fi
 584
 585 dnl
 586 dnl libGL configuration per driver
 587 dnl
 588 case "$mesa_driver" in
 589 xlib)
 590     if test "$x11_pkgconfig" = yes; then
 591         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 592         GL_PC_REQ_PRIV="x11 xext"
 593         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 594         GL_LIB_DEPS="$XLIBGL_LIBS"
 595     else
 596         # should check these...
 597         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 598         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 599         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 600         GL_PC_CFLAGS="$X11_INCLUDES"
 601     fi
 602     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 603     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 604
 605     # if static, move the external libraries to the programs
 606     # and empty the libraries for libGL
 607     if test "$enable_static" = yes; then
 608         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 609         GL_LIB_DEPS=""
 610     fi
 611     ;;
 612 dri)
 613     # DRI must be shared, I think
 614     if test "$enable_static" = yes; then
 615         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 616     fi
 617
 618     # Check for libdrm
 619     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 620     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 621     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 622     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 623     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 624
 625     # find the DRI deps for libGL
 626     if test "$x11_pkgconfig" = yes; then
 627         # add xcb modules if necessary
 628         dri_modules="x11 xext xxf86vm xdamage xfixes"
 629         if test "$enable_xcb" = yes; then
 630             dri_modules="$dri_modules x11-xcb xcb-glx"
 631         fi
 632
 633         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 634         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 635         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 636         GL_LIB_DEPS="$DRIGL_LIBS"
 637     else
 638         # should check these...
 639         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 640         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 641         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 642         GL_PC_CFLAGS="$X11_INCLUDES"
 643
 644         # XCB can only be used from pkg-config
 645         if test "$enable_xcb" = yes; then
 646             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 647             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 648             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 649             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 650         fi
 651     fi
 652
 653     # need DRM libs, -lpthread, etc.
 654     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 655     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 656     ;;
 657 osmesa)
 658     # No libGL for osmesa
 659     GL_LIB_DEPS=""
 660     ;;
 661 esac
 662 AC_SUBST([GL_LIB_DEPS])
 663 AC_SUBST([GL_PC_REQ_PRIV])
 664 AC_SUBST([GL_PC_LIB_PRIV])
 665 AC_SUBST([GL_PC_CFLAGS])
 666 AC_SUBST([DRI_PC_REQ_PRIV])
 667
 668 dnl
 669 dnl More X11 setup
 670 dnl
 671 if test "$mesa_driver" = xlib; then
 672     DEFINES="$DEFINES -DUSE_XSHM"
 673 fi
 674
 675 dnl
 676 dnl More DRI setup
 677 dnl
 678 AC_ARG_ENABLE([glx-tls],
 679     [AS_HELP_STRING([--enable-glx-tls],
 680         [enable TLS support in GLX @<:@default=disabled@:>@])],
 681     [GLX_USE_TLS="$enableval"],
 682     [GLX_USE_TLS=no])
 683 dnl Directory for DRI drivers
 684 AC_ARG_WITH([dri-driverdir],
 685     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 686         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 687     [DRI_DRIVER_INSTALL_DIR="$withval"],
 688     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 689 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 690 dnl Extra search path for DRI drivers
 691 AC_ARG_WITH([dri-searchpath],
 692     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 693         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 694     [DRI_DRIVER_SEARCH_DIR="$withval"],
 695     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 696 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 697 dnl Direct rendering or just indirect rendering
 698 AC_ARG_ENABLE([driglx-direct],
 699     [AS_HELP_STRING([--disable-driglx-direct],
 700         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 701     [driglx_direct="$enableval"],
 702     [driglx_direct="yes"])
 703 dnl Which drivers to build - default is chosen by platform
 704 AC_ARG_WITH([dri-drivers],
 705     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 706         [comma delimited DRI drivers list, e.g.
 707         "swrast,i965,radeon" @<:@default=auto@:>@])],
 708     [with_dri_drivers="$withval"],
 709     [with_dri_drivers=yes])
 710 if test "x$with_dri_drivers" = x; then
 711     with_dri_drivers=no
 712 fi
 713
 714 dnl If $with_dri_drivers is yes, directories will be added through
 715 dnl platform checks
 716 DRI_DIRS=""
 717 case "$with_dri_drivers" in
 718 no) ;;
 719 yes)
 720     DRI_DIRS="yes"
 721     ;;
 722 *)
 723     # verify the requested driver directories exist
 724     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 725     for driver in $dri_drivers; do
 726         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 727             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 728     done
 729     DRI_DIRS="$dri_drivers"
 730     ;;
 731 esac
 732
 733 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 734 if test "$mesa_driver" = dri; then
 735     # Use TLS in GLX?
 736     if test "x$GLX_USE_TLS" = xyes; then
 737         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 738     fi
 739
 740     # Platform specific settings and drivers to build
 741     case "$host_os" in
 742     linux*)
 743         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 744         if test "x$driglx_direct" = xyes; then
 745             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 746         fi
 747         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 748
 749         case "$host_cpu" in
 750         x86_64)
 751             # sis is missing because they have not be converted to use
 752             # the new interface.  i810 are missing because there is no
 753             # x86-64 system where they could *ever* be used.
 754             if test "x$DRI_DIRS" = "xyes"; then
 755                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 756                     savage tdfx unichrome swrast"
 757             fi
 758             ;;
 759         powerpc*)
 760             # Build only the drivers for cards that exist on PowerPC.
 761             # At some point MGA will be added, but not yet.
 762             if test "x$DRI_DIRS" = "xyes"; then
 763                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 764             fi
 765             ;;
 766         sparc*)
 767             # Build only the drivers for cards that exist on sparc`
 768             if test "x$DRI_DIRS" = "xyes"; then
 769                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 770             fi
 771             ;;
 772         esac
 773         ;;
 774     freebsd* | dragonfly*)
 775         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 776         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 777         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 778         if test "x$driglx_direct" = xyes; then
 779             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 780         fi
 781         if test "x$GXX" = xyes; then
 782             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 783         fi
 784
 785         if test "x$DRI_DIRS" = "xyes"; then
 786             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 787                 unichrome savage sis swrast"
 788         fi
 789         ;;
 790     gnu*)
 791         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 792         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 793         ;;
 794     solaris*)
 795         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 796         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 797         if test "x$driglx_direct" = xyes; then
 798             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 799         fi
 800         ;;
 801     esac
 802
 803     # default drivers
 804     if test "x$DRI_DIRS" = "xyes"; then
 805         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 806             savage sis tdfx unichrome swrast"
 807     fi
 808
 809     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 810
 811     # Check for expat
 812     EXPAT_INCLUDES=""
 813     EXPAT_LIB=-lexpat
 814     AC_ARG_WITH([expat],
 815         [AS_HELP_STRING([--with-expat=DIR],
 816             [expat install directory])],[
 817         EXPAT_INCLUDES="-I$withval/include"
 818         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 819         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 820         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 821         ])
 822     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 823     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 824         [AC_MSG_ERROR([Expat required for DRI.])])
 825
 826     # put all the necessary libs together
 827     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 828 fi
 829 AC_SUBST([DRI_DIRS])
 830 AC_SUBST([EXPAT_INCLUDES])
 831 AC_SUBST([DRI_LIB_DEPS])
 832
 833 case $DRI_DIRS in
 834 *i915*|*i965*)
 835     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 836     ;;
 837 esac
 838
 839 case $DRI_DIRS in
 840 *radeon*|*r200*|*r300*|*r600*)
 841     PKG_CHECK_MODULES([LIBDRM_RADEON],
 842                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 843                       HAVE_LIBDRM_RADEON=yes,
 844                       HAVE_LIBDRM_RADEON=no)
 845
 846     if test "$HAVE_LIBDRM_RADEON" = yes; then
 847         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 848         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 849     fi
 850     ;;
 851 esac
 852 AC_SUBST([RADEON_CFLAGS])
 853 AC_SUBST([RADEON_LDFLAGS])
 854
 855
 856 dnl
 857 dnl OSMesa configuration
 858 dnl
 859 if test "$mesa_driver" = xlib; then
 860     default_gl_osmesa=yes
 861 else
 862     default_gl_osmesa=no
 863 fi
 864 AC_ARG_ENABLE([gl-osmesa],
 865     [AS_HELP_STRING([--enable-gl-osmesa],
 866         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 867     [gl_osmesa="$enableval"],
 868     [gl_osmesa="$default_gl_osmesa"])
 869 if test "x$gl_osmesa" = xyes; then
 870     if test "$mesa_driver" = osmesa; then
 871         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 872     else
 873         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 874     fi
 875 fi
 876
 877 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 878 AC_ARG_WITH([osmesa-bits],
 879     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 880         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 881     [osmesa_bits="$withval"],
 882     [osmesa_bits=8])
 883 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 884     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 885     osmesa_bits=8
 886 fi
 887 case "x$osmesa_bits" in
 888 x8)
 889     OSMESA_LIB=OSMesa
 890     ;;
 891 x16|x32)
 892     OSMESA_LIB="OSMesa$osmesa_bits"
 893     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 894     ;;
 895 *)
 896     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 897     ;;
 898 esac
 899 AC_SUBST([OSMESA_LIB])
 900
 901 case "$mesa_driver" in
 902 osmesa)
 903     # only link libraries with osmesa if shared
 904     if test "$enable_static" = no; then
 905         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 906     else
 907         OSMESA_LIB_DEPS=""
 908     fi
 909     OSMESA_MESA_DEPS=""
 910     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 911     ;;
 912 *)
 913     # Link OSMesa to libGL otherwise
 914     OSMESA_LIB_DEPS=""
 915     # only link libraries with osmesa if shared
 916     if test "$enable_static" = no; then
 917         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 918     else
 919         OSMESA_MESA_DEPS=""
 920     fi
 921     OSMESA_PC_REQ="gl"
 922     ;;
 923 esac
 924 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 925 AC_SUBST([OSMESA_LIB_DEPS])
 926 AC_SUBST([OSMESA_MESA_DEPS])
 927 AC_SUBST([OSMESA_PC_REQ])
 928 AC_SUBST([OSMESA_PC_LIB_PRIV])
 929
 930 dnl
 931 dnl EGL configuration
 932 dnl
 933 AC_ARG_ENABLE([egl],
 934     [AS_HELP_STRING([--disable-egl],
 935         [disable EGL library @<:@default=enabled@:>@])],
 936     [enable_egl="$enableval"],
 937     [enable_egl=yes])
 938 if test "x$enable_egl" = xyes; then
 939     SRC_DIRS="$SRC_DIRS egl"
 940     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 941     EGL_DRIVERS_DIRS=""
 942     if test "$enable_static" != yes; then
 943         # build egl_glx when libGL is built
 944         if test "$mesa_driver" != osmesa; then
 945             EGL_DRIVERS_DIRS="glx"
 946         fi
 947
 948         # build egl_dri2 when xcb-dri2 is available
 949         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
 950                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 951         if test "$have_xcb_dri2" = yes; then
 952             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
 953         fi
 954     fi
 955
 956     if test "$with_demos" = yes; then
 957         PROGRAM_DIRS="$PROGRAM_DIRS egl"
 958     fi
 959 fi
 960 AC_SUBST([EGL_LIB_DEPS])
 961 AC_SUBST([EGL_DRIVERS_DIRS])
 962
 963 dnl
 964 dnl GLU configuration
 965 dnl
 966 AC_ARG_ENABLE([glu],
 967     [AS_HELP_STRING([--disable-glu],
 968         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 969     [enable_glu="$enableval"],
 970     [enable_glu=yes])
 971 if test "x$enable_glu" = xyes; then
 972     SRC_DIRS="$SRC_DIRS glu"
 973
 974     case "$mesa_driver" in
 975     osmesa)
 976         # If GLU is available and we have libOSMesa (not 16 or 32),
 977         # we can build the osdemos
 978         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 979             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 980         fi
 981
 982         # Link libGLU to libOSMesa instead of libGL
 983         GLU_LIB_DEPS=""
 984         GLU_PC_REQ="osmesa"
 985         if test "$enable_static" = no; then
 986             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 987         else
 988             GLU_MESA_DEPS=""
 989         fi
 990         ;;
 991     *)
 992         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 993         GLU_PC_REQ="gl"
 994         GLU_PC_LIB_PRIV="-lm"
 995         if test "$enable_static" = no; then
 996             GLU_LIB_DEPS="-lm"
 997             GLU_MESA_DEPS='-l$(GL_LIB)'
 998         else
 999             GLU_LIB_DEPS=""
1000             GLU_MESA_DEPS=""
1001             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1002         fi
1003         ;;
1004     esac
1005 fi
1006 if test "$enable_static" = no; then
1007     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1008 fi
1009 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1010 AC_SUBST([GLU_LIB_DEPS])
1011 AC_SUBST([GLU_MESA_DEPS])
1012 AC_SUBST([GLU_PC_REQ])
1013 AC_SUBST([GLU_PC_REQ_PRIV])
1014 AC_SUBST([GLU_PC_LIB_PRIV])
1015 AC_SUBST([GLU_PC_CFLAGS])
1016
1017 dnl
1018 dnl GLw configuration
1019 dnl
1020 AC_ARG_ENABLE([glw],
1021     [AS_HELP_STRING([--disable-glw],
1022         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1023     [enable_glw="$enableval"],
1024     [enable_glw=yes])
1025 dnl Don't build GLw on osmesa
1026 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1027     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1028     enable_glw=no
1029 fi
1030 AC_ARG_ENABLE([motif],
1031     [AS_HELP_STRING([--enable-motif],
1032         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1033     [enable_motif="$enableval"],
1034     [enable_motif=no])
1035
1036 if test "x$enable_glw" = xyes; then
1037     SRC_DIRS="$SRC_DIRS glw"
1038     if test "$x11_pkgconfig" = yes; then
1039         PKG_CHECK_MODULES([GLW],[x11 xt])
1040         GLW_PC_REQ_PRIV="x11 xt"
1041         GLW_LIB_DEPS="$GLW_LIBS"
1042     else
1043         # should check these...
1044         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1045         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1046         GLW_PC_CFLAGS="$X11_INCLUDES"
1047     fi
1048
1049     GLW_SOURCES="GLwDrawA.c"
1050     MOTIF_CFLAGS=
1051     if test "x$enable_motif" = xyes; then
1052         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1053         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1054         if test "x$MOTIF_CONFIG" != xno; then
1055             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1056             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1057         else
1058             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1059                 [AC_MSG_ERROR([Can't locate Motif headers])])
1060             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1061                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1062         fi
1063         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1064         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1065         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1066         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1067     fi
1068
1069     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1070     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1071     if test "$enable_static" = no; then
1072         GLW_MESA_DEPS='-l$(GL_LIB)'
1073         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1074     else
1075         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1076         GLW_LIB_DEPS=""
1077         GLW_MESA_DEPS=""
1078     fi
1079 fi
1080 AC_SUBST([GLW_LIB_DEPS])
1081 AC_SUBST([GLW_MESA_DEPS])
1082 AC_SUBST([GLW_SOURCES])
1083 AC_SUBST([MOTIF_CFLAGS])
1084 AC_SUBST([GLW_PC_REQ_PRIV])
1085 AC_SUBST([GLW_PC_LIB_PRIV])
1086 AC_SUBST([GLW_PC_CFLAGS])
1087
1088 dnl
1089 dnl GLUT configuration
1090 dnl
1091 if test -f "$srcdir/include/GL/glut.h"; then
1092     default_glut=yes
1093 else
1094     default_glut=no
1095 fi
1096 AC_ARG_ENABLE([glut],
1097     [AS_HELP_STRING([--disable-glut],
1098         [enable GLUT library @<:@default=enabled if source available@:>@])],
1099     [enable_glut="$enableval"],
1100     [enable_glut="$default_glut"])
1101
1102 dnl Can't build glut if GLU not available
1103 if test "x$enable_glu$enable_glut" = xnoyes; then
1104     AC_MSG_WARN([Disabling glut since GLU is disabled])
1105     enable_glut=no
1106 fi
1107 dnl Don't build glut on osmesa
1108 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1109     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1110     enable_glut=no
1111 fi
1112
1113 if test "x$enable_glut" = xyes; then
1114     SRC_DIRS="$SRC_DIRS glut/glx"
1115     GLUT_CFLAGS=""
1116     if test "x$GCC" = xyes; then
1117         GLUT_CFLAGS="-fexceptions"
1118     fi
1119     if test "$x11_pkgconfig" = yes; then
1120         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1121         GLUT_PC_REQ_PRIV="x11 xmu xi"
1122         GLUT_LIB_DEPS="$GLUT_LIBS"
1123     else
1124         # should check these...
1125         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1126         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1127         GLUT_PC_CFLAGS="$X11_INCLUDES"
1128     fi
1129     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1130     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1131
1132     # If glut is available, we can build most programs
1133     if test "$with_demos" = yes; then
1134         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1135     fi
1136
1137     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1138     if test "$enable_static" = no; then
1139         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1140     else
1141         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1142         GLUT_LIB_DEPS=""
1143         GLUT_MESA_DEPS=""
1144     fi
1145 fi
1146 AC_SUBST([GLUT_LIB_DEPS])
1147 AC_SUBST([GLUT_MESA_DEPS])
1148 AC_SUBST([GLUT_CFLAGS])
1149 AC_SUBST([GLUT_PC_REQ_PRIV])
1150 AC_SUBST([GLUT_PC_LIB_PRIV])
1151 AC_SUBST([GLUT_PC_CFLAGS])
1152
1153 dnl
1154 dnl Program library dependencies
1155 dnl    Only libm is added here if necessary as the libraries should
1156 dnl    be pulled in by the linker
1157 dnl
1158 if test "x$APP_LIB_DEPS" = x; then
1159     case "$host_os" in
1160     solaris*)
1161         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1162         ;;
1163     cygwin*)
1164         APP_LIB_DEPS="-lX11"
1165         ;;
1166     *)
1167         APP_LIB_DEPS="-lm"
1168         ;;
1169     esac
1170 fi
1171 AC_SUBST([APP_LIB_DEPS])
1172 AC_SUBST([PROGRAM_DIRS])
1173
1174 dnl
1175 dnl Gallium configuration
1176 dnl
1177 AC_ARG_ENABLE([gallium],
1178     [AS_HELP_STRING([--disable-gallium],
1179         [build gallium @<:@default=enabled@:>@])],
1180     [enable_gallium="$enableval"],
1181     [enable_gallium=yes])
1182 if test "x$enable_gallium" = xyes; then
1183     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1184 fi
1185
1186 dnl
1187 dnl Gallium state trackers configuration
1188 dnl
1189 AC_ARG_WITH([state-trackers],
1190     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1191         [comma delimited state_trackers list, e.g.
1192         "egl,glx" @<:@default=auto@:>@])],
1193     [with_state_trackers="$withval"],
1194     [with_state_trackers=yes])
1195
1196 case "$with_state_trackers" in
1197 no)
1198     GALLIUM_STATE_TRACKERS_DIRS=""
1199     ;;
1200 yes)
1201     # look at what else is built
1202     case "$mesa_driver" in
1203     xlib)
1204         GALLIUM_STATE_TRACKERS_DIRS=glx
1205         ;;
1206     dri)
1207         GALLIUM_STATE_TRACKERS_DIRS="dri"
1208         HAVE_ST_DRI="yes"
1209         if test "x$enable_egl" = xyes; then
1210             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1211             HAVE_ST_EGL="yes"
1212         fi
1213         # Have only tested st/xorg on 1.6.0 servers
1214         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1215             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1216             HAVE_ST_XORG="no")
1217         ;;
1218     esac
1219     ;;
1220 *)
1221     # verify the requested state tracker exist
1222     state_trackers=`IFS=', '; echo $with_state_trackers`
1223     for tracker in $state_trackers; do
1224         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1225             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1226
1227         case "$tracker" in
1228         dri)
1229             if test "x$mesa_driver" != xdri; then
1230                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1231             fi
1232             HAVE_ST_DRI="yes"
1233             ;;
1234         egl)
1235             if test "x$enable_egl" != xyes; then
1236                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1237             fi
1238             HAVE_ST_EGL="yes"
1239             ;;
1240         xorg)
1241             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1242             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1243             HAVE_ST_XORG="yes"
1244             ;;
1245         es)
1246             # mesa/es is required to build es state tracker
1247             CORE_DIRS="$CORE_DIRS mesa/es"
1248             ;;
1249         esac
1250     done
1251     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1252     ;;
1253 esac
1254
1255 if test "x$HAVE_ST_XORG" = xyes; then
1256     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1257         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1258         HAVE_XEXTPROTO_71="no")
1259 fi
1260
1261 AC_ARG_WITH([egl-displays],
1262     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1263         [comma delimited native displays libEGL supports, e.g.
1264         "x11,kms" @<:@default=auto@:>@])],
1265     [with_egl_displays="$withval"],
1266     [with_egl_displays=yes])
1267
1268 EGL_DISPLAYS=""
1269 case "$with_egl_displays" in
1270 yes)
1271     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1272         EGL_DISPLAYS="x11"
1273     fi
1274     ;;
1275 *)
1276     if test "x$enable_egl" != xyes; then
1277         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1278     fi
1279     # verify the requested driver directories exist
1280     egl_displays=`IFS=', '; echo $with_egl_displays`
1281     for dpy in $egl_displays; do
1282         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1283             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1284     done
1285     EGL_DISPLAYS="$egl_displays"
1286     ;;
1287 esac
1288 AC_SUBST([EGL_DISPLAYS])
1289
1290 AC_ARG_WITH([egl-driver-dir],
1291     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1292                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1293     [EGL_DRIVER_INSTALL_DIR="$withval"],
1294     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1295 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1296
1297 AC_ARG_WITH([xorg-driver-dir],
1298     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1299                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1300     [XORG_DRIVER_INSTALL_DIR="$withval"],
1301     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1302 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1303
1304 AC_ARG_WITH([max-width],
1305     [AS_HELP_STRING([--with-max-width=N],
1306                     [Maximum framebuffer width (4096)])],
1307     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1308      AS_IF([test "${withval}" -gt "4096"],
1309            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1310 )
1311 AC_ARG_WITH([max-height],
1312     [AS_HELP_STRING([--with-max-height=N],
1313                     [Maximum framebuffer height (4096)])],
1314     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1315      AS_IF([test "${withval}" -gt "4096"],
1316            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1317 )
1318
1319 dnl
1320 dnl Gallium helper functions
1321 dnl
1322 gallium_check_st() {
1323     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1324          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1325     fi
1326     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1327          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1328     fi
1329     if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1330          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1331     fi
1332     if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1333          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1334     fi
1335 }
1336
1337
1338 dnl
1339 dnl Gallium SVGA configuration
1340 dnl
1341 AC_ARG_ENABLE([gallium-svga],
1342     [AS_HELP_STRING([--enable-gallium-svga],
1343         [build gallium SVGA @<:@default=disabled@:>@])],
1344     [enable_gallium_svga="$enableval"],
1345     [enable_gallium_svga=auto])
1346 if test "x$enable_gallium_svga" = xyes; then
1347     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1348     gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1349 elif test "x$enable_gallium_svga" = xauto; then
1350     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1351 fi
1352
1353 dnl
1354 dnl Gallium Intel configuration
1355 dnl
1356 AC_ARG_ENABLE([gallium-intel],
1357     [AS_HELP_STRING([--enable-gallium-intel],
1358         [build gallium intel @<:@default=disabled@:>@])],
1359     [enable_gallium_intel="$enableval"],
1360     [enable_gallium_intel=auto])
1361 if test "x$enable_gallium_intel" = xyes; then
1362     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1363     gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1364 elif test "x$enable_gallium_intel" = xauto; then
1365     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1366 fi
1367
1368 dnl
1369 dnl Gallium Radeon configuration
1370 dnl
1371 AC_ARG_ENABLE([gallium-radeon],
1372     [AS_HELP_STRING([--enable-gallium-radeon],
1373         [build gallium radeon @<:@default=disabled@:>@])],
1374     [enable_gallium_radeon="$enableval"],
1375     [enable_gallium_radeon=auto])
1376 if test "x$enable_gallium_radeon" = xyes; then
1377     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1378     gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1379 elif test "x$enable_gallium_radeon" = xauto; then
1380     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1381 fi
1382
1383 dnl
1384 dnl Gallium Nouveau configuration
1385 dnl
1386 AC_ARG_ENABLE([gallium-nouveau],
1387     [AS_HELP_STRING([--enable-gallium-nouveau],
1388         [build gallium nouveau @<:@default=disabled@:>@])],
1389     [enable_gallium_nouveau="$enableval"],
1390     [enable_gallium_nouveau=no])
1391 if test "x$enable_gallium_nouveau" = xyes; then
1392     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1393     gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1394 fi
1395
1396 dnl
1397 dnl Gallium swrast configuration
1398 dnl
1399 AC_ARG_ENABLE([gallium-swrast],
1400     [AS_HELP_STRING([--enable-gallium-swrast],
1401         [build gallium swrast @<:@default=auto@:>@])],
1402     [enable_gallium_swrast="$enableval"],
1403     [enable_gallium_swrast=auto])
1404 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1405     if test "x$HAVE_ST_DRI" = xyes; then
1406         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1407     fi
1408     if test "x$HAVE_ST_EGL" = xyes; then
1409         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1410     fi
1411 fi
1412
1413 dnl prepend CORE_DIRS to SRC_DIRS
1414 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1415
1416 dnl Restore LDFLAGS and CPPFLAGS
1417 LDFLAGS="$_SAVE_LDFLAGS"
1418 CPPFLAGS="$_SAVE_CPPFLAGS"
1419
1420 dnl Substitute the config
1421 AC_CONFIG_FILES([configs/autoconf])
1422
1423 dnl Replace the configs/current symlink
1424 AC_CONFIG_COMMANDS([configs],[
1425 if test -f configs/current || test -L configs/current; then
1426     rm -f configs/current
1427 fi
1428 ln -s autoconf configs/current
1429 ])
1430
1431 AC_OUTPUT
1432
1433 dnl
1434 dnl Output some configuration info for the user
1435 dnl
1436 echo ""
1437 echo "        prefix:          $prefix"
1438 echo "        exec_prefix:     $exec_prefix"
1439 echo "        libdir:          $libdir"
1440 echo "        includedir:      $includedir"
1441
1442 dnl Driver info
1443 echo ""
1444 echo "        Driver:          $mesa_driver"
1445 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1446     echo "        OSMesa:          lib$OSMESA_LIB"
1447 else
1448     echo "        OSMesa:          no"
1449 fi
1450 if test "$mesa_driver" = dri; then
1451     # cleanup the drivers var
1452     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1453 if test "x$DRI_DIRS" = x; then
1454     echo "        DRI drivers:     no"
1455 else
1456     echo "        DRI drivers:     $dri_dirs"
1457 fi
1458     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1459 fi
1460 echo "        Use XCB:         $enable_xcb"
1461
1462 echo ""
1463 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1464     echo "        Gallium:         yes"
1465     echo "        Gallium dirs:    $GALLIUM_DIRS"
1466     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1467     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1468     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1469     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1470 else
1471     echo "        Gallium:         no"
1472 fi
1473
1474 dnl Libraries
1475 echo ""
1476 echo "        Shared libs:     $enable_shared"
1477 echo "        Static libs:     $enable_static"
1478 if test "$enable_egl" = yes; then
1479     echo "        EGL:             $EGL_DRIVERS_DIRS"
1480 else
1481     echo "        EGL:             no"
1482 fi
1483 echo "        GLU:             $enable_glu"
1484 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1485 echo "        glut:            $enable_glut"
1486
1487 dnl Programs
1488 # cleanup the programs var for display
1489 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1490 if test "x$program_dirs" = x; then
1491     echo "        Demos:           no"
1492 else
1493     echo "        Demos:           $program_dirs"
1494 fi
1495
1496 dnl Compiler options
1497 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1498 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1499     $SED 's/^ *//;s/  */ /;s/ *$//'`
1500 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1501     $SED 's/^ *//;s/  */ /;s/ *$//'`
1502 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1503 echo ""
1504 echo "        CFLAGS:          $cflags"
1505 echo "        CXXFLAGS:        $cxxflags"
1506 echo "        Macros:          $defines"
1507
1508 echo ""
1509 echo "        Run '${MAKE-make}' to build Mesa"
1510 echo ""