configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 dnl Set internal versions
  28 OSMESA_VERSION=8
  29 AC_SUBST([OSMESA_VERSION])
  30
  31 dnl Versions for external dependencies
  32 LIBDRM_REQUIRED=2.4.24
  33 LIBDRM_RADEON_REQUIRED=2.4.40
  34 LIBDRM_INTEL_REQUIRED=2.4.38
  35 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  36 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  37 DRI2PROTO_REQUIRED=2.6
  38 GLPROTO_REQUIRED=1.4.14
  39 LIBDRM_XORG_REQUIRED=2.4.24
  40 LIBKMS_XORG_REQUIRED=1.0.0
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AX_PROG_CC_FOR_BUILD
  46 AC_PROG_CXX
  47 AX_PROG_CXX_FOR_BUILD
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54
  55 LT_PREREQ([2.2])
  56 LT_INIT([disable-static])
  57
  58 AC_PROG_YACC
  59 AC_PATH_PROG([YACC_INST], $YACC)
  60 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  61     if test -z "$YACC_INST"; then
  62         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  63     fi
  64 fi
  65 AC_PROG_LEX
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 103     AC_MSG_CHECKING([whether gcc version is sufficient])
 104     major=0
 105     minor=0
 106
 107     GCC_VERSION=`$CC -dumpversion`
 108     if test $? -eq 0; then
 109         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 110         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 111     fi
 112
 113     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 114         AC_MSG_RESULT([no])
 115         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 116     else
 117         AC_MSG_RESULT([yes])
 118     fi
 119 fi
 120
 121 dnl Make sure the pkg-config macros are defined
 122 m4_ifndef([PKG_PROG_PKG_CONFIG],
 123     [m4_fatal([Could not locate the pkg-config autoconf macros.
 124   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 125   are in a different location, try setting the environment variable
 126   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 127 PKG_PROG_PKG_CONFIG()
 128
 129 dnl LIB_DIR - library basename
 130 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 131 AC_SUBST([LIB_DIR])
 132
 133 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 134 _SAVE_LDFLAGS="$LDFLAGS"
 135 _SAVE_CPPFLAGS="$CPPFLAGS"
 136
 137 dnl build host compiler macros
 138 DEFINES_FOR_BUILD=""
 139 AC_SUBST([DEFINES_FOR_BUILD])
 140 case "$build_os" in
 141 linux*|*-gnu*|gnu*)
 142     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 143     ;;
 144 solaris*)
 145     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 146     ;;
 147 cygwin*)
 148     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 149     ;;
 150 esac
 151
 152 dnl Compiler macros
 153 DEFINES=""
 154 AC_SUBST([DEFINES])
 155 case "$host_os" in
 156 linux*|*-gnu*|gnu*)
 157     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 158     ;;
 159 solaris*)
 160     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 161     ;;
 162 cygwin*)
 163     DEFINES="$DEFINES -DHAVE_PTHREAD"
 164     ;;
 165 esac
 166
 167 dnl Add flags for gcc and g++
 168 if test "x$GCC" = xyes; then
 169     case "$host_os" in
 170     cygwin*)
 171         CFLAGS="$CFLAGS -Wall -std=gnu99"
 172         ;;
 173     *)
 174         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 175         CFLAGS="$CFLAGS -Wall -std=c99"
 176         ;;
 177     esac
 178
 179     # Enable -Werror=implicit-function-declaration and
 180     # -Werror=missing-prototypes, if available, or otherwise, just
 181     # -Wmissing-prototypes.  This is particularly useful to avoid
 182     # generating a loadable driver module that has undefined symbols.
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 185     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 186     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 188                    AC_MSG_RESULT([yes]),
 189                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 190                     AC_MSG_RESULT([no])]);
 191
 192     # Enable -fvisibility=hidden if using a gcc that supports it
 193     save_CFLAGS="$CFLAGS"
 194     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 195     VISIBILITY_CFLAGS="-fvisibility=hidden"
 196     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 197     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 198                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 199
 200     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 201     CFLAGS=$save_CFLAGS
 202
 203     # Work around aliasing bugs - developers should comment this out
 204     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 210     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 211 fi
 212 if test "x$GXX" = xyes; then
 213     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 231     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 232
 233     # gcc's builtin memcmp is slower than glibc's
 234     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 235     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 236     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 237 fi
 238
 239 dnl even if the compiler appears to support it, using visibility attributes isn't
 240 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 241 case "$host_os" in
 242 cygwin*)
 243     VISIBILITY_CFLAGS=""
 244     VISIBILITY_CXXFLAGS=""
 245     ;;
 246 esac
 247
 248 AC_SUBST([VISIBILITY_CFLAGS])
 249 AC_SUBST([VISIBILITY_CXXFLAGS])
 250
 251 dnl
 252 dnl Hacks to enable 32 or 64 bit build
 253 dnl
 254 AC_ARG_ENABLE([32-bit],
 255     [AS_HELP_STRING([--enable-32-bit],
 256         [build 32-bit libraries @<:@default=auto@:>@])],
 257     [enable_32bit="$enableval"],
 258     [enable_32bit=auto]
 259 )
 260 if test "x$enable_32bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m32"
 263         CCASFLAGS="$CCASFLAGS -m32"
 264     fi
 265     if test "x$GXX" = xyes; then
 266         CXXFLAGS="$CXXFLAGS -m32"
 267     fi
 268 fi
 269 AC_ARG_ENABLE([64-bit],
 270     [AS_HELP_STRING([--enable-64-bit],
 271         [build 64-bit libraries @<:@default=auto@:>@])],
 272     [enable_64bit="$enableval"],
 273     [enable_64bit=auto]
 274 )
 275 if test "x$enable_64bit" = xyes; then
 276     if test "x$GCC" = xyes; then
 277         CFLAGS="$CFLAGS -m64"
 278     fi
 279     if test "x$GXX" = xyes; then
 280         CXXFLAGS="$CXXFLAGS -m64"
 281     fi
 282 fi
 283
 284 dnl Can't have static and shared libraries, default to static if user
 285 dnl explicitly requested. If both disabled, set to static since shared
 286 dnl was explicitly requested.
 287 case "x$enable_static$enable_shared" in
 288 xyesyes )
 289     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 290     enable_shared=no
 291     ;;
 292 xnono )
 293     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 294     enable_static=yes
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 299
 300 dnl
 301 dnl other compiler options
 302 dnl
 303 AC_ARG_ENABLE([debug],
 304     [AS_HELP_STRING([--enable-debug],
 305         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 306     [enable_debug="$enableval"],
 307     [enable_debug=no]
 308 )
 309 if test "x$enable_debug" = xyes; then
 310     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 311     if test "x$GCC_FOR_BUILD" = xyes; then
 312         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 313     fi
 314     if test "x$GXX_FOR_BUILD" = xyes; then
 315         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 316     fi
 317
 318     DEFINES="$DEFINES -DDEBUG"
 319     if test "x$GCC" = xyes; then
 320         CFLAGS="$CFLAGS -g -O0"
 321     fi
 322     if test "x$GXX" = xyes; then
 323         CXXFLAGS="$CXXFLAGS -g -O0"
 324     fi
 325 fi
 326
 327 dnl
 328 dnl library names
 329 dnl
 330 LIB_PREFIX_GLOB='lib'
 331 LIB_VERSION_SEPARATOR='.'
 332 if test "$enable_static" = yes; then
 333     LIB_EXTENSION='a'
 334 else
 335     case "$host_os" in
 336     darwin* )
 337         LIB_EXTENSION='dylib' ;;
 338     cygwin* )
 339         dnl prefix can be 'cyg' or 'lib'
 340         LIB_PREFIX_GLOB='???'
 341         LIB_VERSION_SEPARATOR='-'
 342         LIB_EXTENSION='dll' ;;
 343     aix* )
 344         LIB_EXTENSION='a' ;;
 345     * )
 346         LIB_EXTENSION='so' ;;
 347     esac
 348 fi
 349 AC_ARG_WITH([gl-lib-name],
 350   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 351     [specify GL library name @<:@default=GL@:>@])],
 352   [GL_LIB=$withval],
 353   [GL_LIB=GL])
 354 AC_ARG_WITH([osmesa-lib-name],
 355   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 356     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 357   [OSMESA_LIB=$withval],
 358   [OSMESA_LIB=OSMesa])
 359 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 360 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 361
 362 dnl
 363 dnl Mangled Mesa support
 364 dnl
 365 AC_ARG_ENABLE([mangling],
 366   [AS_HELP_STRING([--enable-mangling],
 367     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 368   [enable_mangling="${enableval}"],
 369   [enable_mangling=no]
 370 )
 371 if test "x${enable_mangling}" = "xyes" ; then
 372   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 373   GL_LIB="Mangled${GL_LIB}"
 374   OSMESA_LIB="Mangled${OSMESA_LIB}"
 375 fi
 376 AC_SUBST([GL_LIB])
 377 AC_SUBST([OSMESA_LIB])
 378
 379 dnl
 380 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 381 dnl
 382 AC_ARG_ENABLE([texture-float],
 383     [AS_HELP_STRING([--enable-texture-float],
 384         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 385     [enable_texture_float="$enableval"],
 386     [enable_texture_float=no]
 387 )
 388 if test "x$enable_texture_float" = xyes; then
 389     AC_MSG_WARN([Floating-point textures enabled.])
 390     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 391     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 392 fi
 393
 394 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 395 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 396 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 397 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 398 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 399 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 400 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 401
 402 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([OSMESA_LIB_NAME])
 412 AC_SUBST([EGL_LIB_NAME])
 413 AC_SUBST([GLESv1_CM_LIB_NAME])
 414 AC_SUBST([GLESv2_LIB_NAME])
 415 AC_SUBST([VG_LIB_NAME])
 416 AC_SUBST([GLAPI_LIB_NAME])
 417
 418 AC_SUBST([GL_LIB_GLOB])
 419 AC_SUBST([EGL_LIB_GLOB])
 420 AC_SUBST([GLESv1_CM_LIB_GLOB])
 421 AC_SUBST([GLESv2_LIB_GLOB])
 422 AC_SUBST([VG_LIB_GLOB])
 423 AC_SUBST([GLAPI_LIB_GLOB])
 424
 425 dnl
 426 dnl Arch/platform-specific settings
 427 dnl
 428 AC_ARG_ENABLE([asm],
 429     [AS_HELP_STRING([--disable-asm],
 430         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 431     [enable_asm="$enableval"],
 432     [enable_asm=yes]
 433 )
 434 asm_arch=""
 435 MESA_ASM_FILES=""
 436 AC_MSG_CHECKING([whether to enable assembly])
 437 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 438 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 439 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 440     case "$host_cpu" in
 441     i?86 | x86_64)
 442         enable_asm=no
 443         AC_MSG_RESULT([no, cross compiling])
 444         ;;
 445     esac
 446 fi
 447 # check for supported arches
 448 if test "x$enable_asm" = xyes; then
 449     case "$host_cpu" in
 450     i?86)
 451         case "$host_os" in
 452         linux* | *freebsd* | dragonfly* | *netbsd*)
 453             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 454             ;;
 455         esac
 456         ;;
 457     x86_64)
 458         case "$host_os" in
 459         linux* | *freebsd* | dragonfly* | *netbsd*)
 460             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 461             ;;
 462         esac
 463         ;;
 464     sparc*)
 465         case "$host_os" in
 466         linux*)
 467             asm_arch=sparc
 468             ;;
 469         esac
 470         ;;
 471     esac
 472
 473     case "$asm_arch" in
 474     x86)
 475         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 476         MESA_ASM_FILES='$(X86_FILES)'
 477         AC_MSG_RESULT([yes, x86])
 478         ;;
 479     x86_64)
 480         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 481         MESA_ASM_FILES='$(X86_64_FILES)'
 482         AC_MSG_RESULT([yes, x86_64])
 483         ;;
 484     sparc)
 485         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 486         MESA_ASM_FILES='$(SPARC_FILES)'
 487         AC_MSG_RESULT([yes, sparc])
 488         ;;
 489     *)
 490         AC_MSG_RESULT([no, platform not supported])
 491         ;;
 492     esac
 493 fi
 494 AC_SUBST([MESA_ASM_FILES])
 495
 496 dnl Check to see if dlopen is in default libraries (like Solaris, which
 497 dnl has it in libc), or if libdl is needed to get it.
 498 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 499     [AC_CHECK_LIB([dl], [dlopen],
 500        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 501 AC_SUBST([DLOPEN_LIBS])
 502
 503 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 504                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 505                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 506 AC_SUBST([CLOCK_LIB])
 507
 508 dnl See if posix_memalign is available
 509 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 510
 511 dnl Check for pthreads
 512 AX_PTHREAD
 513 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 514 dnl to -pthread, which causes problems if we need -lpthread to appear in
 515 dnl pkgconfig files.
 516 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 517
 518 dnl SELinux awareness.
 519 AC_ARG_ENABLE([selinux],
 520     [AS_HELP_STRING([--enable-selinux],
 521         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 522     [MESA_SELINUX="$enableval"],
 523     [MESA_SELINUX=no])
 524 if test "x$enable_selinux" = "xyes"; then
 525     AC_CHECK_HEADER([selinux/selinux.h],[],
 526                     [AC_MSG_ERROR([SELinux headers not found])])
 527     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 528                  [AC_MSG_ERROR([SELinux library not found])])
 529     SELINUX_LIBS="-lselinux"
 530     DEFINES="$DEFINES -DMESA_SELINUX"
 531 fi
 532 AC_SUBST([SELINUX_LIBS])
 533
 534 dnl Options for APIs
 535 AC_ARG_ENABLE([opengl],
 536     [AS_HELP_STRING([--disable-opengl],
 537         [disable support for standard OpenGL API @<:@default=no@:>@])],
 538     [enable_opengl="$enableval"],
 539     [enable_opengl=yes])
 540 AC_ARG_ENABLE([gles1],
 541     [AS_HELP_STRING([--enable-gles1],
 542         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 543     [enable_gles1="$enableval"],
 544     [enable_gles1=no])
 545 AC_ARG_ENABLE([gles2],
 546     [AS_HELP_STRING([--enable-gles2],
 547         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 548     [enable_gles2="$enableval"],
 549     [enable_gles2=no])
 550 AC_ARG_ENABLE([openvg],
 551     [AS_HELP_STRING([--enable-openvg],
 552         [enable support for OpenVG API @<:@default=no@:>@])],
 553     [enable_openvg="$enableval"],
 554     [enable_openvg=no])
 555
 556 AC_ARG_ENABLE([dri],
 557     [AS_HELP_STRING([--enable-dri],
 558         [enable DRI modules @<:@default=enabled@:>@])],
 559     [enable_dri="$enableval"],
 560     [enable_dri=yes])
 561 AC_ARG_ENABLE([glx],
 562     [AS_HELP_STRING([--enable-glx],
 563         [enable GLX library @<:@default=enabled@:>@])],
 564     [enable_glx="$enableval"],
 565     [enable_glx=yes])
 566 AC_ARG_ENABLE([osmesa],
 567     [AS_HELP_STRING([--enable-osmesa],
 568         [enable OSMesa library @<:@default=disabled@:>@])],
 569     [enable_osmesa="$enableval"],
 570     [enable_osmesa=no])
 571 AC_ARG_ENABLE([egl],
 572     [AS_HELP_STRING([--disable-egl],
 573         [disable EGL library @<:@default=enabled@:>@])],
 574     [enable_egl="$enableval"],
 575     [enable_egl=yes])
 576
 577 AC_ARG_ENABLE([xorg],
 578     [AS_HELP_STRING([--enable-xorg],
 579         [enable support for X.Org DDX API @<:@default=no@:>@])],
 580     [enable_xorg="$enableval"],
 581     [enable_xorg=no])
 582 AC_ARG_ENABLE([xa],
 583     [AS_HELP_STRING([--enable-xa],
 584         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 585     [enable_xa="$enableval"],
 586     [enable_xa=no])
 587 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 588 enable_d3d1x=no
 589 dnl AC_ARG_ENABLE([d3d1x],
 590 dnl     [AS_HELP_STRING([--enable-d3d1x],
 591 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 592 dnl     [enable_d3d1x="$enableval"],
 593 dnl     [enable_d3d1x=no])
 594 AC_ARG_ENABLE([gbm],
 595    [AS_HELP_STRING([--enable-gbm],
 596          [enable gbm library @<:@default=auto@:>@])],
 597    [enable_gbm="$enableval"],
 598    [enable_gbm=auto])
 599
 600 AC_ARG_ENABLE([xvmc],
 601    [AS_HELP_STRING([--enable-xvmc],
 602          [enable xvmc library @<:@default=auto@:>@])],
 603    [enable_xvmc="$enableval"],
 604    [enable_xvmc=auto])
 605 AC_ARG_ENABLE([vdpau],
 606    [AS_HELP_STRING([--enable-vdpau],
 607          [enable vdpau library @<:@default=auto@:>@])],
 608    [enable_vdpau="$enableval"],
 609    [enable_vdpau=auto])
 610 AC_ARG_ENABLE([opencl],
 611    [AS_HELP_STRING([--enable-opencl],
 612          [enable OpenCL library @<:@default=no@:>@])],
 613    [enable_opencl="$enableval"],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([xlib_glx],
 616     [AS_HELP_STRING([--enable-xlib-glx],
 617         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 618     [enable_xlib_glx="$enableval"],
 619     [enable_xlib_glx=no])
 620 AC_ARG_ENABLE([gallium_egl],
 621     [AS_HELP_STRING([--enable-gallium-egl],
 622         [enable optional EGL state tracker (not required
 623          for EGL support in Gallium with OpenGL and OpenGL ES)
 624          @<:@default=disable@:>@])],
 625     [enable_gallium_egl="$enableval"],
 626     [enable_gallium_egl=no])
 627 AC_ARG_ENABLE([gallium_gbm],
 628     [AS_HELP_STRING([--enable-gallium-gbm],
 629         [enable optional gbm state tracker (not required for
 630          gbm support in Gallium)
 631          @<:@default=auto@:>@])],
 632     [enable_gallium_gbm="$enableval"],
 633     [enable_gallium_gbm=auto])
 634
 635 AC_ARG_ENABLE([r600-llvm-compiler],
 636     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 637         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 638     [enable_r600_llvm="$enableval"],
 639     [enable_r600_llvm=no])
 640
 641 AC_ARG_ENABLE([gallium_tests],
 642     [AS_HELP_STRING([--enable-gallium-tests],
 643         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 644     [enable_gallium_tests="$enableval"],
 645     [enable_gallium_tests=no])
 646
 647 # Option for Gallium drivers
 648 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 649
 650 AC_ARG_WITH([gallium-drivers],
 651     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 652         [comma delimited Gallium drivers list, e.g.
 653         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 654         @<:@default=r300,r600,swrast@:>@])],
 655     [with_gallium_drivers="$withval"],
 656     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 657
 658 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 659 # here so that the script doesn't choke on an unknown driver name later.
 660 case "$with_gallium_drivers" in
 661     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 662     no) with_gallium_drivers='' ;;
 663 esac
 664
 665 if test "x$enable_opengl" = xno -a \
 666         "x$enable_gles1" = xno -a \
 667         "x$enable_gles2" = xno -a \
 668         "x$enable_openvg" = xno -a \
 669         "x$enable_xorg" = xno -a \
 670         "x$enable_xa" = xno -a \
 671         "x$enable_d3d1x" = xno -a \
 672         "x$enable_xvmc" = xno -a \
 673         "x$enable_vdpau" = xno -a \
 674         "x$enable_opencl" = xno; then
 675     AC_MSG_ERROR([at least one API should be enabled])
 676 fi
 677
 678 API_DEFINES=""
 679 if test "x$enable_opengl" = xno; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 681 else
 682     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 683 fi
 684 if test "x$enable_gles1" = xyes; then
 685     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 686 fi
 687 if test "x$enable_gles2" = xyes; then
 688     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 689 fi
 690 AC_SUBST([API_DEFINES])
 691
 692 if test "x$enable_glx" = xno; then
 693     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 694     enable_xlib_glx=no
 695 fi
 696
 697 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 698     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 699 fi
 700
 701 # Disable GLX if DRI and Xlib-GLX are not enabled
 702 if test "x$enable_glx" = xyes -a \
 703         "x$enable_dri" = xno -a \
 704         "x$enable_xlib_glx" = xno; then
 705     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 706     enable_glx=no
 707 fi
 708
 709 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 710 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 711                                   "x$enable_osmesa" = xyes)
 712
 713 AC_ARG_ENABLE([shared-glapi],
 714     [AS_HELP_STRING([--enable-shared-glapi],
 715         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 716     [enable_shared_glapi="$enableval"],
 717     [enable_shared_glapi="$enable_dri"])
 718
 719 # Shared GLAPI is only useful for DRI
 720 if test "x$enable_dri" = xno; then
 721     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 722     enable_shared_glapi=no
 723 fi
 724
 725 # TODO: Get rid of SHARED_GLAPI variable
 726 SHARED_GLAPI="0"
 727 if test "x$enable_shared_glapi" = xyes; then
 728     SHARED_GLAPI="1"
 729     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 730     # the remap table)
 731     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 732     CORE_DIRS="mapi/shared-glapi"
 733 fi
 734 AC_SUBST([SHARED_GLAPI])
 735 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 736
 737 dnl
 738 dnl Driver specific build directories
 739 dnl
 740 SRC_DIRS="gtest"
 741 GALLIUM_DIRS="auxiliary drivers state_trackers"
 742 GALLIUM_TARGET_DIRS=""
 743 GALLIUM_WINSYS_DIRS="sw"
 744 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 745 GALLIUM_STATE_TRACKERS_DIRS=""
 746
 747 # build glapi if OpenGL is enabled
 748 if test "x$enable_opengl" = xyes; then
 749     CORE_DIRS="$CORE_DIRS mapi/glapi"
 750 fi
 751
 752 # build es1api if OpenGL ES 1.x is enabled
 753 if test "x$enable_gles1" = xyes; then
 754     CORE_DIRS="$CORE_DIRS mapi/es1api"
 755 fi
 756
 757 # build es2api if OpenGL ES 2.x is enabled
 758 if test "x$enable_gles2" = xyes; then
 759     CORE_DIRS="$CORE_DIRS mapi/es2api"
 760 fi
 761
 762 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 763 case "x$enable_opengl$enable_gles1$enable_gles2" in
 764 x*yes*)
 765     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 766     ;;
 767 esac
 768
 769 case "x$enable_glx$enable_xlib_glx" in
 770 xyesyes)
 771     DRIVER_DIRS="$DRIVER_DIRS x11"
 772     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 773     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 774     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 775     HAVE_WINSYS_XLIB="yes"
 776     ;;
 777 xyesno)
 778     # DRI-based GLX
 779     SRC_DIRS="$SRC_DIRS glx"
 780     ;;
 781 esac
 782
 783 if test "x$enable_dri" = xyes; then
 784     DRIVER_DIRS="$DRIVER_DIRS dri"
 785
 786     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 787     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 788     HAVE_ST_DRI="yes"
 789 fi
 790
 791 if test "x$enable_osmesa" = xyes; then
 792     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 793 fi
 794
 795 AC_SUBST([SRC_DIRS])
 796 AC_SUBST([DRIVER_DIRS])
 797 AC_SUBST([GALLIUM_DIRS])
 798 AC_SUBST([GALLIUM_TARGET_DIRS])
 799 AC_SUBST([GALLIUM_WINSYS_DIRS])
 800 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 801 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 802 AC_SUBST([MESA_LLVM])
 803
 804 # Check for libdrm
 805 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 806                   [have_libdrm=yes], [have_libdrm=no])
 807
 808 if test "x$enable_dri" = xyes; then
 809     # DRI must be shared, I think
 810     if test "$enable_static" = yes; then
 811         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 812     fi
 813
 814     # not a hard requirement as swrast does not depend on it
 815     if test "x$have_libdrm" = xyes; then
 816         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 817     fi
 818 fi
 819
 820 dnl Find out if X is available.
 821 PKG_CHECK_MODULES([X11], [x11], [no_x=no], [no_x=yes])
 822
 823 dnl Try to tell the user that the --x-* options are only used when
 824 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 825 m4_divert_once([HELP_BEGIN],
 826 [These options are only used when the X libraries cannot be found by the
 827 pkg-config utility.])
 828
 829 dnl We need X for xlib and dri, so bomb now if it's not found
 830 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 831     AC_MSG_ERROR([X11 development libraries needed for GLX])
 832 fi
 833
 834 dnl Direct rendering or just indirect rendering
 835 case "$host_os" in
 836 gnu*)
 837     dnl Disable by default on GNU/Hurd
 838     driglx_direct_default="no"
 839     ;;
 840 cygwin*)
 841     dnl Disable by default on cygwin
 842     driglx_direct_default="no"
 843     ;;
 844 *)
 845     driglx_direct_default="yes"
 846     ;;
 847 esac
 848 AC_ARG_ENABLE([driglx-direct],
 849     [AS_HELP_STRING([--disable-driglx-direct],
 850         [disable direct rendering in GLX and EGL for DRI \
 851             @<:@default=auto@:>@])],
 852     [driglx_direct="$enableval"],
 853     [driglx_direct="$driglx_direct_default"])
 854
 855 dnl
 856 dnl libGL configuration per driver
 857 dnl
 858 case "x$enable_glx$enable_xlib_glx" in
 859 xyesyes)
 860     # Xlib-based GLX
 861     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 862     GL_PC_REQ_PRIV="x11 xext"
 863     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 864     GL_LIB_DEPS="$XLIBGL_LIBS"
 865     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 866     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 867     ;;
 868 xyesno)
 869     # DRI-based GLX
 870     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 871     if test x"$driglx_direct" = xyes; then
 872         if test "x$have_libdrm" != xyes; then
 873             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 874         fi
 875         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 876         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 877     fi
 878
 879     # find the DRI deps for libGL
 880     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 881
 882     # add xf86vidmode if available
 883     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 884     if test "$HAVE_XF86VIDMODE" = yes ; then
 885         dri_modules="$dri_modules xxf86vm"
 886     fi
 887
 888     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 889     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 890     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 891     GL_LIB_DEPS="$DRIGL_LIBS"
 892
 893     # need DRM libs, $PTHREAD_LIBS, etc.
 894     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 895     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     ;;
 897 esac
 898
 899 # This is outside the case (above) so that it is invoked even for non-GLX
 900 # builds.
 901 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 902
 903 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 904 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 907
 908 AC_SUBST([X11_INCLUDES])
 909 AC_SUBST([GL_LIB_DEPS])
 910 AC_SUBST([GL_PC_REQ_PRIV])
 911 AC_SUBST([GL_PC_LIB_PRIV])
 912 AC_SUBST([GL_PC_CFLAGS])
 913 AC_SUBST([DRI_PC_REQ_PRIV])
 914 AC_SUBST([GLESv1_CM_LIB_DEPS])
 915 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 916 AC_SUBST([GLESv2_LIB_DEPS])
 917 AC_SUBST([GLESv2_PC_LIB_PRIV])
 918
 919 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 920
 921 AC_SUBST([HAVE_XF86VIDMODE])
 922
 923 dnl
 924 dnl More GLX setup
 925 dnl
 926 case "x$enable_glx$enable_xlib_glx" in
 927 xyesyes)
 928     DEFINES="$DEFINES -DUSE_XSHM"
 929     ;;
 930 xyesno)
 931     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 932     if test "x$driglx_direct" = xyes; then
 933         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 934     fi
 935     ;;
 936 esac
 937
 938 dnl
 939 dnl TLS detection
 940 dnl
 941
 942 AC_ARG_ENABLE([glx-tls],
 943     [AS_HELP_STRING([--enable-glx-tls],
 944         [enable TLS support in GLX @<:@default=disabled@:>@])],
 945     [GLX_USE_TLS="$enableval"],
 946     [GLX_USE_TLS=no])
 947 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 948
 949 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 950       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 951
 952 dnl
 953 dnl More DRI setup
 954 dnl
 955 dnl Directory for DRI drivers
 956 AC_ARG_WITH([dri-driverdir],
 957     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 958         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 959     [DRI_DRIVER_INSTALL_DIR="$withval"],
 960     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 961 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 962 dnl Extra search path for DRI drivers
 963 AC_ARG_WITH([dri-searchpath],
 964     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 965         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 966     [DRI_DRIVER_SEARCH_DIR="$withval"],
 967     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 968 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 969 dnl Which drivers to build - default is chosen by platform
 970 AC_ARG_WITH([dri-drivers],
 971     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 972         [comma delimited DRI drivers list, e.g.
 973         "swrast,i965,radeon" @<:@default=auto@:>@])],
 974     [with_dri_drivers="$withval"],
 975     [with_dri_drivers=yes])
 976 if test "x$with_dri_drivers" = x; then
 977     with_dri_drivers=no
 978 fi
 979
 980 dnl If $with_dri_drivers is yes, directories will be added through
 981 dnl platform checks
 982 DRI_DIRS=""
 983 case "$with_dri_drivers" in
 984 no) ;;
 985 yes)
 986     # classic DRI drivers require FEATURE_GL to build
 987     if test "x$enable_opengl" = xyes; then
 988         DRI_DIRS="yes"
 989     fi
 990     ;;
 991 *)
 992     # verify the requested driver directories exist
 993     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 994     for driver in $dri_drivers; do
 995         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 996             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 997     done
 998     DRI_DIRS="$dri_drivers"
 999     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1000         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1001     fi
1002     ;;
1003 esac
1004
1005 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1006 if test "x$enable_dri" = xyes; then
1007     # Platform specific settings and drivers to build
1008     case "$host_os" in
1009     linux*)
1010         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1011         DEFINES="$DEFINES -DHAVE_ALIAS"
1012
1013         case "$host_cpu" in
1014         x86_64)
1015             if test "x$DRI_DIRS" = "xyes"; then
1016                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1017             fi
1018             ;;
1019         powerpc*)
1020             # Build only the drivers for cards that exist on PowerPC.
1021             if test "x$DRI_DIRS" = "xyes"; then
1022                 DRI_DIRS="r200 radeon swrast"
1023             fi
1024             ;;
1025         sparc*)
1026             # Build only the drivers for cards that exist on sparc
1027             if test "x$DRI_DIRS" = "xyes"; then
1028                 DRI_DIRS="r200 radeon swrast"
1029             fi
1030             ;;
1031         esac
1032         ;;
1033     freebsd* | dragonfly* | *netbsd*)
1034         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1035         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1036
1037         if test "x$DRI_DIRS" = "xyes"; then
1038             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1039         fi
1040         ;;
1041     gnu*)
1042         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1043         DEFINES="$DEFINES -DHAVE_ALIAS"
1044         ;;
1045     solaris*)
1046         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1047         ;;
1048     cygwin*)
1049         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1050         if test "x$DRI_DIRS" = "xyes"; then
1051             DRI_DIRS="swrast"
1052         fi
1053         ;;
1054     esac
1055
1056     # default drivers
1057     if test "x$DRI_DIRS" = "xyes"; then
1058         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1059     fi
1060
1061     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1062
1063     # Check for expat
1064     if test "x$enable_dri" = xyes; then
1065         EXPAT_INCLUDES=""
1066         EXPAT_LIB=-lexpat
1067         AC_ARG_WITH([expat],
1068             [AS_HELP_STRING([--with-expat=DIR],
1069                 [expat install directory])],[
1070             EXPAT_INCLUDES="-I$withval/include"
1071             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1072             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1073             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1074             ])
1075         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1076         save_LIBS="$LIBS"
1077         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1078             [AC_MSG_ERROR([Expat required for DRI.])])
1079         LIBS="$save_LIBS"
1080     fi
1081
1082     # if we are building any dri driver other than swrast ...
1083     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1084         # ... libdrm is required
1085         if test "x$have_libdrm" != xyes; then
1086             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1087         fi
1088         # ... and build dricommon
1089         HAVE_COMMON_DRI=yes
1090     fi
1091
1092     # put all the necessary libs together
1093     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1094     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1095 fi
1096 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1097 AC_SUBST([DRI_DIRS])
1098 AC_SUBST([EXPAT_INCLUDES])
1099 AC_SUBST([DRI_LIB_DEPS])
1100 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1101
1102 case $DRI_DIRS in
1103 *i915*|*i965*)
1104     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1105
1106     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1107         case $d in
1108         i915)
1109             HAVE_I915_DRI=yes;
1110             ;;
1111         i965)
1112             HAVE_I965_DRI=yes;
1113             ;;
1114         esac
1115     done
1116
1117     ;;
1118 esac
1119
1120 case $DRI_DIRS in
1121 *nouveau*)
1122     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1123     HAVE_NOUVEAU_DRI=yes;
1124     ;;
1125 esac
1126
1127 case $DRI_DIRS in
1128 *radeon*|*r200*)
1129     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1130
1131     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1132         case $d in
1133         radeon)
1134             HAVE_RADEON_DRI=yes;
1135             ;;
1136         r200)
1137             HAVE_R200_DRI=yes;
1138             ;;
1139         esac
1140     done
1141
1142     ;;
1143 esac
1144
1145 case $DRI_DIRS in
1146 *swrast*)
1147     HAVE_SWRAST_DRI=yes;
1148     ;;
1149 esac
1150
1151 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1152 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1153 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1154 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1158
1159 dnl
1160 dnl OSMesa configuration
1161 dnl
1162
1163 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1164 AC_ARG_WITH([osmesa-bits],
1165     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1166         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1167     [osmesa_bits="$withval"],
1168     [osmesa_bits=8])
1169 if test "x$osmesa_bits" != x8; then
1170     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1171         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1172         osmesa_bits=8
1173     fi
1174 fi
1175 case "x$osmesa_bits" in
1176 x8)
1177     OSMESA_LIB="${OSMESA_LIB}"
1178     ;;
1179 x16|x32)
1180     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1181     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1182     ;;
1183 *)
1184     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1185     ;;
1186 esac
1187
1188 if test "x$enable_osmesa" = xyes; then
1189     # only link libraries with osmesa if shared
1190     if test "$enable_static" = no; then
1191         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1192     else
1193         OSMESA_LIB_DEPS=""
1194     fi
1195     OSMESA_MESA_DEPS=""
1196     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1197 fi
1198
1199 AC_SUBST([OSMESA_LIB_DEPS])
1200 AC_SUBST([OSMESA_MESA_DEPS])
1201 AC_SUBST([OSMESA_PC_REQ])
1202 AC_SUBST([OSMESA_PC_LIB_PRIV])
1203
1204 dnl
1205 dnl gbm configuration
1206 dnl
1207 if test "x$enable_gbm" = xauto; then
1208     case "$with_egl_platforms" in
1209         *drm*)
1210             enable_gbm=yes ;;
1211          *)
1212             enable_gbm=no ;;
1213     esac
1214 fi
1215 if test "x$enable_gbm" = xyes; then
1216     SRC_DIRS="$SRC_DIRS gbm"
1217
1218     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1219                       AC_MSG_ERROR([gbm needs udev]))
1220
1221     if test "x$enable_dri" = xyes; then
1222         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1223         if test "x$enable_shared_glapi" = xno; then
1224             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1225         fi
1226     fi
1227 fi
1228 GBM_PC_REQ_PRIV="libudev"
1229 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1230 AC_SUBST([GBM_PC_REQ_PRIV])
1231 AC_SUBST([GBM_PC_LIB_PRIV])
1232
1233 dnl
1234 dnl EGL configuration
1235 dnl
1236 EGL_CLIENT_APIS=""
1237
1238 if test "x$enable_egl" = xyes; then
1239     SRC_DIRS="$SRC_DIRS egl"
1240     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1241
1242     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1243
1244     if test "$enable_static" != yes; then
1245         # build egl_glx when libGL is built
1246         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1247                           [have_libudev=yes],[have_libudev=no])
1248         if test "$have_libudev" = yes; then
1249             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1250         fi
1251
1252         if test "x$enable_dri" = xyes; then
1253             HAVE_EGL_DRIVER_DRI2=1
1254         fi
1255
1256     fi
1257 fi
1258 AC_SUBST([EGL_LIB_DEPS])
1259
1260 dnl
1261 dnl EGL Gallium configuration
1262 dnl
1263 if test "x$enable_gallium_egl" = xyes; then
1264     if test "x$with_gallium_drivers" = x; then
1265         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1266     fi
1267     if test "x$enable_egl" = xno; then
1268         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1269     fi
1270     if test "x$have_libdrm" != xyes; then
1271         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1272     fi
1273
1274     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1275     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1276     HAVE_ST_EGL="yes"
1277 fi
1278
1279 dnl
1280 dnl gbm Gallium configuration
1281 dnl
1282 if test "x$enable_gallium_gbm" = xauto; then
1283     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1284         yesyesyes*drm*)
1285             enable_gallium_gbm=yes ;;
1286          *)
1287             enable_gallium_gbm=no ;;
1288     esac
1289 fi
1290 if test "x$enable_gallium_gbm" = xyes; then
1291     if test "x$with_gallium_drivers" = x; then
1292         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1293     fi
1294     if test "x$enable_gbm" = xno; then
1295         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1296     fi
1297     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1298     if test "x$enable_dri" = xno; then
1299         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1300     fi
1301
1302     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1303     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1304     HAVE_ST_GBM="yes"
1305     enable_gallium_loader=yes
1306 fi
1307
1308 dnl
1309 dnl X.Org DDX configuration
1310 dnl
1311 if test "x$enable_xorg" = xyes; then
1312     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1313     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1314     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1315     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1316         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1317         HAVE_XEXTPROTO_71="no")
1318     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1319     HAVE_ST_XORG=yes
1320 fi
1321
1322 dnl
1323 dnl XA configuration
1324 dnl
1325 if test "x$enable_xa" = xyes; then
1326 AC_PROG_AWK
1327 AC_PROG_GREP
1328 AC_CHECK_PROG(NM, nm, "nm")
1329 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1330 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1331 enable_xa=no
1332 fi
1333 fi
1334 if test "x$enable_xa" = xyes; then
1335     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1336     HAVE_ST_XA=yes
1337     AC_SUBST(AWK)
1338     AC_SUBST(GREP)
1339     AC_SUBST(NM)
1340 fi
1341
1342 dnl
1343 dnl OpenVG configuration
1344 dnl
1345 VG_LIB_DEPS=""
1346
1347 if test "x$enable_openvg" = xyes; then
1348     if test "x$enable_egl" = xno; then
1349         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1350     fi
1351     if test "x$with_gallium_drivers" = x; then
1352         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1353     fi
1354     if test "x$enable_gallium_egl" = xno; then
1355         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1356     fi
1357
1358     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1359     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1360     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1361     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1362     HAVE_ST_VEGA=yes
1363     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1364     AC_SUBST([VG_PC_LIB_PRIV])
1365 fi
1366 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1367
1368 dnl
1369 dnl D3D1X configuration
1370 dnl
1371
1372 if test "x$enable_d3d1x" = xyes; then
1373     if test "x$with_gallium_drivers" = x; then
1374         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1375     fi
1376
1377     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1378     HAVE_ST_D3D1X=yes
1379 fi
1380
1381 dnl
1382 dnl Gallium G3DVL configuration
1383 dnl
1384 AC_ARG_ENABLE([gallium-g3dvl],
1385     [AS_HELP_STRING([--enable-gallium-g3dvl],
1386         [build gallium g3dvl @<:@default=disabled@:>@])],
1387     [enable_gallium_g3dvl="$enableval"],
1388     [enable_gallium_g3dvl=no])
1389 if test "x$enable_gallium_g3dvl" = xyes; then
1390     if test "x$with_gallium_drivers" = x; then
1391         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1392     fi
1393
1394     if test "x$enable_xvmc" = xauto; then
1395         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1396     fi
1397
1398     if test "x$enable_vdpau" = xauto; then
1399         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1400     fi
1401 fi
1402
1403 if test "x$enable_xvmc" = xyes; then
1404     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1405     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1406     HAVE_ST_XVMC="yes"
1407 fi
1408
1409 if test "x$enable_vdpau" = xyes; then
1410     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1411     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1412     HAVE_ST_VDPAU="yes"
1413 fi
1414
1415 dnl
1416 dnl OpenCL configuration
1417 dnl
1418
1419 AC_ARG_WITH([libclc-path],
1420    [AS_HELP_STRING([--with-libclc-path],
1421          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1422    [LIBCLC_PATH="$withval"],
1423    [LIBCLC_PATH=""])
1424
1425 if test "x$LIBCLC_PATH" != x; then
1426    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1427                   Please review the updated build instructions for clover:
1428                   http://dri.freedesktop.org/wiki/GalliumCompute])
1429 fi
1430
1431
1432 AC_ARG_WITH([clang-libdir],
1433    [AS_HELP_STRING([--with-clang-libdir],
1434          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1435    [CLANG_LIBDIR="$withval"],
1436    [CLANG_LIBDIR=""])
1437
1438 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1439 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1440 AC_SUBST([LIBCLC_INCLUDEDIR])
1441 AC_SUBST([LIBCLC_LIBEXECDIR])
1442
1443 if test "x$enable_opencl" = xyes; then
1444     if test "x$with_gallium_drivers" = x; then
1445         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1446     fi
1447
1448     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1449         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1450     fi
1451
1452     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1453         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1454     fi
1455
1456     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1457     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1458     enable_gallium_loader=yes
1459 fi
1460
1461 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1462     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1463 fi
1464
1465 dnl
1466 dnl Gallium configuration
1467 dnl
1468 if test "x$with_gallium_drivers" != x; then
1469     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1470 fi
1471 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1472
1473 AC_SUBST([LLVM_BINDIR])
1474 AC_SUBST([LLVM_CFLAGS])
1475 AC_SUBST([LLVM_CPPFLAGS])
1476 AC_SUBST([LLVM_CXXFLAGS])
1477 AC_SUBST([LLVM_LIBDIR])
1478 AC_SUBST([LLVM_LIBS])
1479 AC_SUBST([LLVM_LDFLAGS])
1480 AC_SUBST([LLVM_INCLUDEDIR])
1481 AC_SUBST([LLVM_VERSION])
1482 AC_SUBST([CLANG_RESOURCE_DIR])
1483
1484 case "x$enable_opengl$enable_gles1$enable_gles2" in
1485 x*yes*)
1486     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1487     HAVE_OPENGL=yes
1488     ;;
1489 esac
1490 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1491
1492 AC_SUBST([VG_LIB_DEPS])
1493 AC_SUBST([EGL_CLIENT_APIS])
1494
1495 dnl
1496 dnl EGL Platforms configuration
1497 dnl
1498 AC_ARG_WITH([egl-platforms],
1499     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1500         [comma delimited native platforms libEGL supports, e.g.
1501         "x11,drm" @<:@default=auto@:>@])],
1502     [with_egl_platforms="$withval"],
1503     [if test "x$enable_egl" = xyes; then
1504         with_egl_platforms="x11"
1505     else
1506         with_egl_platforms=""
1507     fi])
1508
1509 EGL_PLATFORMS=""
1510
1511 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1512     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1513 fi
1514
1515 # Do per-EGL platform setups and checks
1516 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1517 for plat in $egl_platforms; do
1518         case "$plat" in
1519         fbdev|null)
1520                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1521                 ;;
1522
1523         wayland)
1524                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1525                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1526
1527                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1528                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1529                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1530                 ;;
1531
1532         x11)
1533                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1534
1535                 if test "x$enable_glx" = xyes; then
1536                         HAVE_EGL_DRIVER_GLX=1
1537                 fi
1538                 ;;
1539
1540         drm)
1541                 test "x$enable_gbm" = "xno" &&
1542                         AC_MSG_ERROR([EGL platform drm needs gbm])
1543                 ;;
1544
1545         android|gdi)
1546                 ;;
1547
1548         *)
1549                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1550                 ;;
1551         esac
1552
1553         case "$plat$have_libudev" in
1554                 waylandno|drmno)
1555                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1556         esac
1557 done
1558
1559 # libEGL wants to default to the first platform specified in
1560 # ./configure.  parse that here.
1561 if test "x$egl_platforms" != "x"; then
1562     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1563     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1564 else
1565     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1566 fi
1567
1568 EGL_PLATFORMS="$egl_platforms"
1569
1570 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1571 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1572 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1573 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1574 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1575
1576 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1577 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1578
1579 AC_SUBST([EGL_NATIVE_PLATFORM])
1580 AC_SUBST([EGL_PLATFORMS])
1581 AC_SUBST([EGL_CFLAGS])
1582
1583 AC_ARG_WITH([egl-driver-dir],
1584     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1585                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1586     [EGL_DRIVER_INSTALL_DIR="$withval"],
1587     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1588 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1589
1590 AC_ARG_WITH([xorg-driver-dir],
1591     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1592                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1593     [XORG_DRIVER_INSTALL_DIR="$withval"],
1594     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1595 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1596
1597 AC_ARG_WITH([max-width],
1598     [AS_HELP_STRING([--with-max-width=N],
1599                     [Maximum framebuffer width (4096)])],
1600     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1601      AS_IF([test "${withval}" -gt "4096"],
1602            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1603 )
1604 AC_ARG_WITH([max-height],
1605     [AS_HELP_STRING([--with-max-height=N],
1606                     [Maximum framebuffer height (4096)])],
1607     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1608      AS_IF([test "${withval}" -gt "4096"],
1609            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1610 )
1611
1612 dnl
1613 dnl Gallium LLVM
1614 dnl
1615 AC_ARG_ENABLE([gallium-llvm],
1616     [AS_HELP_STRING([--enable-gallium-llvm],
1617         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1618     [enable_gallium_llvm="$enableval"],
1619     [enable_gallium_llvm=auto])
1620
1621 AC_ARG_WITH([llvm-shared-libs],
1622     [AS_HELP_STRING([--with-llvm-shared-libs],
1623         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1624     [with_llvm_shared_libs=yes],
1625     [with_llvm_shared_libs=no])
1626
1627 AC_ARG_WITH([llvm-prefix],
1628     [AS_HELP_STRING([--with-llvm-prefix],
1629         [Prefix for LLVM installations in non-standard locations])],
1630     [llvm_prefix="$withval"],
1631     [llvm_prefix=""])
1632
1633
1634 # Call this inside ` ` to get the return value.
1635 # $1 is the llvm-config command with arguments.
1636 strip_unwanted_llvm_flags() {
1637     # Use \> (marks the end of the word)
1638     echo `$1` | sed \
1639         -e 's/-DNDEBUG\>//g' \
1640         -e 's/-pedantic\>//g' \
1641         -e 's/-Wcovered-switch-default\>//g' \
1642         -e 's/-O.\>//g' \
1643         -e 's/-g\>//g' \
1644         -e 's/-Wall\>//g' \
1645         -e 's/-fomit-frame-pointer\>//g'
1646 }
1647
1648
1649 if test "x$with_gallium_drivers" = x; then
1650     enable_gallium_llvm=no
1651 fi
1652 if test "x$enable_gallium_llvm" = xauto; then
1653     case "$host_cpu" in
1654     i*86|x86_64) enable_gallium_llvm=yes;;
1655     esac
1656 fi
1657 if test "x$enable_gallium_llvm" = xyes; then
1658     if test "x$llvm_prefix" != x; then
1659         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1660     else
1661         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1662     fi
1663
1664     if test "x$LLVM_CONFIG" != xno; then
1665         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1666         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1667         if test "x$with_llvm_shared_libs" = xyes; then
1668             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1669             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1670         else
1671             LLVM_COMPONENTS="engine bitwriter"
1672             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1673                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1674             fi
1675
1676             if test "x$enable_opencl" = xyes; then
1677                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1678             fi
1679             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1680         fi
1681         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1682         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1683         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1684         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1685         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1686         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1687         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1688         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1689         MESA_LLVM=1
1690
1691         dnl Check for Clang interanl headers
1692         if test "x$enable_opencl" = xyes; then
1693             if test "x$CLANG_LIBDIR" = x; then
1694                 CLANG_LIBDIR=${LLVM_LIBDIR}
1695             fi
1696             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1697             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1698                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1699         fi
1700     else
1701         MESA_LLVM=0
1702         LLVM_VERSION_INT=0
1703     fi
1704 else
1705     MESA_LLVM=0
1706     LLVM_VERSION_INT=0
1707 fi
1708
1709 dnl Directory for XVMC libs
1710 AC_ARG_WITH([xvmc-libdir],
1711     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1712         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1713     [XVMC_LIB_INSTALL_DIR="$withval"],
1714     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1715 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1716
1717 dnl
1718 dnl Gallium Tests
1719 dnl
1720 if test "x$enable_gallium_tests" = xyes; then
1721     SRC_DIRS="$SRC_DIRS gallium/tests/trivial gallium/tests/unit"
1722     enable_gallium_loader=yes
1723 fi
1724
1725 dnl Directory for VDPAU libs
1726 AC_ARG_WITH([vdpau-libdir],
1727     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1728         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1729     [VDPAU_LIB_INSTALL_DIR="$withval"],
1730     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1731 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1732
1733 dnl Directory for OpenCL libs
1734 AC_ARG_WITH([opencl-libdir],
1735     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1736         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1737     [OPENCL_LIB_INSTALL_DIR="$withval"],
1738     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1739 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1740
1741 dnl
1742 dnl Gallium helper functions
1743 dnl
1744 gallium_check_st() {
1745     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1746          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1747          test "x$HAVE_ST_VDPAU" = xyes; then
1748          if test "x$have_libdrm" != xyes; then
1749             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1750          fi
1751          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1752     fi
1753     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1754          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1755     fi
1756     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1757          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1758     fi
1759     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1760          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1761     fi
1762     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1763          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1764     fi
1765     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1766          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1767     fi
1768 }
1769
1770 gallium_require_llvm() {
1771     if test "x$MESA_LLVM" = x0; then
1772         case "$host_cpu" in
1773         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1774         esac
1775     fi
1776 }
1777
1778 gallium_require_drm_loader() {
1779     if test "x$enable_gallium_loader" = xyes; then
1780         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1781                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1782         if test "x$have_libdrm" != xyes; then
1783             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1784         fi
1785         enable_gallium_drm_loader=yes
1786     fi
1787 }
1788
1789 radeon_llvm_check() {
1790     LLVM_REQUIRED_VERSION_MAJOR="3"
1791     LLVM_REQUIRED_VERSION_MINOR="2"
1792     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1793         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1794                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1795                      git://people.freedesktop.org/~tstellar/llvm master
1796                      and build with --enable-experimental-targets=R600])
1797     fi
1798     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1799         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1800                       sources with the --enable-experimental-targets=R600
1801                       configure flag])
1802     fi
1803     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1804     LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --libs r600`"
1805 }
1806
1807 dnl Gallium drivers
1808 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1809 if test "x$with_gallium_drivers" != x; then
1810     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1811     for driver in $gallium_drivers; do
1812         case "x$driver" in
1813         xsvga)
1814             HAVE_GALLIUM_SVGA=yes
1815             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1816             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1817             ;;
1818         xi915)
1819             HAVE_GALLIUM_I915=yes
1820             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1821             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1822             if test "x$MESA_LLVM" = x1; then
1823                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1824             fi
1825             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1826             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1827             ;;
1828         xr300)
1829             HAVE_GALLIUM_R300=yes
1830             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1831             gallium_require_llvm "Gallium R300"
1832             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1833             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300"
1834             ;;
1835         xr600)
1836             HAVE_GALLIUM_R600=yes
1837             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1838             gallium_require_drm_loader
1839             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1840             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1841                 radeon_llvm_check
1842                 NEED_RADEON_GALLIUM=yes;
1843             fi
1844             if test "x$enable_r600_llvm" = xyes; then
1845                 USE_R600_LLVM_COMPILER=yes;
1846             fi
1847             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1848                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1849             fi
1850             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1851             ;;
1852         xradeonsi)
1853             HAVE_GALLIUM_RADEONSI=yes
1854             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1855             gallium_require_drm_loader
1856             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1857             radeon_llvm_check
1858             NEED_RADEON_GALLIUM=yes;
1859             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1860             ;;
1861         xnouveau)
1862             HAVE_GALLIUM_NOUVEAU=yes
1863             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1864             gallium_require_drm_loader
1865             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1866             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1867             ;;
1868         xswrast)
1869             HAVE_GALLIUM_SOFTPIPE=yes
1870             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1871             if test "x$MESA_LLVM" = x1; then
1872                 HAVE_GALLIUM_LLVMPIPE=yes
1873                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1874             fi
1875
1876             if test "x$HAVE_ST_DRI" = xyes; then
1877                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1878             fi
1879             if test "x$HAVE_ST_VDPAU" = xyes; then
1880                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1881             fi
1882             if test "x$HAVE_ST_XVMC" = xyes; then
1883                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1884             fi
1885             if test "x$HAVE_ST_VDPAU" = xyes ||
1886                test "x$HAVE_ST_XVMC" = xyes; then
1887                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1888                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1889                fi
1890             fi
1891             ;;
1892         *)
1893             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1894             ;;
1895         esac
1896     done
1897 fi
1898 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1899 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1900 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1901 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1902 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1903 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1904 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1905 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1906
1907 if test "x$enable_gallium_loader" = xyes; then
1908     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1909     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1910     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1911     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1912
1913     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1914         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1915         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1916     fi
1917
1918     if test "x$enable_gallium_drm_loader" = xyes; then
1919         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1920         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1921                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1922         if test "x$pipe_loader_have_xcb" = xyes; then
1923             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1924             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1925         fi
1926     fi
1927
1928     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1929     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1930 fi
1931
1932 dnl Tell Automake which drivers to build
1933 for driver in $GALLIUM_DRIVERS_DIRS; do
1934     case "x$driver" in
1935         xgalahad)
1936             HAVE_GALAHAD_GALLIUM=yes;
1937             ;;
1938         xidentity)
1939             HAVE_IDENTITY_GALLIUM=yes;
1940             ;;
1941         xnoop)
1942             HAVE_NOOP_GALLIUM=yes;
1943             ;;
1944         *)
1945             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1946             ;;
1947     esac
1948 done
1949
1950 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1951 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1952 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1953 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1954 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1955 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1956 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1957 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1958 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1959 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1960
1961 AC_SUBST([GALLIUM_MAKE_DIRS])
1962
1963 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1964                                      "x$enable_xlib_glx" = xyes -o \
1965                                      "x$enable_osmesa" = xyes)
1966 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1967
1968 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1969 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1970 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1971
1972 AC_SUBST([VDPAU_MAJOR], 1)
1973 AC_SUBST([VDPAU_MINOR], 0)
1974
1975 AC_SUBST([XVMC_MAJOR], 1)
1976 AC_SUBST([XVMC_MINOR], 0)
1977
1978 AC_SUBST([XA_MAJOR], 1)
1979 AC_SUBST([XA_MINOR], 0)
1980 AC_SUBST([XA_TINY], 0)
1981 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1982
1983 dnl prepend CORE_DIRS to SRC_DIRS
1984 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1985
1986 dnl Restore LDFLAGS and CPPFLAGS
1987 LDFLAGS="$_SAVE_LDFLAGS"
1988 CPPFLAGS="$_SAVE_CPPFLAGS"
1989
1990 dnl Add user CFLAGS and CXXFLAGS
1991 CFLAGS="$CFLAGS $USER_CFLAGS"
1992 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1993
1994 dnl Substitute the config
1995 AC_CONFIG_FILES([Makefile
1996                 src/Makefile
1997                 src/egl/Makefile
1998                 src/egl/drivers/Makefile
1999                 src/egl/drivers/dri2/Makefile
2000                 src/egl/drivers/glx/Makefile
2001                 src/egl/main/Makefile
2002                 src/egl/main/egl.pc
2003                 src/egl/wayland/Makefile
2004                 src/egl/wayland/wayland-drm/Makefile
2005                 src/egl/wayland/wayland-egl/Makefile
2006                 src/egl/wayland/wayland-egl/wayland-egl.pc
2007                 src/gallium/Makefile
2008                 src/gallium/auxiliary/Makefile
2009                 src/gallium/auxiliary/pipe-loader/Makefile
2010                 src/gallium/drivers/Makefile
2011                 src/gallium/drivers/i915/Makefile
2012                 src/gallium/drivers/llvmpipe/Makefile
2013                 src/gallium/drivers/nouveau/Makefile
2014                 src/gallium/drivers/nv30/Makefile
2015                 src/gallium/drivers/nv50/Makefile
2016                 src/gallium/drivers/nvc0/Makefile
2017                 src/gallium/drivers/r300/Makefile
2018                 src/gallium/drivers/r600/Makefile
2019                 src/gallium/drivers/radeon/Makefile
2020                 src/gallium/drivers/radeonsi/Makefile
2021                 src/gallium/drivers/rbug/Makefile
2022                 src/gallium/drivers/softpipe/Makefile
2023                 src/gallium/drivers/svga/Makefile
2024                 src/gallium/drivers/trace/Makefile
2025                 src/gallium/state_trackers/Makefile
2026                 src/gallium/state_trackers/clover/Makefile
2027                 src/gallium/state_trackers/dri/Makefile
2028                 src/gallium/state_trackers/dri/drm/Makefile
2029                 src/gallium/state_trackers/dri/sw/Makefile
2030                 src/gallium/state_trackers/egl/Makefile
2031                 src/gallium/state_trackers/gbm/Makefile
2032                 src/gallium/state_trackers/glx/Makefile
2033                 src/gallium/state_trackers/vdpau/Makefile
2034                 src/gallium/state_trackers/vega/Makefile
2035                 src/gallium/state_trackers/xa/Makefile
2036                 src/gallium/state_trackers/xorg/Makefile
2037                 src/gallium/state_trackers/xvmc/Makefile
2038                 src/gallium/targets/Makefile
2039                 src/gallium/targets/dri-i915/Makefile
2040                 src/gallium/targets/dri-nouveau/Makefile
2041                 src/gallium/targets/dri-r300/Makefile
2042                 src/gallium/targets/dri-r600/Makefile
2043                 src/gallium/targets/dri-radeonsi/Makefile
2044                 src/gallium/targets/dri-swrast/Makefile
2045                 src/gallium/targets/dri-vmwgfx/Makefile
2046                 src/gallium/targets/egl-static/Makefile
2047                 src/gallium/targets/gbm/Makefile
2048                 src/gallium/targets/opencl/Makefile
2049                 src/gallium/targets/pipe-loader/Makefile
2050                 src/gallium/targets/libgl-xlib/Makefile
2051                 src/gallium/targets/vdpau-nouveau/Makefile
2052                 src/gallium/targets/vdpau-r300/Makefile
2053                 src/gallium/targets/vdpau-r600/Makefile
2054                 src/gallium/targets/vdpau-radeonsi/Makefile
2055                 src/gallium/targets/vdpau-softpipe/Makefile
2056                 src/gallium/targets/xa-vmwgfx/Makefile
2057                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2058                 src/gallium/targets/xorg-i915/Makefile
2059                 src/gallium/targets/xorg-nouveau/Makefile
2060                 src/gallium/targets/xorg-r300/Makefile
2061                 src/gallium/targets/xorg-r600/Makefile
2062                 src/gallium/targets/xorg-radeonsi/Makefile
2063                 src/gallium/targets/xvmc-nouveau/Makefile
2064                 src/gallium/targets/xvmc-r300/Makefile
2065                 src/gallium/targets/xvmc-r600/Makefile
2066                 src/gallium/targets/xvmc-softpipe/Makefile
2067                 src/gallium/tests/trivial/Makefile
2068                 src/gallium/tests/unit/Makefile
2069                 src/gallium/winsys/Makefile
2070                 src/gallium/winsys/i915/drm/Makefile
2071                 src/gallium/winsys/i915/sw/Makefile
2072                 src/gallium/winsys/nouveau/drm/Makefile
2073                 src/gallium/winsys/radeon/drm/Makefile
2074                 src/gallium/winsys/svga/drm/Makefile
2075                 src/gallium/winsys/sw/Makefile
2076                 src/gallium/winsys/sw/dri/Makefile
2077                 src/gallium/winsys/sw/fbdev/Makefile
2078                 src/gallium/winsys/sw/null/Makefile
2079                 src/gallium/winsys/sw/wayland/Makefile
2080                 src/gallium/winsys/sw/wrapper/Makefile
2081                 src/gallium/winsys/sw/xlib/Makefile
2082                 src/gbm/Makefile
2083                 src/gbm/main/gbm.pc
2084                 src/glsl/Makefile
2085                 src/glsl/builtin_compiler/Makefile
2086                 src/glsl/glcpp/Makefile
2087                 src/glsl/tests/Makefile
2088                 src/glx/Makefile
2089                 src/glx/tests/Makefile
2090                 src/gtest/Makefile
2091                 src/mapi/es1api/Makefile
2092                 src/mapi/es1api/glesv1_cm.pc
2093                 src/mapi/es2api/Makefile
2094                 src/mapi/es2api/glesv2.pc
2095                 src/mapi/glapi/Makefile
2096                 src/mapi/glapi/gen/Makefile
2097                 src/mapi/glapi/tests/Makefile
2098                 src/mapi/shared-glapi/Makefile
2099                 src/mapi/shared-glapi/tests/Makefile
2100                 src/mapi/vgapi/Makefile
2101                 src/mapi/vgapi/vg.pc
2102                 src/mesa/Makefile
2103                 src/mesa/gl.pc
2104                 src/mesa/drivers/Makefile
2105                 src/mesa/drivers/dri/dri.pc
2106                 src/mesa/drivers/dri/common/Makefile
2107                 src/mesa/drivers/dri/i915/Makefile
2108                 src/mesa/drivers/dri/i965/Makefile
2109                 src/mesa/drivers/dri/Makefile
2110                 src/mesa/drivers/dri/nouveau/Makefile
2111                 src/mesa/drivers/dri/r200/Makefile
2112                 src/mesa/drivers/dri/radeon/Makefile
2113                 src/mesa/drivers/dri/swrast/Makefile
2114                 src/mesa/drivers/osmesa/Makefile
2115                 src/mesa/drivers/osmesa/osmesa.pc
2116                 src/mesa/drivers/x11/Makefile
2117                 src/mesa/libdricore/Makefile
2118                 src/mesa/main/tests/Makefile
2119                 src/mesa/main/tests/hash_table/Makefile
2120                 src/mesa/program/Makefile
2121                 src/mesa/x86-64/Makefile
2122                 src/mesa/x86/Makefile])
2123
2124 dnl Sort the dirs alphabetically
2125 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2126 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2127 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2128 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2129 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2130
2131 AC_OUTPUT
2132
2133 dnl
2134 dnl Output some configuration info for the user
2135 dnl
2136 echo ""
2137 echo "        prefix:          $prefix"
2138 echo "        exec_prefix:     $exec_prefix"
2139 echo "        libdir:          $libdir"
2140 echo "        includedir:      $includedir"
2141
2142 dnl API info
2143 echo ""
2144 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2145 echo "        OpenVG:          $enable_openvg"
2146
2147 dnl Driver info
2148 echo ""
2149 if test "x$enable_osmesa" != xno; then
2150         echo "        OSMesa:          lib$OSMESA_LIB"
2151 else
2152         echo "        OSMesa:          no"
2153 fi
2154
2155 if test "x$enable_dri" != xno; then
2156         # cleanup the drivers var
2157         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2158         if test "x$DRI_DIRS" = x; then
2159             echo "        DRI drivers:     no"
2160         else
2161             echo "        DRI drivers:     $dri_dirs"
2162         fi
2163         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2164 fi
2165
2166 case "x$enable_glx$enable_xlib_glx" in
2167 xyesyes)
2168     echo "        GLX:             Xlib-based"
2169     ;;
2170 xyesno)
2171     echo "        GLX:             DRI-based"
2172     ;;
2173 *)
2174     echo "        GLX:             $enable_glx"
2175     ;;
2176 esac
2177
2178 dnl EGL
2179 echo ""
2180 echo "        EGL:             $enable_egl"
2181 if test "$enable_egl" = yes; then
2182     echo "        EGL platforms:   $EGL_PLATFORMS"
2183
2184     egl_drivers=""
2185     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2186         egl_drivers="$egl_drivers builtin:egl_glx"
2187     fi
2188     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2189         egl_drivers="$egl_drivers builtin:egl_dri2"
2190     fi
2191
2192     if test "x$HAVE_ST_EGL" = xyes; then
2193         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2194         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2195     else
2196         echo "        EGL drivers:    $egl_drivers"
2197     fi
2198 fi
2199
2200 echo ""
2201 if test "x$MESA_LLVM" = x1; then
2202     echo "        llvm:            yes"
2203     echo "        llvm-config:     $LLVM_CONFIG"
2204     echo "        llvm-version:    $LLVM_VERSION"
2205 else
2206     echo "        llvm:            no"
2207 fi
2208
2209 echo ""
2210 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2211     echo "        Gallium:         yes"
2212     echo "        Gallium dirs:    $GALLIUM_DIRS"
2213     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2214     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2215     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2216     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2217 else
2218     echo "        Gallium:         no"
2219 fi
2220
2221
2222 dnl Libraries
2223 echo ""
2224 echo "        Shared libs:     $enable_shared"
2225 echo "        Static libs:     $enable_static"
2226 echo "        Shared-glapi:    $enable_shared_glapi"
2227
2228 dnl Compiler options
2229 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2230 cflags=`echo $CFLAGS | \
2231     $SED 's/^ *//;s/  */ /;s/ *$//'`
2232 cxxflags=`echo $CXXFLAGS | \
2233     $SED 's/^ *//;s/  */ /;s/ *$//'`
2234 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2235 echo ""
2236 echo "        CFLAGS:          $cflags"
2237 echo "        CXXFLAGS:        $cxxflags"
2238 echo "        Macros:          $defines"
2239 echo ""
2240 if test "x$MESA_LLVM" = x1; then
2241     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2242     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2243     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2244     echo ""
2245 fi
2246 echo "        PYTHON2:         $PYTHON2"
2247
2248 echo ""
2249 echo "        Run '${MAKE-make}' to build Mesa"
2250 echo ""