src/compiler/glsl/glsl_parser.yy

   1 %{
   2 /*
   3  * Copyright © 2008, 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <string.h>
  27 #ifndef _MSC_VER
  28 #include <strings.h>
  29 #endif
  30 #include <assert.h>
  31
  32 #include "ast.h"
  33 #include "glsl_parser_extras.h"
  34 #include "compiler/glsl_types.h"
  35 #include "main/context.h"
  36
  37 #ifdef _MSC_VER
  38 #pragma warning( disable : 4065 ) // switch statement contains 'default' but no 'case' labels
  39 #endif
  40
  41 #undef yyerror
  42
  43 static void yyerror(YYLTYPE *loc, _mesa_glsl_parse_state *st, const char *msg)
  44 {
  45    _mesa_glsl_error(loc, st, "%s", msg);
  46 }
  47
  48 static int
  49 _mesa_glsl_lex(YYSTYPE *val, YYLTYPE *loc, _mesa_glsl_parse_state *state)
  50 {
  51    return _mesa_glsl_lexer_lex(val, loc, state->scanner);
  52 }
  53
  54 static bool match_layout_qualifier(const char *s1, const char *s2,
  55                                    _mesa_glsl_parse_state *state)
  56 {
  57    /* From the GLSL 1.50 spec, section 4.3.8 (Layout Qualifiers):
  58     *
  59     *     "The tokens in any layout-qualifier-id-list ... are not case
  60     *     sensitive, unless explicitly noted otherwise."
  61     *
  62     * The text "unless explicitly noted otherwise" appears to be
  63     * vacuous--no desktop GLSL spec (up through GLSL 4.40) notes
  64     * otherwise.
  65     *
  66     * However, the GLSL ES 3.00 spec says, in section 4.3.8 (Layout
  67     * Qualifiers):
  68     *
  69     *     "As for other identifiers, they are case sensitive."
  70     *
  71     * So we need to do a case-sensitive or a case-insensitive match,
  72     * depending on whether we are compiling for GLSL ES.
  73     */
  74    if (state->es_shader)
  75       return strcmp(s1, s2);
  76    else
  77       return strcasecmp(s1, s2);
  78 }
  79 %}
  80
  81 %expect 0
  82
  83 %pure-parser
  84 %error-verbose
  85
  86 %locations
  87 %initial-action {
  88    @$.first_line = 1;
  89    @$.first_column = 1;
  90    @$.last_line = 1;
  91    @$.last_column = 1;
  92    @$.source = 0;
  93 }
  94
  95 %lex-param   {struct _mesa_glsl_parse_state *state}
  96 %parse-param {struct _mesa_glsl_parse_state *state}
  97
  98 %union {
  99    int n;
 100    float real;
 101    double dreal;
 102    const char *identifier;
 103
 104    struct ast_type_qualifier type_qualifier;
 105
 106    ast_node *node;
 107    ast_type_specifier *type_specifier;
 108    ast_array_specifier *array_specifier;
 109    ast_fully_specified_type *fully_specified_type;
 110    ast_function *function;
 111    ast_parameter_declarator *parameter_declarator;
 112    ast_function_definition *function_definition;
 113    ast_compound_statement *compound_statement;
 114    ast_expression *expression;
 115    ast_declarator_list *declarator_list;
 116    ast_struct_specifier *struct_specifier;
 117    ast_declaration *declaration;
 118    ast_switch_body *switch_body;
 119    ast_case_label *case_label;
 120    ast_case_label_list *case_label_list;
 121    ast_case_statement *case_statement;
 122    ast_case_statement_list *case_statement_list;
 123    ast_interface_block *interface_block;
 124    ast_subroutine_list *subroutine_list;
 125    struct {
 126       ast_node *cond;
 127       ast_expression *rest;
 128    } for_rest_statement;
 129
 130    struct {
 131       ast_node *then_statement;
 132       ast_node *else_statement;
 133    } selection_rest_statement;
 134 }
 135
 136 %token ATTRIBUTE CONST_TOK BOOL_TOK FLOAT_TOK INT_TOK UINT_TOK DOUBLE_TOK
 137 %token BREAK BUFFER CONTINUE DO ELSE FOR IF DISCARD RETURN SWITCH CASE DEFAULT
 138 %token BVEC2 BVEC3 BVEC4 IVEC2 IVEC3 IVEC4 UVEC2 UVEC3 UVEC4 VEC2 VEC3 VEC4 DVEC2 DVEC3 DVEC4
 139 %token CENTROID IN_TOK OUT_TOK INOUT_TOK UNIFORM VARYING SAMPLE
 140 %token NOPERSPECTIVE FLAT SMOOTH
 141 %token MAT2X2 MAT2X3 MAT2X4
 142 %token MAT3X2 MAT3X3 MAT3X4
 143 %token MAT4X2 MAT4X3 MAT4X4
 144 %token DMAT2X2 DMAT2X3 DMAT2X4
 145 %token DMAT3X2 DMAT3X3 DMAT3X4
 146 %token DMAT4X2 DMAT4X3 DMAT4X4
 147 %token SAMPLER1D SAMPLER2D SAMPLER3D SAMPLERCUBE SAMPLER1DSHADOW SAMPLER2DSHADOW
 148 %token SAMPLERCUBESHADOW SAMPLER1DARRAY SAMPLER2DARRAY SAMPLER1DARRAYSHADOW
 149 %token SAMPLER2DARRAYSHADOW SAMPLERCUBEARRAY SAMPLERCUBEARRAYSHADOW
 150 %token ISAMPLER1D ISAMPLER2D ISAMPLER3D ISAMPLERCUBE
 151 %token ISAMPLER1DARRAY ISAMPLER2DARRAY ISAMPLERCUBEARRAY
 152 %token USAMPLER1D USAMPLER2D USAMPLER3D USAMPLERCUBE USAMPLER1DARRAY
 153 %token USAMPLER2DARRAY USAMPLERCUBEARRAY
 154 %token SAMPLER2DRECT ISAMPLER2DRECT USAMPLER2DRECT SAMPLER2DRECTSHADOW
 155 %token SAMPLERBUFFER ISAMPLERBUFFER USAMPLERBUFFER
 156 %token SAMPLER2DMS ISAMPLER2DMS USAMPLER2DMS
 157 %token SAMPLER2DMSARRAY ISAMPLER2DMSARRAY USAMPLER2DMSARRAY
 158 %token SAMPLEREXTERNALOES
 159 %token IMAGE1D IMAGE2D IMAGE3D IMAGE2DRECT IMAGECUBE IMAGEBUFFER
 160 %token IMAGE1DARRAY IMAGE2DARRAY IMAGECUBEARRAY IMAGE2DMS IMAGE2DMSARRAY
 161 %token IIMAGE1D IIMAGE2D IIMAGE3D IIMAGE2DRECT IIMAGECUBE IIMAGEBUFFER
 162 %token IIMAGE1DARRAY IIMAGE2DARRAY IIMAGECUBEARRAY IIMAGE2DMS IIMAGE2DMSARRAY
 163 %token UIMAGE1D UIMAGE2D UIMAGE3D UIMAGE2DRECT UIMAGECUBE UIMAGEBUFFER
 164 %token UIMAGE1DARRAY UIMAGE2DARRAY UIMAGECUBEARRAY UIMAGE2DMS UIMAGE2DMSARRAY
 165 %token IMAGE1DSHADOW IMAGE2DSHADOW IMAGE1DARRAYSHADOW IMAGE2DARRAYSHADOW
 166 %token COHERENT VOLATILE RESTRICT READONLY WRITEONLY
 167 %token ATOMIC_UINT
 168 %token SHARED
 169 %token STRUCT VOID_TOK WHILE
 170 %token <identifier> IDENTIFIER TYPE_IDENTIFIER NEW_IDENTIFIER
 171 %type <identifier> any_identifier
 172 %type <interface_block> instance_name_opt
 173 %token <real> FLOATCONSTANT
 174 %token <dreal> DOUBLECONSTANT
 175 %token <n> INTCONSTANT UINTCONSTANT BOOLCONSTANT
 176 %token <identifier> FIELD_SELECTION
 177 %token LEFT_OP RIGHT_OP
 178 %token INC_OP DEC_OP LE_OP GE_OP EQ_OP NE_OP
 179 %token AND_OP OR_OP XOR_OP MUL_ASSIGN DIV_ASSIGN ADD_ASSIGN
 180 %token MOD_ASSIGN LEFT_ASSIGN RIGHT_ASSIGN AND_ASSIGN XOR_ASSIGN OR_ASSIGN
 181 %token SUB_ASSIGN
 182 %token INVARIANT PRECISE
 183 %token LOWP MEDIUMP HIGHP SUPERP PRECISION
 184
 185 %token VERSION_TOK EXTENSION LINE COLON EOL INTERFACE OUTPUT
 186 %token PRAGMA_DEBUG_ON PRAGMA_DEBUG_OFF
 187 %token PRAGMA_OPTIMIZE_ON PRAGMA_OPTIMIZE_OFF
 188 %token PRAGMA_INVARIANT_ALL
 189 %token LAYOUT_TOK
 190 %token DOT_TOK
 191    /* Reserved words that are not actually used in the grammar.
 192     */
 193 %token ASM CLASS UNION ENUM TYPEDEF TEMPLATE THIS PACKED_TOK GOTO
 194 %token INLINE_TOK NOINLINE PUBLIC_TOK STATIC EXTERN EXTERNAL
 195 %token LONG_TOK SHORT_TOK HALF FIXED_TOK UNSIGNED INPUT_TOK
 196 %token HVEC2 HVEC3 HVEC4 FVEC2 FVEC3 FVEC4
 197 %token SAMPLER3DRECT
 198 %token SIZEOF CAST NAMESPACE USING
 199 %token RESOURCE PATCH
 200 %token SUBROUTINE
 201
 202 %token ERROR_TOK
 203
 204 %token COMMON PARTITION ACTIVE FILTER ROW_MAJOR
 205
 206 %type <identifier> variable_identifier
 207 %type <node> statement
 208 %type <node> statement_list
 209 %type <node> simple_statement
 210 %type <n> precision_qualifier
 211 %type <type_qualifier> type_qualifier
 212 %type <type_qualifier> auxiliary_storage_qualifier
 213 %type <type_qualifier> storage_qualifier
 214 %type <type_qualifier> interpolation_qualifier
 215 %type <type_qualifier> layout_qualifier
 216 %type <type_qualifier> layout_qualifier_id_list layout_qualifier_id
 217 %type <type_qualifier> interface_block_layout_qualifier
 218 %type <type_qualifier> memory_qualifier
 219 %type <type_qualifier> subroutine_qualifier
 220 %type <subroutine_list> subroutine_type_list
 221 %type <type_qualifier> interface_qualifier
 222 %type <type_specifier> type_specifier
 223 %type <type_specifier> type_specifier_nonarray
 224 %type <array_specifier> array_specifier
 225 %type <identifier> basic_type_specifier_nonarray
 226 %type <fully_specified_type> fully_specified_type
 227 %type <function> function_prototype
 228 %type <function> function_header
 229 %type <function> function_header_with_parameters
 230 %type <function> function_declarator
 231 %type <parameter_declarator> parameter_declarator
 232 %type <parameter_declarator> parameter_declaration
 233 %type <type_qualifier> parameter_qualifier
 234 %type <type_qualifier> parameter_direction_qualifier
 235 %type <type_specifier> parameter_type_specifier
 236 %type <function_definition> function_definition
 237 %type <compound_statement> compound_statement_no_new_scope
 238 %type <compound_statement> compound_statement
 239 %type <node> statement_no_new_scope
 240 %type <node> expression_statement
 241 %type <expression> expression
 242 %type <expression> primary_expression
 243 %type <expression> assignment_expression
 244 %type <expression> conditional_expression
 245 %type <expression> logical_or_expression
 246 %type <expression> logical_xor_expression
 247 %type <expression> logical_and_expression
 248 %type <expression> inclusive_or_expression
 249 %type <expression> exclusive_or_expression
 250 %type <expression> and_expression
 251 %type <expression> equality_expression
 252 %type <expression> relational_expression
 253 %type <expression> shift_expression
 254 %type <expression> additive_expression
 255 %type <expression> multiplicative_expression
 256 %type <expression> unary_expression
 257 %type <expression> constant_expression
 258 %type <expression> integer_expression
 259 %type <expression> postfix_expression
 260 %type <expression> function_call_header_with_parameters
 261 %type <expression> function_call_header_no_parameters
 262 %type <expression> function_call_header
 263 %type <expression> function_call_generic
 264 %type <expression> function_call_or_method
 265 %type <expression> function_call
 266 %type <n> assignment_operator
 267 %type <n> unary_operator
 268 %type <expression> function_identifier
 269 %type <node> external_declaration
 270 %type <declarator_list> init_declarator_list
 271 %type <declarator_list> single_declaration
 272 %type <expression> initializer
 273 %type <expression> initializer_list
 274 %type <node> declaration
 275 %type <node> declaration_statement
 276 %type <node> jump_statement
 277 %type <node> interface_block
 278 %type <interface_block> basic_interface_block
 279 %type <struct_specifier> struct_specifier
 280 %type <declarator_list> struct_declaration_list
 281 %type <declarator_list> struct_declaration
 282 %type <declaration> struct_declarator
 283 %type <declaration> struct_declarator_list
 284 %type <declarator_list> member_list
 285 %type <declarator_list> member_declaration
 286 %type <node> selection_statement
 287 %type <selection_rest_statement> selection_rest_statement
 288 %type <node> switch_statement
 289 %type <switch_body> switch_body
 290 %type <case_label_list> case_label_list
 291 %type <case_label> case_label
 292 %type <case_statement> case_statement
 293 %type <case_statement_list> case_statement_list
 294 %type <node> iteration_statement
 295 %type <node> condition
 296 %type <node> conditionopt
 297 %type <node> for_init_statement
 298 %type <for_rest_statement> for_rest_statement
 299 %type <node> layout_defaults
 300 %type <node> layout_uniform_defaults
 301 %type <node> layout_buffer_defaults
 302 %type <node> layout_in_defaults
 303 %type <node> layout_out_defaults
 304
 305 %right THEN ELSE
 306 %%
 307
 308 translation_unit:
 309    version_statement extension_statement_list
 310    {
 311       _mesa_glsl_initialize_types(state);
 312    }
 313    external_declaration_list
 314    {
 315       delete state->symbols;
 316       state->symbols = new(ralloc_parent(state)) glsl_symbol_table;
 317       if (state->es_shader) {
 318          if (state->stage == MESA_SHADER_FRAGMENT) {
 319             state->symbols->add_default_precision_qualifier("int", ast_precision_medium);
 320          } else {
 321             state->symbols->add_default_precision_qualifier("float", ast_precision_high);
 322             state->symbols->add_default_precision_qualifier("int", ast_precision_high);
 323          }
 324          state->symbols->add_default_precision_qualifier("sampler2D", ast_precision_low);
 325          state->symbols->add_default_precision_qualifier("samplerExternalOES", ast_precision_low);
 326          state->symbols->add_default_precision_qualifier("samplerCube", ast_precision_low);
 327          state->symbols->add_default_precision_qualifier("atomic_uint", ast_precision_high);
 328       }
 329       _mesa_glsl_initialize_types(state);
 330    }
 331    ;
 332
 333 version_statement:
 334    /* blank - no #version specified: defaults are already set */
 335    | VERSION_TOK INTCONSTANT EOL
 336    {
 337       state->process_version_directive(&@2, $2, NULL);
 338       if (state->error) {
 339          YYERROR;
 340       }
 341    }
 342    | VERSION_TOK INTCONSTANT any_identifier EOL
 343    {
 344       state->process_version_directive(&@2, $2, $3);
 345       if (state->error) {
 346          YYERROR;
 347       }
 348    }
 349    ;
 350
 351 pragma_statement:
 352    PRAGMA_DEBUG_ON EOL
 353    | PRAGMA_DEBUG_OFF EOL
 354    | PRAGMA_OPTIMIZE_ON EOL
 355    | PRAGMA_OPTIMIZE_OFF EOL
 356    | PRAGMA_INVARIANT_ALL EOL
 357    {
 358       /* Pragma invariant(all) cannot be used in a fragment shader.
 359        *
 360        * Page 27 of the GLSL 1.20 spec, Page 53 of the GLSL ES 3.00 spec:
 361        *
 362        *     "It is an error to use this pragma in a fragment shader."
 363        */
 364       if (state->is_version(120, 300) &&
 365           state->stage == MESA_SHADER_FRAGMENT) {
 366          _mesa_glsl_error(& @1, state,
 367                           "pragma `invariant(all)' cannot be used "
 368                           "in a fragment shader.");
 369       } else if (!state->is_version(120, 100)) {
 370          _mesa_glsl_warning(& @1, state,
 371                             "pragma `invariant(all)' not supported in %s "
 372                             "(GLSL ES 1.00 or GLSL 1.20 required)",
 373                             state->get_version_string());
 374       } else {
 375          state->all_invariant = true;
 376       }
 377    }
 378    ;
 379
 380 extension_statement_list:
 381
 382    | extension_statement_list extension_statement
 383    ;
 384
 385 any_identifier:
 386    IDENTIFIER
 387    | TYPE_IDENTIFIER
 388    | NEW_IDENTIFIER
 389    ;
 390
 391 extension_statement:
 392    EXTENSION any_identifier COLON any_identifier EOL
 393    {
 394       if (!_mesa_glsl_process_extension($2, & @2, $4, & @4, state)) {
 395          YYERROR;
 396       }
 397    }
 398    ;
 399
 400 external_declaration_list:
 401    external_declaration
 402    {
 403       /* FINISHME: The NULL test is required because pragmas are set to
 404        * FINISHME: NULL. (See production rule for external_declaration.)
 405        */
 406       if ($1 != NULL)
 407          state->translation_unit.push_tail(& $1->link);
 408    }
 409    | external_declaration_list external_declaration
 410    {
 411       /* FINISHME: The NULL test is required because pragmas are set to
 412        * FINISHME: NULL. (See production rule for external_declaration.)
 413        */
 414       if ($2 != NULL)
 415          state->translation_unit.push_tail(& $2->link);
 416    }
 417    | external_declaration_list extension_statement {
 418       if (!state->allow_extension_directive_midshader) {
 419          _mesa_glsl_error(& @2, state,
 420                           "#extension directive is not allowed "
 421                           "in the middle of a shader");
 422          YYERROR;
 423       }
 424    }
 425    ;
 426
 427 variable_identifier:
 428    IDENTIFIER
 429    | NEW_IDENTIFIER
 430    ;
 431
 432 primary_expression:
 433    variable_identifier
 434    {
 435       void *ctx = state->linalloc;
 436       $$ = new(ctx) ast_expression(ast_identifier, NULL, NULL, NULL);
 437       $$->set_location(@1);
 438       $$->primary_expression.identifier = $1;
 439    }
 440    | INTCONSTANT
 441    {
 442       void *ctx = state->linalloc;
 443       $$ = new(ctx) ast_expression(ast_int_constant, NULL, NULL, NULL);
 444       $$->set_location(@1);
 445       $$->primary_expression.int_constant = $1;
 446    }
 447    | UINTCONSTANT
 448    {
 449       void *ctx = state->linalloc;
 450       $$ = new(ctx) ast_expression(ast_uint_constant, NULL, NULL, NULL);
 451       $$->set_location(@1);
 452       $$->primary_expression.uint_constant = $1;
 453    }
 454    | FLOATCONSTANT
 455    {
 456       void *ctx = state->linalloc;
 457       $$ = new(ctx) ast_expression(ast_float_constant, NULL, NULL, NULL);
 458       $$->set_location(@1);
 459       $$->primary_expression.float_constant = $1;
 460    }
 461    | DOUBLECONSTANT
 462    {
 463       void *ctx = state->linalloc;
 464       $$ = new(ctx) ast_expression(ast_double_constant, NULL, NULL, NULL);
 465       $$->set_location(@1);
 466       $$->primary_expression.double_constant = $1;
 467    }
 468    | BOOLCONSTANT
 469    {
 470       void *ctx = state->linalloc;
 471       $$ = new(ctx) ast_expression(ast_bool_constant, NULL, NULL, NULL);
 472       $$->set_location(@1);
 473       $$->primary_expression.bool_constant = $1;
 474    }
 475    | '(' expression ')'
 476    {
 477       $$ = $2;
 478    }
 479    ;
 480
 481 postfix_expression:
 482    primary_expression
 483    | postfix_expression '[' integer_expression ']'
 484    {
 485       void *ctx = state->linalloc;
 486       $$ = new(ctx) ast_expression(ast_array_index, $1, $3, NULL);
 487       $$->set_location_range(@1, @4);
 488    }
 489    | function_call
 490    {
 491       $$ = $1;
 492    }
 493    | postfix_expression DOT_TOK FIELD_SELECTION
 494    {
 495       void *ctx = state->linalloc;
 496       $$ = new(ctx) ast_expression(ast_field_selection, $1, NULL, NULL);
 497       $$->set_location_range(@1, @3);
 498       $$->primary_expression.identifier = $3;
 499    }
 500    | postfix_expression INC_OP
 501    {
 502       void *ctx = state->linalloc;
 503       $$ = new(ctx) ast_expression(ast_post_inc, $1, NULL, NULL);
 504       $$->set_location_range(@1, @2);
 505    }
 506    | postfix_expression DEC_OP
 507    {
 508       void *ctx = state->linalloc;
 509       $$ = new(ctx) ast_expression(ast_post_dec, $1, NULL, NULL);
 510       $$->set_location_range(@1, @2);
 511    }
 512    ;
 513
 514 integer_expression:
 515    expression
 516    ;
 517
 518 function_call:
 519    function_call_or_method
 520    ;
 521
 522 function_call_or_method:
 523    function_call_generic
 524    ;
 525
 526 function_call_generic:
 527    function_call_header_with_parameters ')'
 528    | function_call_header_no_parameters ')'
 529    ;
 530
 531 function_call_header_no_parameters:
 532    function_call_header VOID_TOK
 533    | function_call_header
 534    ;
 535
 536 function_call_header_with_parameters:
 537    function_call_header assignment_expression
 538    {
 539       $$ = $1;
 540       $$->set_location(@1);
 541       $$->expressions.push_tail(& $2->link);
 542    }
 543    | function_call_header_with_parameters ',' assignment_expression
 544    {
 545       $$ = $1;
 546       $$->set_location(@1);
 547       $$->expressions.push_tail(& $3->link);
 548    }
 549    ;
 550
 551    // Grammar Note: Constructors look like functions, but lexical
 552    // analysis recognized most of them as keywords. They are now
 553    // recognized through "type_specifier".
 554 function_call_header:
 555    function_identifier '('
 556    ;
 557
 558 function_identifier:
 559    type_specifier
 560    {
 561       void *ctx = state->linalloc;
 562       $$ = new(ctx) ast_function_expression($1);
 563       $$->set_location(@1);
 564       }
 565    | postfix_expression
 566    {
 567       void *ctx = state->linalloc;
 568       $$ = new(ctx) ast_function_expression($1);
 569       $$->set_location(@1);
 570       }
 571    ;
 572
 573    // Grammar Note: Constructors look like methods, but lexical
 574    // analysis recognized most of them as keywords. They are now
 575    // recognized through "type_specifier".
 576
 577    // Grammar Note: No traditional style type casts.
 578 unary_expression:
 579    postfix_expression
 580    | INC_OP unary_expression
 581    {
 582       void *ctx = state->linalloc;
 583       $$ = new(ctx) ast_expression(ast_pre_inc, $2, NULL, NULL);
 584       $$->set_location(@1);
 585    }
 586    | DEC_OP unary_expression
 587    {
 588       void *ctx = state->linalloc;
 589       $$ = new(ctx) ast_expression(ast_pre_dec, $2, NULL, NULL);
 590       $$->set_location(@1);
 591    }
 592    | unary_operator unary_expression
 593    {
 594       void *ctx = state->linalloc;
 595       $$ = new(ctx) ast_expression($1, $2, NULL, NULL);
 596       $$->set_location_range(@1, @2);
 597    }
 598    ;
 599
 600    // Grammar Note: No '*' or '&' unary ops. Pointers are not supported.
 601 unary_operator:
 602    '+'   { $$ = ast_plus; }
 603    | '-' { $$ = ast_neg; }
 604    | '!' { $$ = ast_logic_not; }
 605    | '~' { $$ = ast_bit_not; }
 606    ;
 607
 608 multiplicative_expression:
 609    unary_expression
 610    | multiplicative_expression '*' unary_expression
 611    {
 612       void *ctx = state->linalloc;
 613       $$ = new(ctx) ast_expression_bin(ast_mul, $1, $3);
 614       $$->set_location_range(@1, @3);
 615    }
 616    | multiplicative_expression '/' unary_expression
 617    {
 618       void *ctx = state->linalloc;
 619       $$ = new(ctx) ast_expression_bin(ast_div, $1, $3);
 620       $$->set_location_range(@1, @3);
 621    }
 622    | multiplicative_expression '%' unary_expression
 623    {
 624       void *ctx = state->linalloc;
 625       $$ = new(ctx) ast_expression_bin(ast_mod, $1, $3);
 626       $$->set_location_range(@1, @3);
 627    }
 628    ;
 629
 630 additive_expression:
 631    multiplicative_expression
 632    | additive_expression '+' multiplicative_expression
 633    {
 634       void *ctx = state->linalloc;
 635       $$ = new(ctx) ast_expression_bin(ast_add, $1, $3);
 636       $$->set_location_range(@1, @3);
 637    }
 638    | additive_expression '-' multiplicative_expression
 639    {
 640       void *ctx = state->linalloc;
 641       $$ = new(ctx) ast_expression_bin(ast_sub, $1, $3);
 642       $$->set_location_range(@1, @3);
 643    }
 644    ;
 645
 646 shift_expression:
 647    additive_expression
 648    | shift_expression LEFT_OP additive_expression
 649    {
 650       void *ctx = state->linalloc;
 651       $$ = new(ctx) ast_expression_bin(ast_lshift, $1, $3);
 652       $$->set_location_range(@1, @3);
 653    }
 654    | shift_expression RIGHT_OP additive_expression
 655    {
 656       void *ctx = state->linalloc;
 657       $$ = new(ctx) ast_expression_bin(ast_rshift, $1, $3);
 658       $$->set_location_range(@1, @3);
 659    }
 660    ;
 661
 662 relational_expression:
 663    shift_expression
 664    | relational_expression '<' shift_expression
 665    {
 666       void *ctx = state->linalloc;
 667       $$ = new(ctx) ast_expression_bin(ast_less, $1, $3);
 668       $$->set_location_range(@1, @3);
 669    }
 670    | relational_expression '>' shift_expression
 671    {
 672       void *ctx = state->linalloc;
 673       $$ = new(ctx) ast_expression_bin(ast_greater, $1, $3);
 674       $$->set_location_range(@1, @3);
 675    }
 676    | relational_expression LE_OP shift_expression
 677    {
 678       void *ctx = state->linalloc;
 679       $$ = new(ctx) ast_expression_bin(ast_lequal, $1, $3);
 680       $$->set_location_range(@1, @3);
 681    }
 682    | relational_expression GE_OP shift_expression
 683    {
 684       void *ctx = state->linalloc;
 685       $$ = new(ctx) ast_expression_bin(ast_gequal, $1, $3);
 686       $$->set_location_range(@1, @3);
 687    }
 688    ;
 689
 690 equality_expression:
 691    relational_expression
 692    | equality_expression EQ_OP relational_expression
 693    {
 694       void *ctx = state->linalloc;
 695       $$ = new(ctx) ast_expression_bin(ast_equal, $1, $3);
 696       $$->set_location_range(@1, @3);
 697    }
 698    | equality_expression NE_OP relational_expression
 699    {
 700       void *ctx = state->linalloc;
 701       $$ = new(ctx) ast_expression_bin(ast_nequal, $1, $3);
 702       $$->set_location_range(@1, @3);
 703    }
 704    ;
 705
 706 and_expression:
 707    equality_expression
 708    | and_expression '&' equality_expression
 709    {
 710       void *ctx = state->linalloc;
 711       $$ = new(ctx) ast_expression_bin(ast_bit_and, $1, $3);
 712       $$->set_location_range(@1, @3);
 713    }
 714    ;
 715
 716 exclusive_or_expression:
 717    and_expression
 718    | exclusive_or_expression '^' and_expression
 719    {
 720       void *ctx = state->linalloc;
 721       $$ = new(ctx) ast_expression_bin(ast_bit_xor, $1, $3);
 722       $$->set_location_range(@1, @3);
 723    }
 724    ;
 725
 726 inclusive_or_expression:
 727    exclusive_or_expression
 728    | inclusive_or_expression '|' exclusive_or_expression
 729    {
 730       void *ctx = state->linalloc;
 731       $$ = new(ctx) ast_expression_bin(ast_bit_or, $1, $3);
 732       $$->set_location_range(@1, @3);
 733    }
 734    ;
 735
 736 logical_and_expression:
 737    inclusive_or_expression
 738    | logical_and_expression AND_OP inclusive_or_expression
 739    {
 740       void *ctx = state->linalloc;
 741       $$ = new(ctx) ast_expression_bin(ast_logic_and, $1, $3);
 742       $$->set_location_range(@1, @3);
 743    }
 744    ;
 745
 746 logical_xor_expression:
 747    logical_and_expression
 748    | logical_xor_expression XOR_OP logical_and_expression
 749    {
 750       void *ctx = state->linalloc;
 751       $$ = new(ctx) ast_expression_bin(ast_logic_xor, $1, $3);
 752       $$->set_location_range(@1, @3);
 753    }
 754    ;
 755
 756 logical_or_expression:
 757    logical_xor_expression
 758    | logical_or_expression OR_OP logical_xor_expression
 759    {
 760       void *ctx = state->linalloc;
 761       $$ = new(ctx) ast_expression_bin(ast_logic_or, $1, $3);
 762       $$->set_location_range(@1, @3);
 763    }
 764    ;
 765
 766 conditional_expression:
 767    logical_or_expression
 768    | logical_or_expression '?' expression ':' assignment_expression
 769    {
 770       void *ctx = state->linalloc;
 771       $$ = new(ctx) ast_expression(ast_conditional, $1, $3, $5);
 772       $$->set_location_range(@1, @5);
 773    }
 774    ;
 775
 776 assignment_expression:
 777    conditional_expression
 778    | unary_expression assignment_operator assignment_expression
 779    {
 780       void *ctx = state->linalloc;
 781       $$ = new(ctx) ast_expression($2, $1, $3, NULL);
 782       $$->set_location_range(@1, @3);
 783    }
 784    ;
 785
 786 assignment_operator:
 787    '='                { $$ = ast_assign; }
 788    | MUL_ASSIGN       { $$ = ast_mul_assign; }
 789    | DIV_ASSIGN       { $$ = ast_div_assign; }
 790    | MOD_ASSIGN       { $$ = ast_mod_assign; }
 791    | ADD_ASSIGN       { $$ = ast_add_assign; }
 792    | SUB_ASSIGN       { $$ = ast_sub_assign; }
 793    | LEFT_ASSIGN      { $$ = ast_ls_assign; }
 794    | RIGHT_ASSIGN     { $$ = ast_rs_assign; }
 795    | AND_ASSIGN       { $$ = ast_and_assign; }
 796    | XOR_ASSIGN       { $$ = ast_xor_assign; }
 797    | OR_ASSIGN        { $$ = ast_or_assign; }
 798    ;
 799
 800 expression:
 801    assignment_expression
 802    {
 803       $$ = $1;
 804    }
 805    | expression ',' assignment_expression
 806    {
 807       void *ctx = state->linalloc;
 808       if ($1->oper != ast_sequence) {
 809          $$ = new(ctx) ast_expression(ast_sequence, NULL, NULL, NULL);
 810          $$->set_location_range(@1, @3);
 811          $$->expressions.push_tail(& $1->link);
 812       } else {
 813          $$ = $1;
 814       }
 815
 816       $$->expressions.push_tail(& $3->link);
 817    }
 818    ;
 819
 820 constant_expression:
 821    conditional_expression
 822    ;
 823
 824 declaration:
 825    function_prototype ';'
 826    {
 827       state->symbols->pop_scope();
 828       $$ = $1;
 829    }
 830    | init_declarator_list ';'
 831    {
 832       $$ = $1;
 833    }
 834    | PRECISION precision_qualifier type_specifier ';'
 835    {
 836       $3->default_precision = $2;
 837       $$ = $3;
 838    }
 839    | interface_block
 840    {
 841       $$ = $1;
 842    }
 843    ;
 844
 845 function_prototype:
 846    function_declarator ')'
 847    ;
 848
 849 function_declarator:
 850    function_header
 851    | function_header_with_parameters
 852    ;
 853
 854 function_header_with_parameters:
 855    function_header parameter_declaration
 856    {
 857       $$ = $1;
 858       $$->parameters.push_tail(& $2->link);
 859    }
 860    | function_header_with_parameters ',' parameter_declaration
 861    {
 862       $$ = $1;
 863       $$->parameters.push_tail(& $3->link);
 864    }
 865    ;
 866
 867 function_header:
 868    fully_specified_type variable_identifier '('
 869    {
 870       void *ctx = state->linalloc;
 871       $$ = new(ctx) ast_function();
 872       $$->set_location(@2);
 873       $$->return_type = $1;
 874       $$->identifier = $2;
 875
 876       if ($1->qualifier.flags.q.subroutine) {
 877          /* add type for IDENTIFIER search */
 878          state->symbols->add_type($2, glsl_type::get_subroutine_instance($2));
 879       } else
 880          state->symbols->add_function(new(state) ir_function($2));
 881       state->symbols->push_scope();
 882    }
 883    ;
 884
 885 parameter_declarator:
 886    type_specifier any_identifier
 887    {
 888       void *ctx = state->linalloc;
 889       $$ = new(ctx) ast_parameter_declarator();
 890       $$->set_location_range(@1, @2);
 891       $$->type = new(ctx) ast_fully_specified_type();
 892       $$->type->set_location(@1);
 893       $$->type->specifier = $1;
 894       $$->identifier = $2;
 895       state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
 896    }
 897    | type_specifier any_identifier array_specifier
 898    {
 899       void *ctx = state->linalloc;
 900       $$ = new(ctx) ast_parameter_declarator();
 901       $$->set_location_range(@1, @3);
 902       $$->type = new(ctx) ast_fully_specified_type();
 903       $$->type->set_location(@1);
 904       $$->type->specifier = $1;
 905       $$->identifier = $2;
 906       $$->array_specifier = $3;
 907       state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
 908    }
 909    ;
 910
 911 parameter_declaration:
 912    parameter_qualifier parameter_declarator
 913    {
 914       $$ = $2;
 915       $$->type->qualifier = $1;
 916    }
 917    | parameter_qualifier parameter_type_specifier
 918    {
 919       void *ctx = state->linalloc;
 920       $$ = new(ctx) ast_parameter_declarator();
 921       $$->set_location(@2);
 922       $$->type = new(ctx) ast_fully_specified_type();
 923       $$->type->set_location_range(@1, @2);
 924       $$->type->qualifier = $1;
 925       $$->type->specifier = $2;
 926    }
 927    ;
 928
 929 parameter_qualifier:
 930    /* empty */
 931    {
 932       memset(& $$, 0, sizeof($$));
 933    }
 934    | CONST_TOK parameter_qualifier
 935    {
 936       if ($2.flags.q.constant)
 937          _mesa_glsl_error(&@1, state, "duplicate const qualifier");
 938
 939       $$ = $2;
 940       $$.flags.q.constant = 1;
 941    }
 942    | PRECISE parameter_qualifier
 943    {
 944       if ($2.flags.q.precise)
 945          _mesa_glsl_error(&@1, state, "duplicate precise qualifier");
 946
 947       $$ = $2;
 948       $$.flags.q.precise = 1;
 949    }
 950    | parameter_direction_qualifier parameter_qualifier
 951    {
 952       if (($1.flags.q.in || $1.flags.q.out) && ($2.flags.q.in || $2.flags.q.out))
 953          _mesa_glsl_error(&@1, state, "duplicate in/out/inout qualifier");
 954
 955       if (!state->has_420pack_or_es31() && $2.flags.q.constant)
 956          _mesa_glsl_error(&@1, state, "in/out/inout must come after const "
 957                                       "or precise");
 958
 959       $$ = $1;
 960       $$.merge_qualifier(&@1, state, $2, false);
 961    }
 962    | precision_qualifier parameter_qualifier
 963    {
 964       if ($2.precision != ast_precision_none)
 965          _mesa_glsl_error(&@1, state, "duplicate precision qualifier");
 966
 967       if (!state->has_420pack_or_es31() &&
 968           $2.flags.i != 0)
 969          _mesa_glsl_error(&@1, state, "precision qualifiers must come last");
 970
 971       $$ = $2;
 972       $$.precision = $1;
 973    }
 974    | memory_qualifier parameter_qualifier
 975    {
 976       $$ = $1;
 977       $$.merge_qualifier(&@1, state, $2, false);
 978    }
 979
 980 parameter_direction_qualifier:
 981    IN_TOK
 982    {
 983       memset(& $$, 0, sizeof($$));
 984       $$.flags.q.in = 1;
 985    }
 986    | OUT_TOK
 987    {
 988       memset(& $$, 0, sizeof($$));
 989       $$.flags.q.out = 1;
 990    }
 991    | INOUT_TOK
 992    {
 993       memset(& $$, 0, sizeof($$));
 994       $$.flags.q.in = 1;
 995       $$.flags.q.out = 1;
 996    }
 997    ;
 998
 999 parameter_type_specifier:
