src/compiler/glsl/glcpp/glcpp-lex.l

   1 %{
   2 /*
   3  * Copyright © 2010 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24
  25 #include <stdio.h>
  26 #include <string.h>
  27 #include <ctype.h>
  28
  29 #include "glcpp.h"
  30 #include "glcpp-parse.h"
  31
  32 /* Flex annoyingly generates some functions without making them
  33  * static. Let's declare them here. */
  34 int glcpp_get_column  (yyscan_t yyscanner);
  35 void glcpp_set_column (int  column_no , yyscan_t yyscanner);
  36
  37 #ifdef _MSC_VER
  38 #define YY_NO_UNISTD_H
  39 #endif
  40
  41 #define YY_NO_INPUT
  42
  43 #define YY_USER_ACTION                                                  \
  44         do {                                                            \
  45                 if (parser->has_new_line_number)                        \
  46                         yylineno = parser->new_line_number;             \
  47                 if (parser->has_new_source_number)                      \
  48                         yylloc->source = parser->new_source_number;     \
  49                 yylloc->first_column = yycolumn + 1;                    \
  50                 yylloc->first_line = yylloc->last_line = yylineno;      \
  51                 yycolumn += yyleng;                                     \
  52                 yylloc->last_column = yycolumn + 1;                     \
  53                 parser->has_new_line_number = 0;                        \
  54                 parser->has_new_source_number = 0;                      \
  55         } while(0);
  56
  57 #define YY_USER_INIT                    \
  58         do {                            \
  59                 yylineno = 1;           \
  60                 yycolumn = 0;           \
  61                 yylloc->source = 0;     \
  62         } while(0)
  63
  64 /* It's ugly to have macros that have return statements inside of
  65  * them, but flex-based lexer generation is all built around the
  66  * return statement.
  67  *
  68  * To mitigate the ugliness, we defer as much of the logic as possible
  69  * to an actual function, not a macro (see
  70  * glcpplex_update_state_per_token) and we make the word RETURN
  71  * prominent in all of the macros which may return.
  72  *
  73  * The most-commonly-used macro is RETURN_TOKEN which will perform all
  74  * necessary state updates based on the provided token,, then
  75  * conditionally return the token. It will not return a token if the
  76  * parser is currently skipping tokens, (such as within #if
  77  * 0...#else).
  78  *
  79  * The RETURN_TOKEN_NEVER_SKIP macro is a lower-level variant that
  80  * makes the token returning unconditional. This is needed for things
  81  * like #if and the tokens of its condition, (since these must be
  82  * evaluated by the parser even when otherwise skipping).
  83  *
  84  * Finally, RETURN_STRING_TOKEN is a simple convenience wrapper on top
  85  * of RETURN_TOKEN that performs a string copy of yytext before the
  86  * return.
  87  */
  88 #define RETURN_TOKEN_NEVER_SKIP(token)                                  \
  89         do {                                                            \
  90                 if (glcpp_lex_update_state_per_token (parser, token))   \
  91                         return token;                                   \
  92         } while (0)
  93
  94 #define RETURN_TOKEN(token)                                             \
  95         do {                                                            \
  96                 if (! parser->skipping) {                               \
  97                         RETURN_TOKEN_NEVER_SKIP(token);                 \
  98                 }                                                       \
  99         } while(0)
 100
 101 #define RETURN_STRING_TOKEN(token)                                      \
 102         do {                                                            \
 103                 if (! parser->skipping) {                               \
 104                         yylval->str = ralloc_strdup (yyextra, yytext);  \
 105                         RETURN_TOKEN_NEVER_SKIP (token);                \
 106                 }                                                       \
 107         } while(0)
 108
 109
 110 /* Update all state necessary for each token being returned.
 111  *
 112  * Here we'll be tracking newlines and spaces so that the lexer can
 113  * alter its behavior as necessary, (for example, '#' has special
 114  * significance if it is the first non-whitespace, non-comment token
 115  * in a line, but does not otherwise).
 116  *
 117  * NOTE: If this function returns FALSE, then no token should be
 118  * returned at all. This is used to suprress duplicate SPACE tokens.
 119  */
 120 static int
 121 glcpp_lex_update_state_per_token (glcpp_parser_t *parser, int token)
 122 {
 123         /* After the first non-space token in a line, we won't
 124          * allow any '#' to introduce a directive. */
 125         if (token == NEWLINE) {
 126                 parser->first_non_space_token_this_line = 1;
 127         } else if (token != SPACE) {
 128                 parser->first_non_space_token_this_line = 0;
 129         }
 130
 131         /* Track newlines just to know whether a newline needs
 132          * to be inserted if end-of-file comes early. */
 133         if (token == NEWLINE) {
 134                 parser->last_token_was_newline = 1;
 135         } else {
 136                 parser->last_token_was_newline = 0;
 137         }
 138
 139         /* Track spaces to avoid emitting multiple SPACE
 140          * tokens in a row. */
 141         if (token == SPACE) {
 142                 if (! parser->last_token_was_space) {
 143                         parser->last_token_was_space = 1;
 144                         return 1;
 145                 } else {
 146                         parser->last_token_was_space = 1;
 147                         return 0;
 148                 }
 149         } else {
 150                 parser->last_token_was_space = 0;
 151                 return 1;
 152         }
 153 }
 154
 155
 156 %}
 157
 158 %option bison-bridge bison-locations reentrant noyywrap
 159 %option extra-type="glcpp_parser_t *"
 160 %option prefix="glcpp_"
 161 %option stack
 162 %option never-interactive
 163 %option warn nodefault
 164
 165         /* Note: When adding any start conditions to this list, you must also
 166          * update the "Internal compiler error" catch-all rule near the end of
 167          * this file. */
 168
 169 %x COMMENT DEFINE DONE HASH NEWLINE_CATCHUP UNREACHABLE
 170
 171 SPACE           [[:space:]]
 172 NONSPACE        [^[:space:]]
 173 HSPACE          [ \t]
 174 HASH            #
 175 NEWLINE         (\r\n|\n\r|\r|\n)
 176 IDENTIFIER      [_a-zA-Z][_a-zA-Z0-9]*
 177 PP_NUMBER       [.]?[0-9]([._a-zA-Z0-9]|[eEpP][-+])*
 178 PUNCTUATION     [][(){}.&*~!/%<>^|;,=+-]
 179
 180 /* The OTHER class is simply a catch-all for things that the CPP
 181 parser just doesn't care about. Since flex regular expressions that
 182 match longer strings take priority over those matching shorter
 183 strings, we have to be careful to avoid OTHER matching and hiding
 184 something that CPP does care about. So we simply exclude all
 185 characters that appear in any other expressions. */
 186
 187 OTHER           [^][_#[:space:]#a-zA-Z0-9(){}.&*~!/%<>^|;,=+-]
 188
 189 DIGITS                  [0-9][0-9]*
 190 DECIMAL_INTEGER         [1-9][0-9]*[uU]?
 191 OCTAL_INTEGER           0[0-7]*[uU]?
 192 HEXADECIMAL_INTEGER     0[xX][0-9a-fA-F]+[uU]?
 193
 194 %%
 195
 196         glcpp_parser_t *parser = yyextra;
 197
 198         /* When we lex a multi-line comment, we replace it (as
 199          * specified) with a single space. But if the comment spanned
 200          * multiple lines, then subsequent parsing stages will not
 201          * count correct line numbers. To avoid this problem we keep
 202          * track of all newlines that were commented out by a
 203          * multi-line comment, and we emit a NEWLINE token for each at
 204          * the next legal opportunity, (which is when the lexer would
 205          * be emitting a NEWLINE token anyway).
 206          */
 207         if (YY_START == NEWLINE_CATCHUP) {
 208                 if (parser->commented_newlines)
 209                         parser->commented_newlines--;
 210                 if (parser->commented_newlines == 0)
 211                         BEGIN INITIAL;
 212                 RETURN_TOKEN_NEVER_SKIP (NEWLINE);
 213         }
 214
 215         /* Set up the parser->skipping bit here before doing any lexing.
 216          *
 217          * This bit controls whether tokens are skipped, (as implemented by
 218          * RETURN_TOKEN), such as between "#if 0" and "#endif".
 219          *
 220          * The parser maintains a skip_stack indicating whether we should be
 221          * skipping, (and nested levels of #if/#ifdef/#ifndef/#endif) will
 222          * push and pop items from the stack.
 223          *
 224          * Here are the rules for determining whether we are skipping:
 225          *
 226          *      1. If the skip stack is NULL, we are outside of all #if blocks
 227          *         and we are not skipping.
 228          *
 229          *      2. If the skip stack is non-NULL, the type of the top node in
 230          *         the stack determines whether to skip. A type of
 231          *         SKIP_NO_SKIP is used for blocks wheere we are emitting
 232          *         tokens, (such as between #if 1 and #endif, or after the
 233          *         #else of an #if 0, etc.).
 234          *
 235          *      3. The lexing_directive bit overrides the skip stack. This bit
 236          *         is set when we are actively lexing the expression for a
 237          *         pre-processor condition, (such as #if, #elif, or #else). In
 238          *         this case, even if otherwise skipping, we need to emit the
 239          *         tokens for this condition so that the parser can evaluate
 240          *         the expression. (For, #else, there's no expression, but we
 241          *         emit tokens so the parser can generate a nice error message
 242          *         if there are any tokens here).
 243          */
 244         if (parser->skip_stack &&
 245             parser->skip_stack->type != SKIP_NO_SKIP &&
 246             ! parser->lexing_directive)
 247         {
 248                 parser->skipping = 1;
 249         } else {
 250                 parser->skipping = 0;
 251         }
 252
 253         /* Single-line comments */
 254 <INITIAL,DEFINE,HASH>"//"[^\r\n]* {
 255 }
 256
 257         /* Multi-line comments */
 258 <INITIAL,DEFINE,HASH>"/*"   { yy_push_state(COMMENT, yyscanner); }
 259 <COMMENT>[^*\r\n]*
 260 <COMMENT>[^*\r\n]*{NEWLINE} { yylineno++; yycolumn = 0; parser->commented_newlines++; }
 261 <COMMENT>"*"+[^*/\r\n]*
 262 <COMMENT>"*"+[^*/\r\n]*{NEWLINE} { yylineno++; yycolumn = 0; parser->commented_newlines++; }
 263 <COMMENT>"*"+"/"        {
 264         yy_pop_state(yyscanner);
 265         /* In the <HASH> start condition, we don't want any SPACE token. */
 266         if (yyextra->space_tokens && YY_START != HASH)
 267                 RETURN_TOKEN (SPACE);
 268 }
 269
 270 {HASH} {
 271
 272         /* If the '#' is the first non-whitespace, non-comment token on this
 273          * line, then it introduces a directive, switch to the <HASH> start
 274          * condition.
 275          *
 276          * Otherwise, this is just punctuation, so return the HASH_TOKEN
 277          * token. */
 278         if (parser->first_non_space_token_this_line) {
 279                 BEGIN HASH;
 280         }
 281
 282         RETURN_TOKEN_NEVER_SKIP (HASH_TOKEN);
 283 }
 284
 285 <HASH>version{HSPACE}+ {
 286         BEGIN INITIAL;
 287         yyextra->space_tokens = 0;
 288         RETURN_STRING_TOKEN (VERSION_TOKEN);
 289 }
 290
 291         /* Swallow empty #pragma directives, (to avoid confusing the
 292          * downstream compiler).
 293          *
 294          * Note: We use a simple regular expression for the lookahead
 295          * here. Specifically, we cannot use the complete {NEWLINE} expression
 296          * since it uses alternation and we've found that there's a flex bug
 297          * where using alternation in the lookahead portion of a pattern
 298          * triggers a buffer overrun. */
 299 <HASH>pragma{HSPACE}*/[\r\n] {
 300         BEGIN INITIAL;
 301 }
 302
 303         /* glcpp doesn't handle #extension, #version, or #pragma directives.
 304          * Simply pass them through to the main compiler's lexer/parser. */
 305 <HASH>(extension|pragma)[^\r\n]* {
 306         BEGIN INITIAL;
 307         RETURN_STRING_TOKEN (PRAGMA);
 308 }
 309
 310 <HASH>line{HSPACE}+ {
 311         BEGIN INITIAL;
 312         RETURN_TOKEN (LINE);
 313 }
 314
 315 <HASH>{NEWLINE} {
 316         BEGIN INITIAL;
 317         RETURN_TOKEN_NEVER_SKIP (NEWLINE);
 318 }
 319
 320         /* For the pre-processor directives, we return these tokens
 321          * even when we are otherwise skipping. */
 322 <HASH>ifdef {
 323         BEGIN INITIAL;
 324         yyextra->lexing_directive = 1;
 325         yyextra->space_tokens = 0;
 326         RETURN_TOKEN_NEVER_SKIP (IFDEF);
 327 }
 328
 329 <HASH>ifndef {
 330         BEGIN INITIAL;
 331         yyextra->lexing_directive = 1;
 332         yyextra->space_tokens = 0;
 333         RETURN_TOKEN_NEVER_SKIP (IFNDEF);
 334 }
 335
 336 <HASH>if/[^_a-zA-Z0-9] {
 337         BEGIN INITIAL;
 338         yyextra->lexing_directive = 1;
 339         yyextra->space_tokens = 0;
 340         RETURN_TOKEN_NEVER_SKIP (IF);
 341 }
 342
 343 <HASH>elif/[^_a-zA-Z0-9] {
 344         BEGIN INITIAL;
 345         yyextra->lexing_directive = 1;
 346         yyextra->space_tokens = 0;
 347         RETURN_TOKEN_NEVER_SKIP (ELIF);
 348 }
 349
 350 <HASH>else {
 351         BEGIN INITIAL;
 352         yyextra->space_tokens = 0;
 353         RETURN_TOKEN_NEVER_SKIP (ELSE);
 354 }
 355
 356 <HASH>endif {
 357         BEGIN INITIAL;
 358         yyextra->space_tokens = 0;
 359         RETURN_TOKEN_NEVER_SKIP (ENDIF);
 360 }
 361
 362 <HASH>error[^\r\n]* {
 363         BEGIN INITIAL;
 364         RETURN_STRING_TOKEN (ERROR_TOKEN);
 365 }
 366
 367         /* After we see a "#define" we enter the <DEFINE> start state
 368          * for the lexer. Within <DEFINE> we are looking for the first
 369          * identifier and specifically checking whether the identifier
 370          * is followed by a '(' or not, (to lex either a
 371          * FUNC_IDENTIFIER or an OBJ_IDENITIFIER token).
 372          *
 373          * While in the <DEFINE> state we also need to explicitly
 374          * handle a few other things that may appear before the
 375          * identifier:
 376          *
 377          *      * Comments, (handled above with the main support for
 378          *        comments).
 379          *
 380          *      * Whitespace (simply ignored)
 381          *
 382          *      * Anything else, (not an identifier, not a comment,
 383          *        and not whitespace). This will generate an error.
 384          */
 385 <HASH>define{HSPACE}* {
 386         if (! parser->skipping) {
 387                 BEGIN DEFINE;
 388                 yyextra->space_tokens = 0;
 389                 RETURN_TOKEN (DEFINE_TOKEN);
 390         }
 391 }
 392
 393 <HASH>undef {
 394         BEGIN INITIAL;
 395         yyextra->space_tokens = 0;
 396         RETURN_TOKEN (UNDEF);
 397 }
 398
 399 <HASH>{HSPACE}+ {
 400         /* Nothing to do here. Importantly, don't leave the <HASH>
 401          * start condition, since it's legal to have space between the
 402          * '#' and the directive.. */
 403 }
 404
 405         /* This will catch any non-directive garbage after a HASH */
 406 <HASH>{NONSPACE} {
 407         BEGIN INITIAL;
 408         RETURN_TOKEN (GARBAGE);
 409 }
 410
 411         /* An identifier immediately followed by '(' */
 412 <DEFINE>{IDENTIFIER}/"(" {
 413         BEGIN INITIAL;
 414         RETURN_STRING_TOKEN (FUNC_IDENTIFIER);
 415 }
 416
 417         /* An identifier not immediately followed by '(' */
 418 <DEFINE>{IDENTIFIER} {
 419         BEGIN INITIAL;
 420         RETURN_STRING_TOKEN (OBJ_IDENTIFIER);
 421 }
 422
 423         /* Whitespace */
 424 <DEFINE>{HSPACE}+ {
 425         /* Just ignore it. Nothing to do here. */
 426 }
 427
 428         /* '/' not followed by '*', so not a comment. This is an error. */
 429 <DEFINE>[/][^*]{NONSPACE}* {
 430         BEGIN INITIAL;
 431         glcpp_error(yylloc, yyextra, "#define followed by a non-identifier: %s", yytext);
 432         RETURN_STRING_TOKEN (INTEGER_STRING);
 433 }
 434
 435         /* A character that can't start an identifier, comment, or
 436          * space. This is an error. */
 437 <DEFINE>[^_a-zA-Z/[:space:]]{NONSPACE}* {
 438         BEGIN INITIAL;
 439         glcpp_error(yylloc, yyextra, "#define followed by a non-identifier: %s", yytext);
 440         RETURN_STRING_TOKEN (INTEGER_STRING);
 441 }
 442
 443 {DECIMAL_INTEGER} {
 444         RETURN_STRING_TOKEN (INTEGER_STRING);
 445 }
 446
 447 {OCTAL_INTEGER} {
 448         RETURN_STRING_TOKEN (INTEGER_STRING);
 449 }
 450
 451 {HEXADECIMAL_INTEGER} {
 452         RETURN_STRING_TOKEN (INTEGER_STRING);
 453 }
 454
 455 "<<"  {
 456         RETURN_TOKEN (LEFT_SHIFT);
 457 }
 458
 459 ">>" {
 460         RETURN_TOKEN (RIGHT_SHIFT);
 461 }
 462
 463 "<=" {
 464         RETURN_TOKEN (LESS_OR_EQUAL);
 465 }
 466
 467 ">=" {
 468         RETURN_TOKEN (GREATER_OR_EQUAL);
 469 }
 470
 471 "==" {
 472         RETURN_TOKEN (EQUAL);
 473 }
 474
 475 "!=" {
 476         RETURN_TOKEN (NOT_EQUAL);
 477 }
 478
 479 "&&" {
 480         RETURN_TOKEN (AND);
 481 }
 482
 483 "||" {
 484         RETURN_TOKEN (OR);
 485 }
 486
 487 "++" {
 488         RETURN_TOKEN (PLUS_PLUS);
 489 }
 490
 491 "--" {
 492         RETURN_TOKEN (MINUS_MINUS);
 493 }
 494
 495 "##" {
 496         if (! parser->skipping) {
 497                 if (parser->is_gles)
 498                         glcpp_error(yylloc, yyextra, "Token pasting (##) is illegal in GLES");
 499                 RETURN_TOKEN (PASTE);
 500         }
 501 }
 502
 503 "defined" {
 504         RETURN_TOKEN (DEFINED);
 505 }
 506
 507 {IDENTIFIER} {
 508         RETURN_STRING_TOKEN (IDENTIFIER);
 509 }
 510
 511 {PP_NUMBER} {
 512         RETURN_STRING_TOKEN (OTHER);
 513 }
 514
 515 {PUNCTUATION} {
 516         RETURN_TOKEN (yytext[0]);
 517 }
 518
 519 {OTHER}+ {
 520         RETURN_STRING_TOKEN (OTHER);
 521 }
 522
 523 {HSPACE} {
 524         if (yyextra->space_tokens) {
 525                 RETURN_TOKEN (SPACE);
 526         }
 527 }
 528
 529         /* We preserve all newlines, even between #if 0..#endif, so no
 530         skipping.. */
 531 <*>{NEWLINE} {
 532         if (parser->commented_newlines) {
 533                 BEGIN NEWLINE_CATCHUP;
 534         } else {
 535                 BEGIN INITIAL;
 536         }
 537         yyextra->space_tokens = 1;
 538         yyextra->lexing_directive = 0;
 539         yylineno++;
 540         yycolumn = 0;
 541         RETURN_TOKEN_NEVER_SKIP (NEWLINE);
 542 }
 543
 544 <INITIAL,COMMENT,DEFINE,HASH><<EOF>> {
 545         if (YY_START == COMMENT)
 546                 glcpp_error(yylloc, yyextra, "Unterminated comment");
 547         BEGIN DONE; /* Don't keep matching this rule forever. */
 548         yyextra->lexing_directive = 0;
 549         if (! parser->last_token_was_newline)
 550                 RETURN_TOKEN (NEWLINE);
 551 }
 552
 553         /* This is a catch-all to avoid the annoying default flex action which
 554          * matches any character and prints it. If any input ever matches this
 555          * rule, then we have made a mistake above and need to fix one or more
 556          * of the preceding patterns to match that input. */
 557
 558 <*>. {
 559         glcpp_error(yylloc, yyextra, "Internal compiler error: Unexpected character: %s", yytext);
 560
 561         /* We don't actually use the UNREACHABLE start condition. We
 562         only have this block here so that we can pretend to call some
 563         generated functions, (to avoid "defined but not used"
 564         warnings. */
 565         if (YY_START == UNREACHABLE) {
 566                 unput('.');
 567                 yy_top_state(yyextra);
 568         }
 569 }
 570
 571 %%
 572
 573 void
 574 glcpp_lex_set_source_string(glcpp_parser_t *parser, const char *shader)
 575 {
 576         yy_scan_string(shader, parser->scanner);
 577 }