configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.88
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.9.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 dnl add this here, so the help for this environmnet variable is close to
 115 dnl other CC/CXX flags related help
 116 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 117                               enabled by default and different  from -std=c++11)])
 118 AM_PROG_CC_C_O
 119 AM_PROG_AS
 120 AX_CHECK_GNU_MAKE
 121 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 122 AC_PROG_SED
 123 AC_PROG_MKDIR_P
 124
 125 AC_SYS_LARGEFILE
 126
 127
 128 LT_PREREQ([2.2])
 129 LT_INIT([disable-static])
 130
 131 AC_CHECK_PROG(RM, rm, [rm -f])
 132
 133 AX_PROG_BISON([],
 134               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 135                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 136 AX_PROG_FLEX([],
 137              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 138                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 139
 140 AC_CHECK_PROG(INDENT, indent, indent, cat)
 141 if test "x$INDENT" != "xcat"; then
 142     # Only GNU indent is supported
 143     INDENT_VERSION=`indent --version | grep GNU`
 144     if test $? -eq 0; then
 145        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 146     else
 147        INDENT="cat"
 148     fi
 149 fi
 150
 151 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 152
 153 if test -z "$PYTHON2"; then
 154     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 155         AC_MSG_ERROR([Python not found - unable to generate sources])
 156     fi
 157 else
 158     if test "x$acv_mako_found" = xno; then
 159         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 160             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 161         fi
 162     fi
 163 fi
 164
 165 AC_PROG_INSTALL
 166
 167 dnl We need a POSIX shell for parts of the build. Assume we have one
 168 dnl in most cases.
 169 case "$host_os" in
 170 solaris*)
 171     # Solaris /bin/sh is too old/non-POSIX compliant
 172     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 173     SHELL="$POSIX_SHELL"
 174     ;;
 175 esac
 176
 177 dnl clang is mostly GCC-compatible, but its version is much lower,
 178 dnl so we have to check for it.
 179 AC_MSG_CHECKING([if compiling with clang])
 180
 181 AC_COMPILE_IFELSE(
 182 [AC_LANG_PROGRAM([], [[
 183 #ifndef __clang__
 184        not clang
 185 #endif
 186 ]])],
 187 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 188
 189 AC_MSG_RESULT([$acv_mesa_CLANG])
 190
 191 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 192 dnl versions are explictly not supported.
 193 GEN_ASM_OFFSETS=no
 194 USE_GNU99=no
 195 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 196     AC_MSG_CHECKING([whether gcc version is sufficient])
 197     major=0
 198     minor=0
 199
 200     GCC_VERSION=`$CC -dumpversion`
 201     if test $? -eq 0; then
 202         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 203         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 204     fi
 205
 206     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 207         AC_MSG_RESULT([no])
 208         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 209     else
 210         AC_MSG_RESULT([yes])
 211     fi
 212
 213     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 214         USE_GNU99=yes
 215     fi
 216     if test "x$cross_compiling" = xyes; then
 217         GEN_ASM_OFFSETS=yes
 218     fi
 219 fi
 220
 221 dnl We don't support building Mesa with Sun C compiler
 222 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 223 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 224 if test "x$SUNCC" = xyes; then
 225     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 226 fi
 227
 228 dnl Check for compiler builtins
 229 AX_GCC_BUILTIN([__builtin_bswap32])
 230 AX_GCC_BUILTIN([__builtin_bswap64])
 231 AX_GCC_BUILTIN([__builtin_clz])
 232 AX_GCC_BUILTIN([__builtin_clzll])
 233 AX_GCC_BUILTIN([__builtin_ctz])
 234 AX_GCC_BUILTIN([__builtin_expect])
 235 AX_GCC_BUILTIN([__builtin_ffs])
 236 AX_GCC_BUILTIN([__builtin_ffsll])
 237 AX_GCC_BUILTIN([__builtin_popcount])
 238 AX_GCC_BUILTIN([__builtin_popcountll])
 239 AX_GCC_BUILTIN([__builtin_unreachable])
 240
 241 AX_GCC_FUNC_ATTRIBUTE([const])
 242 AX_GCC_FUNC_ATTRIBUTE([flatten])
 243 AX_GCC_FUNC_ATTRIBUTE([format])
 244 AX_GCC_FUNC_ATTRIBUTE([malloc])
 245 AX_GCC_FUNC_ATTRIBUTE([packed])
 246 AX_GCC_FUNC_ATTRIBUTE([pure])
 247 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 248 AX_GCC_FUNC_ATTRIBUTE([unused])
 249 AX_GCC_FUNC_ATTRIBUTE([visibility])
 250 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 251 AX_GCC_FUNC_ATTRIBUTE([weak])
 252 AX_GCC_FUNC_ATTRIBUTE([alias])
 253
 254 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 255
 256 dnl Make sure the pkg-config macros are defined
 257 m4_ifndef([PKG_PROG_PKG_CONFIG],
 258     [m4_fatal([Could not locate the pkg-config autoconf macros.
 259   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 260   are in a different location, try setting the environment variable
 261   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 262 PKG_PROG_PKG_CONFIG()
 263
 264 dnl LIB_DIR - library basename
 265 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 266 AC_SUBST([LIB_DIR])
 267
 268 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 269 _SAVE_LDFLAGS="$LDFLAGS"
 270 _SAVE_CPPFLAGS="$CPPFLAGS"
 271
 272 dnl Compiler macros
 273 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 274 AC_SUBST([DEFINES])
 275 android=no
 276 case "$host_os" in
 277 *-android*)
 278     android=yes
 279     ;;
 280 linux*|*-gnu*|gnu*|cygwin*)
 281     DEFINES="$DEFINES -D_GNU_SOURCE"
 282     ;;
 283 solaris*)
 284     DEFINES="$DEFINES -DSVR4"
 285     ;;
 286 esac
 287
 288 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 289
 290 dnl
 291 dnl Check compiler flags
 292 dnl
 293 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 294 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 295 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 296 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 297 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 298 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 299 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 300
 301 dnl
 302 dnl Check C++ compiler flags
 303 dnl
 304 AC_LANG_PUSH([C++])
 305 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 306 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 307 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 308 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 309 AC_LANG_POP([C++])
 310
 311 # Flags to help ensure that certain portions of the code -- and only those
 312 # portions -- can be built with MSVC:
 313 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 314 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 315 #   supports most of C99)
 316 # - the rest has no compiler compiler restrictions
 317 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 318 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 319 AC_LANG_PUSH([C++])
 320 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 321 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 322 AC_LANG_POP([C++])
 323
 324 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 325 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 326
 327 if test "x$GCC" = xyes; then
 328     if test "x$USE_GNU99" = xyes; then
 329         CFLAGS="$CFLAGS -std=gnu99"
 330     else
 331         CFLAGS="$CFLAGS -std=c99"
 332     fi
 333 fi
 334
 335 dnl
 336 dnl Check whether C++11 is supported, if the environment variable
 337 dnl CXX11_CXXFLAGS is set it takes precedence.
 338 dnl
 339
 340 AC_LANG_PUSH([C++])
 341
 342 check_cxx11_available() {
 343     output_support=$1
 344     AC_COMPILE_IFELSE(
 345         [AC_LANG_PROGRAM([
 346              #if !(__cplusplus >= 201103L)
 347              #error
 348              #endif
 349              #include <tuple>
 350         ])
 351     ], [
 352          AC_MSG_RESULT(yes)
 353          cxx11_support=yes
 354     ], AC_MSG_RESULT(no))
 355     eval "$output_support=\$cxx11_support"
 356 }
 357
 358 HAVE_CXX11=no
 359 save_CXXFLAGS="$CXXFLAGS"
 360
 361 dnl If the user provides a flag to enable c++11, then we test only this
 362 if test "x$CXX11_CXXFLAGS" != "x"; then
 363    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 364    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 365    check_cxx11_available HAVE_CXX11
 366 else
 367    dnl test whether c++11 is enabled by default
 368    AC_MSG_CHECKING(whether c++11 is enabled by default)
 369    check_cxx11_available HAVE_CXX11
 370
 371    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 372    if test "x$HAVE_CXX11" != "xyes"; then
 373        CXX11_CXXFLAGS=-std=c++11
 374        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 375        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 376        check_cxx11_available HAVE_CXX11
 377    fi
 378 fi
 379
 380 CXXFLAGS="$save_CXXFLAGS"
 381 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 382 AC_SUBST(CXX11_CXXFLAGS)
 383 AC_LANG_POP([C++])
 384
 385 dnl even if the compiler appears to support it, using visibility attributes isn't
 386 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 387 case "$host_os" in
 388 cygwin*)
 389     VISIBILITY_CFLAGS=""
 390     VISIBILITY_CXXFLAGS=""
 391     ;;
 392 esac
 393
 394 AC_SUBST([VISIBILITY_CFLAGS])
 395 AC_SUBST([VISIBILITY_CXXFLAGS])
 396
 397 AX_CHECK_COMPILE_FLAG([-Wno-override-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 398 AX_CHECK_COMPILE_FLAG([-Wno-initializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 399 AC_SUBST([WNO_OVERRIDE_INIT])
 400
 401 dnl
 402 dnl Optional flags, check for compiler support
 403 dnl
 404 SSE41_CFLAGS="-msse4.1"
 405 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 406 dnl stack, but on x86-32 such alignment is not guaranteed.
 407 case "$target_cpu" in
 408 i?86)
 409     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 410     ;;
 411 esac
 412 save_CFLAGS="$CFLAGS"
 413 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 414 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 415 #include <smmintrin.h>
 416 int param;
 417 int main () {
 418     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 419     c = _mm_max_epu32(a, b);
 420     return _mm_cvtsi128_si32(c);
 421 }]])], SSE41_SUPPORTED=1)
 422 CFLAGS="$save_CFLAGS"
 423 if test "x$SSE41_SUPPORTED" = x1; then
 424     DEFINES="$DEFINES -DUSE_SSE41"
 425 fi
 426 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 427 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 428
 429 dnl Check for new-style atomic builtins
 430 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 431 int main() {
 432     int n;
 433     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 434 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 435 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 436     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 437     dnl On some platforms, new-style atomics need a helper library
 438     AC_MSG_CHECKING(whether -latomic is needed)
 439     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 440     #include <stdint.h>
 441     uint64_t v;
 442     int main() {
 443         return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
 444     }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
 445     AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
 446     if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
 447         LIBATOMIC_LIBS="-latomic"
 448     fi
 449 fi
 450 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 451 AC_SUBST([LIBATOMIC_LIBS])
 452
 453 dnl Check if host supports 64-bit atomics
 454 dnl note that lack of support usually results in link (not compile) error
 455 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 456 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 457 #include <stdint.h>
 458 uint64_t v;
 459 int main() {
 460     return __sync_add_and_fetch(&v, (uint64_t)1);
 461 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 462 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 463     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 464 fi
 465 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 466
 467 dnl Check for Endianness
 468 AC_C_BIGENDIAN(
 469    little_endian=no,
 470    little_endian=yes,
 471    little_endian=no,
 472    little_endian=no
 473 )
 474
 475 dnl Check for POWER8 Architecture
 476 PWR8_CFLAGS="-mpower8-vector"
 477 have_pwr8_intrinsics=no
 478 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 479 save_CFLAGS=$CFLAGS
 480 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 481 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 482 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 483 #error "Need GCC >= 4.8 for sane POWER8 support"
 484 #endif
 485 #include <altivec.h>
 486 int main () {
 487     vector unsigned char r;
 488     vector unsigned int v = vec_splat_u32 (1);
 489     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 490     return 0;
 491 }]])], have_pwr8_intrinsics=yes)
 492 CFLAGS=$save_CFLAGS
 493
 494 AC_ARG_ENABLE(pwr8,
 495    [AS_HELP_STRING([--disable-pwr8],
 496                    [disable POWER8-specific instructions])],
 497    [enable_pwr8=$enableval], [enable_pwr8=auto])
 498
 499 if test "x$enable_pwr8" = xno ; then
 500    have_pwr8_intrinsics=disabled
 501 fi
 502
 503 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 504    DEFINES="$DEFINES -D_ARCH_PWR8"
 505    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 506    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 507 else
 508    PWR8_CFLAGS=
 509 fi
 510
 511 AC_MSG_RESULT($have_pwr8_intrinsics)
 512 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 513    AC_MSG_ERROR([POWER8 compiler support not detected])
 514 fi
 515
 516 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 517    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 518 fi
 519
 520 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 521
 522 dnl Can't have static and shared libraries, default to static if user
 523 dnl explicitly requested. If both disabled, set to static since shared
 524 dnl was explicitly requested.
 525 case "x$enable_static$enable_shared" in
 526 xyesyes)
 527     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 528     ;;
 529 xnono)
 530     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 531     ;;
 532 esac
 533
 534 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 535
 536 dnl
 537 dnl other compiler options
 538 dnl
 539 AC_ARG_ENABLE([debug],
 540     [AS_HELP_STRING([--enable-debug],
 541         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 542     [enable_debug="$enableval"],
 543     [enable_debug=no]
 544 )
 545
 546 AC_ARG_ENABLE([profile],
 547     [AS_HELP_STRING([--enable-profile],
 548         [enable profiling of code @<:@default=disabled@:>@])],
 549     [enable_profile="$enableval"],
 550     [enable_profile=no]
 551 )
 552
 553 AC_ARG_ENABLE([sanitize],
 554     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 555         [enable code sanitizer @<:@default=disabled@:>@])],
 556     [enable_sanitize="$enableval"],
 557     [enable_sanitize=no])
 558
 559 if test "x$enable_profile" = xyes; then
 560     DEFINES="$DEFINES -DPROFILE"
 561     if test "x$GCC" = xyes; then
 562         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 563     fi
 564     if test "x$GXX" = xyes; then
 565         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 566     fi
 567 fi
 568
 569 if test "x$enable_debug" = xyes; then
 570     DEFINES="$DEFINES -DDEBUG"
 571     if test "x$enable_profile" = xyes; then
 572         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 573     fi
 574     if test "x$GCC" = xyes; then
 575         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 576             CFLAGS="$CFLAGS -g"
 577         fi
 578         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 579             CFLAGS="$CFLAGS -O0"
 580         fi
 581     fi
 582     if test "x$GXX" = xyes; then
 583         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 584             CXXFLAGS="$CXXFLAGS -g"
 585         fi
 586         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 587             CXXFLAGS="$CXXFLAGS -O0"
 588         fi
 589     fi
 590 else
 591    DEFINES="$DEFINES -DNDEBUG"
 592 fi
 593
 594 if test "x$enable_sanitize" != xno; then
 595     if test "x$enable_profile" = xyes; then
 596         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 597     fi
 598
 599     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 600     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 601     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 602
 603     AC_LINK_IFELSE(
 604         [AC_LANG_SOURCE([int main(){return 0;}])],
 605         [],
 606         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 607 fi
 608
 609 dnl
 610 dnl Check if linker supports -Bsymbolic
 611 dnl
 612 save_LDFLAGS=$LDFLAGS
 613 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 614 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 615 AC_LINK_IFELSE(
 616     [AC_LANG_SOURCE([int main() { return 0;}])],
 617     [AC_MSG_RESULT([yes])
 618         BSYMBOLIC="-Wl,-Bsymbolic";],
 619     [AC_MSG_RESULT([no])
 620         BSYMBOLIC="";])
 621 LDFLAGS=$save_LDFLAGS
 622
 623 AC_SUBST([BSYMBOLIC])
 624
 625 dnl
 626 dnl Check if linker supports garbage collection
 627 dnl
 628 save_LDFLAGS=$LDFLAGS
 629 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 630 AC_MSG_CHECKING([whether ld supports --gc-sections])
 631 AC_LINK_IFELSE(
 632     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 633     [AC_MSG_RESULT([yes])
 634         GC_SECTIONS="-Wl,--gc-sections";],
 635     [AC_MSG_RESULT([no])
 636         GC_SECTIONS="";])
 637 LDFLAGS=$save_LDFLAGS
 638
 639 AC_SUBST([GC_SECTIONS])
 640
 641 dnl
 642 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 643 dnl so when these flags are passed to ld via libtool the checks will fail
 644 dnl
 645 case "$host_os" in
 646 openbsd* | darwin* )
 647     LD_NO_UNDEFINED="" ;;
 648 *)
 649     if test "x$enable_sanitize" = xno; then
 650         LD_NO_UNDEFINED="-Wl,--no-undefined"
 651     else
 652         LD_NO_UNDEFINED=""
 653     fi
 654     ;;
 655 esac
 656
 657 AC_SUBST([LD_NO_UNDEFINED])
 658
 659 dnl
 660 dnl Check if linker supports version scripts
 661 dnl
 662 AC_MSG_CHECKING([if the linker supports version-scripts])
 663 save_LDFLAGS=$LDFLAGS
 664 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 665 AC_LINK_IFELSE(
 666     [AC_LANG_SOURCE([int main() { return 0;}])],
 667     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 668     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 669 LDFLAGS=$save_LDFLAGS
 670 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 671
 672 dnl
 673 dnl Check if linker supports dynamic list files
 674 dnl
 675 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 676 save_LDFLAGS=$LDFLAGS
 677 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 678 AC_LINK_IFELSE(
 679     [AC_LANG_SOURCE([int main() { return 0;}])],
 680     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 681     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 682 LDFLAGS=$save_LDFLAGS
 683 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 684
 685 dnl
 686 dnl compatibility symlinks
 687 dnl
 688 case "$host_os" in
 689 linux* )
 690     HAVE_COMPAT_SYMLINKS=yes ;;
 691 * )
 692     HAVE_COMPAT_SYMLINKS=no ;;
 693 esac
 694
 695 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 696
 697 dnl
 698 dnl library names
 699 dnl
 700 dnl Unfortunately we need to do a few things that libtool can't help us with,
 701 dnl so we need some knowledge of shared library filenames:
 702 dnl
 703 dnl LIB_EXT is the extension used when creating symlinks for alternate
 704 dnl filenames for a shared library which will be dynamically loaded
 705 dnl
 706 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 707 dnl the file for a shared library we wish to link with
 708 dnl
 709 case "$host_os" in
 710 darwin* )
 711     LIB_EXT='dylib'
 712     IMP_LIB_EXT=$LIB_EXT
 713     ;;
 714 cygwin* )
 715     LIB_EXT='dll'
 716     IMP_LIB_EXT='dll.a'
 717     ;;
 718 aix* )
 719     LIB_EXT='a'
 720     IMP_LIB_EXT=$LIB_EXT
 721     ;;
 722 * )
 723     LIB_EXT='so'
 724     IMP_LIB_EXT=$LIB_EXT
 725     ;;
 726 esac
 727
 728 AC_SUBST([LIB_EXT])
 729
 730 dnl
 731 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 732 dnl
 733 AC_ARG_ENABLE([texture-float],
 734     [AS_HELP_STRING([--enable-texture-float],
 735         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 736     [enable_texture_float="$enableval"],
 737     [enable_texture_float=no]
 738 )
 739 if test "x$enable_texture_float" = xyes; then
 740     AC_MSG_WARN([Floating-point textures enabled.])
 741     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 742     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 743 fi
 744
 745 dnl
 746 dnl Arch/platform-specific settings
 747 dnl
 748 AC_ARG_ENABLE([asm],
 749     [AS_HELP_STRING([--disable-asm],
 750         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 751     [enable_asm="$enableval"],
 752     [enable_asm=yes]
 753 )
 754 asm_arch=""
 755 AC_MSG_CHECKING([whether to enable assembly])
 756 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 757 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 758 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 759     case "$host_cpu" in
 760     i?86 | x86_64 | amd64)
 761         if test "x$host_cpu" != "x$target_cpu"; then
 762             enable_asm=no
 763             AC_MSG_RESULT([no, cross compiling])
 764         fi
 765         ;;
 766     esac
 767 fi
 768 # check for supported arches
 769 if test "x$enable_asm" = xyes; then
 770     case "$host_cpu" in
 771     i?86)
 772         case "$host_os" in
 773         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 774             asm_arch=x86
 775             ;;
 776         esac
 777         ;;
 778     x86_64|amd64)
 779         case "$host_os" in
 780         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 781             asm_arch=x86_64
 782             ;;
 783         esac
 784         ;;
 785     sparc*)
 786         case "$host_os" in
 787         linux*)
 788             asm_arch=sparc
 789             ;;
 790         esac
 791         ;;
 792     powerpc64le)
 793         case "$host_os" in
 794         linux*)
 795             asm_arch=ppc64le
 796             ;;
 797         esac
 798         ;;
 799     aarch64)
 800         case "$host_os" in
 801         linux*)
 802             asm_arch=aarch64
 803             ;;
 804         esac
 805         ;;
 806     arm)
 807         case "$host_os" in
 808         linux*)
 809             asm_arch=arm
 810             ;;
 811         esac
 812         ;;
 813     esac
 814
 815     case "$asm_arch" in
 816     x86)
 817         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 818         AC_MSG_RESULT([yes, x86])
 819         ;;
 820     x86_64|amd64)
 821         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 822         AC_MSG_RESULT([yes, x86_64])
 823         ;;
 824     sparc)
 825         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 826         AC_MSG_RESULT([yes, sparc])
 827         ;;
 828     ppc64le)
 829         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 830         AC_MSG_RESULT([yes, ppc64le])
 831         ;;
 832     aarch64)
 833         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 834         AC_MSG_RESULT([yes, aarch64])
 835         ;;
 836     arm)
 837         DEFINES="$DEFINES -DUSE_ARM_ASM"
 838         AC_MSG_RESULT([yes, arm])
 839         ;;
 840     *)
 841         AC_MSG_RESULT([no, platform not supported])
 842         ;;
 843     esac
 844 fi
 845
 846 AC_HEADER_MAJOR
 847 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 848 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 849 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 850 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 851
 852 AC_MSG_CHECKING([whether strtod has locale support])
 853 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 854     #define _GNU_SOURCE
 855     #include <stdlib.h>
 856     #include <locale.h>
 857     #ifdef HAVE_XLOCALE_H
 858     #include <xlocale.h>
 859     #endif
 860     int main() {
 861        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 862        const char *s = "1.0";
 863        char *end;
 864        double d = strtod_l(s, end, loc);
 865        float f = strtof_l(s, end, loc);
 866        freelocale(loc);
 867        return 0;
 868     }]])],
 869   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 870    AC_MSG_RESULT([yes]),
 871    AC_MSG_RESULT([no]))
 872
 873 dnl Check to see if dlopen is in default libraries (like Solaris, which
 874 dnl has it in libc), or if libdl is needed to get it.
 875 AC_CHECK_FUNC([dlopen], [],
 876     [AC_CHECK_LIB([dl], [dlopen],
 877        [DLOPEN_LIBS="-ldl"])])
 878 AC_SUBST([DLOPEN_LIBS])
 879
 880 dnl Check if that library also has dladdr
 881 save_LIBS="$LIBS"
 882 LIBS="$LIBS $DLOPEN_LIBS"
 883 AC_CHECK_FUNCS([dladdr])
 884 LIBS="$save_LIBS"
 885
 886 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 887
 888 case "$host_os" in
 889 darwin*)
 890     ;;
 891 *)
 892     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 893                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 894                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 895     AC_SUBST([CLOCK_LIB])
 896     ;;
 897 esac
 898
 899 dnl See if posix_memalign is available
 900 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 901
 902 dnl Check for zlib
 903 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 904
 905 dnl Check for pthreads
 906 AX_PTHREAD
 907 if test "x$ax_pthread_ok" = xno; then
 908     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 909 fi
 910 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 911 dnl to -pthread, which causes problems if we need -lpthread to appear in
 912 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 913 dnl is not valid for that platform.
 914 if test "x$android" = xno; then
 915     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 916 fi
 917 dnl According to the manual when using pthreads, one should add -pthread to
 918 dnl both compile and link-time arguments.
 919 dnl In practise that should be sufficient for all platforms, since any
 920 dnl platforms build with GCC and Clang support the flag.
 921 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 922
 923 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 924 dnl project. Even then there's a notable issue as described in the project README
 925 case "$host_os" in
 926 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 927     pthread_stubs_possible="no"
 928     ;;
 929 * )
 930     pthread_stubs_possible="yes"
 931     ;;
 932 esac
 933
 934 if test "x$pthread_stubs_possible" = xyes; then
 935     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 936 fi
 937
 938 dnl Check for futex for fast inline simple_mtx_t.
 939 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 940
 941 dnl SELinux awareness.
 942 AC_ARG_ENABLE([selinux],
 943     [AS_HELP_STRING([--enable-selinux],
 944         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 945     [MESA_SELINUX="$enableval"],
 946     [MESA_SELINUX=no])
 947 if test "x$enable_selinux" = "xyes"; then
 948     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 949         [AC_CHECK_HEADER([selinux/selinux.h],[],
 950                          [AC_MSG_ERROR([SELinux headers not found])])
 951          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 952                       [AC_MSG_ERROR([SELinux library not found])])
 953          SELINUX_LIBS="-lselinux"])
 954     DEFINES="$DEFINES -DMESA_SELINUX"
 955 fi
 956 AC_SUBST([SELINUX_CFLAGS])
 957 AC_SUBST([SELINUX_LIBS])
 958
 959 dnl
 960 dnl LLVM
 961 dnl
 962 AC_ARG_ENABLE([llvm-shared-libs],
 963     [AS_HELP_STRING([--enable-llvm-shared-libs],
 964         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 965     [enable_llvm_shared_libs="$enableval"],
 966     [enable_llvm_shared_libs=yes])
 967
 968 AC_ARG_WITH([llvm-prefix],
 969     [AS_HELP_STRING([--with-llvm-prefix],
 970         [Prefix for LLVM installations in non-standard locations])],
 971     [llvm_prefix="$withval"],
 972     [llvm_prefix=''])
 973
 974 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 975 if test "x$have_libelf" = xno; then
 976    LIBELF_LIBS=''
 977    LIBELF_CFLAGS=''
 978    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 979    AC_SUBST([LIBELF_LIBS])
 980    AC_SUBST([LIBELF_CFLAGS])
 981 fi
 982
 983 if test -z "$LLVM_CONFIG"; then
 984     if test -n "$llvm_prefix"; then
 985         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 986     else
 987         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 988     fi
 989 fi
 990
 991 llvm_add_component() {
 992     new_llvm_component=$1
 993     driver_name=$2
 994
 995     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 996         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 997     else
 998         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 999     fi
1000 }
1001
1002 llvm_add_optional_component() {
1003     new_llvm_component=$1
1004     driver_name=$2
1005
1006     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1007         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1008     fi
1009 }
1010
1011 llvm_add_default_components() {
1012     driver_name=$1
1013
1014     # Required default components
1015     llvm_add_component "bitwriter" $driver_name
1016     llvm_add_component "engine" $driver_name
1017     llvm_add_component "mcdisassembler" $driver_name
1018     llvm_add_component "mcjit" $driver_name
1019
1020     # Optional default components
1021     llvm_add_optional_component "inteljitevents" $driver_name
1022 }
1023
1024 llvm_add_target() {
1025     new_llvm_target=$1
1026     driver_name=$2
1027
1028     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1029         llvm_add_component $new_llvm_target $driver_name
1030     else
1031         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1032     fi
1033 }
1034
1035 # Call this inside ` ` to get the return value.
1036 # $1 is the llvm-config command with arguments.
1037 strip_unwanted_llvm_flags() {
1038     echo " `$1` " | sed -E \
1039         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1040         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1041         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1042         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1043         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1044         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1045         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1046         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1047         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1048         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1049         -e 's/^[[[:space:]]]//' \
1050         -e 's/[[[:space:]]]$//'
1051 }
1052
1053 llvm_set_environment_variables() {
1054     if test "x$LLVM_CONFIG" != xno; then
1055         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1056         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1057         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1058         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1059
1060         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1061         save_CFLAGS="$CFLAGS"
1062         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1063
1064         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1065             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1066         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1067             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1068         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1069             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1070
1071         CFLAGS="$save_CFLAGS"
1072
1073         # Only needed for LLVM < 3.6.0
1074         if test -z "$LLVM_VERSION_PATCH"; then
1075             LLVM_VERSION_PATCH=0
1076         fi
1077
1078         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1079
1080         FOUND_LLVM=yes
1081     else
1082         FOUND_LLVM=no
1083         LLVM_VERSION_INT=0
1084     fi
1085 }
1086
1087 require_llvm() {
1088     if test "x$enable_llvm" != "xyes"; then
1089         AC_MSG_ERROR([--enable-llvm is required when building $1])
1090     fi
1091 }
1092
1093 llvm_require_version() {
1094     require_llvm $2
1095
1096     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1097     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1098     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1099
1100     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1101         # major > required major
1102         #  --> OK
1103         return
1104     fi
1105
1106     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1107         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1108             # major = required major and
1109             # minor > required minor
1110             #  --> OK
1111             return
1112         else
1113             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1114                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1115                     # major = required major and
1116                     # minor = required minor and
1117                     # patch >= required patch
1118                     #  --> OK
1119                     return
1120                 fi
1121             fi
1122         fi
1123     fi
1124
1125     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1126 }
1127
1128 radeon_llvm_check() {
1129     if test ${LLVM_VERSION_INT} -lt 307; then
1130         amdgpu_llvm_target_name='r600'
1131     else
1132         amdgpu_llvm_target_name='amdgpu'
1133     fi
1134
1135     llvm_require_version $*
1136
1137     llvm_add_target $amdgpu_llvm_target_name $2
1138
1139     llvm_add_default_components $2
1140     llvm_add_component "bitreader" $2
1141     llvm_add_component "ipo" $2
1142
1143     if test "x$have_libelf" != xyes; then
1144        AC_MSG_ERROR([$2 requires libelf when using llvm])
1145     fi
1146 }
1147
1148 llvm_set_environment_variables
1149
1150 AC_SUBST([LLVM_CFLAGS])
1151 AC_SUBST([LLVM_CXXFLAGS])
1152 AC_SUBST([LLVM_LIBS])
1153 AC_SUBST([LLVM_LDFLAGS])
1154 AC_SUBST([LLVM_INCLUDEDIR])
1155
1156 dnl
1157 dnl libunwind
1158 dnl
1159 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1160 AC_ARG_ENABLE([libunwind],
1161     [AS_HELP_STRING([--enable-libunwind],
1162             [Use libunwind for backtracing (default: auto)])],
1163         [LIBUNWIND="$enableval"],
1164         [LIBUNWIND="$HAVE_LIBUNWIND"])
1165
1166 if test "x$LIBUNWIND" = "xyes"; then
1167     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1168     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1169 fi
1170
1171
1172 dnl Options for APIs
1173 AC_ARG_ENABLE([opengl],
1174     [AS_HELP_STRING([--disable-opengl],
1175         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1176     [enable_opengl="$enableval"],
1177     [enable_opengl=yes])
1178 AC_ARG_ENABLE([gles1],
1179     [AS_HELP_STRING([--disable-gles1],
1180         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1181     [enable_gles1="$enableval"],
1182     [enable_gles1=yes])
1183 AC_ARG_ENABLE([gles2],
1184     [AS_HELP_STRING([--disable-gles2],
1185         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1186     [enable_gles2="$enableval"],
1187     [enable_gles2=yes])
1188
1189 AC_ARG_ENABLE([dri],
1190     [AS_HELP_STRING([--enable-dri],
1191         [enable DRI modules @<:@default=enabled@:>@])],
1192     [enable_dri="$enableval"],
1193     [enable_dri=yes])
1194
1195 AC_ARG_ENABLE([gallium-extra-hud],
1196     [AS_HELP_STRING([--enable-gallium-extra-hud],
1197         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1198     [enable_gallium_extra_hud="$enableval"],
1199     [enable_gallium_extra_hud=no])
1200 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1201 if test "x$enable_gallium_extra_hud" = xyes ; then
1202     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1203 fi
1204
1205 #TODO: no pkgconfig .pc available for libsensors.
1206 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1207 AC_ARG_ENABLE([lmsensors],
1208     [AS_HELP_STRING([--enable-lmsensors],
1209         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1210     [enable_lmsensors="$enableval"],
1211     [enable_lmsensors=no])
1212 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1213 if test "x$enable_lmsensors" = xyes ; then
1214     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1215     LIBSENSORS_LIBS="-lsensors"
1216 else
1217     LIBSENSORS_LIBS=""
1218 fi
1219 AC_SUBST(LIBSENSORS_LIBS)
1220
1221 case "$host_os" in
1222 linux*)
1223     dri3_default=yes
1224     ;;
1225 *)
1226     dri3_default=no
1227     ;;
1228 esac
1229
1230 if test "x$enable_dri" = xno; then
1231     dri3_default=no
1232 fi
1233
1234 AC_ARG_ENABLE([dri3],
1235     [AS_HELP_STRING([--enable-dri3],
1236         [enable DRI3 @<:@default=auto@:>@])],
1237     [enable_dri3="$enableval"],
1238     [enable_dri3="$dri3_default"])
1239 AC_ARG_ENABLE([glx],
1240     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1241         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1242     [enable_glx="$enableval"],
1243     [enable_glx=yes])
1244 AC_ARG_ENABLE([osmesa],
1245     [AS_HELP_STRING([--enable-osmesa],
1246         [enable OSMesa library @<:@default=disabled@:>@])],
1247     [enable_osmesa="$enableval"],
1248     [enable_osmesa=no])
1249 AC_ARG_ENABLE([gallium-osmesa],
1250     [AS_HELP_STRING([--enable-gallium-osmesa],
1251         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1252     [enable_gallium_osmesa="$enableval"],
1253     [enable_gallium_osmesa=no])
1254 AC_ARG_ENABLE([egl],
1255     [AS_HELP_STRING([--disable-egl],
1256         [disable EGL library @<:@default=enabled@:>@])],
1257     [enable_egl="$enableval"],
1258     [enable_egl=yes])
1259
1260 AC_ARG_ENABLE([xa],
1261     [AS_HELP_STRING([--enable-xa],
1262         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1263     [enable_xa="$enableval"],
1264     [enable_xa=no])
1265 AC_ARG_ENABLE([gbm],
1266    [AS_HELP_STRING([--enable-gbm],
1267          [enable gbm library @<:@default=yes except cygwin@:>@])],
1268    [enable_gbm="$enableval"],
1269    [case "$host_os" in
1270        cygwin*)
1271           enable_gbm=no
1272           ;;
1273        *)
1274           enable_gbm=yes
1275           ;;
1276     esac])
1277 AC_ARG_ENABLE([nine],
1278     [AS_HELP_STRING([--enable-nine],
1279         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1280     [enable_nine="$enableval"],
1281     [enable_nine=no])
1282
1283 AC_ARG_ENABLE([xvmc],
1284    [AS_HELP_STRING([--enable-xvmc],
1285          [enable xvmc library @<:@default=auto@:>@])],
1286    [enable_xvmc="$enableval"],
1287    [enable_xvmc=auto])
1288 AC_ARG_ENABLE([vdpau],
1289    [AS_HELP_STRING([--enable-vdpau],
1290          [enable vdpau library @<:@default=auto@:>@])],
1291    [enable_vdpau="$enableval"],
1292    [enable_vdpau=auto])
1293 AC_ARG_ENABLE([omx],
1294    [AS_HELP_STRING([--enable-omx],
1295          [DEPRECATED: Use --enable-omx-bellagio instead @<:@default=auto@:>@])],
1296    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio instead.])],
1297    [])
1298 AC_ARG_ENABLE([omx-bellagio],
1299    [AS_HELP_STRING([--enable-omx-bellagio],
1300          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1301    [enable_omx_bellagio="$enableval"],
1302    [enable_omx_bellagio=no])
1303 AC_ARG_ENABLE([va],
1304    [AS_HELP_STRING([--enable-va],
1305          [enable va library @<:@default=auto@:>@])],
1306    [enable_va="$enableval"],
1307    [enable_va=auto])
1308 AC_ARG_ENABLE([opencl],
1309    [AS_HELP_STRING([--enable-opencl],
1310          [enable OpenCL library @<:@default=disabled@:>@])],
1311    [enable_opencl="$enableval"],
1312    [enable_opencl=no])
1313 AC_ARG_ENABLE([opencl_icd],
1314    [AS_HELP_STRING([--enable-opencl-icd],
1315           [Build an OpenCL ICD library to be loaded by an ICD implementation
1316            @<:@default=enabled@:>@])],
1317     [enable_opencl_icd="$enableval"],
1318     [enable_opencl_icd=yes])
1319
1320 AC_ARG_ENABLE([gallium-tests],
1321     [AS_HELP_STRING([--enable-gallium-tests],
1322         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1323     [enable_gallium_tests="$enableval"],
1324     [enable_gallium_tests=no])
1325
1326 # Option for Gallium drivers
1327
1328 # Keep this in sync with the --with-gallium-drivers help string default value
1329 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1330
1331 AC_ARG_WITH([gallium-drivers],
1332     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1333         [comma delimited Gallium drivers list, e.g.
1334         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,vc5,virgl,etnaviv,imx"
1335         @<:@default=r300,r600,svga,swrast@:>@])],
1336     [with_gallium_drivers="$withval"],
1337     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1338
1339 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1340 # here so that the script doesn't choke on an unknown driver name later.
1341 case "$with_gallium_drivers" in
1342     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1343     no) with_gallium_drivers='' ;;
1344 esac
1345
1346 if test "x$enable_opengl" = xno -a \
1347         "x$enable_gles1" = xno -a \
1348         "x$enable_gles2" = xno -a \
1349         "x$enable_nine" = xno -a \
1350         "x$enable_xa" = xno -a \
1351         "x$enable_xvmc" = xno -a \
1352         "x$enable_vdpau" = xno -a \
1353         "x$enable_omx_bellagio" = xno -a \
1354         "x$enable_va" = xno -a \
1355         "x$enable_opencl" = xno; then
1356     AC_MSG_ERROR([at least one API should be enabled])
1357 fi
1358
1359 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1360 if test "x$enable_opengl" = xno -a \
1361         "x$enable_gles1" = xyes; then
1362     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1363 fi
1364
1365 if test "x$enable_opengl" = xno -a \
1366         "x$enable_gles2" = xyes; then
1367     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1368 fi
1369
1370 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1371 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1372 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1373 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1374                                         "x$enable_gles1" = xyes -o \
1375                                         "x$enable_gles2" = xyes)
1376 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1377                                       "x$enable_gles1" = xyes -o \
1378                                       "x$enable_gles2" = xyes)
1379
1380 # Validate GLX options
1381 if test "x$enable_glx" = xyes; then
1382     if test "x$enable_dri" = xyes; then
1383         enable_glx=dri
1384     elif test -n "$with_gallium_drivers"; then
1385         enable_glx=gallium-xlib
1386     else
1387         enable_glx=xlib
1388     fi
1389 fi
1390 case "x$enable_glx" in
1391 xdri | xxlib | xgallium-xlib)
1392     # GLX requires OpenGL
1393     if test "x$enable_opengl" = xno; then
1394         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1395     fi
1396
1397     # Check individual dependencies
1398     case "x$enable_glx" in
1399     xdri)
1400         if test "x$enable_dri" = xno; then
1401             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1402         fi
1403         ;;
1404     xxlib)
1405         if test "x$enable_dri" = xyes; then
1406             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1407         fi
1408         ;;
1409     xgallium-xlib )
1410         if test "x$enable_dri" = xyes; then
1411             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1412         fi
1413         if test -z "$with_gallium_drivers"; then
1414             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1415         fi
1416         ;;
1417     esac
1418     ;;
1419 xno)
1420     ;;
1421 *)
1422     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1423     ;;
1424 esac
1425
1426 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1427 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1428 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1429 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1430
1431 DEFAULT_GL_LIB_NAME=GL
1432
1433 dnl
1434 dnl Libglvnd configuration
1435 dnl
1436 AC_ARG_ENABLE([libglvnd],
1437     [AS_HELP_STRING([--enable-libglvnd],
1438         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1439     [enable_libglvnd="$enableval"],
1440     [enable_libglvnd=no])
1441 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1442
1443 if test "x$enable_libglvnd" = xyes ; then
1444     case "x$enable_glx" in
1445     xxlib | xgallium-xlib )
1446         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1447         ;;
1448     esac
1449
1450     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1451     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1452     AC_SUBST([LIBGLVND_DATADIR])
1453
1454     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1455     DEFAULT_GL_LIB_NAME=GLX_mesa
1456
1457     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1458         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1459     fi
1460 fi
1461
1462 AC_ARG_WITH([gl-lib-name],
1463   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1464     [specify GL library name @<:@default=GL@:>@])],
1465   [GL_LIB=$withval],
1466   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1467 AC_ARG_WITH([osmesa-lib-name],
1468   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1469     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1470   [OSMESA_LIB=$withval],
1471   [OSMESA_LIB=OSMesa])
1472 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1473 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1474
1475 dnl
1476 dnl Mangled Mesa support
1477 dnl
1478 AC_ARG_ENABLE([mangling],
1479   [AS_HELP_STRING([--enable-mangling],
1480     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1481   [enable_mangling="${enableval}"],
1482   [enable_mangling=no]
1483 )
1484 if test "x${enable_mangling}" = "xyes" ; then
1485   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1486   GL_LIB="Mangled${GL_LIB}"
1487   OSMESA_LIB="Mangled${OSMESA_LIB}"
1488 fi
1489 AC_SUBST([GL_LIB])
1490 AC_SUBST([OSMESA_LIB])
1491
1492 # Check for libdrm
1493 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1494                   [have_libdrm=yes], [have_libdrm=no])
1495 if test "x$have_libdrm" = xyes; then
1496     DEFINES="$DEFINES -DHAVE_LIBDRM"
1497 fi
1498
1499 require_libdrm() {
1500     if test "x$have_libdrm" != xyes; then
1501        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1502     fi
1503 }
1504
1505
1506 # Select which platform-dependent DRI code gets built
1507 case "$host_os" in
1508 darwin*)
1509     dri_platform='apple' ;;
1510 cygwin*)
1511     dri_platform='windows' ;;
1512 gnu*)
1513     dri_platform='none' ;;
1514 *)
1515     dri_platform='drm' ;;
1516 esac
1517
1518 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1519     have_drisw_kms='yes'
1520 fi
1521
1522 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1523 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1524 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1525 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1526 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1527 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1528 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1529 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1530 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1531
1532 AC_ARG_ENABLE([shared-glapi],
1533     [AS_HELP_STRING([--enable-shared-glapi],
1534         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1535     [enable_shared_glapi="$enableval"],
1536     [enable_shared_glapi=yes])
1537
1538 case "x$enable_opengl$enable_gles1$enable_gles2" in
1539 x*yes*yes*)
1540     if test "x$enable_shared_glapi" = xno; then
1541         AC_MSG_ERROR([shared GLAPI required when building two or more of
1542                       the following APIs - opengl, gles1 gles2])
1543     fi
1544     ;;
1545 esac
1546
1547 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1548
1549 # Build the pipe-drivers as separate libraries/modules.
1550 # Do not touch this unless you know what you are doing.
1551 # XXX: Expose via configure option ?
1552 enable_shared_pipe_drivers=no
1553
1554 dnl
1555 dnl Driver specific build directories
1556 dnl
1557
1558 if test "x$enable_gallium_osmesa" = xyes; then
1559     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1560         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1561     fi
1562     if test "x$enable_osmesa" = xyes; then
1563         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1564     fi
1565 fi
1566
1567 require_dri_shared_libs_and_glapi() {
1568     if test "x$enable_static" = xyes; then
1569         AC_MSG_ERROR([$1 cannot be build as static library])
1570     fi
1571
1572     if test "x$enable_dri" != xyes; then
1573         # There is only a single backend which won't be build/used otherwise.
1574         # XXX: Revisit this as the egl/haiku is a thing.
1575         AC_MSG_ERROR([$1 requires --enable-dri])
1576     fi
1577
1578     if test "x$enable_shared_glapi" != xyes; then
1579         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1580     fi
1581 }
1582
1583 if test "x$enable_dri" = xyes; then
1584     require_dri_shared_libs_and_glapi "DRI"
1585
1586     # not a hard requirement as swrast does not depend on it
1587     if test "x$have_libdrm" = xyes; then
1588         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1589     fi
1590 fi
1591
1592 AC_ARG_ENABLE([driglx-direct],
1593     [AS_HELP_STRING([--disable-driglx-direct],
1594         [disable direct rendering in GLX and EGL for DRI \
1595             @<:@default=auto@:>@])],
1596     [driglx_direct="$enableval"],
1597     [driglx_direct="yes"])
1598
1599 dnl
1600 dnl libGL configuration per driver
1601 dnl
1602 if test "x$enable_glx" != xno; then
1603     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1604 fi
1605 case "x$enable_glx" in
1606 xxlib | xgallium-xlib)
1607     # Xlib-based GLX
1608     dri_modules="x11 xext xcb"
1609     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1610     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1611     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1612     GL_LIB_DEPS="$XLIBGL_LIBS"
1613     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1614     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1615     ;;
1616 xdri)
1617     # DRI-based GLX
1618
1619     # find the DRI deps for libGL
1620     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1621
1622     if test x"$driglx_direct" = xyes; then
1623         if test x"$dri_platform" = xdrm ; then
1624             DEFINES="$DEFINES -DGLX_USE_DRM"
1625             require_libdrm "Direct rendering"
1626
1627             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1628             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1629
1630             if test x"$enable_dri" = xyes; then
1631                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1632             fi
1633         fi
1634         if test x"$dri_platform" = xapple ; then
1635             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1636         fi
1637         if test x"$dri_platform" = xwindows ; then
1638             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1639         fi
1640     fi
1641
1642     # add xf86vidmode if available
1643     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1644     if test "$HAVE_XF86VIDMODE" = yes ; then
1645         dri_modules="$dri_modules xxf86vm"
1646     fi
1647
1648     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1649     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1650     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1651     GL_LIB_DEPS="$DRIGL_LIBS"
1652
1653     # need DRM libs, $PTHREAD_LIBS, etc.
1654     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1655     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1656     ;;
1657 esac
1658
1659 # This is outside the case (above) so that it is invoked even for non-GLX
1660 # builds.
1661 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1662
1663 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1664 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1665 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1666 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1667
1668 AC_SUBST([X11_INCLUDES])
1669 AC_SUBST([GL_LIB_DEPS])
1670 AC_SUBST([GL_PC_REQ_PRIV])
1671 AC_SUBST([GL_PC_LIB_PRIV])
1672 AC_SUBST([GL_PC_CFLAGS])
1673 AC_SUBST([DRI_PC_REQ_PRIV])
1674 AC_SUBST([GLESv1_CM_LIB_DEPS])
1675 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1676 AC_SUBST([GLESv2_LIB_DEPS])
1677 AC_SUBST([GLESv2_PC_LIB_PRIV])
1678
1679 AC_SUBST([HAVE_XF86VIDMODE])
1680
1681 dnl
1682 dnl More GLX setup
1683 dnl
1684 case "x$enable_glx" in
1685 xxlib | xgallium-xlib)
1686     DEFINES="$DEFINES -DUSE_XSHM"
1687     ;;
1688 xdri)
1689     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1690     if test "x$driglx_direct" = xyes; then
1691         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1692     fi
1693     ;;
1694 esac
1695
1696 dnl
1697 dnl TLS detection
1698 dnl
1699
1700 AC_ARG_ENABLE([glx-tls],
1701     [AS_HELP_STRING([--enable-glx-tls],
1702         [enable TLS support in GLX @<:@default=enabled@:>@])],
1703     [GLX_USE_TLS="$enableval"],
1704     [GLX_USE_TLS=yes])
1705 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1706
1707 if test "x$GLX_USE_TLS" = xyes; then
1708     DEFINES="$DEFINES -DGLX_USE_TLS"
1709 fi
1710
1711 dnl Read-only text section on x86 hardened platforms
1712 AC_ARG_ENABLE([glx-read-only-text],
1713     [AS_HELP_STRING([--enable-glx-read-only-text],
1714         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1715     [enable_glx_read_only_text="$enableval"],
1716     [enable_glx_read_only_text=no])
1717 if test "x$enable_glx_read_only_text" = xyes; then
1718     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1719 fi
1720
1721 dnl
1722 dnl DEPRECATED: EGL Platforms configuration
1723 dnl
1724 AC_ARG_WITH([egl-platforms],
1725     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1726         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1727     [with_egl_platforms="$withval"],
1728     [with_egl_platforms=auto])
1729
1730 if test "x$with_egl_platforms" = xauto; then
1731     with_egl_platforms="x11,surfaceless"
1732     if test "x$enable_gbm" = xyes; then
1733         with_egl_platforms="$with_egl_platforms,drm"
1734     fi
1735 else
1736     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1737 fi
1738
1739 dnl
1740 dnl Platforms configuration
1741 dnl
1742 AC_ARG_WITH([platforms],
1743     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1744         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1745         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1746     [with_platforms="$withval"],
1747     [with_platforms=auto])
1748
1749 # Reuse the autodetection rather than duplicating it.
1750 if test "x$with_platforms" = xauto; then
1751     with_platforms=$with_egl_platforms
1752 fi
1753
1754 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1755         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1756         WAYLAND_SCANNER='')
1757 if test "x$WAYLAND_SCANNER" = x; then
1758     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1759 fi
1760
1761 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1762 if test "x$have_wayland_protocols" = xyes; then
1763     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1764 fi
1765 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1766
1767 # Do per platform setups and checks
1768 platforms=`IFS=', '; echo $with_platforms`
1769 for plat in $platforms; do
1770     case "$plat" in
1771     wayland)
1772
1773         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1774         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1775
1776         if test "x$WAYLAND_SCANNER" = "x:"; then
1777                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1778         fi
1779         if test "x$have_wayland_protocols" = xno; then
1780                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1781         fi
1782         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1783         ;;
1784
1785     x11)
1786         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1787         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1788         ;;
1789
1790     drm)
1791         test "x$enable_gbm" = "xno" &&
1792                 AC_MSG_ERROR([EGL platform drm needs gbm])
1793         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1794         ;;
1795
1796     surfaceless)
1797         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1798         ;;
1799
1800     android)
1801         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1802         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1803         ;;
1804
1805     *)
1806         AC_MSG_ERROR([platform '$plat' does not exist])
1807         ;;
1808     esac
1809
1810     case "$plat" in
1811     wayland|drm|surfaceless)
1812         require_libdrm "Platform $plat"
1813         ;;
1814     esac
1815 done
1816
1817 if test "x$enable_glx" != xno; then
1818     if ! echo "$platforms" | grep -q 'x11'; then
1819         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1820     fi
1821 fi
1822
1823 if test x"$enable_dri3" = xyes; then
1824     DEFINES="$DEFINES -DHAVE_DRI3"
1825
1826     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1827     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1828 fi
1829
1830 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1831 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1832 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1833 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1834 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1835
1836 dnl
1837 dnl More DRI setup
1838 dnl
1839 dnl Directory for DRI drivers
1840 AC_ARG_WITH([dri-driverdir],
1841     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1842         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1843     [DRI_DRIVER_INSTALL_DIR="$withval"],
1844     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1845 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1846 dnl Extra search path for DRI drivers
1847 AC_ARG_WITH([dri-searchpath],
1848     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1849         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1850     [DRI_DRIVER_SEARCH_DIR="$withval"],
1851     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1852 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1853 dnl Which drivers to build - default is chosen by platform
1854 AC_ARG_WITH([dri-drivers],
1855     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1856         [comma delimited classic DRI drivers list, e.g.
1857         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1858     [with_dri_drivers="$withval"],
1859     [with_dri_drivers=auto])
1860
1861 if test "x$with_dri_drivers" = xauto; then
1862     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1863         with_dri_drivers="yes"
1864     else
1865         with_dri_drivers="no"
1866     fi
1867 fi
1868 if test "x$with_dri_drivers" = xno; then
1869     with_dri_drivers=''
1870 fi
1871
1872 # Check for expat
1873 PKG_CHECK_MODULES([EXPAT], [expat],,
1874     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1875 )
1876
1877 dnl If $with_dri_drivers is yes, drivers will be added through
1878 dnl platform checks. Set DEFINES and LIB_DEPS
1879 if test "x$enable_dri" = xyes; then
1880     # Platform specific settings and drivers to build
1881     case "$host_os" in
1882     linux*)
1883         case "$host_cpu" in
1884         powerpc* | sparc*)
1885             # Build only the drivers for cards that exist on PowerPC/sparc
1886             if test "x$with_dri_drivers" = "xyes"; then
1887                 with_dri_drivers="r200 radeon swrast"
1888             fi
1889             ;;
1890         esac
1891         ;;
1892     cygwin*)
1893         if test "x$with_dri_drivers" = "xyes"; then
1894             with_dri_drivers="swrast"
1895         fi
1896         ;;
1897     darwin*)
1898         DEFINES="$DEFINES -DBUILDING_MESA"
1899         if test "x$with_dri_drivers" = "xyes"; then
1900             with_dri_drivers="swrast"
1901         fi
1902         ;;
1903     esac
1904
1905     # default drivers
1906     if test "x$with_dri_drivers" = "xyes"; then
1907         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1908     fi
1909
1910     # put all the necessary libs together
1911     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1912 fi
1913
1914 AC_SUBST([DRI_LIB_DEPS])
1915
1916 DRI_DIRS=''
1917 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1918 if test -n "$with_dri_drivers"; then
1919     if test "x$enable_opengl" != xyes; then
1920         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1921     fi
1922
1923     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1924     for driver in $dri_drivers; do
1925         DRI_DIRS="$DRI_DIRS $driver"
1926         case "x$driver" in
1927         xi915)
1928             require_libdrm "i915"
1929             HAVE_I915_DRI=yes
1930             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1931             ;;
1932         xi965)
1933             require_libdrm "i965"
1934             HAVE_I965_DRI=yes
1935             ;;
1936         xnouveau)
1937             require_libdrm "nouveau"
1938             HAVE_NOUVEAU_DRI=yes
1939             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1940             ;;
1941         xradeon)
1942             require_libdrm "radeon"
1943             HAVE_RADEON_DRI=yes;
1944             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1945             ;;
1946         xr200)
1947             require_libdrm "r200"
1948             HAVE_R200_DRI=yes
1949             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1950             ;;
1951         xswrast)
1952             HAVE_SWRAST_DRI=yes
1953             ;;
1954         *)
1955             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1956             ;;
1957         esac
1958     done
1959     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1960 fi
1961
1962
1963 dnl
1964 dnl Gallium LLVM
1965 dnl Deprecated: kept for backwards compatibility
1966 dnl
1967 AC_ARG_ENABLE([gallium-llvm],
1968     [AS_HELP_STRING([--enable-gallium-llvm],
1969         [DEPRECATED: use --enable-llvm instead])],
1970     [enable_gallium_llvm="$enableval"],
1971     [enable_gallium_llvm=auto])
1972
1973 if test "x$enable_gallium_llvm" != xauto; then
1974    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1975    enable_llvm=$enable_gallium_llvm
1976 fi
1977
1978 dnl
1979 dnl LLVM
1980 dnl
1981 AC_ARG_ENABLE([llvm],
1982     [AS_HELP_STRING([--enable-llvm],
1983         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1984     [enable_llvm="$enableval"],
1985     [enable_llvm=auto])
1986
1987 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1988     if test "x$FOUND_LLVM" = xyes; then
1989         case "$host_cpu" in
1990         i*86|x86_64|amd64) enable_llvm=yes;;
1991         *) enable_llvm=no;;
1992         esac
1993     else
1994         enable_llvm=no
1995     fi
1996 fi
1997
1998 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1999     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2000 fi
2001
2002 #
2003 # Vulkan driver configuration
2004 #
2005
2006 AC_ARG_WITH([vulkan-drivers],
2007     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2008         [comma delimited Vulkan drivers list, e.g.
2009         "intel,radeon"
2010         @<:@default=no@:>@])],
2011     [with_vulkan_drivers="$withval"],
2012     [with_vulkan_drivers="no"])
2013
2014 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2015 # here so that the script doesn't choke on an unknown driver name later.
2016 case "x$with_vulkan_drivers" in
2017     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2018     xno) with_vulkan_drivers='' ;;
2019 esac
2020
2021 AC_ARG_WITH([vulkan-icddir],
2022     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2023         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2024     [VULKAN_ICD_INSTALL_DIR="$withval"],
2025     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2026 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2027
2028 require_x11_dri3() {
2029     if echo "$platforms" | grep -q 'x11'; then
2030         if test "x$enable_dri3" != xyes; then
2031             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2032         fi
2033     fi
2034 }
2035
2036 if test -n "$with_vulkan_drivers"; then
2037     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2038         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2039     fi
2040
2041     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2042     for driver in $VULKAN_DRIVERS; do
2043         case "x$driver" in
2044         xintel)
2045             require_libdrm "ANV"
2046             require_x11_dri3 "ANV"
2047             HAVE_INTEL_VULKAN=yes
2048             ;;
2049         xradeon)
2050             require_libdrm "radv"
2051             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2052             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2053             require_x11_dri3 "radv"
2054             HAVE_RADEON_VULKAN=yes
2055             ;;
2056         *)
2057             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2058             ;;
2059         esac
2060     done
2061     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2062 fi
2063
2064
2065 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2066 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2067 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2068                                   "x$enable_osmesa" = xyes -o \
2069                                   -n "$DRI_DIRS")
2070
2071 dnl
2072 dnl OSMesa configuration
2073 dnl
2074
2075 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2076 AC_ARG_WITH([osmesa-bits],
2077     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2078         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2079     [osmesa_bits="$withval"],
2080     [osmesa_bits=8])
2081 if test "x$osmesa_bits" != x8; then
2082     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2083         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2084         osmesa_bits=8
2085     fi
2086 fi
2087 case "x$osmesa_bits" in
2088 x8)
2089     OSMESA_LIB="${OSMESA_LIB}"
2090     ;;
2091 x16|x32)
2092     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2093     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2094     ;;
2095 *)
2096     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2097     ;;
2098 esac
2099
2100 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2101     # only link libraries with osmesa if shared
2102     if test "$enable_static" = no; then
2103         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2104     else
2105         OSMESA_LIB_DEPS=""
2106     fi
2107     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2108 fi
2109
2110 AC_SUBST([OSMESA_LIB_DEPS])
2111 AC_SUBST([OSMESA_PC_REQ])
2112 AC_SUBST([OSMESA_PC_LIB_PRIV])
2113
2114 dnl
2115 dnl gbm configuration
2116 dnl
2117 if test "x$enable_gbm" = xyes; then
2118     require_dri_shared_libs_and_glapi "gbm"
2119 fi
2120 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2121 # FINISHME: GBM has a number of dependencies which we should add below
2122 GBM_PC_REQ_PRIV=""
2123 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2124 AC_SUBST([GBM_PC_REQ_PRIV])
2125 AC_SUBST([GBM_PC_LIB_PRIV])
2126
2127 dnl
2128 dnl EGL configuration
2129 dnl
2130
2131 if test "x$enable_egl" = xyes; then
2132     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2133
2134     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2135
2136     require_dri_shared_libs_and_glapi "egl"
2137 fi
2138 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2139 AC_SUBST([EGL_LIB_DEPS])
2140
2141 gallium_st="mesa"
2142
2143 dnl
2144 dnl XA configuration
2145 dnl
2146 if test "x$enable_xa" = xyes; then
2147     if test "x$with_gallium_drivers" = xswrast; then
2148        AC_MSG_ERROR([
2149           Building xa requires at least one non swrast gallium driver.
2150           If you are looking to use libxatracker.so with the VMware driver,
2151           make sure to include svga in the gallium drivers list, apart from
2152           enabling XA.
2153           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2154     fi
2155     gallium_st="$gallium_st xa"
2156 fi
2157 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2158
2159 if echo $platforms | grep -q "x11"; then
2160     have_xvmc_platform=yes
2161 else
2162     have_xvmc_platform=no
2163 fi
2164
2165 if echo $platforms | grep -q "x11"; then
2166     have_vdpau_platform=yes
2167 else
2168     have_vdpau_platform=no
2169 fi
2170
2171 if echo $platforms | grep -q "x11\|drm"; then
2172     have_omx_platform=yes
2173 else
2174     have_omx_platform=no
2175 fi
2176
2177 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2178     have_va_platform=yes
2179 else
2180     have_va_platform=no
2181 fi
2182
2183 dnl
2184 dnl Gallium G3DVL configuration
2185 dnl
2186 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2187     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2188         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2189     fi
2190
2191     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2192         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2193     fi
2194
2195     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2196         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2197     fi
2198
2199     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2200         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2201     fi
2202 fi
2203
2204 if test "x$enable_dri" = xyes -o \
2205         "x$enable_xvmc" = xyes -o \
2206         "x$enable_vdpau" = xyes -o \
2207         "x$enable_omx_bellagio" = xyes -o \
2208         "x$enable_va" = xyes; then
2209     need_gallium_vl=yes
2210 fi
2211 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2212
2213 if test "x$enable_xvmc" = xyes -o \
2214         "x$enable_vdpau" = xyes -o \
2215         "x$enable_omx_bellagio" = xyes -o \
2216         "x$enable_va" = xyes; then
2217     if echo $platforms | grep -q "x11"; then
2218         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2219     fi
2220     need_gallium_vl_winsys=yes
2221 fi
2222 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2223
2224 if test "x$enable_xvmc" = xyes; then
2225     if test "x$have_xvmc_platform" != xyes; then
2226         AC_MSG_ERROR([XVMC requires the x11 platforms])
2227     fi
2228     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2229     gallium_st="$gallium_st xvmc"
2230 fi
2231 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2232
2233 if test "x$enable_vdpau" = xyes; then
2234     if test "x$have_vdpau_platform" != xyes; then
2235         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2236     fi
2237     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2238     gallium_st="$gallium_st vdpau"
2239     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2240 fi
2241 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2242
2243 if test "x$enable_omx_bellagio" = xyes; then
2244     if test "x$have_omx_platform" != xyes; then
2245         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2246     fi
2247     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2248     gallium_st="$gallium_st omx_bellagio"
2249 fi
2250 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2251
2252 if test "x$enable_va" = xyes; then
2253     if test "x$have_va_platform" != xyes; then
2254         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2255     fi
2256     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2257     gallium_st="$gallium_st va"
2258 fi
2259 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2260
2261 dnl
2262 dnl Nine Direct3D9 configuration
2263 dnl
2264 if test "x$enable_nine" = xyes; then
2265     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2266         AC_MSG_ERROR([nine requires the gallium swrast driver])
2267     fi
2268     if test "x$with_gallium_drivers" = xswrast; then
2269         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2270     fi
2271     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2272         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2273     fi
2274
2275     if test "x$enable_dri3" = xno; then
2276         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2277     fi
2278
2279     gallium_st="$gallium_st nine"
2280 fi
2281 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2282
2283 dnl
2284 dnl OpenCL configuration
2285 dnl
2286
2287 AC_ARG_WITH([clang-libdir],
2288    [AS_HELP_STRING([--with-clang-libdir],
2289          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2290    [CLANG_LIBDIR="$withval"],
2291    [CLANG_LIBDIR=''])
2292
2293 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2294
2295 if test "x$enable_opencl" = xyes; then
2296     if test -z "$with_gallium_drivers"; then
2297         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2298     fi
2299
2300     if test "x$HAVE_CXX11" != "xyes"; then
2301        AC_MSG_ERROR([clover requires c++11 support])
2302     fi
2303
2304     if test "x$have_libclc" = xno; then
2305         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2306                     Make sure the directory containing libclc.pc is specified in your
2307                     PKG_CONFIG_PATH environment variable.
2308                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2309     else
2310         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2311         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2312         AC_SUBST([LIBCLC_INCLUDEDIR])
2313         AC_SUBST([LIBCLC_LIBEXECDIR])
2314     fi
2315
2316     gallium_st="$gallium_st clover"
2317
2318     if test "x$enable_opencl_icd" = xyes; then
2319         OPENCL_LIBNAME="MesaOpenCL"
2320     else
2321         OPENCL_LIBNAME="OpenCL"
2322     fi
2323
2324     if test "x$have_libelf" != xyes; then
2325        AC_MSG_ERROR([Clover requires libelf])
2326     fi
2327
2328     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2329         altivec_enabled=no
2330         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2331         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2332         #error "AltiVec not enabled"
2333         #endif
2334         ])], altivec_enabled=yes)
2335
2336         if test "$altivec_enabled" = yes; then
2337             CLOVER_STD_OVERRIDE="-std=gnu++11"
2338         fi
2339         AC_SUBST([CLOVER_STD_OVERRIDE])
2340     fi
2341
2342     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2343
2344     llvm_add_default_components "opencl"
2345     llvm_add_component "all-targets" "opencl"
2346     llvm_add_component "coverage" "opencl"
2347     llvm_add_component "linker" "opencl"
2348     llvm_add_component "instrumentation" "opencl"
2349     llvm_add_component "ipo" "opencl"
2350     llvm_add_component "irreader" "opencl"
2351     llvm_add_component "lto" "opencl"
2352     llvm_add_component "option" "opencl"
2353     llvm_add_component "objcarcopts" "opencl"
2354     llvm_add_component "profiledata" "opencl"
2355     llvm_add_optional_component "coroutines" "opencl"
2356
2357     dnl Check for Clang internal headers
2358     if test -z "$CLANG_LIBDIR"; then
2359         CLANG_LIBDIR=${LLVM_LIBDIR}
2360     fi
2361     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2362     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2363         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2364 fi
2365 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2366 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2367 AC_SUBST([OPENCL_LIBNAME])
2368 AC_SUBST([CLANG_RESOURCE_DIR])
2369
2370 dnl
2371 dnl Gallium configuration
2372 dnl
2373 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2374
2375 # libEGL wants to default to the first platform specified in
2376 # ./configure.  parse that here.
2377 if test "x$platforms" != "x"; then
2378     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2379     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2380 else
2381     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2382 fi
2383
2384 AC_SUBST([EGL_NATIVE_PLATFORM])
2385 AC_SUBST([EGL_CFLAGS])
2386
2387 # If we don't have the X11 platform, set this define so we don't try to include
2388 # the X11 headers.
2389 if ! echo "$platforms" | grep -q 'x11'; then
2390     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2391     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2392 fi
2393
2394 dnl Directory for XVMC libs
2395 AC_ARG_WITH([xvmc-libdir],
2396     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2397         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2398     [XVMC_LIB_INSTALL_DIR="$withval"],
2399     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2400 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2401
2402 dnl
2403 dnl Gallium Tests
2404 dnl
2405 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2406
2407 dnl Directory for VDPAU libs
2408 AC_ARG_WITH([vdpau-libdir],
2409     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2410         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2411     [VDPAU_LIB_INSTALL_DIR="$withval"],
2412     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2413 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2414
2415 dnl Directory for OMX_BELLAGIO libs
2416
2417 AC_ARG_WITH([omx-bellagio-libdir],
2418     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2419         [directory for the OMX_BELLAGIO libraries])],
2420     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2421     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2422                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2423 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2424
2425 dnl Directory for VA libs
2426
2427 AC_ARG_WITH([va-libdir],
2428     [AS_HELP_STRING([--with-va-libdir=DIR],
2429         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2430     [VA_LIB_INSTALL_DIR="$withval"],
2431     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2432 AC_SUBST([VA_LIB_INSTALL_DIR])
2433
2434 AC_ARG_WITH([d3d-libdir],
2435     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2436         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2437     [D3D_DRIVER_INSTALL_DIR="$withval"],
2438     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2439 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2440
2441 dnl Architectures to build SWR library for
2442
2443 AC_ARG_WITH([swr-archs],
2444     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2445         [comma delimited swr architectures list, e.g.
2446         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2447     [with_swr_archs="$withval"],
2448     [with_swr_archs="avx,avx2"])
2449
2450 dnl
2451 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2452 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2453 dnl architectures.
2454 dnl
2455 r300_require_llvm() {
2456     case "$host" in *gnux32) return;; esac
2457     case "$host_cpu" in
2458     i*86|x86_64|amd64) require_llvm $1
2459         ;;
2460     esac
2461 }
2462
2463 dnl
2464 dnl DRM is needed by X, Wayland, and offscreen rendering.
2465 dnl Surfaceless is an alternative for the last one.
2466 dnl
2467 require_basic_egl() {
2468     case "$with_platforms" in
2469         *drm*|*surfaceless*|*android*)
2470             ;;
2471         *)
2472             AC_MSG_ERROR([$1 requires one of these:
2473                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2474                   2) --with-platforms=surfaceless (offscreen only)
2475                   3) --with-platforms=android (Android only)
2476                   Recommended options: drm,x11])
2477             ;;
2478     esac
2479 }
2480
2481 swr_require_cxx_feature_flags() {
2482     feature_name="$1"
2483     preprocessor_test="$2"
2484     option_list="$3"
2485     output_var="$4"
2486
2487     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2488     AC_LANG_PUSH([C++])
2489     save_CXXFLAGS="$CXXFLAGS"
2490     save_IFS="$IFS"
2491     IFS=","
2492     found=0
2493     for opts in $option_list
2494     do
2495         unset IFS
2496         CXXFLAGS="$opts $save_CXXFLAGS"
2497         AC_COMPILE_IFELSE(
2498             [AC_LANG_PROGRAM(
2499                 [   #if !($preprocessor_test)
2500                     #error
2501                     #endif
2502                 ])],
2503             [found=1; break],
2504             [])
2505         IFS=","
2506     done
2507     IFS="$save_IFS"
2508     CXXFLAGS="$save_CXXFLAGS"
2509     AC_LANG_POP([C++])
2510     if test $found -eq 1; then
2511         AC_MSG_RESULT([$opts])
2512         eval "$output_var=\$opts"
2513         return 0
2514     fi
2515     AC_MSG_RESULT([no])
2516     AC_MSG_ERROR([swr requires $feature_name support])
2517     return 1
2518 }
2519
2520 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2521 if test -n "$with_gallium_drivers"; then
2522     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2523     for driver in $gallium_drivers; do
2524         case "x$driver" in
2525         xsvga)
2526             HAVE_GALLIUM_SVGA=yes
2527             require_libdrm "svga"
2528             ;;
2529         xi915)
2530             HAVE_GALLIUM_I915=yes
2531             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2532             require_libdrm "Gallium i915"
2533             ;;
2534         xr300)
2535             HAVE_GALLIUM_R300=yes
2536             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2537             require_libdrm "r300"
2538             r300_require_llvm "r300"
2539             ;;
2540         xr600)
2541             HAVE_GALLIUM_R600=yes
2542             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2543             require_libdrm "r600"
2544             if test "x$enable_llvm" = xyes; then
2545                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2546
2547                 llvm_add_component "asmparser" "r600"
2548                 llvm_add_component "bitreader" "r600"
2549             fi
2550             ;;
2551         xradeonsi)
2552             HAVE_GALLIUM_RADEONSI=yes
2553             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2554             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2555             require_libdrm "radeonsi"
2556             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2557             if test "x$enable_egl" = xyes; then
2558                 require_basic_egl "radeonsi"
2559             fi
2560             ;;
2561         xnouveau)
2562             HAVE_GALLIUM_NOUVEAU=yes
2563             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2564             require_libdrm "nouveau"
2565             ;;
2566         xfreedreno)
2567             HAVE_GALLIUM_FREEDRENO=yes
2568             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2569             require_libdrm "freedreno"
2570             ;;
2571         xetnaviv)
2572             HAVE_GALLIUM_ETNAVIV=yes
2573             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2574             require_libdrm "etnaviv"
2575             ;;
2576        ximx)
2577             HAVE_GALLIUM_IMX=yes
2578             ;;
2579         xswrast)
2580             HAVE_GALLIUM_SOFTPIPE=yes
2581             if test "x$enable_llvm" = xyes; then
2582                 HAVE_GALLIUM_LLVMPIPE=yes
2583             fi
2584             ;;
2585         xswr)
2586             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2587
2588             if test "x$HAVE_CXX11" != "xyes"; then
2589                 AC_MSG_ERROR([swr requires c++11 support])
2590             fi
2591
2592             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2593                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2594                 SWR_AVX_CXXFLAGS
2595             AC_SUBST([SWR_AVX_CXXFLAGS])
2596
2597             swr_archs=`IFS=', '; echo $with_swr_archs`
2598             for arch in $swr_archs; do
2599                 case "x$arch" in
2600                 xavx)
2601                     HAVE_SWR_AVX=yes
2602                     ;;
2603                 xavx2)
2604                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2605                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2606                         SWR_AVX2_CXXFLAGS
2607                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2608                     HAVE_SWR_AVX2=yes
2609                     ;;
2610                 xknl)
2611                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2612                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2613                         SWR_KNL_CXXFLAGS
2614                     AC_SUBST([SWR_KNL_CXXFLAGS])
2615                     HAVE_SWR_KNL=yes
2616                     ;;
2617                 xskx)
2618                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2619                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2620                         SWR_SKX_CXXFLAGS
2621                     AC_SUBST([SWR_SKX_CXXFLAGS])
2622                     HAVE_SWR_SKX=yes
2623                     ;;
2624                 *)
2625                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2626                     ;;
2627                 esac
2628             done
2629
2630             if test "x$HAVE_SWR_AVX" != xyes -a \
2631                     "x$HAVE_SWR_AVX2" != xyes -a \
2632                     "x$HAVE_SWR_KNL" != xyes -a \
2633                     "x$HAVE_SWR_SKX" != xyes; then
2634                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2635             fi
2636
2637             HAVE_GALLIUM_SWR=yes
2638             ;;
2639         xvc4)
2640             HAVE_GALLIUM_VC4=yes
2641             require_libdrm "vc4"
2642
2643             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2644                               [USE_VC4_SIMULATOR=yes;
2645                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2646                               [USE_VC4_SIMULATOR=no])
2647             ;;
2648         xvc5)
2649             HAVE_GALLIUM_VC5=yes
2650
2651             PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2652                               [USE_VC5_SIMULATOR=yes;
2653                                DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2654                               [AC_MSG_ERROR([vc5 requires the simulator])])
2655             ;;
2656         xpl111)
2657             HAVE_GALLIUM_PL111=yes
2658             ;;
2659         xvirgl)
2660             HAVE_GALLIUM_VIRGL=yes
2661             require_libdrm "virgl"
2662             if test "x$enable_egl" = xyes; then
2663                 require_basic_egl "virgl"
2664             fi
2665             ;;
2666         *)
2667             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2668             ;;
2669         esac
2670     done
2671 fi
2672
2673 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2674 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2675                                               "x$LLVM_VERSION" != x3.9.1)
2676
2677 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2678     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2679     llvm_add_default_components "gallium"
2680 fi
2681
2682 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2683 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2684 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2685 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2686
2687 dnl We need to validate some needed dependencies for renderonly drivers.
2688
2689 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2690     AC_MSG_ERROR([Building with imx requires etnaviv])
2691 fi
2692
2693 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2694     AC_MSG_ERROR([Building with pl111 requires vc4])
2695 fi
2696
2697
2698 detect_old_buggy_llvm() {
2699     dnl llvm-config may not give the right answer when llvm is a built as a
2700     dnl single shared library, so we must work the library name out for
2701     dnl ourselves.
2702     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2703     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2704     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2705     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2706
2707     if test "x$llvm_have_one_so" = xyes; then
2708         dnl LLVM was built using auto*, so there is only one shared object.
2709         LLVM_LIBS="-l$LLVM_SO_NAME"
2710     else
2711         dnl If LLVM was built with CMake, there will be one shared object per
2712         dnl component.
2713         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2714                [AC_MSG_ERROR([Could not find llvm shared libraries:
2715                 Please make sure you have built llvm with the --enable-shared option
2716                 and that your llvm libraries are installed in $LLVM_LIBDIR
2717                 If you have installed your llvm libraries to a different directory you
2718                 can use the --with-llvm-prefix= configure flag to specify this directory.
2719                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2720                 If you do not want to build with llvm shared libraries and instead want to
2721                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2722                 invocation and rebuild.])])
2723
2724         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2725         dnl install uses a shared object for each component and we have
2726         dnl already added all of these objects to LLVM_LIBS.
2727     fi
2728 }
2729
2730 dnl
2731 dnl Set defines and buildtime variables only when using LLVM.
2732 dnl
2733 if test "x$enable_llvm" = xyes; then
2734     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2735
2736     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2737     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2738     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2739
2740     dnl Set LLVM_LIBS - This is done after the driver configuration so
2741     dnl that drivers can add additional components to LLVM_COMPONENTS.
2742     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2743     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2744     dnl this was causing the same libraries to be appear multiple times
2745     dnl in LLVM_LIBS.
2746
2747     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2748         if test "x$enable_llvm_shared_libs" = xyes; then
2749             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2750         else
2751             dnl Invoking llvm-config with both -libs and --system-libs produces the
2752             dnl two separate lines - each for the set of libraries.
2753                 dnl Call the program twice, effectively folding them into a single line.
2754             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2755             dnl We need to link to llvm system libs when using static libs
2756             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2757         fi
2758     else
2759         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2760         if test "x$enable_llvm_shared_libs" = xyes; then
2761             detect_old_buggy_llvm
2762         else
2763             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2764             dnl We need to link to llvm system libs when using static libs
2765             dnl However, only llvm 3.5+ provides --system-libs
2766             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2767                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2768             fi
2769         fi
2770     fi
2771 fi
2772
2773 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2774 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2775 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2776 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2777 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2778 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2779 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2780 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2781 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2782 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2783 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2784 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2785 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2786 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2787 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2788                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2789                                          "x$HAVE_GALLIUM_SWR" = xyes)
2790 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2791 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2792 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2793
2794 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2795
2796 if test "x$enable_dri" = xyes; then
2797     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2798 fi
2799
2800 if test "x$have_drisw_kms" = xyes; then
2801     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2802 fi
2803 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2804
2805 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2806 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2807 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2808 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2809 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2810 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2811
2812 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2813 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2814
2815 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2816                                       "x$HAVE_RADEON_VULKAN" = xyes)
2817
2818 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2819                                       "x$HAVE_GALLIUM_VC5" = xyes)
2820
2821 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2822                                         "x$HAVE_I965_DRI" = xyes)
2823
2824 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2825                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2826                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2827 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2828 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2829 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2830 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2831 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2832
2833 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2834 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2835 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2836 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2837                                         "x$enable_gallium_osmesa" = xyes)
2838
2839 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2840 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2841 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2842 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2843 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2844 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2845
2846 AC_SUBST([NINE_MAJOR], 1)
2847 AC_SUBST([NINE_MINOR], 0)
2848 AC_SUBST([NINE_TINY], 0)
2849 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2850
2851 AC_SUBST([VDPAU_MAJOR], 1)
2852 AC_SUBST([VDPAU_MINOR], 0)
2853
2854 if test "x$enable_va" = xyes; then
2855     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2856     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2857 fi
2858 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2859 AC_SUBST([VA_MINOR], $VA_MINOR)
2860
2861 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2862
2863 AC_SUBST([XVMC_MAJOR], 1)
2864 AC_SUBST([XVMC_MINOR], 0)
2865
2866 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2867 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2868 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2869 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2870
2871 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2872 AC_SUBST([XA_MINOR], $XA_MINOR)
2873 AC_SUBST([XA_TINY], $XA_TINY)
2874 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2875
2876 AC_ARG_ENABLE(valgrind,
2877               [AS_HELP_STRING([--enable-valgrind],
2878                              [Build mesa with valgrind support (default: auto)])],
2879                              [VALGRIND=$enableval], [VALGRIND=auto])
2880 if test "x$VALGRIND" != xno; then
2881     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2882 fi
2883 AC_MSG_CHECKING([whether to enable Valgrind support])
2884 if test "x$VALGRIND" = xauto; then
2885     VALGRIND="$have_valgrind"
2886 fi
2887
2888 if test "x$VALGRIND" = "xyes"; then
2889     if ! test "x$have_valgrind" = xyes; then
2890         AC_MSG_ERROR([Valgrind support required but not present])
2891     fi
2892     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2893 fi
2894
2895 AC_MSG_RESULT([$VALGRIND])
2896
2897 dnl Restore LDFLAGS and CPPFLAGS
2898 LDFLAGS="$_SAVE_LDFLAGS"
2899 CPPFLAGS="$_SAVE_CPPFLAGS"
2900
2901 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2902 if test "x$acv_mesa_CLANG" = xyes; then
2903     CFLAGS="$CFLAGS -Qunused-arguments"
2904     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2905 fi
2906
2907 dnl Add user CFLAGS and CXXFLAGS
2908 CFLAGS="$CFLAGS $USER_CFLAGS"
2909 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2910
2911 dnl Substitute the config
2912 AC_CONFIG_FILES([Makefile
2913                  src/Makefile
2914                  src/amd/Makefile
2915                  src/amd/vulkan/Makefile
2916                  src/broadcom/Makefile
2917                  src/compiler/Makefile
2918                  src/egl/Makefile
2919                  src/egl/main/egl.pc
2920                  src/egl/wayland/wayland-drm/Makefile
2921                  src/egl/wayland/wayland-egl/Makefile
2922                  src/egl/wayland/wayland-egl/wayland-egl.pc
2923                  src/gallium/Makefile
2924                  src/gallium/auxiliary/Makefile
2925                  src/gallium/auxiliary/pipe-loader/Makefile
2926                  src/gallium/drivers/freedreno/Makefile
2927                  src/gallium/drivers/ddebug/Makefile
2928                  src/gallium/drivers/i915/Makefile
2929                  src/gallium/drivers/llvmpipe/Makefile
2930                  src/gallium/drivers/noop/Makefile
2931                  src/gallium/drivers/nouveau/Makefile
2932                  src/gallium/drivers/pl111/Makefile
2933                  src/gallium/drivers/r300/Makefile
2934                  src/gallium/drivers/r600/Makefile
2935                  src/gallium/drivers/radeon/Makefile
2936                  src/gallium/drivers/radeonsi/Makefile
2937                  src/gallium/drivers/rbug/Makefile
2938                  src/gallium/drivers/softpipe/Makefile
2939                  src/gallium/drivers/svga/Makefile
2940                  src/gallium/drivers/swr/Makefile
2941                  src/gallium/drivers/trace/Makefile
2942                  src/gallium/drivers/etnaviv/Makefile
2943                  src/gallium/drivers/imx/Makefile
2944                  src/gallium/drivers/vc4/Makefile
2945                  src/gallium/drivers/vc5/Makefile
2946                  src/gallium/drivers/virgl/Makefile
2947                  src/gallium/state_trackers/clover/Makefile
2948                  src/gallium/state_trackers/dri/Makefile
2949                  src/gallium/state_trackers/glx/xlib/Makefile
2950                  src/gallium/state_trackers/nine/Makefile
2951                  src/gallium/state_trackers/omx_bellagio/Makefile
2952                  src/gallium/state_trackers/osmesa/Makefile
2953                  src/gallium/state_trackers/va/Makefile
2954                  src/gallium/state_trackers/vdpau/Makefile
2955                  src/gallium/state_trackers/xa/Makefile
2956                  src/gallium/state_trackers/xvmc/Makefile
2957                  src/gallium/targets/d3dadapter9/Makefile
2958                  src/gallium/targets/d3dadapter9/d3d.pc
2959                  src/gallium/targets/dri/Makefile
2960                  src/gallium/targets/libgl-xlib/Makefile
2961                  src/gallium/targets/omx-bellagio/Makefile
2962                  src/gallium/targets/opencl/Makefile
2963                  src/gallium/targets/opencl/mesa.icd
2964                  src/gallium/targets/osmesa/Makefile
2965                  src/gallium/targets/osmesa/osmesa.pc
2966                  src/gallium/targets/pipe-loader/Makefile
2967                  src/gallium/targets/va/Makefile
2968                  src/gallium/targets/vdpau/Makefile
2969                  src/gallium/targets/xa/Makefile
2970                  src/gallium/targets/xa/xatracker.pc
2971                  src/gallium/targets/xvmc/Makefile
2972                  src/gallium/tests/trivial/Makefile
2973                  src/gallium/tests/unit/Makefile
2974                  src/gallium/winsys/etnaviv/drm/Makefile
2975                  src/gallium/winsys/imx/drm/Makefile
2976                  src/gallium/winsys/freedreno/drm/Makefile
2977                  src/gallium/winsys/i915/drm/Makefile
2978                  src/gallium/winsys/nouveau/drm/Makefile
2979                  src/gallium/winsys/pl111/drm/Makefile
2980                  src/gallium/winsys/radeon/drm/Makefile
2981                  src/gallium/winsys/amdgpu/drm/Makefile
2982                  src/gallium/winsys/svga/drm/Makefile
2983                  src/gallium/winsys/sw/dri/Makefile
2984                  src/gallium/winsys/sw/kms-dri/Makefile
2985                  src/gallium/winsys/sw/null/Makefile
2986                  src/gallium/winsys/sw/wrapper/Makefile
2987                  src/gallium/winsys/sw/xlib/Makefile
2988                  src/gallium/winsys/vc4/drm/Makefile
2989                  src/gallium/winsys/vc5/drm/Makefile
2990                  src/gallium/winsys/virgl/drm/Makefile
2991                  src/gallium/winsys/virgl/vtest/Makefile
2992                  src/gbm/Makefile
2993                  src/gbm/main/gbm.pc
2994                  src/glx/Makefile
2995                  src/glx/apple/Makefile
2996                  src/glx/tests/Makefile
2997                  src/glx/windows/Makefile
2998                  src/glx/windows/windowsdriproto.pc
2999                  src/gtest/Makefile
3000                  src/intel/Makefile
3001                  src/loader/Makefile
3002                  src/mapi/Makefile
3003                  src/mapi/es1api/glesv1_cm.pc
3004                  src/mapi/es2api/glesv2.pc
3005                  src/mapi/glapi/gen/Makefile
3006                  src/mesa/Makefile
3007                  src/mesa/gl.pc
3008                  src/mesa/drivers/dri/dri.pc
3009                  src/mesa/drivers/dri/common/Makefile
3010                  src/mesa/drivers/dri/i915/Makefile
3011                  src/mesa/drivers/dri/i965/Makefile
3012                  src/mesa/drivers/dri/Makefile
3013                  src/mesa/drivers/dri/nouveau/Makefile
3014                  src/mesa/drivers/dri/r200/Makefile
3015                  src/mesa/drivers/dri/radeon/Makefile
3016                  src/mesa/drivers/dri/swrast/Makefile
3017                  src/mesa/drivers/osmesa/Makefile
3018                  src/mesa/drivers/osmesa/osmesa.pc
3019                  src/mesa/drivers/x11/Makefile
3020                  src/mesa/main/tests/Makefile
3021                  src/mesa/state_tracker/tests/Makefile
3022                  src/util/Makefile
3023                  src/util/tests/hash_table/Makefile
3024                  src/util/tests/string_buffer/Makefile
3025                  src/util/xmlpool/Makefile
3026                  src/vulkan/Makefile])
3027
3028 AC_OUTPUT
3029
3030 # Fix up dependencies in *.Plo files, where we changed the extension of a
3031 # source file
3032 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3033
3034 rm -f src/compiler/spirv/spirv_info.lo
3035 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3036
3037 dnl
3038 dnl Output some configuration info for the user
3039 dnl
3040 echo ""
3041 echo "        prefix:          $prefix"
3042 echo "        exec_prefix:     $exec_prefix"
3043 echo "        libdir:          $libdir"
3044 echo "        includedir:      $includedir"
3045
3046 dnl API info
3047 echo ""
3048 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3049
3050 dnl Driver info
3051 echo ""
3052 case "x$enable_osmesa$enable_gallium_osmesa" in
3053 xnoyes)
3054         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3055         ;;
3056 xyesno)
3057         echo "        OSMesa:          lib$OSMESA_LIB"
3058         ;;
3059 xnono)
3060         echo "        OSMesa:          no"
3061         ;;
3062 esac
3063
3064 echo ""
3065 if test "x$enable_dri" != xno; then
3066         echo "        DRI platform:    $dri_platform"
3067         if test -z "$DRI_DIRS"; then
3068             echo "        DRI drivers:     no"
3069         else
3070             echo "        DRI drivers:     $DRI_DIRS"
3071         fi
3072         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3073 fi
3074
3075 case "x$enable_glx" in
3076 xdri)
3077     echo "        GLX:             DRI-based"
3078     ;;
3079 xxlib)
3080     echo "        GLX:             Xlib-based"
3081     ;;
3082 xgallium-xlib)
3083     echo "        GLX:             Xlib-based (Gallium)"
3084     ;;
3085 *)
3086     echo "        GLX:             $enable_glx"
3087     ;;
3088 esac
3089
3090 dnl EGL
3091 echo ""
3092 echo "        EGL:             $enable_egl"
3093 if test "$enable_egl" = yes; then
3094
3095     egl_drivers=""
3096     if test "x$enable_dri" != "xno"; then
3097         egl_drivers="$egl_drivers builtin:egl_dri2"
3098     fi
3099     if test "x$enable_dri3" != "xno"; then
3100         egl_drivers="$egl_drivers builtin:egl_dri3"
3101     fi
3102
3103     echo "        EGL drivers:    $egl_drivers"
3104 fi
3105 if test "x$enable_gbm" = xyes; then
3106     echo "        GBM:             yes"
3107 else
3108     echo "        GBM:             no"
3109 fi
3110
3111     echo "        EGL/Vulkan/VL platforms:   $platforms"
3112
3113 # Vulkan
3114 echo ""
3115 if test "x$VULKAN_DRIVERS" != x; then
3116     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3117     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3118 else
3119     echo "        Vulkan drivers:  no"
3120 fi
3121
3122 echo ""
3123 if test "x$enable_llvm" = xyes; then
3124     echo "        llvm:            yes"
3125     echo "        llvm-config:     $LLVM_CONFIG"
3126     echo "        llvm-version:    $LLVM_VERSION"
3127 else
3128     echo "        llvm:            no"
3129 fi
3130
3131 echo ""
3132 if test -n "$with_gallium_drivers"; then
3133     echo "        Gallium drivers: $gallium_drivers"
3134     echo "        Gallium st:      $gallium_st"
3135 else
3136     echo "        Gallium:         no"
3137 fi
3138
3139 echo ""
3140 if test "x$enable_gallium_extra_hud" != xyes; then
3141     echo "        HUD extra stats: no"
3142 else
3143     echo "        HUD extra stats: yes"
3144 fi
3145
3146 if test "x$enable_lmsensors" != xyes; then
3147     echo "        HUD lmsensors:   no"
3148 else
3149     echo "        HUD lmsensors:   yes"
3150 fi
3151
3152 echo ""
3153 if test "x$HAVE_GALLIUM_SWR" != x; then
3154     echo "        SWR archs:       $swr_archs"
3155 fi
3156
3157 dnl Libraries
3158 echo ""
3159 echo "        Shared libs:     $enable_shared"
3160 echo "        Static libs:     $enable_static"
3161 echo "        Shared-glapi:    $enable_shared_glapi"
3162
3163 dnl Compiler options
3164 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3165 cflags=`echo $CFLAGS | \
3166     $SED 's/^ *//;s/  */ /;s/ *$//'`
3167 cxxflags=`echo $CXXFLAGS | \
3168     $SED 's/^ *//;s/  */ /;s/ *$//'`
3169 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3170 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3171 echo ""
3172 echo "        CFLAGS:          $cflags"
3173 echo "        CXXFLAGS:        $cxxflags"
3174 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3175 echo "        LDFLAGS:         $ldflags"
3176 echo "        Macros:          $defines"
3177 echo ""
3178 if test "x$enable_llvm" = xyes; then
3179     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3180     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3181     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3182     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3183     echo ""
3184 fi
3185 echo "        PYTHON2:         $PYTHON2"
3186
3187 echo ""
3188 echo "        Run '${MAKE-make}' to build Mesa"
3189 echo ""