1000    type_specifier
1001    ;
1002
1003 init_declarator_list:
1004    single_declaration
1005    | init_declarator_list ',' any_identifier
1006    {
1007       void *ctx = state->linalloc;
1008       ast_declaration *decl = new(ctx) ast_declaration($3, NULL, NULL);
1009       decl->set_location(@3);
1010
1011       $$ = $1;
1012       $$->declarations.push_tail(&decl->link);
1013       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1014    }
1015    | init_declarator_list ',' any_identifier array_specifier
1016    {
1017       void *ctx = state->linalloc;
1018       ast_declaration *decl = new(ctx) ast_declaration($3, $4, NULL);
1019       decl->set_location_range(@3, @4);
1020
1021       $$ = $1;
1022       $$->declarations.push_tail(&decl->link);
1023       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1024    }
1025    | init_declarator_list ',' any_identifier array_specifier '=' initializer
1026    {
1027       void *ctx = state->linalloc;
1028       ast_declaration *decl = new(ctx) ast_declaration($3, $4, $6);
1029       decl->set_location_range(@3, @4);
1030
1031       $$ = $1;
1032       $$->declarations.push_tail(&decl->link);
1033       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1034    }
1035    | init_declarator_list ',' any_identifier '=' initializer
1036    {
1037       void *ctx = state->linalloc;
1038       ast_declaration *decl = new(ctx) ast_declaration($3, NULL, $5);
1039       decl->set_location(@3);
1040
1041       $$ = $1;
1042       $$->declarations.push_tail(&decl->link);
1043       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1044    }
1045    ;
1046
1047    // Grammar Note: No 'enum', or 'typedef'.
1048 single_declaration:
1049    fully_specified_type
1050    {
1051       void *ctx = state->linalloc;
1052       /* Empty declaration list is valid. */
1053       $$ = new(ctx) ast_declarator_list($1);
1054       $$->set_location(@1);
1055    }
1056    | fully_specified_type any_identifier
1057    {
1058       void *ctx = state->linalloc;
1059       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1060       decl->set_location(@2);
1061
1062       $$ = new(ctx) ast_declarator_list($1);
1063       $$->set_location_range(@1, @2);
1064       $$->declarations.push_tail(&decl->link);
1065       state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1066    }
1067    | fully_specified_type any_identifier array_specifier
1068    {
1069       void *ctx = state->linalloc;
1070       ast_declaration *decl = new(ctx) ast_declaration($2, $3, NULL);
1071       decl->set_location_range(@2, @3);
1072
1073       $$ = new(ctx) ast_declarator_list($1);
1074       $$->set_location_range(@1, @3);
1075       $$->declarations.push_tail(&decl->link);
1076       state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1077    }
1078    | fully_specified_type any_identifier array_specifier '=' initializer
1079    {
1080       void *ctx = state->linalloc;
1081       ast_declaration *decl = new(ctx) ast_declaration($2, $3, $5);
1082       decl->set_location_range(@2, @3);
1083
1084       $$ = new(ctx) ast_declarator_list($1);
1085       $$->set_location_range(@1, @3);
1086       $$->declarations.push_tail(&decl->link);
1087       state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1088    }
1089    | fully_specified_type any_identifier '=' initializer
1090    {
1091       void *ctx = state->linalloc;
1092       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, $4);
1093       decl->set_location(@2);
1094
1095       $$ = new(ctx) ast_declarator_list($1);
1096       $$->set_location_range(@1, @2);
1097       $$->declarations.push_tail(&decl->link);
1098       state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1099    }
1100    | INVARIANT variable_identifier
1101    {
1102       void *ctx = state->linalloc;
1103       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1104       decl->set_location(@2);
1105
1106       $$ = new(ctx) ast_declarator_list(NULL);
1107       $$->set_location_range(@1, @2);
1108       $$->invariant = true;
1109
1110       $$->declarations.push_tail(&decl->link);
1111    }
1112    | PRECISE variable_identifier
1113    {
1114       void *ctx = state->linalloc;
1115       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1116       decl->set_location(@2);
1117
1118       $$ = new(ctx) ast_declarator_list(NULL);
1119       $$->set_location_range(@1, @2);
1120       $$->precise = true;
1121
1122       $$->declarations.push_tail(&decl->link);
1123    }
1124    ;
1125
1126 fully_specified_type:
1127    type_specifier
1128    {
1129       void *ctx = state->linalloc;
1130       $$ = new(ctx) ast_fully_specified_type();
1131       $$->set_location(@1);
1132       $$->specifier = $1;
1133    }
1134    | type_qualifier type_specifier
1135    {
1136       void *ctx = state->linalloc;
1137       $$ = new(ctx) ast_fully_specified_type();
1138       $$->set_location_range(@1, @2);
1139       $$->qualifier = $1;
1140       $$->specifier = $2;
1141       if ($$->specifier->structure != NULL &&
1142           $$->specifier->structure->is_declaration) {
1143             $$->specifier->structure->layout = &$$->qualifier;
1144       }
1145    }
1146    ;
1147
1148 layout_qualifier:
1149    LAYOUT_TOK '(' layout_qualifier_id_list ')'
1150    {
1151       $$ = $3;
1152    }
1153    ;
1154
1155 layout_qualifier_id_list:
1156    layout_qualifier_id
1157    | layout_qualifier_id_list ',' layout_qualifier_id
1158    {
1159       $$ = $1;
1160       if (!$$.merge_qualifier(& @3, state, $3, true)) {
1161          YYERROR;
1162       }
1163    }
1164    ;
1165
1166 layout_qualifier_id:
1167    any_identifier
1168    {
1169       memset(& $$, 0, sizeof($$));
1170
1171       /* Layout qualifiers for ARB_fragment_coord_conventions. */
1172       if (!$$.flags.i && (state->ARB_fragment_coord_conventions_enable ||
1173                           state->is_version(150, 0))) {
1174          if (match_layout_qualifier($1, "origin_upper_left", state) == 0) {
1175             $$.flags.q.origin_upper_left = 1;
1176          } else if (match_layout_qualifier($1, "pixel_center_integer",
1177                                            state) == 0) {
1178             $$.flags.q.pixel_center_integer = 1;
1179          }
1180
1181          if ($$.flags.i && state->ARB_fragment_coord_conventions_warn) {
1182             _mesa_glsl_warning(& @1, state,
1183                                "GL_ARB_fragment_coord_conventions layout "
1184                                "identifier `%s' used", $1);
1185          }
1186       }
1187
1188       /* Layout qualifiers for AMD/ARB_conservative_depth. */
1189       if (!$$.flags.i &&
1190           (state->AMD_conservative_depth_enable ||
1191            state->ARB_conservative_depth_enable ||
1192            state->is_version(420, 0))) {
1193          if (match_layout_qualifier($1, "depth_any", state) == 0) {
1194             $$.flags.q.depth_any = 1;
1195          } else if (match_layout_qualifier($1, "depth_greater", state) == 0) {
1196             $$.flags.q.depth_greater = 1;
1197          } else if (match_layout_qualifier($1, "depth_less", state) == 0) {
1198             $$.flags.q.depth_less = 1;
1199          } else if (match_layout_qualifier($1, "depth_unchanged",
1200                                            state) == 0) {
1201             $$.flags.q.depth_unchanged = 1;
1202          }
1203
1204          if ($$.flags.i && state->AMD_conservative_depth_warn) {
1205             _mesa_glsl_warning(& @1, state,
1206                                "GL_AMD_conservative_depth "
1207                                "layout qualifier `%s' is used", $1);
1208          }
1209          if ($$.flags.i && state->ARB_conservative_depth_warn) {
1210             _mesa_glsl_warning(& @1, state,
1211                                "GL_ARB_conservative_depth "
1212                                "layout qualifier `%s' is used", $1);
1213          }
1214       }
1215
1216       /* See also interface_block_layout_qualifier. */
1217       if (!$$.flags.i && state->has_uniform_buffer_objects()) {
1218          if (match_layout_qualifier($1, "std140", state) == 0) {
1219             $$.flags.q.std140 = 1;
1220          } else if (match_layout_qualifier($1, "shared", state) == 0) {
1221             $$.flags.q.shared = 1;
1222          } else if (match_layout_qualifier($1, "std430", state) == 0) {
1223             $$.flags.q.std430 = 1;
1224          } else if (match_layout_qualifier($1, "column_major", state) == 0) {
1225             $$.flags.q.column_major = 1;
1226          /* "row_major" is a reserved word in GLSL 1.30+. Its token is parsed
1227           * below in the interface_block_layout_qualifier rule.
1228           *
1229           * It is not a reserved word in GLSL ES 3.00, so it's handled here as
1230           * an identifier.
1231           *
1232           * Also, this takes care of alternate capitalizations of
1233           * "row_major" (which is necessary because layout qualifiers
1234           * are case-insensitive in desktop GLSL).
1235           */
1236          } else if (match_layout_qualifier($1, "row_major", state) == 0) {
1237             $$.flags.q.row_major = 1;
1238          /* "packed" is a reserved word in GLSL, and its token is
1239           * parsed below in the interface_block_layout_qualifier rule.
1240           * However, we must take care of alternate capitalizations of
1241           * "packed", because layout qualifiers are case-insensitive
1242           * in desktop GLSL.
1243           */
1244          } else if (match_layout_qualifier($1, "packed", state) == 0) {
1245            $$.flags.q.packed = 1;
1246          }
1247
1248          if ($$.flags.i && state->ARB_uniform_buffer_object_warn) {
1249             _mesa_glsl_warning(& @1, state,
1250                                "#version 140 / GL_ARB_uniform_buffer_object "
1251                                "layout qualifier `%s' is used", $1);
1252          }
1253       }
1254
1255       /* Layout qualifiers for GLSL 1.50 geometry shaders. */
1256       if (!$$.flags.i) {
1257          static const struct {
1258             const char *s;
1259             GLenum e;
1260          } map[] = {
1261                  { "points", GL_POINTS },
1262                  { "lines", GL_LINES },
1263                  { "lines_adjacency", GL_LINES_ADJACENCY },
1264                  { "line_strip", GL_LINE_STRIP },
1265                  { "triangles", GL_TRIANGLES },
1266                  { "triangles_adjacency", GL_TRIANGLES_ADJACENCY },
1267                  { "triangle_strip", GL_TRIANGLE_STRIP },
1268          };
1269          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1270             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1271                $$.flags.q.prim_type = 1;
1272                $$.prim_type = map[i].e;
1273                break;
1274             }
1275          }
1276
1277          if ($$.flags.i && !state->has_geometry_shader() &&
1278              !state->has_tessellation_shader()) {
1279             _mesa_glsl_error(& @1, state, "#version 150 layout "
1280                              "qualifier `%s' used", $1);
1281          }
1282       }
1283
1284       /* Layout qualifiers for ARB_shader_image_load_store. */
1285       if (state->ARB_shader_image_load_store_enable ||
1286           state->is_version(420, 310)) {
1287          if (!$$.flags.i) {
1288             static const struct {
1289                const char *name;
1290                GLenum format;
1291                glsl_base_type base_type;
1292                /** Minimum desktop GLSL version required for the image
1293                 * format.  Use 130 if already present in the original
1294                 * ARB extension.
1295                 */
1296                unsigned required_glsl;
1297                /** Minimum GLSL ES version required for the image format. */
1298                unsigned required_essl;
1299             } map[] = {
1300                { "rgba32f", GL_RGBA32F, GLSL_TYPE_FLOAT, 130, 310 },
1301                { "rgba16f", GL_RGBA16F, GLSL_TYPE_FLOAT, 130, 310 },
1302                { "rg32f", GL_RG32F, GLSL_TYPE_FLOAT, 130, 0 },
1303                { "rg16f", GL_RG16F, GLSL_TYPE_FLOAT, 130, 0 },
1304                { "r11f_g11f_b10f", GL_R11F_G11F_B10F, GLSL_TYPE_FLOAT, 130, 0 },
1305                { "r32f", GL_R32F, GLSL_TYPE_FLOAT, 130, 310 },
1306                { "r16f", GL_R16F, GLSL_TYPE_FLOAT, 130, 0 },
1307                { "rgba32ui", GL_RGBA32UI, GLSL_TYPE_UINT, 130, 310 },
1308                { "rgba16ui", GL_RGBA16UI, GLSL_TYPE_UINT, 130, 310 },
1309                { "rgb10_a2ui", GL_RGB10_A2UI, GLSL_TYPE_UINT, 130, 0 },
1310                { "rgba8ui", GL_RGBA8UI, GLSL_TYPE_UINT, 130, 310 },
1311                { "rg32ui", GL_RG32UI, GLSL_TYPE_UINT, 130, 0 },
1312                { "rg16ui", GL_RG16UI, GLSL_TYPE_UINT, 130, 0 },
1313                { "rg8ui", GL_RG8UI, GLSL_TYPE_UINT, 130, 0 },
1314                { "r32ui", GL_R32UI, GLSL_TYPE_UINT, 130, 310 },
1315                { "r16ui", GL_R16UI, GLSL_TYPE_UINT, 130, 0 },
1316                { "r8ui", GL_R8UI, GLSL_TYPE_UINT, 130, 0 },
1317                { "rgba32i", GL_RGBA32I, GLSL_TYPE_INT, 130, 310 },
1318                { "rgba16i", GL_RGBA16I, GLSL_TYPE_INT, 130, 310 },
1319                { "rgba8i", GL_RGBA8I, GLSL_TYPE_INT, 130, 310 },
1320                { "rg32i", GL_RG32I, GLSL_TYPE_INT, 130, 0 },
1321                { "rg16i", GL_RG16I, GLSL_TYPE_INT, 130, 0 },
1322                { "rg8i", GL_RG8I, GLSL_TYPE_INT, 130, 0 },
1323                { "r32i", GL_R32I, GLSL_TYPE_INT, 130, 310 },
1324                { "r16i", GL_R16I, GLSL_TYPE_INT, 130, 0 },
1325                { "r8i", GL_R8I, GLSL_TYPE_INT, 130, 0 },
1326                { "rgba16", GL_RGBA16, GLSL_TYPE_FLOAT, 130, 0 },
1327                { "rgb10_a2", GL_RGB10_A2, GLSL_TYPE_FLOAT, 130, 0 },
1328                { "rgba8", GL_RGBA8, GLSL_TYPE_FLOAT, 130, 310 },
1329                { "rg16", GL_RG16, GLSL_TYPE_FLOAT, 130, 0 },
1330                { "rg8", GL_RG8, GLSL_TYPE_FLOAT, 130, 0 },
1331                { "r16", GL_R16, GLSL_TYPE_FLOAT, 130, 0 },
1332                { "r8", GL_R8, GLSL_TYPE_FLOAT, 130, 0 },
1333                { "rgba16_snorm", GL_RGBA16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1334                { "rgba8_snorm", GL_RGBA8_SNORM, GLSL_TYPE_FLOAT, 130, 310 },
1335                { "rg16_snorm", GL_RG16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1336                { "rg8_snorm", GL_RG8_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1337                { "r16_snorm", GL_R16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1338                { "r8_snorm", GL_R8_SNORM, GLSL_TYPE_FLOAT, 130, 0 }
1339             };
1340
1341             for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1342                if (state->is_version(map[i].required_glsl,
1343                                      map[i].required_essl) &&
1344                    match_layout_qualifier($1, map[i].name, state) == 0) {
1345                   $$.flags.q.explicit_image_format = 1;
1346                   $$.image_format = map[i].format;
1347                   $$.image_base_type = map[i].base_type;
1348                   break;
1349                }
1350             }
1351          }
1352
1353          if (!$$.flags.i &&
1354              match_layout_qualifier($1, "early_fragment_tests", state) == 0) {
1355             /* From section 4.4.1.3 of the GLSL 4.50 specification
1356              * (Fragment Shader Inputs):
1357              *
1358              *  "Fragment shaders also allow the following layout
1359              *   qualifier on in only (not with variable declarations)
1360              *     layout-qualifier-id
1361              *        early_fragment_tests
1362              *   [...]"
1363              */
1364             if (state->stage != MESA_SHADER_FRAGMENT) {
1365                _mesa_glsl_error(& @1, state,
1366                                 "early_fragment_tests layout qualifier only "
1367                                 "valid in fragment shaders");
1368             }
1369
1370             $$.flags.q.early_fragment_tests = 1;
1371          }
1372       }
1373
1374       /* Layout qualifiers for tessellation evaluation shaders. */
1375       if (!$$.flags.i) {
1376          static const struct {
1377             const char *s;
1378             GLenum e;
1379          } map[] = {
1380                  /* triangles already parsed by gs-specific code */
1381                  { "quads", GL_QUADS },
1382                  { "isolines", GL_ISOLINES },
1383          };
1384          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1385             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1386                $$.flags.q.prim_type = 1;
1387                $$.prim_type = map[i].e;
1388                break;
1389             }
1390          }
1391
1392          if ($$.flags.i && !state->has_tessellation_shader()) {
1393             _mesa_glsl_error(& @1, state,
1394                              "primitive mode qualifier `%s' requires "
1395                              "GLSL 4.00 or ARB_tessellation_shader", $1);
1396          }
1397       }
1398       if (!$$.flags.i) {
1399          static const struct {
1400             const char *s;
1401             GLenum e;
1402          } map[] = {
1403                  { "equal_spacing", GL_EQUAL },
1404                  { "fractional_odd_spacing", GL_FRACTIONAL_ODD },
1405                  { "fractional_even_spacing", GL_FRACTIONAL_EVEN },
1406          };
1407          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1408             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1409                $$.flags.q.vertex_spacing = 1;
1410                $$.vertex_spacing = map[i].e;
1411                break;
1412             }
1413          }
1414
1415          if ($$.flags.i && !state->has_tessellation_shader()) {
1416             _mesa_glsl_error(& @1, state,
1417                              "vertex spacing qualifier `%s' requires "
1418                              "GLSL 4.00 or ARB_tessellation_shader", $1);
1419          }
1420       }
1421       if (!$$.flags.i) {
1422          if (match_layout_qualifier($1, "cw", state) == 0) {
1423             $$.flags.q.ordering = 1;
1424             $$.ordering = GL_CW;
1425          } else if (match_layout_qualifier($1, "ccw", state) == 0) {
1426             $$.flags.q.ordering = 1;
1427             $$.ordering = GL_CCW;
1428          }
1429
1430          if ($$.flags.i && !state->has_tessellation_shader()) {
1431             _mesa_glsl_error(& @1, state,
1432                              "ordering qualifier `%s' requires "
1433                              "GLSL 4.00 or ARB_tessellation_shader", $1);
1434          }
1435       }
1436       if (!$$.flags.i) {
1437          if (match_layout_qualifier($1, "point_mode", state) == 0) {
1438             $$.flags.q.point_mode = 1;
1439             $$.point_mode = true;
1440          }
1441
1442          if ($$.flags.i && !state->has_tessellation_shader()) {
1443             _mesa_glsl_error(& @1, state,
1444                              "qualifier `point_mode' requires "
1445                              "GLSL 4.00 or ARB_tessellation_shader");
1446          }
1447       }
1448
1449       if (!$$.flags.i) {
1450          static const struct {
1451             const char *s;
1452             uint32_t mask;
1453          } map[] = {
1454                  { "blend_support_multiply",       BLEND_MULTIPLY },
1455                  { "blend_support_screen",         BLEND_SCREEN },
1456                  { "blend_support_overlay",        BLEND_OVERLAY },
1457                  { "blend_support_darken",         BLEND_DARKEN },
1458                  { "blend_support_lighten",        BLEND_LIGHTEN },
1459                  { "blend_support_colordodge",     BLEND_COLORDODGE },
1460                  { "blend_support_colorburn",      BLEND_COLORBURN },
1461                  { "blend_support_hardlight",      BLEND_HARDLIGHT },
1462                  { "blend_support_softlight",      BLEND_SOFTLIGHT },
1463                  { "blend_support_difference",     BLEND_DIFFERENCE },
1464                  { "blend_support_exclusion",      BLEND_EXCLUSION },
1465                  { "blend_support_hsl_hue",        BLEND_HSL_HUE },
1466                  { "blend_support_hsl_saturation", BLEND_HSL_SATURATION },
1467                  { "blend_support_hsl_color",      BLEND_HSL_COLOR },
1468                  { "blend_support_hsl_luminosity", BLEND_HSL_LUMINOSITY },
1469                  { "blend_support_all_equations",  BLEND_ALL },
1470          };
1471          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1472             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1473                $$.flags.q.blend_support = 1;
1474                state->fs_blend_support |= map[i].mask;
1475                break;
1476             }
1477          }
1478
1479          if ($$.flags.i &&
1480              !state->KHR_blend_equation_advanced_enable &&
1481              !state->is_version(0, 320)) {
1482             _mesa_glsl_error(& @1, state,
1483                              "advanced blending layout qualifiers require "
1484                              "ESSL 3.20 or KHR_blend_equation_advanced");
1485          }
1486
1487          if ($$.flags.i && state->stage != MESA_SHADER_FRAGMENT) {
1488             _mesa_glsl_error(& @1, state,
1489                              "advanced blending layout qualifiers only "
1490                              "valid in fragment shaders");
1491          }
1492       }
1493
1494       /* Layout qualifiers for ARB_compute_variable_group_size. */
1495       if (!$$.flags.i) {
1496          if (match_layout_qualifier($1, "local_size_variable", state) == 0) {
1497             $$.flags.q.local_size_variable = 1;
1498          }
1499
1500          if ($$.flags.i && !state->ARB_compute_variable_group_size_enable) {
1501             _mesa_glsl_error(& @1, state,
1502                              "qualifier `local_size_variable` requires "
1503                              "ARB_compute_variable_group_size");
1504          }
1505       }
1506
1507       if (!$$.flags.i) {
1508          _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1509                           "`%s'", $1);
1510          YYERROR;
1511       }
1512    }
1513    | any_identifier '=' constant_expression
1514    {
1515       memset(& $$, 0, sizeof($$));
1516       void *ctx = state->linalloc;
1517
1518       if ($3->oper != ast_int_constant &&
1519           $3->oper != ast_uint_constant &&
1520           !state->has_enhanced_layouts()) {
1521          _mesa_glsl_error(& @1, state,
1522                           "compile-time constant expressions require "
1523                           "GLSL 4.40 or ARB_enhanced_layouts");
1524       }
1525
1526       if (match_layout_qualifier("align", $1, state) == 0) {
1527          if (!state->has_enhanced_layouts()) {
1528             _mesa_glsl_error(& @1, state,
1529                              "align qualifier requires "
1530                              "GLSL 4.40 or ARB_enhanced_layouts");
1531          } else {
1532             $$.flags.q.explicit_align = 1;
1533             $$.align = $3;
1534          }
1535       }
1536
1537       if (match_layout_qualifier("location", $1, state) == 0) {
1538          $$.flags.q.explicit_location = 1;
1539
1540          if ($$.flags.q.attribute == 1 &&
1541              state->ARB_explicit_attrib_location_warn) {
1542             _mesa_glsl_warning(& @1, state,
1543                                "GL_ARB_explicit_attrib_location layout "
1544                                "identifier `%s' used", $1);
1545          }
1546          $$.location = $3;
1547       }
1548
1549       if (match_layout_qualifier("component", $1, state) == 0) {
1550          if (!state->has_enhanced_layouts()) {
1551             _mesa_glsl_error(& @1, state,
1552                              "component qualifier requires "
1553                              "GLSL 4.40 or ARB_enhanced_layouts");
1554          } else {
1555             $$.flags.q.explicit_component = 1;
1556             $$.component = $3;
1557          }
1558       }
1559
1560       if (match_layout_qualifier("index", $1, state) == 0) {
1561          if (state->es_shader && !state->EXT_blend_func_extended_enable) {
1562             _mesa_glsl_error(& @3, state, "index layout qualifier requires EXT_blend_func_extended");
1563             YYERROR;
1564          }
1565
1566          $$.flags.q.explicit_index = 1;
1567          $$.index = $3;
1568       }
1569
1570       if ((state->has_420pack_or_es31() ||
1571            state->has_atomic_counters() ||
1572            state->has_shader_storage_buffer_objects()) &&
1573           match_layout_qualifier("binding", $1, state) == 0) {
1574          $$.flags.q.explicit_binding = 1;
1575          $$.binding = $3;
1576       }
1577
1578       if ((state->has_atomic_counters() ||
1579            state->has_enhanced_layouts()) &&
1580           match_layout_qualifier("offset", $1, state) == 0) {
1581          $$.flags.q.explicit_offset = 1;
1582          $$.offset = $3;
1583       }
1584
1585       if (match_layout_qualifier("max_vertices", $1, state) == 0) {
1586          $$.flags.q.max_vertices = 1;
1587          $$.max_vertices = new(ctx) ast_layout_expression(@1, $3);
1588          if (!state->has_geometry_shader()) {
1589             _mesa_glsl_error(& @3, state,
1590                              "#version 150 max_vertices qualifier "
1591                              "specified", $3);
1592          }
1593       }
1594
1595       if (state->stage == MESA_SHADER_GEOMETRY) {
1596          if (match_layout_qualifier("stream", $1, state) == 0 &&
1597              state->check_explicit_attrib_stream_allowed(& @3)) {
1598             $$.flags.q.stream = 1;
1599             $$.flags.q.explicit_stream = 1;
1600             $$.stream = $3;
1601          }
1602       }
1603
1604       if (state->has_enhanced_layouts()) {
1605          if (match_layout_qualifier("xfb_buffer", $1, state) == 0) {
1606             $$.flags.q.xfb_buffer = 1;
1607             $$.flags.q.explicit_xfb_buffer = 1;
1608             $$.xfb_buffer = $3;
1609          }
1610
1611          if (match_layout_qualifier("xfb_offset", $1, state) == 0) {
1612             $$.flags.q.explicit_xfb_offset = 1;
1613             $$.offset = $3;
1614          }
1615
1616          if (match_layout_qualifier("xfb_stride", $1, state) == 0) {
1617             $$.flags.q.xfb_stride = 1;
1618             $$.flags.q.explicit_xfb_stride = 1;
1619             $$.xfb_stride = $3;
1620          }
1621       }
1622
1623       static const char * const local_size_qualifiers[3] = {
1624          "local_size_x",
1625          "local_size_y",
1626          "local_size_z",
1627       };
1628       for (int i = 0; i < 3; i++) {
1629          if (match_layout_qualifier(local_size_qualifiers[i], $1,
1630                                     state) == 0) {
1631             if (!state->has_compute_shader()) {
1632                _mesa_glsl_error(& @3, state,
1633                                 "%s qualifier requires GLSL 4.30 or "
1634                                 "GLSL ES 3.10 or ARB_compute_shader",
1635                                 local_size_qualifiers[i]);
1636                YYERROR;
1637             } else {
1638                $$.flags.q.local_size |= (1 << i);
1639                $$.local_size[i] = new(ctx) ast_layout_expression(@1, $3);
1640             }
1641             break;
1642          }
1643       }
1644
1645       if (match_layout_qualifier("invocations", $1, state) == 0) {
1646          $$.flags.q.invocations = 1;
1647          $$.invocations = new(ctx) ast_layout_expression(@1, $3);
1648          if (!state->is_version(400, 320) &&
1649              !state->ARB_gpu_shader5_enable &&
1650              !state->OES_geometry_shader_enable &&
1651              !state->EXT_geometry_shader_enable) {
1652             _mesa_glsl_error(& @3, state,
1653                              "GL_ARB_gpu_shader5 invocations "
1654                              "qualifier specified", $3);
1655          }
1656       }
1657
1658       /* Layout qualifiers for tessellation control shaders. */
1659       if (match_layout_qualifier("vertices", $1, state) == 0) {
1660          $$.flags.q.vertices = 1;
1661          $$.vertices = new(ctx) ast_layout_expression(@1, $3);
1662          if (!state->has_tessellation_shader()) {
1663             _mesa_glsl_error(& @1, state,
1664                              "vertices qualifier requires GLSL 4.00 or "
1665                              "ARB_tessellation_shader");
1666          }
1667       }
1668
1669       /* If the identifier didn't match any known layout identifiers,
1670        * emit an error.
1671        */
1672       if (!$$.flags.i) {
1673          _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1674                           "`%s'", $1);
1675          YYERROR;
1676       }
1677    }
1678    | interface_block_layout_qualifier
1679    {
1680       $$ = $1;
1681       /* Layout qualifiers for ARB_uniform_buffer_object. */
1682       if ($$.flags.q.uniform && !state->has_uniform_buffer_objects()) {
1683          _mesa_glsl_error(& @1, state,
1684                           "#version 140 / GL_ARB_uniform_buffer_object "
1685                           "layout qualifier `%s' is used", $1);
1686       } else if ($$.flags.q.uniform && state->ARB_uniform_buffer_object_warn) {
1687          _mesa_glsl_warning(& @1, state,
1688                             "#version 140 / GL_ARB_uniform_buffer_object "
1689                             "layout qualifier `%s' is used", $1);
1690       }
1691    }
1692    ;
1693
1694 /* This is a separate language rule because we parse these as tokens
1695  * (due to them being reserved keywords) instead of identifiers like
1696  * most qualifiers.  See the any_identifier path of
1697  * layout_qualifier_id for the others.
1698  *
1699  * Note that since layout qualifiers are case-insensitive in desktop
1700  * GLSL, all of these qualifiers need to be handled as identifiers as
1701  * well (by the any_identifier path of layout_qualifier_id).
1702  */
1703 interface_block_layout_qualifier:
1704    ROW_MAJOR
1705    {
1706       memset(& $$, 0, sizeof($$));
1707       $$.flags.q.row_major = 1;
1708    }
1709    | PACKED_TOK
1710    {
1711       memset(& $$, 0, sizeof($$));
1712       $$.flags.q.packed = 1;
1713    }
1714    | SHARED
1715    {
1716       memset(& $$, 0, sizeof($$));
1717       $$.flags.q.shared = 1;
1718    }
1719    ;
1720
1721 subroutine_qualifier:
1722    SUBROUTINE
1723    {
1724       memset(& $$, 0, sizeof($$));
1725       $$.flags.q.subroutine = 1;
1726    }
1727    | SUBROUTINE '(' subroutine_type_list ')'
1728    {
1729       memset(& $$, 0, sizeof($$));
1730       $$.flags.q.subroutine_def = 1;
1731       $$.subroutine_list = $3;
1732    }
1733    ;
1734
1735 subroutine_type_list:
1736    any_identifier
1737    {
1738         void *ctx = state->linalloc;
1739         ast_declaration *decl = new(ctx)  ast_declaration($1, NULL, NULL);
1740         decl->set_location(@1);
1741
1742         $$ = new(ctx) ast_subroutine_list();
1743         $$->declarations.push_tail(&decl->link);
1744    }
1745    | subroutine_type_list ',' any_identifier
1746    {
1747         void *ctx = state->linalloc;
1748         ast_declaration *decl = new(ctx)  ast_declaration($3, NULL, NULL);
1749         decl->set_location(@3);
1750
1751         $$ = $1;
1752         $$->declarations.push_tail(&decl->link);
1753    }
1754    ;
1755
1756 interpolation_qualifier:
1757    SMOOTH
1758    {
1759       memset(& $$, 0, sizeof($$));
1760       $$.flags.q.smooth = 1;
1761    }
1762    | FLAT
1763    {
1764       memset(& $$, 0, sizeof($$));
1765       $$.flags.q.flat = 1;
1766    }
1767    | NOPERSPECTIVE
1768    {
1769       memset(& $$, 0, sizeof($$));
1770       $$.flags.q.noperspective = 1;
1771    }
1772    ;
1773
1774 type_qualifier:
1775    /* Single qualifiers */
1776    INVARIANT
1777    {
1778       memset(& $$, 0, sizeof($$));
1779       $$.flags.q.invariant = 1;
1780    }
1781    | PRECISE
1782    {
1783       memset(& $$, 0, sizeof($$));
1784       $$.flags.q.precise = 1;
1785    }
1786    | auxiliary_storage_qualifier
1787    | storage_qualifier
1788    | interpolation_qualifier
1789    | layout_qualifier
1790    | memory_qualifier
1791    | subroutine_qualifier
1792    | precision_qualifier
1793    {
1794       memset(&$$, 0, sizeof($$));
1795       $$.precision = $1;
1796    }
1797
1798    /* Multiple qualifiers:
1799     * In GLSL 4.20, these can be specified in any order.  In earlier versions,
1800     * they appear in this order (see GLSL 1.50 section 4.7 & comments below):
1801     *
1802     *    invariant interpolation auxiliary storage precision  ...or...
1803     *    layout storage precision
1804     *
1805     * Each qualifier's rule ensures that the accumulated qualifiers on the right
1806     * side don't contain any that must appear on the left hand side.
1807     * For example, when processing a storage qualifier, we check that there are
1808     * no auxiliary, interpolation, layout, invariant, or precise qualifiers to the right.
1809     */
1810    | PRECISE type_qualifier
1811    {
1812       if ($2.flags.q.precise)
1813          _mesa_glsl_error(&@1, state, "duplicate \"precise\" qualifier");
1814
1815       $$ = $2;
1816       $$.flags.q.precise = 1;
1817    }
1818    | INVARIANT type_qualifier
1819    {
1820       if ($2.flags.q.invariant)
1821          _mesa_glsl_error(&@1, state, "duplicate \"invariant\" qualifier");
1822
1823       if (!state->has_420pack_or_es31() && $2.flags.q.precise)
1824          _mesa_glsl_error(&@1, state,
1825                           "\"invariant\" must come after \"precise\"");
1826
1827       $$ = $2;
1828       $$.flags.q.invariant = 1;
1829
1830       /* GLSL ES 3.00 spec, section 4.6.1 "The Invariant Qualifier":
1831        *
1832        * "Only variables output from a shader can be candidates for invariance.
1833        * This includes user-defined output variables and the built-in output
1834        * variables. As only outputs can be declared as invariant, an invariant
1835        * output from one shader stage will still match an input of a subsequent
1836        * stage without the input being declared as invariant."
1837        *
1838        * On the desktop side, this text first appears in GLSL 4.30.
1839        */
1840       if (state->is_version(430, 300) && $$.flags.q.in)
1841          _mesa_glsl_error(&@1, state, "invariant qualifiers cannot be used with shader inputs");
1842    }
1843    | interpolation_qualifier type_qualifier
1844    {
1845       /* Section 4.3 of the GLSL 1.40 specification states:
1846        * "...qualified with one of these interpolation qualifiers"
1847        *
1848        * GLSL 1.30 claims to allow "one or more", but insists that:
1849        * "These interpolation qualifiers may only precede the qualifiers in,
1850        *  centroid in, out, or centroid out in a declaration."
1851        *
1852        * ...which means that e.g. smooth can't precede smooth, so there can be
1853        * only one after all, and the 1.40 text is a clarification, not a change.
1854        */
1855       if ($2.has_interpolation())
1856          _mesa_glsl_error(&@1, state, "duplicate interpolation qualifier");
1857
1858       if (!state->has_420pack_or_es31() &&
1859           ($2.flags.q.precise || $2.flags.q.invariant)) {
1860          _mesa_glsl_error(&@1, state, "interpolation qualifiers must come "
1861                           "after \"precise\" or \"invariant\"");
1862       }
1863
1864       $$ = $1;
1865       $$.merge_qualifier(&@1, state, $2, false);
1866    }
1867    | layout_qualifier type_qualifier
1868    {
1869       /* In the absence of ARB_shading_language_420pack, layout qualifiers may
1870        * appear no later than auxiliary storage qualifiers. There is no
1871        * particularly clear spec language mandating this, but in all examples
1872        * the layout qualifier precedes the storage qualifier.
1873        *
1874        * We allow combinations of layout with interpolation, invariant or
1875        * precise qualifiers since these are useful in ARB_separate_shader_objects.
1876        * There is no clear spec guidance on this either.
1877        */
1878       if (!state->has_420pack_or_es31() && $2.has_layout())
1879          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
1880
1881       $$ = $1;
1882       $$.merge_qualifier(&@1, state, $2, false);
1883    }
1884    | subroutine_qualifier type_qualifier
1885    {
1886       $$ = $1;
1887       $$.merge_qualifier(&@1, state, $2, false);
1888    }
1889    | auxiliary_storage_qualifier type_qualifier
1890    {
1891       if ($2.has_auxiliary_storage()) {
1892          _mesa_glsl_error(&@1, state,
1893                           "duplicate auxiliary storage qualifier (centroid or sample)");
1894       }
1895
1896       if (!state->has_420pack_or_es31() &&
1897           ($2.flags.q.precise || $2.flags.q.invariant ||
1898            $2.has_interpolation() || $2.has_layout())) {
1899          _mesa_glsl_error(&@1, state, "auxiliary storage qualifiers must come "
1900                           "just before storage qualifiers");
1901       }
1902       $$ = $1;
1903       $$.merge_qualifier(&@1, state, $2, false);
1904    }
1905    | storage_qualifier type_qualifier
1906    {
1907       /* Section 4.3 of the GLSL 1.20 specification states:
1908        * "Variable declarations may have a storage qualifier specified..."
1909        *  1.30 clarifies this to "may have one storage qualifier".
1910        */
1911       if ($2.has_storage())
1912          _mesa_glsl_error(&@1, state, "duplicate storage qualifier");
1913
1914       if (!state->has_420pack_or_es31() &&
1915           ($2.flags.q.precise || $2.flags.q.invariant || $2.has_interpolation() ||
1916            $2.has_layout() || $2.has_auxiliary_storage())) {
1917          _mesa_glsl_error(&@1, state, "storage qualifiers must come after "
1918                           "precise, invariant, interpolation, layout and auxiliary "
1919                           "storage qualifiers");
1920       }
1921
1922       $$ = $1;
1923       $$.merge_qualifier(&@1, state, $2, false);
1924    }
1925    | precision_qualifier type_qualifier
1926    {
1927       if ($2.precision != ast_precision_none)
1928          _mesa_glsl_error(&@1, state, "duplicate precision qualifier");
1929
1930       if (!(state->has_420pack_or_es31()) &&
1931           $2.flags.i != 0)
1932          _mesa_glsl_error(&@1, state, "precision qualifiers must come last");
1933
1934       $$ = $2;
1935       $$.precision = $1;
1936    }
1937    | memory_qualifier type_qualifier
1938    {
1939       $$ = $1;
1940       $$.merge_qualifier(&@1, state, $2, false);
1941    }
1942    ;
1943
1944 auxiliary_storage_qualifier:
1945    CENTROID
1946    {
1947       memset(& $$, 0, sizeof($$));
1948       $$.flags.q.centroid = 1;
1949    }
1950    | SAMPLE
1951    {
1952       memset(& $$, 0, sizeof($$));
1953       $$.flags.q.sample = 1;
1954    }
1955    | PATCH
1956    {
1957       memset(& $$, 0, sizeof($$));
1958       $$.flags.q.patch = 1;
1959    }
1960
1961 storage_qualifier:
1962    CONST_TOK
1963    {
1964       memset(& $$, 0, sizeof($$));
1965       $$.flags.q.constant = 1;
1966    }
1967    | ATTRIBUTE
1968    {
1969       memset(& $$, 0, sizeof($$));
1970       $$.flags.q.attribute = 1;
1971    }
1972    | VARYING
1973    {
1974       memset(& $$, 0, sizeof($$));
1975       $$.flags.q.varying = 1;
1976    }
1977    | IN_TOK
1978    {
1979       memset(& $$, 0, sizeof($$));
1980       $$.flags.q.in = 1;
1981    }
1982    | OUT_TOK
1983    {
1984       memset(& $$, 0, sizeof($$));
1985       $$.flags.q.out = 1;
1986
1987       if (state->stage == MESA_SHADER_GEOMETRY &&
1988           state->has_explicit_attrib_stream()) {
1989          /* Section 4.3.8.2 (Output Layout Qualifiers) of the GLSL 4.00
1990           * spec says:
1991           *
1992           *     "If the block or variable is declared with the stream
1993           *     identifier, it is associated with the specified stream;
1994           *     otherwise, it is associated with the current default stream."
1995           */
1996           $$.flags.q.stream = 1;
1997           $$.flags.q.explicit_stream = 0;
1998           $$.stream = state->out_qualifier->stream;
1999       }
2000
2001       if (state->has_enhanced_layouts()) {
2002           $$.flags.q.xfb_buffer = 1;
2003           $$.flags.q.explicit_xfb_buffer = 0;
2004           $$.xfb_buffer = state->out_qualifier->xfb_buffer;
2005       }
2006    }
2007    | INOUT_TOK
2008    {
2009       memset(& $$, 0, sizeof($$));
2010       $$.flags.q.in = 1;
2011       $$.flags.q.out = 1;
2012
2013       if (!state->has_framebuffer_fetch() ||
2014           !state->is_version(130, 300) ||
2015           state->stage != MESA_SHADER_FRAGMENT)
2016          _mesa_glsl_error(&@1, state, "A single interface variable cannot be "
2017                           "declared as both input and output");
2018    }
2019    | UNIFORM
2020    {
2021       memset(& $$, 0, sizeof($$));
2022       $$.flags.q.uniform = 1;
2023    }
2024    | BUFFER
2025    {
2026       memset(& $$, 0, sizeof($$));
2027       $$.flags.q.buffer = 1;
2028    }
2029    | SHARED
2030    {
2031       memset(& $$, 0, sizeof($$));
2032       $$.flags.q.shared_storage = 1;
2033    }
2034    ;
2035
2036 memory_qualifier:
2037    COHERENT
2038    {
2039       memset(& $$, 0, sizeof($$));
2040       $$.flags.q.coherent = 1;
2041    }
2042    | VOLATILE
2043    {
2044       memset(& $$, 0, sizeof($$));
2045       $$.flags.q._volatile = 1;
2046    }
2047    | RESTRICT
2048    {
2049       STATIC_ASSERT(sizeof($$.flags.q) <= sizeof($$.flags.i));
2050       memset(& $$, 0, sizeof($$));
2051       $$.flags.q.restrict_flag = 1;
2052    }
2053    | READONLY
2054    {
2055       memset(& $$, 0, sizeof($$));
2056       $$.flags.q.read_only = 1;
2057    }
2058    | WRITEONLY
2059    {
2060       memset(& $$, 0, sizeof($$));
2061       $$.flags.q.write_only = 1;
2062    }
2063    ;
2064
2065 array_specifier:
2066    '[' ']'
2067    {
2068       void *ctx = state->linalloc;
2069       $$ = new(ctx) ast_array_specifier(@1, new(ctx) ast_expression(
2070                                                   ast_unsized_array_dim, NULL,
2071                                                   NULL, NULL));
2072       $$->set_location_range(@1, @2);
2073    }
2074    | '[' constant_expression ']'
2075    {
2076       void *ctx = state->linalloc;
2077       $$ = new(ctx) ast_array_specifier(@1, $2);
2078       $$->set_location_range(@1, @3);
2079    }
2080    | array_specifier '[' ']'
2081    {
2082       void *ctx = state->linalloc;
2083       $$ = $1;
2084
2085       if (state->check_arrays_of_arrays_allowed(& @1)) {
2086          $$->add_dimension(new(ctx) ast_expression(ast_unsized_array_dim, NULL,
2087                                                    NULL, NULL));
2088       }
2089    }
2090    | array_specifier '[' constant_expression ']'
2091    {
2092       $$ = $1;
2093
2094       if (state->check_arrays_of_arrays_allowed(& @1)) {
2095          $$->add_dimension($3);
2096       }
2097    }
2098    ;
2099
2100 type_specifier:
2101    type_specifier_nonarray
2102    | type_specifier_nonarray array_specifier
2103    {
2104       $$ = $1;
2105       $$->array_specifier = $2;
2106    }
2107    ;
2108
2109 type_specifier_nonarray:
2110    basic_type_specifier_nonarray
2111    {
2112       void *ctx = state->linalloc;
2113       $$ = new(ctx) ast_type_specifier($1);
2114       $$->set_location(@1);
2115    }
2116    | struct_specifier
2117    {
2118       void *ctx = state->linalloc;
2119       $$ = new(ctx) ast_type_specifier($1);
2120       $$->set_location(@1);
2121    }
2122    | TYPE_IDENTIFIER
2123    {
2124       void *ctx = state->linalloc;
2125       $$ = new(ctx) ast_type_specifier($1);
2126       $$->set_location(@1);
2127    }
2128    ;
2129
2130 basic_type_specifier_nonarray:
2131    VOID_TOK                 { $$ = "void"; }
2132    | FLOAT_TOK              { $$ = "float"; }
2133    | DOUBLE_TOK             { $$ = "double"; }
2134    | INT_TOK                { $$ = "int"; }
2135    | UINT_TOK               { $$ = "uint"; }
2136    | BOOL_TOK               { $$ = "bool"; }
2137    | VEC2                   { $$ = "vec2"; }
2138    | VEC3                   { $$ = "vec3"; }
2139    | VEC4                   { $$ = "vec4"; }
2140    | BVEC2                  { $$ = "bvec2"; }
2141    | BVEC3                  { $$ = "bvec3"; }
2142    | BVEC4                  { $$ = "bvec4"; }
2143    | IVEC2                  { $$ = "ivec2"; }
2144    | IVEC3                  { $$ = "ivec3"; }
2145    | IVEC4                  { $$ = "ivec4"; }
2146    | UVEC2                  { $$ = "uvec2"; }
2147    | UVEC3                  { $$ = "uvec3"; }
2148    | UVEC4                  { $$ = "uvec4"; }
2149    | DVEC2                  { $$ = "dvec2"; }
2150    | DVEC3                  { $$ = "dvec3"; }
2151    | DVEC4                  { $$ = "dvec4"; }
2152    | MAT2X2                 { $$ = "mat2"; }
2153    | MAT2X3                 { $$ = "mat2x3"; }
2154    | MAT2X4                 { $$ = "mat2x4"; }
2155    | MAT3X2                 { $$ = "mat3x2"; }
2156    | MAT3X3                 { $$ = "mat3"; }
2157    | MAT3X4                 { $$ = "mat3x4"; }
2158    | MAT4X2                 { $$ = "mat4x2"; }
2159    | MAT4X3                 { $$ = "mat4x3"; }
2160    | MAT4X4                 { $$ = "mat4"; }
2161    | DMAT2X2                { $$ = "dmat2"; }
2162    | DMAT2X3                { $$ = "dmat2x3"; }
2163    | DMAT2X4                { $$ = "dmat2x4"; }
2164    | DMAT3X2                { $$ = "dmat3x2"; }
2165    | DMAT3X3                { $$ = "dmat3"; }
2166    | DMAT3X4                { $$ = "dmat3x4"; }
2167    | DMAT4X2                { $$ = "dmat4x2"; }
2168    | DMAT4X3                { $$ = "dmat4x3"; }
2169    | DMAT4X4                { $$ = "dmat4"; }
2170    | SAMPLER1D              { $$ = "sampler1D"; }
2171    | SAMPLER2D              { $$ = "sampler2D"; }
2172    | SAMPLER2DRECT          { $$ = "sampler2DRect"; }
2173    | SAMPLER3D              { $$ = "sampler3D"; }
2174    | SAMPLERCUBE            { $$ = "samplerCube"; }
2175    | SAMPLEREXTERNALOES     { $$ = "samplerExternalOES"; }
2176    | SAMPLER1DSHADOW        { $$ = "sampler1DShadow"; }
2177    | SAMPLER2DSHADOW        { $$ = "sampler2DShadow"; }
2178    | SAMPLER2DRECTSHADOW    { $$ = "sampler2DRectShadow"; }
2179    | SAMPLERCUBESHADOW      { $$ = "samplerCubeShadow"; }
2180    | SAMPLER1DARRAY         { $$ = "sampler1DArray"; }
2181    | SAMPLER2DARRAY         { $$ = "sampler2DArray"; }
2182    | SAMPLER1DARRAYSHADOW   { $$ = "sampler1DArrayShadow"; }
2183    | SAMPLER2DARRAYSHADOW   { $$ = "sampler2DArrayShadow"; }
2184    | SAMPLERBUFFER          { $$ = "samplerBuffer"; }
2185    | SAMPLERCUBEARRAY       { $$ = "samplerCubeArray"; }
2186    | SAMPLERCUBEARRAYSHADOW { $$ = "samplerCubeArrayShadow"; }
2187    | ISAMPLER1D             { $$ = "isampler1D"; }
2188    | ISAMPLER2D             { $$ = "isampler2D"; }
2189    | ISAMPLER2DRECT         { $$ = "isampler2DRect"; }
2190    | ISAMPLER3D             { $$ = "isampler3D"; }
2191    | ISAMPLERCUBE           { $$ = "isamplerCube"; }
2192    | ISAMPLER1DARRAY        { $$ = "isampler1DArray"; }
2193    | ISAMPLER2DARRAY        { $$ = "isampler2DArray"; }
2194    | ISAMPLERBUFFER         { $$ = "isamplerBuffer"; }
2195    | ISAMPLERCUBEARRAY      { $$ = "isamplerCubeArray"; }
2196    | USAMPLER1D             { $$ = "usampler1D"; }
2197    | USAMPLER2D             { $$ = "usampler2D"; }
2198    | USAMPLER2DRECT         { $$ = "usampler2DRect"; }
2199    | USAMPLER3D             { $$ = "usampler3D"; }
2200    | USAMPLERCUBE           { $$ = "usamplerCube"; }
2201    | USAMPLER1DARRAY        { $$ = "usampler1DArray"; }
2202    | USAMPLER2DARRAY        { $$ = "usampler2DArray"; }
2203    | USAMPLERBUFFER         { $$ = "usamplerBuffer"; }
2204    | USAMPLERCUBEARRAY      { $$ = "usamplerCubeArray"; }
2205    | SAMPLER2DMS            { $$ = "sampler2DMS"; }
2206    | ISAMPLER2DMS           { $$ = "isampler2DMS"; }
2207    | USAMPLER2DMS           { $$ = "usampler2DMS"; }
2208    | SAMPLER2DMSARRAY       { $$ = "sampler2DMSArray"; }
2209    | ISAMPLER2DMSARRAY      { $$ = "isampler2DMSArray"; }
2210    | USAMPLER2DMSARRAY      { $$ = "usampler2DMSArray"; }
2211    | IMAGE1D                { $$ = "image1D"; }
2212    | IMAGE2D                { $$ = "image2D"; }
2213    | IMAGE3D                { $$ = "image3D"; }
2214    | IMAGE2DRECT            { $$ = "image2DRect"; }
2215    | IMAGECUBE              { $$ = "imageCube"; }
2216    | IMAGEBUFFER            { $$ = "imageBuffer"; }
2217    | IMAGE1DARRAY           { $$ = "image1DArray"; }
2218    | IMAGE2DARRAY           { $$ = "image2DArray"; }
2219    | IMAGECUBEARRAY         { $$ = "imageCubeArray"; }
2220    | IMAGE2DMS              { $$ = "image2DMS"; }
2221    | IMAGE2DMSARRAY         { $$ = "image2DMSArray"; }
2222    | IIMAGE1D               { $$ = "iimage1D"; }
2223    | IIMAGE2D               { $$ = "iimage2D"; }
2224    | IIMAGE3D               { $$ = "iimage3D"; }
2225    | IIMAGE2DRECT           { $$ = "iimage2DRect"; }
2226    | IIMAGECUBE             { $$ = "iimageCube"; }
2227    | IIMAGEBUFFER           { $$ = "iimageBuffer"; }
2228    | IIMAGE1DARRAY          { $$ = "iimage1DArray"; }
2229    | IIMAGE2DARRAY          { $$ = "iimage2DArray"; }
2230    | IIMAGECUBEARRAY        { $$ = "iimageCubeArray"; }
2231    | IIMAGE2DMS             { $$ = "iimage2DMS"; }
2232    | IIMAGE2DMSARRAY        { $$ = "iimage2DMSArray"; }
2233    | UIMAGE1D               { $$ = "uimage1D"; }
2234    | UIMAGE2D               { $$ = "uimage2D"; }
2235    | UIMAGE3D               { $$ = "uimage3D"; }
2236    | UIMAGE2DRECT           { $$ = "uimage2DRect"; }
2237    | UIMAGECUBE             { $$ = "uimageCube"; }
2238    | UIMAGEBUFFER           { $$ = "uimageBuffer"; }
2239    | UIMAGE1DARRAY          { $$ = "uimage1DArray"; }
2240    | UIMAGE2DARRAY          { $$ = "uimage2DArray"; }
2241    | UIMAGECUBEARRAY        { $$ = "uimageCubeArray"; }
2242    | UIMAGE2DMS             { $$ = "uimage2DMS"; }
2243    | UIMAGE2DMSARRAY        { $$ = "uimage2DMSArray"; }
2244    | ATOMIC_UINT            { $$ = "atomic_uint"; }
2245    ;
2246
2247 precision_qualifier:
2248    HIGHP
2249    {
2250       state->check_precision_qualifiers_allowed(&@1);
2251       $$ = ast_precision_high;
2252    }
2253    | MEDIUMP
2254    {
2255       state->check_precision_qualifiers_allowed(&@1);
2256       $$ = ast_precision_medium;
2257    }
2258    | LOWP
2259    {
2260       state->check_precision_qualifiers_allowed(&@1);
2261       $$ = ast_precision_low;
2262    }
2263    ;
2264
2265 struct_specifier:
2266    STRUCT any_identifier '{' struct_declaration_list '}'
2267    {
2268       void *ctx = state->linalloc;
2269       $$ = new(ctx) ast_struct_specifier(ctx, $2, $4);
2270       $$->set_location_range(@2, @5);
2271       state->symbols->add_type($2, glsl_type::void_type);
2272    }
2273    | STRUCT '{' struct_declaration_list '}'
2274    {
2275       void *ctx = state->linalloc;
2276       $$ = new(ctx) ast_struct_specifier(ctx, NULL, $3);
2277       $$->set_location_range(@2, @4);
2278    }
2279    ;
2280
2281 struct_declaration_list:
2282    struct_declaration
2283    {
2284       $$ = $1;
2285       $1->link.self_link();
2286    }
2287    | struct_declaration_list struct_declaration
2288    {
2289       $$ = $1;
2290       $$->link.insert_before(& $2->link);
2291    }
2292    ;
2293
2294 struct_declaration:
2295    fully_specified_type struct_declarator_list ';'
2296    {
2297       void *ctx = state->linalloc;
2298       ast_fully_specified_type *const type = $1;
2299       type->set_location(@1);
2300
2301       if (type->qualifier.flags.i != 0)
2302          _mesa_glsl_error(&@1, state,
2303                           "only precision qualifiers may be applied to "
2304                           "structure members");
2305
2306       $$ = new(ctx) ast_declarator_list(type);
2307       $$->set_location(@2);
2308
2309       $$->declarations.push_degenerate_list_at_head(& $2->link);
2310    }
2311    ;
2312
2313 struct_declarator_list:
2314    struct_declarator
2315    {
2316       $$ = $1;
2317       $1->link.self_link();
2318    }
2319    | struct_declarator_list ',' struct_declarator
2320    {
2321       $$ = $1;
2322       $$->link.insert_before(& $3->link);
2323    }
2324    ;
2325
2326 struct_declarator:
2327    any_identifier
2328    {
2329       void *ctx = state->linalloc;
2330       $$ = new(ctx) ast_declaration($1, NULL, NULL);
2331       $$->set_location(@1);
2332    }
2333    | any_identifier array_specifier
2334    {
2335       void *ctx = state->linalloc;
2336       $$ = new(ctx) ast_declaration($1, $2, NULL);
2337       $$->set_location_range(@1, @2);
2338    }
2339    ;
2340
2341 initializer:
2342    assignment_expression
2343    | '{' initializer_list '}'
2344    {
2345       $$ = $2;
2346    }
2347    | '{' initializer_list ',' '}'
2348    {
2349       $$ = $2;
2350    }
2351    ;
2352
2353 initializer_list:
2354    initializer
2355    {
2356       void *ctx = state->linalloc;
2357       $$ = new(ctx) ast_aggregate_initializer();
2358       $$->set_location(@1);
2359       $$->expressions.push_tail(& $1->link);
2360    }
2361    | initializer_list ',' initializer
2362    {
2363       $1->expressions.push_tail(& $3->link);
2364    }
2365    ;
2366
2367 declaration_statement:
2368    declaration
2369    ;
2370
2371    // Grammar Note: labeled statements for SWITCH only; 'goto' is not
2372    // supported.
2373 statement:
2374    compound_statement        { $$ = (ast_node *) $1; }
2375    | simple_statement
2376    ;
2377
2378 simple_statement:
2379    declaration_statement
2380    | expression_statement
2381    | selection_statement
2382    | switch_statement
2383    | iteration_statement
2384    | jump_statement
2385    ;
2386
2387 compound_statement:
2388    '{' '}'
2389    {
2390       void *ctx = state->linalloc;
2391       $$ = new(ctx) ast_compound_statement(true, NULL);
2392       $$->set_location_range(@1, @2);
2393    }
2394    | '{'
2395    {
2396       state->symbols->push_scope();
2397    }
2398    statement_list '}'
2399    {
2400       void *ctx = state->linalloc;
2401       $$ = new(ctx) ast_compound_statement(true, $3);
2402       $$->set_location_range(@1, @4);
2403       state->symbols->pop_scope();
2404    }
2405    ;
2406
2407 statement_no_new_scope:
2408    compound_statement_no_new_scope { $$ = (ast_node *) $1; }
2409    | simple_statement
2410    ;
2411
2412 compound_statement_no_new_scope:
2413    '{' '}'
2414    {
2415       void *ctx = state->linalloc;
2416       $$ = new(ctx) ast_compound_statement(false, NULL);
2417       $$->set_location_range(@1, @2);
2418    }
2419    | '{' statement_list '}'
2420    {
2421       void *ctx = state->linalloc;
2422       $$ = new(ctx) ast_compound_statement(false, $2);
2423       $$->set_location_range(@1, @3);
2424    }
2425    ;
2426
2427 statement_list:
2428    statement
2429    {
2430       if ($1 == NULL) {
2431          _mesa_glsl_error(& @1, state, "<nil> statement");
2432          assert($1 != NULL);
2433       }
2434
2435       $$ = $1;
2436       $$->link.self_link();
2437    }
2438    | statement_list statement
2439    {
2440       if ($2 == NULL) {
2441          _mesa_glsl_error(& @2, state, "<nil> statement");
2442          assert($2 != NULL);
2443       }
2444       $$ = $1;
2445       $$->link.insert_before(& $2->link);
2446    }
2447    ;
2448
2449 expression_statement:
2450    ';'
2451    {
2452       void *ctx = state->linalloc;
2453       $$ = new(ctx) ast_expression_statement(NULL);
2454       $$->set_location(@1);
2455    }
2456    | expression ';'
2457    {
2458       void *ctx = state->linalloc;
2459       $$ = new(ctx) ast_expression_statement($1);
2460       $$->set_location(@1);
2461    }
2462    ;
2463
2464 selection_statement:
2465    IF '(' expression ')' selection_rest_statement
2466    {
2467       $$ = new(state->linalloc) ast_selection_statement($3, $5.then_statement,
2468                                                         $5.else_statement);
2469       $$->set_location_range(@1, @5);
2470    }
2471    ;
2472
2473 selection_rest_statement:
2474    statement ELSE statement
2475    {
2476       $$.then_statement = $1;
2477       $$.else_statement = $3;
2478    }
2479    | statement %prec THEN
2480    {
2481       $$.then_statement = $1;
2482       $$.else_statement = NULL;
2483    }
2484    ;
2485
2486 condition:
2487    expression
2488    {
2489       $$ = (ast_node *) $1;
2490    }
2491    | fully_specified_type any_identifier '=' initializer
2492    {
2493       void *ctx = state->linalloc;
2494       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, $4);
2495       ast_declarator_list *declarator = new(ctx) ast_declarator_list($1);
2496       decl->set_location_range(@2, @4);
2497       declarator->set_location(@1);
2498
2499       declarator->declarations.push_tail(&decl->link);
2500       $$ = declarator;
2501    }
2502    ;
2503
2504 /*
2505  * switch_statement grammar is based on the syntax described in the body
2506  * of the GLSL spec, not in it's appendix!!!
2507  */
2508 switch_statement:
2509    SWITCH '(' expression ')' switch_body
2510    {
2511       $$ = new(state->linalloc) ast_switch_statement($3, $5);
2512       $$->set_location_range(@1, @5);
2513    }
2514    ;
2515
2516 switch_body:
2517    '{' '}'
2518    {
2519       $$ = new(state->linalloc) ast_switch_body(NULL);
2520       $$->set_location_range(@1, @2);
2521    }
2522    | '{' case_statement_list '}'
2523    {
2524       $$ = new(state->linalloc) ast_switch_body($2);
2525       $$->set_location_range(@1, @3);
2526    }
2527    ;
2528
2529 case_label:
2530    CASE expression ':'
2531    {
2532       $$ = new(state->linalloc) ast_case_label($2);
2533       $$->set_location(@2);
2534    }
2535    | DEFAULT ':'
2536    {
2537       $$ = new(state->linalloc) ast_case_label(NULL);
2538       $$->set_location(@2);
2539    }
2540    ;
2541
2542 case_label_list:
2543    case_label
2544    {
2545       ast_case_label_list *labels = new(state->linalloc) ast_case_label_list();
2546
2547       labels->labels.push_tail(& $1->link);
2548       $$ = labels;
2549       $$->set_location(@1);
2550    }
2551    | case_label_list case_label
2552    {
2553       $$ = $1;
2554       $$->labels.push_tail(& $2->link);
2555    }
2556    ;
2557
2558 case_statement:
2559    case_label_list statement
2560    {
2561       ast_case_statement *stmts = new(state->linalloc) ast_case_statement($1);
2562       stmts->set_location(@2);
2563
2564       stmts->stmts.push_tail(& $2->link);
2565       $$ = stmts;
2566    }
2567    | case_statement statement
2568    {
2569       $$ = $1;
2570       $$->stmts.push_tail(& $2->link);
2571    }
2572    ;
2573
2574 case_statement_list:
2575    case_statement
2576    {
2577       ast_case_statement_list *cases= new(state->linalloc) ast_case_statement_list();
2578       cases->set_location(@1);
2579
2580       cases->cases.push_tail(& $1->link);
2581       $$ = cases;
2582    }
2583    | case_statement_list case_statement
2584    {
2585       $$ = $1;
2586       $$->cases.push_tail(& $2->link);
2587    }
2588    ;
2589
2590 iteration_statement:
2591    WHILE '(' condition ')' statement_no_new_scope
2592    {
2593       void *ctx = state->linalloc;
2594       $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_while,
2595                                             NULL, $3, NULL, $5);
2596       $$->set_location_range(@1, @4);
2597    }
2598    | DO statement WHILE '(' expression ')' ';'
2599    {
2600       void *ctx = state->linalloc;
2601       $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_do_while,
2602                                             NULL, $5, NULL, $2);
2603       $$->set_location_range(@1, @6);
2604    }
2605    | FOR '(' for_init_statement for_rest_statement ')' statement_no_new_scope
2606    {
2607       void *ctx = state->linalloc;
2608       $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_for,
2609                                             $3, $4.cond, $4.rest, $6);
2610       $$->set_location_range(@1, @6);
2611    }
2612    ;
2613
2614 for_init_statement:
2615    expression_statement
2616    | declaration_statement
2617    ;
2618
2619 conditionopt:
2620    condition
2621    | /* empty */
2622    {
2623       $$ = NULL;
2624    }
2625    ;
2626
2627 for_rest_statement:
2628    conditionopt ';'
2629    {
2630       $$.cond = $1;
2631       $$.rest = NULL;
2632    }
2633    | conditionopt ';' expression
2634    {
2635       $$.cond = $1;
2636       $$.rest = $3;
2637    }
2638    ;
2639
2640    // Grammar Note: No 'goto'. Gotos are not supported.
2641 jump_statement:
2642    CONTINUE ';'
2643    {
2644       void *ctx = state->linalloc;
2645       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_continue, NULL);
2646       $$->set_location(@1);
2647    }
2648    | BREAK ';'
2649    {
2650       void *ctx = state->linalloc;
2651       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_break, NULL);
2652       $$->set_location(@1);
2653    }
2654    | RETURN ';'
2655    {
2656       void *ctx = state->linalloc;
2657       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, NULL);
2658       $$->set_location(@1);
2659    }
2660    | RETURN expression ';'
2661    {
2662       void *ctx = state->linalloc;
2663       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, $2);
2664       $$->set_location_range(@1, @2);
2665    }
2666    | DISCARD ';' // Fragment shader only.
2667    {
2668       void *ctx = state->linalloc;
2669       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_discard, NULL);
2670       $$->set_location(@1);
2671    }
2672    ;
2673
2674 external_declaration:
2675    function_definition      { $$ = $1; }
2676    | declaration            { $$ = $1; }
2677    | pragma_statement       { $$ = NULL; }
2678    | layout_defaults        { $$ = $1; }
2679    ;
2680
2681 function_definition:
2682    function_prototype compound_statement_no_new_scope
2683    {
2684       void *ctx = state->linalloc;
2685       $$ = new(ctx) ast_function_definition();
2686       $$->set_location_range(@1, @2);
2687       $$->prototype = $1;
2688       $$->body = $2;
2689
2690       state->symbols->pop_scope();
2691    }
2692    ;
2693
2694 /* layout_qualifieropt is packed into this rule */
2695 interface_block:
2696    basic_interface_block
2697    {
2698       $$ = $1;
2699    }
2700    | layout_qualifier interface_block
2701    {
2702       ast_interface_block *block = (ast_interface_block *) $2;
2703
2704       if (!state->has_420pack_or_es31() && block->layout.has_layout() &&
2705           !block->layout.is_default_qualifier) {
2706          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2707          YYERROR;
2708       }
2709
2710       if (!block->layout.merge_qualifier(& @1, state, $1, false)) {
2711          YYERROR;
2712       }
2713
2714       block->layout.is_default_qualifier = false;
2715
2716       $$ = block;
2717    }
2718    | memory_qualifier interface_block
2719    {
2720       ast_interface_block *block = (ast_interface_block *)$2;
2721
2722       if (!block->layout.flags.q.buffer) {
2723             _mesa_glsl_error(& @1, state,
2724                              "memory qualifiers can only be used in the "
2725                              "declaration of shader storage blocks");
2726       }
2727       if (!block->layout.merge_qualifier(& @1, state, $1, false)) {
2728          YYERROR;
2729       }
2730       $$ = block;
2731    }
2732    ;
2733
2734 basic_interface_block:
2735    interface_qualifier NEW_IDENTIFIER '{' member_list '}' instance_name_opt ';'
2736    {
2737       ast_interface_block *const block = $6;
2738
2739       if ($1.flags.q.uniform) {
2740          block->layout = *state->default_uniform_qualifier;
2741       } else if ($1.flags.q.buffer) {
2742          block->layout = *state->default_shader_storage_qualifier;
2743       }
2744       block->block_name = $2;
2745       block->declarations.push_degenerate_list_at_head(& $4->link);
2746
2747       _mesa_ast_process_interface_block(& @1, state, block, $1);
2748
2749       $$ = block;
2750    }
2751    ;
2752
2753 interface_qualifier:
2754    IN_TOK
2755    {
2756       memset(& $$, 0, sizeof($$));
2757       $$.flags.q.in = 1;
2758    }
2759    | OUT_TOK
2760    {
2761       memset(& $$, 0, sizeof($$));
2762       $$.flags.q.out = 1;
2763    }
2764    | UNIFORM
2765    {
2766       memset(& $$, 0, sizeof($$));
2767       $$.flags.q.uniform = 1;
2768    }
2769    | BUFFER
2770    {
2771       memset(& $$, 0, sizeof($$));
2772       $$.flags.q.buffer = 1;
2773    }
2774    | auxiliary_storage_qualifier interface_qualifier
2775    {
2776       if (!$1.flags.q.patch) {
2777          _mesa_glsl_error(&@1, state, "invalid interface qualifier");
2778       }
2779       if ($2.has_auxiliary_storage()) {
2780          _mesa_glsl_error(&@1, state, "duplicate patch qualifier");
2781       }
2782       $$ = $2;
2783       $$.flags.q.patch = 1;
2784    }
2785    ;
2786
2787 instance_name_opt:
2788    /* empty */
2789    {
2790       $$ = new(state->linalloc) ast_interface_block(NULL, NULL);
2791    }
2792    | NEW_IDENTIFIER
2793    {
2794       $$ = new(state->linalloc) ast_interface_block($1, NULL);
2795       $$->set_location(@1);
2796    }
2797    | NEW_IDENTIFIER array_specifier
2798    {
2799       $$ = new(state->linalloc) ast_interface_block($1, $2);
2800       $$->set_location_range(@1, @2);
2801    }
2802    ;
2803
2804 member_list:
2805    member_declaration
2806    {
2807       $$ = $1;
2808       $1->link.self_link();
2809    }
2810    | member_declaration member_list
2811    {
2812       $$ = $1;
2813       $2->link.insert_before(& $$->link);
2814    }
2815    ;
2816
2817 member_declaration:
2818    fully_specified_type struct_declarator_list ';'
2819    {
2820       void *ctx = state->linalloc;
2821       ast_fully_specified_type *type = $1;
2822       type->set_location(@1);
2823
2824       if (type->qualifier.flags.q.attribute) {
2825          _mesa_glsl_error(& @1, state,
2826                           "keyword 'attribute' cannot be used with "
2827                           "interface block member");
2828       } else if (type->qualifier.flags.q.varying) {
2829          _mesa_glsl_error(& @1, state,
2830                           "keyword 'varying' cannot be used with "
2831                           "interface block member");
2832       }
2833
2834       $$ = new(ctx) ast_declarator_list(type);
2835       $$->set_location(@2);
2836
2837       $$->declarations.push_degenerate_list_at_head(& $2->link);
2838    }
2839    ;
2840
2841 layout_uniform_defaults:
2842    layout_qualifier layout_uniform_defaults
2843    {
2844       $$ = NULL;
2845       if (!state->has_420pack_or_es31()) {
2846          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2847          YYERROR;
2848       } else {
2849          if (!state->default_uniform_qualifier->
2850                 merge_qualifier(& @1, state, $1, false)) {
2851             YYERROR;
2852          }
2853       }
2854    }
2855    | layout_qualifier UNIFORM ';'
2856    {
2857       if (!state->default_uniform_qualifier->
2858              merge_qualifier(& @1, state, $1, false)) {
2859          YYERROR;
2860       }
2861       $$ = NULL;
2862    }
2863    ;
2864
2865 layout_buffer_defaults:
2866    layout_qualifier layout_buffer_defaults
2867    {
2868       $$ = NULL;
2869       if (!state->has_420pack_or_es31()) {
2870          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2871          YYERROR;
2872       } else {
2873          if (!state->default_shader_storage_qualifier->
2874                 merge_qualifier(& @1, state, $1, false)) {
2875             YYERROR;
2876          }
2877       }
2878    }
2879    | layout_qualifier BUFFER ';'
2880    {
2881       if (!state->default_shader_storage_qualifier->
2882              merge_qualifier(& @1, state, $1, false)) {
2883          YYERROR;
2884       }
2885
2886       /* From the GLSL 4.50 spec, section 4.4.5:
2887        *
2888        *     "It is a compile-time error to specify the binding identifier for
2889        *     the global scope or for block member declarations."
2890        */
2891       if (state->default_shader_storage_qualifier->flags.q.explicit_binding) {
2892          _mesa_glsl_error(& @1, state,
2893                           "binding qualifier cannot be set for default layout");
2894       }
2895
2896       $$ = NULL;
2897    }
2898    ;
2899
2900 layout_in_defaults:
2901    layout_qualifier layout_in_defaults
2902    {
2903       $$ = NULL;
2904       if (!state->has_420pack_or_es31()) {
2905          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2906          YYERROR;
2907       } else {
2908          if (!state->in_qualifier->
2909                 merge_in_qualifier(& @1, state, $1, $$, false)) {
2910             YYERROR;
2911          }
2912          $$ = $2;
2913       }
2914    }
2915    | layout_qualifier IN_TOK ';'
2916    {
2917       $$ = NULL;
2918       if (!state->in_qualifier->
2919              merge_in_qualifier(& @1, state, $1, $$, true)) {
2920          YYERROR;
2921       }
2922    }
2923    ;
2924
2925 layout_out_defaults:
2926    layout_qualifier layout_out_defaults
2927    {
2928       $$ = NULL;
2929       if (!state->has_420pack_or_es31()) {
2930          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2931          YYERROR;
2932       } else {
2933          if (!state->out_qualifier->
2934                 merge_out_qualifier(& @1, state, $1, $$, false)) {
2935             YYERROR;
2936          }
2937          $$ = $2;
2938       }
2939    }
2940    | layout_qualifier OUT_TOK ';'
2941    {
2942       $$ = NULL;
2943       if (!state->out_qualifier->
2944              merge_out_qualifier(& @1, state, $1, $$, true))
2945          YYERROR;
2946    }
2947    ;
2948
2949 layout_defaults:
2950    layout_uniform_defaults
2951    | layout_buffer_defaults
2952    | layout_in_defaults
2953    | layout_out_defaults
2954    ;