configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports garbage collection
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 323 AC_MSG_CHECKING([whether ld supports --gc-sections])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         GC_SECTIONS="-Wl,--gc-sections";],
 328     [AC_MSG_RESULT([no])
 329         GC_SECTIONS="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([GC_SECTIONS])
 333
 334 dnl
 335 dnl compatibility symlinks
 336 dnl
 337 case "$host_os" in
 338 linux* )
 339     HAVE_COMPAT_SYMLINKS=yes ;;
 340 * )
 341     HAVE_COMPAT_SYMLINKS=no ;;
 342 esac
 343
 344 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 345
 346 dnl
 347 dnl library names
 348 dnl
 349 case "$host_os" in
 350 darwin* )
 351     LIB_EXT='dylib' ;;
 352 cygwin* )
 353     LIB_EXT='dll' ;;
 354 aix* )
 355     LIB_EXT='a' ;;
 356 * )
 357     LIB_EXT='so' ;;
 358 esac
 359
 360 AC_SUBST([LIB_EXT])
 361
 362 AC_ARG_WITH([gl-lib-name],
 363   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 364     [specify GL library name @<:@default=GL@:>@])],
 365   [GL_LIB=$withval],
 366   [GL_LIB=GL])
 367 AC_ARG_WITH([osmesa-lib-name],
 368   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 369     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 370   [OSMESA_LIB=$withval],
 371   [OSMESA_LIB=OSMesa])
 372 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 373 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 374
 375 dnl
 376 dnl Mangled Mesa support
 377 dnl
 378 AC_ARG_ENABLE([mangling],
 379   [AS_HELP_STRING([--enable-mangling],
 380     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 381   [enable_mangling="${enableval}"],
 382   [enable_mangling=no]
 383 )
 384 if test "x${enable_mangling}" = "xyes" ; then
 385   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 386   GL_LIB="Mangled${GL_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([OSMESA_LIB])
 391
 392 dnl
 393 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 394 dnl
 395 AC_ARG_ENABLE([texture-float],
 396     [AS_HELP_STRING([--enable-texture-float],
 397         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 398     [enable_texture_float="$enableval"],
 399     [enable_texture_float=no]
 400 )
 401 if test "x$enable_texture_float" = xyes; then
 402     AC_MSG_WARN([Floating-point textures enabled.])
 403     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 404     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 405 fi
 406
 407 dnl
 408 dnl Arch/platform-specific settings
 409 dnl
 410 AC_ARG_ENABLE([asm],
 411     [AS_HELP_STRING([--disable-asm],
 412         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 413     [enable_asm="$enableval"],
 414     [enable_asm=yes]
 415 )
 416 asm_arch=""
 417 AC_MSG_CHECKING([whether to enable assembly])
 418 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 419 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 420 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 421     case "$host_cpu" in
 422     i?86 | x86_64 | amd64)
 423         enable_asm=no
 424         AC_MSG_RESULT([no, cross compiling])
 425         ;;
 426     esac
 427 fi
 428 # check for supported arches
 429 if test "x$enable_asm" = xyes; then
 430     case "$host_cpu" in
 431     i?86)
 432         case "$host_os" in
 433         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 434             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 435             ;;
 436         gnu*)
 437             asm_arch=x86
 438             ;;
 439         esac
 440         ;;
 441     x86_64|amd64)
 442         case "$host_os" in
 443         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 444             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 445             ;;
 446         esac
 447         ;;
 448     sparc*)
 449         case "$host_os" in
 450         linux*)
 451             asm_arch=sparc
 452             ;;
 453         esac
 454         ;;
 455     esac
 456
 457     case "$asm_arch" in
 458     x86)
 459         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 460         AC_MSG_RESULT([yes, x86])
 461         ;;
 462     x86_64|amd64)
 463         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 464         AC_MSG_RESULT([yes, x86_64])
 465         ;;
 466     sparc)
 467         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 468         AC_MSG_RESULT([yes, sparc])
 469         ;;
 470     *)
 471         AC_MSG_RESULT([no, platform not supported])
 472         ;;
 473     esac
 474 fi
 475
 476 dnl Check to see if dlopen is in default libraries (like Solaris, which
 477 dnl has it in libc), or if libdl is needed to get it.
 478 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 479     [AC_CHECK_LIB([dl], [dlopen],
 480        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 481 AC_SUBST([DLOPEN_LIBS])
 482
 483 dnl Check if that library also has dladdr
 484 save_LDFLAGS="$LDFLAGS"
 485 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 486 AC_CHECK_FUNCS([dladdr])
 487 LDFLAGS="$save_LDFLAGS"
 488
 489 case "$host_os" in
 490 darwin*|mingw*)
 491     ;;
 492 *)
 493     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 494                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 495                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 496     AC_SUBST([CLOCK_LIB])
 497     ;;
 498 esac
 499
 500 dnl See if posix_memalign is available
 501 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 502
 503 dnl Check for pthreads
 504 AX_PTHREAD
 505 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 506 dnl to -pthread, which causes problems if we need -lpthread to appear in
 507 dnl pkgconfig files.
 508 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 509
 510 dnl SELinux awareness.
 511 AC_ARG_ENABLE([selinux],
 512     [AS_HELP_STRING([--enable-selinux],
 513         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 514     [MESA_SELINUX="$enableval"],
 515     [MESA_SELINUX=no])
 516 if test "x$enable_selinux" = "xyes"; then
 517     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 518         [AC_CHECK_HEADER([selinux/selinux.h],[],
 519                          [AC_MSG_ERROR([SELinux headers not found])])
 520          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 521                       [AC_MSG_ERROR([SELinux library not found])])
 522          SELINUX_LIBS="-lselinux"])
 523     DEFINES="$DEFINES -DMESA_SELINUX"
 524 fi
 525 AC_SUBST([SELINUX_CFLAGS])
 526 AC_SUBST([SELINUX_LIBS])
 527
 528 dnl Options for APIs
 529 AC_ARG_ENABLE([opengl],
 530     [AS_HELP_STRING([--disable-opengl],
 531         [disable support for standard OpenGL API @<:@default=no@:>@])],
 532     [enable_opengl="$enableval"],
 533     [enable_opengl=yes])
 534 AC_ARG_ENABLE([gles1],
 535     [AS_HELP_STRING([--enable-gles1],
 536         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 537     [enable_gles1="$enableval"],
 538     [enable_gles1=no])
 539 AC_ARG_ENABLE([gles2],
 540     [AS_HELP_STRING([--enable-gles2],
 541         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 542     [enable_gles2="$enableval"],
 543     [enable_gles2=no])
 544 AC_ARG_ENABLE([openvg],
 545     [AS_HELP_STRING([--enable-openvg],
 546         [enable support for OpenVG API @<:@default=no@:>@])],
 547     [enable_openvg="$enableval"],
 548     [enable_openvg=no])
 549
 550 AC_ARG_ENABLE([dri],
 551     [AS_HELP_STRING([--enable-dri],
 552         [enable DRI modules @<:@default=enabled@:>@])],
 553     [enable_dri="$enableval"],
 554     [enable_dri=yes])
 555
 556 case "$host_os" in
 557 linux*)
 558     dri3_default=yes
 559     ;;
 560 *)
 561     dri3_default=no
 562     ;;
 563 esac
 564 AC_ARG_ENABLE([dri3],
 565     [AS_HELP_STRING([--enable-dri3],
 566         [enable DRI3 @<:@default=auto@:>@])],
 567     [enable_dri3="$enableval"],
 568     [enable_dri3="$dri3_default"])
 569 AC_ARG_ENABLE([glx],
 570     [AS_HELP_STRING([--enable-glx],
 571         [enable GLX library @<:@default=enabled@:>@])],
 572     [enable_glx="$enableval"],
 573     [enable_glx=yes])
 574 AC_ARG_ENABLE([osmesa],
 575     [AS_HELP_STRING([--enable-osmesa],
 576         [enable OSMesa library @<:@default=disabled@:>@])],
 577     [enable_osmesa="$enableval"],
 578     [enable_osmesa=no])
 579 AC_ARG_ENABLE([gallium-osmesa],
 580     [AS_HELP_STRING([--enable-gallium-osmesa],
 581         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 582     [enable_gallium_osmesa="$enableval"],
 583     [enable_gallium_osmesa=no])
 584 AC_ARG_ENABLE([egl],
 585     [AS_HELP_STRING([--disable-egl],
 586         [disable EGL library @<:@default=enabled@:>@])],
 587     [enable_egl="$enableval"],
 588     [enable_egl=yes])
 589
 590 AC_ARG_ENABLE([xa],
 591     [AS_HELP_STRING([--enable-xa],
 592         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 593     [enable_xa="$enableval"],
 594     [enable_xa=no])
 595 AC_ARG_ENABLE([gbm],
 596    [AS_HELP_STRING([--enable-gbm],
 597          [enable gbm library @<:@default=auto@:>@])],
 598    [enable_gbm="$enableval"],
 599    [enable_gbm=auto])
 600
 601 AC_ARG_ENABLE([xvmc],
 602    [AS_HELP_STRING([--enable-xvmc],
 603          [enable xvmc library @<:@default=auto@:>@])],
 604    [enable_xvmc="$enableval"],
 605    [enable_xvmc=no])
 606 AC_ARG_ENABLE([vdpau],
 607    [AS_HELP_STRING([--enable-vdpau],
 608          [enable vdpau library @<:@default=auto@:>@])],
 609    [enable_vdpau="$enableval"],
 610    [enable_vdpau=auto])
 611 AC_ARG_ENABLE([omx],
 612    [AS_HELP_STRING([--enable-omx],
 613          [enable OpenMAX library @<:@default=no@:>@])],
 614    [enable_omx="$enableval"],
 615    [enable_omx=no])
 616 AC_ARG_ENABLE([opencl],
 617    [AS_HELP_STRING([--enable-opencl],
 618          [enable OpenCL library @<:@default=no@:>@])],
 619    [enable_opencl="$enableval"],
 620    [enable_opencl=no])
 621 AC_ARG_ENABLE([opencl_icd],
 622    [AS_HELP_STRING([--enable-opencl-icd],
 623           [Build an OpenCL ICD library to be loaded by an ICD implementation
 624            @<:@default=no@:>@])],
 625     [enable_opencl_icd="$enableval"],
 626     [enable_opencl_icd=no])
 627 AC_ARG_ENABLE([xlib-glx],
 628     [AS_HELP_STRING([--enable-xlib-glx],
 629         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 630     [enable_xlib_glx="$enableval"],
 631     [enable_xlib_glx=no])
 632 AC_ARG_ENABLE([gallium-egl],
 633     [AS_HELP_STRING([--enable-gallium-egl],
 634         [enable optional EGL state tracker (not required
 635          for EGL support in Gallium with OpenGL and OpenGL ES)
 636          @<:@default=disable@:>@])],
 637     [enable_gallium_egl="$enableval"],
 638     [enable_gallium_egl=no])
 639 AC_ARG_ENABLE([gallium-gbm],
 640     [AS_HELP_STRING([--enable-gallium-gbm],
 641         [enable optional gbm state tracker (not required for
 642          gbm support in Gallium)
 643          @<:@default=auto@:>@])],
 644     [enable_gallium_gbm="$enableval"],
 645     [enable_gallium_gbm=auto])
 646
 647 AC_ARG_ENABLE([r600-llvm-compiler],
 648     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 649         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 650     [enable_r600_llvm="$enableval"],
 651     [enable_r600_llvm=no])
 652
 653 AC_ARG_ENABLE([gallium-tests],
 654     [AS_HELP_STRING([--enable-gallium-tests],
 655         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 656     [enable_gallium_tests="$enableval"],
 657     [enable_gallium_tests=no])
 658
 659 # Option for Gallium drivers
 660
 661 # Keep this in sync with the --with-gallium-drivers help string default value
 662 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 663
 664 AC_ARG_WITH([gallium-drivers],
 665     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 666         [comma delimited Gallium drivers list, e.g.
 667         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 668         @<:@default=r300,r600,svga,swrast@:>@])],
 669     [with_gallium_drivers="$withval"],
 670     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 671
 672 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 673 # here so that the script doesn't choke on an unknown driver name later.
 674 case "$with_gallium_drivers" in
 675     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 676     no) with_gallium_drivers='' ;;
 677 esac
 678
 679 if test "x$enable_opengl" = xno -a \
 680         "x$enable_gles1" = xno -a \
 681         "x$enable_gles2" = xno -a \
 682         "x$enable_openvg" = xno -a \
 683         "x$enable_xa" = xno -a \
 684         "x$enable_xvmc" = xno -a \
 685         "x$enable_vdpau" = xno -a \
 686         "x$enable_omx" = xno -a \
 687         "x$enable_opencl" = xno; then
 688     AC_MSG_ERROR([at least one API should be enabled])
 689 fi
 690
 691 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 692 if test "x$enable_opengl" = xno -a \
 693         "x$enable_gles1" = xyes; then
 694     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 695 fi
 696
 697 if test "x$enable_opengl" = xno -a \
 698         "x$enable_gles2" = xyes; then
 699     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 700 fi
 701
 702 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 703 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 704 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 705 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 706                                         "x$enable_gles1" = xyes -o \
 707                                         "x$enable_gles2" = xyes)
 708
 709 if test "x$enable_glx" = xno; then
 710     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 711     enable_xlib_glx=no
 712 fi
 713
 714 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 715     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 716 fi
 717
 718 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 719     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 720 fi
 721
 722 # Disable GLX if OpenGL is not enabled
 723 if test "x$enable_glx$enable_opengl" = xyesno; then
 724     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 725     enable_glx=no
 726 fi
 727
 728 # Disable GLX if DRI and Xlib-GLX are not enabled
 729 if test "x$enable_glx" = xyes -a \
 730         "x$enable_dri" = xno -a \
 731         "x$enable_xlib_glx" = xno; then
 732     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 733     enable_glx=no
 734 fi
 735
 736 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 737                                   "x$enable_dri" = xyes)
 738 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 739 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 740
 741 AC_ARG_ENABLE([shared-glapi],
 742     [AS_HELP_STRING([--enable-shared-glapi],
 743         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 744     [enable_shared_glapi="$enableval"],
 745     [enable_shared_glapi=yes])
 746
 747 case "x$enable_opengl$enable_gles1$enable_gles2" in
 748 x*yes*yes*)
 749     if test "x$enable_shared_glapi" = xno; then
 750         AC_MSG_ERROR([shared GLAPI required when building two or more of
 751                       the following APIs - opengl, gles1 gles2])
 752     fi
 753     ;;
 754 esac
 755
 756 # Building Xlib-GLX requires shared glapi to be disabled.
 757 if test "x$enable_xlib_glx" = xyes; then
 758     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 759     enable_shared_glapi=no
 760 fi
 761
 762 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 763
 764 dnl
 765 dnl Driver specific build directories
 766 dnl
 767 GALLIUM_TARGET_DIRS=""
 768 GALLIUM_WINSYS_DIRS="sw"
 769 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 770 GALLIUM_STATE_TRACKERS_DIRS=""
 771
 772 case "x$enable_glx$enable_xlib_glx" in
 773 xyesyes)
 774     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 775     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 776     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 777     NEED_WINSYS_XLIB="yes"
 778     ;;
 779 esac
 780
 781 if test "x$enable_dri" = xyes; then
 782     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 783     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 784 fi
 785
 786 if test "x$enable_gallium_osmesa" = xyes; then
 787     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 788         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 789     fi
 790     if test "x$enable_osmesa" = xyes; then
 791         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 792     fi
 793     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 794     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 795 fi
 796
 797 AC_SUBST([MESA_LLVM])
 798
 799 # Check for libdrm
 800 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 801                   [have_libdrm=yes], [have_libdrm=no])
 802 if test "x$have_libdrm" = xyes; then
 803         DEFINES="$DEFINES -DHAVE_LIBDRM"
 804 fi
 805
 806 case "$host_os" in
 807 linux*)
 808     need_libudev=yes ;;
 809 *)
 810     need_libudev=no ;;
 811 esac
 812
 813 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 814                   have_libudev=yes, have_libudev=no)
 815
 816 if test "x$enable_dri" = xyes; then
 817     if test "$enable_static" = yes; then
 818         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 819     fi
 820
 821     # not a hard requirement as swrast does not depend on it
 822     if test "x$have_libdrm" = xyes; then
 823         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 824     fi
 825 fi
 826
 827 dnl Direct rendering or just indirect rendering
 828 case "$host_os" in
 829 gnu*)
 830     dnl Disable by default on GNU/Hurd
 831     driglx_direct_default="no"
 832     ;;
 833 cygwin*)
 834     dnl Disable by default on cygwin
 835     driglx_direct_default="no"
 836     ;;
 837 *)
 838     driglx_direct_default="yes"
 839     ;;
 840 esac
 841 AC_ARG_ENABLE([driglx-direct],
 842     [AS_HELP_STRING([--disable-driglx-direct],
 843         [disable direct rendering in GLX and EGL for DRI \
 844             @<:@default=auto@:>@])],
 845     [driglx_direct="$enableval"],
 846     [driglx_direct="$driglx_direct_default"])
 847
 848 dnl
 849 dnl libGL configuration per driver
 850 dnl
 851 case "x$enable_glx$enable_xlib_glx" in
 852 xyesyes)
 853     # Xlib-based GLX
 854     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 855     GL_PC_REQ_PRIV="x11 xext"
 856     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 857     GL_LIB_DEPS="$XLIBGL_LIBS"
 858     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 859     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 860     ;;
 861 xyesno)
 862     # DRI-based GLX
 863     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 864     if test x"$driglx_direct" = xyes; then
 865         if test "x$have_libdrm" != xyes; then
 866             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 867         fi
 868         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 869         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 870         if test x"$enable_dri3" = xyes; then
 871             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 872             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 873         fi
 874     fi
 875
 876     # find the DRI deps for libGL
 877     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 878
 879     if test x"$enable_dri3" = xyes; then
 880         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 881     fi
 882
 883     # add xf86vidmode if available
 884     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 885     if test "$HAVE_XF86VIDMODE" = yes ; then
 886         dri_modules="$dri_modules xxf86vm"
 887     fi
 888
 889     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 890     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 891     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 892     GL_LIB_DEPS="$DRIGL_LIBS"
 893
 894     # need DRM libs, $PTHREAD_LIBS, etc.
 895     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 897     ;;
 898 esac
 899
 900 if test "$have_libudev" = yes; then
 901     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 902 fi
 903
 904 # This is outside the case (above) so that it is invoked even for non-GLX
 905 # builds.
 906 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 907
 908 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 909 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 910 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 911 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 912
 913 AC_SUBST([X11_INCLUDES])
 914 AC_SUBST([GL_LIB_DEPS])
 915 AC_SUBST([GL_PC_REQ_PRIV])
 916 AC_SUBST([GL_PC_LIB_PRIV])
 917 AC_SUBST([GL_PC_CFLAGS])
 918 AC_SUBST([DRI_PC_REQ_PRIV])
 919 AC_SUBST([GLESv1_CM_LIB_DEPS])
 920 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 921 AC_SUBST([GLESv2_LIB_DEPS])
 922 AC_SUBST([GLESv2_PC_LIB_PRIV])
 923
 924 AC_SUBST([HAVE_XF86VIDMODE])
 925
 926 dnl
 927 dnl More GLX setup
 928 dnl
 929 case "x$enable_glx$enable_xlib_glx" in
 930 xyesyes)
 931     DEFINES="$DEFINES -DUSE_XSHM"
 932     ;;
 933 xyesno)
 934     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 935     if test "x$driglx_direct" = xyes; then
 936         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 937     fi
 938     ;;
 939 esac
 940
 941 dnl
 942 dnl TLS detection
 943 dnl
 944
 945 AC_ARG_ENABLE([glx-tls],
 946     [AS_HELP_STRING([--enable-glx-tls],
 947         [enable TLS support in GLX @<:@default=disabled@:>@])],
 948     [GLX_USE_TLS="$enableval"],
 949     [GLX_USE_TLS=no])
 950 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 951
 952 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 953       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 954
 955 dnl
 956 dnl More DRI setup
 957 dnl
 958 dnl Directory for DRI drivers
 959 AC_ARG_WITH([dri-driverdir],
 960     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 961         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 962     [DRI_DRIVER_INSTALL_DIR="$withval"],
 963     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 964 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 965 dnl Extra search path for DRI drivers
 966 AC_ARG_WITH([dri-searchpath],
 967     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 968         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 969     [DRI_DRIVER_SEARCH_DIR="$withval"],
 970     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 971 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 972 dnl Which drivers to build - default is chosen by platform
 973 AC_ARG_WITH([dri-drivers],
 974     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 975         [comma delimited classic DRI drivers list, e.g.
 976         "swrast,i965,radeon" @<:@default=auto@:>@])],
 977     [with_dri_drivers="$withval"],
 978     [with_dri_drivers=auto])
 979
 980 if test "x$with_dri_drivers" = xauto; then
 981     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 982         with_dri_drivers="yes"
 983     else
 984         with_dri_drivers="no"
 985     fi
 986 fi
 987 if test "x$with_dri_drivers" = xno; then
 988     with_dri_drivers=''
 989 fi
 990
 991 dnl If $with_dri_drivers is yes, drivers will be added through
 992 dnl platform checks. Set DEFINES and LIB_DEPS
 993 if test "x$enable_dri" = xyes; then
 994     # Platform specific settings and drivers to build
 995     case "$host_os" in
 996     linux*)
 997         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 998         DEFINES="$DEFINES -DHAVE_ALIAS"
 999         if test "x$enable_dri3" = xyes; then
