configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125
 126 dnl Check for compiler builtins
 127 AX_GCC_BUILTIN([__builtin_bswap32])
 128 AX_GCC_BUILTIN([__builtin_bswap64])
 129
 130 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 131
 132 dnl Make sure the pkg-config macros are defined
 133 m4_ifndef([PKG_PROG_PKG_CONFIG],
 134     [m4_fatal([Could not locate the pkg-config autoconf macros.
 135   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 136   are in a different location, try setting the environment variable
 137   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 138 PKG_PROG_PKG_CONFIG()
 139
 140 dnl LIB_DIR - library basename
 141 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 142 AC_SUBST([LIB_DIR])
 143
 144 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 145 _SAVE_LDFLAGS="$LDFLAGS"
 146 _SAVE_CPPFLAGS="$CPPFLAGS"
 147
 148 dnl Compiler macros
 149 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 150 AC_SUBST([DEFINES])
 151 case "$host_os" in
 152 linux*|*-gnu*|gnu*)
 153     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 154     ;;
 155 solaris*)
 156     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 157     ;;
 158 cygwin*)
 159     DEFINES="$DEFINES -D_XOPEN_SOURCE=700 -DHAVE_PTHREAD"
 160     ;;
 161 esac
 162
 163 dnl Add flags for gcc and g++
 164 if test "x$GCC" = xyes; then
 165     CFLAGS="$CFLAGS -Wall -std=c99"
 166
 167     # Enable -Werror=implicit-function-declaration and
 168     # -Werror=missing-prototypes, if available, or otherwise, just
 169     # -Wmissing-prototypes.  This is particularly useful to avoid
 170     # generating a loadable driver module that has undefined symbols.
 171     save_CFLAGS="$CFLAGS"
 172     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 173     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 174     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 175     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 176                    AC_MSG_RESULT([yes]),
 177                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 178                     AC_MSG_RESULT([no])]);
 179
 180     # Enable -fvisibility=hidden if using a gcc that supports it
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 183     VISIBILITY_CFLAGS="-fvisibility=hidden"
 184     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 186                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 187
 188     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 189     CFLAGS=$save_CFLAGS
 190
 191     # Work around aliasing bugs - developers should comment this out
 192     CFLAGS="$CFLAGS -fno-strict-aliasing"
 193
 194     # gcc's builtin memcmp is slower than glibc's
 195     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 196     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 197 fi
 198 if test "x$GXX" = xyes; then
 199     CXXFLAGS="$CXXFLAGS -Wall"
 200
 201     # Enable -fvisibility=hidden if using a gcc that supports it
 202     save_CXXFLAGS="$CXXFLAGS"
 203     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 204     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 205     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 206     AC_LANG_PUSH([C++])
 207     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 208                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 209     AC_LANG_POP([C++])
 210
 211     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 212     CXXFLAGS=$save_CXXFLAGS
 213
 214     # Work around aliasing bugs - developers should comment this out
 215     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 216
 217     # gcc's builtin memcmp is slower than glibc's
 218     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 219     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 220 fi
 221
 222 dnl even if the compiler appears to support it, using visibility attributes isn't
 223 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 224 case "$host_os" in
 225 cygwin*)
 226     VISIBILITY_CFLAGS=""
 227     VISIBILITY_CXXFLAGS=""
 228     ;;
 229 esac
 230
 231 AC_SUBST([VISIBILITY_CFLAGS])
 232 AC_SUBST([VISIBILITY_CXXFLAGS])
 233
 234 dnl
 235 dnl Optional flags, check for compiler support
 236 dnl
 237 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 238 if test "x$SSE41_SUPPORTED" = x1; then
 239     DEFINES="$DEFINES -DUSE_SSE41"
 240 fi
 241 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 242
 243 dnl
 244 dnl Hacks to enable 32 or 64 bit build
 245 dnl
 246 AC_ARG_ENABLE([32-bit],
 247     [AS_HELP_STRING([--enable-32-bit],
 248         [build 32-bit libraries @<:@default=auto@:>@])],
 249     [enable_32bit="$enableval"],
 250     [enable_32bit=auto]
 251 )
 252 if test "x$enable_32bit" = xyes; then
 253     if test "x$GCC" = xyes; then
 254         CFLAGS="$CFLAGS -m32"
 255         CCASFLAGS="$CCASFLAGS -m32"
 256     fi
 257     if test "x$GXX" = xyes; then
 258         CXXFLAGS="$CXXFLAGS -m32"
 259     fi
 260 fi
 261 AC_ARG_ENABLE([64-bit],
 262     [AS_HELP_STRING([--enable-64-bit],
 263         [build 64-bit libraries @<:@default=auto@:>@])],
 264     [enable_64bit="$enableval"],
 265     [enable_64bit=auto]
 266 )
 267 if test "x$enable_64bit" = xyes; then
 268     if test "x$GCC" = xyes; then
 269         CFLAGS="$CFLAGS -m64"
 270     fi
 271     if test "x$GXX" = xyes; then
 272         CXXFLAGS="$CXXFLAGS -m64"
 273     fi
 274 fi
 275
 276 dnl Can't have static and shared libraries, default to static if user
 277 dnl explicitly requested. If both disabled, set to static since shared
 278 dnl was explicitly requested.
 279 case "x$enable_static$enable_shared" in
 280 xyesyes)
 281     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 282     enable_shared=no
 283     ;;
 284 xnono)
 285     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 286     enable_shared=yes
 287     ;;
 288 esac
 289
 290 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 291
 292 dnl
 293 dnl other compiler options
 294 dnl
 295 AC_ARG_ENABLE([debug],
 296     [AS_HELP_STRING([--enable-debug],
 297         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 298     [enable_debug="$enableval"],
 299     [enable_debug=no]
 300 )
 301 if test "x$enable_debug" = xyes; then
 302     DEFINES="$DEFINES -DDEBUG"
 303     if test "x$GCC" = xyes; then
 304         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 305             CFLAGS="$CFLAGS -g"
 306         fi
 307         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 308             CFLAGS="$CFLAGS -O0"
 309         fi
 310     fi
 311     if test "x$GXX" = xyes; then
 312         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 313             CXXFLAGS="$CXXFLAGS -g"
 314         fi
 315         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 316             CXXFLAGS="$CXXFLAGS -O0"
 317         fi
 318     fi
 319 fi
 320
 321 dnl
 322 dnl Check if linker supports -Bsymbolic
 323 dnl
 324 save_LDFLAGS=$LDFLAGS
 325 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 326 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 327 AC_LINK_IFELSE(
 328     [AC_LANG_SOURCE([int main() { return 0;}])],
 329     [AC_MSG_RESULT([yes])
 330         BSYMBOLIC="-Wl,-Bsymbolic";],
 331     [AC_MSG_RESULT([no])
 332         BSYMBOLIC="";])
 333 LDFLAGS=$save_LDFLAGS
 334
 335 AC_SUBST([BSYMBOLIC])
 336
 337 dnl
 338 dnl Check if linker supports garbage collection
 339 dnl
 340 save_LDFLAGS=$LDFLAGS
 341 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 342 AC_MSG_CHECKING([whether ld supports --gc-sections])
 343 AC_LINK_IFELSE(
 344     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 345     [AC_MSG_RESULT([yes])
 346         GC_SECTIONS="-Wl,--gc-sections";],
 347     [AC_MSG_RESULT([no])
 348         GC_SECTIONS="";])
 349 LDFLAGS=$save_LDFLAGS
 350
 351 AC_SUBST([GC_SECTIONS])
 352
 353 dnl
 354 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 355 dnl so when these flags are passed to ld via libtool the checks will fail
 356 dnl
 357 case "$host_os" in
 358 openbsd* | darwin* )
 359     LD_NO_UNDEFINED="" ;;
 360 *)
 361     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 362 esac
 363
 364 AC_SUBST([LD_NO_UNDEFINED])
 365
 366 dnl
 367 dnl Check if linker supports version scripts
 368 dnl
 369 AC_MSG_CHECKING([if the linker supports version-scripts])
 370 save_LDFLAGS=$LDFLAGS
 371 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 372 cat > conftest.map <<EOF
 373 VERSION_1 {
 374      global:
 375          main;
 376
 377      local:
 378          *;
 379 };
 380 EOF
 381 AC_LINK_IFELSE(
 382     [AC_LANG_SOURCE([int main() { return 0;}])],
 383     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 384     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 385 LDFLAGS=$save_LDFLAGS
 386 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 387
 388 dnl
 389 dnl compatibility symlinks
 390 dnl
 391 case "$host_os" in
 392 linux* )
 393     HAVE_COMPAT_SYMLINKS=yes ;;
 394 * )
 395     HAVE_COMPAT_SYMLINKS=no ;;
 396 esac
 397
 398 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 399
 400 dnl
 401 dnl library names
 402 dnl
 403 case "$host_os" in
 404 darwin* )
 405     LIB_EXT='dylib' ;;
 406 cygwin* )
 407     LIB_EXT='dll' ;;
 408 aix* )
 409     LIB_EXT='a' ;;
 410 * )
 411     LIB_EXT='so' ;;
 412 esac
 413
 414 AC_SUBST([LIB_EXT])
 415
 416 AC_ARG_WITH([gl-lib-name],
 417   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 418     [specify GL library name @<:@default=GL@:>@])],
 419   [GL_LIB=$withval],
 420   [GL_LIB=GL])
 421 AC_ARG_WITH([osmesa-lib-name],
 422   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 423     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 424   [OSMESA_LIB=$withval],
 425   [OSMESA_LIB=OSMesa])
 426 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 427 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 428
 429 dnl
 430 dnl Mangled Mesa support
 431 dnl
 432 AC_ARG_ENABLE([mangling],
 433   [AS_HELP_STRING([--enable-mangling],
 434     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 435   [enable_mangling="${enableval}"],
 436   [enable_mangling=no]
 437 )
 438 if test "x${enable_mangling}" = "xyes" ; then
 439   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 440   GL_LIB="Mangled${GL_LIB}"
 441   OSMESA_LIB="Mangled${OSMESA_LIB}"
 442 fi
 443 AC_SUBST([GL_LIB])
 444 AC_SUBST([OSMESA_LIB])
 445
 446 dnl
 447 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 448 dnl
 449 AC_ARG_ENABLE([texture-float],
 450     [AS_HELP_STRING([--enable-texture-float],
 451         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 452     [enable_texture_float="$enableval"],
 453     [enable_texture_float=no]
 454 )
 455 if test "x$enable_texture_float" = xyes; then
 456     AC_MSG_WARN([Floating-point textures enabled.])
 457     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 458     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 459 fi
 460
 461 dnl
 462 dnl Arch/platform-specific settings
 463 dnl
 464 AC_ARG_ENABLE([asm],
 465     [AS_HELP_STRING([--disable-asm],
 466         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 467     [enable_asm="$enableval"],
 468     [enable_asm=yes]
 469 )
 470 asm_arch=""
 471 AC_MSG_CHECKING([whether to enable assembly])
 472 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 473 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 474 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 475     case "$host_cpu" in
 476     i?86 | x86_64 | amd64)
 477         enable_asm=no
 478         AC_MSG_RESULT([no, cross compiling])
 479         ;;
 480     esac
 481 fi
 482 # check for supported arches
 483 if test "x$enable_asm" = xyes; then
 484     case "$host_cpu" in
 485     i?86)
 486         case "$host_os" in
 487         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 488             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 489             ;;
 490         gnu*)
 491             asm_arch=x86
 492             ;;
 493         esac
 494         ;;
 495     x86_64|amd64)
 496         case "$host_os" in
 497         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 498             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 499             ;;
 500         esac
 501         ;;
 502     sparc*)
 503         case "$host_os" in
 504         linux*)
 505             asm_arch=sparc
 506             ;;
 507         esac
 508         ;;
 509     esac
 510
 511     case "$asm_arch" in
 512     x86)
 513         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 514         AC_MSG_RESULT([yes, x86])
 515         ;;
 516     x86_64|amd64)
 517         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 518         AC_MSG_RESULT([yes, x86_64])
 519         ;;
 520     sparc)
 521         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 522         AC_MSG_RESULT([yes, sparc])
 523         ;;
 524     *)
 525         AC_MSG_RESULT([no, platform not supported])
 526         ;;
 527     esac
 528 fi
 529
 530 dnl Check to see if dlopen is in default libraries (like Solaris, which
 531 dnl has it in libc), or if libdl is needed to get it.
 532 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 533     [AC_CHECK_LIB([dl], [dlopen],
 534        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 535 AC_SUBST([DLOPEN_LIBS])
 536
 537 dnl Check if that library also has dladdr
 538 save_LIBS="$LIBS"
 539 LIBS="$LIBS $DLOPEN_LIBS"
 540 AC_CHECK_FUNCS([dladdr])
 541 LIBS="$save_LIBS"
 542
 543 case "$host_os" in
 544 darwin*|mingw*)
 545     ;;
 546 *)
 547     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 548                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 549                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 550     AC_SUBST([CLOCK_LIB])
 551     ;;
 552 esac
 553
 554 dnl See if posix_memalign is available
 555 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 556
 557 dnl Check for pthreads
 558 case "$host_os" in
 559 mingw*)
 560     ;;
 561 *)
 562     AX_PTHREAD
 563     ;;
 564 esac
 565 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 566 dnl to -pthread, which causes problems if we need -lpthread to appear in
 567 dnl pkgconfig files.
 568 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 569
 570 dnl SELinux awareness.
 571 AC_ARG_ENABLE([selinux],
 572     [AS_HELP_STRING([--enable-selinux],
 573         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 574     [MESA_SELINUX="$enableval"],
 575     [MESA_SELINUX=no])
 576 if test "x$enable_selinux" = "xyes"; then
 577     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 578         [AC_CHECK_HEADER([selinux/selinux.h],[],
 579                          [AC_MSG_ERROR([SELinux headers not found])])
 580          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 581                       [AC_MSG_ERROR([SELinux library not found])])
 582          SELINUX_LIBS="-lselinux"])
 583     DEFINES="$DEFINES -DMESA_SELINUX"
 584 fi
 585 AC_SUBST([SELINUX_CFLAGS])
 586 AC_SUBST([SELINUX_LIBS])
 587
 588 dnl Options for APIs
 589 AC_ARG_ENABLE([opengl],
 590     [AS_HELP_STRING([--disable-opengl],
 591         [disable support for standard OpenGL API @<:@default=no@:>@])],
 592     [enable_opengl="$enableval"],
 593     [enable_opengl=yes])
 594 AC_ARG_ENABLE([gles1],
 595     [AS_HELP_STRING([--enable-gles1],
 596         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 597     [enable_gles1="$enableval"],
 598     [enable_gles1=no])
 599 AC_ARG_ENABLE([gles2],
 600     [AS_HELP_STRING([--enable-gles2],
 601         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 602     [enable_gles2="$enableval"],
 603     [enable_gles2=no])
 604 AC_ARG_ENABLE([openvg],
 605     [AS_HELP_STRING([--enable-openvg],
 606         [enable support for OpenVG API @<:@default=no@:>@])],
 607     [enable_openvg="$enableval"],
 608     [enable_openvg=no])
 609
 610 AC_ARG_ENABLE([dri],
 611     [AS_HELP_STRING([--enable-dri],
 612         [enable DRI modules @<:@default=enabled@:>@])],
 613     [enable_dri="$enableval"],
 614     [enable_dri=yes])
 615
 616 case "$host_os" in
 617 linux*)
 618     dri3_default=yes
 619     ;;
 620 *)
 621     dri3_default=no
 622     ;;
 623 esac
 624 AC_ARG_ENABLE([dri3],
 625     [AS_HELP_STRING([--enable-dri3],
 626         [enable DRI3 @<:@default=auto@:>@])],
 627     [enable_dri3="$enableval"],
 628     [enable_dri3="$dri3_default"])
 629 AC_ARG_ENABLE([glx],
 630     [AS_HELP_STRING([--enable-glx],
 631         [enable GLX library @<:@default=enabled@:>@])],
 632     [enable_glx="$enableval"],
 633     [enable_glx=yes])
 634 AC_ARG_ENABLE([osmesa],
 635     [AS_HELP_STRING([--enable-osmesa],
 636         [enable OSMesa library @<:@default=disabled@:>@])],
 637     [enable_osmesa="$enableval"],
 638     [enable_osmesa=no])
 639 AC_ARG_ENABLE([gallium-osmesa],
 640     [AS_HELP_STRING([--enable-gallium-osmesa],
 641         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 642     [enable_gallium_osmesa="$enableval"],
 643     [enable_gallium_osmesa=no])
 644 AC_ARG_ENABLE([egl],
 645     [AS_HELP_STRING([--disable-egl],
 646         [disable EGL library @<:@default=enabled@:>@])],
 647     [enable_egl="$enableval"],
 648     [enable_egl=yes])
 649
 650 AC_ARG_ENABLE([xa],
 651     [AS_HELP_STRING([--enable-xa],
 652         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 653     [enable_xa="$enableval"],
 654     [enable_xa=no])
 655 AC_ARG_ENABLE([gbm],
 656    [AS_HELP_STRING([--enable-gbm],
 657          [enable gbm library @<:@default=auto@:>@])],
 658    [enable_gbm="$enableval"],
 659    [enable_gbm=auto])
 660
 661 AC_ARG_ENABLE([xvmc],
 662    [AS_HELP_STRING([--enable-xvmc],
 663          [enable xvmc library @<:@default=auto@:>@])],
 664    [enable_xvmc="$enableval"],
 665    [enable_xvmc=no])
 666 AC_ARG_ENABLE([vdpau],
 667    [AS_HELP_STRING([--enable-vdpau],
 668          [enable vdpau library @<:@default=auto@:>@])],
 669    [enable_vdpau="$enableval"],
 670    [enable_vdpau=auto])
 671 AC_ARG_ENABLE([omx],
 672    [AS_HELP_STRING([--enable-omx],
 673          [enable OpenMAX library @<:@default=no@:>@])],
 674    [enable_omx="$enableval"],
 675    [enable_omx=no])
 676 AC_ARG_ENABLE([opencl],
 677    [AS_HELP_STRING([--enable-opencl],
 678          [enable OpenCL library @<:@default=no@:>@])],
 679    [enable_opencl="$enableval"],
 680    [enable_opencl=no])
 681 AC_ARG_ENABLE([opencl_icd],
 682    [AS_HELP_STRING([--enable-opencl-icd],
 683           [Build an OpenCL ICD library to be loaded by an ICD implementation
 684            @<:@default=no@:>@])],
 685     [enable_opencl_icd="$enableval"],
 686     [enable_opencl_icd=no])
 687 AC_ARG_ENABLE([xlib-glx],
 688     [AS_HELP_STRING([--enable-xlib-glx],
 689         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 690     [enable_xlib_glx="$enableval"],
 691     [enable_xlib_glx=no])
 692 AC_ARG_ENABLE([gallium-egl],
 693     [AS_HELP_STRING([--enable-gallium-egl],
 694         [enable optional EGL state tracker (not required
 695          for EGL support in Gallium with OpenGL and OpenGL ES)
 696          @<:@default=disable@:>@])],
 697     [enable_gallium_egl="$enableval"],
 698     [enable_gallium_egl=no])
 699 AC_ARG_ENABLE([gallium-gbm],
 700     [AS_HELP_STRING([--enable-gallium-gbm],
 701         [enable optional gbm state tracker (not required for
 702          gbm support in Gallium)
 703          @<:@default=auto@:>@])],
 704     [enable_gallium_gbm="$enableval"],
 705     [enable_gallium_gbm=auto])
 706
 707 AC_ARG_ENABLE([r600-llvm-compiler],
 708     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 709         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 710     [enable_r600_llvm="$enableval"],
 711     [enable_r600_llvm=no])
 712
 713 AC_ARG_ENABLE([gallium-tests],
 714     [AS_HELP_STRING([--enable-gallium-tests],
 715         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 716     [enable_gallium_tests="$enableval"],
 717     [enable_gallium_tests=no])
 718
 719 # Option for Gallium drivers
 720
 721 # Keep this in sync with the --with-gallium-drivers help string default value
 722 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 723
 724 AC_ARG_WITH([gallium-drivers],
 725     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 726         [comma delimited Gallium drivers list, e.g.
 727         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 728         @<:@default=r300,r600,svga,swrast@:>@])],
 729     [with_gallium_drivers="$withval"],
 730     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 731
 732 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 733 # here so that the script doesn't choke on an unknown driver name later.
 734 case "$with_gallium_drivers" in
 735     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 736     no) with_gallium_drivers='' ;;
 737 esac
 738
 739 if test "x$enable_opengl" = xno -a \
 740         "x$enable_gles1" = xno -a \
 741         "x$enable_gles2" = xno -a \
 742         "x$enable_openvg" = xno -a \
 743         "x$enable_xa" = xno -a \
 744         "x$enable_xvmc" = xno -a \
 745         "x$enable_vdpau" = xno -a \
 746         "x$enable_omx" = xno -a \
 747         "x$enable_opencl" = xno; then
 748     AC_MSG_ERROR([at least one API should be enabled])
 749 fi
 750
 751 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 752 if test "x$enable_opengl" = xno -a \
 753         "x$enable_gles1" = xyes; then
 754     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 755 fi
 756
 757 if test "x$enable_opengl" = xno -a \
 758         "x$enable_gles2" = xyes; then
 759     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 760 fi
 761
 762 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 763 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 764 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 765 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 766                                         "x$enable_gles1" = xyes -o \
 767                                         "x$enable_gles2" = xyes)
 768
 769 if test "x$enable_glx" = xno; then
 770     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 771     enable_xlib_glx=no
 772 fi
 773
 774 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 775     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 776 fi
 777
 778 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 779     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 780 fi
 781
 782 # Disable GLX if OpenGL is not enabled
 783 if test "x$enable_glx$enable_opengl" = xyesno; then
 784     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 785     enable_glx=no
 786 fi
 787
 788 # Disable GLX if DRI and Xlib-GLX are not enabled
 789 if test "x$enable_glx" = xyes -a \
 790         "x$enable_dri" = xno -a \
 791         "x$enable_xlib_glx" = xno; then
 792     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 793     enable_glx=no
 794 fi
 795
 796 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 797                                   "x$enable_dri" = xyes)
 798
 799 # Select which platform-dependent DRI code gets built
 800 case "$host_os" in
 801 darwin*)
 802     dri_platform='apple' ;;
 803 gnu*|mingw*|cygwin*)
 804     dri_platform='none' ;;
 805 *)
 806     dri_platform='drm' ;;
 807 esac
 808
 809 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 810 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 811 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 812 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 813 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 814
 815 AC_ARG_ENABLE([shared-glapi],
 816     [AS_HELP_STRING([--enable-shared-glapi],
 817         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 818     [enable_shared_glapi="$enableval"],
 819     [enable_shared_glapi=yes])
 820
 821 case "x$enable_opengl$enable_gles1$enable_gles2" in
 822 x*yes*yes*)
 823     if test "x$enable_shared_glapi" = xno; then
 824         AC_MSG_ERROR([shared GLAPI required when building two or more of
 825                       the following APIs - opengl, gles1 gles2])
 826     fi
 827     ;;
 828 esac
 829
 830 # Building Xlib-GLX requires shared glapi to be disabled.
 831 if test "x$enable_xlib_glx" = xyes; then
 832     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 833     enable_shared_glapi=no
 834 fi
 835
 836 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 837
 838 dnl
 839 dnl Driver specific build directories
 840 dnl
 841 GALLIUM_TARGET_DIRS=""
 842 GALLIUM_WINSYS_DIRS="sw"
 843 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 844 GALLIUM_STATE_TRACKERS_DIRS=""
 845
 846 case "x$enable_glx$enable_xlib_glx" in
 847 xyesyes)
 848     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 849     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 850     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 851     NEED_WINSYS_XLIB="yes"
 852     ;;
 853 esac
 854
 855 if test "x$enable_dri" = xyes; then
 856     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 857     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 858     enable_gallium_loader=yes
 859 fi
 860
 861 if test "x$enable_gallium_osmesa" = xyes; then
 862     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 863         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 864     fi
 865     if test "x$enable_osmesa" = xyes; then
 866         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 867     fi
 868     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 869     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 870 fi
 871
 872 AC_SUBST([MESA_LLVM])
 873
 874 # Check for libdrm
 875 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 876                   [have_libdrm=yes], [have_libdrm=no])
 877 if test "x$have_libdrm" = xyes; then
 878         DEFINES="$DEFINES -DHAVE_LIBDRM"
 879 fi
 880
 881 case "$host_os" in
 882 linux*)
 883     need_pci_id=yes ;;
 884 *)
 885     need_pci_id=no ;;
 886 esac
 887
 888 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 889                   have_libudev=yes, have_libudev=no)
 890
 891 AC_ARG_ENABLE([sysfs],
 892     [AS_HELP_STRING([--enable-sysfs],
 893         [enable /sys PCI identification @<:@default=disabled@:>@])],
 894     [have_sysfs="$enableval"],
 895     [have_sysfs=no]
 896 )
 897
 898 if test "x$enable_dri" = xyes; then
 899     if test "$enable_static" = yes; then
 900         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 901     fi
 902
 903     # not a hard requirement as swrast does not depend on it
 904     if test "x$have_libdrm" = xyes; then
 905         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 906     fi
 907 fi
 908
 909 AC_ARG_ENABLE([driglx-direct],
 910     [AS_HELP_STRING([--disable-driglx-direct],
 911         [disable direct rendering in GLX and EGL for DRI \
 912             @<:@default=auto@:>@])],
 913     [driglx_direct="$enableval"],
 914     [driglx_direct="yes"])
 915
 916 dnl
 917 dnl libGL configuration per driver
 918 dnl
 919 case "x$enable_glx$enable_xlib_glx" in
 920 xyesyes)
 921     # Xlib-based GLX
 922     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 923     GL_PC_REQ_PRIV="x11 xext"
 924     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 925     GL_LIB_DEPS="$XLIBGL_LIBS"
 926     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 927     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 928     ;;
 929 xyesno)
 930     # DRI-based GLX
 931     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 932
 933     # find the DRI deps for libGL
 934     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 935
 936     if test x"$driglx_direct" = xyes; then
 937         if test x"$dri_platform" = xdrm ; then
 938             DEFINES="$DEFINES -DGLX_USE_DRM"
 939             if test "x$have_libdrm" != xyes; then
 940                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 941             fi
 942
 943             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 944             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 945             if test x"$enable_dri3" = xyes; then
 946                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 947                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 948             fi
 949
 950             if test x"$enable_dri" = xyes; then
 951                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 952             fi
 953
 954             if test x"$enable_dri3" = xyes; then
 955                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 956             fi
 957         fi
 958         if test x"$dri_platform" = xapple ; then
 959             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 960         fi
 961     fi
 962
 963     # add xf86vidmode if available
 964     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 965     if test "$HAVE_XF86VIDMODE" = yes ; then
 966         dri_modules="$dri_modules xxf86vm"
 967     fi
 968
 969     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 970     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 971     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 972     GL_LIB_DEPS="$DRIGL_LIBS"
 973
 974     # need DRM libs, $PTHREAD_LIBS, etc.
 975     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 976     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 977     ;;
 978 esac
 979
 980 have_pci_id=no
 981 if test "$have_libudev" = yes; then
 982     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 983     have_pci_id=yes
 984 fi
 985
 986 if test "$have_sysfs" = yes; then
 987     DEFINES="$DEFINES -DHAVE_SYSFS"
 988     have_pci_id=yes
 989 fi
 990
 991 # This is outside the case (above) so that it is invoked even for non-GLX
 992 # builds.
 993 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 994
 995 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 996 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 997 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 998 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 999
