configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122
 123 dnl Check for compiler builtins
 124 AX_GCC_BUILTIN([__builtin_bswap32])
 125 AX_GCC_BUILTIN([__builtin_bswap64])
 126
 127 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 128
 129 dnl Make sure the pkg-config macros are defined
 130 m4_ifndef([PKG_PROG_PKG_CONFIG],
 131     [m4_fatal([Could not locate the pkg-config autoconf macros.
 132   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 133   are in a different location, try setting the environment variable
 134   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 135 PKG_PROG_PKG_CONFIG()
 136
 137 dnl LIB_DIR - library basename
 138 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 139 AC_SUBST([LIB_DIR])
 140
 141 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 142 _SAVE_LDFLAGS="$LDFLAGS"
 143 _SAVE_CPPFLAGS="$CPPFLAGS"
 144
 145 dnl Compiler macros
 146 DEFINES=""
 147 AC_SUBST([DEFINES])
 148 case "$host_os" in
 149 linux*|*-gnu*|gnu*)
 150     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 151     ;;
 152 solaris*)
 153     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 154     ;;
 155 cygwin*)
 156     DEFINES="$DEFINES -DHAVE_PTHREAD"
 157     ;;
 158 esac
 159
 160 dnl Add flags for gcc and g++
 161 if test "x$GCC" = xyes; then
 162     case "$host_os" in
 163     cygwin*)
 164         CFLAGS="$CFLAGS -Wall -std=gnu99"
 165         ;;
 166     *)
 167         CFLAGS="$CFLAGS -Wall -std=c99"
 168         ;;
 169     esac
 170
 171     # Enable -Werror=implicit-function-declaration and
 172     # -Werror=missing-prototypes, if available, or otherwise, just
 173     # -Wmissing-prototypes.  This is particularly useful to avoid
 174     # generating a loadable driver module that has undefined symbols.
 175     save_CFLAGS="$CFLAGS"
 176     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 177     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 178     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 179     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 180                    AC_MSG_RESULT([yes]),
 181                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 182                     AC_MSG_RESULT([no])]);
 183
 184     # Enable -fvisibility=hidden if using a gcc that supports it
 185     save_CFLAGS="$CFLAGS"
 186     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 187     VISIBILITY_CFLAGS="-fvisibility=hidden"
 188     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 190                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 191
 192     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 193     CFLAGS=$save_CFLAGS
 194
 195     # Work around aliasing bugs - developers should comment this out
 196     CFLAGS="$CFLAGS -fno-strict-aliasing"
 197
 198     # gcc's builtin memcmp is slower than glibc's
 199     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 200     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 201 fi
 202 if test "x$GXX" = xyes; then
 203     CXXFLAGS="$CXXFLAGS -Wall"
 204
 205     # Enable -fvisibility=hidden if using a gcc that supports it
 206     save_CXXFLAGS="$CXXFLAGS"
 207     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 208     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 209     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 210     AC_LANG_PUSH([C++])
 211     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 212                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 213     AC_LANG_POP([C++])
 214
 215     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 216     CXXFLAGS=$save_CXXFLAGS
 217
 218     # Work around aliasing bugs - developers should comment this out
 219     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 220
 221     # gcc's builtin memcmp is slower than glibc's
 222     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 223     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 224 fi
 225
 226 dnl even if the compiler appears to support it, using visibility attributes isn't
 227 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 228 case "$host_os" in
 229 cygwin*)
 230     VISIBILITY_CFLAGS=""
 231     VISIBILITY_CXXFLAGS=""
 232     ;;
 233 esac
 234
 235 AC_SUBST([VISIBILITY_CFLAGS])
 236 AC_SUBST([VISIBILITY_CXXFLAGS])
 237
 238 dnl
 239 dnl Optional flags, check for compiler support
 240 dnl
 241 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 242 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 243
 244 dnl
 245 dnl Hacks to enable 32 or 64 bit build
 246 dnl
 247 AC_ARG_ENABLE([32-bit],
 248     [AS_HELP_STRING([--enable-32-bit],
 249         [build 32-bit libraries @<:@default=auto@:>@])],
 250     [enable_32bit="$enableval"],
 251     [enable_32bit=auto]
 252 )
 253 if test "x$enable_32bit" = xyes; then
 254     if test "x$GCC" = xyes; then
 255         CFLAGS="$CFLAGS -m32"
 256         CCASFLAGS="$CCASFLAGS -m32"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m32"
 260     fi
 261 fi
 262 AC_ARG_ENABLE([64-bit],
 263     [AS_HELP_STRING([--enable-64-bit],
 264         [build 64-bit libraries @<:@default=auto@:>@])],
 265     [enable_64bit="$enableval"],
 266     [enable_64bit=auto]
 267 )
 268 if test "x$enable_64bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m64"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m64"
 274     fi
 275 fi
 276
 277 dnl Can't have static and shared libraries, default to static if user
 278 dnl explicitly requested. If both disabled, set to static since shared
 279 dnl was explicitly requested.
 280 case "x$enable_static$enable_shared" in
 281 xyesyes )
 282     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 283     enable_shared=no
 284     ;;
 285 xnono )
 286     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 287     enable_static=yes
 288     ;;
 289 esac
 290
 291 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 292
 293 dnl
 294 dnl other compiler options
 295 dnl
 296 AC_ARG_ENABLE([debug],
 297     [AS_HELP_STRING([--enable-debug],
 298         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 299     [enable_debug="$enableval"],
 300     [enable_debug=no]
 301 )
 302 if test "x$enable_debug" = xyes; then
 303     DEFINES="$DEFINES -DDEBUG"
 304     if test "x$GCC" = xyes; then
 305         CFLAGS="$CFLAGS -g -O0"
 306     fi
 307     if test "x$GXX" = xyes; then
 308         CXXFLAGS="$CXXFLAGS -g -O0"
 309     fi
 310 fi
 311
 312 dnl
 313 dnl library names
 314 dnl
 315 LIB_PREFIX_GLOB='lib'
 316 LIB_VERSION_SEPARATOR='.'
 317 if test "$enable_static" = yes; then
 318     LIB_EXTENSION='a'
 319 else
 320     case "$host_os" in
 321     darwin* )
 322         LIB_EXTENSION='dylib' ;;
 323     cygwin* )
 324         dnl prefix can be 'cyg' or 'lib'
 325         LIB_PREFIX_GLOB='???'
 326         LIB_VERSION_SEPARATOR='-'
 327         LIB_EXTENSION='dll' ;;
 328     aix* )
 329         LIB_EXTENSION='a' ;;
 330     * )
 331         LIB_EXTENSION='so' ;;
 332     esac
 333 fi
 334 AC_ARG_WITH([gl-lib-name],
 335   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 336     [specify GL library name @<:@default=GL@:>@])],
 337   [GL_LIB=$withval],
 338   [GL_LIB=GL])
 339 AC_ARG_WITH([osmesa-lib-name],
 340   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 341     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 342   [OSMESA_LIB=$withval],
 343   [OSMESA_LIB=OSMesa])
 344 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 345 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 346
 347 dnl
 348 dnl Mangled Mesa support
 349 dnl
 350 AC_ARG_ENABLE([mangling],
 351   [AS_HELP_STRING([--enable-mangling],
 352     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 353   [enable_mangling="${enableval}"],
 354   [enable_mangling=no]
 355 )
 356 if test "x${enable_mangling}" = "xyes" ; then
 357   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 358   GL_LIB="Mangled${GL_LIB}"
 359   OSMESA_LIB="Mangled${OSMESA_LIB}"
 360 fi
 361 AC_SUBST([GL_LIB])
 362 AC_SUBST([OSMESA_LIB])
 363
 364 dnl
 365 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 366 dnl
 367 AC_ARG_ENABLE([texture-float],
 368     [AS_HELP_STRING([--enable-texture-float],
 369         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 370     [enable_texture_float="$enableval"],
 371     [enable_texture_float=no]
 372 )
 373 if test "x$enable_texture_float" = xyes; then
 374     AC_MSG_WARN([Floating-point textures enabled.])
 375     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 376     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 377 fi
 378
 379 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 380 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 381 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 382 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 383 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 384 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 385 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 386
 387 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 390 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 391 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 392 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 393 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 394
 395 AC_SUBST([GL_LIB_NAME])
 396 AC_SUBST([OSMESA_LIB_NAME])
 397 AC_SUBST([EGL_LIB_NAME])
 398 AC_SUBST([GLESv1_CM_LIB_NAME])
 399 AC_SUBST([GLESv2_LIB_NAME])
 400 AC_SUBST([VG_LIB_NAME])
 401 AC_SUBST([GLAPI_LIB_NAME])
 402
 403 AC_SUBST([GL_LIB_GLOB])
 404 AC_SUBST([EGL_LIB_GLOB])
 405 AC_SUBST([GLESv1_CM_LIB_GLOB])
 406 AC_SUBST([GLESv2_LIB_GLOB])
 407 AC_SUBST([VG_LIB_GLOB])
 408 AC_SUBST([GLAPI_LIB_GLOB])
 409
 410 dnl
 411 dnl Arch/platform-specific settings
 412 dnl
 413 AC_ARG_ENABLE([asm],
 414     [AS_HELP_STRING([--disable-asm],
 415         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 416     [enable_asm="$enableval"],
 417     [enable_asm=yes]
 418 )
 419 asm_arch=""
 420 AC_MSG_CHECKING([whether to enable assembly])
 421 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 422 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 423 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 424     case "$host_cpu" in
 425     i?86 | x86_64 | amd64)
 426         enable_asm=no
 427         AC_MSG_RESULT([no, cross compiling])
 428         ;;
 429     esac
 430 fi
 431 # check for supported arches
 432 if test "x$enable_asm" = xyes; then
 433     case "$host_cpu" in
 434     i?86)
 435         case "$host_os" in
 436         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 437             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 438             ;;
 439         gnu*)
 440             asm_arch=x86
 441             ;;
 442         esac
 443         ;;
 444     x86_64|amd64)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 447             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 448             ;;
 449         esac
 450         ;;
 451     sparc*)
 452         case "$host_os" in
 453         linux*)
 454             asm_arch=sparc
 455             ;;
 456         esac
 457         ;;
 458     esac
 459
 460     case "$asm_arch" in
 461     x86)
 462         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 463         AC_MSG_RESULT([yes, x86])
 464         ;;
 465     x86_64|amd64)
 466         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 467         AC_MSG_RESULT([yes, x86_64])
 468         ;;
 469     sparc)
 470         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 471         AC_MSG_RESULT([yes, sparc])
 472         ;;
 473     *)
 474         AC_MSG_RESULT([no, platform not supported])
 475         ;;
 476     esac
 477 fi
 478
 479 dnl Check to see if dlopen is in default libraries (like Solaris, which
 480 dnl has it in libc), or if libdl is needed to get it.
 481 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 482     [AC_CHECK_LIB([dl], [dlopen],
 483        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 484 AC_SUBST([DLOPEN_LIBS])
 485
 486 case "$host_os" in
 487 darwin*|mingw*)
 488     ;;
 489 *)
 490     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 491                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 492                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 493     AC_SUBST([CLOCK_LIB])
 494     ;;
 495 esac
 496
 497 dnl See if posix_memalign is available
 498 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 499
 500 dnl Check for pthreads
 501 AX_PTHREAD
 502 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 503 dnl to -pthread, which causes problems if we need -lpthread to appear in
 504 dnl pkgconfig files.
 505 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 515         [AC_CHECK_HEADER([selinux/selinux.h],[],
 516                          [AC_MSG_ERROR([SELinux headers not found])])
 517          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 518                       [AC_MSG_ERROR([SELinux library not found])])
 519          SELINUX_LIBS="-lselinux"])
 520     DEFINES="$DEFINES -DMESA_SELINUX"
 521 fi
 522 AC_SUBST([SELINUX_CFLAGS])
 523 AC_SUBST([SELINUX_LIBS])
 524
 525 dnl Options for APIs
 526 AC_ARG_ENABLE([opengl],
 527     [AS_HELP_STRING([--disable-opengl],
 528         [disable support for standard OpenGL API @<:@default=no@:>@])],
 529     [enable_opengl="$enableval"],
 530     [enable_opengl=yes])
 531 AC_ARG_ENABLE([gles1],
 532     [AS_HELP_STRING([--enable-gles1],
 533         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 534     [enable_gles1="$enableval"],
 535     [enable_gles1=no])
 536 AC_ARG_ENABLE([gles2],
 537     [AS_HELP_STRING([--enable-gles2],
 538         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 539     [enable_gles2="$enableval"],
 540     [enable_gles2=no])
 541 AC_ARG_ENABLE([openvg],
 542     [AS_HELP_STRING([--enable-openvg],
 543         [enable support for OpenVG API @<:@default=no@:>@])],
 544     [enable_openvg="$enableval"],
 545     [enable_openvg=no])
 546
 547 AC_ARG_ENABLE([dri],
 548     [AS_HELP_STRING([--enable-dri],
 549         [enable DRI modules @<:@default=enabled@:>@])],
 550     [enable_dri="$enableval"],
 551     [enable_dri=yes])
 552 AC_ARG_ENABLE([dri3],
 553     [AS_HELP_STRING([--enable-dri3],
 554         [enable DRI3 @<:@default=enabled@:>@])],
 555     [enable_dri3="$enableval"],
 556     [enable_dri3=yes])
 557 AC_ARG_ENABLE([glx],
 558     [AS_HELP_STRING([--enable-glx],
 559         [enable GLX library @<:@default=enabled@:>@])],
 560     [enable_glx="$enableval"],
 561     [enable_glx=yes])
 562 AC_ARG_ENABLE([osmesa],
 563     [AS_HELP_STRING([--enable-osmesa],
 564         [enable OSMesa library @<:@default=disabled@:>@])],
 565     [enable_osmesa="$enableval"],
 566     [enable_osmesa=no])
 567 AC_ARG_ENABLE([gallium-osmesa],
 568     [AS_HELP_STRING([--enable-gallium-osmesa],
 569         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 570     [enable_gallium_osmesa="$enableval"],
 571     [enable_gallium_osmesa=no])
 572 AC_ARG_ENABLE([egl],
 573     [AS_HELP_STRING([--disable-egl],
 574         [disable EGL library @<:@default=enabled@:>@])],
 575     [enable_egl="$enableval"],
 576     [enable_egl=yes])
 577
 578 AC_ARG_ENABLE([xa],
 579     [AS_HELP_STRING([--enable-xa],
 580         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 581     [enable_xa="$enableval"],
 582     [enable_xa=no])
 583 AC_ARG_ENABLE([gbm],
 584    [AS_HELP_STRING([--enable-gbm],
 585          [enable gbm library @<:@default=auto@:>@])],
 586    [enable_gbm="$enableval"],
 587    [enable_gbm=auto])
 588
 589 AC_ARG_ENABLE([xvmc],
 590    [AS_HELP_STRING([--enable-xvmc],
 591          [enable xvmc library @<:@default=auto@:>@])],
 592    [enable_xvmc="$enableval"],
 593    [enable_xvmc=no])
 594 AC_ARG_ENABLE([vdpau],
 595    [AS_HELP_STRING([--enable-vdpau],
 596          [enable vdpau library @<:@default=auto@:>@])],
 597    [enable_vdpau="$enableval"],
 598    [enable_vdpau=auto])
 599 AC_ARG_ENABLE([omx],
 600    [AS_HELP_STRING([--enable-omx],
 601          [enable OpenMAX library @<:@default=no@:>@])],
 602    [enable_omx="$enableval"],
 603    [enable_omx=no])
 604 AC_ARG_ENABLE([opencl],
 605    [AS_HELP_STRING([--enable-opencl],
 606          [enable OpenCL library NOTE: Enabling this option will also enable
 607           --with-llvm-shared-libs
 608           @<:@default=no@:>@])],
 609    [],
 610    [enable_opencl=no])
 611 AC_ARG_ENABLE([opencl_icd],
 612    [AS_HELP_STRING([--enable-opencl-icd],
 613           [Build an OpenCL ICD library to be loaded by an ICD implementation
 614            @<:@default=no@:>@])],
 615     [enable_opencl_icd="$enableval"],
 616     [enable_opencl_icd=no])
 617 AC_ARG_ENABLE([xlib-glx],
 618     [AS_HELP_STRING([--enable-xlib-glx],
 619         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 620     [enable_xlib_glx="$enableval"],
 621     [enable_xlib_glx=no])
 622 AC_ARG_ENABLE([gallium-egl],
 623     [AS_HELP_STRING([--enable-gallium-egl],
 624         [enable optional EGL state tracker (not required
 625          for EGL support in Gallium with OpenGL and OpenGL ES)
 626          @<:@default=disable@:>@])],
 627     [enable_gallium_egl="$enableval"],
 628     [enable_gallium_egl=no])
 629 AC_ARG_ENABLE([gallium-gbm],
 630     [AS_HELP_STRING([--enable-gallium-gbm],
 631         [enable optional gbm state tracker (not required for
 632          gbm support in Gallium)
 633          @<:@default=auto@:>@])],
 634     [enable_gallium_gbm="$enableval"],
 635     [enable_gallium_gbm=auto])
 636
 637 AC_ARG_ENABLE([r600-llvm-compiler],
 638     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 639         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 640     [enable_r600_llvm="$enableval"],
 641     [enable_r600_llvm=no])
 642
 643 AC_ARG_ENABLE([gallium-tests],
 644     [AS_HELP_STRING([--enable-gallium-tests],
 645         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 646     [enable_gallium_tests="$enableval"],
 647     [enable_gallium_tests=no])
 648
 649 # Option for Gallium drivers
 650
 651 # Keep this in sync with the --with-gallium-drivers help string default value
 652 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 653
 654 AC_ARG_WITH([gallium-drivers],
 655     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 656         [comma delimited Gallium drivers list, e.g.
 657         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 658         @<:@default=r300,r600,svga,swrast@:>@])],
 659     [with_gallium_drivers="$withval"],
 660     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 661
 662 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 663 # here so that the script doesn't choke on an unknown driver name later.
 664 case "$with_gallium_drivers" in
 665     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 666     no) with_gallium_drivers='' ;;
 667 esac
 668
 669 if test "x$enable_opengl" = xno -a \
 670         "x$enable_gles1" = xno -a \
 671         "x$enable_gles2" = xno -a \
 672         "x$enable_openvg" = xno -a \
 673         "x$enable_xa" = xno -a \
 674         "x$enable_xvmc" = xno -a \
 675         "x$enable_vdpau" = xno -a \
 676         "x$enable_omx" = xno -a \
 677         "x$enable_opencl" = xno; then
 678     AC_MSG_ERROR([at least one API should be enabled])
 679 fi
 680
 681 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 682 if test "x$enable_opengl" = xno -a \
 683         "x$enable_gles1" = xyes; then
 684     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 685 fi
 686
 687 if test "x$enable_opengl" = xno -a \
 688         "x$enable_gles2" = xyes; then
 689     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 690 fi
 691
 692 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 693 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 694 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 695 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 696                                         "x$enable_gles1" = xyes -o \
 697                                         "x$enable_gles2" = xyes)
 698
 699 enable_dri_glx=$enable_dri
 700
 701 if test "x$enable_glx" = xno; then
 702     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 703     enable_xlib_glx=no
 704     enable_dri_glx=no
 705 fi
 706
 707 if test "x$enable_dri_glx$enable_xlib_glx" = xyesyes; then
 708     AC_MSG_ERROR([DRI-GLX and Xlib-GLX cannot be built together])
 709 fi
 710
 711 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 712     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 713 fi
 714
 715 # Disable GLX if OpenGL is not enabled
 716 if test "x$enable_glx$enable_opengl" = xyesno; then
 717     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 718     enable_glx=no
 719 fi
 720
 721 # Disable GLX if DRI-GLX and Xlib-GLX are not enabled
 722 if test "x$enable_glx" = xyes -a \
 723         "x$enable_dri_glx" = xno -a \
 724         "x$enable_xlib_glx" = xno; then
 725     AC_MSG_WARN([Neither DRI-GLX nor Xlib-GLX enabled, disabling GLX])
 726     enable_glx=no
 727 fi
 728
 729 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 730                                   "x$enable_dri_glx" = xyes)
 731 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 732 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 733
 734 AC_ARG_ENABLE([shared-glapi],
 735     [AS_HELP_STRING([--enable-shared-glapi],
 736         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 737     [enable_shared_glapi="$enableval"],
 738     [enable_shared_glapi=yes])
 739
 740 case "x$enable_opengl$enable_gles1$enable_gles2" in
 741 x*yes*yes*)
 742     if test "x$enable_shared_glapi" = xno; then
 743         AC_MSG_ERROR([shared GLAPI required when building two or more of
 744                       the following APIs - opengl, gles1 gles2])
 745     fi
 746     ;;
 747 esac
 748
 749 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 750
 751 dnl
 752 dnl Driver specific build directories
 753 dnl
 754 GALLIUM_TARGET_DIRS=""
 755 GALLIUM_WINSYS_DIRS="sw"
 756 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 757 GALLIUM_STATE_TRACKERS_DIRS=""
 758
 759 case "x$enable_glx$enable_xlib_glx" in
 760 xyesyes)
 761     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 762     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 763     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 764     NEED_WINSYS_XLIB="yes"
 765     ;;
 766 esac
 767
 768 if test "x$enable_dri" = xyes; then
 769     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 770     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 771 fi
 772
 773 if test "x$enable_gallium_osmesa" = xyes; then
 774     if test -z "$with_gallium_drivers"; then
 775         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 776     fi
 777     if test "x$enable_osmesa" = xyes; then
 778         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 779     fi
 780     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 781     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 782 fi
 783
 784 AC_SUBST([MESA_LLVM])
 785
 786 # Check for libdrm
 787 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 788                   [have_libdrm=yes], [have_libdrm=no])
 789 if test "x$have_libdrm" = xyes; then
 790         DEFINES="$DEFINES -DHAVE_LIBDRM"
 791 fi
 792
 793 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 794                   have_libudev=yes, have_libudev=no)
 795
 796 if test "x$enable_dri" = xyes; then
 797     # DRI must be shared, I think
 798     if test "$enable_static" = yes; then
 799         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 800     fi
 801
 802     # not a hard requirement as swrast does not depend on it
 803     if test "x$have_libdrm" = xyes; then
 804         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 805     fi
 806 fi
 807
 808 dnl Direct rendering or just indirect rendering
 809 case "$host_os" in
 810 gnu*)
 811     dnl Disable by default on GNU/Hurd
 812     driglx_direct_default="no"
 813     ;;
 814 cygwin*)
 815     dnl Disable by default on cygwin
 816     driglx_direct_default="no"
 817     ;;
 818 *)
 819     driglx_direct_default="yes"
 820     ;;
 821 esac
 822 AC_ARG_ENABLE([driglx-direct],
 823     [AS_HELP_STRING([--disable-driglx-direct],
 824         [disable direct rendering in GLX and EGL for DRI \
 825             @<:@default=auto@:>@])],
 826     [driglx_direct="$enableval"],
 827     [driglx_direct="$driglx_direct_default"])
 828
 829 dnl
 830 dnl libGL configuration per driver
 831 dnl
 832 case "x$enable_glx$enable_xlib_glx" in
 833 xyesyes)
 834     # Xlib-based GLX
 835     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 836     GL_PC_REQ_PRIV="x11 xext"
 837     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 838     GL_LIB_DEPS="$XLIBGL_LIBS"
 839     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 840     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 841     ;;
 842 xyesno)
 843     # DRI-based GLX
 844     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 845     if test x"$driglx_direct" = xyes; then
 846         if test "x$have_libdrm" != xyes; then
 847             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 848         fi
 849         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 850         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 851         if test x"$enable_dri3" = xyes; then
 852             if test x"$have_libudev" != xyes; then
 853               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 854             fi
 855             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 856             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 857         fi
 858     fi
 859
 860     # find the DRI deps for libGL
 861     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 862
 863     if test x"$enable_dri3" = xyes; then
 864         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 865     fi
 866
 867     # add xf86vidmode if available
 868     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 869     if test "$HAVE_XF86VIDMODE" = yes ; then
 870         dri_modules="$dri_modules xxf86vm"
 871     fi
 872
 873     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 874     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 875     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 876     GL_LIB_DEPS="$DRIGL_LIBS"
 877
 878     # need DRM libs, $PTHREAD_LIBS, etc.
 879     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 881     ;;
 882 esac
 883
 884 if test "$have_libudev" = yes; then
 885     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 886 fi
 887
 888 # This is outside the case (above) so that it is invoked even for non-GLX
 889 # builds.
 890 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 891
 892 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 893 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 894 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 895 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896
 897 AC_SUBST([X11_INCLUDES])
 898 AC_SUBST([GL_LIB_DEPS])
 899 AC_SUBST([GL_PC_REQ_PRIV])
 900 AC_SUBST([GL_PC_LIB_PRIV])
 901 AC_SUBST([GL_PC_CFLAGS])
 902 AC_SUBST([DRI_PC_REQ_PRIV])
 903 AC_SUBST([GLESv1_CM_LIB_DEPS])
 904 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 905 AC_SUBST([GLESv2_LIB_DEPS])
 906 AC_SUBST([GLESv2_PC_LIB_PRIV])
 907
 908 AC_SUBST([HAVE_XF86VIDMODE])
 909
 910 dnl
 911 dnl More GLX setup
 912 dnl
 913 case "x$enable_glx$enable_xlib_glx" in
 914 xyesyes)
 915     DEFINES="$DEFINES -DUSE_XSHM"
 916     ;;
 917 xyesno)
 918     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 919     if test "x$driglx_direct" = xyes; then
 920         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 921     fi
 922     ;;
 923 esac
 924
 925 dnl
 926 dnl TLS detection
 927 dnl
 928
 929 AC_ARG_ENABLE([glx-tls],
 930     [AS_HELP_STRING([--enable-glx-tls],
 931         [enable TLS support in GLX @<:@default=disabled@:>@])],
 932     [GLX_USE_TLS="$enableval"],
 933     [GLX_USE_TLS=no])
 934 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 935
 936 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 937       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 938
 939 dnl
 940 dnl More DRI setup
 941 dnl
 942 dnl Directory for DRI drivers
 943 AC_ARG_WITH([dri-driverdir],
 944     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 945         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 946     [DRI_DRIVER_INSTALL_DIR="$withval"],
 947     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 948 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 949 dnl Extra search path for DRI drivers
 950 AC_ARG_WITH([dri-searchpath],
 951     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 952         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 953     [DRI_DRIVER_SEARCH_DIR="$withval"],
 954     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 955 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 956 dnl Which drivers to build - default is chosen by platform
 957 AC_ARG_WITH([dri-drivers],
 958     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 959         [comma delimited classic DRI drivers list, e.g.
 960         "swrast,i965,radeon" @<:@default=auto@:>@])],
 961     [with_dri_drivers="$withval"],
 962     [with_dri_drivers=auto])
 963
 964 if test "x$with_dri_drivers" = xauto; then
 965     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 966         with_dri_drivers="yes"
 967     else
 968         with_dri_drivers="no"
 969     fi
 970 fi
 971 if test "x$with_dri_drivers" = xno; then
 972     with_dri_drivers=''
 973 fi
 974
 975 dnl If $with_dri_drivers is yes, drivers will be added through
 976 dnl platform checks. Set DEFINES and LIB_DEPS
 977 if test "x$enable_dri" = xyes; then
 978     # Platform specific settings and drivers to build
 979     case "$host_os" in
 980     linux*)
 981         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 982         DEFINES="$DEFINES -DHAVE_ALIAS"
 983         if test "x$enable_dri3" = xyes; then
 984             DEFINES="$DEFINES -DHAVE_DRI3"
 985         fi
 986
 987         case "$host_cpu" in
 988         powerpc* | sparc*)
 989             # Build only the drivers for cards that exist on PowerPC/sparc
 990             if test "x$with_dri_drivers" = "xyes"; then
 991                 with_dri_drivers="r200 radeon swrast"
 992             fi
 993             ;;
 994         esac
 995         ;;
 996     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 997         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 998         DEFINES="$DEFINES -DHAVE_ALIAS"
 999         ;;