1000             DEFINES="$DEFINES -DHAVE_DRI3"
1001         fi
1002
1003         if test "x$have_libudev" != xyes; then
1004             AC_MSG_ERROR([libudev-dev required for building DRI])
1005         fi
1006
1007         case "$host_cpu" in
1008         powerpc* | sparc*)
1009             # Build only the drivers for cards that exist on PowerPC/sparc
1010             if test "x$with_dri_drivers" = "xyes"; then
1011                 with_dri_drivers="r200 radeon swrast"
1012             fi
1013             ;;
1014         esac
1015         ;;
1016     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1017         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1018         DEFINES="$DEFINES -DHAVE_ALIAS"
1019         ;;
1020     gnu*)
1021         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1022         DEFINES="$DEFINES -DHAVE_ALIAS"
1023         ;;
1024     solaris*)
1025         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1026         ;;
1027     cygwin*)
1028         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1029         if test "x$with_dri_drivers" = "xyes"; then
1030             with_dri_drivers="swrast"
1031         fi
1032         ;;
1033     esac
1034
1035     # default drivers
1036     if test "x$with_dri_drivers" = "xyes"; then
1037         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1038     fi
1039
1040     # Check for expat
1041     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1042     if test "x$have_expat" = "xyes"; then
1043        PKG_CHECK_MODULES([EXPAT], [expat], [],
1044                          AC_MSG_ERROR([Expat required for DRI.]))
1045     else
1046        # expat version 2.0 and earlier do not provide expat.pc
1047        EXPAT_LIBS=-lexpat
1048     fi
1049
1050     # If we are building any DRI driver other than swrast.
1051     if test -n "$with_dri_drivers"; then
1052         if test "x$with_dri_drivers" != xswrast; then
1053             # ... libdrm is required
1054             if test "x$have_libdrm" != xyes; then
1055                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1056             fi
1057             DRICOMMON_NEED_LIBDRM=yes
1058         else
1059             DRICOMMON_NEED_LIBDRM=no
1060         fi
1061     fi
1062
1063     # put all the necessary libs together
1064     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1065 fi
1066
1067 AC_SUBST([DRI_LIB_DEPS])
1068
1069 DRI_DIRS=''
1070 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1071 if test -n "$with_dri_drivers"; then
1072     if test "x$enable_opengl" != xyes; then
1073         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1074     fi
1075
1076     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1077     for driver in $dri_drivers; do
1078         DRI_DIRS="$DRI_DIRS $driver"
1079         case "x$driver" in
1080         xi915)
1081             HAVE_I915_DRI=yes;
1082             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1083             ;;
1084         xi965)
1085             HAVE_I965_DRI=yes;
1086             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1087             ;;
1088         xnouveau)
1089             HAVE_NOUVEAU_DRI=yes;
1090             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1091             ;;
1092         xradeon)
1093             HAVE_RADEON_DRI=yes;
1094             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1095             ;;
1096         xr200)
1097             HAVE_R200_DRI=yes;
1098             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1099             ;;
1100         xswrast)
1101             HAVE_SWRAST_DRI=yes;
1102             ;;
1103         *)
1104             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1105             ;;
1106         esac
1107     done
1108     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1109 fi
1110
1111 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1112 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1113                                   "x$enable_osmesa" = xyes -o \
1114                                   -n "$DRI_DIRS")
1115
1116 dnl
1117 dnl OSMesa configuration
1118 dnl
1119
1120 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1121 AC_ARG_WITH([osmesa-bits],
1122     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1123         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1124     [osmesa_bits="$withval"],
1125     [osmesa_bits=8])
1126 if test "x$osmesa_bits" != x8; then
1127     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1128         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1129         osmesa_bits=8
1130     fi
1131 fi
1132 case "x$osmesa_bits" in
1133 x8)
1134     OSMESA_LIB="${OSMESA_LIB}"
1135     ;;
1136 x16|x32)
1137     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1138     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1139     ;;
1140 *)
1141     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1142     ;;
1143 esac
1144
1145 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1146     # only link libraries with osmesa if shared
1147     if test "$enable_static" = no; then
1148         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1149     else
1150         OSMESA_LIB_DEPS=""
1151     fi
1152     OSMESA_MESA_DEPS=""
1153     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1154 fi
1155
1156 AC_SUBST([OSMESA_LIB_DEPS])
1157 AC_SUBST([OSMESA_MESA_DEPS])
1158 AC_SUBST([OSMESA_PC_REQ])
1159 AC_SUBST([OSMESA_PC_LIB_PRIV])
1160
1161 dnl
1162 dnl gbm configuration
1163 dnl
1164 if test "x$enable_gbm" = xauto; then
1165     case "$with_egl_platforms" in
1166         *drm*)
1167             enable_gbm=yes ;;
1168          *)
1169             enable_gbm=no ;;
1170     esac
1171 fi
1172 if test "x$enable_gbm" = xyes; then
1173     if test "x$need_libudev$have_libudev" = xyesno; then
1174         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1175     fi
1176
1177     if test "x$enable_dri" = xyes; then
1178         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1179         if test "x$enable_shared_glapi" = xno; then
1180             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1181         fi
1182     else
1183         # Strictly speaking libgbm does not require --enable-dri, although
1184         # both of its backends do. Thus one can build libgbm without any
1185         # backends if --disable-dri is set.
1186         # To avoid unnecessary complexity of checking if at least one backend
1187         # is available when building, just mandate --enable-dri.
1188         AC_MSG_ERROR([gbm requires --enable-dri])
1189     fi
1190 fi
1191 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1192 if test "x$need_libudev" = xyes; then
1193     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1194 else
1195     GBM_PC_REQ_PRIV=""
1196 fi
1197 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1198 AC_SUBST([GBM_PC_REQ_PRIV])
1199 AC_SUBST([GBM_PC_LIB_PRIV])
1200
1201 dnl
1202 dnl EGL configuration
1203 dnl
1204 EGL_CLIENT_APIS=""
1205
1206 if test "x$enable_egl" = xyes; then
1207     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1208
1209     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1210
1211     if test "$enable_static" != yes; then
1212         if test "x$enable_dri" = xyes; then
1213             HAVE_EGL_DRIVER_DRI2=1
1214         fi
1215
1216     fi
1217 fi
1218 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1219 AC_SUBST([EGL_LIB_DEPS])
1220
1221 dnl
1222 dnl EGL Gallium configuration
1223 dnl
1224 if test "x$enable_gallium_egl" = xyes; then
1225     if test -z "$with_gallium_drivers"; then
1226         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1227     fi
1228     if test "x$enable_egl" = xno; then
1229         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1230     fi
1231     if test "x$have_libdrm" != xyes; then
1232         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1233     fi
1234
1235     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1236     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1237 fi
1238 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1239
1240 dnl
1241 dnl gbm Gallium configuration
1242 dnl
1243 if test "x$enable_gallium_gbm" = xauto; then
1244     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1245         yesyesyes*drm*)
1246             enable_gallium_gbm=yes ;;
1247          *)
1248             enable_gallium_gbm=no ;;
1249     esac
1250 fi
1251 if test "x$enable_gallium_gbm" = xyes; then
1252     if test -z "$with_gallium_drivers"; then
1253         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1254     fi
1255     if test "x$enable_gbm" = xno; then
1256         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1257     fi
1258     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1259     if test "x$enable_dri" = xno; then
1260         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1261     fi
1262
1263     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1264     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1265     enable_gallium_loader=yes
1266 fi
1267 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1268
1269 dnl
1270 dnl XA configuration
1271 dnl
1272 if test "x$enable_xa" = xyes; then
1273     if test "x$with_gallium_drivers" = xswrast; then
1274        AC_MSG_ERROR([
1275           Building xa requires at least one non swrast gallium driver.
1276           If you are looking to use libxatracker.so with vmware's virtual gpu,
1277           make sure to include svga in the gallium drivers list, apart from
1278           enabling XA.
1279           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1280     fi
1281     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1282     enable_gallium_loader=yes
1283 fi
1284 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1285
1286 dnl
1287 dnl OpenVG configuration
1288 dnl
1289 VG_LIB_DEPS=""
1290
1291 if test "x$enable_openvg" = xyes; then
1292     if test "x$enable_egl" = xno; then
1293         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1294     fi
1295     if test -z "$with_gallium_drivers"; then
1296         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1297     fi
1298     if test "x$enable_gallium_egl" = xno; then
1299         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1300     fi
1301
1302     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1303     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1304     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1305     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1306     AC_SUBST([VG_PC_LIB_PRIV])
1307 fi
1308 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1309
1310 dnl
1311 dnl Gallium G3DVL configuration
1312 dnl
1313 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1314     if test "x$enable_xvmc" = xauto; then
1315         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1316     fi
1317
1318     if test "x$enable_vdpau" = xauto; then
1319         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1320     fi
1321
1322     if test "x$enable_omx" = xauto; then
1323         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1324     fi
1325 fi
1326
1327 if test "x$enable_xvmc" = xyes; then
1328     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1329     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1330 fi
1331 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1332
1333 if test "x$enable_vdpau" = xyes; then
1334     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1335                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1336     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1337 fi
1338 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1339
1340 if test "x$enable_omx" = xyes; then
1341     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1342     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1343 fi
1344 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1345
1346 dnl
1347 dnl OpenCL configuration
1348 dnl
1349
1350 AC_ARG_WITH([libclc-path],
1351    [AS_HELP_STRING([--with-libclc-path],
1352          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1353    [LIBCLC_PATH="$withval"],
1354    [LIBCLC_PATH=''])
1355
1356 if test -n "$LIBCLC_PATH"; then
1357    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1358                   Please review the updated build instructions for clover:
1359                   http://dri.freedesktop.org/wiki/GalliumCompute])
1360 fi
1361
1362
1363 AC_ARG_WITH([clang-libdir],
1364    [AS_HELP_STRING([--with-clang-libdir],
1365          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1366    [CLANG_LIBDIR="$withval"],
1367    [CLANG_LIBDIR=''])
1368
1369 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1370
1371 if test "x$enable_opencl" = xyes; then
1372     if test -z "$with_gallium_drivers"; then
1373         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1374     fi
1375
1376     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1377         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1378     fi
1379
1380     if test "x$have_libclc" = xno; then
1381         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1382                     Make sure the directory containing libclc.pc is specified in your
1383                     PKG_CONFIG_PATH environment variable.
1384                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1385     else
1386         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1387         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1388         AC_SUBST([LIBCLC_INCLUDEDIR])
1389         AC_SUBST([LIBCLC_LIBEXECDIR])
1390     fi
1391
1392     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1393     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1394     enable_gallium_loader=yes
1395
1396     if test "x$enable_opencl_icd" = xyes; then
1397         OPENCL_LIBNAME="MesaOpenCL"
1398     else
1399         OPENCL_LIBNAME="OpenCL"
1400     fi
1401 fi
1402 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1403 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1404 AC_SUBST([OPENCL_LIBNAME])
1405
1406 dnl
1407 dnl Gallium configuration
1408 dnl
1409 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1410
1411 AC_SUBST([LLVM_BINDIR])
1412 AC_SUBST([LLVM_CFLAGS])
1413 AC_SUBST([LLVM_CPPFLAGS])
1414 AC_SUBST([LLVM_CXXFLAGS])
1415 AC_SUBST([LLVM_LIBDIR])
1416 AC_SUBST([LLVM_LIBS])
1417 AC_SUBST([LLVM_LDFLAGS])
1418 AC_SUBST([LLVM_INCLUDEDIR])
1419 AC_SUBST([LLVM_VERSION])
1420 AC_SUBST([CLANG_RESOURCE_DIR])
1421
1422 case "x$enable_opengl$enable_gles1$enable_gles2" in
1423 x*yes*)
1424     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1425     ;;
1426 esac
1427
1428 AC_SUBST([VG_LIB_DEPS])
1429 AC_SUBST([EGL_CLIENT_APIS])
1430
1431 dnl
1432 dnl EGL Platforms configuration
1433 dnl
1434 AC_ARG_WITH([egl-platforms],
1435     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1436         [comma delimited native platforms libEGL supports, e.g.
1437         "x11,drm" @<:@default=auto@:>@])],
1438     [with_egl_platforms="$withval"],
1439     [if test "x$enable_egl" = xyes; then
1440         with_egl_platforms="x11"
1441     else
1442         with_egl_platforms=""
1443     fi])
1444
1445 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1446     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1447 fi
1448
1449 # Do per-EGL platform setups and checks
1450 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1451 for plat in $egl_platforms; do
1452         case "$plat" in
1453         wayland)
1454                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1455                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1456
1457                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1458                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1459                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1460                 ;;
1461
1462         x11)
1463                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1464                 ;;
1465
1466         drm)
1467                 test "x$enable_gbm" = "xno" &&
1468                         AC_MSG_ERROR([EGL platform drm needs gbm])
1469                 test "x$have_libdrm" != xyes &&
1470                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1471                 ;;
1472
1473         android|fbdev|gdi|null)
1474                 ;;
1475
1476         *)
1477                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1478                 ;;
1479         esac
1480
1481         case "$plat$need_libudev$have_libudev" in
1482                 waylandyesno|drmyesno)
1483                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1484         esac
1485 done
1486
1487 # libEGL wants to default to the first platform specified in
1488 # ./configure.  parse that here.
1489 if test "x$egl_platforms" != "x"; then
1490     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1491     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1492 else
1493     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1494 fi
1495
1496 if echo "$egl_platforms" | grep -q 'x11'; then
1497     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1498     NEED_WINSYS_XLIB=yes
1499 fi
1500 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1501 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1502 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1503 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1504 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1505
1506 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1507
1508 AC_SUBST([EGL_NATIVE_PLATFORM])
1509 AC_SUBST([EGL_CFLAGS])
1510
1511 # If we don't have the X11 platform, set this define so we don't try to include
1512 # the X11 headers.
1513 if ! echo "$egl_platforms" | grep -q 'x11'; then
1514     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1515     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1516 fi
1517
1518 AC_ARG_WITH([egl-driver-dir],
1519     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1520                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1521     [EGL_DRIVER_INSTALL_DIR="$withval"],
1522     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1523 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1524
1525 AC_ARG_WITH([max-width],
1526     [AS_HELP_STRING([--with-max-width=N],
1527                     [Maximum framebuffer width (4096)])],
1528     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1529      AS_IF([test "${withval}" -gt "4096"],
1530            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1531 )
1532 AC_ARG_WITH([max-height],
1533     [AS_HELP_STRING([--with-max-height=N],
1534                     [Maximum framebuffer height (4096)])],
1535     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1536      AS_IF([test "${withval}" -gt "4096"],
1537            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1538 )
1539
1540 dnl
1541 dnl Gallium LLVM
1542 dnl
1543 AC_ARG_ENABLE([gallium-llvm],
1544     [AS_HELP_STRING([--enable-gallium-llvm],
1545         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1546     [enable_gallium_llvm="$enableval"],
1547     [enable_gallium_llvm=auto])
1548
1549 AC_ARG_ENABLE([llvm-shared-libs],
1550     [AS_HELP_STRING([--enable-llvm-shared-libs],
1551         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1552     [enable_llvm_shared_libs="$enableval"],
1553     [enable_llvm_shared_libs=yes])
1554
1555 AC_ARG_WITH([llvm-prefix],
1556     [AS_HELP_STRING([--with-llvm-prefix],
1557         [Prefix for LLVM installations in non-standard locations])],
1558     [llvm_prefix="$withval"],
1559     [llvm_prefix=''])
1560
1561
1562 # Call this inside ` ` to get the return value.
1563 # $1 is the llvm-config command with arguments.
1564 strip_unwanted_llvm_flags() {
1565     # Use \> (marks the end of the word)
1566     echo `$1` | sed \
1567         -e 's/-DNDEBUG\>//g' \
1568         -e 's/-pedantic\>//g' \
1569         -e 's/-Wcovered-switch-default\>//g' \
1570         -e 's/-O.\>//g' \
1571         -e 's/-g\>//g' \
1572         -e 's/-Wall\>//g' \
1573         -e 's/-Wcast-qual\>//g' \
1574         -e 's/-Woverloaded-virtual\>//g' \
1575         -e 's/-fcolor-diagnostics\>//g' \
1576         -e 's/-fdata-sections\>//g' \
1577         -e 's/-ffunction-sections\>//g' \
1578         -e 's/-fno-exceptions\>//g' \
1579         -e 's/-fomit-frame-pointer\>//g' \
1580         -e 's/-fvisibility-inlines-hidden\>//g' \
1581         -e 's/-fPIC\>//g'
1582 }
1583
1584
1585 if test -z "$with_gallium_drivers"; then
1586     enable_gallium_llvm=no
1587 fi
1588 if test "x$enable_gallium_llvm" = xauto; then
1589     case "$host_cpu" in
1590     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1591     esac
1592 fi
1593 if test "x$enable_gallium_llvm" = xyes; then
1594     if test -n "$llvm_prefix"; then
1595         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1596     else
1597         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1598     fi
1599
1600     if test "x$LLVM_CONFIG" != xno; then
1601         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1602         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1603         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1604         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1605         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1606         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1607         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1608         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1609
1610         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1611             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1612         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1613             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1614
1615         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1616         dnl llvm-config.h
1617         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1618             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1619             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1620
1621         if test -n "${LLVM_VERSION_MAJOR}"; then
1622             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1623         else
1624             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1625         fi
1626
1627         LLVM_REQUIRED_VERSION_MAJOR="3"
1628         LLVM_REQUIRED_VERSION_MINOR="1"
1629         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1630             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1631         fi
1632
1633         LLVM_COMPONENTS="engine bitwriter"
1634         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1635             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1636         fi
1637
1638         if test "x$enable_opencl" = xyes; then
1639             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1640             # LLVM 3.3 >= 177971 requires IRReader
1641             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1642                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1643             fi
1644             # LLVM 3.4 requires Option
1645             if $LLVM_CONFIG --components | grep -qw 'option'; then
1646                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1647             fi
1648         fi
1649         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1650         MESA_LLVM=1
1651
1652         dnl Check for Clang internal headers
1653         if test "x$enable_opencl" = xyes; then
1654             if test -z "$CLANG_LIBDIR"; then
1655                 CLANG_LIBDIR=${LLVM_LIBDIR}
1656             fi
1657             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1658             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1659                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1660         fi
1661     else
1662         MESA_LLVM=0
1663         LLVM_VERSION_INT=0
1664     fi
1665 else
1666     MESA_LLVM=0
1667     LLVM_VERSION_INT=0
1668 fi
1669
1670 dnl Directory for XVMC libs
1671 AC_ARG_WITH([xvmc-libdir],
1672     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1673         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1674     [XVMC_LIB_INSTALL_DIR="$withval"],
1675     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1676 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1677
1678 dnl
1679 dnl Gallium Tests
1680 dnl
1681 if test "x$enable_gallium_tests" = xyes; then
1682     enable_gallium_loader=yes
1683 fi
1684 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1685
1686 if test "x$enable_gallium_loader" = xyes; then
1687     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1688 fi
1689 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1690
1691 dnl Directory for VDPAU libs
1692 AC_ARG_WITH([vdpau-libdir],
1693     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1694         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1695     [VDPAU_LIB_INSTALL_DIR="$withval"],
1696     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1697 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1698
1699 OMX_LIB_INSTALL_DIR_DEFAULT=''
1700 if test "x$enable_omx" = xyes; then
1701     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1702 fi
1703
1704 AC_ARG_WITH([omx-libdir],
1705     [AS_HELP_STRING([--with-omx-libdir=DIR],
1706         [directory for the OMX libraries])],
1707     [OMX_LIB_INSTALL_DIR="$withval"],
1708     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1709 AC_SUBST([OMX_LIB_INSTALL_DIR])
1710
1711 dnl Directory for OpenCL libs
1712 AC_ARG_WITH([opencl-libdir],
1713     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1714         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1715     [OPENCL_LIB_INSTALL_DIR="$withval"],
1716     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1717 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1718
1719 dnl
1720 dnl Gallium helper functions
1721 dnl
1722 gallium_check_st() {
1723     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1724          if test "x$have_libdrm" != xyes; then
1725             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1726          fi
1727          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1728     fi
1729     if test "x$enable_dri" = xyes && test -n "$2"; then
1730          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1731     fi
1732     if test "x$enable_xa" = xyes && test -n "$3"; then
1733          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1734     fi
1735     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1736          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1737     fi
1738     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1739          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1740     fi
1741     if test "x$enable_omx" = xyes && test "x$6" != x; then
1742          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1743     fi
1744 }
1745
1746 gallium_require_llvm() {
1747     if test "x$MESA_LLVM" = x0; then
1748         case "$host_cpu" in
1749         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1750         esac
1751     fi
1752 }
1753
1754 gallium_require_drm_loader() {
1755     if test "x$enable_gallium_loader" = xyes; then
1756         if test "x$need_libudev$have_libudev" = xyesno; then
1757             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1758         fi
1759         if test "x$have_libdrm" != xyes; then
1760             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1761         fi
1762         enable_gallium_drm_loader=yes
1763     fi
1764 }
1765
1766 require_egl_drm() {
1767     case "$with_egl_platforms" in
1768         *drm*)
1769             ;;
1770          *)
1771             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1772             ;;
1773     esac
1774     if test "x$enable_gbm" != xyes; then
1775             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1776     fi
1777 }
1778
1779 radeon_llvm_check() {
1780     if test "x$enable_gallium_llvm" != "xyes"; then
1781         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1782     fi
1783     LLVM_REQUIRED_VERSION_MAJOR="3"
1784     LLVM_REQUIRED_VERSION_MINOR="3"
1785     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1786         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1787     fi
1788     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1789         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1790                       sources with the --enable-experimental-targets=R600
1791                       configure flag])
1792     fi
1793     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1794     NEED_RADEON_LLVM=yes
1795     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1796                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1797 }
1798
1799 dnl Gallium drivers
1800 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1801         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1802     NEED_NONNULL_WINSYS=yes
1803 fi
1804 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1805
1806 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1807 if test -n "$with_gallium_drivers"; then
1808     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1809     for driver in $gallium_drivers; do
1810         case "x$driver" in
1811         xsvga)
1812             HAVE_GALLIUM_SVGA=yes
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1814             gallium_require_drm_loader
1815             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1816             ;;
1817         xi915)
1818             HAVE_GALLIUM_I915=yes
1819             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1820             gallium_require_drm_loader
1821             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1822             if test "x$MESA_LLVM" = x1; then
1823                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1824             fi
1825             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1826             gallium_check_st "i915/drm" "dri-i915"
1827             DRICOMMON_NEED_LIBDRM=yes
1828             ;;
1829         xilo)
1830             HAVE_GALLIUM_ILO=yes
1831             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1832             gallium_require_drm_loader
1833             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1834             gallium_check_st "intel/drm" "dri-ilo"
1835             DRICOMMON_NEED_LIBDRM=yes
1836             ;;
1837         xr300)
1838             HAVE_GALLIUM_R300=yes
1839             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1840             gallium_require_drm_loader
1841             gallium_require_llvm "Gallium R300"
1842             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1843             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1844             DRICOMMON_NEED_LIBDRM=yes
1845             ;;
1846         xr600)
1847             HAVE_GALLIUM_R600=yes
1848             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1849             gallium_require_drm_loader
1850             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1851             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1852                 radeon_llvm_check "r600g"
1853                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1854             fi
1855             if test "x$enable_r600_llvm" = xyes; then
1856                 USE_R600_LLVM_COMPILER=yes;
1857             fi
1858             if test "x$enable_opencl" = xyes; then
1859                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1860             fi
1861             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1862             DRICOMMON_NEED_LIBDRM=yes
1863             ;;
1864         xradeonsi)
1865             HAVE_GALLIUM_RADEONSI=yes
1866             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1867             gallium_require_drm_loader
1868             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1869             radeon_llvm_check "radeonsi"
1870             require_egl_drm "radeonsi"
1871             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1872             DRICOMMON_NEED_LIBDRM=yes
1873             ;;
1874         xnouveau)
1875             HAVE_GALLIUM_NOUVEAU=yes
1876             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1877             gallium_require_drm_loader
1878             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1879             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1880             DRICOMMON_NEED_LIBDRM=yes
1881             ;;
1882         xfreedreno)
1883             HAVE_GALLIUM_FREEDRENO=yes
1884             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1885             gallium_require_drm_loader
1886             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1887             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1888             DRICOMMON_NEED_LIBDRM=yes
1889             ;;
1890         xswrast)
1891             HAVE_GALLIUM_SOFTPIPE=yes
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1893             if test "x$MESA_LLVM" = x1; then
1894                 HAVE_GALLIUM_LLVMPIPE=yes
1895                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1896             fi
1897
1898             if test "x$enable_dri" = xyes; then
1899                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1900             fi
1901             ;;
1902         *)
1903             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1904             ;;
1905         esac
1906     done
1907 fi
1908
1909 dnl Set LLVM_LIBS - This is done after the driver configuration so
1910 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1911 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1912 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1913 dnl this was causing the same libraries to be appear multiple times
1914 dnl in LLVM_LIBS.
1915
1916 if test "x$MESA_LLVM" != x0; then
1917
1918     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1919
1920     if test "x$enable_llvm_shared_libs" = xyes; then
1921         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1922         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1923         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1924
1925         if test "x$llvm_have_one_so" = xyes; then
1926             dnl LLVM was built using auto*, so there is only one shared object.
1927             LLVM_LIBS="-l$LLVM_SO_NAME"
1928         else
1929             dnl If LLVM was built with CMake, there will be one shared object per
1930             dnl component.
1931             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1932                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1933         Please make sure you have built llvm with the --enable-shared option
1934         and that your llvm libraries are installed in $LLVM_LIBDIR
1935         If you have installed your llvm libraries to a different directory you
1936         can use the --with-llvm-prefix= configure flag to specify this directory.
1937         NOTE: Mesa is attempting to use llvm shared libraries by default.
1938         If you do not want to build with llvm shared libraries and instead want to
1939         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1940         invocation and rebuild.])])
1941
1942            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1943            dnl install uses a shared object for each compoenent and we have
1944            dnl already added all of these objects to LLVM_LIBS.
1945         fi
1946     else
1947         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1948     fi
1949 fi
1950
1951 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1952 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1953 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1954 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1955 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1956 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1957 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1958 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1959 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1960 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1961
1962 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1963                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1964                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1965 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1966                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1967                                                   && test "x$MESA_LLVM" = x1)
1968
1969 # NOTE: anything using xcb or other client side libs ends up in separate
1970 #       _CLIENT variables.  The pipe loader is built in two variants,
1971 #       one that is standalone and does not link any x client libs (for
1972 #       use by XA tracker in particular, but could be used in any case
1973 #       where communication with xserver is not desired).
1974 if test "x$enable_gallium_loader" = xyes; then
1975     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1976
1977     if test "x$NEED_WINSYS_XLIB" = xyes; then
1978         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1979     fi
1980
1981     if test "x$enable_dri" = xyes; then
1982         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
1983     fi
1984
1985     if test "x$enable_gallium_drm_loader" = xyes; then
1986         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1987         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1988                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1989         if test "x$pipe_loader_have_xcb" = xyes; then
1990             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1991             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1992         fi
1993     fi
1994
1995     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1996     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1997
1998     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1999     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2000     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2001     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2002 fi
2003
2004 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2005 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2006 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2007 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2008 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2009 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2010
2011 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2012                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2013                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2014                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2015 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2016                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2017 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2018 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2019 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2020 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2021 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2022 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2023 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2024
2025 AC_SUBST([ELF_LIB])
2026
2027 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2028 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2029 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2030 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2031 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2032
2033 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2034 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2035 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2036
2037 AC_SUBST([VDPAU_MAJOR], 1)
2038 AC_SUBST([VDPAU_MINOR], 0)
2039
2040 AC_SUBST([XVMC_MAJOR], 1)
2041 AC_SUBST([XVMC_MINOR], 0)
2042
2043 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2044 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2045 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2046 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2047
2048 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2049 AC_SUBST([XA_MINOR], $XA_MINOR)
2050 AC_SUBST([XA_TINY], $XA_TINY)
2051 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2052
2053 dnl Restore LDFLAGS and CPPFLAGS
2054 LDFLAGS="$_SAVE_LDFLAGS"
2055 CPPFLAGS="$_SAVE_CPPFLAGS"
2056
2057 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2058 if test "x$acv_mesa_CLANG" = xyes; then
2059     CFLAGS="$CFLAGS -Qunused-arguments"
2060     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2061 fi
2062
2063 dnl Add user CFLAGS and CXXFLAGS
2064 CFLAGS="$CFLAGS $USER_CFLAGS"
2065 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2066
2067 dnl Substitute the config
2068 AC_CONFIG_FILES([Makefile
2069                 src/Makefile
2070                 src/egl/drivers/dri2/Makefile
2071                 src/egl/main/Makefile
2072                 src/egl/main/egl.pc
2073                 src/egl/wayland/Makefile
2074                 src/egl/wayland/wayland-drm/Makefile
2075                 src/egl/wayland/wayland-egl/Makefile
2076                 src/egl/wayland/wayland-egl/wayland-egl.pc
2077                 src/gallium/auxiliary/Makefile
2078                 src/gallium/auxiliary/pipe-loader/Makefile
2079                 src/gallium/drivers/Makefile
2080                 src/gallium/drivers/freedreno/Makefile
2081                 src/gallium/drivers/galahad/Makefile
2082                 src/gallium/drivers/i915/Makefile
2083                 src/gallium/drivers/identity/Makefile
2084                 src/gallium/drivers/ilo/Makefile
2085                 src/gallium/drivers/llvmpipe/Makefile
2086                 src/gallium/drivers/noop/Makefile
2087                 src/gallium/drivers/nouveau/Makefile
2088                 src/gallium/drivers/r300/Makefile
2089                 src/gallium/drivers/r600/Makefile
2090                 src/gallium/drivers/radeon/Makefile
2091                 src/gallium/drivers/radeonsi/Makefile
2092                 src/gallium/drivers/rbug/Makefile
2093                 src/gallium/drivers/softpipe/Makefile
2094                 src/gallium/drivers/svga/Makefile
2095                 src/gallium/drivers/trace/Makefile
2096                 src/gallium/state_trackers/Makefile
2097                 src/gallium/state_trackers/clover/Makefile
2098                 src/gallium/state_trackers/dri/Makefile
2099                 src/gallium/state_trackers/dri/drm/Makefile
2100                 src/gallium/state_trackers/dri/sw/Makefile
2101                 src/gallium/state_trackers/egl/Makefile
2102                 src/gallium/state_trackers/gbm/Makefile
2103                 src/gallium/state_trackers/glx/xlib/Makefile
2104                 src/gallium/state_trackers/omx/Makefile
2105                 src/gallium/state_trackers/osmesa/Makefile
2106                 src/gallium/state_trackers/vdpau/Makefile
2107                 src/gallium/state_trackers/vega/Makefile
2108                 src/gallium/state_trackers/xa/Makefile
2109                 src/gallium/state_trackers/xvmc/Makefile
2110                 src/gallium/targets/Makefile
2111                 src/gallium/targets/dri-freedreno/Makefile
2112                 src/gallium/targets/dri-i915/Makefile
2113                 src/gallium/targets/dri-ilo/Makefile
2114                 src/gallium/targets/dri-nouveau/Makefile
2115                 src/gallium/targets/dri-swrast/Makefile
2116                 src/gallium/targets/dri-vmwgfx/Makefile
2117                 src/gallium/targets/egl-static/Makefile
2118                 src/gallium/targets/gbm/Makefile
2119                 src/gallium/targets/opencl/Makefile
2120                 src/gallium/targets/xa/Makefile
2121                 src/gallium/targets/xa/xatracker.pc
2122                 src/gallium/targets/omx-nouveau/Makefile
2123                 src/gallium/targets/osmesa/Makefile
2124                 src/gallium/targets/osmesa/osmesa.pc
2125                 src/gallium/targets/pipe-loader/Makefile
2126                 src/gallium/targets/radeonsi/dri/Makefile
2127                 src/gallium/targets/radeonsi/omx/Makefile
2128                 src/gallium/targets/radeonsi/vdpau/Makefile
2129                 src/gallium/targets/r300/dri/Makefile
2130                 src/gallium/targets/r600/dri/Makefile
2131                 src/gallium/targets/r600/omx/Makefile
2132                 src/gallium/targets/r600/vdpau/Makefile
2133                 src/gallium/targets/r600/xvmc/Makefile
2134                 src/gallium/targets/libgl-xlib/Makefile
2135                 src/gallium/targets/vdpau-nouveau/Makefile
2136                 src/gallium/targets/xvmc-nouveau/Makefile
2137                 src/gallium/tests/trivial/Makefile
2138                 src/gallium/tests/unit/Makefile
2139                 src/gallium/winsys/Makefile
2140                 src/gallium/winsys/freedreno/drm/Makefile
2141                 src/gallium/winsys/i915/drm/Makefile
2142                 src/gallium/winsys/i915/sw/Makefile
2143                 src/gallium/winsys/intel/drm/Makefile
2144                 src/gallium/winsys/nouveau/drm/Makefile
2145                 src/gallium/winsys/radeon/drm/Makefile
2146                 src/gallium/winsys/svga/drm/Makefile
2147                 src/gallium/winsys/sw/dri/Makefile
2148                 src/gallium/winsys/sw/fbdev/Makefile
2149                 src/gallium/winsys/sw/null/Makefile
2150                 src/gallium/winsys/sw/wayland/Makefile
2151                 src/gallium/winsys/sw/wrapper/Makefile
2152                 src/gallium/winsys/sw/xlib/Makefile
2153                 src/gbm/Makefile
2154                 src/gbm/main/gbm.pc
2155                 src/glsl/Makefile
2156                 src/glx/Makefile
2157                 src/glx/tests/Makefile
2158                 src/gtest/Makefile
2159                 src/loader/Makefile
2160                 src/mapi/Makefile
2161                 src/mapi/es1api/Makefile
2162                 src/mapi/es1api/glesv1_cm.pc
2163                 src/mapi/es2api/Makefile
2164                 src/mapi/es2api/glesv2.pc
2165                 src/mapi/glapi/Makefile
2166                 src/mapi/glapi/gen/Makefile
2167                 src/mapi/glapi/tests/Makefile
2168                 src/mapi/shared-glapi/Makefile
2169                 src/mapi/shared-glapi/tests/Makefile
2170                 src/mapi/vgapi/Makefile
2171                 src/mapi/vgapi/vg.pc
2172                 src/mesa/Makefile
2173                 src/mesa/gl.pc
2174                 src/mesa/drivers/dri/dri.pc
2175                 src/mesa/drivers/dri/common/Makefile
2176                 src/mesa/drivers/dri/common/xmlpool/Makefile
2177                 src/mesa/drivers/dri/i915/Makefile
2178                 src/mesa/drivers/dri/i965/Makefile
2179                 src/mesa/drivers/dri/Makefile
2180                 src/mesa/drivers/dri/nouveau/Makefile
2181                 src/mesa/drivers/dri/r200/Makefile
2182                 src/mesa/drivers/dri/radeon/Makefile
2183                 src/mesa/drivers/dri/swrast/Makefile
2184                 src/mesa/drivers/osmesa/Makefile
2185                 src/mesa/drivers/osmesa/osmesa.pc
2186                 src/mesa/drivers/x11/Makefile
2187                 src/mesa/main/tests/Makefile
2188                 src/mesa/main/tests/hash_table/Makefile])
2189
2190 dnl Sort the dirs alphabetically
2191 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2192 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2193 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2194 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2195
2196 AC_OUTPUT
2197
2198 dnl
2199 dnl Output some configuration info for the user
2200 dnl
2201 echo ""
2202 echo "        prefix:          $prefix"
2203 echo "        exec_prefix:     $exec_prefix"
2204 echo "        libdir:          $libdir"
2205 echo "        includedir:      $includedir"
2206
2207 dnl API info
2208 echo ""
2209 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2210 echo "        OpenVG:          $enable_openvg"
2211
2212 dnl Driver info
2213 echo ""
2214 case "x$enable_osmesa$enable_gallium_osmesa" in
2215 xnoyes)
2216         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2217         ;;
2218 xyesno)
2219         echo "        OSMesa:          lib$OSMESA_LIB"
2220         ;;
2221 xnono)
2222         echo "        OSMesa:          no"
2223         ;;
2224 esac
2225
2226 if test "x$enable_dri" != xno; then
2227         if test -z "$DRI_DIRS"; then
2228             echo "        DRI drivers:     no"
2229         else
2230             echo "        DRI drivers:     $DRI_DIRS"
2231         fi
2232         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2233 fi
2234
2235 case "x$enable_glx$enable_xlib_glx" in
2236 xyesyes)
2237     echo "        GLX:             Xlib-based"
2238     ;;
2239 xyesno)
2240     echo "        GLX:             DRI-based"
2241     ;;
2242 *)
2243     echo "        GLX:             $enable_glx"
2244     ;;
2245 esac
2246
2247 dnl EGL
2248 echo ""
2249 echo "        EGL:             $enable_egl"
2250 if test "$enable_egl" = yes; then
2251     echo "        EGL platforms:   $egl_platforms"
2252
2253     egl_drivers=""
2254     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2255         egl_drivers="$egl_drivers builtin:egl_dri2"
2256     fi
2257
2258     if test "x$enable_gallium_egl" = xyes; then
2259         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2260         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2261     else
2262         echo "        EGL drivers:    $egl_drivers"
2263     fi
2264 fi
2265
2266 echo ""
2267 if test "x$MESA_LLVM" = x1; then
2268     echo "        llvm:            yes"
2269     echo "        llvm-config:     $LLVM_CONFIG"
2270     echo "        llvm-version:    $LLVM_VERSION"
2271 else
2272     echo "        llvm:            no"
2273 fi
2274
2275 echo ""
2276 if test -n "$with_gallium_drivers"; then
2277     echo "        Gallium:         yes"
2278     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2279     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2280     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2281     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2282 else
2283     echo "        Gallium:         no"
2284 fi
2285
2286
2287 dnl Libraries
2288 echo ""
2289 echo "        Shared libs:     $enable_shared"
2290 echo "        Static libs:     $enable_static"
2291 echo "        Shared-glapi:    $enable_shared_glapi"
2292
2293 dnl Compiler options
2294 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2295 cflags=`echo $CFLAGS | \
2296     $SED 's/^ *//;s/  */ /;s/ *$//'`
2297 cxxflags=`echo $CXXFLAGS | \
2298     $SED 's/^ *//;s/  */ /;s/ *$//'`
2299 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2300 echo ""
2301 echo "        CFLAGS:          $cflags"
2302 echo "        CXXFLAGS:        $cxxflags"
2303 echo "        Macros:          $defines"
2304 echo ""
2305 if test "x$MESA_LLVM" = x1; then
2306     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2307     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2308     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2309     echo ""
2310 fi
2311 echo "        PYTHON2:         $PYTHON2"
2312
2313 echo ""
2314 echo "        Run '${MAKE-make}' to build Mesa"
2315 echo ""