configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25
  26 dnl Check for progs
  27 AC_PROG_CPP
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_CHECK_PROGS([MAKE], [gmake make])
  31 AC_PATH_PROG([MKDEP], [makedepend])
  32 AC_PATH_PROG([SED], [sed])
  33
  34 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  35 dnl configuration in that case.
  36 AC_PROG_INSTALL
  37 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  38
  39 dnl We need a POSIX shell for parts of the build. Assume we have one
  40 dnl in most cases.
  41 case "$host_os" in
  42 solaris*)
  43     # Solaris /bin/sh is too old/non-POSIX compliant
  44     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  45     SHELL="$POSIX_SHELL"
  46     ;;
  47 esac
  48
  49 MKDEP_OPTIONS=-fdepend
  50 dnl Ask gcc where it's keeping its secret headers
  51 if test "x$GCC" = xyes; then
  52     for dir in include include-fixed; do
  53         GCC_INCLUDES=`$CC -print-file-name=$dir`
  54         if test "x$GCC_INCLUDES" != x && \
  55            test "$GCC_INCLUDES" != "$dir" && \
  56            test -d "$GCC_INCLUDES"; then
  57             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  58         fi
  59     done
  60 fi
  61 AC_SUBST([MKDEP_OPTIONS])
  62
  63 dnl Make sure the pkg-config macros are defined
  64 m4_ifndef([PKG_PROG_PKG_CONFIG],
  65     [m4_fatal([Could not locate the pkg-config autoconf macros.
  66   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  67   are in a different location, try setting the environment variable
  68   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  69 PKG_PROG_PKG_CONFIG()
  70
  71 dnl LIB_DIR - library basename
  72 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  73 AC_SUBST([LIB_DIR])
  74
  75 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  76 _SAVE_LDFLAGS="$LDFLAGS"
  77 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  78 AC_SUBST([EXTRA_LIB_PATH])
  79
  80 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  81 _SAVE_CPPFLAGS="$CPPFLAGS"
  82 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  83 AC_SUBST([X11_INCLUDES])
  84
  85 dnl Compiler macros
  86 DEFINES=""
  87 AC_SUBST([DEFINES])
  88 case "$host_os" in
  89 linux*|*-gnu*|gnu*)
  90     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  91     ;;
  92 solaris*)
  93     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  94     ;;
  95 cygwin*)
  96     DEFINES="$DEFINES -DPTHREADS"
  97     ;;
  98 esac
  99
 100 dnl Add flags for gcc and g++
 101 if test "x$GCC" = xyes; then
 102     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 103
 104     # Enable -fvisibility=hidden if using a gcc that supports it
 105     save_CFLAGS="$CFLAGS"
 106     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 107     CFLAGS="$CFLAGS -fvisibility=hidden"
 108     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 109                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 110
 111     # Work around aliasing bugs - developers should comment this out
 112     CFLAGS="$CFLAGS -fno-strict-aliasing"
 113 fi
 114 if test "x$GXX" = xyes; then
 115     CXXFLAGS="$CXXFLAGS -Wall"
 116
 117     # Work around aliasing bugs - developers should comment this out
 118     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 119 fi
 120
 121 dnl These should be unnecessary, but let the user set them if they want
 122 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 123     Default is to use CFLAGS.])
 124 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 125     compiler. Default is to use CFLAGS.])
 126 AC_SUBST([OPT_FLAGS])
 127 AC_SUBST([ARCH_FLAGS])
 128
 129 dnl
 130 dnl Hacks to enable 32 or 64 bit build
 131 dnl
 132 AC_ARG_ENABLE([32-bit],
 133     [AS_HELP_STRING([--enable-32-bit],
 134         [build 32-bit libraries @<:@default=auto@:>@])],
 135     [enable_32bit="$enableval"],
 136     [enable_32bit=auto]
 137 )
 138 if test "x$enable_32bit" = xyes; then
 139     if test "x$GCC" = xyes; then
 140         CFLAGS="$CFLAGS -m32"
 141         ARCH_FLAGS="$ARCH_FLAGS -m32"
 142     fi
 143     if test "x$GXX" = xyes; then
 144         CXXFLAGS="$CXXFLAGS -m32"
 145     fi
 146 fi
 147 AC_ARG_ENABLE([64-bit],
 148     [AS_HELP_STRING([--enable-64-bit],
 149         [build 64-bit libraries @<:@default=auto@:>@])],
 150     [enable_64bit="$enableval"],
 151     [enable_64bit=auto]
 152 )
 153 if test "x$enable_64bit" = xyes; then
 154     if test "x$GCC" = xyes; then
 155         CFLAGS="$CFLAGS -m64"
 156     fi
 157     if test "x$GXX" = xyes; then
 158         CXXFLAGS="$CXXFLAGS -m64"
 159     fi
 160 fi
 161
 162 dnl
 163 dnl shared/static libraries, mimic libtool options
 164 dnl
 165 AC_ARG_ENABLE([static],
 166     [AS_HELP_STRING([--enable-static],
 167         [build static libraries @<:@default=disabled@:>@])],
 168     [enable_static="$enableval"],
 169     [enable_static=no]
 170 )
 171 case "x$enable_static" in
 172 xyes|xno ) ;;
 173 x ) enable_static=no ;;
 174 * )
 175     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 176     ;;
 177 esac
 178 AC_ARG_ENABLE([shared],
 179     [AS_HELP_STRING([--disable-shared],
 180         [build shared libraries @<:@default=enabled@:>@])],
 181     [enable_shared="$enableval"],
 182     [enable_shared=yes]
 183 )
 184 case "x$enable_shared" in
 185 xyes|xno ) ;;
 186 x ) enable_shared=yes ;;
 187 * )
 188     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 189     ;;
 190 esac
 191
 192 dnl Can't have static and shared libraries, default to static if user
 193 dnl explicitly requested. If both disabled, set to static since shared
 194 dnl was explicitly requirested.
 195 case "x$enable_static$enable_shared" in
 196 xyesyes )
 197     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 198     enable_shared=no
 199     ;;
 200 xnono )
 201     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 202     enable_static=yes
 203     ;;
 204 esac
 205
 206 dnl
 207 dnl mklib options
 208 dnl
 209 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 210 if test "$enable_static" = yes; then
 211     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 212 fi
 213 AC_SUBST([MKLIB_OPTIONS])
 214
 215 dnl
 216 dnl other compiler options
 217 dnl
 218 AC_ARG_ENABLE([debug],
 219     [AS_HELP_STRING([--enable-debug],
 220         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 221     [enable_debug="$enableval"],
 222     [enable_debug=no]
 223 )
 224 if test "x$enable_debug" = xyes; then
 225     DEFINES="$DEFINES -DDEBUG"
 226     if test "x$GCC" = xyes; then
 227         CFLAGS="$CFLAGS -g"
 228     fi
 229     if test "x$GXX" = xyes; then
 230         CXXFLAGS="$CXXFLAGS -g"
 231     fi
 232 fi
 233
 234 dnl
 235 dnl library names
 236 dnl
 237 if test "$enable_static" = yes; then
 238     LIB_EXTENSION='a'
 239 else
 240     case "$host_os" in
 241     darwin* )
 242         LIB_EXTENSION='dylib' ;;
 243     cygwin* )
 244         LIB_EXTENSION='dll' ;;
 245     aix* )
 246         LIB_EXTENSION='a' ;;
 247     * )
 248         LIB_EXTENSION='so' ;;
 249     esac
 250 fi
 251
 252 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 253 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 254 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 255 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 256 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 257 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 258
 259 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 260 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 261 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 262 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 263 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 264 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 265
 266 AC_SUBST([GL_LIB_NAME])
 267 AC_SUBST([GLU_LIB_NAME])
 268 AC_SUBST([GLUT_LIB_NAME])
 269 AC_SUBST([GLW_LIB_NAME])
 270 AC_SUBST([OSMESA_LIB_NAME])
 271 AC_SUBST([EGL_LIB_NAME])
 272
 273 AC_SUBST([GL_LIB_GLOB])
 274 AC_SUBST([GLU_LIB_GLOB])
 275 AC_SUBST([GLUT_LIB_GLOB])
 276 AC_SUBST([GLW_LIB_GLOB])
 277 AC_SUBST([OSMESA_LIB_GLOB])
 278 AC_SUBST([EGL_LIB_GLOB])
 279
 280 dnl
 281 dnl Arch/platform-specific settings
 282 dnl
 283 AC_ARG_ENABLE([asm],
 284     [AS_HELP_STRING([--disable-asm],
 285         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 286     [enable_asm="$enableval"],
 287     [enable_asm=yes]
 288 )
 289 asm_arch=""
 290 ASM_FLAGS=""
 291 MESA_ASM_SOURCES=""
 292 GLAPI_ASM_SOURCES=""
 293 AC_MSG_CHECKING([whether to enable assembly])
 294 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 295 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 296 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 297     case "$host_cpu" in
 298     i?86 | x86_64)
 299         enable_asm=no
 300         AC_MSG_RESULT([no, cross compiling])
 301         ;;
 302     esac
 303 fi
 304 # check for supported arches
 305 if test "x$enable_asm" = xyes; then
 306     case "$host_cpu" in
 307     i?86)
 308         case "$host_os" in
 309         linux* | *freebsd* | dragonfly*)
 310             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 311             ;;
 312         esac
 313         ;;
 314     x86_64)
 315         case "$host_os" in
 316         linux* | *freebsd* | dragonfly*)
 317             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 318             ;;
 319         esac
 320         ;;
 321     powerpc)
 322         case "$host_os" in
 323         linux*)
 324             asm_arch=ppc
 325             ;;
 326         esac
 327         ;;
 328     sparc*)
 329         case "$host_os" in
 330         linux*)
 331             asm_arch=sparc
 332             ;;
 333         esac
 334         ;;
 335     esac
 336
 337     case "$asm_arch" in
 338     x86)
 339         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 340         MESA_ASM_SOURCES='$(X86_SOURCES)'
 341         GLAPI_ASM_SOURCES='$(X86_API)'
 342         AC_MSG_RESULT([yes, x86])
 343         ;;
 344     x86_64)
 345         ASM_FLAGS="-DUSE_X86_64_ASM"
 346         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 347         GLAPI_ASM_SOURCES='$(X86-64_API)'
 348         AC_MSG_RESULT([yes, x86_64])
 349         ;;
 350     ppc)
 351         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 352         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 353         AC_MSG_RESULT([yes, ppc])
 354         ;;
 355     sparc)
 356         ASM_FLAGS="-DUSE_SPARC_ASM"
 357         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 358         GLAPI_ASM_SOURCES='$(SPARC_API)'
 359         AC_MSG_RESULT([yes, sparc])
 360         ;;
 361     *)
 362         AC_MSG_RESULT([no, platform not supported])
 363         ;;
 364     esac
 365 fi
 366 AC_SUBST([ASM_FLAGS])
 367 AC_SUBST([MESA_ASM_SOURCES])
 368 AC_SUBST([GLAPI_ASM_SOURCES])
 369
 370 dnl PIC code macro
 371 MESA_PIC_FLAGS
 372
 373 dnl Check to see if dlopen is in default libraries (like Solaris, which
 374 dnl has it in libc), or if libdl is needed to get it.
 375 AC_CHECK_FUNC([dlopen], [],
 376     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 377
 378 dnl See if posix_memalign is available
 379 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 380
 381 dnl SELinux awareness.
 382 AC_ARG_ENABLE([selinux],
 383     [AS_HELP_STRING([--enable-selinux],
 384         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 385     [MESA_SELINUX="$enableval"],
 386     [MESA_SELINUX=no])
 387 if test "x$enable_selinux" = "xyes"; then
 388     AC_CHECK_HEADER([selinux/selinux.h],[],
 389                     [AC_MSG_ERROR([SELinux headers not found])])
 390     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 391                  [AC_MSG_ERROR([SELinux library not found])])
 392     SELINUX_LIBS="-lselinux"
 393     DEFINES="$DEFINES -DMESA_SELINUX"
 394 fi
 395
 396 dnl
 397 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 398 dnl More later: directfb, fbdev, ...
 399 dnl
 400 default_driver="xlib"
 401
 402 case "$host_os" in
 403 linux*)
 404     case "$host_cpu" in
 405     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 406     esac
 407     ;;
 408 *freebsd* | dragonfly*)
 409     case "$host_cpu" in
 410     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 411     esac
 412     ;;
 413 esac
 414
 415 AC_ARG_WITH([driver],
 416     [AS_HELP_STRING([--with-driver=DRIVER],
 417         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 418     [mesa_driver="$withval"],
 419     [mesa_driver="$default_driver"])
 420 dnl Check for valid option
 421 case "x$mesa_driver" in
 422 xxlib|xdri|xosmesa)
 423     ;;
 424 *)
 425     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 426     ;;
 427 esac
 428
 429 dnl
 430 dnl Driver specific build directories
 431 dnl
 432
 433 dnl this variable will be prepended to SRC_DIRS and is not exported
 434 CORE_DIRS="glsl mesa"
 435
 436 SRC_DIRS="glew"
 437 GLU_DIRS="sgi"
 438 WINDOW_SYSTEM=""
 439 GALLIUM_DIRS="auxiliary drivers state_trackers"
 440 GALLIUM_WINSYS_DIRS=""
 441 GALLIUM_WINSYS_DRM_DIRS=""
 442 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 443 GALLIUM_STATE_TRACKERS_DIRS=""
 444
 445 case "$mesa_driver" in
 446 xlib)
 447     DRIVER_DIRS="x11"
 448     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 449     ;;
 450 dri)
 451     SRC_DIRS="$SRC_DIRS glx"
 452     DRIVER_DIRS="dri"
 453     WINDOW_SYSTEM="dri"
 454     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 455     ;;
 456 osmesa)
 457     DRIVER_DIRS="osmesa"
 458     ;;
 459 esac
 460 AC_SUBST([SRC_DIRS])
 461 AC_SUBST([GLU_DIRS])
 462 AC_SUBST([DRIVER_DIRS])
 463 AC_SUBST([WINDOW_SYSTEM])
 464 AC_SUBST([GALLIUM_DIRS])
 465 AC_SUBST([GALLIUM_WINSYS_DIRS])
 466 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 467 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 468 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 469
 470 dnl
 471 dnl User supplied program configuration
 472 dnl
 473 if test -d "$srcdir/progs/demos"; then
 474     default_demos=yes
 475 else
 476     default_demos=no
 477 fi
 478 AC_ARG_WITH([demos],
 479     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 480         [optional comma delimited demo directories to build
 481         @<:@default=auto if source available@:>@])],
 482     [with_demos="$withval"],
 483     [with_demos="$default_demos"])
 484 if test "x$with_demos" = x; then
 485     with_demos=no
 486 fi
 487
 488 dnl If $with_demos is yes, directories will be added as libs available
 489 PROGRAM_DIRS=""
 490 case "$with_demos" in
 491 no) ;;
 492 yes)
 493     # If the driver isn't osmesa, we have libGL and can build xdemos
 494     if test "$mesa_driver" != osmesa; then
 495         PROGRAM_DIRS="xdemos"
 496     fi
 497     ;;
 498 *)
 499     # verify the requested demos directories exist
 500     demos=`IFS=,; echo $with_demos`
 501     for demo in $demos; do
 502         test -d "$srcdir/progs/$demo" || \
 503             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 504     done
 505     PROGRAM_DIRS="$demos"
 506     ;;
 507 esac
 508
 509 dnl
 510 dnl Find out if X is available. The variable have_x is set if libX11 is
 511 dnl found to mimic AC_PATH_XTRA.
 512 dnl
 513 if test -n "$PKG_CONFIG"; then
 514     AC_MSG_CHECKING([pkg-config files for X11 are available])
 515     PKG_CHECK_EXISTS([x11],[
 516         x11_pkgconfig=yes
 517         have_x=yes
 518         ],[
 519         x11_pkgconfig=no
 520     ])
 521     AC_MSG_RESULT([$x11_pkgconfig])
 522 else
 523     x11_pkgconfig=no
 524 fi
 525 dnl Use the autoconf macro if no pkg-config files
 526 if test "$x11_pkgconfig" = no; then
 527     AC_PATH_XTRA
 528 fi
 529
 530 dnl Try to tell the user that the --x-* options are only used when
 531 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 532 m4_divert_once([HELP_BEGIN],
 533 [These options are only used when the X libraries cannot be found by the
 534 pkg-config utility.])
 535
 536 dnl We need X for xlib and dri, so bomb now if it's not found
 537 case "$mesa_driver" in
 538 xlib|dri)
 539     if test "$no_x" = yes; then
 540         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 541     fi
 542     ;;
 543 esac
 544
 545 dnl XCB - this is only used for GLX right now
 546 AC_ARG_ENABLE([xcb],
 547     [AS_HELP_STRING([--enable-xcb],
 548         [use XCB for GLX @<:@default=disabled@:>@])],
 549     [enable_xcb="$enableval"],
 550     [enable_xcb=no])
 551 if test "x$enable_xcb" = xyes; then
 552     DEFINES="$DEFINES -DUSE_XCB"
 553 else
 554     enable_xcb=no
 555 fi
 556
 557 dnl
 558 dnl libGL configuration per driver
 559 dnl
 560 case "$mesa_driver" in
 561 xlib)
 562     if test "$x11_pkgconfig" = yes; then
 563         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 564         GL_PC_REQ_PRIV="x11 xext"
 565         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 566         GL_LIB_DEPS="$XLIBGL_LIBS"
 567     else
 568         # should check these...
 569         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 570         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 571         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 572         GL_PC_CFLAGS="$X11_INCLUDES"
 573     fi
 574     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 575     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 576
 577     # if static, move the external libraries to the programs
 578     # and empty the libraries for libGL
 579     if test "$enable_static" = yes; then
 580         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 581         GL_LIB_DEPS=""
 582     fi
 583     ;;
 584 dri)
 585     # DRI must be shared, I think
 586     if test "$enable_static" = yes; then
 587         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 588     fi
 589
 590     # Check for libdrm
 591     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 592     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 593     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 594     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 595     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 596
 597     # find the DRI deps for libGL
 598     if test "$x11_pkgconfig" = yes; then
 599         # add xcb modules if necessary
 600         dri_modules="x11 xext xxf86vm xdamage xfixes"
 601         if test "$enable_xcb" = yes; then
 602             dri_modules="$dri_modules x11-xcb xcb-glx"
 603         fi
 604
 605         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 606         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 607         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 608         GL_LIB_DEPS="$DRIGL_LIBS"
 609     else
 610         # should check these...
 611         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 612         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 613         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 614         GL_PC_CFLAGS="$X11_INCLUDES"
 615
 616         # XCB can only be used from pkg-config
 617         if test "$enable_xcb" = yes; then
 618             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 619             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 620             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 621             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 622         fi
 623     fi
 624
 625     # need DRM libs, -lpthread, etc.
 626     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 627     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 628     ;;
 629 osmesa)
 630     # No libGL for osmesa
 631     GL_LIB_DEPS=""
 632     ;;
 633 esac
 634 AC_SUBST([GL_LIB_DEPS])
 635 AC_SUBST([GL_PC_REQ_PRIV])
 636 AC_SUBST([GL_PC_LIB_PRIV])
 637 AC_SUBST([GL_PC_CFLAGS])
 638 AC_SUBST([DRI_PC_REQ_PRIV])
 639
 640 dnl
 641 dnl More X11 setup
 642 dnl
 643 if test "$mesa_driver" = xlib; then
 644     DEFINES="$DEFINES -DUSE_XSHM"
 645 fi
 646
 647 dnl
 648 dnl More DRI setup
 649 dnl
 650 AC_ARG_ENABLE([glx-tls],
 651     [AS_HELP_STRING([--enable-glx-tls],
 652         [enable TLS support in GLX @<:@default=disabled@:>@])],
 653     [GLX_USE_TLS="$enableval"],
 654     [GLX_USE_TLS=no])
 655 dnl Directory for DRI drivers
 656 AC_ARG_WITH([dri-driverdir],
 657     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 658         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 659     [DRI_DRIVER_INSTALL_DIR="$withval"],
 660     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 661 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 662 dnl Extra search path for DRI drivers
 663 AC_ARG_WITH([dri-searchpath],
 664     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 665         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 666     [DRI_DRIVER_SEARCH_DIR="$withval"],
 667     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 668 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 669 dnl Direct rendering or just indirect rendering
 670 AC_ARG_ENABLE([driglx-direct],
 671     [AS_HELP_STRING([--disable-driglx-direct],
 672         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 673     [driglx_direct="$enableval"],
 674     [driglx_direct="yes"])
 675 dnl Which drivers to build - default is chosen by platform
 676 AC_ARG_WITH([dri-drivers],
 677     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 678         [comma delimited DRI drivers list, e.g.
 679         "swrast,i965,radeon" @<:@default=auto@:>@])],
 680     [with_dri_drivers="$withval"],
 681     [with_dri_drivers=yes])
 682 if test "x$with_dri_drivers" = x; then
 683     with_dri_drivers=no
 684 fi
 685
 686 dnl If $with_dri_drivers is yes, directories will be added through
 687 dnl platform checks
 688 DRI_DIRS=""
 689 case "$with_dri_drivers" in
 690 no) ;;
 691 yes)
 692     DRI_DIRS="yes"
 693     ;;
 694 *)
 695     # verify the requested driver directories exist
 696     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 697     for driver in $dri_drivers; do
 698         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 699             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 700     done
 701     DRI_DIRS="$dri_drivers"
 702     ;;
 703 esac
 704
 705 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 706 if test "$mesa_driver" = dri; then
 707     # Use TLS in GLX?
 708     if test "x$GLX_USE_TLS" = xyes; then
 709         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 710     fi
 711
 712     # Platform specific settings and drivers to build
 713     case "$host_os" in
 714     linux*)
 715         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 716         if test "x$driglx_direct" = xyes; then
 717             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 718         fi
 719         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 720
 721         case "$host_cpu" in
 722         x86_64)
 723             # ffb, gamma, and sis are missing because they have not be
 724             # converted to use the new interface.  i810 are missing
 725             # because there is no x86-64 system where they could *ever*
 726             # be used.
 727             if test "x$DRI_DIRS" = "xyes"; then
 728                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 729                     savage tdfx unichrome swrast"
 730             fi
 731             ;;
 732         powerpc*)
 733             # Build only the drivers for cards that exist on PowerPC.
 734             # At some point MGA will be added, but not yet.
 735             if test "x$DRI_DIRS" = "xyes"; then
 736                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 737             fi
 738             ;;
 739         sparc*)
 740             # Build only the drivers for cards that exist on sparc`
 741             if test "x$DRI_DIRS" = "xyes"; then
 742                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon ffb swrast"
 743             fi
 744             ;;
 745         esac
 746         ;;
 747     freebsd* | dragonfly*)
 748         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 749         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 750         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 751         if test "x$driglx_direct" = xyes; then
 752             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 753         fi
 754         if test "x$GXX" = xyes; then
 755             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 756         fi
 757
 758         # ffb and gamma are missing because they have not been converted
 759         # to use the new interface.
 760         if test "x$DRI_DIRS" = "xyes"; then
 761             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 762                 unichrome savage sis swrast"
 763         fi
 764         ;;
 765     gnu*)
 766         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 767         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 768         ;;
 769     solaris*)
 770         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 771         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 772         if test "x$driglx_direct" = xyes; then
 773             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 774         fi
 775         ;;
 776     esac
 777
 778     # default drivers
 779     if test "x$DRI_DIRS" = "xyes"; then
 780         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 781             savage sis tdfx unichrome ffb swrast"
 782     fi
 783
 784     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 785
 786     # Check for expat
 787     EXPAT_INCLUDES=""
 788     EXPAT_LIB=-lexpat
 789     AC_ARG_WITH([expat],
 790         [AS_HELP_STRING([--with-expat=DIR],
 791             [expat install directory])],[
 792         EXPAT_INCLUDES="-I$withval/include"
 793         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 794         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 795         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 796         ])
 797     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 798     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 799         [AC_MSG_ERROR([Expat required for DRI.])])
 800
 801     # put all the necessary libs together
 802     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 803 fi
 804 AC_SUBST([DRI_DIRS])
 805 AC_SUBST([EXPAT_INCLUDES])
 806 AC_SUBST([DRI_LIB_DEPS])
 807
 808 case $DRI_DIRS in
 809 *i915*|*i965*)
 810     PKG_CHECK_MODULES([INTEL], [libdrm_intel])
 811     ;;
 812 esac
 813
 814 case $DRI_DIRS in
 815 *radeon*|*r200*|*r300*|*r600*)
 816     PKG_CHECK_MODULES([LIBDRM_RADEON],
 817                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 818                       HAVE_LIBDRM_RADEON=yes,
 819                       HAVE_LIBDRM_RADEON=no)
 820
 821     if test "$HAVE_LIBDRM_RADEON" = yes; then
 822         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 823         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 824     fi
 825     ;;
 826 esac
 827 AC_SUBST([RADEON_CFLAGS])
 828 AC_SUBST([RADEON_LDFLAGS])
 829
 830
 831 dnl
 832 dnl OSMesa configuration
 833 dnl
 834 if test "$mesa_driver" = xlib; then
 835     default_gl_osmesa=yes
 836 else
 837     default_gl_osmesa=no
 838 fi
 839 AC_ARG_ENABLE([gl-osmesa],
 840     [AS_HELP_STRING([--enable-gl-osmesa],
 841         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 842     [gl_osmesa="$enableval"],
 843     [gl_osmesa="$default_gl_osmesa"])
 844 if test "x$gl_osmesa" = xyes; then
 845     if test "$mesa_driver" = osmesa; then
 846         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 847     else
 848         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 849     fi
 850 fi
 851
 852 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 853 AC_ARG_WITH([osmesa-bits],
 854     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 855         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 856     [osmesa_bits="$withval"],
 857     [osmesa_bits=8])
 858 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 859     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 860     osmesa_bits=8
 861 fi
 862 case "x$osmesa_bits" in
 863 x8)
 864     OSMESA_LIB=OSMesa
 865     ;;
 866 x16|x32)
 867     OSMESA_LIB="OSMesa$osmesa_bits"
 868     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 869     ;;
 870 *)
 871     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 872     ;;
 873 esac
 874 AC_SUBST([OSMESA_LIB])
 875
 876 case "$mesa_driver" in
 877 osmesa)
 878     # only link libraries with osmesa if shared
 879     if test "$enable_static" = no; then
 880         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 881     else
 882         OSMESA_LIB_DEPS=""
 883     fi
 884     OSMESA_MESA_DEPS=""
 885     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 886     ;;
 887 *)
 888     # Link OSMesa to libGL otherwise
 889     OSMESA_LIB_DEPS=""
 890     # only link libraries with osmesa if shared
 891     if test "$enable_static" = no; then
 892         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 893     else
 894         OSMESA_MESA_DEPS=""
 895     fi
 896     OSMESA_PC_REQ="gl"
 897     ;;
 898 esac
 899 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 900 AC_SUBST([OSMESA_LIB_DEPS])
 901 AC_SUBST([OSMESA_MESA_DEPS])
 902 AC_SUBST([OSMESA_PC_REQ])
 903 AC_SUBST([OSMESA_PC_LIB_PRIV])
 904
 905 dnl
 906 dnl EGL configuration
 907 dnl
 908 AC_ARG_ENABLE([egl],
 909     [AS_HELP_STRING([--disable-egl],
 910         [disable EGL library @<:@default=enabled@:>@])],
 911     [enable_egl="$enableval"],
 912     [enable_egl=yes])
 913 if test "x$enable_egl" = xyes; then
 914     SRC_DIRS="$SRC_DIRS egl"
 915     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 916     EGL_DRIVERS_DIRS=""
 917     if test "$enable_static" != yes; then
 918         # build egl_glx when libGL is built
 919         if test "$mesa_driver" != osmesa; then
 920             EGL_DRIVERS_DIRS="glx"
 921         fi
 922
 923         # build egl_dri2 when xcb-dri2 is available
 924         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
 925                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 926         if test "$have_xcb_dri2" = yes; then
 927             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
 928         fi
 929     fi
 930
 931     if test "$with_demos" = yes; then
 932         PROGRAM_DIRS="$PROGRAM_DIRS egl"
 933     fi
 934 fi
 935 AC_SUBST([EGL_LIB_DEPS])
 936 AC_SUBST([EGL_DRIVERS_DIRS])
 937
 938 dnl
 939 dnl GLU configuration
 940 dnl
 941 AC_ARG_ENABLE([glu],
 942     [AS_HELP_STRING([--disable-glu],
 943         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 944     [enable_glu="$enableval"],
 945     [enable_glu=yes])
 946 if test "x$enable_glu" = xyes; then
 947     SRC_DIRS="$SRC_DIRS glu"
 948
 949     case "$mesa_driver" in
 950     osmesa)
 951         # If GLU is available and we have libOSMesa (not 16 or 32),
 952         # we can build the osdemos
 953         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 954             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 955         fi
 956
 957         # Link libGLU to libOSMesa instead of libGL
 958         GLU_LIB_DEPS=""
 959         GLU_PC_REQ="osmesa"
 960         if test "$enable_static" = no; then
 961             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 962         else
 963             GLU_MESA_DEPS=""
 964         fi
 965         ;;
 966     *)
 967         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 968         GLU_PC_REQ="gl"
 969         GLU_PC_LIB_PRIV="-lm"
 970         if test "$enable_static" = no; then
 971             GLU_LIB_DEPS="-lm"
 972             GLU_MESA_DEPS='-l$(GL_LIB)'
 973         else
 974             GLU_LIB_DEPS=""
 975             GLU_MESA_DEPS=""
 976             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 977         fi
 978         ;;
 979     esac
 980 fi
 981 if test "$enable_static" = no; then
 982     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 983 fi
 984 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 985 AC_SUBST([GLU_LIB_DEPS])
 986 AC_SUBST([GLU_MESA_DEPS])
 987 AC_SUBST([GLU_PC_REQ])
 988 AC_SUBST([GLU_PC_REQ_PRIV])
 989 AC_SUBST([GLU_PC_LIB_PRIV])
 990 AC_SUBST([GLU_PC_CFLAGS])
 991
 992 dnl
 993 dnl GLw configuration
 994 dnl
 995 AC_ARG_ENABLE([glw],
 996     [AS_HELP_STRING([--disable-glw],
 997         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 998     [enable_glw="$enableval"],
 999     [enable_glw=yes])
1000 dnl Don't build GLw on osmesa
1001 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1002     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1003     enable_glw=no
1004 fi
1005 AC_ARG_ENABLE([motif],
1006     [AS_HELP_STRING([--enable-motif],
1007         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1008     [enable_motif="$enableval"],
1009     [enable_motif=no])
1010
1011 if test "x$enable_glw" = xyes; then
1012     SRC_DIRS="$SRC_DIRS glw"
1013     if test "$x11_pkgconfig" = yes; then
1014         PKG_CHECK_MODULES([GLW],[x11 xt])
1015         GLW_PC_REQ_PRIV="x11 xt"
1016         GLW_LIB_DEPS="$GLW_LIBS"
1017     else
1018         # should check these...
1019         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1020         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1021         GLW_PC_CFLAGS="$X11_INCLUDES"
1022     fi
1023
1024     GLW_SOURCES="GLwDrawA.c"
1025     MOTIF_CFLAGS=
1026     if test "x$enable_motif" = xyes; then
1027         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1028         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1029         if test "x$MOTIF_CONFIG" != xno; then
1030             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1031             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1032         else
1033             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1034                 [AC_MSG_ERROR([Can't locate Motif headers])])
1035             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1036                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1037         fi
1038         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1039         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1040         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1041         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1042     fi
1043
1044     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1045     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1046     if test "$enable_static" = no; then
1047         GLW_MESA_DEPS='-l$(GL_LIB)'
1048         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1049     else
1050         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1051         GLW_LIB_DEPS=""
1052         GLW_MESA_DEPS=""
1053     fi
1054 fi
1055 AC_SUBST([GLW_LIB_DEPS])
1056 AC_SUBST([GLW_MESA_DEPS])
1057 AC_SUBST([GLW_SOURCES])
1058 AC_SUBST([MOTIF_CFLAGS])
1059 AC_SUBST([GLW_PC_REQ_PRIV])
1060 AC_SUBST([GLW_PC_LIB_PRIV])
1061 AC_SUBST([GLW_PC_CFLAGS])
1062
1063 dnl
1064 dnl GLUT configuration
1065 dnl
1066 if test -f "$srcdir/include/GL/glut.h"; then
1067     default_glut=yes
1068 else
1069     default_glut=no
1070 fi
1071 AC_ARG_ENABLE([glut],
1072     [AS_HELP_STRING([--disable-glut],
1073         [enable GLUT library @<:@default=enabled if source available@:>@])],
1074     [enable_glut="$enableval"],
1075     [enable_glut="$default_glut"])
1076
1077 dnl Can't build glut if GLU not available
1078 if test "x$enable_glu$enable_glut" = xnoyes; then
1079     AC_MSG_WARN([Disabling glut since GLU is disabled])
1080     enable_glut=no
1081 fi
1082 dnl Don't build glut on osmesa
1083 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1084     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1085     enable_glut=no
1086 fi
1087
1088 if test "x$enable_glut" = xyes; then
1089     SRC_DIRS="$SRC_DIRS glut/glx"
1090     GLUT_CFLAGS=""
1091     if test "x$GCC" = xyes; then
1092         GLUT_CFLAGS="-fexceptions"
1093     fi
1094     if test "$x11_pkgconfig" = yes; then
1095         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1096         GLUT_PC_REQ_PRIV="x11 xmu xi"
1097         GLUT_LIB_DEPS="$GLUT_LIBS"
1098     else
1099         # should check these...
1100         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1101         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1102         GLUT_PC_CFLAGS="$X11_INCLUDES"
1103     fi
1104     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1105     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1106
1107     # If glut is available, we can build most programs
1108     if test "$with_demos" = yes; then
1109         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1110     fi
1111
1112     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1113     if test "$enable_static" = no; then
1114         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1115     else
1116         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1117         GLUT_LIB_DEPS=""
1118         GLUT_MESA_DEPS=""
1119     fi
1120 fi
1121 AC_SUBST([GLUT_LIB_DEPS])
1122 AC_SUBST([GLUT_MESA_DEPS])
1123 AC_SUBST([GLUT_CFLAGS])
1124 AC_SUBST([GLUT_PC_REQ_PRIV])
1125 AC_SUBST([GLUT_PC_LIB_PRIV])
1126 AC_SUBST([GLUT_PC_CFLAGS])
1127
1128 dnl
1129 dnl Program library dependencies
1130 dnl    Only libm is added here if necessary as the libraries should
1131 dnl    be pulled in by the linker
1132 dnl
1133 if test "x$APP_LIB_DEPS" = x; then
1134     case "$host_os" in
1135     solaris*)
1136         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1137         ;;
1138     cygwin*)
1139         APP_LIB_DEPS="-lX11"
1140         ;;
1141     *)
1142         APP_LIB_DEPS="-lm"
1143         ;;
1144     esac
1145 fi
1146 AC_SUBST([APP_LIB_DEPS])
1147 AC_SUBST([PROGRAM_DIRS])
1148
1149 dnl
1150 dnl Gallium configuration
1151 dnl
1152 AC_ARG_ENABLE([gallium],
1153     [AS_HELP_STRING([--disable-gallium],
1154         [build gallium @<:@default=enabled@:>@])],
1155     [enable_gallium="$enableval"],
1156     [enable_gallium=yes])
1157 if test "x$enable_gallium" = xyes; then
1158     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1159 fi
1160
1161 dnl
1162 dnl Gallium state trackers configuration
1163 dnl
1164 AC_ARG_WITH([state-trackers],
1165     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1166         [comma delimited state_trackers list, e.g.
1167         "egl,glx" @<:@default=auto@:>@])],
1168     [with_state_trackers="$withval"],
1169     [with_state_trackers=yes])
1170
1171 case "$with_state_trackers" in
1172 no)
1173     GALLIUM_STATE_TRACKERS_DIRS=""
1174     ;;
1175 yes)
1176     # look at what else is built
1177     case "$mesa_driver" in
1178     xlib)
1179         GALLIUM_STATE_TRACKERS_DIRS=glx
1180         ;;
1181     dri)
1182         GALLIUM_STATE_TRACKERS_DIRS="dri"
1183         if test "x$enable_egl" = xyes; then
1184             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1185         fi
1186         # Have only tested st/xorg on 1.6.0 servers
1187         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0],
1188             HAVE_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1189             HAVE_XORG="no")
1190         ;;
1191     esac
1192     ;;
1193 *)
1194     # verify the requested state tracker exist
1195     state_trackers=`IFS=', '; echo $with_state_trackers`
1196     for tracker in $state_trackers; do
1197         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1198             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1199
1200         case "$tracker" in
1201         egl)
1202             if test "x$enable_egl" != xyes; then
1203                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1204             fi
1205             ;;
1206         xorg)
1207             PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1208                   HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1209                   HAVE_XEXTPROTO_71="no")
1210             ;;
1211         es)
1212             # mesa/es is required to build es state tracker
1213             CORE_DIRS="$CORE_DIRS mesa/es"
1214             ;;
1215         esac
1216     done
1217     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1218     ;;
1219 esac
1220
1221 AC_ARG_WITH([egl-displays],
1222     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1223         [comma delimited native displays libEGL supports, e.g.
1224         "x11,kms" @<:@default=auto@:>@])],
1225     [with_egl_displays="$withval"],
1226     [with_egl_displays=yes])
1227
1228 EGL_DISPLAYS=""
1229 case "$with_egl_displays" in
1230 yes)
1231     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1232         EGL_DISPLAYS="x11"
1233     fi
1234     ;;
1235 *)
1236     if test "x$enable_egl" != xyes; then
1237         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1238     fi
1239     # verify the requested driver directories exist
1240     egl_displays=`IFS=', '; echo $with_egl_displays`
1241     for dpy in $egl_displays; do
1242         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1243             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1244     done
1245     EGL_DISPLAYS="$egl_displays"
1246     ;;
1247 esac
1248 AC_SUBST([EGL_DISPLAYS])
1249
1250 AC_ARG_WITH([egl-driver-dir],
1251     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1252                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1253     [EGL_DRIVER_INSTALL_DIR="$withval"],
1254     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1255 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1256
1257 AC_ARG_WITH([xorg-driver-dir],
1258     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1259                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1260     [XORG_DRIVER_INSTALL_DIR="$withval"],
1261     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1262 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1263
1264 AC_ARG_WITH([max-width],
1265     [AS_HELP_STRING([--with-max-width=N],
1266                     [Maximum framebuffer width (4096)])],
1267     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1268      AS_IF([test "${withval}" -gt "4096"],
1269            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1270 )
1271 AC_ARG_WITH([max-height],
1272     [AS_HELP_STRING([--with-max-height=N],
1273                     [Maximum framebuffer height (4096)])],
1274     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1275      AS_IF([test "${withval}" -gt "4096"],
1276            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1277 )
1278
1279 dnl
1280 dnl Gallium SVGA configuration
1281 dnl
1282 AC_ARG_ENABLE([gallium-svga],
1283     [AS_HELP_STRING([--enable-gallium-svga],
1284         [build gallium SVGA @<:@default=disabled@:>@])],
1285     [enable_gallium_svga="$enableval"],
1286     [enable_gallium_svga=auto])
1287 if test "x$enable_gallium_svga" = xyes; then
1288     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS vmware"
1289     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1290 elif test "x$enable_gallium_svga" = xauto; then
1291     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1292 fi
1293
1294 dnl
1295 dnl Gallium Intel configuration
1296 dnl
1297 AC_ARG_ENABLE([gallium-intel],
1298     [AS_HELP_STRING([--enable-gallium-intel],
1299         [build gallium intel @<:@default=disabled@:>@])],
1300     [enable_gallium_intel="$enableval"],
1301     [enable_gallium_intel=auto])
1302 if test "x$enable_gallium_intel" = xyes; then
1303     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel i965"
1304     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1305 elif test "x$enable_gallium_intel" = xauto; then
1306     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1307 fi
1308
1309 dnl
1310 dnl Gallium Radeon configuration
1311 dnl
1312 AC_ARG_ENABLE([gallium-radeon],
1313     [AS_HELP_STRING([--enable-gallium-radeon],
1314         [build gallium radeon @<:@default=disabled@:>@])],
1315     [enable_gallium_radeon="$enableval"],
1316     [enable_gallium_radeon=auto])
1317 if test "x$enable_gallium_radeon" = xyes; then
1318     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1319     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1320 elif test "x$enable_gallium_radeon" = xauto; then
1321     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1322 fi
1323
1324 dnl
1325 dnl Gallium Nouveau configuration
1326 dnl
1327 AC_ARG_ENABLE([gallium-nouveau],
1328     [AS_HELP_STRING([--enable-gallium-nouveau],
1329         [build gallium nouveau @<:@default=disabled@:>@])],
1330     [enable_gallium_nouveau="$enableval"],
1331     [enable_gallium_nouveau=no])
1332 if test "x$enable_gallium_nouveau" = xyes; then
1333     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1334     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv40 nv50"
1335 fi
1336
1337 dnl
1338 dnl Gallium swrast configuration
1339 dnl
1340 AC_ARG_ENABLE([gallium-swrast],
1341     [AS_HELP_STRING([--enable-gallium-swrast],
1342         [build gallium swrast @<:@default=disabled@:>@])],
1343     [enable_gallium_swrast="$enableval"],
1344     [enable_gallium_swrast=auto])
1345 if test "x$enable_gallium_swrast" = xyes; then
1346     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS swrast"
1347 fi
1348
1349 dnl prepend CORE_DIRS to SRC_DIRS
1350 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1351
1352 dnl Restore LDFLAGS and CPPFLAGS
1353 LDFLAGS="$_SAVE_LDFLAGS"
1354 CPPFLAGS="$_SAVE_CPPFLAGS"
1355
1356 dnl Substitute the config
1357 AC_CONFIG_FILES([configs/autoconf])
1358
1359 dnl Replace the configs/current symlink
1360 AC_CONFIG_COMMANDS([configs],[
1361 if test -f configs/current || test -L configs/current; then
1362     rm -f configs/current
1363 fi
1364 ln -s autoconf configs/current
1365 ])
1366
1367 AC_OUTPUT
1368
1369 dnl
1370 dnl Output some configuration info for the user
1371 dnl
1372 echo ""
1373 echo "        prefix:          $prefix"
1374 echo "        exec_prefix:     $exec_prefix"
1375 echo "        libdir:          $libdir"
1376 echo "        includedir:      $includedir"
1377
1378 dnl Driver info
1379 echo ""
1380 echo "        Driver:          $mesa_driver"
1381 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1382     echo "        OSMesa:          lib$OSMESA_LIB"
1383 else
1384     echo "        OSMesa:          no"
1385 fi
1386 if test "$mesa_driver" = dri; then
1387     # cleanup the drivers var
1388     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1389 if test "x$DRI_DIRS" = x; then
1390     echo "        DRI drivers:     no"
1391 else
1392     echo "        DRI drivers:     $dri_dirs"
1393 fi
1394     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1395 fi
1396 echo "        Use XCB:         $enable_xcb"
1397
1398 echo ""
1399 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1400     echo "        Gallium:         yes"
1401     echo "        Gallium dirs:    $GALLIUM_DIRS"
1402     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1403     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1404     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1405     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1406 else
1407     echo "        Gallium:         no"
1408 fi
1409
1410 dnl Libraries
1411 echo ""
1412 echo "        Shared libs:     $enable_shared"
1413 echo "        Static libs:     $enable_static"
1414 if test "$enable_egl" = yes; then
1415     echo "        EGL:             $EGL_DRIVERS_DIRS"
1416 else
1417     echo "        EGL:             no"
1418 fi
1419 echo "        GLU:             $enable_glu"
1420 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1421 echo "        glut:            $enable_glut"
1422
1423 dnl Programs
1424 # cleanup the programs var for display
1425 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1426 if test "x$program_dirs" = x; then
1427     echo "        Demos:           no"
1428 else
1429     echo "        Demos:           $program_dirs"
1430 fi
1431
1432 dnl Compiler options
1433 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1434 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1435     $SED 's/^ *//;s/  */ /;s/ *$//'`
1436 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1437     $SED 's/^ *//;s/  */ /;s/ *$//'`
1438 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1439 echo ""
1440 echo "        CFLAGS:          $cflags"
1441 echo "        CXXFLAGS:        $cxxflags"
1442 echo "        Macros:          $defines"
1443
1444 echo ""
1445 echo "        Run '${MAKE-make}' to build Mesa"
1446 echo ""