isa/rv64si/csr.S

   1 # See LICENSE for license details.
   2
   3 #*****************************************************************************
   4 # csr.S
   5 #-----------------------------------------------------------------------------
   6 #
   7 # Test CSRRx and CSRRxI instructions.
   8 #
   9
  10 #include "riscv_test.h"
  11 #include "test_macros.h"
  12
  13 RVTEST_RV64S
  14 RVTEST_CODE_BEGIN
  15
  16 #ifdef __MACHINE_MODE
  17   #define sscratch mscratch
  18   #define sstatus mstatus
  19   #define scause mcause
  20   #define sepc mepc
  21   #define stvec_handler mtvec_handler
  22   #undef SSTATUS_SPP
  23   #define SSTATUS_SPP MSTATUS_MPP
  24 #endif
  25
  26   csrwi sscratch, 3
  27   TEST_CASE( 2, a0,         3, csrr a0, sscratch);
  28   TEST_CASE( 3, a1,         3, csrrci a1, sscratch, 1);
  29   TEST_CASE( 4, a2,         2, csrrsi a2, sscratch, 4);
  30   TEST_CASE( 5, a3,         6, csrrwi a3, sscratch, 2);
  31   TEST_CASE( 6, a1,         2, li a0, 0xbad1dea; csrrw a1, sscratch, a0);
  32   TEST_CASE( 7, a0, 0xbad1dea, li a0, 0x0001dea; csrrc a0, sscratch, a0);
  33   TEST_CASE( 8, a0, 0xbad0000, li a0, 0x000beef; csrrs a0, sscratch, a0);
  34   TEST_CASE( 9, a0, 0xbadbeef, csrr a0, sscratch);
  35
  36   # Make sure writing the cycle counter causes an exception.
  37   TEST_CASE(10, a0, 255, li a0, 255; csrrw a0, cycle, x0);
  38
  39   # jump to user land
  40   li t0, SSTATUS_SPP
  41   csrc sstatus, t0
  42   la t0, 1f
  43   csrw sepc, t0
  44   sret
  45   1:
  46
  47   # Make sure reading status in user mode causes an exception.
  48   TEST_CASE(11, a0, 255, li a0, 255; csrr a0, sstatus);
  49
  50   # Exit by doing a syscall.
  51   TEST_CASE(12, x0, 1, scall)
  52
  53   # We should only fall through to this if scall failed.
  54   TEST_PASSFAIL
  55
  56 stvec_handler:
  57   # Trapping on tests 11 and 12 is usually good news.
  58   # Note that since the test didn't complete, TESTNUM is smaller by 1.
  59   li t0, 9
  60   beq TESTNUM, t0, privileged
  61   li t0, 10
  62   beq TESTNUM, t0, privileged
  63   li t0, 11
  64   beq TESTNUM, t0, syscall
  65
  66   # Trapping on other tests is bad news.
  67   j fail
  68
  69 privileged:
  70   # Make sure scause indicates a lack of privilege.
  71   csrr t0, scause
  72   li t1, CAUSE_ILLEGAL_INSTRUCTION
  73   bne t0, t1, fail
  74   # Return to user mode, but skip the trapping instruction.
  75   csrr t0, sepc
  76   addi t0, t0, 4
  77   csrw sepc, t0
  78   sret
  79
  80 syscall:
  81   # Make sure scause indicates a syscall.
  82   csrr t0, scause
  83   li t1, CAUSE_USER_ECALL
  84   bne t0, t1, fail
  85
  86   # We're done.
  87   j pass
  88
  89 RVTEST_CODE_END
  90
  91   .data
  92 RVTEST_DATA_BEGIN
  93
  94   TEST_DATA
  95
  96 RVTEST_DATA_END