configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  80 DRI2PROTO_REQUIRED=2.6
  81 DRI3PROTO_REQUIRED=1.0
  82 PRESENTPROTO_REQUIRED=1.0
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.11
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.8.0
  94 LIBSENSORS_REQUIRED=4.0.0
  95
  96 dnl LLVM versions
  97 LLVM_REQUIRED_GALLIUM=3.3.0
  98 LLVM_REQUIRED_OPENCL=3.6.0
  99 LLVM_REQUIRED_R600=3.6.0
 100 LLVM_REQUIRED_RADEONSI=3.6.0
 101 LLVM_REQUIRED_RADV=3.9.0
 102 LLVM_REQUIRED_SWR=3.6.0
 103
 104 dnl Check for progs
 105 AC_PROG_CPP
 106 AC_PROG_CC
 107 AC_PROG_CXX
 108 AM_PROG_CC_C_O
 109 AM_PROG_AS
 110 AX_CHECK_GNU_MAKE
 111 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 112 AC_PROG_SED
 113 AC_PROG_MKDIR_P
 114
 115 AC_SYS_LARGEFILE
 116
 117 LT_PREREQ([2.2])
 118 LT_INIT([disable-static])
 119
 120 AC_CHECK_PROG(RM, rm, [rm -f])
 121 AC_CHECK_PROG(XXD, xxd, [xxd])
 122
 123 AX_PROG_BISON([],
 124               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 125                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 126 AX_PROG_FLEX([],
 127              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 128                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 129
 130 AC_CHECK_PROG(INDENT, indent, indent, cat)
 131 if test "x$INDENT" != "xcat"; then
 132     # Only GNU indent is supported
 133     INDENT_VERSION=`indent --version | grep GNU`
 134     if test $? -eq 0; then
 135        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 136     else
 137        INDENT="cat"
 138     fi
 139 fi
 140
 141 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 142
 143 if test -z "$PYTHON2"; then
 144     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 145         AC_MSG_ERROR([Python not found - unable to generate sources])
 146     fi
 147 else
 148     if test "x$acv_mako_found" = xno; then
 149         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 150             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 151         fi
 152     fi
 153 fi
 154
 155 AC_PROG_INSTALL
 156
 157 dnl We need a POSIX shell for parts of the build. Assume we have one
 158 dnl in most cases.
 159 case "$host_os" in
 160 solaris*)
 161     # Solaris /bin/sh is too old/non-POSIX compliant
 162     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 163     SHELL="$POSIX_SHELL"
 164     ;;
 165 esac
 166
 167 dnl clang is mostly GCC-compatible, but its version is much lower,
 168 dnl so we have to check for it.
 169 AC_MSG_CHECKING([if compiling with clang])
 170
 171 AC_COMPILE_IFELSE(
 172 [AC_LANG_PROGRAM([], [[
 173 #ifndef __clang__
 174        not clang
 175 #endif
 176 ]])],
 177 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 178
 179 AC_MSG_RESULT([$acv_mesa_CLANG])
 180
 181 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 182 dnl versions are explictly not supported.
 183 GEN_ASM_OFFSETS=no
 184 USE_GNU99=no
 185 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 186     AC_MSG_CHECKING([whether gcc version is sufficient])
 187     major=0
 188     minor=0
 189
 190     GCC_VERSION=`$CC -dumpversion`
 191     if test $? -eq 0; then
 192         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 193         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 194     fi
 195
 196     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 197         AC_MSG_RESULT([no])
 198         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 199     else
 200         AC_MSG_RESULT([yes])
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 204         USE_GNU99=yes
 205     fi
 206     if test "x$cross_compiling" = xyes; then
 207         GEN_ASM_OFFSETS=yes
 208     fi
 209 fi
 210
 211 dnl We don't support building Mesa with Sun C compiler
 212 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 213 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 214 if test "x$SUNCC" = xyes; then
 215     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 216 fi
 217
 218 dnl Check for compiler builtins
 219 AX_GCC_BUILTIN([__builtin_bswap32])
 220 AX_GCC_BUILTIN([__builtin_bswap64])
 221 AX_GCC_BUILTIN([__builtin_clz])
 222 AX_GCC_BUILTIN([__builtin_clzll])
 223 AX_GCC_BUILTIN([__builtin_ctz])
 224 AX_GCC_BUILTIN([__builtin_expect])
 225 AX_GCC_BUILTIN([__builtin_ffs])
 226 AX_GCC_BUILTIN([__builtin_ffsll])
 227 AX_GCC_BUILTIN([__builtin_popcount])
 228 AX_GCC_BUILTIN([__builtin_popcountll])
 229 AX_GCC_BUILTIN([__builtin_unreachable])
 230
 231 AX_GCC_FUNC_ATTRIBUTE([const])
 232 AX_GCC_FUNC_ATTRIBUTE([flatten])
 233 AX_GCC_FUNC_ATTRIBUTE([format])
 234 AX_GCC_FUNC_ATTRIBUTE([malloc])
 235 AX_GCC_FUNC_ATTRIBUTE([packed])
 236 AX_GCC_FUNC_ATTRIBUTE([pure])
 237 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 238 AX_GCC_FUNC_ATTRIBUTE([unused])
 239 AX_GCC_FUNC_ATTRIBUTE([visibility])
 240 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 241 AX_GCC_FUNC_ATTRIBUTE([weak])
 242
 243 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 244
 245 dnl Make sure the pkg-config macros are defined
 246 m4_ifndef([PKG_PROG_PKG_CONFIG],
 247     [m4_fatal([Could not locate the pkg-config autoconf macros.
 248   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 249   are in a different location, try setting the environment variable
 250   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 251 PKG_PROG_PKG_CONFIG()
 252
 253 dnl LIB_DIR - library basename
 254 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 255 AC_SUBST([LIB_DIR])
 256
 257 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 258 _SAVE_LDFLAGS="$LDFLAGS"
 259 _SAVE_CPPFLAGS="$CPPFLAGS"
 260
 261 dnl Compiler macros
 262 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 263 AC_SUBST([DEFINES])
 264 android=no
 265 case "$host_os" in
 266 *-android)
 267     android=yes
 268     ;;
 269 linux*|*-gnu*|gnu*|cygwin*)
 270     DEFINES="$DEFINES -D_GNU_SOURCE"
 271     ;;
 272 solaris*)
 273     DEFINES="$DEFINES -DSVR4"
 274     ;;
 275 esac
 276
 277 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 278
 279 dnl Add flags for gcc and g++
 280 if test "x$GCC" = xyes; then
 281     CFLAGS="$CFLAGS -Wall"
 282
 283     if test "x$USE_GNU99" = xyes; then
 284         CFLAGS="$CFLAGS -std=gnu99"
 285     else
 286         CFLAGS="$CFLAGS -std=c99"
 287     fi
 288
 289     # Enable -Werror=implicit-function-declaration and
 290     # -Werror=missing-prototypes, if available, or otherwise, just
 291     # -Wmissing-prototypes.  This is particularly useful to avoid
 292     # generating a loadable driver module that has undefined symbols.
 293     save_CFLAGS="$CFLAGS"
 294     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 295     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 296     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 297     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 298                    AC_MSG_RESULT([yes]),
 299                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 300                     AC_MSG_RESULT([no])]);
 301
 302     # Enable -fvisibility=hidden if using a gcc that supports it
 303     save_CFLAGS="$CFLAGS"
 304     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 305     VISIBILITY_CFLAGS="-fvisibility=hidden"
 306     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 307     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 308                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 309
 310     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 311     CFLAGS=$save_CFLAGS
 312
 313     # We don't want floating-point math functions to set errno or trap
 314     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 315
 316     # Flags to help ensure that certain portions of the code -- and only those
 317     # portions -- can be built with MSVC:
 318     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 319     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 320     #   supports most of C99)
 321     # - the rest has no compiler compiler restrictions
 322     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 323     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 324
 325     # Enable -Werror=vla if compiler supports it
 326     save_CFLAGS="$CFLAGS"
 327     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 328     CFLAGS="$CFLAGS -Werror=vla"
 329     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 330                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 331                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 332                     AC_MSG_RESULT([yes])],
 333                     AC_MSG_RESULT([no]));
 334     CFLAGS="$save_CFLAGS"
 335 fi
 336 if test "x$GXX" = xyes; then
 337     CXXFLAGS="$CXXFLAGS -Wall"
 338
 339     # Enable -fvisibility=hidden if using a gcc that supports it
 340     save_CXXFLAGS="$CXXFLAGS"
 341     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 342     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 343     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 344     AC_LANG_PUSH([C++])
 345     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 346                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 347     AC_LANG_POP([C++])
 348
 349     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 350     CXXFLAGS=$save_CXXFLAGS
 351
 352     # We don't want floating-point math functions to set errno or trap
 353     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 354 fi
 355
 356 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 357 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 358
 359 dnl even if the compiler appears to support it, using visibility attributes isn't
 360 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 361 case "$host_os" in
 362 cygwin*)
 363     VISIBILITY_CFLAGS=""
 364     VISIBILITY_CXXFLAGS=""
 365     ;;
 366 esac
 367
 368 AC_SUBST([VISIBILITY_CFLAGS])
 369 AC_SUBST([VISIBILITY_CXXFLAGS])
 370
 371 dnl
 372 dnl Optional flags, check for compiler support
 373 dnl
 374 SSE41_CFLAGS="-msse4.1"
 375 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 376 dnl stack, but on x86-32 such alignment is not guaranteed.
 377 case "$target_cpu" in
 378 i?86)
 379     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 380     ;;
 381 esac
 382 save_CFLAGS="$CFLAGS"
 383 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 384 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 385 #include <smmintrin.h>
 386 int param;
 387 int main () {
 388     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 389     c = _mm_max_epu32(a, b);
 390     return _mm_cvtsi128_si32(c);
 391 }]])], SSE41_SUPPORTED=1)
 392 CFLAGS="$save_CFLAGS"
 393 if test "x$SSE41_SUPPORTED" = x1; then
 394     DEFINES="$DEFINES -DUSE_SSE41"
 395 fi
 396 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 397 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 398
 399 dnl Check for new-style atomic builtins
 400 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 401 int main() {
 402     int n;
 403     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 404 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 405 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 406     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 407 fi
 408 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 409
 410 dnl Check for Endianness
 411 AC_C_BIGENDIAN(
 412    little_endian=no,
 413    little_endian=yes,
 414    little_endian=no,
 415    little_endian=no
 416 )
 417
 418 dnl Check for POWER8 Architecture
 419 PWR8_CFLAGS="-mpower8-vector"
 420 have_pwr8_intrinsics=no
 421 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 422 save_CFLAGS=$CFLAGS
 423 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 424 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 425 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 426 #error "Need GCC >= 4.8 for sane POWER8 support"
 427 #endif
 428 #include <altivec.h>
 429 int main () {
 430     vector unsigned char r;
 431     vector unsigned int v = vec_splat_u32 (1);
 432     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 433     return 0;
 434 }]])], have_pwr8_intrinsics=yes)
 435 CFLAGS=$save_CFLAGS
 436
 437 AC_ARG_ENABLE(pwr8,
 438    [AC_HELP_STRING([--disable-pwr8-inst],
 439                    [disable POWER8-specific instructions])],
 440    [enable_pwr8=$enableval], [enable_pwr8=auto])
 441
 442 if test "x$enable_pwr8" = xno ; then
 443    have_pwr8_intrinsics=disabled
 444 fi
 445
 446 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 447    DEFINES="$DEFINES -D_ARCH_PWR8"
 448    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 449    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 450 else
 451    PWR8_CFLAGS=
 452 fi
 453
 454 AC_MSG_RESULT($have_pwr8_intrinsics)
 455 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 456    AC_MSG_ERROR([POWER8 compiler support not detected])
 457 fi
 458
 459 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 460    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 461 fi
 462
 463 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 464
 465 dnl Can't have static and shared libraries, default to static if user
 466 dnl explicitly requested. If both disabled, set to static since shared
 467 dnl was explicitly requested.
 468 case "x$enable_static$enable_shared" in
 469 xyesyes)
 470     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 471     enable_shared=no
 472     ;;
 473 xnono)
 474     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 475     enable_shared=yes
 476     ;;
 477 esac
 478
 479 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 480
 481 dnl
 482 dnl other compiler options
 483 dnl
 484 AC_ARG_ENABLE([debug],
 485     [AS_HELP_STRING([--enable-debug],
 486         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 487     [enable_debug="$enableval"],
 488     [enable_debug=no]
 489 )
 490
 491 AC_ARG_ENABLE([profile],
 492     [AS_HELP_STRING([--enable-profile],
 493         [enable profiling of code @<:@default=disabled@:>@])],
 494     [enable_profile="$enableval"],
 495     [enable_profile=no]
 496 )
 497
 498 if test "x$enable_profile" = xyes; then
 499     DEFINES="$DEFINES -DPROFILE"
 500     if test "x$GCC" = xyes; then
 501         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 502     fi
 503     if test "x$GXX" = xyes; then
 504         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 505     fi
 506 fi
 507
 508 if test "x$enable_debug" = xyes; then
 509     DEFINES="$DEFINES -DDEBUG"
 510     if test "x$enable_profile" = xyes; then
 511         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 512     fi
 513     if test "x$GCC" = xyes; then
 514         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 515             CFLAGS="$CFLAGS -g"
 516         fi
 517         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 518             CFLAGS="$CFLAGS -O0"
 519         fi
 520     fi
 521     if test "x$GXX" = xyes; then
 522         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 523             CXXFLAGS="$CXXFLAGS -g"
 524         fi
 525         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 526             CXXFLAGS="$CXXFLAGS -O0"
 527         fi
 528     fi
 529 else
 530    DEFINES="$DEFINES -DNDEBUG"
 531 fi
 532
 533 DEFAULT_GL_LIB_NAME=GL
 534
 535 dnl
 536 dnl Check if linker supports -Bsymbolic
 537 dnl
 538 save_LDFLAGS=$LDFLAGS
 539 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 540 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 541 AC_LINK_IFELSE(
 542     [AC_LANG_SOURCE([int main() { return 0;}])],
 543     [AC_MSG_RESULT([yes])
 544         BSYMBOLIC="-Wl,-Bsymbolic";],
 545     [AC_MSG_RESULT([no])
 546         BSYMBOLIC="";])
 547 LDFLAGS=$save_LDFLAGS
 548
 549 AC_SUBST([BSYMBOLIC])
 550
 551 dnl
 552 dnl Check if linker supports garbage collection
 553 dnl
 554 save_LDFLAGS=$LDFLAGS
 555 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 556 AC_MSG_CHECKING([whether ld supports --gc-sections])
 557 AC_LINK_IFELSE(
 558     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 559     [AC_MSG_RESULT([yes])
 560         GC_SECTIONS="-Wl,--gc-sections";],
 561     [AC_MSG_RESULT([no])
 562         GC_SECTIONS="";])
 563 LDFLAGS=$save_LDFLAGS
 564
 565 AC_SUBST([GC_SECTIONS])
 566
 567 dnl
 568 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 569 dnl so when these flags are passed to ld via libtool the checks will fail
 570 dnl
 571 case "$host_os" in
 572 openbsd* | darwin* )
 573     LD_NO_UNDEFINED="" ;;
 574 *)
 575     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 576 esac
 577
 578 AC_SUBST([LD_NO_UNDEFINED])
 579
 580 dnl
 581 dnl Check if linker supports version scripts
 582 dnl
 583 AC_MSG_CHECKING([if the linker supports version-scripts])
 584 save_LDFLAGS=$LDFLAGS
 585 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 586 cat > conftest.map <<EOF
 587 VERSION_1 {
 588      global:
 589          main;
 590
 591      local:
 592          *;
 593 };
 594 EOF
 595 AC_LINK_IFELSE(
 596     [AC_LANG_SOURCE([int main() { return 0;}])],
 597     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 598     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 599 LDFLAGS=$save_LDFLAGS
 600 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 601
 602 dnl
 603 dnl Check if linker supports dynamic list files
 604 dnl
 605 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 606 save_LDFLAGS=$LDFLAGS
 607 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 608 cat > conftest.dyn <<EOF
 609 {
 610         radeon_drm_winsys_create;
 611 };
 612 EOF
 613 AC_LINK_IFELSE(
 614     [AC_LANG_SOURCE([int main() { return 0;}])],
 615     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 616     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 617 LDFLAGS=$save_LDFLAGS
 618 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 619
 620 dnl
 621 dnl compatibility symlinks
 622 dnl
 623 case "$host_os" in
 624 linux* )
 625     HAVE_COMPAT_SYMLINKS=yes ;;
 626 * )
 627     HAVE_COMPAT_SYMLINKS=no ;;
 628 esac
 629
 630 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 631
 632 DEFAULT_GL_LIB_NAME=GL
 633
 634 dnl
 635 dnl Libglvnd configuration
 636 dnl
 637 AC_ARG_ENABLE([libglvnd],
 638     [AS_HELP_STRING([--enable-libglvnd],
 639         [Build for libglvnd @<:@default=disabled@:>@])],
 640     [enable_libglvnd="$enableval"],
 641     [enable_libglvnd=no])
 642 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 643 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 644 if test "x$enable_libglvnd" = xyes ; then
 645     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 646     DEFAULT_GL_LIB_NAME=GLX_mesa
 647 fi
 648
 649 dnl
 650 dnl library names
 651 dnl
 652 dnl Unfortunately we need to do a few things that libtool can't help us with,
 653 dnl so we need some knowledge of shared library filenames:
 654 dnl
 655 dnl LIB_EXT is the extension used when creating symlinks for alternate
 656 dnl filenames for a shared library which will be dynamically loaded
 657 dnl
 658 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 659 dnl the file for a shared library we wish to link with
 660 dnl
 661 case "$host_os" in
 662 darwin* )
 663     LIB_EXT='dylib'
 664     IMP_LIB_EXT=$LIB_EXT
 665     ;;
 666 cygwin* )
 667     LIB_EXT='dll'
 668     IMP_LIB_EXT='dll.a'
 669     ;;
 670 aix* )
 671     LIB_EXT='a'
 672     IMP_LIB_EXT=$LIB_EXT
 673     ;;
 674 * )
 675     LIB_EXT='so'
 676     IMP_LIB_EXT=$LIB_EXT
 677     ;;
 678 esac
 679
 680 AC_SUBST([LIB_EXT])
 681
 682 AC_ARG_WITH([gl-lib-name],
 683   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 684     [specify GL library name @<:@default=GL@:>@])],
 685   [GL_LIB=$withval],
 686   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 687 AC_ARG_WITH([osmesa-lib-name],
 688   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 689     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 690   [OSMESA_LIB=$withval],
 691   [OSMESA_LIB=OSMesa])
 692 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 693 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 694
 695 dnl
 696 dnl Mangled Mesa support
 697 dnl
 698 AC_ARG_ENABLE([mangling],
 699   [AS_HELP_STRING([--enable-mangling],
 700     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 701   [enable_mangling="${enableval}"],
 702   [enable_mangling=no]
 703 )
 704 if test "x${enable_mangling}" = "xyes" ; then
 705   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 706   GL_LIB="Mangled${GL_LIB}"
 707   OSMESA_LIB="Mangled${OSMESA_LIB}"
 708 fi
 709 AC_SUBST([GL_LIB])
 710 AC_SUBST([OSMESA_LIB])
 711
 712 dnl
 713 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 714 dnl
 715 AC_ARG_ENABLE([texture-float],
 716     [AS_HELP_STRING([--enable-texture-float],
 717         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 718     [enable_texture_float="$enableval"],
 719     [enable_texture_float=no]
 720 )
 721 if test "x$enable_texture_float" = xyes; then
 722     AC_MSG_WARN([Floating-point textures enabled.])
 723     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 724     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 725 fi
 726
 727 dnl
 728 dnl Arch/platform-specific settings
 729 dnl
 730 AC_ARG_ENABLE([asm],
 731     [AS_HELP_STRING([--disable-asm],
 732         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 733     [enable_asm="$enableval"],
 734     [enable_asm=yes]
 735 )
 736 asm_arch=""
 737 AC_MSG_CHECKING([whether to enable assembly])
 738 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 739 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 740 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 741     case "$host_cpu" in
 742     i?86 | x86_64 | amd64)
 743         if test "x$host_cpu" != "x$target_cpu"; then
 744             enable_asm=no
 745             AC_MSG_RESULT([no, cross compiling])
 746         fi
 747         ;;
 748     esac
 749 fi
 750 # check for supported arches
 751 if test "x$enable_asm" = xyes; then
 752     case "$host_cpu" in
 753     i?86)
 754         case "$host_os" in
 755         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 756             asm_arch=x86
 757             ;;
 758         esac
 759         ;;
 760     x86_64|amd64)
 761         case "$host_os" in
 762         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 763             asm_arch=x86_64
 764             ;;
 765         esac
 766         ;;
 767     sparc*)
 768         case "$host_os" in
 769         linux*)
 770             asm_arch=sparc
 771             ;;
 772         esac
 773         ;;
 774     esac
 775
 776     case "$asm_arch" in
 777     x86)
 778         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 779         AC_MSG_RESULT([yes, x86])
 780         ;;
 781     x86_64|amd64)
 782         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 783         AC_MSG_RESULT([yes, x86_64])
 784         ;;
 785     sparc)
 786         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 787         AC_MSG_RESULT([yes, sparc])
 788         ;;
 789     *)
 790         AC_MSG_RESULT([no, platform not supported])
 791         ;;
 792     esac
 793 fi
 794
 795 AC_HEADER_MAJOR
 796 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 797 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 798 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 799 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 800
 801 dnl Check to see if dlopen is in default libraries (like Solaris, which
 802 dnl has it in libc), or if libdl is needed to get it.
 803 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 804     [AC_CHECK_LIB([dl], [dlopen],
 805        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 806 AC_SUBST([DLOPEN_LIBS])
 807
 808 dnl Check if that library also has dladdr
 809 save_LIBS="$LIBS"
 810 LIBS="$LIBS $DLOPEN_LIBS"
 811 AC_CHECK_FUNCS([dladdr])
 812 LIBS="$save_LIBS"
 813
 814 case "$host_os" in
 815 darwin*)
 816     ;;
 817 *)
 818     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 819                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 820                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 821     AC_SUBST([CLOCK_LIB])
 822     ;;
 823 esac
 824
 825 dnl See if posix_memalign is available
 826 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on targets where it exists
 842 case "$host_os" in
 843 cygwin* )
 844     pthread_stubs_possible="no"
 845     ;;
 846 * )
 847     pthread_stubs_possible="yes"
 848     ;;
 849 esac
 850
 851 if test "x$pthread_stubs_possible" = xyes; then
 852     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 853     AC_SUBST(PTHREADSTUBS_CFLAGS)
 854     AC_SUBST(PTHREADSTUBS_LIBS)
 855 fi
 856
 857 dnl SELinux awareness.
 858 AC_ARG_ENABLE([selinux],
 859     [AS_HELP_STRING([--enable-selinux],
 860         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 861     [MESA_SELINUX="$enableval"],
 862     [MESA_SELINUX=no])
 863 if test "x$enable_selinux" = "xyes"; then
 864     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 865         [AC_CHECK_HEADER([selinux/selinux.h],[],
 866                          [AC_MSG_ERROR([SELinux headers not found])])
 867          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 868                       [AC_MSG_ERROR([SELinux library not found])])
 869          SELINUX_LIBS="-lselinux"])
 870     DEFINES="$DEFINES -DMESA_SELINUX"
 871 fi
 872 AC_SUBST([SELINUX_CFLAGS])
 873 AC_SUBST([SELINUX_LIBS])
 874
 875 dnl
 876 dnl LLVM
 877 dnl
 878 AC_ARG_ENABLE([llvm-shared-libs],
 879     [AS_HELP_STRING([--enable-llvm-shared-libs],
 880         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 881     [enable_llvm_shared_libs="$enableval"],
 882     [enable_llvm_shared_libs=yes])
 883
 884 AC_ARG_WITH([llvm-prefix],
 885     [AS_HELP_STRING([--with-llvm-prefix],
 886         [Prefix for LLVM installations in non-standard locations])],
 887     [llvm_prefix="$withval"],
 888     [llvm_prefix=''])
 889
 890 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 891 if test "x$have_libelf" = xno; then
 892    LIBELF_LIBS=''
 893    LIBELF_CFLAGS=''
 894    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 895    AC_SUBST([LIBELF_LIBS])
 896    AC_SUBST([LIBELF_CFLAGS])
 897 fi
 898
 899 if test -z "$LLVM_CONFIG"; then
 900     if test -n "$llvm_prefix"; then
 901         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 902     else
 903         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 904     fi
 905 fi
 906
 907 llvm_add_component() {
 908     new_llvm_component=$1
 909     driver_name=$2
 910
 911     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 912         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 913     else
 914         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 915     fi
 916 }
 917
 918 llvm_add_default_components() {
 919     driver_name=$1
 920
 921     # Required default components
 922     llvm_add_component "bitwriter" $driver_name
 923     llvm_add_component "engine" $driver_name
 924     llvm_add_component "mcdisassembler" $driver_name
 925     llvm_add_component "mcjit" $driver_name
 926
 927     # Optional default components
 928     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 929         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 930     fi
 931 }
 932
 933 llvm_add_target() {
 934     new_llvm_target=$1
 935     driver_name=$2
 936
 937     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 938         llvm_add_component $new_llvm_target $driver_name
 939     else
 940         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 941     fi
 942 }
 943
 944 # Call this inside ` ` to get the return value.
 945 # $1 is the llvm-config command with arguments.
 946 strip_unwanted_llvm_flags() {
 947     # Use \> (marks the end of the word)
 948     echo `$1` | sed \
 949         -e 's/-march=\S*//g' \
 950         -e 's/-mtune=\S*//g' \
 951         -e 's/-mcpu=\S*//g' \
 952         -e 's/-DNDEBUG\>//g' \
 953         -e 's/-D_GNU_SOURCE\>//g' \
 954         -e 's/-pedantic\>//g' \
 955         -e 's/-Wcovered-switch-default\>//g' \
 956         -e 's/-O.\>//g' \
 957         -e 's/-g\>//g' \
 958         -e 's/-Wall\>//g' \
 959         -e 's/-Wcast-qual\>//g' \
 960         -e 's/-Woverloaded-virtual\>//g' \
 961         -e 's/-fcolor-diagnostics\>//g' \
 962         -e 's/-fdata-sections\>//g' \
 963         -e 's/-ffunction-sections\>//g' \
 964         -e 's/-fno-exceptions\>//g' \
 965         -e 's/-fomit-frame-pointer\>//g' \
 966         -e 's/-fvisibility-inlines-hidden\>//g' \
 967         -e 's/-fPIC\>//g' \
 968         -e 's/-fstack-protector-strong\>//g'
 969 }
 970
 971 llvm_set_environment_variables() {
 972     if test "x$LLVM_CONFIG" != xno; then
 973         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 974         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 975         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 976         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 977         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 978         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 979         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 980         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 981
 982         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 983             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 984         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 985             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 986         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 987             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 988
 989         # Only needed for LLVM < 3.6.0
 990         if test -z "$LLVM_VERSION_PATCH"; then
 991             LLVM_VERSION_PATCH=0
 992         fi
 993
 994         if test "$LLVM_VERSION_MINOR" -lt 10; then
 995             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 996         else
 997             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
 998         fi
 999
1000         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1001         FOUND_LLVM=yes
1002         USE_LLVM=no
1003     else
1004         FOUND_LLVM=no
1005         USE_LLVM=no
1006         LLVM_VERSION_INT=0
1007     fi
1008 }
1009
1010 llvm_require_version() {
1011     USE_LLVM=yes
1012
1013     if test "x$FOUND_LLVM" = xno; then
1014         AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1015         return
1016     fi
1017
1018     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1019     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1020     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1021
1022     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1023         # major > required major
1024         #  --> OK
1025         return
1026     fi
1027
1028     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1029         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1030             # major = required major and
1031             # minor > required minor
1032             #  --> OK
1033             return
1034         else
1035             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1036                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1037                     # major = required major and
1038                     # minor = required minor and
1039                     # patch >= required patch
1040                     #  --> OK
1041                     return
1042                 fi
1043             fi
1044         fi
1045     fi
1046
1047     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1048 }
1049
1050 radeon_llvm_check() {
1051     if test ${LLVM_VERSION_INT} -lt 307; then
1052         amdgpu_llvm_target_name='r600'
1053     else
1054         amdgpu_llvm_target_name='amdgpu'
1055     fi
1056
1057     llvm_require_version $*
1058
1059     llvm_add_target $amdgpu_llvm_target_name $2
1060
1061     llvm_add_default_components $2
1062     llvm_add_component "bitreader" $2
1063     llvm_add_component "ipo" $2
1064
1065     NEED_RADEON_LLVM=yes
1066     if test "x$have_libelf" != xyes; then
1067        AC_MSG_ERROR([$1 requires libelf when using llvm])
1068     fi
1069 }
1070
1071 llvm_set_environment_variables
1072
1073 AC_SUBST([LLVM_BINDIR])
1074 AC_SUBST([LLVM_CFLAGS])
1075 AC_SUBST([LLVM_CPPFLAGS])
1076 AC_SUBST([LLVM_CXXFLAGS])
1077 AC_SUBST([LLVM_LIBDIR])
1078 AC_SUBST([LLVM_LIBS])
1079 AC_SUBST([LLVM_LDFLAGS])
1080 AC_SUBST([LLVM_INCLUDEDIR])
1081 AC_SUBST([LLVM_VERSION])
1082
1083 dnl Options for APIs
1084 AC_ARG_ENABLE([opengl],
1085     [AS_HELP_STRING([--disable-opengl],
1086         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1087     [enable_opengl="$enableval"],
1088     [enable_opengl=yes])
1089 AC_ARG_ENABLE([gles1],
1090     [AS_HELP_STRING([--disable-gles1],
1091         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1092     [enable_gles1="$enableval"],
1093     [enable_gles1=yes])
1094 AC_ARG_ENABLE([gles2],
1095     [AS_HELP_STRING([--disable-gles2],
1096         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1097     [enable_gles2="$enableval"],
1098     [enable_gles2=yes])
1099
1100 AC_ARG_ENABLE([dri],
1101     [AS_HELP_STRING([--enable-dri],
1102         [enable DRI modules @<:@default=enabled@:>@])],
1103     [enable_dri="$enableval"],
1104     [enable_dri=yes])
1105
1106 AC_ARG_ENABLE([gallium-extra-hud],
1107     [AS_HELP_STRING([--enable-gallium-extra-hud],
1108         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1109     [enable_gallium_extra_hud="$enableval"],
1110     [enable_gallium_extra_hud=no])
1111 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1112 if test "x$enable_gallium_extra_hud" = xyes ; then
1113     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1114 fi
1115
1116 #TODO: no pkgconfig .pc available for libsensors.
1117 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1118 AC_ARG_ENABLE([lmsensors],
1119     [AS_HELP_STRING([--enable-lmsensors],
1120         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1121     [enable_lmsensors="$enableval"],
1122     [enable_lmsensors=no])
1123 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1124 if test "x$enable_lmsensors" = xyes ; then
1125     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1126     LIBSENSORS_LDFLAGS="-lsensors"
1127 else
1128     LIBSENSORS_LDFLAGS=""
1129 fi
1130 AC_SUBST(LIBSENSORS_LDFLAGS)
1131
1132 case "$host_os" in
1133 linux*)
1134     dri3_default=yes
1135     ;;
1136 *)
1137     dri3_default=no
1138     ;;
1139 esac
1140
1141 if test "x$enable_dri" = xno; then
1142     dri3_default=no
1143 fi
1144
1145 AC_ARG_ENABLE([dri3],
1146     [AS_HELP_STRING([--enable-dri3],
1147         [enable DRI3 @<:@default=auto@:>@])],
1148     [enable_dri3="$enableval"],
1149     [enable_dri3="$dri3_default"])
1150 AC_ARG_ENABLE([glx],
1151     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1152         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1153     [enable_glx="$enableval"],
1154     [enable_glx=yes])
1155 AC_ARG_ENABLE([osmesa],
1156     [AS_HELP_STRING([--enable-osmesa],
1157         [enable OSMesa library @<:@default=disabled@:>@])],
1158     [enable_osmesa="$enableval"],
1159     [enable_osmesa=no])
1160 AC_ARG_ENABLE([gallium-osmesa],
1161     [AS_HELP_STRING([--enable-gallium-osmesa],
1162         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1163     [enable_gallium_osmesa="$enableval"],
1164     [enable_gallium_osmesa=no])
1165 AC_ARG_ENABLE([egl],
1166     [AS_HELP_STRING([--disable-egl],
1167         [disable EGL library @<:@default=enabled@:>@])],
1168     [enable_egl="$enableval"],
1169     [enable_egl=yes])
1170
1171 AC_ARG_ENABLE([xa],
1172     [AS_HELP_STRING([--enable-xa],
1173         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1174     [enable_xa="$enableval"],
1175     [enable_xa=no])
1176 AC_ARG_ENABLE([gbm],
1177    [AS_HELP_STRING([--enable-gbm],
1178          [enable gbm library @<:@default=yes except cygwin@:>@])],
1179    [enable_gbm="$enableval"],
1180    [case "$host_os" in
1181        cygwin*)
1182           enable_gbm=no
1183           ;;
1184        *)
1185           enable_gbm=yes
1186           ;;
1187     esac])
1188 AC_ARG_ENABLE([nine],
1189     [AS_HELP_STRING([--enable-nine],
1190         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1191     [enable_nine="$enableval"],
1192     [enable_nine=no])
1193
1194 AC_ARG_ENABLE([xvmc],
1195    [AS_HELP_STRING([--enable-xvmc],
1196          [enable xvmc library @<:@default=auto@:>@])],
1197    [enable_xvmc="$enableval"],
1198    [enable_xvmc=auto])
1199 AC_ARG_ENABLE([vdpau],
1200    [AS_HELP_STRING([--enable-vdpau],
1201          [enable vdpau library @<:@default=auto@:>@])],
1202    [enable_vdpau="$enableval"],
1203    [enable_vdpau=auto])
1204 AC_ARG_ENABLE([omx],
1205    [AS_HELP_STRING([--enable-omx],
1206          [enable OpenMAX library @<:@default=disabled@:>@])],
1207    [enable_omx="$enableval"],
1208    [enable_omx=no])
1209 AC_ARG_ENABLE([va],
1210    [AS_HELP_STRING([--enable-va],
1211          [enable va library @<:@default=auto@:>@])],
1212    [enable_va="$enableval"],
1213    [enable_va=auto])
1214 AC_ARG_ENABLE([opencl],
1215    [AS_HELP_STRING([--enable-opencl],
1216          [enable OpenCL library @<:@default=disabled@:>@])],
1217    [enable_opencl="$enableval"],
1218    [enable_opencl=no])
1219 AC_ARG_ENABLE([opencl_icd],
1220    [AS_HELP_STRING([--enable-opencl-icd],
1221           [Build an OpenCL ICD library to be loaded by an ICD implementation
1222            @<:@default=disabled@:>@])],
1223     [enable_opencl_icd="$enableval"],
1224     [enable_opencl_icd=no])
1225
1226 AC_ARG_ENABLE([gallium-tests],
1227     [AS_HELP_STRING([--enable-gallium-tests],
1228         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1229     [enable_gallium_tests="$enableval"],
1230     [enable_gallium_tests=no])
1231
1232 # Option for Gallium drivers
1233
1234 # Keep this in sync with the --with-gallium-drivers help string default value
1235 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1236
1237 AC_ARG_WITH([gallium-drivers],
1238     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1239         [comma delimited Gallium drivers list, e.g.
1240         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl,etnaviv,imx"
1241         @<:@default=r300,r600,svga,swrast@:>@])],
1242     [with_gallium_drivers="$withval"],
1243     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1244
1245 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1246 # here so that the script doesn't choke on an unknown driver name later.
1247 case "$with_gallium_drivers" in
1248     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1249     no) with_gallium_drivers='' ;;
1250 esac
1251
1252 if test "x$enable_opengl" = xno -a \
1253         "x$enable_gles1" = xno -a \
1254         "x$enable_gles2" = xno -a \
1255         "x$enable_nine" = xno -a \
1256         "x$enable_xa" = xno -a \
1257         "x$enable_xvmc" = xno -a \
1258         "x$enable_vdpau" = xno -a \
1259         "x$enable_omx" = xno -a \
1260         "x$enable_va" = xno -a \
1261         "x$enable_opencl" = xno; then
1262     AC_MSG_ERROR([at least one API should be enabled])
1263 fi
1264
1265 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1266 if test "x$enable_opengl" = xno -a \
1267         "x$enable_gles1" = xyes; then
1268     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1269 fi
1270
1271 if test "x$enable_opengl" = xno -a \
1272         "x$enable_gles2" = xyes; then
1273     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1274 fi
1275
1276 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1277 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1278 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1279 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1280                                         "x$enable_gles1" = xyes -o \
1281                                         "x$enable_gles2" = xyes)
1282
1283 # Validate GLX options
1284 if test "x$enable_glx" = xyes; then
1285     if test "x$enable_dri" = xyes; then
1286         enable_glx=dri
1287     elif test -n "$with_gallium_drivers"; then
1288         enable_glx=gallium-xlib
1289     else
1290         enable_glx=xlib
1291     fi
1292 fi
1293 case "x$enable_glx" in
1294 xdri | xxlib | xgallium-xlib)
1295     # GLX requires OpenGL
1296     if test "x$enable_opengl" = xno; then
1297         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1298     fi
1299
1300     # Check individual dependencies
1301     case "x$enable_glx" in
1302     xdri)
1303         if test "x$enable_dri" = xno; then
1304             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1305         fi
1306         ;;
1307     xxlib)
1308         if test "x$enable_dri" = xyes; then
1309             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1310         fi
1311         ;;
1312     xgallium-xlib )
1313         if test "x$enable_dri" = xyes; then
1314             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1315         fi
1316         if test -z "$with_gallium_drivers"; then
1317             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1318         fi
1319         ;;
1320     esac
1321     ;;
1322 xno)
1323     ;;
1324 *)
1325     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1326     ;;
1327 esac
1328
1329 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1330 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1331 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1332 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1333
1334 dnl
1335 dnl Libglvnd configuration
1336 dnl
1337 AC_ARG_ENABLE([libglvnd],
1338     [AS_HELP_STRING([--enable-libglvnd],
1339         [Build for libglvnd @<:@default=disabled@:>@])],
1340     [enable_libglvnd="$enableval"],
1341     [enable_libglvnd=no])
1342 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1343 if test "x$enable_libglvnd" = xyes ; then
1344     dnl XXX: update once we can handle more than libGL/glx.
1345     dnl Namely: we should error out if neither of the glvnd enabled libraries
1346     dnl are built
1347     case "x$enable_glx" in
1348     xno)
1349         AC_MSG_ERROR([cannot build libglvnd without GLX])
1350         ;;
1351     xxlib | xgallium-xlib )
1352         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1353         ;;
1354     xdri)
1355         ;;
1356     esac
1357
1358     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1359     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1360     DEFAULT_GL_LIB_NAME=GLX_mesa
1361 fi
1362
1363 # Check for libdrm
1364 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1365                   [have_libdrm=yes], [have_libdrm=no])
1366 if test "x$have_libdrm" = xyes; then
1367         DEFINES="$DEFINES -DHAVE_LIBDRM"
1368 fi
1369
1370 require_libdrm() {
1371     if test "x$have_libdrm" != xyes; then
1372        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1373     fi
1374 }
1375
1376
1377 # Select which platform-dependent DRI code gets built
1378 case "$host_os" in
1379 darwin*)
1380     dri_platform='apple' ;;
1381 cygwin*)
1382     dri_platform='windows' ;;
1383 gnu*)
1384     dri_platform='none' ;;
1385 *)
1386     dri_platform='drm' ;;
1387 esac
1388
1389 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1390     have_drisw_kms='yes'
1391 fi
1392
1393 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1394 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1395 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1396 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1397 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1398 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1399 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1400 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1401 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1402
1403 AC_ARG_ENABLE([shared-glapi],
1404     [AS_HELP_STRING([--enable-shared-glapi],
1405         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1406     [enable_shared_glapi="$enableval"],
1407     [enable_shared_glapi=yes])
1408
1409 case "x$enable_opengl$enable_gles1$enable_gles2" in
1410 x*yes*yes*)
1411     if test "x$enable_shared_glapi" = xno; then
1412         AC_MSG_ERROR([shared GLAPI required when building two or more of
1413                       the following APIs - opengl, gles1 gles2])
1414     fi
1415     ;;
1416 esac
1417
1418 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1419
1420 # Build the pipe-drivers as separate libraries/modules.
1421 # Do not touch this unless you know what you are doing.
1422 # XXX: Expose via configure option ?
1423 enable_shared_pipe_drivers=no
1424
1425 dnl
1426 dnl Driver specific build directories
1427 dnl
1428
1429 if test "x$enable_gallium_osmesa" = xyes; then
1430     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1431         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1432     fi
1433     if test "x$enable_osmesa" = xyes; then
1434         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1435     fi
1436 fi
1437
1438 # SHA1 hashing
1439 AC_ARG_WITH([sha1],
1440         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1441         [choose SHA1 implementation])])
1442 case "x$with_sha1" in
1443 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1444   ;;
1445 *)
1446         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1447 esac
1448
1449 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1450 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1451         with_sha1=libc
1452 fi
1453 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1454         AC_MSG_ERROR([sha1 in libc requested but not found])
1455 fi
1456 if test "x$with_sha1" = xlibc; then
1457         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1458                 [Use libc SHA1 functions])
1459         SHA1_LIBS=""
1460 fi
1461 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1462 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1463         with_sha1=CommonCrypto
1464 fi
1465 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1466         AC_MSG_ERROR([CommonCrypto requested but not found])
1467 fi
1468 if test "x$with_sha1" = xCommonCrypto; then
1469         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1470                 [Use CommonCrypto SHA1 functions])
1471         SHA1_LIBS=""
1472 fi
1473 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1474 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1475 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1476         with_sha1=CryptoAPI
1477 fi
1478 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1479         AC_MSG_ERROR([CryptoAPI requested but not found])
1480 fi
1481 if test "x$with_sha1" = xCryptoAPI; then
1482         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1483                 [Use CryptoAPI SHA1 functions])
1484         SHA1_LIBS=""
1485 fi
1486 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1487 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1488         with_sha1=libmd
1489 fi
1490 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1491         AC_MSG_ERROR([libmd requested but not found])
1492 fi
1493 if test "x$with_sha1" = xlibmd; then
1494         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1495                   [Use libmd SHA1 functions])
1496         SHA1_LIBS=-lmd
1497 fi
1498 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1499 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1500    with_sha1=libsha1
1501 fi
1502 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1503         AC_MSG_ERROR([libsha1 requested but not found])
1504 fi
1505 if test "x$with_sha1" = xlibsha1; then
1506         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1507                   [Use libsha1 for SHA1])
1508         SHA1_LIBS=-lsha1
1509 fi
1510 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1511 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1512         with_sha1=libnettle
1513 fi
1514 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1515         AC_MSG_ERROR([libnettle requested but not found])
1516 fi
1517 if test "x$with_sha1" = xlibnettle; then
1518         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1519                   [Use libnettle SHA1 functions])
1520         SHA1_LIBS=-lnettle
1521 fi
1522 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1523 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1524         with_sha1=libgcrypt
1525 fi
1526 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1527         AC_MSG_ERROR([libgcrypt requested but not found])
1528 fi
1529 if test "x$with_sha1" = xlibgcrypt; then
1530         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1531                   [Use libgcrypt SHA1 functions])
1532         SHA1_LIBS=-lgcrypt
1533 fi
1534 # We don't need all of the OpenSSL libraries, just libcrypto
1535 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1536 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1537                   [HAVE_OPENSSL_PKC=no])
1538 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1539         if test "x$with_sha1" = x; then
1540                 with_sha1=libcrypto
1541         fi
1542 else
1543         if test "x$with_sha1" = xlibcrypto; then
1544                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1545         fi
1546 fi
1547 if test "x$with_sha1" = xlibcrypto; then
1548         if test "x$HAVE_LIBCRYPTO" = xyes; then
1549                 SHA1_LIBS=-lcrypto
1550         else
1551                 SHA1_LIBS="$OPENSSL_LIBS"
1552                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1553         fi
1554 fi
1555 AC_MSG_CHECKING([for SHA1 implementation])
1556 AC_MSG_RESULT([$with_sha1])
1557 AC_SUBST(SHA1_LIBS)
1558 AC_SUBST(SHA1_CFLAGS)
1559
1560 # Enable a define for SHA1
1561 if test "x$with_sha1" != "x"; then
1562         DEFINES="$DEFINES -DHAVE_SHA1"
1563 fi
1564
1565 # Allow user to configure out the shader-cache feature
1566 AC_ARG_ENABLE([shader-cache],
1567     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1568     [enable_shader_cache="$enableval"],
1569     [if test "x$with_sha1" != "x"; then
1570         enable_shader_cache=yes
1571      else
1572         enable_shader_cache=no
1573      fi])
1574 if test "x$with_sha1" = "x"; then
1575     if test "x$enable_shader_cache" = "xyes"; then
1576         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1577     fi
1578 fi
1579 if test "x$enable_shader_cache" = "xyes"; then
1580    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1581 fi
1582
1583 if test "x$enable_dri" = xyes; then
1584     if test "$enable_static" = yes; then
1585         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1586     fi
1587
1588     # not a hard requirement as swrast does not depend on it
1589     if test "x$have_libdrm" = xyes; then
1590         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1591     fi
1592 fi
1593
1594 AC_ARG_ENABLE([driglx-direct],
1595     [AS_HELP_STRING([--disable-driglx-direct],
1596         [disable direct rendering in GLX and EGL for DRI \
1597             @<:@default=auto@:>@])],
1598     [driglx_direct="$enableval"],
1599     [driglx_direct="yes"])
1600
1601 dnl
1602 dnl libGL configuration per driver
1603 dnl
1604 if test "x$enable_glx" != xno; then
1605     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1606 fi
1607 case "x$enable_glx" in
1608 xxlib | xgallium-xlib)
1609     # Xlib-based GLX
1610     dri_modules="x11 xext xcb"
1611     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1612     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1613     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1614     GL_LIB_DEPS="$XLIBGL_LIBS"
1615     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1616     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1617     ;;
1618 xdri)
1619     # DRI-based GLX
1620
1621     # find the DRI deps for libGL
1622     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1623
1624     if test x"$driglx_direct" = xyes; then
1625         if test x"$dri_platform" = xdrm ; then
1626             DEFINES="$DEFINES -DGLX_USE_DRM"
1627             require_libdrm "Direct rendering"
1628
1629             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1630             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1631             if test x"$enable_dri3" = xyes; then
1632                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1633                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1634             fi
1635
1636             if test x"$enable_dri" = xyes; then
1637                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1638             fi
1639
1640             if test x"$enable_dri3" = xyes; then
1641                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1642                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1643                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1644             fi
1645         fi
1646         if test x"$dri_platform" = xapple ; then
1647             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1648         fi
1649         if test x"$dri_platform" = xwindows ; then
1650             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1651         fi
1652     fi
1653
1654     # add xf86vidmode if available
1655     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1656     if test "$HAVE_XF86VIDMODE" = yes ; then
1657         dri_modules="$dri_modules xxf86vm"
1658     fi
1659
1660     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1661     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1662     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1663     GL_LIB_DEPS="$DRIGL_LIBS"
1664
1665     # need DRM libs, $PTHREAD_LIBS, etc.
1666     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1667     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1668     ;;
1669 esac
1670
1671 # This is outside the case (above) so that it is invoked even for non-GLX
1672 # builds.
1673 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1674
1675 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1676 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1677 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1678 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1679
1680 AC_SUBST([X11_INCLUDES])
1681 AC_SUBST([GL_LIB_DEPS])
1682 AC_SUBST([GL_PC_REQ_PRIV])
1683 AC_SUBST([GL_PC_LIB_PRIV])
1684 AC_SUBST([GL_PC_CFLAGS])
1685 AC_SUBST([DRI_PC_REQ_PRIV])
1686 AC_SUBST([GLESv1_CM_LIB_DEPS])
1687 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1688 AC_SUBST([GLESv2_LIB_DEPS])
1689 AC_SUBST([GLESv2_PC_LIB_PRIV])
1690
1691 AC_SUBST([HAVE_XF86VIDMODE])
1692
1693 dnl
1694 dnl More GLX setup
1695 dnl
1696 case "x$enable_glx" in
1697 xxlib | xgallium-xlib)
1698     DEFINES="$DEFINES -DUSE_XSHM"
1699     ;;
1700 xdri)
1701     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1702     if test "x$driglx_direct" = xyes; then
1703         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1704     fi
1705     ;;
1706 esac
1707
1708 dnl
1709 dnl TLS detection
1710 dnl
1711
1712 AC_ARG_ENABLE([glx-tls],
1713     [AS_HELP_STRING([--enable-glx-tls],
1714         [enable TLS support in GLX @<:@default=enabled@:>@])],
1715     [GLX_USE_TLS="$enableval"],
1716     [GLX_USE_TLS=yes])
1717 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1718
1719 if test "x$GLX_USE_TLS" = xyes; then
1720     DEFINES="$DEFINES -DGLX_USE_TLS"
1721 fi
1722
1723 dnl Read-only text section on x86 hardened platforms
1724 AC_ARG_ENABLE([glx-read-only-text],
1725     [AS_HELP_STRING([--enable-glx-read-only-text],
1726         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1727     [enable_glx_read_only_text="$enableval"],
1728     [enable_glx_read_only_text=no])
1729 if test "x$enable_glx_read_only_text" = xyes; then
1730     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1731 fi
1732
1733 dnl
1734 dnl More DRI setup
1735 dnl
1736 dnl Directory for DRI drivers
1737 AC_ARG_WITH([dri-driverdir],
1738     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1739         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1740     [DRI_DRIVER_INSTALL_DIR="$withval"],
1741     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1742 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1743 dnl Extra search path for DRI drivers
1744 AC_ARG_WITH([dri-searchpath],
1745     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1746         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1747     [DRI_DRIVER_SEARCH_DIR="$withval"],
1748     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1749 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1750 dnl Which drivers to build - default is chosen by platform
1751 AC_ARG_WITH([dri-drivers],
1752     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1753         [comma delimited classic DRI drivers list, e.g.
1754         "swrast,i965,radeon" @<:@default=auto@:>@])],
1755     [with_dri_drivers="$withval"],
1756     [with_dri_drivers=auto])
1757
1758 if test "x$with_dri_drivers" = xauto; then
1759     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1760         with_dri_drivers="yes"
1761     else
1762         with_dri_drivers="no"
1763     fi
1764 fi
1765 if test "x$with_dri_drivers" = xno; then
1766     with_dri_drivers=''
1767 fi
1768
1769 dnl If $with_dri_drivers is yes, drivers will be added through
1770 dnl platform checks. Set DEFINES and LIB_DEPS
1771 if test "x$enable_dri" = xyes; then
1772     # Platform specific settings and drivers to build
1773     case "$host_os" in
1774     linux*)
1775         DEFINES="$DEFINES -DHAVE_ALIAS"
1776         if test "x$enable_dri3" = xyes; then
1777             DEFINES="$DEFINES -DHAVE_DRI3"
1778         fi
1779
1780         case "$host_cpu" in
1781         powerpc* | sparc*)
1782             # Build only the drivers for cards that exist on PowerPC/sparc
1783             if test "x$with_dri_drivers" = "xyes"; then
1784                 with_dri_drivers="r200 radeon swrast"
1785             fi
1786             ;;
1787         esac
1788         ;;
1789     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1790         DEFINES="$DEFINES -DHAVE_ALIAS"
1791         ;;
1792     gnu*)
1793         DEFINES="$DEFINES -DHAVE_ALIAS"
1794         ;;
1795     cygwin*)
1796         if test "x$with_dri_drivers" = "xyes"; then
1797             with_dri_drivers="swrast"
1798         fi
1799         ;;
1800     darwin*)
1801         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1802         if test "x$with_dri_drivers" = "xyes"; then
1803             with_dri_drivers="swrast"
1804         fi
1805         ;;
1806     esac
1807
1808     # default drivers
1809     if test "x$with_dri_drivers" = "xyes"; then
1810         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1811     fi
1812
1813     # Check for expat
1814     PKG_CHECK_MODULES([EXPAT], [expat], [],
1815         # expat version 2.0 and earlier do not provide expat.pc
1816         [AC_CHECK_HEADER([expat.h],[],
1817                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1818          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1819                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1820          EXPAT_LIBS="-lexpat"])
1821
1822     # put all the necessary libs together
1823     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1824 fi
1825
1826 AC_SUBST([DRI_LIB_DEPS])
1827
1828 DRI_DIRS=''
1829 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1830 if test -n "$with_dri_drivers"; then
1831     if test "x$enable_opengl" != xyes; then
1832         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1833     fi
1834
1835     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1836     for driver in $dri_drivers; do
1837         DRI_DIRS="$DRI_DIRS $driver"
1838         case "x$driver" in
1839         xi915)
1840             HAVE_I915_DRI=yes;
1841             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1842             ;;
1843         xi965)
1844             HAVE_I965_DRI=yes;
1845             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1846             ;;
1847         xnouveau)
1848             HAVE_NOUVEAU_DRI=yes;
1849             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1850             ;;
1851         xradeon)
1852             HAVE_RADEON_DRI=yes;
1853             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1854             ;;
1855         xr200)
1856             HAVE_R200_DRI=yes;
1857             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1858             ;;
1859         xswrast)
1860             HAVE_SWRAST_DRI=yes;
1861             ;;
1862         *)
1863             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1864             ;;
1865         esac
1866     done
1867     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1868 fi
1869
1870
1871 #
1872 # Vulkan driver configuration
1873 #
1874
1875 AC_ARG_WITH([vulkan-drivers],
1876     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1877         [comma delimited Vulkan drivers list, e.g.
1878         "intel"
1879         @<:@default=no@:>@])],
1880     [with_vulkan_drivers="$withval"],
1881     [with_vulkan_drivers="no"])
1882
1883 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1884 # here so that the script doesn't choke on an unknown driver name later.
1885 case "x$with_vulkan_drivers" in
1886     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1887     xno) with_vulkan_drivers='' ;;
1888 esac
1889
1890 AC_ARG_WITH([vulkan-icddir],
1891     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1892         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1893     [VULKAN_ICD_INSTALL_DIR="$withval"],
1894     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1895 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1896
1897 if test -n "$with_vulkan_drivers"; then
1898     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1899     for driver in $VULKAN_DRIVERS; do
1900         case "x$driver" in
1901         xintel)
1902             if test "x$HAVE_I965_DRI" != xyes; then
1903                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1904             fi
1905             if test "x$with_sha1" == "x"; then
1906                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1907             fi
1908             HAVE_INTEL_VULKAN=yes;
1909
1910             ;;
1911         xradeon)
1912             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1913             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1914             HAVE_RADEON_VULKAN=yes;
1915             if test "x$with_sha1" == "x"; then
1916                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1917             fi
1918             ;;
1919         *)
1920             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1921             ;;
1922         esac
1923     done
1924     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1925 fi
1926
1927
1928 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1929 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1930                                   "x$enable_osmesa" = xyes -o \
1931                                   -n "$DRI_DIRS")
1932
1933 dnl
1934 dnl OSMesa configuration
1935 dnl
1936
1937 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1938 AC_ARG_WITH([osmesa-bits],
1939     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1940         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1941     [osmesa_bits="$withval"],
1942     [osmesa_bits=8])
1943 if test "x$osmesa_bits" != x8; then
1944     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1945         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1946         osmesa_bits=8
1947     fi
1948 fi
1949 case "x$osmesa_bits" in
1950 x8)
1951     OSMESA_LIB="${OSMESA_LIB}"
1952     ;;
1953 x16|x32)
1954     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1955     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1956     ;;
1957 *)
1958     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1959     ;;
1960 esac
1961
1962 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1963     # only link libraries with osmesa if shared
1964     if test "$enable_static" = no; then
1965         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1966     else
1967         OSMESA_LIB_DEPS=""
1968     fi
1969     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1970 fi
1971
1972 AC_SUBST([OSMESA_LIB_DEPS])
1973 AC_SUBST([OSMESA_PC_REQ])
1974 AC_SUBST([OSMESA_PC_LIB_PRIV])
1975
1976 dnl
1977 dnl gbm configuration
1978 dnl
1979 if test "x$enable_gbm" = xyes; then
1980     if test "x$enable_dri" = xyes; then
1981         if test "x$enable_shared_glapi" = xno; then
1982             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1983         fi
1984     else
1985         # Strictly speaking libgbm does not require --enable-dri, although
1986         # both of its backends do. Thus one can build libgbm without any
1987         # backends if --disable-dri is set.
1988         # To avoid unnecessary complexity of checking if at least one backend
1989         # is available when building, just mandate --enable-dri.
1990         AC_MSG_ERROR([gbm requires --enable-dri])
1991     fi
1992 fi
1993 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1994 # FINISHME: GBM has a number of dependencies which we should add below
1995 GBM_PC_REQ_PRIV=""
1996 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1997 AC_SUBST([GBM_PC_REQ_PRIV])
1998 AC_SUBST([GBM_PC_LIB_PRIV])
1999
2000 dnl
2001 dnl EGL configuration
2002 dnl
2003 EGL_CLIENT_APIS=""
2004
2005 if test "x$enable_egl" = xyes; then
2006     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2007
2008     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2009
2010     if test "$enable_static" != yes; then
2011         if test "x$enable_dri" = xyes; then
2012             HAVE_EGL_DRIVER_DRI2=1
2013             if test "x$enable_shared_glapi" = xno; then
2014                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
2015             fi
2016             if test "x$enable_dri3" = xyes; then
2017                 HAVE_EGL_DRIVER_DRI3=1
2018                 if test "x$enable_shared_glapi" = xno; then
2019                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
2020                 fi
2021             fi
2022         else
2023             # Avoid building an "empty" libEGL. Drop/update this
2024             # when other backends (haiku?) come along.
2025             AC_MSG_ERROR([egl requires --enable-dri])
2026         fi
2027
2028     fi
2029 fi
2030 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2031 AC_SUBST([EGL_LIB_DEPS])
2032
2033 gallium_st="mesa"
2034
2035 dnl
2036 dnl XA configuration
2037 dnl
2038 if test "x$enable_xa" = xyes; then
2039     if test "x$with_gallium_drivers" = xswrast; then
2040        AC_MSG_ERROR([
2041           Building xa requires at least one non swrast gallium driver.
2042           If you are looking to use libxatracker.so with the VMware driver,
2043           make sure to include svga in the gallium drivers list, apart from
2044           enabling XA.
2045           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2046     fi
2047     gallium_st="$gallium_st xa"
2048 fi
2049 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2050
2051 dnl
2052 dnl Gallium G3DVL configuration
2053 dnl
2054 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2055     if test "x$enable_xvmc" = xauto; then
2056         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2057     fi
2058
2059     if test "x$enable_vdpau" = xauto; then
2060         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2061     fi
2062
2063     if test "x$enable_omx" = xauto; then
2064         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2065     fi
2066
2067     if test "x$enable_va" = xauto; then
2068         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2069     fi
2070 fi
2071
2072 if test "x$enable_dri" = xyes -o \
2073         "x$enable_xvmc" = xyes -o \
2074         "x$enable_vdpau" = xyes -o \
2075         "x$enable_omx" = xyes -o \
2076         "x$enable_va" = xyes; then
2077     need_gallium_vl=yes
2078 fi
2079 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2080
2081 if test "x$enable_xvmc" = xyes -o \
2082         "x$enable_vdpau" = xyes -o \
2083         "x$enable_omx" = xyes -o \
2084         "x$enable_va" = xyes; then
2085     if test x"$enable_dri3" = xyes; then
2086         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2087                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2088     else
2089         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2090     fi
2091     need_gallium_vl_winsys=yes
2092 fi
2093 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2094
2095 if test "x$enable_xvmc" = xyes; then
2096     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2097     gallium_st="$gallium_st xvmc"
2098 fi
2099 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2100
2101 if test "x$enable_vdpau" = xyes; then
2102     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2103     gallium_st="$gallium_st vdpau"
2104     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2105 fi
2106 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2107
2108 if test "x$enable_omx" = xyes; then
2109     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2110     gallium_st="$gallium_st omx"
2111 fi
2112 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2113
2114 if test "x$enable_va" = xyes; then
2115     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2116     gallium_st="$gallium_st va"
2117 fi
2118 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2119
2120 dnl
2121 dnl Nine Direct3D9 configuration
2122 dnl
2123 if test "x$enable_nine" = xyes; then
2124     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2125         AC_MSG_ERROR([nine requires the gallium swrast driver])
2126     fi
2127     if test "x$with_gallium_drivers" = xswrast; then
2128         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2129     fi
2130     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2131         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2132     fi
2133
2134     if test "x$enable_dri3" = xno; then
2135         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2136     fi
2137
2138     gallium_st="$gallium_st nine"
2139 fi
2140 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2141
2142 dnl
2143 dnl OpenCL configuration
2144 dnl
2145
2146 AC_ARG_WITH([clang-libdir],
2147    [AS_HELP_STRING([--with-clang-libdir],
2148          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2149    [CLANG_LIBDIR="$withval"],
2150    [CLANG_LIBDIR=''])
2151
2152 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2153
2154 if test "x$enable_opencl" = xyes; then
2155     if test -z "$with_gallium_drivers"; then
2156         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2157     fi
2158
2159     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2160         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2161     fi
2162
2163     if test "x$have_libclc" = xno; then
2164         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2165                     Make sure the directory containing libclc.pc is specified in your
2166                     PKG_CONFIG_PATH environment variable.
2167                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2168     else
2169         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2170         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2171         AC_SUBST([LIBCLC_INCLUDEDIR])
2172         AC_SUBST([LIBCLC_LIBEXECDIR])
2173     fi
2174
2175     gallium_st="$gallium_st clover"
2176
2177     if test "x$enable_opencl_icd" = xyes; then
2178         OPENCL_LIBNAME="MesaOpenCL"
2179     else
2180         OPENCL_LIBNAME="OpenCL"
2181     fi
2182
2183     if test "x$have_libelf" != xyes; then
2184        AC_MSG_ERROR([Clover requires libelf])
2185     fi
2186
2187     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2188
2189     llvm_add_default_components "opencl"
2190     llvm_add_component "all-targets" "opencl"
2191     llvm_add_component "linker" "opencl"
2192     llvm_add_component "instrumentation" "opencl"
2193     llvm_add_component "ipo" "opencl"
2194     llvm_add_component "irreader" "opencl"
2195     llvm_add_component "option" "opencl"
2196     llvm_add_component "objcarcopts" "opencl"
2197     llvm_add_component "profiledata" "opencl"
2198
2199     dnl Check for Clang internal headers
2200     if test -z "$CLANG_LIBDIR"; then
2201         CLANG_LIBDIR=${LLVM_LIBDIR}
2202     fi
2203     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2204     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2205         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2206 fi
2207 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2208 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2209 AC_SUBST([OPENCL_LIBNAME])
2210 AC_SUBST([CLANG_RESOURCE_DIR])
2211
2212 dnl
2213 dnl Gallium configuration
2214 dnl
2215 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2216
2217 case "x$enable_opengl$enable_gles1$enable_gles2" in
2218 x*yes*)
2219     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2220     ;;
2221 esac
2222
2223 AC_SUBST([VG_LIB_DEPS])
2224 AC_SUBST([EGL_CLIENT_APIS])
2225
2226 dnl
2227 dnl EGL Platforms configuration
2228 dnl
2229 AC_ARG_WITH([egl-platforms],
2230     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2231         [comma delimited native platforms libEGL supports, e.g.
2232         "x11,drm" @<:@default=auto@:>@])],
2233     [with_egl_platforms="$withval"],
2234     [if test "x$enable_egl" = xyes; then
2235         if test "x$enable_gbm" = xyes; then
2236            with_egl_platforms="x11,drm"
2237         else
2238            with_egl_platforms="x11"
2239         fi
2240     else
2241         with_egl_platforms=""
2242     fi])
2243
2244 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2245     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2246 fi
2247
2248 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2249         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2250         WAYLAND_SCANNER='')
2251 if test "x$WAYLAND_SCANNER" = x; then
2252     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2253 fi
2254
2255 # Do per-EGL platform setups and checks
2256 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2257 for plat in $egl_platforms; do
2258         case "$plat" in
2259         wayland)
2260
2261                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2262
2263                 if test "x$WAYLAND_SCANNER" = x; then
2264                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2265                 fi
2266                 ;;
2267
2268         x11)
2269                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2270                 ;;
2271
2272         drm)
2273                 test "x$enable_gbm" = "xno" &&
2274                         AC_MSG_ERROR([EGL platform drm needs gbm])
2275                 ;;
2276
2277         surfaceless)
2278                 ;;
2279
2280         android)
2281                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2282                 ;;
2283
2284         *)
2285                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2286                 ;;
2287         esac
2288
2289         case "$plat" in
2290         wayland|drm|surfaceless)
2291                 require_libdrm "Platform $plat"
2292                 ;;
2293         esac
2294 done
2295
2296 # libEGL wants to default to the first platform specified in
2297 # ./configure.  parse that here.
2298 if test "x$egl_platforms" != "x"; then
2299     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2300     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2301 else
2302     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2303 fi
2304
2305 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2306 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2307 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2308 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2309 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2310
2311 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2312
2313 AC_SUBST([EGL_NATIVE_PLATFORM])
2314 AC_SUBST([EGL_CFLAGS])
2315
2316 # If we don't have the X11 platform, set this define so we don't try to include
2317 # the X11 headers.
2318 if ! echo "$egl_platforms" | grep -q 'x11'; then
2319     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2320     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2321 fi
2322
2323 dnl
2324 dnl Gallium LLVM
2325 dnl
2326 AC_ARG_ENABLE([gallium-llvm],
2327     [AS_HELP_STRING([--enable-gallium-llvm],
2328         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2329     [enable_gallium_llvm="$enableval"],
2330     [enable_gallium_llvm=auto])
2331
2332 if test -z "$with_gallium_drivers"; then
2333     enable_gallium_llvm=no
2334 fi
2335 if test "x$enable_gallium_llvm" = xauto; then
2336     case "$host_cpu" in
2337     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2338     esac
2339 fi
2340
2341 dnl Directory for XVMC libs
2342 AC_ARG_WITH([xvmc-libdir],
2343     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2344         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2345     [XVMC_LIB_INSTALL_DIR="$withval"],
2346     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2347 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2348
2349 dnl
2350 dnl Gallium Tests
2351 dnl
2352 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2353
2354 dnl Directory for VDPAU libs
2355 AC_ARG_WITH([vdpau-libdir],
2356     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2357         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2358     [VDPAU_LIB_INSTALL_DIR="$withval"],
2359     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2360 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2361
2362 dnl Directory for OMX libs
2363
2364 AC_ARG_WITH([omx-libdir],
2365     [AS_HELP_STRING([--with-omx-libdir=DIR],
2366         [directory for the OMX libraries])],
2367     [OMX_LIB_INSTALL_DIR="$withval"],
2368     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2369 AC_SUBST([OMX_LIB_INSTALL_DIR])
2370
2371 dnl Directory for VA libs
2372
2373 AC_ARG_WITH([va-libdir],
2374     [AS_HELP_STRING([--with-va-libdir=DIR],
2375         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2376     [VA_LIB_INSTALL_DIR="$withval"],
2377     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2378 AC_SUBST([VA_LIB_INSTALL_DIR])
2379
2380 AC_ARG_WITH([d3d-libdir],
2381     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2382         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2383     [D3D_DRIVER_INSTALL_DIR="$withval"],
2384     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2385 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2386
2387 dnl
2388 dnl Gallium helper functions
2389 dnl
2390 gallium_require_llvm() {
2391     if test "x$enable_gallium_llvm" = "xyes"; then
2392         llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2393     else
2394         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2395     fi
2396 }
2397
2398 dnl
2399 dnl DRM is needed by X, Wayland, and offscreen rendering.
2400 dnl Surfaceless is an alternative for the last one.
2401 dnl
2402 require_basic_egl() {
2403     case "$with_egl_platforms" in
2404         *drm*|*surfaceless*)
2405             ;;
2406         *)
2407             AC_MSG_ERROR([$1 requires one of these:
2408                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2409                   2) --with-egl-platforms=surfaceless (offscreen only)
2410                   Recommended options: drm,x11])
2411             ;;
2412     esac
2413 }
2414
2415 radeon_gallium_llvm_check() {
2416     if test "x$enable_gallium_llvm" != "xyes"; then
2417         AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2418     fi
2419     radeon_llvm_check $*
2420 }
2421
2422 swr_require_cxx_feature_flags() {
2423     feature_name="$1"
2424     preprocessor_test="$2"
2425     option_list="$3"
2426     output_var="$4"
2427
2428     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2429     AC_LANG_PUSH([C++])
2430     save_CXXFLAGS="$CXXFLAGS"
2431     save_IFS="$IFS"
2432     IFS=","
2433     found=0
2434     for opts in $option_list
2435     do
2436         unset IFS
2437         CXXFLAGS="$opts $save_CXXFLAGS"
2438         AC_COMPILE_IFELSE(
2439             [AC_LANG_PROGRAM(
2440                 [   #if !($preprocessor_test)
2441                     #error
2442                     #endif
2443                 ])],
2444             [found=1; break],
2445             [])
2446         IFS=","
2447     done
2448     IFS="$save_IFS"
2449     CXXFLAGS="$save_CXXFLAGS"
2450     AC_LANG_POP([C++])
2451     if test $found -eq 1; then
2452         AC_MSG_RESULT([$opts])
2453         eval "$output_var=\$opts"
2454         return 0
2455     fi
2456     AC_MSG_RESULT([no])
2457     AC_MSG_ERROR([swr requires $feature_name support])
2458     return 1
2459 }
2460
2461 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2462 if test -n "$with_gallium_drivers"; then
2463     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2464     for driver in $gallium_drivers; do
2465         case "x$driver" in
2466         xsvga)
2467             HAVE_GALLIUM_SVGA=yes
2468             require_libdrm "svga"
2469             ;;
2470         xi915)
2471             HAVE_GALLIUM_I915=yes
2472             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2473             require_libdrm "Gallium i915"
2474             ;;
2475         xilo)
2476             HAVE_GALLIUM_ILO=yes
2477             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2478             require_libdrm "Gallium i965/ilo"
2479             ;;
2480         xr300)
2481             HAVE_GALLIUM_R300=yes
2482             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2483             require_libdrm "r300"
2484             gallium_require_llvm "r300"
2485             ;;
2486         xr600)
2487             HAVE_GALLIUM_R600=yes
2488             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2489             require_libdrm "r600"
2490             if test "x$enable_opencl" = xyes; then
2491                 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2492
2493                 llvm_add_component "asmparser" "r600"
2494                 llvm_add_component "bitreader" "r600"
2495             fi
2496             ;;
2497         xradeonsi)
2498             HAVE_GALLIUM_RADEONSI=yes
2499             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2500             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2501             require_libdrm "radeonsi"
2502             radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2503             require_basic_egl "radeonsi"
2504             ;;
2505         xnouveau)
2506             HAVE_GALLIUM_NOUVEAU=yes
2507             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2508             require_libdrm "nouveau"
2509             ;;
2510         xfreedreno)
2511             HAVE_GALLIUM_FREEDRENO=yes
2512             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2513             require_libdrm "freedreno"
2514             ;;
2515         xetnaviv)
2516             HAVE_GALLIUM_ETNAVIV=yes
2517             PKG_CHECK_MODULES([ETNAVIV], [libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2518             require_libdrm "etnaviv"
2519             ;;
2520        ximx)
2521             HAVE_GALLIUM_IMX=yes
2522             ;;
2523         xswrast)
2524             HAVE_GALLIUM_SOFTPIPE=yes
2525             if test "x$FOUND_LLVM" = xyes -a "x$enable_gallium_llvm" = xyes;  then
2526                 HAVE_GALLIUM_LLVMPIPE=yes
2527             fi
2528             ;;
2529         xswr)
2530             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2531             gallium_require_llvm "swr"
2532
2533             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2534                 ",-std=c++11" \
2535                 SWR_CXX11_CXXFLAGS
2536             AC_SUBST([SWR_CXX11_CXXFLAGS])
2537
2538             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2539                 ",-mavx,-march=core-avx" \
2540                 SWR_AVX_CXXFLAGS
2541             AC_SUBST([SWR_AVX_CXXFLAGS])
2542
2543             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2544                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2545                 SWR_AVX2_CXXFLAGS
2546             AC_SUBST([SWR_AVX2_CXXFLAGS])
2547
2548             HAVE_GALLIUM_SWR=yes
2549             ;;
2550         xvc4)
2551             HAVE_GALLIUM_VC4=yes
2552             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2553             require_libdrm "vc4"
2554
2555             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2556                               [USE_VC4_SIMULATOR=yes;
2557                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2558                               [USE_VC4_SIMULATOR=no])
2559             ;;
2560         xvirgl)
2561             HAVE_GALLIUM_VIRGL=yes
2562             require_libdrm "virgl"
2563             require_basic_egl "virgl"
2564             ;;
2565         *)
2566             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2567             ;;
2568         esac
2569     done
2570 fi
2571
2572 if test "x$enable_gallium_llvm" == "xyes"; then
2573     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2574     llvm_add_default_components "gallium"
2575
2576     HAVE_GALLIUM_LLVM=yes
2577 fi
2578
2579 dnl We need to validate some needed dependencies for renderonly drivers.
2580
2581 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" == xyes  ; then
2582     AC_ERROR([Building with imx requires etnaviv])
2583 fi
2584
2585 dnl Set LLVM_LIBS - This is done after the driver configuration so
2586 dnl that drivers can add additional components to LLVM_COMPONENTS.
2587 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2588 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2589 dnl this was causing the same libraries to be appear multiple times
2590 dnl in LLVM_LIBS.
2591
2592 if test "x$USE_LLVM" == xyes; then
2593
2594     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2595        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2596     fi
2597     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2598
2599     dnl llvm-config may not give the right answer when llvm is a built as a
2600     dnl single shared library, so we must work the library name out for
2601     dnl ourselves.
2602     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2603     if test "x$enable_llvm_shared_libs" = xyes; then
2604         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2605         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2606         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2607
2608         if test "x$llvm_have_one_so" = xyes; then
2609             dnl LLVM was built using auto*, so there is only one shared object.
2610             LLVM_LIBS="-l$LLVM_SO_NAME"
2611         else
2612             dnl If LLVM was built with CMake, there will be one shared object per
2613             dnl component.
2614             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2615                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2616         Please make sure you have built llvm with the --enable-shared option
2617         and that your llvm libraries are installed in $LLVM_LIBDIR
2618         If you have installed your llvm libraries to a different directory you
2619         can use the --with-llvm-prefix= configure flag to specify this directory.
2620         NOTE: Mesa is attempting to use llvm shared libraries by default.
2621         If you do not want to build with llvm shared libraries and instead want to
2622         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2623         invocation and rebuild.])])
2624
2625            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2626            dnl install uses a shared object for each component and we have
2627            dnl already added all of these objects to LLVM_LIBS.
2628         fi
2629     else
2630         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2631         dnl We need to link to llvm system libs when using static libs
2632         dnl However, only llvm 3.5+ provides --system-libs
2633         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2634             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2635         fi
2636     fi
2637 fi
2638
2639 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2640 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2641 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2642 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2643 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2644 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2645 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2646                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2647 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2648 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2649 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2650 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2651 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2652 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2653 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2654 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2655                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2656                                          "x$HAVE_GALLIUM_SWR" = xyes)
2657 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2658 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2659
2660 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2661
2662 if test "x$enable_dri" = xyes; then
2663     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2664 fi
2665
2666 if test "x$have_drisw_kms" = xyes; then
2667     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2668 fi
2669 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2670
2671 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2672 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2673 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2674 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2675 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2676 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2677
2678 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2679 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2680
2681 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2682                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2683                                       "x$HAVE_RADEON_VULKAN" = xyes)
2684
2685 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2686                                         "x$HAVE_I965_DRI" = xyes)
2687
2688 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2689                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2690                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2691 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2692 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2693 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2694 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$HAVE_GALLIUM_LLVM" = xyes)
2695 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2696 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2697     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2698 fi
2699
2700 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2701 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2702 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2703 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2704                                         "x$enable_gallium_osmesa" = xyes)
2705
2706 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2707 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2708 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2709
2710 AC_SUBST([NINE_MAJOR], 1)
2711 AC_SUBST([NINE_MINOR], 0)
2712 AC_SUBST([NINE_TINY], 0)
2713 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2714
2715 AC_SUBST([VDPAU_MAJOR], 1)
2716 AC_SUBST([VDPAU_MINOR], 0)
2717
2718 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2719 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2720 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2721 AC_SUBST([VA_MINOR], $VA_MINOR)
2722
2723 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2724
2725 AC_SUBST([XVMC_MAJOR], 1)
2726 AC_SUBST([XVMC_MINOR], 0)
2727
2728 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2729 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2730 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2731 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2732
2733 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2734 AC_SUBST([XA_MINOR], $XA_MINOR)
2735 AC_SUBST([XA_TINY], $XA_TINY)
2736 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2737
2738 AC_ARG_ENABLE(valgrind,
2739               [AS_HELP_STRING([--enable-valgrind],
2740                              [Build mesa with valgrind support (default: auto)])],
2741                              [VALGRIND=$enableval], [VALGRIND=auto])
2742 if test "x$VALGRIND" != xno; then
2743         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2744 fi
2745 AC_MSG_CHECKING([whether to enable Valgrind support])
2746 if test "x$VALGRIND" = xauto; then
2747         VALGRIND="$have_valgrind"
2748 fi
2749
2750 if test "x$VALGRIND" = "xyes"; then
2751         if ! test "x$have_valgrind" = xyes; then
2752                 AC_MSG_ERROR([Valgrind support required but not present])
2753         fi
2754         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2755 fi
2756
2757 AC_MSG_RESULT([$VALGRIND])
2758
2759 dnl Restore LDFLAGS and CPPFLAGS
2760 LDFLAGS="$_SAVE_LDFLAGS"
2761 CPPFLAGS="$_SAVE_CPPFLAGS"
2762
2763 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2764 if test "x$acv_mesa_CLANG" = xyes; then
2765     CFLAGS="$CFLAGS -Qunused-arguments"
2766     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2767 fi
2768
2769 dnl Add user CFLAGS and CXXFLAGS
2770 CFLAGS="$CFLAGS $USER_CFLAGS"
2771 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2772
2773 dnl Substitute the config
2774 AC_CONFIG_FILES([Makefile
2775                 src/Makefile
2776                 src/amd/Makefile
2777                 src/amd/vulkan/Makefile
2778                 src/compiler/Makefile
2779                 src/egl/Makefile
2780                 src/egl/main/egl.pc
2781                 src/egl/wayland/wayland-drm/Makefile
2782                 src/egl/wayland/wayland-egl/Makefile
2783                 src/egl/wayland/wayland-egl/wayland-egl.pc
2784                 src/gallium/Makefile
2785                 src/gallium/auxiliary/Makefile
2786                 src/gallium/auxiliary/pipe-loader/Makefile
2787                 src/gallium/drivers/freedreno/Makefile
2788                 src/gallium/drivers/ddebug/Makefile
2789                 src/gallium/drivers/i915/Makefile
2790                 src/gallium/drivers/ilo/Makefile
2791                 src/gallium/drivers/llvmpipe/Makefile
2792                 src/gallium/drivers/noop/Makefile
2793                 src/gallium/drivers/nouveau/Makefile
2794                 src/gallium/drivers/r300/Makefile
2795                 src/gallium/drivers/r600/Makefile
2796                 src/gallium/drivers/radeon/Makefile
2797                 src/gallium/drivers/radeonsi/Makefile
2798                 src/gallium/drivers/rbug/Makefile
2799                 src/gallium/drivers/softpipe/Makefile
2800                 src/gallium/drivers/svga/Makefile
2801                 src/gallium/drivers/swr/Makefile
2802                 src/gallium/drivers/trace/Makefile
2803                 src/gallium/drivers/etnaviv/Makefile
2804                 src/gallium/drivers/imx/Makefile
2805                 src/gallium/drivers/vc4/Makefile
2806                 src/gallium/drivers/virgl/Makefile
2807                 src/gallium/state_trackers/clover/Makefile
2808                 src/gallium/state_trackers/dri/Makefile
2809                 src/gallium/state_trackers/glx/xlib/Makefile
2810                 src/gallium/state_trackers/nine/Makefile
2811                 src/gallium/state_trackers/omx/Makefile
2812                 src/gallium/state_trackers/osmesa/Makefile
2813                 src/gallium/state_trackers/va/Makefile
2814                 src/gallium/state_trackers/vdpau/Makefile
2815                 src/gallium/state_trackers/xa/Makefile
2816                 src/gallium/state_trackers/xvmc/Makefile
2817                 src/gallium/targets/d3dadapter9/Makefile
2818                 src/gallium/targets/d3dadapter9/d3d.pc
2819                 src/gallium/targets/dri/Makefile
2820                 src/gallium/targets/libgl-xlib/Makefile
2821                 src/gallium/targets/omx/Makefile
2822                 src/gallium/targets/opencl/Makefile
2823                 src/gallium/targets/opencl/mesa.icd
2824                 src/gallium/targets/osmesa/Makefile
2825                 src/gallium/targets/osmesa/osmesa.pc
2826                 src/gallium/targets/pipe-loader/Makefile
2827                 src/gallium/targets/va/Makefile
2828                 src/gallium/targets/vdpau/Makefile
2829                 src/gallium/targets/xa/Makefile
2830                 src/gallium/targets/xa/xatracker.pc
2831                 src/gallium/targets/xvmc/Makefile
2832                 src/gallium/tests/trivial/Makefile
2833                 src/gallium/tests/unit/Makefile
2834                 src/gallium/winsys/etnaviv/drm/Makefile
2835                 src/gallium/winsys/imx/drm/Makefile
2836                 src/gallium/winsys/freedreno/drm/Makefile
2837                 src/gallium/winsys/i915/drm/Makefile
2838                 src/gallium/winsys/intel/drm/Makefile
2839                 src/gallium/winsys/nouveau/drm/Makefile
2840                 src/gallium/winsys/radeon/drm/Makefile
2841                 src/gallium/winsys/amdgpu/drm/Makefile
2842                 src/gallium/winsys/svga/drm/Makefile
2843                 src/gallium/winsys/sw/dri/Makefile
2844                 src/gallium/winsys/sw/kms-dri/Makefile
2845                 src/gallium/winsys/sw/null/Makefile
2846                 src/gallium/winsys/sw/wrapper/Makefile
2847                 src/gallium/winsys/sw/xlib/Makefile
2848                 src/gallium/winsys/vc4/drm/Makefile
2849                 src/gallium/winsys/virgl/drm/Makefile
2850                 src/gallium/winsys/virgl/vtest/Makefile
2851                 src/gbm/Makefile
2852                 src/gbm/main/gbm.pc
2853                 src/glx/Makefile
2854                 src/glx/apple/Makefile
2855                 src/glx/tests/Makefile
2856                 src/glx/windows/Makefile
2857                 src/glx/windows/windowsdriproto.pc
2858                 src/gtest/Makefile
2859                 src/intel/Makefile
2860                 src/intel/tools/Makefile
2861                 src/intel/vulkan/Makefile
2862                 src/loader/Makefile
2863                 src/mapi/Makefile
2864                 src/mapi/es1api/glesv1_cm.pc
2865                 src/mapi/es2api/glesv2.pc
2866                 src/mapi/glapi/gen/Makefile
2867                 src/mesa/Makefile
2868                 src/mesa/gl.pc
2869                 src/mesa/drivers/dri/dri.pc
2870                 src/mesa/drivers/dri/common/Makefile
2871                 src/mesa/drivers/dri/common/xmlpool/Makefile
2872                 src/mesa/drivers/dri/i915/Makefile
2873                 src/mesa/drivers/dri/i965/Makefile
2874                 src/mesa/drivers/dri/Makefile
2875                 src/mesa/drivers/dri/nouveau/Makefile
2876                 src/mesa/drivers/dri/r200/Makefile
2877                 src/mesa/drivers/dri/radeon/Makefile
2878                 src/mesa/drivers/dri/swrast/Makefile
2879                 src/mesa/drivers/osmesa/Makefile
2880                 src/mesa/drivers/osmesa/osmesa.pc
2881                 src/mesa/drivers/x11/Makefile
2882                 src/mesa/main/tests/Makefile
2883                 src/util/Makefile
2884                 src/util/tests/hash_table/Makefile
2885                 src/vulkan/wsi/Makefile])
2886
2887 AC_OUTPUT
2888
2889 # Fix up dependencies in *.Plo files, where we changed the extension of a
2890 # source file
2891 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2892
2893
2894 dnl
2895 dnl Output some configuration info for the user
2896 dnl
2897 echo ""
2898 echo "        prefix:          $prefix"
2899 echo "        exec_prefix:     $exec_prefix"
2900 echo "        libdir:          $libdir"
2901 echo "        includedir:      $includedir"
2902
2903 dnl API info
2904 echo ""
2905 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2906
2907 dnl Driver info
2908 echo ""
2909 case "x$enable_osmesa$enable_gallium_osmesa" in
2910 xnoyes)
2911         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2912         ;;
2913 xyesno)
2914         echo "        OSMesa:          lib$OSMESA_LIB"
2915         ;;
2916 xnono)
2917         echo "        OSMesa:          no"
2918         ;;
2919 esac
2920
2921 echo ""
2922 if test "x$enable_dri" != xno; then
2923         echo "        DRI platform:    $dri_platform"
2924         if test -z "$DRI_DIRS"; then
2925             echo "        DRI drivers:     no"
2926         else
2927             echo "        DRI drivers:     $DRI_DIRS"
2928         fi
2929         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2930 fi
2931
2932 case "x$enable_glx" in
2933 xdri)
2934     echo "        GLX:             DRI-based"
2935     ;;
2936 xxlib)
2937     echo "        GLX:             Xlib-based"
2938     ;;
2939 xgallium-xlib)
2940     echo "        GLX:             Xlib-based (Gallium)"
2941     ;;
2942 *)
2943     echo "        GLX:             $enable_glx"
2944     ;;
2945 esac
2946
2947 dnl EGL
2948 echo ""
2949 echo "        EGL:             $enable_egl"
2950 if test "$enable_egl" = yes; then
2951     echo "        EGL platforms:   $egl_platforms"
2952
2953     egl_drivers=""
2954     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2955         egl_drivers="$egl_drivers builtin:egl_dri2"
2956     fi
2957     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2958         egl_drivers="$egl_drivers builtin:egl_dri3"
2959     fi
2960
2961     echo "        EGL drivers:    $egl_drivers"
2962 fi
2963 if test "x$enable_gbm" = xyes; then
2964     echo "        GBM:             yes"
2965 else
2966     echo "        GBM:             no"
2967 fi
2968
2969 # Vulkan
2970 echo ""
2971 if test "x$VULKAN_DRIVERS" != x; then
2972     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2973     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2974 else
2975     echo "        Vulkan drivers:  no"
2976 fi
2977
2978 echo ""
2979 if test "x$FOUND_LLVM" = xyes; then
2980     echo "        llvm found:      yes"
2981     echo "        llvm-config:     $LLVM_CONFIG"
2982     echo "        llvm-version:    $LLVM_VERSION"
2983 else
2984     echo "        llvm found:      no"
2985 fi
2986 if test "x$USE_LLVM" = xyes; then
2987     echo "        llvm used:       yes"
2988 else
2989     echo "        llvm used:       no"
2990 fi
2991
2992 echo ""
2993 if test -n "$with_gallium_drivers"; then
2994     echo "        Gallium drivers: $gallium_drivers"
2995     echo "        Gallium st:      $gallium_st"
2996     if test "x$HAVE_GALLIUM_LLVM" = xyes; then
2997         echo "        Gallium llvm:    yes"
2998     else
2999         echo "        Gallium llvm:    no"
3000     fi
3001 else
3002     echo "        Gallium:         no"
3003 fi
3004
3005 echo ""
3006 if test "x$enable_gallium_extra_hud" != xyes; then
3007     echo "        HUD extra stats: no"
3008 else
3009     echo "        HUD extra stats: yes"
3010 fi
3011
3012 if test "x$enable_lmsensors" != xyes; then
3013     echo "        HUD lmsensors:   no"
3014 else
3015     echo "        HUD lmsensors:   yes"
3016 fi
3017
3018 dnl Shader cache
3019 echo ""
3020 echo "        Shader cache:    $enable_shader_cache"
3021 if test "x$enable_shader_cache" = "xyes"; then
3022     echo "        With SHA1 from:  $with_sha1"
3023 fi
3024
3025 dnl Libraries
3026 echo ""
3027 echo "        Shared libs:     $enable_shared"
3028 echo "        Static libs:     $enable_static"
3029 echo "        Shared-glapi:    $enable_shared_glapi"
3030
3031 dnl Compiler options
3032 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
3033 cflags=`echo $CFLAGS | \
3034     $SED 's/^ *//;s/  */ /;s/ *$//'`
3035 cxxflags=`echo $CXXFLAGS | \
3036     $SED 's/^ *//;s/  */ /;s/ *$//'`
3037 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3038 echo ""
3039 echo "        CFLAGS:          $cflags"
3040 echo "        CXXFLAGS:        $cxxflags"
3041 echo "        Macros:          $defines"
3042 echo ""
3043 if test "x$FOUND_LLVM" = xyes; then
3044     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3045     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3046     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3047     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3048     echo ""
3049 fi
3050 echo "        PYTHON2:         $PYTHON2"
3051
3052 echo ""
3053 echo "        Run '${MAKE-make}' to build Mesa"
3054 echo ""