configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 dnl http://people.gnome.org/~walters/docs/build-api.txt
  22 dnl We don't support srcdir != builddir.
  23 echo \#buildapi-variable-no-builddir >/dev/null
  24
  25 # Support silent build rules, requires at least automake-1.11. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  29
  30 LT_PREREQ([2.2])
  31 LT_INIT([disable-static])
  32
  33 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  34 USER_CFLAGS="$CFLAGS"
  35 USER_CXXFLAGS="$CXXFLAGS"
  36
  37 dnl Versions for external dependencies
  38 LIBDRM_REQUIRED=2.4.24
  39 LIBDRM_RADEON_REQUIRED=2.4.31
  40 LIBDRM_INTEL_REQUIRED=2.4.30
  41 LIBDRM_NOUVEAU_REQUIRED=0.6
  42 DRI2PROTO_REQUIRED=2.6
  43 GLPROTO_REQUIRED=1.4.14
  44 LIBDRM_XORG_REQUIRED=2.4.24
  45 LIBKMS_XORG_REQUIRED=1.0.0
  46
  47 dnl Check for progs
  48 AC_PROG_CPP
  49 AC_PROG_CC
  50 AC_PROG_CXX
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55 AC_PATH_PROG([MKDEP], [makedepend])
  56
  57 if test "x$MKDEP" = "x"; then
  58     AC_MSG_ERROR([makedepend is required to build Mesa])
  59 fi
  60
  61 AC_PROG_YACC
  62 AC_PATH_PROG([YACC_INST], $YACC)
  63 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  64     if test -z "$YACC_INST"; then
  65         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  66     fi
  67 fi
  68 AC_PROG_LEX
  69
  70 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  71 dnl configuration in that case.
  72 AC_PROG_INSTALL
  73 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  74
  75 dnl We need a POSIX shell for parts of the build. Assume we have one
  76 dnl in most cases.
  77 case "$host_os" in
  78 solaris*)
  79     # Solaris /bin/sh is too old/non-POSIX compliant
  80     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  81     SHELL="$POSIX_SHELL"
  82     ;;
  83 esac
  84
  85 AC_PATH_PROG([GTESTCONFIG], [gtest-config])
  86 if test "x$GTESTCONFIG" != "x"; then
  87     GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
  88     GTEST_LIBS=`gtest-config --ldflags --libs`
  89     AC_SUBST([GTEST_CFLAGS])
  90     AC_SUBST([GTEST_LIBS])
  91     HAVE_GTEST=yes
  92 else
  93     HAVE_GTEST=no
  94 fi
  95 AM_CONDITIONAL(HAVE_GTEST, test x$HAVE_GTEST = xyes)
  96
  97 dnl clang is mostly GCC-compatible, but its version is much lower,
  98 dnl so we have to check for it.
  99 AC_MSG_CHECKING([if compiling with clang])
 100
 101 AC_COMPILE_IFELSE(
 102 [AC_LANG_PROGRAM([], [[
 103 #ifndef __clang__
 104        not clang
 105 #endif
 106 ]])],
 107 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 108
 109 AC_MSG_RESULT([$acv_mesa_CLANG])
 110
 111 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 112 dnl versions are explictly not supported.
 113 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 114     AC_MSG_CHECKING([whether gcc version is sufficient])
 115     major=0
 116     minor=0
 117
 118     GCC_VERSION=`$CC -dumpversion`
 119     if test $? -eq 0; then
 120         major=`echo $GCC_VERSION | cut -d. -f1`
 121         minor=`echo $GCC_VERSION | cut -d. -f2`
 122     fi
 123
 124     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
 125         AC_MSG_RESULT([no])
 126         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 127     else
 128         AC_MSG_RESULT([yes])
 129     fi
 130 fi
 131
 132
 133 MKDEP_OPTIONS=-fdepend
 134 dnl Ask gcc where it's keeping its secret headers
 135 if test "x$GCC" = xyes; then
 136     for dir in include include-fixed; do
 137         GCC_INCLUDES=`$CC -print-file-name=$dir`
 138         if test "x$GCC_INCLUDES" != x && \
 139            test "$GCC_INCLUDES" != "$dir" && \
 140            test -d "$GCC_INCLUDES"; then
 141             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 142         fi
 143     done
 144 fi
 145 AC_SUBST([MKDEP_OPTIONS])
 146
 147 dnl Make sure the pkg-config macros are defined
 148 m4_ifndef([PKG_PROG_PKG_CONFIG],
 149     [m4_fatal([Could not locate the pkg-config autoconf macros.
 150   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 151   are in a different location, try setting the environment variable
 152   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 153 PKG_PROG_PKG_CONFIG()
 154
 155 dnl LIB_DIR - library basename
 156 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 157 AC_SUBST([LIB_DIR])
 158
 159 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 160 _SAVE_LDFLAGS="$LDFLAGS"
 161 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 162 AC_SUBST([EXTRA_LIB_PATH])
 163
 164 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 165 _SAVE_CPPFLAGS="$CPPFLAGS"
 166 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 167 AC_SUBST([X11_INCLUDES])
 168
 169 dnl Compiler macros
 170 DEFINES=""
 171 AC_SUBST([DEFINES])
 172 case "$host_os" in
 173 linux*|*-gnu*|gnu*)
 174     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 175     ;;
 176 solaris*)
 177     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 178     ;;
 179 cygwin*)
 180     DEFINES="$DEFINES -DPTHREADS"
 181     ;;
 182 esac
 183
 184 dnl Add flags for gcc and g++
 185 if test "x$GCC" = xyes; then
 186     CFLAGS="$CFLAGS -Wall -std=c99"
 187
 188     # Enable -Werror=implicit-function-declaration and
 189     # -Werror=missing-prototypes, if available, or otherwise, just
 190     # -Wmissing-prototypes.  This is particularly useful to avoid
 191     # generating a loadable driver module that has undefined symbols.
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 194     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 195     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 197                    AC_MSG_RESULT([yes]),
 198                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 199                     AC_MSG_RESULT([no])]);
 200
 201     # Enable -fvisibility=hidden if using a gcc that supports it
 202     save_CFLAGS="$CFLAGS"
 203     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 204     VISIBILITY_CFLAGS="-fvisibility=hidden"
 205     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 208
 209     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 210     CFLAGS=$save_CFLAGS
 211
 212     # Work around aliasing bugs - developers should comment this out
 213     CFLAGS="$CFLAGS -fno-strict-aliasing"
 214
 215     # gcc's builtin memcmp is slower than glibc's
 216     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 217     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 218 fi
 219 if test "x$GXX" = xyes; then
 220     CXXFLAGS="$CXXFLAGS -Wall"
 221
 222     # Enable -fvisibility=hidden if using a gcc that supports it
 223     save_CXXFLAGS="$CXXFLAGS"
 224     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 225     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 226     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 227     AC_LANG_PUSH([C++])
 228     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 229                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 230     AC_LANG_POP([C++])
 231
 232     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 233     CXXFLAGS=$save_CXXFLAGS
 234
 235     # Work around aliasing bugs - developers should comment this out
 236     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 237
 238     # gcc's builtin memcmp is slower than glibc's
 239     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 240     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 241 fi
 242
 243 dnl even if the compiler appears to support it, using visibility attributes isn't
 244 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 245 case "$host_os" in
 246 cygwin*)
 247     VISIBILITY_CFLAGS=""
 248     VISIBILITY_CXXFLAGS=""
 249     ;;
 250 esac
 251
 252 AC_SUBST([VISIBILITY_CFLAGS])
 253 AC_SUBST([VISIBILITY_CXXFLAGS])
 254
 255 dnl These should be unnecessary, but let the user set them if they want
 256 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 257     Default is to use CFLAGS.])
 258 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 259     compiler. Default is to use CFLAGS.])
 260 AC_SUBST([OPT_FLAGS])
 261 AC_SUBST([ARCH_FLAGS])
 262
 263 dnl
 264 dnl Hacks to enable 32 or 64 bit build
 265 dnl
 266 AC_ARG_ENABLE([32-bit],
 267     [AS_HELP_STRING([--enable-32-bit],
 268         [build 32-bit libraries @<:@default=auto@:>@])],
 269     [enable_32bit="$enableval"],
 270     [enable_32bit=auto]
 271 )
 272 if test "x$enable_32bit" = xyes; then
 273     if test "x$GCC" = xyes; then
 274         CFLAGS="$CFLAGS -m32"
 275         ARCH_FLAGS="$ARCH_FLAGS -m32"
 276     fi
 277     if test "x$GXX" = xyes; then
 278         CXXFLAGS="$CXXFLAGS -m32"
 279     fi
 280 fi
 281 AC_ARG_ENABLE([64-bit],
 282     [AS_HELP_STRING([--enable-64-bit],
 283         [build 64-bit libraries @<:@default=auto@:>@])],
 284     [enable_64bit="$enableval"],
 285     [enable_64bit=auto]
 286 )
 287 if test "x$enable_64bit" = xyes; then
 288     if test "x$GCC" = xyes; then
 289         CFLAGS="$CFLAGS -m64"
 290     fi
 291     if test "x$GXX" = xyes; then
 292         CXXFLAGS="$CXXFLAGS -m64"
 293     fi
 294 fi
 295
 296 dnl Can't have static and shared libraries, default to static if user
 297 dnl explicitly requested. If both disabled, set to static since shared
 298 dnl was explicitly requested.
 299 case "x$enable_static$enable_shared" in
 300 xyesyes )
 301     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 302     enable_shared=no
 303     ;;
 304 xnono )
 305     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 306     enable_static=yes
 307     ;;
 308 esac
 309
 310 dnl
 311 dnl mklib options
 312 dnl
 313 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 314 if test "$enable_static" = yes; then
 315     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 316 fi
 317 AC_SUBST([MKLIB_OPTIONS])
 318
 319 dnl
 320 dnl other compiler options
 321 dnl
 322 AC_ARG_ENABLE([debug],
 323     [AS_HELP_STRING([--enable-debug],
 324         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 325     [enable_debug="$enableval"],
 326     [enable_debug=no]
 327 )
 328 if test "x$enable_debug" = xyes; then
 329     DEFINES="$DEFINES -DDEBUG"
 330     if test "x$GCC" = xyes; then
 331         CFLAGS="$CFLAGS -g"
 332     fi
 333     if test "x$GXX" = xyes; then
 334         CXXFLAGS="$CXXFLAGS -g"
 335     fi
 336 fi
 337
 338 dnl
 339 dnl library names
 340 dnl
 341 LIB_PREFIX_GLOB='lib'
 342 LIB_VERSION_SEPARATOR='.'
 343 if test "$enable_static" = yes; then
 344     LIB_EXTENSION='a'
 345 else
 346     case "$host_os" in
 347     darwin* )
 348         LIB_EXTENSION='dylib' ;;
 349     cygwin* )
 350         dnl prefix can be 'cyg' or 'lib'
 351         LIB_PREFIX_GLOB='???'
 352         LIB_VERSION_SEPARATOR='-'
 353         LIB_EXTENSION='dll' ;;
 354     aix* )
 355         LIB_EXTENSION='a' ;;
 356     * )
 357         LIB_EXTENSION='so' ;;
 358     esac
 359 fi
 360
 361 dnl
 362 dnl Mangled Mesa support
 363 dnl
 364 AC_ARG_ENABLE([mangling],
 365   [AS_HELP_STRING([--enable-mangling],
 366     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 367   [enable_mangling="${enableval}"],
 368   [enable_mangling=no]
 369 )
 370 GL_LIB="GL"
 371 GLU_LIB="GLU"
 372 OSMESA_LIB="OSMesa"
 373 if test "x${enable_mangling}" = "xyes" ; then
 374   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 375   GL_LIB="MangledGL"
 376   GLU_LIB="MangledGLU"
 377   OSMESA_LIB="MangledOSMesa"
 378 fi
 379 AC_SUBST([GL_LIB])
 380 AC_SUBST([GLU_LIB])
 381 AC_SUBST([OSMESA_LIB])
 382 AM_CONDITIONAL(HAVE_MANGLED_GL, test $GL_LIB = MangledGL)
 383
 384 dnl
 385 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 386 dnl
 387 AC_ARG_ENABLE([texture-float],
 388     [AS_HELP_STRING([--enable-texture-float],
 389         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 390     [enable_texture_float="$enableval"],
 391     [enable_texture_float=no]
 392 )
 393 if test "x$enable_texture_float" = xyes; then
 394     AC_MSG_WARN([Floating-point textures enabled.])
 395     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 396     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 397 fi
 398
 399 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 400 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 401 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 402 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 403 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 404 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 405 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 406 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 407
 408 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 411 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 412 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 413 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 414 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 415 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 416 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 417
 418 AC_SUBST([GL_LIB_NAME])
 419 AC_SUBST([GLU_LIB_NAME])
 420 AC_SUBST([OSMESA_LIB_NAME])
 421 AC_SUBST([EGL_LIB_NAME])
 422 AC_SUBST([GLESv1_CM_LIB_NAME])
 423 AC_SUBST([GLESv2_LIB_NAME])
 424 AC_SUBST([VG_LIB_NAME])
 425 AC_SUBST([GLAPI_LIB_NAME])
 426
 427 AC_SUBST([GL_LIB_GLOB])
 428 AC_SUBST([GLU_LIB_GLOB])
 429 AC_SUBST([OSMESA_LIB_GLOB])
 430 AC_SUBST([EGL_LIB_GLOB])
 431 AC_SUBST([GLESv1_CM_LIB_GLOB])
 432 AC_SUBST([GLESv2_LIB_GLOB])
 433 AC_SUBST([VG_LIB_GLOB])
 434 AC_SUBST([GLAPI_LIB_GLOB])
 435
 436 dnl
 437 dnl Arch/platform-specific settings
 438 dnl
 439 AC_ARG_ENABLE([asm],
 440     [AS_HELP_STRING([--disable-asm],
 441         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 442     [enable_asm="$enableval"],
 443     [enable_asm=yes]
 444 )
 445 asm_arch=""
 446 ASM_FLAGS=""
 447 MESA_ASM_SOURCES=""
 448 GLAPI_ASM_SOURCES=""
 449 AC_MSG_CHECKING([whether to enable assembly])
 450 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 451 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 452 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 453     case "$host_cpu" in
 454     i?86 | x86_64)
 455         enable_asm=no
 456         AC_MSG_RESULT([no, cross compiling])
 457         ;;
 458     esac
 459 fi
 460 # check for supported arches
 461 if test "x$enable_asm" = xyes; then
 462     case "$host_cpu" in
 463     i?86)
 464         case "$host_os" in
 465         linux* | *freebsd* | dragonfly* | *netbsd*)
 466             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 467             ;;
 468         esac
 469         ;;
 470     x86_64)
 471         case "$host_os" in
 472         linux* | *freebsd* | dragonfly* | *netbsd*)
 473             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 474             ;;
 475         esac
 476         ;;
 477     powerpc)
 478         case "$host_os" in
 479         linux*)
 480             asm_arch=ppc
 481             ;;
 482         esac
 483         ;;
 484     sparc*)
 485         case "$host_os" in
 486         linux*)
 487             asm_arch=sparc
 488             ;;
 489         esac
 490         ;;
 491     esac
 492
 493     case "$asm_arch" in
 494     x86)
 495         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 496         MESA_ASM_SOURCES='$(X86_SOURCES)'
 497         GLAPI_ASM_SOURCES='$(X86_API)'
 498         AC_MSG_RESULT([yes, x86])
 499         ;;
 500     x86_64)
 501         ASM_FLAGS="-DUSE_X86_64_ASM"
 502         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 503         GLAPI_ASM_SOURCES='$(X86-64_API)'
 504         AC_MSG_RESULT([yes, x86_64])
 505         ;;
 506     sparc)
 507         ASM_FLAGS="-DUSE_SPARC_ASM"
 508         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 509         GLAPI_ASM_SOURCES='$(SPARC_API)'
 510         AC_MSG_RESULT([yes, sparc])
 511         ;;
 512     *)
 513         AC_MSG_RESULT([no, platform not supported])
 514         ;;
 515     esac
 516 fi
 517 AC_SUBST([ASM_FLAGS])
 518 AC_SUBST([MESA_ASM_SOURCES])
 519 AC_SUBST([GLAPI_ASM_SOURCES])
 520
 521 dnl PIC code macro
 522 MESA_PIC_FLAGS
 523
 524 dnl Check to see if dlopen is in default libraries (like Solaris, which
 525 dnl has it in libc), or if libdl is needed to get it.
 526 AC_CHECK_FUNC([dlopen], [],
 527     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 528 AC_SUBST([DLOPEN_LIBS])
 529
 530 dnl See if posix_memalign is available
 531 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 532
 533 dnl SELinux awareness.
 534 AC_ARG_ENABLE([selinux],
 535     [AS_HELP_STRING([--enable-selinux],
 536         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 537     [MESA_SELINUX="$enableval"],
 538     [MESA_SELINUX=no])
 539 if test "x$enable_selinux" = "xyes"; then
 540     AC_CHECK_HEADER([selinux/selinux.h],[],
 541                     [AC_MSG_ERROR([SELinux headers not found])])
 542     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 543                  [AC_MSG_ERROR([SELinux library not found])])
 544     SELINUX_LIBS="-lselinux"
 545     DEFINES="$DEFINES -DMESA_SELINUX"
 546 fi
 547
 548 dnl Options for APIs
 549 AC_ARG_ENABLE([opengl],
 550     [AS_HELP_STRING([--disable-opengl],
 551         [disable support for standard OpenGL API @<:@default=no@:>@])],
 552     [enable_opengl="$enableval"],
 553     [enable_opengl=yes])
 554 AC_ARG_ENABLE([gles1],
 555     [AS_HELP_STRING([--enable-gles1],
 556         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 557     [enable_gles1="$enableval"],
 558     [enable_gles1=no])
 559 AC_ARG_ENABLE([gles2],
 560     [AS_HELP_STRING([--enable-gles2],
 561         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 562     [enable_gles2="$enableval"],
 563     [enable_gles2=no])
 564 AC_ARG_ENABLE([openvg],
 565     [AS_HELP_STRING([--enable-openvg],
 566         [enable support for OpenVG API @<:@default=no@:>@])],
 567     [enable_openvg="$enableval"],
 568     [enable_openvg=no])
 569
 570 AC_ARG_ENABLE([dri],
 571     [AS_HELP_STRING([--enable-dri],
 572         [enable DRI modules @<:@default=auto@:>@])],
 573     [enable_dri="$enableval"],
 574     [enable_dri=auto])
 575 AC_ARG_ENABLE([glx],
 576     [AS_HELP_STRING([--enable-glx],
 577         [enable GLX library @<:@default=auto@:>@])],
 578     [enable_glx="$enableval"],
 579     [enable_glx=auto])
 580 AC_ARG_ENABLE([osmesa],
 581     [AS_HELP_STRING([--enable-osmesa],
 582         [enable OSMesa library @<:@default=auto@:>@])],
 583     [enable_osmesa="$enableval"],
 584     [enable_osmesa=auto])
 585 AC_ARG_ENABLE([egl],
 586     [AS_HELP_STRING([--disable-egl],
 587         [disable EGL library @<:@default=enabled@:>@])],
 588     [enable_egl="$enableval"],
 589     [enable_egl=yes])
 590
 591 AC_ARG_ENABLE([xorg],
 592     [AS_HELP_STRING([--enable-xorg],
 593         [enable support for X.Org DDX API @<:@default=no@:>@])],
 594     [enable_xorg="$enableval"],
 595     [enable_xorg=no])
 596 AC_ARG_ENABLE([xa],
 597     [AS_HELP_STRING([--enable-xa],
 598         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 599     [enable_xa="$enableval"],
 600     [enable_xa=no])
 601 AC_ARG_ENABLE([d3d1x],
 602     [AS_HELP_STRING([--enable-d3d1x],
 603         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 604     [enable_d3d1x="$enableval"],
 605     [enable_d3d1x=no])
 606 AC_ARG_ENABLE([gbm],
 607    [AS_HELP_STRING([--enable-gbm],
 608          [enable gbm library @<:@default=auto@:>@])],
 609    [enable_gbm="$enableval"],
 610    [enable_gbm=auto])
 611
 612 AC_ARG_ENABLE([xvmc],
 613    [AS_HELP_STRING([--enable-xvmc],
 614          [enable xvmc library @<:@default=auto@:>@])],
 615    [enable_xvmc="$enableval"],
 616    [enable_xvmc=auto])
 617 AC_ARG_ENABLE([vdpau],
 618    [AS_HELP_STRING([--enable-vdpau],
 619          [enable vdpau library @<:@default=auto@:>@])],
 620    [enable_vdpau="$enableval"],
 621    [enable_vdpau=auto])
 622 AC_ARG_ENABLE([va],
 623    [AS_HELP_STRING([--enable-va],
 624          [enable va library @<:@default=auto@:>@])],
 625    [enable_va="$enableval"],
 626    [enable_va=auto])
 627
 628 AC_ARG_ENABLE([xlib_glx],
 629     [AS_HELP_STRING([--enable-xlib-glx],
 630         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 631     [enable_xlib_glx="$enableval"],
 632     [enable_xlib_glx=auto])
 633 AC_ARG_ENABLE([gallium_egl],
 634     [AS_HELP_STRING([--enable-gallium-egl],
 635         [enable optional EGL state tracker (not required
 636          for EGL support in Gallium with OpenGL and OpenGL ES)
 637          @<:@default=disable@:>@])],
 638     [enable_gallium_egl="$enableval"],
 639     [enable_gallium_egl=no])
 640 AC_ARG_ENABLE([gallium_gbm],
 641     [AS_HELP_STRING([--enable-gallium-gbm],
 642         [enable optional gbm state tracker (not required for
 643          gbm support in Gallium)
 644          @<:@default=auto@:>@])],
 645     [enable_gallium_gbm="$enableval"],
 646     [enable_gallium_gbm=auto])
 647
 648 # Option for Gallium drivers
 649 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 650
 651 AC_ARG_WITH([gallium-drivers],
 652     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 653         [comma delimited Gallium drivers list, e.g.
 654         "i915,nouveau,r300,r600,svga,swrast"
 655         @<:@default=r300,r600,swrast@:>@])],
 656     [with_gallium_drivers="$withval"],
 657     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 658
 659 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 660 # here so that the script doesn't choke on an unknown driver name later.
 661 case "$with_gallium_drivers" in
 662     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 663     no) with_gallium_drivers='' ;;
 664 esac
 665
 666 if test "x$enable_opengl" = xno -a \
 667         "x$enable_gles1" = xno -a \
 668         "x$enable_gles2" = xno -a \
 669         "x$enable_openvg" = xno -a \
 670         "x$enable_xorg" = xno -a \
 671         "x$enable_xa" = xno -a \
 672         "x$enable_d3d1x" = xno -a \
 673         "x$enable_xvmc" = xno -a \
 674         "x$enable_vdpau" = xno -a \
 675         "x$enable_va" = xno; then
 676     AC_MSG_ERROR([at least one API should be enabled])
 677 fi
 678
 679 API_DEFINES=""
 680 if test "x$enable_opengl" = xno; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 682 else
 683     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 684 fi
 685 if test "x$enable_gles1" = xyes; then
 686     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 687 fi
 688 if test "x$enable_gles2" = xyes; then
 689     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 690 fi
 691 AC_SUBST([API_DEFINES])
 692
 693 AC_ARG_ENABLE([shared-glapi],
 694     [AS_HELP_STRING([--enable-shared-glapi],
 695         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 696     [enable_shared_glapi="$enableval"],
 697     [enable_shared_glapi=no])
 698
 699 SHARED_GLAPI="0"
 700 if test "x$enable_shared_glapi" = xyes; then
 701     SHARED_GLAPI="1"
 702     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 703     # the remap table)
 704     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 705 fi
 706 AC_SUBST([SHARED_GLAPI])
 707 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 708
 709 dnl
 710 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 711 dnl More later: fbdev, ...
 712 dnl
 713 default_driver="xlib"
 714
 715 case "$host_os" in
 716 linux*)
 717     case "$host_cpu" in
 718     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 719     esac
 720     ;;
 721 *freebsd* | dragonfly* | *netbsd*)
 722     case "$host_cpu" in
 723     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 724     esac
 725     ;;
 726 esac
 727
 728 if test "x$enable_opengl" = xno; then
 729     default_driver="no"
 730 fi
 731
 732 AC_ARG_WITH([driver],
 733     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 734     [mesa_driver="$withval"],
 735     [mesa_driver=auto])
 736 dnl Check for valid option
 737 case "x$mesa_driver" in
 738 xxlib|xdri|xosmesa|xno)
 739     if test "x$enable_dri" != xauto -o \
 740             "x$enable_glx" != xauto -o \
 741             "x$enable_osmesa" != xauto -o \
 742             "x$enable_xlib_glx" != xauto; then
 743         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 744     fi
 745     ;;
 746 xauto)
 747     mesa_driver="$default_driver"
 748     ;;
 749 *)
 750     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 751     ;;
 752 esac
 753
 754 # map $mesa_driver to APIs
 755 if test "x$enable_dri" = xauto; then
 756     case "x$mesa_driver" in
 757     xdri) enable_dri=yes ;;
 758     *)    enable_dri=no ;;
 759     esac
 760 fi
 761
 762 if test "x$enable_glx" = xauto; then
 763     case "x$mesa_driver" in
 764     xdri|xxlib) enable_glx=yes ;;
 765     *)          enable_glx=no ;;
 766     esac
 767 fi
 768
 769 if test "x$enable_osmesa" = xauto; then
 770     case "x$mesa_driver" in
 771     xxlib|xosmesa) enable_osmesa=yes ;;
 772     *)             enable_osmesa=no ;;
 773     esac
 774 fi
 775
 776 if test "x$enable_xlib_glx" = xauto; then
 777     case "x$mesa_driver" in
 778     xxlib) enable_xlib_glx=yes ;;
 779     *)     enable_xlib_glx=no ;;
 780     esac
 781 fi
 782
 783 if test "x$enable_glx" = xno; then
 784     enable_xlib_glx=no
 785 fi
 786
 787 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 788
 789 dnl
 790 dnl Driver specific build directories
 791 dnl
 792
 793 dnl this variable will be prepended to SRC_DIRS and is not exported
 794 CORE_DIRS=""
 795
 796 SRC_DIRS=""
 797 GLU_DIRS="sgi"
 798 GALLIUM_DIRS="auxiliary drivers state_trackers"
 799 GALLIUM_TARGET_DIRS=""
 800 GALLIUM_WINSYS_DIRS="sw"
 801 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 802 GALLIUM_STATE_TRACKERS_DIRS=""
 803
 804 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 805 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 806 x*yes*)
 807     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 808     ;;
 809 esac
 810
 811 # build glapi if OpenGL is enabled
 812 if test "x$enable_opengl" = xyes; then
 813     CORE_DIRS="$CORE_DIRS mapi/glapi"
 814 fi
 815
 816 # build es1api if OpenGL ES 1.x is enabled
 817 if test "x$enable_gles1" = xyes; then
 818     CORE_DIRS="$CORE_DIRS mapi/es1api"
 819 fi
 820
 821 # build es2api if OpenGL ES 2.x is enabled
 822 if test "x$enable_gles2" = xyes; then
 823     CORE_DIRS="$CORE_DIRS mapi/es2api"
 824 fi
 825
 826 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 827 case "x$enable_opengl$enable_gles1$enable_gles2" in
 828 x*yes*)
 829     CORE_DIRS="$CORE_DIRS glsl mesa"
 830     ;;
 831 esac
 832
 833 case "x$enable_glx$enable_xlib_glx" in
 834 xyesyes)
 835     DRIVER_DIRS="$DRIVER_DIRS x11"
 836     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 837     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 838     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 839     HAVE_WINSYS_XLIB="yes"
 840     ;;
 841 xyesno)
 842     # DRI-based GLX
 843     SRC_DIRS="$SRC_DIRS glx"
 844     ;;
 845 esac
 846
 847 if test "x$enable_dri" = xyes; then
 848     DRIVER_DIRS="$DRIVER_DIRS dri"
 849
 850     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 851     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 852     HAVE_ST_DRI="yes"
 853 fi
 854
 855 if test "x$enable_osmesa" = xyes; then
 856     # the empty space matters for osmesa... (see src/mesa/Makefile)
 857     if test -n "$DRIVER_DIRS"; then
 858         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 859     else
 860         DRIVER_DIRS="osmesa"
 861     fi
 862 fi
 863
 864 AC_SUBST([SRC_DIRS])
 865 AC_SUBST([GLU_DIRS])
 866 AC_SUBST([DRIVER_DIRS])
 867 AC_SUBST([GALLIUM_DIRS])
 868 AC_SUBST([GALLIUM_TARGET_DIRS])
 869 AC_SUBST([GALLIUM_WINSYS_DIRS])
 870 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 871 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 872 AC_SUBST([MESA_LLVM])
 873
 874 # Check for libdrm
 875 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 876                   [have_libdrm=yes], [have_libdrm=no])
 877
 878 if test "x$enable_dri" = xyes; then
 879     # DRI must be shared, I think
 880     if test "$enable_static" = yes; then
 881         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 882     fi
 883
 884     # not a hard requirement as swrast does not depend on it
 885     if test "x$have_libdrm" = xyes; then
 886         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 887     fi
 888 fi
 889
 890 dnl
 891 dnl Find out if X is available. The variable have_x is set if libX11 is
 892 dnl found to mimic AC_PATH_XTRA.
 893 dnl
 894 if test -n "$PKG_CONFIG"; then
 895     AC_MSG_CHECKING([pkg-config files for X11 are available])
 896     PKG_CHECK_EXISTS([x11],[
 897         x11_pkgconfig=yes
 898         have_x=yes
 899         ],[
 900         x11_pkgconfig=no
 901     ])
 902     AC_MSG_RESULT([$x11_pkgconfig])
 903 else
 904     x11_pkgconfig=no
 905 fi
 906 dnl Use the autoconf macro if no pkg-config files
 907 if test "$x11_pkgconfig" = yes; then
 908     PKG_CHECK_MODULES([X11], [x11])
 909 else
 910     AC_PATH_XTRA
 911     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 912     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 913     AC_SUBST([X11_CFLAGS])
 914     AC_SUBST([X11_LIBS])
 915 fi
 916
 917 dnl Try to tell the user that the --x-* options are only used when
 918 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 919 m4_divert_once([HELP_BEGIN],
 920 [These options are only used when the X libraries cannot be found by the
 921 pkg-config utility.])
 922
 923 dnl We need X for xlib and dri, so bomb now if it's not found
 924 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 925     AC_MSG_ERROR([X11 development libraries needed for GLX])
 926 fi
 927
 928 if test "x$enable_glx" = xyes; then
 929     DEFINES="$DEFINES -DUSE_XCB"
 930 fi
 931
 932 dnl Direct rendering or just indirect rendering
 933 case "$host_os" in
 934 gnu*)
 935     dnl Disable by default on GNU/Hurd
 936     driglx_direct_default="no"
 937     ;;
 938 cygwin*)
 939     dnl Disable by default on cygwin
 940     driglx_direct_default="no"
 941     ;;
 942 *)
 943     driglx_direct_default="yes"
 944     ;;
 945 esac
 946 AC_ARG_ENABLE([driglx-direct],
 947     [AS_HELP_STRING([--disable-driglx-direct],
 948         [enable direct rendering in GLX and EGL for DRI \
 949             @<:@default=auto@:>@])],
 950     [driglx_direct="$enableval"],
 951     [driglx_direct="$driglx_direct_default"])
 952
 953 dnl
 954 dnl libGL configuration per driver
 955 dnl
 956 case "x$enable_glx$enable_xlib_glx" in
 957 xyesyes)
 958     # Xlib-based GLX
 959     if test "$x11_pkgconfig" = yes; then
 960         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 961         GL_PC_REQ_PRIV="x11 xext"
 962         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 963         GL_LIB_DEPS="$XLIBGL_LIBS"
 964     else
 965         # should check these...
 966         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 967         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 968         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 969         GL_PC_CFLAGS="$X11_INCLUDES"
 970     fi
 971     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 972     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 973     ;;
 974 xyesno)
 975     # DRI-based GLX
 976     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 977     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 978     if test x"$driglx_direct" = xyes; then
 979         if test "x$have_libdrm" != xyes; then
 980             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 981         fi
 982         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 983         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 984     fi
 985
 986     # find the DRI deps for libGL
 987     if test "$x11_pkgconfig" = yes; then
 988         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 989
 990         # add xf86vidmode if available
 991         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 992         if test "$HAVE_XF86VIDMODE" = yes ; then
 993             dri_modules="$dri_modules xxf86vm"
 994         fi
 995
 996         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 997         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 998         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 999         GL_LIB_DEPS="$DRIGL_LIBS"
