benchmarks/common/test.ld

   1 /*======================================================================*/
   2 /* Proxy kernel linker script                                           */
   3 /*======================================================================*/
   4 /* This is the linker script used when building the proxy kernel. */
   5
   6 /*----------------------------------------------------------------------*/
   7 /* Setup                                                                */
   8 /*----------------------------------------------------------------------*/
   9
  10 /* The OUTPUT_ARCH command specifies the machine architecture where the
  11    argument is one of the names used in the BFD library. More
  12    specifically one of the entires in bfd/cpu-mips.c */
  13
  14 OUTPUT_ARCH( "riscv" )
  15 ENTRY(_start)
  16
  17 /*----------------------------------------------------------------------*/
  18 /* Sections                                                             */
  19 /*----------------------------------------------------------------------*/
  20
  21 SECTIONS
  22 {
  23
  24   /* text: test code section */
  25   . = 0x80000000;
  26   .text.init : { *(.text.init) }
  27
  28   . = ALIGN(0x1000);
  29   .tohost : { *(.tohost) }
  30
  31   .text : { *(.text) }
  32
  33   /* data segment */
  34   .data : { *(.data) }
  35
  36   .sdata : {
  37     __global_pointer$ = . + 0x800;
  38     *(.srodata.cst16) *(.srodata.cst8) *(.srodata.cst4) *(.srodata.cst2) *(.srodata*)
  39     *(.sdata .sdata.* .gnu.linkonce.s.*)
  40   }
  41
  42   /* bss segment */
  43   .sbss : {
  44     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  45     *(.scommon)
  46   }
  47   .bss : { *(.bss) }
  48
  49   /* thread-local data segment */
  50   .tdata :
  51   {
  52     _tls_data = .;
  53     *(.tdata.begin)
  54     *(.tdata)
  55     *(.tdata.end)
  56   }
  57   .tbss :
  58   {
  59     *(.tbss)
  60     *(.tbss.end)
  61   }
  62
  63   /* End of uninitalized data segement */
  64   _end = .;
  65 }
  66