configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.67
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 102 AC_CHECK_PROGS([PYTHON3], [python3.5 python3.4 python3])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112
 113 AX_PROG_BISON([],
 114               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 115                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 116 AX_PROG_FLEX([],
 117              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 118                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 119
 120 AC_CHECK_PROG(INDENT, indent, indent, cat)
 121 if test "x$INDENT" != "xcat"; then
 122     # Only GNU indent is supported
 123     INDENT_VERSION=`indent --version | grep GNU`
 124     if test $? -eq 0; then
 125        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 126     else
 127        INDENT="cat"
 128     fi
 129 fi
 130
 131 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 132
 133 if test -z "$PYTHON2"; then
 134     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 135         AC_MSG_ERROR([Python not found - unable to generate sources])
 136     fi
 137 else
 138     if test "x$acv_mako_found" = xno; then
 139         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 140             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 141         fi
 142     fi
 143 fi
 144
 145 if test -z "$PYTHON3"; then
 146     if test ! -f "$srcdir/src/intel/genxml/gen9_pack.h"; then
 147         AC_MSG_ERROR([Python3 not found - unable to generate sources])
 148     fi
 149 fi
 150
 151 AC_PROG_INSTALL
 152
 153 dnl We need a POSIX shell for parts of the build. Assume we have one
 154 dnl in most cases.
 155 case "$host_os" in
 156 solaris*)
 157     # Solaris /bin/sh is too old/non-POSIX compliant
 158     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 159     SHELL="$POSIX_SHELL"
 160     ;;
 161 esac
 162
 163 dnl clang is mostly GCC-compatible, but its version is much lower,
 164 dnl so we have to check for it.
 165 AC_MSG_CHECKING([if compiling with clang])
 166
 167 AC_COMPILE_IFELSE(
 168 [AC_LANG_PROGRAM([], [[
 169 #ifndef __clang__
 170        not clang
 171 #endif
 172 ]])],
 173 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 174
 175 AC_MSG_RESULT([$acv_mesa_CLANG])
 176
 177 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 178 dnl versions are explictly not supported.
 179 GEN_ASM_OFFSETS=no
 180 USE_GNU99=no
 181 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 182     AC_MSG_CHECKING([whether gcc version is sufficient])
 183     major=0
 184     minor=0
 185
 186     GCC_VERSION=`$CC -dumpversion`
 187     if test $? -eq 0; then
 188         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 189         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 193         AC_MSG_RESULT([no])
 194         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 195     else
 196         AC_MSG_RESULT([yes])
 197     fi
 198
 199     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 200         USE_GNU99=yes
 201     fi
 202     if test "x$cross_compiling" = xyes; then
 203         GEN_ASM_OFFSETS=yes
 204     fi
 205 fi
 206
 207 dnl We don't support building Mesa with Sun C compiler
 208 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 209 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 210 if test "x$SUNCC" = xyes; then
 211     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 212 fi
 213
 214 dnl Check for compiler builtins
 215 AX_GCC_BUILTIN([__builtin_bswap32])
 216 AX_GCC_BUILTIN([__builtin_bswap64])
 217 AX_GCC_BUILTIN([__builtin_clz])
 218 AX_GCC_BUILTIN([__builtin_clzll])
 219 AX_GCC_BUILTIN([__builtin_ctz])
 220 AX_GCC_BUILTIN([__builtin_expect])
 221 AX_GCC_BUILTIN([__builtin_ffs])
 222 AX_GCC_BUILTIN([__builtin_ffsll])
 223 AX_GCC_BUILTIN([__builtin_popcount])
 224 AX_GCC_BUILTIN([__builtin_popcountll])
 225 AX_GCC_BUILTIN([__builtin_unreachable])
 226
 227 AX_GCC_FUNC_ATTRIBUTE([const])
 228 AX_GCC_FUNC_ATTRIBUTE([flatten])
 229 AX_GCC_FUNC_ATTRIBUTE([format])
 230 AX_GCC_FUNC_ATTRIBUTE([malloc])
 231 AX_GCC_FUNC_ATTRIBUTE([packed])
 232 AX_GCC_FUNC_ATTRIBUTE([pure])
 233 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 234 AX_GCC_FUNC_ATTRIBUTE([unused])
 235 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 236 AX_GCC_FUNC_ATTRIBUTE([weak])
 237
 238 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 239
 240 dnl Make sure the pkg-config macros are defined
 241 m4_ifndef([PKG_PROG_PKG_CONFIG],
 242     [m4_fatal([Could not locate the pkg-config autoconf macros.
 243   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 244   are in a different location, try setting the environment variable
 245   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 246 PKG_PROG_PKG_CONFIG()
 247
 248 dnl LIB_DIR - library basename
 249 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 250 AC_SUBST([LIB_DIR])
 251
 252 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 253 _SAVE_LDFLAGS="$LDFLAGS"
 254 _SAVE_CPPFLAGS="$CPPFLAGS"
 255
 256 dnl Compiler macros
 257 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 258 AC_SUBST([DEFINES])
 259 android=no
 260 case "$host_os" in
 261 *-android)
 262     android=yes
 263     ;;
 264 linux*|*-gnu*|gnu*)
 265     DEFINES="$DEFINES -D_GNU_SOURCE"
 266     ;;
 267 solaris*)
 268     DEFINES="$DEFINES -DSVR4"
 269     ;;
 270 cygwin*)
 271     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 272     ;;
 273 esac
 274
 275 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 276
 277 dnl Add flags for gcc and g++
 278 if test "x$GCC" = xyes; then
 279     CFLAGS="$CFLAGS -Wall"
 280
 281     if test "x$USE_GNU99" = xyes; then
 282         CFLAGS="$CFLAGS -std=gnu99"
 283     else
 284         CFLAGS="$CFLAGS -std=c99"
 285     fi
 286
 287     # Enable -Werror=implicit-function-declaration and
 288     # -Werror=missing-prototypes, if available, or otherwise, just
 289     # -Wmissing-prototypes.  This is particularly useful to avoid
 290     # generating a loadable driver module that has undefined symbols.
 291     save_CFLAGS="$CFLAGS"
 292     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 293     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 294     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 296                    AC_MSG_RESULT([yes]),
 297                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 298                     AC_MSG_RESULT([no])]);
 299
 300     # Enable -fvisibility=hidden if using a gcc that supports it
 301     save_CFLAGS="$CFLAGS"
 302     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 303     VISIBILITY_CFLAGS="-fvisibility=hidden"
 304     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 306                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 307
 308     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 309     CFLAGS=$save_CFLAGS
 310
 311     # Work around aliasing bugs - developers should comment this out
 312     CFLAGS="$CFLAGS -fno-strict-aliasing"
 313
 314     # We don't want floating-point math functions to set errno or trap
 315     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 316
 317     # gcc's builtin memcmp is slower than glibc's
 318     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 319     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 320
 321     # Flags to help ensure that certain portions of the code -- and only those
 322     # portions -- can be built with MSVC:
 323     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 324     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 325     #   supports most of C99)
 326     # - the rest has no compiler compiler restrictions
 327     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 328     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 329
 330     # Enable -Werror=vla if compiler supports it
 331     save_CFLAGS="$CFLAGS"
 332     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 333     CFLAGS="$CFLAGS -Werror=vla"
 334     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 335                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 336                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 337                     AC_MSG_RESULT([yes])],
 338                     AC_MSG_RESULT([no]));
 339     CFLAGS="$save_CFLAGS"
 340 fi
 341 if test "x$GXX" = xyes; then
 342     CXXFLAGS="$CXXFLAGS -Wall"
 343
 344     # Enable -fvisibility=hidden if using a gcc that supports it
 345     save_CXXFLAGS="$CXXFLAGS"
 346     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 347     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 348     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 349     AC_LANG_PUSH([C++])
 350     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 351                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 352     AC_LANG_POP([C++])
 353
 354     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 355     CXXFLAGS=$save_CXXFLAGS
 356
 357     # Work around aliasing bugs - developers should comment this out
 358     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 359
 360     # gcc's builtin memcmp is slower than glibc's
 361     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 362     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 363 fi
 364
 365 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 366 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 367
 368 dnl even if the compiler appears to support it, using visibility attributes isn't
 369 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 370 case "$host_os" in
 371 cygwin*)
 372     VISIBILITY_CFLAGS=""
 373     VISIBILITY_CXXFLAGS=""
 374     ;;
 375 esac
 376
 377 AC_SUBST([VISIBILITY_CFLAGS])
 378 AC_SUBST([VISIBILITY_CXXFLAGS])
 379
 380 dnl
 381 dnl Optional flags, check for compiler support
 382 dnl
 383 SSE41_CFLAGS="-msse4.1"
 384 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 385 dnl stack, but on x86-32 such alignment is not guaranteed.
 386 case "$target_cpu" in
 387 i?86)
 388     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 389     ;;
 390 esac
 391 save_CFLAGS="$CFLAGS"
 392 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 393 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 394 #include <smmintrin.h>
 395 int param;
 396 int main () {
 397     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 398     c = _mm_max_epu32(a, b);
 399     return _mm_cvtsi128_si32(c);
 400 }]])], SSE41_SUPPORTED=1)
 401 CFLAGS="$save_CFLAGS"
 402 if test "x$SSE41_SUPPORTED" = x1; then
 403     DEFINES="$DEFINES -DUSE_SSE41"
 404 fi
 405 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 406 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 407
 408 dnl Check for Endianness
 409 AC_C_BIGENDIAN(
 410    little_endian=no,
 411    little_endian=yes,
 412    little_endian=no,
 413    little_endian=no
 414 )
 415
 416 dnl Check for POWER8 Architecture
 417 PWR8_CFLAGS="-mpower8-vector"
 418 have_pwr8_intrinsics=no
 419 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 420 save_CFLAGS=$CFLAGS
 421 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 422 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 423 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 424 #error "Need GCC >= 4.8 for sane POWER8 support"
 425 #endif
 426 #include <altivec.h>
 427 int main () {
 428     vector unsigned char r;
 429     vector unsigned int v = vec_splat_u32 (1);
 430     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 431     return 0;
 432 }]])], have_pwr8_intrinsics=yes)
 433 CFLAGS=$save_CFLAGS
 434
 435 AC_ARG_ENABLE(pwr8,
 436    [AC_HELP_STRING([--disable-pwr8-inst],
 437                    [disable POWER8-specific instructions])],
 438    [enable_pwr8=$enableval], [enable_pwr8=auto])
 439
 440 if test "x$enable_pwr8" = xno ; then
 441    have_pwr8_intrinsics=disabled
 442 fi
 443
 444 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 445    DEFINES="$DEFINES -D_ARCH_PWR8"
 446    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 447    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 448 else
 449    PWR8_CFLAGS=
 450 fi
 451
 452 AC_MSG_RESULT($have_pwr8_intrinsics)
 453 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 454    AC_MSG_ERROR([POWER8 compiler support not detected])
 455 fi
 456
 457 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 458    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 459 fi
 460
 461 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 462
 463 dnl Can't have static and shared libraries, default to static if user
 464 dnl explicitly requested. If both disabled, set to static since shared
 465 dnl was explicitly requested.
 466 case "x$enable_static$enable_shared" in
 467 xyesyes)
 468     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 469     enable_shared=no
 470     ;;
 471 xnono)
 472     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 473     enable_shared=yes
 474     ;;
 475 esac
 476
 477 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 478
 479 dnl
 480 dnl other compiler options
 481 dnl
 482 AC_ARG_ENABLE([debug],
 483     [AS_HELP_STRING([--enable-debug],
 484         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 485     [enable_debug="$enableval"],
 486     [enable_debug=no]
 487 )
 488
 489 AC_ARG_ENABLE([profile],
 490     [AS_HELP_STRING([--enable-profile],
 491         [enable profiling of code @<:@default=disabled@:>@])],
 492     [enable_profile="$enableval"],
 493     [enable_profile=no]
 494 )
 495
 496 if test "x$enable_profile" = xyes; then
 497     DEFINES="$DEFINES -DPROFILE"
 498     if test "x$GCC" = xyes; then
 499         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 500     fi
 501     if test "x$GXX" = xyes; then
 502         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 503     fi
 504 fi
 505
 506 if test "x$enable_debug" = xyes; then
 507     DEFINES="$DEFINES -DDEBUG"
 508     if test "x$enable_profile" = xyes; then
 509         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 510     fi
 511     if test "x$GCC" = xyes; then
 512         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 513             CFLAGS="$CFLAGS -g"
 514         fi
 515         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 516             CFLAGS="$CFLAGS -O0"
 517         fi
 518     fi
 519     if test "x$GXX" = xyes; then
 520         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 521             CXXFLAGS="$CXXFLAGS -g"
 522         fi
 523         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 524             CXXFLAGS="$CXXFLAGS -O0"
 525         fi
 526     fi
 527 else
 528    DEFINES="$DEFINES -DNDEBUG"
 529 fi
 530
 531 DEFAULT_GL_LIB_NAME=GL
 532
 533 dnl
 534 dnl Check if linker supports -Bsymbolic
 535 dnl
 536 save_LDFLAGS=$LDFLAGS
 537 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 538 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 539 AC_LINK_IFELSE(
 540     [AC_LANG_SOURCE([int main() { return 0;}])],
 541     [AC_MSG_RESULT([yes])
 542         BSYMBOLIC="-Wl,-Bsymbolic";],
 543     [AC_MSG_RESULT([no])
 544         BSYMBOLIC="";])
 545 LDFLAGS=$save_LDFLAGS
 546
 547 AC_SUBST([BSYMBOLIC])
 548
 549 dnl
 550 dnl Check if linker supports garbage collection
 551 dnl
 552 save_LDFLAGS=$LDFLAGS
 553 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 554 AC_MSG_CHECKING([whether ld supports --gc-sections])
 555 AC_LINK_IFELSE(
 556     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 557     [AC_MSG_RESULT([yes])
 558         GC_SECTIONS="-Wl,--gc-sections";],
 559     [AC_MSG_RESULT([no])
 560         GC_SECTIONS="";])
 561 LDFLAGS=$save_LDFLAGS
 562
 563 AC_SUBST([GC_SECTIONS])
 564
 565 dnl
 566 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 567 dnl so when these flags are passed to ld via libtool the checks will fail
 568 dnl
 569 case "$host_os" in
 570 openbsd* | darwin* )
 571     LD_NO_UNDEFINED="" ;;
 572 *)
 573     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 574 esac
 575
 576 AC_SUBST([LD_NO_UNDEFINED])
 577
 578 dnl
 579 dnl Check if linker supports version scripts
 580 dnl
 581 AC_MSG_CHECKING([if the linker supports version-scripts])
 582 save_LDFLAGS=$LDFLAGS
 583 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 584 cat > conftest.map <<EOF
 585 VERSION_1 {
 586      global:
 587          main;
 588
 589      local:
 590          *;
 591 };
 592 EOF
 593 AC_LINK_IFELSE(
 594     [AC_LANG_SOURCE([int main() { return 0;}])],
 595     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 596     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 597 LDFLAGS=$save_LDFLAGS
 598 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 599
 600 dnl
 601 dnl Check if linker supports dynamic list files
 602 dnl
 603 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 604 save_LDFLAGS=$LDFLAGS
 605 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 606 cat > conftest.dyn <<EOF
 607 {
 608         radeon_drm_winsys_create;
 609 };
 610 EOF
 611 AC_LINK_IFELSE(
 612     [AC_LANG_SOURCE([int main() { return 0;}])],
 613     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 614     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 615 LDFLAGS=$save_LDFLAGS
 616 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 617
 618 dnl
 619 dnl compatibility symlinks
 620 dnl
 621 case "$host_os" in
 622 linux* )
 623     HAVE_COMPAT_SYMLINKS=yes ;;
 624 * )
 625     HAVE_COMPAT_SYMLINKS=no ;;
 626 esac
 627
 628 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 629
 630 DEFAULT_GL_LIB_NAME=GL
 631
 632 dnl
 633 dnl Libglvnd configuration
 634 dnl
 635 AC_ARG_ENABLE([libglvnd],
 636     [AS_HELP_STRING([--enable-libglvnd],
 637         [Build for libglvnd @<:@default=disabled@:>@])],
 638     [enable_libglvnd="$enableval"],
 639     [enable_libglvnd=no])
 640 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 641 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 642 if test "x$enable_libglvnd" = xyes ; then
 643     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 644     DEFAULT_GL_LIB_NAME=GLX_mesa
 645 fi
 646
 647 dnl
 648 dnl library names
 649 dnl
 650 dnl Unfortunately we need to do a few things that libtool can't help us with,
 651 dnl so we need some knowledge of shared library filenames:
 652 dnl
 653 dnl LIB_EXT is the extension used when creating symlinks for alternate
 654 dnl filenames for a shared library which will be dynamically loaded
 655 dnl
 656 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 657 dnl the file for a shared library we wish to link with
 658 dnl
 659 case "$host_os" in
 660 darwin* )
 661     LIB_EXT='dylib'
 662     IMP_LIB_EXT=$LIB_EXT
 663     ;;
 664 cygwin* )
 665     LIB_EXT='dll'
 666     IMP_LIB_EXT='dll.a'
 667     ;;
 668 aix* )
 669     LIB_EXT='a'
 670     IMP_LIB_EXT=$LIB_EXT
 671     ;;
 672 * )
 673     LIB_EXT='so'
 674     IMP_LIB_EXT=$LIB_EXT
 675     ;;
 676 esac
 677
 678 AC_SUBST([LIB_EXT])
 679
 680 AC_ARG_WITH([gl-lib-name],
 681   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 682     [specify GL library name @<:@default=GL@:>@])],
 683   [GL_LIB=$withval],
 684   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 685 AC_ARG_WITH([osmesa-lib-name],
 686   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 687     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 688   [OSMESA_LIB=$withval],
 689   [OSMESA_LIB=OSMesa])
 690 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 691 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 692
 693 dnl
 694 dnl Mangled Mesa support
 695 dnl
 696 AC_ARG_ENABLE([mangling],
 697   [AS_HELP_STRING([--enable-mangling],
 698     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 699   [enable_mangling="${enableval}"],
 700   [enable_mangling=no]
 701 )
 702 if test "x${enable_mangling}" = "xyes" ; then
 703   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 704   GL_LIB="Mangled${GL_LIB}"
 705   OSMESA_LIB="Mangled${OSMESA_LIB}"
 706 fi
 707 AC_SUBST([GL_LIB])
 708 AC_SUBST([OSMESA_LIB])
 709
 710 dnl
 711 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 712 dnl
 713 AC_ARG_ENABLE([texture-float],
 714     [AS_HELP_STRING([--enable-texture-float],
 715         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 716     [enable_texture_float="$enableval"],
 717     [enable_texture_float=no]
 718 )
 719 if test "x$enable_texture_float" = xyes; then
 720     AC_MSG_WARN([Floating-point textures enabled.])
 721     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 722     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 723 fi
 724
 725 dnl
 726 dnl Arch/platform-specific settings
 727 dnl
 728 AC_ARG_ENABLE([asm],
 729     [AS_HELP_STRING([--disable-asm],
 730         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 731     [enable_asm="$enableval"],
 732     [enable_asm=yes]
 733 )
 734 asm_arch=""
 735 AC_MSG_CHECKING([whether to enable assembly])
 736 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 737 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 738 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 739     case "$host_cpu" in
 740     i?86 | x86_64 | amd64)
 741         if test "x$host_cpu" != "x$target_cpu"; then
 742             enable_asm=no
 743             AC_MSG_RESULT([no, cross compiling])
 744         fi
 745         ;;
 746     esac
 747 fi
 748 # check for supported arches
 749 if test "x$enable_asm" = xyes; then
 750     case "$host_cpu" in
 751     i?86)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 754             asm_arch=x86
 755             ;;
 756         esac
 757         ;;
 758     x86_64|amd64)
 759         case "$host_os" in
 760         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 761             asm_arch=x86_64
 762             ;;
 763         esac
 764         ;;
 765     sparc*)
 766         case "$host_os" in
 767         linux*)
 768             asm_arch=sparc
 769             ;;
 770         esac
 771         ;;
 772     esac
 773
 774     case "$asm_arch" in
 775     x86)
 776         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 777         AC_MSG_RESULT([yes, x86])
 778         ;;
 779     x86_64|amd64)
 780         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 781         AC_MSG_RESULT([yes, x86_64])
 782         ;;
 783     sparc)
 784         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 785         AC_MSG_RESULT([yes, sparc])
 786         ;;
 787     *)
 788         AC_MSG_RESULT([no, platform not supported])
 789         ;;
 790     esac
 791 fi
 792
 793 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 794 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 795 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 796 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 797
 798 dnl Check to see if dlopen is in default libraries (like Solaris, which
 799 dnl has it in libc), or if libdl is needed to get it.
 800 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 801     [AC_CHECK_LIB([dl], [dlopen],
 802        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 803 AC_SUBST([DLOPEN_LIBS])
 804
 805 dnl Check if that library also has dladdr
 806 save_LIBS="$LIBS"
 807 LIBS="$LIBS $DLOPEN_LIBS"
 808 AC_CHECK_FUNCS([dladdr])
 809 LIBS="$save_LIBS"
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for pthreads
 826 AX_PTHREAD
 827 if test "x$ax_pthread_ok" = xno; then
 828     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 829 fi
 830 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 831 dnl to -pthread, which causes problems if we need -lpthread to appear in
 832 dnl pkgconfig files.
 833 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 834
 835 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 836 AC_SUBST(PTHREADSTUBS_CFLAGS)
 837 AC_SUBST(PTHREADSTUBS_LIBS)
 838
 839 dnl SELinux awareness.
 840 AC_ARG_ENABLE([selinux],
 841     [AS_HELP_STRING([--enable-selinux],
 842         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 843     [MESA_SELINUX="$enableval"],
 844     [MESA_SELINUX=no])
 845 if test "x$enable_selinux" = "xyes"; then
 846     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 847         [AC_CHECK_HEADER([selinux/selinux.h],[],
 848                          [AC_MSG_ERROR([SELinux headers not found])])
 849          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 850                       [AC_MSG_ERROR([SELinux library not found])])
 851          SELINUX_LIBS="-lselinux"])
 852     DEFINES="$DEFINES -DMESA_SELINUX"
 853 fi
 854 AC_SUBST([SELINUX_CFLAGS])
 855 AC_SUBST([SELINUX_LIBS])
 856
 857 dnl Options for APIs
 858 AC_ARG_ENABLE([opengl],
 859     [AS_HELP_STRING([--disable-opengl],
 860         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 861     [enable_opengl="$enableval"],
 862     [enable_opengl=yes])
 863 AC_ARG_ENABLE([gles1],
 864     [AS_HELP_STRING([--disable-gles1],
 865         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 866     [enable_gles1="$enableval"],
 867     [enable_gles1=yes])
 868 AC_ARG_ENABLE([gles2],
 869     [AS_HELP_STRING([--disable-gles2],
 870         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 871     [enable_gles2="$enableval"],
 872     [enable_gles2=yes])
 873
 874 AC_ARG_ENABLE([dri],
 875     [AS_HELP_STRING([--enable-dri],
 876         [enable DRI modules @<:@default=enabled@:>@])],
 877     [enable_dri="$enableval"],
 878     [enable_dri=yes])
 879
 880 case "$host_os" in
 881 linux*)
 882     dri3_default=yes
 883     ;;
 884 *)
 885     dri3_default=no
 886     ;;
 887 esac
 888
 889 if test "x$enable_dri" = xno; then
 890     dri3_default=no
 891 fi
 892
 893 AC_ARG_ENABLE([dri3],
 894     [AS_HELP_STRING([--enable-dri3],
 895         [enable DRI3 @<:@default=auto@:>@])],
 896     [enable_dri3="$enableval"],
 897     [enable_dri3="$dri3_default"])
 898 AC_ARG_ENABLE([glx],
 899     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 900         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 901     [enable_glx="$enableval"],
 902     [enable_glx=yes])
 903 AC_ARG_ENABLE([osmesa],
 904     [AS_HELP_STRING([--enable-osmesa],
 905         [enable OSMesa library @<:@default=disabled@:>@])],
 906     [enable_osmesa="$enableval"],
 907     [enable_osmesa=no])
 908 AC_ARG_ENABLE([gallium-osmesa],
 909     [AS_HELP_STRING([--enable-gallium-osmesa],
 910         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 911     [enable_gallium_osmesa="$enableval"],
 912     [enable_gallium_osmesa=no])
 913 AC_ARG_ENABLE([egl],
 914     [AS_HELP_STRING([--disable-egl],
 915         [disable EGL library @<:@default=enabled@:>@])],
 916     [enable_egl="$enableval"],
 917     [enable_egl=yes])
 918
 919 AC_ARG_ENABLE([xa],
 920     [AS_HELP_STRING([--enable-xa],
 921         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 922     [enable_xa="$enableval"],
 923     [enable_xa=no])
 924 AC_ARG_ENABLE([gbm],
 925    [AS_HELP_STRING([--enable-gbm],
 926          [enable gbm library @<:@default=auto@:>@])],
 927    [enable_gbm="$enableval"],
 928    [enable_gbm=auto])
 929 AC_ARG_ENABLE([nine],
 930     [AS_HELP_STRING([--enable-nine],
 931         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 932     [enable_nine="$enableval"],
 933     [enable_nine=no])
 934
 935 AC_ARG_ENABLE([xvmc],
 936    [AS_HELP_STRING([--enable-xvmc],
 937          [enable xvmc library @<:@default=auto@:>@])],
 938    [enable_xvmc="$enableval"],
 939    [enable_xvmc=auto])
 940 AC_ARG_ENABLE([vdpau],
 941    [AS_HELP_STRING([--enable-vdpau],
 942          [enable vdpau library @<:@default=auto@:>@])],
 943    [enable_vdpau="$enableval"],
 944    [enable_vdpau=auto])
 945 AC_ARG_ENABLE([omx],
 946    [AS_HELP_STRING([--enable-omx],
 947          [enable OpenMAX library @<:@default=disabled@:>@])],
 948    [enable_omx="$enableval"],
 949    [enable_omx=no])
 950 AC_ARG_ENABLE([va],
 951    [AS_HELP_STRING([--enable-va],
 952          [enable va library @<:@default=auto@:>@])],
 953    [enable_va="$enableval"],
 954    [enable_va=auto])
 955 AC_ARG_ENABLE([opencl],
 956    [AS_HELP_STRING([--enable-opencl],
 957          [enable OpenCL library @<:@default=disabled@:>@])],
 958    [enable_opencl="$enableval"],
 959    [enable_opencl=no])
 960 AC_ARG_ENABLE([opencl_icd],
 961    [AS_HELP_STRING([--enable-opencl-icd],
 962           [Build an OpenCL ICD library to be loaded by an ICD implementation
 963            @<:@default=disabled@:>@])],
 964     [enable_opencl_icd="$enableval"],
 965     [enable_opencl_icd=no])
 966
 967 AC_ARG_ENABLE([gallium-tests],
 968     [AS_HELP_STRING([--enable-gallium-tests],
 969         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 970     [enable_gallium_tests="$enableval"],
 971     [enable_gallium_tests=no])
 972
 973 # Option for Gallium drivers
 974
 975 # Keep this in sync with the --with-gallium-drivers help string default value
 976 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 977
 978 AC_ARG_WITH([gallium-drivers],
 979     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 980         [comma delimited Gallium drivers list, e.g.
 981         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 982         @<:@default=r300,r600,svga,swrast@:>@])],
 983     [with_gallium_drivers="$withval"],
 984     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 985
 986 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 987 # here so that the script doesn't choke on an unknown driver name later.
 988 case "$with_gallium_drivers" in
 989     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 990     no) with_gallium_drivers='' ;;
 991 esac
 992
 993 if test "x$enable_opengl" = xno -a \
 994         "x$enable_gles1" = xno -a \
 995         "x$enable_gles2" = xno -a \
 996         "x$enable_nine" = xno -a \
 997         "x$enable_xa" = xno -a \
 998         "x$enable_xvmc" = xno -a \
 999         "x$enable_vdpau" = xno -a \
1000         "x$enable_omx" = xno -a \
1001         "x$enable_va" = xno -a \
1002         "x$enable_opencl" = xno; then
1003     AC_MSG_ERROR([at least one API should be enabled])
1004 fi
1005
1006 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1007 if test "x$enable_opengl" = xno -a \
1008         "x$enable_gles1" = xyes; then
1009     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1010 fi
1011
1012 if test "x$enable_opengl" = xno -a \
1013         "x$enable_gles2" = xyes; then
1014     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1015 fi
1016
1017 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1018 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1019 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1020 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1021                                         "x$enable_gles1" = xyes -o \
1022                                         "x$enable_gles2" = xyes)
1023
1024 # Validate GLX options
1025 if test "x$enable_glx" = xyes; then
1026     if test "x$enable_dri" = xyes; then
1027         enable_glx=dri
1028     elif test -n "$with_gallium_drivers"; then
1029         enable_glx=gallium-xlib
1030     else
1031         enable_glx=xlib
1032     fi
1033 fi
1034 case "x$enable_glx" in
1035 xdri | xxlib | xgallium-xlib)
1036     # GLX requires OpenGL
1037     if test "x$enable_opengl" = xno; then
1038         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1039     fi
1040
1041     # Check individual dependencies
1042     case "x$enable_glx" in
1043     xdri)
1044         if test "x$enable_dri" = xno; then
1045             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1046         fi
1047         ;;
1048     xxlib)
1049         if test "x$enable_dri" = xyes; then
1050             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1051         fi
1052         ;;
1053     xgallium-xlib )
1054         if test "x$enable_dri" = xyes; then
1055             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1056         fi
1057         if test -z "$with_gallium_drivers"; then
1058             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1059         fi
1060         ;;
1061     esac
1062     ;;
1063 xno)
1064     ;;
1065 *)
1066     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1067     ;;
1068 esac
1069
1070 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1071 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1072 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1073
1074 dnl
1075 dnl Libglvnd configuration
1076 dnl
1077 AC_ARG_ENABLE([libglvnd],
1078     [AS_HELP_STRING([--enable-libglvnd],
1079         [Build for libglvnd @<:@default=disabled@:>@])],
1080     [enable_libglvnd="$enableval"],
1081     [enable_libglvnd=no])
1082 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1083 if test "x$enable_libglvnd" = xyes ; then
1084     dnl XXX: update once we can handle more than libGL/glx.
1085     dnl Namely: we should error out if neither of the glvnd enabled libraries
1086     dnl are built
1087     case "x$enable_glx" in
1088     xno)
1089         AC_MSG_ERROR([cannot build libglvnd without GLX])
1090         ;;
1091     xxlib | xgallium-xlib )
1092         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1093         ;;
1094     xdri)
1095         ;;
1096     esac
1097
1098     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1099     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1100     DEFAULT_GL_LIB_NAME=GLX_mesa
1101 fi
1102
1103 # Check for libdrm
1104 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1105                   [have_libdrm=yes], [have_libdrm=no])
1106 if test "x$have_libdrm" = xyes; then
1107         DEFINES="$DEFINES -DHAVE_LIBDRM"
1108 fi
1109
1110 # Select which platform-dependent DRI code gets built
1111 case "$host_os" in
1112 darwin*)
1113     dri_platform='apple' ;;
1114 gnu*|cygwin*)
1115     dri_platform='none' ;;
1116 *)
1117     dri_platform='drm' ;;
1118 esac
1119
1120 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1121     have_drisw_kms='yes'
1122 fi
1123
1124 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1125 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1126 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1127 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1128 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1129 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1130
1131 AC_ARG_ENABLE([shared-glapi],
1132     [AS_HELP_STRING([--enable-shared-glapi],
1133         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1134     [enable_shared_glapi="$enableval"],
1135     [enable_shared_glapi=yes])
1136
1137 case "x$enable_opengl$enable_gles1$enable_gles2" in
1138 x*yes*yes*)
1139     if test "x$enable_shared_glapi" = xno; then
1140         AC_MSG_ERROR([shared GLAPI required when building two or more of
1141                       the following APIs - opengl, gles1 gles2])
1142     fi
1143     ;;
1144 esac
1145
1146 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1147
1148 # Build the pipe-drivers as separate libraries/modules.
1149 # Do not touch this unless you know what you are doing.
1150 # XXX: Expose via configure option ?
1151 enable_shared_pipe_drivers=no
1152
1153 dnl
1154 dnl Driver specific build directories
1155 dnl
1156
1157 if test "x$enable_gallium_osmesa" = xyes; then
1158     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1159         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1160     fi
1161     if test "x$enable_osmesa" = xyes; then
1162         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1163     fi
1164 fi
1165
1166 AC_SUBST([MESA_LLVM])
1167
1168 # SHA1 hashing
1169 AC_ARG_WITH([sha1],
1170         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1171         [choose SHA1 implementation])])
1172 case "x$with_sha1" in
1173 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1174   ;;
1175 *)
1176         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1177 esac
1178
1179 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1180 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1181         with_sha1=libc
1182 fi
1183 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1184         AC_MSG_ERROR([sha1 in libc requested but not found])
1185 fi
1186 if test "x$with_sha1" = xlibc; then
1187         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1188                 [Use libc SHA1 functions])
1189         SHA1_LIBS=""
1190 fi
1191 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1192 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1193         with_sha1=CommonCrypto
1194 fi
1195 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1196         AC_MSG_ERROR([CommonCrypto requested but not found])
1197 fi
1198 if test "x$with_sha1" = xCommonCrypto; then
1199         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1200                 [Use CommonCrypto SHA1 functions])
1201         SHA1_LIBS=""
1202 fi
1203 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1204 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1205 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1206         with_sha1=CryptoAPI
1207 fi
1208 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1209         AC_MSG_ERROR([CryptoAPI requested but not found])
1210 fi
1211 if test "x$with_sha1" = xCryptoAPI; then
1212         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1213                 [Use CryptoAPI SHA1 functions])
1214         SHA1_LIBS=""
1215 fi
1216 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1217 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1218         with_sha1=libmd
1219 fi
1220 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1221         AC_MSG_ERROR([libmd requested but not found])
1222 fi
1223 if test "x$with_sha1" = xlibmd; then
1224         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1225                   [Use libmd SHA1 functions])
1226         SHA1_LIBS=-lmd
1227 fi
1228 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1229 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1230    with_sha1=libsha1
1231 fi
1232 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1233         AC_MSG_ERROR([libsha1 requested but not found])
1234 fi
1235 if test "x$with_sha1" = xlibsha1; then
1236         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1237                   [Use libsha1 for SHA1])
1238         SHA1_LIBS=-lsha1
1239 fi
1240 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1241 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1242         with_sha1=libnettle
1243 fi
1244 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1245         AC_MSG_ERROR([libnettle requested but not found])
1246 fi
1247 if test "x$with_sha1" = xlibnettle; then
1248         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1249                   [Use libnettle SHA1 functions])
1250         SHA1_LIBS=-lnettle
1251 fi
1252 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1253 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1254         with_sha1=libgcrypt
1255 fi
1256 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1257         AC_MSG_ERROR([libgcrypt requested but not found])
1258 fi
1259 if test "x$with_sha1" = xlibgcrypt; then
1260         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1261                   [Use libgcrypt SHA1 functions])
1262         SHA1_LIBS=-lgcrypt
1263 fi
1264 # We don't need all of the OpenSSL libraries, just libcrypto
1265 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1266 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1267                   [HAVE_OPENSSL_PKC=no])
1268 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1269         if test "x$with_sha1" = x; then
1270                 with_sha1=libcrypto
1271         fi
1272 else
1273         if test "x$with_sha1" = xlibcrypto; then
1274                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1275         fi
1276 fi
1277 if test "x$with_sha1" = xlibcrypto; then
1278         if test "x$HAVE_LIBCRYPTO" = xyes; then
1279                 SHA1_LIBS=-lcrypto
1280         else
1281                 SHA1_LIBS="$OPENSSL_LIBS"
1282                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1283         fi
1284 fi
1285 AC_MSG_CHECKING([for SHA1 implementation])
1286 AC_MSG_RESULT([$with_sha1])
1287 AC_SUBST(SHA1_LIBS)
1288 AC_SUBST(SHA1_CFLAGS)
1289
1290 # Enable a define for SHA1
1291 if test "x$with_sha1" != "x"; then
1292         DEFINES="$DEFINES -DHAVE_SHA1"
1293 fi
1294
1295 # Allow user to configure out the shader-cache feature
1296 AC_ARG_ENABLE([shader-cache],
1297     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1298     [enable_shader_cache="$enableval"],
1299     [if test "x$with_sha1" != "x"; then
1300         enable_shader_cache=yes
1301      else
1302         enable_shader_cache=no
1303      fi])
1304 if test "x$with_sha1" = "x"; then
1305     if test "x$enable_shader_cache" = "xyes"; then
1306         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1307     fi
1308 fi
1309 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1310
1311 case "$host_os" in
1312 linux*)
1313     need_pci_id=yes ;;
1314 *)
1315     need_pci_id=no ;;
1316 esac
1317
1318 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1319                   have_libudev=yes, have_libudev=no)
1320
1321 AC_ARG_ENABLE([sysfs],
1322     [AS_HELP_STRING([--enable-sysfs],
1323         [enable /sys PCI identification @<:@default=disabled@:>@])],
1324     [have_sysfs="$enableval"],
1325     [have_sysfs=no]
1326 )
1327
1328 if test "x$enable_dri" = xyes; then
1329     if test "$enable_static" = yes; then
1330         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1331     fi
1332
1333     # not a hard requirement as swrast does not depend on it
1334     if test "x$have_libdrm" = xyes; then
1335         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1336     fi
1337 fi
1338
1339 AC_ARG_ENABLE([driglx-direct],
1340     [AS_HELP_STRING([--disable-driglx-direct],
1341         [disable direct rendering in GLX and EGL for DRI \
1342             @<:@default=auto@:>@])],
1343     [driglx_direct="$enableval"],
1344     [driglx_direct="yes"])
1345
1346 dnl
1347 dnl libGL configuration per driver
1348 dnl
1349 case "x$enable_glx" in
1350 xxlib | xgallium-xlib)
1351     # Xlib-based GLX
1352     dri_modules="x11 xext xcb"
1353     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1354     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1355     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1356     GL_LIB_DEPS="$XLIBGL_LIBS"
1357     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1358     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1359     ;;
1360 xdri)
1361     # DRI-based GLX
1362     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1363
1364     # find the DRI deps for libGL
1365     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1366
1367     if test x"$driglx_direct" = xyes; then
1368         if test x"$dri_platform" = xdrm ; then
1369             DEFINES="$DEFINES -DGLX_USE_DRM"
1370             if test "x$have_libdrm" != xyes; then
1371                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1372             fi
1373
1374             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1375             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1376             if test x"$enable_dri3" = xyes; then
1377                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1378                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1379             fi
1380
1381             if test x"$enable_dri" = xyes; then
1382                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1383             fi
1384
1385             if test x"$enable_dri3" = xyes; then
1386                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1387                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1388                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1389             fi
1390         fi
1391         if test x"$dri_platform" = xapple ; then
1392             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1393         fi
1394     fi
1395
1396     # add xf86vidmode if available
1397     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1398     if test "$HAVE_XF86VIDMODE" = yes ; then
1399         dri_modules="$dri_modules xxf86vm"
1400     fi
1401
1402     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1403     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1404     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1405     GL_LIB_DEPS="$DRIGL_LIBS"
1406
1407     # need DRM libs, $PTHREAD_LIBS, etc.
1408     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1409     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1410     ;;
1411 esac
1412
1413 have_pci_id=no
1414 if test "$have_libudev" = yes; then
1415     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1416     have_pci_id=yes
1417 fi
1418
1419 if test "$have_sysfs" = yes; then
1420     DEFINES="$DEFINES -DHAVE_SYSFS"
1421     have_pci_id=yes
1422 fi
1423
1424 # This is outside the case (above) so that it is invoked even for non-GLX
1425 # builds.
1426 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1427
1428 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1429 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1430 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1431 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1432
1433 AC_SUBST([X11_INCLUDES])
1434 AC_SUBST([GL_LIB_DEPS])
1435 AC_SUBST([GL_PC_REQ_PRIV])
1436 AC_SUBST([GL_PC_LIB_PRIV])
1437 AC_SUBST([GL_PC_CFLAGS])
1438 AC_SUBST([DRI_PC_REQ_PRIV])
1439 AC_SUBST([GLESv1_CM_LIB_DEPS])
1440 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1441 AC_SUBST([GLESv2_LIB_DEPS])
1442 AC_SUBST([GLESv2_PC_LIB_PRIV])
1443
1444 AC_SUBST([HAVE_XF86VIDMODE])
1445
1446 dnl
1447 dnl More GLX setup
1448 dnl
1449 case "x$enable_glx" in
1450 xxlib | xgallium-xlib)
1451     DEFINES="$DEFINES -DUSE_XSHM"
1452     ;;
1453 xdri)
1454     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1455     if test "x$driglx_direct" = xyes; then
1456         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1457     fi
1458     ;;
1459 esac
1460
1461 dnl
1462 dnl TLS detection
1463 dnl
1464
1465 AC_ARG_ENABLE([glx-tls],
1466     [AS_HELP_STRING([--enable-glx-tls],
1467         [enable TLS support in GLX @<:@default=disabled@:>@])],
1468     [GLX_USE_TLS="$enableval"],
1469     [GLX_USE_TLS=no])
1470 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1471
1472 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1473       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1474
1475 dnl Read-only text section on x86 hardened platforms
1476 AC_ARG_ENABLE([glx-read-only-text],
1477     [AS_HELP_STRING([--enable-glx-read-only-text],
1478         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1479     [enable_glx_read_only_text="$enableval"],
1480     [enable_glx_read_only_text=no])
1481 if test "x$enable_glx_read_only_text" = xyes; then
1482     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1483 fi
1484
1485 dnl
1486 dnl More DRI setup
1487 dnl
1488 dnl Directory for DRI drivers
1489 AC_ARG_WITH([dri-driverdir],
1490     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1491         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1492     [DRI_DRIVER_INSTALL_DIR="$withval"],
1493     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1494 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1495 dnl Extra search path for DRI drivers
1496 AC_ARG_WITH([dri-searchpath],
1497     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1498         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1499     [DRI_DRIVER_SEARCH_DIR="$withval"],
1500     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1501 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1502 dnl Which drivers to build - default is chosen by platform
1503 AC_ARG_WITH([dri-drivers],
1504     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1505         [comma delimited classic DRI drivers list, e.g.
1506         "swrast,i965,radeon" @<:@default=auto@:>@])],
1507     [with_dri_drivers="$withval"],
1508     [with_dri_drivers=auto])
1509
1510 if test "x$with_dri_drivers" = xauto; then
1511     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1512         with_dri_drivers="yes"
1513     else
1514         with_dri_drivers="no"
1515     fi
1516 fi
1517 if test "x$with_dri_drivers" = xno; then
1518     with_dri_drivers=''
1519 fi
1520
1521 dnl If $with_dri_drivers is yes, drivers will be added through
1522 dnl platform checks. Set DEFINES and LIB_DEPS
1523 if test "x$enable_dri" = xyes; then
1524     # Platform specific settings and drivers to build
1525     case "$host_os" in
1526     linux*)
1527         DEFINES="$DEFINES -DHAVE_ALIAS"
1528         if test "x$enable_dri3" = xyes; then
1529             DEFINES="$DEFINES -DHAVE_DRI3"
1530         fi
1531
1532         if test "x$have_pci_id" != xyes; then
1533             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1534         fi
1535
1536         case "$host_cpu" in
1537         powerpc* | sparc*)
1538             # Build only the drivers for cards that exist on PowerPC/sparc
1539             if test "x$with_dri_drivers" = "xyes"; then
1540                 with_dri_drivers="r200 radeon swrast"
1541             fi
1542             ;;
1543         esac
1544         ;;
1545     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1546         DEFINES="$DEFINES -DHAVE_ALIAS"
1547         ;;
1548     gnu*)
1549         DEFINES="$DEFINES -DHAVE_ALIAS"
1550         ;;
1551     cygwin*)
1552         if test "x$with_dri_drivers" = "xyes"; then
1553             with_dri_drivers="swrast"
1554         fi
1555         ;;
1556     darwin*)
1557         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1558         if test "x$with_dri_drivers" = "xyes"; then
1559             with_dri_drivers="swrast"
1560         fi
1561         ;;
1562     esac
1563
1564     # default drivers
1565     if test "x$with_dri_drivers" = "xyes"; then
1566         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1567     fi
1568
1569     # Check for expat
1570     PKG_CHECK_MODULES([EXPAT], [expat], [],
1571         # expat version 2.0 and earlier do not provide expat.pc
1572         [AC_CHECK_HEADER([expat.h],[],
1573                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1574          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1575                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1576          EXPAT_LIBS="-lexpat"])
1577
1578     # put all the necessary libs together
1579     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1580 fi
1581
1582 AC_SUBST([DRI_LIB_DEPS])
1583
1584 DRI_DIRS=''
1585 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1586 if test -n "$with_dri_drivers"; then
1587     if test "x$enable_opengl" != xyes; then
1588         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1589     fi
1590
1591     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1592     for driver in $dri_drivers; do
1593         DRI_DIRS="$DRI_DIRS $driver"
1594         case "x$driver" in
1595         xi915)
1596             HAVE_I915_DRI=yes;
1597             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1598             ;;
1599         xi965)
1600             HAVE_I965_DRI=yes;
1601             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1602             ;;
1603         xnouveau)
1604             HAVE_NOUVEAU_DRI=yes;
1605             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1606             ;;
1607         xradeon)
1608             HAVE_RADEON_DRI=yes;
1609             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1610             ;;
1611         xr200)
1612             HAVE_R200_DRI=yes;
1613             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1614             ;;
1615         xswrast)
1616             HAVE_SWRAST_DRI=yes;
1617             ;;
1618         *)
1619             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1620             ;;
1621         esac
1622     done
1623     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1624 fi
1625
1626
1627 #
1628 # Vulkan driver configuration
1629 #
1630
1631 AC_ARG_WITH([vulkan-drivers],
1632     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1633         [comma delimited Vulkan drivers list, e.g.
1634         "intel"
1635         @<:@default=no@:>@])],
1636     [with_vulkan_drivers="$withval"],
1637     [with_vulkan_drivers="no"])
1638
1639 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1640 # here so that the script doesn't choke on an unknown driver name later.
1641 case "x$with_vulkan_drivers" in
1642     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1643     xno) with_vulkan_drivers='' ;;
1644 esac
1645
1646 AC_ARG_WITH([vulkan-icddir],
1647     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1648         [directory for the Vulkan driver icd files @<:@${sysconfdir}/vulkan/icd.d@:>@])],
1649     [VULKAN_ICD_INSTALL_DIR="$withval"],
1650     [VULKAN_ICD_INSTALL_DIR='${sysconfdir}/vulkan/icd.d'])
1651 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1652
1653 if test -n "$with_vulkan_drivers"; then
1654     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1655     for driver in $VULKAN_DRIVERS; do
1656         case "x$driver" in
1657         xintel)
1658             if test "x$HAVE_I965_DRI" != xyes; then
1659                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1660             fi
1661             if test "x$with_sha1" == "x"; then
1662                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1663             fi
1664             HAVE_INTEL_VULKAN=yes;
1665
1666             ;;
1667         *)
1668             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1669             ;;
1670         esac
1671     done
1672     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1673 fi
1674
1675
1676 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1677 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1678                                   "x$enable_osmesa" = xyes -o \
1679                                   -n "$DRI_DIRS")
1680
1681 dnl
1682 dnl OSMesa configuration
1683 dnl
1684
1685 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1686 AC_ARG_WITH([osmesa-bits],
1687     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1688         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1689     [osmesa_bits="$withval"],
1690     [osmesa_bits=8])
1691 if test "x$osmesa_bits" != x8; then
1692     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1693         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1694         osmesa_bits=8
1695     fi
1696 fi
1697 case "x$osmesa_bits" in
1698 x8)
1699     OSMESA_LIB="${OSMESA_LIB}"
1700     ;;
1701 x16|x32)
1702     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1703     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1704     ;;
1705 *)
1706     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1707     ;;
1708 esac
1709
1710 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1711     # only link libraries with osmesa if shared
1712     if test "$enable_static" = no; then
1713         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1714     else
1715         OSMESA_LIB_DEPS=""
1716     fi
1717     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1718 fi
1719
1720 AC_SUBST([OSMESA_LIB_DEPS])
1721 AC_SUBST([OSMESA_PC_REQ])
1722 AC_SUBST([OSMESA_PC_LIB_PRIV])
1723
1724 dnl
1725 dnl gbm configuration
1726 dnl
1727 if test "x$enable_gbm" = xauto; then
1728     case "$with_egl_platforms" in
1729         *drm*)
1730             enable_gbm=yes ;;
1731          *)
1732             enable_gbm=no ;;
1733     esac
1734 fi
1735 if test "x$enable_gbm" = xyes; then
1736     if test "x$need_pci_id$have_pci_id" = xyesno; then
1737         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1738     fi
1739
1740     if test "x$enable_dri" = xyes; then
1741         if test "x$enable_shared_glapi" = xno; then
1742             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1743         fi
1744     else
1745         # Strictly speaking libgbm does not require --enable-dri, although
1746         # both of its backends do. Thus one can build libgbm without any
1747         # backends if --disable-dri is set.
1748         # To avoid unnecessary complexity of checking if at least one backend
1749         # is available when building, just mandate --enable-dri.
1750         AC_MSG_ERROR([gbm requires --enable-dri])
1751     fi
1752 fi
1753 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1754 if test "x$need_pci_id$have_libudev" = xyesyes; then
1755     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1756 else
1757     GBM_PC_REQ_PRIV=""
1758 fi
1759 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1760 AC_SUBST([GBM_PC_REQ_PRIV])
1761 AC_SUBST([GBM_PC_LIB_PRIV])
1762
1763 dnl
1764 dnl EGL configuration
1765 dnl
1766 EGL_CLIENT_APIS=""
1767
1768 if test "x$enable_egl" = xyes; then
1769     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1770
1771     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1772
1773     if test "$enable_static" != yes; then
1774         if test "x$enable_dri" = xyes; then
1775             HAVE_EGL_DRIVER_DRI2=1
1776             if test "x$enable_shared_glapi" = xno; then
1777                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1778             fi
1779             if test "x$enable_dri3" = xyes; then
1780                 HAVE_EGL_DRIVER_DRI3=1
1781                 if test "x$enable_shared_glapi" = xno; then
1782                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1783                 fi
1784             fi
1785         else
1786             # Avoid building an "empty" libEGL. Drop/update this
1787             # when other backends (haiku?) come along.
1788             AC_MSG_ERROR([egl requires --enable-dri])
1789         fi
1790
1791     fi
1792 fi
1793 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1794 AC_SUBST([EGL_LIB_DEPS])
1795
1796 gallium_st="mesa"
1797
1798 dnl
1799 dnl XA configuration
1800 dnl
1801 if test "x$enable_xa" = xyes; then
1802     if test "x$with_gallium_drivers" = xswrast; then
1803        AC_MSG_ERROR([
1804           Building xa requires at least one non swrast gallium driver.
1805           If you are looking to use libxatracker.so with the VMware driver,
1806           make sure to include svga in the gallium drivers list, apart from
1807           enabling XA.
1808           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1809     fi
1810     gallium_st="$gallium_st xa"
1811 fi
1812 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1813
1814 dnl
1815 dnl Gallium G3DVL configuration
1816 dnl
1817 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1818     if test "x$enable_xvmc" = xauto; then
1819         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1820     fi
1821
1822     if test "x$enable_vdpau" = xauto; then
1823         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1824     fi
1825
1826     if test "x$enable_omx" = xauto; then
1827         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1828     fi
1829
1830     if test "x$enable_va" = xauto; then
1831         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1832     fi
1833 fi
1834
1835 if test "x$enable_dri" = xyes -o \
1836         "x$enable_xvmc" = xyes -o \
1837         "x$enable_vdpau" = xyes -o \
1838         "x$enable_omx" = xyes -o \
1839         "x$enable_va" = xyes; then
1840     need_gallium_vl=yes
1841 fi
1842 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1843
1844 if test "x$enable_xvmc" = xyes -o \
1845         "x$enable_vdpau" = xyes -o \
1846         "x$enable_omx" = xyes -o \
1847         "x$enable_va" = xyes; then
1848     if test x"$enable_dri3" = xyes; then
1849         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1850                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1851     else
1852         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1853     fi
1854     need_gallium_vl_winsys=yes
1855 fi
1856 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1857
1858 if test "x$enable_xvmc" = xyes; then
1859     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1860     gallium_st="$gallium_st xvmc"
1861 fi
1862 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1863
1864 if test "x$enable_vdpau" = xyes; then
1865     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1866     gallium_st="$gallium_st vdpau"
1867     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1868 fi
1869 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1870
1871 if test "x$enable_omx" = xyes; then
1872     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1873     gallium_st="$gallium_st omx"
1874 fi
1875 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1876
1877 if test "x$enable_va" = xyes; then
1878     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1879     gallium_st="$gallium_st va"
1880 fi
1881 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1882
1883 dnl
1884 dnl Nine Direct3D9 configuration
1885 dnl
1886 if test "x$enable_nine" = xyes; then
1887     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1888         AC_MSG_ERROR([nine requires the gallium swrast driver])
1889     fi
1890     if test "x$with_gallium_drivers" = xswrast; then
1891         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1892     fi
1893     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1894         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1895     fi
1896
1897     if test "x$enable_dri3" = xno; then
1898         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1899     fi
1900
1901     gallium_st="$gallium_st nine"
1902 fi
1903 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1904
1905 dnl
1906 dnl OpenCL configuration
1907 dnl
1908
1909 AC_ARG_WITH([clang-libdir],
1910    [AS_HELP_STRING([--with-clang-libdir],
1911          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1912    [CLANG_LIBDIR="$withval"],
1913    [CLANG_LIBDIR=''])
1914
1915 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1916 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1917
1918 if test "x$have_libelf" = xno; then
1919    LIBELF_LIBS=''
1920    LIBELF_CFLAGS=''
1921    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1922    AC_SUBST([LIBELF_LIBS])
1923    AC_SUBST([LIBELF_CFLAGS])
1924 fi
1925
1926 if test "x$enable_opencl" = xyes; then
1927     if test -z "$with_gallium_drivers"; then
1928         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1929     fi
1930
1931     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1932         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1933     fi
1934
1935     if test "x$have_libclc" = xno; then
1936         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1937                     Make sure the directory containing libclc.pc is specified in your
1938                     PKG_CONFIG_PATH environment variable.
1939                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1940     else
1941         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1942         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1943         AC_SUBST([LIBCLC_INCLUDEDIR])
1944         AC_SUBST([LIBCLC_LIBEXECDIR])
1945     fi
1946
1947     gallium_st="$gallium_st clover"
1948
1949     if test "x$enable_opencl_icd" = xyes; then
1950         OPENCL_LIBNAME="MesaOpenCL"
1951     else
1952         OPENCL_LIBNAME="OpenCL"
1953     fi
1954
1955     if test "x$have_libelf" != xyes; then
1956        AC_MSG_ERROR([Clover requires libelf])
1957     fi
1958 fi
1959 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1960 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1961 AC_SUBST([OPENCL_LIBNAME])
1962
1963 dnl
1964 dnl Gallium configuration
1965 dnl
1966 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1967
1968 AC_SUBST([LLVM_BINDIR])
1969 AC_SUBST([LLVM_CFLAGS])
1970 AC_SUBST([LLVM_CPPFLAGS])
1971 AC_SUBST([LLVM_CXXFLAGS])
1972 AC_SUBST([LLVM_LIBDIR])
1973 AC_SUBST([LLVM_LIBS])
1974 AC_SUBST([LLVM_LDFLAGS])
1975 AC_SUBST([LLVM_INCLUDEDIR])
1976 AC_SUBST([LLVM_VERSION])
1977 AC_SUBST([CLANG_RESOURCE_DIR])
1978
1979 case "x$enable_opengl$enable_gles1$enable_gles2" in
1980 x*yes*)
1981     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1982     ;;
1983 esac
1984
1985 AC_SUBST([VG_LIB_DEPS])
1986 AC_SUBST([EGL_CLIENT_APIS])
1987
1988 dnl
1989 dnl EGL Platforms configuration
1990 dnl
1991 AC_ARG_WITH([egl-platforms],
1992     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1993         [comma delimited native platforms libEGL supports, e.g.
1994         "x11,drm" @<:@default=auto@:>@])],
1995     [with_egl_platforms="$withval"],
1996     [if test "x$enable_egl" = xyes; then
1997         with_egl_platforms="x11"
1998     else
1999         with_egl_platforms=""
2000     fi])
2001
2002 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2003     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2004 fi
2005
2006 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
2007         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
2008         WAYLAND_SCANNER='')
2009 if test "x$WAYLAND_SCANNER" = x; then
2010     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2011 fi
2012
2013 # Do per-EGL platform setups and checks
2014 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2015 for plat in $egl_platforms; do
2016         case "$plat" in
2017         wayland)
2018                 test "x$have_libdrm" != xyes &&
2019                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
2020
2021                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2022
2023                 if test "x$WAYLAND_SCANNER" = x; then
2024                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2025                 fi
2026                 ;;
2027
2028         x11)
2029                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2030                 ;;
2031
2032         drm)
2033                 test "x$enable_gbm" = "xno" &&
2034                         AC_MSG_ERROR([EGL platform drm needs gbm])
2035                 test "x$have_libdrm" != xyes &&
2036                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
2037                 ;;
2038
2039         surfaceless)
2040                 test "x$have_libdrm" != xyes &&
2041                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
2042                 ;;
2043
2044         android)
2045                 ;;
2046
2047         *)
2048                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2049                 ;;
2050         esac
2051
2052         case "$plat$need_pci_id$have_pci_id" in
2053                 waylandyesno|drmyesno)
2054                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
2055         esac
2056 done
2057
2058 # libEGL wants to default to the first platform specified in
2059 # ./configure.  parse that here.
2060 if test "x$egl_platforms" != "x"; then
2061     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2062     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2063 else
2064     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2065 fi
2066
2067 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2068 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2069 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2070 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2071 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2072
2073 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2074
2075 AC_SUBST([EGL_NATIVE_PLATFORM])
2076 AC_SUBST([EGL_CFLAGS])
2077
2078 # If we don't have the X11 platform, set this define so we don't try to include
2079 # the X11 headers.
2080 if ! echo "$egl_platforms" | grep -q 'x11'; then
2081     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2082     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2083 fi
2084
2085 dnl
2086 dnl Gallium LLVM
2087 dnl
2088 AC_ARG_ENABLE([gallium-llvm],
2089     [AS_HELP_STRING([--enable-gallium-llvm],
2090         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2091     [enable_gallium_llvm="$enableval"],
2092     [enable_gallium_llvm=auto])
2093
2094 AC_ARG_ENABLE([llvm-shared-libs],
2095     [AS_HELP_STRING([--enable-llvm-shared-libs],
2096         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2097     [enable_llvm_shared_libs="$enableval"],
2098     [enable_llvm_shared_libs=yes])
2099
2100 AC_ARG_WITH([llvm-prefix],
2101     [AS_HELP_STRING([--with-llvm-prefix],
2102         [Prefix for LLVM installations in non-standard locations])],
2103     [llvm_prefix="$withval"],
2104     [llvm_prefix=''])
2105
2106
2107 # Call this inside ` ` to get the return value.
2108 # $1 is the llvm-config command with arguments.
2109 strip_unwanted_llvm_flags() {
2110     # Use \> (marks the end of the word)
2111     echo `$1` | sed \
2112         -e 's/-DNDEBUG\>//g' \
2113         -e 's/-D_GNU_SOURCE\>//g' \
2114         -e 's/-pedantic\>//g' \
2115         -e 's/-Wcovered-switch-default\>//g' \
2116         -e 's/-O.\>//g' \
2117         -e 's/-g\>//g' \
2118         -e 's/-Wall\>//g' \
2119         -e 's/-Wcast-qual\>//g' \
2120         -e 's/-Woverloaded-virtual\>//g' \
2121         -e 's/-fcolor-diagnostics\>//g' \
2122         -e 's/-fdata-sections\>//g' \
2123         -e 's/-ffunction-sections\>//g' \
2124         -e 's/-fno-exceptions\>//g' \
2125         -e 's/-fomit-frame-pointer\>//g' \
2126         -e 's/-fvisibility-inlines-hidden\>//g' \
2127         -e 's/-fPIC\>//g' \
2128         -e 's/-fstack-protector-strong\>//g'
2129 }
2130
2131 llvm_check_version_for() {
2132     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2133         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2134     fi
2135 }
2136
2137
2138
2139 if test -z "$with_gallium_drivers"; then
2140     enable_gallium_llvm=no
2141 fi
2142 if test "x$enable_gallium_llvm" = xauto; then
2143     case "$host_cpu" in
2144     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2145     esac
2146 fi
2147 if test "x$enable_gallium_llvm" = xyes; then
2148     if test -n "$llvm_prefix"; then
2149         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2150     else
2151         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2152     fi
2153
2154     if test "x$LLVM_CONFIG" != xno; then
2155         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2156         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2157         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2158         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2159         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2160         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2161         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2162         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2163
2164         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2165             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2166         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2167             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2168
2169         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2170         if test -z "$LLVM_VERSION_PATCH"; then
2171             LLVM_VERSION_PATCH=0
2172         fi
2173
2174         if test -n "${LLVM_VERSION_MAJOR}"; then
2175             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2176         else
2177             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2178         fi
2179
2180         LLVM_REQUIRED_VERSION_MAJOR="3"
2181         LLVM_REQUIRED_VERSION_MINOR="3"
2182         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2183             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2184         fi
2185
2186         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2187
2188         if test "x$enable_opencl" = xyes; then
2189             llvm_check_version_for "3" "5" "0" "opencl"
2190
2191             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2192             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2193         fi
2194         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2195         MESA_LLVM=1
2196
2197         dnl Check for Clang internal headers
2198         if test "x$enable_opencl" = xyes; then
2199             if test -z "$CLANG_LIBDIR"; then
2200                 CLANG_LIBDIR=${LLVM_LIBDIR}
2201             fi
2202             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2203             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2204                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2205         fi
2206     else
2207         MESA_LLVM=0
2208         LLVM_VERSION_INT=0
2209     fi
2210 else
2211     MESA_LLVM=0
2212     LLVM_VERSION_INT=0
2213
2214     if test "x$enable_opencl" = xyes; then
2215         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2216     fi
2217 fi
2218
2219 dnl Directory for XVMC libs
2220 AC_ARG_WITH([xvmc-libdir],
2221     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2222         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2223     [XVMC_LIB_INSTALL_DIR="$withval"],
2224     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2225 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2226
2227 dnl
2228 dnl Gallium Tests
2229 dnl
2230 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2231
2232 dnl Directory for VDPAU libs
2233 AC_ARG_WITH([vdpau-libdir],
2234     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2235         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2236     [VDPAU_LIB_INSTALL_DIR="$withval"],
2237     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2238 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2239
2240 dnl Directory for OMX libs
2241
2242 AC_ARG_WITH([omx-libdir],
2243     [AS_HELP_STRING([--with-omx-libdir=DIR],
2244         [directory for the OMX libraries])],
2245     [OMX_LIB_INSTALL_DIR="$withval"],
2246     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2247 AC_SUBST([OMX_LIB_INSTALL_DIR])
2248
2249 dnl Directory for VA libs
2250
2251 AC_ARG_WITH([va-libdir],
2252     [AS_HELP_STRING([--with-va-libdir=DIR],
2253         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2254     [VA_LIB_INSTALL_DIR="$withval"],
2255     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2256 AC_SUBST([VA_LIB_INSTALL_DIR])
2257
2258 AC_ARG_WITH([d3d-libdir],
2259     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2260         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2261     [D3D_DRIVER_INSTALL_DIR="$withval"],
2262     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2263 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2264
2265 dnl
2266 dnl Gallium helper functions
2267 dnl
2268 gallium_require_drm() {
2269     if test "x$have_libdrm" != xyes; then
2270        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2271     fi
2272 }
2273
2274 gallium_require_llvm() {
2275     if test "x$MESA_LLVM" = x0; then
2276         case "$host" in *gnux32) return;; esac
2277         case "$host_cpu" in
2278         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2279         esac
2280     fi
2281 }
2282
2283 gallium_require_drm_loader() {
2284     if test "x$need_pci_id$have_pci_id" = xyesno; then
2285         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2286     fi
2287 }
2288
2289 dnl This is for Glamor. Skip this if OpenGL is disabled.
2290 require_egl_drm() {
2291     if test "x$enable_opengl" = xno; then
2292         return 0
2293     fi
2294
2295     case "$with_egl_platforms" in
2296         *drm*)
2297             ;;
2298          *)
2299             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2300             ;;
2301     esac
2302     if test "x$enable_gbm" != xyes; then
2303             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2304     fi
2305 }
2306
2307 radeon_llvm_check() {
2308     if test ${LLVM_VERSION_INT} -lt 307; then
2309         amdgpu_llvm_target_name='r600'
2310     else
2311         amdgpu_llvm_target_name='amdgpu'
2312     fi
2313     if test "x$enable_gallium_llvm" != "xyes"; then
2314         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2315     fi
2316     llvm_check_version_for "3" "6" "0" $1
2317     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2318         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2319     fi
2320     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2321     NEED_RADEON_LLVM=yes
2322     if test "x$have_libelf" != xyes; then
2323        AC_MSG_ERROR([$1 requires libelf when using llvm])
2324     fi
2325 }
2326
2327 swr_llvm_check() {
2328     gallium_require_llvm $1
2329     if test ${LLVM_VERSION_INT} -lt 306; then
2330         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2331     fi
2332     if test "x$enable_gallium_llvm" != "xyes"; then
2333         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2334     fi
2335 }
2336
2337 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2338 if test -n "$with_gallium_drivers"; then
2339     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2340     for driver in $gallium_drivers; do
2341         case "x$driver" in
2342         xsvga)
2343             HAVE_GALLIUM_SVGA=yes
2344             gallium_require_drm "svga"
2345             gallium_require_drm_loader
2346             ;;
2347         xi915)
2348             HAVE_GALLIUM_I915=yes
2349             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2350             gallium_require_drm "Gallium i915"
2351             gallium_require_drm_loader
2352             ;;
2353         xilo)
2354             HAVE_GALLIUM_ILO=yes
2355             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2356             gallium_require_drm "Gallium i965/ilo"
2357             gallium_require_drm_loader
2358             ;;
2359         xr300)
2360             HAVE_GALLIUM_R300=yes
2361             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2362             gallium_require_drm "Gallium R300"
2363             gallium_require_drm_loader
2364             gallium_require_llvm "Gallium R300"
2365             ;;
2366         xr600)
2367             HAVE_GALLIUM_R600=yes
2368             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2369             gallium_require_drm "Gallium R600"
2370             gallium_require_drm_loader
2371             if test "x$enable_opencl" = xyes; then
2372                 radeon_llvm_check "r600g"
2373                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2374             fi
2375             ;;
2376         xradeonsi)
2377             HAVE_GALLIUM_RADEONSI=yes
2378             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2379             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2380             gallium_require_drm "radeonsi"
2381             gallium_require_drm_loader
2382             radeon_llvm_check "radeonsi"
2383             require_egl_drm "radeonsi"
2384             ;;
2385         xnouveau)
2386             HAVE_GALLIUM_NOUVEAU=yes
2387             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2388             gallium_require_drm "nouveau"
2389             gallium_require_drm_loader
2390             ;;
2391         xfreedreno)
2392             HAVE_GALLIUM_FREEDRENO=yes
2393             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2394             gallium_require_drm "freedreno"
2395             gallium_require_drm_loader
2396             ;;
2397         xswrast)
2398             HAVE_GALLIUM_SOFTPIPE=yes
2399             if test "x$MESA_LLVM" = x1; then
2400                 HAVE_GALLIUM_LLVMPIPE=yes
2401             fi
2402             ;;
2403         xswr)
2404             swr_llvm_check "swr"
2405
2406             AC_MSG_CHECKING([whether $CXX supports c++11/AVX/AVX2])
2407             AVX_CXXFLAGS="-march=core-avx-i"
2408             AVX2_CXXFLAGS="-march=core-avx2"
2409
2410             AC_LANG_PUSH([C++])
2411             save_CXXFLAGS="$CXXFLAGS"
2412             CXXFLAGS="-std=c++11 $CXXFLAGS"
2413             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2414                               [AC_MSG_ERROR([c++11 compiler support not detected])])
2415             CXXFLAGS="$save_CXXFLAGS"
2416
2417             save_CXXFLAGS="$CXXFLAGS"
2418             CXXFLAGS="$AVX_CXXFLAGS $CXXFLAGS"
2419             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2420                               [AC_MSG_ERROR([AVX compiler support not detected])])
2421             CXXFLAGS="$save_CXXFLAGS"
2422
2423             save_CFLAGS="$CXXFLAGS"
2424             CXXFLAGS="$AVX2_CXXFLAGS $CXXFLAGS"
2425             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2426                               [AC_MSG_ERROR([AVX2 compiler support not detected])])
2427             CXXFLAGS="$save_CXXFLAGS"
2428             AC_LANG_POP([C++])
2429
2430             HAVE_GALLIUM_SWR=yes
2431             ;;
2432         xvc4)
2433             HAVE_GALLIUM_VC4=yes
2434             gallium_require_drm "vc4"
2435             gallium_require_drm_loader
2436
2437             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2438                               [USE_VC4_SIMULATOR=yes;
2439                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2440                               [USE_VC4_SIMULATOR=no])
2441             ;;
2442         xvirgl)
2443             HAVE_GALLIUM_VIRGL=yes
2444             gallium_require_drm "virgl"
2445             gallium_require_drm_loader
2446             require_egl_drm "virgl"
2447             ;;
2448         *)
2449             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2450             ;;
2451         esac
2452     done
2453 fi
2454
2455 dnl Set LLVM_LIBS - This is done after the driver configuration so
2456 dnl that drivers can add additional components to LLVM_COMPONENTS.
2457 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2458 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2459 dnl this was causing the same libraries to be appear multiple times
2460 dnl in LLVM_LIBS.
2461
2462 if test "x$MESA_LLVM" != x0; then
2463
2464     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2465        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2466     fi
2467     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2468
2469     dnl llvm-config may not give the right answer when llvm is a built as a
2470     dnl single shared library, so we must work the library name out for
2471     dnl ourselves.
2472     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2473     if test "x$enable_llvm_shared_libs" = xyes; then
2474         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2475         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2476         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2477
2478         if test "x$llvm_have_one_so" = xyes; then
2479             dnl LLVM was built using auto*, so there is only one shared object.
2480             LLVM_LIBS="-l$LLVM_SO_NAME"
2481         else
2482             dnl If LLVM was built with CMake, there will be one shared object per
2483             dnl component.
2484             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2485                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2486         Please make sure you have built llvm with the --enable-shared option
2487         and that your llvm libraries are installed in $LLVM_LIBDIR
2488         If you have installed your llvm libraries to a different directory you
2489         can use the --with-llvm-prefix= configure flag to specify this directory.
2490         NOTE: Mesa is attempting to use llvm shared libraries by default.
2491         If you do not want to build with llvm shared libraries and instead want to
2492         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2493         invocation and rebuild.])])
2494
2495            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2496            dnl install uses a shared object for each component and we have
2497            dnl already added all of these objects to LLVM_LIBS.
2498         fi
2499     else
2500         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2501         dnl We need to link to llvm system libs when using static libs
2502         dnl However, only llvm 3.5+ provides --system-libs
2503         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2504             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2505         fi
2506     fi
2507 fi
2508
2509 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2510 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2511 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2512 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2513 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2514 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2515 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2516                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2517 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2518 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2519 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2520 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2521 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2522 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2523                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2524                                          "x$HAVE_GALLIUM_SWR" = xyes)
2525 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2526 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2527
2528 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2529
2530 if test "x$enable_dri" = xyes; then
2531     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2532 fi
2533
2534 if test "x$have_drisw_kms" = xyes; then
2535     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2536 fi
2537 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2538
2539 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2540 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2541 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2542 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2543 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2544 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2545
2546 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2547
2548 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2549                                         "x$HAVE_I965_DRI" = xyes)
2550
2551 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2552                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2553                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2554 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2555 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2557 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2558 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2559 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2560     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2561 fi
2562
2563 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2564 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2565 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2566
2567 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2568 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2569 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2570
2571 AC_SUBST([NINE_MAJOR], 1)
2572 AC_SUBST([NINE_MINOR], 0)
2573 AC_SUBST([NINE_TINY], 0)
2574 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2575
2576 AC_SUBST([VDPAU_MAJOR], 1)
2577 AC_SUBST([VDPAU_MINOR], 0)
2578
2579 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2580 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2581 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2582 AC_SUBST([VA_MINOR], $VA_MINOR)
2583
2584 AC_SUBST([XVMC_MAJOR], 1)
2585 AC_SUBST([XVMC_MINOR], 0)
2586
2587 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2588 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2589 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2590 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2591
2592 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2593 AC_SUBST([XA_MINOR], $XA_MINOR)
2594 AC_SUBST([XA_TINY], $XA_TINY)
2595 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2596
2597 AC_ARG_ENABLE(valgrind,
2598               [AS_HELP_STRING([--enable-valgrind],
2599                              [Build mesa with valgrind support (default: auto)])],
2600                              [VALGRIND=$enableval], [VALGRIND=auto])
2601 if test "x$VALGRIND" != xno; then
2602         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2603 fi
2604 AC_MSG_CHECKING([whether to enable Valgrind support])
2605 if test "x$VALGRIND" = xauto; then
2606         VALGRIND="$have_valgrind"
2607 fi
2608
2609 if test "x$VALGRIND" = "xyes"; then
2610         if ! test "x$have_valgrind" = xyes; then
2611                 AC_MSG_ERROR([Valgrind support required but not present])
2612         fi
2613         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2614 fi
2615
2616 AC_MSG_RESULT([$VALGRIND])
2617
2618 dnl Restore LDFLAGS and CPPFLAGS
2619 LDFLAGS="$_SAVE_LDFLAGS"
2620 CPPFLAGS="$_SAVE_CPPFLAGS"
2621
2622 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2623 if test "x$acv_mesa_CLANG" = xyes; then
2624     CFLAGS="$CFLAGS -Qunused-arguments"
2625     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2626 fi
2627
2628 dnl Add user CFLAGS and CXXFLAGS
2629 CFLAGS="$CFLAGS $USER_CFLAGS"
2630 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2631
2632 dnl Substitute the config
2633 AC_CONFIG_FILES([Makefile
2634                 src/Makefile
2635                 src/compiler/Makefile
2636                 src/egl/Makefile
2637                 src/egl/main/egl.pc
2638                 src/egl/wayland/wayland-drm/Makefile
2639                 src/egl/wayland/wayland-egl/Makefile
2640                 src/egl/wayland/wayland-egl/wayland-egl.pc
2641                 src/gallium/Makefile
2642                 src/gallium/auxiliary/Makefile
2643                 src/gallium/auxiliary/pipe-loader/Makefile
2644                 src/gallium/drivers/freedreno/Makefile
2645                 src/gallium/drivers/ddebug/Makefile
2646                 src/gallium/drivers/i915/Makefile
2647                 src/gallium/drivers/ilo/Makefile
2648                 src/gallium/drivers/llvmpipe/Makefile
2649                 src/gallium/drivers/noop/Makefile
2650                 src/gallium/drivers/nouveau/Makefile
2651                 src/gallium/drivers/r300/Makefile
2652                 src/gallium/drivers/r600/Makefile
2653                 src/gallium/drivers/radeon/Makefile
2654                 src/gallium/drivers/radeonsi/Makefile
2655                 src/gallium/drivers/rbug/Makefile
2656                 src/gallium/drivers/softpipe/Makefile
2657                 src/gallium/drivers/svga/Makefile
2658                 src/gallium/drivers/swr/Makefile
2659                 src/gallium/drivers/trace/Makefile
2660                 src/gallium/drivers/vc4/Makefile
2661                 src/gallium/drivers/virgl/Makefile
2662                 src/gallium/state_trackers/clover/Makefile
2663                 src/gallium/state_trackers/dri/Makefile
2664                 src/gallium/state_trackers/glx/xlib/Makefile
2665                 src/gallium/state_trackers/nine/Makefile
2666                 src/gallium/state_trackers/omx/Makefile
2667                 src/gallium/state_trackers/osmesa/Makefile
2668                 src/gallium/state_trackers/va/Makefile
2669                 src/gallium/state_trackers/vdpau/Makefile
2670                 src/gallium/state_trackers/xa/Makefile
2671                 src/gallium/state_trackers/xvmc/Makefile
2672                 src/gallium/targets/d3dadapter9/Makefile
2673                 src/gallium/targets/d3dadapter9/d3d.pc
2674                 src/gallium/targets/dri/Makefile
2675                 src/gallium/targets/libgl-xlib/Makefile
2676                 src/gallium/targets/omx/Makefile
2677                 src/gallium/targets/opencl/Makefile
2678                 src/gallium/targets/opencl/mesa.icd
2679                 src/gallium/targets/osmesa/Makefile
2680                 src/gallium/targets/osmesa/osmesa.pc
2681                 src/gallium/targets/pipe-loader/Makefile
2682                 src/gallium/targets/va/Makefile
2683                 src/gallium/targets/vdpau/Makefile
2684                 src/gallium/targets/xa/Makefile
2685                 src/gallium/targets/xa/xatracker.pc
2686                 src/gallium/targets/xvmc/Makefile
2687                 src/gallium/tests/trivial/Makefile
2688                 src/gallium/tests/unit/Makefile
2689                 src/gallium/winsys/freedreno/drm/Makefile
2690                 src/gallium/winsys/i915/drm/Makefile
2691                 src/gallium/winsys/intel/drm/Makefile
2692                 src/gallium/winsys/nouveau/drm/Makefile
2693                 src/gallium/winsys/radeon/drm/Makefile
2694                 src/gallium/winsys/amdgpu/drm/Makefile
2695                 src/gallium/winsys/svga/drm/Makefile
2696                 src/gallium/winsys/sw/dri/Makefile
2697                 src/gallium/winsys/sw/kms-dri/Makefile
2698                 src/gallium/winsys/sw/null/Makefile
2699                 src/gallium/winsys/sw/wrapper/Makefile
2700                 src/gallium/winsys/sw/xlib/Makefile
2701                 src/gallium/winsys/vc4/drm/Makefile
2702                 src/gallium/winsys/virgl/drm/Makefile
2703                 src/gallium/winsys/virgl/vtest/Makefile
2704                 src/gbm/Makefile
2705                 src/gbm/main/gbm.pc
2706                 src/glx/Makefile
2707                 src/glx/apple/Makefile
2708                 src/glx/tests/Makefile
2709                 src/gtest/Makefile
2710                 src/intel/Makefile
2711                 src/intel/genxml/Makefile
2712                 src/intel/isl/Makefile
2713                 src/intel/vulkan/Makefile
2714                 src/loader/Makefile
2715                 src/mapi/Makefile
2716                 src/mapi/es1api/glesv1_cm.pc
2717                 src/mapi/es2api/glesv2.pc
2718                 src/mapi/glapi/gen/Makefile
2719                 src/mesa/Makefile
2720                 src/mesa/gl.pc
2721                 src/mesa/drivers/dri/dri.pc
2722                 src/mesa/drivers/dri/common/Makefile
2723                 src/mesa/drivers/dri/common/xmlpool/Makefile
2724                 src/mesa/drivers/dri/i915/Makefile
2725                 src/mesa/drivers/dri/i965/Makefile
2726                 src/mesa/drivers/dri/Makefile
2727                 src/mesa/drivers/dri/nouveau/Makefile
2728                 src/mesa/drivers/dri/r200/Makefile
2729                 src/mesa/drivers/dri/radeon/Makefile
2730                 src/mesa/drivers/dri/swrast/Makefile
2731                 src/mesa/drivers/osmesa/Makefile
2732                 src/mesa/drivers/osmesa/osmesa.pc
2733                 src/mesa/drivers/x11/Makefile
2734                 src/mesa/main/tests/Makefile
2735                 src/util/Makefile
2736                 src/util/tests/hash_table/Makefile])
2737
2738 AC_OUTPUT
2739
2740 # Fix up dependencies in *.Plo files, where we changed the extension of a
2741 # source file
2742 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2743 $SED -i -e 's/gen6_blorp.cpp/gen6_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen6_blorp.Plo
2744 $SED -i -e 's/gen7_blorp.cpp/gen7_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen7_blorp.Plo
2745 $SED -i -e 's/gen8_blorp.cpp/gen8_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen8_blorp.Plo
2746
2747
2748 dnl
2749 dnl Output some configuration info for the user
2750 dnl
2751 echo ""
2752 echo "        prefix:          $prefix"
2753 echo "        exec_prefix:     $exec_prefix"
2754 echo "        libdir:          $libdir"
2755 echo "        includedir:      $includedir"
2756
2757 dnl API info
2758 echo ""
2759 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2760
2761 dnl Driver info
2762 echo ""
2763 case "x$enable_osmesa$enable_gallium_osmesa" in
2764 xnoyes)
2765         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2766         ;;
2767 xyesno)
2768         echo "        OSMesa:          lib$OSMESA_LIB"
2769         ;;
2770 xnono)
2771         echo "        OSMesa:          no"
2772         ;;
2773 esac
2774
2775 echo ""
2776 if test "x$enable_dri" != xno; then
2777         echo "        DRI platform:    $dri_platform"
2778         if test -z "$DRI_DIRS"; then
2779             echo "        DRI drivers:     no"
2780         else
2781             echo "        DRI drivers:     $DRI_DIRS"
2782         fi
2783         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2784 fi
2785
2786 case "x$enable_glx" in
2787 xdri)
2788     echo "        GLX:             DRI-based"
2789     ;;
2790 xxlib)
2791     echo "        GLX:             Xlib-based"
2792     ;;
2793 xgallium-xlib)
2794     echo "        GLX:             Xlib-based (Gallium)"
2795     ;;
2796 *)
2797     echo "        GLX:             $enable_glx"
2798     ;;
2799 esac
2800
2801 dnl EGL
2802 echo ""
2803 echo "        EGL:             $enable_egl"
2804 if test "$enable_egl" = yes; then
2805     echo "        EGL platforms:   $egl_platforms"
2806
2807     egl_drivers=""
2808     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2809         egl_drivers="$egl_drivers builtin:egl_dri2"
2810     fi
2811     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2812         egl_drivers="$egl_drivers builtin:egl_dri3"
2813     fi
2814
2815     echo "        EGL drivers:    $egl_drivers"
2816 fi
2817
2818 # Vulkan
2819 echo ""
2820 if test "x$VULKAN_DRIVERS" != x; then
2821     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2822     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2823 else
2824     echo "        Vulkan drivers:  no"
2825 fi
2826
2827 echo ""
2828 if test "x$MESA_LLVM" = x1; then
2829     echo "        llvm:            yes"
2830     echo "        llvm-config:     $LLVM_CONFIG"
2831     echo "        llvm-version:    $LLVM_VERSION"
2832 else
2833     echo "        llvm:            no"
2834 fi
2835
2836 echo ""
2837 if test -n "$with_gallium_drivers"; then
2838     echo "        Gallium drivers: $gallium_drivers"
2839     echo "        Gallium st:      $gallium_st"
2840 else
2841     echo "        Gallium:         no"
2842 fi
2843
2844 dnl Shader cache
2845 echo ""
2846 echo "        Shader cache:    $enable_shader_cache"
2847 if test "x$enable_shader_cache" = "xyes"; then
2848     echo "        With SHA1 from:  $with_sha1"
2849 fi
2850
2851 dnl Libraries
2852 echo ""
2853 echo "        Shared libs:     $enable_shared"
2854 echo "        Static libs:     $enable_static"
2855 echo "        Shared-glapi:    $enable_shared_glapi"
2856
2857 dnl Compiler options
2858 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2859 cflags=`echo $CFLAGS | \
2860     $SED 's/^ *//;s/  */ /;s/ *$//'`
2861 cxxflags=`echo $CXXFLAGS | \
2862     $SED 's/^ *//;s/  */ /;s/ *$//'`
2863 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2864 echo ""
2865 echo "        CFLAGS:          $cflags"
2866 echo "        CXXFLAGS:        $cxxflags"
2867 echo "        Macros:          $defines"
2868 echo ""
2869 if test "x$MESA_LLVM" = x1; then
2870     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2871     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2872     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2873     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2874     echo ""
2875 fi
2876 echo "        PYTHON2:         $PYTHON2"
2877 echo "        PYTHON3:         $PYTHON3"
2878
2879 echo ""
2880 echo "        Run '${MAKE-make}' to build Mesa"
2881 echo ""