configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([flatten])
 209 AX_GCC_FUNC_ATTRIBUTE([format])
 210 AX_GCC_FUNC_ATTRIBUTE([malloc])
 211 AX_GCC_FUNC_ATTRIBUTE([packed])
 212 AX_GCC_FUNC_ATTRIBUTE([unused])
 213 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 214
 215 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 216
 217 dnl Make sure the pkg-config macros are defined
 218 m4_ifndef([PKG_PROG_PKG_CONFIG],
 219     [m4_fatal([Could not locate the pkg-config autoconf macros.
 220   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 221   are in a different location, try setting the environment variable
 222   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 223 PKG_PROG_PKG_CONFIG()
 224
 225 dnl LIB_DIR - library basename
 226 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 227 AC_SUBST([LIB_DIR])
 228
 229 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 230 _SAVE_LDFLAGS="$LDFLAGS"
 231 _SAVE_CPPFLAGS="$CPPFLAGS"
 232
 233 dnl Compiler macros
 234 DEFINES=""
 235 AC_SUBST([DEFINES])
 236 case "$host_os" in
 237 linux*|*-gnu*|gnu*)
 238     DEFINES="$DEFINES -D_GNU_SOURCE"
 239     ;;
 240 solaris*)
 241     DEFINES="$DEFINES -DSVR4"
 242     ;;
 243 cygwin*)
 244     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 245     ;;
 246 esac
 247
 248 dnl Add flags for gcc and g++
 249 if test "x$GCC" = xyes; then
 250     CFLAGS="$CFLAGS -Wall"
 251
 252     if test "x$USE_GNU99" = xyes; then
 253         CFLAGS="$CFLAGS -std=gnu99"
 254     else
 255         CFLAGS="$CFLAGS -std=c99"
 256     fi
 257
 258     # Enable -Werror=implicit-function-declaration and
 259     # -Werror=missing-prototypes, if available, or otherwise, just
 260     # -Wmissing-prototypes.  This is particularly useful to avoid
 261     # generating a loadable driver module that has undefined symbols.
 262     save_CFLAGS="$CFLAGS"
 263     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 264     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 265     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 266     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 267                    AC_MSG_RESULT([yes]),
 268                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 269                     AC_MSG_RESULT([no])]);
 270
 271     # Enable -fvisibility=hidden if using a gcc that supports it
 272     save_CFLAGS="$CFLAGS"
 273     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 274     VISIBILITY_CFLAGS="-fvisibility=hidden"
 275     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 276     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 277                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 278
 279     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 280     CFLAGS=$save_CFLAGS
 281
 282     # Work around aliasing bugs - developers should comment this out
 283     CFLAGS="$CFLAGS -fno-strict-aliasing"
 284
 285     # gcc's builtin memcmp is slower than glibc's
 286     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 287     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 288
 289     # Flags to help ensure that certain portions of the code -- and only those
 290     # portions -- can be built with MSVC:
 291     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 292     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 293     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 294     #   supports most of C99)
 295     # - the rest has no compiler compiler restrictions
 296     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 297     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 298
 299     # Enable -Werror=vla if compiler supports it
 300     save_CFLAGS="$CFLAGS"
 301     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 302     CFLAGS="$CFLAGS -Werror=vla"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 305                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 306                     AC_MSG_RESULT([yes])],
 307                     AC_MSG_RESULT([no]));
 308     CFLAGS="$save_CFLAGS"
 309
 310     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 311     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 312 fi
 313 if test "x$GXX" = xyes; then
 314     CXXFLAGS="$CXXFLAGS -Wall"
 315
 316     # Enable -fvisibility=hidden if using a gcc that supports it
 317     save_CXXFLAGS="$CXXFLAGS"
 318     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 319     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 320     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 321     AC_LANG_PUSH([C++])
 322     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 323                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 324     AC_LANG_POP([C++])
 325
 326     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 327     CXXFLAGS=$save_CXXFLAGS
 328
 329     # Work around aliasing bugs - developers should comment this out
 330     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 331
 332     # gcc's builtin memcmp is slower than glibc's
 333     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 334     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 335 fi
 336
 337 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 338 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 339 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 340 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 341
 342 dnl even if the compiler appears to support it, using visibility attributes isn't
 343 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 344 case "$host_os" in
 345 cygwin*)
 346     VISIBILITY_CFLAGS=""
 347     VISIBILITY_CXXFLAGS=""
 348     ;;
 349 esac
 350
 351 AC_SUBST([VISIBILITY_CFLAGS])
 352 AC_SUBST([VISIBILITY_CXXFLAGS])
 353
 354 dnl
 355 dnl Optional flags, check for compiler support
 356 dnl
 357 SSE41_CFLAGS="-msse4.1"
 358 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 359 dnl stack, but on x86-32 such alignment is not guaranteed.
 360 case "$target_cpu" in
 361 i?86)
 362     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 363     ;;
 364 esac
 365 save_CFLAGS="$CFLAGS"
 366 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 367 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 368 #include <smmintrin.h>
 369 int main () {
 370     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 371     c = _mm_max_epu32(a, b);
 372     return 0;
 373 }]])], SSE41_SUPPORTED=1)
 374 CFLAGS="$save_CFLAGS"
 375 if test "x$SSE41_SUPPORTED" = x1; then
 376     DEFINES="$DEFINES -DUSE_SSE41"
 377 fi
 378 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 379 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 380
 381 dnl Can't have static and shared libraries, default to static if user
 382 dnl explicitly requested. If both disabled, set to static since shared
 383 dnl was explicitly requested.
 384 case "x$enable_static$enable_shared" in
 385 xyesyes)
 386     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 387     enable_shared=no
 388     ;;
 389 xnono)
 390     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 391     enable_shared=yes
 392     ;;
 393 esac
 394
 395 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 396
 397 dnl
 398 dnl other compiler options
 399 dnl
 400 AC_ARG_ENABLE([debug],
 401     [AS_HELP_STRING([--enable-debug],
 402         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 403     [enable_debug="$enableval"],
 404     [enable_debug=no]
 405 )
 406 if test "x$enable_debug" = xyes; then
 407     DEFINES="$DEFINES -DDEBUG"
 408     if test "x$GCC" = xyes; then
 409         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 410             CFLAGS="$CFLAGS -g"
 411         fi
 412         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 413             CFLAGS="$CFLAGS -O0"
 414         fi
 415     fi
 416     if test "x$GXX" = xyes; then
 417         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 418             CXXFLAGS="$CXXFLAGS -g"
 419         fi
 420         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 421             CXXFLAGS="$CXXFLAGS -O0"
 422         fi
 423     fi
 424 else
 425    DEFINES="$DEFINES -DNDEBUG"
 426 fi
 427
 428 dnl
 429 dnl Check if linker supports -Bsymbolic
 430 dnl
 431 save_LDFLAGS=$LDFLAGS
 432 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 433 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 434 AC_LINK_IFELSE(
 435     [AC_LANG_SOURCE([int main() { return 0;}])],
 436     [AC_MSG_RESULT([yes])
 437         BSYMBOLIC="-Wl,-Bsymbolic";],
 438     [AC_MSG_RESULT([no])
 439         BSYMBOLIC="";])
 440 LDFLAGS=$save_LDFLAGS
 441
 442 AC_SUBST([BSYMBOLIC])
 443
 444 dnl
 445 dnl Check if linker supports garbage collection
 446 dnl
 447 save_LDFLAGS=$LDFLAGS
 448 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 449 AC_MSG_CHECKING([whether ld supports --gc-sections])
 450 AC_LINK_IFELSE(
 451     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 452     [AC_MSG_RESULT([yes])
 453         GC_SECTIONS="-Wl,--gc-sections";],
 454     [AC_MSG_RESULT([no])
 455         GC_SECTIONS="";])
 456 LDFLAGS=$save_LDFLAGS
 457
 458 AC_SUBST([GC_SECTIONS])
 459
 460 dnl
 461 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 462 dnl so when these flags are passed to ld via libtool the checks will fail
 463 dnl
 464 case "$host_os" in
 465 openbsd* | darwin* )
 466     LD_NO_UNDEFINED="" ;;
 467 *)
 468     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 469 esac
 470
 471 AC_SUBST([LD_NO_UNDEFINED])
 472
 473 dnl
 474 dnl Check if linker supports version scripts
 475 dnl
 476 AC_MSG_CHECKING([if the linker supports version-scripts])
 477 save_LDFLAGS=$LDFLAGS
 478 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 479 cat > conftest.map <<EOF
 480 VERSION_1 {
 481      global:
 482          main;
 483
 484      local:
 485          *;
 486 };
 487 EOF
 488 AC_LINK_IFELSE(
 489     [AC_LANG_SOURCE([int main() { return 0;}])],
 490     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 491     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 492 LDFLAGS=$save_LDFLAGS
 493 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 494
 495 dnl
 496 dnl Check if linker supports dynamic list files
 497 dnl
 498 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 499 save_LDFLAGS=$LDFLAGS
 500 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 501 cat > conftest.dyn <<EOF
 502 {
 503         radeon_drm_winsys_create;
 504 };
 505 EOF
 506 AC_LINK_IFELSE(
 507     [AC_LANG_SOURCE([int main() { return 0;}])],
 508     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 509     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 510 LDFLAGS=$save_LDFLAGS
 511 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 512
 513 dnl
 514 dnl compatibility symlinks
 515 dnl
 516 case "$host_os" in
 517 linux* )
 518     HAVE_COMPAT_SYMLINKS=yes ;;
 519 * )
 520     HAVE_COMPAT_SYMLINKS=no ;;
 521 esac
 522
 523 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 524
 525 dnl
 526 dnl library names
 527 dnl
 528 case "$host_os" in
 529 darwin* )
 530     LIB_EXT='dylib' ;;
 531 cygwin* )
 532     LIB_EXT='dll' ;;
 533 aix* )
 534     LIB_EXT='a' ;;
 535 * )
 536     LIB_EXT='so' ;;
 537 esac
 538
 539 AC_SUBST([LIB_EXT])
 540
 541 AC_ARG_WITH([gl-lib-name],
 542   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 543     [specify GL library name @<:@default=GL@:>@])],
 544   [GL_LIB=$withval],
 545   [GL_LIB=GL])
 546 AC_ARG_WITH([osmesa-lib-name],
 547   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 548     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 549   [OSMESA_LIB=$withval],
 550   [OSMESA_LIB=OSMesa])
 551 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 552 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 553
 554 dnl
 555 dnl Mangled Mesa support
 556 dnl
 557 AC_ARG_ENABLE([mangling],
 558   [AS_HELP_STRING([--enable-mangling],
 559     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 560   [enable_mangling="${enableval}"],
 561   [enable_mangling=no]
 562 )
 563 if test "x${enable_mangling}" = "xyes" ; then
 564   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 565   GL_LIB="Mangled${GL_LIB}"
 566   OSMESA_LIB="Mangled${OSMESA_LIB}"
 567 fi
 568 AC_SUBST([GL_LIB])
 569 AC_SUBST([OSMESA_LIB])
 570
 571 dnl
 572 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 573 dnl
 574 AC_ARG_ENABLE([texture-float],
 575     [AS_HELP_STRING([--enable-texture-float],
 576         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 577     [enable_texture_float="$enableval"],
 578     [enable_texture_float=no]
 579 )
 580 if test "x$enable_texture_float" = xyes; then
 581     AC_MSG_WARN([Floating-point textures enabled.])
 582     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 583     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 584 fi
 585
 586 dnl
 587 dnl Arch/platform-specific settings
 588 dnl
 589 AC_ARG_ENABLE([asm],
 590     [AS_HELP_STRING([--disable-asm],
 591         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 592     [enable_asm="$enableval"],
 593     [enable_asm=yes]
 594 )
 595 asm_arch=""
 596 AC_MSG_CHECKING([whether to enable assembly])
 597 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 598 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 599 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 600     case "$host_cpu" in
 601     i?86 | x86_64 | amd64)
 602         enable_asm=no
 603         AC_MSG_RESULT([no, cross compiling])
 604         ;;
 605     esac
 606 fi
 607 # check for supported arches
 608 if test "x$enable_asm" = xyes; then
 609     case "$host_cpu" in
 610     i?86)
 611         case "$host_os" in
 612         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 613             asm_arch=x86
 614             ;;
 615         esac
 616         ;;
 617     x86_64|amd64)
 618         case "$host_os" in
 619         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 620             asm_arch=x86_64
 621             ;;
 622         esac
 623         ;;
 624     sparc*)
 625         case "$host_os" in
 626         linux*)
 627             asm_arch=sparc
 628             ;;
 629         esac
 630         ;;
 631     esac
 632
 633     case "$asm_arch" in
 634     x86)
 635         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 636         AC_MSG_RESULT([yes, x86])
 637         ;;
 638     x86_64|amd64)
 639         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 640         AC_MSG_RESULT([yes, x86_64])
 641         ;;
 642     sparc)
 643         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 644         AC_MSG_RESULT([yes, sparc])
 645         ;;
 646     *)
 647         AC_MSG_RESULT([no, platform not supported])
 648         ;;
 649     esac
 650 fi
 651
 652 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 653 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 654 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 655
 656 dnl Check to see if dlopen is in default libraries (like Solaris, which
 657 dnl has it in libc), or if libdl is needed to get it.
 658 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 659     [AC_CHECK_LIB([dl], [dlopen],
 660        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 661 AC_SUBST([DLOPEN_LIBS])
 662
 663 dnl Check if that library also has dladdr
 664 save_LIBS="$LIBS"
 665 LIBS="$LIBS $DLOPEN_LIBS"
 666 AC_CHECK_FUNCS([dladdr])
 667 LIBS="$save_LIBS"
 668
 669 case "$host_os" in
 670 darwin*)
 671     ;;
 672 *)
 673     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 674                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 675                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 676     AC_SUBST([CLOCK_LIB])
 677     ;;
 678 esac
 679
 680 dnl See if posix_memalign is available
 681 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 682
 683 dnl Check for pthreads
 684 AX_PTHREAD
 685 if test "x$ax_pthread_ok" = xno; then
 686     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 687 fi
 688 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 689 dnl to -pthread, which causes problems if we need -lpthread to appear in
 690 dnl pkgconfig files.
 691 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 692
 693 dnl SELinux awareness.
 694 AC_ARG_ENABLE([selinux],
 695     [AS_HELP_STRING([--enable-selinux],
 696         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 697     [MESA_SELINUX="$enableval"],
 698     [MESA_SELINUX=no])
 699 if test "x$enable_selinux" = "xyes"; then
 700     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 701         [AC_CHECK_HEADER([selinux/selinux.h],[],
 702                          [AC_MSG_ERROR([SELinux headers not found])])
 703          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 704                       [AC_MSG_ERROR([SELinux library not found])])
 705          SELINUX_LIBS="-lselinux"])
 706     DEFINES="$DEFINES -DMESA_SELINUX"
 707 fi
 708 AC_SUBST([SELINUX_CFLAGS])
 709 AC_SUBST([SELINUX_LIBS])
 710
 711 dnl Options for APIs
 712 AC_ARG_ENABLE([opengl],
 713     [AS_HELP_STRING([--disable-opengl],
 714         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 715     [enable_opengl="$enableval"],
 716     [enable_opengl=yes])
 717 AC_ARG_ENABLE([gles1],
 718     [AS_HELP_STRING([--disable-gles1],
 719         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 720     [enable_gles1="$enableval"],
 721     [enable_gles1=yes])
 722 AC_ARG_ENABLE([gles2],
 723     [AS_HELP_STRING([--disable-gles2],
 724         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 725     [enable_gles2="$enableval"],
 726     [enable_gles2=yes])
 727
 728 AC_ARG_ENABLE([dri],
 729     [AS_HELP_STRING([--enable-dri],
 730         [enable DRI modules @<:@default=enabled@:>@])],
 731     [enable_dri="$enableval"],
 732     [enable_dri=yes])
 733
 734 case "$host_os" in
 735 linux*)
 736     dri3_default=yes
 737     ;;
 738 *)
 739     dri3_default=no
 740     ;;
 741 esac
 742 AC_ARG_ENABLE([dri3],
 743     [AS_HELP_STRING([--enable-dri3],
 744         [enable DRI3 @<:@default=auto@:>@])],
 745     [enable_dri3="$enableval"],
 746     [enable_dri3="$dri3_default"])
 747 AC_ARG_ENABLE([glx],
 748     [AS_HELP_STRING([--enable-glx],
 749         [enable GLX library @<:@default=enabled@:>@])],
 750     [enable_glx="$enableval"],
 751     [enable_glx=yes])
 752 AC_ARG_ENABLE([osmesa],
 753     [AS_HELP_STRING([--enable-osmesa],
 754         [enable OSMesa library @<:@default=disabled@:>@])],
 755     [enable_osmesa="$enableval"],
 756     [enable_osmesa=no])
 757 AC_ARG_ENABLE([gallium-osmesa],
 758     [AS_HELP_STRING([--enable-gallium-osmesa],
 759         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 760     [enable_gallium_osmesa="$enableval"],
 761     [enable_gallium_osmesa=no])
 762 AC_ARG_ENABLE([egl],
 763     [AS_HELP_STRING([--disable-egl],
 764         [disable EGL library @<:@default=enabled@:>@])],
 765     [enable_egl="$enableval"],
 766     [enable_egl=yes])
 767
 768 AC_ARG_ENABLE([xa],
 769     [AS_HELP_STRING([--enable-xa],
 770         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 771     [enable_xa="$enableval"],
 772     [enable_xa=no])
 773 AC_ARG_ENABLE([gbm],
 774    [AS_HELP_STRING([--enable-gbm],
 775          [enable gbm library @<:@default=auto@:>@])],
 776    [enable_gbm="$enableval"],
 777    [enable_gbm=auto])
 778 AC_ARG_ENABLE([nine],
 779     [AS_HELP_STRING([--enable-nine],
 780         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 781     [enable_nine="$enableval"],
 782     [enable_nine=no])
 783
 784 AC_ARG_ENABLE([xvmc],
 785    [AS_HELP_STRING([--enable-xvmc],
 786          [enable xvmc library @<:@default=auto@:>@])],
 787    [enable_xvmc="$enableval"],
 788    [enable_xvmc=auto])
 789 AC_ARG_ENABLE([vdpau],
 790    [AS_HELP_STRING([--enable-vdpau],
 791          [enable vdpau library @<:@default=auto@:>@])],
 792    [enable_vdpau="$enableval"],
 793    [enable_vdpau=auto])
 794 AC_ARG_ENABLE([omx],
 795    [AS_HELP_STRING([--enable-omx],
 796          [enable OpenMAX library @<:@default=disabled@:>@])],
 797    [enable_omx="$enableval"],
 798    [enable_omx=no])
 799 AC_ARG_ENABLE([va],
 800    [AS_HELP_STRING([--enable-va],
 801          [enable va library @<:@default=auto@:>@])],
 802    [enable_va="$enableval"],
 803    [enable_va=auto])
 804 AC_ARG_ENABLE([opencl],
 805    [AS_HELP_STRING([--enable-opencl],
 806          [enable OpenCL library @<:@default=disabled@:>@])],
 807    [enable_opencl="$enableval"],
 808    [enable_opencl=no])
 809 AC_ARG_ENABLE([opencl_icd],
 810    [AS_HELP_STRING([--enable-opencl-icd],
 811           [Build an OpenCL ICD library to be loaded by an ICD implementation
 812            @<:@default=disabled@:>@])],
 813     [enable_opencl_icd="$enableval"],
 814     [enable_opencl_icd=no])
 815 AC_ARG_ENABLE([xlib-glx],
 816     [AS_HELP_STRING([--enable-xlib-glx],
 817         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 818     [enable_xlib_glx="$enableval"],
 819     [enable_xlib_glx=no])
 820
 821 AC_ARG_ENABLE([r600-llvm-compiler],
 822     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 823         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 824     [enable_r600_llvm="$enableval"],
 825     [enable_r600_llvm=no])
 826
 827 AC_ARG_ENABLE([gallium-tests],
 828     [AS_HELP_STRING([--enable-gallium-tests],
 829         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 830     [enable_gallium_tests="$enableval"],
 831     [enable_gallium_tests=no])
 832
 833 # Option for Gallium drivers
 834
 835 # Keep this in sync with the --with-gallium-drivers help string default value
 836 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 837
 838 AC_ARG_WITH([gallium-drivers],
 839     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 840         [comma delimited Gallium drivers list, e.g.
 841         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 842         @<:@default=r300,r600,svga,swrast@:>@])],
 843     [with_gallium_drivers="$withval"],
 844     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 845
 846 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 847 # here so that the script doesn't choke on an unknown driver name later.
 848 case "$with_gallium_drivers" in
 849     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 850     no) with_gallium_drivers='' ;;
 851 esac
 852
 853 if test "x$enable_opengl" = xno -a \
 854         "x$enable_gles1" = xno -a \
 855         "x$enable_gles2" = xno -a \
 856         "x$enable_nine" = xno -a \
 857         "x$enable_xa" = xno -a \
 858         "x$enable_xvmc" = xno -a \
 859         "x$enable_vdpau" = xno -a \
 860         "x$enable_omx" = xno -a \
 861         "x$enable_va" = xno -a \
 862         "x$enable_opencl" = xno; then
 863     AC_MSG_ERROR([at least one API should be enabled])
 864 fi
 865
 866 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 867 if test "x$enable_opengl" = xno -a \
 868         "x$enable_gles1" = xyes; then
 869     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 870 fi
 871
 872 if test "x$enable_opengl" = xno -a \
 873         "x$enable_gles2" = xyes; then
 874     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 875 fi
 876
 877 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 878 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 879 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 880 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 881                                         "x$enable_gles1" = xyes -o \
 882                                         "x$enable_gles2" = xyes)
 883
 884 if test "x$enable_glx" = xno; then
 885     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 886     enable_xlib_glx=no
 887 fi
 888
 889 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 890     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 891 fi
 892
 893 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 894     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 895 fi
 896
 897 # Disable GLX if OpenGL is not enabled
 898 if test "x$enable_glx$enable_opengl" = xyesno; then
 899     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 900     enable_glx=no
 901 fi
 902
 903 # Disable GLX if DRI and Xlib-GLX are not enabled
 904 if test "x$enable_glx" = xyes -a \
 905         "x$enable_dri" = xno -a \
 906         "x$enable_xlib_glx" = xno; then
 907     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 908     enable_glx=no
 909 fi
 910
 911 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 912                                   "x$enable_dri" = xyes)
 913
 914 # Select which platform-dependent DRI code gets built
 915 case "$host_os" in
 916 darwin*)
 917     dri_platform='apple' ;;
 918 gnu*|cygwin*)
 919     dri_platform='none' ;;
 920 *)
 921     dri_platform='drm' ;;
 922 esac
 923
 924 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 925 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 926 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 927 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 928 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 929
 930 AC_ARG_ENABLE([shared-glapi],
 931     [AS_HELP_STRING([--enable-shared-glapi],
 932         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 933     [enable_shared_glapi="$enableval"],
 934     [enable_shared_glapi=yes])
 935
 936 case "x$enable_opengl$enable_gles1$enable_gles2" in
 937 x*yes*yes*)
 938     if test "x$enable_shared_glapi" = xno; then
 939         AC_MSG_ERROR([shared GLAPI required when building two or more of
 940                       the following APIs - opengl, gles1 gles2])
 941     fi
 942     ;;
 943 esac
 944
 945 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 946
 947 # Build the pipe-drivers as separate libraries/modules.
 948 # Do not touch this unless you know what you are doing.
 949 # XXX: Expose via configure option ?
 950 enable_shared_pipe_drivers=no
 951
 952 dnl
 953 dnl Driver specific build directories
 954 dnl
 955
 956 case "x$enable_glx$enable_xlib_glx" in
 957 xyesyes)
 958     NEED_WINSYS_XLIB="yes"
 959     ;;
 960 esac
 961
 962 if test "x$enable_dri" = xyes; then
 963     enable_gallium_loader="$enable_shared_pipe_drivers"
 964 fi
 965
 966 if test "x$enable_gallium_osmesa" = xyes; then
 967     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 968         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 969     fi
 970     if test "x$enable_osmesa" = xyes; then
 971         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 972     fi
 973 fi
 974
 975 AC_SUBST([MESA_LLVM])
 976
 977 # SHA1 hashing
 978 AC_ARG_WITH([sha1],
 979         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 980         [choose SHA1 implementation])])
 981 case "x$with_sha1" in
 982 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 983   ;;
 984 *)
 985         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 986 esac
 987
 988 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 989 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 990         with_sha1=libc
 991 fi
 992 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 993         AC_MSG_ERROR([sha1 in libc requested but not found])
 994 fi
 995 if test "x$with_sha1" = xlibc; then
 996         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 997                 [Use libc SHA1 functions])
 998         SHA1_LIBS=""
 999 fi
1000 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1001 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1002         with_sha1=CommonCrypto
1003 fi
1004 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1005         AC_MSG_ERROR([CommonCrypto requested but not found])
1006 fi
1007 if test "x$with_sha1" = xCommonCrypto; then
1008         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1009                 [Use CommonCrypto SHA1 functions])
1010         SHA1_LIBS=""
1011 fi
1012 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1013 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1014 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1015         with_sha1=CryptoAPI
1016 fi
1017 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1018         AC_MSG_ERROR([CryptoAPI requested but not found])
1019 fi
1020 if test "x$with_sha1" = xCryptoAPI; then
1021         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1022                 [Use CryptoAPI SHA1 functions])
1023         SHA1_LIBS=""
1024 fi
1025 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1026 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1027         with_sha1=libmd
1028 fi
1029 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1030         AC_MSG_ERROR([libmd requested but not found])
1031 fi
1032 if test "x$with_sha1" = xlibmd; then
1033         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1034                   [Use libmd SHA1 functions])
1035         SHA1_LIBS=-lmd
1036 fi
1037 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1038 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1039    with_sha1=libsha1
1040 fi
1041 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1042         AC_MSG_ERROR([libsha1 requested but not found])
1043 fi
1044 if test "x$with_sha1" = xlibsha1; then
1045         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1046                   [Use libsha1 for SHA1])
1047         SHA1_LIBS=-lsha1
1048 fi
1049 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1050 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1051         with_sha1=libnettle
1052 fi
1053 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1054         AC_MSG_ERROR([libnettle requested but not found])
1055 fi
1056 if test "x$with_sha1" = xlibnettle; then
1057         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1058                   [Use libnettle SHA1 functions])
1059         SHA1_LIBS=-lnettle
1060 fi
1061 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1062 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1063         with_sha1=libgcrypt
1064 fi
1065 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1066         AC_MSG_ERROR([libgcrypt requested but not found])
1067 fi
1068 if test "x$with_sha1" = xlibgcrypt; then
1069         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1070                   [Use libgcrypt SHA1 functions])
1071         SHA1_LIBS=-lgcrypt
1072 fi
1073 # We don't need all of the OpenSSL libraries, just libcrypto
1074 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1075 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1076                   [HAVE_OPENSSL_PKC=no])
1077 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1078         if test "x$with_sha1" = x; then
1079                 with_sha1=libcrypto
1080         fi
1081 else
1082         if test "x$with_sha1" = xlibcrypto; then
1083                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1084         fi
1085 fi
1086 if test "x$with_sha1" = xlibcrypto; then
1087         if test "x$HAVE_LIBCRYPTO" = xyes; then
1088                 SHA1_LIBS=-lcrypto
1089         else
1090                 SHA1_LIBS="$OPENSSL_LIBS"
1091                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1092         fi
1093 fi
1094 AC_MSG_CHECKING([for SHA1 implementation])
1095 AC_MSG_RESULT([$with_sha1])
1096 AC_SUBST(SHA1_LIBS)
1097 AC_SUBST(SHA1_CFLAGS)
1098
1099 # Allow user to configure out the shader-cache feature
1100 AC_ARG_ENABLE([shader-cache],
1101     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1102     [enable_shader_cache="$enableval"],
1103     [if test "x$with_sha1" != "x"; then
1104         enable_shader_cache=yes
1105      else
1106         enable_shader_cache=no
1107      fi])
1108 if test "x$with_sha1" = "x"; then
1109     if test "x$enable_shader_cache" = "xyes"; then
1110         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1111     fi
1112 fi
1113 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1114
1115 # Check for libdrm
1116 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1117                   [have_libdrm=yes], [have_libdrm=no])
1118 if test "x$have_libdrm" = xyes; then
1119         DEFINES="$DEFINES -DHAVE_LIBDRM"
1120 fi
1121
1122 case "$host_os" in
1123 linux*)
1124     need_pci_id=yes ;;
1125 *)
1126     need_pci_id=no ;;
1127 esac
1128
1129 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1130                   have_libudev=yes, have_libudev=no)
1131
1132 AC_ARG_ENABLE([sysfs],
1133     [AS_HELP_STRING([--enable-sysfs],
1134         [enable /sys PCI identification @<:@default=disabled@:>@])],
1135     [have_sysfs="$enableval"],
1136     [have_sysfs=no]
1137 )
1138
1139 if test "x$enable_dri" = xyes; then
1140     if test "$enable_static" = yes; then
1141         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1142     fi
1143
1144     # not a hard requirement as swrast does not depend on it
1145     if test "x$have_libdrm" = xyes; then
1146         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1147     fi
1148 fi
1149
1150 AC_ARG_ENABLE([driglx-direct],
1151     [AS_HELP_STRING([--disable-driglx-direct],
1152         [disable direct rendering in GLX and EGL for DRI \
1153             @<:@default=auto@:>@])],
1154     [driglx_direct="$enableval"],
1155     [driglx_direct="yes"])
1156
1157 dnl
1158 dnl libGL configuration per driver
1159 dnl
1160 case "x$enable_glx$enable_xlib_glx" in
1161 xyesyes)
1162     # Xlib-based GLX
1163     dri_modules="x11 xext xcb"
1164     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1165     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1166     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1167     GL_LIB_DEPS="$XLIBGL_LIBS"
1168     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1169     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1170     ;;
1171 xyesno)
1172     # DRI-based GLX
1173     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1174
1175     # find the DRI deps for libGL
1176     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1177
1178     if test x"$driglx_direct" = xyes; then
1179         if test x"$dri_platform" = xdrm ; then
1180             DEFINES="$DEFINES -DGLX_USE_DRM"
1181             if test "x$have_libdrm" != xyes; then
1182                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1183             fi
1184
1185             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1186             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1187             if test x"$enable_dri3" = xyes; then
1188                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1189                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1190             fi
1191
1192             if test x"$enable_dri" = xyes; then
1193                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1194             fi
1195
1196             if test x"$enable_dri3" = xyes; then
1197                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1198                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1199             fi
1200         fi
1201         if test x"$dri_platform" = xapple ; then
1202             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1203         fi
1204     fi
1205
1206     # add xf86vidmode if available
1207     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1208     if test "$HAVE_XF86VIDMODE" = yes ; then
1209         dri_modules="$dri_modules xxf86vm"
1210     fi
1211
1212     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1213     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1214     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1215     GL_LIB_DEPS="$DRIGL_LIBS"
1216
1217     # need DRM libs, $PTHREAD_LIBS, etc.
1218     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1219     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1220     ;;
1221 esac
1222
1223 have_pci_id=no
1224 if test "$have_libudev" = yes; then
1225     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1226     have_pci_id=yes
1227 fi
1228
1229 if test "$have_sysfs" = yes; then
1230     DEFINES="$DEFINES -DHAVE_SYSFS"
1231     have_pci_id=yes
1232 fi
1233
1234 # This is outside the case (above) so that it is invoked even for non-GLX
1235 # builds.
1236 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1237
1238 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1239 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1240 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1241 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1242
1243 AC_SUBST([X11_INCLUDES])
1244 AC_SUBST([GL_LIB_DEPS])
1245 AC_SUBST([GL_PC_REQ_PRIV])
1246 AC_SUBST([GL_PC_LIB_PRIV])
1247 AC_SUBST([GL_PC_CFLAGS])
1248 AC_SUBST([DRI_PC_REQ_PRIV])
1249 AC_SUBST([GLESv1_CM_LIB_DEPS])
1250 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1251 AC_SUBST([GLESv2_LIB_DEPS])
1252 AC_SUBST([GLESv2_PC_LIB_PRIV])
1253
1254 AC_SUBST([HAVE_XF86VIDMODE])
1255
1256 dnl
1257 dnl More GLX setup
1258 dnl
1259 case "x$enable_glx$enable_xlib_glx" in
1260 xyesyes)
1261     DEFINES="$DEFINES -DUSE_XSHM"
1262     ;;
1263 xyesno)
1264     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1265     if test "x$driglx_direct" = xyes; then
1266         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1267     fi
1268     ;;
1269 esac
1270
1271 dnl
1272 dnl TLS detection
1273 dnl
1274
1275 AC_ARG_ENABLE([glx-tls],
1276     [AS_HELP_STRING([--enable-glx-tls],
1277         [enable TLS support in GLX @<:@default=disabled@:>@])],
1278     [GLX_USE_TLS="$enableval"],
1279     [GLX_USE_TLS=no])
1280 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1281
1282 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1283       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1284
1285 dnl
1286 dnl More DRI setup
1287 dnl
1288 dnl Directory for DRI drivers
1289 AC_ARG_WITH([dri-driverdir],
1290     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1291         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1292     [DRI_DRIVER_INSTALL_DIR="$withval"],
1293     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1294 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1295 dnl Extra search path for DRI drivers
1296 AC_ARG_WITH([dri-searchpath],
1297     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1298         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1299     [DRI_DRIVER_SEARCH_DIR="$withval"],
1300     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1301 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1302 dnl Which drivers to build - default is chosen by platform
1303 AC_ARG_WITH([dri-drivers],
1304     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1305         [comma delimited classic DRI drivers list, e.g.
1306         "swrast,i965,radeon" @<:@default=auto@:>@])],
1307     [with_dri_drivers="$withval"],
1308     [with_dri_drivers=auto])
1309
1310 if test "x$with_dri_drivers" = xauto; then
1311     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1312         with_dri_drivers="yes"
1313     else
1314         with_dri_drivers="no"
1315     fi
1316 fi
1317 if test "x$with_dri_drivers" = xno; then
1318     with_dri_drivers=''
1319 fi
1320
1321 dnl If $with_dri_drivers is yes, drivers will be added through
1322 dnl platform checks. Set DEFINES and LIB_DEPS
1323 if test "x$enable_dri" = xyes; then
1324     # Platform specific settings and drivers to build
1325     case "$host_os" in
1326     linux*)
1327         DEFINES="$DEFINES -DHAVE_ALIAS"
1328         if test "x$enable_dri3" = xyes; then
1329             DEFINES="$DEFINES -DHAVE_DRI3"
1330         fi
1331
1332         if test "x$have_pci_id" != xyes; then
1333             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1334         fi
1335
1336         case "$host_cpu" in
1337         powerpc* | sparc*)
1338             # Build only the drivers for cards that exist on PowerPC/sparc
1339             if test "x$with_dri_drivers" = "xyes"; then
1340                 with_dri_drivers="r200 radeon swrast"
1341             fi
1342             ;;
1343         esac
1344         ;;
1345     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1346         DEFINES="$DEFINES -DHAVE_ALIAS"
1347         ;;
1348     gnu*)
1349         DEFINES="$DEFINES -DHAVE_ALIAS"
1350         ;;
1351     cygwin*)
1352         if test "x$with_dri_drivers" = "xyes"; then
1353             with_dri_drivers="swrast"
1354         fi
1355         ;;
1356     darwin*)
1357         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1358         if test "x$with_dri_drivers" = "xyes"; then
1359             with_dri_drivers="swrast"
1360         fi
1361         ;;
1362     esac
1363
1364     # default drivers
1365     if test "x$with_dri_drivers" = "xyes"; then
1366         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1367     fi
1368
1369     # Check for expat
1370     PKG_CHECK_MODULES([EXPAT], [expat], [],
1371         # expat version 2.0 and earlier do not provide expat.pc
1372         [AC_CHECK_HEADER([expat.h],[],
1373                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1374          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1375                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1376          EXPAT_LIBS="-lexpat"])
1377
1378     DRICOMMON_NEED_LIBDRM=no
1379     # If we are building any DRI driver other than swrast.
1380     if test -n "$with_dri_drivers"; then
1381         if test "x$with_dri_drivers" != xswrast; then
1382             # ... libdrm is required
1383             if test "x$have_libdrm" != xyes; then
1384                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1385             fi
1386             DRICOMMON_NEED_LIBDRM=yes
1387         fi
1388     fi
1389
1390     # If we're building any gallium DRI driver other than swrast
1391     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1392         if test "x$with_gallium_drivers" != xswrast; then
1393             # ... build a libdrm aware dricommon
1394             DRICOMMON_NEED_LIBDRM=yes
1395         fi
1396     fi
1397
1398     # put all the necessary libs together
1399     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1400 fi
1401
1402 AC_SUBST([DRI_LIB_DEPS])
1403
1404 DRI_DIRS=''
1405 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1406 if test -n "$with_dri_drivers"; then
1407     if test "x$enable_opengl" != xyes; then
1408         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1409     fi
1410
1411     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1412     for driver in $dri_drivers; do
1413         DRI_DIRS="$DRI_DIRS $driver"
1414         case "x$driver" in
1415         xi915)
1416             HAVE_I915_DRI=yes;
1417             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1418             ;;
1419         xi965)
1420             HAVE_I965_DRI=yes;
1421             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1422             ;;
1423         xnouveau)
1424             HAVE_NOUVEAU_DRI=yes;
1425             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1426             ;;
1427         xradeon)
1428             HAVE_RADEON_DRI=yes;
1429             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1430             ;;
1431         xr200)
1432             HAVE_R200_DRI=yes;
1433             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1434             ;;
1435         xswrast)
1436             HAVE_SWRAST_DRI=yes;
1437             ;;
1438         *)
1439             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1440             ;;
1441         esac
1442     done
1443     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1444 fi
1445
1446 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1447 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1448                                   "x$enable_osmesa" = xyes -o \
1449                                   -n "$DRI_DIRS")
1450
1451 dnl
1452 dnl OSMesa configuration
1453 dnl
1454
1455 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1456 AC_ARG_WITH([osmesa-bits],
1457     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1458         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1459     [osmesa_bits="$withval"],
1460     [osmesa_bits=8])
1461 if test "x$osmesa_bits" != x8; then
1462     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1463         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1464         osmesa_bits=8
1465     fi
1466 fi
1467 case "x$osmesa_bits" in
1468 x8)
1469     OSMESA_LIB="${OSMESA_LIB}"
1470     ;;
1471 x16|x32)
1472     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1473     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1474     ;;
1475 *)
1476     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1477     ;;
1478 esac
1479
1480 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1481     # only link libraries with osmesa if shared
1482     if test "$enable_static" = no; then
1483         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1484     else
1485         OSMESA_LIB_DEPS=""
1486     fi
1487     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1488 fi
1489
1490 AC_SUBST([OSMESA_LIB_DEPS])
1491 AC_SUBST([OSMESA_PC_REQ])
1492 AC_SUBST([OSMESA_PC_LIB_PRIV])
1493
1494 dnl
1495 dnl gbm configuration
1496 dnl
1497 if test "x$enable_gbm" = xauto; then
1498     case "$with_egl_platforms" in
1499         *drm*)
1500             enable_gbm=yes ;;
1501          *)
1502             enable_gbm=no ;;
1503     esac
1504 fi
1505 if test "x$enable_gbm" = xyes; then
1506     if test "x$need_pci_id$have_pci_id" = xyesno; then
1507         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1508     fi
1509
1510     if test "x$enable_dri" = xyes; then
1511         if test "x$enable_shared_glapi" = xno; then
1512             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1513         fi
1514     else
1515         # Strictly speaking libgbm does not require --enable-dri, although
1516         # both of its backends do. Thus one can build libgbm without any
1517         # backends if --disable-dri is set.
1518         # To avoid unnecessary complexity of checking if at least one backend
1519         # is available when building, just mandate --enable-dri.
1520         AC_MSG_ERROR([gbm requires --enable-dri])
1521     fi
1522 fi
1523 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1524 if test "x$need_pci_id$have_libudev" = xyesyes; then
1525     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1526 else
1527     GBM_PC_REQ_PRIV=""
1528 fi
1529 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1530 AC_SUBST([GBM_PC_REQ_PRIV])
1531 AC_SUBST([GBM_PC_LIB_PRIV])
1532
1533 dnl
1534 dnl EGL configuration
1535 dnl
1536 EGL_CLIENT_APIS=""
1537
1538 if test "x$enable_egl" = xyes; then
1539     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1540
1541     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1542
1543     if test "$enable_static" != yes; then
1544         if test "x$enable_dri" = xyes; then
1545             HAVE_EGL_DRIVER_DRI2=1
1546             if test "x$enable_shared_glapi" = xno; then
1547                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1548             fi
1549         else
1550             # Avoid building an "empty" libEGL. Drop/update this
1551             # when other backends (haiku?) come along.
1552             AC_MSG_ERROR([egl requires --enable-dri])
1553         fi
1554
1555     fi
1556 fi
1557 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1558 AC_SUBST([EGL_LIB_DEPS])
1559
1560 dnl
1561 dnl XA configuration
1562 dnl
1563 if test "x$enable_xa" = xyes; then
1564     if test "x$with_gallium_drivers" = xswrast; then
1565        AC_MSG_ERROR([
1566           Building xa requires at least one non swrast gallium driver.
1567           If you are looking to use libxatracker.so with the VMware driver,
1568           make sure to include svga in the gallium drivers list, apart from
1569           enabling XA.
1570           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1571     fi
1572     enable_gallium_loader=$enable_shared_pipe_drivers
1573 fi
1574 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1575
1576 dnl
1577 dnl Gallium G3DVL configuration
1578 dnl
1579 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1580     if test "x$enable_xvmc" = xauto; then
1581         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1582     fi
1583
1584     if test "x$enable_vdpau" = xauto; then
1585         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1586     fi
1587
1588     if test "x$enable_omx" = xauto; then
1589         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1590     fi
1591
1592     if test "x$enable_va" = xauto; then
1593         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1594     fi
1595 fi
1596
1597 if test "x$enable_dri" = xyes -o \
1598         "x$enable_xvmc" = xyes -o \
1599         "x$enable_vdpau" = xyes -o \
1600         "x$enable_omx" = xyes -o \
1601         "x$enable_va" = xyes; then
1602     need_gallium_vl=yes
1603 fi
1604 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1605
1606 if test "x$enable_xvmc" = xyes -o \
1607         "x$enable_vdpau" = xyes -o \
1608         "x$enable_omx" = xyes -o \
1609         "x$enable_va" = xyes; then
1610     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1611     need_gallium_vl_winsys=yes
1612 fi
1613 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1614
1615 if test "x$enable_xvmc" = xyes; then
1616     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1617     enable_gallium_loader=$enable_shared_pipe_drivers
1618 fi
1619 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1620
1621 if test "x$enable_vdpau" = xyes; then
1622     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1623     enable_gallium_loader=$enable_shared_pipe_drivers
1624 fi
1625 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1626
1627 if test "x$enable_omx" = xyes; then
1628     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1629     enable_gallium_loader=$enable_shared_pipe_drivers
1630 fi
1631 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1632
1633 if test "x$enable_va" = xyes; then
1634     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1635     enable_gallium_loader=$enable_shared_pipe_drivers
1636 fi
1637 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1638
1639 dnl
1640 dnl Nine Direct3D9 configuration
1641 dnl
1642 if test "x$enable_nine" = xyes; then
1643     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1644         AC_MSG_ERROR([nine requires the gallium swrast driver])
1645     fi
1646     if test "x$with_gallium_drivers" = xswrast; then
1647         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1648     fi
1649     if test "x$enable_dri3" = xno; then
1650         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1651     fi
1652
1653     enable_gallium_loader=$enable_shared_pipe_drivers
1654 fi
1655 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1656
1657 dnl
1658 dnl OpenCL configuration
1659 dnl
1660
1661 AC_ARG_WITH([clang-libdir],
1662    [AS_HELP_STRING([--with-clang-libdir],
1663          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1664    [CLANG_LIBDIR="$withval"],
1665    [CLANG_LIBDIR=''])
1666
1667 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1668 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1669
1670 if test "x$enable_opencl" = xyes; then
1671     if test -z "$with_gallium_drivers"; then
1672         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1673     fi
1674
1675     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1676         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1677     fi
1678
1679     if test "x$have_libclc" = xno; then
1680         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1681                     Make sure the directory containing libclc.pc is specified in your
1682                     PKG_CONFIG_PATH environment variable.
1683                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1684     else
1685         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1686         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1687         AC_SUBST([LIBCLC_INCLUDEDIR])
1688         AC_SUBST([LIBCLC_LIBEXECDIR])
1689     fi
1690
1691     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1692     enable_gallium_loader=yes
1693
1694     if test "x$enable_opencl_icd" = xyes; then
1695         OPENCL_LIBNAME="MesaOpenCL"
1696     else
1697         OPENCL_LIBNAME="OpenCL"
1698     fi
1699
1700     if test "x$have_libelf" != xyes; then
1701        AC_MSG_ERROR([Clover requires libelf])
1702     fi
1703 fi
1704 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1705 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1706 AC_SUBST([OPENCL_LIBNAME])
1707
1708 dnl
1709 dnl Gallium configuration
1710 dnl
1711 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1712
1713 AC_SUBST([LLVM_BINDIR])
1714 AC_SUBST([LLVM_CFLAGS])
1715 AC_SUBST([LLVM_CPPFLAGS])
1716 AC_SUBST([LLVM_CXXFLAGS])
1717 AC_SUBST([LLVM_LIBDIR])
1718 AC_SUBST([LLVM_LIBS])
1719 AC_SUBST([LLVM_LDFLAGS])
1720 AC_SUBST([LLVM_INCLUDEDIR])
1721 AC_SUBST([LLVM_VERSION])
1722 AC_SUBST([CLANG_RESOURCE_DIR])
1723
1724 case "x$enable_opengl$enable_gles1$enable_gles2" in
1725 x*yes*)
1726     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1727     ;;
1728 esac
1729
1730 AC_SUBST([VG_LIB_DEPS])
1731 AC_SUBST([EGL_CLIENT_APIS])
1732
1733 dnl
1734 dnl EGL Platforms configuration
1735 dnl
1736 AC_ARG_WITH([egl-platforms],
1737     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1738         [comma delimited native platforms libEGL supports, e.g.
1739         "x11,drm" @<:@default=auto@:>@])],
1740     [with_egl_platforms="$withval"],
1741     [if test "x$enable_egl" = xyes; then
1742         with_egl_platforms="x11"
1743     else
1744         with_egl_platforms=""
1745     fi])
1746
1747 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1748     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1749 fi
1750
1751 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1752         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1753         WAYLAND_SCANNER='')
1754 if test "x$WAYLAND_SCANNER" = x; then
1755     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1756 fi
1757
1758 # Do per-EGL platform setups and checks
1759 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1760 for plat in $egl_platforms; do
1761         case "$plat" in
1762         wayland)
1763                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1764
1765                 if test "x$WAYLAND_SCANNER" = x; then
1766                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1767                 fi
1768                 ;;
1769
1770         x11)
1771                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1772                 ;;
1773
1774         drm)
1775                 test "x$enable_gbm" = "xno" &&
1776                         AC_MSG_ERROR([EGL platform drm needs gbm])
1777                 test "x$have_libdrm" != xyes &&
1778                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1779                 ;;
1780
1781         surfaceless)
1782                 test "x$have_libdrm" != xyes &&
1783                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1784                 ;;
1785
1786         android|gdi|null)
1787                 ;;
1788
1789         *)
1790                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1791                 ;;
1792         esac
1793
1794         case "$plat$need_pci_id$have_pci_id" in
1795                 waylandyesno|drmyesno)
1796                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1797         esac
1798 done
1799
1800 # libEGL wants to default to the first platform specified in
1801 # ./configure.  parse that here.
1802 if test "x$egl_platforms" != "x"; then
1803     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1804     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1805 else
1806     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1807 fi
1808
1809 if echo "$egl_platforms" | grep -q 'x11'; then
1810     NEED_WINSYS_XLIB=yes
1811 fi
1812 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1813 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1814 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1815 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1816 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1817
1818 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1819
1820 AC_SUBST([EGL_NATIVE_PLATFORM])
1821 AC_SUBST([EGL_CFLAGS])
1822
1823 # If we don't have the X11 platform, set this define so we don't try to include
1824 # the X11 headers.
1825 if ! echo "$egl_platforms" | grep -q 'x11'; then
1826     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1827     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1828 fi
1829
1830 dnl
1831 dnl Gallium LLVM
1832 dnl
1833 AC_ARG_ENABLE([gallium-llvm],
1834     [AS_HELP_STRING([--enable-gallium-llvm],
1835         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1836     [enable_gallium_llvm="$enableval"],
1837     [enable_gallium_llvm=auto])
1838
1839 AC_ARG_ENABLE([llvm-shared-libs],
1840     [AS_HELP_STRING([--enable-llvm-shared-libs],
1841         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1842     [enable_llvm_shared_libs="$enableval"],
1843     [enable_llvm_shared_libs=yes])
1844
1845 AC_ARG_WITH([llvm-prefix],
1846     [AS_HELP_STRING([--with-llvm-prefix],
1847         [Prefix for LLVM installations in non-standard locations])],
1848     [llvm_prefix="$withval"],
1849     [llvm_prefix=''])
1850
1851
1852 # Call this inside ` ` to get the return value.
1853 # $1 is the llvm-config command with arguments.
1854 strip_unwanted_llvm_flags() {
1855     # Use \> (marks the end of the word)
1856     echo `$1` | sed \
1857         -e 's/-DNDEBUG\>//g' \
1858         -e 's/-D_GNU_SOURCE\>//g' \
1859         -e 's/-pedantic\>//g' \
1860         -e 's/-Wcovered-switch-default\>//g' \
1861         -e 's/-O.\>//g' \
1862         -e 's/-g\>//g' \
1863         -e 's/-Wall\>//g' \
1864         -e 's/-Wcast-qual\>//g' \
1865         -e 's/-Woverloaded-virtual\>//g' \
1866         -e 's/-fcolor-diagnostics\>//g' \
1867         -e 's/-fdata-sections\>//g' \
1868         -e 's/-ffunction-sections\>//g' \
1869         -e 's/-fno-exceptions\>//g' \
1870         -e 's/-fomit-frame-pointer\>//g' \
1871         -e 's/-fvisibility-inlines-hidden\>//g' \
1872         -e 's/-fPIC\>//g' \
1873         -e 's/-fstack-protector-strong\>//g'
1874 }
1875
1876 llvm_check_version_for() {
1877     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1878         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1879     fi
1880 }
1881
1882
1883
1884 if test -z "$with_gallium_drivers"; then
1885     enable_gallium_llvm=no
1886 fi
1887 if test "x$enable_gallium_llvm" = xauto; then
1888     case "$host_cpu" in
1889     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1890     esac
1891 fi
1892 if test "x$enable_gallium_llvm" = xyes; then
1893     if test -n "$llvm_prefix"; then
1894         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1895     else
1896         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1897     fi
1898
1899     if test "x$LLVM_CONFIG" != xno; then
1900         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1901         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1902         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1903         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1904         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1905         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1906         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1907         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1908
1909         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1910             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1911         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1912             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1913
1914         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1915         if test -z "$LLVM_VERSION_PATCH"; then
1916             LLVM_VERSION_PATCH=0
1917         fi
1918
1919         if test -n "${LLVM_VERSION_MAJOR}"; then
1920             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1921         else
1922             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1923         fi
1924
1925         LLVM_REQUIRED_VERSION_MAJOR="3"
1926         LLVM_REQUIRED_VERSION_MINOR="3"
1927         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1928             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1929         fi
1930
1931         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1932
1933         if test "x$enable_opencl" = xyes; then
1934             llvm_check_version_for "3" "5" "0" "opencl"
1935
1936             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1937             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1938         fi
1939         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1940         MESA_LLVM=1
1941
1942         dnl Check for Clang internal headers
1943         if test "x$enable_opencl" = xyes; then
1944             if test -z "$CLANG_LIBDIR"; then
1945                 CLANG_LIBDIR=${LLVM_LIBDIR}
1946             fi
1947             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1948             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1949                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1950         fi
1951     else
1952         MESA_LLVM=0
1953         LLVM_VERSION_INT=0
1954     fi
1955 else
1956     MESA_LLVM=0
1957     LLVM_VERSION_INT=0
1958
1959     if test "x$enable_opencl" = xyes; then
1960         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1961     fi
1962 fi
1963
1964 dnl Directory for XVMC libs
1965 AC_ARG_WITH([xvmc-libdir],
1966     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1967         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1968     [XVMC_LIB_INSTALL_DIR="$withval"],
1969     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1970 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1971
1972 dnl
1973 dnl Gallium Tests
1974 dnl
1975 if test "x$enable_gallium_tests" = xyes; then
1976     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1977     enable_gallium_loader=yes
1978 fi
1979 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1980
1981 dnl Directory for VDPAU libs
1982 AC_ARG_WITH([vdpau-libdir],
1983     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1984         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1985     [VDPAU_LIB_INSTALL_DIR="$withval"],
1986     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1987 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1988
1989 dnl Directory for OMX libs
1990
1991 AC_ARG_WITH([omx-libdir],
1992     [AS_HELP_STRING([--with-omx-libdir=DIR],
1993         [directory for the OMX libraries])],
1994     [OMX_LIB_INSTALL_DIR="$withval"],
1995     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1996 AC_SUBST([OMX_LIB_INSTALL_DIR])
1997
1998 dnl Directory for VA libs
1999
2000 AC_ARG_WITH([va-libdir],
2001     [AS_HELP_STRING([--with-va-libdir=DIR],
2002         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2003     [VA_LIB_INSTALL_DIR="$withval"],
2004     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2005 AC_SUBST([VA_LIB_INSTALL_DIR])
2006
2007 AC_ARG_WITH([d3d-libdir],
2008     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2009         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2010     [D3D_DRIVER_INSTALL_DIR="$withval"],
2011     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2012 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2013
2014 dnl
2015 dnl Gallium helper functions
2016 dnl
2017 gallium_require_drm() {
2018     if test "x$have_libdrm" != xyes; then
2019        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2020     fi
2021 }
2022
2023 gallium_require_llvm() {
2024     if test "x$MESA_LLVM" = x0; then
2025         case "$host" in *gnux32) return;; esac
2026         case "$host_cpu" in
2027         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2028         esac
2029     fi
2030 }
2031
2032 gallium_require_drm_loader() {
2033     if test "x$enable_gallium_loader" = xyes; then
2034         if test "x$need_pci_id$have_pci_id" = xyesno; then
2035             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2036         fi
2037         enable_gallium_drm_loader=yes
2038     fi
2039     if test "x$enable_va" = xyes && test "x$7" != x; then
2040          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2041     fi
2042 }
2043
2044 require_egl_drm() {
2045     case "$with_egl_platforms" in
2046         *drm*)
2047             ;;
2048          *)
2049             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2050             ;;
2051     esac
2052     if test "x$enable_gbm" != xyes; then
2053             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2054     fi
2055 }
2056
2057 radeon_llvm_check() {
2058     if test ${LLVM_VERSION_INT} -lt 307; then
2059         amdgpu_llvm_target_name='r600'
2060     else
2061         amdgpu_llvm_target_name='amdgpu'
2062     fi
2063     if test "x$enable_gallium_llvm" != "xyes"; then
2064         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2065     fi
2066     llvm_check_version_for "3" "4" "2" $1
2067     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2068         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2069     fi
2070     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2071     NEED_RADEON_LLVM=yes
2072     if test "x$have_libelf" != xyes; then
2073        AC_MSG_ERROR([$1 requires libelf when using llvm])
2074     fi
2075 }
2076
2077 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2078 if test -n "$with_gallium_drivers"; then
2079     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2080     for driver in $gallium_drivers; do
2081         case "x$driver" in
2082         xsvga)
2083             HAVE_GALLIUM_SVGA=yes
2084             gallium_require_drm "svga"
2085             gallium_require_drm_loader
2086             ;;
2087         xi915)
2088             HAVE_GALLIUM_I915=yes
2089             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2090             gallium_require_drm "Gallium i915"
2091             gallium_require_drm_loader
2092             ;;
2093         xilo)
2094             HAVE_GALLIUM_ILO=yes
2095             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2096             gallium_require_drm "Gallium i965/ilo"
2097             gallium_require_drm_loader
2098             ;;
2099         xr300)
2100             HAVE_GALLIUM_R300=yes
2101             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2102             gallium_require_drm "Gallium R300"
2103             gallium_require_drm_loader
2104             gallium_require_llvm "Gallium R300"
2105             ;;
2106         xr600)
2107             HAVE_GALLIUM_R600=yes
2108             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2109             gallium_require_drm "Gallium R600"
2110             gallium_require_drm_loader
2111             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2112                 radeon_llvm_check "r600g"
2113                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2114             fi
2115             if test "x$enable_r600_llvm" = xyes; then
2116                 USE_R600_LLVM_COMPILER=yes;
2117             fi
2118             if test "x$enable_opencl" = xyes; then
2119                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2120             fi
2121             ;;
2122         xradeonsi)
2123             HAVE_GALLIUM_RADEONSI=yes
2124             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2125             gallium_require_drm "radeonsi"
2126             gallium_require_drm_loader
2127             radeon_llvm_check "radeonsi"
2128             require_egl_drm "radeonsi"
2129             ;;
2130         xnouveau)
2131             HAVE_GALLIUM_NOUVEAU=yes
2132             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2133             gallium_require_drm "nouveau"
2134             gallium_require_drm_loader
2135             ;;
2136         xfreedreno)
2137             HAVE_GALLIUM_FREEDRENO=yes
2138             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2139             gallium_require_drm "freedreno"
2140             gallium_require_drm_loader
2141             ;;
2142         xswrast)
2143             HAVE_GALLIUM_SOFTPIPE=yes
2144             if test "x$MESA_LLVM" = x1; then
2145                 HAVE_GALLIUM_LLVMPIPE=yes
2146             fi
2147             ;;
2148         xvc4)
2149             HAVE_GALLIUM_VC4=yes
2150             gallium_require_drm "vc4"
2151             gallium_require_drm_loader
2152
2153             case "$host_cpu" in
2154                 i?86 | x86_64 | amd64)
2155                 USE_VC4_SIMULATOR=yes
2156                 ;;
2157             esac
2158             ;;
2159         *)
2160             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2161             ;;
2162         esac
2163     done
2164 fi
2165
2166 dnl Set LLVM_LIBS - This is done after the driver configuration so
2167 dnl that drivers can add additional components to LLVM_COMPONENTS.
2168 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2169 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2170 dnl this was causing the same libraries to be appear multiple times
2171 dnl in LLVM_LIBS.
2172
2173 if test "x$MESA_LLVM" != x0; then
2174
2175     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2176
2177     if test "x$enable_llvm_shared_libs" = xyes; then
2178         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2179         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2180         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2181
2182         if test "x$llvm_have_one_so" = xyes; then
2183             dnl LLVM was built using auto*, so there is only one shared object.
2184             LLVM_LIBS="-l$LLVM_SO_NAME"
2185         else
2186             dnl If LLVM was built with CMake, there will be one shared object per
2187             dnl component.
2188             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2189                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2190         Please make sure you have built llvm with the --enable-shared option
2191         and that your llvm libraries are installed in $LLVM_LIBDIR
2192         If you have installed your llvm libraries to a different directory you
2193         can use the --with-llvm-prefix= configure flag to specify this directory.
2194         NOTE: Mesa is attempting to use llvm shared libraries by default.
2195         If you do not want to build with llvm shared libraries and instead want to
2196         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2197         invocation and rebuild.])])
2198
2199            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2200            dnl install uses a shared object for each component and we have
2201            dnl already added all of these objects to LLVM_LIBS.
2202         fi
2203     else
2204         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2205         dnl We need to link to llvm system libs when using static libs
2206         dnl However, only llvm 3.5+ provides --system-libs
2207         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2208             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2209         fi
2210     fi
2211 fi
2212
2213 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2214 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2215 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2216 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2217 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2218 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2219 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2220                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2221 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2222 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2223 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2224 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2225 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2226
2227 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2228
2229 # NOTE: anything using xcb or other client side libs ends up in separate
2230 #       _CLIENT variables.  The pipe loader is built in two variants,
2231 #       one that is standalone and does not link any x client libs (for
2232 #       use by XA tracker in particular, but could be used in any case
2233 #       where communication with xserver is not desired).
2234 if test "x$enable_gallium_loader" = xyes; then
2235     if test "x$NEED_WINSYS_XLIB" = xyes; then
2236         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2237     fi
2238
2239     if test "x$enable_dri" = xyes; then
2240         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2241     fi
2242
2243     if test "x$enable_gallium_drm_loader" = xyes; then
2244         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2245         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2246                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2247         if test "x$pipe_loader_have_xcb" = xyes; then
2248             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2249             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2250         fi
2251     fi
2252
2253     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2254     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2255
2256     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2257     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2258     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2259     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2260 fi
2261
2262 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2263 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2264 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2265 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2266 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2267 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2268
2269 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2270                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2271                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2272 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2273 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2274 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2275 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2276 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2277 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2278 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2279 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2280 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2281     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2282 fi
2283
2284 AC_SUBST([ELF_LIB])
2285
2286 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2287 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2288 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2289 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2290 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2291
2292 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2293 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2294 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2295
2296 AC_SUBST([NINE_MAJOR], 1)
2297 AC_SUBST([NINE_MINOR], 0)
2298 AC_SUBST([NINE_TINY], 0)
2299 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2300
2301 AC_SUBST([VDPAU_MAJOR], 1)
2302 AC_SUBST([VDPAU_MINOR], 0)
2303
2304 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2305 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2306 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2307 AC_SUBST([VA_MINOR], $VA_MINOR)
2308
2309 AC_SUBST([XVMC_MAJOR], 1)
2310 AC_SUBST([XVMC_MINOR], 0)
2311
2312 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2313 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2314 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2315 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2316
2317 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2318 AC_SUBST([XA_MINOR], $XA_MINOR)
2319 AC_SUBST([XA_TINY], $XA_TINY)
2320 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2321
2322 dnl Restore LDFLAGS and CPPFLAGS
2323 LDFLAGS="$_SAVE_LDFLAGS"
2324 CPPFLAGS="$_SAVE_CPPFLAGS"
2325
2326 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2327 if test "x$acv_mesa_CLANG" = xyes; then
2328     CFLAGS="$CFLAGS -Qunused-arguments"
2329     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2330 fi
2331
2332 dnl Add user CFLAGS and CXXFLAGS
2333 CFLAGS="$CFLAGS $USER_CFLAGS"
2334 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2335
2336 dnl Substitute the config
2337 AC_CONFIG_FILES([Makefile
2338                 src/Makefile
2339                 src/egl/drivers/dri2/Makefile
2340                 src/egl/main/Makefile
2341                 src/egl/main/egl.pc
2342                 src/egl/wayland/wayland-drm/Makefile
2343                 src/egl/wayland/wayland-egl/Makefile
2344                 src/egl/wayland/wayland-egl/wayland-egl.pc
2345                 src/gallium/Makefile
2346                 src/gallium/auxiliary/Makefile
2347                 src/gallium/auxiliary/pipe-loader/Makefile
2348                 src/gallium/drivers/freedreno/Makefile
2349                 src/gallium/drivers/i915/Makefile
2350                 src/gallium/drivers/ilo/Makefile
2351                 src/gallium/drivers/llvmpipe/Makefile
2352                 src/gallium/drivers/noop/Makefile
2353                 src/gallium/drivers/nouveau/Makefile
2354                 src/gallium/drivers/r300/Makefile
2355                 src/gallium/drivers/r600/Makefile
2356                 src/gallium/drivers/radeon/Makefile
2357                 src/gallium/drivers/radeonsi/Makefile
2358                 src/gallium/drivers/rbug/Makefile
2359                 src/gallium/drivers/softpipe/Makefile
2360                 src/gallium/drivers/svga/Makefile
2361                 src/gallium/drivers/trace/Makefile
2362                 src/gallium/drivers/vc4/Makefile
2363                 src/gallium/state_trackers/clover/Makefile
2364                 src/gallium/state_trackers/dri/Makefile
2365                 src/gallium/state_trackers/glx/xlib/Makefile
2366                 src/gallium/state_trackers/nine/Makefile
2367                 src/gallium/state_trackers/omx/Makefile
2368                 src/gallium/state_trackers/osmesa/Makefile
2369                 src/gallium/state_trackers/va/Makefile
2370                 src/gallium/state_trackers/vdpau/Makefile
2371                 src/gallium/state_trackers/xa/Makefile
2372                 src/gallium/state_trackers/xvmc/Makefile
2373                 src/gallium/targets/d3dadapter9/Makefile
2374                 src/gallium/targets/d3dadapter9/d3d.pc
2375                 src/gallium/targets/dri/Makefile
2376                 src/gallium/targets/libgl-xlib/Makefile
2377                 src/gallium/targets/omx/Makefile
2378                 src/gallium/targets/opencl/Makefile
2379                 src/gallium/targets/osmesa/Makefile
2380                 src/gallium/targets/osmesa/osmesa.pc
2381                 src/gallium/targets/pipe-loader/Makefile
2382                 src/gallium/targets/va/Makefile
2383                 src/gallium/targets/vdpau/Makefile
2384                 src/gallium/targets/xa/Makefile
2385                 src/gallium/targets/xa/xatracker.pc
2386                 src/gallium/targets/xvmc/Makefile
2387                 src/gallium/tests/trivial/Makefile
2388                 src/gallium/tests/unit/Makefile
2389                 src/gallium/winsys/freedreno/drm/Makefile
2390                 src/gallium/winsys/i915/drm/Makefile
2391                 src/gallium/winsys/intel/drm/Makefile
2392                 src/gallium/winsys/nouveau/drm/Makefile
2393                 src/gallium/winsys/radeon/drm/Makefile
2394                 src/gallium/winsys/svga/drm/Makefile
2395                 src/gallium/winsys/sw/dri/Makefile
2396                 src/gallium/winsys/sw/kms-dri/Makefile
2397                 src/gallium/winsys/sw/null/Makefile
2398                 src/gallium/winsys/sw/wrapper/Makefile
2399                 src/gallium/winsys/sw/xlib/Makefile
2400                 src/gallium/winsys/vc4/drm/Makefile
2401                 src/gbm/Makefile
2402                 src/gbm/main/gbm.pc
2403                 src/glsl/Makefile
2404                 src/glx/Makefile
2405                 src/glx/apple/Makefile
2406                 src/glx/tests/Makefile
2407                 src/gtest/Makefile
2408                 src/loader/Makefile
2409                 src/mapi/Makefile
2410                 src/mapi/es1api/glesv1_cm.pc
2411                 src/mapi/es2api/glesv2.pc
2412                 src/mapi/glapi/gen/Makefile
2413                 src/mesa/Makefile
2414                 src/mesa/gl.pc
2415                 src/mesa/drivers/dri/dri.pc
2416                 src/mesa/drivers/dri/common/Makefile
2417                 src/mesa/drivers/dri/common/xmlpool/Makefile
2418                 src/mesa/drivers/dri/i915/Makefile
2419                 src/mesa/drivers/dri/i965/Makefile
2420                 src/mesa/drivers/dri/Makefile
2421                 src/mesa/drivers/dri/nouveau/Makefile
2422                 src/mesa/drivers/dri/r200/Makefile
2423                 src/mesa/drivers/dri/radeon/Makefile
2424                 src/mesa/drivers/dri/swrast/Makefile
2425                 src/mesa/drivers/osmesa/Makefile
2426                 src/mesa/drivers/osmesa/osmesa.pc
2427                 src/mesa/drivers/x11/Makefile
2428                 src/mesa/main/tests/Makefile
2429                 src/util/Makefile
2430                 src/util/tests/hash_table/Makefile])
2431
2432 AC_OUTPUT
2433
2434 dnl
2435 dnl Output some configuration info for the user
2436 dnl
2437 echo ""
2438 echo "        prefix:          $prefix"
2439 echo "        exec_prefix:     $exec_prefix"
2440 echo "        libdir:          $libdir"
2441 echo "        includedir:      $includedir"
2442
2443 dnl API info
2444 echo ""
2445 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2446
2447 dnl Driver info
2448 echo ""
2449 case "x$enable_osmesa$enable_gallium_osmesa" in
2450 xnoyes)
2451         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2452         ;;
2453 xyesno)
2454         echo "        OSMesa:          lib$OSMESA_LIB"
2455         ;;
2456 xnono)
2457         echo "        OSMesa:          no"
2458         ;;
2459 esac
2460
2461 echo ""
2462 if test "x$enable_dri" != xno; then
2463         echo "        DRI platform:    $dri_platform"
2464         if test -z "$DRI_DIRS"; then
2465             echo "        DRI drivers:     no"
2466         else
2467             echo "        DRI drivers:     $DRI_DIRS"
2468         fi
2469         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2470 fi
2471
2472 case "x$enable_glx$enable_xlib_glx" in
2473 xyesyes)
2474     echo "        GLX:             Xlib-based"
2475     ;;
2476 xyesno)
2477     echo "        GLX:             DRI-based"
2478     ;;
2479 *)
2480     echo "        GLX:             $enable_glx"
2481     ;;
2482 esac
2483
2484 dnl EGL
2485 echo ""
2486 echo "        EGL:             $enable_egl"
2487 if test "$enable_egl" = yes; then
2488     echo "        EGL platforms:   $egl_platforms"
2489
2490     egl_drivers=""
2491     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2492         egl_drivers="$egl_drivers builtin:egl_dri2"
2493     fi
2494
2495     echo "        EGL drivers:    $egl_drivers"
2496 fi
2497
2498 echo ""
2499 if test "x$MESA_LLVM" = x1; then
2500     echo "        llvm:            yes"
2501     echo "        llvm-config:     $LLVM_CONFIG"
2502     echo "        llvm-version:    $LLVM_VERSION"
2503 else
2504     echo "        llvm:            no"
2505 fi
2506
2507 echo ""
2508 if test -n "$with_gallium_drivers"; then
2509     echo "        Gallium:         yes"
2510 else
2511     echo "        Gallium:         no"
2512 fi
2513
2514 dnl Shader cache
2515 echo ""
2516 echo "        Shader cache:    $enable_shader_cache"
2517 if test "x$enable_shader_cache" = "xyes"; then
2518     echo "        With SHA1 from:  $with_sha1"
2519 fi
2520
2521 dnl Libraries
2522 echo ""
2523 echo "        Shared libs:     $enable_shared"
2524 echo "        Static libs:     $enable_static"
2525 echo "        Shared-glapi:    $enable_shared_glapi"
2526
2527 dnl Compiler options
2528 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2529 cflags=`echo $CFLAGS | \
2530     $SED 's/^ *//;s/  */ /;s/ *$//'`
2531 cxxflags=`echo $CXXFLAGS | \
2532     $SED 's/^ *//;s/  */ /;s/ *$//'`
2533 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2534 echo ""
2535 echo "        CFLAGS:          $cflags"
2536 echo "        CXXFLAGS:        $cxxflags"
2537 echo "        Macros:          $defines"
2538 echo ""
2539 if test "x$MESA_LLVM" = x1; then
2540     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2541     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2542     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2543     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2544     echo ""
2545 fi
2546 echo "        PYTHON2:         $PYTHON2"
2547
2548 echo ""
2549 echo "        Run '${MAKE-make}' to build Mesa"
2550 echo ""