1000     gnu*)
1001         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1002         DEFINES="$DEFINES -DHAVE_ALIAS"
1003         ;;
1004     solaris*)
1005         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1006         ;;
1007     cygwin*)
1008         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1009         if test "x$with_dri_drivers" = "xyes"; then
1010             with_dri_drivers="swrast"
1011         fi
1012         ;;
1013     esac
1014
1015     # default drivers
1016     if test "x$with_dri_drivers" = "xyes"; then
1017         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1018     fi
1019
1020     # Check for expat
1021     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1022     if test "x$have_expat" = "xyes"; then
1023        PKG_CHECK_MODULES([EXPAT], [expat], [],
1024                          AC_MSG_ERROR([Expat required for DRI.]))
1025     else
1026        # expat version 2.0 and earlier do not provide expat.pc
1027        EXPAT_LIBS=-lexpat
1028     fi
1029
1030     # If we are building any DRI driver other than swrast.
1031     if test -n "$with_dri_drivers"; then
1032         if test "x$with_dri_drivers" != xswrast; then
1033             # ... libdrm is required
1034             if test "x$have_libdrm" != xyes; then
1035                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1036             fi
1037             DRICOMMON_NEED_LIBDRM=yes
1038         else
1039             DRICOMMON_NEED_LIBDRM=no
1040         fi
1041     fi
1042
1043     # put all the necessary libs together
1044     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1045     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1046
1047 fi
1048
1049 AC_SUBST([DRI_LIB_DEPS])
1050 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1051
1052 DRI_DIRS=''
1053 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1054 if test -n "$with_dri_drivers"; then
1055     if test "x$enable_opengl" != xyes; then
1056         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1057     fi
1058
1059     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1060     for driver in $dri_drivers; do
1061         DRI_DIRS+="$driver "
1062         case "x$driver" in
1063         xi915)
1064             HAVE_I915_DRI=yes;
1065             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1066             ;;
1067         xi965)
1068             HAVE_I965_DRI=yes;
1069             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1070             ;;
1071         xnouveau)
1072             HAVE_NOUVEAU_DRI=yes;
1073             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1074             ;;
1075         xradeon)
1076             HAVE_RADEON_DRI=yes;
1077             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1078             ;;
1079         xr200)
1080             HAVE_R200_DRI=yes;
1081             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1082             ;;
1083         xswrast)
1084             HAVE_SWRAST_DRI=yes;
1085             ;;
1086         *)
1087             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1088             ;;
1089         esac
1090     done
1091     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1092 fi
1093
1094 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1095 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1096                                   "x$enable_osmesa" = xyes -o \
1097                                   -n "$DRI_DIRS")
1098
1099 dnl
1100 dnl OSMesa configuration
1101 dnl
1102
1103 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1104 AC_ARG_WITH([osmesa-bits],
1105     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1106         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1107     [osmesa_bits="$withval"],
1108     [osmesa_bits=8])
1109 if test "x$osmesa_bits" != x8; then
1110     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1111         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1112         osmesa_bits=8
1113     fi
1114 fi
1115 case "x$osmesa_bits" in
1116 x8)
1117     OSMESA_LIB="${OSMESA_LIB}"
1118     ;;
1119 x16|x32)
1120     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1121     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1122     ;;
1123 *)
1124     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1125     ;;
1126 esac
1127
1128 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1129     # only link libraries with osmesa if shared
1130     if test "$enable_static" = no; then
1131         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1132     else
1133         OSMESA_LIB_DEPS=""
1134     fi
1135     OSMESA_MESA_DEPS=""
1136     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1137 fi
1138
1139 AC_SUBST([OSMESA_LIB_DEPS])
1140 AC_SUBST([OSMESA_MESA_DEPS])
1141 AC_SUBST([OSMESA_PC_REQ])
1142 AC_SUBST([OSMESA_PC_LIB_PRIV])
1143
1144 dnl
1145 dnl gbm configuration
1146 dnl
1147 if test "x$enable_gbm" = xauto; then
1148     case "$with_egl_platforms" in
1149         *drm*)
1150             enable_gbm=yes ;;
1151          *)
1152             enable_gbm=no ;;
1153     esac
1154 fi
1155 if test "x$enable_gbm" = xyes; then
1156     if test x"$have_libudev" != xyes; then
1157         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1158     fi
1159
1160     if test "x$enable_dri" = xyes; then
1161         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1162         if test "x$enable_shared_glapi" = xno; then
1163             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1164         fi
1165     fi
1166 fi
1167 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1168 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1169 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1170 AC_SUBST([GBM_PC_REQ_PRIV])
1171 AC_SUBST([GBM_PC_LIB_PRIV])
1172
1173 dnl
1174 dnl EGL configuration
1175 dnl
1176 EGL_CLIENT_APIS=""
1177
1178 if test "x$enable_egl" = xyes; then
1179     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1180
1181     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1182
1183     if test "$enable_static" != yes; then
1184         if test "x$enable_dri" = xyes; then
1185             HAVE_EGL_DRIVER_DRI2=1
1186         fi
1187
1188     fi
1189 fi
1190 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1191 AC_SUBST([EGL_LIB_DEPS])
1192
1193 dnl
1194 dnl EGL Gallium configuration
1195 dnl
1196 if test "x$enable_gallium_egl" = xyes; then
1197     if test -z "$with_gallium_drivers"; then
1198         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1199     fi
1200     if test "x$enable_egl" = xno; then
1201         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1202     fi
1203     if test "x$have_libdrm" != xyes; then
1204         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1205     fi
1206
1207     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1208     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1209 fi
1210 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1211
1212 dnl
1213 dnl gbm Gallium configuration
1214 dnl
1215 if test "x$enable_gallium_gbm" = xauto; then
1216     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1217         yesyesyes*drm*)
1218             enable_gallium_gbm=yes ;;
1219          *)
1220             enable_gallium_gbm=no ;;
1221     esac
1222 fi
1223 if test "x$enable_gallium_gbm" = xyes; then
1224     if test -z "$with_gallium_drivers"; then
1225         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1226     fi
1227     if test "x$enable_gbm" = xno; then
1228         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1229     fi
1230     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1231     if test "x$enable_dri" = xno; then
1232         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1233     fi
1234
1235     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1236     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1237     enable_gallium_loader=yes
1238 fi
1239 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1240
1241 dnl
1242 dnl XA configuration
1243 dnl
1244 if test "x$enable_xa" = xyes; then
1245     if test "x$with_gallium_drivers" = xswrast; then
1246        AC_MSG_ERROR([
1247           Building xa requires at least one non swrast gallium driver.
1248           If you are looking to use libxatracker.so with vmware's virtual gpu,
1249           make sure to include svga in the gallium drivers list, apart from
1250           enabling XA.
1251           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1252     fi
1253     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1254     enable_gallium_loader=yes
1255 fi
1256 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1257
1258 dnl
1259 dnl OpenVG configuration
1260 dnl
1261 VG_LIB_DEPS=""
1262
1263 if test "x$enable_openvg" = xyes; then
1264     if test "x$enable_egl" = xno; then
1265         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1266     fi
1267     if test -z "$with_gallium_drivers"; then
1268         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1269     fi
1270     if test "x$enable_gallium_egl" = xno; then
1271         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1272     fi
1273
1274     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1275     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1276     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1277     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1278     AC_SUBST([VG_PC_LIB_PRIV])
1279 fi
1280 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1281
1282 dnl
1283 dnl Gallium G3DVL configuration
1284 dnl
1285 if test -n "$with_gallium_drivers"; then
1286     if test "x$enable_xvmc" = xauto; then
1287         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1288     fi
1289
1290     if test "x$enable_vdpau" = xauto; then
1291         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1292     fi
1293
1294     if test "x$enable_omx" = xauto; then
1295         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1296     fi
1297 fi
1298
1299 if test "x$enable_xvmc" = xyes; then
1300     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1301     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1302 fi
1303 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1304
1305 if test "x$enable_vdpau" = xyes; then
1306     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8],
1307                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1308     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1309 fi
1310 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1311
1312 if test "x$enable_omx" = xyes; then
1313     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= 0.0 x11-xcb xcb-dri2 >= 1.8])
1314     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1315 fi
1316 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1317
1318 dnl
1319 dnl OpenCL configuration
1320 dnl
1321
1322 AC_ARG_WITH([libclc-path],
1323    [AS_HELP_STRING([--with-libclc-path],
1324          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1325    [LIBCLC_PATH="$withval"],
1326    [LIBCLC_PATH=''])
1327
1328 if test -n "$LIBCLC_PATH"; then
1329    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1330                   Please review the updated build instructions for clover:
1331                   http://dri.freedesktop.org/wiki/GalliumCompute])
1332 fi
1333
1334
1335 AC_ARG_WITH([clang-libdir],
1336    [AS_HELP_STRING([--with-clang-libdir],
1337          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1338    [CLANG_LIBDIR="$withval"],
1339    [CLANG_LIBDIR=''])
1340
1341 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1342
1343 if test "x$enable_opencl" = xyes; then
1344     if test -z "$with_gallium_drivers"; then
1345         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1346     fi
1347
1348     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1349         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1350     fi
1351
1352     if test "x$have_libclc" = xno; then
1353         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1354                     Make sure the directory containing libclc.pc is specified in your
1355                     PKG_CONFIG_PATH environment variable.
1356                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1357     else
1358         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1359         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1360         AC_SUBST([LIBCLC_INCLUDEDIR])
1361         AC_SUBST([LIBCLC_LIBEXECDIR])
1362     fi
1363
1364     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1365     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1366     enable_gallium_loader=yes
1367
1368     if test "x$enable_opencl_icd" = xyes; then
1369         OPENCL_LIBNAME="MesaOpenCL"
1370     else
1371         OPENCL_LIBNAME="OpenCL"
1372     fi
1373 fi
1374 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1375 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1376 AC_SUBST([OPENCL_LIBNAME])
1377
1378 dnl
1379 dnl Gallium configuration
1380 dnl
1381 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1382
1383 AC_SUBST([LLVM_BINDIR])
1384 AC_SUBST([LLVM_CFLAGS])
1385 AC_SUBST([LLVM_CPPFLAGS])
1386 AC_SUBST([LLVM_CXXFLAGS])
1387 AC_SUBST([LLVM_LIBDIR])
1388 AC_SUBST([LLVM_LIBS])
1389 AC_SUBST([LLVM_LDFLAGS])
1390 AC_SUBST([LLVM_INCLUDEDIR])
1391 AC_SUBST([LLVM_VERSION])
1392 AC_SUBST([CLANG_RESOURCE_DIR])
1393
1394 case "x$enable_opengl$enable_gles1$enable_gles2" in
1395 x*yes*)
1396     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1397     ;;
1398 esac
1399
1400 AC_SUBST([VG_LIB_DEPS])
1401 AC_SUBST([EGL_CLIENT_APIS])
1402
1403 dnl
1404 dnl EGL Platforms configuration
1405 dnl
1406 AC_ARG_WITH([egl-platforms],
1407     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1408         [comma delimited native platforms libEGL supports, e.g.
1409         "x11,drm" @<:@default=auto@:>@])],
1410     [with_egl_platforms="$withval"],
1411     [if test "x$enable_egl" = xyes; then
1412         with_egl_platforms="x11"
1413     else
1414         with_egl_platforms=""
1415     fi])
1416
1417 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1418     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1419 fi
1420
1421 # Do per-EGL platform setups and checks
1422 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1423 for plat in $egl_platforms; do
1424         case "$plat" in
1425         wayland)
1426                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1427                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1428
1429                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1430                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1431                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1432                 ;;
1433
1434         x11)
1435                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1436                 ;;
1437
1438         drm)
1439                 test "x$enable_gbm" = "xno" &&
1440                         AC_MSG_ERROR([EGL platform drm needs gbm])
1441                 test "x$have_libdrm" != xyes &&
1442                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1443                 ;;
1444
1445         android|fbdev|gdi|null)
1446                 ;;
1447
1448         *)
1449                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1450                 ;;
1451         esac
1452
1453         case "$plat$have_libudev" in
1454                 waylandno|drmno)
1455                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1456         esac
1457 done
1458
1459 # libEGL wants to default to the first platform specified in
1460 # ./configure.  parse that here.
1461 if test "x$egl_platforms" != "x"; then
1462     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1463     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1464 else
1465     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1466 fi
1467
1468 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1469     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1470     NEED_WINSYS_XLIB=yes
1471 fi
1472 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1473 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1474 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1475 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1476 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1477
1478 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1479
1480 AC_SUBST([EGL_NATIVE_PLATFORM])
1481 AC_SUBST([EGL_CFLAGS])
1482
1483 # If we don't have the X11 platform, set this define so we don't try to include
1484 # the X11 headers.
1485 if ! echo "$egl_platforms" | grep -q 'x11'; then
1486     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1487     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1488 fi
1489
1490 AC_ARG_WITH([egl-driver-dir],
1491     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1492                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1493     [EGL_DRIVER_INSTALL_DIR="$withval"],
1494     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1495 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1496
1497 AC_ARG_WITH([max-width],
1498     [AS_HELP_STRING([--with-max-width=N],
1499                     [Maximum framebuffer width (4096)])],
1500     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1501      AS_IF([test "${withval}" -gt "4096"],
1502            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1503 )
1504 AC_ARG_WITH([max-height],
1505     [AS_HELP_STRING([--with-max-height=N],
1506                     [Maximum framebuffer height (4096)])],
1507     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1508      AS_IF([test "${withval}" -gt "4096"],
1509            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1510 )
1511
1512 dnl
1513 dnl Gallium LLVM
1514 dnl
1515 AC_ARG_ENABLE([gallium-llvm],
1516     [AS_HELP_STRING([--enable-gallium-llvm],
1517         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1518     [enable_gallium_llvm="$enableval"],
1519     [enable_gallium_llvm=auto])
1520
1521 AC_ARG_ENABLE([llvm-shared-libs],
1522     [AS_HELP_STRING([--enable-llvm-shared-libs],
1523         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1524     [],
1525     [with_llvm_shared_libs=yes])
1526
1527 AC_ARG_WITH([llvm-prefix],
1528     [AS_HELP_STRING([--with-llvm-prefix],
1529         [Prefix for LLVM installations in non-standard locations])],
1530     [llvm_prefix="$withval"],
1531     [llvm_prefix=''])
1532
1533
1534 # Call this inside ` ` to get the return value.
1535 # $1 is the llvm-config command with arguments.
1536 strip_unwanted_llvm_flags() {
1537     # Use \> (marks the end of the word)
1538     echo `$1` | sed \
1539         -e 's/-DNDEBUG\>//g' \
1540         -e 's/-pedantic\>//g' \
1541         -e 's/-Wcovered-switch-default\>//g' \
1542         -e 's/-O.\>//g' \
1543         -e 's/-g\>//g' \
1544         -e 's/-Wall\>//g' \
1545         -e 's/-fcolor-diagnostics\>//g' \
1546         -e 's/-fomit-frame-pointer\>//g'
1547 }
1548
1549
1550 if test -z "$with_gallium_drivers"; then
1551     enable_gallium_llvm=no
1552 fi
1553 if test "x$enable_gallium_llvm" = xauto; then
1554     case "$host_cpu" in
1555     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1556     esac
1557 fi
1558 if test "x$enable_gallium_llvm" = xyes; then
1559     if test -n "$llvm_prefix"; then
1560         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1561     else
1562         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1563     fi
1564
1565     if test "x$LLVM_CONFIG" != xno; then
1566         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1567         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1568         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1569         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1570         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1571         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1572         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1573         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1574         LLVM_LDFLAGS="-Wl,-rpath,$LLVM_LIBDIR $LLVM_LDFLAGS"
1575
1576         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1577             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1578         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1579             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1580
1581         if test -n "${LLVM_VERSION_MAJOR}"; then
1582             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1583         else
1584             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1585         fi
1586
1587         LLVM_COMPONENTS="engine bitwriter"
1588         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1589             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1590         fi
1591
1592         if test "x$enable_opencl" = xyes; then
1593             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1594             # LLVM 3.3 >= 177971 requires IRReader
1595             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1596                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1597             fi
1598             # LLVM 3.4 requires Option
1599             if $LLVM_CONFIG --components | grep -qw 'option'; then
1600                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1601             fi
1602         fi
1603         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1604         MESA_LLVM=1
1605
1606         dnl Check for Clang internal headers
1607         if test "x$enable_opencl" = xyes; then
1608             if test -z "$CLANG_LIBDIR"; then
1609                 CLANG_LIBDIR=${LLVM_LIBDIR}
1610             fi
1611             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1612             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1613                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1614         fi
1615     else
1616         MESA_LLVM=0
1617         LLVM_VERSION_INT=0
1618     fi
1619 else
1620     MESA_LLVM=0
1621     LLVM_VERSION_INT=0
1622 fi
1623
1624 dnl Directory for XVMC libs
1625 AC_ARG_WITH([xvmc-libdir],
1626     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1627         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1628     [XVMC_LIB_INSTALL_DIR="$withval"],
1629     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1630 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1631
1632 dnl
1633 dnl Gallium Tests
1634 dnl
1635 if test "x$enable_gallium_tests" = xyes; then
1636     enable_gallium_loader=yes
1637 fi
1638 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1639
1640 if test "x$enable_gallium_loader" = xyes; then
1641     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1642 fi
1643 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1644
1645 dnl Directory for VDPAU libs
1646 AC_ARG_WITH([vdpau-libdir],
1647     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1648         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1649     [VDPAU_LIB_INSTALL_DIR="$withval"],
1650     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1651 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1652
1653 AC_ARG_WITH([omx-libdir],
1654     [AS_HELP_STRING([--with-omx-libdir=DIR],
1655         [directory for the OMX libraries])],
1656     [OMX_LIB_INSTALL_DIR="$withval"],
1657     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1658 AC_SUBST([OMX_LIB_INSTALL_DIR])
1659
1660 dnl Directory for OpenCL libs
1661 AC_ARG_WITH([opencl-libdir],
1662     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1663         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1664     [OPENCL_LIB_INSTALL_DIR="$withval"],
1665     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1666 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1667
1668 dnl
1669 dnl Gallium helper functions
1670 dnl
1671 gallium_check_st() {
1672     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1673          if test "x$have_libdrm" != xyes; then
1674             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1675          fi
1676          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1677     fi
1678     if test "x$enable_dri" = xyes && test -n "$2"; then
1679          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1680     fi
1681     if test "x$enable_xa" = xyes && test -n "$3"; then
1682          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1683     fi
1684     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1685          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1686     fi
1687     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1688          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1689     fi
1690     if test "x$enable_omx" = xyes && test "x$6" != x; then
1691          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1692     fi
1693 }
1694
1695 gallium_require_llvm() {
1696     if test "x$MESA_LLVM" = x0; then
1697         case "$host_cpu" in
1698         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1699         esac
1700     fi
1701 }
1702
1703 gallium_require_drm_loader() {
1704     if test "x$enable_gallium_loader" = xyes; then
1705         if test "x$have_libudev" != xyes; then
1706             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1707         fi
1708         if test "x$have_libdrm" != xyes; then
1709             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1710         fi
1711         enable_gallium_drm_loader=yes
1712     fi
1713 }
1714
1715 radeon_llvm_check() {
1716     if test "x$enable_gallium_llvm" != "xyes"; then
1717         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1718     fi
1719     LLVM_REQUIRED_VERSION_MAJOR="3"
1720     LLVM_REQUIRED_VERSION_MINOR="3"
1721     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1722         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1723     fi
1724     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1725         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1726                       sources with the --enable-experimental-targets=R600
1727                       configure flag])
1728     fi
1729     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1730     NEED_RADEON_LLVM=yes
1731     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1732                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1733 }
1734
1735 dnl Gallium drivers
1736 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1737         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1738     NEED_NONNULL_WINSYS=yes
1739 fi
1740 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1741
1742 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1743 if test -n "$with_gallium_drivers"; then
1744     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1745     for driver in $gallium_drivers; do
1746         case "x$driver" in
1747         xsvga)
1748             HAVE_GALLIUM_SVGA=yes
1749             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1750             gallium_require_drm_loader
1751             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1752             ;;
1753         xi915)
1754             HAVE_GALLIUM_I915=yes
1755             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1756             gallium_require_drm_loader
1757             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1758             if test "x$MESA_LLVM" = x1; then
1759                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1760             fi
1761             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1762             gallium_check_st "i915/drm" "dri-i915"
1763             DRICOMMON_NEED_LIBDRM=yes
1764             ;;
1765         xilo)
1766             HAVE_GALLIUM_ILO=yes
1767             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1768             gallium_require_drm_loader
1769             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1770             gallium_check_st "intel/drm" "dri-ilo"
1771             DRICOMMON_NEED_LIBDRM=yes
1772             ;;
1773         xr300)
1774             HAVE_GALLIUM_R300=yes
1775             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1776             gallium_require_drm_loader
1777             gallium_require_llvm "Gallium R300"
1778             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1779             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1780             DRICOMMON_NEED_LIBDRM=yes
1781             ;;
1782         xr600)
1783             HAVE_GALLIUM_R600=yes
1784             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1785             gallium_require_drm_loader
1786             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1787             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1788                 radeon_llvm_check "r600g"
1789                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1790             fi
1791             if test "x$enable_r600_llvm" = xyes; then
1792                 USE_R600_LLVM_COMPILER=yes;
1793             fi
1794             if test "x$enable_opencl" = xyes; then
1795                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1796             fi
1797             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1798             DRICOMMON_NEED_LIBDRM=yes
1799             ;;
1800         xradeonsi)
1801             HAVE_GALLIUM_RADEONSI=yes
1802             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1803             gallium_require_drm_loader
1804             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1805             radeon_llvm_check "radeonsi"
1806             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1807             DRICOMMON_NEED_LIBDRM=yes
1808             ;;
1809         xnouveau)
1810             HAVE_GALLIUM_NOUVEAU=yes
1811             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1812             gallium_require_drm_loader
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1814             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1815             DRICOMMON_NEED_LIBDRM=yes
1816             ;;
1817         xfreedreno)
1818             HAVE_GALLIUM_FREEDRENO=yes
1819             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1820             gallium_require_drm_loader
1821             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1822             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1823             DRICOMMON_NEED_LIBDRM=yes
1824             ;;
1825         xswrast)
1826             HAVE_GALLIUM_SOFTPIPE=yes
1827             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1828             if test "x$MESA_LLVM" = x1; then
1829                 HAVE_GALLIUM_LLVMPIPE=yes
1830                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1831             fi
1832
1833             if test "x$enable_dri" = xyes; then
1834                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1835             fi
1836             ;;
1837         *)
1838             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1839             ;;
1840         esac
1841     done
1842 fi
1843
1844 dnl Set LLVM_LIBS - This is done after the driver configuration so
1845 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1846 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1847 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1848 dnl this was causing the same libraries to be appear multiple times
1849 dnl in LLVM_LIBS.
1850
1851 if test "x$MESA_LLVM" != x0; then
1852
1853     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1854
1855     if test "x$with_llvm_shared_libs" = xyes; then
1856         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1857         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1858         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1859
1860         if test "x$llvm_have_one_so" = xyes; then
1861             dnl LLVM was built using auto*, so there is only one shared object.
1862             LLVM_LIBS="-l$LLVM_SO_NAME"
1863         else
1864             dnl If LLVM was built with CMake, there will be one shared object per
1865             dnl component.
1866             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1867                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1868         Please make sure you have built llvm with the --enable-shared option
1869         and that your llvm libraries are installed in $LLVM_LIBDIR
1870         If you have installed your llvm libraries to a different directory you
1871         can use the --with-llvm-prefix= configure flag to specify this directory.
1872         NOTE: Mesa is attempting to use llvm shared libraries because you have
1873         passed one of the following options to configure:
1874                 --with-llvm-shared-libs
1875                 --enable-opencl
1876         If you do not want to build with llvm shared libraries and instead want to
1877         use llvm static libraries then remove these options from your configure
1878         invocation and reconfigure.])])
1879
1880            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1881            dnl install uses a shared object for each compoenent and we have
1882            dnl already added all of these objects to LLVM_LIBS.
1883         fi
1884     fi
1885 fi
1886
1887 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1888 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1897
1898 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1899                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1900                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1901 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1902                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1903                                                   && test "x$MESA_LLVM" = x1)
1904
1905 # NOTE: anything using xcb or other client side libs ends up in separate
1906 #       _CLIENT variables.  The pipe loader is built in two variants,
1907 #       one that is standalone and does not link any x client libs (for
1908 #       use by XA tracker in particular, but could be used in any case
1909 #       where communication with xserver is not desired).
1910 if test "x$enable_gallium_loader" = xyes; then
1911     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1912
1913     if test "x$enable_gallium_xlib_loader" = xyes; then
1914         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1915         NEED_WINSYS_XLIB="yes"
1916         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1917     fi
1918
1919     if test "x$enable_gallium_drm_loader" = xyes; then
1920         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1921         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1922                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1923         if test "x$pipe_loader_have_xcb" = xyes; then
1924             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1925             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1926         fi
1927     fi
1928
1929     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1930     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1931
1932     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1933     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1934     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1935     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1936 fi
1937 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1938
1939 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1940 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1941 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1942 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1943 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1944 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1945
1946 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1947                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1948                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1949                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1950 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1951                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1952 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1953 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1954 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1955 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1956 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1957 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1958 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1959
1960 AC_SUBST([ELF_LIB])
1961
1962 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1963 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1964 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1965 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1966 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1967
1968 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1969 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1970 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1971
1972 AC_SUBST([VDPAU_MAJOR], 1)
1973 AC_SUBST([VDPAU_MINOR], 0)
1974
1975 AC_SUBST([XVMC_MAJOR], 1)
1976 AC_SUBST([XVMC_MINOR], 0)
1977
1978 AC_SUBST([XA_MAJOR], 2)
1979 AC_SUBST([XA_MINOR], 2)
1980 AC_SUBST([XA_TINY], 0)
1981 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1982
1983 dnl Restore LDFLAGS and CPPFLAGS
1984 LDFLAGS="$_SAVE_LDFLAGS"
1985 CPPFLAGS="$_SAVE_CPPFLAGS"
1986
1987 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1988 if test "x$acv_mesa_CLANG" = xyes; then
1989     CFLAGS="$CFLAGS -Qunused-arguments"
1990     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1991 fi
1992
1993 dnl Add user CFLAGS and CXXFLAGS
1994 CFLAGS="$CFLAGS $USER_CFLAGS"
1995 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1996
1997 dnl Substitute the config
1998 AC_CONFIG_FILES([Makefile
1999                 src/Makefile
2000                 src/egl/Makefile
2001                 src/egl/drivers/Makefile
2002                 src/egl/drivers/dri2/Makefile
2003                 src/egl/main/Makefile
2004                 src/egl/main/egl.pc
2005                 src/egl/wayland/Makefile
2006                 src/egl/wayland/wayland-drm/Makefile
2007                 src/egl/wayland/wayland-egl/Makefile
2008                 src/egl/wayland/wayland-egl/wayland-egl.pc
2009                 src/gallium/auxiliary/Makefile
2010                 src/gallium/auxiliary/pipe-loader/Makefile
2011                 src/gallium/drivers/Makefile
2012                 src/gallium/drivers/freedreno/Makefile
2013                 src/gallium/drivers/galahad/Makefile
2014                 src/gallium/drivers/i915/Makefile
2015                 src/gallium/drivers/identity/Makefile
2016                 src/gallium/drivers/ilo/Makefile
2017                 src/gallium/drivers/llvmpipe/Makefile
2018                 src/gallium/drivers/noop/Makefile
2019                 src/gallium/drivers/nouveau/Makefile
2020                 src/gallium/drivers/r300/Makefile
2021                 src/gallium/drivers/r600/Makefile
2022                 src/gallium/drivers/radeon/Makefile
2023                 src/gallium/drivers/radeonsi/Makefile
2024                 src/gallium/drivers/rbug/Makefile
2025                 src/gallium/drivers/softpipe/Makefile
2026                 src/gallium/drivers/svga/Makefile
2027                 src/gallium/drivers/trace/Makefile
2028                 src/gallium/state_trackers/Makefile
2029                 src/gallium/state_trackers/clover/Makefile
2030                 src/gallium/state_trackers/dri/Makefile
2031                 src/gallium/state_trackers/dri/drm/Makefile
2032                 src/gallium/state_trackers/dri/sw/Makefile
2033                 src/gallium/state_trackers/egl/Makefile
2034                 src/gallium/state_trackers/gbm/Makefile
2035                 src/gallium/state_trackers/glx/xlib/Makefile
2036                 src/gallium/state_trackers/omx/Makefile
2037                 src/gallium/state_trackers/osmesa/Makefile
2038                 src/gallium/state_trackers/vdpau/Makefile
2039                 src/gallium/state_trackers/vega/Makefile
2040                 src/gallium/state_trackers/xa/Makefile
2041                 src/gallium/state_trackers/xvmc/Makefile
2042                 src/gallium/targets/Makefile
2043                 src/gallium/targets/dri-freedreno/Makefile
2044                 src/gallium/targets/dri-i915/Makefile
2045                 src/gallium/targets/dri-ilo/Makefile
2046                 src/gallium/targets/dri-nouveau/Makefile
2047                 src/gallium/targets/dri-swrast/Makefile
2048                 src/gallium/targets/dri-vmwgfx/Makefile
2049                 src/gallium/targets/egl-static/Makefile
2050                 src/gallium/targets/gbm/Makefile
2051                 src/gallium/targets/opencl/Makefile
2052                 src/gallium/targets/xa/Makefile
2053                 src/gallium/targets/xa/xatracker.pc
2054                 src/gallium/targets/osmesa/Makefile
2055                 src/gallium/targets/osmesa/osmesa.pc
2056                 src/gallium/targets/pipe-loader/Makefile
2057                 src/gallium/targets/radeonsi/dri/Makefile
2058                 src/gallium/targets/radeonsi/omx/Makefile
2059                 src/gallium/targets/radeonsi/vdpau/Makefile
2060                 src/gallium/targets/r300/dri/Makefile
2061                 src/gallium/targets/r600/dri/Makefile
2062                 src/gallium/targets/r600/omx/Makefile
2063                 src/gallium/targets/r600/vdpau/Makefile
2064                 src/gallium/targets/r600/xvmc/Makefile
2065                 src/gallium/targets/libgl-xlib/Makefile
2066                 src/gallium/targets/vdpau-nouveau/Makefile
2067                 src/gallium/targets/xvmc-nouveau/Makefile
2068                 src/gallium/tests/trivial/Makefile
2069                 src/gallium/tests/unit/Makefile
2070                 src/gallium/winsys/Makefile
2071                 src/gallium/winsys/freedreno/drm/Makefile
2072                 src/gallium/winsys/i915/drm/Makefile
2073                 src/gallium/winsys/i915/sw/Makefile
2074                 src/gallium/winsys/intel/drm/Makefile
2075                 src/gallium/winsys/nouveau/drm/Makefile
2076                 src/gallium/winsys/radeon/drm/Makefile
2077                 src/gallium/winsys/svga/drm/Makefile
2078                 src/gallium/winsys/sw/dri/Makefile
2079                 src/gallium/winsys/sw/fbdev/Makefile
2080                 src/gallium/winsys/sw/null/Makefile
2081                 src/gallium/winsys/sw/wayland/Makefile
2082                 src/gallium/winsys/sw/wrapper/Makefile
2083                 src/gallium/winsys/sw/xlib/Makefile
2084                 src/gbm/Makefile
2085                 src/gbm/main/gbm.pc
2086                 src/glsl/Makefile
2087                 src/glx/Makefile
2088                 src/glx/tests/Makefile
2089                 src/gtest/Makefile
2090                 src/loader/Makefile
2091                 src/mapi/Makefile
2092                 src/mapi/es1api/Makefile
2093                 src/mapi/es1api/glesv1_cm.pc
2094                 src/mapi/es2api/Makefile
2095                 src/mapi/es2api/glesv2.pc
2096                 src/mapi/glapi/Makefile
2097                 src/mapi/glapi/gen/Makefile
2098                 src/mapi/glapi/tests/Makefile
2099                 src/mapi/shared-glapi/Makefile
2100                 src/mapi/shared-glapi/tests/Makefile
2101                 src/mapi/vgapi/Makefile
2102                 src/mapi/vgapi/vg.pc
2103                 src/mesa/Makefile
2104                 src/mesa/gl.pc
2105                 src/mesa/drivers/dri/dri.pc
2106                 src/mesa/drivers/dri/common/Makefile
2107                 src/mesa/drivers/dri/common/xmlpool/Makefile
2108                 src/mesa/drivers/dri/i915/Makefile
2109                 src/mesa/drivers/dri/i965/Makefile
2110                 src/mesa/drivers/dri/Makefile
2111                 src/mesa/drivers/dri/nouveau/Makefile
2112                 src/mesa/drivers/dri/r200/Makefile
2113                 src/mesa/drivers/dri/radeon/Makefile
2114                 src/mesa/drivers/dri/swrast/Makefile
2115                 src/mesa/drivers/osmesa/Makefile
2116                 src/mesa/drivers/osmesa/osmesa.pc
2117                 src/mesa/drivers/x11/Makefile
2118                 src/mesa/main/tests/Makefile
2119                 src/mesa/main/tests/hash_table/Makefile])
2120
2121 dnl Sort the dirs alphabetically
2122 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2123 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2124 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2125 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2126
2127 AC_OUTPUT
2128
2129 dnl
2130 dnl Output some configuration info for the user
2131 dnl
2132 echo ""
2133 echo "        prefix:          $prefix"
2134 echo "        exec_prefix:     $exec_prefix"
2135 echo "        libdir:          $libdir"
2136 echo "        includedir:      $includedir"
2137
2138 dnl API info
2139 echo ""
2140 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2141 echo "        OpenVG:          $enable_openvg"
2142
2143 dnl Driver info
2144 echo ""
2145 case "x$enable_osmesa$enable_gallium_osmesa" in
2146 xnoyes)
2147         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2148         ;;
2149 xyesno)
2150         echo "        OSMesa:          lib$OSMESA_LIB"
2151         ;;
2152 xnono)
2153         echo "        OSMesa:          no"
2154         ;;
2155 esac
2156
2157 if test "x$enable_dri" != xno; then
2158         if test -z "$DRI_DIRS"; then
2159             echo "        DRI drivers:     no"
2160         else
2161             echo "        DRI drivers:     $DRI_DIRS"
2162         fi
2163         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2164 fi
2165
2166 case "x$enable_glx$enable_xlib_glx" in
2167 xyesyes)
2168     echo "        GLX:             Xlib-based"
2169     ;;
2170 xyesno)
2171     echo "        GLX:             DRI-based"
2172     ;;
2173 *)
2174     echo "        GLX:             $enable_glx"
2175     ;;
2176 esac
2177
2178 dnl EGL
2179 echo ""
2180 echo "        EGL:             $enable_egl"
2181 if test "$enable_egl" = yes; then
2182     echo "        EGL platforms:   $egl_platforms"
2183
2184     egl_drivers=""
2185     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2186         egl_drivers="$egl_drivers builtin:egl_dri2"
2187     fi
2188
2189     if test "x$enable_gallium_egl" = xyes; then
2190         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2191         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2192     else
2193         echo "        EGL drivers:    $egl_drivers"
2194     fi
2195 fi
2196
2197 echo ""
2198 if test "x$MESA_LLVM" = x1; then
2199     echo "        llvm:            yes"
2200     echo "        llvm-config:     $LLVM_CONFIG"
2201     echo "        llvm-version:    $LLVM_VERSION"
2202 else
2203     echo "        llvm:            no"
2204 fi
2205
2206 echo ""
2207 if test -n "$with_gallium_drivers"; then
2208     echo "        Gallium:         yes"
2209     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2210     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2211     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2212     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2213 else
2214     echo "        Gallium:         no"
2215 fi
2216
2217
2218 dnl Libraries
2219 echo ""
2220 echo "        Shared libs:     $enable_shared"
2221 echo "        Static libs:     $enable_static"
2222 echo "        Shared-glapi:    $enable_shared_glapi"
2223
2224 dnl Compiler options
2225 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2226 cflags=`echo $CFLAGS | \
2227     $SED 's/^ *//;s/  */ /;s/ *$//'`
2228 cxxflags=`echo $CXXFLAGS | \
2229     $SED 's/^ *//;s/  */ /;s/ *$//'`
2230 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2231 echo ""
2232 echo "        CFLAGS:          $cflags"
2233 echo "        CXXFLAGS:        $cxxflags"
2234 echo "        Macros:          $defines"
2235 echo ""
2236 if test "x$MESA_LLVM" = x1; then
2237     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2238     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2239     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2240     echo ""
2241 fi
2242 echo "        PYTHON2:         $PYTHON2"
2243
2244 echo ""
2245 echo "        Run '${MAKE-make}' to build Mesa"
2246 echo ""