1000     else
1001         # should check these...
1002         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1003         if test "x$HAVE_XF86VIDMODE" == xyes; then
1004            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1005         else
1006            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1007         fi
1008         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1009         GL_PC_CFLAGS="$X11_INCLUDES"
1010
1011         # XCB can only be used from pkg-config
1012         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1013         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1014         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1015         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1016     fi
1017
1018     # Check to see if the xcb-glx library is new enough to support
1019     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1020     # is released.
1021     save_CPPFLAGS="$CPPFLAGS"
1022     save_LDFLAGS="$LDFLAGS"
1023     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1024     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1025     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1026         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1027         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1028     CPPFLAGS="$save_CPPFLAGS"
1029     LDFLAGS="$save_LDFLAGS"
1030
1031     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1032         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1033     fi
1034
1035     # need DRM libs, -lpthread, etc.
1036     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1037     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1038     ;;
1039 esac
1040
1041 # This is outside the case (above) so that it is invoked even for non-GLX
1042 # builds.
1043 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1044     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1045 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1046
1047 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1048 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1049 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1050 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1051
1052 AC_SUBST([GL_LIB_DEPS])
1053 AC_SUBST([GL_PC_REQ_PRIV])
1054 AC_SUBST([GL_PC_LIB_PRIV])
1055 AC_SUBST([GL_PC_CFLAGS])
1056 AC_SUBST([DRI_PC_REQ_PRIV])
1057 AC_SUBST([GLESv1_CM_LIB_DEPS])
1058 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1059 AC_SUBST([GLESv2_LIB_DEPS])
1060 AC_SUBST([GLESv2_PC_LIB_PRIV])
1061
1062 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1063 AC_SUBST([GLAPI_LIB_DEPS])
1064
1065
1066 dnl Setup default DRI CFLAGS
1067 DRI_CFLAGS='$(CFLAGS)'
1068 DRI_CXXFLAGS='$(CXXFLAGS)'
1069 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1070 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1071
1072 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1073     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1074     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1075     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1076     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1077     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1078     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1079     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1080 fi
1081 AC_SUBST([DRICORE_LIBS])
1082 AC_SUBST([DRICORE_GLSL_LIBS])
1083 AC_SUBST([DRICORE_LIB_DEPS])
1084 AC_SUBST([DRI_CXXFLAGS])
1085 AC_SUBST([DRI_CFLAGS])
1086 AC_SUBST([MESA_MODULES])
1087
1088 AC_SUBST([HAVE_XF86VIDMODE])
1089
1090 dnl
1091 dnl More GLX setup
1092 dnl
1093 case "x$enable_glx$enable_xlib_glx" in
1094 xyesyes)
1095     DEFINES="$DEFINES -DUSE_XSHM"
1096     ;;
1097 xyesno)
1098     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1099     if test "x$driglx_direct" = xyes; then
1100         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1101     fi
1102     ;;
1103 esac
1104
1105 dnl
1106 dnl TLS detection
1107 dnl
1108
1109 AC_ARG_ENABLE([glx-tls],
1110     [AS_HELP_STRING([--enable-glx-tls],
1111         [enable TLS support in GLX @<:@default=disabled@:>@])],
1112     [GLX_USE_TLS="$enableval"],
1113     [GLX_USE_TLS=no])
1114 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1115
1116 AS_IF([test "x$GLX_USE_TLS" = xyes],
1117       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1118
1119 dnl
1120 dnl More DRI setup
1121 dnl
1122 dnl Directory for DRI drivers
1123 AC_ARG_WITH([dri-driverdir],
1124     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1125         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1126     [DRI_DRIVER_INSTALL_DIR="$withval"],
1127     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1128 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1129 dnl Extra search path for DRI drivers
1130 AC_ARG_WITH([dri-searchpath],
1131     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1132         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1133     [DRI_DRIVER_SEARCH_DIR="$withval"],
1134     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1135 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1136 dnl Which drivers to build - default is chosen by platform
1137 AC_ARG_WITH([dri-drivers],
1138     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1139         [comma delimited DRI drivers list, e.g.
1140         "swrast,i965,radeon" @<:@default=auto@:>@])],
1141     [with_dri_drivers="$withval"],
1142     [with_dri_drivers=yes])
1143 if test "x$with_dri_drivers" = x; then
1144     with_dri_drivers=no
1145 fi
1146
1147 dnl If $with_dri_drivers is yes, directories will be added through
1148 dnl platform checks
1149 DRI_DIRS=""
1150 case "$with_dri_drivers" in
1151 no) ;;
1152 yes)
1153     # classic DRI drivers require FEATURE_GL to build
1154     if test "x$enable_opengl" = xyes; then
1155         DRI_DIRS="yes"
1156     fi
1157     ;;
1158 *)
1159     # verify the requested driver directories exist
1160     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1161     for driver in $dri_drivers; do
1162         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1163             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1164     done
1165     DRI_DIRS="$dri_drivers"
1166     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1167         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1168     fi
1169     ;;
1170 esac
1171
1172 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1173 if test "x$enable_dri" = xyes; then
1174     # Platform specific settings and drivers to build
1175     case "$host_os" in
1176     linux*)
1177         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1178         DEFINES="$DEFINES -DHAVE_ALIAS"
1179
1180         case "$host_cpu" in
1181         x86_64)
1182             if test "x$DRI_DIRS" = "xyes"; then
1183                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1184             fi
1185             ;;
1186         powerpc*)
1187             # Build only the drivers for cards that exist on PowerPC.
1188             if test "x$DRI_DIRS" = "xyes"; then
1189                 DRI_DIRS="r200 radeon swrast"
1190             fi
1191             ;;
1192         sparc*)
1193             # Build only the drivers for cards that exist on sparc
1194             if test "x$DRI_DIRS" = "xyes"; then
1195                 DRI_DIRS="r200 radeon swrast"
1196             fi
1197             ;;
1198         esac
1199         ;;
1200     freebsd* | dragonfly* | *netbsd*)
1201         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1202         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1203
1204         if test "x$DRI_DIRS" = "xyes"; then
1205             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1206         fi
1207         ;;
1208     gnu*)
1209         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1210         DEFINES="$DEFINES -DHAVE_ALIAS"
1211         ;;
1212     solaris*)
1213         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1214         ;;
1215     cygwin*)
1216         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1217         if test "x$DRI_DIRS" = "xyes"; then
1218             DRI_DIRS="swrast"
1219         fi
1220         ;;
1221     esac
1222
1223     # default drivers
1224     if test "x$DRI_DIRS" = "xyes"; then
1225         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1226     fi
1227
1228     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1229
1230     # Check for expat
1231     if test "x$enable_dri" = xyes; then
1232         EXPAT_INCLUDES=""
1233         EXPAT_LIB=-lexpat
1234         AC_ARG_WITH([expat],
1235             [AS_HELP_STRING([--with-expat=DIR],
1236                 [expat install directory])],[
1237             EXPAT_INCLUDES="-I$withval/include"
1238             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1239             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1240             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1241             ])
1242         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1243         save_LIBS="$LIBS"
1244         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1245             [AC_MSG_ERROR([Expat required for DRI.])])
1246         LIBS="$save_LIBS"
1247     fi
1248
1249     # if we are building any dri driver other than swrast ...
1250     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1251         # ... libdrm is required
1252         if test "x$have_libdrm" != xyes; then
1253             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1254         fi
1255         # ... and build dricommon
1256         HAVE_COMMON_DRI=yes
1257     fi
1258
1259     # put all the necessary libs together
1260     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1261 fi
1262 AC_SUBST([DRI_DIRS])
1263 AC_SUBST([EXPAT_INCLUDES])
1264 AC_SUBST([DRI_LIB_DEPS])
1265
1266 case $DRI_DIRS in
1267 *i915*|*i965*)
1268     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1269
1270     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1271         case $d in
1272         i915)
1273             HAVE_I915_DRI=yes;
1274             ;;
1275         i965)
1276             HAVE_I965_DRI=yes;
1277             ;;
1278         esac
1279     done
1280
1281     ;;
1282 esac
1283
1284 case $DRI_DIRS in
1285 *nouveau*)
1286     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1287     HAVE_NOUVEAU_DRI=yes;
1288     ;;
1289 esac
1290
1291 case $DRI_DIRS in
1292 *radeon*|*r200*)
1293     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1294
1295     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1296         case $d in
1297         radeon)
1298             HAVE_RADEON_DRI=yes;
1299             ;;
1300         r200)
1301             HAVE_R200_DRI=yes;
1302             ;;
1303         esac
1304     done
1305
1306     ;;
1307 esac
1308
1309 case $DRI_DIRS in
1310 *swrast*)
1311     HAVE_SWRAST_DRI=yes;
1312     ;;
1313 esac
1314
1315 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1316 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1317 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1318 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1319 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1320 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1321 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1322
1323 dnl
1324 dnl OSMesa configuration
1325 dnl
1326
1327 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1328 AC_ARG_WITH([osmesa-bits],
1329     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1330         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1331     [osmesa_bits="$withval"],
1332     [osmesa_bits=8])
1333 if test "x$osmesa_bits" != x8; then
1334     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1335         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1336         osmesa_bits=8
1337     fi
1338 fi
1339 case "x$osmesa_bits" in
1340 x8)
1341     OSMESA_LIB="${OSMESA_LIB}"
1342     ;;
1343 x16|x32)
1344     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1345     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1346     ;;
1347 *)
1348     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1349     ;;
1350 esac
1351
1352 if test "x$enable_osmesa" = xyes; then
1353     # only link libraries with osmesa if shared
1354     if test "$enable_static" = no; then
1355         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1356     else
1357         OSMESA_LIB_DEPS=""
1358     fi
1359     OSMESA_MESA_DEPS=""
1360     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1361 fi
1362 AC_SUBST([OSMESA_LIB_DEPS])
1363 AC_SUBST([OSMESA_MESA_DEPS])
1364 AC_SUBST([OSMESA_PC_REQ])
1365 AC_SUBST([OSMESA_PC_LIB_PRIV])
1366
1367 dnl
1368 dnl gbm configuration
1369 dnl
1370 if test "x$enable_gbm" = xauto; then
1371     case "$with_egl_platforms" in
1372         *drm*)
1373             enable_gbm=yes ;;
1374          *)
1375             enable_gbm=no ;;
1376     esac
1377 fi
1378 if test "x$enable_gbm" = xyes; then
1379     SRC_DIRS="$SRC_DIRS gbm"
1380
1381     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1382                       AC_MSG_ERROR([gbm needs udev]))
1383
1384     if test "x$enable_dri" = xyes; then
1385         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1386         if test "$SHARED_GLAPI" -eq 0; then
1387             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1388         fi
1389     fi
1390 fi
1391 GBM_PC_REQ_PRIV="libudev"
1392 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1393 AC_SUBST([GBM_PC_REQ_PRIV])
1394 AC_SUBST([GBM_PC_LIB_PRIV])
1395
1396 dnl
1397 dnl EGL configuration
1398 dnl
1399 EGL_CLIENT_APIS=""
1400
1401 if test "x$enable_egl" = xyes; then
1402     SRC_DIRS="$SRC_DIRS egl"
1403     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1404
1405     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1406
1407     if test "$enable_static" != yes; then
1408         # build egl_glx when libGL is built
1409         if test "x$enable_glx" = xyes; then
1410             HAVE_EGL_DRIVER_GLX=1
1411         fi
1412
1413         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1414                           [have_libudev=yes],[have_libudev=no])
1415         if test "$have_libudev" = yes; then
1416             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1417         fi
1418         if test "x$enable_dri" = xyes; then
1419             # build egl_dri2 when xcb-dri2 is available
1420             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1421                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1422             if test "$have_xcb_dri2" = yes; then
1423                 HAVE_EGL_DRIVER_DRI2=1
1424                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1425                 save_LIBS="$LIBS"
1426                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1427                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1428                 LIBS="$save_LIBS"
1429             fi
1430         fi
1431
1432     fi
1433 fi
1434 AC_SUBST([EGL_LIB_DEPS])
1435
1436 dnl
1437 dnl EGL Gallium configuration
1438 dnl
1439 if test "x$enable_gallium_egl" = xyes; then
1440     if test "x$with_gallium_drivers" = x; then
1441         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1442     fi
1443     if test "x$enable_egl" = xno; then
1444         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1445     fi
1446     if test "x$have_libdrm" != xyes; then
1447         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1448     fi
1449
1450     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1451     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1452     HAVE_ST_EGL="yes"
1453 fi
1454
1455 dnl
1456 dnl gbm Gallium configuration
1457 dnl
1458 if test "x$enable_gallium_gbm" = xauto; then
1459     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1460         yesyesyes*drm*)
1461             enable_gallium_gbm=yes ;;
1462          *)
1463             enable_gallium_gbm=no ;;
1464     esac
1465 fi
1466 if test "x$enable_gallium_gbm" = xyes; then
1467     if test "x$with_gallium_drivers" = x; then
1468         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1469     fi
1470     if test "x$enable_gbm" = xno; then
1471         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1472     fi
1473     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1474     if test "x$enable_dri" = xno; then
1475         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1476     fi
1477
1478     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1479     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1480     HAVE_ST_GBM="yes"
1481 fi
1482
1483 dnl
1484 dnl X.Org DDX configuration
1485 dnl
1486 if test "x$enable_xorg" = xyes; then
1487     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1488     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1489     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1490     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1491         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1492         HAVE_XEXTPROTO_71="no")
1493     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1494     HAVE_ST_XORG=yes
1495 fi
1496
1497 dnl
1498 dnl XA configuration
1499 dnl
1500 if test "x$enable_xa" = xyes; then
1501 AC_PROG_AWK
1502 AC_PROG_GREP
1503 AC_CHECK_PROG(NM, nm, "nm")
1504 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1505 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1506 enable_xa=no
1507 fi
1508 fi
1509 if test "x$enable_xa" = xyes; then
1510     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1511     HAVE_ST_XA=yes
1512     AC_SUBST(AWK)
1513     AC_SUBST(GREP)
1514     AC_SUBST(NM)
1515 fi
1516
1517 dnl
1518 dnl OpenVG configuration
1519 dnl
1520 VG_LIB_DEPS=""
1521
1522 if test "x$enable_openvg" = xyes; then
1523     if test "x$enable_egl" = xno; then
1524         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1525     fi
1526     if test "x$with_gallium_drivers" = x; then
1527         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1528     fi
1529     if test "x$enable_gallium_egl" = xno; then
1530         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1531     fi
1532
1533     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1534     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1535     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1536     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1537     HAVE_ST_VEGA=yes
1538 fi
1539
1540 dnl
1541 dnl D3D1X configuration
1542 dnl
1543
1544 if test "x$enable_d3d1x" = xyes; then
1545     if test "x$with_gallium_drivers" = x; then
1546         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1547     fi
1548
1549     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1550     HAVE_ST_D3D1X=yes
1551 fi
1552
1553 dnl
1554 dnl Gallium G3DVL configuration
1555 dnl
1556 AC_ARG_ENABLE([gallium-g3dvl],
1557     [AS_HELP_STRING([--enable-gallium-g3dvl],
1558         [build gallium g3dvl @<:@default=disabled@:>@])],
1559     [enable_gallium_g3dvl="$enableval"],
1560     [enable_gallium_g3dvl=no])
1561 if test "x$enable_gallium_g3dvl" = xyes; then
1562     if test "x$with_gallium_drivers" = x; then
1563         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1564     fi
1565
1566     if test "x$enable_xvmc" = xauto; then
1567         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1568     fi
1569
1570     if test "x$enable_vdpau" = xauto; then
1571         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1572     fi
1573
1574     if test "x$enable_va" = xauto; then
1575         #don't enable vaapi state tracker even if package exists
1576         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1577         enable_va=no
1578     fi
1579 fi
1580
1581 if test "x$enable_xvmc" = xyes; then
1582     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1583     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1584     HAVE_ST_XVMC="yes"
1585 fi
1586
1587 if test "x$enable_vdpau" = xyes; then
1588     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1589     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1590     HAVE_ST_VDPAU="yes"
1591 fi
1592
1593 if test "x$enable_va" = xyes; then
1594     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1595     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1596     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1597     HAVE_ST_VA="yes"
1598 fi
1599
1600 dnl
1601 dnl GLU configuration
1602 dnl
1603 AC_ARG_ENABLE([glu],
1604     [AS_HELP_STRING([--disable-glu],
1605         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1606     [enable_glu="$enableval"],
1607     [enable_glu=yes])
1608
1609 if test "x$enable_glu" = xyes; then
1610     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1611         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1612         enable_glu=no
1613     fi
1614 fi
1615
1616 if test "x$enable_glu" = xyes; then
1617     SRC_DIRS="$SRC_DIRS glu"
1618
1619     if test "x$enable_glx" = xno; then
1620         # Link libGLU to libOSMesa instead of libGL
1621         GLU_LIB_DEPS=""
1622         GLU_PC_REQ="osmesa"
1623         if test "$enable_static" = no; then
1624             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1625         else
1626             GLU_MESA_DEPS=""
1627         fi
1628     else
1629         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1630         GLU_PC_REQ="gl"
1631         GLU_PC_LIB_PRIV="-lm"
1632         if test "$enable_static" = no; then
1633             GLU_LIB_DEPS="-lm"
1634             GLU_MESA_DEPS='-l$(GL_LIB)'
1635         else
1636             GLU_LIB_DEPS=""
1637             GLU_MESA_DEPS=""
1638         fi
1639     fi
1640 fi
1641 if test "$enable_static" = no; then
1642     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1643 fi
1644 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1645 AC_SUBST([GLU_LIB_DEPS])
1646 AC_SUBST([GLU_MESA_DEPS])
1647 AC_SUBST([GLU_PC_REQ])
1648 AC_SUBST([GLU_PC_REQ_PRIV])
1649 AC_SUBST([GLU_PC_LIB_PRIV])
1650 AC_SUBST([GLU_PC_CFLAGS])
1651
1652 AC_SUBST([PROGRAM_DIRS])
1653
1654 dnl
1655 dnl Gallium configuration
1656 dnl
1657 if test "x$with_gallium_drivers" != x; then
1658     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1659 fi
1660
1661 AC_SUBST([LLVM_CFLAGS])
1662 AC_SUBST([LLVM_LIBS])
1663 AC_SUBST([LLVM_LDFLAGS])
1664 AC_SUBST([LLVM_VERSION])
1665
1666 case "x$enable_opengl$enable_gles1$enable_gles2" in
1667 x*yes*)
1668     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1669     ;;
1670 esac
1671
1672 AC_SUBST([VG_LIB_DEPS])
1673 AC_SUBST([EGL_CLIENT_APIS])
1674
1675 AC_ARG_WITH([egl-platforms],
1676     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1677         [comma delimited native platforms libEGL supports, e.g.
1678         "x11,drm" @<:@default=auto@:>@])],
1679     [with_egl_platforms="$withval"],
1680     [if test "x$enable_egl" = xyes; then
1681         with_egl_platforms="x11"
1682     else
1683         with_egl_platforms=""
1684     fi])
1685
1686 EGL_PLATFORMS=""
1687
1688 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1689     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1690 fi
1691
1692 # verify the requested driver directories exist
1693 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1694 for plat in $egl_platforms; do
1695         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1696             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1697         if test "$plat" = "fbdev"; then
1698                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1699         fi
1700         if test "$plat" = "null"; then
1701                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1702         fi
1703         if test "$plat" = "wayland"; then
1704                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1705                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1706                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1707
1708                 m4_ifdef([WAYLAND_SCANNER_RULES],
1709                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1710         fi
1711         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1712                 AC_MSG_ERROR([EGL platform drm needs gbm])
1713         fi
1714         case "$plat$have_libudev" in
1715                 waylandno|drmno)
1716                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1717         esac
1718 done
1719
1720 # libEGL wants to default to the first platform specified in
1721 # ./configure.  parse that here.
1722 if test "x$egl_platforms" != "x"; then
1723     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1724     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1725 else
1726     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1727 fi
1728
1729 EGL_PLATFORMS="$egl_platforms"
1730
1731 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1732 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1733 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1734 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1735 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1736
1737 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1738 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1739
1740 AC_SUBST([EGL_NATIVE_PLATFORM])
1741 AC_SUBST([EGL_PLATFORMS])
1742 AC_SUBST([EGL_CFLAGS])
1743
1744 AC_ARG_WITH([egl-driver-dir],
1745     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1746                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1747     [EGL_DRIVER_INSTALL_DIR="$withval"],
1748     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1749 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1750
1751 AC_ARG_WITH([xorg-driver-dir],
1752     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1753                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1754     [XORG_DRIVER_INSTALL_DIR="$withval"],
1755     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1756 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1757
1758 AC_ARG_WITH([max-width],
1759     [AS_HELP_STRING([--with-max-width=N],
1760                     [Maximum framebuffer width (4096)])],
1761     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1762      AS_IF([test "${withval}" -gt "4096"],
1763            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1764 )
1765 AC_ARG_WITH([max-height],
1766     [AS_HELP_STRING([--with-max-height=N],
1767                     [Maximum framebuffer height (4096)])],
1768     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1769      AS_IF([test "${withval}" -gt "4096"],
1770            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1771 )
1772
1773 dnl
1774 dnl Gallium LLVM
1775 dnl
1776 AC_ARG_ENABLE([gallium-llvm],
1777     [AS_HELP_STRING([--enable-gallium-llvm],
1778         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1779     [enable_gallium_llvm="$enableval"],
1780     [enable_gallium_llvm=auto])
1781 if test "x$with_gallium_drivers" = x; then
1782     enable_gallium_llvm=no
1783 fi
1784 if test "x$enable_gallium_llvm" = xauto; then
1785     case "$host_cpu" in
1786     i*86|x86_64) enable_gallium_llvm=yes;;
1787     esac
1788 fi
1789 if test "x$enable_gallium_llvm" = xyes; then
1790     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1791
1792     if test "x$LLVM_CONFIG" != xno; then
1793         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1794         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1795         LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1796
1797         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1798         DEFINES="$DEFINES -D__STDC_CONSTANT_MACROS"
1799         MESA_LLVM=1
1800     else
1801         MESA_LLVM=0
1802     fi
1803 else
1804     MESA_LLVM=0
1805 fi
1806
1807 dnl Directory for VDPAU libs
1808 AC_ARG_WITH([vdpau-libdir],
1809     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1810         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1811     [VDPAU_LIB_INSTALL_DIR="$withval"],
1812     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1813 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1814
1815 dnl Directory for VA libs
1816 AC_ARG_WITH([va-libdir],
1817     [AS_HELP_STRING([--with-va-libdir=DIR],
1818         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1819     [VA_LIB_INSTALL_DIR="$withval"],
1820     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1821 AC_SUBST([VA_LIB_INSTALL_DIR])
1822
1823 dnl
1824 dnl Gallium helper functions
1825 dnl
1826 gallium_check_st() {
1827     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1828          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1829          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1830          if test "x$have_libdrm" != xyes; then
1831             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1832          fi
1833          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1834     fi
1835     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1836          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1837     fi
1838     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1839          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1840     fi
1841     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1842          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1843     fi
1844     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1845          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1846          NEED_G3DVL_DRI="yes"
1847     fi
1848     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1849          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1850          NEED_G3DVL_DRI="yes"
1851     fi
1852     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1853          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1854          NEED_G3DVL_DRI="yes"
1855     fi
1856 }
1857
1858 gallium_require_llvm() {
1859     if test "x$MESA_LLVM" = x0; then
1860         case "$host_cpu" in
1861         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1862         esac
1863     fi
1864 }
1865
1866 dnl Gallium drivers
1867 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1868 if test "x$with_gallium_drivers" != x; then
1869     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1870     for driver in $gallium_drivers; do
1871         case "x$driver" in
1872         xsvga)
1873             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1874             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1875             ;;
1876         xi915)
1877             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1878             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1879             if test "x$MESA_LLVM" = x1; then
1880                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1881             fi
1882             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1883             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1884             ;;
1885         xr300)
1886             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1887             gallium_require_llvm "Gallium R300"
1888             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1889             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1890             ;;
1891         xr600)
1892             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1893             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1894             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1895             ;;
1896         xnouveau)
1897             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1898             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1899             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1900             ;;
1901         xswrast)
1902             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1903             if test "x$MESA_LLVM" = x1; then
1904                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1905             fi
1906
1907             if test "x$HAVE_ST_DRI" = xyes; then
1908                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1909             fi
1910             if test "x$HAVE_ST_VDPAU" = xyes; then
1911                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1912             fi
1913             if test "x$HAVE_ST_XVMC" = xyes; then
1914                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1915             fi
1916             if test "x$HAVE_ST_VA" = xyes; then
1917                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1918             fi
1919             if test "x$HAVE_ST_VDPAU" = xyes ||
1920                test "x$HAVE_ST_XVMC" = xyes ||
1921                test "x$HAVE_ST_VA" = xyes; then
1922                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1923                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1924                fi
1925             fi
1926             ;;
1927         *)
1928             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1929             ;;
1930         esac
1931     done
1932 fi
1933
1934 if test "x$NEED_G3DVL_DRI" = xyes; then
1935     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS g3dvl/dri"
1936 fi
1937
1938 dnl prepend CORE_DIRS to SRC_DIRS
1939 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1940
1941 dnl Restore LDFLAGS and CPPFLAGS
1942 LDFLAGS="$_SAVE_LDFLAGS"
1943 CPPFLAGS="$_SAVE_CPPFLAGS"
1944
1945 dnl Add user CFLAGS and CXXFLAGS
1946 CFLAGS="$CFLAGS $USER_CFLAGS"
1947 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1948
1949 dnl Substitute the config
1950 AC_CONFIG_FILES([configs/autoconf
1951                 src/gallium/drivers/r300/Makefile
1952                 src/gbm/Makefile
1953                 src/gbm/main/gbm.pc
1954                 src/egl/drivers/Makefile
1955                 src/egl/drivers/dri2/Makefile
1956                 src/egl/drivers/glx/Makefile
1957                 src/egl/main/Makefile
1958                 src/egl/main/egl.pc
1959                 src/egl/wayland/Makefile
1960                 src/egl/wayland/wayland-egl/Makefile
1961                 src/egl/wayland/wayland-egl/wayland-egl.pc
1962                 src/egl/wayland/wayland-drm/Makefile
1963                 src/glx/Makefile
1964                 src/mesa/drivers/dri/dri.pc
1965                 src/mesa/drivers/dri/Makefile
1966                 src/mesa/drivers/dri/common/Makefile
1967                 src/mesa/drivers/dri/i915/Makefile
1968                 src/mesa/drivers/dri/i965/Makefile
1969                 src/mesa/drivers/dri/nouveau/Makefile
1970                 src/mesa/drivers/dri/r200/Makefile
1971                 src/mesa/drivers/dri/radeon/Makefile
1972                 src/mesa/drivers/dri/swrast/Makefile
1973                 tests/Makefile
1974                 tests/glx/Makefile])
1975
1976 dnl Replace the configs/current symlink
1977 AC_CONFIG_COMMANDS([configs],[
1978 if test -f configs/current || test -L configs/current; then
1979     rm -f configs/current
1980 fi
1981 ln -s autoconf configs/current
1982 ])
1983
1984 dnl Sort the dirs alphabetically
1985 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1986 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1987 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1988 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1989
1990 AC_OUTPUT
1991
1992 dnl
1993 dnl Output some configuration info for the user
1994 dnl
1995 echo ""
1996 echo "        prefix:          $prefix"
1997 echo "        exec_prefix:     $exec_prefix"
1998 echo "        libdir:          $libdir"
1999 echo "        includedir:      $includedir"
2000
2001 dnl API info
2002 echo ""
2003 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2004 echo "        OpenVG:          $enable_openvg"
2005
2006 dnl Driver info
2007 echo ""
2008 if test "x$enable_osmesa" != xno; then
2009         echo "        OSMesa:          lib$OSMESA_LIB"
2010 else
2011         echo "        OSMesa:          no"
2012 fi
2013
2014 if test "x$enable_dri" != xno; then
2015         # cleanup the drivers var
2016         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2017         if test "x$DRI_DIRS" = x; then
2018             echo "        DRI drivers:     no"
2019         else
2020             echo "        DRI drivers:     $dri_dirs"
2021         fi
2022         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2023 fi
2024
2025 case "x$enable_glx$enable_xlib_glx" in
2026 xyesyes)
2027     echo "        GLX:             Xlib-based"
2028     ;;
2029 xyesno)
2030     echo "        GLX:             DRI-based"
2031     ;;
2032 *)
2033     echo "        GLX:             $enable_glx"
2034     ;;
2035 esac
2036
2037 echo ""
2038 echo "        GLU:             $enable_glu"
2039
2040 dnl EGL
2041 echo ""
2042 echo "        EGL:             $enable_egl"
2043 if test "$enable_egl" = yes; then
2044     echo "        EGL platforms:   $EGL_PLATFORMS"
2045
2046     egl_drivers=""
2047     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2048         egl_drivers="$egl_drivers builtin:egl_glx"
2049     fi
2050     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2051         egl_drivers="$egl_drivers builtin:egl_dri2"
2052     fi
2053
2054     if test "x$HAVE_ST_EGL" = xyes; then
2055         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2056         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2057     else
2058         echo "        EGL drivers:    $egl_drivers"
2059     fi
2060 fi
2061
2062 echo ""
2063 if test "x$MESA_LLVM" = x1; then
2064     echo "        llvm:            yes"
2065     echo "        llvm-config:     $LLVM_CONFIG"
2066     echo "        llvm-version:    $LLVM_VERSION"
2067 else
2068     echo "        llvm:            no"
2069 fi
2070
2071 echo ""
2072 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2073     echo "        Gallium:         yes"
2074     echo "        Gallium dirs:    $GALLIUM_DIRS"
2075     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2076     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2077     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2078     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2079 else
2080     echo "        Gallium:         no"
2081 fi
2082
2083
2084 dnl Libraries
2085 echo ""
2086 echo "        Shared libs:     $enable_shared"
2087 echo "        Static libs:     $enable_static"
2088
2089 dnl Compiler options
2090 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2091 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2092     $SED 's/^ *//;s/  */ /;s/ *$//'`
2093 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2094     $SED 's/^ *//;s/  */ /;s/ *$//'`
2095 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2096 echo ""
2097 echo "        CFLAGS:          $cflags"
2098 echo "        CXXFLAGS:        $cxxflags"
2099 echo "        Macros:          $defines"
2100 echo ""
2101 echo "        PYTHON2:         $PYTHON2"
2102
2103 echo ""
2104 echo "        Run '${MAKE-make}' to build Mesa"
2105 echo ""