configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.53
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports garbage collection
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 323 AC_MSG_CHECKING([whether ld supports --gc-sections])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         GC_SECTIONS="-Wl,--gc-sections";],
 328     [AC_MSG_RESULT([no])
 329         GC_SECTIONS="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([GC_SECTIONS])
 333
 334 dnl
 335 dnl compatibility symlinks
 336 dnl
 337 case "$host_os" in
 338 linux* )
 339     HAVE_COMPAT_SYMLINKS=yes ;;
 340 * )
 341     HAVE_COMPAT_SYMLINKS=no ;;
 342 esac
 343
 344 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 345
 346 dnl
 347 dnl library names
 348 dnl
 349 case "$host_os" in
 350 darwin* )
 351     LIB_EXT='dylib' ;;
 352 cygwin* )
 353     LIB_EXT='dll' ;;
 354 aix* )
 355     LIB_EXT='a' ;;
 356 * )
 357     LIB_EXT='so' ;;
 358 esac
 359
 360 AC_SUBST([LIB_EXT])
 361
 362 AC_ARG_WITH([gl-lib-name],
 363   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 364     [specify GL library name @<:@default=GL@:>@])],
 365   [GL_LIB=$withval],
 366   [GL_LIB=GL])
 367 AC_ARG_WITH([osmesa-lib-name],
 368   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 369     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 370   [OSMESA_LIB=$withval],
 371   [OSMESA_LIB=OSMesa])
 372 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 373 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 374
 375 dnl
 376 dnl Mangled Mesa support
 377 dnl
 378 AC_ARG_ENABLE([mangling],
 379   [AS_HELP_STRING([--enable-mangling],
 380     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 381   [enable_mangling="${enableval}"],
 382   [enable_mangling=no]
 383 )
 384 if test "x${enable_mangling}" = "xyes" ; then
 385   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 386   GL_LIB="Mangled${GL_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([OSMESA_LIB])
 391
 392 dnl
 393 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 394 dnl
 395 AC_ARG_ENABLE([texture-float],
 396     [AS_HELP_STRING([--enable-texture-float],
 397         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 398     [enable_texture_float="$enableval"],
 399     [enable_texture_float=no]
 400 )
 401 if test "x$enable_texture_float" = xyes; then
 402     AC_MSG_WARN([Floating-point textures enabled.])
 403     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 404     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 405 fi
 406
 407 dnl
 408 dnl Arch/platform-specific settings
 409 dnl
 410 AC_ARG_ENABLE([asm],
 411     [AS_HELP_STRING([--disable-asm],
 412         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 413     [enable_asm="$enableval"],
 414     [enable_asm=yes]
 415 )
 416 asm_arch=""
 417 AC_MSG_CHECKING([whether to enable assembly])
 418 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 419 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 420 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 421     case "$host_cpu" in
 422     i?86 | x86_64 | amd64)
 423         enable_asm=no
 424         AC_MSG_RESULT([no, cross compiling])
 425         ;;
 426     esac
 427 fi
 428 # check for supported arches
 429 if test "x$enable_asm" = xyes; then
 430     case "$host_cpu" in
 431     i?86)
 432         case "$host_os" in
 433         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 434             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 435             ;;
 436         gnu*)
 437             asm_arch=x86
 438             ;;
 439         esac
 440         ;;
 441     x86_64|amd64)
 442         case "$host_os" in
 443         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 444             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 445             ;;
 446         esac
 447         ;;
 448     sparc*)
 449         case "$host_os" in
 450         linux*)
 451             asm_arch=sparc
 452             ;;
 453         esac
 454         ;;
 455     esac
 456
 457     case "$asm_arch" in
 458     x86)
 459         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 460         AC_MSG_RESULT([yes, x86])
 461         ;;
 462     x86_64|amd64)
 463         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 464         AC_MSG_RESULT([yes, x86_64])
 465         ;;
 466     sparc)
 467         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 468         AC_MSG_RESULT([yes, sparc])
 469         ;;
 470     *)
 471         AC_MSG_RESULT([no, platform not supported])
 472         ;;
 473     esac
 474 fi
 475
 476 dnl Check to see if dlopen is in default libraries (like Solaris, which
 477 dnl has it in libc), or if libdl is needed to get it.
 478 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 479     [AC_CHECK_LIB([dl], [dlopen],
 480        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 481 AC_SUBST([DLOPEN_LIBS])
 482
 483 case "$host_os" in
 484 darwin*|mingw*)
 485     ;;
 486 *)
 487     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 488                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 489                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 490     AC_SUBST([CLOCK_LIB])
 491     ;;
 492 esac
 493
 494 dnl See if posix_memalign is available
 495 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 496
 497 dnl Check for pthreads
 498 AX_PTHREAD
 499 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 500 dnl to -pthread, which causes problems if we need -lpthread to appear in
 501 dnl pkgconfig files.
 502 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 503
 504 dnl SELinux awareness.
 505 AC_ARG_ENABLE([selinux],
 506     [AS_HELP_STRING([--enable-selinux],
 507         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 508     [MESA_SELINUX="$enableval"],
 509     [MESA_SELINUX=no])
 510 if test "x$enable_selinux" = "xyes"; then
 511     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 512         [AC_CHECK_HEADER([selinux/selinux.h],[],
 513                          [AC_MSG_ERROR([SELinux headers not found])])
 514          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 515                       [AC_MSG_ERROR([SELinux library not found])])
 516          SELINUX_LIBS="-lselinux"])
 517     DEFINES="$DEFINES -DMESA_SELINUX"
 518 fi
 519 AC_SUBST([SELINUX_CFLAGS])
 520 AC_SUBST([SELINUX_LIBS])
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=enabled@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=yes])
 549
 550 case "$host_os" in
 551 linux*)
 552     dri3_default=yes
 553     ;;
 554 *)
 555     dri3_default=no
 556     ;;
 557 esac
 558 AC_ARG_ENABLE([dri3],
 559     [AS_HELP_STRING([--enable-dri3],
 560         [enable DRI3 @<:@default=auto@:>@])],
 561     [enable_dri3="$enableval"],
 562     [enable_dri3="$dri3_default"])
 563 AC_ARG_ENABLE([glx],
 564     [AS_HELP_STRING([--enable-glx],
 565         [enable GLX library @<:@default=enabled@:>@])],
 566     [enable_glx="$enableval"],
 567     [enable_glx=yes])
 568 AC_ARG_ENABLE([osmesa],
 569     [AS_HELP_STRING([--enable-osmesa],
 570         [enable OSMesa library @<:@default=disabled@:>@])],
 571     [enable_osmesa="$enableval"],
 572     [enable_osmesa=no])
 573 AC_ARG_ENABLE([gallium-osmesa],
 574     [AS_HELP_STRING([--enable-gallium-osmesa],
 575         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 576     [enable_gallium_osmesa="$enableval"],
 577     [enable_gallium_osmesa=no])
 578 AC_ARG_ENABLE([egl],
 579     [AS_HELP_STRING([--disable-egl],
 580         [disable EGL library @<:@default=enabled@:>@])],
 581     [enable_egl="$enableval"],
 582     [enable_egl=yes])
 583
 584 AC_ARG_ENABLE([xa],
 585     [AS_HELP_STRING([--enable-xa],
 586         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 587     [enable_xa="$enableval"],
 588     [enable_xa=no])
 589 AC_ARG_ENABLE([gbm],
 590    [AS_HELP_STRING([--enable-gbm],
 591          [enable gbm library @<:@default=auto@:>@])],
 592    [enable_gbm="$enableval"],
 593    [enable_gbm=auto])
 594
 595 AC_ARG_ENABLE([xvmc],
 596    [AS_HELP_STRING([--enable-xvmc],
 597          [enable xvmc library @<:@default=auto@:>@])],
 598    [enable_xvmc="$enableval"],
 599    [enable_xvmc=no])
 600 AC_ARG_ENABLE([vdpau],
 601    [AS_HELP_STRING([--enable-vdpau],
 602          [enable vdpau library @<:@default=auto@:>@])],
 603    [enable_vdpau="$enableval"],
 604    [enable_vdpau=auto])
 605 AC_ARG_ENABLE([omx],
 606    [AS_HELP_STRING([--enable-omx],
 607          [enable OpenMAX library @<:@default=no@:>@])],
 608    [enable_omx="$enableval"],
 609    [enable_omx=no])
 610 AC_ARG_ENABLE([opencl],
 611    [AS_HELP_STRING([--enable-opencl],
 612          [enable OpenCL library @<:@default=no@:>@])],
 613    [enable_opencl="$enableval"],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([opencl_icd],
 616    [AS_HELP_STRING([--enable-opencl-icd],
 617           [Build an OpenCL ICD library to be loaded by an ICD implementation
 618            @<:@default=no@:>@])],
 619     [enable_opencl_icd="$enableval"],
 620     [enable_opencl_icd=no])
 621 AC_ARG_ENABLE([xlib-glx],
 622     [AS_HELP_STRING([--enable-xlib-glx],
 623         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 624     [enable_xlib_glx="$enableval"],
 625     [enable_xlib_glx=no])
 626 AC_ARG_ENABLE([gallium-egl],
 627     [AS_HELP_STRING([--enable-gallium-egl],
 628         [enable optional EGL state tracker (not required
 629          for EGL support in Gallium with OpenGL and OpenGL ES)
 630          @<:@default=disable@:>@])],
 631     [enable_gallium_egl="$enableval"],
 632     [enable_gallium_egl=no])
 633 AC_ARG_ENABLE([gallium-gbm],
 634     [AS_HELP_STRING([--enable-gallium-gbm],
 635         [enable optional gbm state tracker (not required for
 636          gbm support in Gallium)
 637          @<:@default=auto@:>@])],
 638     [enable_gallium_gbm="$enableval"],
 639     [enable_gallium_gbm=auto])
 640
 641 AC_ARG_ENABLE([r600-llvm-compiler],
 642     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 643         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 644     [enable_r600_llvm="$enableval"],
 645     [enable_r600_llvm=no])
 646
 647 AC_ARG_ENABLE([gallium-tests],
 648     [AS_HELP_STRING([--enable-gallium-tests],
 649         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 650     [enable_gallium_tests="$enableval"],
 651     [enable_gallium_tests=no])
 652
 653 # Option for Gallium drivers
 654
 655 # Keep this in sync with the --with-gallium-drivers help string default value
 656 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 657
 658 AC_ARG_WITH([gallium-drivers],
 659     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 660         [comma delimited Gallium drivers list, e.g.
 661         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 662         @<:@default=r300,r600,svga,swrast@:>@])],
 663     [with_gallium_drivers="$withval"],
 664     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 665
 666 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 667 # here so that the script doesn't choke on an unknown driver name later.
 668 case "$with_gallium_drivers" in
 669     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 670     no) with_gallium_drivers='' ;;
 671 esac
 672
 673 if test "x$enable_opengl" = xno -a \
 674         "x$enable_gles1" = xno -a \
 675         "x$enable_gles2" = xno -a \
 676         "x$enable_openvg" = xno -a \
 677         "x$enable_xa" = xno -a \
 678         "x$enable_xvmc" = xno -a \
 679         "x$enable_vdpau" = xno -a \
 680         "x$enable_omx" = xno -a \
 681         "x$enable_opencl" = xno; then
 682     AC_MSG_ERROR([at least one API should be enabled])
 683 fi
 684
 685 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 686 if test "x$enable_opengl" = xno -a \
 687         "x$enable_gles1" = xyes; then
 688     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 689 fi
 690
 691 if test "x$enable_opengl" = xno -a \
 692         "x$enable_gles2" = xyes; then
 693     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 694 fi
 695
 696 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 697 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 698 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 699 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 700                                         "x$enable_gles1" = xyes -o \
 701                                         "x$enable_gles2" = xyes)
 702
 703 if test "x$enable_glx" = xno; then
 704     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 705     enable_xlib_glx=no
 706 fi
 707
 708 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 709     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 710 fi
 711
 712 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 713     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 714 fi
 715
 716 # Disable GLX if OpenGL is not enabled
 717 if test "x$enable_glx$enable_opengl" = xyesno; then
 718     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 719     enable_glx=no
 720 fi
 721
 722 # Disable GLX if DRI and Xlib-GLX are not enabled
 723 if test "x$enable_glx" = xyes -a \
 724         "x$enable_dri" = xno -a \
 725         "x$enable_xlib_glx" = xno; then
 726     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 727     enable_glx=no
 728 fi
 729
 730 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 731                                   "x$enable_dri" = xyes)
 732 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 733 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 734
 735 AC_ARG_ENABLE([shared-glapi],
 736     [AS_HELP_STRING([--enable-shared-glapi],
 737         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 738     [enable_shared_glapi="$enableval"],
 739     [enable_shared_glapi=yes])
 740
 741 case "x$enable_opengl$enable_gles1$enable_gles2" in
 742 x*yes*yes*)
 743     if test "x$enable_shared_glapi" = xno; then
 744         AC_MSG_ERROR([shared GLAPI required when building two or more of
 745                       the following APIs - opengl, gles1 gles2])
 746     fi
 747     ;;
 748 esac
 749
 750 # Building Xlib-GLX requires shared glapi to be disabled.
 751 if test "x$enable_xlib_glx" = xyes; then
 752     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 753     enable_shared_glapi=no
 754 fi
 755
 756 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 757
 758 dnl
 759 dnl Driver specific build directories
 760 dnl
 761 GALLIUM_TARGET_DIRS=""
 762 GALLIUM_WINSYS_DIRS="sw"
 763 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 764 GALLIUM_STATE_TRACKERS_DIRS=""
 765
 766 case "x$enable_glx$enable_xlib_glx" in
 767 xyesyes)
 768     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 769     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 770     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 771     NEED_WINSYS_XLIB="yes"
 772     ;;
 773 esac
 774
 775 if test "x$enable_dri" = xyes; then
 776     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 777     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 778 fi
 779
 780 if test "x$enable_gallium_osmesa" = xyes; then
 781     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 782         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 783     fi
 784     if test "x$enable_osmesa" = xyes; then
 785         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 786     fi
 787     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 789 fi
 790
 791 AC_SUBST([MESA_LLVM])
 792
 793 # Check for libdrm
 794 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 795                   [have_libdrm=yes], [have_libdrm=no])
 796 if test "x$have_libdrm" = xyes; then
 797         DEFINES="$DEFINES -DHAVE_LIBDRM"
 798 fi
 799
 800 case "$host_os" in
 801 linux*)
 802     need_libudev=yes ;;
 803 *)
 804     need_libudev=no ;;
 805 esac
 806
 807 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 808                   have_libudev=yes, have_libudev=no)
 809
 810 if test "x$enable_dri" = xyes; then
 811     if test "$enable_static" = yes; then
 812         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 813     fi
 814
 815     # not a hard requirement as swrast does not depend on it
 816     if test "x$have_libdrm" = xyes; then
 817         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 818     fi
 819 fi
 820
 821 dnl Direct rendering or just indirect rendering
 822 case "$host_os" in
 823 gnu*)
 824     dnl Disable by default on GNU/Hurd
 825     driglx_direct_default="no"
 826     ;;
 827 cygwin*)
 828     dnl Disable by default on cygwin
 829     driglx_direct_default="no"
 830     ;;
 831 *)
 832     driglx_direct_default="yes"
 833     ;;
 834 esac
 835 AC_ARG_ENABLE([driglx-direct],
 836     [AS_HELP_STRING([--disable-driglx-direct],
 837         [disable direct rendering in GLX and EGL for DRI \
 838             @<:@default=auto@:>@])],
 839     [driglx_direct="$enableval"],
 840     [driglx_direct="$driglx_direct_default"])
 841
 842 dnl
 843 dnl libGL configuration per driver
 844 dnl
 845 case "x$enable_glx$enable_xlib_glx" in
 846 xyesyes)
 847     # Xlib-based GLX
 848     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 849     GL_PC_REQ_PRIV="x11 xext"
 850     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 851     GL_LIB_DEPS="$XLIBGL_LIBS"
 852     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 853     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 854     ;;
 855 xyesno)
 856     # DRI-based GLX
 857     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 858     if test x"$driglx_direct" = xyes; then
 859         if test "x$have_libdrm" != xyes; then
 860             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 861         fi
 862         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 863         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 864         if test x"$enable_dri3" = xyes; then
 865             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 866             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 867         fi
 868     fi
 869
 870     # find the DRI deps for libGL
 871     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 872
 873     if test x"$enable_dri3" = xyes; then
 874         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 875     fi
 876
 877     # add xf86vidmode if available
 878     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 879     if test "$HAVE_XF86VIDMODE" = yes ; then
 880         dri_modules="$dri_modules xxf86vm"
 881     fi
 882
 883     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 884     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 885     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 886     GL_LIB_DEPS="$DRIGL_LIBS"
 887
 888     # need DRM libs, $PTHREAD_LIBS, etc.
 889     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 890     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 891     ;;
 892 esac
 893
 894 if test "$have_libudev" = yes; then
 895     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 896 fi
 897
 898 # This is outside the case (above) so that it is invoked even for non-GLX
 899 # builds.
 900 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 901
 902 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 903 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 904 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906
 907 AC_SUBST([X11_INCLUDES])
 908 AC_SUBST([GL_LIB_DEPS])
 909 AC_SUBST([GL_PC_REQ_PRIV])
 910 AC_SUBST([GL_PC_LIB_PRIV])
 911 AC_SUBST([GL_PC_CFLAGS])
 912 AC_SUBST([DRI_PC_REQ_PRIV])
 913 AC_SUBST([GLESv1_CM_LIB_DEPS])
 914 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 915 AC_SUBST([GLESv2_LIB_DEPS])
 916 AC_SUBST([GLESv2_PC_LIB_PRIV])
 917
 918 AC_SUBST([HAVE_XF86VIDMODE])
 919
 920 dnl
 921 dnl More GLX setup
 922 dnl
 923 case "x$enable_glx$enable_xlib_glx" in
 924 xyesyes)
 925     DEFINES="$DEFINES -DUSE_XSHM"
 926     ;;
 927 xyesno)
 928     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 929     if test "x$driglx_direct" = xyes; then
 930         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 931     fi
 932     ;;
 933 esac
 934
 935 dnl
 936 dnl TLS detection
 937 dnl
 938
 939 AC_ARG_ENABLE([glx-tls],
 940     [AS_HELP_STRING([--enable-glx-tls],
 941         [enable TLS support in GLX @<:@default=disabled@:>@])],
 942     [GLX_USE_TLS="$enableval"],
 943     [GLX_USE_TLS=no])
 944 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 945
 946 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 947       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 948
 949 dnl
 950 dnl More DRI setup
 951 dnl
 952 dnl Directory for DRI drivers
 953 AC_ARG_WITH([dri-driverdir],
 954     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 955         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 956     [DRI_DRIVER_INSTALL_DIR="$withval"],
 957     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 958 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 959 dnl Extra search path for DRI drivers
 960 AC_ARG_WITH([dri-searchpath],
 961     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 962         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 963     [DRI_DRIVER_SEARCH_DIR="$withval"],
 964     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 965 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 966 dnl Which drivers to build - default is chosen by platform
 967 AC_ARG_WITH([dri-drivers],
 968     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 969         [comma delimited classic DRI drivers list, e.g.
 970         "swrast,i965,radeon" @<:@default=auto@:>@])],
 971     [with_dri_drivers="$withval"],
 972     [with_dri_drivers=auto])
 973
 974 if test "x$with_dri_drivers" = xauto; then
 975     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 976         with_dri_drivers="yes"
 977     else
 978         with_dri_drivers="no"
 979     fi
 980 fi
 981 if test "x$with_dri_drivers" = xno; then
 982     with_dri_drivers=''
 983 fi
 984
 985 dnl If $with_dri_drivers is yes, drivers will be added through
 986 dnl platform checks. Set DEFINES and LIB_DEPS
 987 if test "x$enable_dri" = xyes; then
 988     # Platform specific settings and drivers to build
 989     case "$host_os" in
 990     linux*)
 991         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 992         DEFINES="$DEFINES -DHAVE_ALIAS"
 993         if test "x$enable_dri3" = xyes; then
 994             DEFINES="$DEFINES -DHAVE_DRI3"
 995         fi
 996
 997         if test "x$have_libudev" != xyes; then
 998             AC_MSG_ERROR([libudev-dev required for building DRI])
 999         fi
