configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.66
  76 LIBDRM_RADEON_REQUIRED=2.4.56
  77 LIBDRM_AMDGPU_REQUIRED=2.4.63
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.6
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XSHMFENCE_REQUIRED=1.1
  98 XVMC_REQUIRED=1.0.6
  99 PYTHON_MAKO_REQUIRED=0.8.0
 100 LIBSENSORS_REQUIRED=4.0.0
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.6.0
 106 LLVM_REQUIRED_RADEONSI=3.6.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.6.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127 AC_CHECK_PROG(XXD, xxd, [xxd])
 128
 129 AX_PROG_BISON([],
 130               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 131                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 132 AX_PROG_FLEX([],
 133              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 134                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 135
 136 AC_CHECK_PROG(INDENT, indent, indent, cat)
 137 if test "x$INDENT" != "xcat"; then
 138     # Only GNU indent is supported
 139     INDENT_VERSION=`indent --version | grep GNU`
 140     if test $? -eq 0; then
 141        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 142     else
 143        INDENT="cat"
 144     fi
 145 fi
 146
 147 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 148
 149 if test -z "$PYTHON2"; then
 150     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 151         AC_MSG_ERROR([Python not found - unable to generate sources])
 152     fi
 153 else
 154     if test "x$acv_mako_found" = xno; then
 155         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 156             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 157         fi
 158     fi
 159 fi
 160
 161 AC_PROG_INSTALL
 162
 163 dnl We need a POSIX shell for parts of the build. Assume we have one
 164 dnl in most cases.
 165 case "$host_os" in
 166 solaris*)
 167     # Solaris /bin/sh is too old/non-POSIX compliant
 168     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 169     SHELL="$POSIX_SHELL"
 170     ;;
 171 esac
 172
 173 dnl clang is mostly GCC-compatible, but its version is much lower,
 174 dnl so we have to check for it.
 175 AC_MSG_CHECKING([if compiling with clang])
 176
 177 AC_COMPILE_IFELSE(
 178 [AC_LANG_PROGRAM([], [[
 179 #ifndef __clang__
 180        not clang
 181 #endif
 182 ]])],
 183 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 184
 185 AC_MSG_RESULT([$acv_mesa_CLANG])
 186
 187 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 188 dnl versions are explictly not supported.
 189 GEN_ASM_OFFSETS=no
 190 USE_GNU99=no
 191 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 192     AC_MSG_CHECKING([whether gcc version is sufficient])
 193     major=0
 194     minor=0
 195
 196     GCC_VERSION=`$CC -dumpversion`
 197     if test $? -eq 0; then
 198         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 199         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 200     fi
 201
 202     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 203         AC_MSG_RESULT([no])
 204         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 205     else
 206         AC_MSG_RESULT([yes])
 207     fi
 208
 209     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 210         USE_GNU99=yes
 211     fi
 212     if test "x$cross_compiling" = xyes; then
 213         GEN_ASM_OFFSETS=yes
 214     fi
 215 fi
 216
 217 dnl We don't support building Mesa with Sun C compiler
 218 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 219 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 220 if test "x$SUNCC" = xyes; then
 221     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 222 fi
 223
 224 dnl Check for compiler builtins
 225 AX_GCC_BUILTIN([__builtin_bswap32])
 226 AX_GCC_BUILTIN([__builtin_bswap64])
 227 AX_GCC_BUILTIN([__builtin_clz])
 228 AX_GCC_BUILTIN([__builtin_clzll])
 229 AX_GCC_BUILTIN([__builtin_ctz])
 230 AX_GCC_BUILTIN([__builtin_expect])
 231 AX_GCC_BUILTIN([__builtin_ffs])
 232 AX_GCC_BUILTIN([__builtin_ffsll])
 233 AX_GCC_BUILTIN([__builtin_popcount])
 234 AX_GCC_BUILTIN([__builtin_popcountll])
 235 AX_GCC_BUILTIN([__builtin_unreachable])
 236
 237 AX_GCC_FUNC_ATTRIBUTE([const])
 238 AX_GCC_FUNC_ATTRIBUTE([flatten])
 239 AX_GCC_FUNC_ATTRIBUTE([format])
 240 AX_GCC_FUNC_ATTRIBUTE([malloc])
 241 AX_GCC_FUNC_ATTRIBUTE([packed])
 242 AX_GCC_FUNC_ATTRIBUTE([pure])
 243 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 244 AX_GCC_FUNC_ATTRIBUTE([unused])
 245 AX_GCC_FUNC_ATTRIBUTE([visibility])
 246 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 247 AX_GCC_FUNC_ATTRIBUTE([weak])
 248 AX_GCC_FUNC_ATTRIBUTE([alias])
 249
 250 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 251
 252 dnl Make sure the pkg-config macros are defined
 253 m4_ifndef([PKG_PROG_PKG_CONFIG],
 254     [m4_fatal([Could not locate the pkg-config autoconf macros.
 255   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 256   are in a different location, try setting the environment variable
 257   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 258 PKG_PROG_PKG_CONFIG()
 259
 260 dnl LIB_DIR - library basename
 261 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 262 AC_SUBST([LIB_DIR])
 263
 264 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 265 _SAVE_LDFLAGS="$LDFLAGS"
 266 _SAVE_CPPFLAGS="$CPPFLAGS"
 267
 268 dnl Compiler macros
 269 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 270 AC_SUBST([DEFINES])
 271 android=no
 272 case "$host_os" in
 273 *-android)
 274     android=yes
 275     ;;
 276 linux*|*-gnu*|gnu*|cygwin*)
 277     DEFINES="$DEFINES -D_GNU_SOURCE"
 278     ;;
 279 solaris*)
 280     DEFINES="$DEFINES -DSVR4"
 281     ;;
 282 esac
 283
 284 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 285
 286 dnl Add flags for gcc and g++
 287 if test "x$GCC" = xyes; then
 288     CFLAGS="$CFLAGS -Wall"
 289
 290     if test "x$USE_GNU99" = xyes; then
 291         CFLAGS="$CFLAGS -std=gnu99"
 292     else
 293         CFLAGS="$CFLAGS -std=c99"
 294     fi
 295
 296     # Enable -Werror=implicit-function-declaration and
 297     # -Werror=missing-prototypes, if available, or otherwise, just
 298     # -Wmissing-prototypes.  This is particularly useful to avoid
 299     # generating a loadable driver module that has undefined symbols.
 300     save_CFLAGS="$CFLAGS"
 301     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 302     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 303     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 304     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 305                    AC_MSG_RESULT([yes]),
 306                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 307                     AC_MSG_RESULT([no])]);
 308
 309     # Enable -fvisibility=hidden if using a gcc that supports it
 310     save_CFLAGS="$CFLAGS"
 311     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 312     VISIBILITY_CFLAGS="-fvisibility=hidden"
 313     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 314     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 315                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 316
 317     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 318     CFLAGS=$save_CFLAGS
 319
 320     # We don't want floating-point math functions to set errno or trap
 321     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 322
 323     # Flags to help ensure that certain portions of the code -- and only those
 324     # portions -- can be built with MSVC:
 325     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 326     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 327     #   supports most of C99)
 328     # - the rest has no compiler compiler restrictions
 329     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 330     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 331
 332     # Enable -Werror=vla if compiler supports it
 333     save_CFLAGS="$CFLAGS"
 334     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 335     CFLAGS="$CFLAGS -Werror=vla"
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 337                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 338                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 339                     AC_MSG_RESULT([yes])],
 340                     AC_MSG_RESULT([no]));
 341     CFLAGS="$save_CFLAGS"
 342 fi
 343 if test "x$GXX" = xyes; then
 344     CXXFLAGS="$CXXFLAGS -Wall"
 345
 346     # Enable -fvisibility=hidden if using a gcc that supports it
 347     save_CXXFLAGS="$CXXFLAGS"
 348     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 349     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 350     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 351     AC_LANG_PUSH([C++])
 352     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 353                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 354     AC_LANG_POP([C++])
 355
 356     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 357     CXXFLAGS=$save_CXXFLAGS
 358
 359     # We don't want floating-point math functions to set errno or trap
 360     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 361 fi
 362
 363 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 364 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 365
 366 dnl even if the compiler appears to support it, using visibility attributes isn't
 367 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 368 case "$host_os" in
 369 cygwin*)
 370     VISIBILITY_CFLAGS=""
 371     VISIBILITY_CXXFLAGS=""
 372     ;;
 373 esac
 374
 375 AC_SUBST([VISIBILITY_CFLAGS])
 376 AC_SUBST([VISIBILITY_CXXFLAGS])
 377
 378 dnl
 379 dnl Optional flags, check for compiler support
 380 dnl
 381 SSE41_CFLAGS="-msse4.1"
 382 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 383 dnl stack, but on x86-32 such alignment is not guaranteed.
 384 case "$target_cpu" in
 385 i?86)
 386     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 387     ;;
 388 esac
 389 save_CFLAGS="$CFLAGS"
 390 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 #include <smmintrin.h>
 393 int param;
 394 int main () {
 395     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 396     c = _mm_max_epu32(a, b);
 397     return _mm_cvtsi128_si32(c);
 398 }]])], SSE41_SUPPORTED=1)
 399 CFLAGS="$save_CFLAGS"
 400 if test "x$SSE41_SUPPORTED" = x1; then
 401     DEFINES="$DEFINES -DUSE_SSE41"
 402 fi
 403 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 404 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 405
 406 dnl Check for new-style atomic builtins
 407 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 408 int main() {
 409     int n;
 410     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 411 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 412 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 413     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 414 fi
 415 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 416
 417 dnl Check for Endianness
 418 AC_C_BIGENDIAN(
 419    little_endian=no,
 420    little_endian=yes,
 421    little_endian=no,
 422    little_endian=no
 423 )
 424
 425 dnl Check for POWER8 Architecture
 426 PWR8_CFLAGS="-mpower8-vector"
 427 have_pwr8_intrinsics=no
 428 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 429 save_CFLAGS=$CFLAGS
 430 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 431 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 432 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 433 #error "Need GCC >= 4.8 for sane POWER8 support"
 434 #endif
 435 #include <altivec.h>
 436 int main () {
 437     vector unsigned char r;
 438     vector unsigned int v = vec_splat_u32 (1);
 439     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 440     return 0;
 441 }]])], have_pwr8_intrinsics=yes)
 442 CFLAGS=$save_CFLAGS
 443
 444 AC_ARG_ENABLE(pwr8,
 445    [AC_HELP_STRING([--disable-pwr8-inst],
 446                    [disable POWER8-specific instructions])],
 447    [enable_pwr8=$enableval], [enable_pwr8=auto])
 448
 449 if test "x$enable_pwr8" = xno ; then
 450    have_pwr8_intrinsics=disabled
 451 fi
 452
 453 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 454    DEFINES="$DEFINES -D_ARCH_PWR8"
 455    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 456    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 457 else
 458    PWR8_CFLAGS=
 459 fi
 460
 461 AC_MSG_RESULT($have_pwr8_intrinsics)
 462 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 463    AC_MSG_ERROR([POWER8 compiler support not detected])
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 467    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 468 fi
 469
 470 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 471
 472 dnl Can't have static and shared libraries, default to static if user
 473 dnl explicitly requested. If both disabled, set to static since shared
 474 dnl was explicitly requested.
 475 case "x$enable_static$enable_shared" in
 476 xyesyes)
 477     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 478     ;;
 479 xnono)
 480     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 481     ;;
 482 esac
 483
 484 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 485
 486 dnl
 487 dnl other compiler options
 488 dnl
 489 AC_ARG_ENABLE([debug],
 490     [AS_HELP_STRING([--enable-debug],
 491         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 492     [enable_debug="$enableval"],
 493     [enable_debug=no]
 494 )
 495
 496 AC_ARG_ENABLE([profile],
 497     [AS_HELP_STRING([--enable-profile],
 498         [enable profiling of code @<:@default=disabled@:>@])],
 499     [enable_profile="$enableval"],
 500     [enable_profile=no]
 501 )
 502
 503 if test "x$enable_profile" = xyes; then
 504     DEFINES="$DEFINES -DPROFILE"
 505     if test "x$GCC" = xyes; then
 506         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 507     fi
 508     if test "x$GXX" = xyes; then
 509         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 510     fi
 511 fi
 512
 513 if test "x$enable_debug" = xyes; then
 514     DEFINES="$DEFINES -DDEBUG"
 515     if test "x$enable_profile" = xyes; then
 516         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 517     fi
 518     if test "x$GCC" = xyes; then
 519         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 520             CFLAGS="$CFLAGS -g"
 521         fi
 522         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 523             CFLAGS="$CFLAGS -O0"
 524         fi
 525     fi
 526     if test "x$GXX" = xyes; then
 527         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 528             CXXFLAGS="$CXXFLAGS -g"
 529         fi
 530         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 531             CXXFLAGS="$CXXFLAGS -O0"
 532         fi
 533     fi
 534 else
 535    DEFINES="$DEFINES -DNDEBUG"
 536 fi
 537
 538 dnl
 539 dnl Check if linker supports -Bsymbolic
 540 dnl
 541 save_LDFLAGS=$LDFLAGS
 542 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 543 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 544 AC_LINK_IFELSE(
 545     [AC_LANG_SOURCE([int main() { return 0;}])],
 546     [AC_MSG_RESULT([yes])
 547         BSYMBOLIC="-Wl,-Bsymbolic";],
 548     [AC_MSG_RESULT([no])
 549         BSYMBOLIC="";])
 550 LDFLAGS=$save_LDFLAGS
 551
 552 AC_SUBST([BSYMBOLIC])
 553
 554 dnl
 555 dnl Check if linker supports garbage collection
 556 dnl
 557 save_LDFLAGS=$LDFLAGS
 558 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 559 AC_MSG_CHECKING([whether ld supports --gc-sections])
 560 AC_LINK_IFELSE(
 561     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 562     [AC_MSG_RESULT([yes])
 563         GC_SECTIONS="-Wl,--gc-sections";],
 564     [AC_MSG_RESULT([no])
 565         GC_SECTIONS="";])
 566 LDFLAGS=$save_LDFLAGS
 567
 568 AC_SUBST([GC_SECTIONS])
 569
 570 dnl
 571 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 572 dnl so when these flags are passed to ld via libtool the checks will fail
 573 dnl
 574 case "$host_os" in
 575 openbsd* | darwin* )
 576     LD_NO_UNDEFINED="" ;;
 577 *)
 578     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 579 esac
 580
 581 AC_SUBST([LD_NO_UNDEFINED])
 582
 583 dnl
 584 dnl Check if linker supports version scripts
 585 dnl
 586 AC_MSG_CHECKING([if the linker supports version-scripts])
 587 save_LDFLAGS=$LDFLAGS
 588 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 589 cat > conftest.map <<EOF
 590 VERSION_1 {
 591      global:
 592          main;
 593
 594      local:
 595          *;
 596 };
 597 EOF
 598 AC_LINK_IFELSE(
 599     [AC_LANG_SOURCE([int main() { return 0;}])],
 600     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 601     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 602 LDFLAGS=$save_LDFLAGS
 603 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 604
 605 dnl
 606 dnl Check if linker supports dynamic list files
 607 dnl
 608 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 609 save_LDFLAGS=$LDFLAGS
 610 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 611 cat > conftest.dyn <<EOF
 612 {
 613         radeon_drm_winsys_create;
 614 };
 615 EOF
 616 AC_LINK_IFELSE(
 617     [AC_LANG_SOURCE([int main() { return 0;}])],
 618     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 619     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 620 LDFLAGS=$save_LDFLAGS
 621 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 622
 623 dnl
 624 dnl compatibility symlinks
 625 dnl
 626 case "$host_os" in
 627 linux* )
 628     HAVE_COMPAT_SYMLINKS=yes ;;
 629 * )
 630     HAVE_COMPAT_SYMLINKS=no ;;
 631 esac
 632
 633 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 634
 635 dnl
 636 dnl library names
 637 dnl
 638 dnl Unfortunately we need to do a few things that libtool can't help us with,
 639 dnl so we need some knowledge of shared library filenames:
 640 dnl
 641 dnl LIB_EXT is the extension used when creating symlinks for alternate
 642 dnl filenames for a shared library which will be dynamically loaded
 643 dnl
 644 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 645 dnl the file for a shared library we wish to link with
 646 dnl
 647 case "$host_os" in
 648 darwin* )
 649     LIB_EXT='dylib'
 650     IMP_LIB_EXT=$LIB_EXT
 651     ;;
 652 cygwin* )
 653     LIB_EXT='dll'
 654     IMP_LIB_EXT='dll.a'
 655     ;;
 656 aix* )
 657     LIB_EXT='a'
 658     IMP_LIB_EXT=$LIB_EXT
 659     ;;
 660 * )
 661     LIB_EXT='so'
 662     IMP_LIB_EXT=$LIB_EXT
 663     ;;
 664 esac
 665
 666 AC_SUBST([LIB_EXT])
 667
 668 dnl
 669 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 670 dnl
 671 AC_ARG_ENABLE([texture-float],
 672     [AS_HELP_STRING([--enable-texture-float],
 673         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 674     [enable_texture_float="$enableval"],
 675     [enable_texture_float=no]
 676 )
 677 if test "x$enable_texture_float" = xyes; then
 678     AC_MSG_WARN([Floating-point textures enabled.])
 679     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 680     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 681 fi
 682
 683 dnl
 684 dnl Arch/platform-specific settings
 685 dnl
 686 AC_ARG_ENABLE([asm],
 687     [AS_HELP_STRING([--disable-asm],
 688         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 689     [enable_asm="$enableval"],
 690     [enable_asm=yes]
 691 )
 692 asm_arch=""
 693 AC_MSG_CHECKING([whether to enable assembly])
 694 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 695 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 696 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 697     case "$host_cpu" in
 698     i?86 | x86_64 | amd64)
 699         if test "x$host_cpu" != "x$target_cpu"; then
 700             enable_asm=no
 701             AC_MSG_RESULT([no, cross compiling])
 702         fi
 703         ;;
 704     esac
 705 fi
 706 # check for supported arches
 707 if test "x$enable_asm" = xyes; then
 708     case "$host_cpu" in
 709     i?86)
 710         case "$host_os" in
 711         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 712             asm_arch=x86
 713             ;;
 714         esac
 715         ;;
 716     x86_64|amd64)
 717         case "$host_os" in
 718         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 719             asm_arch=x86_64
 720             ;;
 721         esac
 722         ;;
 723     sparc*)
 724         case "$host_os" in
 725         linux*)
 726             asm_arch=sparc
 727             ;;
 728         esac
 729         ;;
 730     esac
 731
 732     case "$asm_arch" in
 733     x86)
 734         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 735         AC_MSG_RESULT([yes, x86])
 736         ;;
 737     x86_64|amd64)
 738         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 739         AC_MSG_RESULT([yes, x86_64])
 740         ;;
 741     sparc)
 742         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 743         AC_MSG_RESULT([yes, sparc])
 744         ;;
 745     *)
 746         AC_MSG_RESULT([no, platform not supported])
 747         ;;
 748     esac
 749 fi
 750
 751 AC_HEADER_MAJOR
 752 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 753 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 754 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 755 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 756
 757 dnl Check to see if dlopen is in default libraries (like Solaris, which
 758 dnl has it in libc), or if libdl is needed to get it.
 759 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 760     [AC_CHECK_LIB([dl], [dlopen],
 761        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 762 AC_SUBST([DLOPEN_LIBS])
 763
 764 dnl Check if that library also has dladdr
 765 save_LIBS="$LIBS"
 766 LIBS="$LIBS $DLOPEN_LIBS"
 767 AC_CHECK_FUNCS([dladdr])
 768 LIBS="$save_LIBS"
 769
 770 case "$host_os" in
 771 darwin*)
 772     ;;
 773 *)
 774     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 775                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 776                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 777     AC_SUBST([CLOCK_LIB])
 778     ;;
 779 esac
 780
 781 dnl See if posix_memalign is available
 782 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 783
 784 dnl Check for pthreads
 785 AX_PTHREAD
 786 if test "x$ax_pthread_ok" = xno; then
 787     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 788 fi
 789 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 790 dnl to -pthread, which causes problems if we need -lpthread to appear in
 791 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 792 dnl is not valid for that platform.
 793 if test "x$android" = xno; then
 794     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 795 fi
 796
 797 dnl pthread-stubs is mandatory on targets where it exists
 798 case "$host_os" in
 799 cygwin* )
 800     pthread_stubs_possible="no"
 801     ;;
 802 * )
 803     pthread_stubs_possible="yes"
 804     ;;
 805 esac
 806
 807 if test "x$pthread_stubs_possible" = xyes; then
 808     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 809     AC_SUBST(PTHREADSTUBS_CFLAGS)
 810     AC_SUBST(PTHREADSTUBS_LIBS)
 811 fi
 812
 813 dnl SELinux awareness.
 814 AC_ARG_ENABLE([selinux],
 815     [AS_HELP_STRING([--enable-selinux],
 816         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 817     [MESA_SELINUX="$enableval"],
 818     [MESA_SELINUX=no])
 819 if test "x$enable_selinux" = "xyes"; then
 820     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 821         [AC_CHECK_HEADER([selinux/selinux.h],[],
 822                          [AC_MSG_ERROR([SELinux headers not found])])
 823          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 824                       [AC_MSG_ERROR([SELinux library not found])])
 825          SELINUX_LIBS="-lselinux"])
 826     DEFINES="$DEFINES -DMESA_SELINUX"
 827 fi
 828 AC_SUBST([SELINUX_CFLAGS])
 829 AC_SUBST([SELINUX_LIBS])
 830
 831 dnl
 832 dnl LLVM
 833 dnl
 834 AC_ARG_ENABLE([llvm-shared-libs],
 835     [AS_HELP_STRING([--enable-llvm-shared-libs],
 836         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 837     [enable_llvm_shared_libs="$enableval"],
 838     [enable_llvm_shared_libs=yes])
 839
 840 AC_ARG_WITH([llvm-prefix],
 841     [AS_HELP_STRING([--with-llvm-prefix],
 842         [Prefix for LLVM installations in non-standard locations])],
 843     [llvm_prefix="$withval"],
 844     [llvm_prefix=''])
 845
 846 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 847 if test "x$have_libelf" = xno; then
 848    LIBELF_LIBS=''
 849    LIBELF_CFLAGS=''
 850    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 851    AC_SUBST([LIBELF_LIBS])
 852    AC_SUBST([LIBELF_CFLAGS])
 853 fi
 854
 855 if test -z "$LLVM_CONFIG"; then
 856     if test -n "$llvm_prefix"; then
 857         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 858     else
 859         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 860     fi
 861 fi
 862
 863 llvm_add_component() {
 864     new_llvm_component=$1
 865     driver_name=$2
 866
 867     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 868         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 869     else
 870         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 871     fi
 872 }
 873
 874 llvm_add_default_components() {
 875     driver_name=$1
 876
 877     # Required default components
 878     llvm_add_component "bitwriter" $driver_name
 879     llvm_add_component "engine" $driver_name
 880     llvm_add_component "mcdisassembler" $driver_name
 881     llvm_add_component "mcjit" $driver_name
 882
 883     # Optional default components
 884     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 885         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 886     fi
 887 }
 888
 889 llvm_add_target() {
 890     new_llvm_target=$1
 891     driver_name=$2
 892
 893     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 894         llvm_add_component $new_llvm_target $driver_name
 895     else
 896         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 897     fi
 898 }
 899
 900 # Call this inside ` ` to get the return value.
 901 # $1 is the llvm-config command with arguments.
 902 strip_unwanted_llvm_flags() {
 903     # Use \> (marks the end of the word)
 904     echo `$1` | sed \
 905         -e 's/-march=\S*//g' \
 906         -e 's/-mtune=\S*//g' \
 907         -e 's/-mcpu=\S*//g' \
 908         -e 's/-DNDEBUG\>//g' \
 909         -e 's/-D_GNU_SOURCE\>//g' \
 910         -e 's/-pedantic\>//g' \
 911         -e 's/-Wcovered-switch-default\>//g' \
 912         -e 's/-O.\>//g' \
 913         -e 's/-g\>//g' \
 914         -e 's/-Wall\>//g' \
 915         -e 's/-Wcast-qual\>//g' \
 916         -e 's/-Woverloaded-virtual\>//g' \
 917         -e 's/-fcolor-diagnostics\>//g' \
 918         -e 's/-fdata-sections\>//g' \
 919         -e 's/-ffunction-sections\>//g' \
 920         -e 's/-fno-exceptions\>//g' \
 921         -e 's/-fomit-frame-pointer\>//g' \
 922         -e 's/-fvisibility-inlines-hidden\>//g' \
 923         -e 's/-fPIC\>//g' \
 924         -e 's/-fstack-protector-strong\>//g'
 925 }
 926
 927 llvm_set_environment_variables() {
 928     if test "x$LLVM_CONFIG" != xno; then
 929         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 930         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 931         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 932         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 933         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 934         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 935         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 936         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 937
 938         # We need to respect LLVM_CFLAGS when compiling LLVM headers.
 939         save_CFLAGS="$CFLAGS"
 940         CFLAGS="$CFLAGS $LLVM_CFLAGS"
 941
 942         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 943             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 944         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 945             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 946         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 947             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 948
 949         CFLAGS="$save_CFLAGS"
 950
 951         # Only needed for LLVM < 3.6.0
 952         if test -z "$LLVM_VERSION_PATCH"; then
 953             LLVM_VERSION_PATCH=0
 954         fi
 955
 956         if test "$LLVM_VERSION_MINOR" -lt 10; then
 957             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 958         else
 959             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
 960         fi
 961
 962         FOUND_LLVM=yes
 963     else
 964         FOUND_LLVM=no
 965         LLVM_VERSION_INT=0
 966     fi
 967 }
 968
 969 require_llvm() {
 970     if test "x$enable_gallium_llvm" != "xyes"; then
 971         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
 972     fi
 973 }
 974
 975 llvm_require_version() {
 976     require_llvm $2
 977
 978     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
 979     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
 980     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 981
 982     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
 983         # major > required major
 984         #  --> OK
 985         return
 986     fi
 987
 988     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
 989         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
 990             # major = required major and
 991             # minor > required minor
 992             #  --> OK
 993             return
 994         else
 995             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
 996                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
 997                     # major = required major and
 998                     # minor = required minor and
 999                     # patch >= required patch
1000                     #  --> OK
1001                     return
1002                 fi
1003             fi
1004         fi
1005     fi
1006
1007     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1008 }
1009
1010 radeon_llvm_check() {
1011     if test ${LLVM_VERSION_INT} -lt 307; then
1012         amdgpu_llvm_target_name='r600'
1013     else
1014         amdgpu_llvm_target_name='amdgpu'
1015     fi
1016
1017     llvm_require_version $*
1018
1019     llvm_add_target $amdgpu_llvm_target_name $2
1020
1021     llvm_add_default_components $2
1022     llvm_add_component "bitreader" $2
1023     llvm_add_component "ipo" $2
1024
1025     NEED_RADEON_LLVM=yes
1026     if test "x$have_libelf" != xyes; then
1027        AC_MSG_ERROR([$1 requires libelf when using llvm])
1028     fi
1029 }
1030
1031 llvm_set_environment_variables
1032
1033 AC_SUBST([LLVM_BINDIR])
1034 AC_SUBST([LLVM_CFLAGS])
1035 AC_SUBST([LLVM_CPPFLAGS])
1036 AC_SUBST([LLVM_CXXFLAGS])
1037 AC_SUBST([LLVM_LIBDIR])
1038 AC_SUBST([LLVM_LIBS])
1039 AC_SUBST([LLVM_LDFLAGS])
1040 AC_SUBST([LLVM_INCLUDEDIR])
1041 AC_SUBST([LLVM_VERSION])
1042
1043 dnl Options for APIs
1044 AC_ARG_ENABLE([opengl],
1045     [AS_HELP_STRING([--disable-opengl],
1046         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1047     [enable_opengl="$enableval"],
1048     [enable_opengl=yes])
1049 AC_ARG_ENABLE([gles1],
1050     [AS_HELP_STRING([--disable-gles1],
1051         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1052     [enable_gles1="$enableval"],
1053     [enable_gles1=yes])
1054 AC_ARG_ENABLE([gles2],
1055     [AS_HELP_STRING([--disable-gles2],
1056         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1057     [enable_gles2="$enableval"],
1058     [enable_gles2=yes])
1059
1060 AC_ARG_ENABLE([dri],
1061     [AS_HELP_STRING([--enable-dri],
1062         [enable DRI modules @<:@default=enabled@:>@])],
1063     [enable_dri="$enableval"],
1064     [enable_dri=yes])
1065
1066 AC_ARG_ENABLE([gallium-extra-hud],
1067     [AS_HELP_STRING([--enable-gallium-extra-hud],
1068         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1069     [enable_gallium_extra_hud="$enableval"],
1070     [enable_gallium_extra_hud=no])
1071 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1072 if test "x$enable_gallium_extra_hud" = xyes ; then
1073     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1074 fi
1075
1076 #TODO: no pkgconfig .pc available for libsensors.
1077 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1078 AC_ARG_ENABLE([lmsensors],
1079     [AS_HELP_STRING([--enable-lmsensors],
1080         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1081     [enable_lmsensors="$enableval"],
1082     [enable_lmsensors=no])
1083 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1084 if test "x$enable_lmsensors" = xyes ; then
1085     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1086     LIBSENSORS_LIBS="-lsensors"
1087 else
1088     LIBSENSORS_LIBS=""
1089 fi
1090 AC_SUBST(LIBSENSORS_LIBS)
1091
1092 case "$host_os" in
1093 linux*)
1094     dri3_default=yes
1095     ;;
1096 *)
1097     dri3_default=no
1098     ;;
1099 esac
1100
1101 if test "x$enable_dri" = xno; then
1102     dri3_default=no
1103 fi
1104
1105 AC_ARG_ENABLE([dri3],
1106     [AS_HELP_STRING([--enable-dri3],
1107         [enable DRI3 @<:@default=auto@:>@])],
1108     [enable_dri3="$enableval"],
1109     [enable_dri3="$dri3_default"])
1110 AC_ARG_ENABLE([glx],
1111     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1112         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1113     [enable_glx="$enableval"],
1114     [enable_glx=yes])
1115 AC_ARG_ENABLE([osmesa],
1116     [AS_HELP_STRING([--enable-osmesa],
1117         [enable OSMesa library @<:@default=disabled@:>@])],
1118     [enable_osmesa="$enableval"],
1119     [enable_osmesa=no])
1120 AC_ARG_ENABLE([gallium-osmesa],
1121     [AS_HELP_STRING([--enable-gallium-osmesa],
1122         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1123     [enable_gallium_osmesa="$enableval"],
1124     [enable_gallium_osmesa=no])
1125 AC_ARG_ENABLE([egl],
1126     [AS_HELP_STRING([--disable-egl],
1127         [disable EGL library @<:@default=enabled@:>@])],
1128     [enable_egl="$enableval"],
1129     [enable_egl=yes])
1130
1131 AC_ARG_ENABLE([xa],
1132     [AS_HELP_STRING([--enable-xa],
1133         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1134     [enable_xa="$enableval"],
1135     [enable_xa=no])
1136 AC_ARG_ENABLE([gbm],
1137    [AS_HELP_STRING([--enable-gbm],
1138          [enable gbm library @<:@default=yes except cygwin@:>@])],
1139    [enable_gbm="$enableval"],
1140    [case "$host_os" in
1141        cygwin*)
1142           enable_gbm=no
1143           ;;
1144        *)
1145           enable_gbm=yes
1146           ;;
1147     esac])
1148 AC_ARG_ENABLE([nine],
1149     [AS_HELP_STRING([--enable-nine],
1150         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1151     [enable_nine="$enableval"],
1152     [enable_nine=no])
1153
1154 AC_ARG_ENABLE([xvmc],
1155    [AS_HELP_STRING([--enable-xvmc],
1156          [enable xvmc library @<:@default=auto@:>@])],
1157    [enable_xvmc="$enableval"],
1158    [enable_xvmc=auto])
1159 AC_ARG_ENABLE([vdpau],
1160    [AS_HELP_STRING([--enable-vdpau],
1161          [enable vdpau library @<:@default=auto@:>@])],
1162    [enable_vdpau="$enableval"],
1163    [enable_vdpau=auto])
1164 AC_ARG_ENABLE([omx],
1165    [AS_HELP_STRING([--enable-omx],
1166          [enable OpenMAX library @<:@default=disabled@:>@])],
1167    [enable_omx="$enableval"],
1168    [enable_omx=no])
1169 AC_ARG_ENABLE([va],
1170    [AS_HELP_STRING([--enable-va],
1171          [enable va library @<:@default=auto@:>@])],
1172    [enable_va="$enableval"],
1173    [enable_va=auto])
1174 AC_ARG_ENABLE([opencl],
1175    [AS_HELP_STRING([--enable-opencl],
1176          [enable OpenCL library @<:@default=disabled@:>@])],
1177    [enable_opencl="$enableval"],
1178    [enable_opencl=no])
1179 AC_ARG_ENABLE([opencl_icd],
1180    [AS_HELP_STRING([--enable-opencl-icd],
1181           [Build an OpenCL ICD library to be loaded by an ICD implementation
1182            @<:@default=disabled@:>@])],
1183     [enable_opencl_icd="$enableval"],
1184     [enable_opencl_icd=no])
1185
1186 AC_ARG_ENABLE([gallium-tests],
1187     [AS_HELP_STRING([--enable-gallium-tests],
1188         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1189     [enable_gallium_tests="$enableval"],
1190     [enable_gallium_tests=no])
1191
1192 # Option for Gallium drivers
1193
1194 # Keep this in sync with the --with-gallium-drivers help string default value
1195 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1196
1197 AC_ARG_WITH([gallium-drivers],
1198     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1199         [comma delimited Gallium drivers list, e.g.
1200         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1201         @<:@default=r300,r600,svga,swrast@:>@])],
1202     [with_gallium_drivers="$withval"],
1203     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1204
1205 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1206 # here so that the script doesn't choke on an unknown driver name later.
1207 case "$with_gallium_drivers" in
1208     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1209     no) with_gallium_drivers='' ;;
1210 esac
1211
1212 if test "x$enable_opengl" = xno -a \
1213         "x$enable_gles1" = xno -a \
1214         "x$enable_gles2" = xno -a \
1215         "x$enable_nine" = xno -a \
1216         "x$enable_xa" = xno -a \
1217         "x$enable_xvmc" = xno -a \
1218         "x$enable_vdpau" = xno -a \
1219         "x$enable_omx" = xno -a \
1220         "x$enable_va" = xno -a \
1221         "x$enable_opencl" = xno; then
1222     AC_MSG_ERROR([at least one API should be enabled])
1223 fi
1224
1225 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1226 if test "x$enable_opengl" = xno -a \
1227         "x$enable_gles1" = xyes; then
1228     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1229 fi
1230
1231 if test "x$enable_opengl" = xno -a \
1232         "x$enable_gles2" = xyes; then
1233     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1234 fi
1235
1236 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1237 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1238 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1239 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1240                                         "x$enable_gles1" = xyes -o \
1241                                         "x$enable_gles2" = xyes)
1242
1243 # Validate GLX options
1244 if test "x$enable_glx" = xyes; then
1245     if test "x$enable_dri" = xyes; then
1246         enable_glx=dri
1247     elif test -n "$with_gallium_drivers"; then
1248         enable_glx=gallium-xlib
1249     else
1250         enable_glx=xlib
1251     fi
1252 fi
1253 case "x$enable_glx" in
1254 xdri | xxlib | xgallium-xlib)
1255     # GLX requires OpenGL
1256     if test "x$enable_opengl" = xno; then
1257         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1258     fi
1259
1260     # Check individual dependencies
1261     case "x$enable_glx" in
1262     xdri)
1263         if test "x$enable_dri" = xno; then
1264             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1265         fi
1266         ;;
1267     xxlib)
1268         if test "x$enable_dri" = xyes; then
1269             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1270         fi
1271         ;;
1272     xgallium-xlib )
1273         if test "x$enable_dri" = xyes; then
1274             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1275         fi
1276         if test -z "$with_gallium_drivers"; then
1277             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1278         fi
1279         ;;
1280     esac
1281     ;;
1282 xno)
1283     ;;
1284 *)
1285     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1286     ;;
1287 esac
1288
1289 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1290 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1291 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1292 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1293
1294 DEFAULT_GL_LIB_NAME=GL
1295
1296 dnl
1297 dnl Libglvnd configuration
1298 dnl
1299 AC_ARG_ENABLE([libglvnd],
1300     [AS_HELP_STRING([--enable-libglvnd],
1301         [Build for libglvnd @<:@default=disabled@:>@])],
1302     [enable_libglvnd="$enableval"],
1303     [enable_libglvnd=no])
1304 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1305 if test "x$enable_libglvnd" = xyes ; then
1306     dnl XXX: update once we can handle more than libGL/glx.
1307     dnl Namely: we should error out if neither of the glvnd enabled libraries
1308     dnl are built
1309     case "x$enable_glx" in
1310     xno)
1311         AC_MSG_ERROR([cannot build libglvnd without GLX])
1312         ;;
1313     xxlib | xgallium-xlib )
1314         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1315         ;;
1316     xdri)
1317         ;;
1318     esac
1319
1320     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1321     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1322     DEFAULT_GL_LIB_NAME=GLX_mesa
1323 fi
1324
1325 AC_ARG_WITH([gl-lib-name],
1326   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1327     [specify GL library name @<:@default=GL@:>@])],
1328   [GL_LIB=$withval],
1329   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1330 AC_ARG_WITH([osmesa-lib-name],
1331   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1332     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1333   [OSMESA_LIB=$withval],
1334   [OSMESA_LIB=OSMesa])
1335 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1336 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1337
1338 dnl
1339 dnl Mangled Mesa support
1340 dnl
1341 AC_ARG_ENABLE([mangling],
1342   [AS_HELP_STRING([--enable-mangling],
1343     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1344   [enable_mangling="${enableval}"],
1345   [enable_mangling=no]
1346 )
1347 if test "x${enable_mangling}" = "xyes" ; then
1348   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1349   GL_LIB="Mangled${GL_LIB}"
1350   OSMESA_LIB="Mangled${OSMESA_LIB}"
1351 fi
1352 AC_SUBST([GL_LIB])
1353 AC_SUBST([OSMESA_LIB])
1354
1355 # Check for libdrm
1356 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1357                   [have_libdrm=yes], [have_libdrm=no])
1358 if test "x$have_libdrm" = xyes; then
1359         DEFINES="$DEFINES -DHAVE_LIBDRM"
1360 fi
1361
1362 require_libdrm() {
1363     if test "x$have_libdrm" != xyes; then
1364        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1365     fi
1366 }
1367
1368
1369 # Select which platform-dependent DRI code gets built
1370 case "$host_os" in
1371 darwin*)
1372     dri_platform='apple' ;;
1373 cygwin*)
1374     dri_platform='windows' ;;
1375 gnu*)
1376     dri_platform='none' ;;
1377 *)
1378     dri_platform='drm' ;;
1379 esac
1380
1381 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1382     have_drisw_kms='yes'
1383 fi
1384
1385 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1386 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1387 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1388 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1389 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1390 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1391 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1392 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1393 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1394
1395 AC_ARG_ENABLE([shared-glapi],
1396     [AS_HELP_STRING([--enable-shared-glapi],
1397         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1398     [enable_shared_glapi="$enableval"],
1399     [enable_shared_glapi=yes])
1400
1401 case "x$enable_opengl$enable_gles1$enable_gles2" in
1402 x*yes*yes*)
1403     if test "x$enable_shared_glapi" = xno; then
1404         AC_MSG_ERROR([shared GLAPI required when building two or more of
1405                       the following APIs - opengl, gles1 gles2])
1406     fi
1407     ;;
1408 esac
1409
1410 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1411
1412 # Build the pipe-drivers as separate libraries/modules.
1413 # Do not touch this unless you know what you are doing.
1414 # XXX: Expose via configure option ?
1415 enable_shared_pipe_drivers=no
1416
1417 dnl
1418 dnl Driver specific build directories
1419 dnl
1420
1421 if test "x$enable_gallium_osmesa" = xyes; then
1422     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1423         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1424     fi
1425     if test "x$enable_osmesa" = xyes; then
1426         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1427     fi
1428 fi
1429
1430 require_dri_shared_libs_and_glapi() {
1431     if test "x$enable_static" = xyes; then
1432         AC_MSG_ERROR([$1 cannot be build as static library])
1433     fi
1434
1435     if test "x$enable_dri" != xyes; then
1436         # There is only a single backend which won't be build/used otherwise.
1437         # XXX: Revisit this as the egl/haiku is a thing.
1438         AC_MSG_ERROR([$1 requires --enable-dri])
1439     fi
1440
1441     if test "x$enable_shared_glapi" != xyes; then
1442         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1443     fi
1444 }
1445
1446 if test "x$enable_dri" = xyes; then
1447     require_dri_shared_libs_and_glapi "DRI"
1448
1449     # not a hard requirement as swrast does not depend on it
1450     if test "x$have_libdrm" = xyes; then
1451         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1452     fi
1453 fi
1454
1455 AC_ARG_ENABLE([driglx-direct],
1456     [AS_HELP_STRING([--disable-driglx-direct],
1457         [disable direct rendering in GLX and EGL for DRI \
1458             @<:@default=auto@:>@])],
1459     [driglx_direct="$enableval"],
1460     [driglx_direct="yes"])
1461
1462 dnl
1463 dnl libGL configuration per driver
1464 dnl
1465 if test "x$enable_glx" != xno; then
1466     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1467 fi
1468 case "x$enable_glx" in
1469 xxlib | xgallium-xlib)
1470     # Xlib-based GLX
1471     dri_modules="x11 xext xcb"
1472     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1473     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1474     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1475     GL_LIB_DEPS="$XLIBGL_LIBS"
1476     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1477     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1478     ;;
1479 xdri)
1480     # DRI-based GLX
1481
1482     # find the DRI deps for libGL
1483     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1484
1485     if test x"$driglx_direct" = xyes; then
1486         if test x"$dri_platform" = xdrm ; then
1487             DEFINES="$DEFINES -DGLX_USE_DRM"
1488             require_libdrm "Direct rendering"
1489
1490             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1491             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1492             if test x"$enable_dri3" = xyes; then
1493                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1494                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1495             fi
1496
1497             if test x"$enable_dri" = xyes; then
1498                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1499             fi
1500
1501             if test x"$enable_dri3" = xyes; then
1502                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1503                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1504                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1505             fi
1506         fi
1507         if test x"$dri_platform" = xapple ; then
1508             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1509         fi
1510         if test x"$dri_platform" = xwindows ; then
1511             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1512         fi
1513     fi
1514
1515     # add xf86vidmode if available
1516     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1517     if test "$HAVE_XF86VIDMODE" = yes ; then
1518         dri_modules="$dri_modules xxf86vm"
1519     fi
1520
1521     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1522     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1523     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1524     GL_LIB_DEPS="$DRIGL_LIBS"
1525
1526     # need DRM libs, $PTHREAD_LIBS, etc.
1527     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1528     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1529     ;;
1530 esac
1531
1532 # This is outside the case (above) so that it is invoked even for non-GLX
1533 # builds.
1534 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1535
1536 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1537 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1538 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1539 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1540
1541 AC_SUBST([X11_INCLUDES])
1542 AC_SUBST([GL_LIB_DEPS])
1543 AC_SUBST([GL_PC_REQ_PRIV])
1544 AC_SUBST([GL_PC_LIB_PRIV])
1545 AC_SUBST([GL_PC_CFLAGS])
1546 AC_SUBST([DRI_PC_REQ_PRIV])
1547 AC_SUBST([GLESv1_CM_LIB_DEPS])
1548 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1549 AC_SUBST([GLESv2_LIB_DEPS])
1550 AC_SUBST([GLESv2_PC_LIB_PRIV])
1551
1552 AC_SUBST([HAVE_XF86VIDMODE])
1553
1554 dnl
1555 dnl More GLX setup
1556 dnl
1557 case "x$enable_glx" in
1558 xxlib | xgallium-xlib)
1559     DEFINES="$DEFINES -DUSE_XSHM"
1560     ;;
1561 xdri)
1562     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1563     if test "x$driglx_direct" = xyes; then
1564         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1565     fi
1566     ;;
1567 esac
1568
1569 dnl
1570 dnl TLS detection
1571 dnl
1572
1573 AC_ARG_ENABLE([glx-tls],
1574     [AS_HELP_STRING([--enable-glx-tls],
1575         [enable TLS support in GLX @<:@default=enabled@:>@])],
1576     [GLX_USE_TLS="$enableval"],
1577     [GLX_USE_TLS=yes])
1578 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1579
1580 if test "x$GLX_USE_TLS" = xyes; then
1581     DEFINES="$DEFINES -DGLX_USE_TLS"
1582 fi
1583
1584 dnl Read-only text section on x86 hardened platforms
1585 AC_ARG_ENABLE([glx-read-only-text],
1586     [AS_HELP_STRING([--enable-glx-read-only-text],
1587         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1588     [enable_glx_read_only_text="$enableval"],
1589     [enable_glx_read_only_text=no])
1590 if test "x$enable_glx_read_only_text" = xyes; then
1591     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1592 fi
1593
1594 dnl
1595 dnl More DRI setup
1596 dnl
1597 dnl Directory for DRI drivers
1598 AC_ARG_WITH([dri-driverdir],
1599     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1600         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1601     [DRI_DRIVER_INSTALL_DIR="$withval"],
1602     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1603 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1604 dnl Extra search path for DRI drivers
1605 AC_ARG_WITH([dri-searchpath],
1606     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1607         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1608     [DRI_DRIVER_SEARCH_DIR="$withval"],
1609     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1610 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1611 dnl Which drivers to build - default is chosen by platform
1612 AC_ARG_WITH([dri-drivers],
1613     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1614         [comma delimited classic DRI drivers list, e.g.
1615         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1616     [with_dri_drivers="$withval"],
1617     [with_dri_drivers=auto])
1618
1619 if test "x$with_dri_drivers" = xauto; then
1620     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1621         with_dri_drivers="yes"
1622     else
1623         with_dri_drivers="no"
1624     fi
1625 fi
1626 if test "x$with_dri_drivers" = xno; then
1627     with_dri_drivers=''
1628 fi
1629
1630 dnl If $with_dri_drivers is yes, drivers will be added through
1631 dnl platform checks. Set DEFINES and LIB_DEPS
1632 if test "x$enable_dri" = xyes; then
1633     # Platform specific settings and drivers to build
1634     case "$host_os" in
1635     linux*)
1636         if test "x$enable_dri3" = xyes; then
1637             DEFINES="$DEFINES -DHAVE_DRI3"
1638         fi
1639
1640         case "$host_cpu" in
1641         powerpc* | sparc*)
1642             # Build only the drivers for cards that exist on PowerPC/sparc
1643             if test "x$with_dri_drivers" = "xyes"; then
1644                 with_dri_drivers="r200 radeon swrast"
1645             fi
1646             ;;
1647         esac
1648         ;;
1649     cygwin*)
1650         if test "x$with_dri_drivers" = "xyes"; then
1651             with_dri_drivers="swrast"
1652         fi
1653         ;;
1654     darwin*)
1655         DEFINES="$DEFINES -DBUILDING_MESA"
1656         if test "x$with_dri_drivers" = "xyes"; then
1657             with_dri_drivers="swrast"
1658         fi
1659         ;;
1660     esac
1661
1662     # default drivers
1663     if test "x$with_dri_drivers" = "xyes"; then
1664         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1665     fi
1666
1667     # Check for expat
1668     PKG_CHECK_MODULES([EXPAT], [expat], [],
1669         # expat version 2.0 and earlier do not provide expat.pc
1670         [AC_CHECK_HEADER([expat.h],[],
1671                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1672          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1673                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1674          EXPAT_LIBS="-lexpat"])
1675
1676     # put all the necessary libs together
1677     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1678 fi
1679
1680 AC_SUBST([DRI_LIB_DEPS])
1681
1682 DRI_DIRS=''
1683 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1684 if test -n "$with_dri_drivers"; then
1685     if test "x$enable_opengl" != xyes; then
1686         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1687     fi
1688
1689     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1690     for driver in $dri_drivers; do
1691         DRI_DIRS="$DRI_DIRS $driver"
1692         case "x$driver" in
1693         xi915)
1694             require_libdrm "i915"
1695             HAVE_I915_DRI=yes;
1696             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1697             ;;
1698         xi965)
1699             require_libdrm "i965"
1700             HAVE_I965_DRI=yes;
1701             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1702             ;;
1703         xnouveau)
1704             require_libdrm "nouveau"
1705             HAVE_NOUVEAU_DRI=yes;
1706             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1707             ;;
1708         xradeon)
1709             require_libdrm "radeon"
1710             HAVE_RADEON_DRI=yes;
1711             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1712             ;;
1713         xr200)
1714             require_libdrm "r200"
1715             HAVE_R200_DRI=yes;
1716             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1717             ;;
1718         xswrast)
1719             HAVE_SWRAST_DRI=yes;
1720             ;;
1721         *)
1722             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1723             ;;
1724         esac
1725     done
1726     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1727 fi
1728
1729
1730 dnl
1731 dnl Gallium LLVM
1732 dnl
1733 dnl With follow-up commits we'll rework --enable-gallium-llvm to --enable-llvm
1734 dnl Since that is too invasive to stable, do the more conservative thing for now
1735 dnl and consider it as a global LLVM toggle.
1736 dnl
1737 AC_ARG_ENABLE([gallium-llvm],
1738     [AS_HELP_STRING([--enable-gallium-llvm],
1739         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1740     [enable_gallium_llvm="$enableval"],
1741     [enable_gallium_llvm=auto])
1742
1743 if test "x$enable_gallium_llvm" = xauto; then
1744     case "$host_cpu" in
1745     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1746     esac
1747 fi
1748
1749 if test "x$enable_gallium_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1750     AC_MSG_ERROR([--enable-gallium-llvm selected but llvm-config is not found])
1751 fi
1752
1753 #
1754 # Vulkan driver configuration
1755 #
1756
1757 AC_ARG_WITH([vulkan-drivers],
1758     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1759         [comma delimited Vulkan drivers list, e.g.
1760         "intel,radeon"
1761         @<:@default=no@:>@])],
1762     [with_vulkan_drivers="$withval"],
1763     [with_vulkan_drivers="no"])
1764
1765 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1766 # here so that the script doesn't choke on an unknown driver name later.
1767 case "x$with_vulkan_drivers" in
1768     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1769     xno) with_vulkan_drivers='' ;;
1770 esac
1771
1772 AC_ARG_WITH([vulkan-icddir],
1773     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1774         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1775     [VULKAN_ICD_INSTALL_DIR="$withval"],
1776     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1777 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1778
1779 if test -n "$with_vulkan_drivers"; then
1780     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1781     for driver in $VULKAN_DRIVERS; do
1782         case "x$driver" in
1783         xintel)
1784             if test "x$HAVE_I965_DRI" != xyes; then
1785                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1786             fi
1787             HAVE_INTEL_VULKAN=yes;
1788
1789             ;;
1790         xradeon)
1791             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1792             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1793             HAVE_RADEON_VULKAN=yes;
1794             ;;
1795         *)
1796             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1797             ;;
1798         esac
1799     done
1800     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1801 fi
1802
1803
1804 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1805 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1806 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1807                                   "x$enable_osmesa" = xyes -o \
1808                                   -n "$DRI_DIRS")
1809
1810 dnl
1811 dnl OSMesa configuration
1812 dnl
1813
1814 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1815 AC_ARG_WITH([osmesa-bits],
1816     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1817         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1818     [osmesa_bits="$withval"],
1819     [osmesa_bits=8])
1820 if test "x$osmesa_bits" != x8; then
1821     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1822         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1823         osmesa_bits=8
1824     fi
1825 fi
1826 case "x$osmesa_bits" in
1827 x8)
1828     OSMESA_LIB="${OSMESA_LIB}"
1829     ;;
1830 x16|x32)
1831     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1832     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1833     ;;
1834 *)
1835     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1836     ;;
1837 esac
1838
1839 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1840     # only link libraries with osmesa if shared
1841     if test "$enable_static" = no; then
1842         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1843     else
1844         OSMESA_LIB_DEPS=""
1845     fi
1846     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1847 fi
1848
1849 AC_SUBST([OSMESA_LIB_DEPS])
1850 AC_SUBST([OSMESA_PC_REQ])
1851 AC_SUBST([OSMESA_PC_LIB_PRIV])
1852
1853 dnl
1854 dnl gbm configuration
1855 dnl
1856 if test "x$enable_gbm" = xyes; then
1857     require_dri_shared_libs_and_glapi "gbm"
1858 fi
1859 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1860 # FINISHME: GBM has a number of dependencies which we should add below
1861 GBM_PC_REQ_PRIV=""
1862 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1863 AC_SUBST([GBM_PC_REQ_PRIV])
1864 AC_SUBST([GBM_PC_LIB_PRIV])
1865
1866 dnl
1867 dnl EGL configuration
1868 dnl
1869
1870 if test "x$enable_egl" = xyes; then
1871     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1872
1873     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1874
1875     require_dri_shared_libs_and_glapi "egl"
1876 fi
1877 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1878 AC_SUBST([EGL_LIB_DEPS])
1879
1880 gallium_st="mesa"
1881
1882 dnl
1883 dnl XA configuration
1884 dnl
1885 if test "x$enable_xa" = xyes; then
1886     if test "x$with_gallium_drivers" = xswrast; then
1887        AC_MSG_ERROR([
1888           Building xa requires at least one non swrast gallium driver.
1889           If you are looking to use libxatracker.so with the VMware driver,
1890           make sure to include svga in the gallium drivers list, apart from
1891           enabling XA.
1892           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1893     fi
1894     gallium_st="$gallium_st xa"
1895 fi
1896 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1897
1898 dnl
1899 dnl Gallium G3DVL configuration
1900 dnl
1901 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1902     if test "x$enable_xvmc" = xauto; then
1903         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1904     fi
1905
1906     if test "x$enable_vdpau" = xauto; then
1907         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1908     fi
1909
1910     if test "x$enable_omx" = xauto; then
1911         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1912     fi
1913
1914     if test "x$enable_va" = xauto; then
1915         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1916     fi
1917 fi
1918
1919 if test "x$enable_dri" = xyes -o \
1920         "x$enable_xvmc" = xyes -o \
1921         "x$enable_vdpau" = xyes -o \
1922         "x$enable_omx" = xyes -o \
1923         "x$enable_va" = xyes; then
1924     need_gallium_vl=yes
1925 fi
1926 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1927
1928 if test "x$enable_xvmc" = xyes -o \
1929         "x$enable_vdpau" = xyes -o \
1930         "x$enable_omx" = xyes -o \
1931         "x$enable_va" = xyes; then
1932     if test x"$enable_dri3" = xyes; then
1933         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1934                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1935     else
1936         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1937     fi
1938     need_gallium_vl_winsys=yes
1939 fi
1940 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1941
1942 if test "x$enable_xvmc" = xyes; then
1943     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1944     gallium_st="$gallium_st xvmc"
1945 fi
1946 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1947
1948 if test "x$enable_vdpau" = xyes; then
1949     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1950     gallium_st="$gallium_st vdpau"
1951     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1952 fi
1953 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1954
1955 if test "x$enable_omx" = xyes; then
1956     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1957     gallium_st="$gallium_st omx"
1958 fi
1959 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1960
1961 if test "x$enable_va" = xyes; then
1962     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1963     gallium_st="$gallium_st va"
1964 fi
1965 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1966
1967 dnl
1968 dnl Nine Direct3D9 configuration
1969 dnl
1970 if test "x$enable_nine" = xyes; then
1971     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1972         AC_MSG_ERROR([nine requires the gallium swrast driver])
1973     fi
1974     if test "x$with_gallium_drivers" = xswrast; then
1975         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1976     fi
1977     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1978         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1979     fi
1980
1981     if test "x$enable_dri3" = xno; then
1982         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1983     fi
1984
1985     gallium_st="$gallium_st nine"
1986 fi
1987 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1988
1989 dnl
1990 dnl OpenCL configuration
1991 dnl
1992
1993 AC_ARG_WITH([clang-libdir],
1994    [AS_HELP_STRING([--with-clang-libdir],
1995          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1996    [CLANG_LIBDIR="$withval"],
1997    [CLANG_LIBDIR=''])
1998
1999 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2000
2001 if test "x$enable_opencl" = xyes; then
2002     if test -z "$with_gallium_drivers"; then
2003         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2004     fi
2005
2006     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2007         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2008     fi
2009
2010     if test "x$have_libclc" = xno; then
2011         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2012                     Make sure the directory containing libclc.pc is specified in your
2013                     PKG_CONFIG_PATH environment variable.
2014                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2015     else
2016         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2017         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2018         AC_SUBST([LIBCLC_INCLUDEDIR])
2019         AC_SUBST([LIBCLC_LIBEXECDIR])
2020     fi
2021
2022     gallium_st="$gallium_st clover"
2023
2024     if test "x$enable_opencl_icd" = xyes; then
2025         OPENCL_LIBNAME="MesaOpenCL"
2026     else
2027         OPENCL_LIBNAME="OpenCL"
2028     fi
2029
2030     if test "x$have_libelf" != xyes; then
2031        AC_MSG_ERROR([Clover requires libelf])
2032     fi
2033
2034     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2035
2036     llvm_add_default_components "opencl"
2037     llvm_add_component "all-targets" "opencl"
2038     llvm_add_component "linker" "opencl"
2039     llvm_add_component "instrumentation" "opencl"
2040     llvm_add_component "ipo" "opencl"
2041     llvm_add_component "irreader" "opencl"
2042     llvm_add_component "option" "opencl"
2043     llvm_add_component "objcarcopts" "opencl"
2044     llvm_add_component "profiledata" "opencl"
2045
2046     dnl Check for Clang internal headers
2047     if test -z "$CLANG_LIBDIR"; then
2048         CLANG_LIBDIR=${LLVM_LIBDIR}
2049     fi
2050     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2051     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2052         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2053 fi
2054 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2055 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2056 AC_SUBST([OPENCL_LIBNAME])
2057 AC_SUBST([CLANG_RESOURCE_DIR])
2058
2059 dnl
2060 dnl Gallium configuration
2061 dnl
2062 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2063
2064 dnl
2065 dnl EGL Platforms configuration
2066 dnl
2067 AC_ARG_WITH([egl-platforms],
2068     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2069         [comma delimited native platforms libEGL supports, e.g.
2070         "x11,drm" @<:@default=auto@:>@])],
2071     [with_egl_platforms="$withval"],
2072     [if test "x$enable_egl" = xyes; then
2073         if test "x$enable_gbm" = xyes; then
2074            with_egl_platforms="x11,drm"
2075         else
2076            with_egl_platforms="x11"
2077         fi
2078     else
2079         with_egl_platforms=""
2080     fi])
2081
2082 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2083     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2084 fi
2085
2086 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2087         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2088         WAYLAND_SCANNER='')
2089 if test "x$WAYLAND_SCANNER" = x; then
2090     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2091 fi
2092
2093 # Do per-EGL platform setups and checks
2094 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2095 for plat in $egl_platforms; do
2096         case "$plat" in
2097         wayland)
2098
2099                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2100
2101                 if test "x$WAYLAND_SCANNER" = x; then
2102                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2103                 fi
2104                 ;;
2105
2106         x11)
2107                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2108                 ;;
2109
2110         drm)
2111                 test "x$enable_gbm" = "xno" &&
2112                         AC_MSG_ERROR([EGL platform drm needs gbm])
2113                 ;;
2114
2115         surfaceless)
2116                 ;;
2117
2118         android)
2119                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2120                 ;;
2121
2122         *)
2123                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2124                 ;;
2125         esac
2126
2127         case "$plat" in
2128         wayland|drm|surfaceless)
2129                 require_libdrm "Platform $plat"
2130                 ;;
2131         esac
2132 done
2133
2134 # libEGL wants to default to the first platform specified in
2135 # ./configure.  parse that here.
2136 if test "x$egl_platforms" != "x"; then
2137     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2138     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2139 else
2140     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2141 fi
2142
2143 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2144 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2145 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2146 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2147 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2148
2149 AC_SUBST([EGL_NATIVE_PLATFORM])
2150 AC_SUBST([EGL_CFLAGS])
2151
2152 # If we don't have the X11 platform, set this define so we don't try to include
2153 # the X11 headers.
2154 if ! echo "$egl_platforms" | grep -q 'x11'; then
2155     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2156     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2157 fi
2158
2159 dnl Directory for XVMC libs
2160 AC_ARG_WITH([xvmc-libdir],
2161     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2162         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2163     [XVMC_LIB_INSTALL_DIR="$withval"],
2164     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2165 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2166
2167 dnl
2168 dnl Gallium Tests
2169 dnl
2170 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2171
2172 dnl Directory for VDPAU libs
2173 AC_ARG_WITH([vdpau-libdir],
2174     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2175         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2176     [VDPAU_LIB_INSTALL_DIR="$withval"],
2177     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2178 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2179
2180 dnl Directory for OMX libs
2181
2182 AC_ARG_WITH([omx-libdir],
2183     [AS_HELP_STRING([--with-omx-libdir=DIR],
2184         [directory for the OMX libraries])],
2185     [OMX_LIB_INSTALL_DIR="$withval"],
2186     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2187 AC_SUBST([OMX_LIB_INSTALL_DIR])
2188
2189 dnl Directory for VA libs
2190
2191 AC_ARG_WITH([va-libdir],
2192     [AS_HELP_STRING([--with-va-libdir=DIR],
2193         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2194     [VA_LIB_INSTALL_DIR="$withval"],
2195     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2196 AC_SUBST([VA_LIB_INSTALL_DIR])
2197
2198 AC_ARG_WITH([d3d-libdir],
2199     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2200         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2201     [D3D_DRIVER_INSTALL_DIR="$withval"],
2202     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2203 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2204
2205 dnl
2206 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2207 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2208 dnl architectures.
2209 dnl
2210 r300_require_llvm() {
2211     case "$host" in *gnux32) return;; esac
2212     case "$host_cpu" in
2213     i*86|x86_64|amd64) require_llvm $1
2214         ;;
2215     esac
2216 }
2217
2218 dnl
2219 dnl DRM is needed by X, Wayland, and offscreen rendering.
2220 dnl Surfaceless is an alternative for the last one.
2221 dnl
2222 require_basic_egl() {
2223     case "$with_egl_platforms" in
2224         *drm*|*surfaceless*)
2225             ;;
2226         *)
2227             AC_MSG_ERROR([$1 requires one of these:
2228                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2229                   2) --with-egl-platforms=surfaceless (offscreen only)
2230                   Recommended options: drm,x11])
2231             ;;
2232     esac
2233 }
2234
2235 radeon_gallium_llvm_check() {
2236     if test "x$enable_gallium_llvm" != "xyes"; then
2237         AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2238     fi
2239     radeon_llvm_check $*
2240 }
2241
2242 swr_require_cxx_feature_flags() {
2243     feature_name="$1"
2244     preprocessor_test="$2"
2245     option_list="$3"
2246     output_var="$4"
2247
2248     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2249     AC_LANG_PUSH([C++])
2250     save_CXXFLAGS="$CXXFLAGS"
2251     save_IFS="$IFS"
2252     IFS=","
2253     found=0
2254     for opts in $option_list
2255     do
2256         unset IFS
2257         CXXFLAGS="$opts $save_CXXFLAGS"
2258         AC_COMPILE_IFELSE(
2259             [AC_LANG_PROGRAM(
2260                 [   #if !($preprocessor_test)
2261                     #error
2262                     #endif
2263                 ])],
2264             [found=1; break],
2265             [])
2266         IFS=","
2267     done
2268     IFS="$save_IFS"
2269     CXXFLAGS="$save_CXXFLAGS"
2270     AC_LANG_POP([C++])
2271     if test $found -eq 1; then
2272         AC_MSG_RESULT([$opts])
2273         eval "$output_var=\$opts"
2274         return 0
2275     fi
2276     AC_MSG_RESULT([no])
2277     AC_MSG_ERROR([swr requires $feature_name support])
2278     return 1
2279 }
2280
2281 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2282 if test -n "$with_gallium_drivers"; then
2283     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2284     for driver in $gallium_drivers; do
2285         case "x$driver" in
2286         xsvga)
2287             HAVE_GALLIUM_SVGA=yes
2288             require_libdrm "svga"
2289             ;;
2290         xi915)
2291             HAVE_GALLIUM_I915=yes
2292             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2293             require_libdrm "Gallium i915"
2294             ;;
2295         xr300)
2296             HAVE_GALLIUM_R300=yes
2297             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2298             require_libdrm "r300"
2299             r300_require_llvm "r300"
2300             ;;
2301         xr600)
2302             HAVE_GALLIUM_R600=yes
2303             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2304             require_libdrm "r600"
2305             if test "x$enable_opencl" = xyes; then
2306                 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2307
2308                 llvm_add_component "asmparser" "r600"
2309                 llvm_add_component "bitreader" "r600"
2310             fi
2311             ;;
2312         xradeonsi)
2313             HAVE_GALLIUM_RADEONSI=yes
2314             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2315             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2316             require_libdrm "radeonsi"
2317             radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2318             require_basic_egl "radeonsi"
2319             ;;
2320         xnouveau)
2321             HAVE_GALLIUM_NOUVEAU=yes
2322             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2323             require_libdrm "nouveau"
2324             ;;
2325         xfreedreno)
2326             HAVE_GALLIUM_FREEDRENO=yes
2327             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2328             require_libdrm "freedreno"
2329             ;;
2330         xetnaviv)
2331             HAVE_GALLIUM_ETNAVIV=yes
2332             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2333             require_libdrm "etnaviv"
2334             ;;
2335        ximx)
2336             HAVE_GALLIUM_IMX=yes
2337             ;;
2338         xswrast)
2339             HAVE_GALLIUM_SOFTPIPE=yes
2340             if test "x$enable_gallium_llvm" = xyes; then
2341                 HAVE_GALLIUM_LLVMPIPE=yes
2342             fi
2343             ;;
2344         xswr)
2345             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2346
2347             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2348                 ",-std=c++11" \
2349                 SWR_CXX11_CXXFLAGS
2350             AC_SUBST([SWR_CXX11_CXXFLAGS])
2351
2352             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2353                 ",-mavx,-march=core-avx" \
2354                 SWR_AVX_CXXFLAGS
2355             AC_SUBST([SWR_AVX_CXXFLAGS])
2356
2357             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2358                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2359                 SWR_AVX2_CXXFLAGS
2360             AC_SUBST([SWR_AVX2_CXXFLAGS])
2361
2362             HAVE_GALLIUM_SWR=yes
2363             ;;
2364         xvc4)
2365             HAVE_GALLIUM_VC4=yes
2366             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2367             require_libdrm "vc4"
2368
2369             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2370                               [USE_VC4_SIMULATOR=yes;
2371                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2372                               [USE_VC4_SIMULATOR=no])
2373             ;;
2374         xvirgl)
2375             HAVE_GALLIUM_VIRGL=yes
2376             require_libdrm "virgl"
2377             require_basic_egl "virgl"
2378             ;;
2379         *)
2380             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2381             ;;
2382         esac
2383     done
2384 fi
2385
2386 if test "x$enable_gallium_llvm" == "xyes" -a "$with_gallium_drivers"; then
2387     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2388     llvm_add_default_components "gallium"
2389 fi
2390
2391 dnl We need to validate some needed dependencies for renderonly drivers.
2392
2393 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" == xyes  ; then
2394     AC_ERROR([Building with imx requires etnaviv])
2395 fi
2396
2397 dnl
2398 dnl Set defines and buildtime variables only when using LLVM.
2399 dnl
2400 if test "x$enable_gallium_llvm" = xyes; then
2401     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2402
2403     dnl Set LLVM_LIBS - This is done after the driver configuration so
2404     dnl that drivers can add additional components to LLVM_COMPONENTS.
2405     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2406     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2407     dnl this was causing the same libraries to be appear multiple times
2408     dnl in LLVM_LIBS.
2409
2410     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2411        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2412     fi
2413     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2414
2415     dnl llvm-config may not give the right answer when llvm is a built as a
2416     dnl single shared library, so we must work the library name out for
2417     dnl ourselves.
2418     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2419     if test "x$enable_llvm_shared_libs" = xyes; then
2420         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2421         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2422         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2423
2424         if test "x$llvm_have_one_so" = xyes; then
2425             dnl LLVM was built using auto*, so there is only one shared object.
2426             LLVM_LIBS="-l$LLVM_SO_NAME"
2427         else
2428             dnl If LLVM was built with CMake, there will be one shared object per
2429             dnl component.
2430             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2431                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2432         Please make sure you have built llvm with the --enable-shared option
2433         and that your llvm libraries are installed in $LLVM_LIBDIR
2434         If you have installed your llvm libraries to a different directory you
2435         can use the --with-llvm-prefix= configure flag to specify this directory.
2436         NOTE: Mesa is attempting to use llvm shared libraries by default.
2437         If you do not want to build with llvm shared libraries and instead want to
2438         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2439         invocation and rebuild.])])
2440
2441            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2442            dnl install uses a shared object for each component and we have
2443            dnl already added all of these objects to LLVM_LIBS.
2444         fi
2445     else
2446         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2447         dnl We need to link to llvm system libs when using static libs
2448         dnl However, only llvm 3.5+ provides --system-libs
2449         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2450             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2451         fi
2452     fi
2453 fi
2454
2455 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2456 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2457 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2458 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2459 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2460 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2461                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2462 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2463 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2464 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2465 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2466 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2467 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2468 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2469 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2470                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2471                                          "x$HAVE_GALLIUM_SWR" = xyes)
2472 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2473 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2474
2475 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2476
2477 if test "x$enable_dri" = xyes; then
2478     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2479 fi
2480
2481 if test "x$have_drisw_kms" = xyes; then
2482     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2483 fi
2484 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2485
2486 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2487 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2488 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2489 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2490 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2491 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2492
2493 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2494 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2495
2496 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2497                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2498                                       "x$HAVE_RADEON_VULKAN" = xyes)
2499
2500 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2501                                         "x$HAVE_I965_DRI" = xyes)
2502
2503 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2504                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2505                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2506 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2507 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2508 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2509 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_gallium_llvm" = xyes)
2510 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2511
2512 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2513 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2514 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2515 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2516                                         "x$enable_gallium_osmesa" = xyes)
2517
2518 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2519 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2520 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2521
2522 AC_SUBST([NINE_MAJOR], 1)
2523 AC_SUBST([NINE_MINOR], 0)
2524 AC_SUBST([NINE_TINY], 0)
2525 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2526
2527 AC_SUBST([VDPAU_MAJOR], 1)
2528 AC_SUBST([VDPAU_MINOR], 0)
2529
2530 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2531 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2532 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2533 AC_SUBST([VA_MINOR], $VA_MINOR)
2534
2535 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2536
2537 AC_SUBST([XVMC_MAJOR], 1)
2538 AC_SUBST([XVMC_MINOR], 0)
2539
2540 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2541 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2542 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2543 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2544
2545 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2546 AC_SUBST([XA_MINOR], $XA_MINOR)
2547 AC_SUBST([XA_TINY], $XA_TINY)
2548 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2549
2550 AC_ARG_ENABLE(valgrind,
2551               [AS_HELP_STRING([--enable-valgrind],
2552                              [Build mesa with valgrind support (default: auto)])],
2553                              [VALGRIND=$enableval], [VALGRIND=auto])
2554 if test "x$VALGRIND" != xno; then
2555         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2556 fi
2557 AC_MSG_CHECKING([whether to enable Valgrind support])
2558 if test "x$VALGRIND" = xauto; then
2559         VALGRIND="$have_valgrind"
2560 fi
2561
2562 if test "x$VALGRIND" = "xyes"; then
2563         if ! test "x$have_valgrind" = xyes; then
2564                 AC_MSG_ERROR([Valgrind support required but not present])
2565         fi
2566         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2567 fi
2568
2569 AC_MSG_RESULT([$VALGRIND])
2570
2571 dnl Restore LDFLAGS and CPPFLAGS
2572 LDFLAGS="$_SAVE_LDFLAGS"
2573 CPPFLAGS="$_SAVE_CPPFLAGS"
2574
2575 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2576 if test "x$acv_mesa_CLANG" = xyes; then
2577     CFLAGS="$CFLAGS -Qunused-arguments"
2578     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2579 fi
2580
2581 dnl Add user CFLAGS and CXXFLAGS
2582 CFLAGS="$CFLAGS $USER_CFLAGS"
2583 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2584
2585 dnl Substitute the config
2586 AC_CONFIG_FILES([Makefile
2587                 src/Makefile
2588                 src/amd/Makefile
2589                 src/amd/vulkan/Makefile
2590                 src/compiler/Makefile
2591                 src/egl/Makefile
2592                 src/egl/main/egl.pc
2593                 src/egl/wayland/wayland-drm/Makefile
2594                 src/egl/wayland/wayland-egl/Makefile
2595                 src/egl/wayland/wayland-egl/wayland-egl.pc
2596                 src/gallium/Makefile
2597                 src/gallium/auxiliary/Makefile
2598                 src/gallium/auxiliary/pipe-loader/Makefile
2599                 src/gallium/drivers/freedreno/Makefile
2600                 src/gallium/drivers/ddebug/Makefile
2601                 src/gallium/drivers/i915/Makefile
2602                 src/gallium/drivers/llvmpipe/Makefile
2603                 src/gallium/drivers/noop/Makefile
2604                 src/gallium/drivers/nouveau/Makefile
2605                 src/gallium/drivers/r300/Makefile
2606                 src/gallium/drivers/r600/Makefile
2607                 src/gallium/drivers/radeon/Makefile
2608                 src/gallium/drivers/radeonsi/Makefile
2609                 src/gallium/drivers/rbug/Makefile
2610                 src/gallium/drivers/softpipe/Makefile
2611                 src/gallium/drivers/svga/Makefile
2612                 src/gallium/drivers/swr/Makefile
2613                 src/gallium/drivers/trace/Makefile
2614                 src/gallium/drivers/etnaviv/Makefile
2615                 src/gallium/drivers/imx/Makefile
2616                 src/gallium/drivers/vc4/Makefile
2617                 src/gallium/drivers/virgl/Makefile
2618                 src/gallium/state_trackers/clover/Makefile
2619                 src/gallium/state_trackers/dri/Makefile
2620                 src/gallium/state_trackers/glx/xlib/Makefile
2621                 src/gallium/state_trackers/nine/Makefile
2622                 src/gallium/state_trackers/omx/Makefile
2623                 src/gallium/state_trackers/osmesa/Makefile
2624                 src/gallium/state_trackers/va/Makefile
2625                 src/gallium/state_trackers/vdpau/Makefile
2626                 src/gallium/state_trackers/xa/Makefile
2627                 src/gallium/state_trackers/xvmc/Makefile
2628                 src/gallium/targets/d3dadapter9/Makefile
2629                 src/gallium/targets/d3dadapter9/d3d.pc
2630                 src/gallium/targets/dri/Makefile
2631                 src/gallium/targets/libgl-xlib/Makefile
2632                 src/gallium/targets/omx/Makefile
2633                 src/gallium/targets/opencl/Makefile
2634                 src/gallium/targets/opencl/mesa.icd
2635                 src/gallium/targets/osmesa/Makefile
2636                 src/gallium/targets/osmesa/osmesa.pc
2637                 src/gallium/targets/pipe-loader/Makefile
2638                 src/gallium/targets/va/Makefile
2639                 src/gallium/targets/vdpau/Makefile
2640                 src/gallium/targets/xa/Makefile
2641                 src/gallium/targets/xa/xatracker.pc
2642                 src/gallium/targets/xvmc/Makefile
2643                 src/gallium/tests/trivial/Makefile
2644                 src/gallium/tests/unit/Makefile
2645                 src/gallium/winsys/etnaviv/drm/Makefile
2646                 src/gallium/winsys/imx/drm/Makefile
2647                 src/gallium/winsys/freedreno/drm/Makefile
2648                 src/gallium/winsys/i915/drm/Makefile
2649                 src/gallium/winsys/nouveau/drm/Makefile
2650                 src/gallium/winsys/radeon/drm/Makefile
2651                 src/gallium/winsys/amdgpu/drm/Makefile
2652                 src/gallium/winsys/svga/drm/Makefile
2653                 src/gallium/winsys/sw/dri/Makefile
2654                 src/gallium/winsys/sw/kms-dri/Makefile
2655                 src/gallium/winsys/sw/null/Makefile
2656                 src/gallium/winsys/sw/wrapper/Makefile
2657                 src/gallium/winsys/sw/xlib/Makefile
2658                 src/gallium/winsys/vc4/drm/Makefile
2659                 src/gallium/winsys/virgl/drm/Makefile
2660                 src/gallium/winsys/virgl/vtest/Makefile
2661                 src/gbm/Makefile
2662                 src/gbm/main/gbm.pc
2663                 src/glx/Makefile
2664                 src/glx/apple/Makefile
2665                 src/glx/tests/Makefile
2666                 src/glx/windows/Makefile
2667                 src/glx/windows/windowsdriproto.pc
2668                 src/gtest/Makefile
2669                 src/intel/Makefile
2670                 src/intel/tools/Makefile
2671                 src/intel/vulkan/Makefile
2672                 src/loader/Makefile
2673                 src/mapi/Makefile
2674                 src/mapi/es1api/glesv1_cm.pc
2675                 src/mapi/es2api/glesv2.pc
2676                 src/mapi/glapi/gen/Makefile
2677                 src/mesa/Makefile
2678                 src/mesa/gl.pc
2679                 src/mesa/drivers/dri/dri.pc
2680                 src/mesa/drivers/dri/common/Makefile
2681                 src/mesa/drivers/dri/common/xmlpool/Makefile
2682                 src/mesa/drivers/dri/i915/Makefile
2683                 src/mesa/drivers/dri/i965/Makefile
2684                 src/mesa/drivers/dri/Makefile
2685                 src/mesa/drivers/dri/nouveau/Makefile
2686                 src/mesa/drivers/dri/r200/Makefile
2687                 src/mesa/drivers/dri/radeon/Makefile
2688                 src/mesa/drivers/dri/swrast/Makefile
2689                 src/mesa/drivers/osmesa/Makefile
2690                 src/mesa/drivers/osmesa/osmesa.pc
2691                 src/mesa/drivers/x11/Makefile
2692                 src/mesa/main/tests/Makefile
2693                 src/util/Makefile
2694                 src/util/tests/hash_table/Makefile
2695                 src/vulkan/wsi/Makefile])
2696
2697 AC_OUTPUT
2698
2699 # Fix up dependencies in *.Plo files, where we changed the extension of a
2700 # source file
2701 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2702
2703
2704 dnl
2705 dnl Output some configuration info for the user
2706 dnl
2707 echo ""
2708 echo "        prefix:          $prefix"
2709 echo "        exec_prefix:     $exec_prefix"
2710 echo "        libdir:          $libdir"
2711 echo "        includedir:      $includedir"
2712
2713 dnl API info
2714 echo ""
2715 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2716
2717 dnl Driver info
2718 echo ""
2719 case "x$enable_osmesa$enable_gallium_osmesa" in
2720 xnoyes)
2721         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2722         ;;
2723 xyesno)
2724         echo "        OSMesa:          lib$OSMESA_LIB"
2725         ;;
2726 xnono)
2727         echo "        OSMesa:          no"
2728         ;;
2729 esac
2730
2731 echo ""
2732 if test "x$enable_dri" != xno; then
2733         echo "        DRI platform:    $dri_platform"
2734         if test -z "$DRI_DIRS"; then
2735             echo "        DRI drivers:     no"
2736         else
2737             echo "        DRI drivers:     $DRI_DIRS"
2738         fi
2739         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2740 fi
2741
2742 case "x$enable_glx" in
2743 xdri)
2744     echo "        GLX:             DRI-based"
2745     ;;
2746 xxlib)
2747     echo "        GLX:             Xlib-based"
2748     ;;
2749 xgallium-xlib)
2750     echo "        GLX:             Xlib-based (Gallium)"
2751     ;;
2752 *)
2753     echo "        GLX:             $enable_glx"
2754     ;;
2755 esac
2756
2757 dnl EGL
2758 echo ""
2759 echo "        EGL:             $enable_egl"
2760 if test "$enable_egl" = yes; then
2761     echo "        EGL platforms:   $egl_platforms"
2762
2763     egl_drivers=""
2764     if test "x$enable_dri" != "xno"; then
2765         egl_drivers="$egl_drivers builtin:egl_dri2"
2766     fi
2767     if test "x$enable_dri3" != "xno"; then
2768         egl_drivers="$egl_drivers builtin:egl_dri3"
2769     fi
2770
2771     echo "        EGL drivers:    $egl_drivers"
2772 fi
2773 if test "x$enable_gbm" = xyes; then
2774     echo "        GBM:             yes"
2775 else
2776     echo "        GBM:             no"
2777 fi
2778
2779 # Vulkan
2780 echo ""
2781 if test "x$VULKAN_DRIVERS" != x; then
2782     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2783     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2784 else
2785     echo "        Vulkan drivers:  no"
2786 fi
2787
2788 echo ""
2789 if test "x$enable_gallium_llvm" = xyes; then
2790     echo "        llvm:            yes"
2791     echo "        llvm-config:     $LLVM_CONFIG"
2792     echo "        llvm-version:    $LLVM_VERSION"
2793 else
2794     echo "        llvm:            no"
2795 fi
2796
2797 echo ""
2798 if test -n "$with_gallium_drivers"; then
2799     echo "        Gallium drivers: $gallium_drivers"
2800     echo "        Gallium st:      $gallium_st"
2801 else
2802     echo "        Gallium:         no"
2803 fi
2804
2805 echo ""
2806 if test "x$enable_gallium_extra_hud" != xyes; then
2807     echo "        HUD extra stats: no"
2808 else
2809     echo "        HUD extra stats: yes"
2810 fi
2811
2812 if test "x$enable_lmsensors" != xyes; then
2813     echo "        HUD lmsensors:   no"
2814 else
2815     echo "        HUD lmsensors:   yes"
2816 fi
2817
2818 dnl Libraries
2819 echo ""
2820 echo "        Shared libs:     $enable_shared"
2821 echo "        Static libs:     $enable_static"
2822 echo "        Shared-glapi:    $enable_shared_glapi"
2823
2824 dnl Compiler options
2825 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2826 cflags=`echo $CFLAGS | \
2827     $SED 's/^ *//;s/  */ /;s/ *$//'`
2828 cxxflags=`echo $CXXFLAGS | \
2829     $SED 's/^ *//;s/  */ /;s/ *$//'`
2830 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2831 echo ""
2832 echo "        CFLAGS:          $cflags"
2833 echo "        CXXFLAGS:        $cxxflags"
2834 echo "        Macros:          $defines"
2835 echo ""
2836 if test "x$enable_gallium_llvm" = xyes; then
2837     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2838     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2839     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2840     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2841     echo ""
2842 fi
2843 echo "        PYTHON2:         $PYTHON2"
2844
2845 echo ""
2846 echo "        Run '${MAKE-make}' to build Mesa"
2847 echo ""