1000 AC_SUBST([X11_INCLUDES])
1001 AC_SUBST([GL_LIB_DEPS])
1002 AC_SUBST([GL_PC_REQ_PRIV])
1003 AC_SUBST([GL_PC_LIB_PRIV])
1004 AC_SUBST([GL_PC_CFLAGS])
1005 AC_SUBST([DRI_PC_REQ_PRIV])
1006 AC_SUBST([GLESv1_CM_LIB_DEPS])
1007 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1008 AC_SUBST([GLESv2_LIB_DEPS])
1009 AC_SUBST([GLESv2_PC_LIB_PRIV])
1010
1011 AC_SUBST([HAVE_XF86VIDMODE])
1012
1013 dnl
1014 dnl More GLX setup
1015 dnl
1016 case "x$enable_glx$enable_xlib_glx" in
1017 xyesyes)
1018     DEFINES="$DEFINES -DUSE_XSHM"
1019     ;;
1020 xyesno)
1021     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1022     if test "x$driglx_direct" = xyes; then
1023         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1024     fi
1025     ;;
1026 esac
1027
1028 dnl
1029 dnl TLS detection
1030 dnl
1031
1032 AC_ARG_ENABLE([glx-tls],
1033     [AS_HELP_STRING([--enable-glx-tls],
1034         [enable TLS support in GLX @<:@default=disabled@:>@])],
1035     [GLX_USE_TLS="$enableval"],
1036     [GLX_USE_TLS=no])
1037 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1038
1039 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1040       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1041
1042 dnl
1043 dnl More DRI setup
1044 dnl
1045 dnl Directory for DRI drivers
1046 AC_ARG_WITH([dri-driverdir],
1047     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1048         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1049     [DRI_DRIVER_INSTALL_DIR="$withval"],
1050     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1051 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1052 dnl Extra search path for DRI drivers
1053 AC_ARG_WITH([dri-searchpath],
1054     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1055         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1056     [DRI_DRIVER_SEARCH_DIR="$withval"],
1057     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1058 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1059 dnl Which drivers to build - default is chosen by platform
1060 AC_ARG_WITH([dri-drivers],
1061     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1062         [comma delimited classic DRI drivers list, e.g.
1063         "swrast,i965,radeon" @<:@default=auto@:>@])],
1064     [with_dri_drivers="$withval"],
1065     [with_dri_drivers=auto])
1066
1067 if test "x$with_dri_drivers" = xauto; then
1068     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1069         with_dri_drivers="yes"
1070     else
1071         with_dri_drivers="no"
1072     fi
1073 fi
1074 if test "x$with_dri_drivers" = xno; then
1075     with_dri_drivers=''
1076 fi
1077
1078 dnl If $with_dri_drivers is yes, drivers will be added through
1079 dnl platform checks. Set DEFINES and LIB_DEPS
1080 if test "x$enable_dri" = xyes; then
1081     # Platform specific settings and drivers to build
1082     case "$host_os" in
1083     linux*)
1084         DEFINES="$DEFINES -DHAVE_ALIAS"
1085         if test "x$enable_dri3" = xyes; then
1086             DEFINES="$DEFINES -DHAVE_DRI3"
1087         fi
1088
1089         if test "x$have_pci_id" != xyes; then
1090             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1091         fi
1092
1093         case "$host_cpu" in
1094         powerpc* | sparc*)
1095             # Build only the drivers for cards that exist on PowerPC/sparc
1096             if test "x$with_dri_drivers" = "xyes"; then
1097                 with_dri_drivers="r200 radeon swrast"
1098             fi
1099             ;;
1100         esac
1101         ;;
1102     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1103         DEFINES="$DEFINES -DHAVE_PTHREAD"
1104         DEFINES="$DEFINES -DHAVE_ALIAS"
1105         ;;
1106     gnu*)
1107         DEFINES="$DEFINES -DHAVE_ALIAS"
1108         ;;
1109     cygwin*)
1110         if test "x$with_dri_drivers" = "xyes"; then
1111             with_dri_drivers="swrast"
1112         fi
1113         ;;
1114     darwin*)
1115         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1116         if test "x$with_dri_drivers" = "xyes"; then
1117             with_dri_drivers="swrast"
1118         fi
1119         ;;
1120     esac
1121
1122     # default drivers
1123     if test "x$with_dri_drivers" = "xyes"; then
1124         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1125     fi
1126
1127     # Check for expat
1128     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1129     if test "x$have_expat" = "xyes"; then
1130        PKG_CHECK_MODULES([EXPAT], [expat], [],
1131                          AC_MSG_ERROR([Expat required for DRI.]))
1132     else
1133        # expat version 2.0 and earlier do not provide expat.pc
1134        EXPAT_LIBS=-lexpat
1135     fi
1136
1137     DRICOMMON_NEED_LIBDRM=no
1138     # If we are building any DRI driver other than swrast.
1139     if test -n "$with_dri_drivers"; then
1140         if test "x$with_dri_drivers" != xswrast; then
1141             # ... libdrm is required
1142             if test "x$have_libdrm" != xyes; then
1143                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1144             fi
1145             DRICOMMON_NEED_LIBDRM=yes
1146         fi
1147     fi
1148
1149     # If we're building any gallium DRI driver other than swrast
1150     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1151         if test "x$with_gallium_drivers" != xswrast; then
1152             # ... build a libdrm aware dricommon
1153             DRICOMMON_NEED_LIBDRM=yes
1154         fi
1155     fi
1156
1157     # put all the necessary libs together
1158     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1159 fi
1160
1161 AC_SUBST([DRI_LIB_DEPS])
1162
1163 DRI_DIRS=''
1164 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1165 if test -n "$with_dri_drivers"; then
1166     if test "x$enable_opengl" != xyes; then
1167         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1168     fi
1169
1170     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1171     for driver in $dri_drivers; do
1172         DRI_DIRS="$DRI_DIRS $driver"
1173         case "x$driver" in
1174         xi915)
1175             HAVE_I915_DRI=yes;
1176             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1177             ;;
1178         xi965)
1179             HAVE_I965_DRI=yes;
1180             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1181             ;;
1182         xnouveau)
1183             HAVE_NOUVEAU_DRI=yes;
1184             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1185             ;;
1186         xradeon)
1187             HAVE_RADEON_DRI=yes;
1188             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1189             ;;
1190         xr200)
1191             HAVE_R200_DRI=yes;
1192             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1193             ;;
1194         xswrast)
1195             HAVE_SWRAST_DRI=yes;
1196             ;;
1197         *)
1198             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1199             ;;
1200         esac
1201     done
1202     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1203 fi
1204
1205 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1206 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1207                                   "x$enable_osmesa" = xyes -o \
1208                                   -n "$DRI_DIRS")
1209
1210 dnl
1211 dnl OSMesa configuration
1212 dnl
1213
1214 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1215 AC_ARG_WITH([osmesa-bits],
1216     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1217         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1218     [osmesa_bits="$withval"],
1219     [osmesa_bits=8])
1220 if test "x$osmesa_bits" != x8; then
1221     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1222         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1223         osmesa_bits=8
1224     fi
1225 fi
1226 case "x$osmesa_bits" in
1227 x8)
1228     OSMESA_LIB="${OSMESA_LIB}"
1229     ;;
1230 x16|x32)
1231     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1232     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1233     ;;
1234 *)
1235     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1236     ;;
1237 esac
1238
1239 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1240     # only link libraries with osmesa if shared
1241     if test "$enable_static" = no; then
1242         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1243     else
1244         OSMESA_LIB_DEPS=""
1245     fi
1246     OSMESA_MESA_DEPS=""
1247     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1248 fi
1249
1250 AC_SUBST([OSMESA_LIB_DEPS])
1251 AC_SUBST([OSMESA_MESA_DEPS])
1252 AC_SUBST([OSMESA_PC_REQ])
1253 AC_SUBST([OSMESA_PC_LIB_PRIV])
1254
1255 dnl
1256 dnl gbm configuration
1257 dnl
1258 if test "x$enable_gbm" = xauto; then
1259     case "$with_egl_platforms" in
1260         *drm*)
1261             enable_gbm=yes ;;
1262          *)
1263             enable_gbm=no ;;
1264     esac
1265 fi
1266 if test "x$enable_gbm" = xyes; then
1267     if test "x$need_pci_id$have_pci_id" = xyesno; then
1268         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1269     fi
1270
1271     if test "x$enable_dri" = xyes; then
1272         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1273         if test "x$enable_shared_glapi" = xno; then
1274             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1275         fi
1276     else
1277         # Strictly speaking libgbm does not require --enable-dri, although
1278         # both of its backends do. Thus one can build libgbm without any
1279         # backends if --disable-dri is set.
1280         # To avoid unnecessary complexity of checking if at least one backend
1281         # is available when building, just mandate --enable-dri.
1282         AC_MSG_ERROR([gbm requires --enable-dri])
1283     fi
1284 fi
1285 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1286 if test "x$need_pci_id$have_libudev" = xyesyes; then
1287     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1288 else
1289     GBM_PC_REQ_PRIV=""
1290 fi
1291 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1292 AC_SUBST([GBM_PC_REQ_PRIV])
1293 AC_SUBST([GBM_PC_LIB_PRIV])
1294
1295 dnl
1296 dnl EGL configuration
1297 dnl
1298 EGL_CLIENT_APIS=""
1299
1300 if test "x$enable_egl" = xyes; then
1301     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1302
1303     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1304
1305     if test "$enable_static" != yes; then
1306         if test "x$enable_dri" = xyes; then
1307             HAVE_EGL_DRIVER_DRI2=1
1308         fi
1309
1310     fi
1311 fi
1312 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1313 AC_SUBST([EGL_LIB_DEPS])
1314
1315 dnl
1316 dnl EGL Gallium configuration
1317 dnl
1318 if test "x$enable_gallium_egl" = xyes; then
1319     if test -z "$with_gallium_drivers"; then
1320         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1321     fi
1322     if test "x$enable_egl" = xno; then
1323         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1324     fi
1325     if test "x$have_libdrm" != xyes; then
1326         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1327     fi
1328
1329     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1330     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1331 #    enable_gallium_loader=yes
1332 fi
1333 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1334
1335 dnl
1336 dnl gbm Gallium configuration
1337 dnl
1338 if test "x$enable_gallium_gbm" = xauto; then
1339     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1340         yesyesyes*drm*)
1341             enable_gallium_gbm=yes ;;
1342          *)
1343             enable_gallium_gbm=no ;;
1344     esac
1345 fi
1346 if test "x$enable_gallium_gbm" = xyes; then
1347     if test -z "$with_gallium_drivers"; then
1348         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1349     fi
1350     if test "x$enable_gbm" = xno; then
1351         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1352     fi
1353
1354     if test "x$enable_gallium_egl" != xyes; then
1355         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1356     fi
1357
1358     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1359     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1360     enable_gallium_loader=yes
1361 fi
1362 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1363
1364 dnl
1365 dnl XA configuration
1366 dnl
1367 if test "x$enable_xa" = xyes; then
1368     if test "x$with_gallium_drivers" = xswrast; then
1369        AC_MSG_ERROR([
1370           Building xa requires at least one non swrast gallium driver.
1371           If you are looking to use libxatracker.so with the VMware driver,
1372           make sure to include svga in the gallium drivers list, apart from
1373           enabling XA.
1374           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1375     fi
1376     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1377     enable_gallium_loader=yes
1378 fi
1379 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1380
1381 dnl
1382 dnl OpenVG configuration
1383 dnl
1384 VG_LIB_DEPS=""
1385
1386 if test "x$enable_openvg" = xyes; then
1387     if test "x$enable_egl" = xno; then
1388         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1389     fi
1390     if test -z "$with_gallium_drivers"; then
1391         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1392     fi
1393     if test "x$enable_gallium_egl" = xno; then
1394         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1395     fi
1396
1397     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1398     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1399     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1400     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1401     AC_SUBST([VG_PC_LIB_PRIV])
1402 fi
1403 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1404
1405 dnl
1406 dnl Gallium G3DVL configuration
1407 dnl
1408 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1409     if test "x$enable_xvmc" = xauto; then
1410         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1411     fi
1412
1413     if test "x$enable_vdpau" = xauto; then
1414         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1415     fi
1416
1417     if test "x$enable_omx" = xauto; then
1418         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1419     fi
1420 fi
1421
1422 if test "x$enable_xvmc" = xyes; then
1423     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1424     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1425     enable_gallium_loader=yes
1426 fi
1427 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1428
1429 if test "x$enable_vdpau" = xyes; then
1430     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1431                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1432     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1433     enable_gallium_loader=yes
1434 fi
1435 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1436
1437 if test "x$enable_omx" = xyes; then
1438     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1439     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1440     enable_gallium_loader=yes
1441 fi
1442 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1443
1444 dnl
1445 dnl OpenCL configuration
1446 dnl
1447
1448 AC_ARG_WITH([libclc-path],
1449    [AS_HELP_STRING([--with-libclc-path],
1450          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1451    [LIBCLC_PATH="$withval"],
1452    [LIBCLC_PATH=''])
1453
1454 if test -n "$LIBCLC_PATH"; then
1455    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1456                   Please review the updated build instructions for clover:
1457                   http://dri.freedesktop.org/wiki/GalliumCompute])
1458 fi
1459
1460
1461 AC_ARG_WITH([clang-libdir],
1462    [AS_HELP_STRING([--with-clang-libdir],
1463          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1464    [CLANG_LIBDIR="$withval"],
1465    [CLANG_LIBDIR=''])
1466
1467 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1468
1469 if test "x$enable_opencl" = xyes; then
1470     if test -z "$with_gallium_drivers"; then
1471         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1472     fi
1473
1474     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1475         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1476     fi
1477
1478     if test "x$have_libclc" = xno; then
1479         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1480                     Make sure the directory containing libclc.pc is specified in your
1481                     PKG_CONFIG_PATH environment variable.
1482                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1483     else
1484         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1485         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1486         AC_SUBST([LIBCLC_INCLUDEDIR])
1487         AC_SUBST([LIBCLC_LIBEXECDIR])
1488     fi
1489
1490     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1491     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1492     enable_gallium_loader=yes
1493
1494     if test "x$enable_opencl_icd" = xyes; then
1495         OPENCL_LIBNAME="MesaOpenCL"
1496     else
1497         OPENCL_LIBNAME="OpenCL"
1498     fi
1499 fi
1500 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1501 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1502 AC_SUBST([OPENCL_LIBNAME])
1503
1504 dnl
1505 dnl Gallium configuration
1506 dnl
1507 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1508
1509 AC_SUBST([LLVM_BINDIR])
1510 AC_SUBST([LLVM_CFLAGS])
1511 AC_SUBST([LLVM_CPPFLAGS])
1512 AC_SUBST([LLVM_CXXFLAGS])
1513 AC_SUBST([LLVM_LIBDIR])
1514 AC_SUBST([LLVM_LIBS])
1515 AC_SUBST([LLVM_LDFLAGS])
1516 AC_SUBST([LLVM_INCLUDEDIR])
1517 AC_SUBST([LLVM_VERSION])
1518 AC_SUBST([CLANG_RESOURCE_DIR])
1519
1520 case "x$enable_opengl$enable_gles1$enable_gles2" in
1521 x*yes*)
1522     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1523     ;;
1524 esac
1525
1526 AC_SUBST([VG_LIB_DEPS])
1527 AC_SUBST([EGL_CLIENT_APIS])
1528
1529 dnl
1530 dnl EGL Platforms configuration
1531 dnl
1532 AC_ARG_WITH([egl-platforms],
1533     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1534         [comma delimited native platforms libEGL supports, e.g.
1535         "x11,drm" @<:@default=auto@:>@])],
1536     [with_egl_platforms="$withval"],
1537     [if test "x$enable_egl" = xyes; then
1538         with_egl_platforms="x11"
1539     else
1540         with_egl_platforms=""
1541     fi])
1542
1543 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1544     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1545 fi
1546
1547 # Do per-EGL platform setups and checks
1548 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1549 for plat in $egl_platforms; do
1550         case "$plat" in
1551         wayland)
1552                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1553                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1554
1555                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1556                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1557                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1558                 ;;
1559
1560         x11)
1561                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1562                 ;;
1563
1564         drm)
1565                 test "x$enable_gbm" = "xno" &&
1566                         AC_MSG_ERROR([EGL platform drm needs gbm])
1567                 test "x$have_libdrm" != xyes &&
1568                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1569                 ;;
1570
1571         android|fbdev|gdi|null)
1572                 ;;
1573
1574         *)
1575                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1576                 ;;
1577         esac
1578
1579         case "$plat$need_pci_id$have_pci_id" in
1580                 waylandyesno|drmyesno)
1581                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1582         esac
1583 done
1584
1585 # libEGL wants to default to the first platform specified in
1586 # ./configure.  parse that here.
1587 if test "x$egl_platforms" != "x"; then
1588     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1589     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1590 else
1591     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1592 fi
1593
1594 if echo "$egl_platforms" | grep -q 'x11'; then
1595     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1596     NEED_WINSYS_XLIB=yes
1597 fi
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1599 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1600 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1601 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1602 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1603
1604 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1605
1606 AC_SUBST([EGL_NATIVE_PLATFORM])
1607 AC_SUBST([EGL_CFLAGS])
1608
1609 # If we don't have the X11 platform, set this define so we don't try to include
1610 # the X11 headers.
1611 if ! echo "$egl_platforms" | grep -q 'x11'; then
1612     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1613     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1614 fi
1615
1616 AC_ARG_WITH([egl-driver-dir],
1617     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1618                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1619     [EGL_DRIVER_INSTALL_DIR="$withval"],
1620     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1621 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1622
1623 AC_ARG_WITH([max-width],
1624     [AS_HELP_STRING([--with-max-width=N],
1625                     [Maximum framebuffer width (4096)])],
1626     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1627      AS_IF([test "${withval}" -gt "4096"],
1628            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1629 )
1630 AC_ARG_WITH([max-height],
1631     [AS_HELP_STRING([--with-max-height=N],
1632                     [Maximum framebuffer height (4096)])],
1633     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1634      AS_IF([test "${withval}" -gt "4096"],
1635            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1636 )
1637
1638 dnl
1639 dnl Gallium LLVM
1640 dnl
1641 AC_ARG_ENABLE([gallium-llvm],
1642     [AS_HELP_STRING([--enable-gallium-llvm],
1643         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1644     [enable_gallium_llvm="$enableval"],
1645     [enable_gallium_llvm=auto])
1646
1647 AC_ARG_ENABLE([llvm-shared-libs],
1648     [AS_HELP_STRING([--enable-llvm-shared-libs],
1649         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1650     [enable_llvm_shared_libs="$enableval"],
1651     [enable_llvm_shared_libs=yes])
1652
1653 AC_ARG_WITH([llvm-prefix],
1654     [AS_HELP_STRING([--with-llvm-prefix],
1655         [Prefix for LLVM installations in non-standard locations])],
1656     [llvm_prefix="$withval"],
1657     [llvm_prefix=''])
1658
1659
1660 # Call this inside ` ` to get the return value.
1661 # $1 is the llvm-config command with arguments.
1662 strip_unwanted_llvm_flags() {
1663     # Use \> (marks the end of the word)
1664     echo `$1` | sed \
1665         -e 's/-DNDEBUG\>//g' \
1666         -e 's/-pedantic\>//g' \
1667         -e 's/-Wcovered-switch-default\>//g' \
1668         -e 's/-O.\>//g' \
1669         -e 's/-g\>//g' \
1670         -e 's/-Wall\>//g' \
1671         -e 's/-Wcast-qual\>//g' \
1672         -e 's/-Woverloaded-virtual\>//g' \
1673         -e 's/-fcolor-diagnostics\>//g' \
1674         -e 's/-fdata-sections\>//g' \
1675         -e 's/-ffunction-sections\>//g' \
1676         -e 's/-fno-exceptions\>//g' \
1677         -e 's/-fomit-frame-pointer\>//g' \
1678         -e 's/-fvisibility-inlines-hidden\>//g' \
1679         -e 's/-fPIC\>//g' \
1680         -e 's/-fstack-protector-strong\>//g'
1681 }
1682
1683
1684 if test -z "$with_gallium_drivers"; then
1685     enable_gallium_llvm=no
1686 fi
1687 if test "x$enable_gallium_llvm" = xauto; then
1688     case "$host_cpu" in
1689     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1690     esac
1691 fi
1692 if test "x$enable_gallium_llvm" = xyes; then
1693     if test -n "$llvm_prefix"; then
1694         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1695     else
1696         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1697     fi
1698
1699     if test "x$LLVM_CONFIG" != xno; then
1700         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1701         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1702         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1703         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1704         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1705         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1706         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1707         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1708
1709         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1710             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1711         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1712             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1713
1714         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1715         dnl llvm-config.h
1716         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1717             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1718             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1719
1720         if test -n "${LLVM_VERSION_MAJOR}"; then
1721             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1722         else
1723             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1724         fi
1725
1726         LLVM_REQUIRED_VERSION_MAJOR="3"
1727         LLVM_REQUIRED_VERSION_MINOR="1"
1728         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1729             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1730         fi
1731
1732         LLVM_COMPONENTS="engine bitwriter"
1733         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1734             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1735         fi
1736
1737         if test "x$enable_opencl" = xyes; then
1738             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1739             # LLVM 3.3 >= 177971 requires IRReader
1740             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1741                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1742             fi
1743             # LLVM 3.4 requires Option
1744             if $LLVM_CONFIG --components | grep -qw 'option'; then
1745                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1746             fi
1747             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1748             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1749                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1750             fi
1751             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1752                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1753             fi
1754         fi
1755         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1756         MESA_LLVM=1
1757
1758         dnl Check for Clang internal headers
1759         if test "x$enable_opencl" = xyes; then
1760             if test -z "$CLANG_LIBDIR"; then
1761                 CLANG_LIBDIR=${LLVM_LIBDIR}
1762             fi
1763             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1764             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1765                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1766         fi
1767     else
1768         MESA_LLVM=0
1769         LLVM_VERSION_INT=0
1770     fi
1771 else
1772     MESA_LLVM=0
1773     LLVM_VERSION_INT=0
1774
1775     if test "x$enable_opencl" = xyes; then
1776         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1777     fi
1778 fi
1779
1780 dnl Directory for XVMC libs
1781 AC_ARG_WITH([xvmc-libdir],
1782     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1783         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1784     [XVMC_LIB_INSTALL_DIR="$withval"],
1785     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1786 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1787
1788 dnl
1789 dnl Gallium Tests
1790 dnl
1791 if test "x$enable_gallium_tests" = xyes; then
1792     enable_gallium_loader=yes
1793 fi
1794 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1795
1796 if test "x$enable_gallium_loader" = xyes; then
1797     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1798 fi
1799 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1800
1801 dnl Directory for VDPAU libs
1802 AC_ARG_WITH([vdpau-libdir],
1803     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1804         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1805     [VDPAU_LIB_INSTALL_DIR="$withval"],
1806     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1807 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1808
1809 OMX_LIB_INSTALL_DIR_DEFAULT=''
1810 if test "x$enable_omx" = xyes; then
1811     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1812 fi
1813
1814 AC_ARG_WITH([omx-libdir],
1815     [AS_HELP_STRING([--with-omx-libdir=DIR],
1816         [directory for the OMX libraries])],
1817     [OMX_LIB_INSTALL_DIR="$withval"],
1818     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1819 AC_SUBST([OMX_LIB_INSTALL_DIR])
1820
1821 dnl Directory for OpenCL libs
1822 AC_ARG_WITH([opencl-libdir],
1823     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1824         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1825     [OPENCL_LIB_INSTALL_DIR="$withval"],
1826     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1827 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1828
1829 dnl
1830 dnl Gallium helper functions
1831 dnl
1832 gallium_check_st() {
1833     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1834          if test "x$have_libdrm" != xyes; then
1835             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1836          fi
1837          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1838     fi
1839     if test "x$enable_dri" = xyes && test -n "$2"; then
1840          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1841     fi
1842     if test "x$enable_xa" = xyes && test -n "$3"; then
1843          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1844     fi
1845     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1846          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1847     fi
1848     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1849          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1850     fi
1851     if test "x$enable_omx" = xyes && test "x$6" != x; then
1852          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1853     fi
1854 }
1855
1856 gallium_require_llvm() {
1857     if test "x$MESA_LLVM" = x0; then
1858         case "$host" in *gnux32) return;; esac
1859         case "$host_cpu" in
1860         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1861         esac
1862     fi
1863 }
1864
1865 gallium_require_drm_loader() {
1866     if test "x$enable_gallium_loader" = xyes; then
1867         if test "x$need_pci_id$have_pci_id" = xyesno; then
1868             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1869         fi
1870         if test "x$have_libdrm" != xyes; then
1871             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1872         fi
1873         enable_gallium_drm_loader=yes
1874     fi
1875 }
1876
1877 require_egl_drm() {
1878     case "$with_egl_platforms" in
1879         *drm*)
1880             ;;
1881          *)
1882             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1883             ;;
1884     esac
1885     if test "x$enable_gbm" != xyes; then
1886             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1887     fi
1888 }
1889
1890 radeon_llvm_check() {
1891     if test "x$enable_gallium_llvm" != "xyes"; then
1892         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1893     fi
1894     LLVM_REQUIRED_VERSION_MAJOR="3"
1895     LLVM_REQUIRED_VERSION_MINOR="4"
1896     LLVM_REQUIRED_VERSION_PATCH="2"
1897     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1898         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1899     fi
1900     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1901         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1902                       sources with the --enable-experimental-targets=R600
1903                       configure flag])
1904     fi
1905     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1906     NEED_RADEON_LLVM=yes
1907     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1908                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1909 }
1910
1911 dnl Gallium drivers
1912 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1913         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1914     NEED_NONNULL_WINSYS=yes
1915 fi
1916 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1917
1918 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1919 if test -n "$with_gallium_drivers"; then
1920     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1921     for driver in $gallium_drivers; do
1922         case "x$driver" in
1923         xsvga)
1924             HAVE_GALLIUM_SVGA=yes
1925             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1926             gallium_require_drm_loader
1927             gallium_check_st "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1928             ;;
1929         xi915)
1930             HAVE_GALLIUM_I915=yes
1931             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1932             gallium_require_drm_loader
1933             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1934             gallium_check_st "i915/drm" "dri/i915" "xa/i915"
1935             ;;
1936         xilo)
1937             HAVE_GALLIUM_ILO=yes
1938             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1939             gallium_require_drm_loader
1940             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1941             gallium_check_st "intel/drm" "dri/ilo" "xa/ilo"
1942             ;;
1943         xr300)
1944             HAVE_GALLIUM_R300=yes
1945             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1946             gallium_require_drm_loader
1947             gallium_require_llvm "Gallium R300"
1948             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1949             gallium_check_st "radeon/drm" "dri/r300"
1950             ;;
1951         xr600)
1952             HAVE_GALLIUM_R600=yes
1953             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1954             gallium_require_drm_loader
1955             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1956             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1957                 radeon_llvm_check "r600g"
1958                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1959             fi
1960             if test "x$enable_r600_llvm" = xyes; then
1961                 USE_R600_LLVM_COMPILER=yes;
1962             fi
1963             if test "x$enable_opencl" = xyes; then
1964                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1965             fi
1966             gallium_check_st "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1967             ;;
1968         xradeonsi)
1969             HAVE_GALLIUM_RADEONSI=yes
1970             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1971             gallium_require_drm_loader
1972             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1973             radeon_llvm_check "radeonsi"
1974             require_egl_drm "radeonsi"
1975             gallium_check_st "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1976             ;;
1977         xnouveau)
1978             HAVE_GALLIUM_NOUVEAU=yes
1979             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1980             gallium_require_drm_loader
1981             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1982             gallium_check_st "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1983             ;;
1984         xfreedreno)
1985             HAVE_GALLIUM_FREEDRENO=yes
1986             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1987             gallium_require_drm_loader
1988             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1989             gallium_check_st "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1990             ;;
1991         xswrast)
1992             HAVE_GALLIUM_SOFTPIPE=yes
1993             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1994             if test "x$MESA_LLVM" = x1; then
1995                 HAVE_GALLIUM_LLVMPIPE=yes
1996                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1997             fi
1998
1999             if test "x$enable_dri" = xyes; then
2000                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
2001             fi
2002
2003             if test "x$have_libdrm" = xyes; then
2004                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
2005             fi
2006             ;;
2007         xvc4)
2008             HAVE_GALLIUM_VC4=yes
2009             gallium_require_drm_loader
2010             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS vc4"
2011             gallium_check_st "vc4/drm" "dri-vc4" "" "" ""
2012
2013             case "$host_cpu" in
2014                 i?86 | x86_64 | amd64)
2015                 USE_VC4_SIMULATOR=yes
2016                 ;;
2017             esac
2018             ;;
2019         *)
2020             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2021             ;;
2022         esac
2023     done
2024 fi
2025
2026 dnl Set LLVM_LIBS - This is done after the driver configuration so
2027 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2028 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2029 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2030 dnl this was causing the same libraries to be appear multiple times
2031 dnl in LLVM_LIBS.
2032
2033 if test "x$MESA_LLVM" != x0; then
2034
2035     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2036
2037     if test "x$enable_llvm_shared_libs" = xyes; then
2038         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2039         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2040         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2041
2042         if test "x$llvm_have_one_so" = xyes; then
2043             dnl LLVM was built using auto*, so there is only one shared object.
2044             LLVM_LIBS="-l$LLVM_SO_NAME"
2045         else
2046             dnl If LLVM was built with CMake, there will be one shared object per
2047             dnl component.
2048             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2049                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2050         Please make sure you have built llvm with the --enable-shared option
2051         and that your llvm libraries are installed in $LLVM_LIBDIR
2052         If you have installed your llvm libraries to a different directory you
2053         can use the --with-llvm-prefix= configure flag to specify this directory.
2054         NOTE: Mesa is attempting to use llvm shared libraries by default.
2055         If you do not want to build with llvm shared libraries and instead want to
2056         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2057         invocation and rebuild.])])
2058
2059            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2060            dnl install uses a shared object for each compoenent and we have
2061            dnl already added all of these objects to LLVM_LIBS.
2062         fi
2063     else
2064         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2065     fi
2066 fi
2067
2068 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2070 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2071 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2072 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2073 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2074 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2075                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2076 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2077 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2078 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2079 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2080 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2081
2082 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2083                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2084 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2085                                                   && test "x$MESA_LLVM" = x1)
2086
2087 # Enable static gallium targets for now.
2088 # Do not touch this unless you know what you are doing.
2089 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "xyes" = xyes)
2090
2091 # NOTE: anything using xcb or other client side libs ends up in separate
2092 #       _CLIENT variables.  The pipe loader is built in two variants,
2093 #       one that is standalone and does not link any x client libs (for
2094 #       use by XA tracker in particular, but could be used in any case
2095 #       where communication with xserver is not desired).
2096 if test "x$enable_gallium_loader" = xyes; then
2097     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2098
2099     if test "x$NEED_WINSYS_XLIB" = xyes; then
2100         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2101     fi
2102
2103     if test "x$enable_dri" = xyes; then
2104         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2105     fi
2106
2107     if test "x$enable_gallium_drm_loader" = xyes; then
2108         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2109         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2110                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2111         if test "x$pipe_loader_have_xcb" = xyes; then
2112             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2113             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2114         fi
2115     fi
2116
2117     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2118     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2119
2120     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2121     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2122     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2123     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2124 fi
2125
2126 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2127 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2128 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2129 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2130 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2131 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2132
2133 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2134                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2135                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2136                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2137 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2138                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2139 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2140 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2141 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2142 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2143 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2144 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2145 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2146 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2147 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2148     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2149 fi
2150
2151 AC_SUBST([ELF_LIB])
2152
2153 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2154 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2155 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2156 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2157 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2158
2159 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2160 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2161 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2162
2163 AC_SUBST([VDPAU_MAJOR], 1)
2164 AC_SUBST([VDPAU_MINOR], 0)
2165
2166 AC_SUBST([XVMC_MAJOR], 1)
2167 AC_SUBST([XVMC_MINOR], 0)
2168
2169 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2170 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2171 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2172 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2173
2174 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2175 AC_SUBST([XA_MINOR], $XA_MINOR)
2176 AC_SUBST([XA_TINY], $XA_TINY)
2177 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2178
2179 dnl Restore LDFLAGS and CPPFLAGS
2180 LDFLAGS="$_SAVE_LDFLAGS"
2181 CPPFLAGS="$_SAVE_CPPFLAGS"
2182
2183 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2184 if test "x$acv_mesa_CLANG" = xyes; then
2185     CFLAGS="$CFLAGS -Qunused-arguments"
2186     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2187 fi
2188
2189 dnl Add user CFLAGS and CXXFLAGS
2190 CFLAGS="$CFLAGS $USER_CFLAGS"
2191 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2192
2193 dnl
2194 dnl LT_INIT adds tests to determine host based on some variables like (AM_)C(XX)FLAGS and (AM_)LDFLAGS.
2195 dnl They need to be set before calling LT_INIT so the macro can configure things correctly when cross_compiling.
2196 dnl This will allow --enable-xx-bit to work as expected.
2197 dnl
2198 LT_PREREQ([2.2])
2199 LT_INIT([disable-static])
2200
2201 dnl Substitute the config
2202 AC_CONFIG_FILES([Makefile
2203                 src/Makefile
2204                 src/egl/drivers/dri2/Makefile
2205                 src/egl/main/Makefile
2206                 src/egl/main/egl.pc
2207                 src/egl/wayland/Makefile
2208                 src/egl/wayland/wayland-drm/Makefile
2209                 src/egl/wayland/wayland-egl/Makefile
2210                 src/egl/wayland/wayland-egl/wayland-egl.pc
2211                 src/gallium/Makefile
2212                 src/gallium/auxiliary/Makefile
2213                 src/gallium/auxiliary/pipe-loader/Makefile
2214                 src/gallium/drivers/freedreno/Makefile
2215                 src/gallium/drivers/galahad/Makefile
2216                 src/gallium/drivers/i915/Makefile
2217                 src/gallium/drivers/identity/Makefile
2218                 src/gallium/drivers/ilo/Makefile
2219                 src/gallium/drivers/llvmpipe/Makefile
2220                 src/gallium/drivers/noop/Makefile
2221                 src/gallium/drivers/nouveau/Makefile
2222                 src/gallium/drivers/r300/Makefile
2223                 src/gallium/drivers/r600/Makefile
2224                 src/gallium/drivers/radeon/Makefile
2225                 src/gallium/drivers/radeonsi/Makefile
2226                 src/gallium/drivers/rbug/Makefile
2227                 src/gallium/drivers/softpipe/Makefile
2228                 src/gallium/drivers/svga/Makefile
2229                 src/gallium/drivers/trace/Makefile
2230                 src/gallium/drivers/vc4/Makefile
2231                 src/gallium/state_trackers/clover/Makefile
2232                 src/gallium/state_trackers/dri/Makefile
2233                 src/gallium/state_trackers/egl/Makefile
2234                 src/gallium/state_trackers/gbm/Makefile
2235                 src/gallium/state_trackers/glx/xlib/Makefile
2236                 src/gallium/state_trackers/omx/Makefile
2237                 src/gallium/state_trackers/osmesa/Makefile
2238                 src/gallium/state_trackers/vdpau/Makefile
2239                 src/gallium/state_trackers/vega/Makefile
2240                 src/gallium/state_trackers/xa/Makefile
2241                 src/gallium/state_trackers/xvmc/Makefile
2242                 src/gallium/targets/dri/Makefile
2243                 src/gallium/targets/egl-static/Makefile
2244                 src/gallium/targets/gbm/Makefile
2245                 src/gallium/targets/libgl-xlib/Makefile
2246                 src/gallium/targets/omx/Makefile
2247                 src/gallium/targets/opencl/Makefile
2248                 src/gallium/targets/osmesa/Makefile
2249                 src/gallium/targets/osmesa/osmesa.pc
2250                 src/gallium/targets/pipe-loader/Makefile
2251                 src/gallium/targets/vdpau/Makefile
2252                 src/gallium/targets/xa/Makefile
2253                 src/gallium/targets/xa/xatracker.pc
2254                 src/gallium/targets/xvmc/Makefile
2255                 src/gallium/tests/trivial/Makefile
2256                 src/gallium/tests/unit/Makefile
2257                 src/gallium/winsys/freedreno/drm/Makefile
2258                 src/gallium/winsys/i915/drm/Makefile
2259                 src/gallium/winsys/intel/drm/Makefile
2260                 src/gallium/winsys/nouveau/drm/Makefile
2261                 src/gallium/winsys/radeon/drm/Makefile
2262                 src/gallium/winsys/svga/drm/Makefile
2263                 src/gallium/winsys/sw/dri/Makefile
2264                 src/gallium/winsys/sw/fbdev/Makefile
2265                 src/gallium/winsys/sw/kms-dri/Makefile
2266                 src/gallium/winsys/sw/null/Makefile
2267                 src/gallium/winsys/sw/wayland/Makefile
2268                 src/gallium/winsys/sw/wrapper/Makefile
2269                 src/gallium/winsys/sw/xlib/Makefile
2270                 src/gallium/winsys/vc4/drm/Makefile
2271                 src/gbm/Makefile
2272                 src/gbm/main/gbm.pc
2273                 src/glsl/Makefile
2274                 src/glx/Makefile
2275                 src/glx/apple/Makefile
2276                 src/glx/tests/Makefile
2277                 src/gtest/Makefile
2278                 src/loader/Makefile
2279                 src/mapi/Makefile
2280                 src/mapi/es1api/Makefile
2281                 src/mapi/es1api/glesv1_cm.pc
2282                 src/mapi/es2api/Makefile
2283                 src/mapi/es2api/glesv2.pc
2284                 src/mapi/glapi/Makefile
2285                 src/mapi/glapi/gen/Makefile
2286                 src/mapi/glapi/tests/Makefile
2287                 src/mapi/shared-glapi/Makefile
2288                 src/mapi/shared-glapi/tests/Makefile
2289                 src/mapi/vgapi/Makefile
2290                 src/mapi/vgapi/vg.pc
2291                 src/mesa/Makefile
2292                 src/mesa/gl.pc
2293                 src/mesa/drivers/dri/dri.pc
2294                 src/mesa/drivers/dri/common/Makefile
2295                 src/mesa/drivers/dri/common/xmlpool/Makefile
2296                 src/mesa/drivers/dri/i915/Makefile
2297                 src/mesa/drivers/dri/i965/Makefile
2298                 src/mesa/drivers/dri/Makefile
2299                 src/mesa/drivers/dri/nouveau/Makefile
2300                 src/mesa/drivers/dri/r200/Makefile
2301                 src/mesa/drivers/dri/radeon/Makefile
2302                 src/mesa/drivers/dri/swrast/Makefile
2303                 src/mesa/drivers/osmesa/Makefile
2304                 src/mesa/drivers/osmesa/osmesa.pc
2305                 src/mesa/drivers/x11/Makefile
2306                 src/mesa/main/tests/Makefile
2307                 src/util/Makefile
2308                 src/util/tests/hash_table/Makefile])
2309
2310 dnl Sort the dirs alphabetically
2311 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2312 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2313 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2314 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2315
2316 AC_OUTPUT
2317
2318 dnl
2319 dnl Output some configuration info for the user
2320 dnl
2321 echo ""
2322 echo "        prefix:          $prefix"
2323 echo "        exec_prefix:     $exec_prefix"
2324 echo "        libdir:          $libdir"
2325 echo "        includedir:      $includedir"
2326
2327 dnl API info
2328 echo ""
2329 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2330 echo "        OpenVG:          $enable_openvg"
2331
2332 dnl Driver info
2333 echo ""
2334 case "x$enable_osmesa$enable_gallium_osmesa" in
2335 xnoyes)
2336         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2337         ;;
2338 xyesno)
2339         echo "        OSMesa:          lib$OSMESA_LIB"
2340         ;;
2341 xnono)
2342         echo "        OSMesa:          no"
2343         ;;
2344 esac
2345
2346 echo ""
2347 if test "x$enable_dri" != xno; then
2348         echo "        DRI platform:    $dri_platform"
2349         if test -z "$DRI_DIRS"; then
2350             echo "        DRI drivers:     no"
2351         else
2352             echo "        DRI drivers:     $DRI_DIRS"
2353         fi
2354         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2355 fi
2356
2357 case "x$enable_glx$enable_xlib_glx" in
2358 xyesyes)
2359     echo "        GLX:             Xlib-based"
2360     ;;
2361 xyesno)
2362     echo "        GLX:             DRI-based"
2363     ;;
2364 *)
2365     echo "        GLX:             $enable_glx"
2366     ;;
2367 esac
2368
2369 dnl EGL
2370 echo ""
2371 echo "        EGL:             $enable_egl"
2372 if test "$enable_egl" = yes; then
2373     echo "        EGL platforms:   $egl_platforms"
2374
2375     egl_drivers=""
2376     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2377         egl_drivers="$egl_drivers builtin:egl_dri2"
2378     fi
2379
2380     if test "x$enable_gallium_egl" = xyes; then
2381         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2382         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2383     else
2384         echo "        EGL drivers:    $egl_drivers"
2385     fi
2386 fi
2387
2388 echo ""
2389 if test "x$MESA_LLVM" = x1; then
2390     echo "        llvm:            yes"
2391     echo "        llvm-config:     $LLVM_CONFIG"
2392     echo "        llvm-version:    $LLVM_VERSION"
2393 else
2394     echo "        llvm:            no"
2395 fi
2396
2397 echo ""
2398 if test -n "$with_gallium_drivers"; then
2399     echo "        Gallium:         yes"
2400     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2401     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2402     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2403     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2404 else
2405     echo "        Gallium:         no"
2406 fi
2407
2408
2409 dnl Libraries
2410 echo ""
2411 echo "        Shared libs:     $enable_shared"
2412 echo "        Static libs:     $enable_static"
2413 echo "        Shared-glapi:    $enable_shared_glapi"
2414
2415 dnl Compiler options
2416 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2417 cflags=`echo $CFLAGS | \
2418     $SED 's/^ *//;s/  */ /;s/ *$//'`
2419 cxxflags=`echo $CXXFLAGS | \
2420     $SED 's/^ *//;s/  */ /;s/ *$//'`
2421 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2422 echo ""
2423 echo "        CFLAGS:          $cflags"
2424 echo "        CXXFLAGS:        $cxxflags"
2425 echo "        Macros:          $defines"
2426 echo ""
2427 if test "x$MESA_LLVM" = x1; then
2428     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2429     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2430     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2431     echo ""
2432 fi
2433 echo "        PYTHON2:         $PYTHON2"
2434
2435 echo ""
2436 echo "        Run '${MAKE-make}' to build Mesa"
2437 echo ""