1000
1001         case "$host_cpu" in
1002         powerpc* | sparc*)
1003             # Build only the drivers for cards that exist on PowerPC/sparc
1004             if test "x$with_dri_drivers" = "xyes"; then
1005                 with_dri_drivers="r200 radeon swrast"
1006             fi
1007             ;;
1008         esac
1009         ;;
1010     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1011         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1012         DEFINES="$DEFINES -DHAVE_ALIAS"
1013         ;;
1014     gnu*)
1015         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1016         DEFINES="$DEFINES -DHAVE_ALIAS"
1017         ;;
1018     solaris*)
1019         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1020         ;;
1021     cygwin*)
1022         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1023         if test "x$with_dri_drivers" = "xyes"; then
1024             with_dri_drivers="swrast"
1025         fi
1026         ;;
1027     esac
1028
1029     # default drivers
1030     if test "x$with_dri_drivers" = "xyes"; then
1031         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1032     fi
1033
1034     # Check for expat
1035     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1036     if test "x$have_expat" = "xyes"; then
1037        PKG_CHECK_MODULES([EXPAT], [expat], [],
1038                          AC_MSG_ERROR([Expat required for DRI.]))
1039     else
1040        # expat version 2.0 and earlier do not provide expat.pc
1041        EXPAT_LIBS=-lexpat
1042     fi
1043
1044     # If we are building any DRI driver other than swrast.
1045     if test -n "$with_dri_drivers"; then
1046         if test "x$with_dri_drivers" != xswrast; then
1047             # ... libdrm is required
1048             if test "x$have_libdrm" != xyes; then
1049                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1050             fi
1051             DRICOMMON_NEED_LIBDRM=yes
1052         else
1053             DRICOMMON_NEED_LIBDRM=no
1054         fi
1055     fi
1056
1057     # put all the necessary libs together
1058     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1059 fi
1060
1061 AC_SUBST([DRI_LIB_DEPS])
1062
1063 DRI_DIRS=''
1064 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1065 if test -n "$with_dri_drivers"; then
1066     if test "x$enable_opengl" != xyes; then
1067         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1068     fi
1069
1070     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1071     for driver in $dri_drivers; do
1072         DRI_DIRS="$DRI_DIRS $driver"
1073         case "x$driver" in
1074         xi915)
1075             HAVE_I915_DRI=yes;
1076             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1077             ;;
1078         xi965)
1079             HAVE_I965_DRI=yes;
1080             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1081             ;;
1082         xnouveau)
1083             HAVE_NOUVEAU_DRI=yes;
1084             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1085             ;;
1086         xradeon)
1087             HAVE_RADEON_DRI=yes;
1088             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1089             ;;
1090         xr200)
1091             HAVE_R200_DRI=yes;
1092             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1093             ;;
1094         xswrast)
1095             HAVE_SWRAST_DRI=yes;
1096             ;;
1097         *)
1098             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1099             ;;
1100         esac
1101     done
1102     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1103 fi
1104
1105 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1106 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1107                                   "x$enable_osmesa" = xyes -o \
1108                                   -n "$DRI_DIRS")
1109
1110 dnl
1111 dnl OSMesa configuration
1112 dnl
1113
1114 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1115 AC_ARG_WITH([osmesa-bits],
1116     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1117         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1118     [osmesa_bits="$withval"],
1119     [osmesa_bits=8])
1120 if test "x$osmesa_bits" != x8; then
1121     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1122         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1123         osmesa_bits=8
1124     fi
1125 fi
1126 case "x$osmesa_bits" in
1127 x8)
1128     OSMESA_LIB="${OSMESA_LIB}"
1129     ;;
1130 x16|x32)
1131     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1132     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1133     ;;
1134 *)
1135     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1136     ;;
1137 esac
1138
1139 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1140     # only link libraries with osmesa if shared
1141     if test "$enable_static" = no; then
1142         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1143     else
1144         OSMESA_LIB_DEPS=""
1145     fi
1146     OSMESA_MESA_DEPS=""
1147     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1148 fi
1149
1150 AC_SUBST([OSMESA_LIB_DEPS])
1151 AC_SUBST([OSMESA_MESA_DEPS])
1152 AC_SUBST([OSMESA_PC_REQ])
1153 AC_SUBST([OSMESA_PC_LIB_PRIV])
1154
1155 dnl
1156 dnl gbm configuration
1157 dnl
1158 if test "x$enable_gbm" = xauto; then
1159     case "$with_egl_platforms" in
1160         *drm*)
1161             enable_gbm=yes ;;
1162          *)
1163             enable_gbm=no ;;
1164     esac
1165 fi
1166 if test "x$enable_gbm" = xyes; then
1167     if test "x$need_libudev$have_libudev" = xyesno; then
1168         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1169     fi
1170
1171     if test "x$enable_dri" = xyes; then
1172         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1173         if test "x$enable_shared_glapi" = xno; then
1174             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1175         fi
1176     fi
1177 fi
1178 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1179 if test "x$need_libudev" = xyes; then
1180     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1181 else
1182     GBM_PC_REQ_PRIV=""
1183 fi
1184 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1185 AC_SUBST([GBM_PC_REQ_PRIV])
1186 AC_SUBST([GBM_PC_LIB_PRIV])
1187
1188 dnl
1189 dnl EGL configuration
1190 dnl
1191 EGL_CLIENT_APIS=""
1192
1193 if test "x$enable_egl" = xyes; then
1194     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1195
1196     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1197
1198     if test "$enable_static" != yes; then
1199         if test "x$enable_dri" = xyes; then
1200             HAVE_EGL_DRIVER_DRI2=1
1201         fi
1202
1203     fi
1204 fi
1205 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1206 AC_SUBST([EGL_LIB_DEPS])
1207
1208 dnl
1209 dnl EGL Gallium configuration
1210 dnl
1211 if test "x$enable_gallium_egl" = xyes; then
1212     if test -z "$with_gallium_drivers"; then
1213         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1214     fi
1215     if test "x$enable_egl" = xno; then
1216         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1217     fi
1218     if test "x$have_libdrm" != xyes; then
1219         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1220     fi
1221
1222     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1223     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1224 fi
1225 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1226
1227 dnl
1228 dnl gbm Gallium configuration
1229 dnl
1230 if test "x$enable_gallium_gbm" = xauto; then
1231     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1232         yesyesyes*drm*)
1233             enable_gallium_gbm=yes ;;
1234          *)
1235             enable_gallium_gbm=no ;;
1236     esac
1237 fi
1238 if test "x$enable_gallium_gbm" = xyes; then
1239     if test -z "$with_gallium_drivers"; then
1240         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1241     fi
1242     if test "x$enable_gbm" = xno; then
1243         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1244     fi
1245     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1246     if test "x$enable_dri" = xno; then
1247         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1248     fi
1249
1250     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1251     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1252     enable_gallium_loader=yes
1253 fi
1254 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1255
1256 dnl
1257 dnl XA configuration
1258 dnl
1259 if test "x$enable_xa" = xyes; then
1260     if test "x$with_gallium_drivers" = xswrast; then
1261        AC_MSG_ERROR([
1262           Building xa requires at least one non swrast gallium driver.
1263           If you are looking to use libxatracker.so with vmware's virtual gpu,
1264           make sure to include svga in the gallium drivers list, apart from
1265           enabling XA.
1266           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1267     fi
1268     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1269     enable_gallium_loader=yes
1270 fi
1271 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1272
1273 dnl
1274 dnl OpenVG configuration
1275 dnl
1276 VG_LIB_DEPS=""
1277
1278 if test "x$enable_openvg" = xyes; then
1279     if test "x$enable_egl" = xno; then
1280         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1281     fi
1282     if test -z "$with_gallium_drivers"; then
1283         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1284     fi
1285     if test "x$enable_gallium_egl" = xno; then
1286         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1287     fi
1288
1289     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1290     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1291     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1292     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1293     AC_SUBST([VG_PC_LIB_PRIV])
1294 fi
1295 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1296
1297 dnl
1298 dnl Gallium G3DVL configuration
1299 dnl
1300 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1301     if test "x$enable_xvmc" = xauto; then
1302         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1303     fi
1304
1305     if test "x$enable_vdpau" = xauto; then
1306         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1307     fi
1308
1309     if test "x$enable_omx" = xauto; then
1310         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1311     fi
1312 fi
1313
1314 if test "x$enable_xvmc" = xyes; then
1315     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1316     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1317 fi
1318 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1319
1320 if test "x$enable_vdpau" = xyes; then
1321     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1322                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1323     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1324 fi
1325 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1326
1327 if test "x$enable_omx" = xyes; then
1328     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1329     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1330 fi
1331 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1332
1333 dnl
1334 dnl OpenCL configuration
1335 dnl
1336
1337 AC_ARG_WITH([libclc-path],
1338    [AS_HELP_STRING([--with-libclc-path],
1339          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1340    [LIBCLC_PATH="$withval"],
1341    [LIBCLC_PATH=''])
1342
1343 if test -n "$LIBCLC_PATH"; then
1344    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1345                   Please review the updated build instructions for clover:
1346                   http://dri.freedesktop.org/wiki/GalliumCompute])
1347 fi
1348
1349
1350 AC_ARG_WITH([clang-libdir],
1351    [AS_HELP_STRING([--with-clang-libdir],
1352          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1353    [CLANG_LIBDIR="$withval"],
1354    [CLANG_LIBDIR=''])
1355
1356 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1357
1358 if test "x$enable_opencl" = xyes; then
1359     if test -z "$with_gallium_drivers"; then
1360         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1361     fi
1362
1363     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1364         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1365     fi
1366
1367     if test "x$have_libclc" = xno; then
1368         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1369                     Make sure the directory containing libclc.pc is specified in your
1370                     PKG_CONFIG_PATH environment variable.
1371                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1372     else
1373         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1374         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1375         AC_SUBST([LIBCLC_INCLUDEDIR])
1376         AC_SUBST([LIBCLC_LIBEXECDIR])
1377     fi
1378
1379     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1380     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1381     enable_gallium_loader=yes
1382
1383     if test "x$enable_opencl_icd" = xyes; then
1384         OPENCL_LIBNAME="MesaOpenCL"
1385     else
1386         OPENCL_LIBNAME="OpenCL"
1387     fi
1388 fi
1389 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1390 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1391 AC_SUBST([OPENCL_LIBNAME])
1392
1393 dnl
1394 dnl Gallium configuration
1395 dnl
1396 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1397
1398 AC_SUBST([LLVM_BINDIR])
1399 AC_SUBST([LLVM_CFLAGS])
1400 AC_SUBST([LLVM_CPPFLAGS])
1401 AC_SUBST([LLVM_CXXFLAGS])
1402 AC_SUBST([LLVM_LIBDIR])
1403 AC_SUBST([LLVM_LIBS])
1404 AC_SUBST([LLVM_LDFLAGS])
1405 AC_SUBST([LLVM_INCLUDEDIR])
1406 AC_SUBST([LLVM_VERSION])
1407 AC_SUBST([CLANG_RESOURCE_DIR])
1408
1409 case "x$enable_opengl$enable_gles1$enable_gles2" in
1410 x*yes*)
1411     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1412     ;;
1413 esac
1414
1415 AC_SUBST([VG_LIB_DEPS])
1416 AC_SUBST([EGL_CLIENT_APIS])
1417
1418 dnl
1419 dnl EGL Platforms configuration
1420 dnl
1421 AC_ARG_WITH([egl-platforms],
1422     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1423         [comma delimited native platforms libEGL supports, e.g.
1424         "x11,drm" @<:@default=auto@:>@])],
1425     [with_egl_platforms="$withval"],
1426     [if test "x$enable_egl" = xyes; then
1427         with_egl_platforms="x11"
1428     else
1429         with_egl_platforms=""
1430     fi])
1431
1432 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1433     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1434 fi
1435
1436 # Do per-EGL platform setups and checks
1437 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1438 for plat in $egl_platforms; do
1439         case "$plat" in
1440         wayland)
1441                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1442                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1443
1444                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1445                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1446                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1447                 ;;
1448
1449         x11)
1450                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1451                 ;;
1452
1453         drm)
1454                 test "x$enable_gbm" = "xno" &&
1455                         AC_MSG_ERROR([EGL platform drm needs gbm])
1456                 test "x$have_libdrm" != xyes &&
1457                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1458                 ;;
1459
1460         android|fbdev|gdi|null)
1461                 ;;
1462
1463         *)
1464                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1465                 ;;
1466         esac
1467
1468         case "$plat$need_libudev$have_libudev" in
1469                 waylandyesno|drmyesno)
1470                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1471         esac
1472 done
1473
1474 # libEGL wants to default to the first platform specified in
1475 # ./configure.  parse that here.
1476 if test "x$egl_platforms" != "x"; then
1477     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1478     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1479 else
1480     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1481 fi
1482
1483 if echo "$egl_platforms" | grep -q 'x11'; then
1484     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1485     NEED_WINSYS_XLIB=yes
1486 fi
1487 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1488 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1489 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1490 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1491 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1492
1493 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1494
1495 AC_SUBST([EGL_NATIVE_PLATFORM])
1496 AC_SUBST([EGL_CFLAGS])
1497
1498 # If we don't have the X11 platform, set this define so we don't try to include
1499 # the X11 headers.
1500 if ! echo "$egl_platforms" | grep -q 'x11'; then
1501     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1502     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1503 fi
1504
1505 AC_ARG_WITH([egl-driver-dir],
1506     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1507                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1508     [EGL_DRIVER_INSTALL_DIR="$withval"],
1509     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1510 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1511
1512 AC_ARG_WITH([max-width],
1513     [AS_HELP_STRING([--with-max-width=N],
1514                     [Maximum framebuffer width (4096)])],
1515     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1516      AS_IF([test "${withval}" -gt "4096"],
1517            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1518 )
1519 AC_ARG_WITH([max-height],
1520     [AS_HELP_STRING([--with-max-height=N],
1521                     [Maximum framebuffer height (4096)])],
1522     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1523      AS_IF([test "${withval}" -gt "4096"],
1524            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1525 )
1526
1527 dnl
1528 dnl Gallium LLVM
1529 dnl
1530 AC_ARG_ENABLE([gallium-llvm],
1531     [AS_HELP_STRING([--enable-gallium-llvm],
1532         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1533     [enable_gallium_llvm="$enableval"],
1534     [enable_gallium_llvm=auto])
1535
1536 AC_ARG_ENABLE([llvm-shared-libs],
1537     [AS_HELP_STRING([--enable-llvm-shared-libs],
1538         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1539     [enable_llvm_shared_libs="$enableval"],
1540     [enable_llvm_shared_libs=yes])
1541
1542 AC_ARG_WITH([llvm-prefix],
1543     [AS_HELP_STRING([--with-llvm-prefix],
1544         [Prefix for LLVM installations in non-standard locations])],
1545     [llvm_prefix="$withval"],
1546     [llvm_prefix=''])
1547
1548
1549 # Call this inside ` ` to get the return value.
1550 # $1 is the llvm-config command with arguments.
1551 strip_unwanted_llvm_flags() {
1552     # Use \> (marks the end of the word)
1553     echo `$1` | sed \
1554         -e 's/-DNDEBUG\>//g' \
1555         -e 's/-pedantic\>//g' \
1556         -e 's/-Wcovered-switch-default\>//g' \
1557         -e 's/-O.\>//g' \
1558         -e 's/-g\>//g' \
1559         -e 's/-Wall\>//g' \
1560         -e 's/-Wcast-qual\>//g' \
1561         -e 's/-Woverloaded-virtual\>//g' \
1562         -e 's/-fcolor-diagnostics\>//g' \
1563         -e 's/-fdata-sections\>//g' \
1564         -e 's/-ffunction-sections\>//g' \
1565         -e 's/-fno-exceptions\>//g' \
1566         -e 's/-fomit-frame-pointer\>//g' \
1567         -e 's/-fvisibility-inlines-hidden\>//g' \
1568         -e 's/-fPIC\>//g'
1569 }
1570
1571
1572 if test -z "$with_gallium_drivers"; then
1573     enable_gallium_llvm=no
1574 fi
1575 if test "x$enable_gallium_llvm" = xauto; then
1576     case "$host_cpu" in
1577     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1578     esac
1579 fi
1580 if test "x$enable_gallium_llvm" = xyes; then
1581     if test -n "$llvm_prefix"; then
1582         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1583     else
1584         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1585     fi
1586
1587     if test "x$LLVM_CONFIG" != xno; then
1588         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1589         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1590         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1591         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1592         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1593         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1594         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1595         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1596
1597         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1598             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1599         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1600             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1601
1602         if test -n "${LLVM_VERSION_MAJOR}"; then
1603             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1604         else
1605             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1606         fi
1607
1608         LLVM_COMPONENTS="engine bitwriter"
1609         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1610             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1611         fi
1612
1613         if test "x$enable_opencl" = xyes; then
1614             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1615             # LLVM 3.3 >= 177971 requires IRReader
1616             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1617                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1618             fi
1619             # LLVM 3.4 requires Option
1620             if $LLVM_CONFIG --components | grep -qw 'option'; then
1621                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1622             fi
1623         fi
1624         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1625         MESA_LLVM=1
1626
1627         dnl Check for Clang internal headers
1628         if test "x$enable_opencl" = xyes; then
1629             if test -z "$CLANG_LIBDIR"; then
1630                 CLANG_LIBDIR=${LLVM_LIBDIR}
1631             fi
1632             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1633             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1634                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1635         fi
1636     else
1637         MESA_LLVM=0
1638         LLVM_VERSION_INT=0
1639     fi
1640 else
1641     MESA_LLVM=0
1642     LLVM_VERSION_INT=0
1643 fi
1644
1645 dnl Directory for XVMC libs
1646 AC_ARG_WITH([xvmc-libdir],
1647     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1648         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1649     [XVMC_LIB_INSTALL_DIR="$withval"],
1650     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1651 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1652
1653 dnl
1654 dnl Gallium Tests
1655 dnl
1656 if test "x$enable_gallium_tests" = xyes; then
1657     enable_gallium_loader=yes
1658 fi
1659 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1660
1661 if test "x$enable_gallium_loader" = xyes; then
1662     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1663 fi
1664 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1665
1666 dnl Directory for VDPAU libs
1667 AC_ARG_WITH([vdpau-libdir],
1668     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1669         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1670     [VDPAU_LIB_INSTALL_DIR="$withval"],
1671     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1672 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1673
1674 OMX_LIB_INSTALL_DIR_DEFAULT=''
1675 if test "x$enable_omx" = xyes; then
1676     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1677 fi
1678
1679 AC_ARG_WITH([omx-libdir],
1680     [AS_HELP_STRING([--with-omx-libdir=DIR],
1681         [directory for the OMX libraries])],
1682     [OMX_LIB_INSTALL_DIR="$withval"],
1683     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1684 AC_SUBST([OMX_LIB_INSTALL_DIR])
1685
1686 dnl Directory for OpenCL libs
1687 AC_ARG_WITH([opencl-libdir],
1688     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1689         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1690     [OPENCL_LIB_INSTALL_DIR="$withval"],
1691     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1692 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1693
1694 dnl
1695 dnl Gallium helper functions
1696 dnl
1697 gallium_check_st() {
1698     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1699          if test "x$have_libdrm" != xyes; then
1700             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1701          fi
1702          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1703     fi
1704     if test "x$enable_dri" = xyes && test -n "$2"; then
1705          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1706     fi
1707     if test "x$enable_xa" = xyes && test -n "$3"; then
1708          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1709     fi
1710     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1711          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1712     fi
1713     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1714          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1715     fi
1716     if test "x$enable_omx" = xyes && test "x$6" != x; then
1717          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1718     fi
1719 }
1720
1721 gallium_require_llvm() {
1722     if test "x$MESA_LLVM" = x0; then
1723         case "$host_cpu" in
1724         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1725         esac
1726     fi
1727 }
1728
1729 gallium_require_drm_loader() {
1730     if test "x$enable_gallium_loader" = xyes; then
1731         if test "x$need_libudev$have_libudev" = xyesno; then
1732             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1733         fi
1734         if test "x$have_libdrm" != xyes; then
1735             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1736         fi
1737         enable_gallium_drm_loader=yes
1738     fi
1739 }
1740
1741 radeon_llvm_check() {
1742     if test "x$enable_gallium_llvm" != "xyes"; then
1743         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1744     fi
1745     LLVM_REQUIRED_VERSION_MAJOR="3"
1746     LLVM_REQUIRED_VERSION_MINOR="3"
1747     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1748         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1749     fi
1750     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1751         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1752                       sources with the --enable-experimental-targets=R600
1753                       configure flag])
1754     fi
1755     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1756     NEED_RADEON_LLVM=yes
1757     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1758                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1759 }
1760
1761 dnl Gallium drivers
1762 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1763         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1764     NEED_NONNULL_WINSYS=yes
1765 fi
1766 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1767
1768 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1769 if test -n "$with_gallium_drivers"; then
1770     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1771     for driver in $gallium_drivers; do
1772         case "x$driver" in
1773         xsvga)
1774             HAVE_GALLIUM_SVGA=yes
1775             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1776             gallium_require_drm_loader
1777             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1778             ;;
1779         xi915)
1780             HAVE_GALLIUM_I915=yes
1781             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1782             gallium_require_drm_loader
1783             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1784             if test "x$MESA_LLVM" = x1; then
1785                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1786             fi
1787             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1788             gallium_check_st "i915/drm" "dri-i915"
1789             DRICOMMON_NEED_LIBDRM=yes
1790             ;;
1791         xilo)
1792             HAVE_GALLIUM_ILO=yes
1793             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1794             gallium_require_drm_loader
1795             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1796             gallium_check_st "intel/drm" "dri-ilo"
1797             DRICOMMON_NEED_LIBDRM=yes
1798             ;;
1799         xr300)
1800             HAVE_GALLIUM_R300=yes
1801             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1802             gallium_require_drm_loader
1803             gallium_require_llvm "Gallium R300"
1804             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1805             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1806             DRICOMMON_NEED_LIBDRM=yes
1807             ;;
1808         xr600)
1809             HAVE_GALLIUM_R600=yes
1810             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1811             gallium_require_drm_loader
1812             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1813             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1814                 radeon_llvm_check "r600g"
1815                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1816             fi
1817             if test "x$enable_r600_llvm" = xyes; then
1818                 USE_R600_LLVM_COMPILER=yes;
1819             fi
1820             if test "x$enable_opencl" = xyes; then
1821                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1822             fi
1823             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1824             DRICOMMON_NEED_LIBDRM=yes
1825             ;;
1826         xradeonsi)
1827             HAVE_GALLIUM_RADEONSI=yes
1828             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1829             gallium_require_drm_loader
1830             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1831             radeon_llvm_check "radeonsi"
1832             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1833             DRICOMMON_NEED_LIBDRM=yes
1834             ;;
1835         xnouveau)
1836             HAVE_GALLIUM_NOUVEAU=yes
1837             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1838             gallium_require_drm_loader
1839             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1840             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1841             DRICOMMON_NEED_LIBDRM=yes
1842             ;;
1843         xfreedreno)
1844             HAVE_GALLIUM_FREEDRENO=yes
1845             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1846             gallium_require_drm_loader
1847             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1848             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1849             DRICOMMON_NEED_LIBDRM=yes
1850             ;;
1851         xswrast)
1852             HAVE_GALLIUM_SOFTPIPE=yes
1853             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1854             if test "x$MESA_LLVM" = x1; then
1855                 HAVE_GALLIUM_LLVMPIPE=yes
1856                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1857             fi
1858
1859             if test "x$enable_dri" = xyes; then
1860                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1861             fi
1862             ;;
1863         *)
1864             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1865             ;;
1866         esac
1867     done
1868 fi
1869
1870 dnl Set LLVM_LIBS - This is done after the driver configuration so
1871 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1872 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1873 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1874 dnl this was causing the same libraries to be appear multiple times
1875 dnl in LLVM_LIBS.
1876
1877 if test "x$MESA_LLVM" != x0; then
1878
1879     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1880
1881     if test "x$enable_llvm_shared_libs" = xyes; then
1882         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1883         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1884         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1885
1886         if test "x$llvm_have_one_so" = xyes; then
1887             dnl LLVM was built using auto*, so there is only one shared object.
1888             LLVM_LIBS="-l$LLVM_SO_NAME"
1889         else
1890             dnl If LLVM was built with CMake, there will be one shared object per
1891             dnl component.
1892             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1893                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1894         Please make sure you have built llvm with the --enable-shared option
1895         and that your llvm libraries are installed in $LLVM_LIBDIR
1896         If you have installed your llvm libraries to a different directory you
1897         can use the --with-llvm-prefix= configure flag to specify this directory.
1898         NOTE: Mesa is attempting to use llvm shared libraries by default.
1899         If you do not want to build with llvm shared libraries and instead want to
1900         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1901         invocation and rebuild.])])
1902
1903            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1904            dnl install uses a shared object for each compoenent and we have
1905            dnl already added all of these objects to LLVM_LIBS.
1906         fi
1907     else
1908         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1909     fi
1910 fi
1911
1912 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1913 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1914 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1915 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1916 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1917 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1918 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1919 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1920 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1921 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1922
1923 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1924                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1925                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1926 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1927                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1928                                                   && test "x$MESA_LLVM" = x1)
1929
1930 # NOTE: anything using xcb or other client side libs ends up in separate
1931 #       _CLIENT variables.  The pipe loader is built in two variants,
1932 #       one that is standalone and does not link any x client libs (for
1933 #       use by XA tracker in particular, but could be used in any case
1934 #       where communication with xserver is not desired).
1935 if test "x$enable_gallium_loader" = xyes; then
1936     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1937
1938     if test "x$enable_gallium_xlib_loader" = xyes; then
1939         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1940         NEED_WINSYS_XLIB="yes"
1941         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1942     fi
1943
1944     if test "x$enable_gallium_drm_loader" = xyes; then
1945         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1946         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1947                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1948         if test "x$pipe_loader_have_xcb" = xyes; then
1949             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1950             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1951         fi
1952     fi
1953
1954     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1955     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1956
1957     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1958     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1959     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1960     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1961 fi
1962 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1963
1964 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1965 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1966 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1967 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1968 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1969 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1970
1971 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1972                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1973                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1974                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1975 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1976                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1977 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1978 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1979 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1980 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1981 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1982 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1983 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1984
1985 AC_SUBST([ELF_LIB])
1986
1987 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1988 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1989 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1990 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1991 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1992
1993 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1994 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1995 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1996
1997 AC_SUBST([VDPAU_MAJOR], 1)
1998 AC_SUBST([VDPAU_MINOR], 0)
1999
2000 AC_SUBST([XVMC_MAJOR], 1)
2001 AC_SUBST([XVMC_MINOR], 0)
2002
2003 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2004 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2005 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2006 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2007
2008 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2009 AC_SUBST([XA_MINOR], $XA_MINOR)
2010 AC_SUBST([XA_TINY], $XA_TINY)
2011 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2012
2013 dnl Restore LDFLAGS and CPPFLAGS
2014 LDFLAGS="$_SAVE_LDFLAGS"
2015 CPPFLAGS="$_SAVE_CPPFLAGS"
2016
2017 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2018 if test "x$acv_mesa_CLANG" = xyes; then
2019     CFLAGS="$CFLAGS -Qunused-arguments"
2020     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2021 fi
2022
2023 dnl Add user CFLAGS and CXXFLAGS
2024 CFLAGS="$CFLAGS $USER_CFLAGS"
2025 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2026
2027 dnl Substitute the config
2028 AC_CONFIG_FILES([Makefile
2029                 src/Makefile
2030                 src/egl/drivers/dri2/Makefile
2031                 src/egl/main/Makefile
2032                 src/egl/main/egl.pc
2033                 src/egl/wayland/Makefile
2034                 src/egl/wayland/wayland-drm/Makefile
2035                 src/egl/wayland/wayland-egl/Makefile
2036                 src/egl/wayland/wayland-egl/wayland-egl.pc
2037                 src/gallium/auxiliary/Makefile
2038                 src/gallium/auxiliary/pipe-loader/Makefile
2039                 src/gallium/drivers/Makefile
2040                 src/gallium/drivers/freedreno/Makefile
2041                 src/gallium/drivers/galahad/Makefile
2042                 src/gallium/drivers/i915/Makefile
2043                 src/gallium/drivers/identity/Makefile
2044                 src/gallium/drivers/ilo/Makefile
2045                 src/gallium/drivers/llvmpipe/Makefile
2046                 src/gallium/drivers/noop/Makefile
2047                 src/gallium/drivers/nouveau/Makefile
2048                 src/gallium/drivers/r300/Makefile
2049                 src/gallium/drivers/r600/Makefile
2050                 src/gallium/drivers/radeon/Makefile
2051                 src/gallium/drivers/radeonsi/Makefile
2052                 src/gallium/drivers/rbug/Makefile
2053                 src/gallium/drivers/softpipe/Makefile
2054                 src/gallium/drivers/svga/Makefile
2055                 src/gallium/drivers/trace/Makefile
2056                 src/gallium/state_trackers/Makefile
2057                 src/gallium/state_trackers/clover/Makefile
2058                 src/gallium/state_trackers/dri/Makefile
2059                 src/gallium/state_trackers/dri/drm/Makefile
2060                 src/gallium/state_trackers/dri/sw/Makefile
2061                 src/gallium/state_trackers/egl/Makefile
2062                 src/gallium/state_trackers/gbm/Makefile
2063                 src/gallium/state_trackers/glx/xlib/Makefile
2064                 src/gallium/state_trackers/omx/Makefile
2065                 src/gallium/state_trackers/osmesa/Makefile
2066                 src/gallium/state_trackers/vdpau/Makefile
2067                 src/gallium/state_trackers/vega/Makefile
2068                 src/gallium/state_trackers/xa/Makefile
2069                 src/gallium/state_trackers/xvmc/Makefile
2070                 src/gallium/targets/Makefile
2071                 src/gallium/targets/dri-freedreno/Makefile
2072                 src/gallium/targets/dri-i915/Makefile
2073                 src/gallium/targets/dri-ilo/Makefile
2074                 src/gallium/targets/dri-nouveau/Makefile
2075                 src/gallium/targets/dri-swrast/Makefile
2076                 src/gallium/targets/dri-vmwgfx/Makefile
2077                 src/gallium/targets/egl-static/Makefile
2078                 src/gallium/targets/gbm/Makefile
2079                 src/gallium/targets/opencl/Makefile
2080                 src/gallium/targets/xa/Makefile
2081                 src/gallium/targets/xa/xatracker.pc
2082                 src/gallium/targets/osmesa/Makefile
2083                 src/gallium/targets/osmesa/osmesa.pc
2084                 src/gallium/targets/pipe-loader/Makefile
2085                 src/gallium/targets/radeonsi/dri/Makefile
2086                 src/gallium/targets/radeonsi/omx/Makefile
2087                 src/gallium/targets/radeonsi/vdpau/Makefile
2088                 src/gallium/targets/r300/dri/Makefile
2089                 src/gallium/targets/r600/dri/Makefile
2090                 src/gallium/targets/r600/omx/Makefile
2091                 src/gallium/targets/r600/vdpau/Makefile
2092                 src/gallium/targets/r600/xvmc/Makefile
2093                 src/gallium/targets/libgl-xlib/Makefile
2094                 src/gallium/targets/vdpau-nouveau/Makefile
2095                 src/gallium/targets/xvmc-nouveau/Makefile
2096                 src/gallium/tests/trivial/Makefile
2097                 src/gallium/tests/unit/Makefile
2098                 src/gallium/winsys/Makefile
2099                 src/gallium/winsys/freedreno/drm/Makefile
2100                 src/gallium/winsys/i915/drm/Makefile
2101                 src/gallium/winsys/i915/sw/Makefile
2102                 src/gallium/winsys/intel/drm/Makefile
2103                 src/gallium/winsys/nouveau/drm/Makefile
2104                 src/gallium/winsys/radeon/drm/Makefile
2105                 src/gallium/winsys/svga/drm/Makefile
2106                 src/gallium/winsys/sw/dri/Makefile
2107                 src/gallium/winsys/sw/fbdev/Makefile
2108                 src/gallium/winsys/sw/null/Makefile
2109                 src/gallium/winsys/sw/wayland/Makefile
2110                 src/gallium/winsys/sw/wrapper/Makefile
2111                 src/gallium/winsys/sw/xlib/Makefile
2112                 src/gbm/Makefile
2113                 src/gbm/main/gbm.pc
2114                 src/glsl/Makefile
2115                 src/glx/Makefile
2116                 src/glx/tests/Makefile
2117                 src/gtest/Makefile
2118                 src/loader/Makefile
2119                 src/mapi/Makefile
2120                 src/mapi/es1api/Makefile
2121                 src/mapi/es1api/glesv1_cm.pc
2122                 src/mapi/es2api/Makefile
2123                 src/mapi/es2api/glesv2.pc
2124                 src/mapi/glapi/Makefile
2125                 src/mapi/glapi/gen/Makefile
2126                 src/mapi/glapi/tests/Makefile
2127                 src/mapi/shared-glapi/Makefile
2128                 src/mapi/shared-glapi/tests/Makefile
2129                 src/mapi/vgapi/Makefile
2130                 src/mapi/vgapi/vg.pc
2131                 src/mesa/Makefile
2132                 src/mesa/gl.pc
2133                 src/mesa/drivers/dri/dri.pc
2134                 src/mesa/drivers/dri/common/Makefile
2135                 src/mesa/drivers/dri/common/xmlpool/Makefile
2136                 src/mesa/drivers/dri/i915/Makefile
2137                 src/mesa/drivers/dri/i965/Makefile
2138                 src/mesa/drivers/dri/Makefile
2139                 src/mesa/drivers/dri/nouveau/Makefile
2140                 src/mesa/drivers/dri/r200/Makefile
2141                 src/mesa/drivers/dri/radeon/Makefile
2142                 src/mesa/drivers/dri/swrast/Makefile
2143                 src/mesa/drivers/osmesa/Makefile
2144                 src/mesa/drivers/osmesa/osmesa.pc
2145                 src/mesa/drivers/x11/Makefile
2146                 src/mesa/main/tests/Makefile
2147                 src/mesa/main/tests/hash_table/Makefile])
2148
2149 dnl Sort the dirs alphabetically
2150 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2151 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2152 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2153 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2154
2155 AC_OUTPUT
2156
2157 dnl
2158 dnl Output some configuration info for the user
2159 dnl
2160 echo ""
2161 echo "        prefix:          $prefix"
2162 echo "        exec_prefix:     $exec_prefix"
2163 echo "        libdir:          $libdir"
2164 echo "        includedir:      $includedir"
2165
2166 dnl API info
2167 echo ""
2168 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2169 echo "        OpenVG:          $enable_openvg"
2170
2171 dnl Driver info
2172 echo ""
2173 case "x$enable_osmesa$enable_gallium_osmesa" in
2174 xnoyes)
2175         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2176         ;;
2177 xyesno)
2178         echo "        OSMesa:          lib$OSMESA_LIB"
2179         ;;
2180 xnono)
2181         echo "        OSMesa:          no"
2182         ;;
2183 esac
2184
2185 if test "x$enable_dri" != xno; then
2186         if test -z "$DRI_DIRS"; then
2187             echo "        DRI drivers:     no"
2188         else
2189             echo "        DRI drivers:     $DRI_DIRS"
2190         fi
2191         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2192 fi
2193
2194 case "x$enable_glx$enable_xlib_glx" in
2195 xyesyes)
2196     echo "        GLX:             Xlib-based"
2197     ;;
2198 xyesno)
2199     echo "        GLX:             DRI-based"
2200     ;;
2201 *)
2202     echo "        GLX:             $enable_glx"
2203     ;;
2204 esac
2205
2206 dnl EGL
2207 echo ""
2208 echo "        EGL:             $enable_egl"
2209 if test "$enable_egl" = yes; then
2210     echo "        EGL platforms:   $egl_platforms"
2211
2212     egl_drivers=""
2213     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2214         egl_drivers="$egl_drivers builtin:egl_dri2"
2215     fi
2216
2217     if test "x$enable_gallium_egl" = xyes; then
2218         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2219         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2220     else
2221         echo "        EGL drivers:    $egl_drivers"
2222     fi
2223 fi
2224
2225 echo ""
2226 if test "x$MESA_LLVM" = x1; then
2227     echo "        llvm:            yes"
2228     echo "        llvm-config:     $LLVM_CONFIG"
2229     echo "        llvm-version:    $LLVM_VERSION"
2230 else
2231     echo "        llvm:            no"
2232 fi
2233
2234 echo ""
2235 if test -n "$with_gallium_drivers"; then
2236     echo "        Gallium:         yes"
2237     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2238     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2239     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2240     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2241 else
2242     echo "        Gallium:         no"
2243 fi
2244
2245
2246 dnl Libraries
2247 echo ""
2248 echo "        Shared libs:     $enable_shared"
2249 echo "        Static libs:     $enable_static"
2250 echo "        Shared-glapi:    $enable_shared_glapi"
2251
2252 dnl Compiler options
2253 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2254 cflags=`echo $CFLAGS | \
2255     $SED 's/^ *//;s/  */ /;s/ *$//'`
2256 cxxflags=`echo $CXXFLAGS | \
2257     $SED 's/^ *//;s/  */ /;s/ *$//'`
2258 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2259 echo ""
2260 echo "        CFLAGS:          $cflags"
2261 echo "        CXXFLAGS:        $cxxflags"
2262 echo "        Macros:          $defines"
2263 echo ""
2264 if test "x$MESA_LLVM" = x1; then
2265     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2266     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2267     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2268     echo ""
2269 fi
2270 echo "        PYTHON2:         $PYTHON2"
2271
2272 echo ""
2273 echo "        Run '${MAKE-make}' to build Mesa"
2274 echo ""